src/HOL/Map.thy
author paulson
Tue Jun 28 15:27:45 2005 +0200 (2005-06-28)
changeset 16587 b34c8aa657a5
parent 15695 f072119afa4e
child 17391 c6338ed6caf8
permissions -rw-r--r--
Constant "If" is now local
     1 (*  Title:      HOL/Map.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, based on a theory by David von Oheimb
     4     Copyright   1997-2003 TU Muenchen
     5 
     6 The datatype of `maps' (written ~=>); strongly resembles maps in VDM.
     7 *)
     8 
     9 header {* Maps *}
    10 
    11 theory Map
    12 imports List
    13 begin
    14 
    15 types ('a,'b) "~=>" = "'a => 'b option" (infixr 0)
    16 translations (type) "a ~=> b " <= (type) "a => b option"
    17 
    18 consts
    19 chg_map	:: "('b => 'b) => 'a => ('a ~=> 'b) => ('a ~=> 'b)"
    20 map_add :: "('a ~=> 'b) => ('a ~=> 'b) => ('a ~=> 'b)" (infixl "++" 100)
    21 restrict_map :: "('a ~=> 'b) => 'a set => ('a ~=> 'b)" (infixl "|`"  110)
    22 dom	:: "('a ~=> 'b) => 'a set"
    23 ran	:: "('a ~=> 'b) => 'b set"
    24 map_of	:: "('a * 'b)list => 'a ~=> 'b"
    25 map_upds:: "('a ~=> 'b) => 'a list => 'b list => 
    26 	    ('a ~=> 'b)"
    27 map_upd_s::"('a ~=> 'b) => 'a set => 'b => 
    28 	    ('a ~=> 'b)"			 ("_/'(_{|->}_/')" [900,0,0]900)
    29 map_subst::"('a ~=> 'b) => 'b => 'b => 
    30 	    ('a ~=> 'b)"			 ("_/'(_~>_/')"    [900,0,0]900)
    31 map_le  :: "('a ~=> 'b) => ('a ~=> 'b) => bool" (infix "\<subseteq>\<^sub>m" 50)
    32 
    33 syntax
    34   fun_map_comp :: "('b => 'c)  => ('a ~=> 'b) => ('a ~=> 'c)" (infixl "o'_m" 55)
    35 translations
    36   "f o_m m" == "option_map f o m"
    37 
    38 nonterminals
    39   maplets maplet
    40 
    41 syntax
    42   empty	    ::  "'a ~=> 'b"
    43   "_maplet"  :: "['a, 'a] => maplet"             ("_ /|->/ _")
    44   "_maplets" :: "['a, 'a] => maplet"             ("_ /[|->]/ _")
    45   ""         :: "maplet => maplets"             ("_")
    46   "_Maplets" :: "[maplet, maplets] => maplets" ("_,/ _")
    47   "_MapUpd"  :: "['a ~=> 'b, maplets] => 'a ~=> 'b" ("_/'(_')" [900,0]900)
    48   "_Map"     :: "maplets => 'a ~=> 'b"            ("(1[_])")
    49 
    50 syntax (xsymbols)
    51   "~=>"     :: "[type, type] => type"    (infixr "\<rightharpoonup>" 0)
    52 
    53   fun_map_comp :: "('b => 'c)  => ('a ~=> 'b) => ('a ~=> 'c)" (infixl "\<circ>\<^sub>m" 55)
    54 
    55   "_maplet"  :: "['a, 'a] => maplet"             ("_ /\<mapsto>/ _")
    56   "_maplets" :: "['a, 'a] => maplet"             ("_ /[\<mapsto>]/ _")
    57 
    58   map_upd_s  :: "('a ~=> 'b) => 'a set => 'b => ('a ~=> 'b)"
    59 				    		 ("_/'(_/{\<mapsto>}/_')" [900,0,0]900)
    60   map_subst :: "('a ~=> 'b) => 'b => 'b => 
    61 	        ('a ~=> 'b)"			 ("_/'(_\<leadsto>_/')"    [900,0,0]900)
    62  "@chg_map" :: "('a ~=> 'b) => 'a => ('b => 'b) => ('a ~=> 'b)"
    63 					  ("_/'(_/\<mapsto>\<lambda>_. _')"  [900,0,0,0] 900)
    64 
    65 syntax (latex output)
    66   restrict_map :: "('a ~=> 'b) => 'a set => ('a ~=> 'b)" ("_\<restriction>\<^bsub>_\<^esub>" [111,110] 110)
    67   --"requires amssymb!"
    68 
    69 translations
    70   "empty"    => "_K None"
    71   "empty"    <= "%x. None"
    72 
    73   "m(x\<mapsto>\<lambda>y. f)" == "chg_map (\<lambda>y. f) x m"
    74 
    75   "_MapUpd m (_Maplets xy ms)"  == "_MapUpd (_MapUpd m xy) ms"
    76   "_MapUpd m (_maplet  x y)"    == "m(x:=Some y)"
    77   "_MapUpd m (_maplets x y)"    == "map_upds m x y"
    78   "_Map ms"                     == "_MapUpd empty ms"
    79   "_Map (_Maplets ms1 ms2)"     <= "_MapUpd (_Map ms1) ms2"
    80   "_Maplets ms1 (_Maplets ms2 ms3)" <= "_Maplets (_Maplets ms1 ms2) ms3"
    81 
    82 defs
    83 chg_map_def:  "chg_map f a m == case m a of None => m | Some b => m(a|->f b)"
    84 
    85 map_add_def:   "m1++m2 == %x. case m2 x of None => m1 x | Some y => Some y"
    86 restrict_map_def: "m|`A == %x. if x : A then m x else None"
    87 
    88 map_upds_def: "m(xs [|->] ys) == m ++ map_of (rev(zip xs ys))"
    89 map_upd_s_def: "m(as{|->}b) == %x. if x : as then Some b else m x"
    90 map_subst_def: "m(a~>b)     == %x. if m x = Some a then Some b else m x"
    91 
    92 dom_def: "dom(m) == {a. m a ~= None}"
    93 ran_def: "ran(m) == {b. EX a. m a = Some b}"
    94 
    95 map_le_def: "m\<^isub>1 \<subseteq>\<^sub>m m\<^isub>2  ==  ALL a : dom m\<^isub>1. m\<^isub>1 a = m\<^isub>2 a"
    96 
    97 primrec
    98   "map_of [] = empty"
    99   "map_of (p#ps) = (map_of ps)(fst p |-> snd p)"
   100 
   101 
   102 subsection {* @{term empty} *}
   103 
   104 lemma empty_upd_none[simp]: "empty(x := None) = empty"
   105 apply (rule ext)
   106 apply (simp (no_asm))
   107 done
   108 
   109 
   110 (* FIXME: what is this sum_case nonsense?? *)
   111 lemma sum_case_empty_empty[simp]: "sum_case empty empty = empty"
   112 apply (rule ext)
   113 apply (simp (no_asm) split add: sum.split)
   114 done
   115 
   116 subsection {* @{term map_upd} *}
   117 
   118 lemma map_upd_triv: "t k = Some x ==> t(k|->x) = t"
   119 apply (rule ext)
   120 apply (simp (no_asm_simp))
   121 done
   122 
   123 lemma map_upd_nonempty[simp]: "t(k|->x) ~= empty"
   124 apply safe
   125 apply (drule_tac x = k in fun_cong)
   126 apply (simp (no_asm_use))
   127 done
   128 
   129 lemma map_upd_eqD1: "m(a\<mapsto>x) = n(a\<mapsto>y) \<Longrightarrow> x = y"
   130 by (drule fun_cong [of _ _ a], auto)
   131 
   132 lemma map_upd_Some_unfold: 
   133   "((m(a|->b)) x = Some y) = (x = a \<and> b = y \<or> x \<noteq> a \<and> m x = Some y)"
   134 by auto
   135 
   136 lemma image_map_upd[simp]: "x \<notin> A \<Longrightarrow> m(x \<mapsto> y) ` A = m ` A"
   137 by fastsimp
   138 
   139 lemma finite_range_updI: "finite (range f) ==> finite (range (f(a|->b)))"
   140 apply (unfold image_def)
   141 apply (simp (no_asm_use) add: full_SetCompr_eq)
   142 apply (rule finite_subset)
   143 prefer 2 apply assumption
   144 apply auto
   145 done
   146 
   147 
   148 (* FIXME: what is this sum_case nonsense?? *)
   149 subsection {* @{term sum_case} and @{term empty}/@{term map_upd} *}
   150 
   151 lemma sum_case_map_upd_empty[simp]:
   152  "sum_case (m(k|->y)) empty =  (sum_case m empty)(Inl k|->y)"
   153 apply (rule ext)
   154 apply (simp (no_asm) split add: sum.split)
   155 done
   156 
   157 lemma sum_case_empty_map_upd[simp]:
   158  "sum_case empty (m(k|->y)) =  (sum_case empty m)(Inr k|->y)"
   159 apply (rule ext)
   160 apply (simp (no_asm) split add: sum.split)
   161 done
   162 
   163 lemma sum_case_map_upd_map_upd[simp]:
   164  "sum_case (m1(k1|->y1)) (m2(k2|->y2)) = (sum_case (m1(k1|->y1)) m2)(Inr k2|->y2)"
   165 apply (rule ext)
   166 apply (simp (no_asm) split add: sum.split)
   167 done
   168 
   169 
   170 subsection {* @{term chg_map} *}
   171 
   172 lemma chg_map_new[simp]: "m a = None   ==> chg_map f a m = m"
   173 by (unfold chg_map_def, auto)
   174 
   175 lemma chg_map_upd[simp]: "m a = Some b ==> chg_map f a m = m(a|->f b)"
   176 by (unfold chg_map_def, auto)
   177 
   178 lemma chg_map_other [simp]: "a \<noteq> b \<Longrightarrow> chg_map f a m b = m b"
   179 by (auto simp: chg_map_def split add: option.split)
   180 
   181 
   182 subsection {* @{term map_of} *}
   183 
   184 lemma map_of_eq_None_iff:
   185  "(map_of xys x = None) = (x \<notin> fst ` (set xys))"
   186 by (induct xys) simp_all
   187 
   188 lemma map_of_is_SomeD:
   189  "map_of xys x = Some y \<Longrightarrow> (x,y) \<in> set xys"
   190 apply(induct xys)
   191  apply simp
   192 apply(clarsimp split:if_splits)
   193 done
   194 
   195 lemma map_of_eq_Some_iff[simp]:
   196  "distinct(map fst xys) \<Longrightarrow> (map_of xys x = Some y) = ((x,y) \<in> set xys)"
   197 apply(induct xys)
   198  apply(simp)
   199 apply(auto simp:map_of_eq_None_iff[symmetric])
   200 done
   201 
   202 lemma Some_eq_map_of_iff[simp]:
   203  "distinct(map fst xys) \<Longrightarrow> (Some y = map_of xys x) = ((x,y) \<in> set xys)"
   204 by(auto simp del:map_of_eq_Some_iff simp add:map_of_eq_Some_iff[symmetric])
   205 
   206 lemma [simp]: "\<lbrakk> distinct(map fst xys); (x,y) \<in> set xys \<rbrakk>
   207   \<Longrightarrow> map_of xys x = Some y"
   208 apply (induct xys)
   209  apply simp
   210 apply force
   211 done
   212 
   213 lemma map_of_zip_is_None[simp]:
   214   "length xs = length ys \<Longrightarrow> (map_of (zip xs ys) x = None) = (x \<notin> set xs)"
   215 by (induct rule:list_induct2, simp_all)
   216 
   217 lemma finite_range_map_of: "finite (range (map_of xys))"
   218 apply (induct xys)
   219 apply  (simp_all (no_asm) add: image_constant)
   220 apply (rule finite_subset)
   221 prefer 2 apply assumption
   222 apply auto
   223 done
   224 
   225 lemma map_of_SomeD [rule_format]: "map_of xs k = Some y --> (k,y):set xs"
   226 by (induct "xs", auto)
   227 
   228 lemma map_of_mapk_SomeI [rule_format]:
   229      "inj f ==> map_of t k = Some x -->  
   230         map_of (map (split (%k. Pair (f k))) t) (f k) = Some x"
   231 apply (induct "t")
   232 apply  (auto simp add: inj_eq)
   233 done
   234 
   235 lemma weak_map_of_SomeI [rule_format]:
   236      "(k, x) : set l --> (\<exists>x. map_of l k = Some x)"
   237 by (induct "l", auto)
   238 
   239 lemma map_of_filter_in: 
   240 "[| map_of xs k = Some z; P k z |] ==> map_of (filter (split P) xs) k = Some z"
   241 apply (rule mp)
   242 prefer 2 apply assumption
   243 apply (erule thin_rl)
   244 apply (induct "xs", auto)
   245 done
   246 
   247 lemma map_of_map: "map_of (map (%(a,b). (a,f b)) xs) x = option_map f (map_of xs x)"
   248 by (induct "xs", auto)
   249 
   250 
   251 subsection {* @{term option_map} related *}
   252 
   253 lemma option_map_o_empty[simp]: "option_map f o empty = empty"
   254 apply (rule ext)
   255 apply (simp (no_asm))
   256 done
   257 
   258 lemma option_map_o_map_upd[simp]:
   259  "option_map f o m(a|->b) = (option_map f o m)(a|->f b)"
   260 apply (rule ext)
   261 apply (simp (no_asm))
   262 done
   263 
   264 
   265 subsection {* @{text "++"} *}
   266 
   267 lemma map_add_empty[simp]: "m ++ empty = m"
   268 apply (unfold map_add_def)
   269 apply (simp (no_asm))
   270 done
   271 
   272 lemma empty_map_add[simp]: "empty ++ m = m"
   273 apply (unfold map_add_def)
   274 apply (rule ext)
   275 apply (simp split add: option.split)
   276 done
   277 
   278 lemma map_add_assoc[simp]: "m1 ++ (m2 ++ m3) = (m1 ++ m2) ++ m3"
   279 apply(rule ext)
   280 apply(simp add: map_add_def split:option.split)
   281 done
   282 
   283 lemma map_add_Some_iff: 
   284  "((m ++ n) k = Some x) = (n k = Some x | n k = None & m k = Some x)"
   285 apply (unfold map_add_def)
   286 apply (simp (no_asm) split add: option.split)
   287 done
   288 
   289 lemmas map_add_SomeD = map_add_Some_iff [THEN iffD1, standard]
   290 declare map_add_SomeD [dest!]
   291 
   292 lemma map_add_find_right[simp]: "!!xx. n k = Some xx ==> (m ++ n) k = Some xx"
   293 by (subst map_add_Some_iff, fast)
   294 
   295 lemma map_add_None [iff]: "((m ++ n) k = None) = (n k = None & m k = None)"
   296 apply (unfold map_add_def)
   297 apply (simp (no_asm) split add: option.split)
   298 done
   299 
   300 lemma map_add_upd[simp]: "f ++ g(x|->y) = (f ++ g)(x|->y)"
   301 apply (unfold map_add_def)
   302 apply (rule ext, auto)
   303 done
   304 
   305 lemma map_add_upds[simp]: "m1 ++ (m2(xs[\<mapsto>]ys)) = (m1++m2)(xs[\<mapsto>]ys)"
   306 by(simp add:map_upds_def)
   307 
   308 lemma map_of_append[simp]: "map_of (xs@ys) = map_of ys ++ map_of xs"
   309 apply (unfold map_add_def)
   310 apply (induct "xs")
   311 apply (simp (no_asm))
   312 apply (rule ext)
   313 apply (simp (no_asm_simp) split add: option.split)
   314 done
   315 
   316 declare fun_upd_apply [simp del]
   317 lemma finite_range_map_of_map_add:
   318  "finite (range f) ==> finite (range (f ++ map_of l))"
   319 apply (induct "l", auto)
   320 apply (erule finite_range_updI)
   321 done
   322 declare fun_upd_apply [simp]
   323 
   324 lemma inj_on_map_add_dom[iff]:
   325  "inj_on (m ++ m') (dom m') = inj_on m' (dom m')"
   326 by(fastsimp simp add:map_add_def dom_def inj_on_def split:option.splits)
   327 
   328 subsection {* @{term restrict_map} *}
   329 
   330 lemma restrict_map_to_empty[simp]: "m|`{} = empty"
   331 by(simp add: restrict_map_def)
   332 
   333 lemma restrict_map_empty[simp]: "empty|`D = empty"
   334 by(simp add: restrict_map_def)
   335 
   336 lemma restrict_in [simp]: "x \<in> A \<Longrightarrow> (m|`A) x = m x"
   337 by (auto simp: restrict_map_def)
   338 
   339 lemma restrict_out [simp]: "x \<notin> A \<Longrightarrow> (m|`A) x = None"
   340 by (auto simp: restrict_map_def)
   341 
   342 lemma ran_restrictD: "y \<in> ran (m|`A) \<Longrightarrow> \<exists>x\<in>A. m x = Some y"
   343 by (auto simp: restrict_map_def ran_def split: split_if_asm)
   344 
   345 lemma dom_restrict [simp]: "dom (m|`A) = dom m \<inter> A"
   346 by (auto simp: restrict_map_def dom_def split: split_if_asm)
   347 
   348 lemma restrict_upd_same [simp]: "m(x\<mapsto>y)|`(-{x}) = m|`(-{x})"
   349 by (rule ext, auto simp: restrict_map_def)
   350 
   351 lemma restrict_restrict [simp]: "m|`A|`B = m|`(A\<inter>B)"
   352 by (rule ext, auto simp: restrict_map_def)
   353 
   354 lemma restrict_fun_upd[simp]:
   355  "m(x := y)|`D = (if x \<in> D then (m|`(D-{x}))(x := y) else m|`D)"
   356 by(simp add: restrict_map_def expand_fun_eq)
   357 
   358 lemma fun_upd_None_restrict[simp]:
   359   "(m|`D)(x := None) = (if x:D then m|`(D - {x}) else m|`D)"
   360 by(simp add: restrict_map_def expand_fun_eq)
   361 
   362 lemma fun_upd_restrict:
   363  "(m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   364 by(simp add: restrict_map_def expand_fun_eq)
   365 
   366 lemma fun_upd_restrict_conv[simp]:
   367  "x \<in> D \<Longrightarrow> (m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   368 by(simp add: restrict_map_def expand_fun_eq)
   369 
   370 
   371 subsection {* @{term map_upds} *}
   372 
   373 lemma map_upds_Nil1[simp]: "m([] [|->] bs) = m"
   374 by(simp add:map_upds_def)
   375 
   376 lemma map_upds_Nil2[simp]: "m(as [|->] []) = m"
   377 by(simp add:map_upds_def)
   378 
   379 lemma map_upds_Cons[simp]: "m(a#as [|->] b#bs) = (m(a|->b))(as[|->]bs)"
   380 by(simp add:map_upds_def)
   381 
   382 lemma map_upds_append1[simp]: "\<And>ys m. size xs < size ys \<Longrightarrow>
   383   m(xs@[x] [\<mapsto>] ys) = m(xs [\<mapsto>] ys)(x \<mapsto> ys!size xs)"
   384 apply(induct xs)
   385  apply(clarsimp simp add:neq_Nil_conv)
   386 apply (case_tac ys, simp, simp)
   387 done
   388 
   389 lemma map_upds_list_update2_drop[simp]:
   390  "\<And>m ys i. \<lbrakk>size xs \<le> i; i < size ys\<rbrakk>
   391      \<Longrightarrow> m(xs[\<mapsto>]ys[i:=y]) = m(xs[\<mapsto>]ys)"
   392 apply (induct xs, simp)
   393 apply (case_tac ys, simp)
   394 apply(simp split:nat.split)
   395 done
   396 
   397 lemma map_upd_upds_conv_if: "!!x y ys f.
   398  (f(x|->y))(xs [|->] ys) =
   399  (if x : set(take (length ys) xs) then f(xs [|->] ys)
   400                                   else (f(xs [|->] ys))(x|->y))"
   401 apply (induct xs, simp)
   402 apply(case_tac ys)
   403  apply(auto split:split_if simp:fun_upd_twist)
   404 done
   405 
   406 lemma map_upds_twist [simp]:
   407  "a ~: set as ==> m(a|->b)(as[|->]bs) = m(as[|->]bs)(a|->b)"
   408 apply(insert set_take_subset)
   409 apply (fastsimp simp add: map_upd_upds_conv_if)
   410 done
   411 
   412 lemma map_upds_apply_nontin[simp]:
   413  "!!ys. x ~: set xs ==> (f(xs[|->]ys)) x = f x"
   414 apply (induct xs, simp)
   415 apply(case_tac ys)
   416  apply(auto simp: map_upd_upds_conv_if)
   417 done
   418 
   419 lemma fun_upds_append_drop[simp]:
   420   "!!m ys. size xs = size ys \<Longrightarrow> m(xs@zs[\<mapsto>]ys) = m(xs[\<mapsto>]ys)"
   421 apply(induct xs)
   422  apply (simp)
   423 apply(case_tac ys)
   424 apply simp_all
   425 done
   426 
   427 lemma fun_upds_append2_drop[simp]:
   428   "!!m ys. size xs = size ys \<Longrightarrow> m(xs[\<mapsto>]ys@zs) = m(xs[\<mapsto>]ys)"
   429 apply(induct xs)
   430  apply (simp)
   431 apply(case_tac ys)
   432 apply simp_all
   433 done
   434 
   435 
   436 lemma restrict_map_upds[simp]: "!!m ys.
   437  \<lbrakk> length xs = length ys; set xs \<subseteq> D \<rbrakk>
   438  \<Longrightarrow> m(xs [\<mapsto>] ys)|`D = (m|`(D - set xs))(xs [\<mapsto>] ys)"
   439 apply (induct xs, simp)
   440 apply (case_tac ys, simp)
   441 apply(simp add:Diff_insert[symmetric] insert_absorb)
   442 apply(simp add: map_upd_upds_conv_if)
   443 done
   444 
   445 
   446 subsection {* @{term map_upd_s} *}
   447 
   448 lemma map_upd_s_apply [simp]: 
   449   "(m(as{|->}b)) x = (if x : as then Some b else m x)"
   450 by (simp add: map_upd_s_def)
   451 
   452 lemma map_subst_apply [simp]: 
   453   "(m(a~>b)) x = (if m x = Some a then Some b else m x)" 
   454 by (simp add: map_subst_def)
   455 
   456 subsection {* @{term dom} *}
   457 
   458 lemma domI: "m a = Some b ==> a : dom m"
   459 by (unfold dom_def, auto)
   460 (* declare domI [intro]? *)
   461 
   462 lemma domD: "a : dom m ==> \<exists>b. m a = Some b"
   463 by (unfold dom_def, auto)
   464 
   465 lemma domIff[iff]: "(a : dom m) = (m a ~= None)"
   466 by (unfold dom_def, auto)
   467 declare domIff [simp del]
   468 
   469 lemma dom_empty[simp]: "dom empty = {}"
   470 apply (unfold dom_def)
   471 apply (simp (no_asm))
   472 done
   473 
   474 lemma dom_fun_upd[simp]:
   475  "dom(f(x := y)) = (if y=None then dom f - {x} else insert x (dom f))"
   476 by (simp add:dom_def) blast
   477 
   478 lemma dom_map_of: "dom(map_of xys) = {x. \<exists>y. (x,y) : set xys}"
   479 apply(induct xys)
   480 apply(auto simp del:fun_upd_apply)
   481 done
   482 
   483 lemma dom_map_of_conv_image_fst:
   484   "dom(map_of xys) = fst ` (set xys)"
   485 by(force simp: dom_map_of)
   486 
   487 lemma dom_map_of_zip[simp]: "[| length xs = length ys; distinct xs |] ==>
   488   dom(map_of(zip xs ys)) = set xs"
   489 by(induct rule: list_induct2, simp_all)
   490 
   491 lemma finite_dom_map_of: "finite (dom (map_of l))"
   492 apply (unfold dom_def)
   493 apply (induct "l")
   494 apply (auto simp add: insert_Collect [symmetric])
   495 done
   496 
   497 lemma dom_map_upds[simp]:
   498  "!!m ys. dom(m(xs[|->]ys)) = set(take (length ys) xs) Un dom m"
   499 apply (induct xs, simp)
   500 apply (case_tac ys, auto)
   501 done
   502 
   503 lemma dom_map_add[simp]: "dom(m++n) = dom n Un dom m"
   504 by (unfold dom_def, auto)
   505 
   506 lemma dom_override_on[simp]:
   507  "dom(override_on f g A) =
   508  (dom f  - {a. a : A - dom g}) Un {a. a : A Int dom g}"
   509 by(auto simp add: dom_def override_on_def)
   510 
   511 lemma map_add_comm: "dom m1 \<inter> dom m2 = {} \<Longrightarrow> m1++m2 = m2++m1"
   512 apply(rule ext)
   513 apply(fastsimp simp:map_add_def split:option.split)
   514 done
   515 
   516 subsection {* @{term ran} *}
   517 
   518 lemma ranI: "m a = Some b ==> b : ran m" 
   519 by (auto simp add: ran_def)
   520 (* declare ranI [intro]? *)
   521 
   522 lemma ran_empty[simp]: "ran empty = {}"
   523 apply (unfold ran_def)
   524 apply (simp (no_asm))
   525 done
   526 
   527 lemma ran_map_upd[simp]: "m a = None ==> ran(m(a|->b)) = insert b (ran m)"
   528 apply (unfold ran_def, auto)
   529 apply (subgoal_tac "~ (aa = a) ")
   530 apply auto
   531 done
   532 
   533 subsection {* @{text "map_le"} *}
   534 
   535 lemma map_le_empty [simp]: "empty \<subseteq>\<^sub>m g"
   536 by(simp add:map_le_def)
   537 
   538 lemma [simp]: "f(x := None) \<subseteq>\<^sub>m f"
   539 by(force simp add:map_le_def)
   540 
   541 lemma map_le_upd[simp]: "f \<subseteq>\<^sub>m g ==> f(a := b) \<subseteq>\<^sub>m g(a := b)"
   542 by(fastsimp simp add:map_le_def)
   543 
   544 lemma [simp]: "m1 \<subseteq>\<^sub>m m2 \<Longrightarrow> m1(x := None) \<subseteq>\<^sub>m m2(x \<mapsto> y)"
   545 by(force simp add:map_le_def)
   546 
   547 lemma map_le_upds[simp]:
   548  "!!f g bs. f \<subseteq>\<^sub>m g ==> f(as [|->] bs) \<subseteq>\<^sub>m g(as [|->] bs)"
   549 apply (induct as, simp)
   550 apply (case_tac bs, auto)
   551 done
   552 
   553 lemma map_le_implies_dom_le: "(f \<subseteq>\<^sub>m g) \<Longrightarrow> (dom f \<subseteq> dom g)"
   554   by (fastsimp simp add: map_le_def dom_def)
   555 
   556 lemma map_le_refl [simp]: "f \<subseteq>\<^sub>m f"
   557   by (simp add: map_le_def)
   558 
   559 lemma map_le_trans[trans]: "\<lbrakk> m1 \<subseteq>\<^sub>m m2; m2 \<subseteq>\<^sub>m m3\<rbrakk> \<Longrightarrow> m1 \<subseteq>\<^sub>m m3"
   560 by(force simp add:map_le_def)
   561 
   562 lemma map_le_antisym: "\<lbrakk> f \<subseteq>\<^sub>m g; g \<subseteq>\<^sub>m f \<rbrakk> \<Longrightarrow> f = g"
   563   apply (unfold map_le_def)
   564   apply (rule ext)
   565   apply (case_tac "x \<in> dom f", simp)
   566   apply (case_tac "x \<in> dom g", simp, fastsimp)
   567 done
   568 
   569 lemma map_le_map_add [simp]: "f \<subseteq>\<^sub>m (g ++ f)"
   570   by (fastsimp simp add: map_le_def)
   571 
   572 lemma map_le_iff_map_add_commute: "(f \<subseteq>\<^sub>m f ++ g) = (f++g = g++f)"
   573 by(fastsimp simp add:map_add_def map_le_def expand_fun_eq split:option.splits)
   574 
   575 lemma map_add_le_mapE: "f++g \<subseteq>\<^sub>m h \<Longrightarrow> g \<subseteq>\<^sub>m h"
   576 by (fastsimp simp add: map_le_def map_add_def dom_def)
   577 
   578 lemma map_add_le_mapI: "\<lbrakk> f \<subseteq>\<^sub>m h; g \<subseteq>\<^sub>m h; f \<subseteq>\<^sub>m f++g \<rbrakk> \<Longrightarrow> f++g \<subseteq>\<^sub>m h"
   579 by (clarsimp simp add: map_le_def map_add_def dom_def split:option.splits)
   580 
   581 end