src/HOL/Lattices.thy
author haftmann
Sat Jul 25 18:44:54 2009 +0200 (2009-07-25)
changeset 32204 b330aa4d59cb
parent 32064 53ca12ff305d
child 32436 10cd49e0c067
permissions -rw-r--r--
localized interpretation of min/max-lattice
     1 (*  Title:      HOL/Lattices.thy
     2     Author:     Tobias Nipkow
     3 *)
     4 
     5 header {* Abstract lattices *}
     6 
     7 theory Lattices
     8 imports Orderings
     9 begin
    10 
    11 subsection {* Lattices *}
    12 
    13 notation
    14   less_eq  (infix "\<sqsubseteq>" 50) and
    15   less  (infix "\<sqsubset>" 50)
    16 
    17 class lower_semilattice = order +
    18   fixes inf :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "\<sqinter>" 70)
    19   assumes inf_le1 [simp]: "x \<sqinter> y \<sqsubseteq> x"
    20   and inf_le2 [simp]: "x \<sqinter> y \<sqsubseteq> y"
    21   and inf_greatest: "x \<sqsubseteq> y \<Longrightarrow> x \<sqsubseteq> z \<Longrightarrow> x \<sqsubseteq> y \<sqinter> z"
    22 
    23 class upper_semilattice = order +
    24   fixes sup :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "\<squnion>" 65)
    25   assumes sup_ge1 [simp]: "x \<sqsubseteq> x \<squnion> y"
    26   and sup_ge2 [simp]: "y \<sqsubseteq> x \<squnion> y"
    27   and sup_least: "y \<sqsubseteq> x \<Longrightarrow> z \<sqsubseteq> x \<Longrightarrow> y \<squnion> z \<sqsubseteq> x"
    28 begin
    29 
    30 text {* Dual lattice *}
    31 
    32 lemma dual_semilattice:
    33   "lower_semilattice (op \<ge>) (op >) sup"
    34 by (rule lower_semilattice.intro, rule dual_order)
    35   (unfold_locales, simp_all add: sup_least)
    36 
    37 end
    38 
    39 class lattice = lower_semilattice + upper_semilattice
    40 
    41 
    42 subsubsection {* Intro and elim rules*}
    43 
    44 context lower_semilattice
    45 begin
    46 
    47 lemma le_infI1:
    48   "a \<sqsubseteq> x \<Longrightarrow> a \<sqinter> b \<sqsubseteq> x"
    49   by (rule order_trans) auto
    50 
    51 lemma le_infI2:
    52   "b \<sqsubseteq> x \<Longrightarrow> a \<sqinter> b \<sqsubseteq> x"
    53   by (rule order_trans) auto
    54 
    55 lemma le_infI: "x \<sqsubseteq> a \<Longrightarrow> x \<sqsubseteq> b \<Longrightarrow> x \<sqsubseteq> a \<sqinter> b"
    56   by (blast intro: inf_greatest)
    57 
    58 lemma le_infE: "x \<sqsubseteq> a \<sqinter> b \<Longrightarrow> (x \<sqsubseteq> a \<Longrightarrow> x \<sqsubseteq> b \<Longrightarrow> P) \<Longrightarrow> P"
    59   by (blast intro: order_trans le_infI1 le_infI2)
    60 
    61 lemma le_inf_iff [simp]:
    62   "x \<sqsubseteq> y \<sqinter> z \<longleftrightarrow> x \<sqsubseteq> y \<and> x \<sqsubseteq> z"
    63   by (blast intro: le_infI elim: le_infE)
    64 
    65 lemma le_iff_inf:
    66   "x \<sqsubseteq> y \<longleftrightarrow> x \<sqinter> y = x"
    67   by (auto intro: le_infI1 antisym dest: eq_iff [THEN iffD1])
    68 
    69 lemma mono_inf:
    70   fixes f :: "'a \<Rightarrow> 'b\<Colon>lower_semilattice"
    71   shows "mono f \<Longrightarrow> f (A \<sqinter> B) \<le> f A \<sqinter> f B"
    72   by (auto simp add: mono_def intro: Lattices.inf_greatest)
    73 
    74 end
    75 
    76 context upper_semilattice
    77 begin
    78 
    79 lemma le_supI1:
    80   "x \<sqsubseteq> a \<Longrightarrow> x \<sqsubseteq> a \<squnion> b"
    81   by (rule order_trans) auto
    82 
    83 lemma le_supI2:
    84   "x \<sqsubseteq> b \<Longrightarrow> x \<sqsubseteq> a \<squnion> b"
    85   by (rule order_trans) auto 
    86 
    87 lemma le_supI:
    88   "a \<sqsubseteq> x \<Longrightarrow> b \<sqsubseteq> x \<Longrightarrow> a \<squnion> b \<sqsubseteq> x"
    89   by (blast intro: sup_least)
    90 
    91 lemma le_supE:
    92   "a \<squnion> b \<sqsubseteq> x \<Longrightarrow> (a \<sqsubseteq> x \<Longrightarrow> b \<sqsubseteq> x \<Longrightarrow> P) \<Longrightarrow> P"
    93   by (blast intro: le_supI1 le_supI2 order_trans)
    94 
    95 lemma le_sup_iff [simp]:
    96   "x \<squnion> y \<sqsubseteq> z \<longleftrightarrow> x \<sqsubseteq> z \<and> y \<sqsubseteq> z"
    97   by (blast intro: le_supI elim: le_supE)
    98 
    99 lemma le_iff_sup:
   100   "x \<sqsubseteq> y \<longleftrightarrow> x \<squnion> y = y"
   101   by (auto intro: le_supI2 antisym dest: eq_iff [THEN iffD1])
   102 
   103 lemma mono_sup:
   104   fixes f :: "'a \<Rightarrow> 'b\<Colon>upper_semilattice"
   105   shows "mono f \<Longrightarrow> f A \<squnion> f B \<le> f (A \<squnion> B)"
   106   by (auto simp add: mono_def intro: Lattices.sup_least)
   107 
   108 end
   109 
   110 
   111 subsubsection {* Equational laws *}
   112 
   113 context lower_semilattice
   114 begin
   115 
   116 lemma inf_commute: "(x \<sqinter> y) = (y \<sqinter> x)"
   117   by (rule antisym) auto
   118 
   119 lemma inf_assoc: "(x \<sqinter> y) \<sqinter> z = x \<sqinter> (y \<sqinter> z)"
   120   by (rule antisym) (auto intro: le_infI1 le_infI2)
   121 
   122 lemma inf_idem[simp]: "x \<sqinter> x = x"
   123   by (rule antisym) auto
   124 
   125 lemma inf_left_idem[simp]: "x \<sqinter> (x \<sqinter> y) = x \<sqinter> y"
   126   by (rule antisym) (auto intro: le_infI2)
   127 
   128 lemma inf_absorb1: "x \<sqsubseteq> y \<Longrightarrow> x \<sqinter> y = x"
   129   by (rule antisym) auto
   130 
   131 lemma inf_absorb2: "y \<sqsubseteq> x \<Longrightarrow> x \<sqinter> y = y"
   132   by (rule antisym) auto
   133 
   134 lemma inf_left_commute: "x \<sqinter> (y \<sqinter> z) = y \<sqinter> (x \<sqinter> z)"
   135   by (rule mk_left_commute [of inf]) (fact inf_assoc inf_commute)+
   136   
   137 lemmas inf_aci = inf_commute inf_assoc inf_left_commute inf_left_idem
   138 
   139 end
   140 
   141 context upper_semilattice
   142 begin
   143 
   144 lemma sup_commute: "(x \<squnion> y) = (y \<squnion> x)"
   145   by (rule antisym) auto
   146 
   147 lemma sup_assoc: "(x \<squnion> y) \<squnion> z = x \<squnion> (y \<squnion> z)"
   148   by (rule antisym) (auto intro: le_supI1 le_supI2)
   149 
   150 lemma sup_idem[simp]: "x \<squnion> x = x"
   151   by (rule antisym) auto
   152 
   153 lemma sup_left_idem[simp]: "x \<squnion> (x \<squnion> y) = x \<squnion> y"
   154   by (rule antisym) (auto intro: le_supI2)
   155 
   156 lemma sup_absorb1: "y \<sqsubseteq> x \<Longrightarrow> x \<squnion> y = x"
   157   by (rule antisym) auto
   158 
   159 lemma sup_absorb2: "x \<sqsubseteq> y \<Longrightarrow> x \<squnion> y = y"
   160   by (rule antisym) auto
   161 
   162 lemma sup_left_commute: "x \<squnion> (y \<squnion> z) = y \<squnion> (x \<squnion> z)"
   163   by (rule mk_left_commute [of sup]) (fact sup_assoc sup_commute)+
   164 
   165 lemmas sup_aci = sup_commute sup_assoc sup_left_commute sup_left_idem
   166 
   167 end
   168 
   169 context lattice
   170 begin
   171 
   172 lemma dual_lattice:
   173   "lattice (op \<ge>) (op >) sup inf"
   174   by (rule lattice.intro, rule dual_semilattice, rule upper_semilattice.intro, rule dual_order)
   175     (unfold_locales, auto)
   176 
   177 lemma inf_sup_absorb: "x \<sqinter> (x \<squnion> y) = x"
   178   by (blast intro: antisym inf_le1 inf_greatest sup_ge1)
   179 
   180 lemma sup_inf_absorb: "x \<squnion> (x \<sqinter> y) = x"
   181   by (blast intro: antisym sup_ge1 sup_least inf_le1)
   182 
   183 lemmas inf_sup_aci = inf_aci sup_aci
   184 
   185 lemmas inf_sup_ord = inf_le1 inf_le2 sup_ge1 sup_ge2
   186 
   187 text{* Towards distributivity *}
   188 
   189 lemma distrib_sup_le: "x \<squnion> (y \<sqinter> z) \<sqsubseteq> (x \<squnion> y) \<sqinter> (x \<squnion> z)"
   190   by (auto intro: le_infI1 le_infI2 le_supI1 le_supI2)
   191 
   192 lemma distrib_inf_le: "(x \<sqinter> y) \<squnion> (x \<sqinter> z) \<sqsubseteq> x \<sqinter> (y \<squnion> z)"
   193   by (auto intro: le_infI1 le_infI2 le_supI1 le_supI2)
   194 
   195 text{* If you have one of them, you have them all. *}
   196 
   197 lemma distrib_imp1:
   198 assumes D: "!!x y z. x \<sqinter> (y \<squnion> z) = (x \<sqinter> y) \<squnion> (x \<sqinter> z)"
   199 shows "x \<squnion> (y \<sqinter> z) = (x \<squnion> y) \<sqinter> (x \<squnion> z)"
   200 proof-
   201   have "x \<squnion> (y \<sqinter> z) = (x \<squnion> (x \<sqinter> z)) \<squnion> (y \<sqinter> z)" by(simp add:sup_inf_absorb)
   202   also have "\<dots> = x \<squnion> (z \<sqinter> (x \<squnion> y))" by(simp add:D inf_commute sup_assoc)
   203   also have "\<dots> = ((x \<squnion> y) \<sqinter> x) \<squnion> ((x \<squnion> y) \<sqinter> z)"
   204     by(simp add:inf_sup_absorb inf_commute)
   205   also have "\<dots> = (x \<squnion> y) \<sqinter> (x \<squnion> z)" by(simp add:D)
   206   finally show ?thesis .
   207 qed
   208 
   209 lemma distrib_imp2:
   210 assumes D: "!!x y z. x \<squnion> (y \<sqinter> z) = (x \<squnion> y) \<sqinter> (x \<squnion> z)"
   211 shows "x \<sqinter> (y \<squnion> z) = (x \<sqinter> y) \<squnion> (x \<sqinter> z)"
   212 proof-
   213   have "x \<sqinter> (y \<squnion> z) = (x \<sqinter> (x \<squnion> z)) \<sqinter> (y \<squnion> z)" by(simp add:inf_sup_absorb)
   214   also have "\<dots> = x \<sqinter> (z \<squnion> (x \<sqinter> y))" by(simp add:D sup_commute inf_assoc)
   215   also have "\<dots> = ((x \<sqinter> y) \<squnion> x) \<sqinter> ((x \<sqinter> y) \<squnion> z)"
   216     by(simp add:sup_inf_absorb sup_commute)
   217   also have "\<dots> = (x \<sqinter> y) \<squnion> (x \<sqinter> z)" by(simp add:D)
   218   finally show ?thesis .
   219 qed
   220 
   221 end
   222 
   223 
   224 subsection {* Distributive lattices *}
   225 
   226 class distrib_lattice = lattice +
   227   assumes sup_inf_distrib1: "x \<squnion> (y \<sqinter> z) = (x \<squnion> y) \<sqinter> (x \<squnion> z)"
   228 
   229 context distrib_lattice
   230 begin
   231 
   232 lemma sup_inf_distrib2:
   233  "(y \<sqinter> z) \<squnion> x = (y \<squnion> x) \<sqinter> (z \<squnion> x)"
   234 by(simp add: inf_sup_aci sup_inf_distrib1)
   235 
   236 lemma inf_sup_distrib1:
   237  "x \<sqinter> (y \<squnion> z) = (x \<sqinter> y) \<squnion> (x \<sqinter> z)"
   238 by(rule distrib_imp2[OF sup_inf_distrib1])
   239 
   240 lemma inf_sup_distrib2:
   241  "(y \<squnion> z) \<sqinter> x = (y \<sqinter> x) \<squnion> (z \<sqinter> x)"
   242 by(simp add: inf_sup_aci inf_sup_distrib1)
   243 
   244 lemma dual_distrib_lattice:
   245   "distrib_lattice (op \<ge>) (op >) sup inf"
   246   by (rule distrib_lattice.intro, rule dual_lattice)
   247     (unfold_locales, fact inf_sup_distrib1)
   248 
   249 lemmas distrib =
   250   sup_inf_distrib1 sup_inf_distrib2 inf_sup_distrib1 inf_sup_distrib2
   251 
   252 end
   253 
   254 
   255 subsection {* Boolean algebras *}
   256 
   257 class boolean_algebra = distrib_lattice + top + bot + minus + uminus +
   258   assumes inf_compl_bot: "x \<sqinter> - x = bot"
   259     and sup_compl_top: "x \<squnion> - x = top"
   260   assumes diff_eq: "x - y = x \<sqinter> - y"
   261 begin
   262 
   263 lemma dual_boolean_algebra:
   264   "boolean_algebra (\<lambda>x y. x \<squnion> - y) uminus (op \<ge>) (op >) (op \<squnion>) (op \<sqinter>) top bot"
   265   by (rule boolean_algebra.intro, rule dual_distrib_lattice)
   266     (unfold_locales,
   267       auto simp add: inf_compl_bot sup_compl_top diff_eq less_le_not_le)
   268 
   269 lemma compl_inf_bot:
   270   "- x \<sqinter> x = bot"
   271   by (simp add: inf_commute inf_compl_bot)
   272 
   273 lemma compl_sup_top:
   274   "- x \<squnion> x = top"
   275   by (simp add: sup_commute sup_compl_top)
   276 
   277 lemma inf_bot_left [simp]:
   278   "bot \<sqinter> x = bot"
   279   by (rule inf_absorb1) simp
   280 
   281 lemma inf_bot_right [simp]:
   282   "x \<sqinter> bot = bot"
   283   by (rule inf_absorb2) simp
   284 
   285 lemma sup_top_left [simp]:
   286   "top \<squnion> x = top"
   287   by (rule sup_absorb1) simp
   288 
   289 lemma sup_top_right [simp]:
   290   "x \<squnion> top = top"
   291   by (rule sup_absorb2) simp
   292 
   293 lemma inf_top_left [simp]:
   294   "top \<sqinter> x = x"
   295   by (rule inf_absorb2) simp
   296 
   297 lemma inf_top_right [simp]:
   298   "x \<sqinter> top = x"
   299   by (rule inf_absorb1) simp
   300 
   301 lemma sup_bot_left [simp]:
   302   "bot \<squnion> x = x"
   303   by (rule sup_absorb2) simp
   304 
   305 lemma sup_bot_right [simp]:
   306   "x \<squnion> bot = x"
   307   by (rule sup_absorb1) simp
   308 
   309 lemma compl_unique:
   310   assumes "x \<sqinter> y = bot"
   311     and "x \<squnion> y = top"
   312   shows "- x = y"
   313 proof -
   314   have "(x \<sqinter> - x) \<squnion> (- x \<sqinter> y) = (x \<sqinter> y) \<squnion> (- x \<sqinter> y)"
   315     using inf_compl_bot assms(1) by simp
   316   then have "(- x \<sqinter> x) \<squnion> (- x \<sqinter> y) = (y \<sqinter> x) \<squnion> (y \<sqinter> - x)"
   317     by (simp add: inf_commute)
   318   then have "- x \<sqinter> (x \<squnion> y) = y \<sqinter> (x \<squnion> - x)"
   319     by (simp add: inf_sup_distrib1)
   320   then have "- x \<sqinter> top = y \<sqinter> top"
   321     using sup_compl_top assms(2) by simp
   322   then show "- x = y" by (simp add: inf_top_right)
   323 qed
   324 
   325 lemma double_compl [simp]:
   326   "- (- x) = x"
   327   using compl_inf_bot compl_sup_top by (rule compl_unique)
   328 
   329 lemma compl_eq_compl_iff [simp]:
   330   "- x = - y \<longleftrightarrow> x = y"
   331 proof
   332   assume "- x = - y"
   333   then have "- x \<sqinter> y = bot"
   334     and "- x \<squnion> y = top"
   335     by (simp_all add: compl_inf_bot compl_sup_top)
   336   then have "- (- x) = y" by (rule compl_unique)
   337   then show "x = y" by simp
   338 next
   339   assume "x = y"
   340   then show "- x = - y" by simp
   341 qed
   342 
   343 lemma compl_bot_eq [simp]:
   344   "- bot = top"
   345 proof -
   346   from sup_compl_top have "bot \<squnion> - bot = top" .
   347   then show ?thesis by simp
   348 qed
   349 
   350 lemma compl_top_eq [simp]:
   351   "- top = bot"
   352 proof -
   353   from inf_compl_bot have "top \<sqinter> - top = bot" .
   354   then show ?thesis by simp
   355 qed
   356 
   357 lemma compl_inf [simp]:
   358   "- (x \<sqinter> y) = - x \<squnion> - y"
   359 proof (rule compl_unique)
   360   have "(x \<sqinter> y) \<sqinter> (- x \<squnion> - y) = ((x \<sqinter> y) \<sqinter> - x) \<squnion> ((x \<sqinter> y) \<sqinter> - y)"
   361     by (rule inf_sup_distrib1)
   362   also have "... = (y \<sqinter> (x \<sqinter> - x)) \<squnion> (x \<sqinter> (y \<sqinter> - y))"
   363     by (simp only: inf_commute inf_assoc inf_left_commute)
   364   finally show "(x \<sqinter> y) \<sqinter> (- x \<squnion> - y) = bot"
   365     by (simp add: inf_compl_bot)
   366 next
   367   have "(x \<sqinter> y) \<squnion> (- x \<squnion> - y) = (x \<squnion> (- x \<squnion> - y)) \<sqinter> (y \<squnion> (- x \<squnion> - y))"
   368     by (rule sup_inf_distrib2)
   369   also have "... = (- y \<squnion> (x \<squnion> - x)) \<sqinter> (- x \<squnion> (y \<squnion> - y))"
   370     by (simp only: sup_commute sup_assoc sup_left_commute)
   371   finally show "(x \<sqinter> y) \<squnion> (- x \<squnion> - y) = top"
   372     by (simp add: sup_compl_top)
   373 qed
   374 
   375 lemma compl_sup [simp]:
   376   "- (x \<squnion> y) = - x \<sqinter> - y"
   377 proof -
   378   interpret boolean_algebra "\<lambda>x y. x \<squnion> - y" uminus "op \<ge>" "op >" "op \<squnion>" "op \<sqinter>" top bot
   379     by (rule dual_boolean_algebra)
   380   then show ?thesis by simp
   381 qed
   382 
   383 end
   384 
   385 
   386 subsection {* Uniqueness of inf and sup *}
   387 
   388 lemma (in lower_semilattice) inf_unique:
   389   fixes f (infixl "\<triangle>" 70)
   390   assumes le1: "\<And>x y. x \<triangle> y \<le> x" and le2: "\<And>x y. x \<triangle> y \<le> y"
   391   and greatest: "\<And>x y z. x \<le> y \<Longrightarrow> x \<le> z \<Longrightarrow> x \<le> y \<triangle> z"
   392   shows "x \<sqinter> y = x \<triangle> y"
   393 proof (rule antisym)
   394   show "x \<triangle> y \<le> x \<sqinter> y" by (rule le_infI) (rule le1, rule le2)
   395 next
   396   have leI: "\<And>x y z. x \<le> y \<Longrightarrow> x \<le> z \<Longrightarrow> x \<le> y \<triangle> z" by (blast intro: greatest)
   397   show "x \<sqinter> y \<le> x \<triangle> y" by (rule leI) simp_all
   398 qed
   399 
   400 lemma (in upper_semilattice) sup_unique:
   401   fixes f (infixl "\<nabla>" 70)
   402   assumes ge1 [simp]: "\<And>x y. x \<le> x \<nabla> y" and ge2: "\<And>x y. y \<le> x \<nabla> y"
   403   and least: "\<And>x y z. y \<le> x \<Longrightarrow> z \<le> x \<Longrightarrow> y \<nabla> z \<le> x"
   404   shows "x \<squnion> y = x \<nabla> y"
   405 proof (rule antisym)
   406   show "x \<squnion> y \<le> x \<nabla> y" by (rule le_supI) (rule ge1, rule ge2)
   407 next
   408   have leI: "\<And>x y z. x \<le> z \<Longrightarrow> y \<le> z \<Longrightarrow> x \<nabla> y \<le> z" by (blast intro: least)
   409   show "x \<nabla> y \<le> x \<squnion> y" by (rule leI) simp_all
   410 qed
   411   
   412 
   413 subsection {* @{const min}/@{const max} on linear orders as
   414   special case of @{const inf}/@{const sup} *}
   415 
   416 sublocale linorder < min_max!: distrib_lattice less_eq less "Orderings.ord.min less_eq" "Orderings.ord.max less_eq"
   417 proof
   418   fix x y z
   419   show "Orderings.ord.max less_eq x (Orderings.ord.min less_eq y z) =
   420     Orderings.ord.min less_eq (Orderings.ord.max less_eq x y) (Orderings.ord.max less_eq x z)"
   421   unfolding min_def max_def by auto
   422 qed (auto simp add: min_def max_def not_le less_imp_le)
   423 
   424 lemma inf_min: "inf = (min \<Colon> 'a\<Colon>{lower_semilattice, linorder} \<Rightarrow> 'a \<Rightarrow> 'a)"
   425   by (rule ext)+ (auto intro: antisym)
   426 
   427 lemma sup_max: "sup = (max \<Colon> 'a\<Colon>{upper_semilattice, linorder} \<Rightarrow> 'a \<Rightarrow> 'a)"
   428   by (rule ext)+ (auto intro: antisym)
   429 
   430 lemmas le_maxI1 = min_max.sup_ge1
   431 lemmas le_maxI2 = min_max.sup_ge2
   432  
   433 lemmas max_ac = min_max.sup_assoc min_max.sup_commute
   434   mk_left_commute [of max, OF min_max.sup_assoc min_max.sup_commute]
   435 
   436 lemmas min_ac = min_max.inf_assoc min_max.inf_commute
   437   mk_left_commute [of min, OF min_max.inf_assoc min_max.inf_commute]
   438 
   439 
   440 subsection {* Bool as lattice *}
   441 
   442 instantiation bool :: boolean_algebra
   443 begin
   444 
   445 definition
   446   bool_Compl_def: "uminus = Not"
   447 
   448 definition
   449   bool_diff_def: "A - B \<longleftrightarrow> A \<and> \<not> B"
   450 
   451 definition
   452   inf_bool_eq: "P \<sqinter> Q \<longleftrightarrow> P \<and> Q"
   453 
   454 definition
   455   sup_bool_eq: "P \<squnion> Q \<longleftrightarrow> P \<or> Q"
   456 
   457 instance proof
   458 qed (simp_all add: inf_bool_eq sup_bool_eq le_bool_def
   459   bot_bool_eq top_bool_eq bool_Compl_def bool_diff_def, auto)
   460 
   461 end
   462 
   463 
   464 subsection {* Fun as lattice *}
   465 
   466 instantiation "fun" :: (type, lattice) lattice
   467 begin
   468 
   469 definition
   470   inf_fun_eq [code del]: "f \<sqinter> g = (\<lambda>x. f x \<sqinter> g x)"
   471 
   472 definition
   473   sup_fun_eq [code del]: "f \<squnion> g = (\<lambda>x. f x \<squnion> g x)"
   474 
   475 instance
   476 apply intro_classes
   477 unfolding inf_fun_eq sup_fun_eq
   478 apply (auto intro: le_funI)
   479 apply (rule le_funI)
   480 apply (auto dest: le_funD)
   481 apply (rule le_funI)
   482 apply (auto dest: le_funD)
   483 done
   484 
   485 end
   486 
   487 instance "fun" :: (type, distrib_lattice) distrib_lattice
   488 proof
   489 qed (auto simp add: inf_fun_eq sup_fun_eq sup_inf_distrib1)
   490 
   491 instantiation "fun" :: (type, uminus) uminus
   492 begin
   493 
   494 definition
   495   fun_Compl_def: "- A = (\<lambda>x. - A x)"
   496 
   497 instance ..
   498 
   499 end
   500 
   501 instantiation "fun" :: (type, minus) minus
   502 begin
   503 
   504 definition
   505   fun_diff_def: "A - B = (\<lambda>x. A x - B x)"
   506 
   507 instance ..
   508 
   509 end
   510 
   511 instance "fun" :: (type, boolean_algebra) boolean_algebra
   512 proof
   513 qed (simp_all add: inf_fun_eq sup_fun_eq bot_fun_eq top_fun_eq fun_Compl_def fun_diff_def
   514   inf_compl_bot sup_compl_top diff_eq)
   515 
   516 
   517 text {* redundant bindings *}
   518 
   519 
   520 no_notation
   521   less_eq  (infix "\<sqsubseteq>" 50) and
   522   less (infix "\<sqsubset>" 50) and
   523   inf  (infixl "\<sqinter>" 70) and
   524   sup  (infixl "\<squnion>" 65)
   525 
   526 end