src/ZF/Constructible/Datatype_absolute.thy
author wenzelm
Tue Jul 16 18:46:59 2002 +0200 (2002-07-16)
changeset 13382 b37764a46b16
parent 13363 c26eeb000470
child 13385 31df66ca0780
permissions -rw-r--r--
adapted locales;
     1 header {*Absoluteness Properties for Recursive Datatypes*}
     2 
     3 theory Datatype_absolute = Formula + WF_absolute:
     4 
     5 
     6 subsection{*The lfp of a continuous function can be expressed as a union*}
     7 
     8 constdefs
     9   contin :: "[i=>i]=>o"
    10    "contin(h) == (\<forall>A. A\<noteq>0 --> h(\<Union>A) = (\<Union>X\<in>A. h(X)))"
    11 
    12 lemma bnd_mono_iterates_subset: "[|bnd_mono(D, h); n \<in> nat|] ==> h^n (0) <= D"
    13 apply (induct_tac n) 
    14  apply (simp_all add: bnd_mono_def, blast) 
    15 done
    16 
    17 
    18 lemma contin_iterates_eq: 
    19     "contin(h) \<Longrightarrow> h(\<Union>n\<in>nat. h^n (0)) = (\<Union>n\<in>nat. h^n (0))"
    20 apply (simp add: contin_def) 
    21 apply (rule trans) 
    22 apply (rule equalityI) 
    23  apply (simp_all add: UN_subset_iff) 
    24  apply safe
    25  apply (erule_tac [2] natE) 
    26   apply (rule_tac a="succ(x)" in UN_I) 
    27    apply simp_all 
    28 apply blast 
    29 done
    30 
    31 lemma lfp_subset_Union:
    32      "[|bnd_mono(D, h); contin(h)|] ==> lfp(D,h) <= (\<Union>n\<in>nat. h^n(0))"
    33 apply (rule lfp_lowerbound) 
    34  apply (simp add: contin_iterates_eq) 
    35 apply (simp add: contin_def bnd_mono_iterates_subset UN_subset_iff) 
    36 done
    37 
    38 lemma Union_subset_lfp:
    39      "bnd_mono(D,h) ==> (\<Union>n\<in>nat. h^n(0)) <= lfp(D,h)"
    40 apply (simp add: UN_subset_iff)
    41 apply (rule ballI)  
    42 apply (induct_tac n, simp_all) 
    43 apply (rule subset_trans [of _ "h(lfp(D,h))"])
    44  apply (blast dest: bnd_monoD2 [OF _ _ lfp_subset] )  
    45 apply (erule lfp_lemma2) 
    46 done
    47 
    48 lemma lfp_eq_Union:
    49      "[|bnd_mono(D, h); contin(h)|] ==> lfp(D,h) = (\<Union>n\<in>nat. h^n(0))"
    50 by (blast del: subsetI 
    51           intro: lfp_subset_Union Union_subset_lfp)
    52 
    53 
    54 subsection {*lists without univ*}
    55 
    56 lemmas datatype_univs = A_into_univ Inl_in_univ Inr_in_univ 
    57                         Pair_in_univ zero_in_univ
    58 
    59 lemma list_fun_bnd_mono: "bnd_mono(univ(A), \<lambda>X. {0} + A*X)"
    60 apply (rule bnd_monoI)
    61  apply (intro subset_refl zero_subset_univ A_subset_univ 
    62 	      sum_subset_univ Sigma_subset_univ) 
    63  apply (blast intro!: subset_refl sum_mono Sigma_mono del: subsetI)
    64 done
    65 
    66 lemma list_fun_contin: "contin(\<lambda>X. {0} + A*X)"
    67 by (simp add: contin_def, blast)
    68 
    69 text{*Re-expresses lists using sum and product*}
    70 lemma list_eq_lfp2: "list(A) = lfp(univ(A), \<lambda>X. {0} + A*X)"
    71 apply (simp add: list_def) 
    72 apply (rule equalityI) 
    73  apply (rule lfp_lowerbound) 
    74   prefer 2 apply (rule lfp_subset)
    75  apply (clarify, subst lfp_unfold [OF list_fun_bnd_mono])
    76  apply (simp add: Nil_def Cons_def)
    77  apply blast 
    78 txt{*Opposite inclusion*}
    79 apply (rule lfp_lowerbound) 
    80  prefer 2 apply (rule lfp_subset) 
    81 apply (clarify, subst lfp_unfold [OF list.bnd_mono]) 
    82 apply (simp add: Nil_def Cons_def)
    83 apply (blast intro: datatype_univs
    84              dest: lfp_subset [THEN subsetD])
    85 done
    86 
    87 text{*Re-expresses lists using "iterates", no univ.*}
    88 lemma list_eq_Union:
    89      "list(A) = (\<Union>n\<in>nat. (\<lambda>X. {0} + A*X) ^ n (0))"
    90 by (simp add: list_eq_lfp2 lfp_eq_Union list_fun_bnd_mono list_fun_contin)
    91 
    92 
    93 subsection {*Absoluteness for "Iterates"*}
    94 
    95 constdefs
    96 
    97   iterates_MH :: "[i=>o, [i,i]=>o, i, i, i, i] => o"
    98    "iterates_MH(M,isF,v,n,g,z) ==
    99         is_nat_case(M, v, \<lambda>m u. \<exists>gm[M]. fun_apply(M,g,m,gm) & isF(gm,u),
   100                     n, z)"
   101 
   102   iterates_replacement :: "[i=>o, [i,i]=>o, i] => o"
   103    "iterates_replacement(M,isF,v) ==
   104       \<forall>n[M]. n\<in>nat --> 
   105          wfrec_replacement(M, iterates_MH(M,isF,v), Memrel(succ(n)))"
   106 
   107 lemma (in M_axioms) iterates_MH_abs:
   108   "[| relativize1(M,isF,F); M(n); M(g); M(z) |] 
   109    ==> iterates_MH(M,isF,v,n,g,z) <-> z = nat_case(v, \<lambda>m. F(g`m), n)"
   110 by (simp add: nat_case_abs [of _ "\<lambda>m. F(g ` m)"]
   111               relativize1_def iterates_MH_def)  
   112 
   113 lemma (in M_axioms) iterates_imp_wfrec_replacement:
   114   "[|relativize1(M,isF,F); n \<in> nat; iterates_replacement(M,isF,v)|] 
   115    ==> wfrec_replacement(M, \<lambda>n f z. z = nat_case(v, \<lambda>m. F(f`m), n), 
   116                        Memrel(succ(n)))" 
   117 by (simp add: iterates_replacement_def iterates_MH_abs)
   118 
   119 theorem (in M_trancl) iterates_abs:
   120   "[| iterates_replacement(M,isF,v); relativize1(M,isF,F);
   121       n \<in> nat; M(v); M(z); \<forall>x[M]. M(F(x)) |] 
   122    ==> is_wfrec(M, iterates_MH(M,isF,v), Memrel(succ(n)), n, z) <->
   123        z = iterates(F,n,v)" 
   124 apply (frule iterates_imp_wfrec_replacement, assumption+)
   125 apply (simp add: wf_Memrel trans_Memrel relation_Memrel nat_into_M
   126                  relativize2_def iterates_MH_abs 
   127                  iterates_nat_def recursor_def transrec_def 
   128                  eclose_sing_Ord_eq nat_into_M
   129          trans_wfrec_abs [of _ _ _ _ "\<lambda>n g. nat_case(v, \<lambda>m. F(g`m), n)"])
   130 done
   131 
   132 
   133 lemma (in M_wfrank) iterates_closed [intro,simp]:
   134   "[| iterates_replacement(M,isF,v); relativize1(M,isF,F);
   135       n \<in> nat; M(v); \<forall>x[M]. M(F(x)) |] 
   136    ==> M(iterates(F,n,v))"
   137 apply (frule iterates_imp_wfrec_replacement, assumption+)
   138 apply (simp add: wf_Memrel trans_Memrel relation_Memrel nat_into_M
   139                  relativize2_def iterates_MH_abs 
   140                  iterates_nat_def recursor_def transrec_def 
   141                  eclose_sing_Ord_eq nat_into_M
   142          trans_wfrec_closed [of _ _ _ "\<lambda>n g. nat_case(v, \<lambda>m. F(g`m), n)"])
   143 done
   144 
   145 
   146 constdefs
   147   is_list_functor :: "[i=>o,i,i,i] => o"
   148     "is_list_functor(M,A,X,Z) == 
   149         \<exists>n1[M]. \<exists>AX[M]. 
   150          number1(M,n1) & cartprod(M,A,X,AX) & is_sum(M,n1,AX,Z)"
   151 
   152 lemma (in M_axioms) list_functor_abs [simp]: 
   153      "[| M(A); M(X); M(Z) |] ==> is_list_functor(M,A,X,Z) <-> (Z = {0} + A*X)"
   154 by (simp add: is_list_functor_def singleton_0 nat_into_M)
   155 
   156 
   157 locale (open) M_datatypes = M_wfrank +
   158  assumes list_replacement1: 
   159    "M(A) ==> iterates_replacement(M, is_list_functor(M,A), 0)"
   160   and list_replacement2: 
   161    "M(A) ==> strong_replacement(M, 
   162          \<lambda>n y. n\<in>nat & 
   163                (\<exists>sn[M]. \<exists>msn[M]. successor(M,n,sn) & membership(M,sn,msn) &
   164                is_wfrec(M, iterates_MH(M,is_list_functor(M,A), 0), 
   165                         msn, n, y)))"
   166 
   167 lemma (in M_datatypes) list_replacement2': 
   168   "M(A) ==> strong_replacement(M, \<lambda>n y. n\<in>nat & y = (\<lambda>X. {0} + A * X)^n (0))"
   169 apply (insert list_replacement2 [of A]) 
   170 apply (rule strong_replacement_cong [THEN iffD1])  
   171 apply (rule conj_cong [OF iff_refl iterates_abs [of "is_list_functor(M,A)"]]) 
   172 apply (simp_all add: list_replacement1 relativize1_def) 
   173 done
   174 
   175 lemma (in M_datatypes) list_closed [intro,simp]:
   176      "M(A) ==> M(list(A))"
   177 apply (insert list_replacement1)
   178 by  (simp add: RepFun_closed2 list_eq_Union 
   179                list_replacement2' relativize1_def
   180                iterates_closed [of "is_list_functor(M,A)"])
   181 
   182 
   183 end