src/HOL/List.thy
author nipkow
Wed Apr 16 22:14:08 2003 +0200 (2003-04-16)
changeset 13913 b3ed67af04b8
parent 13883 0451e0fb3f22
child 14025 d9b155757dc8
permissions -rw-r--r--
Added take/dropWhile thms
     1 (*  Title:      HOL/List.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow
     4     License:    GPL (GNU GENERAL PUBLIC LICENSE)
     5 *)
     6 
     7 header {* The datatype of finite lists *}
     8 
     9 theory List = PreList:
    10 
    11 datatype 'a list =
    12     Nil    ("[]")
    13   | Cons 'a  "'a list"    (infixr "#" 65)
    14 
    15 consts
    16   "@" :: "'a list => 'a list => 'a list"    (infixr 65)
    17   filter:: "('a => bool) => 'a list => 'a list"
    18   concat:: "'a list list => 'a list"
    19   foldl :: "('b => 'a => 'b) => 'b => 'a list => 'b"
    20   foldr :: "('a => 'b => 'b) => 'a list => 'b => 'b"
    21   hd:: "'a list => 'a"
    22   tl:: "'a list => 'a list"
    23   last:: "'a list => 'a"
    24   butlast :: "'a list => 'a list"
    25   set :: "'a list => 'a set"
    26   list_all:: "('a => bool) => ('a list => bool)"
    27   list_all2 :: "('a => 'b => bool) => 'a list => 'b list => bool"
    28   map :: "('a=>'b) => ('a list => 'b list)"
    29   mem :: "'a => 'a list => bool"    (infixl 55)
    30   nth :: "'a list => nat => 'a"    (infixl "!" 100)
    31   list_update :: "'a list => nat => 'a => 'a list"
    32   take:: "nat => 'a list => 'a list"
    33   drop:: "nat => 'a list => 'a list"
    34   takeWhile :: "('a => bool) => 'a list => 'a list"
    35   dropWhile :: "('a => bool) => 'a list => 'a list"
    36   rev :: "'a list => 'a list"
    37   zip :: "'a list => 'b list => ('a * 'b) list"
    38   upt :: "nat => nat => nat list" ("(1[_../_'(])")
    39   remdups :: "'a list => 'a list"
    40   null:: "'a list => bool"
    41   "distinct":: "'a list => bool"
    42   replicate :: "nat => 'a => 'a list"
    43 
    44 nonterminals lupdbinds lupdbind
    45 
    46 syntax
    47   -- {* list Enumeration *}
    48   "@list" :: "args => 'a list"    ("[(_)]")
    49 
    50   -- {* Special syntax for filter *}
    51   "@filter" :: "[pttrn, 'a list, bool] => 'a list"    ("(1[_:_./ _])")
    52 
    53   -- {* list update *}
    54   "_lupdbind":: "['a, 'a] => lupdbind"    ("(2_ :=/ _)")
    55   "" :: "lupdbind => lupdbinds"    ("_")
    56   "_lupdbinds" :: "[lupdbind, lupdbinds] => lupdbinds"    ("_,/ _")
    57   "_LUpdate" :: "['a, lupdbinds] => 'a"    ("_/[(_)]" [900,0] 900)
    58 
    59   upto:: "nat => nat => nat list"    ("(1[_../_])")
    60 
    61 translations
    62   "[x, xs]" == "x#[xs]"
    63   "[x]" == "x#[]"
    64   "[x:xs . P]"== "filter (%x. P) xs"
    65 
    66   "_LUpdate xs (_lupdbinds b bs)"== "_LUpdate (_LUpdate xs b) bs"
    67   "xs[i:=x]" == "list_update xs i x"
    68 
    69   "[i..j]" == "[i..(Suc j)(]"
    70 
    71 
    72 syntax (xsymbols)
    73   "@filter" :: "[pttrn, 'a list, bool] => 'a list"("(1[_\<in>_ ./ _])")
    74 
    75 
    76 text {*
    77   Function @{text size} is overloaded for all datatypes.Users may
    78   refer to the list version as @{text length}. *}
    79 
    80 syntax length :: "'a list => nat"
    81 translations "length" => "size :: _ list => nat"
    82 
    83 typed_print_translation {*
    84   let
    85     fun size_tr' _ (Type ("fun", (Type ("list", _) :: _))) [t] =
    86           Syntax.const "length" $ t
    87       | size_tr' _ _ _ = raise Match;
    88   in [("size", size_tr')] end
    89 *}
    90 
    91 primrec
    92 "hd(x#xs) = x"
    93 primrec
    94 "tl([]) = []"
    95 "tl(x#xs) = xs"
    96 primrec
    97 "null([]) = True"
    98 "null(x#xs) = False"
    99 primrec
   100 "last(x#xs) = (if xs=[] then x else last xs)"
   101 primrec
   102 "butlast []= []"
   103 "butlast(x#xs) = (if xs=[] then [] else x#butlast xs)"
   104 primrec
   105 "x mem [] = False"
   106 "x mem (y#ys) = (if y=x then True else x mem ys)"
   107 primrec
   108 "set [] = {}"
   109 "set (x#xs) = insert x (set xs)"
   110 primrec
   111 list_all_Nil:"list_all P [] = True"
   112 list_all_Cons: "list_all P (x#xs) = (P(x) \<and> list_all P xs)"
   113 primrec
   114 "map f [] = []"
   115 "map f (x#xs) = f(x)#map f xs"
   116 primrec
   117 append_Nil:"[]@ys = ys"
   118 append_Cons: "(x#xs)@ys = x#(xs@ys)"
   119 primrec
   120 "rev([]) = []"
   121 "rev(x#xs) = rev(xs) @ [x]"
   122 primrec
   123 "filter P [] = []"
   124 "filter P (x#xs) = (if P x then x#filter P xs else filter P xs)"
   125 primrec
   126 foldl_Nil:"foldl f a [] = a"
   127 foldl_Cons: "foldl f a (x#xs) = foldl f (f a x) xs"
   128 primrec
   129 "foldr f [] a = a"
   130 "foldr f (x#xs) a = f x (foldr f xs a)"
   131 primrec
   132 "concat([]) = []"
   133 "concat(x#xs) = x @ concat(xs)"
   134 primrec
   135 drop_Nil:"drop n [] = []"
   136 drop_Cons: "drop n (x#xs) = (case n of 0 => x#xs | Suc(m) => drop m xs)"
   137 -- {* Warning: simpset does not contain this definition *}
   138 -- {* but separate theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   139 primrec
   140 take_Nil:"take n [] = []"
   141 take_Cons: "take n (x#xs) = (case n of 0 => [] | Suc(m) => x # take m xs)"
   142 -- {* Warning: simpset does not contain this definition *}
   143 -- {* but separate theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   144 primrec
   145 nth_Cons:"(x#xs)!n = (case n of 0 => x | (Suc k) => xs!k)"
   146 -- {* Warning: simpset does not contain this definition *}
   147 -- {* but separate theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   148 primrec
   149 "[][i:=v] = []"
   150 "(x#xs)[i:=v] =
   151 (case i of 0 => v # xs
   152 | Suc j => x # xs[j:=v])"
   153 primrec
   154 "takeWhile P [] = []"
   155 "takeWhile P (x#xs) = (if P x then x#takeWhile P xs else [])"
   156 primrec
   157 "dropWhile P [] = []"
   158 "dropWhile P (x#xs) = (if P x then dropWhile P xs else x#xs)"
   159 primrec
   160 "zip xs [] = []"
   161 zip_Cons: "zip xs (y#ys) = (case xs of [] => [] | z#zs => (z,y)#zip zs ys)"
   162 -- {* Warning: simpset does not contain this definition *}
   163 -- {* but separate theorems for @{text "xs = []"} and @{text "xs = z # zs"} *}
   164 primrec
   165 upt_0: "[i..0(] = []"
   166 upt_Suc: "[i..(Suc j)(] = (if i <= j then [i..j(] @ [j] else [])"
   167 primrec
   168 "distinct [] = True"
   169 "distinct (x#xs) = (x ~: set xs \<and> distinct xs)"
   170 primrec
   171 "remdups [] = []"
   172 "remdups (x#xs) = (if x : set xs then remdups xs else x # remdups xs)"
   173 primrec
   174 replicate_0: "replicate 0 x = []"
   175 replicate_Suc: "replicate (Suc n) x = x # replicate n x"
   176 defs
   177  list_all2_def:
   178  "list_all2 P xs ys == length xs = length ys \<and> (\<forall>(x, y) \<in> set (zip xs ys). P x y)"
   179 
   180 
   181 subsection {* Lexicographic orderings on lists *}
   182 
   183 consts
   184 lexn :: "('a * 'a)set => nat => ('a list * 'a list)set"
   185 primrec
   186 "lexn r 0 = {}"
   187 "lexn r (Suc n) =
   188 (prod_fun (%(x,xs). x#xs) (%(x,xs). x#xs) ` (r <*lex*> lexn r n)) Int
   189 {(xs,ys). length xs = Suc n \<and> length ys = Suc n}"
   190 
   191 constdefs
   192 lex :: "('a \<times> 'a) set => ('a list \<times> 'a list) set"
   193 "lex r == \<Union>n. lexn r n"
   194 
   195 lexico :: "('a \<times> 'a) set => ('a list \<times> 'a list) set"
   196 "lexico r == inv_image (less_than <*lex*> lex r) (%xs. (length xs, xs))"
   197 
   198 sublist :: "'a list => nat set => 'a list"
   199 "sublist xs A == map fst (filter (%p. snd p : A) (zip xs [0..size xs(]))"
   200 
   201 
   202 lemma not_Cons_self [simp]: "xs \<noteq> x # xs"
   203 by (induct xs) auto
   204 
   205 lemmas not_Cons_self2 [simp] = not_Cons_self [symmetric]
   206 
   207 lemma neq_Nil_conv: "(xs \<noteq> []) = (\<exists>y ys. xs = y # ys)"
   208 by (induct xs) auto
   209 
   210 lemma length_induct:
   211 "(!!xs. \<forall>ys. length ys < length xs --> P ys ==> P xs) ==> P xs"
   212 by (rule measure_induct [of length]) rules
   213 
   214 
   215 subsection {* @{text lists}: the list-forming operator over sets *}
   216 
   217 consts lists :: "'a set => 'a list set"
   218 inductive "lists A"
   219 intros
   220 Nil [intro!]: "[]: lists A"
   221 Cons [intro!]: "[| a: A;l: lists A|] ==> a#l : lists A"
   222 
   223 inductive_cases listsE [elim!]: "x#l : lists A"
   224 
   225 lemma lists_mono [mono]: "A \<subseteq> B ==> lists A \<subseteq> lists B"
   226 by (unfold lists.defs) (blast intro!: lfp_mono)
   227 
   228 lemma lists_IntI:
   229   assumes l: "l: lists A" shows "l: lists B ==> l: lists (A Int B)" using l
   230   by induct blast+
   231 
   232 lemma lists_Int_eq [simp]: "lists (A \<inter> B) = lists A \<inter> lists B"
   233 apply (rule mono_Int [THEN equalityI])
   234 apply (simp add: mono_def lists_mono)
   235 apply (blast intro!: lists_IntI)
   236 done
   237 
   238 lemma append_in_lists_conv [iff]:
   239 "(xs @ ys : lists A) = (xs : lists A \<and> ys : lists A)"
   240 by (induct xs) auto
   241 
   242 
   243 subsection {* @{text length} *}
   244 
   245 text {*
   246 Needs to come before @{text "@"} because of theorem @{text
   247 append_eq_append_conv}.
   248 *}
   249 
   250 lemma length_append [simp]: "length (xs @ ys) = length xs + length ys"
   251 by (induct xs) auto
   252 
   253 lemma length_map [simp]: "length (map f xs) = length xs"
   254 by (induct xs) auto
   255 
   256 lemma length_rev [simp]: "length (rev xs) = length xs"
   257 by (induct xs) auto
   258 
   259 lemma length_tl [simp]: "length (tl xs) = length xs - 1"
   260 by (cases xs) auto
   261 
   262 lemma length_0_conv [iff]: "(length xs = 0) = (xs = [])"
   263 by (induct xs) auto
   264 
   265 lemma length_greater_0_conv [iff]: "(0 < length xs) = (xs \<noteq> [])"
   266 by (induct xs) auto
   267 
   268 lemma length_Suc_conv:
   269 "(length xs = Suc n) = (\<exists>y ys. xs = y # ys \<and> length ys = n)"
   270 by (induct xs) auto
   271 
   272 
   273 subsection {* @{text "@"} -- append *}
   274 
   275 lemma append_assoc [simp]: "(xs @ ys) @ zs = xs @ (ys @ zs)"
   276 by (induct xs) auto
   277 
   278 lemma append_Nil2 [simp]: "xs @ [] = xs"
   279 by (induct xs) auto
   280 
   281 lemma append_is_Nil_conv [iff]: "(xs @ ys = []) = (xs = [] \<and> ys = [])"
   282 by (induct xs) auto
   283 
   284 lemma Nil_is_append_conv [iff]: "([] = xs @ ys) = (xs = [] \<and> ys = [])"
   285 by (induct xs) auto
   286 
   287 lemma append_self_conv [iff]: "(xs @ ys = xs) = (ys = [])"
   288 by (induct xs) auto
   289 
   290 lemma self_append_conv [iff]: "(xs = xs @ ys) = (ys = [])"
   291 by (induct xs) auto
   292 
   293 lemma append_eq_append_conv [simp]:
   294  "!!ys. length xs = length ys \<or> length us = length vs
   295  ==> (xs@us = ys@vs) = (xs=ys \<and> us=vs)"
   296 apply (induct xs)
   297  apply (case_tac ys)
   298 apply simp
   299  apply force
   300 apply (case_tac ys)
   301  apply force
   302 apply simp
   303 done
   304 
   305 lemma same_append_eq [iff]: "(xs @ ys = xs @ zs) = (ys = zs)"
   306 by simp
   307 
   308 lemma append1_eq_conv [iff]: "(xs @ [x] = ys @ [y]) = (xs = ys \<and> x = y)"
   309 by simp
   310 
   311 lemma append_same_eq [iff]: "(ys @ xs = zs @ xs) = (ys = zs)"
   312 by simp
   313 
   314 lemma append_self_conv2 [iff]: "(xs @ ys = ys) = (xs = [])"
   315 using append_same_eq [of _ _ "[]"] by auto
   316 
   317 lemma self_append_conv2 [iff]: "(ys = xs @ ys) = (xs = [])"
   318 using append_same_eq [of "[]"] by auto
   319 
   320 lemma hd_Cons_tl [simp]: "xs \<noteq> [] ==> hd xs # tl xs = xs"
   321 by (induct xs) auto
   322 
   323 lemma hd_append: "hd (xs @ ys) = (if xs = [] then hd ys else hd xs)"
   324 by (induct xs) auto
   325 
   326 lemma hd_append2 [simp]: "xs \<noteq> [] ==> hd (xs @ ys) = hd xs"
   327 by (simp add: hd_append split: list.split)
   328 
   329 lemma tl_append: "tl (xs @ ys) = (case xs of [] => tl ys | z#zs => zs @ ys)"
   330 by (simp split: list.split)
   331 
   332 lemma tl_append2 [simp]: "xs \<noteq> [] ==> tl (xs @ ys) = tl xs @ ys"
   333 by (simp add: tl_append split: list.split)
   334 
   335 
   336 text {* Trivial rules for solving @{text "@"}-equations automatically. *}
   337 
   338 lemma eq_Nil_appendI: "xs = ys ==> xs = [] @ ys"
   339 by simp
   340 
   341 lemma Cons_eq_appendI:
   342 "[| x # xs1 = ys; xs = xs1 @ zs |] ==> x # xs = ys @ zs"
   343 by (drule sym) simp
   344 
   345 lemma append_eq_appendI:
   346 "[| xs @ xs1 = zs; ys = xs1 @ us |] ==> xs @ ys = zs @ us"
   347 by (drule sym) simp
   348 
   349 
   350 text {*
   351 Simplification procedure for all list equalities.
   352 Currently only tries to rearrange @{text "@"} to see if
   353 - both lists end in a singleton list,
   354 - or both lists end in the same list.
   355 *}
   356 
   357 ML_setup {*
   358 local
   359 
   360 val append_assoc = thm "append_assoc";
   361 val append_Nil = thm "append_Nil";
   362 val append_Cons = thm "append_Cons";
   363 val append1_eq_conv = thm "append1_eq_conv";
   364 val append_same_eq = thm "append_same_eq";
   365 
   366 fun last (cons as Const("List.list.Cons",_) $ _ $ xs) =
   367   (case xs of Const("List.list.Nil",_) => cons | _ => last xs)
   368   | last (Const("List.op @",_) $ _ $ ys) = last ys
   369   | last t = t;
   370 
   371 fun list1 (Const("List.list.Cons",_) $ _ $ Const("List.list.Nil",_)) = true
   372   | list1 _ = false;
   373 
   374 fun butlast ((cons as Const("List.list.Cons",_) $ x) $ xs) =
   375   (case xs of Const("List.list.Nil",_) => xs | _ => cons $ butlast xs)
   376   | butlast ((app as Const("List.op @",_) $ xs) $ ys) = app $ butlast ys
   377   | butlast xs = Const("List.list.Nil",fastype_of xs);
   378 
   379 val rearr_tac =
   380   simp_tac (HOL_basic_ss addsimps [append_assoc, append_Nil, append_Cons]);
   381 
   382 fun list_eq sg _ (F as (eq as Const(_,eqT)) $ lhs $ rhs) =
   383   let
   384     val lastl = last lhs and lastr = last rhs;
   385     fun rearr conv =
   386       let
   387         val lhs1 = butlast lhs and rhs1 = butlast rhs;
   388         val Type(_,listT::_) = eqT
   389         val appT = [listT,listT] ---> listT
   390         val app = Const("List.op @",appT)
   391         val F2 = eq $ (app$lhs1$lastl) $ (app$rhs1$lastr)
   392         val eq = HOLogic.mk_Trueprop (HOLogic.mk_eq (F,F2));
   393         val thm = Tactic.prove sg [] [] eq (K (rearr_tac 1));
   394       in Some ((conv RS (thm RS trans)) RS eq_reflection) end;
   395 
   396   in
   397     if list1 lastl andalso list1 lastr then rearr append1_eq_conv
   398     else if lastl aconv lastr then rearr append_same_eq
   399     else None
   400   end;
   401 
   402 in
   403 
   404 val list_eq_simproc =
   405   Simplifier.simproc (Theory.sign_of (the_context ())) "list_eq" ["(xs::'a list) = ys"] list_eq;
   406 
   407 end;
   408 
   409 Addsimprocs [list_eq_simproc];
   410 *}
   411 
   412 
   413 subsection {* @{text map} *}
   414 
   415 lemma map_ext: "(!!x. x : set xs --> f x = g x) ==> map f xs = map g xs"
   416 by (induct xs) simp_all
   417 
   418 lemma map_ident [simp]: "map (\<lambda>x. x) = (\<lambda>xs. xs)"
   419 by (rule ext, induct_tac xs) auto
   420 
   421 lemma map_append [simp]: "map f (xs @ ys) = map f xs @ map f ys"
   422 by (induct xs) auto
   423 
   424 lemma map_compose: "map (f o g) xs = map f (map g xs)"
   425 by (induct xs) (auto simp add: o_def)
   426 
   427 lemma rev_map: "rev (map f xs) = map f (rev xs)"
   428 by (induct xs) auto
   429 
   430 lemma map_eq_conv[simp]: "(map f xs = map g xs) = (!x : set xs. f x = g x)"
   431 by (induct xs) auto
   432 
   433 lemma map_cong [recdef_cong]:
   434 "xs = ys ==> (!!x. x : set ys ==> f x = g x) ==> map f xs = map g ys"
   435 -- {* a congruence rule for @{text map} *}
   436 by simp
   437 
   438 lemma map_is_Nil_conv [iff]: "(map f xs = []) = (xs = [])"
   439 by (cases xs) auto
   440 
   441 lemma Nil_is_map_conv [iff]: "([] = map f xs) = (xs = [])"
   442 by (cases xs) auto
   443 
   444 lemma map_eq_Cons:
   445 "(map f xs = y # ys) = (\<exists>x xs'. xs = x # xs' \<and> f x = y \<and> map f xs' = ys)"
   446 by (cases xs) auto
   447 
   448 lemma map_injective:
   449 "!!xs. map f xs = map f ys ==> (\<forall>x y. f x = f y --> x = y) ==> xs = ys"
   450 by (induct ys) (auto simp add: map_eq_Cons)
   451 
   452 lemma inj_mapI: "inj f ==> inj (map f)"
   453 by (rules dest: map_injective injD intro: inj_onI)
   454 
   455 lemma inj_mapD: "inj (map f) ==> inj f"
   456 apply (unfold inj_on_def)
   457 apply clarify
   458 apply (erule_tac x = "[x]" in ballE)
   459  apply (erule_tac x = "[y]" in ballE)
   460 apply simp
   461  apply blast
   462 apply blast
   463 done
   464 
   465 lemma inj_map: "inj (map f) = inj f"
   466 by (blast dest: inj_mapD intro: inj_mapI)
   467 
   468 
   469 subsection {* @{text rev} *}
   470 
   471 lemma rev_append [simp]: "rev (xs @ ys) = rev ys @ rev xs"
   472 by (induct xs) auto
   473 
   474 lemma rev_rev_ident [simp]: "rev (rev xs) = xs"
   475 by (induct xs) auto
   476 
   477 lemma rev_is_Nil_conv [iff]: "(rev xs = []) = (xs = [])"
   478 by (induct xs) auto
   479 
   480 lemma Nil_is_rev_conv [iff]: "([] = rev xs) = (xs = [])"
   481 by (induct xs) auto
   482 
   483 lemma rev_is_rev_conv [iff]: "!!ys. (rev xs = rev ys) = (xs = ys)"
   484 apply (induct xs)
   485  apply force
   486 apply (case_tac ys)
   487  apply simp
   488 apply force
   489 done
   490 
   491 lemma rev_induct [case_names Nil snoc]:
   492   "[| P []; !!x xs. P xs ==> P (xs @ [x]) |] ==> P xs"
   493 apply(subst rev_rev_ident[symmetric])
   494 apply(rule_tac list = "rev xs" in list.induct, simp_all)
   495 done
   496 
   497 ML {* val rev_induct_tac = induct_thm_tac (thm "rev_induct") *}-- "compatibility"
   498 
   499 lemma rev_exhaust [case_names Nil snoc]:
   500   "(xs = [] ==> P) ==>(!!ys y. xs = ys @ [y] ==> P) ==> P"
   501 by (induct xs rule: rev_induct) auto
   502 
   503 lemmas rev_cases = rev_exhaust
   504 
   505 
   506 subsection {* @{text set} *}
   507 
   508 lemma finite_set [iff]: "finite (set xs)"
   509 by (induct xs) auto
   510 
   511 lemma set_append [simp]: "set (xs @ ys) = (set xs \<union> set ys)"
   512 by (induct xs) auto
   513 
   514 lemma set_subset_Cons: "set xs \<subseteq> set (x # xs)"
   515 by auto
   516 
   517 lemma set_empty [iff]: "(set xs = {}) = (xs = [])"
   518 by (induct xs) auto
   519 
   520 lemma set_rev [simp]: "set (rev xs) = set xs"
   521 by (induct xs) auto
   522 
   523 lemma set_map [simp]: "set (map f xs) = f`(set xs)"
   524 by (induct xs) auto
   525 
   526 lemma set_filter [simp]: "set (filter P xs) = {x. x : set xs \<and> P x}"
   527 by (induct xs) auto
   528 
   529 lemma set_upt [simp]: "set[i..j(] = {k. i \<le> k \<and> k < j}"
   530 apply (induct j)
   531  apply simp_all
   532 apply(erule ssubst)
   533 apply auto
   534 done
   535 
   536 lemma in_set_conv_decomp: "(x : set xs) = (\<exists>ys zs. xs = ys @ x # zs)"
   537 apply (induct xs)
   538  apply simp
   539 apply simp
   540 apply (rule iffI)
   541  apply (blast intro: eq_Nil_appendI Cons_eq_appendI)
   542 apply (erule exE)+
   543 apply (case_tac ys)
   544 apply auto
   545 done
   546 
   547 lemma in_lists_conv_set: "(xs : lists A) = (\<forall>x \<in> set xs. x : A)"
   548 -- {* eliminate @{text lists} in favour of @{text set} *}
   549 by (induct xs) auto
   550 
   551 lemma in_listsD [dest!]: "xs \<in> lists A ==> \<forall>x\<in>set xs. x \<in> A"
   552 by (rule in_lists_conv_set [THEN iffD1])
   553 
   554 lemma in_listsI [intro!]: "\<forall>x\<in>set xs. x \<in> A ==> xs \<in> lists A"
   555 by (rule in_lists_conv_set [THEN iffD2])
   556 
   557 lemma finite_list: "finite A ==> EX l. set l = A"
   558 apply (erule finite_induct, auto)
   559 apply (rule_tac x="x#l" in exI, auto)
   560 done
   561 
   562 
   563 subsection {* @{text mem} *}
   564 
   565 lemma set_mem_eq: "(x mem xs) = (x : set xs)"
   566 by (induct xs) auto
   567 
   568 
   569 subsection {* @{text list_all} *}
   570 
   571 lemma list_all_conv: "list_all P xs = (\<forall>x \<in> set xs. P x)"
   572 by (induct xs) auto
   573 
   574 lemma list_all_append [simp]:
   575 "list_all P (xs @ ys) = (list_all P xs \<and> list_all P ys)"
   576 by (induct xs) auto
   577 
   578 
   579 subsection {* @{text filter} *}
   580 
   581 lemma filter_append [simp]: "filter P (xs @ ys) = filter P xs @ filter P ys"
   582 by (induct xs) auto
   583 
   584 lemma filter_filter [simp]: "filter P (filter Q xs) = filter (\<lambda>x. Q x \<and> P x) xs"
   585 by (induct xs) auto
   586 
   587 lemma filter_True [simp]: "\<forall>x \<in> set xs. P x ==> filter P xs = xs"
   588 by (induct xs) auto
   589 
   590 lemma filter_False [simp]: "\<forall>x \<in> set xs. \<not> P x ==> filter P xs = []"
   591 by (induct xs) auto
   592 
   593 lemma length_filter [simp]: "length (filter P xs) \<le> length xs"
   594 by (induct xs) (auto simp add: le_SucI)
   595 
   596 lemma filter_is_subset [simp]: "set (filter P xs) \<le> set xs"
   597 by auto
   598 
   599 
   600 subsection {* @{text concat} *}
   601 
   602 lemma concat_append [simp]: "concat (xs @ ys) = concat xs @ concat ys"
   603 by (induct xs) auto
   604 
   605 lemma concat_eq_Nil_conv [iff]: "(concat xss = []) = (\<forall>xs \<in> set xss. xs = [])"
   606 by (induct xss) auto
   607 
   608 lemma Nil_eq_concat_conv [iff]: "([] = concat xss) = (\<forall>xs \<in> set xss. xs = [])"
   609 by (induct xss) auto
   610 
   611 lemma set_concat [simp]: "set (concat xs) = \<Union>(set ` set xs)"
   612 by (induct xs) auto
   613 
   614 lemma map_concat: "map f (concat xs) = concat (map (map f) xs)"
   615 by (induct xs) auto
   616 
   617 lemma filter_concat: "filter p (concat xs) = concat (map (filter p) xs)"
   618 by (induct xs) auto
   619 
   620 lemma rev_concat: "rev (concat xs) = concat (map rev (rev xs))"
   621 by (induct xs) auto
   622 
   623 
   624 subsection {* @{text nth} *}
   625 
   626 lemma nth_Cons_0 [simp]: "(x # xs)!0 = x"
   627 by auto
   628 
   629 lemma nth_Cons_Suc [simp]: "(x # xs)!(Suc n) = xs!n"
   630 by auto
   631 
   632 declare nth.simps [simp del]
   633 
   634 lemma nth_append:
   635 "!!n. (xs @ ys)!n = (if n < length xs then xs!n else ys!(n - length xs))"
   636 apply(induct "xs")
   637  apply simp
   638 apply (case_tac n)
   639  apply auto
   640 done
   641 
   642 lemma nth_map [simp]: "!!n. n < length xs ==> (map f xs)!n = f(xs!n)"
   643 apply(induct xs)
   644  apply simp
   645 apply (case_tac n)
   646  apply auto
   647 done
   648 
   649 lemma set_conv_nth: "set xs = {xs!i | i. i < length xs}"
   650 apply (induct_tac xs)
   651  apply simp
   652 apply simp
   653 apply safe
   654 apply (rule_tac x = 0 in exI)
   655 apply simp
   656  apply (rule_tac x = "Suc i" in exI)
   657  apply simp
   658 apply (case_tac i)
   659  apply simp
   660 apply (rename_tac j)
   661 apply (rule_tac x = j in exI)
   662 apply simp
   663 done
   664 
   665 lemma list_ball_nth: "[| n < length xs; !x : set xs. P x|] ==> P(xs!n)"
   666 by (auto simp add: set_conv_nth)
   667 
   668 lemma nth_mem [simp]: "n < length xs ==> xs!n : set xs"
   669 by (auto simp add: set_conv_nth)
   670 
   671 lemma all_nth_imp_all_set:
   672 "[| !i < length xs. P(xs!i); x : set xs|] ==> P x"
   673 by (auto simp add: set_conv_nth)
   674 
   675 lemma all_set_conv_all_nth:
   676 "(\<forall>x \<in> set xs. P x) = (\<forall>i. i < length xs --> P (xs ! i))"
   677 by (auto simp add: set_conv_nth)
   678 
   679 
   680 subsection {* @{text list_update} *}
   681 
   682 lemma length_list_update [simp]: "!!i. length(xs[i:=x]) = length xs"
   683 by (induct xs) (auto split: nat.split)
   684 
   685 lemma nth_list_update:
   686 "!!i j. i < length xs==> (xs[i:=x])!j = (if i = j then x else xs!j)"
   687 by (induct xs) (auto simp add: nth_Cons split: nat.split)
   688 
   689 lemma nth_list_update_eq [simp]: "i < length xs ==> (xs[i:=x])!i = x"
   690 by (simp add: nth_list_update)
   691 
   692 lemma nth_list_update_neq [simp]: "!!i j. i \<noteq> j ==> xs[i:=x]!j = xs!j"
   693 by (induct xs) (auto simp add: nth_Cons split: nat.split)
   694 
   695 lemma list_update_overwrite [simp]:
   696 "!!i. i < size xs ==> xs[i:=x, i:=y] = xs[i:=y]"
   697 by (induct xs) (auto split: nat.split)
   698 
   699 lemma list_update_same_conv:
   700 "!!i. i < length xs ==> (xs[i := x] = xs) = (xs!i = x)"
   701 by (induct xs) (auto split: nat.split)
   702 
   703 lemma update_zip:
   704 "!!i xy xs. length xs = length ys ==>
   705 (zip xs ys)[i:=xy] = zip (xs[i:=fst xy]) (ys[i:=snd xy])"
   706 by (induct ys) (auto, case_tac xs, auto split: nat.split)
   707 
   708 lemma set_update_subset_insert: "!!i. set(xs[i:=x]) <= insert x (set xs)"
   709 by (induct xs) (auto split: nat.split)
   710 
   711 lemma set_update_subsetI: "[| set xs <= A; x:A |] ==> set(xs[i := x]) <= A"
   712 by (blast dest!: set_update_subset_insert [THEN subsetD])
   713 
   714 
   715 subsection {* @{text last} and @{text butlast} *}
   716 
   717 lemma last_snoc [simp]: "last (xs @ [x]) = x"
   718 by (induct xs) auto
   719 
   720 lemma butlast_snoc [simp]: "butlast (xs @ [x]) = xs"
   721 by (induct xs) auto
   722 
   723 lemma length_butlast [simp]: "length (butlast xs) = length xs - 1"
   724 by (induct xs rule: rev_induct) auto
   725 
   726 lemma butlast_append:
   727 "!!ys. butlast (xs @ ys) = (if ys = [] then butlast xs else xs @ butlast ys)"
   728 by (induct xs) auto
   729 
   730 lemma append_butlast_last_id [simp]:
   731 "xs \<noteq> [] ==> butlast xs @ [last xs] = xs"
   732 by (induct xs) auto
   733 
   734 lemma in_set_butlastD: "x : set (butlast xs) ==> x : set xs"
   735 by (induct xs) (auto split: split_if_asm)
   736 
   737 lemma in_set_butlast_appendI:
   738 "x : set (butlast xs) | x : set (butlast ys) ==> x : set (butlast (xs @ ys))"
   739 by (auto dest: in_set_butlastD simp add: butlast_append)
   740 
   741 
   742 subsection {* @{text take} and @{text drop} *}
   743 
   744 lemma take_0 [simp]: "take 0 xs = []"
   745 by (induct xs) auto
   746 
   747 lemma drop_0 [simp]: "drop 0 xs = xs"
   748 by (induct xs) auto
   749 
   750 lemma take_Suc_Cons [simp]: "take (Suc n) (x # xs) = x # take n xs"
   751 by simp
   752 
   753 lemma drop_Suc_Cons [simp]: "drop (Suc n) (x # xs) = drop n xs"
   754 by simp
   755 
   756 declare take_Cons [simp del] and drop_Cons [simp del]
   757 
   758 lemma take_Suc_conv_app_nth:
   759  "!!i. i < length xs \<Longrightarrow> take (Suc i) xs = take i xs @ [xs!i]"
   760 apply(induct xs)
   761  apply simp
   762 apply(case_tac i)
   763 apply auto
   764 done
   765 
   766 lemma length_take [simp]: "!!xs. length (take n xs) = min (length xs) n"
   767 by (induct n) (auto, case_tac xs, auto)
   768 
   769 lemma length_drop [simp]: "!!xs. length (drop n xs) = (length xs - n)"
   770 by (induct n) (auto, case_tac xs, auto)
   771 
   772 lemma take_all [simp]: "!!xs. length xs <= n ==> take n xs = xs"
   773 by (induct n) (auto, case_tac xs, auto)
   774 
   775 lemma drop_all [simp]: "!!xs. length xs <= n ==> drop n xs = []"
   776 by (induct n) (auto, case_tac xs, auto)
   777 
   778 lemma take_append [simp]:
   779 "!!xs. take n (xs @ ys) = (take n xs @ take (n - length xs) ys)"
   780 by (induct n) (auto, case_tac xs, auto)
   781 
   782 lemma drop_append [simp]:
   783 "!!xs. drop n (xs @ ys) = drop n xs @ drop (n - length xs) ys"
   784 by (induct n) (auto, case_tac xs, auto)
   785 
   786 lemma take_take [simp]: "!!xs n. take n (take m xs) = take (min n m) xs"
   787 apply (induct m)
   788  apply auto
   789 apply (case_tac xs)
   790  apply auto
   791 apply (case_tac na)
   792  apply auto
   793 done
   794 
   795 lemma drop_drop [simp]: "!!xs. drop n (drop m xs) = drop (n + m) xs"
   796 apply (induct m)
   797  apply auto
   798 apply (case_tac xs)
   799  apply auto
   800 done
   801 
   802 lemma take_drop: "!!xs n. take n (drop m xs) = drop m (take (n + m) xs)"
   803 apply (induct m)
   804  apply auto
   805 apply (case_tac xs)
   806  apply auto
   807 done
   808 
   809 lemma append_take_drop_id [simp]: "!!xs. take n xs @ drop n xs = xs"
   810 apply (induct n)
   811  apply auto
   812 apply (case_tac xs)
   813  apply auto
   814 done
   815 
   816 lemma take_map: "!!xs. take n (map f xs) = map f (take n xs)"
   817 apply (induct n)
   818  apply auto
   819 apply (case_tac xs)
   820  apply auto
   821 done
   822 
   823 lemma drop_map: "!!xs. drop n (map f xs) = map f (drop n xs)"
   824 apply (induct n)
   825  apply auto
   826 apply (case_tac xs)
   827  apply auto
   828 done
   829 
   830 lemma rev_take: "!!i. rev (take i xs) = drop (length xs - i) (rev xs)"
   831 apply (induct xs)
   832  apply auto
   833 apply (case_tac i)
   834  apply auto
   835 done
   836 
   837 lemma rev_drop: "!!i. rev (drop i xs) = take (length xs - i) (rev xs)"
   838 apply (induct xs)
   839  apply auto
   840 apply (case_tac i)
   841  apply auto
   842 done
   843 
   844 lemma nth_take [simp]: "!!n i. i < n ==> (take n xs)!i = xs!i"
   845 apply (induct xs)
   846  apply auto
   847 apply (case_tac n)
   848  apply(blast )
   849 apply (case_tac i)
   850  apply auto
   851 done
   852 
   853 lemma nth_drop [simp]:
   854 "!!xs i. n + i <= length xs ==> (drop n xs)!i = xs!(n + i)"
   855 apply (induct n)
   856  apply auto
   857 apply (case_tac xs)
   858  apply auto
   859 done
   860 
   861 lemma append_eq_conv_conj:
   862 "!!zs. (xs @ ys = zs) = (xs = take (length xs) zs \<and> ys = drop (length xs) zs)"
   863 apply(induct xs)
   864  apply simp
   865 apply clarsimp
   866 apply (case_tac zs)
   867 apply auto
   868 done
   869 
   870 
   871 subsection {* @{text takeWhile} and @{text dropWhile} *}
   872 
   873 lemma takeWhile_dropWhile_id [simp]: "takeWhile P xs @ dropWhile P xs = xs"
   874 by (induct xs) auto
   875 
   876 lemma takeWhile_append1 [simp]:
   877 "[| x:set xs; ~P(x)|] ==> takeWhile P (xs @ ys) = takeWhile P xs"
   878 by (induct xs) auto
   879 
   880 lemma takeWhile_append2 [simp]:
   881 "(!!x. x : set xs ==> P x) ==> takeWhile P (xs @ ys) = xs @ takeWhile P ys"
   882 by (induct xs) auto
   883 
   884 lemma takeWhile_tail: "\<not> P x ==> takeWhile P (xs @ (x#l)) = takeWhile P xs"
   885 by (induct xs) auto
   886 
   887 lemma dropWhile_append1 [simp]:
   888 "[| x : set xs; ~P(x)|] ==> dropWhile P (xs @ ys) = (dropWhile P xs)@ys"
   889 by (induct xs) auto
   890 
   891 lemma dropWhile_append2 [simp]:
   892 "(!!x. x:set xs ==> P(x)) ==> dropWhile P (xs @ ys) = dropWhile P ys"
   893 by (induct xs) auto
   894 
   895 lemma set_take_whileD: "x : set (takeWhile P xs) ==> x : set xs \<and> P x"
   896 by (induct xs) (auto split: split_if_asm)
   897 
   898 lemma takeWhile_eq_all_conv[simp]:
   899  "(takeWhile P xs = xs) = (\<forall>x \<in> set xs. P x)"
   900 by(induct xs, auto)
   901 
   902 lemma dropWhile_eq_Nil_conv[simp]:
   903  "(dropWhile P xs = []) = (\<forall>x \<in> set xs. P x)"
   904 by(induct xs, auto)
   905 
   906 lemma dropWhile_eq_Cons_conv:
   907  "(dropWhile P xs = y#ys) = (xs = takeWhile P xs @ y # ys & \<not> P y)"
   908 by(induct xs, auto)
   909 
   910 
   911 subsection {* @{text zip} *}
   912 
   913 lemma zip_Nil [simp]: "zip [] ys = []"
   914 by (induct ys) auto
   915 
   916 lemma zip_Cons_Cons [simp]: "zip (x # xs) (y # ys) = (x, y) # zip xs ys"
   917 by simp
   918 
   919 declare zip_Cons [simp del]
   920 
   921 lemma length_zip [simp]:
   922 "!!xs. length (zip xs ys) = min (length xs) (length ys)"
   923 apply(induct ys)
   924  apply simp
   925 apply (case_tac xs)
   926  apply auto
   927 done
   928 
   929 lemma zip_append1:
   930 "!!xs. zip (xs @ ys) zs =
   931 zip xs (take (length xs) zs) @ zip ys (drop (length xs) zs)"
   932 apply (induct zs)
   933  apply simp
   934 apply (case_tac xs)
   935  apply simp_all
   936 done
   937 
   938 lemma zip_append2:
   939 "!!ys. zip xs (ys @ zs) =
   940 zip (take (length ys) xs) ys @ zip (drop (length ys) xs) zs"
   941 apply (induct xs)
   942  apply simp
   943 apply (case_tac ys)
   944  apply simp_all
   945 done
   946 
   947 lemma zip_append [simp]:
   948  "[| length xs = length us; length ys = length vs |] ==>
   949 zip (xs@ys) (us@vs) = zip xs us @ zip ys vs"
   950 by (simp add: zip_append1)
   951 
   952 lemma zip_rev:
   953 "!!xs. length xs = length ys ==> zip (rev xs) (rev ys) = rev (zip xs ys)"
   954 apply(induct ys)
   955  apply simp
   956 apply (case_tac xs)
   957  apply simp_all
   958 done
   959 
   960 lemma nth_zip [simp]:
   961 "!!i xs. [| i < length xs; i < length ys|] ==> (zip xs ys)!i = (xs!i, ys!i)"
   962 apply (induct ys)
   963  apply simp
   964 apply (case_tac xs)
   965  apply (simp_all add: nth.simps split: nat.split)
   966 done
   967 
   968 lemma set_zip:
   969 "set (zip xs ys) = {(xs!i, ys!i) | i. i < min (length xs) (length ys)}"
   970 by (simp add: set_conv_nth cong: rev_conj_cong)
   971 
   972 lemma zip_update:
   973 "length xs = length ys ==> zip (xs[i:=x]) (ys[i:=y]) = (zip xs ys)[i:=(x,y)]"
   974 by (rule sym, simp add: update_zip)
   975 
   976 lemma zip_replicate [simp]:
   977 "!!j. zip (replicate i x) (replicate j y) = replicate (min i j) (x,y)"
   978 apply (induct i)
   979  apply auto
   980 apply (case_tac j)
   981  apply auto
   982 done
   983 
   984 
   985 subsection {* @{text list_all2} *}
   986 
   987 lemma list_all2_lengthD: "list_all2 P xs ys ==> length xs = length ys"
   988 by (simp add: list_all2_def)
   989 
   990 lemma list_all2_Nil [iff]: "list_all2 P [] ys = (ys = [])"
   991 by (simp add: list_all2_def)
   992 
   993 lemma list_all2_Nil2[iff]: "list_all2 P xs [] = (xs = [])"
   994 by (simp add: list_all2_def)
   995 
   996 lemma list_all2_Cons [iff]:
   997 "list_all2 P (x # xs) (y # ys) = (P x y \<and> list_all2 P xs ys)"
   998 by (auto simp add: list_all2_def)
   999 
  1000 lemma list_all2_Cons1:
  1001 "list_all2 P (x # xs) ys = (\<exists>z zs. ys = z # zs \<and> P x z \<and> list_all2 P xs zs)"
  1002 by (cases ys) auto
  1003 
  1004 lemma list_all2_Cons2:
  1005 "list_all2 P xs (y # ys) = (\<exists>z zs. xs = z # zs \<and> P z y \<and> list_all2 P zs ys)"
  1006 by (cases xs) auto
  1007 
  1008 lemma list_all2_rev [iff]:
  1009 "list_all2 P (rev xs) (rev ys) = list_all2 P xs ys"
  1010 by (simp add: list_all2_def zip_rev cong: conj_cong)
  1011 
  1012 lemma list_all2_rev1:
  1013 "list_all2 P (rev xs) ys = list_all2 P xs (rev ys)"
  1014 by (subst list_all2_rev [symmetric]) simp
  1015 
  1016 lemma list_all2_append1:
  1017 "list_all2 P (xs @ ys) zs =
  1018 (EX us vs. zs = us @ vs \<and> length us = length xs \<and> length vs = length ys \<and>
  1019 list_all2 P xs us \<and> list_all2 P ys vs)"
  1020 apply (simp add: list_all2_def zip_append1)
  1021 apply (rule iffI)
  1022  apply (rule_tac x = "take (length xs) zs" in exI)
  1023  apply (rule_tac x = "drop (length xs) zs" in exI)
  1024  apply (force split: nat_diff_split simp add: min_def)
  1025 apply clarify
  1026 apply (simp add: ball_Un)
  1027 done
  1028 
  1029 lemma list_all2_append2:
  1030 "list_all2 P xs (ys @ zs) =
  1031 (EX us vs. xs = us @ vs \<and> length us = length ys \<and> length vs = length zs \<and>
  1032 list_all2 P us ys \<and> list_all2 P vs zs)"
  1033 apply (simp add: list_all2_def zip_append2)
  1034 apply (rule iffI)
  1035  apply (rule_tac x = "take (length ys) xs" in exI)
  1036  apply (rule_tac x = "drop (length ys) xs" in exI)
  1037  apply (force split: nat_diff_split simp add: min_def)
  1038 apply clarify
  1039 apply (simp add: ball_Un)
  1040 done
  1041 
  1042 lemma list_all2_append:
  1043   "\<And>b. length a = length b \<Longrightarrow>
  1044   list_all2 P (a@c) (b@d) = (list_all2 P a b \<and> list_all2 P c d)"
  1045   apply (induct a)
  1046    apply simp
  1047   apply (case_tac b)
  1048   apply auto
  1049   done
  1050 
  1051 lemma list_all2_appendI [intro?, trans]:
  1052   "\<lbrakk> list_all2 P a b; list_all2 P c d \<rbrakk> \<Longrightarrow> list_all2 P (a@c) (b@d)"
  1053   by (simp add: list_all2_append list_all2_lengthD)
  1054 
  1055 lemma list_all2_conv_all_nth:
  1056 "list_all2 P xs ys =
  1057 (length xs = length ys \<and> (\<forall>i < length xs. P (xs!i) (ys!i)))"
  1058 by (force simp add: list_all2_def set_zip)
  1059 
  1060 lemma list_all2_trans:
  1061   assumes tr: "!!a b c. P1 a b ==> P2 b c ==> P3 a c"
  1062   shows "!!bs cs. list_all2 P1 as bs ==> list_all2 P2 bs cs ==> list_all2 P3 as cs"
  1063         (is "!!bs cs. PROP ?Q as bs cs")
  1064 proof (induct as)
  1065   fix x xs bs assume I1: "!!bs cs. PROP ?Q xs bs cs"
  1066   show "!!cs. PROP ?Q (x # xs) bs cs"
  1067   proof (induct bs)
  1068     fix y ys cs assume I2: "!!cs. PROP ?Q (x # xs) ys cs"
  1069     show "PROP ?Q (x # xs) (y # ys) cs"
  1070       by (induct cs) (auto intro: tr I1 I2)
  1071   qed simp
  1072 qed simp
  1073 
  1074 lemma list_all2_all_nthI [intro?]:
  1075   "length a = length b \<Longrightarrow> (\<And>n. n < length a \<Longrightarrow> P (a!n) (b!n)) \<Longrightarrow> list_all2 P a b"
  1076   by (simp add: list_all2_conv_all_nth)
  1077 
  1078 lemma list_all2_nthD [dest?]:
  1079   "\<lbrakk> list_all2 P xs ys; p < size xs \<rbrakk> \<Longrightarrow> P (xs!p) (ys!p)"
  1080   by (simp add: list_all2_conv_all_nth)
  1081 
  1082 lemma list_all2_map1: 
  1083   "list_all2 P (map f as) bs = list_all2 (\<lambda>x y. P (f x) y) as bs"
  1084   by (simp add: list_all2_conv_all_nth)
  1085 
  1086 lemma list_all2_map2: 
  1087   "list_all2 P as (map f bs) = list_all2 (\<lambda>x y. P x (f y)) as bs"
  1088   by (auto simp add: list_all2_conv_all_nth)
  1089 
  1090 lemma list_all2_refl:
  1091   "(\<And>x. P x x) \<Longrightarrow> list_all2 P xs xs"
  1092   by (simp add: list_all2_conv_all_nth)
  1093 
  1094 lemma list_all2_update_cong:
  1095   "\<lbrakk> i<size xs; list_all2 P xs ys; P x y \<rbrakk> \<Longrightarrow> list_all2 P (xs[i:=x]) (ys[i:=y])"
  1096   by (simp add: list_all2_conv_all_nth nth_list_update)
  1097 
  1098 lemma list_all2_update_cong2:
  1099   "\<lbrakk>list_all2 P xs ys; P x y; i < length ys\<rbrakk> \<Longrightarrow> list_all2 P (xs[i:=x]) (ys[i:=y])"
  1100   by (simp add: list_all2_lengthD list_all2_update_cong)
  1101 
  1102 lemma list_all2_dropI [intro?]:
  1103   "\<And>n bs. list_all2 P as bs \<Longrightarrow> list_all2 P (drop n as) (drop n bs)"
  1104   apply (induct as)
  1105    apply simp
  1106   apply (clarsimp simp add: list_all2_Cons1)
  1107   apply (case_tac n)
  1108    apply simp
  1109   apply simp
  1110   done
  1111 
  1112 lemma list_all2_mono [intro?]:
  1113   "\<And>y. list_all2 P x y \<Longrightarrow> (\<And>x y. P x y \<Longrightarrow> Q x y) \<Longrightarrow> list_all2 Q x y"
  1114   apply (induct x)
  1115    apply simp
  1116   apply (case_tac y)
  1117   apply auto
  1118   done
  1119 
  1120 
  1121 subsection {* @{text foldl} *}
  1122 
  1123 lemma foldl_append [simp]:
  1124 "!!a. foldl f a (xs @ ys) = foldl f (foldl f a xs) ys"
  1125 by (induct xs) auto
  1126 
  1127 text {*
  1128 Note: @{text "n \<le> foldl (op +) n ns"} looks simpler, but is more
  1129 difficult to use because it requires an additional transitivity step.
  1130 *}
  1131 
  1132 lemma start_le_sum: "!!n::nat. m <= n ==> m <= foldl (op +) n ns"
  1133 by (induct ns) auto
  1134 
  1135 lemma elem_le_sum: "!!n::nat. n : set ns ==> n <= foldl (op +) 0 ns"
  1136 by (force intro: start_le_sum simp add: in_set_conv_decomp)
  1137 
  1138 lemma sum_eq_0_conv [iff]:
  1139 "!!m::nat. (foldl (op +) m ns = 0) = (m = 0 \<and> (\<forall>n \<in> set ns. n = 0))"
  1140 by (induct ns) auto
  1141 
  1142 
  1143 subsection {* @{text upto} *}
  1144 
  1145 lemma upt_rec: "[i..j(] = (if i<j then i#[Suc i..j(] else [])"
  1146 -- {* Does not terminate! *}
  1147 by (induct j) auto
  1148 
  1149 lemma upt_conv_Nil [simp]: "j <= i ==> [i..j(] = []"
  1150 by (subst upt_rec) simp
  1151 
  1152 lemma upt_Suc_append: "i <= j ==> [i..(Suc j)(] = [i..j(]@[j]"
  1153 -- {* Only needed if @{text upt_Suc} is deleted from the simpset. *}
  1154 by simp
  1155 
  1156 lemma upt_conv_Cons: "i < j ==> [i..j(] = i # [Suc i..j(]"
  1157 apply(rule trans)
  1158 apply(subst upt_rec)
  1159  prefer 2 apply(rule refl)
  1160 apply simp
  1161 done
  1162 
  1163 lemma upt_add_eq_append: "i<=j ==> [i..j+k(] = [i..j(]@[j..j+k(]"
  1164 -- {* LOOPS as a simprule, since @{text "j <= j"}. *}
  1165 by (induct k) auto
  1166 
  1167 lemma length_upt [simp]: "length [i..j(] = j - i"
  1168 by (induct j) (auto simp add: Suc_diff_le)
  1169 
  1170 lemma nth_upt [simp]: "i + k < j ==> [i..j(] ! k = i + k"
  1171 apply (induct j)
  1172 apply (auto simp add: less_Suc_eq nth_append split: nat_diff_split)
  1173 done
  1174 
  1175 lemma take_upt [simp]: "!!i. i+m <= n ==> take m [i..n(] = [i..i+m(]"
  1176 apply (induct m)
  1177  apply simp
  1178 apply (subst upt_rec)
  1179 apply (rule sym)
  1180 apply (subst upt_rec)
  1181 apply (simp del: upt.simps)
  1182 done
  1183 
  1184 lemma map_Suc_upt: "map Suc [m..n(] = [Suc m..n]"
  1185 by (induct n) auto
  1186 
  1187 lemma nth_map_upt: "!!i. i < n-m ==> (map f [m..n(]) ! i = f(m+i)"
  1188 apply (induct n m rule: diff_induct)
  1189 prefer 3 apply (subst map_Suc_upt[symmetric])
  1190 apply (auto simp add: less_diff_conv nth_upt)
  1191 done
  1192 
  1193 lemma nth_take_lemma:
  1194   "!!xs ys. k <= length xs ==> k <= length ys ==>
  1195      (!!i. i < k --> xs!i = ys!i) ==> take k xs = take k ys"
  1196 apply (atomize, induct k)
  1197 apply (simp_all add: less_Suc_eq_0_disj all_conj_distrib)
  1198 apply clarify
  1199 txt {* Both lists must be non-empty *}
  1200 apply (case_tac xs)
  1201  apply simp
  1202 apply (case_tac ys)
  1203  apply clarify
  1204  apply (simp (no_asm_use))
  1205 apply clarify
  1206 txt {* prenexing's needed, not miniscoping *}
  1207 apply (simp (no_asm_use) add: all_simps [symmetric] del: all_simps)
  1208 apply blast
  1209 done
  1210 
  1211 lemma nth_equalityI:
  1212  "[| length xs = length ys; ALL i < length xs. xs!i = ys!i |] ==> xs = ys"
  1213 apply (frule nth_take_lemma [OF le_refl eq_imp_le])
  1214 apply (simp_all add: take_all)
  1215 done
  1216 
  1217 (* needs nth_equalityI *)
  1218 lemma list_all2_antisym:
  1219   "\<lbrakk> (\<And>x y. \<lbrakk>P x y; Q y x\<rbrakk> \<Longrightarrow> x = y); list_all2 P xs ys; list_all2 Q ys xs \<rbrakk> 
  1220   \<Longrightarrow> xs = ys"
  1221   apply (simp add: list_all2_conv_all_nth) 
  1222   apply (rule nth_equalityI)
  1223    apply blast
  1224   apply simp
  1225   done
  1226 
  1227 lemma take_equalityI: "(\<forall>i. take i xs = take i ys) ==> xs = ys"
  1228 -- {* The famous take-lemma. *}
  1229 apply (drule_tac x = "max (length xs) (length ys)" in spec)
  1230 apply (simp add: le_max_iff_disj take_all)
  1231 done
  1232 
  1233 
  1234 subsection {* @{text "distinct"} and @{text remdups} *}
  1235 
  1236 lemma distinct_append [simp]:
  1237 "distinct (xs @ ys) = (distinct xs \<and> distinct ys \<and> set xs \<inter> set ys = {})"
  1238 by (induct xs) auto
  1239 
  1240 lemma set_remdups [simp]: "set (remdups xs) = set xs"
  1241 by (induct xs) (auto simp add: insert_absorb)
  1242 
  1243 lemma distinct_remdups [iff]: "distinct (remdups xs)"
  1244 by (induct xs) auto
  1245 
  1246 lemma distinct_filter [simp]: "distinct xs ==> distinct (filter P xs)"
  1247 by (induct xs) auto
  1248 
  1249 text {*
  1250 It is best to avoid this indexed version of distinct, but sometimes
  1251 it is useful. *}
  1252 lemma distinct_conv_nth:
  1253 "distinct xs = (\<forall>i j. i < size xs \<and> j < size xs \<and> i \<noteq> j --> xs!i \<noteq> xs!j)"
  1254 apply (induct_tac xs)
  1255  apply simp
  1256 apply simp
  1257 apply (rule iffI)
  1258  apply clarsimp
  1259  apply (case_tac i)
  1260 apply (case_tac j)
  1261  apply simp
  1262 apply (simp add: set_conv_nth)
  1263  apply (case_tac j)
  1264 apply (clarsimp simp add: set_conv_nth)
  1265  apply simp
  1266 apply (rule conjI)
  1267  apply (clarsimp simp add: set_conv_nth)
  1268  apply (erule_tac x = 0 in allE)
  1269  apply (erule_tac x = "Suc i" in allE)
  1270  apply simp
  1271 apply clarsimp
  1272 apply (erule_tac x = "Suc i" in allE)
  1273 apply (erule_tac x = "Suc j" in allE)
  1274 apply simp
  1275 done
  1276 
  1277 
  1278 subsection {* @{text replicate} *}
  1279 
  1280 lemma length_replicate [simp]: "length (replicate n x) = n"
  1281 by (induct n) auto
  1282 
  1283 lemma map_replicate [simp]: "map f (replicate n x) = replicate n (f x)"
  1284 by (induct n) auto
  1285 
  1286 lemma replicate_app_Cons_same:
  1287 "(replicate n x) @ (x # xs) = x # replicate n x @ xs"
  1288 by (induct n) auto
  1289 
  1290 lemma rev_replicate [simp]: "rev (replicate n x) = replicate n x"
  1291 apply(induct n)
  1292  apply simp
  1293 apply (simp add: replicate_app_Cons_same)
  1294 done
  1295 
  1296 lemma replicate_add: "replicate (n + m) x = replicate n x @ replicate m x"
  1297 by (induct n) auto
  1298 
  1299 lemma hd_replicate [simp]: "n \<noteq> 0 ==> hd (replicate n x) = x"
  1300 by (induct n) auto
  1301 
  1302 lemma tl_replicate [simp]: "n \<noteq> 0 ==> tl (replicate n x) = replicate (n - 1) x"
  1303 by (induct n) auto
  1304 
  1305 lemma last_replicate [simp]: "n \<noteq> 0 ==> last (replicate n x) = x"
  1306 by (atomize (full), induct n) auto
  1307 
  1308 lemma nth_replicate[simp]: "!!i. i < n ==> (replicate n x)!i = x"
  1309 apply(induct n)
  1310  apply simp
  1311 apply (simp add: nth_Cons split: nat.split)
  1312 done
  1313 
  1314 lemma set_replicate_Suc: "set (replicate (Suc n) x) = {x}"
  1315 by (induct n) auto
  1316 
  1317 lemma set_replicate [simp]: "n \<noteq> 0 ==> set (replicate n x) = {x}"
  1318 by (fast dest!: not0_implies_Suc intro!: set_replicate_Suc)
  1319 
  1320 lemma set_replicate_conv_if: "set (replicate n x) = (if n = 0 then {} else {x})"
  1321 by auto
  1322 
  1323 lemma in_set_replicateD: "x : set (replicate n y) ==> x = y"
  1324 by (simp add: set_replicate_conv_if split: split_if_asm)
  1325 
  1326 
  1327 subsection {* Lexcicographic orderings on lists *}
  1328 
  1329 lemma wf_lexn: "wf r ==> wf (lexn r n)"
  1330 apply (induct_tac n)
  1331  apply simp
  1332 apply simp
  1333 apply(rule wf_subset)
  1334  prefer 2 apply (rule Int_lower1)
  1335 apply(rule wf_prod_fun_image)
  1336  prefer 2 apply (rule inj_onI)
  1337 apply auto
  1338 done
  1339 
  1340 lemma lexn_length:
  1341 "!!xs ys. (xs, ys) : lexn r n ==> length xs = n \<and> length ys = n"
  1342 by (induct n) auto
  1343 
  1344 lemma wf_lex [intro!]: "wf r ==> wf (lex r)"
  1345 apply (unfold lex_def)
  1346 apply (rule wf_UN)
  1347 apply (blast intro: wf_lexn)
  1348 apply clarify
  1349 apply (rename_tac m n)
  1350 apply (subgoal_tac "m \<noteq> n")
  1351  prefer 2 apply blast
  1352 apply (blast dest: lexn_length not_sym)
  1353 done
  1354 
  1355 lemma lexn_conv:
  1356 "lexn r n =
  1357 {(xs,ys). length xs = n \<and> length ys = n \<and>
  1358 (\<exists>xys x y xs' ys'. xs= xys @ x#xs' \<and> ys= xys @ y # ys' \<and> (x, y):r)}"
  1359 apply (induct_tac n)
  1360  apply simp
  1361  apply blast
  1362 apply (simp add: image_Collect lex_prod_def)
  1363 apply safe
  1364 apply blast
  1365  apply (rule_tac x = "ab # xys" in exI)
  1366  apply simp
  1367 apply (case_tac xys)
  1368  apply simp_all
  1369 apply blast
  1370 done
  1371 
  1372 lemma lex_conv:
  1373 "lex r =
  1374 {(xs,ys). length xs = length ys \<and>
  1375 (\<exists>xys x y xs' ys'. xs = xys @ x # xs' \<and> ys = xys @ y # ys' \<and> (x, y):r)}"
  1376 by (force simp add: lex_def lexn_conv)
  1377 
  1378 lemma wf_lexico [intro!]: "wf r ==> wf (lexico r)"
  1379 by (unfold lexico_def) blast
  1380 
  1381 lemma lexico_conv:
  1382 "lexico r = {(xs,ys). length xs < length ys |
  1383 length xs = length ys \<and> (xs, ys) : lex r}"
  1384 by (simp add: lexico_def diag_def lex_prod_def measure_def inv_image_def)
  1385 
  1386 lemma Nil_notin_lex [iff]: "([], ys) \<notin> lex r"
  1387 by (simp add: lex_conv)
  1388 
  1389 lemma Nil2_notin_lex [iff]: "(xs, []) \<notin> lex r"
  1390 by (simp add:lex_conv)
  1391 
  1392 lemma Cons_in_lex [iff]:
  1393 "((x # xs, y # ys) : lex r) =
  1394 ((x, y) : r \<and> length xs = length ys | x = y \<and> (xs, ys) : lex r)"
  1395 apply (simp add: lex_conv)
  1396 apply (rule iffI)
  1397  prefer 2 apply (blast intro: Cons_eq_appendI)
  1398 apply clarify
  1399 apply (case_tac xys)
  1400  apply simp
  1401 apply simp
  1402 apply blast
  1403 done
  1404 
  1405 
  1406 subsection {* @{text sublist} --- a generalization of @{text nth} to sets *}
  1407 
  1408 lemma sublist_empty [simp]: "sublist xs {} = []"
  1409 by (auto simp add: sublist_def)
  1410 
  1411 lemma sublist_nil [simp]: "sublist [] A = []"
  1412 by (auto simp add: sublist_def)
  1413 
  1414 lemma sublist_shift_lemma:
  1415 "map fst [p:zip xs [i..i + length xs(] . snd p : A] =
  1416 map fst [p:zip xs [0..length xs(] . snd p + i : A]"
  1417 by (induct xs rule: rev_induct) (simp_all add: add_commute)
  1418 
  1419 lemma sublist_append:
  1420 "sublist (l @ l') A = sublist l A @ sublist l' {j. j + length l : A}"
  1421 apply (unfold sublist_def)
  1422 apply (induct l' rule: rev_induct)
  1423  apply simp
  1424 apply (simp add: upt_add_eq_append[of 0] zip_append sublist_shift_lemma)
  1425 apply (simp add: add_commute)
  1426 done
  1427 
  1428 lemma sublist_Cons:
  1429 "sublist (x # l) A = (if 0:A then [x] else []) @ sublist l {j. Suc j : A}"
  1430 apply (induct l rule: rev_induct)
  1431  apply (simp add: sublist_def)
  1432 apply (simp del: append_Cons add: append_Cons[symmetric] sublist_append)
  1433 done
  1434 
  1435 lemma sublist_singleton [simp]: "sublist [x] A = (if 0 : A then [x] else [])"
  1436 by (simp add: sublist_Cons)
  1437 
  1438 lemma sublist_upt_eq_take [simp]: "sublist l {..n(} = take n l"
  1439 apply (induct l rule: rev_induct)
  1440  apply simp
  1441 apply (simp split: nat_diff_split add: sublist_append)
  1442 done
  1443 
  1444 
  1445 lemma take_Cons':
  1446 "take n (x # xs) = (if n = 0 then [] else x # take (n - 1) xs)"
  1447 by (cases n) simp_all
  1448 
  1449 lemma drop_Cons':
  1450 "drop n (x # xs) = (if n = 0 then x # xs else drop (n - 1) xs)"
  1451 by (cases n) simp_all
  1452 
  1453 lemma nth_Cons': "(x # xs)!n = (if n = 0 then x else xs!(n - 1))"
  1454 by (cases n) simp_all
  1455 
  1456 lemmas [simp] = take_Cons'[of "number_of v",standard]
  1457                 drop_Cons'[of "number_of v",standard]
  1458                 nth_Cons'[of _ _ "number_of v",standard]
  1459 
  1460 
  1461 subsection {* Characters and strings *}
  1462 
  1463 datatype nibble =
  1464     Nibble0 | Nibble1 | Nibble2 | Nibble3 | Nibble4 | Nibble5 | Nibble6 | Nibble7
  1465   | Nibble8 | Nibble9 | NibbleA | NibbleB | NibbleC | NibbleD | NibbleE | NibbleF
  1466 
  1467 datatype char = Char nibble nibble
  1468   -- "Note: canonical order of character encoding coincides with standard term ordering"
  1469 
  1470 types string = "char list"
  1471 
  1472 syntax
  1473   "_Char" :: "xstr => char"    ("CHR _")
  1474   "_String" :: "xstr => string"    ("_")
  1475 
  1476 parse_ast_translation {*
  1477   let
  1478     val constants = Syntax.Appl o map Syntax.Constant;
  1479 
  1480     fun mk_nib n = "Nibble" ^ chr (n + (if n <= 9 then ord "0" else ord "A" - 10));
  1481     fun mk_char c =
  1482       if Symbol.is_ascii c andalso Symbol.is_printable c then
  1483         constants ["Char", mk_nib (ord c div 16), mk_nib (ord c mod 16)]
  1484       else error ("Printable ASCII character expected: " ^ quote c);
  1485 
  1486     fun mk_string [] = Syntax.Constant "Nil"
  1487       | mk_string (c :: cs) = Syntax.Appl [Syntax.Constant "Cons", mk_char c, mk_string cs];
  1488 
  1489     fun char_ast_tr [Syntax.Variable xstr] =
  1490         (case Syntax.explode_xstr xstr of
  1491           [c] => mk_char c
  1492         | _ => error ("Single character expected: " ^ xstr))
  1493       | char_ast_tr asts = raise AST ("char_ast_tr", asts);
  1494 
  1495     fun string_ast_tr [Syntax.Variable xstr] =
  1496         (case Syntax.explode_xstr xstr of
  1497           [] => constants [Syntax.constrainC, "Nil", "string"]
  1498         | cs => mk_string cs)
  1499       | string_ast_tr asts = raise AST ("string_tr", asts);
  1500   in [("_Char", char_ast_tr), ("_String", string_ast_tr)] end;
  1501 *}
  1502 
  1503 print_ast_translation {*
  1504   let
  1505     fun dest_nib (Syntax.Constant c) =
  1506         (case explode c of
  1507           ["N", "i", "b", "b", "l", "e", h] =>
  1508             if "0" <= h andalso h <= "9" then ord h - ord "0"
  1509             else if "A" <= h andalso h <= "F" then ord h - ord "A" + 10
  1510             else raise Match
  1511         | _ => raise Match)
  1512       | dest_nib _ = raise Match;
  1513 
  1514     fun dest_chr c1 c2 =
  1515       let val c = chr (dest_nib c1 * 16 + dest_nib c2)
  1516       in if Symbol.is_printable c then c else raise Match end;
  1517 
  1518     fun dest_char (Syntax.Appl [Syntax.Constant "Char", c1, c2]) = dest_chr c1 c2
  1519       | dest_char _ = raise Match;
  1520 
  1521     fun xstr cs = Syntax.Appl [Syntax.Constant "_xstr", Syntax.Variable (Syntax.implode_xstr cs)];
  1522 
  1523     fun char_ast_tr' [c1, c2] = Syntax.Appl [Syntax.Constant "_Char", xstr [dest_chr c1 c2]]
  1524       | char_ast_tr' _ = raise Match;
  1525 
  1526     fun list_ast_tr' [args] = Syntax.Appl [Syntax.Constant "_String",
  1527             xstr (map dest_char (Syntax.unfold_ast "_args" args))]
  1528       | list_ast_tr' ts = raise Match;
  1529   in [("Char", char_ast_tr'), ("@list", list_ast_tr')] end;
  1530 *}
  1531 
  1532 end