src/Pure/Thy/thy_parse.ML
author clasohm
Wed Jan 18 11:36:04 1995 +0100 (1995-01-18)
changeset 865 b38c67991122
parent 777 c007eba368b7
child 889 e87c01fd0351
permissions -rw-r--r--
added optional precedence for body of binder;
removed call to infer_types from read_xrules
     1 (*  Title:      Pure/Thy/thy_parse.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 The parser for theory files.
     6 *)
     7 
     8 infix 5 -- --$$ $$-- ^^;
     9 infix 3 >>;
    10 infix 0 ||;
    11 
    12 signature THY_PARSE =
    13 sig
    14   type token
    15   val !! : ('a -> 'b * 'c) -> 'a -> 'b * 'c
    16   val >> : ('a -> 'b * 'c) * ('b -> 'd) -> 'a -> 'd * 'c
    17   val || : ('a -> 'b) * ('a -> 'b) -> 'a -> 'b
    18   val -- : ('a -> 'b * 'c) * ('c -> 'd * 'e) -> 'a -> ('b * 'd) * 'e
    19   val ^^ : ('a -> string * 'b) * ('b -> string * 'c) -> 'a -> string * 'c
    20   val $$ : string -> token list -> string * token list
    21   val $$-- : string * (token list -> 'b * 'c) -> token list -> 'b * 'c
    22   val --$$ : ('a -> 'b * token list) * string -> 'a -> 'b * token list
    23   val ident: token list -> string * token list
    24   val long_ident: token list -> string * token list
    25   val long_id: token list -> string * token list
    26   val type_var: token list -> string * token list
    27   val type_args: token list -> string list * token list
    28   val nat: token list -> string * token list
    29   val string: token list -> string * token list
    30   val verbatim: token list -> string * token list
    31   val empty: 'a -> 'b list * 'a
    32   val optional: ('a -> 'b * 'a) -> 'b -> 'a -> 'b * 'a
    33   val repeat: ('a -> 'b * 'a) -> 'a -> 'b list * 'a
    34   val repeat1: ('a -> 'b * 'a) -> 'a -> 'b list * 'a
    35   val enum: string -> (token list -> 'a * token list)
    36     -> token list -> 'a list * token list
    37   val enum1: string -> (token list -> 'a * token list)
    38     -> token list -> 'a list * token list
    39   val list: (token list -> 'a * token list)
    40     -> token list -> 'a list * token list
    41   val list1: (token list -> 'a * token list)
    42     -> token list -> 'a list * token list
    43   val name: token list -> string * token list
    44   val sort: token list -> string * token list
    45   val opt_infix: token list -> string * token list
    46   val opt_mixfix: token list -> string * token list
    47   val opt_witness: token list -> string * token list
    48   type syntax
    49   val make_syntax: string list ->
    50     (string * (token list -> (string * string) * token list)) list -> syntax
    51   val parse_thy: syntax -> string -> string -> string
    52   val section: string -> string -> (token list -> string * token list)
    53     -> (string * (token list -> (string * string) * token list))
    54   val axm_section: string -> string
    55     -> (token list -> (string * string list) * token list)
    56     -> (string * (token list -> (string * string) * token list))
    57   val pure_keywords: string list
    58   val pure_sections:
    59     (string * (token list -> (string * string) * token list)) list
    60   (*items for building strings*)
    61   val cat: string -> string -> string
    62   val parens: string -> string
    63   val brackets: string -> string
    64   val mk_list: string list -> string
    65   val mk_big_list: string list -> string
    66   val mk_pair: string * string -> string
    67   val mk_triple: string * string * string -> string
    68   val strip_quotes: string -> string
    69 end;
    70 
    71 functor ThyParseFun(structure Symtab: SYMTAB and ThyScan: THY_SCAN): THY_PARSE =
    72 struct
    73 
    74 open ThyScan;
    75 
    76 
    77 (** parser toolbox **)
    78 
    79 type token = token_kind * string * int;
    80 
    81 
    82 (* errors *)
    83 
    84 exception SYNTAX_ERROR of string * string * int;
    85 
    86 fun syn_err s1 s2 n = raise SYNTAX_ERROR (s1, s2, n);
    87 
    88 fun eof_err () = error "Unexpected end-of-file";
    89 
    90 (*Similar to Prolog's cut: reports any syntax error instead of backtracking
    91   through a superior || *)
    92 fun !! parse toks = parse toks
    93   handle SYNTAX_ERROR (s1, s2, n) => error ("Syntax error on line " ^
    94     string_of_int n ^ ": " ^ s1 ^ " expected and " ^ s2 ^ " was found");
    95 
    96 
    97 (* parser combinators *)
    98 
    99 fun (parse >> f) toks = apfst f (parse toks);
   100 
   101 fun (parse1 || parse2) toks =
   102   parse1 toks handle SYNTAX_ERROR _ => parse2 toks;
   103 
   104 fun (parse1 -- parse2) toks =
   105   let
   106     val (x, toks') = parse1 toks;
   107     val (y, toks'') = parse2 toks';
   108   in
   109     ((x, y), toks'')
   110   end;
   111 
   112 fun (parse1 ^^ parse2) = parse1 -- parse2 >> op ^;
   113 
   114 
   115 (* generic parsers *)
   116 
   117 fun $$ a ((k, b, n) :: toks) =
   118       if k = Keyword andalso a = b then (a, toks)
   119       else syn_err (quote a) (quote b) n
   120   | $$ _ [] = eof_err ();
   121 
   122 fun (a $$-- parse) = $$ a -- parse >> #2;
   123 
   124 fun (parse --$$ a) = parse -- $$ a >> #1;
   125 
   126 
   127 fun kind k1 ((k2, s, n) :: toks) =
   128       if k1 = k2 then (s, toks)
   129       else syn_err (name_of_kind k1) (quote s) n
   130   | kind _ [] = eof_err ();
   131 
   132 val ident = kind Ident;
   133 val long_ident = kind LongIdent;
   134 val long_id = ident || long_ident;
   135 val type_var = kind TypeVar >> quote;
   136 val nat = kind Nat;
   137 val string = kind String;
   138 val verbatim = kind Verbatim;
   139 val eof = kind EOF;
   140 
   141 fun empty toks = ([], toks);
   142 
   143 fun optional parse def = parse || empty >> K def;
   144 
   145 fun repeat parse toks = (parse -- repeat parse >> op :: || empty) toks;
   146 fun repeat1 parse = parse -- repeat parse >> op ::;
   147 
   148 fun enum1 sep parse = parse -- repeat (sep $$-- parse) >> op ::;
   149 fun enum sep parse = enum1 sep parse || empty;
   150 
   151 val list = enum ",";
   152 val list1 = enum1 ",";
   153 
   154 
   155 
   156 (** theory parsers **)
   157 
   158 (* misc utilities *)
   159 
   160 fun cat s1 s2 = s1 ^ " " ^ s2;
   161 
   162 val parens = enclose "(" ")";
   163 val brackets = enclose "[" "]";
   164 
   165 val mk_list = brackets o commas;
   166 val mk_big_list = brackets o space_implode ",\n ";
   167 
   168 fun mk_pair (x, y) = parens (commas [x, y]);
   169 fun mk_triple (x, y, z) = parens (commas [x, y, z]);
   170 fun mk_triple1 ((x, y), z) = mk_triple (x, y, z);
   171 fun mk_triple2 (x, (y, z)) = mk_triple (x, y, z);
   172 
   173 val split_decls = flat o map (fn (xs, y) => map (rpair y) xs);
   174 
   175 fun strip_quotes str =
   176   implode (tl (take (size str - 1, explode str)));
   177 
   178 
   179 (* names *)
   180 
   181 val name = ident >> quote || string;
   182 val names = list name;
   183 val names1 = list1 name;
   184 val name_list = names >> mk_list;
   185 val name_list1 = names1 >> mk_list;
   186 
   187 
   188 (* classes *)
   189 
   190 val subclass = name -- optional ("<" $$-- !! name_list1) "[]";
   191 
   192 val class_decls = repeat1 (subclass >> mk_pair) >> mk_big_list;
   193 
   194 
   195 (* arities *)
   196 
   197 val sort =
   198   name >> brackets ||
   199   "{" $$-- name_list --$$ "}";
   200 
   201 val sort_list1 = list1 sort >> mk_list;
   202 
   203 
   204 val arity = optional ("(" $$-- !! (sort_list1 --$$")")) "[]" -- sort;
   205 
   206 val arity_decls = repeat1 (names1 --$$ "::" -- !! arity)
   207   >> (mk_big_list o map mk_triple2 o split_decls);
   208 
   209 
   210 (* mixfix annotations *)
   211 
   212 val infxl = "infixl" $$-- !! nat >> cat "Infixl";
   213 val infxr = "infixr" $$-- !! nat >> cat "Infixr";
   214 
   215 fun mk_binder ((name, x), y) =
   216   let val (p1, p2) = if y = "None" then ("0", x) else (x, y);
   217   in mk_triple (name, p1, p2) end;
   218 
   219 val binder = "binder" $$-- !! (string -- nat -- optional nat "None") 
   220              >> (cat "Binder" o mk_binder);
   221 
   222 val opt_pris = optional ("[" $$-- !! (list nat --$$ "]")) [] >> mk_list;
   223 
   224 val mixfix = string -- !! (opt_pris -- optional nat "max_pri")
   225   >> (cat "Mixfix" o mk_triple2);
   226 
   227 fun opt_syn fx = optional ("(" $$-- fx --$$ ")") "NoSyn";
   228 
   229 val opt_infix = opt_syn (infxl || infxr);
   230 val opt_mixfix = opt_syn (mixfix || infxl || infxr || binder);
   231 
   232 
   233 (* types *)
   234 
   235 fun mk_old_type_decl ((ts, n), syn) =
   236   map (fn t => (mk_triple (t, n, syn), false)) ts;
   237 
   238 fun mk_type_decl (((xs, t), None), syn) =
   239       [(mk_triple (t, string_of_int (length xs), syn), false)]
   240   | mk_type_decl (((xs, t), Some rhs), syn) =
   241       [(parens (commas [t, mk_list xs, rhs, syn]), true)];
   242 
   243 fun mk_type_decls tys =
   244   "|> add_types\n" ^ mk_big_list (keyfilter tys false) ^ "\n\n\
   245   \|> add_tyabbrs\n" ^ mk_big_list (keyfilter tys true);
   246 
   247 
   248 val old_type_decl = names1 -- nat -- opt_infix >> mk_old_type_decl;
   249 
   250 val type_args =
   251   type_var >> (fn x => [x]) ||
   252   "(" $$-- !! (list1 type_var --$$ ")") ||
   253   empty >> K [];
   254 
   255 val type_decl = type_args -- name -- optional ("=" $$-- !! string >> Some) None
   256   -- opt_infix >> mk_type_decl;
   257 
   258 val type_decls = repeat1 (old_type_decl || type_decl) >> (mk_type_decls o flat);
   259 
   260 
   261 (* consts *)
   262 
   263 val const_decls = repeat1 (names1 --$$ "::" -- !! (string -- opt_mixfix))
   264   >> (mk_big_list o map mk_triple2 o split_decls);
   265 
   266 
   267 (* translations *)
   268 
   269 val trans_pat =
   270   optional ("(" $$-- !! (name --$$ ")")) "\"logic\"" -- string >> mk_pair;
   271 
   272 val trans_arrow =
   273   $$ "=>" >> K " |-> " ||
   274   $$ "<=" >> K " <-| " ||
   275   $$ "==" >> K " <-> ";
   276 
   277 val trans_decls = repeat1 (trans_pat ^^ !! (trans_arrow ^^ trans_pat))
   278   >> mk_big_list;
   279 
   280 
   281 (* ML translations *)
   282 
   283 val trfun_defs =
   284   " val parse_ast_translation = [];\n\
   285   \ val parse_translation = [];\n\
   286   \ val print_translation = [];\n\
   287   \ val print_ast_translation = [];";
   288 
   289 val trfun_args =
   290   "(parse_ast_translation, parse_translation, \
   291   \print_translation, print_ast_translation)";
   292 
   293 fun mk_mltrans txt =
   294   "let\n"
   295   ^ trfun_defs ^ "\n"
   296   ^ txt ^ "\n\
   297   \in\n\
   298   \ " ^ trfun_args ^ "\n\
   299   \end";
   300 
   301 val mltrans = verbatim >> mk_mltrans;
   302 
   303 
   304 (* axioms *)
   305 
   306 val mk_axms = mk_big_list o map (mk_pair o apfst quote);
   307 
   308 fun mk_axiom_decls axms = (mk_axms axms, map fst axms);
   309 
   310 val axiom_decls = repeat1 (ident -- !! string) >> mk_axiom_decls;
   311 
   312 
   313 (* axclass *)
   314 
   315 fun mk_axclass_decl ((c, cs), axms) =
   316   (mk_pair (c, cs) ^ "\n" ^ mk_axms axms,
   317     (strip_quotes c ^ "I") :: map fst axms);
   318 
   319 val axclass_decl = subclass -- repeat (ident -- !! string) >> mk_axclass_decl;
   320 
   321 
   322 (* instance *)
   323 
   324 fun mk_witness (axths, opt_tac) =
   325   mk_list (keyfilter axths false) ^ "\n" ^
   326   mk_list (keyfilter axths true) ^ "\n" ^
   327   opt_tac;
   328 
   329 val axm_or_thm =
   330   string >> rpair false ||
   331   long_id >> rpair true;
   332 
   333 
   334 val opt_witness =
   335   optional ("(" $$-- list1 axm_or_thm --$$ ")") [] --
   336   optional (verbatim >> (parens o cat "Some" o parens)) "None"
   337   >> mk_witness;
   338 
   339 val instance_decl =
   340   (name --$$ "<" -- name >> (pair "|> AxClass.add_inst_subclass" o mk_pair) ||
   341     name --$$ "::" -- arity >> (pair "|> AxClass.add_inst_arity" o mk_triple2))
   342   -- opt_witness
   343   >> (fn ((x, y), z) => (cat_lines [x, y, z]));
   344 
   345 
   346 
   347 (** theory syntax **)
   348 
   349 type syntax =
   350   lexicon * (token list -> (string * string) * token list) Symtab.table;
   351 
   352 fun make_syntax keywords sects =
   353   (make_lexicon (map fst sects @ keywords),
   354     Symtab.make sects handle Symtab.DUPS dups =>
   355       error ("Duplicate sections in theory file syntax: " ^ commas_quote dups));
   356 
   357 
   358 (* header *)
   359 
   360 fun mk_header (thy_name, bases) =
   361   (thy_name, "mk_base " ^ mk_list bases ^ " " ^ quote thy_name);
   362 
   363 val base =
   364   ident >> (cat "Thy" o quote) ||
   365   string >> cat "File";
   366 
   367 val header = ident --$$ "=" -- enum1 "+" base >> mk_header;
   368 
   369 
   370 (* extension *)
   371 
   372 fun mk_extension (txts, mltxt) =
   373   let
   374     val cat_sects = space_implode "\n\n" o filter_out (equal "");
   375     val (extxts, postxts) = split_list txts;
   376   in
   377     (cat_sects extxts, cat_sects postxts, mltxt)
   378   end;
   379 
   380 fun sect tab ((Keyword, s, n) :: toks) =
   381       (case Symtab.lookup (tab, s) of
   382         Some parse => !! parse toks
   383       | None => syn_err "section" s n)
   384   | sect _ ((_, s, n) :: _) = syn_err "section" s n
   385   | sect _ [] = eof_err ();
   386 
   387 fun extension sectab = "+" $$-- !! (repeat (sect sectab) --$$ "end") --
   388   optional ("ML" $$-- verbatim) "" >> mk_extension;
   389 
   390 
   391 (* theory definition *)
   392 
   393 fun mk_structure tname ((thy_name, old_thys), opt_txts) =
   394   if thy_name <> tname then
   395     error ("Filename \"" ^ tname ^ ".thy\" and theory name "
   396       ^ quote thy_name ^ " are different")
   397   else
   398     (case opt_txts of
   399       Some (extxt, postxt, mltxt) =>
   400         "val thy = " ^ old_thys ^ " true;\n\n\
   401         \structure " ^ thy_name ^ " =\n\
   402         \struct\n\
   403         \\n\
   404         \local\n"
   405         ^ trfun_defs ^ "\n\
   406         \in\n\
   407         \\n"
   408         ^ mltxt ^ "\n\
   409         \\n\
   410         \val thy = thy\n\
   411         \\n\
   412         \|> add_trfuns\n"
   413         ^ trfun_args ^ "\n\
   414         \\n"
   415         ^ extxt ^ "\n\
   416         \\n\
   417         \|> add_thyname " ^ quote thy_name ^ ";\n\
   418         \\n\
   419         \val () = store_theory (thy, " ^ quote thy_name ^ ");\n\
   420         \\n\
   421         \\n"
   422         ^ postxt ^ "\n\
   423         \\n\
   424         \end;\n\
   425         \end;\n"
   426     | None =>
   427         "val thy = " ^ old_thys ^ " false;\n\
   428         \\n\
   429         \structure " ^ thy_name ^ " =\n\
   430         \struct\n\
   431         \\n\
   432         \val thy = thy\n\
   433         \\n\
   434         \val () = store_theory (thy, " ^ quote thy_name ^ ");\n\
   435         \\n\
   436         \end;\n");
   437 
   438 fun theory_defn sectab tname =
   439   header -- optional (extension sectab >> Some) None -- eof
   440   >> (mk_structure tname o #1);
   441 
   442 fun parse_thy (lex, sectab) tname str =
   443   #1 (!! (theory_defn sectab tname) (tokenize lex str));
   444 
   445 
   446 (* standard sections *)
   447 
   448 fun mk_val ax = "val " ^ ax ^ " = get_axiom thy " ^ quote ax ^ ";";
   449 val mk_vals = cat_lines o map mk_val;
   450 
   451 fun mk_axm_sect "" (txt, axs) = (txt, mk_vals axs)
   452   | mk_axm_sect pretxt (txt, axs) = (pretxt ^ "\n" ^ txt, mk_vals axs);
   453 
   454 fun axm_section name pretxt parse =
   455   (name, parse >> mk_axm_sect pretxt);
   456 
   457 fun section name pretxt parse =
   458   axm_section name pretxt (parse >> rpair []);
   459 
   460 
   461 val pure_keywords =
   462  ["end", "ML", "mixfix", "infixr", "infixl", "binder", "=", "+", ",", "<",
   463   "{", "}", "(", ")", "[", "]", "::", "==", "=>", "<="];
   464 
   465 val pure_sections =
   466  [section "classes" "|> add_classes" class_decls,
   467   section "default" "|> add_defsort" sort,
   468   section "types" "" type_decls,
   469   section "arities" "|> add_arities" arity_decls,
   470   section "consts" "|> add_consts" const_decls,
   471   section "syntax" "|> add_syntax" const_decls,
   472   section "translations" "|> add_trrules" trans_decls,
   473   section "MLtrans" "|> add_trfuns" mltrans,
   474   section "MLtext" "" verbatim,
   475   axm_section "rules" "|> add_axioms" axiom_decls,
   476   axm_section "defs" "|> add_defs" axiom_decls,
   477   axm_section "axclass" "|> AxClass.add_axclass" axclass_decl,
   478   section "instance" "" instance_decl];
   479 
   480 
   481 end;