src/HOL/Map.thy
author haftmann
Thu Aug 27 21:19:48 2015 +0200 (2015-08-27)
changeset 61032 b57df8eecad6
parent 60841 144523e0678e
child 61069 aefe89038dd2
permissions -rw-r--r--
standardized some occurences of ancient "split" alias
     1 (*  Title:      HOL/Map.thy
     2     Author:     Tobias Nipkow, based on a theory by David von Oheimb
     3     Copyright   1997-2003 TU Muenchen
     4 
     5 The datatype of "maps"; strongly resembles maps in VDM.
     6 *)
     7 
     8 section \<open>Maps\<close>
     9 
    10 theory Map
    11 imports List
    12 begin
    13 
    14 type_synonym ('a, 'b) "map" = "'a \<Rightarrow> 'b option" (infixr "~=>" 0)
    15 
    16 type_notation (xsymbols)
    17   "map" (infixr "\<rightharpoonup>" 0)
    18 
    19 abbreviation
    20   empty :: "'a \<rightharpoonup> 'b" where
    21   "empty \<equiv> \<lambda>x. None"
    22 
    23 definition
    24   map_comp :: "('b \<rightharpoonup> 'c) \<Rightarrow> ('a \<rightharpoonup> 'b) \<Rightarrow> ('a \<rightharpoonup> 'c)"  (infixl "o'_m" 55) where
    25   "f o_m g = (\<lambda>k. case g k of None \<Rightarrow> None | Some v \<Rightarrow> f v)"
    26 
    27 notation (xsymbols)
    28   map_comp  (infixl "\<circ>\<^sub>m" 55)
    29 
    30 definition
    31   map_add :: "('a \<rightharpoonup> 'b) \<Rightarrow> ('a \<rightharpoonup> 'b) \<Rightarrow> ('a \<rightharpoonup> 'b)"  (infixl "++" 100) where
    32   "m1 ++ m2 = (\<lambda>x. case m2 x of None \<Rightarrow> m1 x | Some y \<Rightarrow> Some y)"
    33 
    34 definition
    35   restrict_map :: "('a \<rightharpoonup> 'b) \<Rightarrow> 'a set \<Rightarrow> ('a \<rightharpoonup> 'b)"  (infixl "|`"  110) where
    36   "m|`A = (\<lambda>x. if x \<in> A then m x else None)"
    37 
    38 notation (latex output)
    39   restrict_map  ("_\<restriction>\<^bsub>_\<^esub>" [111,110] 110)
    40 
    41 definition
    42   dom :: "('a \<rightharpoonup> 'b) \<Rightarrow> 'a set" where
    43   "dom m = {a. m a \<noteq> None}"
    44 
    45 definition
    46   ran :: "('a \<rightharpoonup> 'b) \<Rightarrow> 'b set" where
    47   "ran m = {b. \<exists>a. m a = Some b}"
    48 
    49 definition
    50   map_le :: "('a \<rightharpoonup> 'b) \<Rightarrow> ('a \<rightharpoonup> 'b) \<Rightarrow> bool"  (infix "\<subseteq>\<^sub>m" 50) where
    51   "(m\<^sub>1 \<subseteq>\<^sub>m m\<^sub>2) \<longleftrightarrow> (\<forall>a \<in> dom m\<^sub>1. m\<^sub>1 a = m\<^sub>2 a)"
    52 
    53 nonterminal maplets and maplet
    54 
    55 syntax
    56   "_maplet"  :: "['a, 'a] \<Rightarrow> maplet"             ("_ /|->/ _")
    57   "_maplets" :: "['a, 'a] \<Rightarrow> maplet"             ("_ /[|->]/ _")
    58   ""         :: "maplet \<Rightarrow> maplets"             ("_")
    59   "_Maplets" :: "[maplet, maplets] \<Rightarrow> maplets" ("_,/ _")
    60   "_MapUpd"  :: "['a \<rightharpoonup> 'b, maplets] \<Rightarrow> 'a \<rightharpoonup> 'b" ("_/'(_')" [900,0]900)
    61   "_Map"     :: "maplets \<Rightarrow> 'a \<rightharpoonup> 'b"            ("(1[_])")
    62 
    63 syntax (xsymbols)
    64   "_maplet"  :: "['a, 'a] \<Rightarrow> maplet"             ("_ /\<mapsto>/ _")
    65   "_maplets" :: "['a, 'a] \<Rightarrow> maplet"             ("_ /[\<mapsto>]/ _")
    66 
    67 translations
    68   "_MapUpd m (_Maplets xy ms)"  \<rightleftharpoons> "_MapUpd (_MapUpd m xy) ms"
    69   "_MapUpd m (_maplet  x y)"    \<rightleftharpoons> "m(x := CONST Some y)"
    70   "_Map ms"                     \<rightleftharpoons> "_MapUpd (CONST empty) ms"
    71   "_Map (_Maplets ms1 ms2)"     \<leftharpoondown> "_MapUpd (_Map ms1) ms2"
    72   "_Maplets ms1 (_Maplets ms2 ms3)" \<leftharpoondown> "_Maplets (_Maplets ms1 ms2) ms3"
    73 
    74 primrec
    75   map_of :: "('a \<times> 'b) list \<Rightarrow> 'a \<rightharpoonup> 'b" where
    76     "map_of [] = empty"
    77   | "map_of (p # ps) = (map_of ps)(fst p \<mapsto> snd p)"
    78 
    79 definition
    80   map_upds :: "('a \<rightharpoonup> 'b) \<Rightarrow> 'a list \<Rightarrow> 'b list \<Rightarrow> 'a \<rightharpoonup> 'b" where
    81   "map_upds m xs ys = m ++ map_of (rev (zip xs ys))"
    82 
    83 translations
    84   "_MapUpd m (_maplets x y)" \<rightleftharpoons> "CONST map_upds m x y"
    85 
    86 lemma map_of_Cons_code [code]:
    87   "map_of [] k = None"
    88   "map_of ((l, v) # ps) k = (if l = k then Some v else map_of ps k)"
    89   by simp_all
    90 
    91 
    92 subsection \<open>@{term [source] empty}\<close>
    93 
    94 lemma empty_upd_none [simp]: "empty(x := None) = empty"
    95   by (rule ext) simp
    96 
    97 
    98 subsection \<open>@{term [source] map_upd}\<close>
    99 
   100 lemma map_upd_triv: "t k = Some x \<Longrightarrow> t(k\<mapsto>x) = t"
   101   by (rule ext) simp
   102 
   103 lemma map_upd_nonempty [simp]: "t(k\<mapsto>x) \<noteq> empty"
   104 proof
   105   assume "t(k \<mapsto> x) = empty"
   106   then have "(t(k \<mapsto> x)) k = None" by simp
   107   then show False by simp
   108 qed
   109 
   110 lemma map_upd_eqD1:
   111   assumes "m(a\<mapsto>x) = n(a\<mapsto>y)"
   112   shows "x = y"
   113 proof -
   114   from assms have "(m(a\<mapsto>x)) a = (n(a\<mapsto>y)) a" by simp
   115   then show ?thesis by simp
   116 qed
   117 
   118 lemma map_upd_Some_unfold:
   119   "((m(a\<mapsto>b)) x = Some y) = (x = a \<and> b = y \<or> x \<noteq> a \<and> m x = Some y)"
   120 by auto
   121 
   122 lemma image_map_upd [simp]: "x \<notin> A \<Longrightarrow> m(x \<mapsto> y) ` A = m ` A"
   123 by auto
   124 
   125 lemma finite_range_updI: "finite (range f) \<Longrightarrow> finite (range (f(a\<mapsto>b)))"
   126 unfolding image_def
   127 apply (simp (no_asm_use) add:full_SetCompr_eq)
   128 apply (rule finite_subset)
   129  prefer 2 apply assumption
   130 apply (auto)
   131 done
   132 
   133 
   134 subsection \<open>@{term [source] map_of}\<close>
   135 
   136 lemma map_of_eq_None_iff:
   137   "(map_of xys x = None) = (x \<notin> fst ` (set xys))"
   138 by (induct xys) simp_all
   139 
   140 lemma map_of_eq_Some_iff [simp]:
   141   "distinct(map fst xys) \<Longrightarrow> (map_of xys x = Some y) = ((x,y) \<in> set xys)"
   142 apply (induct xys)
   143  apply simp
   144 apply (auto simp: map_of_eq_None_iff [symmetric])
   145 done
   146 
   147 lemma Some_eq_map_of_iff [simp]:
   148   "distinct(map fst xys) \<Longrightarrow> (Some y = map_of xys x) = ((x,y) \<in> set xys)"
   149 by (auto simp del: map_of_eq_Some_iff simp: map_of_eq_Some_iff [symmetric])
   150 
   151 lemma map_of_is_SomeI [simp]: "\<lbrakk> distinct(map fst xys); (x,y) \<in> set xys \<rbrakk>
   152     \<Longrightarrow> map_of xys x = Some y"
   153 apply (induct xys)
   154  apply simp
   155 apply force
   156 done
   157 
   158 lemma map_of_zip_is_None [simp]:
   159   "length xs = length ys \<Longrightarrow> (map_of (zip xs ys) x = None) = (x \<notin> set xs)"
   160 by (induct rule: list_induct2) simp_all
   161 
   162 lemma map_of_zip_is_Some:
   163   assumes "length xs = length ys"
   164   shows "x \<in> set xs \<longleftrightarrow> (\<exists>y. map_of (zip xs ys) x = Some y)"
   165 using assms by (induct rule: list_induct2) simp_all
   166 
   167 lemma map_of_zip_upd:
   168   fixes x :: 'a and xs :: "'a list" and ys zs :: "'b list"
   169   assumes "length ys = length xs"
   170     and "length zs = length xs"
   171     and "x \<notin> set xs"
   172     and "map_of (zip xs ys)(x \<mapsto> y) = map_of (zip xs zs)(x \<mapsto> z)"
   173   shows "map_of (zip xs ys) = map_of (zip xs zs)"
   174 proof
   175   fix x' :: 'a
   176   show "map_of (zip xs ys) x' = map_of (zip xs zs) x'"
   177   proof (cases "x = x'")
   178     case True
   179     from assms True map_of_zip_is_None [of xs ys x']
   180       have "map_of (zip xs ys) x' = None" by simp
   181     moreover from assms True map_of_zip_is_None [of xs zs x']
   182       have "map_of (zip xs zs) x' = None" by simp
   183     ultimately show ?thesis by simp
   184   next
   185     case False from assms
   186       have "(map_of (zip xs ys)(x \<mapsto> y)) x' = (map_of (zip xs zs)(x \<mapsto> z)) x'" by auto
   187     with False show ?thesis by simp
   188   qed
   189 qed
   190 
   191 lemma map_of_zip_inject:
   192   assumes "length ys = length xs"
   193     and "length zs = length xs"
   194     and dist: "distinct xs"
   195     and map_of: "map_of (zip xs ys) = map_of (zip xs zs)"
   196   shows "ys = zs"
   197   using assms(1) assms(2)[symmetric]
   198   using dist map_of
   199 proof (induct ys xs zs rule: list_induct3)
   200   case Nil show ?case by simp
   201 next
   202   case (Cons y ys x xs z zs)
   203   from \<open>map_of (zip (x#xs) (y#ys)) = map_of (zip (x#xs) (z#zs))\<close>
   204     have map_of: "map_of (zip xs ys)(x \<mapsto> y) = map_of (zip xs zs)(x \<mapsto> z)" by simp
   205   from Cons have "length ys = length xs" and "length zs = length xs"
   206     and "x \<notin> set xs" by simp_all
   207   then have "map_of (zip xs ys) = map_of (zip xs zs)" using map_of by (rule map_of_zip_upd)
   208   with Cons.hyps \<open>distinct (x # xs)\<close> have "ys = zs" by simp
   209   moreover from map_of have "y = z" by (rule map_upd_eqD1)
   210   ultimately show ?case by simp
   211 qed
   212 
   213 lemma map_of_zip_map:
   214   "map_of (zip xs (map f xs)) = (\<lambda>x. if x \<in> set xs then Some (f x) else None)"
   215   by (induct xs) (simp_all add: fun_eq_iff)
   216 
   217 lemma finite_range_map_of: "finite (range (map_of xys))"
   218 apply (induct xys)
   219  apply (simp_all add: image_constant)
   220 apply (rule finite_subset)
   221  prefer 2 apply assumption
   222 apply auto
   223 done
   224 
   225 lemma map_of_SomeD: "map_of xs k = Some y \<Longrightarrow> (k, y) \<in> set xs"
   226   by (induct xs) (auto split: if_splits)
   227 
   228 lemma map_of_mapk_SomeI:
   229   "inj f \<Longrightarrow> map_of t k = Some x \<Longrightarrow>
   230    map_of (map (case_prod (\<lambda>k. Pair (f k))) t) (f k) = Some x"
   231 by (induct t) (auto simp: inj_eq)
   232 
   233 lemma weak_map_of_SomeI: "(k, x) \<in> set l \<Longrightarrow> \<exists>x. map_of l k = Some x"
   234 by (induct l) auto
   235 
   236 lemma map_of_filter_in:
   237   "map_of xs k = Some z \<Longrightarrow> P k z \<Longrightarrow> map_of (filter (case_prod P) xs) k = Some z"
   238 by (induct xs) auto
   239 
   240 lemma map_of_map:
   241   "map_of (map (\<lambda>(k, v). (k, f v)) xs) = map_option f \<circ> map_of xs"
   242   by (induct xs) (auto simp: fun_eq_iff)
   243 
   244 lemma dom_map_option:
   245   "dom (\<lambda>k. map_option (f k) (m k)) = dom m"
   246   by (simp add: dom_def)
   247 
   248 lemma dom_map_option_comp [simp]:
   249   "dom (map_option g \<circ> m) = dom m"
   250   using dom_map_option [of "\<lambda>_. g" m] by (simp add: comp_def)
   251 
   252 
   253 subsection \<open>@{const map_option} related\<close>
   254 
   255 lemma map_option_o_empty [simp]: "map_option f o empty = empty"
   256 by (rule ext) simp
   257 
   258 lemma map_option_o_map_upd [simp]:
   259   "map_option f o m(a\<mapsto>b) = (map_option f o m)(a\<mapsto>f b)"
   260 by (rule ext) simp
   261 
   262 
   263 subsection \<open>@{term [source] map_comp} related\<close>
   264 
   265 lemma map_comp_empty [simp]:
   266   "m \<circ>\<^sub>m empty = empty"
   267   "empty \<circ>\<^sub>m m = empty"
   268 by (auto simp: map_comp_def split: option.splits)
   269 
   270 lemma map_comp_simps [simp]:
   271   "m2 k = None \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = None"
   272   "m2 k = Some k' \<Longrightarrow> (m1 \<circ>\<^sub>m m2) k = m1 k'"
   273 by (auto simp: map_comp_def)
   274 
   275 lemma map_comp_Some_iff:
   276   "((m1 \<circ>\<^sub>m m2) k = Some v) = (\<exists>k'. m2 k = Some k' \<and> m1 k' = Some v)"
   277 by (auto simp: map_comp_def split: option.splits)
   278 
   279 lemma map_comp_None_iff:
   280   "((m1 \<circ>\<^sub>m m2) k = None) = (m2 k = None \<or> (\<exists>k'. m2 k = Some k' \<and> m1 k' = None)) "
   281 by (auto simp: map_comp_def split: option.splits)
   282 
   283 
   284 subsection \<open>@{text "++"}\<close>
   285 
   286 lemma map_add_empty[simp]: "m ++ empty = m"
   287 by(simp add: map_add_def)
   288 
   289 lemma empty_map_add[simp]: "empty ++ m = m"
   290 by (rule ext) (simp add: map_add_def split: option.split)
   291 
   292 lemma map_add_assoc[simp]: "m1 ++ (m2 ++ m3) = (m1 ++ m2) ++ m3"
   293 by (rule ext) (simp add: map_add_def split: option.split)
   294 
   295 lemma map_add_Some_iff:
   296   "((m ++ n) k = Some x) = (n k = Some x | n k = None & m k = Some x)"
   297 by (simp add: map_add_def split: option.split)
   298 
   299 lemma map_add_SomeD [dest!]:
   300   "(m ++ n) k = Some x \<Longrightarrow> n k = Some x \<or> n k = None \<and> m k = Some x"
   301 by (rule map_add_Some_iff [THEN iffD1])
   302 
   303 lemma map_add_find_right [simp]: "n k = Some xx \<Longrightarrow> (m ++ n) k = Some xx"
   304 by (subst map_add_Some_iff) fast
   305 
   306 lemma map_add_None [iff]: "((m ++ n) k = None) = (n k = None & m k = None)"
   307 by (simp add: map_add_def split: option.split)
   308 
   309 lemma map_add_upd[simp]: "f ++ g(x\<mapsto>y) = (f ++ g)(x\<mapsto>y)"
   310 by (rule ext) (simp add: map_add_def)
   311 
   312 lemma map_add_upds[simp]: "m1 ++ (m2(xs[\<mapsto>]ys)) = (m1++m2)(xs[\<mapsto>]ys)"
   313 by (simp add: map_upds_def)
   314 
   315 lemma map_add_upd_left: "m\<notin>dom e2 \<Longrightarrow> e1(m \<mapsto> u1) ++ e2 = (e1 ++ e2)(m \<mapsto> u1)"
   316 by (rule ext) (auto simp: map_add_def dom_def split: option.split)
   317 
   318 lemma map_of_append[simp]: "map_of (xs @ ys) = map_of ys ++ map_of xs"
   319 unfolding map_add_def
   320 apply (induct xs)
   321  apply simp
   322 apply (rule ext)
   323 apply (simp split add: option.split)
   324 done
   325 
   326 lemma finite_range_map_of_map_add:
   327   "finite (range f) \<Longrightarrow> finite (range (f ++ map_of l))"
   328 apply (induct l)
   329  apply (auto simp del: fun_upd_apply)
   330 apply (erule finite_range_updI)
   331 done
   332 
   333 lemma inj_on_map_add_dom [iff]:
   334   "inj_on (m ++ m') (dom m') = inj_on m' (dom m')"
   335 by (fastforce simp: map_add_def dom_def inj_on_def split: option.splits)
   336 
   337 lemma map_upds_fold_map_upd:
   338   "m(ks[\<mapsto>]vs) = foldl (\<lambda>m (k, v). m(k \<mapsto> v)) m (zip ks vs)"
   339 unfolding map_upds_def proof (rule sym, rule zip_obtain_same_length)
   340   fix ks :: "'a list" and vs :: "'b list"
   341   assume "length ks = length vs"
   342   then show "foldl (\<lambda>m (k, v). m(k\<mapsto>v)) m (zip ks vs) = m ++ map_of (rev (zip ks vs))"
   343     by(induct arbitrary: m rule: list_induct2) simp_all
   344 qed
   345 
   346 lemma map_add_map_of_foldr:
   347   "m ++ map_of ps = foldr (\<lambda>(k, v) m. m(k \<mapsto> v)) ps m"
   348   by (induct ps) (auto simp: fun_eq_iff map_add_def)
   349 
   350 
   351 subsection \<open>@{term [source] restrict_map}\<close>
   352 
   353 lemma restrict_map_to_empty [simp]: "m|`{} = empty"
   354 by (simp add: restrict_map_def)
   355 
   356 lemma restrict_map_insert: "f |` (insert a A) = (f |` A)(a := f a)"
   357 by (auto simp: restrict_map_def)
   358 
   359 lemma restrict_map_empty [simp]: "empty|`D = empty"
   360 by (simp add: restrict_map_def)
   361 
   362 lemma restrict_in [simp]: "x \<in> A \<Longrightarrow> (m|`A) x = m x"
   363 by (simp add: restrict_map_def)
   364 
   365 lemma restrict_out [simp]: "x \<notin> A \<Longrightarrow> (m|`A) x = None"
   366 by (simp add: restrict_map_def)
   367 
   368 lemma ran_restrictD: "y \<in> ran (m|`A) \<Longrightarrow> \<exists>x\<in>A. m x = Some y"
   369 by (auto simp: restrict_map_def ran_def split: split_if_asm)
   370 
   371 lemma dom_restrict [simp]: "dom (m|`A) = dom m \<inter> A"
   372 by (auto simp: restrict_map_def dom_def split: split_if_asm)
   373 
   374 lemma restrict_upd_same [simp]: "m(x\<mapsto>y)|`(-{x}) = m|`(-{x})"
   375 by (rule ext) (auto simp: restrict_map_def)
   376 
   377 lemma restrict_restrict [simp]: "m|`A|`B = m|`(A\<inter>B)"
   378 by (rule ext) (auto simp: restrict_map_def)
   379 
   380 lemma restrict_fun_upd [simp]:
   381   "m(x := y)|`D = (if x \<in> D then (m|`(D-{x}))(x := y) else m|`D)"
   382 by (simp add: restrict_map_def fun_eq_iff)
   383 
   384 lemma fun_upd_None_restrict [simp]:
   385   "(m|`D)(x := None) = (if x \<in> D then m|`(D - {x}) else m|`D)"
   386 by (simp add: restrict_map_def fun_eq_iff)
   387 
   388 lemma fun_upd_restrict: "(m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   389 by (simp add: restrict_map_def fun_eq_iff)
   390 
   391 lemma fun_upd_restrict_conv [simp]:
   392   "x \<in> D \<Longrightarrow> (m|`D)(x := y) = (m|`(D-{x}))(x := y)"
   393 by (simp add: restrict_map_def fun_eq_iff)
   394 
   395 lemma map_of_map_restrict:
   396   "map_of (map (\<lambda>k. (k, f k)) ks) = (Some \<circ> f) |` set ks"
   397   by (induct ks) (simp_all add: fun_eq_iff restrict_map_insert)
   398 
   399 lemma restrict_complement_singleton_eq:
   400   "f |` (- {x}) = f(x := None)"
   401   by (simp add: restrict_map_def fun_eq_iff)
   402 
   403 
   404 subsection \<open>@{term [source] map_upds}\<close>
   405 
   406 lemma map_upds_Nil1 [simp]: "m([] [\<mapsto>] bs) = m"
   407 by (simp add: map_upds_def)
   408 
   409 lemma map_upds_Nil2 [simp]: "m(as [\<mapsto>] []) = m"
   410 by (simp add:map_upds_def)
   411 
   412 lemma map_upds_Cons [simp]: "m(a#as [\<mapsto>] b#bs) = (m(a\<mapsto>b))(as[\<mapsto>]bs)"
   413 by (simp add:map_upds_def)
   414 
   415 lemma map_upds_append1 [simp]: "size xs < size ys \<Longrightarrow>
   416   m(xs@[x] [\<mapsto>] ys) = m(xs [\<mapsto>] ys)(x \<mapsto> ys!size xs)"
   417 apply(induct xs arbitrary: ys m)
   418  apply (clarsimp simp add: neq_Nil_conv)
   419 apply (case_tac ys)
   420  apply simp
   421 apply simp
   422 done
   423 
   424 lemma map_upds_list_update2_drop [simp]:
   425   "size xs \<le> i \<Longrightarrow> m(xs[\<mapsto>]ys[i:=y]) = m(xs[\<mapsto>]ys)"
   426 apply (induct xs arbitrary: m ys i)
   427  apply simp
   428 apply (case_tac ys)
   429  apply simp
   430 apply (simp split: nat.split)
   431 done
   432 
   433 lemma map_upd_upds_conv_if:
   434   "(f(x\<mapsto>y))(xs [\<mapsto>] ys) =
   435    (if x \<in> set(take (length ys) xs) then f(xs [\<mapsto>] ys)
   436                                     else (f(xs [\<mapsto>] ys))(x\<mapsto>y))"
   437 apply (induct xs arbitrary: x y ys f)
   438  apply simp
   439 apply (case_tac ys)
   440  apply (auto split: split_if simp: fun_upd_twist)
   441 done
   442 
   443 lemma map_upds_twist [simp]:
   444   "a \<notin> set as \<Longrightarrow> m(a\<mapsto>b)(as[\<mapsto>]bs) = m(as[\<mapsto>]bs)(a\<mapsto>b)"
   445 using set_take_subset by (fastforce simp add: map_upd_upds_conv_if)
   446 
   447 lemma map_upds_apply_nontin [simp]:
   448   "x \<notin> set xs \<Longrightarrow> (f(xs[\<mapsto>]ys)) x = f x"
   449 apply (induct xs arbitrary: ys)
   450  apply simp
   451 apply (case_tac ys)
   452  apply (auto simp: map_upd_upds_conv_if)
   453 done
   454 
   455 lemma fun_upds_append_drop [simp]:
   456   "size xs = size ys \<Longrightarrow> m(xs@zs[\<mapsto>]ys) = m(xs[\<mapsto>]ys)"
   457 apply (induct xs arbitrary: m ys)
   458  apply simp
   459 apply (case_tac ys)
   460  apply simp_all
   461 done
   462 
   463 lemma fun_upds_append2_drop [simp]:
   464   "size xs = size ys \<Longrightarrow> m(xs[\<mapsto>]ys@zs) = m(xs[\<mapsto>]ys)"
   465 apply (induct xs arbitrary: m ys)
   466  apply simp
   467 apply (case_tac ys)
   468  apply simp_all
   469 done
   470 
   471 
   472 lemma restrict_map_upds[simp]:
   473   "\<lbrakk> length xs = length ys; set xs \<subseteq> D \<rbrakk>
   474     \<Longrightarrow> m(xs [\<mapsto>] ys)|`D = (m|`(D - set xs))(xs [\<mapsto>] ys)"
   475 apply (induct xs arbitrary: m ys)
   476  apply simp
   477 apply (case_tac ys)
   478  apply simp
   479 apply (simp add: Diff_insert [symmetric] insert_absorb)
   480 apply (simp add: map_upd_upds_conv_if)
   481 done
   482 
   483 
   484 subsection \<open>@{term [source] dom}\<close>
   485 
   486 lemma dom_eq_empty_conv [simp]: "dom f = {} \<longleftrightarrow> f = empty"
   487   by (auto simp: dom_def)
   488 
   489 lemma domI: "m a = Some b \<Longrightarrow> a \<in> dom m"
   490   by (simp add: dom_def)
   491 (* declare domI [intro]? *)
   492 
   493 lemma domD: "a \<in> dom m \<Longrightarrow> \<exists>b. m a = Some b"
   494   by (cases "m a") (auto simp add: dom_def)
   495 
   496 lemma domIff [iff, simp del]: "a \<in> dom m \<longleftrightarrow> m a \<noteq> None"
   497   by (simp add: dom_def)
   498 
   499 lemma dom_empty [simp]: "dom empty = {}"
   500   by (simp add: dom_def)
   501 
   502 lemma dom_fun_upd [simp]:
   503   "dom(f(x := y)) = (if y = None then dom f - {x} else insert x (dom f))"
   504   by (auto simp: dom_def)
   505 
   506 lemma dom_if:
   507   "dom (\<lambda>x. if P x then f x else g x) = dom f \<inter> {x. P x} \<union> dom g \<inter> {x. \<not> P x}"
   508   by (auto split: if_splits)
   509 
   510 lemma dom_map_of_conv_image_fst:
   511   "dom (map_of xys) = fst ` set xys"
   512   by (induct xys) (auto simp add: dom_if)
   513 
   514 lemma dom_map_of_zip [simp]: "length xs = length ys \<Longrightarrow> dom (map_of (zip xs ys)) = set xs"
   515   by (induct rule: list_induct2) (auto simp: dom_if)
   516 
   517 lemma finite_dom_map_of: "finite (dom (map_of l))"
   518   by (induct l) (auto simp: dom_def insert_Collect [symmetric])
   519 
   520 lemma dom_map_upds [simp]:
   521   "dom(m(xs[\<mapsto>]ys)) = set(take (length ys) xs) \<union> dom m"
   522 apply (induct xs arbitrary: m ys)
   523  apply simp
   524 apply (case_tac ys)
   525  apply auto
   526 done
   527 
   528 lemma dom_map_add [simp]: "dom (m ++ n) = dom n \<union> dom m"
   529   by (auto simp: dom_def)
   530 
   531 lemma dom_override_on [simp]:
   532   "dom (override_on f g A) =
   533     (dom f  - {a. a \<in> A - dom g}) \<union> {a. a \<in> A \<inter> dom g}"
   534   by (auto simp: dom_def override_on_def)
   535 
   536 lemma map_add_comm: "dom m1 \<inter> dom m2 = {} \<Longrightarrow> m1 ++ m2 = m2 ++ m1"
   537   by (rule ext) (force simp: map_add_def dom_def split: option.split)
   538 
   539 lemma map_add_dom_app_simps:
   540   "m \<in> dom l2 \<Longrightarrow> (l1 ++ l2) m = l2 m"
   541   "m \<notin> dom l1 \<Longrightarrow> (l1 ++ l2) m = l2 m"
   542   "m \<notin> dom l2 \<Longrightarrow> (l1 ++ l2) m = l1 m"
   543   by (auto simp add: map_add_def split: option.split_asm)
   544 
   545 lemma dom_const [simp]:
   546   "dom (\<lambda>x. Some (f x)) = UNIV"
   547   by auto
   548 
   549 (* Due to John Matthews - could be rephrased with dom *)
   550 lemma finite_map_freshness:
   551   "finite (dom (f :: 'a \<rightharpoonup> 'b)) \<Longrightarrow> \<not> finite (UNIV :: 'a set) \<Longrightarrow>
   552    \<exists>x. f x = None"
   553   by (bestsimp dest: ex_new_if_finite)
   554 
   555 lemma dom_minus:
   556   "f x = None \<Longrightarrow> dom f - insert x A = dom f - A"
   557   unfolding dom_def by simp
   558 
   559 lemma insert_dom:
   560   "f x = Some y \<Longrightarrow> insert x (dom f) = dom f"
   561   unfolding dom_def by auto
   562 
   563 lemma map_of_map_keys:
   564   "set xs = dom m \<Longrightarrow> map_of (map (\<lambda>k. (k, the (m k))) xs) = m"
   565   by (rule ext) (auto simp add: map_of_map_restrict restrict_map_def)
   566 
   567 lemma map_of_eqI:
   568   assumes set_eq: "set (map fst xs) = set (map fst ys)"
   569   assumes map_eq: "\<forall>k\<in>set (map fst xs). map_of xs k = map_of ys k"
   570   shows "map_of xs = map_of ys"
   571 proof (rule ext)
   572   fix k show "map_of xs k = map_of ys k"
   573   proof (cases "map_of xs k")
   574     case None
   575     then have "k \<notin> set (map fst xs)" by (simp add: map_of_eq_None_iff)
   576     with set_eq have "k \<notin> set (map fst ys)" by simp
   577     then have "map_of ys k = None" by (simp add: map_of_eq_None_iff)
   578     with None show ?thesis by simp
   579   next
   580     case (Some v)
   581     then have "k \<in> set (map fst xs)" by (auto simp add: dom_map_of_conv_image_fst [symmetric])
   582     with map_eq show ?thesis by auto
   583   qed
   584 qed
   585 
   586 lemma map_of_eq_dom:
   587   assumes "map_of xs = map_of ys"
   588   shows "fst ` set xs = fst ` set ys"
   589 proof -
   590   from assms have "dom (map_of xs) = dom (map_of ys)" by simp
   591   then show ?thesis by (simp add: dom_map_of_conv_image_fst)
   592 qed
   593 
   594 lemma finite_set_of_finite_maps:
   595   assumes "finite A" "finite B"
   596   shows "finite {m. dom m = A \<and> ran m \<subseteq> B}" (is "finite ?S")
   597 proof -
   598   let ?S' = "{m. \<forall>x. (x \<in> A \<longrightarrow> m x \<in> Some ` B) \<and> (x \<notin> A \<longrightarrow> m x = None)}"
   599   have "?S = ?S'"
   600   proof
   601     show "?S \<subseteq> ?S'" by (auto simp: dom_def ran_def image_def)
   602     show "?S' \<subseteq> ?S"
   603     proof
   604       fix m assume "m \<in> ?S'"
   605       hence 1: "dom m = A" by force
   606       hence 2: "ran m \<subseteq> B" using \<open>m \<in> ?S'\<close> by (auto simp: dom_def ran_def)
   607       from 1 2 show "m \<in> ?S" by blast
   608     qed
   609   qed
   610   with assms show ?thesis by(simp add: finite_set_of_finite_funs)
   611 qed
   612 
   613 
   614 subsection \<open>@{term [source] ran}\<close>
   615 
   616 lemma ranI: "m a = Some b \<Longrightarrow> b \<in> ran m"
   617   by (auto simp: ran_def)
   618 (* declare ranI [intro]? *)
   619 
   620 lemma ran_empty [simp]: "ran empty = {}"
   621   by (auto simp: ran_def)
   622 
   623 lemma ran_map_upd [simp]: "m a = None \<Longrightarrow> ran(m(a\<mapsto>b)) = insert b (ran m)"
   624   unfolding ran_def
   625 apply auto
   626 apply (subgoal_tac "aa \<noteq> a")
   627  apply auto
   628 done
   629 
   630 lemma ran_distinct:
   631   assumes dist: "distinct (map fst al)"
   632   shows "ran (map_of al) = snd ` set al"
   633   using assms
   634 proof (induct al)
   635   case Nil
   636   then show ?case by simp
   637 next
   638   case (Cons kv al)
   639   then have "ran (map_of al) = snd ` set al" by simp
   640   moreover from Cons.prems have "map_of al (fst kv) = None"
   641     by (simp add: map_of_eq_None_iff)
   642   ultimately show ?case by (simp only: map_of.simps ran_map_upd) simp
   643 qed
   644 
   645 lemma ran_map_option: "ran (\<lambda>x. map_option f (m x)) = f ` ran m"
   646   by (auto simp add: ran_def)
   647 
   648 
   649 subsection \<open>@{text "map_le"}\<close>
   650 
   651 lemma map_le_empty [simp]: "empty \<subseteq>\<^sub>m g"
   652   by (simp add: map_le_def)
   653 
   654 lemma upd_None_map_le [simp]: "f(x := None) \<subseteq>\<^sub>m f"
   655   by (force simp add: map_le_def)
   656 
   657 lemma map_le_upd[simp]: "f \<subseteq>\<^sub>m g ==> f(a := b) \<subseteq>\<^sub>m g(a := b)"
   658   by (fastforce simp add: map_le_def)
   659 
   660 lemma map_le_imp_upd_le [simp]: "m1 \<subseteq>\<^sub>m m2 \<Longrightarrow> m1(x := None) \<subseteq>\<^sub>m m2(x \<mapsto> y)"
   661   by (force simp add: map_le_def)
   662 
   663 lemma map_le_upds [simp]:
   664   "f \<subseteq>\<^sub>m g \<Longrightarrow> f(as [\<mapsto>] bs) \<subseteq>\<^sub>m g(as [\<mapsto>] bs)"
   665 apply (induct as arbitrary: f g bs)
   666  apply simp
   667 apply (case_tac bs)
   668  apply auto
   669 done
   670 
   671 lemma map_le_implies_dom_le: "(f \<subseteq>\<^sub>m g) \<Longrightarrow> (dom f \<subseteq> dom g)"
   672   by (fastforce simp add: map_le_def dom_def)
   673 
   674 lemma map_le_refl [simp]: "f \<subseteq>\<^sub>m f"
   675   by (simp add: map_le_def)
   676 
   677 lemma map_le_trans[trans]: "\<lbrakk> m1 \<subseteq>\<^sub>m m2; m2 \<subseteq>\<^sub>m m3\<rbrakk> \<Longrightarrow> m1 \<subseteq>\<^sub>m m3"
   678   by (auto simp add: map_le_def dom_def)
   679 
   680 lemma map_le_antisym: "\<lbrakk> f \<subseteq>\<^sub>m g; g \<subseteq>\<^sub>m f \<rbrakk> \<Longrightarrow> f = g"
   681 unfolding map_le_def
   682 apply (rule ext)
   683 apply (case_tac "x \<in> dom f", simp)
   684 apply (case_tac "x \<in> dom g", simp, fastforce)
   685 done
   686 
   687 lemma map_le_map_add [simp]: "f \<subseteq>\<^sub>m g ++ f"
   688   by (fastforce simp: map_le_def)
   689 
   690 lemma map_le_iff_map_add_commute: "f \<subseteq>\<^sub>m f ++ g \<longleftrightarrow> f ++ g = g ++ f"
   691   by (fastforce simp: map_add_def map_le_def fun_eq_iff split: option.splits)
   692 
   693 lemma map_add_le_mapE: "f ++ g \<subseteq>\<^sub>m h \<Longrightarrow> g \<subseteq>\<^sub>m h"
   694   by (fastforce simp: map_le_def map_add_def dom_def)
   695 
   696 lemma map_add_le_mapI: "\<lbrakk> f \<subseteq>\<^sub>m h; g \<subseteq>\<^sub>m h \<rbrakk> \<Longrightarrow> f ++ g \<subseteq>\<^sub>m h"
   697   by (auto simp: map_le_def map_add_def dom_def split: option.splits)
   698 
   699 lemma dom_eq_singleton_conv: "dom f = {x} \<longleftrightarrow> (\<exists>v. f = [x \<mapsto> v])"
   700 proof(rule iffI)
   701   assume "\<exists>v. f = [x \<mapsto> v]"
   702   thus "dom f = {x}" by(auto split: split_if_asm)
   703 next
   704   assume "dom f = {x}"
   705   then obtain v where "f x = Some v" by auto
   706   hence "[x \<mapsto> v] \<subseteq>\<^sub>m f" by(auto simp add: map_le_def)
   707   moreover have "f \<subseteq>\<^sub>m [x \<mapsto> v]" using \<open>dom f = {x}\<close> \<open>f x = Some v\<close>
   708     by(auto simp add: map_le_def)
   709   ultimately have "f = [x \<mapsto> v]" by-(rule map_le_antisym)
   710   thus "\<exists>v. f = [x \<mapsto> v]" by blast
   711 qed
   712 
   713 
   714 subsection \<open>Various\<close>
   715 
   716 lemma set_map_of_compr:
   717   assumes distinct: "distinct (map fst xs)"
   718   shows "set xs = {(k, v). map_of xs k = Some v}"
   719   using assms
   720 proof (induct xs)
   721   case Nil
   722   then show ?case by simp
   723 next
   724   case (Cons x xs)
   725   obtain k v where "x = (k, v)" by (cases x) blast
   726   with Cons.prems have "k \<notin> dom (map_of xs)"
   727     by (simp add: dom_map_of_conv_image_fst)
   728   then have *: "insert (k, v) {(k, v). map_of xs k = Some v} =
   729     {(k', v'). (map_of xs(k \<mapsto> v)) k' = Some v'}"
   730     by (auto split: if_splits)
   731   from Cons have "set xs = {(k, v). map_of xs k = Some v}" by simp
   732   with * \<open>x = (k, v)\<close> show ?case by simp
   733 qed
   734 
   735 lemma map_of_inject_set:
   736   assumes distinct: "distinct (map fst xs)" "distinct (map fst ys)"
   737   shows "map_of xs = map_of ys \<longleftrightarrow> set xs = set ys" (is "?lhs \<longleftrightarrow> ?rhs")
   738 proof
   739   assume ?lhs
   740   moreover from \<open>distinct (map fst xs)\<close> have "set xs = {(k, v). map_of xs k = Some v}"
   741     by (rule set_map_of_compr)
   742   moreover from \<open>distinct (map fst ys)\<close> have "set ys = {(k, v). map_of ys k = Some v}"
   743     by (rule set_map_of_compr)
   744   ultimately show ?rhs by simp
   745 next
   746   assume ?rhs show ?lhs
   747   proof
   748     fix k
   749     show "map_of xs k = map_of ys k"
   750     proof (cases "map_of xs k")
   751       case None
   752       with \<open>?rhs\<close> have "map_of ys k = None"
   753         by (simp add: map_of_eq_None_iff)
   754       with None show ?thesis by simp
   755     next
   756       case (Some v)
   757       with distinct \<open>?rhs\<close> have "map_of ys k = Some v"
   758         by simp
   759       with Some show ?thesis by simp
   760     qed
   761   qed
   762 qed
   763 
   764 end