src/Pure/type.ML
author haftmann
Fri Nov 10 07:44:47 2006 +0100 (2006-11-10)
changeset 21286 b5e7b80caa6a
parent 21116 be58cded79da
child 21858 05f57309170c
permissions -rw-r--r--
introduces canonical AList functions for loop_tacs
     1 (*  Title:      Pure/type.ML
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Lawrence C Paulson, and Markus Wenzel
     4 
     5 Type signatures and certified types, special treatment of type vars,
     6 matching and unification of types, extend and merge type signatures.
     7 *)
     8 
     9 signature TYPE =
    10 sig
    11   (*type signatures and certified types*)
    12   datatype decl =
    13     LogicalType of int |
    14     Abbreviation of string list * typ * bool |
    15     Nonterminal
    16   type tsig
    17   val rep_tsig: tsig ->
    18    {classes: NameSpace.T * Sorts.algebra,
    19     default: sort,
    20     types: (decl * serial) NameSpace.table,
    21     log_types: string list,
    22     witness: (typ * sort) option}
    23   val empty_tsig: tsig
    24   val defaultS: tsig -> sort
    25   val logical_types: tsig -> string list
    26   val universal_witness: tsig -> (typ * sort) option
    27   val eq_sort: tsig -> sort * sort -> bool
    28   val subsort: tsig -> sort * sort -> bool
    29   val of_sort: tsig -> typ * sort -> bool
    30   val inter_sort: tsig -> sort * sort -> sort
    31   val cert_class: tsig -> class -> class
    32   val cert_sort: tsig -> sort -> sort
    33   val witness_sorts: tsig -> sort list -> sort list -> (typ * sort) list
    34   val cert_typ: tsig -> typ -> typ
    35   val cert_typ_syntax: tsig -> typ -> typ
    36   val cert_typ_abbrev: tsig -> typ -> typ
    37   val arity_number: tsig -> string -> int
    38   val arity_sorts: Pretty.pp -> tsig -> string -> sort -> sort list
    39 
    40   (*special treatment of type vars*)
    41   val strip_sorts: typ -> typ
    42   val no_tvars: typ -> typ
    43   val varify: (string * sort) list -> term -> ((string * sort) * indexname) list * term
    44   val freeze_thaw_type: typ -> typ * (typ -> typ)
    45   val freeze_type: typ -> typ
    46   val freeze_thaw: term -> term * (term -> term)
    47   val freeze: term -> term
    48 
    49   (*matching and unification*)
    50   exception TYPE_MATCH
    51   type tyenv
    52   val lookup: tyenv * (indexname * sort) -> typ option
    53   val typ_match: tsig -> typ * typ -> tyenv -> tyenv
    54   val typ_instance: tsig -> typ * typ -> bool
    55   val raw_match: typ * typ -> tyenv -> tyenv
    56   val raw_matches: typ list * typ list -> tyenv -> tyenv
    57   val raw_instance: typ * typ -> bool
    58   exception TUNIFY
    59   val unify: tsig -> typ * typ -> tyenv * int -> tyenv * int
    60   val raw_unify: typ * typ -> tyenv -> tyenv
    61   val raw_unifys: typ list * typ list -> tyenv -> tyenv
    62   val could_unify: typ * typ -> bool
    63   val could_unifys: typ list * typ list -> bool
    64   val eq_type: tyenv -> typ * typ -> bool
    65 
    66   (*extend and merge type signatures*)
    67   val add_class: Pretty.pp -> NameSpace.naming -> bstring * class list -> tsig -> tsig
    68   val hide_classes: bool -> string list -> tsig -> tsig
    69   val set_defsort: sort -> tsig -> tsig
    70   val add_types: NameSpace.naming -> (bstring * int) list -> tsig -> tsig
    71   val add_abbrevs: NameSpace.naming -> (string * string list * typ) list -> tsig -> tsig
    72   val add_nonterminals: NameSpace.naming -> string list -> tsig -> tsig
    73   val hide_types: bool -> string list -> tsig -> tsig
    74   val add_arity: Pretty.pp -> arity -> tsig -> tsig
    75   val add_classrel: Pretty.pp -> class * class -> tsig -> tsig
    76   val merge_tsigs: Pretty.pp -> tsig * tsig -> tsig
    77 end;
    78 
    79 structure Type: TYPE =
    80 struct
    81 
    82 (** type signatures and certified types **)
    83 
    84 (* type declarations *)
    85 
    86 datatype decl =
    87   LogicalType of int |
    88   Abbreviation of string list * typ * bool |
    89   Nonterminal;
    90 
    91 fun str_of_decl (LogicalType _) = "logical type constructor"
    92   | str_of_decl (Abbreviation _) = "type abbreviation"
    93   | str_of_decl Nonterminal = "syntactic type";
    94 
    95 
    96 (* type tsig *)
    97 
    98 datatype tsig =
    99   TSig of {
   100     classes: NameSpace.T * Sorts.algebra,   (*order-sorted algebra of type classes*)
   101     default: sort,                          (*default sort on input*)
   102     types: (decl * serial) NameSpace.table, (*declared types*)
   103     log_types: string list,                 (*logical types sorted by number of arguments*)
   104     witness: (typ * sort) option};          (*witness for non-emptiness of strictest sort*)
   105 
   106 fun rep_tsig (TSig comps) = comps;
   107 
   108 fun make_tsig (classes, default, types, log_types, witness) =
   109   TSig {classes = classes, default = default, types = types,
   110     log_types = log_types, witness = witness};
   111 
   112 fun build_tsig ((space, classes), default, types) =
   113   let
   114     val log_types =
   115       Symtab.fold (fn (c, (LogicalType n, _)) => cons (c, n) | _ => I) (snd types) []
   116       |> Library.sort (Library.int_ord o pairself snd) |> map fst;
   117     val witness =
   118       (case Sorts.witness_sorts classes log_types [] [Sorts.classes classes] of
   119         [w] => SOME w | _ => NONE);
   120   in make_tsig ((space, classes), default, types, log_types, witness) end;
   121 
   122 fun map_tsig f (TSig {classes, default, types, log_types = _, witness = _}) =
   123   build_tsig (f (classes, default, types));
   124 
   125 val empty_tsig =
   126   build_tsig ((NameSpace.empty, Sorts.empty_algebra), [], NameSpace.empty_table);
   127 
   128 
   129 (* classes and sorts *)
   130 
   131 fun defaultS (TSig {default, ...}) = default;
   132 fun logical_types (TSig {log_types, ...}) = log_types;
   133 fun universal_witness (TSig {witness, ...}) = witness;
   134 
   135 fun eq_sort (TSig {classes, ...}) = Sorts.sort_eq (#2 classes);
   136 fun subsort (TSig {classes, ...}) = Sorts.sort_le (#2 classes);
   137 fun of_sort (TSig {classes, ...}) = Sorts.of_sort (#2 classes);
   138 fun inter_sort (TSig {classes, ...}) = Sorts.inter_sort (#2 classes);
   139 
   140 fun cert_class (TSig {classes, ...}) = Sorts.certify_class (#2 classes);
   141 fun cert_sort (TSig {classes, ...}) = Sorts.certify_sort (#2 classes);
   142 
   143 fun witness_sorts (tsig as TSig {classes, log_types, ...}) =
   144   Sorts.witness_sorts (#2 classes) log_types;
   145 
   146 
   147 (* certified types *)
   148 
   149 fun bad_nargs t = "Bad number of arguments for type constructor: " ^ quote t;
   150 fun undecl_type c = "Undeclared type constructor: " ^ quote c;
   151 
   152 local
   153 
   154 fun inst_typ env (Type (c, Ts)) = Type (c, map (inst_typ env) Ts)
   155   | inst_typ env (T as TFree (x, _)) = the_default T (AList.lookup (op =) env x)
   156   | inst_typ _ T = T;
   157 
   158 fun certify_typ normalize syntax tsig ty =
   159   let
   160     val TSig {types = (_, types), ...} = tsig;
   161     fun err msg = raise TYPE (msg, [ty], []);
   162 
   163     val check_syntax =
   164       if syntax then K ()
   165       else fn c => err ("Illegal occurrence of syntactic type: " ^ quote c);
   166 
   167     fun cert (T as Type (c, Ts)) =
   168           let
   169             val Ts' = map cert Ts;
   170             fun nargs n = if length Ts <> n then err (bad_nargs c) else ();
   171           in
   172             (case Symtab.lookup types c of
   173               SOME (LogicalType n, _) => (nargs n; Type (c, Ts'))
   174             | SOME (Abbreviation (vs, U, syn), _) => (nargs (length vs);
   175                 if syn then check_syntax c else ();
   176                 if normalize then inst_typ (vs ~~ Ts') U
   177                 else Type (c, Ts'))
   178             | SOME (Nonterminal, _) => (nargs 0; check_syntax c; T)
   179             | NONE => err (undecl_type c))
   180           end
   181       | cert (TFree (x, S)) = TFree (x, cert_sort tsig S)
   182       | cert (TVar (xi as (_, i), S)) =
   183           if i < 0 then
   184             err ("Malformed type variable: " ^ quote (Term.string_of_vname xi))
   185           else TVar (xi, cert_sort tsig S);
   186 
   187     val ty' = cert ty;
   188   in if ty = ty' then ty else ty' end;  (*avoid copying of already normal type*)
   189 
   190 in
   191 
   192 val cert_typ        = certify_typ true false;
   193 val cert_typ_syntax = certify_typ true true;
   194 val cert_typ_abbrev = certify_typ false true;
   195 
   196 end;
   197 
   198 
   199 (* type arities *)
   200 
   201 fun arity_number (TSig {types = (_, types), ...}) a =
   202   (case Symtab.lookup types a of
   203     SOME (LogicalType n, _) => n
   204   | _ => error (undecl_type a));
   205 
   206 fun arity_sorts _ tsig a [] = replicate (arity_number tsig a) []
   207   | arity_sorts pp (TSig {classes, ...}) a S = Sorts.mg_domain (#2 classes) a S
   208       handle Sorts.CLASS_ERROR err => Sorts.class_error pp err;
   209 
   210 
   211 
   212 (** special treatment of type vars **)
   213 
   214 (* strip_sorts *)
   215 
   216 fun strip_sorts (Type (a, Ts)) = Type (a, map strip_sorts Ts)
   217   | strip_sorts (TFree (x, _)) = TFree (x, [])
   218   | strip_sorts (TVar (xi, _)) = TVar (xi, []);
   219 
   220 
   221 (* no_tvars *)
   222 
   223 fun no_tvars T =
   224   (case typ_tvars T of [] => T
   225   | vs => raise TYPE ("Illegal schematic type variable(s): " ^
   226       commas_quote (map (Term.string_of_vname o #1) vs), [T], []));
   227 
   228 
   229 (* varify *)
   230 
   231 fun varify fixed t =
   232   let
   233     val fs = Term.fold_types (Term.fold_atyps
   234       (fn TFree v => if member (op =) fixed v then I else insert (op =) v | _ => I)) t [];
   235     val ixns = add_term_tvar_ixns (t, []);
   236     val fmap = fs ~~ map (rpair 0) (Name.variant_list (map #1 ixns) (map fst fs))
   237     fun thaw (f as (a, S)) =
   238       (case AList.lookup (op =) fmap f of
   239         NONE => TFree f
   240       | SOME xi => TVar (xi, S));
   241   in (fmap, map_types (map_type_tfree thaw) t) end;
   242 
   243 
   244 (* freeze_thaw: freeze TVars in a term; return the "thaw" inverse *)
   245 
   246 local
   247 
   248 fun new_name (ix, (pairs, used)) =
   249   let val v = Name.variant used (string_of_indexname ix)
   250   in ((ix, v) :: pairs, v :: used) end;
   251 
   252 fun freeze_one alist (ix, sort) =
   253   TFree (the (AList.lookup (op =) alist ix), sort)
   254     handle Option =>
   255       raise TYPE ("Failure during freezing of ?" ^ string_of_indexname ix, [], []);
   256 
   257 fun thaw_one alist (a, sort) = TVar (the (AList.lookup (op =) alist a), sort)
   258   handle Option => TFree (a, sort);
   259 
   260 in
   261 
   262 (*this sort of code could replace unvarifyT*)
   263 fun freeze_thaw_type T =
   264   let
   265     val used = add_typ_tfree_names (T, [])
   266     and tvars = map #1 (add_typ_tvars (T, []));
   267     val (alist, _) = foldr new_name ([], used) tvars;
   268   in (map_type_tvar (freeze_one alist) T, map_type_tfree (thaw_one (map swap alist))) end;
   269 
   270 val freeze_type = #1 o freeze_thaw_type;
   271 
   272 fun freeze_thaw t =
   273   let
   274     val used = it_term_types add_typ_tfree_names (t, [])
   275     and tvars = map #1 (it_term_types add_typ_tvars (t, []));
   276     val (alist, _) = foldr new_name ([], used) tvars;
   277   in
   278     (case alist of
   279       [] => (t, fn x => x) (*nothing to do!*)
   280     | _ => (map_types (map_type_tvar (freeze_one alist)) t,
   281       map_types (map_type_tfree (thaw_one (map swap alist)))))
   282   end;
   283 
   284 val freeze = #1 o freeze_thaw;
   285 
   286 end;
   287 
   288 
   289 
   290 (** matching and unification of types **)
   291 
   292 type tyenv = (sort * typ) Vartab.table;
   293 
   294 fun tvar_clash ixn S S' = raise TYPE ("Type variable " ^
   295   quote (Term.string_of_vname ixn) ^ " has two distinct sorts",
   296   [TVar (ixn, S), TVar (ixn, S')], []);
   297 
   298 fun lookup (tye, (ixn, S)) =
   299   (case Vartab.lookup tye ixn of
   300     NONE => NONE
   301   | SOME (S', T) => if S = S' then SOME T else tvar_clash ixn S S');
   302 
   303 
   304 (* matching *)
   305 
   306 exception TYPE_MATCH;
   307 
   308 fun typ_match tsig =
   309   let
   310     fun match (TVar (v, S), T) subs =
   311           (case lookup (subs, (v, S)) of
   312             NONE =>
   313               if of_sort tsig (T, S) then Vartab.update_new (v, (S, T)) subs
   314               else raise TYPE_MATCH
   315           | SOME U => if U = T then subs else raise TYPE_MATCH)
   316       | match (Type (a, Ts), Type (b, Us)) subs =
   317           if a <> b then raise TYPE_MATCH
   318           else matches (Ts, Us) subs
   319       | match (TFree x, TFree y) subs =
   320           if x = y then subs else raise TYPE_MATCH
   321       | match _ _ = raise TYPE_MATCH
   322     and matches (T :: Ts, U :: Us) subs = matches (Ts, Us) (match (T, U) subs)
   323       | matches _ subs = subs;
   324   in match end;
   325 
   326 fun typ_instance tsig (T, U) =
   327   (typ_match tsig (U, T) Vartab.empty; true) handle TYPE_MATCH => false;
   328 
   329 (*purely structural matching*)
   330 fun raw_match (TVar (v, S), T) subs =
   331       (case lookup (subs, (v, S)) of
   332         NONE => Vartab.update_new (v, (S, T)) subs
   333       | SOME U => if U = T then subs else raise TYPE_MATCH)
   334   | raw_match (Type (a, Ts), Type (b, Us)) subs =
   335       if a <> b then raise TYPE_MATCH
   336       else raw_matches (Ts, Us) subs
   337   | raw_match (TFree x, TFree y) subs =
   338       if x = y then subs else raise TYPE_MATCH
   339   | raw_match _ _ = raise TYPE_MATCH
   340 and raw_matches (T :: Ts, U :: Us) subs = raw_matches (Ts, Us) (raw_match (T, U) subs)
   341   | raw_matches ([], []) subs = subs
   342   | raw_matches _ _ = raise TYPE_MATCH;
   343 
   344 fun raw_instance (T, U) =
   345   (raw_match (U, T) Vartab.empty; true) handle TYPE_MATCH => false;
   346 
   347 
   348 (* unification *)
   349 
   350 exception TUNIFY;
   351 
   352 (*occurs_check*)
   353 fun occurs v tye =
   354   let
   355     fun occ (Type (_, Ts)) = exists occ Ts
   356       | occ (TFree _) = false
   357       | occ (TVar (w, S)) =
   358           eq_ix (v, w) orelse
   359             (case lookup (tye, (w, S)) of
   360               NONE => false
   361             | SOME U => occ U);
   362   in occ end;
   363 
   364 (*chase variable assignments; if devar returns a type var then it must be unassigned*)
   365 fun devar tye (T as TVar v) =
   366       (case lookup (tye, v) of
   367         SOME U => devar tye U
   368       | NONE => T)
   369   | devar tye T = T;
   370 
   371 (*order-sorted unification*)
   372 fun unify (tsig as TSig {classes = (_, classes), ...}) TU (tyenv, maxidx) =
   373   let
   374     val tyvar_count = ref maxidx;
   375     fun gen_tyvar S = TVar (("'a", inc tyvar_count), S);
   376 
   377     fun mg_domain a S = Sorts.mg_domain classes a S
   378       handle Sorts.CLASS_ERROR _ => raise TUNIFY;
   379 
   380     fun meet (_, []) tye = tye
   381       | meet (TVar (xi, S'), S) tye =
   382           if Sorts.sort_le classes (S', S) then tye
   383           else Vartab.update_new
   384             (xi, (S', gen_tyvar (Sorts.inter_sort classes (S', S)))) tye
   385       | meet (TFree (_, S'), S) tye =
   386           if Sorts.sort_le classes (S', S) then tye
   387           else raise TUNIFY
   388       | meet (Type (a, Ts), S) tye = meets (Ts, mg_domain a S) tye
   389     and meets (T :: Ts, S :: Ss) tye = meets (Ts, Ss) (meet (devar tye T, S) tye)
   390       | meets _ tye = tye;
   391 
   392     fun unif (ty1, ty2) tye =
   393       (case (devar tye ty1, devar tye ty2) of
   394         (T as TVar (v, S1), U as TVar (w, S2)) =>
   395           if eq_ix (v, w) then
   396             if S1 = S2 then tye else tvar_clash v S1 S2
   397           else if Sorts.sort_le classes (S1, S2) then
   398             Vartab.update_new (w, (S2, T)) tye
   399           else if Sorts.sort_le classes (S2, S1) then
   400             Vartab.update_new (v, (S1, U)) tye
   401           else
   402             let val S = gen_tyvar (Sorts.inter_sort classes (S1, S2)) in
   403               Vartab.update_new (v, (S1, S)) (Vartab.update_new (w, (S2, S)) tye)
   404             end
   405       | (TVar (v, S), T) =>
   406           if occurs v tye T then raise TUNIFY
   407           else meet (T, S) (Vartab.update_new (v, (S, T)) tye)
   408       | (T, TVar (v, S)) =>
   409           if occurs v tye T then raise TUNIFY
   410           else meet (T, S) (Vartab.update_new (v, (S, T)) tye)
   411       | (Type (a, Ts), Type (b, Us)) =>
   412           if a <> b then raise TUNIFY
   413           else unifs (Ts, Us) tye
   414       | (T, U) => if T = U then tye else raise TUNIFY)
   415     and unifs (T :: Ts, U :: Us) tye = unifs (Ts, Us) (unif (T, U) tye)
   416       | unifs _ tye = tye;
   417   in (unif TU tyenv, ! tyvar_count) end;
   418 
   419 (*purely structural unification*)
   420 fun raw_unify (ty1, ty2) tye =
   421   (case (devar tye ty1, devar tye ty2) of
   422     (T as TVar (v, S1), U as TVar (w, S2)) =>
   423       if eq_ix (v, w) then
   424         if S1 = S2 then tye else tvar_clash v S1 S2
   425       else Vartab.update_new (w, (S2, T)) tye
   426   | (TVar (v, S), T) =>
   427       if occurs v tye T then raise TUNIFY
   428       else Vartab.update_new (v, (S, T)) tye
   429   | (T, TVar (v, S)) =>
   430       if occurs v tye T then raise TUNIFY
   431       else Vartab.update_new (v, (S, T)) tye
   432   | (Type (a, Ts), Type (b, Us)) =>
   433       if a <> b then raise TUNIFY
   434       else raw_unifys (Ts, Us) tye
   435   | (T, U) => if T = U then tye else raise TUNIFY)
   436 and raw_unifys (T :: Ts, U :: Us) tye = raw_unifys (Ts, Us) (raw_unify (T, U) tye)
   437   | raw_unifys ([], []) tye = tye
   438   | raw_unifys _ _ = raise TUNIFY;
   439 
   440 (*fast unification filter*)
   441 fun could_unify (Type (a, Ts), Type (b, Us)) = a = b andalso could_unifys (Ts, Us)
   442   | could_unify (TFree (a, _), TFree (b, _)) = a = b
   443   | could_unify (TVar _, _) = true
   444   | could_unify (_, TVar _) = true
   445   | could_unify _ = false
   446 and could_unifys (T :: Ts, U :: Us) = could_unify (T, U) andalso could_unifys (Ts, Us)
   447   | could_unifys ([], []) = true
   448   | could_unifys _ = false;
   449 
   450 
   451 (*equality with respect to a type environment*)
   452 fun eq_type tye (T, T') =
   453   (case (devar tye T, devar tye T') of
   454      (Type (s, Ts), Type (s', Ts')) =>
   455        s = s' andalso ListPair.all (eq_type tye) (Ts, Ts')
   456    | (U, U') => U = U');
   457 
   458 
   459 
   460 (** extend and merge type signatures **)
   461 
   462 (* classes *)
   463 
   464 fun add_class pp naming (c, cs) tsig =
   465   tsig |> map_tsig (fn ((space, classes), default, types) =>
   466     let
   467       val c' = NameSpace.full naming c;
   468       val cs' = map (cert_class tsig) cs
   469         handle TYPE (msg, _, _) => error msg;
   470       val space' = space |> NameSpace.declare naming c';
   471       val classes' = classes |> Sorts.add_class pp (c', cs');
   472     in ((space', classes'), default, types) end);
   473 
   474 fun hide_classes fully cs = map_tsig (fn ((space, classes), default, types) =>
   475   ((fold (NameSpace.hide fully) cs space, classes), default, types));
   476 
   477 
   478 (* arities *)
   479 
   480 fun add_arity pp (t, Ss, S) tsig = tsig |> map_tsig (fn ((space, classes), default, types) =>
   481   let
   482     val _ =
   483       (case Symtab.lookup (#2 types) t of
   484         SOME (LogicalType n, _) => if length Ss <> n then error (bad_nargs t) else ()
   485       | SOME (decl, _) => error ("Illegal " ^ str_of_decl decl ^ ": " ^ quote t)
   486       | NONE => error (undecl_type t));
   487     val (Ss', S') = (map (cert_sort tsig) Ss, cert_sort tsig S)
   488       handle TYPE (msg, _, _) => error msg;
   489     val classes' = classes |> Sorts.add_arities pp ((t, map (fn c' => (c', Ss')) S'));
   490   in ((space, classes'), default, types) end);
   491 
   492 
   493 (* classrel *)
   494 
   495 fun add_classrel pp rel tsig =
   496   tsig |> map_tsig (fn ((space, classes), default, types) =>
   497     let
   498       val rel' = pairself (cert_class tsig) rel
   499         handle TYPE (msg, _, _) => error msg;
   500       val classes' = classes |> Sorts.add_classrel pp rel;
   501     in ((space, classes'), default, types) end);
   502 
   503 
   504 (* default sort *)
   505 
   506 fun set_defsort S tsig = tsig |> map_tsig (fn (classes, _, types) =>
   507   (classes, cert_sort tsig S handle TYPE (msg, _, _) => error msg, types));
   508 
   509 
   510 (* types *)
   511 
   512 local
   513 
   514 fun err_neg_args c =
   515   error ("Negative number of arguments in type constructor declaration: " ^ quote c);
   516 
   517 fun err_in_decls c decl decl' =
   518   let val s = str_of_decl decl and s' = str_of_decl decl' in
   519     if s = s' then error ("Duplicate declaration of " ^ s ^ ": " ^ quote c)
   520     else error ("Conflict of " ^ s ^ " with " ^ s' ^ ": " ^ quote c)
   521   end;
   522 
   523 fun new_decl naming (c, decl) (space, types) =
   524   let
   525     val c' = NameSpace.full naming c;
   526     val space' = NameSpace.declare naming c' space;
   527     val types' =
   528       (case Symtab.lookup types c' of
   529         SOME (decl', _) => err_in_decls c' decl decl'
   530       | NONE => Symtab.update (c', (decl, serial ())) types);
   531   in (space', types') end;
   532 
   533 fun the_decl (_, types) = fst o the o Symtab.lookup types;
   534 
   535 fun map_types f = map_tsig (fn (classes, default, types) =>
   536   let
   537     val (space', tab') = f types;
   538     val _ = assert (NameSpace.intern space' "dummy" = "dummy") "Illegal declaration of dummy type";
   539   in (classes, default, (space', tab')) end);
   540 
   541 fun syntactic types (Type (c, Ts)) =
   542       (case Symtab.lookup types c of SOME (Nonterminal, _) => true | _ => false)
   543         orelse exists (syntactic types) Ts
   544   | syntactic _ _ = false;
   545 
   546 fun add_abbrev naming (a, vs, rhs) tsig = tsig |> map_types (fn types =>
   547   let
   548     fun err msg = cat_error msg ("The error(s) above occurred in type abbreviation: " ^ quote a);
   549     val rhs' = strip_sorts (no_tvars (cert_typ_syntax tsig rhs))
   550       handle TYPE (msg, _, _) => err msg;
   551   in
   552     (case duplicates (op =) vs of
   553       [] => []
   554     | dups => err ("Duplicate variables on lhs: " ^ commas_quote dups));
   555     (case subtract (op =) vs (map (#1 o #1) (typ_tvars rhs')) of
   556       [] => []
   557     | extras => err ("Extra variables on rhs: " ^ commas_quote extras));
   558     types |> new_decl naming (a, Abbreviation (vs, rhs', syntactic (#2 types) rhs'))
   559   end);
   560 
   561 in
   562 
   563 fun add_types naming ps = map_types (fold (new_decl naming) (ps |> map (fn (c, n) =>
   564   if n < 0 then err_neg_args c else (c, LogicalType n))));
   565 
   566 val add_abbrevs = fold o add_abbrev;
   567 
   568 fun add_nonterminals naming = map_types o fold (new_decl naming) o map (rpair Nonterminal);
   569 
   570 fun merge_types (types1, types2) =
   571   NameSpace.merge_tables (Library.eq_snd (op = : serial * serial -> bool)) (types1, types2)
   572     handle Symtab.DUPS (d :: _) => err_in_decls d (the_decl types1 d) (the_decl types2 d);
   573 
   574 end;
   575 
   576 fun hide_types fully cs = map_tsig (fn (classes, default, (space, types)) =>
   577   (classes, default, (fold (NameSpace.hide fully) cs space, types)));
   578 
   579 
   580 (* merge type signatures *)
   581 
   582 fun merge_tsigs pp (tsig1, tsig2) =
   583   let
   584     val (TSig {classes = (space1, classes1), default = default1, types = types1,
   585       log_types = _, witness = _}) = tsig1;
   586     val (TSig {classes = (space2, classes2), default = default2, types = types2,
   587       log_types = _, witness = _}) = tsig2;
   588 
   589     val space' = NameSpace.merge (space1, space2);
   590     val classes' = Sorts.merge_algebra pp (classes1, classes2);
   591     val default' = Sorts.inter_sort classes' (default1, default2);
   592     val types' = merge_types (types1, types2);
   593   in build_tsig ((space', classes'), default', types') end;
   594 
   595 end;