src/HOL/Analysis/Cartesian_Euclidean_Space.thy
author paulson <lp15@cam.ac.uk>
Sun Apr 15 21:41:40 2018 +0100 (16 months ago)
changeset 67986 b65c4a6a015e
parent 67982 7643b005b29a
child 68038 20b713cff87a
child 68072 493b818e8e10
permissions -rw-r--r--
quite a few more results about negligibility, etc., and a bit of tidying up
     1 section \<open>Instantiates the finite Cartesian product of Euclidean spaces as a Euclidean space\<close>
     2 
     3 theory Cartesian_Euclidean_Space
     4 imports Finite_Cartesian_Product Derivative
     5 begin
     6 
     7 lemma norm_le_componentwise:
     8    "(\<And>b. b \<in> Basis \<Longrightarrow> abs(x \<bullet> b) \<le> abs(y \<bullet> b)) \<Longrightarrow> norm x \<le> norm y"
     9   by (auto simp: norm_le euclidean_inner [of x x] euclidean_inner [of y y] abs_le_square_iff power2_eq_square intro!: sum_mono)
    10 
    11 lemma norm_le_componentwise_cart:
    12   fixes x :: "real^'n"
    13   shows "(\<And>i. abs(x$i) \<le> abs(y$i)) \<Longrightarrow> norm x \<le> norm y"
    14   unfolding cart_eq_inner_axis
    15   by (rule norm_le_componentwise) (metis axis_index)
    16   
    17 lemma subspace_special_hyperplane: "subspace {x. x $ k = 0}"
    18   by (simp add: subspace_def)
    19 
    20 lemma sum_mult_product:
    21   "sum h {..<A * B :: nat} = (\<Sum>i\<in>{..<A}. \<Sum>j\<in>{..<B}. h (j + i * B))"
    22   unfolding sum_nat_group[of h B A, unfolded atLeast0LessThan, symmetric]
    23 proof (rule sum.cong, simp, rule sum.reindex_cong)
    24   fix i
    25   show "inj_on (\<lambda>j. j + i * B) {..<B}" by (auto intro!: inj_onI)
    26   show "{i * B..<i * B + B} = (\<lambda>j. j + i * B) ` {..<B}"
    27   proof safe
    28     fix j assume "j \<in> {i * B..<i * B + B}"
    29     then show "j \<in> (\<lambda>j. j + i * B) ` {..<B}"
    30       by (auto intro!: image_eqI[of _ _ "j - i * B"])
    31   qed simp
    32 qed simp
    33 
    34 subsection\<open>Basic componentwise operations on vectors\<close>
    35 
    36 instantiation vec :: (times, finite) times
    37 begin
    38 
    39 definition "( * ) \<equiv> (\<lambda> x y.  (\<chi> i. (x$i) * (y$i)))"
    40 instance ..
    41 
    42 end
    43 
    44 instantiation vec :: (one, finite) one
    45 begin
    46 
    47 definition "1 \<equiv> (\<chi> i. 1)"
    48 instance ..
    49 
    50 end
    51 
    52 instantiation vec :: (ord, finite) ord
    53 begin
    54 
    55 definition "x \<le> y \<longleftrightarrow> (\<forall>i. x$i \<le> y$i)"
    56 definition "x < (y::'a^'b) \<longleftrightarrow> x \<le> y \<and> \<not> y \<le> x"
    57 instance ..
    58 
    59 end
    60 
    61 text\<open>The ordering on one-dimensional vectors is linear.\<close>
    62 
    63 class cart_one =
    64   assumes UNIV_one: "card (UNIV :: 'a set) = Suc 0"
    65 begin
    66 
    67 subclass finite
    68 proof
    69   from UNIV_one show "finite (UNIV :: 'a set)"
    70     by (auto intro!: card_ge_0_finite)
    71 qed
    72 
    73 end
    74 
    75 instance vec:: (order, finite) order
    76   by standard (auto simp: less_eq_vec_def less_vec_def vec_eq_iff
    77       intro: order.trans order.antisym order.strict_implies_order)
    78 
    79 instance vec :: (linorder, cart_one) linorder
    80 proof
    81   obtain a :: 'b where all: "\<And>P. (\<forall>i. P i) \<longleftrightarrow> P a"
    82   proof -
    83     have "card (UNIV :: 'b set) = Suc 0" by (rule UNIV_one)
    84     then obtain b :: 'b where "UNIV = {b}" by (auto iff: card_Suc_eq)
    85     then have "\<And>P. (\<forall>i\<in>UNIV. P i) \<longleftrightarrow> P b" by auto
    86     then show thesis by (auto intro: that)
    87   qed
    88   fix x y :: "'a^'b::cart_one"
    89   note [simp] = less_eq_vec_def less_vec_def all vec_eq_iff field_simps
    90   show "x \<le> y \<or> y \<le> x" by auto
    91 qed
    92 
    93 text\<open>Constant Vectors\<close>
    94 
    95 definition "vec x = (\<chi> i. x)"
    96 
    97 lemma interval_cbox_cart: "{a::real^'n..b} = cbox a b"
    98   by (auto simp add: less_eq_vec_def mem_box Basis_vec_def inner_axis)
    99 
   100 text\<open>Also the scalar-vector multiplication.\<close>
   101 
   102 definition vector_scalar_mult:: "'a::times \<Rightarrow> 'a ^ 'n \<Rightarrow> 'a ^ 'n" (infixl "*s" 70)
   103   where "c *s x = (\<chi> i. c * (x$i))"
   104 
   105 
   106 subsection \<open>A naive proof procedure to lift really trivial arithmetic stuff from the basis of the vector space\<close>
   107 
   108 lemma sum_cong_aux:
   109   "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> sum f A = sum g A"
   110   by (auto intro: sum.cong)
   111 
   112 hide_fact (open) sum_cong_aux
   113 
   114 method_setup vector = \<open>
   115 let
   116   val ss1 =
   117     simpset_of (put_simpset HOL_basic_ss @{context}
   118       addsimps [@{thm sum.distrib} RS sym,
   119       @{thm sum_subtractf} RS sym, @{thm sum_distrib_left},
   120       @{thm sum_distrib_right}, @{thm sum_negf} RS sym])
   121   val ss2 =
   122     simpset_of (@{context} addsimps
   123              [@{thm plus_vec_def}, @{thm times_vec_def},
   124               @{thm minus_vec_def}, @{thm uminus_vec_def},
   125               @{thm one_vec_def}, @{thm zero_vec_def}, @{thm vec_def},
   126               @{thm scaleR_vec_def},
   127               @{thm vec_lambda_beta}, @{thm vector_scalar_mult_def}])
   128   fun vector_arith_tac ctxt ths =
   129     simp_tac (put_simpset ss1 ctxt)
   130     THEN' (fn i => resolve_tac ctxt @{thms Cartesian_Euclidean_Space.sum_cong_aux} i
   131          ORELSE resolve_tac ctxt @{thms sum.neutral} i
   132          ORELSE simp_tac (put_simpset HOL_basic_ss ctxt addsimps [@{thm vec_eq_iff}]) i)
   133     (* THEN' TRY o clarify_tac HOL_cs  THEN' (TRY o rtac @{thm iffI}) *)
   134     THEN' asm_full_simp_tac (put_simpset ss2 ctxt addsimps ths)
   135 in
   136   Attrib.thms >> (fn ths => fn ctxt => SIMPLE_METHOD' (vector_arith_tac ctxt ths))
   137 end
   138 \<close> "lift trivial vector statements to real arith statements"
   139 
   140 lemma vec_0[simp]: "vec 0 = 0" by vector
   141 lemma vec_1[simp]: "vec 1 = 1" by vector
   142 
   143 lemma vec_inj[simp]: "vec x = vec y \<longleftrightarrow> x = y" by vector
   144 
   145 lemma vec_in_image_vec: "vec x \<in> (vec ` S) \<longleftrightarrow> x \<in> S" by auto
   146 
   147 lemma vec_add: "vec(x + y) = vec x + vec y"  by vector
   148 lemma vec_sub: "vec(x - y) = vec x - vec y" by vector
   149 lemma vec_cmul: "vec(c * x) = c *s vec x " by vector
   150 lemma vec_neg: "vec(- x) = - vec x " by vector
   151 
   152 lemma vec_scaleR: "vec(c * x) = c *\<^sub>R vec x"
   153   by vector
   154 
   155 lemma vec_sum:
   156   assumes "finite S"
   157   shows "vec(sum f S) = sum (vec \<circ> f) S"
   158   using assms
   159 proof induct
   160   case empty
   161   then show ?case by simp
   162 next
   163   case insert
   164   then show ?case by (auto simp add: vec_add)
   165 qed
   166 
   167 text\<open>Obvious "component-pushing".\<close>
   168 
   169 lemma vec_component [simp]: "vec x $ i = x"
   170   by vector
   171 
   172 lemma vector_mult_component [simp]: "(x * y)$i = x$i * y$i"
   173   by vector
   174 
   175 lemma vector_smult_component [simp]: "(c *s y)$i = c * (y$i)"
   176   by vector
   177 
   178 lemma cond_component: "(if b then x else y)$i = (if b then x$i else y$i)" by vector
   179 
   180 lemmas vector_component =
   181   vec_component vector_add_component vector_mult_component
   182   vector_smult_component vector_minus_component vector_uminus_component
   183   vector_scaleR_component cond_component
   184 
   185 
   186 subsection \<open>Some frequently useful arithmetic lemmas over vectors\<close>
   187 
   188 instance vec :: (semigroup_mult, finite) semigroup_mult
   189   by standard (vector mult.assoc)
   190 
   191 instance vec :: (monoid_mult, finite) monoid_mult
   192   by standard vector+
   193 
   194 instance vec :: (ab_semigroup_mult, finite) ab_semigroup_mult
   195   by standard (vector mult.commute)
   196 
   197 instance vec :: (comm_monoid_mult, finite) comm_monoid_mult
   198   by standard vector
   199 
   200 instance vec :: (semiring, finite) semiring
   201   by standard (vector field_simps)+
   202 
   203 instance vec :: (semiring_0, finite) semiring_0
   204   by standard (vector field_simps)+
   205 instance vec :: (semiring_1, finite) semiring_1
   206   by standard vector
   207 instance vec :: (comm_semiring, finite) comm_semiring
   208   by standard (vector field_simps)+
   209 
   210 instance vec :: (comm_semiring_0, finite) comm_semiring_0 ..
   211 instance vec :: (cancel_comm_monoid_add, finite) cancel_comm_monoid_add ..
   212 instance vec :: (semiring_0_cancel, finite) semiring_0_cancel ..
   213 instance vec :: (comm_semiring_0_cancel, finite) comm_semiring_0_cancel ..
   214 instance vec :: (ring, finite) ring ..
   215 instance vec :: (semiring_1_cancel, finite) semiring_1_cancel ..
   216 instance vec :: (comm_semiring_1, finite) comm_semiring_1 ..
   217 
   218 instance vec :: (ring_1, finite) ring_1 ..
   219 
   220 instance vec :: (real_algebra, finite) real_algebra
   221   by standard (simp_all add: vec_eq_iff)
   222 
   223 instance vec :: (real_algebra_1, finite) real_algebra_1 ..
   224 
   225 lemma of_nat_index: "(of_nat n :: 'a::semiring_1 ^'n)$i = of_nat n"
   226 proof (induct n)
   227   case 0
   228   then show ?case by vector
   229 next
   230   case Suc
   231   then show ?case by vector
   232 qed
   233 
   234 lemma one_index [simp]: "(1 :: 'a :: one ^ 'n) $ i = 1"
   235   by vector
   236 
   237 lemma neg_one_index [simp]: "(- 1 :: 'a :: {one, uminus} ^ 'n) $ i = - 1"
   238   by vector
   239 
   240 instance vec :: (semiring_char_0, finite) semiring_char_0
   241 proof
   242   fix m n :: nat
   243   show "inj (of_nat :: nat \<Rightarrow> 'a ^ 'b)"
   244     by (auto intro!: injI simp add: vec_eq_iff of_nat_index)
   245 qed
   246 
   247 instance vec :: (numeral, finite) numeral ..
   248 instance vec :: (semiring_numeral, finite) semiring_numeral ..
   249 
   250 lemma numeral_index [simp]: "numeral w $ i = numeral w"
   251   by (induct w) (simp_all only: numeral.simps vector_add_component one_index)
   252 
   253 lemma neg_numeral_index [simp]: "- numeral w $ i = - numeral w"
   254   by (simp only: vector_uminus_component numeral_index)
   255 
   256 instance vec :: (comm_ring_1, finite) comm_ring_1 ..
   257 instance vec :: (ring_char_0, finite) ring_char_0 ..
   258 
   259 lemma vector_smult_assoc: "a *s (b *s x) = ((a::'a::semigroup_mult) * b) *s x"
   260   by (vector mult.assoc)
   261 lemma vector_sadd_rdistrib: "((a::'a::semiring) + b) *s x = a *s x + b *s x"
   262   by (vector field_simps)
   263 lemma vector_add_ldistrib: "(c::'a::semiring) *s (x + y) = c *s x + c *s y"
   264   by (vector field_simps)
   265 lemma vector_smult_lzero[simp]: "(0::'a::mult_zero) *s x = 0" by vector
   266 lemma vector_smult_lid[simp]: "(1::'a::monoid_mult) *s x = x" by vector
   267 lemma vector_ssub_ldistrib: "(c::'a::ring) *s (x - y) = c *s x - c *s y"
   268   by (vector field_simps)
   269 lemma vector_smult_rneg: "(c::'a::ring) *s -x = -(c *s x)" by vector
   270 lemma vector_smult_lneg: "- (c::'a::ring) *s x = -(c *s x)" by vector
   271 lemma vector_sneg_minus1: "-x = (-1::'a::ring_1) *s x" by vector
   272 lemma vector_smult_rzero[simp]: "c *s 0 = (0::'a::mult_zero ^ 'n)" by vector
   273 lemma vector_sub_rdistrib: "((a::'a::ring) - b) *s x = a *s x - b *s x"
   274   by (vector field_simps)
   275 
   276 lemma vec_eq[simp]: "(vec m = vec n) \<longleftrightarrow> (m = n)"
   277   by (simp add: vec_eq_iff)
   278 
   279 lemma linear_vec [simp]: "linear vec"
   280   by (simp add: linearI vec_add vec_eq_iff)
   281 
   282 lemma differentiable_vec:
   283   fixes S :: "'a::euclidean_space set"
   284   shows "vec differentiable_on S"
   285   by (simp add: linear_linear bounded_linear_imp_differentiable_on)
   286 
   287 lemma continuous_vec [continuous_intros]:
   288   fixes x :: "'a::euclidean_space"
   289   shows "isCont vec x"
   290   apply (clarsimp simp add: continuous_def LIM_def dist_vec_def L2_set_def)
   291   apply (rule_tac x="r / sqrt (real CARD('b))" in exI)
   292   by (simp add: mult.commute pos_less_divide_eq real_sqrt_mult)
   293 
   294 lemma box_vec_eq_empty [simp]:
   295   shows "cbox (vec a) (vec b) = {} \<longleftrightarrow> cbox a b = {}"
   296         "box (vec a) (vec b) = {} \<longleftrightarrow> box a b = {}"
   297   by (auto simp: Basis_vec_def mem_box box_eq_empty inner_axis)
   298 
   299 lemma norm_eq_0_imp: "norm x = 0 ==> x = (0::real ^'n)" by (metis norm_eq_zero)
   300 
   301 lemma norm_axis_1 [simp]: "norm (axis m (1::real)) = 1"
   302   by (simp add: inner_axis' norm_eq_1)
   303 
   304 lemma vector_mul_eq_0[simp]: "(a *s x = 0) \<longleftrightarrow> a = (0::'a::idom) \<or> x = 0"
   305   by vector
   306 
   307 lemma vector_mul_lcancel[simp]: "a *s x = a *s y \<longleftrightarrow> a = (0::real) \<or> x = y"
   308   by (metis eq_iff_diff_eq_0 vector_mul_eq_0 vector_ssub_ldistrib)
   309 
   310 lemma vector_mul_rcancel[simp]: "a *s x = b *s x \<longleftrightarrow> (a::real) = b \<or> x = 0"
   311   by (metis eq_iff_diff_eq_0 vector_mul_eq_0 vector_sub_rdistrib)
   312 
   313 lemma vector_mul_lcancel_imp: "a \<noteq> (0::real) ==>  a *s x = a *s y ==> (x = y)"
   314   by (metis vector_mul_lcancel)
   315 
   316 lemma vector_mul_rcancel_imp: "x \<noteq> 0 \<Longrightarrow> (a::real) *s x = b *s x ==> a = b"
   317   by (metis vector_mul_rcancel)
   318 
   319 lemma component_le_norm_cart: "\<bar>x$i\<bar> \<le> norm x"
   320   apply (simp add: norm_vec_def)
   321   apply (rule member_le_L2_set, simp_all)
   322   done
   323 
   324 lemma norm_bound_component_le_cart: "norm x \<le> e ==> \<bar>x$i\<bar> \<le> e"
   325   by (metis component_le_norm_cart order_trans)
   326 
   327 lemma norm_bound_component_lt_cart: "norm x < e ==> \<bar>x$i\<bar> < e"
   328   by (metis component_le_norm_cart le_less_trans)
   329 
   330 lemma norm_le_l1_cart: "norm x \<le> sum(\<lambda>i. \<bar>x$i\<bar>) UNIV"
   331   by (simp add: norm_vec_def L2_set_le_sum)
   332 
   333 lemma scalar_mult_eq_scaleR [simp]: "c *s x = c *\<^sub>R x"
   334   unfolding scaleR_vec_def vector_scalar_mult_def by simp
   335 
   336 lemma dist_mul[simp]: "dist (c *s x) (c *s y) = \<bar>c\<bar> * dist x y"
   337   unfolding dist_norm scalar_mult_eq_scaleR
   338   unfolding scaleR_right_diff_distrib[symmetric] by simp
   339 
   340 lemma sum_component [simp]:
   341   fixes f:: " 'a \<Rightarrow> ('b::comm_monoid_add) ^'n"
   342   shows "(sum f S)$i = sum (\<lambda>x. (f x)$i) S"
   343 proof (cases "finite S")
   344   case True
   345   then show ?thesis by induct simp_all
   346 next
   347   case False
   348   then show ?thesis by simp
   349 qed
   350 
   351 lemma sum_eq: "sum f S = (\<chi> i. sum (\<lambda>x. (f x)$i ) S)"
   352   by (simp add: vec_eq_iff)
   353 
   354 lemma sum_cmul:
   355   fixes f:: "'c \<Rightarrow> ('a::semiring_1)^'n"
   356   shows "sum (\<lambda>x. c *s f x) S = c *s sum f S"
   357   by (simp add: vec_eq_iff sum_distrib_left)
   358 
   359 lemma sum_norm_allsubsets_bound_cart:
   360   fixes f:: "'a \<Rightarrow> real ^'n"
   361   assumes fP: "finite P" and fPs: "\<And>Q. Q \<subseteq> P \<Longrightarrow> norm (sum f Q) \<le> e"
   362   shows "sum (\<lambda>x. norm (f x)) P \<le> 2 * real CARD('n) *  e"
   363   using sum_norm_allsubsets_bound[OF assms]
   364   by simp
   365 
   366 subsection\<open>Closures and interiors of halfspaces\<close>
   367 
   368 lemma interior_halfspace_le [simp]:
   369   assumes "a \<noteq> 0"
   370     shows "interior {x. a \<bullet> x \<le> b} = {x. a \<bullet> x < b}"
   371 proof -
   372   have *: "a \<bullet> x < b" if x: "x \<in> S" and S: "S \<subseteq> {x. a \<bullet> x \<le> b}" and "open S" for S x
   373   proof -
   374     obtain e where "e>0" and e: "cball x e \<subseteq> S"
   375       using \<open>open S\<close> open_contains_cball x by blast
   376     then have "x + (e / norm a) *\<^sub>R a \<in> cball x e"
   377       by (simp add: dist_norm)
   378     then have "x + (e / norm a) *\<^sub>R a \<in> S"
   379       using e by blast
   380     then have "x + (e / norm a) *\<^sub>R a \<in> {x. a \<bullet> x \<le> b}"
   381       using S by blast
   382     moreover have "e * (a \<bullet> a) / norm a > 0"
   383       by (simp add: \<open>0 < e\<close> assms)
   384     ultimately show ?thesis
   385       by (simp add: algebra_simps)
   386   qed
   387   show ?thesis
   388     by (rule interior_unique) (auto simp: open_halfspace_lt *)
   389 qed
   390 
   391 lemma interior_halfspace_ge [simp]:
   392    "a \<noteq> 0 \<Longrightarrow> interior {x. a \<bullet> x \<ge> b} = {x. a \<bullet> x > b}"
   393 using interior_halfspace_le [of "-a" "-b"] by simp
   394 
   395 lemma interior_halfspace_component_le [simp]:
   396      "interior {x. x$k \<le> a} = {x :: (real^'n). x$k < a}" (is "?LE")
   397   and interior_halfspace_component_ge [simp]:
   398      "interior {x. x$k \<ge> a} = {x :: (real^'n). x$k > a}" (is "?GE")
   399 proof -
   400   have "axis k (1::real) \<noteq> 0"
   401     by (simp add: axis_def vec_eq_iff)
   402   moreover have "axis k (1::real) \<bullet> x = x$k" for x
   403     by (simp add: cart_eq_inner_axis inner_commute)
   404   ultimately show ?LE ?GE
   405     using interior_halfspace_le [of "axis k (1::real)" a]
   406           interior_halfspace_ge [of "axis k (1::real)" a] by auto
   407 qed
   408 
   409 lemma closure_halfspace_lt [simp]:
   410   assumes "a \<noteq> 0"
   411     shows "closure {x. a \<bullet> x < b} = {x. a \<bullet> x \<le> b}"
   412 proof -
   413   have [simp]: "-{x. a \<bullet> x < b} = {x. a \<bullet> x \<ge> b}"
   414     by (force simp:)
   415   then show ?thesis
   416     using interior_halfspace_ge [of a b] assms
   417     by (force simp: closure_interior)
   418 qed
   419 
   420 lemma closure_halfspace_gt [simp]:
   421    "a \<noteq> 0 \<Longrightarrow> closure {x. a \<bullet> x > b} = {x. a \<bullet> x \<ge> b}"
   422 using closure_halfspace_lt [of "-a" "-b"] by simp
   423 
   424 lemma closure_halfspace_component_lt [simp]:
   425      "closure {x. x$k < a} = {x :: (real^'n). x$k \<le> a}" (is "?LE")
   426   and closure_halfspace_component_gt [simp]:
   427      "closure {x. x$k > a} = {x :: (real^'n). x$k \<ge> a}" (is "?GE")
   428 proof -
   429   have "axis k (1::real) \<noteq> 0"
   430     by (simp add: axis_def vec_eq_iff)
   431   moreover have "axis k (1::real) \<bullet> x = x$k" for x
   432     by (simp add: cart_eq_inner_axis inner_commute)
   433   ultimately show ?LE ?GE
   434     using closure_halfspace_lt [of "axis k (1::real)" a]
   435           closure_halfspace_gt [of "axis k (1::real)" a] by auto
   436 qed
   437 
   438 lemma interior_hyperplane [simp]:
   439   assumes "a \<noteq> 0"
   440     shows "interior {x. a \<bullet> x = b} = {}"
   441 proof -
   442   have [simp]: "{x. a \<bullet> x = b} = {x. a \<bullet> x \<le> b} \<inter> {x. a \<bullet> x \<ge> b}"
   443     by (force simp:)
   444   then show ?thesis
   445     by (auto simp: assms)
   446 qed
   447 
   448 lemma frontier_halfspace_le:
   449   assumes "a \<noteq> 0 \<or> b \<noteq> 0"
   450     shows "frontier {x. a \<bullet> x \<le> b} = {x. a \<bullet> x = b}"
   451 proof (cases "a = 0")
   452   case True with assms show ?thesis by simp
   453 next
   454   case False then show ?thesis
   455     by (force simp: frontier_def closed_halfspace_le)
   456 qed
   457 
   458 lemma frontier_halfspace_ge:
   459   assumes "a \<noteq> 0 \<or> b \<noteq> 0"
   460     shows "frontier {x. a \<bullet> x \<ge> b} = {x. a \<bullet> x = b}"
   461 proof (cases "a = 0")
   462   case True with assms show ?thesis by simp
   463 next
   464   case False then show ?thesis
   465     by (force simp: frontier_def closed_halfspace_ge)
   466 qed
   467 
   468 lemma frontier_halfspace_lt:
   469   assumes "a \<noteq> 0 \<or> b \<noteq> 0"
   470     shows "frontier {x. a \<bullet> x < b} = {x. a \<bullet> x = b}"
   471 proof (cases "a = 0")
   472   case True with assms show ?thesis by simp
   473 next
   474   case False then show ?thesis
   475     by (force simp: frontier_def interior_open open_halfspace_lt)
   476 qed
   477 
   478 lemma frontier_halfspace_gt:
   479   assumes "a \<noteq> 0 \<or> b \<noteq> 0"
   480     shows "frontier {x. a \<bullet> x > b} = {x. a \<bullet> x = b}"
   481 proof (cases "a = 0")
   482   case True with assms show ?thesis by simp
   483 next
   484   case False then show ?thesis
   485     by (force simp: frontier_def interior_open open_halfspace_gt)
   486 qed
   487 
   488 lemma interior_standard_hyperplane:
   489    "interior {x :: (real^'n). x$k = a} = {}"
   490 proof -
   491   have "axis k (1::real) \<noteq> 0"
   492     by (simp add: axis_def vec_eq_iff)
   493   moreover have "axis k (1::real) \<bullet> x = x$k" for x
   494     by (simp add: cart_eq_inner_axis inner_commute)
   495   ultimately show ?thesis
   496     using interior_hyperplane [of "axis k (1::real)" a]
   497     by force
   498 qed
   499 
   500 subsection \<open>Matrix operations\<close>
   501 
   502 text\<open>Matrix notation. NB: an MxN matrix is of type @{typ "'a^'n^'m"}, not @{typ "'a^'m^'n"}\<close>
   503 
   504 definition map_matrix::"('a \<Rightarrow> 'b) \<Rightarrow> (('a, 'i::finite)vec, 'j::finite) vec \<Rightarrow> (('b, 'i)vec, 'j) vec" where
   505   "map_matrix f x = (\<chi> i j. f (x $ i $ j))"
   506 
   507 lemma nth_map_matrix[simp]: "map_matrix f x $ i $ j = f (x $ i $ j)"
   508   by (simp add: map_matrix_def)
   509 
   510 definition matrix_matrix_mult :: "('a::semiring_1) ^'n^'m \<Rightarrow> 'a ^'p^'n \<Rightarrow> 'a ^ 'p ^'m"
   511     (infixl "**" 70)
   512   where "m ** m' == (\<chi> i j. sum (\<lambda>k. ((m$i)$k) * ((m'$k)$j)) (UNIV :: 'n set)) ::'a ^ 'p ^'m"
   513 
   514 definition matrix_vector_mult :: "('a::semiring_1) ^'n^'m \<Rightarrow> 'a ^'n \<Rightarrow> 'a ^ 'm"
   515     (infixl "*v" 70)
   516   where "m *v x \<equiv> (\<chi> i. sum (\<lambda>j. ((m$i)$j) * (x$j)) (UNIV ::'n set)) :: 'a^'m"
   517 
   518 definition vector_matrix_mult :: "'a ^ 'm \<Rightarrow> ('a::semiring_1) ^'n^'m \<Rightarrow> 'a ^'n "
   519     (infixl "v*" 70)
   520   where "v v* m == (\<chi> j. sum (\<lambda>i. ((m$i)$j) * (v$i)) (UNIV :: 'm set)) :: 'a^'n"
   521 
   522 definition "(mat::'a::zero => 'a ^'n^'n) k = (\<chi> i j. if i = j then k else 0)"
   523 definition transpose where
   524   "(transpose::'a^'n^'m \<Rightarrow> 'a^'m^'n) A = (\<chi> i j. ((A$j)$i))"
   525 definition "(row::'m => 'a ^'n^'m \<Rightarrow> 'a ^'n) i A = (\<chi> j. ((A$i)$j))"
   526 definition "(column::'n =>'a^'n^'m =>'a^'m) j A = (\<chi> i. ((A$i)$j))"
   527 definition "rows(A::'a^'n^'m) = { row i A | i. i \<in> (UNIV :: 'm set)}"
   528 definition "columns(A::'a^'n^'m) = { column i A | i. i \<in> (UNIV :: 'n set)}"
   529 
   530 lemma mat_0[simp]: "mat 0 = 0" by (vector mat_def)
   531 lemma matrix_add_ldistrib: "(A ** (B + C)) = (A ** B) + (A ** C)"
   532   by (vector matrix_matrix_mult_def sum.distrib[symmetric] field_simps)
   533 
   534 lemma matrix_mul_lid [simp]:
   535   fixes A :: "'a::semiring_1 ^ 'm ^ 'n"
   536   shows "mat 1 ** A = A"
   537   apply (simp add: matrix_matrix_mult_def mat_def)
   538   apply vector
   539   apply (auto simp only: if_distrib cond_application_beta sum.delta'[OF finite]
   540     mult_1_left mult_zero_left if_True UNIV_I)
   541   done
   542 
   543 lemma matrix_mul_rid [simp]:
   544   fixes A :: "'a::semiring_1 ^ 'm ^ 'n"
   545   shows "A ** mat 1 = A"
   546   apply (simp add: matrix_matrix_mult_def mat_def)
   547   apply vector
   548   apply (auto simp only: if_distrib cond_application_beta sum.delta[OF finite]
   549     mult_1_right mult_zero_right if_True UNIV_I cong: if_cong)
   550   done
   551 
   552 lemma matrix_mul_assoc: "A ** (B ** C) = (A ** B) ** C"
   553   apply (vector matrix_matrix_mult_def sum_distrib_left sum_distrib_right mult.assoc)
   554   apply (subst sum.swap)
   555   apply simp
   556   done
   557 
   558 lemma matrix_vector_mul_assoc: "A *v (B *v x) = (A ** B) *v x"
   559   apply (vector matrix_matrix_mult_def matrix_vector_mult_def
   560     sum_distrib_left sum_distrib_right mult.assoc)
   561   apply (subst sum.swap)
   562   apply simp
   563   done
   564 
   565 lemma matrix_vector_mul_lid [simp]: "mat 1 *v x = (x::'a::semiring_1 ^ 'n)"
   566   apply (vector matrix_vector_mult_def mat_def)
   567   apply (simp add: if_distrib cond_application_beta sum.delta' cong del: if_weak_cong)
   568   done
   569 
   570 lemma matrix_transpose_mul:
   571     "transpose(A ** B) = transpose B ** transpose (A::'a::comm_semiring_1^_^_)"
   572   by (simp add: matrix_matrix_mult_def transpose_def vec_eq_iff mult.commute)
   573 
   574 lemma matrix_eq:
   575   fixes A B :: "'a::semiring_1 ^ 'n ^ 'm"
   576   shows "A = B \<longleftrightarrow>  (\<forall>x. A *v x = B *v x)" (is "?lhs \<longleftrightarrow> ?rhs")
   577   apply auto
   578   apply (subst vec_eq_iff)
   579   apply clarify
   580   apply (clarsimp simp add: matrix_vector_mult_def if_distrib cond_application_beta vec_eq_iff cong del: if_weak_cong)
   581   apply (erule_tac x="axis ia 1" in allE)
   582   apply (erule_tac x="i" in allE)
   583   apply (auto simp add: if_distrib cond_application_beta axis_def
   584     sum.delta[OF finite] cong del: if_weak_cong)
   585   done
   586 
   587 lemma matrix_vector_mul_component: "((A::real^_^_) *v x)$k = (A$k) \<bullet> x"
   588   by (simp add: matrix_vector_mult_def inner_vec_def)
   589 
   590 lemma dot_lmul_matrix: "((x::real ^_) v* A) \<bullet> y = x \<bullet> (A *v y)"
   591   apply (simp add: inner_vec_def matrix_vector_mult_def vector_matrix_mult_def sum_distrib_right sum_distrib_left ac_simps)
   592   apply (subst sum.swap)
   593   apply simp
   594   done
   595 
   596 lemma transpose_mat [simp]: "transpose (mat n) = mat n"
   597   by (vector transpose_def mat_def)
   598 
   599 lemma transpose_transpose [simp]: "transpose(transpose A) = A"
   600   by (vector transpose_def)
   601 
   602 lemma row_transpose [simp]:
   603   fixes A:: "'a::semiring_1^_^_"
   604   shows "row i (transpose A) = column i A"
   605   by (simp add: row_def column_def transpose_def vec_eq_iff)
   606 
   607 lemma column_transpose [simp]:
   608   fixes A:: "'a::semiring_1^_^_"
   609   shows "column i (transpose A) = row i A"
   610   by (simp add: row_def column_def transpose_def vec_eq_iff)
   611 
   612 lemma rows_transpose [simp]: "rows(transpose (A::'a::semiring_1^_^_)) = columns A"
   613   by (auto simp add: rows_def columns_def row_transpose intro: set_eqI)
   614 
   615 lemma columns_transpose [simp]: "columns(transpose (A::'a::semiring_1^_^_)) = rows A"
   616   by (metis transpose_transpose rows_transpose)
   617 
   618 lemma matrix_mult_transpose_dot_column:
   619   fixes A :: "real^'n^'n"
   620   shows "transpose A ** A = (\<chi> i j. (column i A) \<bullet> (column j A))"
   621   by (simp add: matrix_matrix_mult_def vec_eq_iff transpose_def column_def inner_vec_def)
   622 
   623 lemma matrix_mult_transpose_dot_row:
   624   fixes A :: "real^'n^'n"
   625   shows "A ** transpose A = (\<chi> i j. (row i A) \<bullet> (row j A))"
   626   by (simp add: matrix_matrix_mult_def vec_eq_iff transpose_def row_def inner_vec_def)
   627 
   628 text\<open>Two sometimes fruitful ways of looking at matrix-vector multiplication.\<close>
   629 
   630 lemma matrix_mult_dot: "A *v x = (\<chi> i. A$i \<bullet> x)"
   631   by (simp add: matrix_vector_mult_def inner_vec_def)
   632 
   633 lemma matrix_mult_sum:
   634   "(A::'a::comm_semiring_1^'n^'m) *v x = sum (\<lambda>i. (x$i) *s column i A) (UNIV:: 'n set)"
   635   by (simp add: matrix_vector_mult_def vec_eq_iff column_def mult.commute)
   636 
   637 lemma vector_componentwise:
   638   "(x::'a::ring_1^'n) = (\<chi> j. \<Sum>i\<in>UNIV. (x$i) * (axis i 1 :: 'a^'n) $ j)"
   639   by (simp add: axis_def if_distrib sum.If_cases vec_eq_iff)
   640 
   641 lemma basis_expansion: "sum (\<lambda>i. (x$i) *s axis i 1) UNIV = (x::('a::ring_1) ^'n)"
   642   by (auto simp add: axis_def vec_eq_iff if_distrib sum.If_cases cong del: if_weak_cong)
   643 
   644 lemma linear_componentwise_expansion:
   645   fixes f:: "real ^'m \<Rightarrow> real ^ _"
   646   assumes lf: "linear f"
   647   shows "(f x)$j = sum (\<lambda>i. (x$i) * (f (axis i 1)$j)) (UNIV :: 'm set)" (is "?lhs = ?rhs")
   648 proof -
   649   let ?M = "(UNIV :: 'm set)"
   650   let ?N = "(UNIV :: 'n set)"
   651   have "?rhs = (sum (\<lambda>i.(x$i) *\<^sub>R f (axis i 1) ) ?M)$j"
   652     unfolding sum_component by simp
   653   then show ?thesis
   654     unfolding linear_sum_mul[OF lf, symmetric]
   655     unfolding scalar_mult_eq_scaleR[symmetric]
   656     unfolding basis_expansion
   657     by simp
   658 qed
   659 
   660 subsection\<open>Inverse matrices  (not necessarily square)\<close>
   661 
   662 definition
   663   "invertible(A::'a::semiring_1^'n^'m) \<longleftrightarrow> (\<exists>A'::'a^'m^'n. A ** A' = mat 1 \<and> A' ** A = mat 1)"
   664 
   665 definition
   666   "matrix_inv(A:: 'a::semiring_1^'n^'m) =
   667     (SOME A'::'a^'m^'n. A ** A' = mat 1 \<and> A' ** A = mat 1)"
   668 
   669 text\<open>Correspondence between matrices and linear operators.\<close>
   670 
   671 definition matrix :: "('a::{plus,times, one, zero}^'m \<Rightarrow> 'a ^ 'n) \<Rightarrow> 'a^'m^'n"
   672   where "matrix f = (\<chi> i j. (f(axis j 1))$i)"
   673 
   674 lemma matrix_id_mat_1: "matrix id = mat 1"
   675   by (simp add: mat_def matrix_def axis_def)
   676 
   677 lemma matrix_scaleR: "(matrix (( *\<^sub>R) r)) = mat r"
   678   by (simp add: mat_def matrix_def axis_def if_distrib cong: if_cong)
   679 
   680 lemma matrix_vector_mul_linear: "linear(\<lambda>x. A *v (x::real ^ _))"
   681   by (simp add: linear_iff matrix_vector_mult_def vec_eq_iff
   682       field_simps sum_distrib_left sum.distrib)
   683 
   684 lemma
   685   fixes A :: "real^'n^'m"
   686   shows matrix_vector_mult_linear_continuous_at [continuous_intros]: "isCont (( *v) A) z"
   687     and matrix_vector_mult_linear_continuous_on [continuous_intros]: "continuous_on S (( *v) A)"
   688   by (simp_all add: linear_linear linear_continuous_at linear_continuous_on matrix_vector_mul_linear)
   689 
   690 lemma matrix_vector_mult_add_distrib [algebra_simps]:
   691   "A *v (x + y) = A *v x + A *v y"
   692   by (vector matrix_vector_mult_def sum.distrib distrib_left)
   693 
   694 lemma matrix_vector_mult_diff_distrib [algebra_simps]:
   695   fixes A :: "'a::ring_1^'n^'m"
   696   shows "A *v (x - y) = A *v x - A *v y"
   697   by (vector matrix_vector_mult_def sum_subtractf right_diff_distrib)
   698 
   699 lemma matrix_vector_mult_scaleR[algebra_simps]:
   700   fixes A :: "real^'n^'m"
   701   shows "A *v (c *\<^sub>R x) = c *\<^sub>R (A *v x)"
   702   using linear_iff matrix_vector_mul_linear by blast
   703 
   704 lemma matrix_vector_mult_0_right [simp]: "A *v 0 = 0"
   705   by (simp add: matrix_vector_mult_def vec_eq_iff)
   706 
   707 lemma matrix_vector_mult_0 [simp]: "0 *v w = 0"
   708   by (simp add: matrix_vector_mult_def vec_eq_iff)
   709 
   710 lemma matrix_vector_mult_add_rdistrib [algebra_simps]:
   711   "(A + B) *v x = (A *v x) + (B *v x)"
   712   by (vector matrix_vector_mult_def sum.distrib distrib_right)
   713 
   714 lemma matrix_vector_mult_diff_rdistrib [algebra_simps]:
   715   fixes A :: "'a :: ring_1^'n^'m"
   716   shows "(A - B) *v x = (A *v x) - (B *v x)"
   717   by (vector matrix_vector_mult_def sum_subtractf left_diff_distrib)
   718 
   719 lemma matrix_works:
   720   assumes lf: "linear f"
   721   shows "matrix f *v x = f (x::real ^ 'n)"
   722   apply (simp add: matrix_def matrix_vector_mult_def vec_eq_iff mult.commute)
   723   by (simp add: linear_componentwise_expansion lf)
   724 
   725 lemma matrix_vector_mul: "linear f ==> f = (\<lambda>x. matrix f *v (x::real ^ 'n))"
   726   by (simp add: ext matrix_works)
   727 
   728 declare matrix_vector_mul [symmetric, simp]
   729 
   730 lemma matrix_of_matrix_vector_mul [simp]: "matrix(\<lambda>x. A *v (x :: real ^ 'n)) = A"
   731   by (simp add: matrix_eq matrix_vector_mul_linear matrix_works)
   732 
   733 lemma matrix_compose:
   734   assumes lf: "linear (f::real^'n \<Rightarrow> real^'m)"
   735     and lg: "linear (g::real^'m \<Rightarrow> real^_)"
   736   shows "matrix (g \<circ> f) = matrix g ** matrix f"
   737   using lf lg linear_compose[OF lf lg] matrix_works[OF linear_compose[OF lf lg]]
   738   by (simp add: matrix_eq matrix_works matrix_vector_mul_assoc[symmetric] o_def)
   739 
   740 lemma matrix_vector_column:
   741   "(A::'a::comm_semiring_1^'n^_) *v x = sum (\<lambda>i. (x$i) *s ((transpose A)$i)) (UNIV:: 'n set)"
   742   by (simp add: matrix_vector_mult_def transpose_def vec_eq_iff mult.commute)
   743 
   744 lemma adjoint_matrix: "adjoint(\<lambda>x. (A::real^'n^'m) *v x) = (\<lambda>x. transpose A *v x)"
   745   apply (rule adjoint_unique)
   746   apply (simp add: transpose_def inner_vec_def matrix_vector_mult_def
   747     sum_distrib_right sum_distrib_left)
   748   apply (subst sum.swap)
   749   apply (auto simp add: ac_simps)
   750   done
   751 
   752 lemma matrix_adjoint: assumes lf: "linear (f :: real^'n \<Rightarrow> real ^'m)"
   753   shows "matrix(adjoint f) = transpose(matrix f)"
   754   apply (subst matrix_vector_mul[OF lf])
   755   unfolding adjoint_matrix matrix_of_matrix_vector_mul
   756   apply rule
   757   done
   758 
   759 lemma inj_matrix_vector_mult:
   760   fixes A::"'a::field^'n^'m"
   761   assumes "invertible A"
   762   shows "inj (( *v) A)"
   763   by (metis assms inj_on_inverseI invertible_def matrix_vector_mul_assoc matrix_vector_mul_lid)
   764 
   765 
   766 subsection\<open>Some bounds on components etc. relative to operator norm\<close>
   767 
   768 lemma norm_column_le_onorm:
   769   fixes A :: "real^'n^'m"
   770   shows "norm(column i A) \<le> onorm(( *v) A)"
   771 proof -
   772   have bl: "bounded_linear (( *v) A)"
   773     by (simp add: linear_linear matrix_vector_mul_linear)
   774   have "norm (\<chi> j. A $ j $ i) \<le> norm (A *v axis i 1)"
   775     by (simp add: matrix_mult_dot cart_eq_inner_axis)
   776   also have "\<dots> \<le> onorm (( *v) A)"
   777     using onorm [OF bl, of "axis i 1"] by auto
   778   finally have "norm (\<chi> j. A $ j $ i) \<le> onorm (( *v) A)" .
   779   then show ?thesis
   780     unfolding column_def .
   781 qed
   782 
   783 lemma matrix_component_le_onorm:
   784   fixes A :: "real^'n^'m"
   785   shows "\<bar>A $ i $ j\<bar> \<le> onorm(( *v) A)"
   786 proof -
   787   have "\<bar>A $ i $ j\<bar> \<le> norm (\<chi> n. (A $ n $ j))"
   788     by (metis (full_types, lifting) component_le_norm_cart vec_lambda_beta)
   789   also have "\<dots> \<le> onorm (( *v) A)"
   790     by (metis (no_types) column_def norm_column_le_onorm)
   791   finally show ?thesis .
   792 qed
   793 
   794 lemma component_le_onorm:
   795   fixes f :: "real^'m \<Rightarrow> real^'n"
   796   shows "linear f \<Longrightarrow> \<bar>matrix f $ i $ j\<bar> \<le> onorm f"
   797   by (metis matrix_component_le_onorm matrix_vector_mul)
   798 
   799 lemma onorm_le_matrix_component_sum:
   800   fixes A :: "real^'n^'m"
   801   shows "onorm(( *v) A) \<le> (\<Sum>i\<in>UNIV. \<Sum>j\<in>UNIV. \<bar>A $ i $ j\<bar>)"
   802 proof (rule onorm_le)
   803   fix x
   804   have "norm (A *v x) \<le> (\<Sum>i\<in>UNIV. \<bar>(A *v x) $ i\<bar>)"
   805     by (rule norm_le_l1_cart)
   806   also have "\<dots> \<le> (\<Sum>i\<in>UNIV. \<Sum>j\<in>UNIV. \<bar>A $ i $ j\<bar> * norm x)"
   807   proof (rule sum_mono)
   808     fix i
   809     have "\<bar>(A *v x) $ i\<bar> \<le> \<bar>\<Sum>j\<in>UNIV. A $ i $ j * x $ j\<bar>"
   810       by (simp add: matrix_vector_mult_def)
   811     also have "\<dots> \<le> (\<Sum>j\<in>UNIV. \<bar>A $ i $ j * x $ j\<bar>)"
   812       by (rule sum_abs)
   813     also have "\<dots> \<le> (\<Sum>j\<in>UNIV. \<bar>A $ i $ j\<bar> * norm x)"
   814       by (rule sum_mono) (simp add: abs_mult component_le_norm_cart mult_left_mono)
   815     finally show "\<bar>(A *v x) $ i\<bar> \<le> (\<Sum>j\<in>UNIV. \<bar>A $ i $ j\<bar> * norm x)" .
   816   qed
   817   finally show "norm (A *v x) \<le> (\<Sum>i\<in>UNIV. \<Sum>j\<in>UNIV. \<bar>A $ i $ j\<bar>) * norm x"
   818     by (simp add: sum_distrib_right)
   819 qed
   820 
   821 lemma onorm_le_matrix_component:
   822   fixes A :: "real^'n^'m"
   823   assumes "\<And>i j. abs(A$i$j) \<le> B"
   824   shows "onorm(( *v) A) \<le> real (CARD('m)) * real (CARD('n)) * B"
   825 proof (rule onorm_le)
   826   fix x :: "real^'n::_"
   827   have "norm (A *v x) \<le> (\<Sum>i\<in>UNIV. \<bar>(A *v x) $ i\<bar>)"
   828     by (rule norm_le_l1_cart)
   829   also have "\<dots> \<le> (\<Sum>i::'m \<in>UNIV. real (CARD('n)) * B * norm x)"
   830   proof (rule sum_mono)
   831     fix i
   832     have "\<bar>(A *v x) $ i\<bar> \<le> norm(A $ i) * norm x"
   833       by (simp add: matrix_mult_dot Cauchy_Schwarz_ineq2)
   834     also have "\<dots> \<le> (\<Sum>j\<in>UNIV. \<bar>A $ i $ j\<bar>) * norm x"
   835       by (simp add: mult_right_mono norm_le_l1_cart)
   836     also have "\<dots> \<le> real (CARD('n)) * B * norm x"
   837       by (simp add: assms sum_bounded_above mult_right_mono)
   838     finally show "\<bar>(A *v x) $ i\<bar> \<le> real (CARD('n)) * B * norm x" .
   839   qed
   840   also have "\<dots> \<le> CARD('m) * real (CARD('n)) * B * norm x"
   841     by simp
   842   finally show "norm (A *v x) \<le> CARD('m) * real (CARD('n)) * B * norm x" .
   843 qed
   844 
   845 subsection \<open>lambda skolemization on cartesian products\<close>
   846 
   847 lemma lambda_skolem: "(\<forall>i. \<exists>x. P i x) \<longleftrightarrow>
   848    (\<exists>x::'a ^ 'n. \<forall>i. P i (x $ i))" (is "?lhs \<longleftrightarrow> ?rhs")
   849 proof -
   850   let ?S = "(UNIV :: 'n set)"
   851   { assume H: "?rhs"
   852     then have ?lhs by auto }
   853   moreover
   854   { assume H: "?lhs"
   855     then obtain f where f:"\<forall>i. P i (f i)" unfolding choice_iff by metis
   856     let ?x = "(\<chi> i. (f i)) :: 'a ^ 'n"
   857     { fix i
   858       from f have "P i (f i)" by metis
   859       then have "P i (?x $ i)" by auto
   860     }
   861     hence "\<forall>i. P i (?x$i)" by metis
   862     hence ?rhs by metis }
   863   ultimately show ?thesis by metis
   864 qed
   865 
   866 lemma rational_approximation:
   867   assumes "e > 0"
   868   obtains r::real where "r \<in> \<rat>" "\<bar>r - x\<bar> < e"
   869   using Rats_dense_in_real [of "x - e/2" "x + e/2"] assms by auto
   870 
   871 lemma matrix_rational_approximation:
   872   fixes A :: "real^'n^'m"
   873   assumes "e > 0"
   874   obtains B where "\<And>i j. B$i$j \<in> \<rat>" "onorm(\<lambda>x. (A - B) *v x) < e"
   875 proof -
   876   have "\<forall>i j. \<exists>q \<in> \<rat>. \<bar>q - A $ i $ j\<bar> < e / (2 * CARD('m) * CARD('n))"
   877     using assms by (force intro: rational_approximation [of "e / (2 * CARD('m) * CARD('n))"])
   878   then obtain B where B: "\<And>i j. B$i$j \<in> \<rat>" and Bclo: "\<And>i j. \<bar>B$i$j - A $ i $ j\<bar> < e / (2 * CARD('m) * CARD('n))"
   879     by (auto simp: lambda_skolem Bex_def)
   880   show ?thesis
   881   proof
   882     have "onorm (( *v) (A - B)) \<le> real CARD('m) * real CARD('n) *
   883     (e / (2 * real CARD('m) * real CARD('n)))"
   884       apply (rule onorm_le_matrix_component)
   885       using Bclo by (simp add: abs_minus_commute less_imp_le)
   886     also have "\<dots> < e"
   887       using \<open>0 < e\<close> by (simp add: divide_simps)
   888     finally show "onorm (( *v) (A - B)) < e" .
   889   qed (use B in auto)
   890 qed
   891 
   892 lemma vector_sub_project_orthogonal_cart: "(b::real^'n) \<bullet> (x - ((b \<bullet> x) / (b \<bullet> b)) *s b) = 0"
   893   unfolding inner_simps scalar_mult_eq_scaleR by auto
   894 
   895 lemma left_invertible_transpose:
   896   "(\<exists>(B). B ** transpose (A) = mat (1::'a::comm_semiring_1)) \<longleftrightarrow> (\<exists>(B). A ** B = mat 1)"
   897   by (metis matrix_transpose_mul transpose_mat transpose_transpose)
   898 
   899 lemma right_invertible_transpose:
   900   "(\<exists>(B). transpose (A) ** B = mat (1::'a::comm_semiring_1)) \<longleftrightarrow> (\<exists>(B). B ** A = mat 1)"
   901   by (metis matrix_transpose_mul transpose_mat transpose_transpose)
   902 
   903 lemma matrix_left_invertible_injective:
   904   fixes A :: "real^'n^'m"
   905   shows "(\<exists>B. B ** A = mat 1) \<longleftrightarrow> inj (( *v) A)"
   906 proof safe
   907   fix B
   908   assume B: "B ** A = mat 1"
   909   show "inj (( *v) A)"
   910     unfolding inj_on_def
   911       by (metis B matrix_vector_mul_assoc matrix_vector_mul_lid)
   912 next
   913   assume "inj (( *v) A)"
   914   with linear_injective_left_inverse[OF matrix_vector_mul_linear]
   915   obtain g where "linear g" and g: "g \<circ> ( *v) A = id"
   916     by blast
   917   have "matrix g ** A = mat 1"
   918     by (metis \<open>linear g\<close> g matrix_compose matrix_id_mat_1 matrix_of_matrix_vector_mul matrix_vector_mul_linear)
   919   then show "\<exists>B. B ** A = mat 1"
   920     by metis
   921 qed
   922 
   923 lemma matrix_left_invertible_ker:
   924   "(\<exists>B. (B::real ^'m^'n) ** (A::real^'n^'m) = mat 1) \<longleftrightarrow> (\<forall>x. A *v x = 0 \<longrightarrow> x = 0)"
   925   unfolding matrix_left_invertible_injective
   926   using linear_injective_0[OF matrix_vector_mul_linear, of A]
   927   by (simp add: inj_on_def)
   928 
   929 lemma matrix_right_invertible_surjective:
   930   "(\<exists>B. (A::real^'n^'m) ** (B::real^'m^'n) = mat 1) \<longleftrightarrow> surj (\<lambda>x. A *v x)"
   931 proof -
   932   { fix B :: "real ^'m^'n"
   933     assume AB: "A ** B = mat 1"
   934     { fix x :: "real ^ 'm"
   935       have "A *v (B *v x) = x"
   936         by (simp add: matrix_vector_mul_lid matrix_vector_mul_assoc AB) }
   937     hence "surj (( *v) A)" unfolding surj_def by metis }
   938   moreover
   939   { assume sf: "surj (( *v) A)"
   940     from linear_surjective_right_inverse[OF matrix_vector_mul_linear sf]
   941     obtain g:: "real ^'m \<Rightarrow> real ^'n" where g: "linear g" "( *v) A \<circ> g = id"
   942       by blast
   943 
   944     have "A ** (matrix g) = mat 1"
   945       unfolding matrix_eq  matrix_vector_mul_lid
   946         matrix_vector_mul_assoc[symmetric] matrix_works[OF g(1)]
   947       using g(2) unfolding o_def fun_eq_iff id_def
   948       .
   949     hence "\<exists>B. A ** (B::real^'m^'n) = mat 1" by blast
   950   }
   951   ultimately show ?thesis unfolding surj_def by blast
   952 qed
   953 
   954 lemma matrix_left_invertible_independent_columns:
   955   fixes A :: "real^'n^'m"
   956   shows "(\<exists>(B::real ^'m^'n). B ** A = mat 1) \<longleftrightarrow>
   957       (\<forall>c. sum (\<lambda>i. c i *s column i A) (UNIV :: 'n set) = 0 \<longrightarrow> (\<forall>i. c i = 0))"
   958     (is "?lhs \<longleftrightarrow> ?rhs")
   959 proof -
   960   let ?U = "UNIV :: 'n set"
   961   { assume k: "\<forall>x. A *v x = 0 \<longrightarrow> x = 0"
   962     { fix c i
   963       assume c: "sum (\<lambda>i. c i *s column i A) ?U = 0" and i: "i \<in> ?U"
   964       let ?x = "\<chi> i. c i"
   965       have th0:"A *v ?x = 0"
   966         using c
   967         unfolding matrix_mult_sum vec_eq_iff
   968         by auto
   969       from k[rule_format, OF th0] i
   970       have "c i = 0" by (vector vec_eq_iff)}
   971     hence ?rhs by blast }
   972   moreover
   973   { assume H: ?rhs
   974     { fix x assume x: "A *v x = 0"
   975       let ?c = "\<lambda>i. ((x$i ):: real)"
   976       from H[rule_format, of ?c, unfolded matrix_mult_sum[symmetric], OF x]
   977       have "x = 0" by vector }
   978   }
   979   ultimately show ?thesis unfolding matrix_left_invertible_ker by blast
   980 qed
   981 
   982 lemma matrix_right_invertible_independent_rows:
   983   fixes A :: "real^'n^'m"
   984   shows "(\<exists>(B::real^'m^'n). A ** B = mat 1) \<longleftrightarrow>
   985     (\<forall>c. sum (\<lambda>i. c i *s row i A) (UNIV :: 'm set) = 0 \<longrightarrow> (\<forall>i. c i = 0))"
   986   unfolding left_invertible_transpose[symmetric]
   987     matrix_left_invertible_independent_columns
   988   by (simp add: column_transpose)
   989 
   990 lemma matrix_right_invertible_span_columns:
   991   "(\<exists>(B::real ^'n^'m). (A::real ^'m^'n) ** B = mat 1) \<longleftrightarrow>
   992     span (columns A) = UNIV" (is "?lhs = ?rhs")
   993 proof -
   994   let ?U = "UNIV :: 'm set"
   995   have fU: "finite ?U" by simp
   996   have lhseq: "?lhs \<longleftrightarrow> (\<forall>y. \<exists>(x::real^'m). sum (\<lambda>i. (x$i) *s column i A) ?U = y)"
   997     unfolding matrix_right_invertible_surjective matrix_mult_sum surj_def
   998     apply (subst eq_commute)
   999     apply rule
  1000     done
  1001   have rhseq: "?rhs \<longleftrightarrow> (\<forall>x. x \<in> span (columns A))" by blast
  1002   { assume h: ?lhs
  1003     { fix x:: "real ^'n"
  1004       from h[unfolded lhseq, rule_format, of x] obtain y :: "real ^'m"
  1005         where y: "sum (\<lambda>i. (y$i) *s column i A) ?U = x" by blast
  1006       have "x \<in> span (columns A)"
  1007         unfolding y[symmetric]
  1008         apply (rule span_sum)
  1009         unfolding scalar_mult_eq_scaleR
  1010         apply (rule span_mul)
  1011         apply (rule span_superset)
  1012         unfolding columns_def
  1013         apply blast
  1014         done
  1015     }
  1016     then have ?rhs unfolding rhseq by blast }
  1017   moreover
  1018   { assume h:?rhs
  1019     let ?P = "\<lambda>(y::real ^'n). \<exists>(x::real^'m). sum (\<lambda>i. (x$i) *s column i A) ?U = y"
  1020     { fix y
  1021       have "?P y"
  1022       proof (rule span_induct_alt[of ?P "columns A", folded scalar_mult_eq_scaleR])
  1023         show "\<exists>x::real ^ 'm. sum (\<lambda>i. (x$i) *s column i A) ?U = 0"
  1024           by (rule exI[where x=0], simp)
  1025       next
  1026         fix c y1 y2
  1027         assume y1: "y1 \<in> columns A" and y2: "?P y2"
  1028         from y1 obtain i where i: "i \<in> ?U" "y1 = column i A"
  1029           unfolding columns_def by blast
  1030         from y2 obtain x:: "real ^'m" where
  1031           x: "sum (\<lambda>i. (x$i) *s column i A) ?U = y2" by blast
  1032         let ?x = "(\<chi> j. if j = i then c + (x$i) else (x$j))::real^'m"
  1033         show "?P (c*s y1 + y2)"
  1034         proof (rule exI[where x= "?x"], vector, auto simp add: i x[symmetric] if_distrib distrib_left cond_application_beta cong del: if_weak_cong)
  1035           fix j
  1036           have th: "\<forall>xa \<in> ?U. (if xa = i then (c + (x$i)) * ((column xa A)$j)
  1037               else (x$xa) * ((column xa A$j))) = (if xa = i then c * ((column i A)$j) else 0) + ((x$xa) * ((column xa A)$j))"
  1038             using i(1) by (simp add: field_simps)
  1039           have "sum (\<lambda>xa. if xa = i then (c + (x$i)) * ((column xa A)$j)
  1040               else (x$xa) * ((column xa A$j))) ?U = sum (\<lambda>xa. (if xa = i then c * ((column i A)$j) else 0) + ((x$xa) * ((column xa A)$j))) ?U"
  1041             apply (rule sum.cong[OF refl])
  1042             using th apply blast
  1043             done
  1044           also have "\<dots> = sum (\<lambda>xa. if xa = i then c * ((column i A)$j) else 0) ?U + sum (\<lambda>xa. ((x$xa) * ((column xa A)$j))) ?U"
  1045             by (simp add: sum.distrib)
  1046           also have "\<dots> = c * ((column i A)$j) + sum (\<lambda>xa. ((x$xa) * ((column xa A)$j))) ?U"
  1047             unfolding sum.delta[OF fU]
  1048             using i(1) by simp
  1049           finally show "sum (\<lambda>xa. if xa = i then (c + (x$i)) * ((column xa A)$j)
  1050             else (x$xa) * ((column xa A$j))) ?U = c * ((column i A)$j) + sum (\<lambda>xa. ((x$xa) * ((column xa A)$j))) ?U" .
  1051         qed
  1052       next
  1053         show "y \<in> span (columns A)"
  1054           unfolding h by blast
  1055       qed
  1056     }
  1057     then have ?lhs unfolding lhseq ..
  1058   }
  1059   ultimately show ?thesis by blast
  1060 qed
  1061 
  1062 lemma matrix_left_invertible_span_rows:
  1063   "(\<exists>(B::real^'m^'n). B ** (A::real^'n^'m) = mat 1) \<longleftrightarrow> span (rows A) = UNIV"
  1064   unfolding right_invertible_transpose[symmetric]
  1065   unfolding columns_transpose[symmetric]
  1066   unfolding matrix_right_invertible_span_columns
  1067   ..
  1068 
  1069 text \<open>The same result in terms of square matrices.\<close>
  1070 
  1071 lemma matrix_left_right_inverse:
  1072   fixes A A' :: "real ^'n^'n"
  1073   shows "A ** A' = mat 1 \<longleftrightarrow> A' ** A = mat 1"
  1074 proof -
  1075   { fix A A' :: "real ^'n^'n"
  1076     assume AA': "A ** A' = mat 1"
  1077     have sA: "surj (( *v) A)"
  1078       unfolding surj_def
  1079       apply clarify
  1080       apply (rule_tac x="(A' *v y)" in exI)
  1081       apply (simp add: matrix_vector_mul_assoc AA' matrix_vector_mul_lid)
  1082       done
  1083     from linear_surjective_isomorphism[OF matrix_vector_mul_linear sA]
  1084     obtain f' :: "real ^'n \<Rightarrow> real ^'n"
  1085       where f': "linear f'" "\<forall>x. f' (A *v x) = x" "\<forall>x. A *v f' x = x" by blast
  1086     have th: "matrix f' ** A = mat 1"
  1087       by (simp add: matrix_eq matrix_works[OF f'(1)]
  1088           matrix_vector_mul_assoc[symmetric] matrix_vector_mul_lid f'(2)[rule_format])
  1089     hence "(matrix f' ** A) ** A' = mat 1 ** A'" by simp
  1090     hence "matrix f' = A'"
  1091       by (simp add: matrix_mul_assoc[symmetric] AA' matrix_mul_rid matrix_mul_lid)
  1092     hence "matrix f' ** A = A' ** A" by simp
  1093     hence "A' ** A = mat 1" by (simp add: th)
  1094   }
  1095   then show ?thesis by blast
  1096 qed
  1097 
  1098 text \<open>Considering an n-element vector as an n-by-1 or 1-by-n matrix.\<close>
  1099 
  1100 definition "rowvector v = (\<chi> i j. (v$j))"
  1101 
  1102 definition "columnvector v = (\<chi> i j. (v$i))"
  1103 
  1104 lemma transpose_columnvector: "transpose(columnvector v) = rowvector v"
  1105   by (simp add: transpose_def rowvector_def columnvector_def vec_eq_iff)
  1106 
  1107 lemma transpose_rowvector: "transpose(rowvector v) = columnvector v"
  1108   by (simp add: transpose_def columnvector_def rowvector_def vec_eq_iff)
  1109 
  1110 lemma dot_rowvector_columnvector: "columnvector (A *v v) = A ** columnvector v"
  1111   by (vector columnvector_def matrix_matrix_mult_def matrix_vector_mult_def)
  1112 
  1113 lemma dot_matrix_product:
  1114   "(x::real^'n) \<bullet> y = (((rowvector x ::real^'n^1) ** (columnvector y :: real^1^'n))$1)$1"
  1115   by (vector matrix_matrix_mult_def rowvector_def columnvector_def inner_vec_def)
  1116 
  1117 lemma dot_matrix_vector_mul:
  1118   fixes A B :: "real ^'n ^'n" and x y :: "real ^'n"
  1119   shows "(A *v x) \<bullet> (B *v y) =
  1120       (((rowvector x :: real^'n^1) ** ((transpose A ** B) ** (columnvector y :: real ^1^'n)))$1)$1"
  1121   unfolding dot_matrix_product transpose_columnvector[symmetric]
  1122     dot_rowvector_columnvector matrix_transpose_mul matrix_mul_assoc ..
  1123 
  1124 lemma infnorm_cart:"infnorm (x::real^'n) = Sup {\<bar>x$i\<bar> |i. i\<in>UNIV}"
  1125   by (simp add: infnorm_def inner_axis Basis_vec_def) (metis (lifting) inner_axis real_inner_1_right)
  1126 
  1127 lemma component_le_infnorm_cart: "\<bar>x$i\<bar> \<le> infnorm (x::real^'n)"
  1128   using Basis_le_infnorm[of "axis i 1" x]
  1129   by (simp add: Basis_vec_def axis_eq_axis inner_axis)
  1130 
  1131 lemma continuous_component[continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. f x $ i)"
  1132   unfolding continuous_def by (rule tendsto_vec_nth)
  1133 
  1134 lemma continuous_on_component[continuous_intros]: "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. f x $ i)"
  1135   unfolding continuous_on_def by (fast intro: tendsto_vec_nth)
  1136 
  1137 lemma continuous_on_vec_lambda[continuous_intros]:
  1138   "(\<And>i. continuous_on S (f i)) \<Longrightarrow> continuous_on S (\<lambda>x. \<chi> i. f i x)"
  1139   unfolding continuous_on_def by (auto intro: tendsto_vec_lambda)
  1140 
  1141 lemma closed_positive_orthant: "closed {x::real^'n. \<forall>i. 0 \<le>x$i}"
  1142   by (simp add: Collect_all_eq closed_INT closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1143 
  1144 lemma bounded_component_cart: "bounded s \<Longrightarrow> bounded ((\<lambda>x. x $ i) ` s)"
  1145   unfolding bounded_def
  1146   apply clarify
  1147   apply (rule_tac x="x $ i" in exI)
  1148   apply (rule_tac x="e" in exI)
  1149   apply clarify
  1150   apply (rule order_trans [OF dist_vec_nth_le], simp)
  1151   done
  1152 
  1153 lemma compact_lemma_cart:
  1154   fixes f :: "nat \<Rightarrow> 'a::heine_borel ^ 'n"
  1155   assumes f: "bounded (range f)"
  1156   shows "\<exists>l r. strict_mono r \<and>
  1157         (\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>d. dist (f (r n) $ i) (l $ i) < e) sequentially)"
  1158     (is "?th d")
  1159 proof -
  1160   have "\<forall>d' \<subseteq> d. ?th d'"
  1161     by (rule compact_lemma_general[where unproj=vec_lambda])
  1162       (auto intro!: f bounded_component_cart simp: vec_lambda_eta)
  1163   then show "?th d" by simp
  1164 qed
  1165 
  1166 instance vec :: (heine_borel, finite) heine_borel
  1167 proof
  1168   fix f :: "nat \<Rightarrow> 'a ^ 'b"
  1169   assume f: "bounded (range f)"
  1170   then obtain l r where r: "strict_mono r"
  1171       and l: "\<forall>e>0. eventually (\<lambda>n. \<forall>i\<in>UNIV. dist (f (r n) $ i) (l $ i) < e) sequentially"
  1172     using compact_lemma_cart [OF f] by blast
  1173   let ?d = "UNIV::'b set"
  1174   { fix e::real assume "e>0"
  1175     hence "0 < e / (real_of_nat (card ?d))"
  1176       using zero_less_card_finite divide_pos_pos[of e, of "real_of_nat (card ?d)"] by auto
  1177     with l have "eventually (\<lambda>n. \<forall>i. dist (f (r n) $ i) (l $ i) < e / (real_of_nat (card ?d))) sequentially"
  1178       by simp
  1179     moreover
  1180     { fix n
  1181       assume n: "\<forall>i. dist (f (r n) $ i) (l $ i) < e / (real_of_nat (card ?d))"
  1182       have "dist (f (r n)) l \<le> (\<Sum>i\<in>?d. dist (f (r n) $ i) (l $ i))"
  1183         unfolding dist_vec_def using zero_le_dist by (rule L2_set_le_sum)
  1184       also have "\<dots> < (\<Sum>i\<in>?d. e / (real_of_nat (card ?d)))"
  1185         by (rule sum_strict_mono) (simp_all add: n)
  1186       finally have "dist (f (r n)) l < e" by simp
  1187     }
  1188     ultimately have "eventually (\<lambda>n. dist (f (r n)) l < e) sequentially"
  1189       by (rule eventually_mono)
  1190   }
  1191   hence "((f \<circ> r) \<longlongrightarrow> l) sequentially" unfolding o_def tendsto_iff by simp
  1192   with r show "\<exists>l r. strict_mono r \<and> ((f \<circ> r) \<longlongrightarrow> l) sequentially" by auto
  1193 qed
  1194 
  1195 lemma interval_cart:
  1196   fixes a :: "real^'n"
  1197   shows "box a b = {x::real^'n. \<forall>i. a$i < x$i \<and> x$i < b$i}"
  1198     and "cbox a b = {x::real^'n. \<forall>i. a$i \<le> x$i \<and> x$i \<le> b$i}"
  1199   by (auto simp add: set_eq_iff less_vec_def less_eq_vec_def mem_box Basis_vec_def inner_axis)
  1200 
  1201 lemma mem_box_cart:
  1202   fixes a :: "real^'n"
  1203   shows "x \<in> box a b \<longleftrightarrow> (\<forall>i. a$i < x$i \<and> x$i < b$i)"
  1204     and "x \<in> cbox a b \<longleftrightarrow> (\<forall>i. a$i \<le> x$i \<and> x$i \<le> b$i)"
  1205   using interval_cart[of a b] by (auto simp add: set_eq_iff less_vec_def less_eq_vec_def)
  1206 
  1207 lemma interval_eq_empty_cart:
  1208   fixes a :: "real^'n"
  1209   shows "(box a b = {} \<longleftrightarrow> (\<exists>i. b$i \<le> a$i))" (is ?th1)
  1210     and "(cbox a b = {} \<longleftrightarrow> (\<exists>i. b$i < a$i))" (is ?th2)
  1211 proof -
  1212   { fix i x assume as:"b$i \<le> a$i" and x:"x\<in>box a b"
  1213     hence "a $ i < x $ i \<and> x $ i < b $ i" unfolding mem_box_cart by auto
  1214     hence "a$i < b$i" by auto
  1215     hence False using as by auto }
  1216   moreover
  1217   { assume as:"\<forall>i. \<not> (b$i \<le> a$i)"
  1218     let ?x = "(1/2) *\<^sub>R (a + b)"
  1219     { fix i
  1220       have "a$i < b$i" using as[THEN spec[where x=i]] by auto
  1221       hence "a$i < ((1/2) *\<^sub>R (a+b)) $ i" "((1/2) *\<^sub>R (a+b)) $ i < b$i"
  1222         unfolding vector_smult_component and vector_add_component
  1223         by auto }
  1224     hence "box a b \<noteq> {}" using mem_box_cart(1)[of "?x" a b] by auto }
  1225   ultimately show ?th1 by blast
  1226 
  1227   { fix i x assume as:"b$i < a$i" and x:"x\<in>cbox a b"
  1228     hence "a $ i \<le> x $ i \<and> x $ i \<le> b $ i" unfolding mem_box_cart by auto
  1229     hence "a$i \<le> b$i" by auto
  1230     hence False using as by auto }
  1231   moreover
  1232   { assume as:"\<forall>i. \<not> (b$i < a$i)"
  1233     let ?x = "(1/2) *\<^sub>R (a + b)"
  1234     { fix i
  1235       have "a$i \<le> b$i" using as[THEN spec[where x=i]] by auto
  1236       hence "a$i \<le> ((1/2) *\<^sub>R (a+b)) $ i" "((1/2) *\<^sub>R (a+b)) $ i \<le> b$i"
  1237         unfolding vector_smult_component and vector_add_component
  1238         by auto }
  1239     hence "cbox a b \<noteq> {}" using mem_box_cart(2)[of "?x" a b] by auto  }
  1240   ultimately show ?th2 by blast
  1241 qed
  1242 
  1243 lemma interval_ne_empty_cart:
  1244   fixes a :: "real^'n"
  1245   shows "cbox a b \<noteq> {} \<longleftrightarrow> (\<forall>i. a$i \<le> b$i)"
  1246     and "box a b \<noteq> {} \<longleftrightarrow> (\<forall>i. a$i < b$i)"
  1247   unfolding interval_eq_empty_cart[of a b] by (auto simp add: not_less not_le)
  1248     (* BH: Why doesn't just "auto" work here? *)
  1249 
  1250 lemma subset_interval_imp_cart:
  1251   fixes a :: "real^'n"
  1252   shows "(\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i) \<Longrightarrow> cbox c d \<subseteq> cbox a b"
  1253     and "(\<forall>i. a$i < c$i \<and> d$i < b$i) \<Longrightarrow> cbox c d \<subseteq> box a b"
  1254     and "(\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i) \<Longrightarrow> box c d \<subseteq> cbox a b"
  1255     and "(\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i) \<Longrightarrow> box c d \<subseteq> box a b"
  1256   unfolding subset_eq[unfolded Ball_def] unfolding mem_box_cart
  1257   by (auto intro: order_trans less_le_trans le_less_trans less_imp_le) (* BH: Why doesn't just "auto" work here? *)
  1258 
  1259 lemma interval_sing:
  1260   fixes a :: "'a::linorder^'n"
  1261   shows "{a .. a} = {a} \<and> {a<..<a} = {}"
  1262   apply (auto simp add: set_eq_iff less_vec_def less_eq_vec_def vec_eq_iff)
  1263   done
  1264 
  1265 lemma subset_interval_cart:
  1266   fixes a :: "real^'n"
  1267   shows "cbox c d \<subseteq> cbox a b \<longleftrightarrow> (\<forall>i. c$i \<le> d$i) --> (\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i)" (is ?th1)
  1268     and "cbox c d \<subseteq> box a b \<longleftrightarrow> (\<forall>i. c$i \<le> d$i) --> (\<forall>i. a$i < c$i \<and> d$i < b$i)" (is ?th2)
  1269     and "box c d \<subseteq> cbox a b \<longleftrightarrow> (\<forall>i. c$i < d$i) --> (\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i)" (is ?th3)
  1270     and "box c d \<subseteq> box a b \<longleftrightarrow> (\<forall>i. c$i < d$i) --> (\<forall>i. a$i \<le> c$i \<and> d$i \<le> b$i)" (is ?th4)
  1271   using subset_box[of c d a b] by (simp_all add: Basis_vec_def inner_axis)
  1272 
  1273 lemma disjoint_interval_cart:
  1274   fixes a::"real^'n"
  1275   shows "cbox a b \<inter> cbox c d = {} \<longleftrightarrow> (\<exists>i. (b$i < a$i \<or> d$i < c$i \<or> b$i < c$i \<or> d$i < a$i))" (is ?th1)
  1276     and "cbox a b \<inter> box c d = {} \<longleftrightarrow> (\<exists>i. (b$i < a$i \<or> d$i \<le> c$i \<or> b$i \<le> c$i \<or> d$i \<le> a$i))" (is ?th2)
  1277     and "box a b \<inter> cbox c d = {} \<longleftrightarrow> (\<exists>i. (b$i \<le> a$i \<or> d$i < c$i \<or> b$i \<le> c$i \<or> d$i \<le> a$i))" (is ?th3)
  1278     and "box a b \<inter> box c d = {} \<longleftrightarrow> (\<exists>i. (b$i \<le> a$i \<or> d$i \<le> c$i \<or> b$i \<le> c$i \<or> d$i \<le> a$i))" (is ?th4)
  1279   using disjoint_interval[of a b c d] by (simp_all add: Basis_vec_def inner_axis)
  1280 
  1281 lemma Int_interval_cart:
  1282   fixes a :: "real^'n"
  1283   shows "cbox a b \<inter> cbox c d =  {(\<chi> i. max (a$i) (c$i)) .. (\<chi> i. min (b$i) (d$i))}"
  1284   unfolding Int_interval
  1285   by (auto simp: mem_box less_eq_vec_def)
  1286     (auto simp: Basis_vec_def inner_axis)
  1287 
  1288 lemma closed_interval_left_cart:
  1289   fixes b :: "real^'n"
  1290   shows "closed {x::real^'n. \<forall>i. x$i \<le> b$i}"
  1291   by (simp add: Collect_all_eq closed_INT closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1292 
  1293 lemma closed_interval_right_cart:
  1294   fixes a::"real^'n"
  1295   shows "closed {x::real^'n. \<forall>i. a$i \<le> x$i}"
  1296   by (simp add: Collect_all_eq closed_INT closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1297 
  1298 lemma is_interval_cart:
  1299   "is_interval (s::(real^'n) set) \<longleftrightarrow>
  1300     (\<forall>a\<in>s. \<forall>b\<in>s. \<forall>x. (\<forall>i. ((a$i \<le> x$i \<and> x$i \<le> b$i) \<or> (b$i \<le> x$i \<and> x$i \<le> a$i))) \<longrightarrow> x \<in> s)"
  1301   by (simp add: is_interval_def Ball_def Basis_vec_def inner_axis imp_ex)
  1302 
  1303 lemma closed_halfspace_component_le_cart: "closed {x::real^'n. x$i \<le> a}"
  1304   by (simp add: closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1305 
  1306 lemma closed_halfspace_component_ge_cart: "closed {x::real^'n. x$i \<ge> a}"
  1307   by (simp add: closed_Collect_le continuous_on_const continuous_on_id continuous_on_component)
  1308 
  1309 lemma open_halfspace_component_lt_cart: "open {x::real^'n. x$i < a}"
  1310   by (simp add: open_Collect_less continuous_on_const continuous_on_id continuous_on_component)
  1311 
  1312 lemma open_halfspace_component_gt_cart: "open {x::real^'n. x$i  > a}"
  1313   by (simp add: open_Collect_less continuous_on_const continuous_on_id continuous_on_component)
  1314 
  1315 lemma Lim_component_le_cart:
  1316   fixes f :: "'a \<Rightarrow> real^'n"
  1317   assumes "(f \<longlongrightarrow> l) net" "\<not> (trivial_limit net)"  "eventually (\<lambda>x. f x $i \<le> b) net"
  1318   shows "l$i \<le> b"
  1319   by (rule tendsto_le[OF assms(2) tendsto_const tendsto_vec_nth, OF assms(1, 3)])
  1320 
  1321 lemma Lim_component_ge_cart:
  1322   fixes f :: "'a \<Rightarrow> real^'n"
  1323   assumes "(f \<longlongrightarrow> l) net"  "\<not> (trivial_limit net)"  "eventually (\<lambda>x. b \<le> (f x)$i) net"
  1324   shows "b \<le> l$i"
  1325   by (rule tendsto_le[OF assms(2) tendsto_vec_nth tendsto_const, OF assms(1, 3)])
  1326 
  1327 lemma Lim_component_eq_cart:
  1328   fixes f :: "'a \<Rightarrow> real^'n"
  1329   assumes net: "(f \<longlongrightarrow> l) net" "~(trivial_limit net)" and ev:"eventually (\<lambda>x. f(x)$i = b) net"
  1330   shows "l$i = b"
  1331   using ev[unfolded order_eq_iff eventually_conj_iff] and
  1332     Lim_component_ge_cart[OF net, of b i] and
  1333     Lim_component_le_cart[OF net, of i b] by auto
  1334 
  1335 lemma connected_ivt_component_cart:
  1336   fixes x :: "real^'n"
  1337   shows "connected s \<Longrightarrow> x \<in> s \<Longrightarrow> y \<in> s \<Longrightarrow> x$k \<le> a \<Longrightarrow> a \<le> y$k \<Longrightarrow> (\<exists>z\<in>s.  z$k = a)"
  1338   using connected_ivt_hyperplane[of s x y "axis k 1" a]
  1339   by (auto simp add: inner_axis inner_commute)
  1340 
  1341 lemma subspace_substandard_cart: "subspace {x::real^_. (\<forall>i. P i \<longrightarrow> x$i = 0)}"
  1342   unfolding subspace_def by auto
  1343 
  1344 lemma closed_substandard_cart:
  1345   "closed {x::'a::real_normed_vector ^ 'n. \<forall>i. P i \<longrightarrow> x$i = 0}"
  1346 proof -
  1347   { fix i::'n
  1348     have "closed {x::'a ^ 'n. P i \<longrightarrow> x$i = 0}"
  1349       by (cases "P i") (simp_all add: closed_Collect_eq continuous_on_const continuous_on_id continuous_on_component) }
  1350   thus ?thesis
  1351     unfolding Collect_all_eq by (simp add: closed_INT)
  1352 qed
  1353 
  1354 lemma dim_substandard_cart: "dim {x::real^'n. \<forall>i. i \<notin> d \<longrightarrow> x$i = 0} = card d"
  1355   (is "dim ?A = _")
  1356 proof -
  1357   let ?a = "\<lambda>x. axis x 1 :: real^'n"
  1358   have *: "{x. \<forall>i\<in>Basis. i \<notin> ?a ` d \<longrightarrow> x \<bullet> i = 0} = ?A"
  1359     by (auto simp: image_iff Basis_vec_def axis_eq_axis inner_axis)
  1360   have "?a ` d \<subseteq> Basis"
  1361     by (auto simp: Basis_vec_def)
  1362   thus ?thesis
  1363     using dim_substandard[of "?a ` d"] card_image[of ?a d]
  1364     by (auto simp: axis_eq_axis inj_on_def *)
  1365 qed
  1366 
  1367 lemma dim_subset_UNIV_cart:
  1368   fixes S :: "(real^'n) set"
  1369   shows "dim S \<le> CARD('n)"
  1370   by (metis dim_subset_UNIV DIM_cart DIM_real mult.right_neutral)
  1371 
  1372 lemma affinity_inverses:
  1373   assumes m0: "m \<noteq> (0::'a::field)"
  1374   shows "(\<lambda>x. m *s x + c) \<circ> (\<lambda>x. inverse(m) *s x + (-(inverse(m) *s c))) = id"
  1375   "(\<lambda>x. inverse(m) *s x + (-(inverse(m) *s c))) \<circ> (\<lambda>x. m *s x + c) = id"
  1376   using m0
  1377   apply (auto simp add: fun_eq_iff vector_add_ldistrib diff_conv_add_uminus simp del: add_uminus_conv_diff)
  1378   apply (simp_all add: vector_smult_lneg[symmetric] vector_smult_assoc vector_sneg_minus1 [symmetric])
  1379   done
  1380 
  1381 lemma vector_affinity_eq:
  1382   assumes m0: "(m::'a::field) \<noteq> 0"
  1383   shows "m *s x + c = y \<longleftrightarrow> x = inverse m *s y + -(inverse m *s c)"
  1384 proof
  1385   assume h: "m *s x + c = y"
  1386   hence "m *s x = y - c" by (simp add: field_simps)
  1387   hence "inverse m *s (m *s x) = inverse m *s (y - c)" by simp
  1388   then show "x = inverse m *s y + - (inverse m *s c)"
  1389     using m0 by (simp add: vector_smult_assoc vector_ssub_ldistrib)
  1390 next
  1391   assume h: "x = inverse m *s y + - (inverse m *s c)"
  1392   show "m *s x + c = y" unfolding h
  1393     using m0 by (simp add: vector_smult_assoc vector_ssub_ldistrib)
  1394 qed
  1395 
  1396 lemma vector_eq_affinity:
  1397     "(m::'a::field) \<noteq> 0 ==> (y = m *s x + c \<longleftrightarrow> inverse(m) *s y + -(inverse(m) *s c) = x)"
  1398   using vector_affinity_eq[where m=m and x=x and y=y and c=c]
  1399   by metis
  1400 
  1401 lemma vector_cart:
  1402   fixes f :: "real^'n \<Rightarrow> real"
  1403   shows "(\<chi> i. f (axis i 1)) = (\<Sum>i\<in>Basis. f i *\<^sub>R i)"
  1404   unfolding euclidean_eq_iff[where 'a="real^'n"]
  1405   by simp (simp add: Basis_vec_def inner_axis)
  1406 
  1407 lemma const_vector_cart:"((\<chi> i. d)::real^'n) = (\<Sum>i\<in>Basis. d *\<^sub>R i)"
  1408   by (rule vector_cart)
  1409 
  1410 subsection "Convex Euclidean Space"
  1411 
  1412 lemma Cart_1:"(1::real^'n) = \<Sum>Basis"
  1413   using const_vector_cart[of 1] by (simp add: one_vec_def)
  1414 
  1415 declare vector_add_ldistrib[simp] vector_ssub_ldistrib[simp] vector_smult_assoc[simp] vector_smult_rneg[simp]
  1416 declare vector_sadd_rdistrib[simp] vector_sub_rdistrib[simp]
  1417 
  1418 lemmas vector_component_simps = vector_minus_component vector_smult_component vector_add_component less_eq_vec_def vec_lambda_beta vector_uminus_component
  1419 
  1420 lemma convex_box_cart:
  1421   assumes "\<And>i. convex {x. P i x}"
  1422   shows "convex {x. \<forall>i. P i (x$i)}"
  1423   using assms unfolding convex_def by auto
  1424 
  1425 lemma convex_positive_orthant_cart: "convex {x::real^'n. (\<forall>i. 0 \<le> x$i)}"
  1426   by (rule convex_box_cart) (simp add: atLeast_def[symmetric])
  1427 
  1428 lemma unit_interval_convex_hull_cart:
  1429   "cbox (0::real^'n) 1 = convex hull {x. \<forall>i. (x$i = 0) \<or> (x$i = 1)}"
  1430   unfolding Cart_1 unit_interval_convex_hull[where 'a="real^'n"] box_real[symmetric]
  1431   by (rule arg_cong[where f="\<lambda>x. convex hull x"]) (simp add: Basis_vec_def inner_axis)
  1432 
  1433 lemma cube_convex_hull_cart:
  1434   assumes "0 < d"
  1435   obtains s::"(real^'n) set"
  1436     where "finite s" "cbox (x - (\<chi> i. d)) (x + (\<chi> i. d)) = convex hull s"
  1437 proof -
  1438   from assms obtain s where "finite s"
  1439     and "cbox (x - sum (( *\<^sub>R) d) Basis) (x + sum (( *\<^sub>R) d) Basis) = convex hull s"
  1440     by (rule cube_convex_hull)
  1441   with that[of s] show thesis
  1442     by (simp add: const_vector_cart)
  1443 qed
  1444 
  1445 
  1446 subsection "Derivative"
  1447 
  1448 definition "jacobian f net = matrix(frechet_derivative f net)"
  1449 
  1450 lemma jacobian_works:
  1451   "(f::(real^'a) \<Rightarrow> (real^'b)) differentiable net \<longleftrightarrow>
  1452     (f has_derivative (\<lambda>h. (jacobian f net) *v h)) net" (is "?lhs = ?rhs")
  1453 proof
  1454   assume ?lhs then show ?rhs
  1455     by (simp add: frechet_derivative_works has_derivative_linear jacobian_def)
  1456 next
  1457   assume ?rhs then show ?lhs
  1458     by (rule differentiableI)
  1459 qed
  1460 
  1461 
  1462 subsection \<open>Component of the differential must be zero if it exists at a local
  1463   maximum or minimum for that corresponding component\<close>
  1464 
  1465 lemma differential_zero_maxmin_cart:
  1466   fixes f::"real^'a \<Rightarrow> real^'b"
  1467   assumes "0 < e" "((\<forall>y \<in> ball x e. (f y)$k \<le> (f x)$k) \<or> (\<forall>y\<in>ball x e. (f x)$k \<le> (f y)$k))"
  1468     "f differentiable (at x)"
  1469   shows "jacobian f (at x) $ k = 0"
  1470   using differential_zero_maxmin_component[of "axis k 1" e x f] assms
  1471     vector_cart[of "\<lambda>j. frechet_derivative f (at x) j $ k"]
  1472   by (simp add: Basis_vec_def axis_eq_axis inner_axis jacobian_def matrix_def)
  1473 
  1474 subsection \<open>Lemmas for working on @{typ "real^1"}\<close>
  1475 
  1476 lemma forall_1[simp]: "(\<forall>i::1. P i) \<longleftrightarrow> P 1"
  1477   by (metis (full_types) num1_eq_iff)
  1478 
  1479 lemma ex_1[simp]: "(\<exists>x::1. P x) \<longleftrightarrow> P 1"
  1480   by auto (metis (full_types) num1_eq_iff)
  1481 
  1482 lemma exhaust_2:
  1483   fixes x :: 2
  1484   shows "x = 1 \<or> x = 2"
  1485 proof (induct x)
  1486   case (of_int z)
  1487   then have "0 \<le> z" and "z < 2" by simp_all
  1488   then have "z = 0 | z = 1" by arith
  1489   then show ?case by auto
  1490 qed
  1491 
  1492 lemma forall_2: "(\<forall>i::2. P i) \<longleftrightarrow> P 1 \<and> P 2"
  1493   by (metis exhaust_2)
  1494 
  1495 lemma exhaust_3:
  1496   fixes x :: 3
  1497   shows "x = 1 \<or> x = 2 \<or> x = 3"
  1498 proof (induct x)
  1499   case (of_int z)
  1500   then have "0 \<le> z" and "z < 3" by simp_all
  1501   then have "z = 0 \<or> z = 1 \<or> z = 2" by arith
  1502   then show ?case by auto
  1503 qed
  1504 
  1505 lemma forall_3: "(\<forall>i::3. P i) \<longleftrightarrow> P 1 \<and> P 2 \<and> P 3"
  1506   by (metis exhaust_3)
  1507 
  1508 lemma UNIV_1 [simp]: "UNIV = {1::1}"
  1509   by (auto simp add: num1_eq_iff)
  1510 
  1511 lemma UNIV_2: "UNIV = {1::2, 2::2}"
  1512   using exhaust_2 by auto
  1513 
  1514 lemma UNIV_3: "UNIV = {1::3, 2::3, 3::3}"
  1515   using exhaust_3 by auto
  1516 
  1517 lemma sum_1: "sum f (UNIV::1 set) = f 1"
  1518   unfolding UNIV_1 by simp
  1519 
  1520 lemma sum_2: "sum f (UNIV::2 set) = f 1 + f 2"
  1521   unfolding UNIV_2 by simp
  1522 
  1523 lemma sum_3: "sum f (UNIV::3 set) = f 1 + f 2 + f 3"
  1524   unfolding UNIV_3 by (simp add: ac_simps)
  1525 
  1526 lemma num1_eqI:
  1527   fixes a::num1 shows "a = b"
  1528   by (metis (full_types) UNIV_1 UNIV_I empty_iff insert_iff)
  1529 
  1530 lemma num1_eq1 [simp]:
  1531   fixes a::num1 shows "a = 1"
  1532   by (rule num1_eqI)
  1533 
  1534 instantiation num1 :: cart_one
  1535 begin
  1536 
  1537 instance
  1538 proof
  1539   show "CARD(1) = Suc 0" by auto
  1540 qed
  1541 
  1542 end
  1543 
  1544 instantiation num1 :: linorder begin
  1545 definition "a < b \<longleftrightarrow> Rep_num1 a < Rep_num1 b"
  1546 definition "a \<le> b \<longleftrightarrow> Rep_num1 a \<le> Rep_num1 b"
  1547 instance
  1548   by intro_classes (auto simp: less_eq_num1_def less_num1_def intro: num1_eqI)
  1549 end
  1550 
  1551 instance num1 :: wellorder
  1552   by intro_classes (auto simp: less_eq_num1_def less_num1_def)
  1553 
  1554 subsection\<open>The collapse of the general concepts to dimension one\<close>
  1555 
  1556 lemma vector_one: "(x::'a ^1) = (\<chi> i. (x$1))"
  1557   by (simp add: vec_eq_iff)
  1558 
  1559 lemma forall_one: "(\<forall>(x::'a ^1). P x) \<longleftrightarrow> (\<forall>x. P(\<chi> i. x))"
  1560   apply auto
  1561   apply (erule_tac x= "x$1" in allE)
  1562   apply (simp only: vector_one[symmetric])
  1563   done
  1564 
  1565 lemma norm_vector_1: "norm (x :: _^1) = norm (x$1)"
  1566   by (simp add: norm_vec_def)
  1567 
  1568 lemma dist_vector_1:
  1569   fixes x :: "'a::real_normed_vector^1"
  1570   shows "dist x y = dist (x$1) (y$1)"
  1571   by (simp add: dist_norm norm_vector_1)
  1572 
  1573 lemma norm_real: "norm(x::real ^ 1) = \<bar>x$1\<bar>"
  1574   by (simp add: norm_vector_1)
  1575 
  1576 lemma dist_real: "dist(x::real ^ 1) y = \<bar>(x$1) - (y$1)\<bar>"
  1577   by (auto simp add: norm_real dist_norm)
  1578 
  1579 subsection\<open> Rank of a matrix\<close>
  1580 
  1581 text\<open>Equivalence of row and column rank is taken from George Mackiw's paper, Mathematics Magazine 1995, p. 285.\<close>
  1582 
  1583 lemma matrix_vector_mult_in_columnspace:
  1584   fixes A :: "real^'n^'m"
  1585   shows "(A *v x) \<in> span(columns A)"
  1586   apply (simp add: matrix_vector_column columns_def transpose_def column_def)
  1587   apply (intro span_sum span_mul)
  1588   apply (force intro: span_superset)
  1589   done
  1590 
  1591 lemma orthogonal_nullspace_rowspace:
  1592   fixes A :: "real^'n^'m"
  1593   assumes 0: "A *v x = 0" and y: "y \<in> span(rows A)"
  1594   shows "orthogonal x y"
  1595 proof (rule span_induct [OF y])
  1596   show "subspace {a. orthogonal x a}"
  1597     by (simp add: subspace_orthogonal_to_vector)
  1598 next
  1599   fix v
  1600   assume "v \<in> rows A"
  1601   then obtain i where "v = row i A"
  1602     by (auto simp: rows_def)
  1603   with 0 show "orthogonal x v"
  1604     unfolding orthogonal_def inner_vec_def matrix_vector_mult_def row_def
  1605     by (simp add: mult.commute) (metis (no_types) vec_lambda_beta zero_index)
  1606 qed
  1607 
  1608 lemma nullspace_inter_rowspace:
  1609   fixes A :: "real^'n^'m"
  1610   shows "A *v x = 0 \<and> x \<in> span(rows A) \<longleftrightarrow> x = 0"
  1611   using orthogonal_nullspace_rowspace orthogonal_self by auto
  1612 
  1613 lemma matrix_vector_mul_injective_on_rowspace:
  1614   fixes A :: "real^'n^'m"
  1615   shows "\<lbrakk>A *v x = A *v y; x \<in> span(rows A); y \<in> span(rows A)\<rbrakk> \<Longrightarrow> x = y"
  1616   using nullspace_inter_rowspace [of A "x-y"]
  1617   by (metis eq_iff_diff_eq_0 matrix_vector_mult_diff_distrib span_diff)
  1618 
  1619 definition rank :: "real^'n^'m=>nat"
  1620   where "rank A \<equiv> dim(columns A)"
  1621 
  1622 lemma dim_rows_le_dim_columns:
  1623   fixes A :: "real^'n^'m"
  1624   shows "dim(rows A) \<le> dim(columns A)"
  1625 proof -
  1626   have "dim (span (rows A)) \<le> dim (span (columns A))"
  1627   proof -
  1628     obtain B where "independent B" "span(rows A) \<subseteq> span B"
  1629               and B: "B \<subseteq> span(rows A)""card B = dim (span(rows A))"
  1630       using basis_exists [of "span(rows A)"] by blast
  1631     with span_subspace have eq: "span B = span(rows A)"
  1632       by auto
  1633     then have inj: "inj_on (( *v) A) (span B)"
  1634       using inj_on_def matrix_vector_mul_injective_on_rowspace by blast
  1635     then have ind: "independent (( *v) A ` B)"
  1636       by (rule independent_inj_on_image [OF \<open>independent B\<close> matrix_vector_mul_linear])
  1637     then have "finite (( *v) A ` B) \<and> card (( *v) A ` B) \<le> dim (( *v) A ` B)"
  1638       by (rule independent_bound_general)
  1639     then show ?thesis
  1640       by (metis (no_types, lifting) B ind inj eq card_image image_subset_iff independent_card_le_dim inj_on_subset matrix_vector_mult_in_columnspace)
  1641   qed
  1642   then show ?thesis
  1643     by simp
  1644 qed
  1645 
  1646 lemma rank_row:
  1647   fixes A :: "real^'n^'m"
  1648   shows "rank A = dim(rows A)"
  1649   unfolding rank_def
  1650   by (metis dim_rows_le_dim_columns columns_transpose dual_order.antisym rows_transpose)
  1651 
  1652 lemma rank_transpose:
  1653   fixes A :: "real^'n^'m"
  1654   shows "rank(transpose A) = rank A"
  1655   by (metis rank_def rank_row rows_transpose)
  1656 
  1657 lemma matrix_vector_mult_basis:
  1658   fixes A :: "real^'n^'m"
  1659   shows "A *v (axis k 1) = column k A"
  1660   by (simp add: cart_eq_inner_axis column_def matrix_mult_dot)
  1661 
  1662 lemma columns_image_basis:
  1663   fixes A :: "real^'n^'m"
  1664   shows "columns A = ( *v) A ` (range (\<lambda>i. axis i 1))"
  1665   by (force simp: columns_def matrix_vector_mult_basis [symmetric])
  1666 
  1667 lemma rank_dim_range:
  1668   fixes A :: "real^'n^'m"
  1669   shows "rank A = dim(range (\<lambda>x. A *v x))"
  1670   unfolding rank_def
  1671 proof (rule span_eq_dim)
  1672   show "span (columns A) = span (range (( *v) A))"
  1673     apply (auto simp: columns_image_basis span_linear_image matrix_vector_mul_linear)
  1674     by (metis columns_image_basis matrix_vector_mul_linear matrix_vector_mult_in_columnspace span_linear_image)
  1675 qed
  1676 
  1677 lemma rank_bound:
  1678   fixes A :: "real^'n^'m"
  1679   shows "rank A \<le> min CARD('m) (CARD('n))"
  1680   by (metis (mono_tags, hide_lams) min.bounded_iff DIM_cart DIM_real dim_subset_UNIV mult.right_neutral rank_def rank_transpose)
  1681 
  1682 lemma full_rank_injective:
  1683   fixes A :: "real^'n^'m"
  1684   shows "rank A = CARD('n) \<longleftrightarrow> inj (( *v) A)"
  1685   by (simp add: matrix_left_invertible_injective [symmetric] matrix_left_invertible_span_rows rank_row dim_eq_full [symmetric])
  1686 
  1687 lemma full_rank_surjective:
  1688   fixes A :: "real^'n^'m"
  1689   shows "rank A = CARD('m) \<longleftrightarrow> surj (( *v) A)"
  1690   by (simp add: matrix_right_invertible_surjective [symmetric] left_invertible_transpose [symmetric]
  1691                 matrix_left_invertible_injective full_rank_injective [symmetric] rank_transpose)
  1692 
  1693 lemma rank_I: "rank(mat 1::real^'n^'n) = CARD('n)"
  1694   by (simp add: full_rank_injective inj_on_def)
  1695 
  1696 lemma less_rank_noninjective:
  1697   fixes A :: "real^'n^'m"
  1698   shows "rank A < CARD('n) \<longleftrightarrow> \<not> inj (( *v) A)"
  1699 using less_le rank_bound by (auto simp: full_rank_injective [symmetric])
  1700 
  1701 lemma matrix_nonfull_linear_equations_eq:
  1702   fixes A :: "real^'n^'m"
  1703   shows "(\<exists>x. (x \<noteq> 0) \<and> A *v x = 0) \<longleftrightarrow> ~(rank A = CARD('n))"
  1704   by (meson matrix_left_invertible_injective full_rank_injective matrix_left_invertible_ker)
  1705 
  1706 lemma rank_eq_0: "rank A = 0 \<longleftrightarrow> A = 0" and rank_0 [simp]: "rank 0 = 0"
  1707   by (auto simp: rank_dim_range matrix_eq)
  1708 
  1709 
  1710 lemma rank_mul_le_right:
  1711   fixes A :: "real^'n^'m" and B :: "real^'p^'n"
  1712   shows "rank(A ** B) \<le> rank B"
  1713 proof -
  1714   have "rank(A ** B) \<le> dim (( *v) A ` range (( *v) B))"
  1715     by (auto simp: rank_dim_range image_comp o_def matrix_vector_mul_assoc)
  1716   also have "\<dots> \<le> rank B"
  1717     by (simp add: rank_dim_range matrix_vector_mul_linear dim_image_le)
  1718   finally show ?thesis .
  1719 qed
  1720 
  1721 lemma rank_mul_le_left:
  1722   fixes A :: "real^'n^'m" and B :: "real^'p^'n"
  1723   shows "rank(A ** B) \<le> rank A"
  1724   by (metis matrix_transpose_mul rank_mul_le_right rank_transpose)
  1725 
  1726 subsection\<open>Routine results connecting the types @{typ "real^1"} and @{typ real}\<close>
  1727 
  1728 lemma vector_one_nth [simp]:
  1729   fixes x :: "'a^1" shows "vec (x $ 1) = x"
  1730   by (metis vec_def vector_one)
  1731 
  1732 lemma vec_cbox_1_eq [simp]:
  1733   shows "vec ` cbox u v = cbox (vec u) (vec v ::real^1)"
  1734   by (force simp: Basis_vec_def cart_eq_inner_axis [symmetric] mem_box)
  1735 
  1736 lemma vec_nth_cbox_1_eq [simp]:
  1737   fixes u v :: "'a::euclidean_space^1"
  1738   shows "(\<lambda>x. x $ 1) ` cbox u v = cbox (u$1) (v$1)"
  1739     by (auto simp: Basis_vec_def cart_eq_inner_axis [symmetric] mem_box image_iff Bex_def inner_axis) (metis vec_component)
  1740 
  1741 lemma vec_nth_1_iff_cbox [simp]:
  1742   fixes a b :: "'a::euclidean_space"
  1743   shows "(\<lambda>x::'a^1. x $ 1) ` S = cbox a b \<longleftrightarrow> S = cbox (vec a) (vec b)"
  1744     (is "?lhs = ?rhs")
  1745 proof
  1746   assume L: ?lhs show ?rhs
  1747   proof (intro equalityI subsetI)
  1748     fix x 
  1749     assume "x \<in> S"
  1750     then have "x $ 1 \<in> (\<lambda>v. v $ (1::1)) ` cbox (vec a) (vec b)"
  1751       using L by auto
  1752     then show "x \<in> cbox (vec a) (vec b)"
  1753       by (metis (no_types, lifting) imageE vector_one_nth)
  1754   next
  1755     fix x :: "'a^1"
  1756     assume "x \<in> cbox (vec a) (vec b)"
  1757     then show "x \<in> S"
  1758       by (metis (no_types, lifting) L imageE imageI vec_component vec_nth_cbox_1_eq vector_one_nth)
  1759   qed
  1760 qed simp
  1761 
  1762 lemma tendsto_at_within_vector_1:
  1763   fixes S :: "'a :: metric_space set"
  1764   assumes "(f \<longlongrightarrow> fx) (at x within S)"
  1765   shows "((\<lambda>y::'a^1. \<chi> i. f (y $ 1)) \<longlongrightarrow> (vec fx::'a^1)) (at (vec x) within vec ` S)"
  1766 proof (rule topological_tendstoI)
  1767   fix T :: "('a^1) set"
  1768   assume "open T" "vec fx \<in> T"
  1769   have "\<forall>\<^sub>F x in at x within S. f x \<in> (\<lambda>x. x $ 1) ` T"
  1770     using \<open>open T\<close> \<open>vec fx \<in> T\<close> assms open_image_vec_nth tendsto_def by fastforce
  1771   then show "\<forall>\<^sub>F x::'a^1 in at (vec x) within vec ` S. (\<chi> i. f (x $ 1)) \<in> T"
  1772     unfolding eventually_at dist_norm [symmetric]
  1773     by (rule ex_forward)
  1774        (use \<open>open T\<close> in 
  1775          \<open>fastforce simp: dist_norm dist_vec_def L2_set_def image_iff vector_one open_vec_def\<close>)
  1776 qed
  1777 
  1778 lemma has_derivative_vector_1:
  1779   assumes der_g: "(g has_derivative (\<lambda>x. x * g' a)) (at a within S)"
  1780   shows "((\<lambda>x. vec (g (x $ 1))) has_derivative ( *\<^sub>R) (g' a))
  1781          (at ((vec a)::real^1) within vec ` S)"
  1782     using der_g
  1783     apply (auto simp: Deriv.has_derivative_within bounded_linear_scaleR_right norm_vector_1)
  1784     apply (drule tendsto_at_within_vector_1, vector)
  1785     apply (auto simp: algebra_simps eventually_at tendsto_def)
  1786     done
  1787 
  1788 
  1789 subsection\<open>Explicit vector construction from lists\<close>
  1790 
  1791 definition "vector l = (\<chi> i. foldr (\<lambda>x f n. fun_upd (f (n+1)) n x) l (\<lambda>n x. 0) 1 i)"
  1792 
  1793 lemma vector_1: "(vector[x]) $1 = x"
  1794   unfolding vector_def by simp
  1795 
  1796 lemma vector_2:
  1797  "(vector[x,y]) $1 = x"
  1798  "(vector[x,y] :: 'a^2)$2 = (y::'a::zero)"
  1799   unfolding vector_def by simp_all
  1800 
  1801 lemma vector_3:
  1802  "(vector [x,y,z] ::('a::zero)^3)$1 = x"
  1803  "(vector [x,y,z] ::('a::zero)^3)$2 = y"
  1804  "(vector [x,y,z] ::('a::zero)^3)$3 = z"
  1805   unfolding vector_def by simp_all
  1806 
  1807 lemma forall_vector_1: "(\<forall>v::'a::zero^1. P v) \<longleftrightarrow> (\<forall>x. P(vector[x]))"
  1808   by (metis vector_1 vector_one)
  1809 
  1810 lemma forall_vector_2: "(\<forall>v::'a::zero^2. P v) \<longleftrightarrow> (\<forall>x y. P(vector[x, y]))"
  1811   apply auto
  1812   apply (erule_tac x="v$1" in allE)
  1813   apply (erule_tac x="v$2" in allE)
  1814   apply (subgoal_tac "vector [v$1, v$2] = v")
  1815   apply simp
  1816   apply (vector vector_def)
  1817   apply (simp add: forall_2)
  1818   done
  1819 
  1820 lemma forall_vector_3: "(\<forall>v::'a::zero^3. P v) \<longleftrightarrow> (\<forall>x y z. P(vector[x, y, z]))"
  1821   apply auto
  1822   apply (erule_tac x="v$1" in allE)
  1823   apply (erule_tac x="v$2" in allE)
  1824   apply (erule_tac x="v$3" in allE)
  1825   apply (subgoal_tac "vector [v$1, v$2, v$3] = v")
  1826   apply simp
  1827   apply (vector vector_def)
  1828   apply (simp add: forall_3)
  1829   done
  1830 
  1831 lemma bounded_linear_component_cart[intro]: "bounded_linear (\<lambda>x::real^'n. x $ k)"
  1832   apply (rule bounded_linearI[where K=1])
  1833   using component_le_norm_cart[of _ k] unfolding real_norm_def by auto
  1834 
  1835 lemma interval_split_cart:
  1836   "{a..b::real^'n} \<inter> {x. x$k \<le> c} = {a .. (\<chi> i. if i = k then min (b$k) c else b$i)}"
  1837   "cbox a b \<inter> {x. x$k \<ge> c} = {(\<chi> i. if i = k then max (a$k) c else a$i) .. b}"
  1838   apply (rule_tac[!] set_eqI)
  1839   unfolding Int_iff mem_box_cart mem_Collect_eq interval_cbox_cart
  1840   unfolding vec_lambda_beta
  1841   by auto
  1842 
  1843 lemmas cartesian_euclidean_space_uniform_limit_intros[uniform_limit_intros] =
  1844   bounded_linear.uniform_limit[OF blinfun.bounded_linear_right]
  1845   bounded_linear.uniform_limit[OF bounded_linear_vec_nth]
  1846   bounded_linear.uniform_limit[OF bounded_linear_component_cart]
  1847 
  1848 end