src/Pure/library.ML
author wenzelm
Tue May 02 20:42:37 2006 +0200 (2006-05-02)
changeset 19542 b5abe6cd4cbf
parent 19512 94cd541dc8fa
child 19567 48d3b4266b52
permissions -rw-r--r--
sys_error: exception SYS_ERROR;
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Muenchen
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 strings, lists as sets, association lists, generic
     8 tables, balanced trees, orders, current directory, misc.
     9 *)
    10 
    11 infix 1 |> |-> ||> ||>> |>> |>>> #> #->;
    12 infix 2 ?;
    13 infix 3 o oo ooo oooo;
    14 
    15 infix 4 ~~ upto downto;
    16 infix orf andf \ \\ ins ins_string ins_int mem mem_int mem_string union union_int
    17   union_string inter inter_int inter_string subset subset_int subset_string;
    18 
    19 signature BASIC_LIBRARY =
    20 sig
    21   (*functions*)
    22   val I: 'a -> 'a
    23   val K: 'a -> 'b -> 'a
    24   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    25   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    26   val |> : 'a * ('a -> 'b) -> 'b
    27   val |-> : ('c * 'a) * ('c -> 'a -> 'b) -> 'b
    28   val ||> : ('c * 'a) * ('a -> 'b) -> 'c * 'b
    29   val ||>> : ('c * 'a) * ('a -> 'd * 'b) -> ('c * 'd) * 'b
    30   val |>> : ('a * 'c) * ('a -> 'b) -> 'b * 'c
    31   val |>>> : ('a * 'c) * ('a -> 'b * 'd) -> 'b * ('c * 'd)
    32   val #> : ('a -> 'b) * ('b -> 'c) -> 'a -> 'c
    33   val #-> : ('a -> 'c * 'b) * ('c -> 'b -> 'd) -> 'a -> 'd
    34   val ? : ('a -> bool) * ('a -> 'a) -> 'a -> 'a
    35   val ` : ('b -> 'a) -> 'b -> 'a * 'b
    36   val tap: ('b -> 'a) -> 'b -> 'b
    37   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    38   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    39   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    40   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    41 
    42   (*old options -- invalidated*)
    43   datatype invalid = None of invalid
    44   exception OPTION of invalid
    45 
    46   (*options*)
    47   val the: 'a option -> 'a
    48   val these: 'a list option -> 'a list
    49   val the_default: 'a -> 'a option -> 'a
    50   val the_list: 'a option -> 'a list
    51   val is_some: 'a option -> bool
    52   val is_none: 'a option -> bool
    53   val perhaps: ('a -> 'a option) -> 'a -> 'a
    54   val eq_opt: ('a * 'b -> bool) -> 'a option * 'b option -> bool
    55   val merge_opt: ('a * 'a -> bool) -> 'a option * 'a option -> 'a option
    56 
    57   (*exceptions*)
    58   val try: ('a -> 'b) -> 'a -> 'b option
    59   val can: ('a -> 'b) -> 'a -> bool
    60   exception EXCEPTION of exn * string
    61   val do_transform_failure: bool ref
    62   val transform_failure: (exn -> exn) -> ('a -> 'b) -> 'a -> 'b
    63   datatype 'a result = Result of 'a | Exn of exn
    64   val capture: ('a -> 'b) -> 'a -> 'b result
    65   val release: 'a result -> 'a
    66   val get_result: 'a result -> 'a option
    67   val get_exn: 'a result -> exn option
    68 
    69   (*errors*)
    70   exception SYS_ERROR of string
    71   val sys_error: string -> 'a
    72   exception ERROR of string
    73   val error: string -> 'a
    74   val cat_error: string -> string -> 'a
    75   val assert: bool -> string -> unit
    76   val deny: bool -> string -> unit
    77   val assert_all: ('a -> bool) -> 'a list -> ('a -> string) -> unit
    78 
    79   (*pairs*)
    80   val pair: 'a -> 'b -> 'a * 'b
    81   val rpair: 'a -> 'b -> 'b * 'a
    82   val fst: 'a * 'b -> 'a
    83   val snd: 'a * 'b -> 'b
    84   val eq_fst: ('a * 'c -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    85   val eq_snd: ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    86   val eq_pair: ('a * 'c -> bool) -> ('b * 'd -> bool) -> ('a * 'b) * ('c * 'd) -> bool
    87   val swap: 'a * 'b -> 'b * 'a
    88   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    89   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    90   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    91 
    92   (*booleans*)
    93   val equal: ''a -> ''a -> bool
    94   val not_equal: ''a -> ''a -> bool
    95   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    96   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    97   val exists: ('a -> bool) -> 'a list -> bool
    98   val forall: ('a -> bool) -> 'a list -> bool
    99   val set: bool ref -> bool
   100   val reset: bool ref -> bool
   101   val toggle: bool ref -> bool
   102   val change: 'a ref -> ('a -> 'a) -> unit
   103   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
   104   val conditional: bool -> (unit -> unit) -> unit
   105 
   106   (*lists*)
   107   exception UnequalLengths
   108   val cons: 'a -> 'a list -> 'a list
   109   val single: 'a -> 'a list
   110   val singleton: ('a list -> 'b list) -> 'a -> 'b
   111   val append: 'a list -> 'a list -> 'a list
   112   val apply: ('a -> 'a) list -> 'a -> 'a
   113   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
   114   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
   115   val fold_map: ('a -> 'b -> 'c * 'b) -> 'a list -> 'b -> 'c list * 'b
   116   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
   117   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
   118   val flat: 'a list list -> 'a list
   119   val maps: ('a -> 'b list) -> 'a list -> 'b list
   120   val unflat: 'a list list -> 'b list -> 'b list list
   121   val burrow: ('a list -> 'b list) -> 'a list list -> 'b list list
   122   val fold_burrow: ('a list -> 'c -> 'b list * 'd) -> 'a list list -> 'c -> 'b list list * 'd
   123   val chop: int -> 'a list -> 'a list * 'a list
   124   val dropwhile: ('a -> bool) -> 'a list -> 'a list
   125   val nth: 'a list -> int -> 'a
   126   val nth_update: int * 'a -> 'a list -> 'a list
   127   val nth_map: int -> ('a -> 'a) -> 'a list -> 'a list
   128   val nth_list: 'a list list -> int -> 'a list
   129   val map_index: (int * 'a -> 'b) -> 'a list -> 'b list
   130   val fold_index: (int * 'a -> 'b -> 'b) -> 'a list -> 'b -> 'b
   131   val split_last: 'a list -> 'a list * 'a
   132   val find_index: ('a -> bool) -> 'a list -> int
   133   val find_index_eq: ''a -> ''a list -> int
   134   val find_first: ('a -> bool) -> 'a list -> 'a option
   135   val get_index: ('a -> 'b option) -> 'a list -> (int * 'b) option
   136   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   137   val eq_list: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   138   val map2: ('a -> 'b -> 'c) -> 'a list -> 'b list -> 'c list
   139   val fold2: ('a -> 'b -> 'c -> 'c) -> 'a list -> 'b list -> 'c -> 'c
   140   val ~~ : 'a list * 'b list -> ('a * 'b) list
   141   val split_list: ('a * 'b) list -> 'a list * 'b list
   142   val separate: 'a -> 'a list -> 'a list
   143   val replicate: int -> 'a -> 'a list
   144   val multiply: 'a list -> 'a list list -> 'a list list
   145   val product: 'a list -> 'b list -> ('a * 'b) list
   146   val filter: ('a -> bool) -> 'a list -> 'a list
   147   val filter_out: ('a -> bool) -> 'a list -> 'a list
   148   val map_filter: ('a -> 'b option) -> 'a list -> 'b list
   149   val equal_lists: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   150   val is_prefix: ('a * 'a -> bool) -> 'a list -> 'a list -> bool
   151   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   152   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   153   val prefixes1: 'a list -> 'a list list
   154   val prefixes: 'a list -> 'a list list
   155   val suffixes1: 'a list -> 'a list list
   156   val suffixes: 'a list -> 'a list list
   157 
   158   (*integers*)
   159   val gcd: IntInf.int * IntInf.int -> IntInf.int
   160   val lcm: IntInf.int * IntInf.int -> IntInf.int
   161   val inc: int ref -> int
   162   val dec: int ref -> int
   163   val upto: int * int -> int list
   164   val downto: int * int -> int list
   165   val downto0: int list * int -> bool
   166   val radixpand: int * int -> int list
   167   val radixstring: int * string * int -> string
   168   val string_of_int: int -> string
   169   val string_of_indexname: string * int -> string
   170   val read_radixint: int * string list -> int * string list
   171   val read_int: string list -> int * string list
   172   val oct_char: string -> string
   173 
   174   (*strings*)
   175   val nth_string: string -> int -> string
   176   val fold_string: (string -> 'a -> 'a) -> string -> 'a -> 'a
   177   val exists_string: (string -> bool) -> string -> bool
   178   val forall_string: (string -> bool) -> string -> bool
   179   val enclose: string -> string -> string -> string
   180   val unenclose: string -> string
   181   val quote: string -> string
   182   val space_implode: string -> string list -> string
   183   val commas: string list -> string
   184   val commas_quote: string list -> string
   185   val cat_lines: string list -> string
   186   val space_explode: string -> string -> string list
   187   val split_lines: string -> string list
   188   val prefix_lines: string -> string -> string
   189   val untabify: string list -> string list
   190   val prefix: string -> string -> string
   191   val suffix: string -> string -> string
   192   val unprefix: string -> string -> string
   193   val unsuffix: string -> string -> string
   194   val replicate_string: int -> string -> string
   195   val translate_string: (string -> string) -> string -> string
   196 
   197   (*lists as sets -- see also Pure/General/ord_list.ML*)
   198   val member: ('b * 'a -> bool) -> 'a list -> 'b -> bool
   199   val insert: ('a * 'a -> bool) -> 'a -> 'a list -> 'a list
   200   val remove: ('b * 'a -> bool) -> 'b -> 'a list -> 'a list
   201   val subtract: ('b * 'a -> bool) -> 'b list -> 'a list -> 'a list
   202   val merge: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   203   val mem: ''a * ''a list -> bool
   204   val mem_int: int * int list -> bool
   205   val mem_string: string * string list -> bool
   206   val ins: ''a * ''a list -> ''a list
   207   val ins_int: int * int list -> int list
   208   val ins_string: string * string list -> string list
   209   val union: ''a list * ''a list -> ''a list
   210   val union_int: int list * int list -> int list
   211   val union_string: string list * string list -> string list
   212   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   213   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   214   val inter: ''a list * ''a list -> ''a list
   215   val inter_int: int list * int list -> int list
   216   val inter_string: string list * string list -> string list
   217   val subset: ''a list * ''a list -> bool
   218   val subset_int: int list * int list -> bool
   219   val subset_string: string list * string list -> bool
   220   val eq_set: ''a list * ''a list -> bool
   221   val eq_set_string: string list * string list -> bool
   222   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   223   val gen_eq_set: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   224   val \ : ''a list * ''a -> ''a list
   225   val \\ : ''a list * ''a list -> ''a list
   226   val gen_rem: ('a * 'b -> bool) -> 'a list * 'b -> 'a list
   227   val gen_rems: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   228   val findrep: ''a list -> ''a list
   229   val distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   230   val duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   231   val has_duplicates: ('a * 'a -> bool) -> 'a list -> bool
   232 
   233   (*lists as tables -- see also Pure/General/alist.ML*)
   234   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   235   val merge_lists: ''a list -> ''a list -> ''a list
   236   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   237 
   238   (*balanced trees*)
   239   exception Balance
   240   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   241   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   242   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   243 
   244   (*orders*)
   245   val is_equal: order -> bool
   246   val rev_order: order -> order
   247   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   248   val eq_ord: ('a -> order) -> 'a -> bool
   249   val int_ord: int * int -> order
   250   val string_ord: string * string -> order
   251   val fast_string_ord: string * string -> order
   252   val option_ord: ('a * 'b -> order) -> 'a option * 'b option -> order
   253   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   254   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   255   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   256   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   257   val sort_distinct: ('a * 'a -> order) -> 'a list -> 'a list
   258   val sort_strings: string list -> string list
   259   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   260 
   261   (*random numbers*)
   262   exception RANDOM
   263   val random: unit -> real
   264   val random_range: int -> int -> int
   265   val one_of: 'a list -> 'a
   266   val frequency: (int * 'a) list -> 'a
   267 
   268   (*current directory*)
   269   val cd: string -> unit
   270   val pwd: unit -> string
   271 
   272   (*misc*)
   273   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   274   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   275   val gensym: string -> string
   276   val scanwords: (string -> bool) -> string list -> string list
   277   type stamp
   278   val stamp: unit -> stamp
   279   type serial
   280   val serial: unit -> serial
   281   val serial_string: unit -> string
   282   structure Object: sig type T end
   283 end;
   284 
   285 signature LIBRARY =
   286 sig
   287   include BASIC_LIBRARY
   288   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   289   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   290   val take: int * 'a list -> 'a list
   291   val drop: int * 'a list -> 'a list
   292   val last_elem: 'a list -> 'a
   293   val seq: ('a -> unit) -> 'a list -> unit
   294   val partition: ('a -> bool) -> 'a list -> 'a list * 'a list
   295 end;
   296 
   297 structure Library: LIBRARY =
   298 struct
   299 
   300 
   301 (** functions **)
   302 
   303 fun I x = x;
   304 fun K x = fn _ => x;
   305 fun curry f x y = f (x, y);
   306 fun uncurry f (x, y) = f x y;
   307 
   308 (*reverse application and structured results*)
   309 fun x |> f = f x;
   310 fun (x, y) |-> f = f x y;
   311 fun (x, y) |>> f = (f x, y);
   312 fun (x, y) ||> f = (x, f y);
   313 fun (x, y) |>>> f = let val (x', z) = f x in (x', (y, z)) end;
   314 fun (x, y) ||>> f = let val (z, y') = f y in ((x, z), y') end;
   315 
   316 (*reverse composition*)
   317 fun f #> g = g o f;
   318 fun f #-> g = uncurry g o f;
   319 
   320 (*conditional application*)
   321 fun b ? f = fn x => if b x then f x else x;
   322 
   323 (*view results*)
   324 fun `f = fn x => (f x, x);
   325 fun tap f = fn x => (f x; x);
   326 
   327 (*composition with multiple args*)
   328 fun (f oo g) x y = f (g x y);
   329 fun (f ooo g) x y z = f (g x y z);
   330 fun (f oooo g) x y z w = f (g x y z w);
   331 
   332 (*function exponentiation: f(...(f x)...) with n applications of f*)
   333 fun funpow n f x =
   334   let fun rep (0, x) = x
   335         | rep (n, x) = rep (n - 1, f x)
   336   in rep (n, x) end;
   337 
   338 
   339 (** options **)
   340 
   341 (*invalidate former constructors to prevent accidental use as match-all patterns!*)
   342 datatype invalid = None of invalid;
   343 exception OPTION of invalid;
   344 
   345 val the = Option.valOf;
   346 
   347 fun these (SOME x) = x
   348   | these _ = [];
   349 
   350 fun the_default x (SOME y) = y
   351   | the_default x _ = x;
   352 
   353 fun the_list (SOME x) = [x]
   354   | the_list _ = []
   355 
   356 fun is_some (SOME _) = true
   357   | is_some NONE = false;
   358 
   359 fun is_none (SOME _) = false
   360   | is_none NONE = true;
   361 
   362 fun perhaps f x = the_default x (f x);
   363 
   364 fun eq_opt eq (NONE, NONE) = true
   365   | eq_opt eq (SOME x, SOME y) = eq (x, y)
   366   | eq_opt _ _ = false;
   367 
   368 fun merge_opt _ (NONE, y) = y
   369   | merge_opt _ (x, NONE) = x
   370   | merge_opt eq (SOME x, SOME y) = if eq (x, y) then SOME y else raise Option;
   371 
   372 
   373 (* exceptions *)
   374 
   375 val do_transform_failure = ref true;
   376 
   377 fun transform_failure exn f x =
   378   if ! do_transform_failure then
   379     f x handle Interrupt => raise Interrupt | e => raise exn e
   380   else f x;
   381 
   382 exception EXCEPTION of exn * string;
   383 
   384 
   385 fun try f x = SOME (f x)
   386   handle Interrupt => raise Interrupt | _ => NONE;
   387 
   388 fun can f x = is_some (try f x);
   389 
   390 
   391 datatype 'a result =
   392   Result of 'a |
   393   Exn of exn;
   394 
   395 fun capture f x = Result (f x) handle e => Exn e;
   396 
   397 fun release (Result y) = y
   398   | release (Exn e) = raise e;
   399 
   400 fun get_result (Result x) = SOME x
   401   | get_result _ = NONE;
   402 
   403 fun get_exn (Exn exn) = SOME exn
   404   | get_exn _ = NONE;
   405 
   406 
   407 (* errors *)
   408 
   409 exception SYS_ERROR of string;
   410 fun sys_error msg = raise SYS_ERROR msg;
   411 
   412 exception ERROR of string;
   413 fun error msg = raise ERROR msg;
   414 
   415 fun cat_error "" msg = error msg
   416   | cat_error msg1 msg2 = error (msg1 ^ "\n" ^ msg2);
   417 
   418 fun assert p msg = if p then () else error msg;
   419 fun deny p msg = if p then error msg else ();
   420 
   421 fun assert_all pred list msg =
   422   let
   423     fun ass [] = ()
   424       | ass (x :: xs) = if pred x then ass xs else error (msg x);
   425   in ass list end;
   426 
   427 
   428 
   429 (** pairs **)
   430 
   431 fun pair x y = (x, y);
   432 fun rpair x y = (y, x);
   433 
   434 fun fst (x, y) = x;
   435 fun snd (x, y) = y;
   436 
   437 fun eq_fst eq ((x1, _), (x2, _)) = eq (x1, x2);
   438 fun eq_snd eq ((_, y1), (_, y2)) = eq (y1, y2);
   439 fun eq_pair eqx eqy ((x1, y1), (x2, y2)) = eqx (x1, x2) andalso eqy (y1, y2);
   440 
   441 fun swap (x, y) = (y, x);
   442 
   443 (*apply function to components*)
   444 fun apfst f (x, y) = (f x, y);
   445 fun apsnd f (x, y) = (x, f y);
   446 fun pairself f (x, y) = (f x, f y);
   447 
   448 
   449 
   450 (** booleans **)
   451 
   452 (* equality *)
   453 
   454 fun equal x y = x = y;
   455 fun not_equal x y = x <> y;
   456 
   457 
   458 (* operators for combining predicates *)
   459 
   460 fun p orf q = fn x => p x orelse q x;
   461 fun p andf q = fn x => p x andalso q x;
   462 
   463 
   464 (* predicates on lists *)
   465 
   466 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   467 fun exists (pred: 'a -> bool) : 'a list -> bool =
   468   let fun boolf [] = false
   469         | boolf (x :: xs) = pred x orelse boolf xs
   470   in boolf end;
   471 
   472 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   473 fun forall (pred: 'a -> bool) : 'a list -> bool =
   474   let fun boolf [] = true
   475         | boolf (x :: xs) = pred x andalso boolf xs
   476   in boolf end;
   477 
   478 
   479 (* flags *)
   480 
   481 fun set flag = (flag := true; true);
   482 fun reset flag = (flag := false; false);
   483 fun toggle flag = (flag := not (! flag); ! flag);
   484 
   485 fun change r f = r := f (! r);
   486 
   487 (*temporarily set flag during execution*)
   488 fun setmp flag value f x =
   489   let
   490     val orig_value = ! flag;
   491     val _ = flag := value;
   492     val result = capture f x;
   493     val _ = flag := orig_value;
   494   in release result end;
   495 
   496 
   497 (* conditional execution *)
   498 
   499 fun conditional b f = if b then f () else ();
   500 
   501 
   502 
   503 (** lists **)
   504 
   505 exception UnequalLengths;
   506 
   507 fun cons x xs = x :: xs;
   508 fun single x = [x];
   509 
   510 fun singleton f x = (case f [x] of [y] => y | _ => raise Empty);
   511 
   512 fun append xs ys = xs @ ys;
   513 
   514 fun apply [] x = x
   515   | apply (f :: fs) x = apply fs (f x);
   516 
   517 
   518 (* fold *)
   519 
   520 fun fold f =
   521   let
   522     fun fold_aux [] y = y
   523       | fold_aux (x :: xs) y = fold_aux xs (f x y);
   524   in fold_aux end;
   525 
   526 fun fold_rev f =
   527   let
   528     fun fold_aux [] y = y
   529       | fold_aux (x :: xs) y = f x (fold_aux xs y);
   530   in fold_aux end;
   531 
   532 fun fold_map f =
   533   let
   534     fun fold_aux [] y = ([], y)
   535       | fold_aux (x :: xs) y =
   536           let
   537             val (x', y') = f x y;
   538             val (xs', y'') = fold_aux xs y';
   539           in (x' :: xs', y'') end;
   540   in fold_aux end;
   541 
   542 (*the following versions of fold are designed to fit nicely with infixes*)
   543 
   544 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   545     for operators that associate to the left (TAIL RECURSIVE)*)
   546 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   547   let fun itl (e, [])  = e
   548         | itl (e, a::l) = itl (f(e, a), l)
   549   in  itl end;
   550 
   551 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   552     for operators that associate to the right (not tail recursive)*)
   553 fun foldr f (l, e) =
   554   let fun itr [] = e
   555         | itr (a::l) = f(a, itr l)
   556   in  itr l  end;
   557 
   558 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   559     for n > 0, operators that associate to the right (not tail recursive)*)
   560 fun foldr1 f l =
   561   let fun itr [x] = x
   562         | itr (x::l) = f(x, itr l)
   563   in  itr l  end;
   564 
   565 fun fold_index f =
   566   let
   567     fun fold_aux _ [] y = y
   568       | fold_aux i (x :: xs) y = fold_aux (i+1) xs (f (i, x) y);
   569   in fold_aux 0 end;
   570 
   571 fun foldl_map f =
   572   let
   573     fun fold_aux (x, []) = (x, [])
   574       | fold_aux (x, y :: ys) =
   575           let
   576             val (x', y') = f (x, y);
   577             val (x'', ys') = fold_aux (x', ys);
   578           in (x'', y' :: ys') end;
   579   in fold_aux end;
   580 
   581 
   582 (* basic list functions *)
   583 
   584 fun maps f [] = []
   585   | maps f (x :: xs) = f x @ maps f xs;
   586 
   587 fun chop 0 xs = ([], xs)
   588   | chop _ [] = ([], [])
   589   | chop n (x :: xs) = chop (n - 1) xs |>> cons x;
   590 
   591 (*take the first n elements from a list*)
   592 fun take (n, []) = []
   593   | take (n, x :: xs) =
   594       if n > 0 then x :: take (n - 1, xs) else [];
   595 
   596 (*drop the first n elements from a list*)
   597 fun drop (n, []) = []
   598   | drop (n, x :: xs) =
   599       if n > 0 then drop (n - 1, xs) else x :: xs;
   600 
   601 fun dropwhile P [] = []
   602   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   603 
   604 (*return nth element of a list, where 0 designates the first element;
   605   raise Subscript if list too short*)
   606 fun nth xs i = List.nth (xs, i);
   607 
   608 fun nth_list xss i = nth xss i handle Subscript => [];
   609 
   610 (*update nth element*)
   611 fun nth_update (n, x) xs =
   612   (case chop n xs of
   613     (_, []) => raise Subscript
   614   | (prfx, _ :: sffx') => prfx @ (x :: sffx'));
   615 
   616 fun nth_map 0 f (x :: xs) = f x :: xs
   617   | nth_map n f (x :: xs) = x :: nth_map (n - 1) f xs
   618   | nth_map _ _ [] = raise Subscript;
   619 
   620 fun map_index f =
   621   let
   622     fun mapp _ [] = []
   623       | mapp i (x :: xs) = f (i, x) :: mapp (i+1) xs
   624   in mapp 0 end;
   625 
   626 val last_elem = List.last;
   627 
   628 (*rear decomposition*)
   629 fun split_last [] = raise Empty
   630   | split_last [x] = ([], x)
   631   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   632 
   633 (*find the position of an element in a list*)
   634 fun find_index pred =
   635   let fun find _ [] = ~1
   636         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   637   in find 0 end;
   638 
   639 fun find_index_eq x = find_index (equal x);
   640 
   641 (*find first element satisfying predicate*)
   642 fun find_first _ [] = NONE
   643   | find_first pred (x :: xs) =
   644       if pred x then SOME x else find_first pred xs;
   645 
   646 (*get first element by lookup function*)
   647 fun get_first _ [] = NONE
   648   | get_first f (x :: xs) =
   649       (case f x of
   650         NONE => get_first f xs
   651       | some => some);
   652 
   653 fun get_index f =
   654   let
   655     fun get _ [] = NONE
   656       | get i (x :: xs) =
   657           case f x
   658            of NONE => get (i + 1) xs
   659             | SOME y => SOME (i, y)
   660   in get 0 end;
   661 
   662 fun eq_list _ ([], []) = true
   663   | eq_list eq (x :: xs, y :: ys) = eq (x, y) andalso eq_list eq (xs, ys)
   664   | eq_list _ _ = false;
   665 
   666 val flat = List.concat;
   667 
   668 fun unflat (xs :: xss) ys =
   669       let val (ps, qs) = chop (length xs) ys
   670       in ps :: unflat xss qs end
   671   | unflat [] [] = []
   672   | unflat _ _ = raise UnequalLengths;
   673 
   674 fun burrow f xss =
   675   unflat xss ((f o flat) xss);
   676 
   677 fun fold_burrow f xss s =
   678   apfst (unflat xss) (f (flat xss) s);
   679 
   680 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   681   (proc x1; ...; proc xn) for side effects*)
   682 val seq = List.app;
   683 
   684 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   685 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   686   | separate _ xs = xs;
   687 
   688 (*make the list [x, x, ..., x] of length n*)
   689 fun replicate n (x: 'a) : 'a list =
   690   let fun rep (0, xs) = xs
   691         | rep (n, xs) = rep (n - 1, x :: xs)
   692   in
   693     if n < 0 then raise Subscript
   694     else rep (n, [])
   695   end;
   696 
   697 fun translate_string f = String.translate (f o String.str);
   698 
   699 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   700 fun multiply [] _ = []
   701   | multiply (x :: xs) yss = map (cons x) yss @ multiply xs yss;
   702 
   703 (*direct product*)
   704 fun product _ [] = []
   705   | product [] _ = []
   706   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   707 
   708 
   709 (* filter *)
   710 
   711 (*copy the list preserving elements that satisfy the predicate*)
   712 val filter = List.filter;
   713 fun filter_out f = filter (not o f);
   714 val map_filter = List.mapPartial;
   715 
   716 
   717 (* lists of pairs *)
   718 
   719 exception UnequalLengths;
   720 
   721 fun map2 _ [] [] = []
   722   | map2 f (x :: xs) (y :: ys) = f x y :: map2 f xs ys
   723   | map2 _ _ _ = raise UnequalLengths;
   724 
   725 fun fold2 f =
   726   let
   727     fun fold_aux [] [] z = z
   728       | fold_aux (x :: xs) (y :: ys) z = fold_aux xs ys (f x y z)
   729       | fold_aux _ _ _ = raise UnequalLengths;
   730   in fold_aux end;
   731 
   732 
   733 (*combine two lists forming a list of pairs:
   734   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   735 fun [] ~~ [] = []
   736   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   737   | _ ~~ _ = raise UnequalLengths;
   738 
   739 (*inverse of ~~; the old 'split':
   740   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   741 val split_list = ListPair.unzip;
   742 
   743 fun equal_lists eq (xs, ys) =
   744   let
   745     fun eq' [] [] = true
   746       | eq' (x :: xs) (y :: ys) = eq (x, y) andalso eq' xs ys
   747   in length xs = length ys andalso eq' xs ys end;
   748 
   749 
   750 (* prefixes, suffixes *)
   751 
   752 fun is_prefix _ [] _ = true
   753   | is_prefix eq (x :: xs) (y :: ys) = eq (x, y) andalso is_prefix eq xs ys
   754   | is_prefix eq _ _ = false;
   755 
   756 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   757    where xi is the first element that does not satisfy the predicate*)
   758 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   759   let fun take (rxs, []) = (rev rxs, [])
   760         | take (rxs, x :: xs) =
   761             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   762   in  take([], xs)  end;
   763 
   764 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   765    where xi is the last element that does not satisfy the predicate*)
   766 fun take_suffix _ [] = ([], [])
   767   | take_suffix pred (x :: xs) =
   768       (case take_suffix pred xs of
   769         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   770       | (prfx, sffx) => (x :: prfx, sffx));
   771 
   772 fun prefixes1 [] = []
   773   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   774 
   775 fun prefixes xs = [] :: prefixes1 xs;
   776 
   777 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   778 fun suffixes xs = [] :: suffixes1 xs;
   779 
   780 
   781 (** integers **)
   782 
   783 fun gcd (x, y) =
   784   let fun gxd x y : IntInf.int =
   785     if y = 0 then x else gxd y (x mod y)
   786   in if x < y then gxd y x else gxd x y end;
   787 
   788 fun lcm (x, y) = (x * y) div gcd (x, y);
   789 
   790 fun inc i = (i := ! i + 1; ! i);
   791 fun dec i = (i := ! i - 1; ! i);
   792 
   793 
   794 (* lists of integers *)
   795 
   796 (*make the list [from, from + 1, ..., to]*)
   797 fun (from upto to) =
   798   if from > to then [] else from :: ((from + 1) upto to);
   799 
   800 (*make the list [from, from - 1, ..., to]*)
   801 fun (from downto to) =
   802   if from < to then [] else from :: ((from - 1) downto to);
   803 
   804 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   805 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   806   | downto0 ([], n) = n = ~1;
   807 
   808 
   809 (* convert integers to strings *)
   810 
   811 (*expand the number in the given base;
   812   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   813 fun radixpand (base, num) : int list =
   814   let
   815     fun radix (n, tail) =
   816       if n < base then n :: tail
   817       else radix (n div base, (n mod base) :: tail)
   818   in radix (num, []) end;
   819 
   820 (*expands a number into a string of characters starting from "zerochar";
   821   example: radixstring (2, "0", 8) gives "1000"*)
   822 fun radixstring (base, zerochar, num) =
   823   let val offset = ord zerochar;
   824       fun chrof n = chr (offset + n)
   825   in implode (map chrof (radixpand (base, num))) end;
   826 
   827 
   828 val string_of_int = Int.toString;
   829 
   830 fun string_of_indexname (a,0) = a
   831   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   832 
   833 
   834 (* read integers *)
   835 
   836 fun read_radixint (radix: int, cs) : int * string list =
   837   let val zero = ord"0"
   838       val limit = zero+radix
   839       fun scan (num,[]) = (num,[])
   840         | scan (num, c::cs) =
   841               if  zero <= ord c  andalso  ord c < limit
   842               then scan(radix*num + ord c - zero, cs)
   843               else (num, c::cs)
   844   in  scan(0,cs)  end;
   845 
   846 fun read_int cs = read_radixint (10, cs);
   847 
   848 fun oct_char s = chr (#1 (read_radixint (8, explode s)));
   849 
   850 
   851 
   852 (** strings **)
   853 
   854 (* functions tuned for strings, avoiding explode *)
   855 
   856 fun nth_string str i =
   857   (case try String.substring (str, i, 1) of
   858     SOME s => s
   859   | NONE => raise Subscript);
   860 
   861 fun fold_string f str x0 =
   862   let
   863     val n = size str;
   864     fun iter (x, i) =
   865       if i < n then iter (f (String.substring (str, i, 1)) x, i + 1) else x;
   866   in iter (x0, 0) end;
   867 
   868 fun exists_string pred str =
   869   let
   870     val n = size str;
   871     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   872   in ex 0 end;
   873 
   874 fun forall_string pred = not o exists_string (not o pred);
   875 
   876 (*enclose in brackets*)
   877 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   878 fun unenclose str = String.substring (str, 1, size str - 2);
   879 
   880 (*simple quoting (does not escape special chars)*)
   881 val quote = enclose "\"" "\"";
   882 
   883 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   884 fun space_implode a bs = implode (separate a bs);
   885 
   886 val commas = space_implode ", ";
   887 val commas_quote = commas o map quote;
   888 
   889 (*concatenate messages, one per line, into a string*)
   890 val cat_lines = space_implode "\n";
   891 
   892 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   893 fun space_explode _ "" = []
   894   | space_explode sep str =
   895       let
   896         fun expl chs =
   897           (case take_prefix (fn s => s <> sep) chs of
   898             (cs, []) => [implode cs]
   899           | (cs, _ :: cs') => implode cs :: expl cs');
   900       in expl (explode str) end;
   901 
   902 val split_lines = space_explode "\n";
   903 
   904 fun prefix_lines "" txt = txt
   905   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   906 
   907 fun untabify chs =
   908   let
   909     val tab_width = 8;
   910 
   911     fun untab (_, "\n") = (0, ["\n"])
   912       | untab (pos, "\t") =
   913           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   914       | untab (pos, c) = (pos + 1, [c]);
   915   in
   916     if not (exists (fn c => c = "\t") chs) then chs
   917     else flat (#2 (foldl_map untab (0, chs)))
   918   end;
   919 
   920 fun prefix prfx s = prfx ^ s;
   921 fun suffix sffx s = s ^ sffx;
   922 
   923 fun unprefix prfx s =
   924   if String.isPrefix prfx s then String.substring (s, size prfx, size s - size prfx)
   925   else raise Fail "unprefix";
   926 
   927 fun unsuffix sffx s =
   928   if String.isSuffix sffx s then String.substring (s, 0, size s - size sffx)
   929   else raise Fail "unsuffix";
   930 
   931 fun replicate_string 0 _ = ""
   932   | replicate_string 1 a = a
   933   | replicate_string k a =
   934       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   935       else replicate_string (k div 2) (a ^ a) ^ a;
   936 
   937 
   938 
   939 (** lists as sets -- see also Pure/General/ord_list.ML **)
   940 
   941 (*canonical member, insert, remove*)
   942 fun member eq list x =
   943   let
   944     fun memb [] = false
   945       | memb (y :: ys) = eq (x, y) orelse memb ys;
   946   in memb list end;
   947 
   948 fun insert eq x xs = if member eq xs x then xs else x :: xs;
   949 fun remove eq x xs = if member eq xs x then filter_out (fn y => eq (x, y)) xs else xs;
   950 
   951 fun subtract eq = fold (remove eq);
   952 
   953 fun merge _ ([], ys) = ys
   954   | merge eq (xs, ys) = fold_rev (insert eq) ys xs;
   955 
   956 (*old-style infixes*)
   957 fun x mem xs = member (op =) xs x;
   958 fun (x: int) mem_int xs = member (op =) xs x;
   959 fun (x: string) mem_string xs = member (op =) xs x;
   960 
   961 fun x ins xs = insert (op =) x xs;
   962 fun (x: int) ins_int xs = insert (op =) x xs;
   963 fun (x: string) ins_string xs = insert (op =) x xs;
   964 
   965 
   966 (*union of sets represented as lists: no repetitions*)
   967 fun xs union [] = xs
   968   | [] union ys = ys
   969   | (x :: xs) union ys = xs union (x ins ys);
   970 
   971 (*union of sets, optimized version for ints*)
   972 fun (xs:int list) union_int [] = xs
   973   | [] union_int ys = ys
   974   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   975 
   976 (*union of sets, optimized version for strings*)
   977 fun (xs:string list) union_string [] = xs
   978   | [] union_string ys = ys
   979   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   980 
   981 (*generalized union*)
   982 fun gen_union eq (xs, []) = xs
   983   | gen_union eq ([], ys) = ys
   984   | gen_union eq (x :: xs, ys) = gen_union eq (xs, insert eq x ys);
   985 
   986 
   987 (*intersection*)
   988 fun [] inter ys = []
   989   | (x :: xs) inter ys =
   990       if x mem ys then x :: (xs inter ys) else xs inter ys;
   991 
   992 (*intersection, optimized version for ints*)
   993 fun ([]:int list) inter_int ys = []
   994   | (x :: xs) inter_int ys =
   995       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   996 
   997 (*intersection, optimized version for strings *)
   998 fun ([]:string list) inter_string ys = []
   999   | (x :: xs) inter_string ys =
  1000       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
  1001 
  1002 (*generalized intersection*)
  1003 fun gen_inter eq ([], ys) = []
  1004   | gen_inter eq (x::xs, ys) =
  1005       if member eq ys x then x :: gen_inter eq (xs, ys)
  1006       else gen_inter eq (xs, ys);
  1007 
  1008 
  1009 (*subset*)
  1010 fun [] subset ys = true
  1011   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
  1012 
  1013 (*subset, optimized version for ints*)
  1014 fun ([]: int list) subset_int ys = true
  1015   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
  1016 
  1017 (*subset, optimized version for strings*)
  1018 fun ([]: string list) subset_string ys = true
  1019   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
  1020 
  1021 (*set equality*)
  1022 fun eq_set (xs, ys) =
  1023   xs = ys orelse (xs subset ys andalso ys subset xs);
  1024 
  1025 (*set equality for strings*)
  1026 fun eq_set_string ((xs: string list), ys) =
  1027   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
  1028 
  1029 fun gen_subset eq (xs, ys) = forall (member eq ys) xs;
  1030 
  1031 fun gen_eq_set eq (xs, ys) =
  1032   equal_lists eq (xs, ys) orelse
  1033     (gen_subset eq (xs, ys) andalso gen_subset (eq o swap) (ys, xs));
  1034 
  1035 
  1036 (*removing an element from a list WITHOUT duplicates*)
  1037 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
  1038   | [] \ x = [];
  1039 
  1040 fun ys \\ xs = foldl (op \) (ys,xs);
  1041 
  1042 (*removing an element from a list -- possibly WITH duplicates*)
  1043 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
  1044 fun gen_rems eq (xs, ys) = filter_out (member eq ys) xs;
  1045 
  1046 (*returns the tail beginning with the first repeated element, or []*)
  1047 fun findrep [] = []
  1048   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
  1049 
  1050 
  1051 (*makes a list of the distinct members of the input; preserves order, takes
  1052   first of equal elements*)
  1053 fun distinct eq lst =
  1054   let
  1055     fun dist (rev_seen, []) = rev rev_seen
  1056       | dist (rev_seen, x :: xs) =
  1057           if member eq rev_seen x then dist (rev_seen, xs)
  1058           else dist (x :: rev_seen, xs);
  1059   in dist ([], lst) end;
  1060 
  1061 (*returns a list containing all repeated elements exactly once; preserves
  1062   order, takes first of equal elements*)
  1063 fun duplicates eq lst =
  1064   let
  1065     fun dups (rev_dups, []) = rev rev_dups
  1066       | dups (rev_dups, x :: xs) =
  1067           if member eq rev_dups x orelse not (member eq xs x) then
  1068             dups (rev_dups, xs)
  1069           else dups (x :: rev_dups, xs);
  1070   in dups ([], lst) end;
  1071 
  1072 fun has_duplicates eq =
  1073   let
  1074     fun dups [] = false
  1075       | dups (x :: xs) = member eq xs x orelse dups xs;
  1076   in dups end;
  1077 
  1078 
  1079 (** association lists -- legacy operations **)
  1080 
  1081 fun gen_merge_lists _ xs [] = xs
  1082   | gen_merge_lists _ [] ys = ys
  1083   | gen_merge_lists eq xs ys = xs @ gen_rems eq (ys, xs);
  1084 
  1085 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
  1086 fun merge_alists al = gen_merge_lists (eq_fst (op =)) al;
  1087 
  1088 
  1089 (** balanced trees **)
  1090 
  1091 exception Balance;      (*indicates non-positive argument to balancing fun*)
  1092 
  1093 (*balanced folding; avoids deep nesting*)
  1094 fun fold_bal f [x] = x
  1095   | fold_bal f [] = raise Balance
  1096   | fold_bal f xs =
  1097       let val (ps, qs) = chop (length xs div 2) xs
  1098       in  f (fold_bal f ps, fold_bal f qs)  end;
  1099 
  1100 (*construct something of the form f(...g(...(x)...)) for balanced access*)
  1101 fun access_bal (f, g, x) n i =
  1102   let fun acc n i =     (*1<=i<=n*)
  1103           if n=1 then x else
  1104           let val n2 = n div 2
  1105           in  if i<=n2 then f (acc n2 i)
  1106                        else g (acc (n-n2) (i-n2))
  1107           end
  1108   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
  1109 
  1110 (*construct ALL such accesses; could try harder to share recursive calls!*)
  1111 fun accesses_bal (f, g, x) n =
  1112   let fun acc n =
  1113           if n=1 then [x] else
  1114           let val n2 = n div 2
  1115               val acc2 = acc n2
  1116           in  if n-n2=n2 then map f acc2 @ map g acc2
  1117                          else map f acc2 @ map g (acc (n-n2)) end
  1118   in  if 1<=n then acc n else raise Balance  end;
  1119 
  1120 
  1121 
  1122 (** orders **)
  1123 
  1124 fun is_equal EQUAL = true
  1125   | is_equal _ = false;
  1126 
  1127 fun rev_order LESS = GREATER
  1128   | rev_order EQUAL = EQUAL
  1129   | rev_order GREATER = LESS;
  1130 
  1131 (*assume rel is a linear strict order*)
  1132 fun make_ord rel (x, y) =
  1133   if rel (x, y) then LESS
  1134   else if rel (y, x) then GREATER
  1135   else EQUAL;
  1136 
  1137 fun eq_ord ord xy =
  1138   case ord xy
  1139    of EQUAL => true
  1140     | _ => false;
  1141 
  1142 val int_ord = Int.compare;
  1143 val string_ord = String.compare;
  1144 
  1145 fun fast_string_ord (s1, s2) =
  1146   (case int_ord (size s1, size s2) of EQUAL => string_ord (s1, s2) | ord => ord);
  1147 
  1148 fun option_ord ord (SOME x, SOME y) = ord (x, y)
  1149   | option_ord _ (NONE, NONE) = EQUAL
  1150   | option_ord _ (NONE, SOME _) = LESS
  1151   | option_ord _ (SOME _, NONE) = GREATER;
  1152 
  1153 (*lexicographic product*)
  1154 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1155   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1156 
  1157 (*dictionary order -- in general NOT well-founded!*)
  1158 fun dict_ord elem_ord (x :: xs, y :: ys) =
  1159       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord)
  1160   | dict_ord _ ([], []) = EQUAL
  1161   | dict_ord _ ([], _ :: _) = LESS
  1162   | dict_ord _ (_ :: _, []) = GREATER;
  1163 
  1164 (*lexicographic product of lists*)
  1165 fun list_ord elem_ord (xs, ys) =
  1166   (case int_ord (length xs, length ys) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1167 
  1168 
  1169 (* sorting *)
  1170 
  1171 (*quicksort -- stable, i.e. does not reorder equal elements*)
  1172 fun quicksort unique ord =
  1173   let
  1174     fun qsort [] = []
  1175       | qsort (xs as [_]) = xs
  1176       | qsort (xs as [x, y]) =
  1177           (case ord (x, y) of
  1178             LESS => xs
  1179           | EQUAL => if unique then [x] else xs
  1180           | GREATER => [y, x])
  1181       | qsort xs =
  1182           let val (lts, eqs, gts) = part (nth xs (length xs div 2)) xs
  1183           in qsort lts @ eqs @ qsort gts end
  1184     and part _ [] = ([], [], [])
  1185       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1186     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1187       | add EQUAL x (lts, [], gts) = (lts, [x], gts)
  1188       | add EQUAL x (res as (lts, eqs, gts)) = if unique then res else (lts, x :: eqs, gts)
  1189       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1190   in qsort end;
  1191 
  1192 fun sort ord = quicksort false ord;
  1193 fun sort_distinct ord = quicksort true ord;
  1194 
  1195 val sort_strings = sort string_ord;
  1196 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1197 
  1198 
  1199 
  1200 (** random numbers **)
  1201 
  1202 exception RANDOM;
  1203 
  1204 fun rmod x y = x - y * Real.realFloor (x / y);
  1205 
  1206 local
  1207   val a = 16807.0;
  1208   val m = 2147483647.0;
  1209   val random_seed = ref 1.0;
  1210 in
  1211 
  1212 fun random () =
  1213   let val r = rmod (a * !random_seed) m
  1214   in (random_seed := r; r) end;
  1215 
  1216 end;
  1217 
  1218 fun random_range l h =
  1219   if h < l orelse l < 0 then raise RANDOM
  1220   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1221 
  1222 fun one_of xs = nth xs (random_range 0 (length xs - 1));
  1223 
  1224 fun frequency xs =
  1225   let
  1226     val sum = foldl op + (0, map fst xs);
  1227     fun pick n ((k: int, x) :: xs) =
  1228       if n <= k then x else pick (n - k) xs
  1229   in pick (random_range 1 sum) xs end;
  1230 
  1231 
  1232 (** current directory **)
  1233 
  1234 val cd = OS.FileSys.chDir;
  1235 val pwd = OS.FileSys.getDir;
  1236 
  1237 
  1238 (** misc **)
  1239 
  1240 (*Partition list into elements that satisfy predicate and those that don't.
  1241   Preserves order of elements in both lists.*)
  1242 val partition = List.partition;
  1243 
  1244 fun partition_eq (eq:'a * 'a -> bool) =
  1245   let
  1246     fun part [] = []
  1247       | part (x :: ys) =
  1248           let val (xs, xs') = partition (fn y => eq (x, y)) ys
  1249           in (x::xs)::(part xs') end
  1250   in part end;
  1251 
  1252 
  1253 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1254    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1255 fun partition_list p i j =
  1256   let fun part k xs =
  1257             if k>j then
  1258               (case xs of [] => []
  1259                          | _ => raise Fail "partition_list")
  1260             else
  1261             let val (ns, rest) = partition (p k) xs;
  1262             in  ns :: part(k+1)rest  end
  1263   in  part i end;
  1264 
  1265 
  1266 (* generating identifiers *)
  1267 
  1268 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1269 local
  1270 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1271 fun char i =      if i<26 then chr (ord "A" + i)
  1272              else if i<52 then chr (ord "a" + i - 26)
  1273              else if i<62 then chr (ord"0" + i - 52)
  1274              else if i=62 then "_"
  1275              else  (*i=63*)    "'";
  1276 
  1277 val charVec = Vector.tabulate (64, char);
  1278 
  1279 fun newid n =
  1280   let
  1281   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1282 
  1283 val seedr = ref 0;
  1284 
  1285 in
  1286 
  1287 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1288 
  1289 end;
  1290 
  1291 
  1292 (* lexical scanning *)
  1293 
  1294 (*scan a list of characters into "words" composed of "letters" (recognized by
  1295   is_let) and separated by any number of non-"letters"*)
  1296 fun scanwords is_let cs =
  1297   let fun scan1 [] = []
  1298         | scan1 cs =
  1299             let val (lets, rest) = take_prefix is_let cs
  1300             in implode lets :: scanwords is_let rest end;
  1301   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1302 
  1303 
  1304 (* stamps and serial numbers *)
  1305 
  1306 type stamp = unit ref;
  1307 val stamp: unit -> stamp = ref;
  1308 
  1309 type serial = int;
  1310 local val count = ref 0
  1311 in fun serial () = inc count end;
  1312 
  1313 val serial_string = string_of_int o serial;
  1314 
  1315 
  1316 (* generic objects *)
  1317 
  1318 (*note that the builtin exception datatype may be extended by new
  1319   constructors at any time*)
  1320 structure Object = struct type T = exn end;
  1321 
  1322 end;
  1323 
  1324 structure BasicLibrary: BASIC_LIBRARY = Library;
  1325 open BasicLibrary;