src/HOL/Real/RealDef.thy
author huffman
Mon May 14 18:48:24 2007 +0200 (2007-05-14)
changeset 22970 b5910e3dec4c
parent 22962 4bb05ba38939
child 23031 9da9585c816e
permissions -rw-r--r--
move lemmas to RealPow.thy; tuned proofs
     1 (*  Title       : Real/RealDef.thy
     2     ID          : $Id$
     3     Author      : Jacques D. Fleuriot
     4     Copyright   : 1998  University of Cambridge
     5     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     6     Additional contributions by Jeremy Avigad
     7 *)
     8 
     9 header{*Defining the Reals from the Positive Reals*}
    10 
    11 theory RealDef
    12 imports PReal
    13 uses ("real_arith.ML")
    14 begin
    15 
    16 definition
    17   realrel   ::  "((preal * preal) * (preal * preal)) set" where
    18   "realrel = {p. \<exists>x1 y1 x2 y2. p = ((x1,y1),(x2,y2)) & x1+y2 = x2+y1}"
    19 
    20 typedef (Real)  real = "UNIV//realrel"
    21   by (auto simp add: quotient_def)
    22 
    23 instance real :: "{ord, zero, one, plus, times, minus, inverse}" ..
    24 
    25 definition
    26 
    27   (** these don't use the overloaded "real" function: users don't see them **)
    28 
    29   real_of_preal :: "preal => real" where
    30   "real_of_preal m = Abs_Real(realrel``{(m + preal_of_rat 1, preal_of_rat 1)})"
    31 
    32 consts
    33    (*overloaded constant for injecting other types into "real"*)
    34    real :: "'a => real"
    35 
    36 
    37 defs (overloaded)
    38 
    39   real_zero_def:
    40   "0 == Abs_Real(realrel``{(preal_of_rat 1, preal_of_rat 1)})"
    41 
    42   real_one_def:
    43   "1 == Abs_Real(realrel``
    44                {(preal_of_rat 1 + preal_of_rat 1,
    45 		 preal_of_rat 1)})"
    46 
    47   real_minus_def:
    48   "- r ==  contents (\<Union>(x,y) \<in> Rep_Real(r). { Abs_Real(realrel``{(y,x)}) })"
    49 
    50   real_add_def:
    51    "z + w ==
    52        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    53 		 { Abs_Real(realrel``{(x+u, y+v)}) })"
    54 
    55   real_diff_def:
    56    "r - (s::real) == r + - s"
    57 
    58   real_mult_def:
    59     "z * w ==
    60        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    61 		 { Abs_Real(realrel``{(x*u + y*v, x*v + y*u)}) })"
    62 
    63   real_inverse_def:
    64   "inverse (R::real) == (SOME S. (R = 0 & S = 0) | S * R = 1)"
    65 
    66   real_divide_def:
    67   "R / (S::real) == R * inverse S"
    68 
    69   real_le_def:
    70    "z \<le> (w::real) == 
    71     \<exists>x y u v. x+v \<le> u+y & (x,y) \<in> Rep_Real z & (u,v) \<in> Rep_Real w"
    72 
    73   real_less_def: "(x < (y::real)) == (x \<le> y & x \<noteq> y)"
    74 
    75   real_abs_def:  "abs (r::real) == (if r < 0 then - r else r)"
    76 
    77 
    78 
    79 subsection{*Proving that realrel is an equivalence relation*}
    80 
    81 lemma preal_trans_lemma:
    82   assumes "x + y1 = x1 + y"
    83       and "x + y2 = x2 + y"
    84   shows "x1 + y2 = x2 + (y1::preal)"
    85 proof -
    86   have "(x1 + y2) + x = (x + y2) + x1" by (simp add: preal_add_ac) 
    87   also have "... = (x2 + y) + x1"  by (simp add: prems)
    88   also have "... = x2 + (x1 + y)"  by (simp add: preal_add_ac)
    89   also have "... = x2 + (x + y1)"  by (simp add: prems)
    90   also have "... = (x2 + y1) + x"  by (simp add: preal_add_ac)
    91   finally have "(x1 + y2) + x = (x2 + y1) + x" .
    92   thus ?thesis by (simp add: preal_add_right_cancel_iff) 
    93 qed
    94 
    95 
    96 lemma realrel_iff [simp]: "(((x1,y1),(x2,y2)) \<in> realrel) = (x1 + y2 = x2 + y1)"
    97 by (simp add: realrel_def)
    98 
    99 lemma equiv_realrel: "equiv UNIV realrel"
   100 apply (auto simp add: equiv_def refl_def sym_def trans_def realrel_def)
   101 apply (blast dest: preal_trans_lemma) 
   102 done
   103 
   104 text{*Reduces equality of equivalence classes to the @{term realrel} relation:
   105   @{term "(realrel `` {x} = realrel `` {y}) = ((x,y) \<in> realrel)"} *}
   106 lemmas equiv_realrel_iff = 
   107        eq_equiv_class_iff [OF equiv_realrel UNIV_I UNIV_I]
   108 
   109 declare equiv_realrel_iff [simp]
   110 
   111 
   112 lemma realrel_in_real [simp]: "realrel``{(x,y)}: Real"
   113 by (simp add: Real_def realrel_def quotient_def, blast)
   114 
   115 declare Abs_Real_inject [simp]
   116 declare Abs_Real_inverse [simp]
   117 
   118 
   119 text{*Case analysis on the representation of a real number as an equivalence
   120       class of pairs of positive reals.*}
   121 lemma eq_Abs_Real [case_names Abs_Real, cases type: real]: 
   122      "(!!x y. z = Abs_Real(realrel``{(x,y)}) ==> P) ==> P"
   123 apply (rule Rep_Real [of z, unfolded Real_def, THEN quotientE])
   124 apply (drule arg_cong [where f=Abs_Real])
   125 apply (auto simp add: Rep_Real_inverse)
   126 done
   127 
   128 
   129 subsection{*Congruence property for addition*}
   130 
   131 lemma real_add_congruent2_lemma:
   132      "[|a + ba = aa + b; ab + bc = ac + bb|]
   133       ==> a + ab + (ba + bc) = aa + ac + (b + (bb::preal))"
   134 apply (simp add: preal_add_assoc) 
   135 apply (rule preal_add_left_commute [of ab, THEN ssubst])
   136 apply (simp add: preal_add_assoc [symmetric])
   137 apply (simp add: preal_add_ac)
   138 done
   139 
   140 lemma real_add:
   141      "Abs_Real (realrel``{(x,y)}) + Abs_Real (realrel``{(u,v)}) =
   142       Abs_Real (realrel``{(x+u, y+v)})"
   143 proof -
   144   have "(\<lambda>z w. (\<lambda>(x,y). (\<lambda>(u,v). {Abs_Real (realrel `` {(x+u, y+v)})}) w) z)
   145         respects2 realrel"
   146     by (simp add: congruent2_def, blast intro: real_add_congruent2_lemma) 
   147   thus ?thesis
   148     by (simp add: real_add_def UN_UN_split_split_eq
   149                   UN_equiv_class2 [OF equiv_realrel equiv_realrel])
   150 qed
   151 
   152 lemma real_add_commute: "(z::real) + w = w + z"
   153 by (cases z, cases w, simp add: real_add preal_add_ac)
   154 
   155 lemma real_add_assoc: "((z1::real) + z2) + z3 = z1 + (z2 + z3)"
   156 by (cases z1, cases z2, cases z3, simp add: real_add preal_add_assoc)
   157 
   158 lemma real_add_zero_left: "(0::real) + z = z"
   159 by (cases z, simp add: real_add real_zero_def preal_add_ac)
   160 
   161 instance real :: comm_monoid_add
   162   by (intro_classes,
   163       (assumption | 
   164        rule real_add_commute real_add_assoc real_add_zero_left)+)
   165 
   166 
   167 subsection{*Additive Inverse on real*}
   168 
   169 lemma real_minus: "- Abs_Real(realrel``{(x,y)}) = Abs_Real(realrel `` {(y,x)})"
   170 proof -
   171   have "(\<lambda>(x,y). {Abs_Real (realrel``{(y,x)})}) respects realrel"
   172     by (simp add: congruent_def preal_add_commute) 
   173   thus ?thesis
   174     by (simp add: real_minus_def UN_equiv_class [OF equiv_realrel])
   175 qed
   176 
   177 lemma real_add_minus_left: "(-z) + z = (0::real)"
   178 by (cases z, simp add: real_minus real_add real_zero_def preal_add_commute)
   179 
   180 
   181 subsection{*Congruence property for multiplication*}
   182 
   183 lemma real_mult_congruent2_lemma:
   184      "!!(x1::preal). [| x1 + y2 = x2 + y1 |] ==>
   185           x * x1 + y * y1 + (x * y2 + y * x2) =
   186           x * x2 + y * y2 + (x * y1 + y * x1)"
   187 apply (simp add: preal_add_left_commute preal_add_assoc [symmetric])
   188 apply (simp add: preal_add_assoc preal_add_mult_distrib2 [symmetric])
   189 apply (simp add: preal_add_commute)
   190 done
   191 
   192 lemma real_mult_congruent2:
   193     "(%p1 p2.
   194         (%(x1,y1). (%(x2,y2). 
   195           { Abs_Real (realrel``{(x1*x2 + y1*y2, x1*y2+y1*x2)}) }) p2) p1)
   196      respects2 realrel"
   197 apply (rule congruent2_commuteI [OF equiv_realrel], clarify)
   198 apply (simp add: preal_mult_commute preal_add_commute)
   199 apply (auto simp add: real_mult_congruent2_lemma)
   200 done
   201 
   202 lemma real_mult:
   203       "Abs_Real((realrel``{(x1,y1)})) * Abs_Real((realrel``{(x2,y2)})) =
   204        Abs_Real(realrel `` {(x1*x2+y1*y2,x1*y2+y1*x2)})"
   205 by (simp add: real_mult_def UN_UN_split_split_eq
   206          UN_equiv_class2 [OF equiv_realrel equiv_realrel real_mult_congruent2])
   207 
   208 lemma real_mult_commute: "(z::real) * w = w * z"
   209 by (cases z, cases w, simp add: real_mult preal_add_ac preal_mult_ac)
   210 
   211 lemma real_mult_assoc: "((z1::real) * z2) * z3 = z1 * (z2 * z3)"
   212 apply (cases z1, cases z2, cases z3)
   213 apply (simp add: real_mult preal_add_mult_distrib2 preal_add_ac preal_mult_ac)
   214 done
   215 
   216 lemma real_mult_1: "(1::real) * z = z"
   217 apply (cases z)
   218 apply (simp add: real_mult real_one_def preal_add_mult_distrib2
   219                  preal_mult_1_right preal_mult_ac preal_add_ac)
   220 done
   221 
   222 lemma real_add_mult_distrib: "((z1::real) + z2) * w = (z1 * w) + (z2 * w)"
   223 apply (cases z1, cases z2, cases w)
   224 apply (simp add: real_add real_mult preal_add_mult_distrib2 
   225                  preal_add_ac preal_mult_ac)
   226 done
   227 
   228 text{*one and zero are distinct*}
   229 lemma real_zero_not_eq_one: "0 \<noteq> (1::real)"
   230 proof -
   231   have "preal_of_rat 1 < preal_of_rat 1 + preal_of_rat 1"
   232     by (simp add: preal_self_less_add_left) 
   233   thus ?thesis
   234     by (simp add: real_zero_def real_one_def preal_add_right_cancel_iff)
   235 qed
   236 
   237 subsection{*existence of inverse*}
   238 
   239 lemma real_zero_iff: "Abs_Real (realrel `` {(x, x)}) = 0"
   240 by (simp add: real_zero_def preal_add_commute)
   241 
   242 text{*Instead of using an existential quantifier and constructing the inverse
   243 within the proof, we could define the inverse explicitly.*}
   244 
   245 lemma real_mult_inverse_left_ex: "x \<noteq> 0 ==> \<exists>y. y*x = (1::real)"
   246 apply (simp add: real_zero_def real_one_def, cases x)
   247 apply (cut_tac x = xa and y = y in linorder_less_linear)
   248 apply (auto dest!: less_add_left_Ex simp add: real_zero_iff)
   249 apply (rule_tac
   250         x = "Abs_Real (realrel `` { (preal_of_rat 1, 
   251                             inverse (D) + preal_of_rat 1)}) " 
   252        in exI)
   253 apply (rule_tac [2]
   254         x = "Abs_Real (realrel `` { (inverse (D) + preal_of_rat 1,
   255                    preal_of_rat 1)})" 
   256        in exI)
   257 apply (auto simp add: real_mult preal_mult_1_right
   258               preal_add_mult_distrib2 preal_add_mult_distrib preal_mult_1
   259               preal_mult_inverse_right preal_add_ac preal_mult_ac)
   260 done
   261 
   262 lemma real_mult_inverse_left: "x \<noteq> 0 ==> inverse(x)*x = (1::real)"
   263 apply (simp add: real_inverse_def)
   264 apply (frule real_mult_inverse_left_ex, safe)
   265 apply (rule someI2, auto)
   266 done
   267 
   268 
   269 subsection{*The Real Numbers form a Field*}
   270 
   271 instance real :: field
   272 proof
   273   fix x y z :: real
   274   show "- x + x = 0" by (rule real_add_minus_left)
   275   show "x - y = x + (-y)" by (simp add: real_diff_def)
   276   show "(x * y) * z = x * (y * z)" by (rule real_mult_assoc)
   277   show "x * y = y * x" by (rule real_mult_commute)
   278   show "1 * x = x" by (rule real_mult_1)
   279   show "(x + y) * z = x * z + y * z" by (simp add: real_add_mult_distrib)
   280   show "0 \<noteq> (1::real)" by (rule real_zero_not_eq_one)
   281   show "x \<noteq> 0 ==> inverse x * x = 1" by (rule real_mult_inverse_left)
   282   show "x / y = x * inverse y" by (simp add: real_divide_def)
   283 qed
   284 
   285 
   286 text{*Inverse of zero!  Useful to simplify certain equations*}
   287 
   288 lemma INVERSE_ZERO: "inverse 0 = (0::real)"
   289 by (simp add: real_inverse_def)
   290 
   291 instance real :: division_by_zero
   292 proof
   293   show "inverse 0 = (0::real)" by (rule INVERSE_ZERO)
   294 qed
   295 
   296 
   297 subsection{*The @{text "\<le>"} Ordering*}
   298 
   299 lemma real_le_refl: "w \<le> (w::real)"
   300 by (cases w, force simp add: real_le_def)
   301 
   302 text{*The arithmetic decision procedure is not set up for type preal.
   303   This lemma is currently unused, but it could simplify the proofs of the
   304   following two lemmas.*}
   305 lemma preal_eq_le_imp_le:
   306   assumes eq: "a+b = c+d" and le: "c \<le> a"
   307   shows "b \<le> (d::preal)"
   308 proof -
   309   have "c+d \<le> a+d" by (simp add: prems preal_cancels)
   310   hence "a+b \<le> a+d" by (simp add: prems)
   311   thus "b \<le> d" by (simp add: preal_cancels)
   312 qed
   313 
   314 lemma real_le_lemma:
   315   assumes l: "u1 + v2 \<le> u2 + v1"
   316       and "x1 + v1 = u1 + y1"
   317       and "x2 + v2 = u2 + y2"
   318   shows "x1 + y2 \<le> x2 + (y1::preal)"
   319 proof -
   320   have "(x1+v1) + (u2+y2) = (u1+y1) + (x2+v2)" by (simp add: prems)
   321   hence "(x1+y2) + (u2+v1) = (x2+y1) + (u1+v2)" by (simp add: preal_add_ac)
   322   also have "... \<le> (x2+y1) + (u2+v1)"
   323          by (simp add: prems preal_add_le_cancel_left)
   324   finally show ?thesis by (simp add: preal_add_le_cancel_right)
   325 qed						 
   326 
   327 lemma real_le: 
   328      "(Abs_Real(realrel``{(x1,y1)}) \<le> Abs_Real(realrel``{(x2,y2)})) =  
   329       (x1 + y2 \<le> x2 + y1)"
   330 apply (simp add: real_le_def) 
   331 apply (auto intro: real_le_lemma)
   332 done
   333 
   334 lemma real_le_anti_sym: "[| z \<le> w; w \<le> z |] ==> z = (w::real)"
   335 by (cases z, cases w, simp add: real_le)
   336 
   337 lemma real_trans_lemma:
   338   assumes "x + v \<le> u + y"
   339       and "u + v' \<le> u' + v"
   340       and "x2 + v2 = u2 + y2"
   341   shows "x + v' \<le> u' + (y::preal)"
   342 proof -
   343   have "(x+v') + (u+v) = (x+v) + (u+v')" by (simp add: preal_add_ac)
   344   also have "... \<le> (u+y) + (u+v')" 
   345     by (simp add: preal_add_le_cancel_right prems) 
   346   also have "... \<le> (u+y) + (u'+v)" 
   347     by (simp add: preal_add_le_cancel_left prems) 
   348   also have "... = (u'+y) + (u+v)"  by (simp add: preal_add_ac)
   349   finally show ?thesis by (simp add: preal_add_le_cancel_right)
   350 qed
   351 
   352 lemma real_le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::real)"
   353 apply (cases i, cases j, cases k)
   354 apply (simp add: real_le)
   355 apply (blast intro: real_trans_lemma) 
   356 done
   357 
   358 (* Axiom 'order_less_le' of class 'order': *)
   359 lemma real_less_le: "((w::real) < z) = (w \<le> z & w \<noteq> z)"
   360 by (simp add: real_less_def)
   361 
   362 instance real :: order
   363 proof qed
   364  (assumption |
   365   rule real_le_refl real_le_trans real_le_anti_sym real_less_le)+
   366 
   367 (* Axiom 'linorder_linear' of class 'linorder': *)
   368 lemma real_le_linear: "(z::real) \<le> w | w \<le> z"
   369 apply (cases z, cases w) 
   370 apply (auto simp add: real_le real_zero_def preal_add_ac preal_cancels)
   371 done
   372 
   373 
   374 instance real :: linorder
   375   by (intro_classes, rule real_le_linear)
   376 
   377 
   378 lemma real_le_eq_diff: "(x \<le> y) = (x-y \<le> (0::real))"
   379 apply (cases x, cases y) 
   380 apply (auto simp add: real_le real_zero_def real_diff_def real_add real_minus
   381                       preal_add_ac)
   382 apply (simp_all add: preal_add_assoc [symmetric] preal_cancels)
   383 done
   384 
   385 lemma real_add_left_mono: 
   386   assumes le: "x \<le> y" shows "z + x \<le> z + (y::real)"
   387 proof -
   388   have "z + x - (z + y) = (z + -z) + (x - y)"
   389     by (simp add: diff_minus add_ac) 
   390   with le show ?thesis 
   391     by (simp add: real_le_eq_diff[of x] real_le_eq_diff[of "z+x"] diff_minus)
   392 qed
   393 
   394 lemma real_sum_gt_zero_less: "(0 < S + (-W::real)) ==> (W < S)"
   395 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   396 
   397 lemma real_less_sum_gt_zero: "(W < S) ==> (0 < S + (-W::real))"
   398 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   399 
   400 lemma real_mult_order: "[| 0 < x; 0 < y |] ==> (0::real) < x * y"
   401 apply (cases x, cases y)
   402 apply (simp add: linorder_not_le [where 'a = real, symmetric] 
   403                  linorder_not_le [where 'a = preal] 
   404                   real_zero_def real_le real_mult)
   405   --{*Reduce to the (simpler) @{text "\<le>"} relation *}
   406 apply (auto dest!: less_add_left_Ex
   407      simp add: preal_add_ac preal_mult_ac 
   408           preal_add_mult_distrib2 preal_cancels preal_self_less_add_left)
   409 done
   410 
   411 lemma real_mult_less_mono2: "[| (0::real) < z; x < y |] ==> z * x < z * y"
   412 apply (rule real_sum_gt_zero_less)
   413 apply (drule real_less_sum_gt_zero [of x y])
   414 apply (drule real_mult_order, assumption)
   415 apply (simp add: right_distrib)
   416 done
   417 
   418 instance real :: distrib_lattice
   419   "inf x y \<equiv> min x y"
   420   "sup x y \<equiv> max x y"
   421   by default (auto simp add: inf_real_def sup_real_def min_max.sup_inf_distrib1)
   422 
   423 
   424 subsection{*The Reals Form an Ordered Field*}
   425 
   426 instance real :: ordered_field
   427 proof
   428   fix x y z :: real
   429   show "x \<le> y ==> z + x \<le> z + y" by (rule real_add_left_mono)
   430   show "x < y ==> 0 < z ==> z * x < z * y" by (rule real_mult_less_mono2)
   431   show "\<bar>x\<bar> = (if x < 0 then -x else x)" by (simp only: real_abs_def)
   432 qed
   433 
   434 text{*The function @{term real_of_preal} requires many proofs, but it seems
   435 to be essential for proving completeness of the reals from that of the
   436 positive reals.*}
   437 
   438 lemma real_of_preal_add:
   439      "real_of_preal ((x::preal) + y) = real_of_preal x + real_of_preal y"
   440 by (simp add: real_of_preal_def real_add preal_add_mult_distrib preal_mult_1 
   441               preal_add_ac)
   442 
   443 lemma real_of_preal_mult:
   444      "real_of_preal ((x::preal) * y) = real_of_preal x* real_of_preal y"
   445 by (simp add: real_of_preal_def real_mult preal_add_mult_distrib2
   446               preal_mult_1 preal_mult_1_right preal_add_ac preal_mult_ac)
   447 
   448 
   449 text{*Gleason prop 9-4.4 p 127*}
   450 lemma real_of_preal_trichotomy:
   451       "\<exists>m. (x::real) = real_of_preal m | x = 0 | x = -(real_of_preal m)"
   452 apply (simp add: real_of_preal_def real_zero_def, cases x)
   453 apply (auto simp add: real_minus preal_add_ac)
   454 apply (cut_tac x = x and y = y in linorder_less_linear)
   455 apply (auto dest!: less_add_left_Ex simp add: preal_add_assoc [symmetric])
   456 done
   457 
   458 lemma real_of_preal_leD:
   459       "real_of_preal m1 \<le> real_of_preal m2 ==> m1 \<le> m2"
   460 by (simp add: real_of_preal_def real_le preal_cancels)
   461 
   462 lemma real_of_preal_lessI: "m1 < m2 ==> real_of_preal m1 < real_of_preal m2"
   463 by (auto simp add: real_of_preal_leD linorder_not_le [symmetric])
   464 
   465 lemma real_of_preal_lessD:
   466       "real_of_preal m1 < real_of_preal m2 ==> m1 < m2"
   467 by (simp add: real_of_preal_def real_le linorder_not_le [symmetric] 
   468               preal_cancels) 
   469 
   470 
   471 lemma real_of_preal_less_iff [simp]:
   472      "(real_of_preal m1 < real_of_preal m2) = (m1 < m2)"
   473 by (blast intro: real_of_preal_lessI real_of_preal_lessD)
   474 
   475 lemma real_of_preal_le_iff:
   476      "(real_of_preal m1 \<le> real_of_preal m2) = (m1 \<le> m2)"
   477 by (simp add: linorder_not_less [symmetric]) 
   478 
   479 lemma real_of_preal_zero_less: "0 < real_of_preal m"
   480 apply (auto simp add: real_zero_def real_of_preal_def real_less_def real_le_def
   481             preal_add_ac preal_cancels)
   482 apply (simp_all add: preal_add_assoc [symmetric] preal_cancels)
   483 apply (blast intro: preal_self_less_add_left order_less_imp_le)
   484 apply (insert preal_not_eq_self [of "preal_of_rat 1" m]) 
   485 apply (simp add: preal_add_ac) 
   486 done
   487 
   488 lemma real_of_preal_minus_less_zero: "- real_of_preal m < 0"
   489 by (simp add: real_of_preal_zero_less)
   490 
   491 lemma real_of_preal_not_minus_gt_zero: "~ 0 < - real_of_preal m"
   492 proof -
   493   from real_of_preal_minus_less_zero
   494   show ?thesis by (blast dest: order_less_trans)
   495 qed
   496 
   497 
   498 subsection{*Theorems About the Ordering*}
   499 
   500 text{*obsolete but used a lot*}
   501 
   502 lemma real_not_refl2: "x < y ==> x \<noteq> (y::real)"
   503 by blast 
   504 
   505 lemma real_le_imp_less_or_eq: "!!(x::real). x \<le> y ==> x < y | x = y"
   506 by (simp add: order_le_less)
   507 
   508 lemma real_gt_zero_preal_Ex: "(0 < x) = (\<exists>y. x = real_of_preal y)"
   509 apply (auto simp add: real_of_preal_zero_less)
   510 apply (cut_tac x = x in real_of_preal_trichotomy)
   511 apply (blast elim!: real_of_preal_not_minus_gt_zero [THEN notE])
   512 done
   513 
   514 lemma real_gt_preal_preal_Ex:
   515      "real_of_preal z < x ==> \<exists>y. x = real_of_preal y"
   516 by (blast dest!: real_of_preal_zero_less [THEN order_less_trans]
   517              intro: real_gt_zero_preal_Ex [THEN iffD1])
   518 
   519 lemma real_ge_preal_preal_Ex:
   520      "real_of_preal z \<le> x ==> \<exists>y. x = real_of_preal y"
   521 by (blast dest: order_le_imp_less_or_eq real_gt_preal_preal_Ex)
   522 
   523 lemma real_less_all_preal: "y \<le> 0 ==> \<forall>x. y < real_of_preal x"
   524 by (auto elim: order_le_imp_less_or_eq [THEN disjE] 
   525             intro: real_of_preal_zero_less [THEN [2] order_less_trans] 
   526             simp add: real_of_preal_zero_less)
   527 
   528 lemma real_less_all_real2: "~ 0 < y ==> \<forall>x. y < real_of_preal x"
   529 by (blast intro!: real_less_all_preal linorder_not_less [THEN iffD1])
   530 
   531 lemma real_le_square [simp]: "(0::real) \<le> x*x"
   532  by (rule Ring_and_Field.zero_le_square)
   533 
   534 
   535 subsection{*More Lemmas*}
   536 
   537 lemma real_mult_left_cancel: "(c::real) \<noteq> 0 ==> (c*a=c*b) = (a=b)"
   538 by auto
   539 
   540 lemma real_mult_right_cancel: "(c::real) \<noteq> 0 ==> (a*c=b*c) = (a=b)"
   541 by auto
   542 
   543 text{*The precondition could be weakened to @{term "0\<le>x"}*}
   544 lemma real_mult_less_mono:
   545      "[| u<v;  x<y;  (0::real) < v;  0 < x |] ==> u*x < v* y"
   546  by (simp add: Ring_and_Field.mult_strict_mono order_less_imp_le)
   547 
   548 lemma real_mult_less_iff1 [simp]: "(0::real) < z ==> (x*z < y*z) = (x < y)"
   549   by (force elim: order_less_asym
   550             simp add: Ring_and_Field.mult_less_cancel_right)
   551 
   552 lemma real_mult_le_cancel_iff1 [simp]: "(0::real) < z ==> (x*z \<le> y*z) = (x\<le>y)"
   553 apply (simp add: mult_le_cancel_right)
   554 apply (blast intro: elim: order_less_asym) 
   555 done
   556 
   557 lemma real_mult_le_cancel_iff2 [simp]: "(0::real) < z ==> (z*x \<le> z*y) = (x\<le>y)"
   558 by(simp add:mult_commute)
   559 
   560 lemma real_add_order: "[| 0 < x; 0 < y |] ==> (0::real) < x + y"
   561 by (rule add_pos_pos)
   562 
   563 lemma real_le_add_order: "[| 0 \<le> x; 0 \<le> y |] ==> (0::real) \<le> x + y"
   564 by (rule add_nonneg_nonneg)
   565 
   566 lemma real_inverse_unique: "x*y = (1::real) ==> y = inverse x"
   567 by (rule inverse_unique [symmetric])
   568 
   569 lemma real_inverse_gt_one: "[| (0::real) < x; x < 1 |] ==> 1 < inverse x"
   570 by (simp add: one_less_inverse_iff)
   571 
   572 
   573 subsection{*Embedding the Integers into the Reals*}
   574 
   575 defs (overloaded)
   576   real_of_nat_def: "real z == of_nat z"
   577   real_of_int_def: "real z == of_int z"
   578 
   579 lemma real_eq_of_nat: "real = of_nat"
   580   apply (rule ext)
   581   apply (unfold real_of_nat_def)
   582   apply (rule refl)
   583   done
   584 
   585 lemma real_eq_of_int: "real = of_int"
   586   apply (rule ext)
   587   apply (unfold real_of_int_def)
   588   apply (rule refl)
   589   done
   590 
   591 lemma real_of_int_zero [simp]: "real (0::int) = 0"  
   592 by (simp add: real_of_int_def) 
   593 
   594 lemma real_of_one [simp]: "real (1::int) = (1::real)"
   595 by (simp add: real_of_int_def) 
   596 
   597 lemma real_of_int_add [simp]: "real(x + y) = real (x::int) + real y"
   598 by (simp add: real_of_int_def) 
   599 
   600 lemma real_of_int_minus [simp]: "real(-x) = -real (x::int)"
   601 by (simp add: real_of_int_def) 
   602 
   603 lemma real_of_int_diff [simp]: "real(x - y) = real (x::int) - real y"
   604 by (simp add: real_of_int_def) 
   605 
   606 lemma real_of_int_mult [simp]: "real(x * y) = real (x::int) * real y"
   607 by (simp add: real_of_int_def) 
   608 
   609 lemma real_of_int_setsum [simp]: "real ((SUM x:A. f x)::int) = (SUM x:A. real(f x))"
   610   apply (subst real_eq_of_int)+
   611   apply (rule of_int_setsum)
   612 done
   613 
   614 lemma real_of_int_setprod [simp]: "real ((PROD x:A. f x)::int) = 
   615     (PROD x:A. real(f x))"
   616   apply (subst real_eq_of_int)+
   617   apply (rule of_int_setprod)
   618 done
   619 
   620 lemma real_of_int_zero_cancel [simp]: "(real x = 0) = (x = (0::int))"
   621 by (simp add: real_of_int_def) 
   622 
   623 lemma real_of_int_inject [iff]: "(real (x::int) = real y) = (x = y)"
   624 by (simp add: real_of_int_def) 
   625 
   626 lemma real_of_int_less_iff [iff]: "(real (x::int) < real y) = (x < y)"
   627 by (simp add: real_of_int_def) 
   628 
   629 lemma real_of_int_le_iff [simp]: "(real (x::int) \<le> real y) = (x \<le> y)"
   630 by (simp add: real_of_int_def) 
   631 
   632 lemma real_of_int_gt_zero_cancel_iff [simp]: "(0 < real (n::int)) = (0 < n)"
   633 by (simp add: real_of_int_def) 
   634 
   635 lemma real_of_int_ge_zero_cancel_iff [simp]: "(0 <= real (n::int)) = (0 <= n)"
   636 by (simp add: real_of_int_def) 
   637 
   638 lemma real_of_int_lt_zero_cancel_iff [simp]: "(real (n::int) < 0) = (n < 0)"
   639 by (simp add: real_of_int_def)
   640 
   641 lemma real_of_int_le_zero_cancel_iff [simp]: "(real (n::int) <= 0) = (n <= 0)"
   642 by (simp add: real_of_int_def)
   643 
   644 lemma real_of_int_abs [simp]: "real (abs x) = abs(real (x::int))"
   645 by (auto simp add: abs_if)
   646 
   647 lemma int_less_real_le: "((n::int) < m) = (real n + 1 <= real m)"
   648   apply (subgoal_tac "real n + 1 = real (n + 1)")
   649   apply (simp del: real_of_int_add)
   650   apply auto
   651 done
   652 
   653 lemma int_le_real_less: "((n::int) <= m) = (real n < real m + 1)"
   654   apply (subgoal_tac "real m + 1 = real (m + 1)")
   655   apply (simp del: real_of_int_add)
   656   apply simp
   657 done
   658 
   659 lemma real_of_int_div_aux: "d ~= 0 ==> (real (x::int)) / (real d) = 
   660     real (x div d) + (real (x mod d)) / (real d)"
   661 proof -
   662   assume "d ~= 0"
   663   have "x = (x div d) * d + x mod d"
   664     by auto
   665   then have "real x = real (x div d) * real d + real(x mod d)"
   666     by (simp only: real_of_int_mult [THEN sym] real_of_int_add [THEN sym])
   667   then have "real x / real d = ... / real d"
   668     by simp
   669   then show ?thesis
   670     by (auto simp add: add_divide_distrib ring_eq_simps prems)
   671 qed
   672 
   673 lemma real_of_int_div: "(d::int) ~= 0 ==> d dvd n ==>
   674     real(n div d) = real n / real d"
   675   apply (frule real_of_int_div_aux [of d n])
   676   apply simp
   677   apply (simp add: zdvd_iff_zmod_eq_0)
   678 done
   679 
   680 lemma real_of_int_div2:
   681   "0 <= real (n::int) / real (x) - real (n div x)"
   682   apply (case_tac "x = 0")
   683   apply simp
   684   apply (case_tac "0 < x")
   685   apply (simp add: compare_rls)
   686   apply (subst real_of_int_div_aux)
   687   apply simp
   688   apply simp
   689   apply (subst zero_le_divide_iff)
   690   apply auto
   691   apply (simp add: compare_rls)
   692   apply (subst real_of_int_div_aux)
   693   apply simp
   694   apply simp
   695   apply (subst zero_le_divide_iff)
   696   apply auto
   697 done
   698 
   699 lemma real_of_int_div3:
   700   "real (n::int) / real (x) - real (n div x) <= 1"
   701   apply(case_tac "x = 0")
   702   apply simp
   703   apply (simp add: compare_rls)
   704   apply (subst real_of_int_div_aux)
   705   apply assumption
   706   apply simp
   707   apply (subst divide_le_eq)
   708   apply clarsimp
   709   apply (rule conjI)
   710   apply (rule impI)
   711   apply (rule order_less_imp_le)
   712   apply simp
   713   apply (rule impI)
   714   apply (rule order_less_imp_le)
   715   apply simp
   716 done
   717 
   718 lemma real_of_int_div4: "real (n div x) <= real (n::int) / real x" 
   719   by (insert real_of_int_div2 [of n x], simp)
   720 
   721 subsection{*Embedding the Naturals into the Reals*}
   722 
   723 lemma real_of_nat_zero [simp]: "real (0::nat) = 0"
   724 by (simp add: real_of_nat_def)
   725 
   726 lemma real_of_nat_one [simp]: "real (Suc 0) = (1::real)"
   727 by (simp add: real_of_nat_def)
   728 
   729 lemma real_of_nat_add [simp]: "real (m + n) = real (m::nat) + real n"
   730 by (simp add: real_of_nat_def)
   731 
   732 (*Not for addsimps: often the LHS is used to represent a positive natural*)
   733 lemma real_of_nat_Suc: "real (Suc n) = real n + (1::real)"
   734 by (simp add: real_of_nat_def)
   735 
   736 lemma real_of_nat_less_iff [iff]: 
   737      "(real (n::nat) < real m) = (n < m)"
   738 by (simp add: real_of_nat_def)
   739 
   740 lemma real_of_nat_le_iff [iff]: "(real (n::nat) \<le> real m) = (n \<le> m)"
   741 by (simp add: real_of_nat_def)
   742 
   743 lemma real_of_nat_ge_zero [iff]: "0 \<le> real (n::nat)"
   744 by (simp add: real_of_nat_def zero_le_imp_of_nat)
   745 
   746 lemma real_of_nat_Suc_gt_zero: "0 < real (Suc n)"
   747 by (simp add: real_of_nat_def del: of_nat_Suc)
   748 
   749 lemma real_of_nat_mult [simp]: "real (m * n) = real (m::nat) * real n"
   750 by (simp add: real_of_nat_def)
   751 
   752 lemma real_of_nat_setsum [simp]: "real ((SUM x:A. f x)::nat) = 
   753     (SUM x:A. real(f x))"
   754   apply (subst real_eq_of_nat)+
   755   apply (rule of_nat_setsum)
   756 done
   757 
   758 lemma real_of_nat_setprod [simp]: "real ((PROD x:A. f x)::nat) = 
   759     (PROD x:A. real(f x))"
   760   apply (subst real_eq_of_nat)+
   761   apply (rule of_nat_setprod)
   762 done
   763 
   764 lemma real_of_card: "real (card A) = setsum (%x.1) A"
   765   apply (subst card_eq_setsum)
   766   apply (subst real_of_nat_setsum)
   767   apply simp
   768 done
   769 
   770 lemma real_of_nat_inject [iff]: "(real (n::nat) = real m) = (n = m)"
   771 by (simp add: real_of_nat_def)
   772 
   773 lemma real_of_nat_zero_iff [iff]: "(real (n::nat) = 0) = (n = 0)"
   774 by (simp add: real_of_nat_def)
   775 
   776 lemma real_of_nat_diff: "n \<le> m ==> real (m - n) = real (m::nat) - real n"
   777 by (simp add: add: real_of_nat_def) 
   778 
   779 lemma real_of_nat_gt_zero_cancel_iff [simp]: "(0 < real (n::nat)) = (0 < n)"
   780 by (simp add: add: real_of_nat_def) 
   781 
   782 lemma real_of_nat_le_zero_cancel_iff [simp]: "(real (n::nat) \<le> 0) = (n = 0)"
   783 by (simp add: add: real_of_nat_def)
   784 
   785 lemma not_real_of_nat_less_zero [simp]: "~ real (n::nat) < 0"
   786 by (simp add: add: real_of_nat_def)
   787 
   788 lemma real_of_nat_ge_zero_cancel_iff [simp]: "(0 \<le> real (n::nat)) = (0 \<le> n)"
   789 by (simp add: add: real_of_nat_def)
   790 
   791 lemma nat_less_real_le: "((n::nat) < m) = (real n + 1 <= real m)"
   792   apply (subgoal_tac "real n + 1 = real (Suc n)")
   793   apply simp
   794   apply (auto simp add: real_of_nat_Suc)
   795 done
   796 
   797 lemma nat_le_real_less: "((n::nat) <= m) = (real n < real m + 1)"
   798   apply (subgoal_tac "real m + 1 = real (Suc m)")
   799   apply (simp add: less_Suc_eq_le)
   800   apply (simp add: real_of_nat_Suc)
   801 done
   802 
   803 lemma real_of_nat_div_aux: "0 < d ==> (real (x::nat)) / (real d) = 
   804     real (x div d) + (real (x mod d)) / (real d)"
   805 proof -
   806   assume "0 < d"
   807   have "x = (x div d) * d + x mod d"
   808     by auto
   809   then have "real x = real (x div d) * real d + real(x mod d)"
   810     by (simp only: real_of_nat_mult [THEN sym] real_of_nat_add [THEN sym])
   811   then have "real x / real d = \<dots> / real d"
   812     by simp
   813   then show ?thesis
   814     by (auto simp add: add_divide_distrib ring_eq_simps prems)
   815 qed
   816 
   817 lemma real_of_nat_div: "0 < (d::nat) ==> d dvd n ==>
   818     real(n div d) = real n / real d"
   819   apply (frule real_of_nat_div_aux [of d n])
   820   apply simp
   821   apply (subst dvd_eq_mod_eq_0 [THEN sym])
   822   apply assumption
   823 done
   824 
   825 lemma real_of_nat_div2:
   826   "0 <= real (n::nat) / real (x) - real (n div x)"
   827   apply(case_tac "x = 0")
   828   apply simp
   829   apply (simp add: compare_rls)
   830   apply (subst real_of_nat_div_aux)
   831   apply assumption
   832   apply simp
   833   apply (subst zero_le_divide_iff)
   834   apply simp
   835 done
   836 
   837 lemma real_of_nat_div3:
   838   "real (n::nat) / real (x) - real (n div x) <= 1"
   839   apply(case_tac "x = 0")
   840   apply simp
   841   apply (simp add: compare_rls)
   842   apply (subst real_of_nat_div_aux)
   843   apply assumption
   844   apply simp
   845 done
   846 
   847 lemma real_of_nat_div4: "real (n div x) <= real (n::nat) / real x" 
   848   by (insert real_of_nat_div2 [of n x], simp)
   849 
   850 lemma real_of_int_real_of_nat: "real (int n) = real n"
   851 by (simp add: real_of_nat_def real_of_int_def int_eq_of_nat)
   852 
   853 lemma real_of_int_of_nat_eq [simp]: "real (of_nat n :: int) = real n"
   854 by (simp add: real_of_int_def real_of_nat_def)
   855 
   856 lemma real_nat_eq_real [simp]: "0 <= x ==> real(nat x) = real x"
   857   apply (subgoal_tac "real(int(nat x)) = real(nat x)")
   858   apply force
   859   apply (simp only: real_of_int_real_of_nat)
   860 done
   861 
   862 subsection{*Numerals and Arithmetic*}
   863 
   864 instance real :: number ..
   865 
   866 defs (overloaded)
   867   real_number_of_def: "(number_of w :: real) == of_int w"
   868     --{*the type constraint is essential!*}
   869 
   870 instance real :: number_ring
   871 by (intro_classes, simp add: real_number_of_def) 
   872 
   873 text{*Collapse applications of @{term real} to @{term number_of}*}
   874 lemma real_number_of [simp]: "real (number_of v :: int) = number_of v"
   875 by (simp add:  real_of_int_def of_int_number_of_eq)
   876 
   877 lemma real_of_nat_number_of [simp]:
   878      "real (number_of v :: nat) =  
   879         (if neg (number_of v :: int) then 0  
   880          else (number_of v :: real))"
   881 by (simp add: real_of_int_real_of_nat [symmetric] int_nat_number_of)
   882  
   883 
   884 use "real_arith.ML"
   885 
   886 setup real_arith_setup
   887 
   888 
   889 lemma real_diff_mult_distrib:
   890   fixes a::real
   891   shows "a * (b - c) = a * b - a * c" 
   892 proof -
   893   have "a * (b - c) = a * (b + -c)" by simp
   894   also have "\<dots> = (b + -c) * a" by simp
   895   also have "\<dots> = b*a + (-c)*a" by (rule real_add_mult_distrib)
   896   also have "\<dots> = a*b - a*c" by simp
   897   finally show ?thesis .
   898 qed
   899 
   900 
   901 subsection{* Simprules combining x+y and 0: ARE THEY NEEDED?*}
   902 
   903 text{*Needed in this non-standard form by Hyperreal/Transcendental*}
   904 lemma real_0_le_divide_iff:
   905      "((0::real) \<le> x/y) = ((x \<le> 0 | 0 \<le> y) & (0 \<le> x | y \<le> 0))"
   906 by (simp add: real_divide_def zero_le_mult_iff, auto)
   907 
   908 lemma real_add_minus_iff [simp]: "(x + - a = (0::real)) = (x=a)" 
   909 by arith
   910 
   911 lemma real_add_eq_0_iff: "(x+y = (0::real)) = (y = -x)"
   912 by auto
   913 
   914 lemma real_add_less_0_iff: "(x+y < (0::real)) = (y < -x)"
   915 by auto
   916 
   917 lemma real_0_less_add_iff: "((0::real) < x+y) = (-x < y)"
   918 by auto
   919 
   920 lemma real_add_le_0_iff: "(x+y \<le> (0::real)) = (y \<le> -x)"
   921 by auto
   922 
   923 lemma real_0_le_add_iff: "((0::real) \<le> x+y) = (-x \<le> y)"
   924 by auto
   925 
   926 
   927 (*
   928 FIXME: we should have this, as for type int, but many proofs would break.
   929 It replaces x+-y by x-y.
   930 declare real_diff_def [symmetric, simp]
   931 *)
   932 
   933 
   934 subsubsection{*Density of the Reals*}
   935 
   936 lemma real_lbound_gt_zero:
   937      "[| (0::real) < d1; 0 < d2 |] ==> \<exists>e. 0 < e & e < d1 & e < d2"
   938 apply (rule_tac x = " (min d1 d2) /2" in exI)
   939 apply (simp add: min_def)
   940 done
   941 
   942 
   943 text{*Similar results are proved in @{text Ring_and_Field}*}
   944 lemma real_less_half_sum: "x < y ==> x < (x+y) / (2::real)"
   945   by auto
   946 
   947 lemma real_gt_half_sum: "x < y ==> (x+y)/(2::real) < y"
   948   by auto
   949 
   950 
   951 subsection{*Absolute Value Function for the Reals*}
   952 
   953 lemma abs_minus_add_cancel: "abs(x + (-y)) = abs (y + (-(x::real)))"
   954 by (simp add: abs_if)
   955 
   956 lemma abs_interval_iff: "(abs x < r) = (-r < x & x < (r::real))"
   957 by (force simp add: Ring_and_Field.abs_less_iff)
   958 
   959 lemma abs_le_interval_iff: "(abs x \<le> r) = (-r\<le>x & x\<le>(r::real))"
   960 by (force simp add: OrderedGroup.abs_le_iff)
   961 
   962 lemma abs_add_one_gt_zero [simp]: "(0::real) < 1 + abs(x)"
   963 by (simp add: abs_if)
   964 
   965 lemma abs_real_of_nat_cancel [simp]: "abs (real x) = real (x::nat)"
   966 by (rule abs_of_nonneg [OF real_of_nat_ge_zero])
   967 
   968 lemma abs_add_one_not_less_self [simp]: "~ abs(x) + (1::real) < x"
   969 by simp
   970  
   971 lemma abs_sum_triangle_ineq: "abs ((x::real) + y + (-l + -m)) \<le> abs(x + -l) + abs(y + -m)"
   972 by simp
   973 
   974 end