src/Pure/pattern.ML
author haftmann
Fri Nov 10 07:44:47 2006 +0100 (2006-11-10)
changeset 21286 b5e7b80caa6a
parent 20672 b96394d8c702
child 22255 8fcd11cb9be7
permissions -rw-r--r--
introduces canonical AList functions for loop_tacs
     1 (*  Title:      Pure/pattern.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Christine Heinzelmann, and Stefan Berghofer
     4 
     5 Unification of Higher-Order Patterns.
     6 
     7 See also:
     8 Tobias Nipkow. Functional Unification of Higher-Order Patterns.
     9 In Proceedings of the 8th IEEE Symposium Logic in Computer Science, 1993.
    10 
    11 TODO: optimize red by special-casing it
    12 *)
    13 
    14 infix aeconv;
    15 
    16 signature PATTERN =
    17 sig
    18   val trace_unify_fail: bool ref
    19   val aeconv: term * term -> bool
    20   val eta_long: typ list -> term -> term
    21   val eta_contract_atom: term -> term
    22   val match: theory -> term * term -> Type.tyenv * Envir.tenv -> Type.tyenv * Envir.tenv
    23   val first_order_match: theory -> term * term
    24     -> Type.tyenv * Envir.tenv -> Type.tyenv * Envir.tenv
    25   val matches: theory -> term * term -> bool
    26   val equiv: theory -> term * term -> bool
    27   val matches_subterm: theory -> term * term -> bool
    28   val unify: theory -> term * term -> Envir.env -> Envir.env
    29   val first_order: term -> bool
    30   val pattern: term -> bool
    31   val rewrite_term: theory -> (term * term) list -> (term -> term option) list -> term -> term
    32   exception Unif
    33   exception MATCH
    34   exception Pattern
    35 end;
    36 
    37 structure Pattern: PATTERN =
    38 struct
    39 
    40 exception Unif;
    41 exception Pattern;
    42 
    43 val trace_unify_fail = ref false;
    44 
    45 fun string_of_term thy env binders t = Sign.string_of_term thy
    46   (Envir.norm_term env (subst_bounds(map Free binders,t)));
    47 
    48 fun bname binders i = fst (nth binders i);
    49 fun bnames binders is = space_implode " " (map (bname binders) is);
    50 
    51 fun typ_clash thy (tye,T,U) =
    52   if !trace_unify_fail
    53   then let val t = Sign.string_of_typ thy (Envir.norm_type tye T)
    54            and u = Sign.string_of_typ thy (Envir.norm_type tye U)
    55        in tracing("The following types do not unify:\n" ^ t ^ "\n" ^ u) end
    56   else ()
    57 
    58 fun clash a b =
    59   if !trace_unify_fail then tracing("Clash: " ^ a ^ " =/= " ^ b) else ()
    60 
    61 fun boundVar binders i =
    62   "bound variable " ^ bname binders i ^ " (depth " ^ string_of_int i ^ ")";
    63 
    64 fun clashBB binders i j =
    65   if !trace_unify_fail then clash (boundVar binders i) (boundVar binders j)
    66   else ()
    67 
    68 fun clashB binders i s =
    69   if !trace_unify_fail then clash (boundVar binders i) s
    70   else ()
    71 
    72 fun proj_fail thy (env,binders,F,_,is,t) =
    73   if !trace_unify_fail
    74   then let val f = Syntax.string_of_vname F
    75            val xs = bnames binders is
    76            val u = string_of_term thy env binders t
    77            val ys = bnames binders (subtract (op =) is (loose_bnos t))
    78        in tracing("Cannot unify variable " ^ f ^
    79                " (depending on bound variables " ^ xs ^ ")\nwith term " ^ u ^
    80                "\nTerm contains additional bound variable(s) " ^ ys)
    81        end
    82   else ()
    83 
    84 fun ocheck_fail thy (F,t,binders,env) =
    85   if !trace_unify_fail
    86   then let val f = Syntax.string_of_vname F
    87            val u = string_of_term thy env binders t
    88        in tracing("Variable " ^ f ^ " occurs in term\n" ^ u ^
    89                   "\nCannot unify!\n")
    90        end
    91   else ()
    92 
    93 fun occurs(F,t,env) =
    94     let fun occ(Var (G, T))   = (case Envir.lookup (env, (G, T)) of
    95                                  SOME(t) => occ t
    96                                | NONE    => F=G)
    97           | occ(t1$t2)      = occ t1 orelse occ t2
    98           | occ(Abs(_,_,t)) = occ t
    99           | occ _           = false
   100     in occ t end;
   101 
   102 
   103 fun mapbnd f =
   104     let fun mpb d (Bound(i))     = if i < d then Bound(i) else Bound(f(i-d)+d)
   105           | mpb d (Abs(s,T,t))   = Abs(s,T,mpb(d+1) t)
   106           | mpb d ((u1 $ u2))    = (mpb d u1)$(mpb d u2)
   107           | mpb _ atom           = atom
   108     in mpb 0 end;
   109 
   110 fun idx [] j     = raise Unif
   111   | idx(i::is) j = if (i:int) =j then length is else idx is j;
   112 
   113 fun mkabs (binders,is,t)  =
   114     let fun mk(i::is) = let val (x,T) = nth binders i
   115                         in Abs(x,T,mk is) end
   116           | mk []     = t
   117     in mk is end;
   118 
   119 val incr = mapbnd (fn i => i+1);
   120 
   121 fun ints_of []             = []
   122   | ints_of (Bound i ::bs) =
   123       let val is = ints_of bs
   124       in if member (op =) is i then raise Pattern else i::is end
   125   | ints_of _              = raise Pattern;
   126 
   127 fun ints_of' env ts = ints_of (map (Envir.head_norm env) ts);
   128 
   129 
   130 fun app (s,(i::is)) = app (s$Bound(i),is)
   131   | app (s,[])      = s;
   132 
   133 fun red (Abs(_,_,s)) (i::is) js = red s is (i::js)
   134   | red t            []      [] = t
   135   | red t            is      jn = app (mapbnd (nth jn) t,is);
   136 
   137 
   138 (* split_type ([T1,....,Tn]---> T,n,[]) = ([Tn,...,T1],T) *)
   139 fun split_type (T,0,Ts)                    = (Ts,T)
   140   | split_type (Type ("fun",[T1,T2]),n,Ts) = split_type (T2,n-1,T1::Ts)
   141   | split_type _                           = error("split_type");
   142 
   143 fun type_of_G (env as Envir.Envir {iTs, ...}) (T,n,is) =
   144   let val (Ts, U) = split_type (Envir.norm_type iTs T, n, [])
   145   in map (nth Ts) is ---> U end;
   146 
   147 fun mkhnf (binders,is,G,js) = mkabs (binders, is, app(G,js));
   148 
   149 fun mknewhnf(env,binders,is,F as (a,_),T,js) =
   150   let val (env',G) = Envir.genvar a (env,type_of_G env (T,length is,js))
   151   in Envir.update (((F, T), mkhnf (binders, is, G, js)), env') end;
   152 
   153 
   154 (* mk_proj_list(is) = [ |is| - k | 1 <= k <= |is| and is[k] >= 0 ] *)
   155 fun mk_proj_list is =
   156     let fun mk(i::is,j) = if is_some i then j :: mk(is,j-1) else mk(is,j-1)
   157           | mk([],_)    = []
   158     in mk(is,length is - 1) end;
   159 
   160 fun proj(s,env,binders,is) =
   161     let fun trans d i = if i<d then i else (idx is (i-d))+d;
   162         fun pr(s,env,d,binders) = (case Envir.head_norm env s of
   163               Abs(a,T,t) => let val (t',env') = pr(t,env,d+1,((a,T)::binders))
   164                             in (Abs(a,T,t'),env') end
   165             | t => (case strip_comb t of
   166                 (c as Const _,ts) =>
   167                          let val (ts',env') = prs(ts,env,d,binders)
   168                          in (list_comb(c,ts'),env') end
   169                  | (f as Free _,ts) =>
   170                          let val (ts',env') = prs(ts,env,d,binders)
   171                          in (list_comb(f,ts'),env') end
   172                  | (Bound(i),ts) =>
   173                          let val j = trans d i
   174                              val (ts',env') = prs(ts,env,d,binders)
   175                          in (list_comb(Bound j,ts'),env') end
   176                  | (Var(F as (a,_),Fty),ts) =>
   177                       let val js = ints_of' env ts;
   178                           val js' = map (try (trans d)) js;
   179                           val ks = mk_proj_list js';
   180                           val ls = map_filter I js'
   181                           val Hty = type_of_G env (Fty,length js,ks)
   182                           val (env',H) = Envir.genvar a (env,Hty)
   183                           val env'' =
   184                             Envir.update (((F, Fty), mkhnf (binders, js, H, ks)), env')
   185                       in (app(H,ls),env'') end
   186                  | _  => raise Pattern))
   187         and prs(s::ss,env,d,binders) =
   188               let val (s',env1) = pr(s,env,d,binders)
   189                   val (ss',env2) = prs(ss,env1,d,binders)
   190               in (s'::ss',env2) end
   191           | prs([],env,_,_) = ([],env)
   192    in if downto0(is,length binders - 1) then (s,env)
   193       else pr(s,env,0,binders)
   194    end;
   195 
   196 
   197 (* mk_ff_list(is,js) = [ length(is) - k | 1 <= k <= |is| and is[k] = js[k] ] *)
   198 fun mk_ff_list(is,js) =
   199     let fun mk([],[],_)        = []
   200           | mk(i::is,j::js, k) = if (i:int) = j then k :: mk(is,js,k-1)
   201                                         else mk(is,js,k-1)
   202           | mk _               = error"mk_ff_list"
   203     in mk(is,js,length is-1) end;
   204 
   205 fun flexflex1(env,binders,F,Fty,is,js) =
   206   if is=js then env
   207   else let val ks = mk_ff_list(is,js)
   208        in mknewhnf(env,binders,is,F,Fty,ks) end;
   209 
   210 fun flexflex2(env,binders,F,Fty,is,G,Gty,js) =
   211   let fun ff(F,Fty,is,G as (a,_),Gty,js) =
   212             if js subset_int is
   213             then let val t= mkabs(binders,is,app(Var(G,Gty),map (idx is) js))
   214                  in Envir.update (((F, Fty), t), env) end
   215             else let val ks = is inter_int js
   216                      val Hty = type_of_G env (Fty,length is,map (idx is) ks)
   217                      val (env',H) = Envir.genvar a (env,Hty)
   218                      fun lam(is) = mkabs(binders,is,app(H,map (idx is) ks));
   219                  in Envir.update (((G, Gty), lam js), Envir.update (((F, Fty), lam is), env'))
   220                  end;
   221   in if Term.indexname_ord (G,F) = LESS then ff(F,Fty,is,G,Gty,js) else ff(G,Gty,js,F,Fty,is) end
   222 
   223 fun unify_types thy (T,U) (env as Envir.Envir{asol,iTs,maxidx}) =
   224   if T=U then env
   225   else let val (iTs',maxidx') = Sign.typ_unify thy (U, T) (iTs, maxidx)
   226        in Envir.Envir{asol=asol,maxidx=maxidx',iTs=iTs'} end
   227        handle Type.TUNIFY => (typ_clash thy (iTs,T,U); raise Unif);
   228 
   229 fun unif thy binders (s,t) env = case (Envir.head_norm env s, Envir.head_norm env t) of
   230       (Abs(ns,Ts,ts),Abs(nt,Tt,tt)) =>
   231          let val name = if ns = "" then nt else ns
   232          in unif thy ((name,Ts)::binders) (ts,tt) env end
   233     | (Abs(ns,Ts,ts),t) => unif thy ((ns,Ts)::binders) (ts,(incr t)$Bound(0)) env
   234     | (t,Abs(nt,Tt,tt)) => unif thy ((nt,Tt)::binders) ((incr t)$Bound(0),tt) env
   235     | p => cases thy (binders,env,p)
   236 
   237 and cases thy (binders,env,(s,t)) = case (strip_comb s,strip_comb t) of
   238        ((Var(F,Fty),ss),(Var(G,Gty),ts)) =>
   239          if F = G then flexflex1(env,binders,F,Fty,ints_of' env ss,ints_of' env ts)
   240                   else flexflex2(env,binders,F,Fty,ints_of' env ss,G,Gty,ints_of' env ts)
   241       | ((Var(F,Fty),ss),_)           => flexrigid thy (env,binders,F,Fty,ints_of' env ss,t)
   242       | (_,(Var(F,Fty),ts))           => flexrigid thy (env,binders,F,Fty,ints_of' env ts,s)
   243       | ((Const c,ss),(Const d,ts))   => rigidrigid thy (env,binders,c,d,ss,ts)
   244       | ((Free(f),ss),(Free(g),ts))   => rigidrigid thy (env,binders,f,g,ss,ts)
   245       | ((Bound(i),ss),(Bound(j),ts)) => rigidrigidB thy (env,binders,i,j,ss,ts)
   246       | ((Abs(_),_),_)                => raise Pattern
   247       | (_,(Abs(_),_))                => raise Pattern
   248       | ((Const(c,_),_),(Free(f,_),_)) => (clash c f; raise Unif)
   249       | ((Const(c,_),_),(Bound i,_))   => (clashB binders i c; raise Unif)
   250       | ((Free(f,_),_),(Const(c,_),_)) => (clash f c; raise Unif)
   251       | ((Free(f,_),_),(Bound i,_))    => (clashB binders i f; raise Unif)
   252       | ((Bound i,_),(Const(c,_),_))   => (clashB binders i c; raise Unif)
   253       | ((Bound i,_),(Free(f,_),_))    => (clashB binders i f; raise Unif)
   254 
   255 
   256 and rigidrigid thy (env,binders,(a,Ta),(b,Tb),ss,ts) =
   257       if a<>b then (clash a b; raise Unif)
   258       else env |> unify_types thy (Ta,Tb) |> fold (unif thy binders) (ss~~ts)
   259 
   260 and rigidrigidB thy (env,binders,i,j,ss,ts) =
   261      if i <> j then (clashBB binders i j; raise Unif)
   262      else fold (unif thy binders) (ss~~ts) env
   263 
   264 and flexrigid thy (params as (env,binders,F,Fty,is,t)) =
   265       if occurs(F,t,env) then (ocheck_fail thy (F,t,binders,env); raise Unif)
   266       else (let val (u,env') = proj(t,env,binders,is)
   267             in Envir.update (((F, Fty), mkabs (binders, is, u)), env') end
   268             handle Unif => (proj_fail thy params; raise Unif));
   269 
   270 fun unify thy = unif thy [];
   271 
   272 
   273 (*Eta-contract a term from outside: just enough to reduce it to an atom
   274 DOESN'T QUITE WORK!
   275 *)
   276 fun eta_contract_atom (t0 as Abs(a, T, body)) =
   277       (case  eta_contract2 body  of
   278         body' as (f $ Bound 0) =>
   279             if loose_bvar1(f,0) then Abs(a,T,body')
   280             else eta_contract_atom (incr_boundvars ~1 f)
   281       | _ => t0)
   282   | eta_contract_atom t = t
   283 and eta_contract2 (f$t) = f $ eta_contract_atom t
   284   | eta_contract2 t     = eta_contract_atom t;
   285 
   286 (* put a term into eta long beta normal form *)
   287 fun eta_long Ts (Abs (s, T, t)) = Abs (s, T, eta_long (T :: Ts) t)
   288   | eta_long Ts t = (case strip_comb t of
   289       (Abs _, _) => eta_long Ts (Envir.beta_norm t)
   290     | (u, ts) =>
   291       let
   292         val Us = binder_types (fastype_of1 (Ts, t));
   293         val i = length Us
   294       in list_abs (map (pair "x") Us,
   295         list_comb (incr_boundvars i u, map (eta_long (rev Us @ Ts))
   296           (map (incr_boundvars i) ts @ map Bound (i - 1 downto 0))))
   297       end);
   298 
   299 
   300 (*Tests whether 2 terms are alpha/eta-convertible and have same type.
   301   Note that Consts and Vars may have more than one type.*)
   302 fun t aeconv u = aconv_aux (eta_contract_atom t, eta_contract_atom u)
   303 and aconv_aux (Const(a,T), Const(b,U)) = a=b  andalso  T=U
   304   | aconv_aux (Free(a,T),  Free(b,U))  = a=b  andalso  T=U
   305   | aconv_aux (Var(v,T),   Var(w,U))   = eq_ix(v,w) andalso  T=U
   306   | aconv_aux (Bound i,    Bound j)    = i=j
   307   | aconv_aux (Abs(_,T,t), Abs(_,U,u)) = (t aeconv u)  andalso  T=U
   308   | aconv_aux (f$t,        g$u)        = (f aeconv g)  andalso (t aeconv u)
   309   | aconv_aux _ =  false;
   310 
   311 
   312 (*** Matching ***)
   313 
   314 exception MATCH;
   315 
   316 fun typ_match thy TU tyenv = Sign.typ_match thy TU tyenv
   317   handle Type.TYPE_MATCH => raise MATCH;
   318 
   319 (*First-order matching;
   320   The pattern and object may have variables in common.
   321   Instantiation does not affect the object, so matching ?a with ?a+1 works.
   322   Object is eta-contracted on the fly (by eta-expanding the pattern).
   323   Precondition: the pattern is already eta-contracted!
   324   Types are matched on the fly*)
   325 fun first_order_match thy =
   326   let
   327     fun mtch (instsp as (tyinsts,insts)) = fn
   328         (Var(ixn,T), t)  =>
   329           if loose_bvar(t,0) then raise MATCH
   330           else (case Envir.lookup' (insts, (ixn, T)) of
   331                   NONE => (typ_match thy (T, fastype_of t) tyinsts,
   332                            Vartab.update_new (ixn, (T, t)) insts)
   333                 | SOME u => if t aeconv u then instsp else raise MATCH)
   334       | (Free (a,T), Free (b,U)) =>
   335           if a=b then (typ_match thy (T,U) tyinsts, insts) else raise MATCH
   336       | (Const (a,T), Const (b,U))  =>
   337           if a=b then (typ_match thy (T,U) tyinsts, insts) else raise MATCH
   338       | (Bound i, Bound j)  =>  if  i=j  then  instsp  else raise MATCH
   339       | (Abs(_,T,t), Abs(_,U,u))  =>
   340           mtch (typ_match thy (T,U) tyinsts, insts) (t,u)
   341       | (f$t, g$u) => mtch (mtch instsp (f,g)) (t, u)
   342       | (t, Abs(_,U,u))  =>  mtch instsp ((incr t)$(Bound 0), u)
   343       | _ => raise MATCH
   344   in fn tu => fn env => mtch env tu end;
   345 
   346 
   347 (* Matching of higher-order patterns *)
   348 
   349 fun match_bind(itms,binders,ixn,T,is,t) =
   350   let val js = loose_bnos t
   351   in if null is
   352      then if null js then Vartab.update_new (ixn, (T, t)) itms else raise MATCH
   353      else if js subset_int is
   354           then let val t' = if downto0(is,length binders - 1) then t
   355                             else mapbnd (idx is) t
   356                in Vartab.update_new (ixn, (T, mkabs (binders, is, t'))) itms end
   357           else raise MATCH
   358   end;
   359 
   360 fun match thy (po as (pat,obj)) envir =
   361 let
   362   (* Pre: pat and obj have same type *)
   363   fun mtch binders (pat,obj) (env as (iTs,itms)) =
   364     case pat of
   365       Abs(ns,Ts,ts) =>
   366         (case obj of
   367            Abs(nt,Tt,tt) => mtch ((nt,Tt)::binders) (ts,tt) env
   368          | _ => let val Tt = Envir.typ_subst_TVars iTs Ts
   369                 in mtch((ns,Tt)::binders) (ts,(incr obj)$Bound(0)) env end)
   370     | _ => (case obj of
   371               Abs(nt,Tt,tt) =>
   372                 mtch((nt,Tt)::binders) ((incr pat)$Bound(0),tt) env
   373             | _ => cases(binders,env,pat,obj))
   374 
   375   and cases(binders,env as (iTs,itms),pat,obj) =
   376     let val (ph,pargs) = strip_comb pat
   377         fun rigrig1(iTs,oargs) = fold (mtch binders) (pargs~~oargs) (iTs,itms)
   378         fun rigrig2((a:string,Ta),(b,Tb),oargs) =
   379               if a <> b then raise MATCH
   380               else rigrig1(typ_match thy (Ta,Tb) iTs, oargs)
   381     in case ph of
   382          Var(ixn,T) =>
   383            let val is = ints_of pargs
   384            in case Envir.lookup' (itms, (ixn, T)) of
   385                 NONE => (iTs,match_bind(itms,binders,ixn,T,is,obj))
   386               | SOME u => if obj aeconv (red u is []) then env
   387                           else raise MATCH
   388            end
   389        | _ =>
   390            let val (oh,oargs) = strip_comb obj
   391            in case (ph,oh) of
   392                 (Const c,Const d) => rigrig2(c,d,oargs)
   393               | (Free f,Free g)   => rigrig2(f,g,oargs)
   394               | (Bound i,Bound j) => if i<>j then raise MATCH
   395                                      else rigrig1(iTs,oargs)
   396               | (Abs _, _)        => raise Pattern
   397               | (_, Abs _)        => raise Pattern
   398               | _                 => raise MATCH
   399            end
   400     end;
   401 
   402   val pT = fastype_of pat
   403   and oT = fastype_of obj
   404   val envir' = apfst (typ_match thy (pT, oT)) envir;
   405 in mtch [] po envir' handle Pattern => first_order_match thy po envir' end;
   406 
   407 fun matches thy po = (match thy po (Vartab.empty, Vartab.empty); true) handle MATCH => false;
   408 
   409 fun equiv thy (t, u) = matches thy (t, u) andalso matches thy (u, t);
   410 
   411 
   412 (* Does pat match a subterm of obj? *)
   413 fun matches_subterm thy (pat,obj) =
   414   let fun msub(bounds,obj) = matches thy (pat,obj) orelse
   415             (case obj of
   416               Abs(x,T,t) => let val y = Name.variant bounds x
   417                                 val f = Free(":" ^ y,T)
   418                             in msub(x::bounds,subst_bound(f,t)) end
   419             | s$t => msub(bounds,s) orelse msub(bounds,t)
   420             | _ => false)
   421   in msub([],obj) end;
   422 
   423 fun first_order(Abs(_,_,t)) = first_order t
   424   | first_order(t $ u) = first_order t andalso first_order u andalso
   425                          not(is_Var t)
   426   | first_order _ = true;
   427 
   428 fun pattern (Abs (_, _, t)) = pattern t
   429   | pattern t =
   430       let val (head, args) = strip_comb t in
   431         if is_Var head then
   432           forall is_Bound args andalso not (has_duplicates (op aconv) args)
   433         else forall pattern args
   434       end;
   435 
   436 
   437 (* rewriting -- simple but fast *)
   438 
   439 fun rewrite_term thy rules procs tm =
   440   let
   441     val skel0 = Bound 0;
   442 
   443     fun variant_absfree bounds (x, T, t) =
   444       let
   445         val (x', t') = Term.dest_abs (Name.bound bounds, T, t);
   446         fun abs u = Abs (x, T, abstract_over (Free (x', T), u));
   447       in (abs, t') end;
   448 
   449     fun match_rew tm (tm1, tm2) =
   450       let val rtm = the_default tm2 (Term.rename_abs tm1 tm tm2) in
   451         SOME (Envir.subst_vars (match thy (tm1, tm) (Vartab.empty, Vartab.empty)) rtm, rtm)
   452           handle MATCH => NONE
   453       end;
   454 
   455     fun rew (Abs (_, _, body) $ t) = SOME (subst_bound (t, body), skel0)
   456       | rew tm = (case get_first (match_rew tm) rules of
   457           NONE => Option.map (rpair skel0) (get_first (fn p => p tm) procs)
   458         | x => x);
   459 
   460     fun rew1 bounds (Var _) _ = NONE
   461       | rew1 bounds skel tm = (case rew2 bounds skel tm of
   462           SOME tm1 => (case rew tm1 of
   463               SOME (tm2, skel') => SOME (the_default tm2 (rew1 bounds skel' tm2))
   464             | NONE => SOME tm1)
   465         | NONE => (case rew tm of
   466               SOME (tm1, skel') => SOME (the_default tm1 (rew1 bounds skel' tm1))
   467             | NONE => NONE))
   468 
   469     and rew2 bounds skel (tm1 $ tm2) = (case tm1 of
   470             Abs (_, _, body) =>
   471               let val tm' = subst_bound (tm2, body)
   472               in SOME (the_default tm' (rew2 bounds skel0 tm')) end
   473           | _ =>
   474             let val (skel1, skel2) = (case skel of
   475                 skel1 $ skel2 => (skel1, skel2)
   476               | _ => (skel0, skel0))
   477             in case rew1 bounds skel1 tm1 of
   478                 SOME tm1' => (case rew1 bounds skel2 tm2 of
   479                     SOME tm2' => SOME (tm1' $ tm2')
   480                   | NONE => SOME (tm1' $ tm2))
   481               | NONE => (case rew1 bounds skel2 tm2 of
   482                     SOME tm2' => SOME (tm1 $ tm2')
   483                   | NONE => NONE)
   484             end)
   485       | rew2 bounds skel (Abs body) =
   486           let
   487             val (abs, tm') = variant_absfree bounds body;
   488             val skel' = (case skel of Abs (_, _, skel') => skel' | _ => skel0)
   489           in case rew1 (bounds + 1) skel' tm' of
   490               SOME tm'' => SOME (abs tm'')
   491             | NONE => NONE
   492           end
   493       | rew2 _ _ _ = NONE;
   494 
   495   in the_default tm (rew1 0 skel0 tm) end;
   496 
   497 end;
   498 
   499 val trace_unify_fail = Pattern.trace_unify_fail;