src/HOL/Real/RealDef.thy
author wenzelm
Mon Aug 01 19:20:26 2005 +0200 (2005-08-01)
changeset 16973 b2a894562b8f
parent 16888 7cb4bcfa058e
child 19023 5652a536b7e8
permissions -rw-r--r--
simprocs: Simplifier.inherit_bounds;
     1 (*  Title       : Real/RealDef.thy
     2     ID          : $Id$
     3     Author      : Jacques D. Fleuriot
     4     Copyright   : 1998  University of Cambridge
     5     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     6     Additional contributions by Jeremy Avigad
     7 *)
     8 
     9 header{*Defining the Reals from the Positive Reals*}
    10 
    11 theory RealDef
    12 imports PReal
    13 uses ("real_arith.ML")
    14 begin
    15 
    16 constdefs
    17   realrel   ::  "((preal * preal) * (preal * preal)) set"
    18   "realrel == {p. \<exists>x1 y1 x2 y2. p = ((x1,y1),(x2,y2)) & x1+y2 = x2+y1}"
    19 
    20 typedef (Real)  real = "UNIV//realrel"
    21   by (auto simp add: quotient_def)
    22 
    23 instance real :: "{ord, zero, one, plus, times, minus, inverse}" ..
    24 
    25 constdefs
    26 
    27   (** these don't use the overloaded "real" function: users don't see them **)
    28 
    29   real_of_preal :: "preal => real"
    30   "real_of_preal m     ==
    31            Abs_Real(realrel``{(m + preal_of_rat 1, preal_of_rat 1)})"
    32 
    33 consts
    34    (*Overloaded constant denoting the Real subset of enclosing
    35      types such as hypreal and complex*)
    36    Reals :: "'a set"
    37 
    38    (*overloaded constant for injecting other types into "real"*)
    39    real :: "'a => real"
    40 
    41 syntax (xsymbols)
    42   Reals     :: "'a set"                   ("\<real>")
    43 
    44 
    45 defs (overloaded)
    46 
    47   real_zero_def:
    48   "0 == Abs_Real(realrel``{(preal_of_rat 1, preal_of_rat 1)})"
    49 
    50   real_one_def:
    51   "1 == Abs_Real(realrel``
    52                {(preal_of_rat 1 + preal_of_rat 1,
    53 		 preal_of_rat 1)})"
    54 
    55   real_minus_def:
    56   "- r ==  contents (\<Union>(x,y) \<in> Rep_Real(r). { Abs_Real(realrel``{(y,x)}) })"
    57 
    58   real_add_def:
    59    "z + w ==
    60        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    61 		 { Abs_Real(realrel``{(x+u, y+v)}) })"
    62 
    63   real_diff_def:
    64    "r - (s::real) == r + - s"
    65 
    66   real_mult_def:
    67     "z * w ==
    68        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    69 		 { Abs_Real(realrel``{(x*u + y*v, x*v + y*u)}) })"
    70 
    71   real_inverse_def:
    72   "inverse (R::real) == (SOME S. (R = 0 & S = 0) | S * R = 1)"
    73 
    74   real_divide_def:
    75   "R / (S::real) == R * inverse S"
    76 
    77   real_le_def:
    78    "z \<le> (w::real) == 
    79     \<exists>x y u v. x+v \<le> u+y & (x,y) \<in> Rep_Real z & (u,v) \<in> Rep_Real w"
    80 
    81   real_less_def: "(x < (y::real)) == (x \<le> y & x \<noteq> y)"
    82 
    83   real_abs_def:  "abs (r::real) == (if 0 \<le> r then r else -r)"
    84 
    85 
    86 
    87 subsection{*Proving that realrel is an equivalence relation*}
    88 
    89 lemma preal_trans_lemma:
    90   assumes "x + y1 = x1 + y"
    91       and "x + y2 = x2 + y"
    92   shows "x1 + y2 = x2 + (y1::preal)"
    93 proof -
    94   have "(x1 + y2) + x = (x + y2) + x1" by (simp add: preal_add_ac) 
    95   also have "... = (x2 + y) + x1"  by (simp add: prems)
    96   also have "... = x2 + (x1 + y)"  by (simp add: preal_add_ac)
    97   also have "... = x2 + (x + y1)"  by (simp add: prems)
    98   also have "... = (x2 + y1) + x"  by (simp add: preal_add_ac)
    99   finally have "(x1 + y2) + x = (x2 + y1) + x" .
   100   thus ?thesis by (simp add: preal_add_right_cancel_iff) 
   101 qed
   102 
   103 
   104 lemma realrel_iff [simp]: "(((x1,y1),(x2,y2)) \<in> realrel) = (x1 + y2 = x2 + y1)"
   105 by (simp add: realrel_def)
   106 
   107 lemma equiv_realrel: "equiv UNIV realrel"
   108 apply (auto simp add: equiv_def refl_def sym_def trans_def realrel_def)
   109 apply (blast dest: preal_trans_lemma) 
   110 done
   111 
   112 text{*Reduces equality of equivalence classes to the @{term realrel} relation:
   113   @{term "(realrel `` {x} = realrel `` {y}) = ((x,y) \<in> realrel)"} *}
   114 lemmas equiv_realrel_iff = 
   115        eq_equiv_class_iff [OF equiv_realrel UNIV_I UNIV_I]
   116 
   117 declare equiv_realrel_iff [simp]
   118 
   119 
   120 lemma realrel_in_real [simp]: "realrel``{(x,y)}: Real"
   121 by (simp add: Real_def realrel_def quotient_def, blast)
   122 
   123 
   124 lemma inj_on_Abs_Real: "inj_on Abs_Real Real"
   125 apply (rule inj_on_inverseI)
   126 apply (erule Abs_Real_inverse)
   127 done
   128 
   129 declare inj_on_Abs_Real [THEN inj_on_iff, simp]
   130 declare Abs_Real_inverse [simp]
   131 
   132 
   133 text{*Case analysis on the representation of a real number as an equivalence
   134       class of pairs of positive reals.*}
   135 lemma eq_Abs_Real [case_names Abs_Real, cases type: real]: 
   136      "(!!x y. z = Abs_Real(realrel``{(x,y)}) ==> P) ==> P"
   137 apply (rule Rep_Real [of z, unfolded Real_def, THEN quotientE])
   138 apply (drule arg_cong [where f=Abs_Real])
   139 apply (auto simp add: Rep_Real_inverse)
   140 done
   141 
   142 
   143 subsection{*Congruence property for addition*}
   144 
   145 lemma real_add_congruent2_lemma:
   146      "[|a + ba = aa + b; ab + bc = ac + bb|]
   147       ==> a + ab + (ba + bc) = aa + ac + (b + (bb::preal))"
   148 apply (simp add: preal_add_assoc) 
   149 apply (rule preal_add_left_commute [of ab, THEN ssubst])
   150 apply (simp add: preal_add_assoc [symmetric])
   151 apply (simp add: preal_add_ac)
   152 done
   153 
   154 lemma real_add:
   155      "Abs_Real (realrel``{(x,y)}) + Abs_Real (realrel``{(u,v)}) =
   156       Abs_Real (realrel``{(x+u, y+v)})"
   157 proof -
   158   have "(\<lambda>z w. (\<lambda>(x,y). (\<lambda>(u,v). {Abs_Real (realrel `` {(x+u, y+v)})}) w) z)
   159         respects2 realrel"
   160     by (simp add: congruent2_def, blast intro: real_add_congruent2_lemma) 
   161   thus ?thesis
   162     by (simp add: real_add_def UN_UN_split_split_eq
   163                   UN_equiv_class2 [OF equiv_realrel equiv_realrel])
   164 qed
   165 
   166 lemma real_add_commute: "(z::real) + w = w + z"
   167 by (cases z, cases w, simp add: real_add preal_add_ac)
   168 
   169 lemma real_add_assoc: "((z1::real) + z2) + z3 = z1 + (z2 + z3)"
   170 by (cases z1, cases z2, cases z3, simp add: real_add preal_add_assoc)
   171 
   172 lemma real_add_zero_left: "(0::real) + z = z"
   173 by (cases z, simp add: real_add real_zero_def preal_add_ac)
   174 
   175 instance real :: comm_monoid_add
   176   by (intro_classes,
   177       (assumption | 
   178        rule real_add_commute real_add_assoc real_add_zero_left)+)
   179 
   180 
   181 subsection{*Additive Inverse on real*}
   182 
   183 lemma real_minus: "- Abs_Real(realrel``{(x,y)}) = Abs_Real(realrel `` {(y,x)})"
   184 proof -
   185   have "(\<lambda>(x,y). {Abs_Real (realrel``{(y,x)})}) respects realrel"
   186     by (simp add: congruent_def preal_add_commute) 
   187   thus ?thesis
   188     by (simp add: real_minus_def UN_equiv_class [OF equiv_realrel])
   189 qed
   190 
   191 lemma real_add_minus_left: "(-z) + z = (0::real)"
   192 by (cases z, simp add: real_minus real_add real_zero_def preal_add_commute)
   193 
   194 
   195 subsection{*Congruence property for multiplication*}
   196 
   197 lemma real_mult_congruent2_lemma:
   198      "!!(x1::preal). [| x1 + y2 = x2 + y1 |] ==>
   199           x * x1 + y * y1 + (x * y2 + y * x2) =
   200           x * x2 + y * y2 + (x * y1 + y * x1)"
   201 apply (simp add: preal_add_left_commute preal_add_assoc [symmetric])
   202 apply (simp add: preal_add_assoc preal_add_mult_distrib2 [symmetric])
   203 apply (simp add: preal_add_commute)
   204 done
   205 
   206 lemma real_mult_congruent2:
   207     "(%p1 p2.
   208         (%(x1,y1). (%(x2,y2). 
   209           { Abs_Real (realrel``{(x1*x2 + y1*y2, x1*y2+y1*x2)}) }) p2) p1)
   210      respects2 realrel"
   211 apply (rule congruent2_commuteI [OF equiv_realrel], clarify)
   212 apply (simp add: preal_mult_commute preal_add_commute)
   213 apply (auto simp add: real_mult_congruent2_lemma)
   214 done
   215 
   216 lemma real_mult:
   217       "Abs_Real((realrel``{(x1,y1)})) * Abs_Real((realrel``{(x2,y2)})) =
   218        Abs_Real(realrel `` {(x1*x2+y1*y2,x1*y2+y1*x2)})"
   219 by (simp add: real_mult_def UN_UN_split_split_eq
   220          UN_equiv_class2 [OF equiv_realrel equiv_realrel real_mult_congruent2])
   221 
   222 lemma real_mult_commute: "(z::real) * w = w * z"
   223 by (cases z, cases w, simp add: real_mult preal_add_ac preal_mult_ac)
   224 
   225 lemma real_mult_assoc: "((z1::real) * z2) * z3 = z1 * (z2 * z3)"
   226 apply (cases z1, cases z2, cases z3)
   227 apply (simp add: real_mult preal_add_mult_distrib2 preal_add_ac preal_mult_ac)
   228 done
   229 
   230 lemma real_mult_1: "(1::real) * z = z"
   231 apply (cases z)
   232 apply (simp add: real_mult real_one_def preal_add_mult_distrib2
   233                  preal_mult_1_right preal_mult_ac preal_add_ac)
   234 done
   235 
   236 lemma real_add_mult_distrib: "((z1::real) + z2) * w = (z1 * w) + (z2 * w)"
   237 apply (cases z1, cases z2, cases w)
   238 apply (simp add: real_add real_mult preal_add_mult_distrib2 
   239                  preal_add_ac preal_mult_ac)
   240 done
   241 
   242 text{*one and zero are distinct*}
   243 lemma real_zero_not_eq_one: "0 \<noteq> (1::real)"
   244 proof -
   245   have "preal_of_rat 1 < preal_of_rat 1 + preal_of_rat 1"
   246     by (simp add: preal_self_less_add_left) 
   247   thus ?thesis
   248     by (simp add: real_zero_def real_one_def preal_add_right_cancel_iff)
   249 qed
   250 
   251 subsection{*existence of inverse*}
   252 
   253 lemma real_zero_iff: "Abs_Real (realrel `` {(x, x)}) = 0"
   254 by (simp add: real_zero_def preal_add_commute)
   255 
   256 text{*Instead of using an existential quantifier and constructing the inverse
   257 within the proof, we could define the inverse explicitly.*}
   258 
   259 lemma real_mult_inverse_left_ex: "x \<noteq> 0 ==> \<exists>y. y*x = (1::real)"
   260 apply (simp add: real_zero_def real_one_def, cases x)
   261 apply (cut_tac x = xa and y = y in linorder_less_linear)
   262 apply (auto dest!: less_add_left_Ex simp add: real_zero_iff)
   263 apply (rule_tac
   264         x = "Abs_Real (realrel `` { (preal_of_rat 1, 
   265                             inverse (D) + preal_of_rat 1)}) " 
   266        in exI)
   267 apply (rule_tac [2]
   268         x = "Abs_Real (realrel `` { (inverse (D) + preal_of_rat 1,
   269                    preal_of_rat 1)})" 
   270        in exI)
   271 apply (auto simp add: real_mult preal_mult_1_right
   272               preal_add_mult_distrib2 preal_add_mult_distrib preal_mult_1
   273               preal_mult_inverse_right preal_add_ac preal_mult_ac)
   274 done
   275 
   276 lemma real_mult_inverse_left: "x \<noteq> 0 ==> inverse(x)*x = (1::real)"
   277 apply (simp add: real_inverse_def)
   278 apply (frule real_mult_inverse_left_ex, safe)
   279 apply (rule someI2, auto)
   280 done
   281 
   282 
   283 subsection{*The Real Numbers form a Field*}
   284 
   285 instance real :: field
   286 proof
   287   fix x y z :: real
   288   show "- x + x = 0" by (rule real_add_minus_left)
   289   show "x - y = x + (-y)" by (simp add: real_diff_def)
   290   show "(x * y) * z = x * (y * z)" by (rule real_mult_assoc)
   291   show "x * y = y * x" by (rule real_mult_commute)
   292   show "1 * x = x" by (rule real_mult_1)
   293   show "(x + y) * z = x * z + y * z" by (simp add: real_add_mult_distrib)
   294   show "0 \<noteq> (1::real)" by (rule real_zero_not_eq_one)
   295   show "x \<noteq> 0 ==> inverse x * x = 1" by (rule real_mult_inverse_left)
   296   show "x / y = x * inverse y" by (simp add: real_divide_def)
   297 qed
   298 
   299 
   300 text{*Inverse of zero!  Useful to simplify certain equations*}
   301 
   302 lemma INVERSE_ZERO: "inverse 0 = (0::real)"
   303 by (simp add: real_inverse_def)
   304 
   305 instance real :: division_by_zero
   306 proof
   307   show "inverse 0 = (0::real)" by (rule INVERSE_ZERO)
   308 qed
   309 
   310 
   311 (*Pull negations out*)
   312 declare minus_mult_right [symmetric, simp] 
   313         minus_mult_left [symmetric, simp]
   314 
   315 lemma real_mult_1_right: "z * (1::real) = z"
   316   by (rule OrderedGroup.mult_1_right)
   317 
   318 
   319 subsection{*The @{text "\<le>"} Ordering*}
   320 
   321 lemma real_le_refl: "w \<le> (w::real)"
   322 by (cases w, force simp add: real_le_def)
   323 
   324 text{*The arithmetic decision procedure is not set up for type preal.
   325   This lemma is currently unused, but it could simplify the proofs of the
   326   following two lemmas.*}
   327 lemma preal_eq_le_imp_le:
   328   assumes eq: "a+b = c+d" and le: "c \<le> a"
   329   shows "b \<le> (d::preal)"
   330 proof -
   331   have "c+d \<le> a+d" by (simp add: prems preal_cancels)
   332   hence "a+b \<le> a+d" by (simp add: prems)
   333   thus "b \<le> d" by (simp add: preal_cancels)
   334 qed
   335 
   336 lemma real_le_lemma:
   337   assumes l: "u1 + v2 \<le> u2 + v1"
   338       and "x1 + v1 = u1 + y1"
   339       and "x2 + v2 = u2 + y2"
   340   shows "x1 + y2 \<le> x2 + (y1::preal)"
   341 proof -
   342   have "(x1+v1) + (u2+y2) = (u1+y1) + (x2+v2)" by (simp add: prems)
   343   hence "(x1+y2) + (u2+v1) = (x2+y1) + (u1+v2)" by (simp add: preal_add_ac)
   344   also have "... \<le> (x2+y1) + (u2+v1)"
   345          by (simp add: prems preal_add_le_cancel_left)
   346   finally show ?thesis by (simp add: preal_add_le_cancel_right)
   347 qed						 
   348 
   349 lemma real_le: 
   350      "(Abs_Real(realrel``{(x1,y1)}) \<le> Abs_Real(realrel``{(x2,y2)})) =  
   351       (x1 + y2 \<le> x2 + y1)"
   352 apply (simp add: real_le_def) 
   353 apply (auto intro: real_le_lemma)
   354 done
   355 
   356 lemma real_le_anti_sym: "[| z \<le> w; w \<le> z |] ==> z = (w::real)"
   357 by (cases z, cases w, simp add: real_le)
   358 
   359 lemma real_trans_lemma:
   360   assumes "x + v \<le> u + y"
   361       and "u + v' \<le> u' + v"
   362       and "x2 + v2 = u2 + y2"
   363   shows "x + v' \<le> u' + (y::preal)"
   364 proof -
   365   have "(x+v') + (u+v) = (x+v) + (u+v')" by (simp add: preal_add_ac)
   366   also have "... \<le> (u+y) + (u+v')" 
   367     by (simp add: preal_add_le_cancel_right prems) 
   368   also have "... \<le> (u+y) + (u'+v)" 
   369     by (simp add: preal_add_le_cancel_left prems) 
   370   also have "... = (u'+y) + (u+v)"  by (simp add: preal_add_ac)
   371   finally show ?thesis by (simp add: preal_add_le_cancel_right)
   372 qed
   373 
   374 lemma real_le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::real)"
   375 apply (cases i, cases j, cases k)
   376 apply (simp add: real_le)
   377 apply (blast intro: real_trans_lemma) 
   378 done
   379 
   380 (* Axiom 'order_less_le' of class 'order': *)
   381 lemma real_less_le: "((w::real) < z) = (w \<le> z & w \<noteq> z)"
   382 by (simp add: real_less_def)
   383 
   384 instance real :: order
   385 proof qed
   386  (assumption |
   387   rule real_le_refl real_le_trans real_le_anti_sym real_less_le)+
   388 
   389 (* Axiom 'linorder_linear' of class 'linorder': *)
   390 lemma real_le_linear: "(z::real) \<le> w | w \<le> z"
   391 apply (cases z, cases w) 
   392 apply (auto simp add: real_le real_zero_def preal_add_ac preal_cancels)
   393 done
   394 
   395 
   396 instance real :: linorder
   397   by (intro_classes, rule real_le_linear)
   398 
   399 
   400 lemma real_le_eq_diff: "(x \<le> y) = (x-y \<le> (0::real))"
   401 apply (cases x, cases y) 
   402 apply (auto simp add: real_le real_zero_def real_diff_def real_add real_minus
   403                       preal_add_ac)
   404 apply (simp_all add: preal_add_assoc [symmetric] preal_cancels)
   405 done
   406 
   407 lemma real_add_left_mono: 
   408   assumes le: "x \<le> y" shows "z + x \<le> z + (y::real)"
   409 proof -
   410   have "z + x - (z + y) = (z + -z) + (x - y)"
   411     by (simp add: diff_minus add_ac) 
   412   with le show ?thesis 
   413     by (simp add: real_le_eq_diff[of x] real_le_eq_diff[of "z+x"] diff_minus)
   414 qed
   415 
   416 lemma real_sum_gt_zero_less: "(0 < S + (-W::real)) ==> (W < S)"
   417 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   418 
   419 lemma real_less_sum_gt_zero: "(W < S) ==> (0 < S + (-W::real))"
   420 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   421 
   422 lemma real_mult_order: "[| 0 < x; 0 < y |] ==> (0::real) < x * y"
   423 apply (cases x, cases y)
   424 apply (simp add: linorder_not_le [where 'a = real, symmetric] 
   425                  linorder_not_le [where 'a = preal] 
   426                   real_zero_def real_le real_mult)
   427   --{*Reduce to the (simpler) @{text "\<le>"} relation *}
   428 apply (auto dest!: less_add_left_Ex
   429      simp add: preal_add_ac preal_mult_ac 
   430           preal_add_mult_distrib2 preal_cancels preal_self_less_add_left)
   431 done
   432 
   433 lemma real_mult_less_mono2: "[| (0::real) < z; x < y |] ==> z * x < z * y"
   434 apply (rule real_sum_gt_zero_less)
   435 apply (drule real_less_sum_gt_zero [of x y])
   436 apply (drule real_mult_order, assumption)
   437 apply (simp add: right_distrib)
   438 done
   439 
   440 text{*lemma for proving @{term "0<(1::real)"}*}
   441 lemma real_zero_le_one: "0 \<le> (1::real)"
   442 by (simp add: real_zero_def real_one_def real_le 
   443                  preal_self_less_add_left order_less_imp_le)
   444 
   445 
   446 subsection{*The Reals Form an Ordered Field*}
   447 
   448 instance real :: ordered_field
   449 proof
   450   fix x y z :: real
   451   show "x \<le> y ==> z + x \<le> z + y" by (rule real_add_left_mono)
   452   show "x < y ==> 0 < z ==> z * x < z * y" by (simp add: real_mult_less_mono2)
   453   show "\<bar>x\<bar> = (if x < 0 then -x else x)"
   454     by (auto dest: order_le_less_trans simp add: real_abs_def linorder_not_le)
   455 qed
   456 
   457 
   458 
   459 text{*The function @{term real_of_preal} requires many proofs, but it seems
   460 to be essential for proving completeness of the reals from that of the
   461 positive reals.*}
   462 
   463 lemma real_of_preal_add:
   464      "real_of_preal ((x::preal) + y) = real_of_preal x + real_of_preal y"
   465 by (simp add: real_of_preal_def real_add preal_add_mult_distrib preal_mult_1 
   466               preal_add_ac)
   467 
   468 lemma real_of_preal_mult:
   469      "real_of_preal ((x::preal) * y) = real_of_preal x* real_of_preal y"
   470 by (simp add: real_of_preal_def real_mult preal_add_mult_distrib2
   471               preal_mult_1 preal_mult_1_right preal_add_ac preal_mult_ac)
   472 
   473 
   474 text{*Gleason prop 9-4.4 p 127*}
   475 lemma real_of_preal_trichotomy:
   476       "\<exists>m. (x::real) = real_of_preal m | x = 0 | x = -(real_of_preal m)"
   477 apply (simp add: real_of_preal_def real_zero_def, cases x)
   478 apply (auto simp add: real_minus preal_add_ac)
   479 apply (cut_tac x = x and y = y in linorder_less_linear)
   480 apply (auto dest!: less_add_left_Ex simp add: preal_add_assoc [symmetric])
   481 done
   482 
   483 lemma real_of_preal_leD:
   484       "real_of_preal m1 \<le> real_of_preal m2 ==> m1 \<le> m2"
   485 by (simp add: real_of_preal_def real_le preal_cancels)
   486 
   487 lemma real_of_preal_lessI: "m1 < m2 ==> real_of_preal m1 < real_of_preal m2"
   488 by (auto simp add: real_of_preal_leD linorder_not_le [symmetric])
   489 
   490 lemma real_of_preal_lessD:
   491       "real_of_preal m1 < real_of_preal m2 ==> m1 < m2"
   492 by (simp add: real_of_preal_def real_le linorder_not_le [symmetric] 
   493               preal_cancels) 
   494 
   495 
   496 lemma real_of_preal_less_iff [simp]:
   497      "(real_of_preal m1 < real_of_preal m2) = (m1 < m2)"
   498 by (blast intro: real_of_preal_lessI real_of_preal_lessD)
   499 
   500 lemma real_of_preal_le_iff:
   501      "(real_of_preal m1 \<le> real_of_preal m2) = (m1 \<le> m2)"
   502 by (simp add: linorder_not_less [symmetric]) 
   503 
   504 lemma real_of_preal_zero_less: "0 < real_of_preal m"
   505 apply (auto simp add: real_zero_def real_of_preal_def real_less_def real_le_def
   506             preal_add_ac preal_cancels)
   507 apply (simp_all add: preal_add_assoc [symmetric] preal_cancels)
   508 apply (blast intro: preal_self_less_add_left order_less_imp_le)
   509 apply (insert preal_not_eq_self [of "preal_of_rat 1" m]) 
   510 apply (simp add: preal_add_ac) 
   511 done
   512 
   513 lemma real_of_preal_minus_less_zero: "- real_of_preal m < 0"
   514 by (simp add: real_of_preal_zero_less)
   515 
   516 lemma real_of_preal_not_minus_gt_zero: "~ 0 < - real_of_preal m"
   517 proof -
   518   from real_of_preal_minus_less_zero
   519   show ?thesis by (blast dest: order_less_trans)
   520 qed
   521 
   522 
   523 subsection{*Theorems About the Ordering*}
   524 
   525 text{*obsolete but used a lot*}
   526 
   527 lemma real_not_refl2: "x < y ==> x \<noteq> (y::real)"
   528 by blast 
   529 
   530 lemma real_le_imp_less_or_eq: "!!(x::real). x \<le> y ==> x < y | x = y"
   531 by (simp add: order_le_less)
   532 
   533 lemma real_gt_zero_preal_Ex: "(0 < x) = (\<exists>y. x = real_of_preal y)"
   534 apply (auto simp add: real_of_preal_zero_less)
   535 apply (cut_tac x = x in real_of_preal_trichotomy)
   536 apply (blast elim!: real_of_preal_not_minus_gt_zero [THEN notE])
   537 done
   538 
   539 lemma real_gt_preal_preal_Ex:
   540      "real_of_preal z < x ==> \<exists>y. x = real_of_preal y"
   541 by (blast dest!: real_of_preal_zero_less [THEN order_less_trans]
   542              intro: real_gt_zero_preal_Ex [THEN iffD1])
   543 
   544 lemma real_ge_preal_preal_Ex:
   545      "real_of_preal z \<le> x ==> \<exists>y. x = real_of_preal y"
   546 by (blast dest: order_le_imp_less_or_eq real_gt_preal_preal_Ex)
   547 
   548 lemma real_less_all_preal: "y \<le> 0 ==> \<forall>x. y < real_of_preal x"
   549 by (auto elim: order_le_imp_less_or_eq [THEN disjE] 
   550             intro: real_of_preal_zero_less [THEN [2] order_less_trans] 
   551             simp add: real_of_preal_zero_less)
   552 
   553 lemma real_less_all_real2: "~ 0 < y ==> \<forall>x. y < real_of_preal x"
   554 by (blast intro!: real_less_all_preal linorder_not_less [THEN iffD1])
   555 
   556 lemma real_add_less_le_mono: "[| w'<w; z'\<le>z |] ==> w' + z' < w + (z::real)"
   557   by (rule OrderedGroup.add_less_le_mono)
   558 
   559 lemma real_add_le_less_mono:
   560      "!!z z'::real. [| w'\<le>w; z'<z |] ==> w' + z' < w + z"
   561   by (rule OrderedGroup.add_le_less_mono)
   562 
   563 lemma real_le_square [simp]: "(0::real) \<le> x*x"
   564  by (rule Ring_and_Field.zero_le_square)
   565 
   566 
   567 subsection{*More Lemmas*}
   568 
   569 lemma real_mult_left_cancel: "(c::real) \<noteq> 0 ==> (c*a=c*b) = (a=b)"
   570 by auto
   571 
   572 lemma real_mult_right_cancel: "(c::real) \<noteq> 0 ==> (a*c=b*c) = (a=b)"
   573 by auto
   574 
   575 text{*The precondition could be weakened to @{term "0\<le>x"}*}
   576 lemma real_mult_less_mono:
   577      "[| u<v;  x<y;  (0::real) < v;  0 < x |] ==> u*x < v* y"
   578  by (simp add: Ring_and_Field.mult_strict_mono order_less_imp_le)
   579 
   580 lemma real_mult_less_iff1 [simp]: "(0::real) < z ==> (x*z < y*z) = (x < y)"
   581   by (force elim: order_less_asym
   582             simp add: Ring_and_Field.mult_less_cancel_right)
   583 
   584 lemma real_mult_le_cancel_iff1 [simp]: "(0::real) < z ==> (x*z \<le> y*z) = (x\<le>y)"
   585 apply (simp add: mult_le_cancel_right)
   586 apply (blast intro: elim: order_less_asym) 
   587 done
   588 
   589 lemma real_mult_le_cancel_iff2 [simp]: "(0::real) < z ==> (z*x \<le> z*y) = (x\<le>y)"
   590 by(simp add:mult_commute)
   591 
   592 text{*Only two uses?*}
   593 lemma real_mult_less_mono':
   594      "[| x < y;  r1 < r2;  (0::real) \<le> r1;  0 \<le> x|] ==> r1 * x < r2 * y"
   595  by (rule Ring_and_Field.mult_strict_mono')
   596 
   597 text{*FIXME: delete or at least combine the next two lemmas*}
   598 lemma real_sum_squares_cancel: "x * x + y * y = 0 ==> x = (0::real)"
   599 apply (drule OrderedGroup.equals_zero_I [THEN sym])
   600 apply (cut_tac x = y in real_le_square) 
   601 apply (auto, drule order_antisym, auto)
   602 done
   603 
   604 lemma real_sum_squares_cancel2: "x * x + y * y = 0 ==> y = (0::real)"
   605 apply (rule_tac y = x in real_sum_squares_cancel)
   606 apply (simp add: add_commute)
   607 done
   608 
   609 lemma real_add_order: "[| 0 < x; 0 < y |] ==> (0::real) < x + y"
   610 by (drule add_strict_mono [of concl: 0 0], assumption, simp)
   611 
   612 lemma real_le_add_order: "[| 0 \<le> x; 0 \<le> y |] ==> (0::real) \<le> x + y"
   613 apply (drule order_le_imp_less_or_eq)+
   614 apply (auto intro: real_add_order order_less_imp_le)
   615 done
   616 
   617 lemma real_inverse_unique: "x*y = (1::real) ==> y = inverse x"
   618 apply (case_tac "x \<noteq> 0")
   619 apply (rule_tac c1 = x in real_mult_left_cancel [THEN iffD1], auto)
   620 done
   621 
   622 lemma real_inverse_gt_one: "[| (0::real) < x; x < 1 |] ==> 1 < inverse x"
   623 by (auto dest: less_imp_inverse_less)
   624 
   625 lemma real_mult_self_sum_ge_zero: "(0::real) \<le> x*x + y*y"
   626 proof -
   627   have "0 + 0 \<le> x*x + y*y" by (blast intro: add_mono zero_le_square)
   628   thus ?thesis by simp
   629 qed
   630 
   631 
   632 subsection{*Embedding the Integers into the Reals*}
   633 
   634 defs (overloaded)
   635   real_of_nat_def: "real z == of_nat z"
   636   real_of_int_def: "real z == of_int z"
   637 
   638 lemma real_eq_of_nat: "real = of_nat"
   639   apply (rule ext)
   640   apply (unfold real_of_nat_def)
   641   apply (rule refl)
   642   done
   643 
   644 lemma real_eq_of_int: "real = of_int"
   645   apply (rule ext)
   646   apply (unfold real_of_int_def)
   647   apply (rule refl)
   648   done
   649 
   650 lemma real_of_int_zero [simp]: "real (0::int) = 0"  
   651 by (simp add: real_of_int_def) 
   652 
   653 lemma real_of_one [simp]: "real (1::int) = (1::real)"
   654 by (simp add: real_of_int_def) 
   655 
   656 lemma real_of_int_add [simp]: "real(x + y) = real (x::int) + real y"
   657 by (simp add: real_of_int_def) 
   658 
   659 lemma real_of_int_minus [simp]: "real(-x) = -real (x::int)"
   660 by (simp add: real_of_int_def) 
   661 
   662 lemma real_of_int_diff [simp]: "real(x - y) = real (x::int) - real y"
   663 by (simp add: real_of_int_def) 
   664 
   665 lemma real_of_int_mult [simp]: "real(x * y) = real (x::int) * real y"
   666 by (simp add: real_of_int_def) 
   667 
   668 lemma real_of_int_setsum [simp]: "real ((SUM x:A. f x)::int) = (SUM x:A. real(f x))"
   669   apply (subst real_eq_of_int)+
   670   apply (rule of_int_setsum)
   671 done
   672 
   673 lemma real_of_int_setprod [simp]: "real ((PROD x:A. f x)::int) = 
   674     (PROD x:A. real(f x))"
   675   apply (subst real_eq_of_int)+
   676   apply (rule of_int_setprod)
   677 done
   678 
   679 lemma real_of_int_zero_cancel [simp]: "(real x = 0) = (x = (0::int))"
   680 by (simp add: real_of_int_def) 
   681 
   682 lemma real_of_int_inject [iff]: "(real (x::int) = real y) = (x = y)"
   683 by (simp add: real_of_int_def) 
   684 
   685 lemma real_of_int_less_iff [iff]: "(real (x::int) < real y) = (x < y)"
   686 by (simp add: real_of_int_def) 
   687 
   688 lemma real_of_int_le_iff [simp]: "(real (x::int) \<le> real y) = (x \<le> y)"
   689 by (simp add: real_of_int_def) 
   690 
   691 lemma real_of_int_gt_zero_cancel_iff [simp]: "(0 < real (n::int)) = (0 < n)"
   692 by (simp add: real_of_int_def) 
   693 
   694 lemma real_of_int_ge_zero_cancel_iff [simp]: "(0 <= real (n::int)) = (0 <= n)"
   695 by (simp add: real_of_int_def) 
   696 
   697 lemma real_of_int_lt_zero_cancel_iff [simp]: "(real (n::int) < 0) = (n < 0)"
   698 by (simp add: real_of_int_def)
   699 
   700 lemma real_of_int_le_zero_cancel_iff [simp]: "(real (n::int) <= 0) = (n <= 0)"
   701 by (simp add: real_of_int_def)
   702 
   703 lemma real_of_int_abs [simp]: "real (abs x) = abs(real (x::int))"
   704 by (auto simp add: abs_if)
   705 
   706 lemma int_less_real_le: "((n::int) < m) = (real n + 1 <= real m)"
   707   apply (subgoal_tac "real n + 1 = real (n + 1)")
   708   apply (simp del: real_of_int_add)
   709   apply auto
   710 done
   711 
   712 lemma int_le_real_less: "((n::int) <= m) = (real n < real m + 1)"
   713   apply (subgoal_tac "real m + 1 = real (m + 1)")
   714   apply (simp del: real_of_int_add)
   715   apply simp
   716 done
   717 
   718 lemma real_of_int_div_aux: "d ~= 0 ==> (real (x::int)) / (real d) = 
   719     real (x div d) + (real (x mod d)) / (real d)"
   720 proof -
   721   assume "d ~= 0"
   722   have "x = (x div d) * d + x mod d"
   723     by auto
   724   then have "real x = real (x div d) * real d + real(x mod d)"
   725     by (simp only: real_of_int_mult [THEN sym] real_of_int_add [THEN sym])
   726   then have "real x / real d = ... / real d"
   727     by simp
   728   then show ?thesis
   729     by (auto simp add: add_divide_distrib ring_eq_simps prems)
   730 qed
   731 
   732 lemma real_of_int_div: "(d::int) ~= 0 ==> d dvd n ==>
   733     real(n div d) = real n / real d"
   734   apply (frule real_of_int_div_aux [of d n])
   735   apply simp
   736   apply (simp add: zdvd_iff_zmod_eq_0)
   737 done
   738 
   739 lemma real_of_int_div2:
   740   "0 <= real (n::int) / real (x) - real (n div x)"
   741   apply (case_tac "x = 0")
   742   apply simp
   743   apply (case_tac "0 < x")
   744   apply (simp add: compare_rls)
   745   apply (subst real_of_int_div_aux)
   746   apply simp
   747   apply simp
   748   apply (subst zero_le_divide_iff)
   749   apply auto
   750   apply (simp add: compare_rls)
   751   apply (subst real_of_int_div_aux)
   752   apply simp
   753   apply simp
   754   apply (subst zero_le_divide_iff)
   755   apply auto
   756 done
   757 
   758 lemma real_of_int_div3:
   759   "real (n::int) / real (x) - real (n div x) <= 1"
   760   apply(case_tac "x = 0")
   761   apply simp
   762   apply (simp add: compare_rls)
   763   apply (subst real_of_int_div_aux)
   764   apply assumption
   765   apply simp
   766   apply (subst divide_le_eq)
   767   apply clarsimp
   768   apply (rule conjI)
   769   apply (rule impI)
   770   apply (rule order_less_imp_le)
   771   apply simp
   772   apply (rule impI)
   773   apply (rule order_less_imp_le)
   774   apply simp
   775 done
   776 
   777 lemma real_of_int_div4: "real (n div x) <= real (n::int) / real x" 
   778   by (insert real_of_int_div2 [of n x], simp)
   779 
   780 subsection{*Embedding the Naturals into the Reals*}
   781 
   782 lemma real_of_nat_zero [simp]: "real (0::nat) = 0"
   783 by (simp add: real_of_nat_def)
   784 
   785 lemma real_of_nat_one [simp]: "real (Suc 0) = (1::real)"
   786 by (simp add: real_of_nat_def)
   787 
   788 lemma real_of_nat_add [simp]: "real (m + n) = real (m::nat) + real n"
   789 by (simp add: real_of_nat_def)
   790 
   791 (*Not for addsimps: often the LHS is used to represent a positive natural*)
   792 lemma real_of_nat_Suc: "real (Suc n) = real n + (1::real)"
   793 by (simp add: real_of_nat_def)
   794 
   795 lemma real_of_nat_less_iff [iff]: 
   796      "(real (n::nat) < real m) = (n < m)"
   797 by (simp add: real_of_nat_def)
   798 
   799 lemma real_of_nat_le_iff [iff]: "(real (n::nat) \<le> real m) = (n \<le> m)"
   800 by (simp add: real_of_nat_def)
   801 
   802 lemma real_of_nat_ge_zero [iff]: "0 \<le> real (n::nat)"
   803 by (simp add: real_of_nat_def zero_le_imp_of_nat)
   804 
   805 lemma real_of_nat_Suc_gt_zero: "0 < real (Suc n)"
   806 by (simp add: real_of_nat_def del: of_nat_Suc)
   807 
   808 lemma real_of_nat_mult [simp]: "real (m * n) = real (m::nat) * real n"
   809 by (simp add: real_of_nat_def)
   810 
   811 lemma real_of_nat_setsum [simp]: "real ((SUM x:A. f x)::nat) = 
   812     (SUM x:A. real(f x))"
   813   apply (subst real_eq_of_nat)+
   814   apply (rule of_nat_setsum)
   815 done
   816 
   817 lemma real_of_nat_setprod [simp]: "real ((PROD x:A. f x)::nat) = 
   818     (PROD x:A. real(f x))"
   819   apply (subst real_eq_of_nat)+
   820   apply (rule of_nat_setprod)
   821 done
   822 
   823 lemma real_of_card: "real (card A) = setsum (%x.1) A"
   824   apply (subst card_eq_setsum)
   825   apply (subst real_of_nat_setsum)
   826   apply simp
   827 done
   828 
   829 lemma real_of_nat_inject [iff]: "(real (n::nat) = real m) = (n = m)"
   830 by (simp add: real_of_nat_def)
   831 
   832 lemma real_of_nat_zero_iff [iff]: "(real (n::nat) = 0) = (n = 0)"
   833 by (simp add: real_of_nat_def)
   834 
   835 lemma real_of_nat_diff: "n \<le> m ==> real (m - n) = real (m::nat) - real n"
   836 by (simp add: add: real_of_nat_def) 
   837 
   838 lemma real_of_nat_gt_zero_cancel_iff [simp]: "(0 < real (n::nat)) = (0 < n)"
   839 by (simp add: add: real_of_nat_def) 
   840 
   841 lemma real_of_nat_le_zero_cancel_iff [simp]: "(real (n::nat) \<le> 0) = (n = 0)"
   842 by (simp add: add: real_of_nat_def)
   843 
   844 lemma not_real_of_nat_less_zero [simp]: "~ real (n::nat) < 0"
   845 by (simp add: add: real_of_nat_def)
   846 
   847 lemma real_of_nat_ge_zero_cancel_iff [simp]: "(0 \<le> real (n::nat)) = (0 \<le> n)"
   848 by (simp add: add: real_of_nat_def)
   849 
   850 lemma nat_less_real_le: "((n::nat) < m) = (real n + 1 <= real m)"
   851   apply (subgoal_tac "real n + 1 = real (Suc n)")
   852   apply simp
   853   apply (auto simp add: real_of_nat_Suc)
   854 done
   855 
   856 lemma nat_le_real_less: "((n::nat) <= m) = (real n < real m + 1)"
   857   apply (subgoal_tac "real m + 1 = real (Suc m)")
   858   apply (simp add: less_Suc_eq_le)
   859   apply (simp add: real_of_nat_Suc)
   860 done
   861 
   862 lemma real_of_nat_div_aux: "0 < d ==> (real (x::nat)) / (real d) = 
   863     real (x div d) + (real (x mod d)) / (real d)"
   864 proof -
   865   assume "0 < d"
   866   have "x = (x div d) * d + x mod d"
   867     by auto
   868   then have "real x = real (x div d) * real d + real(x mod d)"
   869     by (simp only: real_of_nat_mult [THEN sym] real_of_nat_add [THEN sym])
   870   then have "real x / real d = \<dots> / real d"
   871     by simp
   872   then show ?thesis
   873     by (auto simp add: add_divide_distrib ring_eq_simps prems)
   874 qed
   875 
   876 lemma real_of_nat_div: "0 < (d::nat) ==> d dvd n ==>
   877     real(n div d) = real n / real d"
   878   apply (frule real_of_nat_div_aux [of d n])
   879   apply simp
   880   apply (subst dvd_eq_mod_eq_0 [THEN sym])
   881   apply assumption
   882 done
   883 
   884 lemma real_of_nat_div2:
   885   "0 <= real (n::nat) / real (x) - real (n div x)"
   886   apply(case_tac "x = 0")
   887   apply simp
   888   apply (simp add: compare_rls)
   889   apply (subst real_of_nat_div_aux)
   890   apply assumption
   891   apply simp
   892   apply (subst zero_le_divide_iff)
   893   apply simp
   894 done
   895 
   896 lemma real_of_nat_div3:
   897   "real (n::nat) / real (x) - real (n div x) <= 1"
   898   apply(case_tac "x = 0")
   899   apply simp
   900   apply (simp add: compare_rls)
   901   apply (subst real_of_nat_div_aux)
   902   apply assumption
   903   apply simp
   904 done
   905 
   906 lemma real_of_nat_div4: "real (n div x) <= real (n::nat) / real x" 
   907   by (insert real_of_nat_div2 [of n x], simp)
   908 
   909 lemma real_of_int_real_of_nat: "real (int n) = real n"
   910 by (simp add: real_of_nat_def real_of_int_def int_eq_of_nat)
   911 
   912 lemma real_of_int_of_nat_eq [simp]: "real (of_nat n :: int) = real n"
   913 by (simp add: real_of_int_def real_of_nat_def)
   914 
   915 lemma real_nat_eq_real [simp]: "0 <= x ==> real(nat x) = real x"
   916   apply (subgoal_tac "real(int(nat x)) = real(nat x)")
   917   apply force
   918   apply (simp only: real_of_int_real_of_nat)
   919 done
   920 
   921 subsection{*Numerals and Arithmetic*}
   922 
   923 instance real :: number ..
   924 
   925 defs (overloaded)
   926   real_number_of_def: "(number_of w :: real) == of_int (Rep_Bin w)"
   927     --{*the type constraint is essential!*}
   928 
   929 instance real :: number_ring
   930 by (intro_classes, simp add: real_number_of_def) 
   931 
   932 
   933 text{*Collapse applications of @{term real} to @{term number_of}*}
   934 lemma real_number_of [simp]: "real (number_of v :: int) = number_of v"
   935 by (simp add:  real_of_int_def of_int_number_of_eq)
   936 
   937 lemma real_of_nat_number_of [simp]:
   938      "real (number_of v :: nat) =  
   939         (if neg (number_of v :: int) then 0  
   940          else (number_of v :: real))"
   941 by (simp add: real_of_int_real_of_nat [symmetric] int_nat_number_of)
   942  
   943 
   944 use "real_arith.ML"
   945 
   946 setup real_arith_setup
   947 
   948 subsection{* Simprules combining x+y and 0: ARE THEY NEEDED?*}
   949 
   950 text{*Needed in this non-standard form by Hyperreal/Transcendental*}
   951 lemma real_0_le_divide_iff:
   952      "((0::real) \<le> x/y) = ((x \<le> 0 | 0 \<le> y) & (0 \<le> x | y \<le> 0))"
   953 by (simp add: real_divide_def zero_le_mult_iff, auto)
   954 
   955 lemma real_add_minus_iff [simp]: "(x + - a = (0::real)) = (x=a)" 
   956 by arith
   957 
   958 lemma real_add_eq_0_iff: "(x+y = (0::real)) = (y = -x)"
   959 by auto
   960 
   961 lemma real_add_less_0_iff: "(x+y < (0::real)) = (y < -x)"
   962 by auto
   963 
   964 lemma real_0_less_add_iff: "((0::real) < x+y) = (-x < y)"
   965 by auto
   966 
   967 lemma real_add_le_0_iff: "(x+y \<le> (0::real)) = (y \<le> -x)"
   968 by auto
   969 
   970 lemma real_0_le_add_iff: "((0::real) \<le> x+y) = (-x \<le> y)"
   971 by auto
   972 
   973 
   974 (*
   975 FIXME: we should have this, as for type int, but many proofs would break.
   976 It replaces x+-y by x-y.
   977 declare real_diff_def [symmetric, simp]
   978 *)
   979 
   980 
   981 subsubsection{*Density of the Reals*}
   982 
   983 lemma real_lbound_gt_zero:
   984      "[| (0::real) < d1; 0 < d2 |] ==> \<exists>e. 0 < e & e < d1 & e < d2"
   985 apply (rule_tac x = " (min d1 d2) /2" in exI)
   986 apply (simp add: min_def)
   987 done
   988 
   989 
   990 text{*Similar results are proved in @{text Ring_and_Field}*}
   991 lemma real_less_half_sum: "x < y ==> x < (x+y) / (2::real)"
   992   by auto
   993 
   994 lemma real_gt_half_sum: "x < y ==> (x+y)/(2::real) < y"
   995   by auto
   996 
   997 
   998 subsection{*Absolute Value Function for the Reals*}
   999 
  1000 lemma abs_minus_add_cancel: "abs(x + (-y)) = abs (y + (-(x::real)))"
  1001 by (simp add: abs_if)
  1002 
  1003 lemma abs_interval_iff: "(abs x < r) = (-r < x & x < (r::real))"
  1004 by (force simp add: Ring_and_Field.abs_less_iff)
  1005 
  1006 lemma abs_le_interval_iff: "(abs x \<le> r) = (-r\<le>x & x\<le>(r::real))"
  1007 by (force simp add: OrderedGroup.abs_le_iff)
  1008 
  1009 (*FIXME: used only once, in SEQ.ML*)
  1010 lemma abs_add_one_gt_zero [simp]: "(0::real) < 1 + abs(x)"
  1011 by (simp add: abs_if)
  1012 
  1013 lemma abs_real_of_nat_cancel [simp]: "abs (real x) = real (x::nat)"
  1014 by (simp add: real_of_nat_ge_zero)
  1015 
  1016 lemma abs_add_one_not_less_self [simp]: "~ abs(x) + (1::real) < x"
  1017 apply (simp add: linorder_not_less)
  1018 apply (auto intro: abs_ge_self [THEN order_trans])
  1019 done
  1020  
  1021 text{*Used only in Hyperreal/Lim.ML*}
  1022 lemma abs_sum_triangle_ineq: "abs ((x::real) + y + (-l + -m)) \<le> abs(x + -l) + abs(y + -m)"
  1023 apply (simp add: real_add_assoc)
  1024 apply (rule_tac a1 = y in add_left_commute [THEN ssubst])
  1025 apply (rule real_add_assoc [THEN subst])
  1026 apply (rule abs_triangle_ineq)
  1027 done
  1028 
  1029 
  1030 
  1031 ML
  1032 {*
  1033 val real_lbound_gt_zero = thm"real_lbound_gt_zero";
  1034 val real_less_half_sum = thm"real_less_half_sum";
  1035 val real_gt_half_sum = thm"real_gt_half_sum";
  1036 
  1037 val abs_interval_iff = thm"abs_interval_iff";
  1038 val abs_le_interval_iff = thm"abs_le_interval_iff";
  1039 val abs_add_one_gt_zero = thm"abs_add_one_gt_zero";
  1040 val abs_add_one_not_less_self = thm"abs_add_one_not_less_self";
  1041 val abs_sum_triangle_ineq = thm"abs_sum_triangle_ineq";
  1042 *}
  1043 
  1044 
  1045 end