src/Pure/sign.ML
author haftmann
Wed Jan 21 16:47:32 2009 +0100 (2009-01-21)
changeset 29581 b3b33e0298eb
parent 29006 abe0f11cfa4e
child 29606 fedb8be05f24
permissions -rw-r--r--
binding is alias for Binding.T
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical signature content: naming conventions, concrete syntax, type
     6 signature, polymorphic constants.
     7 *)
     8 
     9 signature SIGN =
    10 sig
    11   val rep_sg: theory ->
    12    {naming: NameSpace.naming,
    13     syn: Syntax.syntax,
    14     tsig: Type.tsig,
    15     consts: Consts.T}
    16   val naming_of: theory -> NameSpace.naming
    17   val full_name: theory -> binding -> string
    18   val base_name: string -> bstring
    19   val full_bname: theory -> bstring -> string
    20   val full_bname_path: theory -> string -> bstring -> string
    21   val syn_of: theory -> Syntax.syntax
    22   val tsig_of: theory -> Type.tsig
    23   val classes_of: theory -> Sorts.algebra
    24   val all_classes: theory -> class list
    25   val super_classes: theory -> class -> class list
    26   val minimize_sort: theory -> sort -> sort
    27   val complete_sort: theory -> sort -> sort
    28   val defaultS: theory -> sort
    29   val subsort: theory -> sort * sort -> bool
    30   val of_sort: theory -> typ * sort -> bool
    31   val witness_sorts: theory -> sort list -> sort list -> (typ * sort) list
    32   val is_logtype: theory -> string -> bool
    33   val typ_instance: theory -> typ * typ -> bool
    34   val typ_equiv: theory -> typ * typ -> bool
    35   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    36   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    37   val consts_of: theory -> Consts.T
    38   val the_const_constraint: theory -> string -> typ
    39   val const_type: theory -> string -> typ option
    40   val the_const_type: theory -> string -> typ
    41   val declared_tyname: theory -> string -> bool
    42   val declared_const: theory -> string -> bool
    43   val const_monomorphic: theory -> string -> bool
    44   val const_syntax_name: theory -> string -> string
    45   val const_typargs: theory -> string * typ -> typ list
    46   val const_instance: theory -> string * typ list -> typ
    47   val mk_const: theory -> string * typ list -> term
    48   val class_space: theory -> NameSpace.T
    49   val type_space: theory -> NameSpace.T
    50   val const_space: theory -> NameSpace.T
    51   val intern_class: theory -> xstring -> string
    52   val extern_class: theory -> string -> xstring
    53   val intern_type: theory -> xstring -> string
    54   val extern_type: theory -> string -> xstring
    55   val intern_const: theory -> xstring -> string
    56   val extern_const: theory -> string -> xstring
    57   val intern_sort: theory -> sort -> sort
    58   val extern_sort: theory -> sort -> sort
    59   val intern_typ: theory -> typ -> typ
    60   val extern_typ: theory -> typ -> typ
    61   val intern_term: theory -> term -> term
    62   val extern_term: (string -> xstring) -> theory -> term -> term
    63   val intern_tycons: theory -> typ -> typ
    64   val arity_number: theory -> string -> int
    65   val arity_sorts: theory -> string -> sort -> sort list
    66   val certify_class: theory -> class -> class
    67   val certify_sort: theory -> sort -> sort
    68   val certify_typ: theory -> typ -> typ
    69   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    70   val certify': bool -> Pretty.pp -> bool -> Consts.T -> theory -> term -> term * typ * int
    71   val certify_term: theory -> term -> term * typ * int
    72   val certify_prop: theory -> term -> term * typ * int
    73   val cert_term: theory -> term -> term
    74   val cert_prop: theory -> term -> term
    75   val no_frees: Pretty.pp -> term -> term
    76   val no_vars: Pretty.pp -> term -> term
    77   val cert_def: Proof.context -> term -> (string * typ) * term
    78   val read_class: theory -> xstring -> class
    79   val read_arity: theory -> xstring * string list * string -> arity
    80   val cert_arity: theory -> arity -> arity
    81   val add_defsort: string -> theory -> theory
    82   val add_defsort_i: sort -> theory -> theory
    83   val add_types: (bstring * int * mixfix) list -> theory -> theory
    84   val add_nonterminals: bstring list -> theory -> theory
    85   val add_tyabbrs: (bstring * string list * string * mixfix) list -> theory -> theory
    86   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> theory -> theory
    87   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    88   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    89   val add_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    90   val add_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    91   val del_modesyntax: Syntax.mode -> (bstring * string * mixfix) list -> theory -> theory
    92   val del_modesyntax_i: Syntax.mode -> (bstring * typ * mixfix) list -> theory -> theory
    93   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    94   val declare_const: Properties.T -> (binding * typ) * mixfix -> theory -> term * theory
    95   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    96   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    97   val add_abbrev: string -> Properties.T -> binding * term -> theory -> (term * term) * theory
    98   val revert_abbrev: string -> string -> theory -> theory
    99   val add_const_constraint: string * typ option -> theory -> theory
   100   val primitive_class: string * class list -> theory -> theory
   101   val primitive_classrel: class * class -> theory -> theory
   102   val primitive_arity: arity -> theory -> theory
   103   val add_trfuns:
   104     (string * (ast list -> ast)) list *
   105     (string * (term list -> term)) list *
   106     (string * (term list -> term)) list *
   107     (string * (ast list -> ast)) list -> theory -> theory
   108   val add_trfunsT:
   109     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
   110   val add_advanced_trfuns:
   111     (string * (Proof.context -> ast list -> ast)) list *
   112     (string * (Proof.context -> term list -> term)) list *
   113     (string * (Proof.context -> term list -> term)) list *
   114     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
   115   val add_advanced_trfunsT:
   116     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
   117   val add_tokentrfuns:
   118     (string * string * (Proof.context -> string -> Pretty.T)) list -> theory -> theory
   119   val add_mode_tokentrfuns: string -> (string * (Proof.context -> string -> Pretty.T)) list
   120     -> theory -> theory
   121   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   122   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   123   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
   124   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
   125   val add_path: string -> theory -> theory
   126   val parent_path: theory -> theory
   127   val root_path: theory -> theory
   128   val absolute_path: theory -> theory
   129   val local_path: theory -> theory
   130   val no_base_names: theory -> theory
   131   val qualified_names: theory -> theory
   132   val sticky_prefix: string -> theory -> theory
   133   val restore_naming: theory -> theory -> theory
   134   val hide_class: bool -> string -> theory -> theory
   135   val hide_type: bool -> string -> theory -> theory
   136   val hide_const: bool -> string -> theory -> theory
   137 end
   138 
   139 structure Sign: SIGN =
   140 struct
   141 
   142 (** datatype sign **)
   143 
   144 datatype sign = Sign of
   145  {naming: NameSpace.naming,     (*common naming conventions*)
   146   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   147   tsig: Type.tsig,              (*order-sorted signature of types*)
   148   consts: Consts.T};            (*polymorphic constants*)
   149 
   150 fun make_sign (naming, syn, tsig, consts) =
   151   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   152 
   153 structure SignData = TheoryDataFun
   154 (
   155   type T = sign;
   156   val copy = I;
   157   fun extend (Sign {syn, tsig, consts, ...}) =
   158     make_sign (NameSpace.default_naming, syn, tsig, consts);
   159 
   160   val empty =
   161     make_sign (NameSpace.default_naming, Syntax.basic_syn, Type.empty_tsig, Consts.empty);
   162 
   163   fun merge pp (sign1, sign2) =
   164     let
   165       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   166       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   167 
   168       val naming = NameSpace.default_naming;
   169       val syn = Syntax.merge_syntaxes syn1 syn2;
   170       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   171       val consts = Consts.merge (consts1, consts2);
   172     in make_sign (naming, syn, tsig, consts) end;
   173 );
   174 
   175 fun rep_sg thy = SignData.get thy |> (fn Sign args => args);
   176 
   177 fun map_sign f = SignData.map (fn Sign {naming, syn, tsig, consts} =>
   178   make_sign (f (naming, syn, tsig, consts)));
   179 
   180 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   181 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   182 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   183 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   184 
   185 
   186 (* naming *)
   187 
   188 val naming_of = #naming o rep_sg;
   189 val base_name = NameSpace.base;
   190 
   191 val full_name = NameSpace.full_name o naming_of;
   192 fun full_bname thy = NameSpace.full_name (naming_of thy) o Binding.name;
   193 fun full_bname_path thy elems =
   194   NameSpace.full_name (NameSpace.add_path elems (naming_of thy)) o Binding.name;
   195 
   196 
   197 (* syntax *)
   198 
   199 val syn_of = #syn o rep_sg;
   200 
   201 
   202 (* type signature *)
   203 
   204 val tsig_of = #tsig o rep_sg;
   205 
   206 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   207 val all_classes = Sorts.all_classes o classes_of;
   208 val super_classes = Sorts.super_classes o classes_of;
   209 val minimize_sort = Sorts.minimize_sort o classes_of;
   210 val complete_sort = Sorts.complete_sort o classes_of;
   211 
   212 val defaultS = Type.defaultS o tsig_of;
   213 val subsort = Type.subsort o tsig_of;
   214 val of_sort = Type.of_sort o tsig_of;
   215 val witness_sorts = Type.witness_sorts o tsig_of;
   216 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   217 
   218 val typ_instance = Type.typ_instance o tsig_of;
   219 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   220 val typ_match = Type.typ_match o tsig_of;
   221 val typ_unify = Type.unify o tsig_of;
   222 
   223 
   224 (* polymorphic constants *)
   225 
   226 val consts_of = #consts o rep_sg;
   227 val the_const_constraint = Consts.the_constraint o consts_of;
   228 val the_const_type = Consts.the_type o consts_of;
   229 val const_type = try o the_const_type;
   230 val const_monomorphic = Consts.is_monomorphic o consts_of;
   231 val const_syntax_name = Consts.syntax_name o consts_of;
   232 val const_typargs = Consts.typargs o consts_of;
   233 val const_instance = Consts.instance o consts_of;
   234 
   235 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   236 
   237 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   238 val declared_const = can o the_const_constraint;
   239 
   240 
   241 
   242 (** intern / extern names **)
   243 
   244 val class_space = #1 o #classes o Type.rep_tsig o tsig_of;
   245 val type_space = #1 o #types o Type.rep_tsig o tsig_of;
   246 val const_space = Consts.space_of o consts_of;
   247 
   248 val intern_class = NameSpace.intern o class_space;
   249 val extern_class = NameSpace.extern o class_space;
   250 val intern_type = NameSpace.intern o type_space;
   251 val extern_type = NameSpace.extern o type_space;
   252 val intern_const = NameSpace.intern o const_space;
   253 val extern_const = NameSpace.extern o const_space;
   254 
   255 val intern_sort = map o intern_class;
   256 val extern_sort = map o extern_class;
   257 
   258 local
   259 
   260 fun map_typ f g (Type (c, Ts)) = Type (g c, map (map_typ f g) Ts)
   261   | map_typ f _ (TFree (x, S)) = TFree (x, map f S)
   262   | map_typ f _ (TVar (xi, S)) = TVar (xi, map f S);
   263 
   264 fun map_term f g h (Const (c, T)) = Const (h c, map_typ f g T)
   265   | map_term f g _ (Free (x, T)) = Free (x, map_typ f g T)
   266   | map_term f g _ (Var (xi, T)) = Var (xi, map_typ f g T)
   267   | map_term _ _ _ (t as Bound _) = t
   268   | map_term f g h (Abs (x, T, t)) = Abs (x, map_typ f g T, map_term f g h t)
   269   | map_term f g h (t $ u) = map_term f g h t $ map_term f g h u;
   270 
   271 val add_classesT = Term.fold_atyps
   272   (fn TFree (_, S) => fold (insert (op =)) S
   273     | TVar (_, S) => fold (insert (op =)) S
   274     | _ => I);
   275 
   276 fun add_tyconsT (Type (c, Ts)) = insert (op =) c #> fold add_tyconsT Ts
   277   | add_tyconsT _ = I;
   278 
   279 val add_consts = Term.fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   280 
   281 fun mapping add_names f t =
   282   let
   283     fun f' (x: string) = let val y = f x in if x = y then NONE else SOME (x, y) end;
   284     val tab = map_filter f' (add_names t []);
   285     fun get x = the_default x (AList.lookup (op =) tab x);
   286   in get end;
   287 
   288 fun typ_mapping f g thy T =
   289   T |> map_typ
   290     (mapping add_classesT (f thy) T)
   291     (mapping add_tyconsT (g thy) T);
   292 
   293 fun term_mapping f g h thy t =
   294   t |> map_term
   295     (mapping (Term.fold_types add_classesT) (f thy) t)
   296     (mapping (Term.fold_types add_tyconsT) (g thy) t)
   297     (mapping add_consts (h thy) t);
   298 
   299 in
   300 
   301 val intern_typ = typ_mapping intern_class intern_type;
   302 val extern_typ = typ_mapping extern_class extern_type;
   303 val intern_term = term_mapping intern_class intern_type intern_const;
   304 fun extern_term h = term_mapping extern_class extern_type (K h);
   305 val intern_tycons = typ_mapping (K I) intern_type;
   306 
   307 end;
   308 
   309 
   310 
   311 (** certify entities **)    (*exception TYPE*)
   312 
   313 (* certify wrt. type signature *)
   314 
   315 val arity_number = Type.arity_number o tsig_of;
   316 fun arity_sorts thy = Type.arity_sorts (Syntax.pp_global thy) (tsig_of thy);
   317 
   318 val certify_class         = Type.cert_class o tsig_of;
   319 val certify_sort          = Type.cert_sort o tsig_of;
   320 val certify_typ           = Type.cert_typ o tsig_of;
   321 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   322 
   323 
   324 (* certify term/prop *)
   325 
   326 local
   327 
   328 fun type_check pp tm =
   329   let
   330     fun err_appl why bs t T u U =
   331       let
   332         val xs = map Free bs;           (*we do not rename here*)
   333         val t' = subst_bounds (xs, t);
   334         val u' = subst_bounds (xs, u);
   335         val msg = cat_lines
   336           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   337       in raise TYPE (msg, [T, U], [t', u']) end;
   338 
   339     fun typ_of (_, Const (_, T)) = T
   340       | typ_of (_, Free  (_, T)) = T
   341       | typ_of (_, Var (_, T)) = T
   342       | typ_of (bs, Bound i) = snd (List.nth (bs, i) handle Subscript =>
   343           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   344       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   345       | typ_of (bs, t $ u) =
   346           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   347             (case T of
   348               Type ("fun", [T1, T2]) =>
   349                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   350             | _ => err_appl "Operator not of function type" bs t T u U)
   351           end;
   352   in typ_of ([], tm) end;
   353 
   354 fun err msg = raise TYPE (msg, [], []);
   355 
   356 fun check_vars (t $ u) = (check_vars t; check_vars u)
   357   | check_vars (Abs (_, _, t)) = check_vars t
   358   | check_vars (Free (x, _)) =
   359       if NameSpace.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   360   | check_vars (Var (xi as (_, i), _)) =
   361       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   362   | check_vars _ = ();
   363 
   364 in
   365 
   366 fun certify' prop pp do_expand consts thy tm =
   367   let
   368     val _ = check_vars tm;
   369     val tm' = Term.map_types (certify_typ thy) tm;
   370     val T = type_check pp tm';
   371     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   372     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   373   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   374 
   375 fun certify_term thy = certify' false (Syntax.pp_global thy) true (consts_of thy) thy;
   376 fun certify_prop thy = certify' true (Syntax.pp_global thy) true (consts_of thy) thy;
   377 
   378 fun cert_term_abbrev thy = #1 o certify' false (Syntax.pp_global thy) false (consts_of thy) thy;
   379 val cert_term = #1 oo certify_term;
   380 val cert_prop = #1 oo certify_prop;
   381 
   382 end;
   383 
   384 
   385 (* specifications *)
   386 
   387 fun no_variables kind add addT mk mkT pp tm =
   388   (case (add tm [], addT tm []) of
   389     ([], []) => tm
   390   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   391       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   392        Pretty.commas (map (Pretty.term pp o mk) frees @ map (Pretty.typ pp o mkT) tfrees)))));
   393 
   394 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   395 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   396 
   397 fun cert_def ctxt tm =
   398   let val ((lhs, rhs), _) = tm
   399     |> no_vars (Syntax.pp ctxt)
   400     |> Logic.strip_imp_concl
   401     |> PrimitiveDefs.dest_def ctxt Term.is_Const (K false) (K false)
   402   in (Term.dest_Const (Term.head_of lhs), rhs) end
   403   handle TERM (msg, _) => error msg;
   404 
   405 
   406 
   407 (** read and certify entities **)    (*exception ERROR*)
   408 
   409 (* classes *)
   410 
   411 fun read_class thy c = certify_class thy (intern_class thy c)
   412   handle TYPE (msg, _, _) => error msg;
   413 
   414 
   415 (* type arities *)
   416 
   417 fun prep_arity prep_tycon prep_sort thy (t, Ss, S) =
   418   let val arity = (prep_tycon thy t, map (prep_sort thy) Ss, prep_sort thy S)
   419   in Type.add_arity (Syntax.pp_global thy) arity (tsig_of thy); arity end;
   420 
   421 val read_arity = prep_arity intern_type Syntax.read_sort_global;
   422 val cert_arity = prep_arity (K I) certify_sort;
   423 
   424 
   425 
   426 (** signature extension functions **)  (*exception ERROR/TYPE*)
   427 
   428 (* add default sort *)
   429 
   430 fun gen_add_defsort prep_sort s thy =
   431   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   432 
   433 val add_defsort = gen_add_defsort Syntax.read_sort_global;
   434 val add_defsort_i = gen_add_defsort certify_sort;
   435 
   436 
   437 (* add type constructors *)
   438 
   439 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   440   let
   441     val syn' = Syntax.update_type_gram types syn;
   442     val decls = map (fn (a, n, mx) => (Syntax.type_name a mx, n)) types;
   443     val tags = [(Markup.theory_nameN, Context.theory_name thy)];
   444     val tsig' = fold (Type.add_type naming tags) decls tsig;
   445   in (naming, syn', tsig', consts) end);
   446 
   447 
   448 (* add nonterminals *)
   449 
   450 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   451   let
   452     val syn' = Syntax.update_consts ns syn;
   453     val tsig' = fold (Type.add_nonterminal naming []) ns tsig;
   454   in (naming, syn', tsig', consts) end);
   455 
   456 
   457 (* add type abbreviations *)
   458 
   459 fun gen_add_tyabbr parse_typ (a, vs, rhs, mx) thy =
   460   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   461     let
   462       val ctxt = ProofContext.init thy;
   463       val syn' = Syntax.update_type_gram [(a, length vs, mx)] syn;
   464       val a' = Syntax.type_name a mx;
   465       val abbr = (a', vs, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt rhs))
   466         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote a');
   467       val tsig' = Type.add_abbrev naming [] abbr tsig;
   468     in (naming, syn', tsig', consts) end);
   469 
   470 val add_tyabbrs = fold (gen_add_tyabbr Syntax.parse_typ);
   471 val add_tyabbrs_i = fold (gen_add_tyabbr (K I));
   472 
   473 
   474 (* modify syntax *)
   475 
   476 fun gen_syntax change_gram parse_typ mode args thy =
   477   let
   478     val ctxt = ProofContext.init thy;
   479     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   480       handle ERROR msg =>
   481         cat_error msg ("in syntax declaration " ^ quote (Syntax.const_name c mx));
   482   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   483 
   484 fun gen_add_syntax x = gen_syntax Syntax.update_const_gram x;
   485 
   486 val add_modesyntax = gen_add_syntax Syntax.parse_typ;
   487 val add_modesyntax_i = gen_add_syntax (K I);
   488 val add_syntax = add_modesyntax Syntax.mode_default;
   489 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   490 val del_modesyntax = gen_syntax Syntax.remove_const_gram Syntax.parse_typ;
   491 val del_modesyntax_i = gen_syntax Syntax.remove_const_gram (K I);
   492 
   493 fun notation add mode args thy =
   494   let
   495     val change_gram = if add then Syntax.update_const_gram else Syntax.remove_const_gram;
   496     fun const_syntax (Const (c, _), mx) = try (Consts.syntax (consts_of thy)) (c, mx)
   497       | const_syntax _ = NONE;
   498   in gen_syntax change_gram (K I) mode (map_filter const_syntax args) thy end;
   499 
   500 
   501 (* add constants *)
   502 
   503 local
   504 
   505 fun gen_add_consts parse_typ authentic tags raw_args thy =
   506   let
   507     val ctxt = ProofContext.init thy;
   508     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o parse_typ ctxt;
   509     fun prep (raw_b, raw_T, raw_mx) =
   510       let
   511         val (mx_name, mx) = Syntax.const_mixfix (Binding.base_name raw_b) raw_mx;
   512         val b = Binding.map_base (K mx_name) raw_b;
   513         val c = full_name thy b;
   514         val c_syn = if authentic then Syntax.constN ^ c else Binding.base_name b;
   515         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   516           cat_error msg ("in declaration of constant " ^ quote (Binding.display b));
   517         val T' = Logic.varifyT T;
   518       in ((b, T'), (c_syn, T', mx), Const (c, T)) end;
   519     val args = map prep raw_args;
   520     val tags' = tags |> Properties.put (Markup.theory_nameN, Context.theory_name thy);
   521   in
   522     thy
   523     |> map_consts (fold (Consts.declare authentic (naming_of thy) tags' o #1) args)
   524     |> add_syntax_i (map #2 args)
   525     |> pair (map #3 args)
   526   end;
   527 
   528 fun bindify (name, T, mx) = (Binding.name name, T, mx);
   529 
   530 in
   531 
   532 fun add_consts args = snd o gen_add_consts Syntax.parse_typ false [] (map bindify args);
   533 fun add_consts_i args = snd o gen_add_consts (K I) false [] (map bindify args);
   534 
   535 fun declare_const tags ((b, T), mx) thy =
   536   let
   537     val pos = Binding.pos_of b;
   538     val tags' = Position.default_properties pos tags;
   539     val ([const as Const (c, _)], thy') = gen_add_consts (K I) true tags' [(b, T, mx)] thy;
   540     val _ = Position.report (Markup.const_decl c) pos;
   541   in (const, thy') end;
   542 
   543 end;
   544 
   545 
   546 (* abbreviations *)
   547 
   548 fun add_abbrev mode tags (b, raw_t) thy =
   549   let
   550     val pp = Syntax.pp_global thy;
   551     val prep_tm = no_frees pp o Term.no_dummy_patterns o cert_term_abbrev thy;
   552     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   553       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote (Binding.display b));
   554     val (res, consts') = consts_of thy
   555       |> Consts.abbreviate pp (tsig_of thy) (naming_of thy) mode tags (b, t);
   556   in (res, thy |> map_consts (K consts')) end;
   557 
   558 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   559 
   560 
   561 (* add constraints *)
   562 
   563 fun add_const_constraint (c, opt_T) thy =
   564   let
   565     fun prepT raw_T =
   566       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   567       in cert_term thy (Const (c, T)); T end
   568       handle TYPE (msg, _, _) => error msg;
   569   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   570 
   571 
   572 (* primitive classes and arities *)
   573 
   574 fun primitive_class (bclass, classes) thy =
   575   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   576     let
   577       val syn' = Syntax.update_consts [bclass] syn;
   578       val tsig' = Type.add_class (Syntax.pp_global thy) naming (bclass, classes) tsig;
   579     in (naming, syn', tsig', consts) end)
   580   |> add_consts_i [(Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   581 
   582 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (Syntax.pp_global thy) arg);
   583 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (Syntax.pp_global thy) arg);
   584 
   585 
   586 (* add translation functions *)
   587 
   588 local
   589 
   590 fun mk trs = map Syntax.mk_trfun trs;
   591 
   592 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   593   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   594 
   595 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   596 
   597 in
   598 
   599 val add_trfuns = gen_add_trfuns Syntax.update_trfuns Syntax.non_typed_tr';
   600 val add_trfunsT = gen_add_trfunsT Syntax.update_trfuns;
   601 val add_advanced_trfuns = gen_add_trfuns Syntax.update_advanced_trfuns Syntax.non_typed_tr'';
   602 val add_advanced_trfunsT = gen_add_trfunsT Syntax.update_advanced_trfuns;
   603 
   604 end;
   605 
   606 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   607 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   608 
   609 
   610 (* translation rules *)
   611 
   612 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   613   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   614   in f (ProofContext.init thy) (is_logtype thy) syn rules syn end);
   615 
   616 val add_trrules = gen_trrules Syntax.update_trrules;
   617 val del_trrules = gen_trrules Syntax.remove_trrules;
   618 val add_trrules_i = map_syn o Syntax.update_trrules_i;
   619 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   620 
   621 
   622 (* naming *)
   623 
   624 val add_path        = map_naming o NameSpace.add_path;
   625 val no_base_names   = map_naming NameSpace.no_base_names;
   626 val qualified_names = map_naming NameSpace.qualified_names;
   627 val sticky_prefix   = map_naming o NameSpace.sticky_prefix;
   628 val restore_naming  = map_naming o K o naming_of;
   629 
   630 val parent_path   = add_path "..";
   631 val root_path     = add_path "/";
   632 val absolute_path = add_path "//";
   633 
   634 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   635 
   636 
   637 (* hide names *)
   638 
   639 val hide_class = map_tsig oo Type.hide_class;
   640 val hide_type = map_tsig oo Type.hide_type;
   641 val hide_const = map_consts oo Consts.hide;
   642 
   643 end;