src/Pure/Proof/extraction.ML
author wenzelm
Thu Oct 29 17:58:26 2009 +0100 (2009-10-29)
changeset 33317 b4534348b8fd
parent 33245 65232054ffd0
child 33337 9c3b9bf81e8b
permissions -rw-r--r--
standardized filter/filter_out;
     1 (*  Title:      Pure/Proof/extraction.ML
     2     Author:     Stefan Berghofer, TU Muenchen
     3 
     4 Extraction of programs from proofs.
     5 *)
     6 
     7 signature EXTRACTION =
     8 sig
     9   val set_preprocessor : (theory -> Proofterm.proof -> Proofterm.proof) -> theory -> theory
    10   val add_realizes_eqns_i : ((term * term) list * (term * term)) list -> theory -> theory
    11   val add_realizes_eqns : string list -> theory -> theory
    12   val add_typeof_eqns_i : ((term * term) list * (term * term)) list -> theory -> theory
    13   val add_typeof_eqns : string list -> theory -> theory
    14   val add_realizers_i : (string * (string list * term * Proofterm.proof)) list
    15     -> theory -> theory
    16   val add_realizers : (thm * (string list * string * string)) list
    17     -> theory -> theory
    18   val add_expand_thms : thm list -> theory -> theory
    19   val add_types : (xstring * ((term -> term option) list *
    20     (term -> typ -> term -> typ -> term) option)) list -> theory -> theory
    21   val extract : (thm * string list) list -> theory -> theory
    22   val nullT : typ
    23   val nullt : term
    24   val mk_typ : typ -> term
    25   val etype_of : theory -> string list -> typ list -> term -> typ
    26   val realizes_of: theory -> string list -> term -> term -> term
    27 end;
    28 
    29 structure Extraction : EXTRACTION =
    30 struct
    31 
    32 open Proofterm;
    33 
    34 (**** tools ****)
    35 
    36 fun add_syntax thy =
    37   thy
    38   |> Theory.copy
    39   |> Sign.root_path
    40   |> Sign.add_types [(Binding.name "Type", 0, NoSyn), (Binding.name "Null", 0, NoSyn)]
    41   |> Sign.add_consts
    42       [(Binding.name "typeof", "'b::{} => Type", NoSyn),
    43        (Binding.name "Type", "'a::{} itself => Type", NoSyn),
    44        (Binding.name "Null", "Null", NoSyn),
    45        (Binding.name "realizes", "'a::{} => 'b::{} => 'b", NoSyn)];
    46 
    47 val nullT = Type ("Null", []);
    48 val nullt = Const ("Null", nullT);
    49 
    50 fun mk_typ T =
    51   Const ("Type", Term.itselfT T --> Type ("Type", [])) $ Logic.mk_type T;
    52 
    53 fun typeof_proc defaultS vs (Const ("typeof", _) $ u) =
    54       SOME (mk_typ (case strip_comb u of
    55           (Var ((a, i), _), _) =>
    56             if member (op =) vs a then TFree ("'" ^ a ^ ":" ^ string_of_int i, defaultS)
    57             else nullT
    58         | (Free (a, _), _) =>
    59             if member (op =) vs a then TFree ("'" ^ a, defaultS) else nullT
    60         | _ => nullT))
    61   | typeof_proc _ _ _ = NONE;
    62 
    63 fun rlz_proc (Const ("realizes", Type (_, [Type ("Null", []), _])) $ r $ t) = SOME t
    64   | rlz_proc (Const ("realizes", Type (_, [T, _])) $ r $ t) =
    65       (case strip_comb t of
    66          (Var (ixn, U), ts) => SOME (list_comb (Var (ixn, T --> U), r :: ts))
    67        | (Free (s, U), ts) => SOME (list_comb (Free (s, T --> U), r :: ts))
    68        | _ => NONE)
    69   | rlz_proc _ = NONE;
    70 
    71 val unpack_ixn = apfst implode o apsnd (fst o read_int o tl) o
    72   take_prefix (fn s => s <> ":") o explode;
    73 
    74 type rules =
    75   {next: int, rs: ((term * term) list * (term * term)) list,
    76    net: (int * ((term * term) list * (term * term))) Net.net};
    77 
    78 val empty_rules : rules = {next = 0, rs = [], net = Net.empty};
    79 
    80 fun add_rule (r as (_, (lhs, _)), {next, rs, net} : rules) =
    81   {next = next - 1, rs = r :: rs, net = Net.insert_term (K false)
    82      (Envir.eta_contract lhs, (next, r)) net};
    83 
    84 fun merge_rules ({next, rs = rs1, net} : rules) ({rs = rs2, ...} : rules) =
    85   List.foldr add_rule {next = next, rs = rs1, net = net} (subtract (op =) rs1 rs2);
    86 
    87 fun condrew thy rules procs =
    88   let
    89     fun rew tm =
    90       Pattern.rewrite_term thy [] (condrew' :: procs) tm
    91     and condrew' tm =
    92       let
    93         val cache = Unsynchronized.ref ([] : (term * term) list);
    94         fun lookup f x = (case AList.lookup (op =) (!cache) x of
    95             NONE =>
    96               let val y = f x
    97               in (cache := (x, y) :: !cache; y) end
    98           | SOME y => y);
    99       in
   100         get_first (fn (_, (prems, (tm1, tm2))) =>
   101         let
   102           fun ren t = the_default t (Term.rename_abs tm1 tm t);
   103           val inc = Logic.incr_indexes ([], maxidx_of_term tm + 1);
   104           val env as (Tenv, tenv) = Pattern.match thy (inc tm1, tm) (Vartab.empty, Vartab.empty);
   105           val prems' = map (pairself (Envir.subst_term env o inc o ren)) prems;
   106           val env' = Envir.Envir
   107             {maxidx = fold (fn (t, u) => Term.maxidx_term t #> Term.maxidx_term u) prems' ~1,
   108              tenv = tenv, tyenv = Tenv};
   109           val env'' = fold (Pattern.unify thy o pairself (lookup rew)) prems' env';
   110         in SOME (Envir.norm_term env'' (inc (ren tm2)))
   111         end handle Pattern.MATCH => NONE | Pattern.Unif => NONE)
   112           (sort (int_ord o pairself fst)
   113             (Net.match_term rules (Envir.eta_contract tm)))
   114       end;
   115 
   116   in rew end;
   117 
   118 val chtype = change_type o SOME;
   119 
   120 fun extr_name s vs = Long_Name.append "extr" (space_implode "_" (s :: vs));
   121 fun corr_name s vs = extr_name s vs ^ "_correctness";
   122 
   123 fun msg d s = priority (Symbol.spaces d ^ s);
   124 
   125 fun vars_of t = map Var (rev (Term.add_vars t []));
   126 fun frees_of t = map Free (rev (Term.add_frees t []));
   127 fun vfs_of t = vars_of t @ frees_of t;
   128 
   129 fun forall_intr_prf (t, prf) =
   130   let val (a, T) = (case t of Var ((a, _), T) => (a, T) | Free p => p)
   131   in Abst (a, SOME T, prf_abstract_over t prf) end;
   132 
   133 val mkabs = List.foldr (fn (v, t) => Abs ("x", fastype_of v, abstract_over (v, t)));
   134 
   135 fun strip_abs 0 t = t
   136   | strip_abs n (Abs (_, _, t)) = strip_abs (n-1) t
   137   | strip_abs _ _ = error "strip_abs: not an abstraction";
   138 
   139 fun prf_subst_TVars tye =
   140   map_proof_terms (subst_TVars tye) (typ_subst_TVars tye);
   141 
   142 fun relevant_vars types prop = List.foldr (fn
   143       (Var ((a, _), T), vs) => (case strip_type T of
   144         (_, Type (s, _)) => if member (op =) types s then a :: vs else vs
   145       | _ => vs)
   146     | (_, vs) => vs) [] (vars_of prop);
   147 
   148 fun tname_of (Type (s, _)) = s
   149   | tname_of _ = "";
   150 
   151 fun get_var_type t =
   152   let
   153     val vs = Term.add_vars t [];
   154     val fs = Term.add_frees t [];
   155   in fn 
   156       Var (ixn, _) => (case AList.lookup (op =) vs ixn of
   157           NONE => error "get_var_type: no such variable in term"
   158         | SOME T => Var (ixn, T))
   159     | Free (s, _) => (case AList.lookup (op =) fs s of
   160           NONE => error "get_var_type: no such variable in term"
   161         | SOME T => Free (s, T))
   162     | _ => error "get_var_type: not a variable"
   163   end;
   164 
   165 
   166 (**** theory data ****)
   167 
   168 (* theory data *)
   169 
   170 structure ExtractionData = TheoryDataFun
   171 (
   172   type T =
   173     {realizes_eqns : rules,
   174      typeof_eqns : rules,
   175      types : (string * ((term -> term option) list *
   176        (term -> typ -> term -> typ -> term) option)) list,
   177      realizers : (string list * (term * proof)) list Symtab.table,
   178      defs : thm list,
   179      expand : (string * term) list,
   180      prep : (theory -> proof -> proof) option}
   181 
   182   val empty =
   183     {realizes_eqns = empty_rules,
   184      typeof_eqns = empty_rules,
   185      types = [],
   186      realizers = Symtab.empty,
   187      defs = [],
   188      expand = [],
   189      prep = NONE};
   190   val copy = I;
   191   val extend = I;
   192 
   193   fun merge _
   194     (({realizes_eqns = realizes_eqns1, typeof_eqns = typeof_eqns1, types = types1,
   195        realizers = realizers1, defs = defs1, expand = expand1, prep = prep1},
   196       {realizes_eqns = realizes_eqns2, typeof_eqns = typeof_eqns2, types = types2,
   197        realizers = realizers2, defs = defs2, expand = expand2, prep = prep2}) : T * T) =
   198     {realizes_eqns = merge_rules realizes_eqns1 realizes_eqns2,
   199      typeof_eqns = merge_rules typeof_eqns1 typeof_eqns2,
   200      types = AList.merge (op =) (K true) (types1, types2),
   201      realizers = Symtab.merge_list (eq_set (op =) o pairself #1) (realizers1, realizers2),
   202      defs = Library.merge Thm.eq_thm (defs1, defs2),
   203      expand = Library.merge (op =) (expand1, expand2),
   204      prep = (case prep1 of NONE => prep2 | _ => prep1)};
   205 );
   206 
   207 fun read_condeq thy =
   208   let val thy' = add_syntax thy
   209   in fn s =>
   210     let val t = Logic.varify (Syntax.read_prop_global thy' s)
   211     in (map Logic.dest_equals (Logic.strip_imp_prems t),
   212       Logic.dest_equals (Logic.strip_imp_concl t))
   213     end handle TERM _ => error ("Not a (conditional) meta equality:\n" ^ s)
   214   end;
   215 
   216 (** preprocessor **)
   217 
   218 fun set_preprocessor prep thy =
   219   let val {realizes_eqns, typeof_eqns, types, realizers,
   220     defs, expand, ...} = ExtractionData.get thy
   221   in
   222     ExtractionData.put
   223       {realizes_eqns = realizes_eqns, typeof_eqns = typeof_eqns, types = types,
   224        realizers = realizers, defs = defs, expand = expand, prep = SOME prep} thy
   225   end;
   226 
   227 (** equations characterizing realizability **)
   228 
   229 fun gen_add_realizes_eqns prep_eq eqns thy =
   230   let val {realizes_eqns, typeof_eqns, types, realizers,
   231     defs, expand, prep} = ExtractionData.get thy;
   232   in
   233     ExtractionData.put
   234       {realizes_eqns = List.foldr add_rule realizes_eqns (map (prep_eq thy) eqns),
   235        typeof_eqns = typeof_eqns, types = types, realizers = realizers,
   236        defs = defs, expand = expand, prep = prep} thy
   237   end
   238 
   239 val add_realizes_eqns_i = gen_add_realizes_eqns (K I);
   240 val add_realizes_eqns = gen_add_realizes_eqns read_condeq;
   241 
   242 (** equations characterizing type of extracted program **)
   243 
   244 fun gen_add_typeof_eqns prep_eq eqns thy =
   245   let
   246     val {realizes_eqns, typeof_eqns, types, realizers,
   247       defs, expand, prep} = ExtractionData.get thy;
   248     val eqns' = map (prep_eq thy) eqns
   249   in
   250     ExtractionData.put
   251       {realizes_eqns = realizes_eqns, realizers = realizers,
   252        typeof_eqns = List.foldr add_rule typeof_eqns eqns',
   253        types = types, defs = defs, expand = expand, prep = prep} thy
   254   end
   255 
   256 val add_typeof_eqns_i = gen_add_typeof_eqns (K I);
   257 val add_typeof_eqns = gen_add_typeof_eqns read_condeq;
   258 
   259 fun thaw (T as TFree (a, S)) =
   260       if exists_string (fn s => s = ":") a then TVar (unpack_ixn a, S) else T
   261   | thaw (Type (a, Ts)) = Type (a, map thaw Ts)
   262   | thaw T = T;
   263 
   264 fun freeze (TVar ((a, i), S)) = TFree (a ^ ":" ^ string_of_int i, S)
   265   | freeze (Type (a, Ts)) = Type (a, map freeze Ts)
   266   | freeze T = T;
   267 
   268 fun freeze_thaw f x =
   269   map_types thaw (f (map_types freeze x));
   270 
   271 fun etype_of thy vs Ts t =
   272   let
   273     val {typeof_eqns, ...} = ExtractionData.get thy;
   274     fun err () = error ("Unable to determine type of extracted program for\n" ^
   275       Syntax.string_of_term_global thy t)
   276   in case strip_abs_body (freeze_thaw (condrew thy (#net typeof_eqns)
   277     [typeof_proc (Sign.defaultS thy) vs]) (list_abs (map (pair "x") (rev Ts),
   278       Const ("typeof", fastype_of1 (Ts, t) --> Type ("Type", [])) $ t))) of
   279       Const ("Type", _) $ u => (Logic.dest_type u handle TERM _ => err ())
   280     | _ => err ()
   281   end;
   282 
   283 (** realizers for axioms / theorems, together with correctness proofs **)
   284 
   285 fun gen_add_realizers prep_rlz rs thy =
   286   let val {realizes_eqns, typeof_eqns, types, realizers,
   287     defs, expand, prep} = ExtractionData.get thy
   288   in
   289     ExtractionData.put
   290       {realizes_eqns = realizes_eqns, typeof_eqns = typeof_eqns, types = types,
   291        realizers = fold (Symtab.cons_list o prep_rlz thy) rs realizers,
   292        defs = defs, expand = expand, prep = prep} thy
   293   end
   294 
   295 fun prep_realizer thy =
   296   let
   297     val {realizes_eqns, typeof_eqns, defs, types, ...} =
   298       ExtractionData.get thy;
   299     val procs = maps (fst o snd) types;
   300     val rtypes = map fst types;
   301     val eqns = Net.merge (K false) (#net realizes_eqns, #net typeof_eqns);
   302     val thy' = add_syntax thy;
   303     val rd = ProofSyntax.read_proof thy' false
   304   in fn (thm, (vs, s1, s2)) =>
   305     let
   306       val name = Thm.get_name thm;
   307       val _ = name <> "" orelse error "add_realizers: unnamed theorem";
   308       val prop = Pattern.rewrite_term thy'
   309         (map (Logic.dest_equals o prop_of) defs) [] (prop_of thm);
   310       val vars = vars_of prop;
   311       val vars' = filter_out (fn v =>
   312         member (op =) rtypes (tname_of (body_type (fastype_of v)))) vars;
   313       val T = etype_of thy' vs [] prop;
   314       val (T', thw) = Type.freeze_thaw_type
   315         (if T = nullT then nullT else map fastype_of vars' ---> T);
   316       val t = map_types thw (OldGoals.simple_read_term thy' T' s1);
   317       val r' = freeze_thaw (condrew thy' eqns
   318         (procs @ [typeof_proc (Sign.defaultS thy') vs, rlz_proc]))
   319           (Const ("realizes", T --> propT --> propT) $
   320             (if T = nullT then t else list_comb (t, vars')) $ prop);
   321       val r = fold_rev Logic.all (map (get_var_type r') vars) r';
   322       val prf = Reconstruct.reconstruct_proof thy' r (rd s2);
   323     in (name, (vs, (t, prf))) end
   324   end;
   325 
   326 val add_realizers_i = gen_add_realizers
   327   (fn _ => fn (name, (vs, t, prf)) => (name, (vs, (t, prf))));
   328 val add_realizers = gen_add_realizers prep_realizer;
   329 
   330 fun realizes_of thy vs t prop =
   331   let
   332     val thy' = add_syntax thy;
   333     val {realizes_eqns, typeof_eqns, defs, types, ...} =
   334       ExtractionData.get thy';
   335     val procs = maps (rev o fst o snd) types;
   336     val eqns = Net.merge (K false) (#net realizes_eqns, #net typeof_eqns);
   337     val prop' = Pattern.rewrite_term thy'
   338       (map (Logic.dest_equals o prop_of) defs) [] prop;
   339   in freeze_thaw (condrew thy' eqns
   340     (procs @ [typeof_proc (Sign.defaultS thy') vs, rlz_proc]))
   341       (Const ("realizes", fastype_of t --> propT --> propT) $ t $ prop')
   342   end;
   343 
   344 (** expanding theorems / definitions **)
   345 
   346 fun add_expand_thm thm thy =
   347   let
   348     val {realizes_eqns, typeof_eqns, types, realizers,
   349       defs, expand, prep} = ExtractionData.get thy;
   350 
   351     val name = Thm.get_name thm;
   352     val _ = name <> "" orelse error "add_expand_thms: unnamed theorem";
   353 
   354     val is_def =
   355       (case strip_comb (fst (Logic.dest_equals (prop_of thm))) of
   356          (Const _, ts) => forall is_Var ts andalso not (has_duplicates (op =) ts)
   357            andalso (Thm.get_kind thm = Thm.definitionK orelse can (Thm.axiom thy) name)
   358        | _ => false) handle TERM _ => false;
   359   in
   360     (ExtractionData.put (if is_def then
   361         {realizes_eqns = realizes_eqns,
   362          typeof_eqns = add_rule (([],
   363            Logic.dest_equals (prop_of (Drule.abs_def thm))), typeof_eqns),
   364          types = types,
   365          realizers = realizers, defs = insert Thm.eq_thm thm defs,
   366          expand = expand, prep = prep}
   367       else
   368         {realizes_eqns = realizes_eqns, typeof_eqns = typeof_eqns, types = types,
   369          realizers = realizers, defs = defs,
   370          expand = insert (op =) (name, prop_of thm) expand, prep = prep}) thy)
   371   end;
   372 
   373 val add_expand_thms = fold add_expand_thm;
   374 
   375 val extraction_expand = Thm.declaration_attribute (fn th => Context.mapping (add_expand_thm th) I);
   376 
   377 
   378 (** types with computational content **)
   379 
   380 fun add_types tys thy =
   381   ExtractionData.map
   382     (fn {realizes_eqns, typeof_eqns, types, realizers, defs, expand, prep} =>
   383       {realizes_eqns = realizes_eqns, typeof_eqns = typeof_eqns,
   384        types = fold (AList.update (op =) o apfst (Sign.intern_type thy)) tys types,
   385        realizers = realizers, defs = defs, expand = expand, prep = prep})
   386     thy;
   387 
   388 
   389 (** Pure setup **)
   390 
   391 val _ = Context.>> (Context.map_theory
   392   (add_types [("prop", ([], NONE))] #>
   393 
   394    add_typeof_eqns
   395      ["(typeof (PROP P)) == (Type (TYPE(Null))) ==>  \
   396     \  (typeof (PROP Q)) == (Type (TYPE('Q))) ==>  \
   397     \    (typeof (PROP P ==> PROP Q)) == (Type (TYPE('Q)))",
   398 
   399       "(typeof (PROP Q)) == (Type (TYPE(Null))) ==>  \
   400     \    (typeof (PROP P ==> PROP Q)) == (Type (TYPE(Null)))",
   401 
   402       "(typeof (PROP P)) == (Type (TYPE('P))) ==>  \
   403     \  (typeof (PROP Q)) == (Type (TYPE('Q))) ==>  \
   404     \    (typeof (PROP P ==> PROP Q)) == (Type (TYPE('P => 'Q)))",
   405 
   406       "(%x. typeof (PROP P (x))) == (%x. Type (TYPE(Null))) ==>  \
   407     \    (typeof (!!x. PROP P (x))) == (Type (TYPE(Null)))",
   408 
   409       "(%x. typeof (PROP P (x))) == (%x. Type (TYPE('P))) ==>  \
   410     \    (typeof (!!x::'a. PROP P (x))) == (Type (TYPE('a => 'P)))",
   411 
   412       "(%x. typeof (f (x))) == (%x. Type (TYPE('f))) ==>  \
   413     \    (typeof (f)) == (Type (TYPE('f)))"] #>
   414 
   415    add_realizes_eqns
   416      ["(typeof (PROP P)) == (Type (TYPE(Null))) ==>  \
   417     \    (realizes (r) (PROP P ==> PROP Q)) ==  \
   418     \    (PROP realizes (Null) (PROP P) ==> PROP realizes (r) (PROP Q))",
   419 
   420       "(typeof (PROP P)) == (Type (TYPE('P))) ==>  \
   421     \  (typeof (PROP Q)) == (Type (TYPE(Null))) ==>  \
   422     \    (realizes (r) (PROP P ==> PROP Q)) ==  \
   423     \    (!!x::'P. PROP realizes (x) (PROP P) ==> PROP realizes (Null) (PROP Q))",
   424 
   425       "(realizes (r) (PROP P ==> PROP Q)) ==  \
   426     \  (!!x. PROP realizes (x) (PROP P) ==> PROP realizes (r (x)) (PROP Q))",
   427 
   428       "(%x. typeof (PROP P (x))) == (%x. Type (TYPE(Null))) ==>  \
   429     \    (realizes (r) (!!x. PROP P (x))) ==  \
   430     \    (!!x. PROP realizes (Null) (PROP P (x)))",
   431 
   432       "(realizes (r) (!!x. PROP P (x))) ==  \
   433     \  (!!x. PROP realizes (r (x)) (PROP P (x)))"] #>
   434 
   435    Attrib.setup (Binding.name "extraction_expand") (Scan.succeed extraction_expand)
   436      "specify theorems / definitions to be expanded during extraction"));
   437 
   438 
   439 (**** extract program ****)
   440 
   441 val dummyt = Const ("dummy", dummyT);
   442 
   443 fun extract thms thy =
   444   let
   445     val thy' = add_syntax thy;
   446     val {realizes_eqns, typeof_eqns, types, realizers, defs, expand, prep} =
   447       ExtractionData.get thy;
   448     val procs = maps (rev o fst o snd) types;
   449     val rtypes = map fst types;
   450     val typroc = typeof_proc (Sign.defaultS thy');
   451     val prep = the_default (K I) prep thy' o ProofRewriteRules.elim_defs thy' false defs o
   452       Reconstruct.expand_proof thy' (("", NONE) :: map (apsnd SOME) expand);
   453     val rrews = Net.merge (K false) (#net realizes_eqns, #net typeof_eqns);
   454 
   455     fun find_inst prop Ts ts vs =
   456       let
   457         val rvs = relevant_vars rtypes prop;
   458         val vars = vars_of prop;
   459         val n = Int.min (length vars, length ts);
   460 
   461         fun add_args ((Var ((a, i), _), t), (vs', tye)) =
   462           if member (op =) rvs a then
   463             let val T = etype_of thy' vs Ts t
   464             in if T = nullT then (vs', tye)
   465                else (a :: vs', (("'" ^ a, i), T) :: tye)
   466             end
   467           else (vs', tye)
   468 
   469       in List.foldr add_args ([], []) (Library.take (n, vars) ~~ Library.take (n, ts)) end;
   470 
   471     fun find (vs: string list) = Option.map snd o find_first (curry (eq_set (op =)) vs o fst);
   472     fun find' (s: string) = map_filter (fn (s', x) => if s = s' then SOME x else NONE);
   473 
   474     fun app_rlz_rews Ts vs t = strip_abs (length Ts) (freeze_thaw
   475       (condrew thy' rrews (procs @ [typroc vs, rlz_proc])) (list_abs
   476         (map (pair "x") (rev Ts), t)));
   477 
   478     fun realizes_null vs prop = app_rlz_rews [] vs
   479       (Const ("realizes", nullT --> propT --> propT) $ nullt $ prop);
   480 
   481     fun corr d defs vs ts Ts hs (PBound i) _ _ = (defs, PBound i)
   482 
   483       | corr d defs vs ts Ts hs (Abst (s, SOME T, prf)) (Abst (_, _, prf')) t =
   484           let val (defs', corr_prf) = corr d defs vs [] (T :: Ts)
   485             (dummyt :: hs) prf (incr_pboundvars 1 0 prf')
   486             (case t of SOME (Abs (_, _, u)) => SOME u | _ => NONE)
   487           in (defs', Abst (s, SOME T, corr_prf)) end
   488 
   489       | corr d defs vs ts Ts hs (AbsP (s, SOME prop, prf)) (AbsP (_, _, prf')) t =
   490           let
   491             val T = etype_of thy' vs Ts prop;
   492             val u = if T = nullT then 
   493                 (case t of SOME u => SOME (incr_boundvars 1 u) | NONE => NONE)
   494               else (case t of SOME (Abs (_, _, u)) => SOME u | _ => NONE);
   495             val (defs', corr_prf) = corr d defs vs [] (T :: Ts) (prop :: hs)
   496               (incr_pboundvars 0 1 prf) (incr_pboundvars 0 1 prf') u;
   497             val rlz = Const ("realizes", T --> propT --> propT)
   498           in (defs',
   499             if T = nullT then AbsP ("R",
   500               SOME (app_rlz_rews Ts vs (rlz $ nullt $ prop)),
   501                 prf_subst_bounds [nullt] corr_prf)
   502             else Abst (s, SOME T, AbsP ("R",
   503               SOME (app_rlz_rews (T :: Ts) vs
   504                 (rlz $ Bound 0 $ incr_boundvars 1 prop)), corr_prf)))
   505           end
   506 
   507       | corr d defs vs ts Ts hs (prf % SOME t) (prf' % _) t' =
   508           let
   509             val (Us, T) = strip_type (fastype_of1 (Ts, t));
   510             val (defs', corr_prf) = corr d defs vs (t :: ts) Ts hs prf prf'
   511               (if member (op =) rtypes (tname_of T) then t'
   512                else (case t' of SOME (u $ _) => SOME u | _ => NONE));
   513             val u = if not (member (op =) rtypes (tname_of T)) then t else
   514               let
   515                 val eT = etype_of thy' vs Ts t;
   516                 val (r, Us') = if eT = nullT then (nullt, Us) else
   517                   (Bound (length Us), eT :: Us);
   518                 val u = list_comb (incr_boundvars (length Us') t,
   519                   map Bound (length Us - 1 downto 0));
   520                 val u' = (case AList.lookup (op =) types (tname_of T) of
   521                     SOME ((_, SOME f)) => f r eT u T
   522                   | _ => Const ("realizes", eT --> T --> T) $ r $ u)
   523               in app_rlz_rews Ts vs (list_abs (map (pair "x") Us', u')) end
   524           in (defs', corr_prf % SOME u) end
   525 
   526       | corr d defs vs ts Ts hs (prf1 %% prf2) (prf1' %% prf2') t =
   527           let
   528             val prop = Reconstruct.prop_of' hs prf2';
   529             val T = etype_of thy' vs Ts prop;
   530             val (defs1, f, u) = if T = nullT then (defs, t, NONE) else
   531               (case t of
   532                  SOME (f $ u) => (defs, SOME f, SOME u)
   533                | _ =>
   534                  let val (defs1, u) = extr d defs vs [] Ts hs prf2'
   535                  in (defs1, NONE, SOME u) end)
   536             val (defs2, corr_prf1) = corr d defs1 vs [] Ts hs prf1 prf1' f;
   537             val (defs3, corr_prf2) = corr d defs2 vs [] Ts hs prf2 prf2' u;
   538           in
   539             if T = nullT then (defs3, corr_prf1 %% corr_prf2) else
   540               (defs3, corr_prf1 % u %% corr_prf2)
   541           end
   542 
   543       | corr d defs vs ts Ts hs (prf0 as PThm (_, ((name, prop, SOME Ts'), body))) _ _ =
   544           let
   545             val prf = join_proof body;
   546             val (vs', tye) = find_inst prop Ts ts vs;
   547             val tye' = (map fst (OldTerm.term_tvars prop) ~~ Ts') @ tye;
   548             val T = etype_of thy' vs' [] prop;
   549             val defs' = if T = nullT then defs
   550               else fst (extr d defs vs ts Ts hs prf0)
   551           in
   552             if T = nullT andalso realizes_null vs' prop aconv prop then (defs, prf0)
   553             else case Symtab.lookup realizers name of
   554               NONE => (case find vs' (find' name defs') of
   555                 NONE =>
   556                   let
   557                     val _ = T = nullT orelse error "corr: internal error";
   558                     val _ = msg d ("Building correctness proof for " ^ quote name ^
   559                       (if null vs' then ""
   560                        else " (relevant variables: " ^ commas_quote vs' ^ ")"));
   561                     val prf' = prep (Reconstruct.reconstruct_proof thy' prop prf);
   562                     val (defs'', corr_prf) =
   563                       corr (d + 1) defs' vs' [] [] [] prf' prf' NONE;
   564                     val corr_prop = Reconstruct.prop_of corr_prf;
   565                     val corr_prf' = List.foldr forall_intr_prf
   566                       (proof_combt
   567                          (PThm (serial (),
   568                           ((corr_name name vs', corr_prop, SOME (map TVar (OldTerm.term_tvars corr_prop))),
   569                             Future.value (approximate_proof_body corr_prf))), vfs_of corr_prop))
   570                       (map (get_var_type corr_prop) (vfs_of prop))
   571                   in
   572                     ((name, (vs', ((nullt, nullt), (corr_prf, corr_prf')))) :: defs'',
   573                      prf_subst_TVars tye' corr_prf')
   574                   end
   575               | SOME (_, (_, prf')) => (defs', prf_subst_TVars tye' prf'))
   576             | SOME rs => (case find vs' rs of
   577                 SOME (_, prf') => (defs', prf_subst_TVars tye' prf')
   578               | NONE => error ("corr: no realizer for instance of theorem " ^
   579                   quote name ^ ":\n" ^ Syntax.string_of_term_global thy' (Envir.beta_norm
   580                     (Reconstruct.prop_of (proof_combt (prf0, ts))))))
   581           end
   582 
   583       | corr d defs vs ts Ts hs (prf0 as PAxm (s, prop, SOME Ts')) _ _ =
   584           let
   585             val (vs', tye) = find_inst prop Ts ts vs;
   586             val tye' = (map fst (OldTerm.term_tvars prop) ~~ Ts') @ tye
   587           in
   588             if etype_of thy' vs' [] prop = nullT andalso
   589               realizes_null vs' prop aconv prop then (defs, prf0)
   590             else case find vs' (Symtab.lookup_list realizers s) of
   591               SOME (_, prf) => (defs, prf_subst_TVars tye' prf)
   592             | NONE => error ("corr: no realizer for instance of axiom " ^
   593                 quote s ^ ":\n" ^ Syntax.string_of_term_global thy' (Envir.beta_norm
   594                   (Reconstruct.prop_of (proof_combt (prf0, ts)))))
   595           end
   596 
   597       | corr d defs vs ts Ts hs _ _ _ = error "corr: bad proof"
   598 
   599     and extr d defs vs ts Ts hs (PBound i) = (defs, Bound i)
   600 
   601       | extr d defs vs ts Ts hs (Abst (s, SOME T, prf)) =
   602           let val (defs', t) = extr d defs vs []
   603             (T :: Ts) (dummyt :: hs) (incr_pboundvars 1 0 prf)
   604           in (defs', Abs (s, T, t)) end
   605 
   606       | extr d defs vs ts Ts hs (AbsP (s, SOME t, prf)) =
   607           let
   608             val T = etype_of thy' vs Ts t;
   609             val (defs', t) = extr d defs vs [] (T :: Ts) (t :: hs)
   610               (incr_pboundvars 0 1 prf)
   611           in (defs',
   612             if T = nullT then subst_bound (nullt, t) else Abs (s, T, t))
   613           end
   614 
   615       | extr d defs vs ts Ts hs (prf % SOME t) =
   616           let val (defs', u) = extr d defs vs (t :: ts) Ts hs prf
   617           in (defs',
   618             if member (op =) rtypes (tname_of (body_type (fastype_of1 (Ts, t)))) then u
   619             else u $ t)
   620           end
   621 
   622       | extr d defs vs ts Ts hs (prf1 %% prf2) =
   623           let
   624             val (defs', f) = extr d defs vs [] Ts hs prf1;
   625             val prop = Reconstruct.prop_of' hs prf2;
   626             val T = etype_of thy' vs Ts prop
   627           in
   628             if T = nullT then (defs', f) else
   629               let val (defs'', t) = extr d defs' vs [] Ts hs prf2
   630               in (defs'', f $ t) end
   631           end
   632 
   633       | extr d defs vs ts Ts hs (prf0 as PThm (_, ((s, prop, SOME Ts'), body))) =
   634           let
   635             val prf = join_proof body;
   636             val (vs', tye) = find_inst prop Ts ts vs;
   637             val tye' = (map fst (OldTerm.term_tvars prop) ~~ Ts') @ tye
   638           in
   639             case Symtab.lookup realizers s of
   640               NONE => (case find vs' (find' s defs) of
   641                 NONE =>
   642                   let
   643                     val _ = msg d ("Extracting " ^ quote s ^
   644                       (if null vs' then ""
   645                        else " (relevant variables: " ^ commas_quote vs' ^ ")"));
   646                     val prf' = prep (Reconstruct.reconstruct_proof thy' prop prf);
   647                     val (defs', t) = extr (d + 1) defs vs' [] [] [] prf';
   648                     val (defs'', corr_prf) =
   649                       corr (d + 1) defs' vs' [] [] [] prf' prf' (SOME t);
   650 
   651                     val nt = Envir.beta_norm t;
   652                     val args = filter_out (fn v => member (op =) rtypes
   653                       (tname_of (body_type (fastype_of v)))) (vfs_of prop);
   654                     val args' = filter (fn v => Logic.occs (v, nt)) args;
   655                     val t' = mkabs nt args';
   656                     val T = fastype_of t';
   657                     val cname = extr_name s vs';
   658                     val c = Const (cname, T);
   659                     val u = mkabs (list_comb (c, args')) args;
   660                     val eqn = Logic.mk_equals (c, t');
   661                     val rlz =
   662                       Const ("realizes", fastype_of nt --> propT --> propT);
   663                     val lhs = app_rlz_rews [] vs' (rlz $ nt $ prop);
   664                     val rhs = app_rlz_rews [] vs' (rlz $ list_comb (c, args') $ prop);
   665                     val f = app_rlz_rews [] vs'
   666                       (Abs ("x", T, rlz $ list_comb (Bound 0, args') $ prop));
   667 
   668                     val corr_prf' =
   669                       chtype [] equal_elim_axm %> lhs %> rhs %%
   670                        (chtype [propT] symmetric_axm %> rhs %> lhs %%
   671                          (chtype [propT, T] combination_axm %> f %> f %> c %> t' %%
   672                            (chtype [T --> propT] reflexive_axm %> f) %%
   673                            PAxm (cname ^ "_def", eqn,
   674                              SOME (map TVar (OldTerm.term_tvars eqn))))) %% corr_prf;
   675                     val corr_prop = Reconstruct.prop_of corr_prf';
   676                     val corr_prf'' = List.foldr forall_intr_prf
   677                       (proof_combt
   678                         (PThm (serial (),
   679                          ((corr_name s vs', corr_prop, SOME (map TVar (OldTerm.term_tvars corr_prop))),
   680                            Future.value (approximate_proof_body corr_prf'))), vfs_of corr_prop))
   681                       (map (get_var_type corr_prop) (vfs_of prop));
   682                   in
   683                     ((s, (vs', ((t', u), (corr_prf', corr_prf'')))) :: defs'',
   684                      subst_TVars tye' u)
   685                   end
   686               | SOME ((_, u), _) => (defs, subst_TVars tye' u))
   687             | SOME rs => (case find vs' rs of
   688                 SOME (t, _) => (defs, subst_TVars tye' t)
   689               | NONE => error ("extr: no realizer for instance of theorem " ^
   690                   quote s ^ ":\n" ^ Syntax.string_of_term_global thy' (Envir.beta_norm
   691                     (Reconstruct.prop_of (proof_combt (prf0, ts))))))
   692           end
   693 
   694       | extr d defs vs ts Ts hs (prf0 as PAxm (s, prop, SOME Ts')) =
   695           let
   696             val (vs', tye) = find_inst prop Ts ts vs;
   697             val tye' = (map fst (OldTerm.term_tvars prop) ~~ Ts') @ tye
   698           in
   699             case find vs' (Symtab.lookup_list realizers s) of
   700               SOME (t, _) => (defs, subst_TVars tye' t)
   701             | NONE => error ("extr: no realizer for instance of axiom " ^
   702                 quote s ^ ":\n" ^ Syntax.string_of_term_global thy' (Envir.beta_norm
   703                   (Reconstruct.prop_of (proof_combt (prf0, ts)))))
   704           end
   705 
   706       | extr d defs vs ts Ts hs _ = error "extr: bad proof";
   707 
   708     fun prep_thm (thm, vs) =
   709       let
   710         val thy = Thm.theory_of_thm thm;
   711         val prop = Thm.prop_of thm;
   712         val prf = Thm.proof_of thm;
   713         val name = Thm.get_name thm;
   714         val _ = name <> "" orelse error "extraction: unnamed theorem";
   715         val _ = etype_of thy' vs [] prop <> nullT orelse error ("theorem " ^
   716           quote name ^ " has no computational content")
   717       in (Reconstruct.reconstruct_proof thy prop prf, vs) end;
   718 
   719     val defs =
   720       fold (fn (prf, vs) => fn defs => fst (extr 0 defs vs [] [] [] prf))
   721         (map prep_thm thms) [];
   722 
   723     fun add_def (s, (vs, ((t, u), (prf, _)))) thy =
   724       (case Sign.const_type thy (extr_name s vs) of
   725          NONE =>
   726            let
   727              val corr_prop = Reconstruct.prop_of prf;
   728              val ft = Type.freeze t;
   729              val fu = Type.freeze u;
   730              val (def_thms, thy') = if t = nullt then ([], thy) else
   731                thy
   732                |> Sign.add_consts_i [(Binding.qualified_name (extr_name s vs), fastype_of ft, NoSyn)]
   733                |> PureThy.add_defs false [((Binding.qualified_name (extr_name s vs ^ "_def"),
   734                     Logic.mk_equals (head_of (strip_abs_body fu), ft)), [])]
   735            in
   736              thy'
   737              |> PureThy.store_thm (Binding.qualified_name (corr_name s vs),
   738                   Thm.varifyT (funpow (length (OldTerm.term_vars corr_prop))
   739                     (Thm.forall_elim_var 0) (forall_intr_frees
   740                       (ProofChecker.thm_of_proof thy'
   741                        (fst (Proofterm.freeze_thaw_prf prf))))))
   742              |> snd
   743              |> fold Code.add_default_eqn def_thms
   744            end
   745        | SOME _ => thy);
   746 
   747   in
   748     thy
   749     |> Sign.root_path
   750     |> fold_rev add_def defs
   751     |> Sign.restore_naming thy
   752   end;
   753 
   754 
   755 (**** interface ****)
   756 
   757 structure P = OuterParse and K = OuterKeyword;
   758 
   759 val parse_vars = Scan.optional (P.$$$ "(" |-- P.list1 P.name --| P.$$$ ")") [];
   760 
   761 val _ =
   762   OuterSyntax.command "realizers"
   763   "specify realizers for primitive axioms / theorems, together with correctness proof"
   764   K.thy_decl
   765     (Scan.repeat1 (P.xname -- parse_vars --| P.$$$ ":" -- P.string -- P.string) >>
   766      (fn xs => Toplevel.theory (fn thy => add_realizers
   767        (map (fn (((a, vs), s1), s2) => (PureThy.get_thm thy a, (vs, s1, s2))) xs) thy)));
   768 
   769 val _ =
   770   OuterSyntax.command "realizability"
   771   "add equations characterizing realizability" K.thy_decl
   772   (Scan.repeat1 P.string >> (Toplevel.theory o add_realizes_eqns));
   773 
   774 val _ =
   775   OuterSyntax.command "extract_type"
   776   "add equations characterizing type of extracted program" K.thy_decl
   777   (Scan.repeat1 P.string >> (Toplevel.theory o add_typeof_eqns));
   778 
   779 val _ =
   780   OuterSyntax.command "extract" "extract terms from proofs" K.thy_decl
   781     (Scan.repeat1 (P.xname -- parse_vars) >> (fn xs => Toplevel.theory (fn thy =>
   782       extract (map (apfst (PureThy.get_thm thy)) xs) thy)));
   783 
   784 val etype_of = etype_of o add_syntax;
   785 
   786 end;