src/Pure/Isar/isar_output.ML
author haftmann
Fri Nov 10 07:44:47 2006 +0100 (2006-11-10)
changeset 21286 b5e7b80caa6a
parent 20966 75c8a52f8447
child 21309 367f4512e65c
permissions -rw-r--r--
introduces canonical AList functions for loop_tacs
     1 (*  Title:      Pure/Isar/isar_output.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Isar theory output.
     6 *)
     7 
     8 signature ISAR_OUTPUT =
     9 sig
    10   val display: bool ref
    11   val quotes: bool ref
    12   val indent: int ref
    13   val source: bool ref
    14   val add_commands: (string * (Args.src -> Toplevel.node option -> string)) list -> unit
    15   val add_options: (string * (string -> (unit -> string) -> unit -> string)) list -> unit
    16   val print_antiquotations: unit -> unit
    17   val boolean: string -> bool
    18   val integer: string -> int
    19   val args: (Context.generic * Args.T list -> 'a * (Context.generic * Args.T list)) ->
    20     (Args.src -> Proof.context -> 'a -> string) -> Args.src -> Toplevel.node option -> string
    21   datatype markup = Markup | MarkupEnv | Verbatim
    22   val modes: string list ref
    23   val eval_antiquote: Scan.lexicon -> Toplevel.node option -> string * Position.T -> string
    24   val present_thy: Scan.lexicon -> (string -> string list) -> (markup -> string -> bool) ->
    25     Toplevel.transition list -> (OuterLex.token, 'a) Source.source -> Buffer.T
    26   val output_list: (Proof.context -> 'a -> Pretty.T) -> Args.src ->
    27     Proof.context -> 'a list -> string
    28   val output: (Proof.context -> 'a -> Pretty.T) -> Args.src -> Proof.context -> 'a -> string
    29 end;
    30 
    31 structure IsarOutput: ISAR_OUTPUT =
    32 struct
    33 
    34 structure T = OuterLex;
    35 structure P = OuterParse;
    36 
    37 
    38 (** global options **)
    39 
    40 val locale = ref "";
    41 val display = ref false;
    42 val quotes = ref false;
    43 val indent = ref 0;
    44 val source = ref false;
    45 val break = ref false;
    46 
    47 
    48 
    49 (** maintain global commands **)
    50 
    51 local
    52 
    53 val global_commands =
    54   ref (Symtab.empty: (Args.src -> Toplevel.node option -> string) Symtab.table);
    55 
    56 val global_options =
    57   ref (Symtab.empty: (string -> (unit -> string) -> unit -> string) Symtab.table);
    58 
    59 fun add_item kind (name, x) tab =
    60  (if not (Symtab.defined tab name) then ()
    61   else warning ("Redefined antiquotation " ^ kind ^ ": " ^ quote name);
    62   Symtab.update (name, x) tab);
    63 
    64 in
    65 
    66 val add_commands = Library.change global_commands o fold (add_item "command");
    67 val add_options = Library.change global_options o fold (add_item "option");
    68 
    69 fun command src =
    70   let val ((name, _), pos) = Args.dest_src src in
    71     (case Symtab.lookup (! global_commands) name of
    72       NONE => error ("Unknown antiquotation command: " ^ quote name ^ Position.str_of pos)
    73     | SOME f => transform_failure (curry Antiquote.ANTIQUOTE_FAIL (name, pos)) (f src))
    74   end;
    75 
    76 fun option (name, s) f () =
    77   (case Symtab.lookup (! global_options) name of
    78     NONE => error ("Unknown antiquotation option: " ^ quote name)
    79   | SOME opt => opt s f ());
    80 
    81 fun options [] f = f
    82   | options (opt :: opts) f = option opt (options opts f);
    83 
    84 
    85 fun print_antiquotations () =
    86  [Pretty.big_list "antiquotation commands:" (map Pretty.str (Symtab.keys (! global_commands))),
    87   Pretty.big_list "antiquotation options:" (map Pretty.str (Symtab.keys (! global_options)))]
    88  |> Pretty.chunks |> Pretty.writeln;
    89 
    90 end;
    91 
    92 
    93 
    94 (** syntax of antiquotations **)
    95 
    96 (* option values *)
    97 
    98 fun boolean "" = true
    99   | boolean "true" = true
   100   | boolean "false" = false
   101   | boolean s = error ("Bad boolean value: " ^ quote s);
   102 
   103 fun integer s =
   104   let
   105     fun int ss =
   106       (case Library.read_int ss of (i, []) => i
   107       | _ => error ("Bad integer value: " ^ quote s));
   108   in (case Symbol.explode s of "-" :: ss => ~ (int ss) | ss => int ss) end;
   109 
   110 
   111 (* args syntax *)
   112 
   113 fun syntax scan = Args.context_syntax "antiquotation" scan;
   114 
   115 fun args scan f src node : string =
   116   let
   117     val loc = if ! locale = "" then NONE else SOME (! locale);
   118     val (ctxt, x) = syntax scan src (Toplevel.presentation_context node loc);
   119   in f src ctxt x end;
   120 
   121 
   122 (* outer syntax *)
   123 
   124 local
   125 
   126 val property = P.xname -- Scan.optional (P.$$$ "=" |-- P.!!! P.xname) "";
   127 val properties = Scan.optional (P.$$$ "[" |-- P.!!! (P.enum "," property --| P.$$$ "]")) [];
   128 
   129 val antiq = P.position P.xname -- properties -- P.arguments --| Scan.ahead P.eof
   130   >> (fn (((x, pos), y), z) => (y, Args.src ((x, z), pos)));
   131 
   132 fun antiq_args_aux keyword_lexicon (str, pos) =
   133   Source.of_string str
   134   |> Symbol.source false
   135   |> T.source false (K (keyword_lexicon, Scan.empty_lexicon)) pos
   136   |> T.source_proper
   137   |> Source.source T.stopper (Scan.error (Scan.bulk (P.!!! antiq))) NONE
   138   |> Source.exhaust;
   139 
   140 in
   141 
   142 fun antiq_args lex (s, pos) =
   143   let
   144     fun err msg = cat_error msg
   145       ("Malformed antiquotation: " ^ quote ("@{" ^ s ^ "}") ^ Position.str_of pos);
   146   in (case antiq_args_aux lex (s, pos) of [x] => x | _ => err "") handle ERROR msg => err msg end;
   147 
   148 end;
   149 
   150 
   151 (* eval_antiquote *)
   152 
   153 val modes = ref ([]: string list);
   154 
   155 fun eval_antiquote lex node (str, pos) =
   156   let
   157     fun expand (Antiquote.Text s) = s
   158       | expand (Antiquote.Antiq x) =
   159           let val (opts, src) = antiq_args lex x in
   160             options opts (fn () => command src node) ();  (*preview errors!*)
   161             Library.setmp print_mode (! modes @ Latex.modes @ ! print_mode)
   162               (Output.no_warnings (options opts (fn () => command src node))) ()
   163           end;
   164     val ants = Antiquote.antiquotes_of (str, pos);
   165   in
   166     if is_none node andalso exists Antiquote.is_antiq ants then
   167       error ("Cannot expand antiquotations at top-level" ^ Position.str_of pos)
   168     else implode (map expand ants)
   169   end;
   170 
   171 
   172 
   173 (** present theory source **)
   174 
   175 (* presentation tokens *)
   176 
   177 datatype token =
   178     NoToken
   179   | BasicToken of T.token
   180   | MarkupToken of string * (string * Position.T)
   181   | MarkupEnvToken of string * (string * Position.T)
   182   | VerbatimToken of string * Position.T;
   183 
   184 fun output_token lex state =
   185   let
   186     val eval = eval_antiquote lex (try Toplevel.node_of state)
   187   in
   188     fn NoToken => ""
   189      | BasicToken tok => Latex.output_basic tok
   190      | MarkupToken (cmd, txt) => Latex.output_markup cmd (eval txt)
   191      | MarkupEnvToken (cmd, txt) => Latex.output_markup_env cmd (eval txt)
   192      | VerbatimToken txt => Latex.output_verbatim (eval txt)
   193   end;
   194 
   195 fun basic_token pred (BasicToken tok) = pred tok
   196   | basic_token _ _ = false;
   197 
   198 val improper_token = basic_token (not o T.is_proper);
   199 val comment_token = basic_token T.is_comment;
   200 val blank_token = basic_token T.is_blank;
   201 val newline_token = basic_token T.is_newline;
   202 
   203 
   204 (* command spans *)
   205 
   206 type command = string * Position.T * string list;   (*name, position, tags*)
   207 type source = (token * (string * int)) list;        (*token, markup flag, meta-comment depth*)
   208 
   209 datatype span = Span of command * (source * source * source * source) * bool;
   210 
   211 fun make_span cmd src =
   212   let
   213     fun take_newline (tok :: toks) =
   214           if newline_token (fst tok) then ([tok], toks, true)
   215           else ([], tok :: toks, false)
   216       | take_newline [] = ([], [], false);
   217     val (((src_prefix, src_main), src_suffix1), (src_suffix2, src_appendix, newline)) =
   218       src
   219       |> take_prefix (improper_token o fst)
   220       ||>> take_suffix (improper_token o fst)
   221       ||>> take_prefix (comment_token o fst)
   222       ||> take_newline;
   223   in Span (cmd, (src_prefix, src_main, src_suffix1 @ src_suffix2, src_appendix), newline) end;
   224 
   225 
   226 (* present spans *)
   227 
   228 local
   229 
   230 fun err_bad_nesting pos =
   231   error ("Bad nesting of commands in presentation" ^ pos);
   232 
   233 fun edge1 f (x, y) = the_default I (Option.map (Buffer.add o f) (if x = y then NONE else x));
   234 fun edge2 f (x, y) = the_default I (Option.map (Buffer.add o f) (if x = y then NONE else y));
   235 
   236 val begin_tag = edge2 Latex.begin_tag;
   237 val end_tag = edge1 Latex.end_tag;
   238 fun open_delim delim e = edge2 Latex.begin_delim e #> delim #> edge2 Latex.end_delim e;
   239 fun close_delim delim e = edge1 Latex.begin_delim e #> delim #> edge1 Latex.end_delim e;
   240 
   241 in
   242 
   243 fun present_span lex default_tags span state state'
   244     (tag_stack, active_tag, newline, buffer, present_cont) =
   245   let
   246     val present = fold (fn (tok, (flag, 0)) =>
   247         Buffer.add (output_token lex state' tok)
   248         #> Buffer.add flag
   249       | _ => I);
   250 
   251     val Span ((cmd_name, cmd_pos, cmd_tags), srcs, span_newline) = span;
   252 
   253     val (tag, tags) = tag_stack;
   254     val tag' = try hd (fold OuterKeyword.update_tags cmd_tags (the_list tag));
   255 
   256     val active_tag' =
   257       if is_some tag' then tag'
   258       else try hd (default_tags cmd_name);
   259     val edge = (active_tag, active_tag');
   260 
   261     val newline' =
   262       if is_none active_tag' then span_newline else newline;
   263 
   264     val nesting = Toplevel.level state' - Toplevel.level state;
   265     val tag_stack' =
   266       if nesting = 0 andalso not (Toplevel.is_proof state) then tag_stack
   267       else if nesting >= 0 then (tag', replicate nesting tag @ tags)
   268       else
   269         (case Library.drop (~ nesting - 1, tags) of
   270           tgs :: tgss => (tgs, tgss)
   271         | [] => err_bad_nesting (Position.str_of cmd_pos));
   272 
   273     val buffer' =
   274       buffer
   275       |> end_tag edge
   276       |> close_delim (fst present_cont) edge
   277       |> snd present_cont
   278       |> open_delim (present (#1 srcs)) edge
   279       |> begin_tag edge
   280       |> present (#2 srcs);
   281     val present_cont' =
   282       if newline then (present (#3 srcs), present (#4 srcs))
   283       else (I, present (#3 srcs) #> present (#4 srcs));
   284   in (tag_stack', active_tag', newline', buffer', present_cont') end;
   285 
   286 fun present_trailer ((_, tags), active_tag, _, buffer, present_cont) =
   287   if not (null tags) then err_bad_nesting " at end of theory"
   288   else
   289     buffer
   290     |> end_tag (active_tag, NONE)
   291     |> close_delim (fst present_cont) (active_tag, NONE)
   292     |> snd present_cont;
   293 
   294 end;
   295 
   296 
   297 (* present_thy *)
   298 
   299 datatype markup = Markup | MarkupEnv | Verbatim;
   300 
   301 local
   302 
   303 val space_proper =
   304   Scan.one T.is_blank -- Scan.any T.is_comment -- Scan.one T.is_proper;
   305 
   306 val is_improper = not o (T.is_proper orf T.is_begin_ignore orf T.is_end_ignore);
   307 val improper = Scan.any is_improper;
   308 val improper_end = Scan.repeat (Scan.unless space_proper (Scan.one is_improper));
   309 
   310 val opt_newline = Scan.option (Scan.one T.is_newline);
   311 
   312 val ignore =
   313   Scan.depend (fn d => opt_newline |-- Scan.one T.is_begin_ignore
   314     >> pair (d + 1)) ||
   315   Scan.depend (fn d => Scan.one T.is_end_ignore --|
   316     (if d = 0 then Scan.fail_with (K "Bad nesting of meta-comments") else opt_newline)
   317     >> pair (d - 1));
   318 
   319 val tag = (improper -- P.$$$ "%" -- improper) |-- P.!!! (P.tag_name --| improper_end);
   320 
   321 val locale =
   322   Scan.option ((P.$$$ "(" -- improper -- P.$$$ "in") |--
   323     P.!!! (improper |-- P.xname --| (improper -- P.$$$ ")")));
   324 
   325 in
   326 
   327 fun present_thy lex default_tags is_markup trs src =
   328   let
   329     (* tokens *)
   330 
   331     val ignored = Scan.state --| ignore
   332       >> (fn d => (NONE, (NoToken, ("", d))));
   333 
   334     fun markup mark mk flag = Scan.peek (fn d =>
   335       improper |-- P.position (Scan.one (T.is_kind T.Command andf is_markup mark o T.val_of)) --
   336       Scan.repeat tag --
   337       P.!!!! ((improper -- locale -- improper) |-- P.position P.text --| improper_end)
   338       >> (fn (((tok, pos), tags), txt) =>
   339         let val name = T.val_of tok
   340         in (SOME (name, pos, tags), (mk (name, txt), (flag, d))) end));
   341 
   342     val command = Scan.peek (fn d =>
   343       P.position (Scan.one (T.is_kind T.Command)) --
   344       Scan.repeat tag
   345       >> (fn ((tok, pos), tags) =>
   346         let val name = T.val_of tok
   347         in (SOME (name, pos, tags), (BasicToken tok, (Latex.markup_false, d))) end));
   348 
   349     val cmt = Scan.peek (fn d =>
   350       P.$$$ "--" |-- P.!!!! (improper |-- P.position P.text)
   351       >> (fn txt => (NONE, (MarkupToken ("cmt", txt), ("", d)))));
   352 
   353     val other = Scan.peek (fn d =>
   354        Scan.one T.not_eof >> (fn tok => (NONE, (BasicToken tok, ("", d)))));
   355 
   356     val token =
   357       ignored ||
   358       markup Markup MarkupToken Latex.markup_true ||
   359       markup MarkupEnv MarkupEnvToken Latex.markup_true ||
   360       markup Verbatim (VerbatimToken o #2) "" ||
   361       command || cmt || other;
   362 
   363 
   364     (* spans *)
   365 
   366     val stopper =
   367       ((NONE, (BasicToken (#1 T.stopper), ("", 0))),
   368         fn (_, (BasicToken x, _)) => #2 T.stopper x | _ => false);
   369 
   370     val cmd = Scan.one (is_some o fst);
   371     val non_cmd = Scan.one (is_none o fst andf not o #2 stopper) >> #2;
   372 
   373     val comments = Scan.any (comment_token o fst o snd);
   374     val blank = Scan.one (blank_token o fst o snd);
   375     val newline = Scan.one (newline_token o fst o snd);
   376     val before_cmd =
   377       Scan.option (newline -- comments) --
   378       Scan.option (newline -- comments) --
   379       Scan.option (blank -- comments) -- cmd;
   380 
   381     val span =
   382       Scan.repeat non_cmd -- cmd --
   383         Scan.repeat (Scan.unless before_cmd non_cmd) --
   384         Scan.option (newline >> (single o snd))
   385       >> (fn (((toks1, (cmd, tok2)), toks3), tok4) =>
   386           make_span (the cmd) (toks1 @ (tok2 :: (toks3 @ the_default [] tok4))));
   387 
   388     val spans =
   389       src
   390       |> Source.filter (not o T.is_semicolon)
   391       |> Source.source' 0 T.stopper (Scan.error (Scan.bulk token)) NONE
   392       |> Source.source stopper (Scan.error (Scan.bulk span)) NONE
   393       |> Source.exhaust;
   394   in
   395     if length trs = length spans then
   396       ((NONE, []), NONE, true, Buffer.empty, (I, I))
   397       |> Toplevel.present_excursion (trs ~~ map (present_span lex default_tags) spans)
   398       |> present_trailer
   399     else error "Messed-up outer syntax for presentation"
   400   end;
   401 
   402 end;
   403 
   404 
   405 
   406 (** setup default output **)
   407 
   408 (* options *)
   409 
   410 val _ = add_options
   411  [("show_types", Library.setmp Syntax.show_types o boolean),
   412   ("show_sorts", Library.setmp Syntax.show_sorts o boolean),
   413   ("show_structs", Library.setmp show_structs o boolean),
   414   ("show_question_marks", Library.setmp show_question_marks o boolean),
   415   ("long_names", Library.setmp NameSpace.long_names o boolean),
   416   ("short_names", Library.setmp NameSpace.short_names o boolean),
   417   ("unique_names", Library.setmp NameSpace.unique_names o boolean),
   418   ("eta_contract", Library.setmp Syntax.eta_contract o boolean),
   419   ("locale", Library.setmp locale),
   420   ("display", Library.setmp display o boolean),
   421   ("break", Library.setmp break o boolean),
   422   ("quotes", Library.setmp quotes o boolean),
   423   ("mode", fn s => fn f => fn () => Library.setmp print_mode (s :: ! print_mode) f ()),
   424   ("margin", Pretty.setmp_margin o integer),
   425   ("indent", Library.setmp indent o integer),
   426   ("source", Library.setmp source o boolean),
   427   ("goals_limit", Library.setmp goals_limit o integer)];
   428 
   429 
   430 (* basic pretty printing *)
   431 
   432 val str_of_source = space_implode " " o map Args.string_of o #2 o #1 o Args.dest_src;
   433 
   434 fun tweak_line s =
   435   if ! display then s else Symbol.strip_blanks s;
   436 
   437 val pretty_text = Pretty.chunks o map Pretty.str o map tweak_line o Library.split_lines;
   438 
   439 fun pretty_term ctxt = ProofContext.pretty_term ctxt o ProofContext.revert_skolems ctxt;
   440 
   441 fun pretty_term_typ ctxt t =
   442   ProofContext.pretty_term ctxt (TypeInfer.constrain t (Term.fastype_of t));
   443 
   444 fun pretty_term_typeof ctxt = ProofContext.pretty_typ ctxt o Term.fastype_of;
   445 
   446 fun pretty_term_const ctxt t =
   447   if Term.is_Const t then pretty_term ctxt t
   448   else error ("Logical constant expected: " ^ ProofContext.string_of_term ctxt t);
   449 
   450 fun pretty_thm ctxt = pretty_term ctxt o Thm.full_prop_of;
   451 
   452 fun pretty_term_style ctxt (name, t) =
   453   pretty_term ctxt (TermStyle.the_style (ProofContext.theory_of ctxt) name ctxt t);
   454 
   455 fun pretty_thm_style ctxt (name, th) =
   456   pretty_term_style ctxt (name, Thm.full_prop_of th);
   457 
   458 fun pretty_prf full ctxt thms =
   459   Pretty.chunks (map (ProofContext.pretty_proof_of ctxt full) thms);
   460 
   461 
   462 (* Isar output *)
   463 
   464 fun output_list pretty src ctxt xs =
   465   map (pretty ctxt) xs        (*always pretty in order to exhibit errors!*)
   466   |> (if ! source then K [pretty_text (str_of_source src)] else I)
   467   |> (if ! quotes then map Pretty.quote else I)
   468   |> (if ! display then
   469     map (Output.output o Pretty.string_of o Pretty.indent (! indent))
   470     #> space_implode "\\isasep\\isanewline%\n"
   471     #> enclose "\\begin{isabelle}%\n" "%\n\\end{isabelle}"
   472   else
   473     map (Output.output o (if ! break then Pretty.string_of else Pretty.str_of))
   474     #> space_implode "\\isasep\\isanewline%\n"
   475     #> enclose "\\isa{" "}");
   476 
   477 fun output pretty src ctxt = output_list pretty src ctxt o single;
   478 
   479 fun proof_state node =
   480   (case Option.map Toplevel.proof_node node of
   481     SOME (SOME prf) => ProofHistory.current prf
   482   | _ => error "No proof state");
   483 
   484 fun output_goals main_goal src node = args (Scan.succeed ()) (output (fn _ => fn _ =>
   485   Pretty.chunks (Proof.pretty_goals main_goal (proof_state node)))) src node;
   486 
   487 fun ml_val txt = "fn _ => (" ^ txt ^ ");";
   488 fun ml_type txt = "val _ = NONE : (" ^ txt ^ ") option;";
   489 fun ml_struct txt = "functor DUMMY_FUNCTOR() = struct structure DUMMY = " ^ txt ^ " end;"
   490 
   491 fun output_ml ml src ctxt txt =
   492  (Context.use_mltext (ml txt) false (SOME (ProofContext.theory_of ctxt));
   493   (if ! source then str_of_source src else txt)
   494   |> (if ! quotes then quote else I)
   495   |> (if ! display then enclose "\\begin{verbatim}\n" "\n\\end{verbatim}"
   496   else
   497     split_lines
   498     #> map (space_implode "\\verb,|," o map (enclose "\\verb|" "|") o space_explode "|")
   499     #> space_implode "\\isasep\\isanewline%\n"));
   500 
   501 
   502 (* commands *)
   503 
   504 val _ = add_commands
   505  [("thm", args Attrib.thms (output_list pretty_thm)),
   506   ("thm_style", args (Scan.lift Args.liberal_name -- Attrib.thm) (output pretty_thm_style)),
   507   ("prop", args Args.prop (output pretty_term)),
   508   ("term", args Args.term (output pretty_term)),
   509   ("term_style", args (Scan.lift Args.liberal_name -- Args.term) (output pretty_term_style)),
   510   ("term_type", args Args.term (output pretty_term_typ)),
   511   ("typeof", args Args.term (output pretty_term_typeof)),
   512   ("const", args Args.term (output pretty_term_const)),
   513   ("typ", args Args.typ_abbrev (output ProofContext.pretty_typ)),
   514   ("text", args (Scan.lift Args.name) (output (K pretty_text))),
   515   ("goals", output_goals true),
   516   ("subgoals", output_goals false),
   517   ("prf", args Attrib.thms (output (pretty_prf false))),
   518   ("full_prf", args Attrib.thms (output (pretty_prf true))),
   519   ("ML", args (Scan.lift Args.name) (output_ml ml_val)),
   520   ("ML_type", args (Scan.lift Args.name) (output_ml ml_type)),
   521   ("ML_struct", args (Scan.lift Args.name) (output_ml ml_struct))];
   522 
   523 end;