src/HOL/Transcendental.thy
author hoelzl
Mon Dec 03 18:19:05 2012 +0100 (2012-12-03)
changeset 50326 b5afeccab2db
parent 49962 a8cc904a6820
child 50346 a75c6429c3c3
permissions -rw-r--r--
add filterlim rules for exp and ln to infinity
     1 (*  Title:      HOL/Transcendental.thy
     2     Author:     Jacques D. Fleuriot, University of Cambridge, University of Edinburgh
     3     Author:     Lawrence C Paulson
     4 *)
     5 
     6 header{*Power Series, Transcendental Functions etc.*}
     7 
     8 theory Transcendental
     9 imports Fact Series Deriv NthRoot
    10 begin
    11 
    12 subsection {* Properties of Power Series *}
    13 
    14 lemma lemma_realpow_diff:
    15   fixes y :: "'a::monoid_mult"
    16   shows "p \<le> n \<Longrightarrow> y ^ (Suc n - p) = (y ^ (n - p)) * y"
    17 proof -
    18   assume "p \<le> n"
    19   hence "Suc n - p = Suc (n - p)" by (rule Suc_diff_le)
    20   thus ?thesis by (simp add: power_commutes)
    21 qed
    22 
    23 lemma lemma_realpow_diff_sumr:
    24   fixes y :: "'a::{comm_semiring_0,monoid_mult}" shows
    25      "(\<Sum>p=0..<Suc n. (x ^ p) * y ^ (Suc n - p)) =
    26       y * (\<Sum>p=0..<Suc n. (x ^ p) * y ^ (n - p))"
    27 by (simp add: setsum_right_distrib lemma_realpow_diff mult_ac
    28          del: setsum_op_ivl_Suc)
    29 
    30 lemma lemma_realpow_diff_sumr2:
    31   fixes y :: "'a::{comm_ring,monoid_mult}" shows
    32      "x ^ (Suc n) - y ^ (Suc n) =
    33       (x - y) * (\<Sum>p=0..<Suc n. (x ^ p) * y ^ (n - p))"
    34 apply (induct n, simp)
    35 apply (simp del: setsum_op_ivl_Suc)
    36 apply (subst setsum_op_ivl_Suc)
    37 apply (subst lemma_realpow_diff_sumr)
    38 apply (simp add: distrib_left del: setsum_op_ivl_Suc)
    39 apply (subst mult_left_commute [of "x - y"])
    40 apply (erule subst)
    41 apply (simp add: algebra_simps)
    42 done
    43 
    44 lemma lemma_realpow_rev_sumr:
    45      "(\<Sum>p=0..<Suc n. (x ^ p) * (y ^ (n - p))) =
    46       (\<Sum>p=0..<Suc n. (x ^ (n - p)) * (y ^ p))"
    47 apply (rule setsum_reindex_cong [where f="\<lambda>i. n - i"])
    48 apply (rule inj_onI, simp)
    49 apply auto
    50 apply (rule_tac x="n - x" in image_eqI, simp, simp)
    51 done
    52 
    53 text{*Power series has a `circle` of convergence, i.e. if it sums for @{term
    54 x}, then it sums absolutely for @{term z} with @{term "\<bar>z\<bar> < \<bar>x\<bar>"}.*}
    55 
    56 lemma powser_insidea:
    57   fixes x z :: "'a::real_normed_field"
    58   assumes 1: "summable (\<lambda>n. f n * x ^ n)"
    59   assumes 2: "norm z < norm x"
    60   shows "summable (\<lambda>n. norm (f n * z ^ n))"
    61 proof -
    62   from 2 have x_neq_0: "x \<noteq> 0" by clarsimp
    63   from 1 have "(\<lambda>n. f n * x ^ n) ----> 0"
    64     by (rule summable_LIMSEQ_zero)
    65   hence "convergent (\<lambda>n. f n * x ^ n)"
    66     by (rule convergentI)
    67   hence "Cauchy (\<lambda>n. f n * x ^ n)"
    68     by (rule convergent_Cauchy)
    69   hence "Bseq (\<lambda>n. f n * x ^ n)"
    70     by (rule Cauchy_Bseq)
    71   then obtain K where 3: "0 < K" and 4: "\<forall>n. norm (f n * x ^ n) \<le> K"
    72     by (simp add: Bseq_def, safe)
    73   have "\<exists>N. \<forall>n\<ge>N. norm (norm (f n * z ^ n)) \<le>
    74                    K * norm (z ^ n) * inverse (norm (x ^ n))"
    75   proof (intro exI allI impI)
    76     fix n::nat assume "0 \<le> n"
    77     have "norm (norm (f n * z ^ n)) * norm (x ^ n) =
    78           norm (f n * x ^ n) * norm (z ^ n)"
    79       by (simp add: norm_mult abs_mult)
    80     also have "\<dots> \<le> K * norm (z ^ n)"
    81       by (simp only: mult_right_mono 4 norm_ge_zero)
    82     also have "\<dots> = K * norm (z ^ n) * (inverse (norm (x ^ n)) * norm (x ^ n))"
    83       by (simp add: x_neq_0)
    84     also have "\<dots> = K * norm (z ^ n) * inverse (norm (x ^ n)) * norm (x ^ n)"
    85       by (simp only: mult_assoc)
    86     finally show "norm (norm (f n * z ^ n)) \<le>
    87                   K * norm (z ^ n) * inverse (norm (x ^ n))"
    88       by (simp add: mult_le_cancel_right x_neq_0)
    89   qed
    90   moreover have "summable (\<lambda>n. K * norm (z ^ n) * inverse (norm (x ^ n)))"
    91   proof -
    92     from 2 have "norm (norm (z * inverse x)) < 1"
    93       using x_neq_0
    94       by (simp add: nonzero_norm_divide divide_inverse [symmetric])
    95     hence "summable (\<lambda>n. norm (z * inverse x) ^ n)"
    96       by (rule summable_geometric)
    97     hence "summable (\<lambda>n. K * norm (z * inverse x) ^ n)"
    98       by (rule summable_mult)
    99     thus "summable (\<lambda>n. K * norm (z ^ n) * inverse (norm (x ^ n)))"
   100       using x_neq_0
   101       by (simp add: norm_mult nonzero_norm_inverse power_mult_distrib
   102                     power_inverse norm_power mult_assoc)
   103   qed
   104   ultimately show "summable (\<lambda>n. norm (f n * z ^ n))"
   105     by (rule summable_comparison_test)
   106 qed
   107 
   108 lemma powser_inside:
   109   fixes f :: "nat \<Rightarrow> 'a::{real_normed_field,banach}" shows
   110      "[| summable (%n. f(n) * (x ^ n)); norm z < norm x |]
   111       ==> summable (%n. f(n) * (z ^ n))"
   112 by (rule powser_insidea [THEN summable_norm_cancel])
   113 
   114 lemma sum_split_even_odd: fixes f :: "nat \<Rightarrow> real" shows
   115   "(\<Sum> i = 0 ..< 2 * n. if even i then f i else g i) =
   116    (\<Sum> i = 0 ..< n. f (2 * i)) + (\<Sum> i = 0 ..< n. g (2 * i + 1))"
   117 proof (induct n)
   118   case (Suc n)
   119   have "(\<Sum> i = 0 ..< 2 * Suc n. if even i then f i else g i) =
   120         (\<Sum> i = 0 ..< n. f (2 * i)) + (\<Sum> i = 0 ..< n. g (2 * i + 1)) + (f (2 * n) + g (2 * n + 1))"
   121     using Suc.hyps unfolding One_nat_def by auto
   122   also have "\<dots> = (\<Sum> i = 0 ..< Suc n. f (2 * i)) + (\<Sum> i = 0 ..< Suc n. g (2 * i + 1))" by auto
   123   finally show ?case .
   124 qed auto
   125 
   126 lemma sums_if': fixes g :: "nat \<Rightarrow> real" assumes "g sums x"
   127   shows "(\<lambda> n. if even n then 0 else g ((n - 1) div 2)) sums x"
   128   unfolding sums_def
   129 proof (rule LIMSEQ_I)
   130   fix r :: real assume "0 < r"
   131   from `g sums x`[unfolded sums_def, THEN LIMSEQ_D, OF this]
   132   obtain no where no_eq: "\<And> n. n \<ge> no \<Longrightarrow> (norm (setsum g { 0..<n } - x) < r)" by blast
   133 
   134   let ?SUM = "\<lambda> m. \<Sum> i = 0 ..< m. if even i then 0 else g ((i - 1) div 2)"
   135   { fix m assume "m \<ge> 2 * no" hence "m div 2 \<ge> no" by auto
   136     have sum_eq: "?SUM (2 * (m div 2)) = setsum g { 0 ..< m div 2 }"
   137       using sum_split_even_odd by auto
   138     hence "(norm (?SUM (2 * (m div 2)) - x) < r)" using no_eq unfolding sum_eq using `m div 2 \<ge> no` by auto
   139     moreover
   140     have "?SUM (2 * (m div 2)) = ?SUM m"
   141     proof (cases "even m")
   142       case True show ?thesis unfolding even_nat_div_two_times_two[OF True, unfolded numeral_2_eq_2[symmetric]] ..
   143     next
   144       case False hence "even (Suc m)" by auto
   145       from even_nat_div_two_times_two[OF this, unfolded numeral_2_eq_2[symmetric]] odd_nat_plus_one_div_two[OF False, unfolded numeral_2_eq_2[symmetric]]
   146       have eq: "Suc (2 * (m div 2)) = m" by auto
   147       hence "even (2 * (m div 2))" using `odd m` by auto
   148       have "?SUM m = ?SUM (Suc (2 * (m div 2)))" unfolding eq ..
   149       also have "\<dots> = ?SUM (2 * (m div 2))" using `even (2 * (m div 2))` by auto
   150       finally show ?thesis by auto
   151     qed
   152     ultimately have "(norm (?SUM m - x) < r)" by auto
   153   }
   154   thus "\<exists> no. \<forall> m \<ge> no. norm (?SUM m - x) < r" by blast
   155 qed
   156 
   157 lemma sums_if: fixes g :: "nat \<Rightarrow> real" assumes "g sums x" and "f sums y"
   158   shows "(\<lambda> n. if even n then f (n div 2) else g ((n - 1) div 2)) sums (x + y)"
   159 proof -
   160   let ?s = "\<lambda> n. if even n then 0 else f ((n - 1) div 2)"
   161   { fix B T E have "(if B then (0 :: real) else E) + (if B then T else 0) = (if B then T else E)"
   162       by (cases B) auto } note if_sum = this
   163   have g_sums: "(\<lambda> n. if even n then 0 else g ((n - 1) div 2)) sums x" using sums_if'[OF `g sums x`] .
   164   {
   165     have "?s 0 = 0" by auto
   166     have Suc_m1: "\<And> n. Suc n - 1 = n" by auto
   167     have if_eq: "\<And>B T E. (if \<not> B then T else E) = (if B then E else T)" by auto
   168 
   169     have "?s sums y" using sums_if'[OF `f sums y`] .
   170     from this[unfolded sums_def, THEN LIMSEQ_Suc]
   171     have "(\<lambda> n. if even n then f (n div 2) else 0) sums y"
   172       unfolding sums_def setsum_shift_lb_Suc0_0_upt[where f="?s", OF `?s 0 = 0`, symmetric]
   173                 image_Suc_atLeastLessThan[symmetric] setsum_reindex[OF inj_Suc, unfolded comp_def]
   174                 even_Suc Suc_m1 if_eq .
   175   } from sums_add[OF g_sums this]
   176   show ?thesis unfolding if_sum .
   177 qed
   178 
   179 subsection {* Alternating series test / Leibniz formula *}
   180 
   181 lemma sums_alternating_upper_lower:
   182   fixes a :: "nat \<Rightarrow> real"
   183   assumes mono: "\<And>n. a (Suc n) \<le> a n" and a_pos: "\<And>n. 0 \<le> a n" and "a ----> 0"
   184   shows "\<exists>l. ((\<forall>n. (\<Sum>i=0..<2*n. -1^i*a i) \<le> l) \<and> (\<lambda> n. \<Sum>i=0..<2*n. -1^i*a i) ----> l) \<and>
   185              ((\<forall>n. l \<le> (\<Sum>i=0..<2*n + 1. -1^i*a i)) \<and> (\<lambda> n. \<Sum>i=0..<2*n + 1. -1^i*a i) ----> l)"
   186   (is "\<exists>l. ((\<forall>n. ?f n \<le> l) \<and> _) \<and> ((\<forall>n. l \<le> ?g n) \<and> _)")
   187 proof -
   188   have fg_diff: "\<And>n. ?f n - ?g n = - a (2 * n)" unfolding One_nat_def by auto
   189 
   190   have "\<forall> n. ?f n \<le> ?f (Suc n)"
   191   proof fix n show "?f n \<le> ?f (Suc n)" using mono[of "2*n"] by auto qed
   192   moreover
   193   have "\<forall> n. ?g (Suc n) \<le> ?g n"
   194   proof fix n show "?g (Suc n) \<le> ?g n" using mono[of "Suc (2*n)"]
   195     unfolding One_nat_def by auto qed
   196   moreover
   197   have "\<forall> n. ?f n \<le> ?g n"
   198   proof fix n show "?f n \<le> ?g n" using fg_diff a_pos
   199     unfolding One_nat_def by auto qed
   200   moreover
   201   have "(\<lambda> n. ?f n - ?g n) ----> 0" unfolding fg_diff
   202   proof (rule LIMSEQ_I)
   203     fix r :: real assume "0 < r"
   204     with `a ----> 0`[THEN LIMSEQ_D]
   205     obtain N where "\<And> n. n \<ge> N \<Longrightarrow> norm (a n - 0) < r" by auto
   206     hence "\<forall> n \<ge> N. norm (- a (2 * n) - 0) < r" by auto
   207     thus "\<exists> N. \<forall> n \<ge> N. norm (- a (2 * n) - 0) < r" by auto
   208   qed
   209   ultimately
   210   show ?thesis by (rule lemma_nest_unique)
   211 qed
   212 
   213 lemma summable_Leibniz': fixes a :: "nat \<Rightarrow> real"
   214   assumes a_zero: "a ----> 0" and a_pos: "\<And> n. 0 \<le> a n"
   215   and a_monotone: "\<And> n. a (Suc n) \<le> a n"
   216   shows summable: "summable (\<lambda> n. (-1)^n * a n)"
   217   and "\<And>n. (\<Sum>i=0..<2*n. (-1)^i*a i) \<le> (\<Sum>i. (-1)^i*a i)"
   218   and "(\<lambda>n. \<Sum>i=0..<2*n. (-1)^i*a i) ----> (\<Sum>i. (-1)^i*a i)"
   219   and "\<And>n. (\<Sum>i. (-1)^i*a i) \<le> (\<Sum>i=0..<2*n+1. (-1)^i*a i)"
   220   and "(\<lambda>n. \<Sum>i=0..<2*n+1. (-1)^i*a i) ----> (\<Sum>i. (-1)^i*a i)"
   221 proof -
   222   let "?S n" = "(-1)^n * a n"
   223   let "?P n" = "\<Sum>i=0..<n. ?S i"
   224   let "?f n" = "?P (2 * n)"
   225   let "?g n" = "?P (2 * n + 1)"
   226   obtain l :: real where below_l: "\<forall> n. ?f n \<le> l" and "?f ----> l" and above_l: "\<forall> n. l \<le> ?g n" and "?g ----> l"
   227     using sums_alternating_upper_lower[OF a_monotone a_pos a_zero] by blast
   228 
   229   let ?Sa = "\<lambda> m. \<Sum> n = 0..<m. ?S n"
   230   have "?Sa ----> l"
   231   proof (rule LIMSEQ_I)
   232     fix r :: real assume "0 < r"
   233 
   234     with `?f ----> l`[THEN LIMSEQ_D]
   235     obtain f_no where f: "\<And> n. n \<ge> f_no \<Longrightarrow> norm (?f n - l) < r" by auto
   236 
   237     from `0 < r` `?g ----> l`[THEN LIMSEQ_D]
   238     obtain g_no where g: "\<And> n. n \<ge> g_no \<Longrightarrow> norm (?g n - l) < r" by auto
   239 
   240     { fix n :: nat
   241       assume "n \<ge> (max (2 * f_no) (2 * g_no))" hence "n \<ge> 2 * f_no" and "n \<ge> 2 * g_no" by auto
   242       have "norm (?Sa n - l) < r"
   243       proof (cases "even n")
   244         case True from even_nat_div_two_times_two[OF this]
   245         have n_eq: "2 * (n div 2) = n" unfolding numeral_2_eq_2[symmetric] by auto
   246         with `n \<ge> 2 * f_no` have "n div 2 \<ge> f_no" by auto
   247         from f[OF this]
   248         show ?thesis unfolding n_eq atLeastLessThanSuc_atLeastAtMost .
   249       next
   250         case False hence "even (n - 1)" by simp
   251         from even_nat_div_two_times_two[OF this]
   252         have n_eq: "2 * ((n - 1) div 2) = n - 1" unfolding numeral_2_eq_2[symmetric] by auto
   253         hence range_eq: "n - 1 + 1 = n" using odd_pos[OF False] by auto
   254 
   255         from n_eq `n \<ge> 2 * g_no` have "(n - 1) div 2 \<ge> g_no" by auto
   256         from g[OF this]
   257         show ?thesis unfolding n_eq atLeastLessThanSuc_atLeastAtMost range_eq .
   258       qed
   259     }
   260     thus "\<exists> no. \<forall> n \<ge> no. norm (?Sa n - l) < r" by blast
   261   qed
   262   hence sums_l: "(\<lambda>i. (-1)^i * a i) sums l" unfolding sums_def atLeastLessThanSuc_atLeastAtMost[symmetric] .
   263   thus "summable ?S" using summable_def by auto
   264 
   265   have "l = suminf ?S" using sums_unique[OF sums_l] .
   266 
   267   { fix n show "suminf ?S \<le> ?g n" unfolding sums_unique[OF sums_l, symmetric] using above_l by auto }
   268   { fix n show "?f n \<le> suminf ?S" unfolding sums_unique[OF sums_l, symmetric] using below_l by auto }
   269   show "?g ----> suminf ?S" using `?g ----> l` `l = suminf ?S` by auto
   270   show "?f ----> suminf ?S" using `?f ----> l` `l = suminf ?S` by auto
   271 qed
   272 
   273 theorem summable_Leibniz: fixes a :: "nat \<Rightarrow> real"
   274   assumes a_zero: "a ----> 0" and "monoseq a"
   275   shows "summable (\<lambda> n. (-1)^n * a n)" (is "?summable")
   276   and "0 < a 0 \<longrightarrow> (\<forall>n. (\<Sum>i. -1^i*a i) \<in> { \<Sum>i=0..<2*n. -1^i * a i .. \<Sum>i=0..<2*n+1. -1^i * a i})" (is "?pos")
   277   and "a 0 < 0 \<longrightarrow> (\<forall>n. (\<Sum>i. -1^i*a i) \<in> { \<Sum>i=0..<2*n+1. -1^i * a i .. \<Sum>i=0..<2*n. -1^i * a i})" (is "?neg")
   278   and "(\<lambda>n. \<Sum>i=0..<2*n. -1^i*a i) ----> (\<Sum>i. -1^i*a i)" (is "?f")
   279   and "(\<lambda>n. \<Sum>i=0..<2*n+1. -1^i*a i) ----> (\<Sum>i. -1^i*a i)" (is "?g")
   280 proof -
   281   have "?summable \<and> ?pos \<and> ?neg \<and> ?f \<and> ?g"
   282   proof (cases "(\<forall> n. 0 \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m)")
   283     case True
   284     hence ord: "\<And>n m. m \<le> n \<Longrightarrow> a n \<le> a m" and ge0: "\<And> n. 0 \<le> a n" by auto
   285     { fix n have "a (Suc n) \<le> a n" using ord[where n="Suc n" and m=n] by auto }
   286     note leibniz = summable_Leibniz'[OF `a ----> 0` ge0] and mono = this
   287     from leibniz[OF mono]
   288     show ?thesis using `0 \<le> a 0` by auto
   289   next
   290     let ?a = "\<lambda> n. - a n"
   291     case False
   292     with monoseq_le[OF `monoseq a` `a ----> 0`]
   293     have "(\<forall> n. a n \<le> 0) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)" by auto
   294     hence ord: "\<And>n m. m \<le> n \<Longrightarrow> ?a n \<le> ?a m" and ge0: "\<And> n. 0 \<le> ?a n" by auto
   295     { fix n have "?a (Suc n) \<le> ?a n" using ord[where n="Suc n" and m=n] by auto }
   296     note monotone = this
   297     note leibniz = summable_Leibniz'[OF _ ge0, of "\<lambda>x. x", OF tendsto_minus[OF `a ----> 0`, unfolded minus_zero] monotone]
   298     have "summable (\<lambda> n. (-1)^n * ?a n)" using leibniz(1) by auto
   299     then obtain l where "(\<lambda> n. (-1)^n * ?a n) sums l" unfolding summable_def by auto
   300     from this[THEN sums_minus]
   301     have "(\<lambda> n. (-1)^n * a n) sums -l" by auto
   302     hence ?summable unfolding summable_def by auto
   303     moreover
   304     have "\<And> a b :: real. \<bar> - a - - b \<bar> = \<bar>a - b\<bar>" unfolding minus_diff_minus by auto
   305 
   306     from suminf_minus[OF leibniz(1), unfolded mult_minus_right minus_minus]
   307     have move_minus: "(\<Sum>n. - (-1 ^ n * a n)) = - (\<Sum>n. -1 ^ n * a n)" by auto
   308 
   309     have ?pos using `0 \<le> ?a 0` by auto
   310     moreover have ?neg using leibniz(2,4) unfolding mult_minus_right setsum_negf move_minus neg_le_iff_le by auto
   311     moreover have ?f and ?g using leibniz(3,5)[unfolded mult_minus_right setsum_negf move_minus, THEN tendsto_minus_cancel] by auto
   312     ultimately show ?thesis by auto
   313   qed
   314   from this[THEN conjunct1] this[THEN conjunct2, THEN conjunct1] this[THEN conjunct2, THEN conjunct2, THEN conjunct1] this[THEN conjunct2, THEN conjunct2, THEN conjunct2, THEN conjunct1]
   315        this[THEN conjunct2, THEN conjunct2, THEN conjunct2, THEN conjunct2]
   316   show ?summable and ?pos and ?neg and ?f and ?g .
   317 qed
   318 
   319 subsection {* Term-by-Term Differentiability of Power Series *}
   320 
   321 definition
   322   diffs :: "(nat => 'a::ring_1) => nat => 'a" where
   323   "diffs c = (%n. of_nat (Suc n) * c(Suc n))"
   324 
   325 text{*Lemma about distributing negation over it*}
   326 lemma diffs_minus: "diffs (%n. - c n) = (%n. - diffs c n)"
   327 by (simp add: diffs_def)
   328 
   329 lemma sums_Suc_imp:
   330   assumes f: "f 0 = 0"
   331   shows "(\<lambda>n. f (Suc n)) sums s \<Longrightarrow> (\<lambda>n. f n) sums s"
   332 unfolding sums_def
   333 apply (rule LIMSEQ_imp_Suc)
   334 apply (subst setsum_shift_lb_Suc0_0_upt [where f=f, OF f, symmetric])
   335 apply (simp only: setsum_shift_bounds_Suc_ivl)
   336 done
   337 
   338 lemma diffs_equiv:
   339   fixes x :: "'a::{real_normed_vector, ring_1}"
   340   shows "summable (%n. (diffs c)(n) * (x ^ n)) ==>
   341       (%n. of_nat n * c(n) * (x ^ (n - Suc 0))) sums
   342          (\<Sum>n. (diffs c)(n) * (x ^ n))"
   343 unfolding diffs_def
   344 apply (drule summable_sums)
   345 apply (rule sums_Suc_imp, simp_all)
   346 done
   347 
   348 lemma lemma_termdiff1:
   349   fixes z :: "'a :: {monoid_mult,comm_ring}" shows
   350   "(\<Sum>p=0..<m. (((z + h) ^ (m - p)) * (z ^ p)) - (z ^ m)) =
   351    (\<Sum>p=0..<m. (z ^ p) * (((z + h) ^ (m - p)) - (z ^ (m - p))))"
   352 by(auto simp add: algebra_simps power_add [symmetric])
   353 
   354 lemma sumr_diff_mult_const2:
   355   "setsum f {0..<n} - of_nat n * (r::'a::ring_1) = (\<Sum>i = 0..<n. f i - r)"
   356 by (simp add: setsum_subtractf)
   357 
   358 lemma lemma_termdiff2:
   359   fixes h :: "'a :: {field}"
   360   assumes h: "h \<noteq> 0" shows
   361   "((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0) =
   362    h * (\<Sum>p=0..< n - Suc 0. \<Sum>q=0..< n - Suc 0 - p.
   363         (z + h) ^ q * z ^ (n - 2 - q))" (is "?lhs = ?rhs")
   364 apply (subgoal_tac "h * ?lhs = h * ?rhs", simp add: h)
   365 apply (simp add: right_diff_distrib diff_divide_distrib h)
   366 apply (simp add: mult_assoc [symmetric])
   367 apply (cases "n", simp)
   368 apply (simp add: lemma_realpow_diff_sumr2 h
   369                  right_diff_distrib [symmetric] mult_assoc
   370             del: power_Suc setsum_op_ivl_Suc of_nat_Suc)
   371 apply (subst lemma_realpow_rev_sumr)
   372 apply (subst sumr_diff_mult_const2)
   373 apply simp
   374 apply (simp only: lemma_termdiff1 setsum_right_distrib)
   375 apply (rule setsum_cong [OF refl])
   376 apply (simp add: diff_minus [symmetric] less_iff_Suc_add)
   377 apply (clarify)
   378 apply (simp add: setsum_right_distrib lemma_realpow_diff_sumr2 mult_ac
   379             del: setsum_op_ivl_Suc power_Suc)
   380 apply (subst mult_assoc [symmetric], subst power_add [symmetric])
   381 apply (simp add: mult_ac)
   382 done
   383 
   384 lemma real_setsum_nat_ivl_bounded2:
   385   fixes K :: "'a::linordered_semidom"
   386   assumes f: "\<And>p::nat. p < n \<Longrightarrow> f p \<le> K"
   387   assumes K: "0 \<le> K"
   388   shows "setsum f {0..<n-k} \<le> of_nat n * K"
   389 apply (rule order_trans [OF setsum_mono])
   390 apply (rule f, simp)
   391 apply (simp add: mult_right_mono K)
   392 done
   393 
   394 lemma lemma_termdiff3:
   395   fixes h z :: "'a::{real_normed_field}"
   396   assumes 1: "h \<noteq> 0"
   397   assumes 2: "norm z \<le> K"
   398   assumes 3: "norm (z + h) \<le> K"
   399   shows "norm (((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0))
   400           \<le> of_nat n * of_nat (n - Suc 0) * K ^ (n - 2) * norm h"
   401 proof -
   402   have "norm (((z + h) ^ n - z ^ n) / h - of_nat n * z ^ (n - Suc 0)) =
   403         norm (\<Sum>p = 0..<n - Suc 0. \<Sum>q = 0..<n - Suc 0 - p.
   404           (z + h) ^ q * z ^ (n - 2 - q)) * norm h"
   405     apply (subst lemma_termdiff2 [OF 1])
   406     apply (subst norm_mult)
   407     apply (rule mult_commute)
   408     done
   409   also have "\<dots> \<le> of_nat n * (of_nat (n - Suc 0) * K ^ (n - 2)) * norm h"
   410   proof (rule mult_right_mono [OF _ norm_ge_zero])
   411     from norm_ge_zero 2 have K: "0 \<le> K" by (rule order_trans)
   412     have le_Kn: "\<And>i j n. i + j = n \<Longrightarrow> norm ((z + h) ^ i * z ^ j) \<le> K ^ n"
   413       apply (erule subst)
   414       apply (simp only: norm_mult norm_power power_add)
   415       apply (intro mult_mono power_mono 2 3 norm_ge_zero zero_le_power K)
   416       done
   417     show "norm (\<Sum>p = 0..<n - Suc 0. \<Sum>q = 0..<n - Suc 0 - p.
   418               (z + h) ^ q * z ^ (n - 2 - q))
   419           \<le> of_nat n * (of_nat (n - Suc 0) * K ^ (n - 2))"
   420       apply (intro
   421          order_trans [OF norm_setsum]
   422          real_setsum_nat_ivl_bounded2
   423          mult_nonneg_nonneg
   424          of_nat_0_le_iff
   425          zero_le_power K)
   426       apply (rule le_Kn, simp)
   427       done
   428   qed
   429   also have "\<dots> = of_nat n * of_nat (n - Suc 0) * K ^ (n - 2) * norm h"
   430     by (simp only: mult_assoc)
   431   finally show ?thesis .
   432 qed
   433 
   434 lemma lemma_termdiff4:
   435   fixes f :: "'a::{real_normed_field} \<Rightarrow>
   436               'b::real_normed_vector"
   437   assumes k: "0 < (k::real)"
   438   assumes le: "\<And>h. \<lbrakk>h \<noteq> 0; norm h < k\<rbrakk> \<Longrightarrow> norm (f h) \<le> K * norm h"
   439   shows "f -- 0 --> 0"
   440 unfolding LIM_eq diff_0_right
   441 proof (safe)
   442   let ?h = "of_real (k / 2)::'a"
   443   have "?h \<noteq> 0" and "norm ?h < k" using k by simp_all
   444   hence "norm (f ?h) \<le> K * norm ?h" by (rule le)
   445   hence "0 \<le> K * norm ?h" by (rule order_trans [OF norm_ge_zero])
   446   hence zero_le_K: "0 \<le> K" using k by (simp add: zero_le_mult_iff)
   447 
   448   fix r::real assume r: "0 < r"
   449   show "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)"
   450   proof (cases)
   451     assume "K = 0"
   452     with k r le have "0 < k \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < k \<longrightarrow> norm (f x) < r)"
   453       by simp
   454     thus "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)" ..
   455   next
   456     assume K_neq_zero: "K \<noteq> 0"
   457     with zero_le_K have K: "0 < K" by simp
   458     show "\<exists>s. 0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> norm x < s \<longrightarrow> norm (f x) < r)"
   459     proof (rule exI, safe)
   460       from k r K show "0 < min k (r * inverse K / 2)"
   461         by (simp add: mult_pos_pos positive_imp_inverse_positive)
   462     next
   463       fix x::'a
   464       assume x1: "x \<noteq> 0" and x2: "norm x < min k (r * inverse K / 2)"
   465       from x2 have x3: "norm x < k" and x4: "norm x < r * inverse K / 2"
   466         by simp_all
   467       from x1 x3 le have "norm (f x) \<le> K * norm x" by simp
   468       also from x4 K have "K * norm x < K * (r * inverse K / 2)"
   469         by (rule mult_strict_left_mono)
   470       also have "\<dots> = r / 2"
   471         using K_neq_zero by simp
   472       also have "r / 2 < r"
   473         using r by simp
   474       finally show "norm (f x) < r" .
   475     qed
   476   qed
   477 qed
   478 
   479 lemma lemma_termdiff5:
   480   fixes g :: "'a::{real_normed_field} \<Rightarrow>
   481               nat \<Rightarrow> 'b::banach"
   482   assumes k: "0 < (k::real)"
   483   assumes f: "summable f"
   484   assumes le: "\<And>h n. \<lbrakk>h \<noteq> 0; norm h < k\<rbrakk> \<Longrightarrow> norm (g h n) \<le> f n * norm h"
   485   shows "(\<lambda>h. suminf (g h)) -- 0 --> 0"
   486 proof (rule lemma_termdiff4 [OF k])
   487   fix h::'a assume "h \<noteq> 0" and "norm h < k"
   488   hence A: "\<forall>n. norm (g h n) \<le> f n * norm h"
   489     by (simp add: le)
   490   hence "\<exists>N. \<forall>n\<ge>N. norm (norm (g h n)) \<le> f n * norm h"
   491     by simp
   492   moreover from f have B: "summable (\<lambda>n. f n * norm h)"
   493     by (rule summable_mult2)
   494   ultimately have C: "summable (\<lambda>n. norm (g h n))"
   495     by (rule summable_comparison_test)
   496   hence "norm (suminf (g h)) \<le> (\<Sum>n. norm (g h n))"
   497     by (rule summable_norm)
   498   also from A C B have "(\<Sum>n. norm (g h n)) \<le> (\<Sum>n. f n * norm h)"
   499     by (rule summable_le)
   500   also from f have "(\<Sum>n. f n * norm h) = suminf f * norm h"
   501     by (rule suminf_mult2 [symmetric])
   502   finally show "norm (suminf (g h)) \<le> suminf f * norm h" .
   503 qed
   504 
   505 
   506 text{* FIXME: Long proofs*}
   507 
   508 lemma termdiffs_aux:
   509   fixes x :: "'a::{real_normed_field,banach}"
   510   assumes 1: "summable (\<lambda>n. diffs (diffs c) n * K ^ n)"
   511   assumes 2: "norm x < norm K"
   512   shows "(\<lambda>h. \<Sum>n. c n * (((x + h) ^ n - x ^ n) / h
   513              - of_nat n * x ^ (n - Suc 0))) -- 0 --> 0"
   514 proof -
   515   from dense [OF 2]
   516   obtain r where r1: "norm x < r" and r2: "r < norm K" by fast
   517   from norm_ge_zero r1 have r: "0 < r"
   518     by (rule order_le_less_trans)
   519   hence r_neq_0: "r \<noteq> 0" by simp
   520   show ?thesis
   521   proof (rule lemma_termdiff5)
   522     show "0 < r - norm x" using r1 by simp
   523   next
   524     from r r2 have "norm (of_real r::'a) < norm K"
   525       by simp
   526     with 1 have "summable (\<lambda>n. norm (diffs (diffs c) n * (of_real r ^ n)))"
   527       by (rule powser_insidea)
   528     hence "summable (\<lambda>n. diffs (diffs (\<lambda>n. norm (c n))) n * r ^ n)"
   529       using r
   530       by (simp add: diffs_def norm_mult norm_power del: of_nat_Suc)
   531     hence "summable (\<lambda>n. of_nat n * diffs (\<lambda>n. norm (c n)) n * r ^ (n - Suc 0))"
   532       by (rule diffs_equiv [THEN sums_summable])
   533     also have "(\<lambda>n. of_nat n * diffs (\<lambda>n. norm (c n)) n * r ^ (n - Suc 0))
   534       = (\<lambda>n. diffs (%m. of_nat (m - Suc 0) * norm (c m) * inverse r) n * (r ^ n))"
   535       apply (rule ext)
   536       apply (simp add: diffs_def)
   537       apply (case_tac n, simp_all add: r_neq_0)
   538       done
   539     finally have "summable
   540       (\<lambda>n. of_nat n * (of_nat (n - Suc 0) * norm (c n) * inverse r) * r ^ (n - Suc 0))"
   541       by (rule diffs_equiv [THEN sums_summable])
   542     also have
   543       "(\<lambda>n. of_nat n * (of_nat (n - Suc 0) * norm (c n) * inverse r) *
   544            r ^ (n - Suc 0)) =
   545        (\<lambda>n. norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2))"
   546       apply (rule ext)
   547       apply (case_tac "n", simp)
   548       apply (case_tac "nat", simp)
   549       apply (simp add: r_neq_0)
   550       done
   551     finally show
   552       "summable (\<lambda>n. norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2))" .
   553   next
   554     fix h::'a and n::nat
   555     assume h: "h \<noteq> 0"
   556     assume "norm h < r - norm x"
   557     hence "norm x + norm h < r" by simp
   558     with norm_triangle_ineq have xh: "norm (x + h) < r"
   559       by (rule order_le_less_trans)
   560     show "norm (c n * (((x + h) ^ n - x ^ n) / h - of_nat n * x ^ (n - Suc 0)))
   561           \<le> norm (c n) * of_nat n * of_nat (n - Suc 0) * r ^ (n - 2) * norm h"
   562       apply (simp only: norm_mult mult_assoc)
   563       apply (rule mult_left_mono [OF _ norm_ge_zero])
   564       apply (simp (no_asm) add: mult_assoc [symmetric])
   565       apply (rule lemma_termdiff3)
   566       apply (rule h)
   567       apply (rule r1 [THEN order_less_imp_le])
   568       apply (rule xh [THEN order_less_imp_le])
   569       done
   570   qed
   571 qed
   572 
   573 lemma termdiffs:
   574   fixes K x :: "'a::{real_normed_field,banach}"
   575   assumes 1: "summable (\<lambda>n. c n * K ^ n)"
   576   assumes 2: "summable (\<lambda>n. (diffs c) n * K ^ n)"
   577   assumes 3: "summable (\<lambda>n. (diffs (diffs c)) n * K ^ n)"
   578   assumes 4: "norm x < norm K"
   579   shows "DERIV (\<lambda>x. \<Sum>n. c n * x ^ n) x :> (\<Sum>n. (diffs c) n * x ^ n)"
   580 unfolding deriv_def
   581 proof (rule LIM_zero_cancel)
   582   show "(\<lambda>h. (suminf (\<lambda>n. c n * (x + h) ^ n) - suminf (\<lambda>n. c n * x ^ n)) / h
   583             - suminf (\<lambda>n. diffs c n * x ^ n)) -- 0 --> 0"
   584   proof (rule LIM_equal2)
   585     show "0 < norm K - norm x" using 4 by (simp add: less_diff_eq)
   586   next
   587     fix h :: 'a
   588     assume "h \<noteq> 0"
   589     assume "norm (h - 0) < norm K - norm x"
   590     hence "norm x + norm h < norm K" by simp
   591     hence 5: "norm (x + h) < norm K"
   592       by (rule norm_triangle_ineq [THEN order_le_less_trans])
   593     have A: "summable (\<lambda>n. c n * x ^ n)"
   594       by (rule powser_inside [OF 1 4])
   595     have B: "summable (\<lambda>n. c n * (x + h) ^ n)"
   596       by (rule powser_inside [OF 1 5])
   597     have C: "summable (\<lambda>n. diffs c n * x ^ n)"
   598       by (rule powser_inside [OF 2 4])
   599     show "((\<Sum>n. c n * (x + h) ^ n) - (\<Sum>n. c n * x ^ n)) / h
   600              - (\<Sum>n. diffs c n * x ^ n) =
   601           (\<Sum>n. c n * (((x + h) ^ n - x ^ n) / h - of_nat n * x ^ (n - Suc 0)))"
   602       apply (subst sums_unique [OF diffs_equiv [OF C]])
   603       apply (subst suminf_diff [OF B A])
   604       apply (subst suminf_divide [symmetric])
   605       apply (rule summable_diff [OF B A])
   606       apply (subst suminf_diff)
   607       apply (rule summable_divide)
   608       apply (rule summable_diff [OF B A])
   609       apply (rule sums_summable [OF diffs_equiv [OF C]])
   610       apply (rule arg_cong [where f="suminf"], rule ext)
   611       apply (simp add: algebra_simps)
   612       done
   613   next
   614     show "(\<lambda>h. \<Sum>n. c n * (((x + h) ^ n - x ^ n) / h -
   615                of_nat n * x ^ (n - Suc 0))) -- 0 --> 0"
   616         by (rule termdiffs_aux [OF 3 4])
   617   qed
   618 qed
   619 
   620 
   621 subsection {* Derivability of power series *}
   622 
   623 lemma DERIV_series': fixes f :: "real \<Rightarrow> nat \<Rightarrow> real"
   624   assumes DERIV_f: "\<And> n. DERIV (\<lambda> x. f x n) x0 :> (f' x0 n)"
   625   and allf_summable: "\<And> x. x \<in> {a <..< b} \<Longrightarrow> summable (f x)" and x0_in_I: "x0 \<in> {a <..< b}"
   626   and "summable (f' x0)"
   627   and "summable L" and L_def: "\<And> n x y. \<lbrakk> x \<in> { a <..< b} ; y \<in> { a <..< b} \<rbrakk> \<Longrightarrow> \<bar> f x n - f y n \<bar> \<le> L n * \<bar> x - y \<bar>"
   628   shows "DERIV (\<lambda> x. suminf (f x)) x0 :> (suminf (f' x0))"
   629   unfolding deriv_def
   630 proof (rule LIM_I)
   631   fix r :: real assume "0 < r" hence "0 < r/3" by auto
   632 
   633   obtain N_L where N_L: "\<And> n. N_L \<le> n \<Longrightarrow> \<bar> \<Sum> i. L (i + n) \<bar> < r/3"
   634     using suminf_exist_split[OF `0 < r/3` `summable L`] by auto
   635 
   636   obtain N_f' where N_f': "\<And> n. N_f' \<le> n \<Longrightarrow> \<bar> \<Sum> i. f' x0 (i + n) \<bar> < r/3"
   637     using suminf_exist_split[OF `0 < r/3` `summable (f' x0)`] by auto
   638 
   639   let ?N = "Suc (max N_L N_f')"
   640   have "\<bar> \<Sum> i. f' x0 (i + ?N) \<bar> < r/3" (is "?f'_part < r/3") and
   641     L_estimate: "\<bar> \<Sum> i. L (i + ?N) \<bar> < r/3" using N_L[of "?N"] and N_f' [of "?N"] by auto
   642 
   643   let "?diff i x" = "(f (x0 + x) i - f x0 i) / x"
   644 
   645   let ?r = "r / (3 * real ?N)"
   646   have "0 < 3 * real ?N" by auto
   647   from divide_pos_pos[OF `0 < r` this]
   648   have "0 < ?r" .
   649 
   650   let "?s n" = "SOME s. 0 < s \<and> (\<forall> x. x \<noteq> 0 \<and> \<bar> x \<bar> < s \<longrightarrow> \<bar> ?diff n x - f' x0 n \<bar> < ?r)"
   651   def S' \<equiv> "Min (?s ` { 0 ..< ?N })"
   652 
   653   have "0 < S'" unfolding S'_def
   654   proof (rule iffD2[OF Min_gr_iff])
   655     show "\<forall> x \<in> (?s ` { 0 ..< ?N }). 0 < x"
   656     proof (rule ballI)
   657       fix x assume "x \<in> ?s ` {0..<?N}"
   658       then obtain n where "x = ?s n" and "n \<in> {0..<?N}" using image_iff[THEN iffD1] by blast
   659       from DERIV_D[OF DERIV_f[where n=n], THEN LIM_D, OF `0 < ?r`, unfolded real_norm_def]
   660       obtain s where s_bound: "0 < s \<and> (\<forall>x. x \<noteq> 0 \<and> \<bar>x\<bar> < s \<longrightarrow> \<bar>?diff n x - f' x0 n\<bar> < ?r)" by auto
   661       have "0 < ?s n" by (rule someI2[where a=s], auto simp add: s_bound)
   662       thus "0 < x" unfolding `x = ?s n` .
   663     qed
   664   qed auto
   665 
   666   def S \<equiv> "min (min (x0 - a) (b - x0)) S'"
   667   hence "0 < S" and S_a: "S \<le> x0 - a" and S_b: "S \<le> b - x0" and "S \<le> S'" using x0_in_I and `0 < S'`
   668     by auto
   669 
   670   { fix x assume "x \<noteq> 0" and "\<bar> x \<bar> < S"
   671     hence x_in_I: "x0 + x \<in> { a <..< b }" using S_a S_b by auto
   672 
   673     note diff_smbl = summable_diff[OF allf_summable[OF x_in_I] allf_summable[OF x0_in_I]]
   674     note div_smbl = summable_divide[OF diff_smbl]
   675     note all_smbl = summable_diff[OF div_smbl `summable (f' x0)`]
   676     note ign = summable_ignore_initial_segment[where k="?N"]
   677     note diff_shft_smbl = summable_diff[OF ign[OF allf_summable[OF x_in_I]] ign[OF allf_summable[OF x0_in_I]]]
   678     note div_shft_smbl = summable_divide[OF diff_shft_smbl]
   679     note all_shft_smbl = summable_diff[OF div_smbl ign[OF `summable (f' x0)`]]
   680 
   681     { fix n
   682       have "\<bar> ?diff (n + ?N) x \<bar> \<le> L (n + ?N) * \<bar> (x0 + x) - x0 \<bar> / \<bar> x \<bar>"
   683         using divide_right_mono[OF L_def[OF x_in_I x0_in_I] abs_ge_zero] unfolding abs_divide .
   684       hence "\<bar> ( \<bar> ?diff (n + ?N) x \<bar>) \<bar> \<le> L (n + ?N)" using `x \<noteq> 0` by auto
   685     } note L_ge = summable_le2[OF allI[OF this] ign[OF `summable L`]]
   686     from order_trans[OF summable_rabs[OF conjunct1[OF L_ge]] L_ge[THEN conjunct2]]
   687     have "\<bar> \<Sum> i. ?diff (i + ?N) x \<bar> \<le> (\<Sum> i. L (i + ?N))" .
   688     hence "\<bar> \<Sum> i. ?diff (i + ?N) x \<bar> \<le> r / 3" (is "?L_part \<le> r/3") using L_estimate by auto
   689 
   690     have "\<bar>\<Sum>n \<in> { 0 ..< ?N}. ?diff n x - f' x0 n \<bar> \<le> (\<Sum>n \<in> { 0 ..< ?N}. \<bar>?diff n x - f' x0 n \<bar>)" ..
   691     also have "\<dots> < (\<Sum>n \<in> { 0 ..< ?N}. ?r)"
   692     proof (rule setsum_strict_mono)
   693       fix n assume "n \<in> { 0 ..< ?N}"
   694       have "\<bar> x \<bar> < S" using `\<bar> x \<bar> < S` .
   695       also have "S \<le> S'" using `S \<le> S'` .
   696       also have "S' \<le> ?s n" unfolding S'_def
   697       proof (rule Min_le_iff[THEN iffD2])
   698         have "?s n \<in> (?s ` {0..<?N}) \<and> ?s n \<le> ?s n" using `n \<in> { 0 ..< ?N}` by auto
   699         thus "\<exists> a \<in> (?s ` {0..<?N}). a \<le> ?s n" by blast
   700       qed auto
   701       finally have "\<bar> x \<bar> < ?s n" .
   702 
   703       from DERIV_D[OF DERIV_f[where n=n], THEN LIM_D, OF `0 < ?r`, unfolded real_norm_def diff_0_right, unfolded some_eq_ex[symmetric], THEN conjunct2]
   704       have "\<forall>x. x \<noteq> 0 \<and> \<bar>x\<bar> < ?s n \<longrightarrow> \<bar>?diff n x - f' x0 n\<bar> < ?r" .
   705       with `x \<noteq> 0` and `\<bar>x\<bar> < ?s n`
   706       show "\<bar>?diff n x - f' x0 n\<bar> < ?r" by blast
   707     qed auto
   708     also have "\<dots> = of_nat (card {0 ..< ?N}) * ?r" by (rule setsum_constant)
   709     also have "\<dots> = real ?N * ?r" unfolding real_eq_of_nat by auto
   710     also have "\<dots> = r/3" by auto
   711     finally have "\<bar>\<Sum>n \<in> { 0 ..< ?N}. ?diff n x - f' x0 n \<bar> < r / 3" (is "?diff_part < r / 3") .
   712 
   713     from suminf_diff[OF allf_summable[OF x_in_I] allf_summable[OF x0_in_I]]
   714     have "\<bar> (suminf (f (x0 + x)) - (suminf (f x0))) / x - suminf (f' x0) \<bar> =
   715                     \<bar> \<Sum>n. ?diff n x - f' x0 n \<bar>" unfolding suminf_diff[OF div_smbl `summable (f' x0)`, symmetric] using suminf_divide[OF diff_smbl, symmetric] by auto
   716     also have "\<dots> \<le> ?diff_part + \<bar> (\<Sum>n. ?diff (n + ?N) x) - (\<Sum> n. f' x0 (n + ?N)) \<bar>" unfolding suminf_split_initial_segment[OF all_smbl, where k="?N"] unfolding suminf_diff[OF div_shft_smbl ign[OF `summable (f' x0)`]] by (rule abs_triangle_ineq)
   717     also have "\<dots> \<le> ?diff_part + ?L_part + ?f'_part" using abs_triangle_ineq4 by auto
   718     also have "\<dots> < r /3 + r/3 + r/3"
   719       using `?diff_part < r/3` `?L_part \<le> r/3` and `?f'_part < r/3`
   720       by (rule add_strict_mono [OF add_less_le_mono])
   721     finally have "\<bar> (suminf (f (x0 + x)) - (suminf (f x0))) / x - suminf (f' x0) \<bar> < r"
   722       by auto
   723   } thus "\<exists> s > 0. \<forall> x. x \<noteq> 0 \<and> norm (x - 0) < s \<longrightarrow>
   724       norm (((\<Sum>n. f (x0 + x) n) - (\<Sum>n. f x0 n)) / x - (\<Sum>n. f' x0 n)) < r" using `0 < S`
   725     unfolding real_norm_def diff_0_right by blast
   726 qed
   727 
   728 lemma DERIV_power_series': fixes f :: "nat \<Rightarrow> real"
   729   assumes converges: "\<And> x. x \<in> {-R <..< R} \<Longrightarrow> summable (\<lambda> n. f n * real (Suc n) * x^n)"
   730   and x0_in_I: "x0 \<in> {-R <..< R}" and "0 < R"
   731   shows "DERIV (\<lambda> x. (\<Sum> n. f n * x^(Suc n))) x0 :> (\<Sum> n. f n * real (Suc n) * x0^n)"
   732   (is "DERIV (\<lambda> x. (suminf (?f x))) x0 :> (suminf (?f' x0))")
   733 proof -
   734   { fix R' assume "0 < R'" and "R' < R" and "-R' < x0" and "x0 < R'"
   735     hence "x0 \<in> {-R' <..< R'}" and "R' \<in> {-R <..< R}" and "x0 \<in> {-R <..< R}" by auto
   736     have "DERIV (\<lambda> x. (suminf (?f x))) x0 :> (suminf (?f' x0))"
   737     proof (rule DERIV_series')
   738       show "summable (\<lambda> n. \<bar>f n * real (Suc n) * R'^n\<bar>)"
   739       proof -
   740         have "(R' + R) / 2 < R" and "0 < (R' + R) / 2" using `0 < R'` `0 < R` `R' < R` by auto
   741         hence in_Rball: "(R' + R) / 2 \<in> {-R <..< R}" using `R' < R` by auto
   742         have "norm R' < norm ((R' + R) / 2)" using `0 < R'` `0 < R` `R' < R` by auto
   743         from powser_insidea[OF converges[OF in_Rball] this] show ?thesis by auto
   744       qed
   745       { fix n x y assume "x \<in> {-R' <..< R'}" and "y \<in> {-R' <..< R'}"
   746         show "\<bar>?f x n - ?f y n\<bar> \<le> \<bar>f n * real (Suc n) * R'^n\<bar> * \<bar>x-y\<bar>"
   747         proof -
   748           have "\<bar>f n * x ^ (Suc n) - f n * y ^ (Suc n)\<bar> = (\<bar>f n\<bar> * \<bar>x-y\<bar>) * \<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar>"
   749             unfolding right_diff_distrib[symmetric] lemma_realpow_diff_sumr2 abs_mult by auto
   750           also have "\<dots> \<le> (\<bar>f n\<bar> * \<bar>x-y\<bar>) * (\<bar>real (Suc n)\<bar> * \<bar>R' ^ n\<bar>)"
   751           proof (rule mult_left_mono)
   752             have "\<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar> \<le> (\<Sum>p = 0..<Suc n. \<bar>x ^ p * y ^ (n - p)\<bar>)" by (rule setsum_abs)
   753             also have "\<dots> \<le> (\<Sum>p = 0..<Suc n. R' ^ n)"
   754             proof (rule setsum_mono)
   755               fix p assume "p \<in> {0..<Suc n}" hence "p \<le> n" by auto
   756               { fix n fix x :: real assume "x \<in> {-R'<..<R'}"
   757                 hence "\<bar>x\<bar> \<le> R'"  by auto
   758                 hence "\<bar>x^n\<bar> \<le> R'^n" unfolding power_abs by (rule power_mono, auto)
   759               } from mult_mono[OF this[OF `x \<in> {-R'<..<R'}`, of p] this[OF `y \<in> {-R'<..<R'}`, of "n-p"]] `0 < R'`
   760               have "\<bar>x^p * y^(n-p)\<bar> \<le> R'^p * R'^(n-p)" unfolding abs_mult by auto
   761               thus "\<bar>x^p * y^(n-p)\<bar> \<le> R'^n" unfolding power_add[symmetric] using `p \<le> n` by auto
   762             qed
   763             also have "\<dots> = real (Suc n) * R' ^ n" unfolding setsum_constant card_atLeastLessThan real_of_nat_def by auto
   764             finally show "\<bar>\<Sum>p = 0..<Suc n. x ^ p * y ^ (n - p)\<bar> \<le> \<bar>real (Suc n)\<bar> * \<bar>R' ^ n\<bar>" unfolding abs_real_of_nat_cancel abs_of_nonneg[OF zero_le_power[OF less_imp_le[OF `0 < R'`]]] .
   765             show "0 \<le> \<bar>f n\<bar> * \<bar>x - y\<bar>" unfolding abs_mult[symmetric] by auto
   766           qed
   767           also have "\<dots> = \<bar>f n * real (Suc n) * R' ^ n\<bar> * \<bar>x - y\<bar>" unfolding abs_mult mult_assoc[symmetric] by algebra
   768           finally show ?thesis .
   769         qed }
   770       { fix n show "DERIV (\<lambda> x. ?f x n) x0 :> (?f' x0 n)"
   771           by (auto intro!: DERIV_intros simp del: power_Suc) }
   772       { fix x assume "x \<in> {-R' <..< R'}" hence "R' \<in> {-R <..< R}" and "norm x < norm R'" using assms `R' < R` by auto
   773         have "summable (\<lambda> n. f n * x^n)"
   774         proof (rule summable_le2[THEN conjunct1, OF _ powser_insidea[OF converges[OF `R' \<in> {-R <..< R}`] `norm x < norm R'`]], rule allI)
   775           fix n
   776           have le: "\<bar>f n\<bar> * 1 \<le> \<bar>f n\<bar> * real (Suc n)" by (rule mult_left_mono, auto)
   777           show "\<bar>f n * x ^ n\<bar> \<le> norm (f n * real (Suc n) * x ^ n)" unfolding real_norm_def abs_mult
   778             by (rule mult_right_mono, auto simp add: le[unfolded mult_1_right])
   779         qed
   780         from this[THEN summable_mult2[where c=x], unfolded mult_assoc, unfolded mult_commute]
   781         show "summable (?f x)" by auto }
   782       show "summable (?f' x0)" using converges[OF `x0 \<in> {-R <..< R}`] .
   783       show "x0 \<in> {-R' <..< R'}" using `x0 \<in> {-R' <..< R'}` .
   784     qed
   785   } note for_subinterval = this
   786   let ?R = "(R + \<bar>x0\<bar>) / 2"
   787   have "\<bar>x0\<bar> < ?R" using assms by auto
   788   hence "- ?R < x0"
   789   proof (cases "x0 < 0")
   790     case True
   791     hence "- x0 < ?R" using `\<bar>x0\<bar> < ?R` by auto
   792     thus ?thesis unfolding neg_less_iff_less[symmetric, of "- x0"] by auto
   793   next
   794     case False
   795     have "- ?R < 0" using assms by auto
   796     also have "\<dots> \<le> x0" using False by auto
   797     finally show ?thesis .
   798   qed
   799   hence "0 < ?R" "?R < R" "- ?R < x0" and "x0 < ?R" using assms by auto
   800   from for_subinterval[OF this]
   801   show ?thesis .
   802 qed
   803 
   804 subsection {* Exponential Function *}
   805 
   806 definition exp :: "'a \<Rightarrow> 'a::{real_normed_field,banach}" where
   807   "exp = (\<lambda>x. \<Sum>n. x ^ n /\<^sub>R real (fact n))"
   808 
   809 lemma summable_exp_generic:
   810   fixes x :: "'a::{real_normed_algebra_1,banach}"
   811   defines S_def: "S \<equiv> \<lambda>n. x ^ n /\<^sub>R real (fact n)"
   812   shows "summable S"
   813 proof -
   814   have S_Suc: "\<And>n. S (Suc n) = (x * S n) /\<^sub>R real (Suc n)"
   815     unfolding S_def by (simp del: mult_Suc)
   816   obtain r :: real where r0: "0 < r" and r1: "r < 1"
   817     using dense [OF zero_less_one] by fast
   818   obtain N :: nat where N: "norm x < real N * r"
   819     using reals_Archimedean3 [OF r0] by fast
   820   from r1 show ?thesis
   821   proof (rule ratio_test [rule_format])
   822     fix n :: nat
   823     assume n: "N \<le> n"
   824     have "norm x \<le> real N * r"
   825       using N by (rule order_less_imp_le)
   826     also have "real N * r \<le> real (Suc n) * r"
   827       using r0 n by (simp add: mult_right_mono)
   828     finally have "norm x * norm (S n) \<le> real (Suc n) * r * norm (S n)"
   829       using norm_ge_zero by (rule mult_right_mono)
   830     hence "norm (x * S n) \<le> real (Suc n) * r * norm (S n)"
   831       by (rule order_trans [OF norm_mult_ineq])
   832     hence "norm (x * S n) / real (Suc n) \<le> r * norm (S n)"
   833       by (simp add: pos_divide_le_eq mult_ac)
   834     thus "norm (S (Suc n)) \<le> r * norm (S n)"
   835       by (simp add: S_Suc inverse_eq_divide)
   836   qed
   837 qed
   838 
   839 lemma summable_norm_exp:
   840   fixes x :: "'a::{real_normed_algebra_1,banach}"
   841   shows "summable (\<lambda>n. norm (x ^ n /\<^sub>R real (fact n)))"
   842 proof (rule summable_norm_comparison_test [OF exI, rule_format])
   843   show "summable (\<lambda>n. norm x ^ n /\<^sub>R real (fact n))"
   844     by (rule summable_exp_generic)
   845 next
   846   fix n show "norm (x ^ n /\<^sub>R real (fact n)) \<le> norm x ^ n /\<^sub>R real (fact n)"
   847     by (simp add: norm_power_ineq)
   848 qed
   849 
   850 lemma summable_exp: "summable (%n. inverse (real (fact n)) * x ^ n)"
   851 by (insert summable_exp_generic [where x=x], simp)
   852 
   853 lemma exp_converges: "(\<lambda>n. x ^ n /\<^sub>R real (fact n)) sums exp x"
   854 unfolding exp_def by (rule summable_exp_generic [THEN summable_sums])
   855 
   856 
   857 lemma exp_fdiffs:
   858       "diffs (%n. inverse(real (fact n))) = (%n. inverse(real (fact n)))"
   859 by (simp add: diffs_def mult_assoc [symmetric] real_of_nat_def of_nat_mult
   860          del: mult_Suc of_nat_Suc)
   861 
   862 lemma diffs_of_real: "diffs (\<lambda>n. of_real (f n)) = (\<lambda>n. of_real (diffs f n))"
   863 by (simp add: diffs_def)
   864 
   865 lemma DERIV_exp [simp]: "DERIV exp x :> exp(x)"
   866 unfolding exp_def scaleR_conv_of_real
   867 apply (rule DERIV_cong)
   868 apply (rule termdiffs [where K="of_real (1 + norm x)"])
   869 apply (simp_all only: diffs_of_real scaleR_conv_of_real exp_fdiffs)
   870 apply (rule exp_converges [THEN sums_summable, unfolded scaleR_conv_of_real])+
   871 apply (simp del: of_real_add)
   872 done
   873 
   874 lemma isCont_exp: "isCont exp x"
   875   by (rule DERIV_exp [THEN DERIV_isCont])
   876 
   877 lemma isCont_exp' [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. exp (f x)) a"
   878   by (rule isCont_o2 [OF _ isCont_exp])
   879 
   880 lemma tendsto_exp [tendsto_intros]:
   881   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. exp (f x)) ---> exp a) F"
   882   by (rule isCont_tendsto_compose [OF isCont_exp])
   883 
   884 subsubsection {* Properties of the Exponential Function *}
   885 
   886 lemma powser_zero:
   887   fixes f :: "nat \<Rightarrow> 'a::{real_normed_algebra_1}"
   888   shows "(\<Sum>n. f n * 0 ^ n) = f 0"
   889 proof -
   890   have "(\<Sum>n = 0..<1. f n * 0 ^ n) = (\<Sum>n. f n * 0 ^ n)"
   891     by (rule sums_unique [OF series_zero], simp add: power_0_left)
   892   thus ?thesis unfolding One_nat_def by simp
   893 qed
   894 
   895 lemma exp_zero [simp]: "exp 0 = 1"
   896 unfolding exp_def by (simp add: scaleR_conv_of_real powser_zero)
   897 
   898 lemma setsum_cl_ivl_Suc2:
   899   "(\<Sum>i=m..Suc n. f i) = (if Suc n < m then 0 else f m + (\<Sum>i=m..n. f (Suc i)))"
   900 by (simp add: setsum_head_Suc setsum_shift_bounds_cl_Suc_ivl
   901          del: setsum_cl_ivl_Suc)
   902 
   903 lemma exp_series_add:
   904   fixes x y :: "'a::{real_field}"
   905   defines S_def: "S \<equiv> \<lambda>x n. x ^ n /\<^sub>R real (fact n)"
   906   shows "S (x + y) n = (\<Sum>i=0..n. S x i * S y (n - i))"
   907 proof (induct n)
   908   case 0
   909   show ?case
   910     unfolding S_def by simp
   911 next
   912   case (Suc n)
   913   have S_Suc: "\<And>x n. S x (Suc n) = (x * S x n) /\<^sub>R real (Suc n)"
   914     unfolding S_def by (simp del: mult_Suc)
   915   hence times_S: "\<And>x n. x * S x n = real (Suc n) *\<^sub>R S x (Suc n)"
   916     by simp
   917 
   918   have "real (Suc n) *\<^sub>R S (x + y) (Suc n) = (x + y) * S (x + y) n"
   919     by (simp only: times_S)
   920   also have "\<dots> = (x + y) * (\<Sum>i=0..n. S x i * S y (n-i))"
   921     by (simp only: Suc)
   922   also have "\<dots> = x * (\<Sum>i=0..n. S x i * S y (n-i))
   923                 + y * (\<Sum>i=0..n. S x i * S y (n-i))"
   924     by (rule distrib_right)
   925   also have "\<dots> = (\<Sum>i=0..n. (x * S x i) * S y (n-i))
   926                 + (\<Sum>i=0..n. S x i * (y * S y (n-i)))"
   927     by (simp only: setsum_right_distrib mult_ac)
   928   also have "\<dots> = (\<Sum>i=0..n. real (Suc i) *\<^sub>R (S x (Suc i) * S y (n-i)))
   929                 + (\<Sum>i=0..n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i)))"
   930     by (simp add: times_S Suc_diff_le)
   931   also have "(\<Sum>i=0..n. real (Suc i) *\<^sub>R (S x (Suc i) * S y (n-i))) =
   932              (\<Sum>i=0..Suc n. real i *\<^sub>R (S x i * S y (Suc n-i)))"
   933     by (subst setsum_cl_ivl_Suc2, simp)
   934   also have "(\<Sum>i=0..n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i))) =
   935              (\<Sum>i=0..Suc n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i)))"
   936     by (subst setsum_cl_ivl_Suc, simp)
   937   also have "(\<Sum>i=0..Suc n. real i *\<^sub>R (S x i * S y (Suc n-i))) +
   938              (\<Sum>i=0..Suc n. real (Suc n-i) *\<^sub>R (S x i * S y (Suc n-i))) =
   939              (\<Sum>i=0..Suc n. real (Suc n) *\<^sub>R (S x i * S y (Suc n-i)))"
   940     by (simp only: setsum_addf [symmetric] scaleR_left_distrib [symmetric]
   941               real_of_nat_add [symmetric], simp)
   942   also have "\<dots> = real (Suc n) *\<^sub>R (\<Sum>i=0..Suc n. S x i * S y (Suc n-i))"
   943     by (simp only: scaleR_right.setsum)
   944   finally show
   945     "S (x + y) (Suc n) = (\<Sum>i=0..Suc n. S x i * S y (Suc n - i))"
   946     by (simp del: setsum_cl_ivl_Suc)
   947 qed
   948 
   949 lemma exp_add: "exp (x + y) = exp x * exp y"
   950 unfolding exp_def
   951 by (simp only: Cauchy_product summable_norm_exp exp_series_add)
   952 
   953 lemma mult_exp_exp: "exp x * exp y = exp (x + y)"
   954 by (rule exp_add [symmetric])
   955 
   956 lemma exp_of_real: "exp (of_real x) = of_real (exp x)"
   957 unfolding exp_def
   958 apply (subst suminf_of_real)
   959 apply (rule summable_exp_generic)
   960 apply (simp add: scaleR_conv_of_real)
   961 done
   962 
   963 lemma exp_not_eq_zero [simp]: "exp x \<noteq> 0"
   964 proof
   965   have "exp x * exp (- x) = 1" by (simp add: mult_exp_exp)
   966   also assume "exp x = 0"
   967   finally show "False" by simp
   968 qed
   969 
   970 lemma exp_minus: "exp (- x) = inverse (exp x)"
   971 by (rule inverse_unique [symmetric], simp add: mult_exp_exp)
   972 
   973 lemma exp_diff: "exp (x - y) = exp x / exp y"
   974   unfolding diff_minus divide_inverse
   975   by (simp add: exp_add exp_minus)
   976 
   977 
   978 subsubsection {* Properties of the Exponential Function on Reals *}
   979 
   980 text {* Comparisons of @{term "exp x"} with zero. *}
   981 
   982 text{*Proof: because every exponential can be seen as a square.*}
   983 lemma exp_ge_zero [simp]: "0 \<le> exp (x::real)"
   984 proof -
   985   have "0 \<le> exp (x/2) * exp (x/2)" by simp
   986   thus ?thesis by (simp add: exp_add [symmetric])
   987 qed
   988 
   989 lemma exp_gt_zero [simp]: "0 < exp (x::real)"
   990 by (simp add: order_less_le)
   991 
   992 lemma not_exp_less_zero [simp]: "\<not> exp (x::real) < 0"
   993 by (simp add: not_less)
   994 
   995 lemma not_exp_le_zero [simp]: "\<not> exp (x::real) \<le> 0"
   996 by (simp add: not_le)
   997 
   998 lemma abs_exp_cancel [simp]: "\<bar>exp x::real\<bar> = exp x"
   999 by simp
  1000 
  1001 lemma exp_real_of_nat_mult: "exp(real n * x) = exp(x) ^ n"
  1002 apply (induct "n")
  1003 apply (auto simp add: real_of_nat_Suc distrib_left exp_add mult_commute)
  1004 done
  1005 
  1006 text {* Strict monotonicity of exponential. *}
  1007 
  1008 lemma exp_ge_add_one_self_aux: "0 \<le> (x::real) ==> (1 + x) \<le> exp(x)"
  1009 apply (drule order_le_imp_less_or_eq, auto)
  1010 apply (simp add: exp_def)
  1011 apply (rule order_trans)
  1012 apply (rule_tac [2] n = 2 and f = "(%n. inverse (real (fact n)) * x ^ n)" in series_pos_le)
  1013 apply (auto intro: summable_exp simp add: numeral_2_eq_2 zero_le_mult_iff)
  1014 done
  1015 
  1016 lemma exp_gt_one: "0 < (x::real) \<Longrightarrow> 1 < exp x"
  1017 proof -
  1018   assume x: "0 < x"
  1019   hence "1 < 1 + x" by simp
  1020   also from x have "1 + x \<le> exp x"
  1021     by (simp add: exp_ge_add_one_self_aux)
  1022   finally show ?thesis .
  1023 qed
  1024 
  1025 lemma exp_less_mono:
  1026   fixes x y :: real
  1027   assumes "x < y" shows "exp x < exp y"
  1028 proof -
  1029   from `x < y` have "0 < y - x" by simp
  1030   hence "1 < exp (y - x)" by (rule exp_gt_one)
  1031   hence "1 < exp y / exp x" by (simp only: exp_diff)
  1032   thus "exp x < exp y" by simp
  1033 qed
  1034 
  1035 lemma exp_less_cancel: "exp (x::real) < exp y ==> x < y"
  1036 apply (simp add: linorder_not_le [symmetric])
  1037 apply (auto simp add: order_le_less exp_less_mono)
  1038 done
  1039 
  1040 lemma exp_less_cancel_iff [iff]: "exp (x::real) < exp y \<longleftrightarrow> x < y"
  1041 by (auto intro: exp_less_mono exp_less_cancel)
  1042 
  1043 lemma exp_le_cancel_iff [iff]: "exp (x::real) \<le> exp y \<longleftrightarrow> x \<le> y"
  1044 by (auto simp add: linorder_not_less [symmetric])
  1045 
  1046 lemma exp_inj_iff [iff]: "exp (x::real) = exp y \<longleftrightarrow> x = y"
  1047 by (simp add: order_eq_iff)
  1048 
  1049 text {* Comparisons of @{term "exp x"} with one. *}
  1050 
  1051 lemma one_less_exp_iff [simp]: "1 < exp (x::real) \<longleftrightarrow> 0 < x"
  1052   using exp_less_cancel_iff [where x=0 and y=x] by simp
  1053 
  1054 lemma exp_less_one_iff [simp]: "exp (x::real) < 1 \<longleftrightarrow> x < 0"
  1055   using exp_less_cancel_iff [where x=x and y=0] by simp
  1056 
  1057 lemma one_le_exp_iff [simp]: "1 \<le> exp (x::real) \<longleftrightarrow> 0 \<le> x"
  1058   using exp_le_cancel_iff [where x=0 and y=x] by simp
  1059 
  1060 lemma exp_le_one_iff [simp]: "exp (x::real) \<le> 1 \<longleftrightarrow> x \<le> 0"
  1061   using exp_le_cancel_iff [where x=x and y=0] by simp
  1062 
  1063 lemma exp_eq_one_iff [simp]: "exp (x::real) = 1 \<longleftrightarrow> x = 0"
  1064   using exp_inj_iff [where x=x and y=0] by simp
  1065 
  1066 lemma lemma_exp_total: "1 \<le> y ==> \<exists>x. 0 \<le> x & x \<le> y - 1 & exp(x::real) = y"
  1067 proof (rule IVT)
  1068   assume "1 \<le> y"
  1069   hence "0 \<le> y - 1" by simp
  1070   hence "1 + (y - 1) \<le> exp (y - 1)" by (rule exp_ge_add_one_self_aux)
  1071   thus "y \<le> exp (y - 1)" by simp
  1072 qed (simp_all add: le_diff_eq)
  1073 
  1074 lemma exp_total: "0 < (y::real) ==> \<exists>x. exp x = y"
  1075 proof (rule linorder_le_cases [of 1 y])
  1076   assume "1 \<le> y" thus "\<exists>x. exp x = y"
  1077     by (fast dest: lemma_exp_total)
  1078 next
  1079   assume "0 < y" and "y \<le> 1"
  1080   hence "1 \<le> inverse y" by (simp add: one_le_inverse_iff)
  1081   then obtain x where "exp x = inverse y" by (fast dest: lemma_exp_total)
  1082   hence "exp (- x) = y" by (simp add: exp_minus)
  1083   thus "\<exists>x. exp x = y" ..
  1084 qed
  1085 
  1086 
  1087 subsection {* Natural Logarithm *}
  1088 
  1089 definition ln :: "real \<Rightarrow> real" where
  1090   "ln x = (THE u. exp u = x)"
  1091 
  1092 lemma ln_exp [simp]: "ln (exp x) = x"
  1093   by (simp add: ln_def)
  1094 
  1095 lemma exp_ln [simp]: "0 < x \<Longrightarrow> exp (ln x) = x"
  1096   by (auto dest: exp_total)
  1097 
  1098 lemma exp_ln_iff [simp]: "exp (ln x) = x \<longleftrightarrow> 0 < x"
  1099   by (metis exp_gt_zero exp_ln)
  1100 
  1101 lemma ln_unique: "exp y = x \<Longrightarrow> ln x = y"
  1102   by (erule subst, rule ln_exp)
  1103 
  1104 lemma ln_one [simp]: "ln 1 = 0"
  1105   by (rule ln_unique, simp)
  1106 
  1107 lemma ln_mult: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln (x * y) = ln x + ln y"
  1108   by (rule ln_unique, simp add: exp_add)
  1109 
  1110 lemma ln_inverse: "0 < x \<Longrightarrow> ln (inverse x) = - ln x"
  1111   by (rule ln_unique, simp add: exp_minus)
  1112 
  1113 lemma ln_div: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln (x / y) = ln x - ln y"
  1114   by (rule ln_unique, simp add: exp_diff)
  1115 
  1116 lemma ln_realpow: "0 < x \<Longrightarrow> ln (x ^ n) = real n * ln x"
  1117   by (rule ln_unique, simp add: exp_real_of_nat_mult)
  1118 
  1119 lemma ln_less_cancel_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x < ln y \<longleftrightarrow> x < y"
  1120   by (subst exp_less_cancel_iff [symmetric], simp)
  1121 
  1122 lemma ln_le_cancel_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x \<le> ln y \<longleftrightarrow> x \<le> y"
  1123   by (simp add: linorder_not_less [symmetric])
  1124 
  1125 lemma ln_inj_iff [simp]: "\<lbrakk>0 < x; 0 < y\<rbrakk> \<Longrightarrow> ln x = ln y \<longleftrightarrow> x = y"
  1126   by (simp add: order_eq_iff)
  1127 
  1128 lemma ln_add_one_self_le_self [simp]: "0 \<le> x \<Longrightarrow> ln (1 + x) \<le> x"
  1129   apply (rule exp_le_cancel_iff [THEN iffD1])
  1130   apply (simp add: exp_ge_add_one_self_aux)
  1131   done
  1132 
  1133 lemma ln_less_self [simp]: "0 < x \<Longrightarrow> ln x < x"
  1134   by (rule order_less_le_trans [where y="ln (1 + x)"]) simp_all
  1135 
  1136 lemma ln_ge_zero [simp]: "1 \<le> x \<Longrightarrow> 0 \<le> ln x"
  1137   using ln_le_cancel_iff [of 1 x] by simp
  1138 
  1139 lemma ln_ge_zero_imp_ge_one: "\<lbrakk>0 \<le> ln x; 0 < x\<rbrakk> \<Longrightarrow> 1 \<le> x"
  1140   using ln_le_cancel_iff [of 1 x] by simp
  1141 
  1142 lemma ln_ge_zero_iff [simp]: "0 < x \<Longrightarrow> (0 \<le> ln x) = (1 \<le> x)"
  1143   using ln_le_cancel_iff [of 1 x] by simp
  1144 
  1145 lemma ln_less_zero_iff [simp]: "0 < x \<Longrightarrow> (ln x < 0) = (x < 1)"
  1146   using ln_less_cancel_iff [of x 1] by simp
  1147 
  1148 lemma ln_gt_zero: "1 < x \<Longrightarrow> 0 < ln x"
  1149   using ln_less_cancel_iff [of 1 x] by simp
  1150 
  1151 lemma ln_gt_zero_imp_gt_one: "\<lbrakk>0 < ln x; 0 < x\<rbrakk> \<Longrightarrow> 1 < x"
  1152   using ln_less_cancel_iff [of 1 x] by simp
  1153 
  1154 lemma ln_gt_zero_iff [simp]: "0 < x \<Longrightarrow> (0 < ln x) = (1 < x)"
  1155   using ln_less_cancel_iff [of 1 x] by simp
  1156 
  1157 lemma ln_eq_zero_iff [simp]: "0 < x \<Longrightarrow> (ln x = 0) = (x = 1)"
  1158   using ln_inj_iff [of x 1] by simp
  1159 
  1160 lemma ln_less_zero: "\<lbrakk>0 < x; x < 1\<rbrakk> \<Longrightarrow> ln x < 0"
  1161   by simp
  1162 
  1163 lemma isCont_ln: "0 < x \<Longrightarrow> isCont ln x"
  1164   apply (subgoal_tac "isCont ln (exp (ln x))", simp)
  1165   apply (rule isCont_inverse_function [where f=exp], simp_all)
  1166   done
  1167 
  1168 lemma tendsto_ln [tendsto_intros]:
  1169   "\<lbrakk>(f ---> a) F; 0 < a\<rbrakk> \<Longrightarrow> ((\<lambda>x. ln (f x)) ---> ln a) F"
  1170   by (rule isCont_tendsto_compose [OF isCont_ln])
  1171 
  1172 lemma DERIV_ln: "0 < x \<Longrightarrow> DERIV ln x :> inverse x"
  1173   apply (rule DERIV_inverse_function [where f=exp and a=0 and b="x+1"])
  1174   apply (erule DERIV_cong [OF DERIV_exp exp_ln])
  1175   apply (simp_all add: abs_if isCont_ln)
  1176   done
  1177 
  1178 lemma DERIV_ln_divide: "0 < x ==> DERIV ln x :> 1 / x"
  1179   by (rule DERIV_ln[THEN DERIV_cong], simp, simp add: divide_inverse)
  1180 
  1181 lemma ln_series: assumes "0 < x" and "x < 2"
  1182   shows "ln x = (\<Sum> n. (-1)^n * (1 / real (n + 1)) * (x - 1)^(Suc n))" (is "ln x = suminf (?f (x - 1))")
  1183 proof -
  1184   let "?f' x n" = "(-1)^n * (x - 1)^n"
  1185 
  1186   have "ln x - suminf (?f (x - 1)) = ln 1 - suminf (?f (1 - 1))"
  1187   proof (rule DERIV_isconst3[where x=x])
  1188     fix x :: real assume "x \<in> {0 <..< 2}" hence "0 < x" and "x < 2" by auto
  1189     have "norm (1 - x) < 1" using `0 < x` and `x < 2` by auto
  1190     have "1 / x = 1 / (1 - (1 - x))" by auto
  1191     also have "\<dots> = (\<Sum> n. (1 - x)^n)" using geometric_sums[OF `norm (1 - x) < 1`] by (rule sums_unique)
  1192     also have "\<dots> = suminf (?f' x)" unfolding power_mult_distrib[symmetric] by (rule arg_cong[where f=suminf], rule arg_cong[where f="op ^"], auto)
  1193     finally have "DERIV ln x :> suminf (?f' x)" using DERIV_ln[OF `0 < x`] unfolding divide_inverse by auto
  1194     moreover
  1195     have repos: "\<And> h x :: real. h - 1 + x = h + x - 1" by auto
  1196     have "DERIV (\<lambda>x. suminf (?f x)) (x - 1) :> (\<Sum>n. (-1)^n * (1 / real (n + 1)) * real (Suc n) * (x - 1) ^ n)"
  1197     proof (rule DERIV_power_series')
  1198       show "x - 1 \<in> {- 1<..<1}" and "(0 :: real) < 1" using `0 < x` `x < 2` by auto
  1199       { fix x :: real assume "x \<in> {- 1<..<1}" hence "norm (-x) < 1" by auto
  1200         show "summable (\<lambda>n. -1 ^ n * (1 / real (n + 1)) * real (Suc n) * x ^ n)"
  1201           unfolding One_nat_def
  1202           by (auto simp add: power_mult_distrib[symmetric] summable_geometric[OF `norm (-x) < 1`])
  1203       }
  1204     qed
  1205     hence "DERIV (\<lambda>x. suminf (?f x)) (x - 1) :> suminf (?f' x)" unfolding One_nat_def by auto
  1206     hence "DERIV (\<lambda>x. suminf (?f (x - 1))) x :> suminf (?f' x)" unfolding DERIV_iff repos .
  1207     ultimately have "DERIV (\<lambda>x. ln x - suminf (?f (x - 1))) x :> (suminf (?f' x) - suminf (?f' x))"
  1208       by (rule DERIV_diff)
  1209     thus "DERIV (\<lambda>x. ln x - suminf (?f (x - 1))) x :> 0" by auto
  1210   qed (auto simp add: assms)
  1211   thus ?thesis by auto
  1212 qed
  1213 
  1214 lemma exp_first_two_terms: "exp x = 1 + x + (\<Sum> n. inverse(fact (n+2)) * (x ^ (n+2)))"
  1215 proof -
  1216   have "exp x = suminf (%n. inverse(fact n) * (x ^ n))"
  1217     by (simp add: exp_def)
  1218   also from summable_exp have "... = (\<Sum> n::nat = 0 ..< 2. inverse(fact n) * (x ^ n)) +
  1219       (\<Sum> n. inverse(fact(n+2)) * (x ^ (n+2)))" (is "_ = ?a + _")
  1220     by (rule suminf_split_initial_segment)
  1221   also have "?a = 1 + x"
  1222     by (simp add: numeral_2_eq_2)
  1223   finally show ?thesis .
  1224 qed
  1225 
  1226 lemma exp_bound: "0 <= (x::real) ==> x <= 1 ==> exp x <= 1 + x + x^2"
  1227 proof -
  1228   assume a: "0 <= x"
  1229   assume b: "x <= 1"
  1230   { fix n :: nat
  1231     have "2 * 2 ^ n \<le> fact (n + 2)"
  1232       by (induct n, simp, simp)
  1233     hence "real ((2::nat) * 2 ^ n) \<le> real (fact (n + 2))"
  1234       by (simp only: real_of_nat_le_iff)
  1235     hence "2 * 2 ^ n \<le> real (fact (n + 2))"
  1236       by simp
  1237     hence "inverse (fact (n + 2)) \<le> inverse (2 * 2 ^ n)"
  1238       by (rule le_imp_inverse_le) simp
  1239     hence "inverse (fact (n + 2)) \<le> 1/2 * (1/2)^n"
  1240       by (simp add: inverse_mult_distrib power_inverse)
  1241     hence "inverse (fact (n + 2)) * (x^n * x\<twosuperior>) \<le> 1/2 * (1/2)^n * (1 * x\<twosuperior>)"
  1242       by (rule mult_mono)
  1243         (rule mult_mono, simp_all add: power_le_one a b mult_nonneg_nonneg)
  1244     hence "inverse (fact (n + 2)) * x ^ (n + 2) \<le> (x\<twosuperior>/2) * ((1/2)^n)"
  1245       unfolding power_add by (simp add: mult_ac del: fact_Suc) }
  1246   note aux1 = this
  1247   have "(\<lambda>n. x\<twosuperior> / 2 * (1 / 2) ^ n) sums (x\<twosuperior> / 2 * (1 / (1 - 1 / 2)))"
  1248     by (intro sums_mult geometric_sums, simp)
  1249   hence aux2: "(\<lambda>n. (x::real) ^ 2 / 2 * (1 / 2) ^ n) sums x^2"
  1250     by simp
  1251   have "suminf (%n. inverse(fact (n+2)) * (x ^ (n+2))) <= x^2"
  1252   proof -
  1253     have "suminf (%n. inverse(fact (n+2)) * (x ^ (n+2))) <=
  1254         suminf (%n. (x^2/2) * ((1/2)^n))"
  1255       apply (rule summable_le)
  1256       apply (rule allI, rule aux1)
  1257       apply (rule summable_exp [THEN summable_ignore_initial_segment])
  1258       by (rule sums_summable, rule aux2)
  1259     also have "... = x^2"
  1260       by (rule sums_unique [THEN sym], rule aux2)
  1261     finally show ?thesis .
  1262   qed
  1263   thus ?thesis unfolding exp_first_two_terms by auto
  1264 qed
  1265 
  1266 lemma ln_one_minus_pos_upper_bound: "0 <= x ==> x < 1 ==> ln (1 - x) <= - x"
  1267 proof -
  1268   assume a: "0 <= (x::real)" and b: "x < 1"
  1269   have "(1 - x) * (1 + x + x^2) = (1 - x^3)"
  1270     by (simp add: algebra_simps power2_eq_square power3_eq_cube)
  1271   also have "... <= 1"
  1272     by (auto simp add: a)
  1273   finally have "(1 - x) * (1 + x + x ^ 2) <= 1" .
  1274   moreover have c: "0 < 1 + x + x\<twosuperior>"
  1275     by (simp add: add_pos_nonneg a)
  1276   ultimately have "1 - x <= 1 / (1 + x + x^2)"
  1277     by (elim mult_imp_le_div_pos)
  1278   also have "... <= 1 / exp x"
  1279     apply (rule divide_left_mono)
  1280     apply (rule exp_bound, rule a)
  1281     apply (rule b [THEN less_imp_le])
  1282     apply simp
  1283     apply (rule mult_pos_pos)
  1284     apply (rule c)
  1285     apply simp
  1286     done
  1287   also have "... = exp (-x)"
  1288     by (auto simp add: exp_minus divide_inverse)
  1289   finally have "1 - x <= exp (- x)" .
  1290   also have "1 - x = exp (ln (1 - x))"
  1291   proof -
  1292     have "0 < 1 - x"
  1293       by (insert b, auto)
  1294     thus ?thesis
  1295       by (auto simp only: exp_ln_iff [THEN sym])
  1296   qed
  1297   finally have "exp (ln (1 - x)) <= exp (- x)" .
  1298   thus ?thesis by (auto simp only: exp_le_cancel_iff)
  1299 qed
  1300 
  1301 lemma exp_ge_add_one_self [simp]: "1 + (x::real) <= exp x"
  1302   apply (case_tac "0 <= x")
  1303   apply (erule exp_ge_add_one_self_aux)
  1304   apply (case_tac "x <= -1")
  1305   apply (subgoal_tac "1 + x <= 0")
  1306   apply (erule order_trans)
  1307   apply simp
  1308   apply simp
  1309   apply (subgoal_tac "1 + x = exp(ln (1 + x))")
  1310   apply (erule ssubst)
  1311   apply (subst exp_le_cancel_iff)
  1312   apply (subgoal_tac "ln (1 - (- x)) <= - (- x)")
  1313   apply simp
  1314   apply (rule ln_one_minus_pos_upper_bound)
  1315   apply auto
  1316 done
  1317 
  1318 lemma exp_at_bot: "(exp ---> (0::real)) at_bot"
  1319   unfolding tendsto_Zfun_iff
  1320 proof (rule ZfunI, simp add: eventually_at_bot_dense)
  1321   fix r :: real assume "0 < r"
  1322   { fix x assume "x < ln r"
  1323     then have "exp x < exp (ln r)"
  1324       by simp
  1325     with `0 < r` have "exp x < r"
  1326       by simp }
  1327   then show "\<exists>k. \<forall>n<k. exp n < r" by auto
  1328 qed
  1329 
  1330 lemma exp_at_top: "LIM x at_top. exp x :: real :> at_top"
  1331 proof -
  1332   { fix r n :: real assume "r < n"
  1333     also have "n < 1 + n" by simp
  1334     also have "1 + n \<le> exp n" by (rule exp_ge_add_one_self)
  1335     finally have "r < exp n" . }
  1336   then show ?thesis
  1337     by (auto simp: eventually_at_top_dense filterlim_at_top)
  1338 qed
  1339 
  1340 lemma ln_at_0: "LIM x at_right 0. ln x :> at_bot"
  1341   unfolding filterlim_at_bot
  1342 proof safe
  1343   fix r :: real
  1344   { fix x :: real assume "0 < x" "x < exp r"
  1345     then have "ln x < ln (exp r)"
  1346       by (subst ln_less_cancel_iff) auto
  1347     then have "ln x < r" by simp }
  1348   then show "eventually (\<lambda>x. ln x < r) (at_right 0)"
  1349     by (auto simp add: dist_real_def eventually_within eventually_at intro!: exI[of _ "exp r"])
  1350 qed
  1351 
  1352 lemma ln_at_top: "LIM x at_top. ln x :> at_top"
  1353   unfolding filterlim_at_top
  1354 proof safe
  1355   fix r :: real
  1356   { fix x assume "exp r < x"
  1357     with exp_gt_zero[of r] have "ln (exp r) < ln x"
  1358       by (subst ln_less_cancel_iff) (auto simp del: exp_gt_zero)
  1359     then have "r < ln x"
  1360       by simp }
  1361   then show "eventually (\<lambda>x. r < ln x) at_top"
  1362     by (auto simp add: eventually_at_top_dense)
  1363 qed
  1364 
  1365 subsection {* Sine and Cosine *}
  1366 
  1367 definition sin_coeff :: "nat \<Rightarrow> real" where
  1368   "sin_coeff = (\<lambda>n. if even n then 0 else -1 ^ ((n - Suc 0) div 2) / real (fact n))"
  1369 
  1370 definition cos_coeff :: "nat \<Rightarrow> real" where
  1371   "cos_coeff = (\<lambda>n. if even n then (-1 ^ (n div 2)) / real (fact n) else 0)"
  1372 
  1373 definition sin :: "real \<Rightarrow> real" where
  1374   "sin = (\<lambda>x. \<Sum>n. sin_coeff n * x ^ n)"
  1375 
  1376 definition cos :: "real \<Rightarrow> real" where
  1377   "cos = (\<lambda>x. \<Sum>n. cos_coeff n * x ^ n)"
  1378 
  1379 lemma sin_coeff_0 [simp]: "sin_coeff 0 = 0"
  1380   unfolding sin_coeff_def by simp
  1381 
  1382 lemma cos_coeff_0 [simp]: "cos_coeff 0 = 1"
  1383   unfolding cos_coeff_def by simp
  1384 
  1385 lemma sin_coeff_Suc: "sin_coeff (Suc n) = cos_coeff n / real (Suc n)"
  1386   unfolding cos_coeff_def sin_coeff_def
  1387   by (simp del: mult_Suc)
  1388 
  1389 lemma cos_coeff_Suc: "cos_coeff (Suc n) = - sin_coeff n / real (Suc n)"
  1390   unfolding cos_coeff_def sin_coeff_def
  1391   by (simp del: mult_Suc, auto simp add: odd_Suc_mult_two_ex)
  1392 
  1393 lemma summable_sin: "summable (\<lambda>n. sin_coeff n * x ^ n)"
  1394 unfolding sin_coeff_def
  1395 apply (rule summable_comparison_test [OF _ summable_exp [where x="\<bar>x\<bar>"]])
  1396 apply (auto simp add: divide_inverse abs_mult power_abs [symmetric] zero_le_mult_iff)
  1397 done
  1398 
  1399 lemma summable_cos: "summable (\<lambda>n. cos_coeff n * x ^ n)"
  1400 unfolding cos_coeff_def
  1401 apply (rule summable_comparison_test [OF _ summable_exp [where x="\<bar>x\<bar>"]])
  1402 apply (auto simp add: divide_inverse abs_mult power_abs [symmetric] zero_le_mult_iff)
  1403 done
  1404 
  1405 lemma sin_converges: "(\<lambda>n. sin_coeff n * x ^ n) sums sin(x)"
  1406 unfolding sin_def by (rule summable_sin [THEN summable_sums])
  1407 
  1408 lemma cos_converges: "(\<lambda>n. cos_coeff n * x ^ n) sums cos(x)"
  1409 unfolding cos_def by (rule summable_cos [THEN summable_sums])
  1410 
  1411 lemma diffs_sin_coeff: "diffs sin_coeff = cos_coeff"
  1412   by (simp add: diffs_def sin_coeff_Suc real_of_nat_def del: of_nat_Suc)
  1413 
  1414 lemma diffs_cos_coeff: "diffs cos_coeff = (\<lambda>n. - sin_coeff n)"
  1415   by (simp add: diffs_def cos_coeff_Suc real_of_nat_def del: of_nat_Suc)
  1416 
  1417 text{*Now at last we can get the derivatives of exp, sin and cos*}
  1418 
  1419 lemma DERIV_sin [simp]: "DERIV sin x :> cos(x)"
  1420   unfolding sin_def cos_def
  1421   apply (rule DERIV_cong, rule termdiffs [where K="1 + \<bar>x\<bar>"])
  1422   apply (simp_all add: diffs_sin_coeff diffs_cos_coeff
  1423     summable_minus summable_sin summable_cos)
  1424   done
  1425 
  1426 lemma DERIV_cos [simp]: "DERIV cos x :> -sin(x)"
  1427   unfolding cos_def sin_def
  1428   apply (rule DERIV_cong, rule termdiffs [where K="1 + \<bar>x\<bar>"])
  1429   apply (simp_all add: diffs_sin_coeff diffs_cos_coeff diffs_minus
  1430     summable_minus summable_sin summable_cos suminf_minus)
  1431   done
  1432 
  1433 lemma isCont_sin: "isCont sin x"
  1434   by (rule DERIV_sin [THEN DERIV_isCont])
  1435 
  1436 lemma isCont_cos: "isCont cos x"
  1437   by (rule DERIV_cos [THEN DERIV_isCont])
  1438 
  1439 lemma isCont_sin' [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. sin (f x)) a"
  1440   by (rule isCont_o2 [OF _ isCont_sin])
  1441 
  1442 lemma isCont_cos' [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. cos (f x)) a"
  1443   by (rule isCont_o2 [OF _ isCont_cos])
  1444 
  1445 lemma tendsto_sin [tendsto_intros]:
  1446   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. sin (f x)) ---> sin a) F"
  1447   by (rule isCont_tendsto_compose [OF isCont_sin])
  1448 
  1449 lemma tendsto_cos [tendsto_intros]:
  1450   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. cos (f x)) ---> cos a) F"
  1451   by (rule isCont_tendsto_compose [OF isCont_cos])
  1452 
  1453 declare
  1454   DERIV_exp[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1455   DERIV_ln_divide[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1456   DERIV_sin[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1457   DERIV_cos[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  1458 
  1459 subsection {* Properties of Sine and Cosine *}
  1460 
  1461 lemma sin_zero [simp]: "sin 0 = 0"
  1462   unfolding sin_def sin_coeff_def by (simp add: powser_zero)
  1463 
  1464 lemma cos_zero [simp]: "cos 0 = 1"
  1465   unfolding cos_def cos_coeff_def by (simp add: powser_zero)
  1466 
  1467 lemma sin_cos_squared_add [simp]: "(sin x)\<twosuperior> + (cos x)\<twosuperior> = 1"
  1468 proof -
  1469   have "\<forall>x. DERIV (\<lambda>x. (sin x)\<twosuperior> + (cos x)\<twosuperior>) x :> 0"
  1470     by (auto intro!: DERIV_intros)
  1471   hence "(sin x)\<twosuperior> + (cos x)\<twosuperior> = (sin 0)\<twosuperior> + (cos 0)\<twosuperior>"
  1472     by (rule DERIV_isconst_all)
  1473   thus "(sin x)\<twosuperior> + (cos x)\<twosuperior> = 1" by simp
  1474 qed
  1475 
  1476 lemma sin_cos_squared_add2 [simp]: "(cos x)\<twosuperior> + (sin x)\<twosuperior> = 1"
  1477   by (subst add_commute, rule sin_cos_squared_add)
  1478 
  1479 lemma sin_cos_squared_add3 [simp]: "cos x * cos x + sin x * sin x = 1"
  1480   using sin_cos_squared_add2 [unfolded power2_eq_square] .
  1481 
  1482 lemma sin_squared_eq: "(sin x)\<twosuperior> = 1 - (cos x)\<twosuperior>"
  1483   unfolding eq_diff_eq by (rule sin_cos_squared_add)
  1484 
  1485 lemma cos_squared_eq: "(cos x)\<twosuperior> = 1 - (sin x)\<twosuperior>"
  1486   unfolding eq_diff_eq by (rule sin_cos_squared_add2)
  1487 
  1488 lemma abs_sin_le_one [simp]: "\<bar>sin x\<bar> \<le> 1"
  1489   by (rule power2_le_imp_le, simp_all add: sin_squared_eq)
  1490 
  1491 lemma sin_ge_minus_one [simp]: "-1 \<le> sin x"
  1492   using abs_sin_le_one [of x] unfolding abs_le_iff by simp
  1493 
  1494 lemma sin_le_one [simp]: "sin x \<le> 1"
  1495   using abs_sin_le_one [of x] unfolding abs_le_iff by simp
  1496 
  1497 lemma abs_cos_le_one [simp]: "\<bar>cos x\<bar> \<le> 1"
  1498   by (rule power2_le_imp_le, simp_all add: cos_squared_eq)
  1499 
  1500 lemma cos_ge_minus_one [simp]: "-1 \<le> cos x"
  1501   using abs_cos_le_one [of x] unfolding abs_le_iff by simp
  1502 
  1503 lemma cos_le_one [simp]: "cos x \<le> 1"
  1504   using abs_cos_le_one [of x] unfolding abs_le_iff by simp
  1505 
  1506 lemma DERIV_fun_pow: "DERIV g x :> m ==>
  1507       DERIV (%x. (g x) ^ n) x :> real n * (g x) ^ (n - 1) * m"
  1508   by (auto intro!: DERIV_intros)
  1509 
  1510 lemma DERIV_fun_exp:
  1511      "DERIV g x :> m ==> DERIV (%x. exp(g x)) x :> exp(g x) * m"
  1512   by (auto intro!: DERIV_intros)
  1513 
  1514 lemma DERIV_fun_sin:
  1515      "DERIV g x :> m ==> DERIV (%x. sin(g x)) x :> cos(g x) * m"
  1516   by (auto intro!: DERIV_intros)
  1517 
  1518 lemma DERIV_fun_cos:
  1519      "DERIV g x :> m ==> DERIV (%x. cos(g x)) x :> -sin(g x) * m"
  1520   by (auto intro!: DERIV_intros)
  1521 
  1522 lemma sin_cos_add_lemma:
  1523      "(sin (x + y) - (sin x * cos y + cos x * sin y)) ^ 2 +
  1524       (cos (x + y) - (cos x * cos y - sin x * sin y)) ^ 2 = 0"
  1525   (is "?f x = 0")
  1526 proof -
  1527   have "\<forall>x. DERIV (\<lambda>x. ?f x) x :> 0"
  1528     by (auto intro!: DERIV_intros simp add: algebra_simps)
  1529   hence "?f x = ?f 0"
  1530     by (rule DERIV_isconst_all)
  1531   thus ?thesis by simp
  1532 qed
  1533 
  1534 lemma sin_add: "sin (x + y) = sin x * cos y + cos x * sin y"
  1535   using sin_cos_add_lemma unfolding realpow_two_sum_zero_iff by simp
  1536 
  1537 lemma cos_add: "cos (x + y) = cos x * cos y - sin x * sin y"
  1538   using sin_cos_add_lemma unfolding realpow_two_sum_zero_iff by simp
  1539 
  1540 lemma sin_cos_minus_lemma:
  1541   "(sin(-x) + sin(x))\<twosuperior> + (cos(-x) - cos(x))\<twosuperior> = 0" (is "?f x = 0")
  1542 proof -
  1543   have "\<forall>x. DERIV (\<lambda>x. ?f x) x :> 0"
  1544     by (auto intro!: DERIV_intros simp add: algebra_simps)
  1545   hence "?f x = ?f 0"
  1546     by (rule DERIV_isconst_all)
  1547   thus ?thesis by simp
  1548 qed
  1549 
  1550 lemma sin_minus [simp]: "sin (-x) = -sin(x)"
  1551   using sin_cos_minus_lemma [where x=x] by simp
  1552 
  1553 lemma cos_minus [simp]: "cos (-x) = cos(x)"
  1554   using sin_cos_minus_lemma [where x=x] by simp
  1555 
  1556 lemma sin_diff: "sin (x - y) = sin x * cos y - cos x * sin y"
  1557   by (simp add: diff_minus sin_add)
  1558 
  1559 lemma sin_diff2: "sin (x - y) = cos y * sin x - sin y * cos x"
  1560   by (simp add: sin_diff mult_commute)
  1561 
  1562 lemma cos_diff: "cos (x - y) = cos x * cos y + sin x * sin y"
  1563   by (simp add: diff_minus cos_add)
  1564 
  1565 lemma cos_diff2: "cos (x - y) = cos y * cos x + sin y * sin x"
  1566   by (simp add: cos_diff mult_commute)
  1567 
  1568 lemma sin_double [simp]: "sin(2 * x) = 2* sin x * cos x"
  1569   using sin_add [where x=x and y=x] by simp
  1570 
  1571 lemma cos_double: "cos(2* x) = ((cos x)\<twosuperior>) - ((sin x)\<twosuperior>)"
  1572   using cos_add [where x=x and y=x]
  1573   by (simp add: power2_eq_square)
  1574 
  1575 
  1576 subsection {* The Constant Pi *}
  1577 
  1578 definition pi :: "real" where
  1579   "pi = 2 * (THE x. 0 \<le> (x::real) & x \<le> 2 & cos x = 0)"
  1580 
  1581 text{*Show that there's a least positive @{term x} with @{term "cos(x) = 0"};
  1582    hence define pi.*}
  1583 
  1584 lemma sin_paired:
  1585      "(%n. -1 ^ n /(real (fact (2 * n + 1))) * x ^ (2 * n + 1))
  1586       sums  sin x"
  1587 proof -
  1588   have "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2. sin_coeff k * x ^ k) sums sin x"
  1589     by (rule sin_converges [THEN sums_group], simp)
  1590   thus ?thesis unfolding One_nat_def sin_coeff_def by (simp add: mult_ac)
  1591 qed
  1592 
  1593 lemma sin_gt_zero:
  1594   assumes "0 < x" and "x < 2" shows "0 < sin x"
  1595 proof -
  1596   let ?f = "\<lambda>n. \<Sum>k = n*2..<n*2+2. -1 ^ k / real (fact (2*k+1)) * x^(2*k+1)"
  1597   have pos: "\<forall>n. 0 < ?f n"
  1598   proof
  1599     fix n :: nat
  1600     let ?k2 = "real (Suc (Suc (4 * n)))"
  1601     let ?k3 = "real (Suc (Suc (Suc (4 * n))))"
  1602     have "x * x < ?k2 * ?k3"
  1603       using assms by (intro mult_strict_mono', simp_all)
  1604     hence "x * x * x * x ^ (n * 4) < ?k2 * ?k3 * x * x ^ (n * 4)"
  1605       by (intro mult_strict_right_mono zero_less_power `0 < x`)
  1606     thus "0 < ?f n"
  1607       by (simp del: mult_Suc,
  1608         simp add: less_divide_eq mult_pos_pos field_simps del: mult_Suc)
  1609   qed
  1610   have sums: "?f sums sin x"
  1611     by (rule sin_paired [THEN sums_group], simp)
  1612   show "0 < sin x"
  1613     unfolding sums_unique [OF sums]
  1614     using sums_summable [OF sums] pos
  1615     by (rule suminf_gt_zero)
  1616 qed
  1617 
  1618 lemma cos_double_less_one: "[| 0 < x; x < 2 |] ==> cos (2 * x) < 1"
  1619 apply (cut_tac x = x in sin_gt_zero)
  1620 apply (auto simp add: cos_squared_eq cos_double)
  1621 done
  1622 
  1623 lemma cos_paired:
  1624      "(%n. -1 ^ n /(real (fact (2 * n))) * x ^ (2 * n)) sums cos x"
  1625 proof -
  1626   have "(\<lambda>n. \<Sum>k = n * 2..<n * 2 + 2. cos_coeff k * x ^ k) sums cos x"
  1627     by (rule cos_converges [THEN sums_group], simp)
  1628   thus ?thesis unfolding cos_coeff_def by (simp add: mult_ac)
  1629 qed
  1630 
  1631 lemma real_mult_inverse_cancel:
  1632      "[|(0::real) < x; 0 < x1; x1 * y < x * u |]
  1633       ==> inverse x * y < inverse x1 * u"
  1634 apply (rule_tac c=x in mult_less_imp_less_left)
  1635 apply (auto simp add: mult_assoc [symmetric])
  1636 apply (simp (no_asm) add: mult_ac)
  1637 apply (rule_tac c=x1 in mult_less_imp_less_right)
  1638 apply (auto simp add: mult_ac)
  1639 done
  1640 
  1641 lemma real_mult_inverse_cancel2:
  1642      "[|(0::real) < x;0 < x1; x1 * y < x * u |] ==> y * inverse x < u * inverse x1"
  1643 apply (auto dest: real_mult_inverse_cancel simp add: mult_ac)
  1644 done
  1645 
  1646 lemma realpow_num_eq_if:
  1647   fixes m :: "'a::power"
  1648   shows "m ^ n = (if n=0 then 1 else m * m ^ (n - 1))"
  1649 by (cases n, auto)
  1650 
  1651 lemma cos_two_less_zero [simp]: "cos (2) < 0"
  1652 apply (cut_tac x = 2 in cos_paired)
  1653 apply (drule sums_minus)
  1654 apply (rule neg_less_iff_less [THEN iffD1])
  1655 apply (frule sums_unique, auto)
  1656 apply (rule_tac y =
  1657  "\<Sum>n=0..< Suc(Suc(Suc 0)). - (-1 ^ n / (real(fact (2*n))) * 2 ^ (2*n))"
  1658        in order_less_trans)
  1659 apply (simp (no_asm) add: fact_num_eq_if_nat realpow_num_eq_if del: fact_Suc)
  1660 apply (simp (no_asm) add: mult_assoc del: setsum_op_ivl_Suc)
  1661 apply (rule sumr_pos_lt_pair)
  1662 apply (erule sums_summable, safe)
  1663 unfolding One_nat_def
  1664 apply (simp (no_asm) add: divide_inverse real_0_less_add_iff mult_assoc [symmetric]
  1665             del: fact_Suc)
  1666 apply (simp add: inverse_eq_divide less_divide_eq del: fact_Suc)
  1667 apply (subst fact_Suc [of "Suc (Suc (Suc (Suc (Suc (Suc (Suc (4 * d)))))))"])
  1668 apply (simp only: real_of_nat_mult)
  1669 apply (rule mult_strict_mono, force)
  1670   apply (rule_tac [3] real_of_nat_ge_zero)
  1671  prefer 2 apply force
  1672 apply (rule real_of_nat_less_iff [THEN iffD2])
  1673 apply (rule fact_less_mono_nat, auto)
  1674 done
  1675 
  1676 lemmas cos_two_neq_zero [simp] = cos_two_less_zero [THEN less_imp_neq]
  1677 lemmas cos_two_le_zero [simp] = cos_two_less_zero [THEN order_less_imp_le]
  1678 
  1679 lemma cos_is_zero: "EX! x. 0 \<le> x & x \<le> 2 & cos x = 0"
  1680 proof (rule ex_ex1I)
  1681   show "\<exists>x. 0 \<le> x & x \<le> 2 & cos x = 0"
  1682     by (rule IVT2, simp_all)
  1683 next
  1684   fix x y
  1685   assume x: "0 \<le> x \<and> x \<le> 2 \<and> cos x = 0"
  1686   assume y: "0 \<le> y \<and> y \<le> 2 \<and> cos y = 0"
  1687   have [simp]: "\<forall>x. cos differentiable x"
  1688     unfolding differentiable_def by (auto intro: DERIV_cos)
  1689   from x y show "x = y"
  1690     apply (cut_tac less_linear [of x y], auto)
  1691     apply (drule_tac f = cos in Rolle)
  1692     apply (drule_tac [5] f = cos in Rolle)
  1693     apply (auto dest!: DERIV_cos [THEN DERIV_unique])
  1694     apply (metis order_less_le_trans less_le sin_gt_zero)
  1695     apply (metis order_less_le_trans less_le sin_gt_zero)
  1696     done
  1697 qed
  1698 
  1699 lemma pi_half: "pi/2 = (THE x. 0 \<le> x & x \<le> 2 & cos x = 0)"
  1700 by (simp add: pi_def)
  1701 
  1702 lemma cos_pi_half [simp]: "cos (pi / 2) = 0"
  1703 by (simp add: pi_half cos_is_zero [THEN theI'])
  1704 
  1705 lemma pi_half_gt_zero [simp]: "0 < pi / 2"
  1706 apply (rule order_le_neq_trans)
  1707 apply (simp add: pi_half cos_is_zero [THEN theI'])
  1708 apply (rule notI, drule arg_cong [where f=cos], simp)
  1709 done
  1710 
  1711 lemmas pi_half_neq_zero [simp] = pi_half_gt_zero [THEN less_imp_neq, symmetric]
  1712 lemmas pi_half_ge_zero [simp] = pi_half_gt_zero [THEN order_less_imp_le]
  1713 
  1714 lemma pi_half_less_two [simp]: "pi / 2 < 2"
  1715 apply (rule order_le_neq_trans)
  1716 apply (simp add: pi_half cos_is_zero [THEN theI'])
  1717 apply (rule notI, drule arg_cong [where f=cos], simp)
  1718 done
  1719 
  1720 lemmas pi_half_neq_two [simp] = pi_half_less_two [THEN less_imp_neq]
  1721 lemmas pi_half_le_two [simp] =  pi_half_less_two [THEN order_less_imp_le]
  1722 
  1723 lemma pi_gt_zero [simp]: "0 < pi"
  1724 by (insert pi_half_gt_zero, simp)
  1725 
  1726 lemma pi_ge_zero [simp]: "0 \<le> pi"
  1727 by (rule pi_gt_zero [THEN order_less_imp_le])
  1728 
  1729 lemma pi_neq_zero [simp]: "pi \<noteq> 0"
  1730 by (rule pi_gt_zero [THEN less_imp_neq, THEN not_sym])
  1731 
  1732 lemma pi_not_less_zero [simp]: "\<not> pi < 0"
  1733 by (simp add: linorder_not_less)
  1734 
  1735 lemma minus_pi_half_less_zero: "-(pi/2) < 0"
  1736 by simp
  1737 
  1738 lemma m2pi_less_pi: "- (2 * pi) < pi"
  1739 by simp
  1740 
  1741 lemma sin_pi_half [simp]: "sin(pi/2) = 1"
  1742 apply (cut_tac x = "pi/2" in sin_cos_squared_add2)
  1743 apply (cut_tac sin_gt_zero [OF pi_half_gt_zero pi_half_less_two])
  1744 apply (simp add: power2_eq_1_iff)
  1745 done
  1746 
  1747 lemma cos_pi [simp]: "cos pi = -1"
  1748 by (cut_tac x = "pi/2" and y = "pi/2" in cos_add, simp)
  1749 
  1750 lemma sin_pi [simp]: "sin pi = 0"
  1751 by (cut_tac x = "pi/2" and y = "pi/2" in sin_add, simp)
  1752 
  1753 lemma sin_cos_eq: "sin x = cos (pi/2 - x)"
  1754 by (simp add: cos_diff)
  1755 
  1756 lemma minus_sin_cos_eq: "-sin x = cos (x + pi/2)"
  1757 by (simp add: cos_add)
  1758 
  1759 lemma cos_sin_eq: "cos x = sin (pi/2 - x)"
  1760 by (simp add: sin_diff)
  1761 
  1762 lemma sin_periodic_pi [simp]: "sin (x + pi) = - sin x"
  1763 by (simp add: sin_add)
  1764 
  1765 lemma sin_periodic_pi2 [simp]: "sin (pi + x) = - sin x"
  1766 by (simp add: sin_add)
  1767 
  1768 lemma cos_periodic_pi [simp]: "cos (x + pi) = - cos x"
  1769 by (simp add: cos_add)
  1770 
  1771 lemma sin_periodic [simp]: "sin (x + 2*pi) = sin x"
  1772 by (simp add: sin_add cos_double)
  1773 
  1774 lemma cos_periodic [simp]: "cos (x + 2*pi) = cos x"
  1775 by (simp add: cos_add cos_double)
  1776 
  1777 lemma cos_npi [simp]: "cos (real n * pi) = -1 ^ n"
  1778 apply (induct "n")
  1779 apply (auto simp add: real_of_nat_Suc distrib_right)
  1780 done
  1781 
  1782 lemma cos_npi2 [simp]: "cos (pi * real n) = -1 ^ n"
  1783 proof -
  1784   have "cos (pi * real n) = cos (real n * pi)" by (simp only: mult_commute)
  1785   also have "... = -1 ^ n" by (rule cos_npi)
  1786   finally show ?thesis .
  1787 qed
  1788 
  1789 lemma sin_npi [simp]: "sin (real (n::nat) * pi) = 0"
  1790 apply (induct "n")
  1791 apply (auto simp add: real_of_nat_Suc distrib_right)
  1792 done
  1793 
  1794 lemma sin_npi2 [simp]: "sin (pi * real (n::nat)) = 0"
  1795 by (simp add: mult_commute [of pi])
  1796 
  1797 lemma cos_two_pi [simp]: "cos (2 * pi) = 1"
  1798 by (simp add: cos_double)
  1799 
  1800 lemma sin_two_pi [simp]: "sin (2 * pi) = 0"
  1801 by simp
  1802 
  1803 lemma sin_gt_zero2: "[| 0 < x; x < pi/2 |] ==> 0 < sin x"
  1804 apply (rule sin_gt_zero, assumption)
  1805 apply (rule order_less_trans, assumption)
  1806 apply (rule pi_half_less_two)
  1807 done
  1808 
  1809 lemma sin_less_zero:
  1810   assumes lb: "- pi/2 < x" and "x < 0" shows "sin x < 0"
  1811 proof -
  1812   have "0 < sin (- x)" using assms by (simp only: sin_gt_zero2)
  1813   thus ?thesis by simp
  1814 qed
  1815 
  1816 lemma pi_less_4: "pi < 4"
  1817 by (cut_tac pi_half_less_two, auto)
  1818 
  1819 lemma cos_gt_zero: "[| 0 < x; x < pi/2 |] ==> 0 < cos x"
  1820 apply (cut_tac pi_less_4)
  1821 apply (cut_tac f = cos and a = 0 and b = x and y = 0 in IVT2_objl, safe, simp_all)
  1822 apply (cut_tac cos_is_zero, safe)
  1823 apply (rename_tac y z)
  1824 apply (drule_tac x = y in spec)
  1825 apply (drule_tac x = "pi/2" in spec, simp)
  1826 done
  1827 
  1828 lemma cos_gt_zero_pi: "[| -(pi/2) < x; x < pi/2 |] ==> 0 < cos x"
  1829 apply (rule_tac x = x and y = 0 in linorder_cases)
  1830 apply (rule cos_minus [THEN subst])
  1831 apply (rule cos_gt_zero)
  1832 apply (auto intro: cos_gt_zero)
  1833 done
  1834 
  1835 lemma cos_ge_zero: "[| -(pi/2) \<le> x; x \<le> pi/2 |] ==> 0 \<le> cos x"
  1836 apply (auto simp add: order_le_less cos_gt_zero_pi)
  1837 apply (subgoal_tac "x = pi/2", auto)
  1838 done
  1839 
  1840 lemma sin_gt_zero_pi: "[| 0 < x; x < pi  |] ==> 0 < sin x"
  1841 by (simp add: sin_cos_eq cos_gt_zero_pi)
  1842 
  1843 lemma pi_ge_two: "2 \<le> pi"
  1844 proof (rule ccontr)
  1845   assume "\<not> 2 \<le> pi" hence "pi < 2" by auto
  1846   have "\<exists>y > pi. y < 2 \<and> y < 2 * pi"
  1847   proof (cases "2 < 2 * pi")
  1848     case True with dense[OF `pi < 2`] show ?thesis by auto
  1849   next
  1850     case False have "pi < 2 * pi" by auto
  1851     from dense[OF this] and False show ?thesis by auto
  1852   qed
  1853   then obtain y where "pi < y" and "y < 2" and "y < 2 * pi" by blast
  1854   hence "0 < sin y" using sin_gt_zero by auto
  1855   moreover
  1856   have "sin y < 0" using sin_gt_zero_pi[of "y - pi"] `pi < y` and `y < 2 * pi` sin_periodic_pi[of "y - pi"] by auto
  1857   ultimately show False by auto
  1858 qed
  1859 
  1860 lemma sin_ge_zero: "[| 0 \<le> x; x \<le> pi |] ==> 0 \<le> sin x"
  1861 by (auto simp add: order_le_less sin_gt_zero_pi)
  1862 
  1863 text {* FIXME: This proof is almost identical to lemma @{text cos_is_zero}.
  1864   It should be possible to factor out some of the common parts. *}
  1865 
  1866 lemma cos_total: "[| -1 \<le> y; y \<le> 1 |] ==> EX! x. 0 \<le> x & x \<le> pi & (cos x = y)"
  1867 proof (rule ex_ex1I)
  1868   assume y: "-1 \<le> y" "y \<le> 1"
  1869   show "\<exists>x. 0 \<le> x & x \<le> pi & cos x = y"
  1870     by (rule IVT2, simp_all add: y)
  1871 next
  1872   fix a b
  1873   assume a: "0 \<le> a \<and> a \<le> pi \<and> cos a = y"
  1874   assume b: "0 \<le> b \<and> b \<le> pi \<and> cos b = y"
  1875   have [simp]: "\<forall>x. cos differentiable x"
  1876     unfolding differentiable_def by (auto intro: DERIV_cos)
  1877   from a b show "a = b"
  1878     apply (cut_tac less_linear [of a b], auto)
  1879     apply (drule_tac f = cos in Rolle)
  1880     apply (drule_tac [5] f = cos in Rolle)
  1881     apply (auto dest!: DERIV_cos [THEN DERIV_unique])
  1882     apply (metis order_less_le_trans less_le sin_gt_zero_pi)
  1883     apply (metis order_less_le_trans less_le sin_gt_zero_pi)
  1884     done
  1885 qed
  1886 
  1887 lemma sin_total:
  1888      "[| -1 \<le> y; y \<le> 1 |] ==> EX! x. -(pi/2) \<le> x & x \<le> pi/2 & (sin x = y)"
  1889 apply (rule ccontr)
  1890 apply (subgoal_tac "\<forall>x. (- (pi/2) \<le> x & x \<le> pi/2 & (sin x = y)) = (0 \<le> (x + pi/2) & (x + pi/2) \<le> pi & (cos (x + pi/2) = -y))")
  1891 apply (erule contrapos_np)
  1892 apply simp
  1893 apply (cut_tac y="-y" in cos_total, simp) apply simp
  1894 apply (erule ex1E)
  1895 apply (rule_tac a = "x - (pi/2)" in ex1I)
  1896 apply (simp (no_asm) add: add_assoc)
  1897 apply (rotate_tac 3)
  1898 apply (drule_tac x = "xa + pi/2" in spec, safe, simp_all add: cos_add)
  1899 done
  1900 
  1901 lemma reals_Archimedean4:
  1902      "[| 0 < y; 0 \<le> x |] ==> \<exists>n. real n * y \<le> x & x < real (Suc n) * y"
  1903 apply (auto dest!: reals_Archimedean3)
  1904 apply (drule_tac x = x in spec, clarify)
  1905 apply (subgoal_tac "x < real(LEAST m::nat. x < real m * y) * y")
  1906  prefer 2 apply (erule LeastI)
  1907 apply (case_tac "LEAST m::nat. x < real m * y", simp)
  1908 apply (subgoal_tac "~ x < real nat * y")
  1909  prefer 2 apply (rule not_less_Least, simp, force)
  1910 done
  1911 
  1912 (* Pre Isabelle99-2 proof was simpler- numerals arithmetic
  1913    now causes some unwanted re-arrangements of literals!   *)
  1914 lemma cos_zero_lemma:
  1915      "[| 0 \<le> x; cos x = 0 |] ==>
  1916       \<exists>n::nat. ~even n & x = real n * (pi/2)"
  1917 apply (drule pi_gt_zero [THEN reals_Archimedean4], safe)
  1918 apply (subgoal_tac "0 \<le> x - real n * pi &
  1919                     (x - real n * pi) \<le> pi & (cos (x - real n * pi) = 0) ")
  1920 apply (auto simp add: algebra_simps real_of_nat_Suc)
  1921  prefer 2 apply (simp add: cos_diff)
  1922 apply (simp add: cos_diff)
  1923 apply (subgoal_tac "EX! x. 0 \<le> x & x \<le> pi & cos x = 0")
  1924 apply (rule_tac [2] cos_total, safe)
  1925 apply (drule_tac x = "x - real n * pi" in spec)
  1926 apply (drule_tac x = "pi/2" in spec)
  1927 apply (simp add: cos_diff)
  1928 apply (rule_tac x = "Suc (2 * n)" in exI)
  1929 apply (simp add: real_of_nat_Suc algebra_simps, auto)
  1930 done
  1931 
  1932 lemma sin_zero_lemma:
  1933      "[| 0 \<le> x; sin x = 0 |] ==>
  1934       \<exists>n::nat. even n & x = real n * (pi/2)"
  1935 apply (subgoal_tac "\<exists>n::nat. ~ even n & x + pi/2 = real n * (pi/2) ")
  1936  apply (clarify, rule_tac x = "n - 1" in exI)
  1937  apply (force simp add: odd_Suc_mult_two_ex real_of_nat_Suc distrib_right)
  1938 apply (rule cos_zero_lemma)
  1939 apply (simp_all add: cos_add)
  1940 done
  1941 
  1942 
  1943 lemma cos_zero_iff:
  1944      "(cos x = 0) =
  1945       ((\<exists>n::nat. ~even n & (x = real n * (pi/2))) |
  1946        (\<exists>n::nat. ~even n & (x = -(real n * (pi/2)))))"
  1947 apply (rule iffI)
  1948 apply (cut_tac linorder_linear [of 0 x], safe)
  1949 apply (drule cos_zero_lemma, assumption+)
  1950 apply (cut_tac x="-x" in cos_zero_lemma, simp, simp)
  1951 apply (force simp add: minus_equation_iff [of x])
  1952 apply (auto simp only: odd_Suc_mult_two_ex real_of_nat_Suc distrib_right)
  1953 apply (auto simp add: cos_add)
  1954 done
  1955 
  1956 (* ditto: but to a lesser extent *)
  1957 lemma sin_zero_iff:
  1958      "(sin x = 0) =
  1959       ((\<exists>n::nat. even n & (x = real n * (pi/2))) |
  1960        (\<exists>n::nat. even n & (x = -(real n * (pi/2)))))"
  1961 apply (rule iffI)
  1962 apply (cut_tac linorder_linear [of 0 x], safe)
  1963 apply (drule sin_zero_lemma, assumption+)
  1964 apply (cut_tac x="-x" in sin_zero_lemma, simp, simp, safe)
  1965 apply (force simp add: minus_equation_iff [of x])
  1966 apply (auto simp add: even_mult_two_ex)
  1967 done
  1968 
  1969 lemma cos_monotone_0_pi: assumes "0 \<le> y" and "y < x" and "x \<le> pi"
  1970   shows "cos x < cos y"
  1971 proof -
  1972   have "- (x - y) < 0" using assms by auto
  1973 
  1974   from MVT2[OF `y < x` DERIV_cos[THEN impI, THEN allI]]
  1975   obtain z where "y < z" and "z < x" and cos_diff: "cos x - cos y = (x - y) * - sin z" by auto
  1976   hence "0 < z" and "z < pi" using assms by auto
  1977   hence "0 < sin z" using sin_gt_zero_pi by auto
  1978   hence "cos x - cos y < 0" unfolding cos_diff minus_mult_commute[symmetric] using `- (x - y) < 0` by (rule mult_pos_neg2)
  1979   thus ?thesis by auto
  1980 qed
  1981 
  1982 lemma cos_monotone_0_pi': assumes "0 \<le> y" and "y \<le> x" and "x \<le> pi" shows "cos x \<le> cos y"
  1983 proof (cases "y < x")
  1984   case True show ?thesis using cos_monotone_0_pi[OF `0 \<le> y` True `x \<le> pi`] by auto
  1985 next
  1986   case False hence "y = x" using `y \<le> x` by auto
  1987   thus ?thesis by auto
  1988 qed
  1989 
  1990 lemma cos_monotone_minus_pi_0: assumes "-pi \<le> y" and "y < x" and "x \<le> 0"
  1991   shows "cos y < cos x"
  1992 proof -
  1993   have "0 \<le> -x" and "-x < -y" and "-y \<le> pi" using assms by auto
  1994   from cos_monotone_0_pi[OF this]
  1995   show ?thesis unfolding cos_minus .
  1996 qed
  1997 
  1998 lemma cos_monotone_minus_pi_0': assumes "-pi \<le> y" and "y \<le> x" and "x \<le> 0" shows "cos y \<le> cos x"
  1999 proof (cases "y < x")
  2000   case True show ?thesis using cos_monotone_minus_pi_0[OF `-pi \<le> y` True `x \<le> 0`] by auto
  2001 next
  2002   case False hence "y = x" using `y \<le> x` by auto
  2003   thus ?thesis by auto
  2004 qed
  2005 
  2006 lemma sin_monotone_2pi': assumes "- (pi / 2) \<le> y" and "y \<le> x" and "x \<le> pi / 2" shows "sin y \<le> sin x"
  2007 proof -
  2008   have "0 \<le> y + pi / 2" and "y + pi / 2 \<le> x + pi / 2" and "x + pi /2 \<le> pi"
  2009     using pi_ge_two and assms by auto
  2010   from cos_monotone_0_pi'[OF this] show ?thesis unfolding minus_sin_cos_eq[symmetric] by auto
  2011 qed
  2012 
  2013 subsection {* Tangent *}
  2014 
  2015 definition tan :: "real \<Rightarrow> real" where
  2016   "tan = (\<lambda>x. sin x / cos x)"
  2017 
  2018 lemma tan_zero [simp]: "tan 0 = 0"
  2019   by (simp add: tan_def)
  2020 
  2021 lemma tan_pi [simp]: "tan pi = 0"
  2022   by (simp add: tan_def)
  2023 
  2024 lemma tan_npi [simp]: "tan (real (n::nat) * pi) = 0"
  2025   by (simp add: tan_def)
  2026 
  2027 lemma tan_minus [simp]: "tan (-x) = - tan x"
  2028   by (simp add: tan_def)
  2029 
  2030 lemma tan_periodic [simp]: "tan (x + 2*pi) = tan x"
  2031   by (simp add: tan_def)
  2032 
  2033 lemma lemma_tan_add1:
  2034   "\<lbrakk>cos x \<noteq> 0; cos y \<noteq> 0\<rbrakk> \<Longrightarrow> 1 - tan x * tan y = cos (x + y)/(cos x * cos y)"
  2035   by (simp add: tan_def cos_add field_simps)
  2036 
  2037 lemma add_tan_eq:
  2038   "\<lbrakk>cos x \<noteq> 0; cos y \<noteq> 0\<rbrakk> \<Longrightarrow> tan x + tan y = sin(x + y)/(cos x * cos y)"
  2039   by (simp add: tan_def sin_add field_simps)
  2040 
  2041 lemma tan_add:
  2042      "[| cos x \<noteq> 0; cos y \<noteq> 0; cos (x + y) \<noteq> 0 |]
  2043       ==> tan(x + y) = (tan(x) + tan(y))/(1 - tan(x) * tan(y))"
  2044   by (simp add: add_tan_eq lemma_tan_add1, simp add: tan_def)
  2045 
  2046 lemma tan_double:
  2047      "[| cos x \<noteq> 0; cos (2 * x) \<noteq> 0 |]
  2048       ==> tan (2 * x) = (2 * tan x)/(1 - (tan(x) ^ 2))"
  2049   using tan_add [of x x] by (simp add: power2_eq_square)
  2050 
  2051 lemma tan_gt_zero: "[| 0 < x; x < pi/2 |] ==> 0 < tan x"
  2052 by (simp add: tan_def zero_less_divide_iff sin_gt_zero2 cos_gt_zero_pi)
  2053 
  2054 lemma tan_less_zero:
  2055   assumes lb: "- pi/2 < x" and "x < 0" shows "tan x < 0"
  2056 proof -
  2057   have "0 < tan (- x)" using assms by (simp only: tan_gt_zero)
  2058   thus ?thesis by simp
  2059 qed
  2060 
  2061 lemma tan_half: "tan x = sin (2 * x) / (cos (2 * x) + 1)"
  2062   unfolding tan_def sin_double cos_double sin_squared_eq
  2063   by (simp add: power2_eq_square)
  2064 
  2065 lemma DERIV_tan [simp]: "cos x \<noteq> 0 \<Longrightarrow> DERIV tan x :> inverse ((cos x)\<twosuperior>)"
  2066   unfolding tan_def
  2067   by (auto intro!: DERIV_intros, simp add: divide_inverse power2_eq_square)
  2068 
  2069 lemma isCont_tan: "cos x \<noteq> 0 \<Longrightarrow> isCont tan x"
  2070   by (rule DERIV_tan [THEN DERIV_isCont])
  2071 
  2072 lemma isCont_tan' [simp]:
  2073   "\<lbrakk>isCont f a; cos (f a) \<noteq> 0\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. tan (f x)) a"
  2074   by (rule isCont_o2 [OF _ isCont_tan])
  2075 
  2076 lemma tendsto_tan [tendsto_intros]:
  2077   "\<lbrakk>(f ---> a) F; cos a \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. tan (f x)) ---> tan a) F"
  2078   by (rule isCont_tendsto_compose [OF isCont_tan])
  2079 
  2080 lemma LIM_cos_div_sin: "(%x. cos(x)/sin(x)) -- pi/2 --> 0"
  2081   by (rule LIM_cong_limit, (rule tendsto_intros)+, simp_all)
  2082 
  2083 lemma lemma_tan_total: "0 < y ==> \<exists>x. 0 < x & x < pi/2 & y < tan x"
  2084 apply (cut_tac LIM_cos_div_sin)
  2085 apply (simp only: LIM_eq)
  2086 apply (drule_tac x = "inverse y" in spec, safe, force)
  2087 apply (drule_tac ?d1.0 = s in pi_half_gt_zero [THEN [2] real_lbound_gt_zero], safe)
  2088 apply (rule_tac x = "(pi/2) - e" in exI)
  2089 apply (simp (no_asm_simp))
  2090 apply (drule_tac x = "(pi/2) - e" in spec)
  2091 apply (auto simp add: tan_def sin_diff cos_diff)
  2092 apply (rule inverse_less_iff_less [THEN iffD1])
  2093 apply (auto simp add: divide_inverse)
  2094 apply (rule mult_pos_pos)
  2095 apply (subgoal_tac [3] "0 < sin e & 0 < cos e")
  2096 apply (auto intro: cos_gt_zero sin_gt_zero2 simp add: mult_commute)
  2097 done
  2098 
  2099 lemma tan_total_pos: "0 \<le> y ==> \<exists>x. 0 \<le> x & x < pi/2 & tan x = y"
  2100 apply (frule order_le_imp_less_or_eq, safe)
  2101  prefer 2 apply force
  2102 apply (drule lemma_tan_total, safe)
  2103 apply (cut_tac f = tan and a = 0 and b = x and y = y in IVT_objl)
  2104 apply (auto intro!: DERIV_tan [THEN DERIV_isCont])
  2105 apply (drule_tac y = xa in order_le_imp_less_or_eq)
  2106 apply (auto dest: cos_gt_zero)
  2107 done
  2108 
  2109 lemma lemma_tan_total1: "\<exists>x. -(pi/2) < x & x < (pi/2) & tan x = y"
  2110 apply (cut_tac linorder_linear [of 0 y], safe)
  2111 apply (drule tan_total_pos)
  2112 apply (cut_tac [2] y="-y" in tan_total_pos, safe)
  2113 apply (rule_tac [3] x = "-x" in exI)
  2114 apply (auto del: exI intro!: exI)
  2115 done
  2116 
  2117 lemma tan_total: "EX! x. -(pi/2) < x & x < (pi/2) & tan x = y"
  2118 apply (cut_tac y = y in lemma_tan_total1, auto)
  2119 apply (cut_tac x = xa and y = y in linorder_less_linear, auto)
  2120 apply (subgoal_tac [2] "\<exists>z. y < z & z < xa & DERIV tan z :> 0")
  2121 apply (subgoal_tac "\<exists>z. xa < z & z < y & DERIV tan z :> 0")
  2122 apply (rule_tac [4] Rolle)
  2123 apply (rule_tac [2] Rolle)
  2124 apply (auto del: exI intro!: DERIV_tan DERIV_isCont exI
  2125             simp add: differentiable_def)
  2126 txt{*Now, simulate TRYALL*}
  2127 apply (rule_tac [!] DERIV_tan asm_rl)
  2128 apply (auto dest!: DERIV_unique [OF _ DERIV_tan]
  2129             simp add: cos_gt_zero_pi [THEN less_imp_neq, THEN not_sym])
  2130 done
  2131 
  2132 lemma tan_monotone: assumes "- (pi / 2) < y" and "y < x" and "x < pi / 2"
  2133   shows "tan y < tan x"
  2134 proof -
  2135   have "\<forall> x'. y \<le> x' \<and> x' \<le> x \<longrightarrow> DERIV tan x' :> inverse (cos x'^2)"
  2136   proof (rule allI, rule impI)
  2137     fix x' :: real assume "y \<le> x' \<and> x' \<le> x"
  2138     hence "-(pi/2) < x'" and "x' < pi/2" using assms by auto
  2139     from cos_gt_zero_pi[OF this]
  2140     have "cos x' \<noteq> 0" by auto
  2141     thus "DERIV tan x' :> inverse (cos x'^2)" by (rule DERIV_tan)
  2142   qed
  2143   from MVT2[OF `y < x` this]
  2144   obtain z where "y < z" and "z < x" and tan_diff: "tan x - tan y = (x - y) * inverse ((cos z)\<twosuperior>)" by auto
  2145   hence "- (pi / 2) < z" and "z < pi / 2" using assms by auto
  2146   hence "0 < cos z" using cos_gt_zero_pi by auto
  2147   hence inv_pos: "0 < inverse ((cos z)\<twosuperior>)" by auto
  2148   have "0 < x - y" using `y < x` by auto
  2149   from mult_pos_pos [OF this inv_pos]
  2150   have "0 < tan x - tan y" unfolding tan_diff by auto
  2151   thus ?thesis by auto
  2152 qed
  2153 
  2154 lemma tan_monotone': assumes "- (pi / 2) < y" and "y < pi / 2" and "- (pi / 2) < x" and "x < pi / 2"
  2155   shows "(y < x) = (tan y < tan x)"
  2156 proof
  2157   assume "y < x" thus "tan y < tan x" using tan_monotone and `- (pi / 2) < y` and `x < pi / 2` by auto
  2158 next
  2159   assume "tan y < tan x"
  2160   show "y < x"
  2161   proof (rule ccontr)
  2162     assume "\<not> y < x" hence "x \<le> y" by auto
  2163     hence "tan x \<le> tan y"
  2164     proof (cases "x = y")
  2165       case True thus ?thesis by auto
  2166     next
  2167       case False hence "x < y" using `x \<le> y` by auto
  2168       from tan_monotone[OF `- (pi/2) < x` this `y < pi / 2`] show ?thesis by auto
  2169     qed
  2170     thus False using `tan y < tan x` by auto
  2171   qed
  2172 qed
  2173 
  2174 lemma tan_inverse: "1 / (tan y) = tan (pi / 2 - y)" unfolding tan_def sin_cos_eq[of y] cos_sin_eq[of y] by auto
  2175 
  2176 lemma tan_periodic_pi[simp]: "tan (x + pi) = tan x"
  2177   by (simp add: tan_def)
  2178 
  2179 lemma tan_periodic_nat[simp]: fixes n :: nat shows "tan (x + real n * pi) = tan x"
  2180 proof (induct n arbitrary: x)
  2181   case (Suc n)
  2182   have split_pi_off: "x + real (Suc n) * pi = (x + real n * pi) + pi" unfolding Suc_eq_plus1 real_of_nat_add real_of_one distrib_right by auto
  2183   show ?case unfolding split_pi_off using Suc by auto
  2184 qed auto
  2185 
  2186 lemma tan_periodic_int[simp]: fixes i :: int shows "tan (x + real i * pi) = tan x"
  2187 proof (cases "0 \<le> i")
  2188   case True hence i_nat: "real i = real (nat i)" by auto
  2189   show ?thesis unfolding i_nat by auto
  2190 next
  2191   case False hence i_nat: "real i = - real (nat (-i))" by auto
  2192   have "tan x = tan (x + real i * pi - real i * pi)" by auto
  2193   also have "\<dots> = tan (x + real i * pi)" unfolding i_nat mult_minus_left diff_minus_eq_add by (rule tan_periodic_nat)
  2194   finally show ?thesis by auto
  2195 qed
  2196 
  2197 lemma tan_periodic_n[simp]: "tan (x + numeral n * pi) = tan x"
  2198   using tan_periodic_int[of _ "numeral n" ] unfolding real_numeral .
  2199 
  2200 subsection {* Inverse Trigonometric Functions *}
  2201 
  2202 definition
  2203   arcsin :: "real => real" where
  2204   "arcsin y = (THE x. -(pi/2) \<le> x & x \<le> pi/2 & sin x = y)"
  2205 
  2206 definition
  2207   arccos :: "real => real" where
  2208   "arccos y = (THE x. 0 \<le> x & x \<le> pi & cos x = y)"
  2209 
  2210 definition
  2211   arctan :: "real => real" where
  2212   "arctan y = (THE x. -(pi/2) < x & x < pi/2 & tan x = y)"
  2213 
  2214 lemma arcsin:
  2215      "[| -1 \<le> y; y \<le> 1 |]
  2216       ==> -(pi/2) \<le> arcsin y &
  2217            arcsin y \<le> pi/2 & sin(arcsin y) = y"
  2218 unfolding arcsin_def by (rule theI' [OF sin_total])
  2219 
  2220 lemma arcsin_pi:
  2221      "[| -1 \<le> y; y \<le> 1 |]
  2222       ==> -(pi/2) \<le> arcsin y & arcsin y \<le> pi & sin(arcsin y) = y"
  2223 apply (drule (1) arcsin)
  2224 apply (force intro: order_trans)
  2225 done
  2226 
  2227 lemma sin_arcsin [simp]: "[| -1 \<le> y; y \<le> 1 |] ==> sin(arcsin y) = y"
  2228 by (blast dest: arcsin)
  2229 
  2230 lemma arcsin_bounded:
  2231      "[| -1 \<le> y; y \<le> 1 |] ==> -(pi/2) \<le> arcsin y & arcsin y \<le> pi/2"
  2232 by (blast dest: arcsin)
  2233 
  2234 lemma arcsin_lbound: "[| -1 \<le> y; y \<le> 1 |] ==> -(pi/2) \<le> arcsin y"
  2235 by (blast dest: arcsin)
  2236 
  2237 lemma arcsin_ubound: "[| -1 \<le> y; y \<le> 1 |] ==> arcsin y \<le> pi/2"
  2238 by (blast dest: arcsin)
  2239 
  2240 lemma arcsin_lt_bounded:
  2241      "[| -1 < y; y < 1 |] ==> -(pi/2) < arcsin y & arcsin y < pi/2"
  2242 apply (frule order_less_imp_le)
  2243 apply (frule_tac y = y in order_less_imp_le)
  2244 apply (frule arcsin_bounded)
  2245 apply (safe, simp)
  2246 apply (drule_tac y = "arcsin y" in order_le_imp_less_or_eq)
  2247 apply (drule_tac [2] y = "pi/2" in order_le_imp_less_or_eq, safe)
  2248 apply (drule_tac [!] f = sin in arg_cong, auto)
  2249 done
  2250 
  2251 lemma arcsin_sin: "[|-(pi/2) \<le> x; x \<le> pi/2 |] ==> arcsin(sin x) = x"
  2252 apply (unfold arcsin_def)
  2253 apply (rule the1_equality)
  2254 apply (rule sin_total, auto)
  2255 done
  2256 
  2257 lemma arccos:
  2258      "[| -1 \<le> y; y \<le> 1 |]
  2259       ==> 0 \<le> arccos y & arccos y \<le> pi & cos(arccos y) = y"
  2260 unfolding arccos_def by (rule theI' [OF cos_total])
  2261 
  2262 lemma cos_arccos [simp]: "[| -1 \<le> y; y \<le> 1 |] ==> cos(arccos y) = y"
  2263 by (blast dest: arccos)
  2264 
  2265 lemma arccos_bounded: "[| -1 \<le> y; y \<le> 1 |] ==> 0 \<le> arccos y & arccos y \<le> pi"
  2266 by (blast dest: arccos)
  2267 
  2268 lemma arccos_lbound: "[| -1 \<le> y; y \<le> 1 |] ==> 0 \<le> arccos y"
  2269 by (blast dest: arccos)
  2270 
  2271 lemma arccos_ubound: "[| -1 \<le> y; y \<le> 1 |] ==> arccos y \<le> pi"
  2272 by (blast dest: arccos)
  2273 
  2274 lemma arccos_lt_bounded:
  2275      "[| -1 < y; y < 1 |]
  2276       ==> 0 < arccos y & arccos y < pi"
  2277 apply (frule order_less_imp_le)
  2278 apply (frule_tac y = y in order_less_imp_le)
  2279 apply (frule arccos_bounded, auto)
  2280 apply (drule_tac y = "arccos y" in order_le_imp_less_or_eq)
  2281 apply (drule_tac [2] y = pi in order_le_imp_less_or_eq, auto)
  2282 apply (drule_tac [!] f = cos in arg_cong, auto)
  2283 done
  2284 
  2285 lemma arccos_cos: "[|0 \<le> x; x \<le> pi |] ==> arccos(cos x) = x"
  2286 apply (simp add: arccos_def)
  2287 apply (auto intro!: the1_equality cos_total)
  2288 done
  2289 
  2290 lemma arccos_cos2: "[|x \<le> 0; -pi \<le> x |] ==> arccos(cos x) = -x"
  2291 apply (simp add: arccos_def)
  2292 apply (auto intro!: the1_equality cos_total)
  2293 done
  2294 
  2295 lemma cos_arcsin: "\<lbrakk>-1 \<le> x; x \<le> 1\<rbrakk> \<Longrightarrow> cos (arcsin x) = sqrt (1 - x\<twosuperior>)"
  2296 apply (subgoal_tac "x\<twosuperior> \<le> 1")
  2297 apply (rule power2_eq_imp_eq)
  2298 apply (simp add: cos_squared_eq)
  2299 apply (rule cos_ge_zero)
  2300 apply (erule (1) arcsin_lbound)
  2301 apply (erule (1) arcsin_ubound)
  2302 apply simp
  2303 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> \<le> 1\<twosuperior>", simp)
  2304 apply (rule power_mono, simp, simp)
  2305 done
  2306 
  2307 lemma sin_arccos: "\<lbrakk>-1 \<le> x; x \<le> 1\<rbrakk> \<Longrightarrow> sin (arccos x) = sqrt (1 - x\<twosuperior>)"
  2308 apply (subgoal_tac "x\<twosuperior> \<le> 1")
  2309 apply (rule power2_eq_imp_eq)
  2310 apply (simp add: sin_squared_eq)
  2311 apply (rule sin_ge_zero)
  2312 apply (erule (1) arccos_lbound)
  2313 apply (erule (1) arccos_ubound)
  2314 apply simp
  2315 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> \<le> 1\<twosuperior>", simp)
  2316 apply (rule power_mono, simp, simp)
  2317 done
  2318 
  2319 lemma arctan [simp]:
  2320      "- (pi/2) < arctan y  & arctan y < pi/2 & tan (arctan y) = y"
  2321 unfolding arctan_def by (rule theI' [OF tan_total])
  2322 
  2323 lemma tan_arctan: "tan(arctan y) = y"
  2324 by auto
  2325 
  2326 lemma arctan_bounded: "- (pi/2) < arctan y  & arctan y < pi/2"
  2327 by (auto simp only: arctan)
  2328 
  2329 lemma arctan_lbound: "- (pi/2) < arctan y"
  2330 by auto
  2331 
  2332 lemma arctan_ubound: "arctan y < pi/2"
  2333 by (auto simp only: arctan)
  2334 
  2335 lemma arctan_unique:
  2336   assumes "-(pi/2) < x" and "x < pi/2" and "tan x = y"
  2337   shows "arctan y = x"
  2338   using assms arctan [of y] tan_total [of y] by (fast elim: ex1E)
  2339 
  2340 lemma arctan_tan:
  2341       "[|-(pi/2) < x; x < pi/2 |] ==> arctan(tan x) = x"
  2342   by (rule arctan_unique, simp_all)
  2343 
  2344 lemma arctan_zero_zero [simp]: "arctan 0 = 0"
  2345   by (rule arctan_unique, simp_all)
  2346 
  2347 lemma arctan_minus: "arctan (- x) = - arctan x"
  2348   apply (rule arctan_unique)
  2349   apply (simp only: neg_less_iff_less arctan_ubound)
  2350   apply (metis minus_less_iff arctan_lbound)
  2351   apply simp
  2352   done
  2353 
  2354 lemma cos_arctan_not_zero [simp]: "cos (arctan x) \<noteq> 0"
  2355   by (intro less_imp_neq [symmetric] cos_gt_zero_pi
  2356     arctan_lbound arctan_ubound)
  2357 
  2358 lemma cos_arctan: "cos (arctan x) = 1 / sqrt (1 + x\<twosuperior>)"
  2359 proof (rule power2_eq_imp_eq)
  2360   have "0 < 1 + x\<twosuperior>" by (simp add: add_pos_nonneg)
  2361   show "0 \<le> 1 / sqrt (1 + x\<twosuperior>)" by simp
  2362   show "0 \<le> cos (arctan x)"
  2363     by (intro less_imp_le cos_gt_zero_pi arctan_lbound arctan_ubound)
  2364   have "(cos (arctan x))\<twosuperior> * (1 + (tan (arctan x))\<twosuperior>) = 1"
  2365     unfolding tan_def by (simp add: distrib_left power_divide)
  2366   thus "(cos (arctan x))\<twosuperior> = (1 / sqrt (1 + x\<twosuperior>))\<twosuperior>"
  2367     using `0 < 1 + x\<twosuperior>` by (simp add: power_divide eq_divide_eq)
  2368 qed
  2369 
  2370 lemma sin_arctan: "sin (arctan x) = x / sqrt (1 + x\<twosuperior>)"
  2371   using add_pos_nonneg [OF zero_less_one zero_le_power2 [of x]]
  2372   using tan_arctan [of x] unfolding tan_def cos_arctan
  2373   by (simp add: eq_divide_eq)
  2374 
  2375 lemma tan_sec: "cos x \<noteq> 0 ==> 1 + tan(x) ^ 2 = inverse(cos x) ^ 2"
  2376 apply (rule power_inverse [THEN subst])
  2377 apply (rule_tac c1 = "(cos x)\<twosuperior>" in real_mult_right_cancel [THEN iffD1])
  2378 apply (auto dest: field_power_not_zero
  2379         simp add: power_mult_distrib distrib_right power_divide tan_def
  2380                   mult_assoc power_inverse [symmetric])
  2381 done
  2382 
  2383 lemma arctan_less_iff: "arctan x < arctan y \<longleftrightarrow> x < y"
  2384   by (metis tan_monotone' arctan_lbound arctan_ubound tan_arctan)
  2385 
  2386 lemma arctan_le_iff: "arctan x \<le> arctan y \<longleftrightarrow> x \<le> y"
  2387   by (simp only: not_less [symmetric] arctan_less_iff)
  2388 
  2389 lemma arctan_eq_iff: "arctan x = arctan y \<longleftrightarrow> x = y"
  2390   by (simp only: eq_iff [where 'a=real] arctan_le_iff)
  2391 
  2392 lemma zero_less_arctan_iff [simp]: "0 < arctan x \<longleftrightarrow> 0 < x"
  2393   using arctan_less_iff [of 0 x] by simp
  2394 
  2395 lemma arctan_less_zero_iff [simp]: "arctan x < 0 \<longleftrightarrow> x < 0"
  2396   using arctan_less_iff [of x 0] by simp
  2397 
  2398 lemma zero_le_arctan_iff [simp]: "0 \<le> arctan x \<longleftrightarrow> 0 \<le> x"
  2399   using arctan_le_iff [of 0 x] by simp
  2400 
  2401 lemma arctan_le_zero_iff [simp]: "arctan x \<le> 0 \<longleftrightarrow> x \<le> 0"
  2402   using arctan_le_iff [of x 0] by simp
  2403 
  2404 lemma arctan_eq_zero_iff [simp]: "arctan x = 0 \<longleftrightarrow> x = 0"
  2405   using arctan_eq_iff [of x 0] by simp
  2406 
  2407 lemma isCont_inverse_function2:
  2408   fixes f g :: "real \<Rightarrow> real" shows
  2409   "\<lbrakk>a < x; x < b;
  2410     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z;
  2411     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z\<rbrakk>
  2412    \<Longrightarrow> isCont g (f x)"
  2413 apply (rule isCont_inverse_function
  2414        [where f=f and d="min (x - a) (b - x)"])
  2415 apply (simp_all add: abs_le_iff)
  2416 done
  2417 
  2418 lemma isCont_arcsin: "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> isCont arcsin x"
  2419 apply (subgoal_tac "isCont arcsin (sin (arcsin x))", simp)
  2420 apply (rule isCont_inverse_function2 [where f=sin])
  2421 apply (erule (1) arcsin_lt_bounded [THEN conjunct1])
  2422 apply (erule (1) arcsin_lt_bounded [THEN conjunct2])
  2423 apply (fast intro: arcsin_sin, simp)
  2424 done
  2425 
  2426 lemma isCont_arccos: "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> isCont arccos x"
  2427 apply (subgoal_tac "isCont arccos (cos (arccos x))", simp)
  2428 apply (rule isCont_inverse_function2 [where f=cos])
  2429 apply (erule (1) arccos_lt_bounded [THEN conjunct1])
  2430 apply (erule (1) arccos_lt_bounded [THEN conjunct2])
  2431 apply (fast intro: arccos_cos, simp)
  2432 done
  2433 
  2434 lemma isCont_arctan: "isCont arctan x"
  2435 apply (rule arctan_lbound [of x, THEN dense, THEN exE], clarify)
  2436 apply (rule arctan_ubound [of x, THEN dense, THEN exE], clarify)
  2437 apply (subgoal_tac "isCont arctan (tan (arctan x))", simp)
  2438 apply (erule (1) isCont_inverse_function2 [where f=tan])
  2439 apply (metis arctan_tan order_le_less_trans order_less_le_trans)
  2440 apply (metis cos_gt_zero_pi isCont_tan order_less_le_trans less_le)
  2441 done
  2442 
  2443 lemma DERIV_arcsin:
  2444   "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> DERIV arcsin x :> inverse (sqrt (1 - x\<twosuperior>))"
  2445 apply (rule DERIV_inverse_function [where f=sin and a="-1" and b="1"])
  2446 apply (rule DERIV_cong [OF DERIV_sin])
  2447 apply (simp add: cos_arcsin)
  2448 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> < 1\<twosuperior>", simp)
  2449 apply (rule power_strict_mono, simp, simp, simp)
  2450 apply assumption
  2451 apply assumption
  2452 apply simp
  2453 apply (erule (1) isCont_arcsin)
  2454 done
  2455 
  2456 lemma DERIV_arccos:
  2457   "\<lbrakk>-1 < x; x < 1\<rbrakk> \<Longrightarrow> DERIV arccos x :> inverse (- sqrt (1 - x\<twosuperior>))"
  2458 apply (rule DERIV_inverse_function [where f=cos and a="-1" and b="1"])
  2459 apply (rule DERIV_cong [OF DERIV_cos])
  2460 apply (simp add: sin_arccos)
  2461 apply (subgoal_tac "\<bar>x\<bar>\<twosuperior> < 1\<twosuperior>", simp)
  2462 apply (rule power_strict_mono, simp, simp, simp)
  2463 apply assumption
  2464 apply assumption
  2465 apply simp
  2466 apply (erule (1) isCont_arccos)
  2467 done
  2468 
  2469 lemma DERIV_arctan: "DERIV arctan x :> inverse (1 + x\<twosuperior>)"
  2470 apply (rule DERIV_inverse_function [where f=tan and a="x - 1" and b="x + 1"])
  2471 apply (rule DERIV_cong [OF DERIV_tan])
  2472 apply (rule cos_arctan_not_zero)
  2473 apply (simp add: power_inverse tan_sec [symmetric])
  2474 apply (subgoal_tac "0 < 1 + x\<twosuperior>", simp)
  2475 apply (simp add: add_pos_nonneg)
  2476 apply (simp, simp, simp, rule isCont_arctan)
  2477 done
  2478 
  2479 declare
  2480   DERIV_arcsin[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2481   DERIV_arccos[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2482   DERIV_arctan[THEN DERIV_chain2, THEN DERIV_cong, DERIV_intros]
  2483 
  2484 subsection {* More Theorems about Sin and Cos *}
  2485 
  2486 lemma cos_45: "cos (pi / 4) = sqrt 2 / 2"
  2487 proof -
  2488   let ?c = "cos (pi / 4)" and ?s = "sin (pi / 4)"
  2489   have nonneg: "0 \<le> ?c"
  2490     by (simp add: cos_ge_zero)
  2491   have "0 = cos (pi / 4 + pi / 4)"
  2492     by simp
  2493   also have "cos (pi / 4 + pi / 4) = ?c\<twosuperior> - ?s\<twosuperior>"
  2494     by (simp only: cos_add power2_eq_square)
  2495   also have "\<dots> = 2 * ?c\<twosuperior> - 1"
  2496     by (simp add: sin_squared_eq)
  2497   finally have "?c\<twosuperior> = (sqrt 2 / 2)\<twosuperior>"
  2498     by (simp add: power_divide)
  2499   thus ?thesis
  2500     using nonneg by (rule power2_eq_imp_eq) simp
  2501 qed
  2502 
  2503 lemma cos_30: "cos (pi / 6) = sqrt 3 / 2"
  2504 proof -
  2505   let ?c = "cos (pi / 6)" and ?s = "sin (pi / 6)"
  2506   have pos_c: "0 < ?c"
  2507     by (rule cos_gt_zero, simp, simp)
  2508   have "0 = cos (pi / 6 + pi / 6 + pi / 6)"
  2509     by simp
  2510   also have "\<dots> = (?c * ?c - ?s * ?s) * ?c - (?s * ?c + ?c * ?s) * ?s"
  2511     by (simp only: cos_add sin_add)
  2512   also have "\<dots> = ?c * (?c\<twosuperior> - 3 * ?s\<twosuperior>)"
  2513     by (simp add: algebra_simps power2_eq_square)
  2514   finally have "?c\<twosuperior> = (sqrt 3 / 2)\<twosuperior>"
  2515     using pos_c by (simp add: sin_squared_eq power_divide)
  2516   thus ?thesis
  2517     using pos_c [THEN order_less_imp_le]
  2518     by (rule power2_eq_imp_eq) simp
  2519 qed
  2520 
  2521 lemma sin_45: "sin (pi / 4) = sqrt 2 / 2"
  2522 by (simp add: sin_cos_eq cos_45)
  2523 
  2524 lemma sin_60: "sin (pi / 3) = sqrt 3 / 2"
  2525 by (simp add: sin_cos_eq cos_30)
  2526 
  2527 lemma cos_60: "cos (pi / 3) = 1 / 2"
  2528 apply (rule power2_eq_imp_eq)
  2529 apply (simp add: cos_squared_eq sin_60 power_divide)
  2530 apply (rule cos_ge_zero, rule order_trans [where y=0], simp_all)
  2531 done
  2532 
  2533 lemma sin_30: "sin (pi / 6) = 1 / 2"
  2534 by (simp add: sin_cos_eq cos_60)
  2535 
  2536 lemma tan_30: "tan (pi / 6) = 1 / sqrt 3"
  2537 unfolding tan_def by (simp add: sin_30 cos_30)
  2538 
  2539 lemma tan_45: "tan (pi / 4) = 1"
  2540 unfolding tan_def by (simp add: sin_45 cos_45)
  2541 
  2542 lemma tan_60: "tan (pi / 3) = sqrt 3"
  2543 unfolding tan_def by (simp add: sin_60 cos_60)
  2544 
  2545 lemma sin_cos_npi [simp]: "sin (real (Suc (2 * n)) * pi / 2) = (-1) ^ n"
  2546 proof -
  2547   have "sin ((real n + 1/2) * pi) = cos (real n * pi)"
  2548     by (auto simp add: algebra_simps sin_add)
  2549   thus ?thesis
  2550     by (simp add: real_of_nat_Suc distrib_right add_divide_distrib
  2551                   mult_commute [of pi])
  2552 qed
  2553 
  2554 lemma cos_2npi [simp]: "cos (2 * real (n::nat) * pi) = 1"
  2555 by (simp add: cos_double mult_assoc power_add [symmetric] numeral_2_eq_2)
  2556 
  2557 lemma cos_3over2_pi [simp]: "cos (3 / 2 * pi) = 0"
  2558 apply (subgoal_tac "cos (pi + pi/2) = 0", simp)
  2559 apply (subst cos_add, simp)
  2560 done
  2561 
  2562 lemma sin_2npi [simp]: "sin (2 * real (n::nat) * pi) = 0"
  2563 by (auto simp add: mult_assoc)
  2564 
  2565 lemma sin_3over2_pi [simp]: "sin (3 / 2 * pi) = - 1"
  2566 apply (subgoal_tac "sin (pi + pi/2) = - 1", simp)
  2567 apply (subst sin_add, simp)
  2568 done
  2569 
  2570 lemma cos_pi_eq_zero [simp]: "cos (pi * real (Suc (2 * m)) / 2) = 0"
  2571 by (simp only: cos_add sin_add real_of_nat_Suc distrib_right distrib_left add_divide_distrib, auto)
  2572 
  2573 lemma DERIV_cos_add [simp]: "DERIV (%x. cos (x + k)) xa :> - sin (xa + k)"
  2574   by (auto intro!: DERIV_intros)
  2575 
  2576 lemma sin_zero_abs_cos_one: "sin x = 0 ==> \<bar>cos x\<bar> = 1"
  2577 by (auto simp add: sin_zero_iff even_mult_two_ex)
  2578 
  2579 lemma cos_one_sin_zero: "cos x = 1 ==> sin x = 0"
  2580 by (cut_tac x = x in sin_cos_squared_add3, auto)
  2581 
  2582 subsection {* Machins formula *}
  2583 
  2584 lemma arctan_one: "arctan 1 = pi / 4"
  2585   by (rule arctan_unique, simp_all add: tan_45 m2pi_less_pi)
  2586 
  2587 lemma tan_total_pi4: assumes "\<bar>x\<bar> < 1"
  2588   shows "\<exists> z. - (pi / 4) < z \<and> z < pi / 4 \<and> tan z = x"
  2589 proof
  2590   show "- (pi / 4) < arctan x \<and> arctan x < pi / 4 \<and> tan (arctan x) = x"
  2591     unfolding arctan_one [symmetric] arctan_minus [symmetric]
  2592     unfolding arctan_less_iff using assms by auto
  2593 qed
  2594 
  2595 lemma arctan_add: assumes "\<bar>x\<bar> \<le> 1" and "\<bar>y\<bar> < 1"
  2596   shows "arctan x + arctan y = arctan ((x + y) / (1 - x * y))"
  2597 proof (rule arctan_unique [symmetric])
  2598   have "- (pi / 4) \<le> arctan x" and "- (pi / 4) < arctan y"
  2599     unfolding arctan_one [symmetric] arctan_minus [symmetric]
  2600     unfolding arctan_le_iff arctan_less_iff using assms by auto
  2601   from add_le_less_mono [OF this]
  2602   show 1: "- (pi / 2) < arctan x + arctan y" by simp
  2603   have "arctan x \<le> pi / 4" and "arctan y < pi / 4"
  2604     unfolding arctan_one [symmetric]
  2605     unfolding arctan_le_iff arctan_less_iff using assms by auto
  2606   from add_le_less_mono [OF this]
  2607   show 2: "arctan x + arctan y < pi / 2" by simp
  2608   show "tan (arctan x + arctan y) = (x + y) / (1 - x * y)"
  2609     using cos_gt_zero_pi [OF 1 2] by (simp add: tan_add)
  2610 qed
  2611 
  2612 theorem machin: "pi / 4 = 4 * arctan (1/5) - arctan (1 / 239)"
  2613 proof -
  2614   have "\<bar>1 / 5\<bar> < (1 :: real)" by auto
  2615   from arctan_add[OF less_imp_le[OF this] this]
  2616   have "2 * arctan (1 / 5) = arctan (5 / 12)" by auto
  2617   moreover
  2618   have "\<bar>5 / 12\<bar> < (1 :: real)" by auto
  2619   from arctan_add[OF less_imp_le[OF this] this]
  2620   have "2 * arctan (5 / 12) = arctan (120 / 119)" by auto
  2621   moreover
  2622   have "\<bar>1\<bar> \<le> (1::real)" and "\<bar>1 / 239\<bar> < (1::real)" by auto
  2623   from arctan_add[OF this]
  2624   have "arctan 1 + arctan (1 / 239) = arctan (120 / 119)" by auto
  2625   ultimately have "arctan 1 + arctan (1 / 239) = 4 * arctan (1 / 5)" by auto
  2626   thus ?thesis unfolding arctan_one by algebra
  2627 qed
  2628 
  2629 subsection {* Introducing the arcus tangens power series *}
  2630 
  2631 lemma monoseq_arctan_series: fixes x :: real
  2632   assumes "\<bar>x\<bar> \<le> 1" shows "monoseq (\<lambda> n. 1 / real (n*2+1) * x^(n*2+1))" (is "monoseq ?a")
  2633 proof (cases "x = 0") case True thus ?thesis unfolding monoseq_def One_nat_def by auto
  2634 next
  2635   case False
  2636   have "norm x \<le> 1" and "x \<le> 1" and "-1 \<le> x" using assms by auto
  2637   show "monoseq ?a"
  2638   proof -
  2639     { fix n fix x :: real assume "0 \<le> x" and "x \<le> 1"
  2640       have "1 / real (Suc (Suc n * 2)) * x ^ Suc (Suc n * 2) \<le> 1 / real (Suc (n * 2)) * x ^ Suc (n * 2)"
  2641       proof (rule mult_mono)
  2642         show "1 / real (Suc (Suc n * 2)) \<le> 1 / real (Suc (n * 2))" by (rule frac_le) simp_all
  2643         show "0 \<le> 1 / real (Suc (n * 2))" by auto
  2644         show "x ^ Suc (Suc n * 2) \<le> x ^ Suc (n * 2)" by (rule power_decreasing) (simp_all add: `0 \<le> x` `x \<le> 1`)
  2645         show "0 \<le> x ^ Suc (Suc n * 2)" by (rule zero_le_power) (simp add: `0 \<le> x`)
  2646       qed
  2647     } note mono = this
  2648 
  2649     show ?thesis
  2650     proof (cases "0 \<le> x")
  2651       case True from mono[OF this `x \<le> 1`, THEN allI]
  2652       show ?thesis unfolding Suc_eq_plus1[symmetric] by (rule mono_SucI2)
  2653     next
  2654       case False hence "0 \<le> -x" and "-x \<le> 1" using `-1 \<le> x` by auto
  2655       from mono[OF this]
  2656       have "\<And>n. 1 / real (Suc (Suc n * 2)) * x ^ Suc (Suc n * 2) \<ge> 1 / real (Suc (n * 2)) * x ^ Suc (n * 2)" using `0 \<le> -x` by auto
  2657       thus ?thesis unfolding Suc_eq_plus1[symmetric] by (rule mono_SucI1[OF allI])
  2658     qed
  2659   qed
  2660 qed
  2661 
  2662 lemma zeroseq_arctan_series: fixes x :: real
  2663   assumes "\<bar>x\<bar> \<le> 1" shows "(\<lambda> n. 1 / real (n*2+1) * x^(n*2+1)) ----> 0" (is "?a ----> 0")
  2664 proof (cases "x = 0") case True thus ?thesis unfolding One_nat_def by (auto simp add: tendsto_const)
  2665 next
  2666   case False
  2667   have "norm x \<le> 1" and "x \<le> 1" and "-1 \<le> x" using assms by auto
  2668   show "?a ----> 0"
  2669   proof (cases "\<bar>x\<bar> < 1")
  2670     case True hence "norm x < 1" by auto
  2671     from tendsto_mult[OF LIMSEQ_inverse_real_of_nat LIMSEQ_power_zero[OF `norm x < 1`, THEN LIMSEQ_Suc]]
  2672     have "(\<lambda>n. 1 / real (n + 1) * x ^ (n + 1)) ----> 0"
  2673       unfolding inverse_eq_divide Suc_eq_plus1 by simp
  2674     then show ?thesis using pos2 by (rule LIMSEQ_linear)
  2675   next
  2676     case False hence "x = -1 \<or> x = 1" using `\<bar>x\<bar> \<le> 1` by auto
  2677     hence n_eq: "\<And> n. x ^ (n * 2 + 1) = x" unfolding One_nat_def by auto
  2678     from tendsto_mult[OF LIMSEQ_inverse_real_of_nat[THEN LIMSEQ_linear, OF pos2, unfolded inverse_eq_divide] tendsto_const[of x]]
  2679     show ?thesis unfolding n_eq Suc_eq_plus1 by auto
  2680   qed
  2681 qed
  2682 
  2683 lemma summable_arctan_series: fixes x :: real and n :: nat
  2684   assumes "\<bar>x\<bar> \<le> 1" shows "summable (\<lambda> k. (-1)^k * (1 / real (k*2+1) * x ^ (k*2+1)))" (is "summable (?c x)")
  2685   by (rule summable_Leibniz(1), rule zeroseq_arctan_series[OF assms], rule monoseq_arctan_series[OF assms])
  2686 
  2687 lemma less_one_imp_sqr_less_one: fixes x :: real assumes "\<bar>x\<bar> < 1" shows "x^2 < 1"
  2688 proof -
  2689   from mult_left_mono[OF less_imp_le[OF `\<bar>x\<bar> < 1`] abs_ge_zero[of x]]
  2690   have "\<bar> x^2 \<bar> < 1" using `\<bar> x \<bar> < 1` unfolding numeral_2_eq_2 power_Suc2 by auto
  2691   thus ?thesis using zero_le_power2 by auto
  2692 qed
  2693 
  2694 lemma DERIV_arctan_series: assumes "\<bar> x \<bar> < 1"
  2695   shows "DERIV (\<lambda> x'. \<Sum> k. (-1)^k * (1 / real (k*2+1) * x' ^ (k*2+1))) x :> (\<Sum> k. (-1)^k * x^(k*2))" (is "DERIV ?arctan _ :> ?Int")
  2696 proof -
  2697   let "?f n" = "if even n then (-1)^(n div 2) * 1 / real (Suc n) else 0"
  2698 
  2699   { fix n :: nat assume "even n" hence "2 * (n div 2) = n" by presburger } note n_even=this
  2700   have if_eq: "\<And> n x'. ?f n * real (Suc n) * x'^n = (if even n then (-1)^(n div 2) * x'^(2 * (n div 2)) else 0)" using n_even by auto
  2701 
  2702   { fix x :: real assume "\<bar>x\<bar> < 1" hence "x^2 < 1" by (rule less_one_imp_sqr_less_one)
  2703     have "summable (\<lambda> n. -1 ^ n * (x^2) ^n)"
  2704       by (rule summable_Leibniz(1), auto intro!: LIMSEQ_realpow_zero monoseq_realpow `x^2 < 1` order_less_imp_le[OF `x^2 < 1`])
  2705     hence "summable (\<lambda> n. -1 ^ n * x^(2*n))" unfolding power_mult .
  2706   } note summable_Integral = this
  2707 
  2708   { fix f :: "nat \<Rightarrow> real"
  2709     have "\<And> x. f sums x = (\<lambda> n. if even n then f (n div 2) else 0) sums x"
  2710     proof
  2711       fix x :: real assume "f sums x"
  2712       from sums_if[OF sums_zero this]
  2713       show "(\<lambda> n. if even n then f (n div 2) else 0) sums x" by auto
  2714     next
  2715       fix x :: real assume "(\<lambda> n. if even n then f (n div 2) else 0) sums x"
  2716       from LIMSEQ_linear[OF this[unfolded sums_def] pos2, unfolded sum_split_even_odd[unfolded mult_commute]]
  2717       show "f sums x" unfolding sums_def by auto
  2718     qed
  2719     hence "op sums f = op sums (\<lambda> n. if even n then f (n div 2) else 0)" ..
  2720   } note sums_even = this
  2721 
  2722   have Int_eq: "(\<Sum> n. ?f n * real (Suc n) * x^n) = ?Int" unfolding if_eq mult_commute[of _ 2] suminf_def sums_even[of "\<lambda> n. -1 ^ n * x ^ (2 * n)", symmetric]
  2723     by auto
  2724 
  2725   { fix x :: real
  2726     have if_eq': "\<And> n. (if even n then -1 ^ (n div 2) * 1 / real (Suc n) else 0) * x ^ Suc n =
  2727       (if even n then -1 ^ (n div 2) * (1 / real (Suc (2 * (n div 2))) * x ^ Suc (2 * (n div 2))) else 0)"
  2728       using n_even by auto
  2729     have idx_eq: "\<And> n. n * 2 + 1 = Suc (2 * n)" by auto
  2730     have "(\<Sum> n. ?f n * x^(Suc n)) = ?arctan x" unfolding if_eq' idx_eq suminf_def sums_even[of "\<lambda> n. -1 ^ n * (1 / real (Suc (2 * n)) * x ^ Suc (2 * n))", symmetric]
  2731       by auto
  2732   } note arctan_eq = this
  2733 
  2734   have "DERIV (\<lambda> x. \<Sum> n. ?f n * x^(Suc n)) x :> (\<Sum> n. ?f n * real (Suc n) * x^n)"
  2735   proof (rule DERIV_power_series')
  2736     show "x \<in> {- 1 <..< 1}" using `\<bar> x \<bar> < 1` by auto
  2737     { fix x' :: real assume x'_bounds: "x' \<in> {- 1 <..< 1}"
  2738       hence "\<bar>x'\<bar> < 1" by auto
  2739 
  2740       let ?S = "\<Sum> n. (-1)^n * x'^(2 * n)"
  2741       show "summable (\<lambda> n. ?f n * real (Suc n) * x'^n)" unfolding if_eq
  2742         by (rule sums_summable[where l="0 + ?S"], rule sums_if, rule sums_zero, rule summable_sums, rule summable_Integral[OF `\<bar>x'\<bar> < 1`])
  2743     }
  2744   qed auto
  2745   thus ?thesis unfolding Int_eq arctan_eq .
  2746 qed
  2747 
  2748 lemma arctan_series: assumes "\<bar> x \<bar> \<le> 1"
  2749   shows "arctan x = (\<Sum> k. (-1)^k * (1 / real (k*2+1) * x ^ (k*2+1)))" (is "_ = suminf (\<lambda> n. ?c x n)")
  2750 proof -
  2751   let "?c' x n" = "(-1)^n * x^(n*2)"
  2752 
  2753   { fix r x :: real assume "0 < r" and "r < 1" and "\<bar> x \<bar> < r"
  2754     have "\<bar>x\<bar> < 1" using `r < 1` and `\<bar>x\<bar> < r` by auto
  2755     from DERIV_arctan_series[OF this]
  2756     have "DERIV (\<lambda> x. suminf (?c x)) x :> (suminf (?c' x))" .
  2757   } note DERIV_arctan_suminf = this
  2758 
  2759   { fix x :: real assume "\<bar>x\<bar> \<le> 1" note summable_Leibniz[OF zeroseq_arctan_series[OF this] monoseq_arctan_series[OF this]] }
  2760   note arctan_series_borders = this
  2761 
  2762   { fix x :: real assume "\<bar>x\<bar> < 1" have "arctan x = (\<Sum> k. ?c x k)"
  2763   proof -
  2764     obtain r where "\<bar>x\<bar> < r" and "r < 1" using dense[OF `\<bar>x\<bar> < 1`] by blast
  2765     hence "0 < r" and "-r < x" and "x < r" by auto
  2766 
  2767     have suminf_eq_arctan_bounded: "\<And> x a b. \<lbrakk> -r < a ; b < r ; a < b ; a \<le> x ; x \<le> b \<rbrakk> \<Longrightarrow> suminf (?c x) - arctan x = suminf (?c a) - arctan a"
  2768     proof -
  2769       fix x a b assume "-r < a" and "b < r" and "a < b" and "a \<le> x" and "x \<le> b"
  2770       hence "\<bar>x\<bar> < r" by auto
  2771       show "suminf (?c x) - arctan x = suminf (?c a) - arctan a"
  2772       proof (rule DERIV_isconst2[of "a" "b"])
  2773         show "a < b" and "a \<le> x" and "x \<le> b" using `a < b` `a \<le> x` `x \<le> b` by auto
  2774         have "\<forall> x. -r < x \<and> x < r \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) x :> 0"
  2775         proof (rule allI, rule impI)
  2776           fix x assume "-r < x \<and> x < r" hence "\<bar>x\<bar> < r" by auto
  2777           hence "\<bar>x\<bar> < 1" using `r < 1` by auto
  2778           have "\<bar> - (x^2) \<bar> < 1" using less_one_imp_sqr_less_one[OF `\<bar>x\<bar> < 1`] by auto
  2779           hence "(\<lambda> n. (- (x^2)) ^ n) sums (1 / (1 - (- (x^2))))" unfolding real_norm_def[symmetric] by (rule geometric_sums)
  2780           hence "(?c' x) sums (1 / (1 - (- (x^2))))" unfolding power_mult_distrib[symmetric] power_mult nat_mult_commute[of _ 2] by auto
  2781           hence suminf_c'_eq_geom: "inverse (1 + x^2) = suminf (?c' x)" using sums_unique unfolding inverse_eq_divide by auto
  2782           have "DERIV (\<lambda> x. suminf (?c x)) x :> (inverse (1 + x^2))" unfolding suminf_c'_eq_geom
  2783             by (rule DERIV_arctan_suminf[OF `0 < r` `r < 1` `\<bar>x\<bar> < r`])
  2784           from DERIV_add_minus[OF this DERIV_arctan]
  2785           show "DERIV (\<lambda> x. suminf (?c x) - arctan x) x :> 0" unfolding diff_minus by auto
  2786         qed
  2787         hence DERIV_in_rball: "\<forall> y. a \<le> y \<and> y \<le> b \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) y :> 0" using `-r < a` `b < r` by auto
  2788         thus "\<forall> y. a < y \<and> y < b \<longrightarrow> DERIV (\<lambda> x. suminf (?c x) - arctan x) y :> 0" using `\<bar>x\<bar> < r` by auto
  2789         show "\<forall> y. a \<le> y \<and> y \<le> b \<longrightarrow> isCont (\<lambda> x. suminf (?c x) - arctan x) y" using DERIV_in_rball DERIV_isCont by auto
  2790       qed
  2791     qed
  2792 
  2793     have suminf_arctan_zero: "suminf (?c 0) - arctan 0 = 0"
  2794       unfolding Suc_eq_plus1[symmetric] power_Suc2 mult_zero_right arctan_zero_zero suminf_zero by auto
  2795 
  2796     have "suminf (?c x) - arctan x = 0"
  2797     proof (cases "x = 0")
  2798       case True thus ?thesis using suminf_arctan_zero by auto
  2799     next
  2800       case False hence "0 < \<bar>x\<bar>" and "- \<bar>x\<bar> < \<bar>x\<bar>" by auto
  2801       have "suminf (?c (-\<bar>x\<bar>)) - arctan (-\<bar>x\<bar>) = suminf (?c 0) - arctan 0"
  2802         by (rule suminf_eq_arctan_bounded[where x="0" and a="-\<bar>x\<bar>" and b="\<bar>x\<bar>", symmetric])
  2803           (simp_all only: `\<bar>x\<bar> < r` `-\<bar>x\<bar> < \<bar>x\<bar>` neg_less_iff_less)
  2804       moreover
  2805       have "suminf (?c x) - arctan x = suminf (?c (-\<bar>x\<bar>)) - arctan (-\<bar>x\<bar>)"
  2806         by (rule suminf_eq_arctan_bounded[where x="x" and a="-\<bar>x\<bar>" and b="\<bar>x\<bar>"])
  2807           (simp_all only: `\<bar>x\<bar> < r` `-\<bar>x\<bar> < \<bar>x\<bar>` neg_less_iff_less)
  2808       ultimately
  2809       show ?thesis using suminf_arctan_zero by auto
  2810     qed
  2811     thus ?thesis by auto
  2812   qed } note when_less_one = this
  2813 
  2814   show "arctan x = suminf (\<lambda> n. ?c x n)"
  2815   proof (cases "\<bar>x\<bar> < 1")
  2816     case True thus ?thesis by (rule when_less_one)
  2817   next case False hence "\<bar>x\<bar> = 1" using `\<bar>x\<bar> \<le> 1` by auto
  2818     let "?a x n" = "\<bar>1 / real (n*2+1) * x^(n*2+1)\<bar>"
  2819     let "?diff x n" = "\<bar> arctan x - (\<Sum> i = 0..<n. ?c x i)\<bar>"
  2820     { fix n :: nat
  2821       have "0 < (1 :: real)" by auto
  2822       moreover
  2823       { fix x :: real assume "0 < x" and "x < 1" hence "\<bar>x\<bar> \<le> 1" and "\<bar>x\<bar> < 1" by auto
  2824         from `0 < x` have "0 < 1 / real (0 * 2 + (1::nat)) * x ^ (0 * 2 + 1)" by auto
  2825         note bounds = mp[OF arctan_series_borders(2)[OF `\<bar>x\<bar> \<le> 1`] this, unfolded when_less_one[OF `\<bar>x\<bar> < 1`, symmetric], THEN spec]
  2826         have "0 < 1 / real (n*2+1) * x^(n*2+1)" by (rule mult_pos_pos, auto simp only: zero_less_power[OF `0 < x`], auto)
  2827         hence a_pos: "?a x n = 1 / real (n*2+1) * x^(n*2+1)" by (rule abs_of_pos)
  2828         have "?diff x n \<le> ?a x n"
  2829         proof (cases "even n")
  2830           case True hence sgn_pos: "(-1)^n = (1::real)" by auto
  2831           from `even n` obtain m where "2 * m = n" unfolding even_mult_two_ex by auto
  2832           from bounds[of m, unfolded this atLeastAtMost_iff]
  2833           have "\<bar>arctan x - (\<Sum>i = 0..<n. (?c x i))\<bar> \<le> (\<Sum>i = 0..<n + 1. (?c x i)) - (\<Sum>i = 0..<n. (?c x i))" by auto
  2834           also have "\<dots> = ?c x n" unfolding One_nat_def by auto
  2835           also have "\<dots> = ?a x n" unfolding sgn_pos a_pos by auto
  2836           finally show ?thesis .
  2837         next
  2838           case False hence sgn_neg: "(-1)^n = (-1::real)" by auto
  2839           from `odd n` obtain m where m_def: "2 * m + 1 = n" unfolding odd_Suc_mult_two_ex by auto
  2840           hence m_plus: "2 * (m + 1) = n + 1" by auto
  2841           from bounds[of "m + 1", unfolded this atLeastAtMost_iff, THEN conjunct1] bounds[of m, unfolded m_def atLeastAtMost_iff, THEN conjunct2]
  2842           have "\<bar>arctan x - (\<Sum>i = 0..<n. (?c x i))\<bar> \<le> (\<Sum>i = 0..<n. (?c x i)) - (\<Sum>i = 0..<n+1. (?c x i))" by auto
  2843           also have "\<dots> = - ?c x n" unfolding One_nat_def by auto
  2844           also have "\<dots> = ?a x n" unfolding sgn_neg a_pos by auto
  2845           finally show ?thesis .
  2846         qed
  2847         hence "0 \<le> ?a x n - ?diff x n" by auto
  2848       }
  2849       hence "\<forall> x \<in> { 0 <..< 1 }. 0 \<le> ?a x n - ?diff x n" by auto
  2850       moreover have "\<And>x. isCont (\<lambda> x. ?a x n - ?diff x n) x"
  2851         unfolding diff_minus divide_inverse
  2852         by (auto intro!: isCont_add isCont_rabs isCont_ident isCont_minus isCont_arctan isCont_inverse isCont_mult isCont_power isCont_const isCont_setsum)
  2853       ultimately have "0 \<le> ?a 1 n - ?diff 1 n" by (rule LIM_less_bound)
  2854       hence "?diff 1 n \<le> ?a 1 n" by auto
  2855     }
  2856     have "?a 1 ----> 0"
  2857       unfolding tendsto_rabs_zero_iff power_one divide_inverse One_nat_def
  2858       by (auto intro!: tendsto_mult LIMSEQ_linear LIMSEQ_inverse_real_of_nat)
  2859     have "?diff 1 ----> 0"
  2860     proof (rule LIMSEQ_I)
  2861       fix r :: real assume "0 < r"
  2862       obtain N :: nat where N_I: "\<And> n. N \<le> n \<Longrightarrow> ?a 1 n < r" using LIMSEQ_D[OF `?a 1 ----> 0` `0 < r`] by auto
  2863       { fix n assume "N \<le> n" from `?diff 1 n \<le> ?a 1 n` N_I[OF this]
  2864         have "norm (?diff 1 n - 0) < r" by auto }
  2865       thus "\<exists> N. \<forall> n \<ge> N. norm (?diff 1 n - 0) < r" by blast
  2866     qed
  2867     from this [unfolded tendsto_rabs_zero_iff, THEN tendsto_add [OF _ tendsto_const], of "- arctan 1", THEN tendsto_minus]
  2868     have "(?c 1) sums (arctan 1)" unfolding sums_def by auto
  2869     hence "arctan 1 = (\<Sum> i. ?c 1 i)" by (rule sums_unique)
  2870 
  2871     show ?thesis
  2872     proof (cases "x = 1", simp add: `arctan 1 = (\<Sum> i. ?c 1 i)`)
  2873       assume "x \<noteq> 1" hence "x = -1" using `\<bar>x\<bar> = 1` by auto
  2874 
  2875       have "- (pi / 2) < 0" using pi_gt_zero by auto
  2876       have "- (2 * pi) < 0" using pi_gt_zero by auto
  2877 
  2878       have c_minus_minus: "\<And> i. ?c (- 1) i = - ?c 1 i" unfolding One_nat_def by auto
  2879 
  2880       have "arctan (- 1) = arctan (tan (-(pi / 4)))" unfolding tan_45 tan_minus ..
  2881       also have "\<dots> = - (pi / 4)" by (rule arctan_tan, auto simp add: order_less_trans[OF `- (pi / 2) < 0` pi_gt_zero])
  2882       also have "\<dots> = - (arctan (tan (pi / 4)))" unfolding neg_equal_iff_equal by (rule arctan_tan[symmetric], auto simp add: order_less_trans[OF `- (2 * pi) < 0` pi_gt_zero])
  2883       also have "\<dots> = - (arctan 1)" unfolding tan_45 ..
  2884       also have "\<dots> = - (\<Sum> i. ?c 1 i)" using `arctan 1 = (\<Sum> i. ?c 1 i)` by auto
  2885       also have "\<dots> = (\<Sum> i. ?c (- 1) i)" using suminf_minus[OF sums_summable[OF `(?c 1) sums (arctan 1)`]] unfolding c_minus_minus by auto
  2886       finally show ?thesis using `x = -1` by auto
  2887     qed
  2888   qed
  2889 qed
  2890 
  2891 lemma arctan_half: fixes x :: real
  2892   shows "arctan x = 2 * arctan (x / (1 + sqrt(1 + x^2)))"
  2893 proof -
  2894   obtain y where low: "- (pi / 2) < y" and high: "y < pi / 2" and y_eq: "tan y = x" using tan_total by blast
  2895   hence low2: "- (pi / 2) < y / 2" and high2: "y / 2 < pi / 2" by auto
  2896 
  2897   have divide_nonzero_divide: "\<And> A B C :: real. C \<noteq> 0 \<Longrightarrow> A / B = (A / C) / (B / C)" by auto
  2898 
  2899   have "0 < cos y" using cos_gt_zero_pi[OF low high] .
  2900   hence "cos y \<noteq> 0" and cos_sqrt: "sqrt ((cos y) ^ 2) = cos y" by auto
  2901 
  2902   have "1 + (tan y)^2 = 1 + sin y^2 / cos y^2" unfolding tan_def power_divide ..
  2903   also have "\<dots> = cos y^2 / cos y^2 + sin y^2 / cos y^2" using `cos y \<noteq> 0` by auto
  2904   also have "\<dots> = 1 / cos y^2" unfolding add_divide_distrib[symmetric] sin_cos_squared_add2 ..
  2905   finally have "1 + (tan y)^2 = 1 / cos y^2" .
  2906 
  2907   have "sin y / (cos y + 1) = tan y / ((cos y + 1) / cos y)" unfolding tan_def divide_nonzero_divide[OF `cos y \<noteq> 0`, symmetric] ..
  2908   also have "\<dots> = tan y / (1 + 1 / cos y)" using `cos y \<noteq> 0` unfolding add_divide_distrib by auto
  2909   also have "\<dots> = tan y / (1 + 1 / sqrt(cos y^2))" unfolding cos_sqrt ..
  2910   also have "\<dots> = tan y / (1 + sqrt(1 / cos y^2))" unfolding real_sqrt_divide by auto
  2911   finally have eq: "sin y / (cos y + 1) = tan y / (1 + sqrt(1 + (tan y)^2))" unfolding `1 + (tan y)^2 = 1 / cos y^2` .
  2912 
  2913   have "arctan x = y" using arctan_tan low high y_eq by auto
  2914   also have "\<dots> = 2 * (arctan (tan (y/2)))" using arctan_tan[OF low2 high2] by auto
  2915   also have "\<dots> = 2 * (arctan (sin y / (cos y + 1)))" unfolding tan_half by auto
  2916   finally show ?thesis unfolding eq `tan y = x` .
  2917 qed
  2918 
  2919 lemma arctan_monotone: assumes "x < y"
  2920   shows "arctan x < arctan y"
  2921   using assms by (simp only: arctan_less_iff)
  2922 
  2923 lemma arctan_monotone': assumes "x \<le> y" shows "arctan x \<le> arctan y"
  2924   using assms by (simp only: arctan_le_iff)
  2925 
  2926 lemma arctan_inverse:
  2927   assumes "x \<noteq> 0" shows "arctan (1 / x) = sgn x * pi / 2 - arctan x"
  2928 proof (rule arctan_unique)
  2929   show "- (pi / 2) < sgn x * pi / 2 - arctan x"
  2930     using arctan_bounded [of x] assms
  2931     unfolding sgn_real_def
  2932     apply (auto simp add: algebra_simps)
  2933     apply (drule zero_less_arctan_iff [THEN iffD2])
  2934     apply arith
  2935     done
  2936   show "sgn x * pi / 2 - arctan x < pi / 2"
  2937     using arctan_bounded [of "- x"] assms
  2938     unfolding sgn_real_def arctan_minus
  2939     by auto
  2940   show "tan (sgn x * pi / 2 - arctan x) = 1 / x"
  2941     unfolding tan_inverse [of "arctan x", unfolded tan_arctan]
  2942     unfolding sgn_real_def
  2943     by (simp add: tan_def cos_arctan sin_arctan sin_diff cos_diff)
  2944 qed
  2945 
  2946 theorem pi_series: "pi / 4 = (\<Sum> k. (-1)^k * 1 / real (k*2+1))" (is "_ = ?SUM")
  2947 proof -
  2948   have "pi / 4 = arctan 1" using arctan_one by auto
  2949   also have "\<dots> = ?SUM" using arctan_series[of 1] by auto
  2950   finally show ?thesis by auto
  2951 qed
  2952 
  2953 subsection {* Existence of Polar Coordinates *}
  2954 
  2955 lemma cos_x_y_le_one: "\<bar>x / sqrt (x\<twosuperior> + y\<twosuperior>)\<bar> \<le> 1"
  2956 apply (rule power2_le_imp_le [OF _ zero_le_one])
  2957 apply (simp add: power_divide divide_le_eq not_sum_power2_lt_zero)
  2958 done
  2959 
  2960 lemma cos_arccos_abs: "\<bar>y\<bar> \<le> 1 \<Longrightarrow> cos (arccos y) = y"
  2961 by (simp add: abs_le_iff)
  2962 
  2963 lemma sin_arccos_abs: "\<bar>y\<bar> \<le> 1 \<Longrightarrow> sin (arccos y) = sqrt (1 - y\<twosuperior>)"
  2964 by (simp add: sin_arccos abs_le_iff)
  2965 
  2966 lemmas cos_arccos_lemma1 = cos_arccos_abs [OF cos_x_y_le_one]
  2967 
  2968 lemmas sin_arccos_lemma1 = sin_arccos_abs [OF cos_x_y_le_one]
  2969 
  2970 lemma polar_ex1:
  2971      "0 < y ==> \<exists>r a. x = r * cos a & y = r * sin a"
  2972 apply (rule_tac x = "sqrt (x\<twosuperior> + y\<twosuperior>)" in exI)
  2973 apply (rule_tac x = "arccos (x / sqrt (x\<twosuperior> + y\<twosuperior>))" in exI)
  2974 apply (simp add: cos_arccos_lemma1)
  2975 apply (simp add: sin_arccos_lemma1)
  2976 apply (simp add: power_divide)
  2977 apply (simp add: real_sqrt_mult [symmetric])
  2978 apply (simp add: right_diff_distrib)
  2979 done
  2980 
  2981 lemma polar_ex2:
  2982      "y < 0 ==> \<exists>r a. x = r * cos a & y = r * sin a"
  2983 apply (insert polar_ex1 [where x=x and y="-y"], simp, clarify)
  2984 apply (metis cos_minus minus_minus minus_mult_right sin_minus)
  2985 done
  2986 
  2987 lemma polar_Ex: "\<exists>r a. x = r * cos a & y = r * sin a"
  2988 apply (rule_tac x=0 and y=y in linorder_cases)
  2989 apply (erule polar_ex1)
  2990 apply (rule_tac x=x in exI, rule_tac x=0 in exI, simp)
  2991 apply (erule polar_ex2)
  2992 done
  2993 
  2994 end