src/HOL/Fun.thy
author haftmann
Fri Aug 20 17:46:55 2010 +0200 (2010-08-20)
changeset 38620 b40524b74f77
parent 37767 a2b7a20d6ea3
child 39074 211e4f6aad63
permissions -rw-r--r--
inj_comp and inj_fun
     1 (*  Title:      HOL/Fun.thy
     2     Author:     Tobias Nipkow, Cambridge University Computer Laboratory
     3     Copyright   1994  University of Cambridge
     4 *)
     5 
     6 header {* Notions about functions *}
     7 
     8 theory Fun
     9 imports Complete_Lattice
    10 begin
    11 
    12 text{*As a simplification rule, it replaces all function equalities by
    13   first-order equalities.*}
    14 lemma expand_fun_eq: "f = g \<longleftrightarrow> (\<forall>x. f x = g x)"
    15 apply (rule iffI)
    16 apply (simp (no_asm_simp))
    17 apply (rule ext)
    18 apply (simp (no_asm_simp))
    19 done
    20 
    21 lemma apply_inverse:
    22   "f x = u \<Longrightarrow> (\<And>x. P x \<Longrightarrow> g (f x) = x) \<Longrightarrow> P x \<Longrightarrow> x = g u"
    23   by auto
    24 
    25 
    26 subsection {* The Identity Function @{text id} *}
    27 
    28 definition
    29   id :: "'a \<Rightarrow> 'a"
    30 where
    31   "id = (\<lambda>x. x)"
    32 
    33 lemma id_apply [simp]: "id x = x"
    34   by (simp add: id_def)
    35 
    36 lemma image_ident [simp]: "(%x. x) ` Y = Y"
    37 by blast
    38 
    39 lemma image_id [simp]: "id ` Y = Y"
    40 by (simp add: id_def)
    41 
    42 lemma vimage_ident [simp]: "(%x. x) -` Y = Y"
    43 by blast
    44 
    45 lemma vimage_id [simp]: "id -` A = A"
    46 by (simp add: id_def)
    47 
    48 
    49 subsection {* The Composition Operator @{text "f \<circ> g"} *}
    50 
    51 definition
    52   comp :: "('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "o" 55)
    53 where
    54   "f o g = (\<lambda>x. f (g x))"
    55 
    56 notation (xsymbols)
    57   comp  (infixl "\<circ>" 55)
    58 
    59 notation (HTML output)
    60   comp  (infixl "\<circ>" 55)
    61 
    62 text{*compatibility*}
    63 lemmas o_def = comp_def
    64 
    65 lemma o_apply [simp]: "(f o g) x = f (g x)"
    66 by (simp add: comp_def)
    67 
    68 lemma o_assoc: "f o (g o h) = f o g o h"
    69 by (simp add: comp_def)
    70 
    71 lemma id_o [simp]: "id o g = g"
    72 by (simp add: comp_def)
    73 
    74 lemma o_id [simp]: "f o id = f"
    75 by (simp add: comp_def)
    76 
    77 lemma o_eq_dest:
    78   "a o b = c o d \<Longrightarrow> a (b v) = c (d v)"
    79   by (simp only: o_def) (fact fun_cong)
    80 
    81 lemma o_eq_elim:
    82   "a o b = c o d \<Longrightarrow> ((\<And>v. a (b v) = c (d v)) \<Longrightarrow> R) \<Longrightarrow> R"
    83   by (erule meta_mp) (fact o_eq_dest) 
    84 
    85 lemma image_compose: "(f o g) ` r = f`(g`r)"
    86 by (simp add: comp_def, blast)
    87 
    88 lemma vimage_compose: "(g \<circ> f) -` x = f -` (g -` x)"
    89   by auto
    90 
    91 lemma UN_o: "UNION A (g o f) = UNION (f`A) g"
    92 by (unfold comp_def, blast)
    93 
    94 
    95 subsection {* The Forward Composition Operator @{text fcomp} *}
    96 
    97 definition
    98   fcomp :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "\<circ>>" 60)
    99 where
   100   "f \<circ>> g = (\<lambda>x. g (f x))"
   101 
   102 lemma fcomp_apply [simp]:  "(f \<circ>> g) x = g (f x)"
   103   by (simp add: fcomp_def)
   104 
   105 lemma fcomp_assoc: "(f \<circ>> g) \<circ>> h = f \<circ>> (g \<circ>> h)"
   106   by (simp add: fcomp_def)
   107 
   108 lemma id_fcomp [simp]: "id \<circ>> g = g"
   109   by (simp add: fcomp_def)
   110 
   111 lemma fcomp_id [simp]: "f \<circ>> id = f"
   112   by (simp add: fcomp_def)
   113 
   114 code_const fcomp
   115   (Eval infixl 1 "#>")
   116 
   117 no_notation fcomp (infixl "\<circ>>" 60)
   118 
   119 
   120 subsection {* Injectivity and Surjectivity *}
   121 
   122 definition
   123   inj_on :: "['a => 'b, 'a set] => bool" where
   124   -- "injective"
   125   "inj_on f A == ! x:A. ! y:A. f(x)=f(y) --> x=y"
   126 
   127 text{*A common special case: functions injective over the entire domain type.*}
   128 
   129 abbreviation
   130   "inj f == inj_on f UNIV"
   131 
   132 definition
   133   bij_betw :: "('a => 'b) => 'a set => 'b set => bool" where -- "bijective"
   134   "bij_betw f A B \<longleftrightarrow> inj_on f A & f ` A = B"
   135 
   136 definition
   137   surj :: "('a => 'b) => bool" where
   138   -- "surjective"
   139   "surj f == ! y. ? x. y=f(x)"
   140 
   141 definition
   142   bij :: "('a => 'b) => bool" where
   143   -- "bijective"
   144   "bij f == inj f & surj f"
   145 
   146 lemma injI:
   147   assumes "\<And>x y. f x = f y \<Longrightarrow> x = y"
   148   shows "inj f"
   149   using assms unfolding inj_on_def by auto
   150 
   151 text{*For Proofs in @{text "Tools/Datatype/datatype_rep_proofs"}*}
   152 lemma datatype_injI:
   153     "(!! x. ALL y. f(x) = f(y) --> x=y) ==> inj(f)"
   154 by (simp add: inj_on_def)
   155 
   156 theorem range_ex1_eq: "inj f \<Longrightarrow> b : range f = (EX! x. b = f x)"
   157   by (unfold inj_on_def, blast)
   158 
   159 lemma injD: "[| inj(f); f(x) = f(y) |] ==> x=y"
   160 by (simp add: inj_on_def)
   161 
   162 lemma inj_on_eq_iff: "inj_on f A ==> x:A ==> y:A ==> (f(x) = f(y)) = (x=y)"
   163 by (force simp add: inj_on_def)
   164 
   165 lemma inj_comp:
   166   "inj f \<Longrightarrow> inj g \<Longrightarrow> inj (f \<circ> g)"
   167   by (simp add: inj_on_def)
   168 
   169 lemma inj_fun: "inj f \<Longrightarrow> inj (\<lambda>x y. f x)"
   170   by (simp add: inj_on_def expand_fun_eq)
   171 
   172 lemma inj_eq: "inj f ==> (f(x) = f(y)) = (x=y)"
   173 by (simp add: inj_on_eq_iff)
   174 
   175 lemma inj_on_id[simp]: "inj_on id A"
   176   by (simp add: inj_on_def) 
   177 
   178 lemma inj_on_id2[simp]: "inj_on (%x. x) A"
   179 by (simp add: inj_on_def) 
   180 
   181 lemma surj_id[simp]: "surj id"
   182 by (simp add: surj_def) 
   183 
   184 lemma bij_id[simp]: "bij id"
   185 by (simp add: bij_def)
   186 
   187 lemma inj_onI:
   188     "(!! x y. [|  x:A;  y:A;  f(x) = f(y) |] ==> x=y) ==> inj_on f A"
   189 by (simp add: inj_on_def)
   190 
   191 lemma inj_on_inverseI: "(!!x. x:A ==> g(f(x)) = x) ==> inj_on f A"
   192 by (auto dest:  arg_cong [of concl: g] simp add: inj_on_def)
   193 
   194 lemma inj_onD: "[| inj_on f A;  f(x)=f(y);  x:A;  y:A |] ==> x=y"
   195 by (unfold inj_on_def, blast)
   196 
   197 lemma inj_on_iff: "[| inj_on f A;  x:A;  y:A |] ==> (f(x)=f(y)) = (x=y)"
   198 by (blast dest!: inj_onD)
   199 
   200 lemma comp_inj_on:
   201      "[| inj_on f A;  inj_on g (f`A) |] ==> inj_on (g o f) A"
   202 by (simp add: comp_def inj_on_def)
   203 
   204 lemma inj_on_imageI: "inj_on (g o f) A \<Longrightarrow> inj_on g (f ` A)"
   205 apply(simp add:inj_on_def image_def)
   206 apply blast
   207 done
   208 
   209 lemma inj_on_image_iff: "\<lbrakk> ALL x:A. ALL y:A. (g(f x) = g(f y)) = (g x = g y);
   210   inj_on f A \<rbrakk> \<Longrightarrow> inj_on g (f ` A) = inj_on g A"
   211 apply(unfold inj_on_def)
   212 apply blast
   213 done
   214 
   215 lemma inj_on_contraD: "[| inj_on f A;  ~x=y;  x:A;  y:A |] ==> ~ f(x)=f(y)"
   216 by (unfold inj_on_def, blast)
   217 
   218 lemma inj_singleton: "inj (%s. {s})"
   219 by (simp add: inj_on_def)
   220 
   221 lemma inj_on_empty[iff]: "inj_on f {}"
   222 by(simp add: inj_on_def)
   223 
   224 lemma subset_inj_on: "[| inj_on f B; A <= B |] ==> inj_on f A"
   225 by (unfold inj_on_def, blast)
   226 
   227 lemma inj_on_Un:
   228  "inj_on f (A Un B) =
   229   (inj_on f A & inj_on f B & f`(A-B) Int f`(B-A) = {})"
   230 apply(unfold inj_on_def)
   231 apply (blast intro:sym)
   232 done
   233 
   234 lemma inj_on_insert[iff]:
   235   "inj_on f (insert a A) = (inj_on f A & f a ~: f`(A-{a}))"
   236 apply(unfold inj_on_def)
   237 apply (blast intro:sym)
   238 done
   239 
   240 lemma inj_on_diff: "inj_on f A ==> inj_on f (A-B)"
   241 apply(unfold inj_on_def)
   242 apply (blast)
   243 done
   244 
   245 lemma surjI: "(!! x. g(f x) = x) ==> surj g"
   246 apply (simp add: surj_def)
   247 apply (blast intro: sym)
   248 done
   249 
   250 lemma surj_range: "surj f ==> range f = UNIV"
   251 by (auto simp add: surj_def)
   252 
   253 lemma surjD: "surj f ==> EX x. y = f x"
   254 by (simp add: surj_def)
   255 
   256 lemma surjE: "surj f ==> (!!x. y = f x ==> C) ==> C"
   257 by (simp add: surj_def, blast)
   258 
   259 lemma comp_surj: "[| surj f;  surj g |] ==> surj (g o f)"
   260 apply (simp add: comp_def surj_def, clarify)
   261 apply (drule_tac x = y in spec, clarify)
   262 apply (drule_tac x = x in spec, blast)
   263 done
   264 
   265 lemma bijI: "[| inj f; surj f |] ==> bij f"
   266 by (simp add: bij_def)
   267 
   268 lemma bij_is_inj: "bij f ==> inj f"
   269 by (simp add: bij_def)
   270 
   271 lemma bij_is_surj: "bij f ==> surj f"
   272 by (simp add: bij_def)
   273 
   274 lemma bij_betw_imp_inj_on: "bij_betw f A B \<Longrightarrow> inj_on f A"
   275 by (simp add: bij_betw_def)
   276 
   277 lemma bij_comp: "bij f \<Longrightarrow> bij g \<Longrightarrow> bij (g o f)"
   278 by(fastsimp intro: comp_inj_on comp_surj simp: bij_def surj_range)
   279 
   280 lemma bij_betw_trans:
   281   "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (g o f) A C"
   282 by(auto simp add:bij_betw_def comp_inj_on)
   283 
   284 lemma bij_betw_inv: assumes "bij_betw f A B" shows "EX g. bij_betw g B A"
   285 proof -
   286   have i: "inj_on f A" and s: "f ` A = B"
   287     using assms by(auto simp:bij_betw_def)
   288   let ?P = "%b a. a:A \<and> f a = b" let ?g = "%b. The (?P b)"
   289   { fix a b assume P: "?P b a"
   290     hence ex1: "\<exists>a. ?P b a" using s unfolding image_def by blast
   291     hence uex1: "\<exists>!a. ?P b a" by(blast dest:inj_onD[OF i])
   292     hence " ?g b = a" using the1_equality[OF uex1, OF P] P by simp
   293   } note g = this
   294   have "inj_on ?g B"
   295   proof(rule inj_onI)
   296     fix x y assume "x:B" "y:B" "?g x = ?g y"
   297     from s `x:B` obtain a1 where a1: "?P x a1" unfolding image_def by blast
   298     from s `y:B` obtain a2 where a2: "?P y a2" unfolding image_def by blast
   299     from g[OF a1] a1 g[OF a2] a2 `?g x = ?g y` show "x=y" by simp
   300   qed
   301   moreover have "?g ` B = A"
   302   proof(auto simp:image_def)
   303     fix b assume "b:B"
   304     with s obtain a where P: "?P b a" unfolding image_def by blast
   305     thus "?g b \<in> A" using g[OF P] by auto
   306   next
   307     fix a assume "a:A"
   308     then obtain b where P: "?P b a" using s unfolding image_def by blast
   309     then have "b:B" using s unfolding image_def by blast
   310     with g[OF P] show "\<exists>b\<in>B. a = ?g b" by blast
   311   qed
   312   ultimately show ?thesis by(auto simp:bij_betw_def)
   313 qed
   314 
   315 lemma surj_image_vimage_eq: "surj f ==> f ` (f -` A) = A"
   316 by (simp add: surj_range)
   317 
   318 lemma inj_vimage_image_eq: "inj f ==> f -` (f ` A) = A"
   319 by (simp add: inj_on_def, blast)
   320 
   321 lemma vimage_subsetD: "surj f ==> f -` B <= A ==> B <= f ` A"
   322 apply (unfold surj_def)
   323 apply (blast intro: sym)
   324 done
   325 
   326 lemma vimage_subsetI: "inj f ==> B <= f ` A ==> f -` B <= A"
   327 by (unfold inj_on_def, blast)
   328 
   329 lemma vimage_subset_eq: "bij f ==> (f -` B <= A) = (B <= f ` A)"
   330 apply (unfold bij_def)
   331 apply (blast del: subsetI intro: vimage_subsetI vimage_subsetD)
   332 done
   333 
   334 lemma inj_on_Un_image_eq_iff: "inj_on f (A \<union> B) \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   335 by(blast dest: inj_onD)
   336 
   337 lemma inj_on_image_Int:
   338    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A Int B) = f`A Int f`B"
   339 apply (simp add: inj_on_def, blast)
   340 done
   341 
   342 lemma inj_on_image_set_diff:
   343    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A-B) = f`A - f`B"
   344 apply (simp add: inj_on_def, blast)
   345 done
   346 
   347 lemma image_Int: "inj f ==> f`(A Int B) = f`A Int f`B"
   348 by (simp add: inj_on_def, blast)
   349 
   350 lemma image_set_diff: "inj f ==> f`(A-B) = f`A - f`B"
   351 by (simp add: inj_on_def, blast)
   352 
   353 lemma inj_image_mem_iff: "inj f ==> (f a : f`A) = (a : A)"
   354 by (blast dest: injD)
   355 
   356 lemma inj_image_subset_iff: "inj f ==> (f`A <= f`B) = (A<=B)"
   357 by (simp add: inj_on_def, blast)
   358 
   359 lemma inj_image_eq_iff: "inj f ==> (f`A = f`B) = (A = B)"
   360 by (blast dest: injD)
   361 
   362 (*injectivity's required.  Left-to-right inclusion holds even if A is empty*)
   363 lemma image_INT:
   364    "[| inj_on f C;  ALL x:A. B x <= C;  j:A |]
   365     ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   366 apply (simp add: inj_on_def, blast)
   367 done
   368 
   369 (*Compare with image_INT: no use of inj_on, and if f is surjective then
   370   it doesn't matter whether A is empty*)
   371 lemma bij_image_INT: "bij f ==> f ` (INTER A B) = (INT x:A. f ` B x)"
   372 apply (simp add: bij_def)
   373 apply (simp add: inj_on_def surj_def, blast)
   374 done
   375 
   376 lemma surj_Compl_image_subset: "surj f ==> -(f`A) <= f`(-A)"
   377 by (auto simp add: surj_def)
   378 
   379 lemma inj_image_Compl_subset: "inj f ==> f`(-A) <= -(f`A)"
   380 by (auto simp add: inj_on_def)
   381 
   382 lemma bij_image_Compl_eq: "bij f ==> f`(-A) = -(f`A)"
   383 apply (simp add: bij_def)
   384 apply (rule equalityI)
   385 apply (simp_all (no_asm_simp) add: inj_image_Compl_subset surj_Compl_image_subset)
   386 done
   387 
   388 lemma (in ordered_ab_group_add) inj_uminus[simp, intro]: "inj_on uminus A"
   389   by (auto intro!: inj_onI)
   390 
   391 lemma (in linorder) strict_mono_imp_inj_on: "strict_mono f \<Longrightarrow> inj_on f A"
   392   by (auto intro!: inj_onI dest: strict_mono_eq)
   393 
   394 subsection{*Function Updating*}
   395 
   396 definition
   397   fun_upd :: "('a => 'b) => 'a => 'b => ('a => 'b)" where
   398   "fun_upd f a b == % x. if x=a then b else f x"
   399 
   400 nonterminals
   401   updbinds updbind
   402 syntax
   403   "_updbind" :: "['a, 'a] => updbind"             ("(2_ :=/ _)")
   404   ""         :: "updbind => updbinds"             ("_")
   405   "_updbinds":: "[updbind, updbinds] => updbinds" ("_,/ _")
   406   "_Update"  :: "['a, updbinds] => 'a"            ("_/'((_)')" [1000, 0] 900)
   407 
   408 translations
   409   "_Update f (_updbinds b bs)" == "_Update (_Update f b) bs"
   410   "f(x:=y)" == "CONST fun_upd f x y"
   411 
   412 (* Hint: to define the sum of two functions (or maps), use sum_case.
   413          A nice infix syntax could be defined (in Datatype.thy or below) by
   414 notation
   415   sum_case  (infixr "'(+')"80)
   416 *)
   417 
   418 lemma fun_upd_idem_iff: "(f(x:=y) = f) = (f x = y)"
   419 apply (simp add: fun_upd_def, safe)
   420 apply (erule subst)
   421 apply (rule_tac [2] ext, auto)
   422 done
   423 
   424 (* f x = y ==> f(x:=y) = f *)
   425 lemmas fun_upd_idem = fun_upd_idem_iff [THEN iffD2, standard]
   426 
   427 (* f(x := f x) = f *)
   428 lemmas fun_upd_triv = refl [THEN fun_upd_idem]
   429 declare fun_upd_triv [iff]
   430 
   431 lemma fun_upd_apply [simp]: "(f(x:=y))z = (if z=x then y else f z)"
   432 by (simp add: fun_upd_def)
   433 
   434 (* fun_upd_apply supersedes these two,   but they are useful
   435    if fun_upd_apply is intentionally removed from the simpset *)
   436 lemma fun_upd_same: "(f(x:=y)) x = y"
   437 by simp
   438 
   439 lemma fun_upd_other: "z~=x ==> (f(x:=y)) z = f z"
   440 by simp
   441 
   442 lemma fun_upd_upd [simp]: "f(x:=y,x:=z) = f(x:=z)"
   443 by (simp add: expand_fun_eq)
   444 
   445 lemma fun_upd_twist: "a ~= c ==> (m(a:=b))(c:=d) = (m(c:=d))(a:=b)"
   446 by (rule ext, auto)
   447 
   448 lemma inj_on_fun_updI: "\<lbrakk> inj_on f A; y \<notin> f`A \<rbrakk> \<Longrightarrow> inj_on (f(x:=y)) A"
   449 by (fastsimp simp:inj_on_def image_def)
   450 
   451 lemma fun_upd_image:
   452      "f(x:=y) ` A = (if x \<in> A then insert y (f ` (A-{x})) else f ` A)"
   453 by auto
   454 
   455 lemma fun_upd_comp: "f \<circ> (g(x := y)) = (f \<circ> g)(x := f y)"
   456 by (auto intro: ext)
   457 
   458 
   459 subsection {* @{text override_on} *}
   460 
   461 definition
   462   override_on :: "('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b"
   463 where
   464   "override_on f g A = (\<lambda>a. if a \<in> A then g a else f a)"
   465 
   466 lemma override_on_emptyset[simp]: "override_on f g {} = f"
   467 by(simp add:override_on_def)
   468 
   469 lemma override_on_apply_notin[simp]: "a ~: A ==> (override_on f g A) a = f a"
   470 by(simp add:override_on_def)
   471 
   472 lemma override_on_apply_in[simp]: "a : A ==> (override_on f g A) a = g a"
   473 by(simp add:override_on_def)
   474 
   475 
   476 subsection {* @{text swap} *}
   477 
   478 definition
   479   swap :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"
   480 where
   481   "swap a b f = f (a := f b, b:= f a)"
   482 
   483 lemma swap_self [simp]: "swap a a f = f"
   484 by (simp add: swap_def)
   485 
   486 lemma swap_commute: "swap a b f = swap b a f"
   487 by (rule ext, simp add: fun_upd_def swap_def)
   488 
   489 lemma swap_nilpotent [simp]: "swap a b (swap a b f) = f"
   490 by (rule ext, simp add: fun_upd_def swap_def)
   491 
   492 lemma swap_triple:
   493   assumes "a \<noteq> c" and "b \<noteq> c"
   494   shows "swap a b (swap b c (swap a b f)) = swap a c f"
   495   using assms by (simp add: expand_fun_eq swap_def)
   496 
   497 lemma comp_swap: "f \<circ> swap a b g = swap a b (f \<circ> g)"
   498 by (rule ext, simp add: fun_upd_def swap_def)
   499 
   500 lemma inj_on_imp_inj_on_swap:
   501   "[|inj_on f A; a \<in> A; b \<in> A|] ==> inj_on (swap a b f) A"
   502 by (simp add: inj_on_def swap_def, blast)
   503 
   504 lemma inj_on_swap_iff [simp]:
   505   assumes A: "a \<in> A" "b \<in> A" shows "inj_on (swap a b f) A = inj_on f A"
   506 proof 
   507   assume "inj_on (swap a b f) A"
   508   with A have "inj_on (swap a b (swap a b f)) A" 
   509     by (iprover intro: inj_on_imp_inj_on_swap) 
   510   thus "inj_on f A" by simp 
   511 next
   512   assume "inj_on f A"
   513   with A show "inj_on (swap a b f) A" by (iprover intro: inj_on_imp_inj_on_swap)
   514 qed
   515 
   516 lemma surj_imp_surj_swap: "surj f ==> surj (swap a b f)"
   517 apply (simp add: surj_def swap_def, clarify)
   518 apply (case_tac "y = f b", blast)
   519 apply (case_tac "y = f a", auto)
   520 done
   521 
   522 lemma surj_swap_iff [simp]: "surj (swap a b f) = surj f"
   523 proof 
   524   assume "surj (swap a b f)"
   525   hence "surj (swap a b (swap a b f))" by (rule surj_imp_surj_swap) 
   526   thus "surj f" by simp 
   527 next
   528   assume "surj f"
   529   thus "surj (swap a b f)" by (rule surj_imp_surj_swap) 
   530 qed
   531 
   532 lemma bij_swap_iff: "bij (swap a b f) = bij f"
   533 by (simp add: bij_def)
   534 
   535 hide_const (open) swap
   536 
   537 
   538 subsection {* Inversion of injective functions *}
   539 
   540 definition the_inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
   541 "the_inv_into A f == %x. THE y. y : A & f y = x"
   542 
   543 lemma the_inv_into_f_f:
   544   "[| inj_on f A;  x : A |] ==> the_inv_into A f (f x) = x"
   545 apply (simp add: the_inv_into_def inj_on_def)
   546 apply blast
   547 done
   548 
   549 lemma f_the_inv_into_f:
   550   "inj_on f A ==> y : f`A  ==> f (the_inv_into A f y) = y"
   551 apply (simp add: the_inv_into_def)
   552 apply (rule the1I2)
   553  apply(blast dest: inj_onD)
   554 apply blast
   555 done
   556 
   557 lemma the_inv_into_into:
   558   "[| inj_on f A; x : f ` A; A <= B |] ==> the_inv_into A f x : B"
   559 apply (simp add: the_inv_into_def)
   560 apply (rule the1I2)
   561  apply(blast dest: inj_onD)
   562 apply blast
   563 done
   564 
   565 lemma the_inv_into_onto[simp]:
   566   "inj_on f A ==> the_inv_into A f ` (f ` A) = A"
   567 by (fast intro:the_inv_into_into the_inv_into_f_f[symmetric])
   568 
   569 lemma the_inv_into_f_eq:
   570   "[| inj_on f A; f x = y; x : A |] ==> the_inv_into A f y = x"
   571   apply (erule subst)
   572   apply (erule the_inv_into_f_f, assumption)
   573   done
   574 
   575 lemma the_inv_into_comp:
   576   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
   577   the_inv_into A (f o g) x = (the_inv_into A g o the_inv_into (g ` A) f) x"
   578 apply (rule the_inv_into_f_eq)
   579   apply (fast intro: comp_inj_on)
   580  apply (simp add: f_the_inv_into_f the_inv_into_into)
   581 apply (simp add: the_inv_into_into)
   582 done
   583 
   584 lemma inj_on_the_inv_into:
   585   "inj_on f A \<Longrightarrow> inj_on (the_inv_into A f) (f ` A)"
   586 by (auto intro: inj_onI simp: image_def the_inv_into_f_f)
   587 
   588 lemma bij_betw_the_inv_into:
   589   "bij_betw f A B \<Longrightarrow> bij_betw (the_inv_into A f) B A"
   590 by (auto simp add: bij_betw_def inj_on_the_inv_into the_inv_into_into)
   591 
   592 abbreviation the_inv :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'a)" where
   593   "the_inv f \<equiv> the_inv_into UNIV f"
   594 
   595 lemma the_inv_f_f:
   596   assumes "inj f"
   597   shows "the_inv f (f x) = x" using assms UNIV_I
   598   by (rule the_inv_into_f_f)
   599 
   600 
   601 subsection {* Proof tool setup *} 
   602 
   603 text {* simplifies terms of the form
   604   f(...,x:=y,...,x:=z,...) to f(...,x:=z,...) *}
   605 
   606 simproc_setup fun_upd2 ("f(v := w, x := y)") = {* fn _ =>
   607 let
   608   fun gen_fun_upd NONE T _ _ = NONE
   609     | gen_fun_upd (SOME f) T x y = SOME (Const (@{const_name fun_upd}, T) $ f $ x $ y)
   610   fun dest_fun_T1 (Type (_, T :: Ts)) = T
   611   fun find_double (t as Const (@{const_name fun_upd},T) $ f $ x $ y) =
   612     let
   613       fun find (Const (@{const_name fun_upd},T) $ g $ v $ w) =
   614             if v aconv x then SOME g else gen_fun_upd (find g) T v w
   615         | find t = NONE
   616     in (dest_fun_T1 T, gen_fun_upd (find f) T x y) end
   617 
   618   fun proc ss ct =
   619     let
   620       val ctxt = Simplifier.the_context ss
   621       val t = Thm.term_of ct
   622     in
   623       case find_double t of
   624         (T, NONE) => NONE
   625       | (T, SOME rhs) =>
   626           SOME (Goal.prove ctxt [] [] (Logic.mk_equals (t, rhs))
   627             (fn _ =>
   628               rtac eq_reflection 1 THEN
   629               rtac ext 1 THEN
   630               simp_tac (Simplifier.inherit_context ss @{simpset}) 1))
   631     end
   632 in proc end
   633 *}
   634 
   635 
   636 subsection {* Code generator setup *}
   637 
   638 types_code
   639   "fun"  ("(_ ->/ _)")
   640 attach (term_of) {*
   641 fun term_of_fun_type _ aT _ bT _ = Free ("<function>", aT --> bT);
   642 *}
   643 attach (test) {*
   644 fun gen_fun_type aF aT bG bT i =
   645   let
   646     val tab = Unsynchronized.ref [];
   647     fun mk_upd (x, (_, y)) t = Const ("Fun.fun_upd",
   648       (aT --> bT) --> aT --> bT --> aT --> bT) $ t $ aF x $ y ()
   649   in
   650     (fn x =>
   651        case AList.lookup op = (!tab) x of
   652          NONE =>
   653            let val p as (y, _) = bG i
   654            in (tab := (x, p) :: !tab; y) end
   655        | SOME (y, _) => y,
   656      fn () => Basics.fold mk_upd (!tab) (Const ("HOL.undefined", aT --> bT)))
   657   end;
   658 *}
   659 
   660 code_const "op \<circ>"
   661   (SML infixl 5 "o")
   662   (Haskell infixr 9 ".")
   663 
   664 code_const "id"
   665   (Haskell "id")
   666 
   667 end