src/Pure/Thy/thy_parse.ML
author wenzelm
Mon Aug 21 18:03:12 1995 +0200 (1995-08-21)
changeset 1235 b4056a71eca2
parent 1027 651637377289
child 1249 2d1c27d1dac3
permissions -rw-r--r--
minor fix to make less noise with SML/NJ;
     1 (*  Title:      Pure/Thy/thy_parse.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 The parser for theory files.
     6 *)
     7 
     8 infix 5 -- --$$ $$-- ^^;
     9 infix 3 >>;
    10 infix 0 ||;
    11 
    12 signature THY_PARSE =
    13 sig
    14   type token
    15   val !! : ('a -> 'b * 'c) -> 'a -> 'b * 'c
    16   val >> : ('a -> 'b * 'c) * ('b -> 'd) -> 'a -> 'd * 'c
    17   val || : ('a -> 'b) * ('a -> 'b) -> 'a -> 'b
    18   val -- : ('a -> 'b * 'c) * ('c -> 'd * 'e) -> 'a -> ('b * 'd) * 'e
    19   val ^^ : ('a -> string * 'b) * ('b -> string * 'c) -> 'a -> string * 'c
    20   val $$ : string -> token list -> string * token list
    21   val $$-- : string * (token list -> 'b * 'c) -> token list -> 'b * 'c
    22   val --$$ : ('a -> 'b * token list) * string -> 'a -> 'b * token list
    23   val ident: token list -> string * token list
    24   val long_ident: token list -> string * token list
    25   val long_id: token list -> string * token list
    26   val type_var: token list -> string * token list
    27   val type_args: token list -> string list * token list
    28   val nat: token list -> string * token list
    29   val string: token list -> string * token list
    30   val verbatim: token list -> string * token list
    31   val empty: 'a -> 'b list * 'a
    32   val optional: ('a -> 'b * 'a) -> 'b -> 'a -> 'b * 'a
    33   val repeat: ('a -> 'b * 'a) -> 'a -> 'b list * 'a
    34   val repeat1: ('a -> 'b * 'a) -> 'a -> 'b list * 'a
    35   val enum: string -> (token list -> 'a * token list)
    36     -> token list -> 'a list * token list
    37   val enum1: string -> (token list -> 'a * token list)
    38     -> token list -> 'a list * token list
    39   val list: (token list -> 'a * token list)
    40     -> token list -> 'a list * token list
    41   val list1: (token list -> 'a * token list)
    42     -> token list -> 'a list * token list
    43   val name: token list -> string * token list
    44   val sort: token list -> string * token list
    45   val opt_infix: token list -> string * token list
    46   val opt_mixfix: token list -> string * token list
    47   val opt_witness: token list -> string * token list
    48   type syntax
    49   val make_syntax: string list ->
    50     (string * (token list -> (string * string) * token list)) list -> syntax
    51   val parse_thy: syntax -> string -> string -> string
    52   val section: string -> string -> (token list -> string * token list)
    53     -> (string * (token list -> (string * string) * token list))
    54   val axm_section: string -> string
    55     -> (token list -> (string * string list) * token list)
    56     -> (string * (token list -> (string * string) * token list))
    57   val pure_keywords: string list
    58   val pure_sections:
    59     (string * (token list -> (string * string) * token list)) list
    60   (*items for building strings*)
    61   val cat: string -> string -> string
    62   val parens: string -> string
    63   val brackets: string -> string
    64   val mk_list: string list -> string
    65   val mk_big_list: string list -> string
    66   val mk_pair: string * string -> string
    67   val mk_triple: string * string * string -> string
    68   val strip_quotes: string -> string
    69 end;
    70 
    71 functor ThyParseFun(structure Symtab: SYMTAB and ThyScan: THY_SCAN): THY_PARSE =
    72 struct
    73 
    74 open ThyScan;
    75 
    76 
    77 (** parser toolbox **)
    78 
    79 type token = token_kind * string * int;
    80 
    81 
    82 (* errors *)
    83 
    84 exception SYNTAX_ERROR of string * string * int;
    85 
    86 fun syn_err s1 s2 n = raise SYNTAX_ERROR (s1, s2, n);
    87 
    88 fun eof_err () = error "Unexpected end-of-file";
    89 
    90 (*Similar to Prolog's cut: reports any syntax error instead of backtracking
    91   through a superior || *)
    92 fun !! parse toks = parse toks
    93   handle SYNTAX_ERROR (s1, s2, n) => error ("Syntax error on line " ^
    94     string_of_int n ^ ": " ^ s1 ^ " expected and " ^ s2 ^ " was found");
    95 
    96 
    97 (* parser combinators *)
    98 
    99 fun (parse >> f) toks = apfst f (parse toks);
   100 
   101 fun (parse1 || parse2) toks =
   102   parse1 toks handle SYNTAX_ERROR _ => parse2 toks;
   103 
   104 fun (parse1 -- parse2) toks =
   105   let
   106     val (x, toks') = parse1 toks;
   107     val (y, toks'') = parse2 toks';
   108   in
   109     ((x, y), toks'')
   110   end;
   111 
   112 fun (parse1 ^^ parse2) = parse1 -- parse2 >> op ^;
   113 
   114 
   115 (* generic parsers *)
   116 
   117 fun $$ a ((k, b, n) :: toks) =
   118       if k = Keyword andalso a = b then (a, toks)
   119       else syn_err (quote a) (quote b) n
   120   | $$ _ [] = eof_err ();
   121 
   122 fun (a $$-- parse) = $$ a -- parse >> #2;
   123 
   124 fun (parse --$$ a) = parse -- $$ a >> #1;
   125 
   126 
   127 fun kind k1 ((k2, s, n) :: toks) =
   128       if k1 = k2 then (s, toks)
   129       else syn_err (name_of_kind k1) (quote s) n
   130   | kind _ [] = eof_err ();
   131 
   132 val ident = kind Ident;
   133 val long_ident = kind LongIdent;
   134 val long_id = ident || long_ident;
   135 val type_var = kind TypeVar >> quote;
   136 val nat = kind Nat;
   137 val string = kind String;
   138 val verbatim = kind Verbatim;
   139 val eof = kind EOF;
   140 
   141 fun empty toks = ([], toks);
   142 
   143 fun optional parse def = parse || empty >> K def;
   144 
   145 fun repeat parse toks = (parse -- repeat parse >> op :: || empty) toks;
   146 fun repeat1 parse = parse -- repeat parse >> op ::;
   147 
   148 fun enum1 sep parse = parse -- repeat (sep $$-- parse) >> op ::;
   149 fun enum sep parse = enum1 sep parse || empty;
   150 
   151 val list = enum ",";
   152 val list1 = enum1 ",";
   153 
   154 
   155 
   156 (** theory parsers **)
   157 
   158 (* misc utilities *)
   159 
   160 fun cat s1 s2 = s1 ^ " " ^ s2;
   161 
   162 val parens = enclose "(" ")";
   163 val brackets = enclose "[" "]";
   164 
   165 val mk_list = brackets o commas;
   166 val mk_big_list = brackets o space_implode ",\n ";
   167 
   168 fun mk_pair (x, y) = parens (commas [x, y]);
   169 fun mk_triple (x, y, z) = parens (commas [x, y, z]);
   170 fun mk_triple1 ((x, y), z) = mk_triple (x, y, z);
   171 fun mk_triple2 (x, (y, z)) = mk_triple (x, y, z);
   172 
   173 val split_decls = flat o map (fn (xs, y) => map (rpair y) xs);
   174 
   175 fun strip_quotes str =
   176   implode (tl (take (size str - 1, explode str)));
   177 
   178 
   179 (* names *)
   180 
   181 val name = ident >> quote || string;
   182 val names = list name;
   183 val names1 = list1 name;
   184 val name_list = names >> mk_list;
   185 val name_list1 = names1 >> mk_list;
   186 
   187 
   188 (* classes *)
   189 
   190 val subclass = name -- optional ("<" $$-- !! name_list1) "[]";
   191 
   192 val class_decls = repeat1 (subclass >> mk_pair) >> mk_big_list;
   193 
   194 
   195 (* arities *)
   196 
   197 val sort =
   198   name >> brackets ||
   199   "{" $$-- name_list --$$ "}";
   200 
   201 val sort_list1 = list1 sort >> mk_list;
   202 
   203 
   204 val arity = optional ("(" $$-- !! (sort_list1 --$$")")) "[]" -- sort;
   205 
   206 val arity_decls = repeat1 (names1 --$$ "::" -- !! arity)
   207   >> (mk_big_list o map mk_triple2 o split_decls);
   208 
   209 
   210 (* mixfix annotations *)
   211 
   212 val infxl = "infixl" $$-- !! nat >> cat "Infixl";
   213 val infxr = "infixr" $$-- !! nat >> cat "Infixr";
   214 
   215 val binder = "binder" $$--
   216   !! (string -- ( ("[" $$-- nat --$$ "]") -- nat
   217                 || nat >> (fn n => (n,n))
   218      )          )
   219   >> (cat "Binder" o mk_triple2);
   220 
   221 val opt_pris = optional ("[" $$-- !! (list nat --$$ "]")) [] >> mk_list;
   222 
   223 val mixfix = string -- !! (opt_pris -- optional nat "max_pri")
   224   >> (cat "Mixfix" o mk_triple2);
   225 
   226 fun opt_syn fx = optional ("(" $$-- fx --$$ ")") "NoSyn";
   227 
   228 val opt_infix = opt_syn (infxl || infxr);
   229 val opt_mixfix = opt_syn (mixfix || infxl || infxr || binder);
   230 
   231 
   232 (* types *)
   233 
   234 fun mk_old_type_decl ((ts, n), syn) =
   235   map (fn t => (mk_triple (t, n, syn), false)) ts;
   236 
   237 fun mk_type_decl (((xs, t), None), syn) =
   238       [(mk_triple (t, string_of_int (length xs), syn), false)]
   239   | mk_type_decl (((xs, t), Some rhs), syn) =
   240       [(parens (commas [t, mk_list xs, rhs, syn]), true)];
   241 
   242 fun mk_type_decls tys =
   243   "|> add_types\n" ^ mk_big_list (keyfilter tys false) ^ "\n\n\
   244   \|> add_tyabbrs\n" ^ mk_big_list (keyfilter tys true);
   245 
   246 
   247 val old_type_decl = names1 -- nat -- opt_infix >> mk_old_type_decl;
   248 
   249 val type_args =
   250   type_var >> (fn x => [x]) ||
   251   "(" $$-- !! (list1 type_var --$$ ")") ||
   252   empty >> K [];
   253 
   254 val type_decl = type_args -- name -- optional ("=" $$-- !! string >> Some) None
   255   -- opt_infix >> mk_type_decl;
   256 
   257 val type_decls = repeat1 (old_type_decl || type_decl) >> (mk_type_decls o flat);
   258 
   259 
   260 (* consts *)
   261 
   262 val const_decls = repeat1 (names1 --$$ "::" -- !! (string -- opt_mixfix))
   263   >> (mk_big_list o map mk_triple2 o split_decls);
   264 
   265 
   266 (* translations *)
   267 
   268 val trans_pat =
   269   optional ("(" $$-- !! (name --$$ ")")) "\"logic\"" -- string >> mk_pair;
   270 
   271 val trans_arrow =
   272   $$ "=>" >> K " |-> " ||
   273   $$ "<=" >> K " <-| " ||
   274   $$ "==" >> K " <-> ";
   275 
   276 val trans_decls = repeat1 (trans_pat ^^ !! (trans_arrow ^^ trans_pat))
   277   >> mk_big_list;
   278 
   279 
   280 (* ML translations *)
   281 
   282 val trfun_defs =
   283   " val parse_ast_translation = [];\n\
   284   \ val parse_translation = [];\n\
   285   \ val print_translation = [];\n\
   286   \ val print_ast_translation = [];";
   287 
   288 val trfun_args =
   289   "(parse_ast_translation, parse_translation, \
   290   \print_translation, print_ast_translation)";
   291 
   292 fun mk_mltrans txt =
   293   "let\n"
   294   ^ trfun_defs ^ "\n"
   295   ^ txt ^ "\n\
   296   \in\n\
   297   \ " ^ trfun_args ^ "\n\
   298   \end";
   299 
   300 val mltrans = verbatim >> mk_mltrans;
   301 
   302 
   303 (* axioms *)
   304 
   305 val mk_axms = mk_big_list o map (mk_pair o apfst quote);
   306 
   307 fun mk_axiom_decls axms = (mk_axms axms, map fst axms);
   308 
   309 val axiom_decls = repeat1 (ident -- !! string) >> mk_axiom_decls;
   310 
   311 
   312 (* axclass *)
   313 
   314 fun mk_axclass_decl ((c, cs), axms) =
   315   (mk_pair (c, cs) ^ "\n" ^ mk_axms axms,
   316     (strip_quotes c ^ "I") :: map fst axms);
   317 
   318 val axclass_decl = subclass -- repeat (ident -- !! string) >> mk_axclass_decl;
   319 
   320 
   321 (* instance *)
   322 
   323 fun mk_witness (axths, opt_tac) =
   324   mk_list (keyfilter axths false) ^ "\n" ^
   325   mk_list (keyfilter axths true) ^ "\n" ^
   326   opt_tac;
   327 
   328 val axm_or_thm =
   329   string >> rpair false ||
   330   long_id >> rpair true;
   331 
   332 
   333 val opt_witness =
   334   optional ("(" $$-- list1 axm_or_thm --$$ ")") [] --
   335   optional (verbatim >> (parens o cat "Some" o parens)) "None"
   336   >> mk_witness;
   337 
   338 val instance_decl =
   339   (name --$$ "<" -- name >> (pair "|> AxClass.add_inst_subclass" o mk_pair) ||
   340     name --$$ "::" -- arity >> (pair "|> AxClass.add_inst_arity" o mk_triple2))
   341   -- opt_witness
   342   >> (fn ((x, y), z) => (cat_lines [x, y, z]));
   343 
   344 
   345 
   346 (** theory syntax **)
   347 
   348 type syntax =
   349   lexicon * (token list -> (string * string) * token list) Symtab.table;
   350 
   351 fun make_syntax keywords sects =
   352   (make_lexicon (map fst sects @ keywords),
   353     Symtab.make sects handle Symtab.DUPS dups =>
   354       error ("Duplicate sections in theory file syntax: " ^ commas_quote dups));
   355 
   356 
   357 (* header *)
   358 
   359 fun mk_header (thy_name, bases) =
   360   (thy_name, "mk_base " ^ mk_list bases ^ " " ^ quote thy_name);
   361 
   362 val base =
   363   ident >> (cat "Thy" o quote) ||
   364   string >> cat "File";
   365 
   366 val header = ident --$$ "=" -- enum1 "+" base >> mk_header;
   367 
   368 
   369 (* extension *)
   370 
   371 fun mk_extension (txts, mltxt) =
   372   let
   373     val cat_sects = space_implode "\n\n" o filter_out (equal "");
   374     val (extxts, postxts) = split_list txts;
   375   in
   376     (cat_sects extxts, cat_sects postxts, mltxt)
   377   end;
   378 
   379 fun sect tab ((Keyword, s, n) :: toks) =
   380       (case Symtab.lookup (tab, s) of
   381         Some parse => !! parse toks
   382       | None => syn_err "section" s n)
   383   | sect _ ((_, s, n) :: _) = syn_err "section" s n
   384   | sect _ [] = eof_err ();
   385 
   386 fun extension sectab = "+" $$-- !! (repeat (sect sectab) --$$ "end") --
   387   optional ("ML" $$-- verbatim) "" >> mk_extension;
   388 
   389 
   390 (* theory definition *)
   391 
   392 fun mk_structure tname ((thy_name, old_thys), opt_txts) =
   393   if thy_name <> tname then
   394     error ("Filename \"" ^ tname ^ ".thy\" and theory name "
   395       ^ quote thy_name ^ " are different")
   396   else
   397     (case opt_txts of
   398       Some (extxt, postxt, mltxt) =>
   399         "val thy = " ^ old_thys ^ " true;\n\n\
   400         \structure " ^ thy_name ^ " =\n\
   401         \struct\n\
   402         \\n\
   403         \local\n"
   404         ^ trfun_defs ^ "\n\
   405         \in\n\
   406         \\n"
   407         ^ mltxt ^ "\n\
   408         \\n\
   409         \val thy = thy\n\
   410         \\n\
   411         \|> add_trfuns\n"
   412         ^ trfun_args ^ "\n\
   413         \\n"
   414         ^ extxt ^ "\n\
   415         \\n\
   416         \|> add_thyname " ^ quote thy_name ^ ";\n\
   417         \\n\
   418         \val _ = store_theory (thy, " ^ quote thy_name ^ ");\n\
   419         \\n\
   420         \\n"
   421         ^ postxt ^ "\n\
   422         \\n\
   423         \end;\n\
   424         \end;\n"
   425     | None =>
   426         "val thy = " ^ old_thys ^ " false;\n\
   427         \\n\
   428         \structure " ^ thy_name ^ " =\n\
   429         \struct\n\
   430         \\n\
   431         \val thy = thy\n\
   432         \\n\
   433         \val _ = store_theory (thy, " ^ quote thy_name ^ ");\n\
   434         \\n\
   435         \end;\n");
   436 
   437 fun theory_defn sectab tname =
   438   header -- optional (extension sectab >> Some) None -- eof
   439   >> (mk_structure tname o #1);
   440 
   441 fun parse_thy (lex, sectab) tname str =
   442   #1 (!! (theory_defn sectab tname) (tokenize lex str));
   443 
   444 
   445 (* standard sections *)
   446 
   447 fun mk_val ax = "val " ^ ax ^ " = get_axiom thy " ^ quote ax ^ ";";
   448 val mk_vals = cat_lines o map mk_val;
   449 
   450 fun mk_axm_sect "" (txt, axs) = (txt, mk_vals axs)
   451   | mk_axm_sect pretxt (txt, axs) = (pretxt ^ "\n" ^ txt, mk_vals axs);
   452 
   453 fun axm_section name pretxt parse =
   454   (name, parse >> mk_axm_sect pretxt);
   455 
   456 fun section name pretxt parse =
   457   axm_section name pretxt (parse >> rpair []);
   458 
   459 
   460 val pure_keywords =
   461  ["end", "ML", "mixfix", "infixr", "infixl", "binder", "=", "+", ",", "<",
   462   "{", "}", "(", ")", "[", "]", "::", "==", "=>", "<="];
   463 
   464 val pure_sections =
   465  [section "classes" "|> add_classes" class_decls,
   466   section "default" "|> add_defsort" sort,
   467   section "types" "" type_decls,
   468   section "arities" "|> add_arities" arity_decls,
   469   section "consts" "|> add_consts" const_decls,
   470   section "syntax" "|> add_syntax" const_decls,
   471   section "translations" "|> add_trrules" trans_decls,
   472   section "MLtrans" "|> add_trfuns" mltrans,
   473   section "MLtext" "" verbatim,
   474   axm_section "rules" "|> add_axioms" axiom_decls,
   475   axm_section "defs" "|> add_defs" axiom_decls,
   476   axm_section "axclass" "|> AxClass.add_axclass" axclass_decl,
   477   section "instance" "" instance_decl];
   478 
   479 
   480 end;