src/Pure/Isar/class.ML
author haftmann
Mon Mar 10 21:51:45 2008 +0100 (2008-03-10)
changeset 26247 b6608fbeaae1
parent 26238 c30bb8182da2
child 26259 d30f4a509361
permissions -rw-r--r--
some theorems named explicitly
     1 (*  Title:      Pure/Isar/class.ML
     2     ID:         $Id$
     3     Author:     Florian Haftmann, TU Muenchen
     4 
     5 Type classes derived from primitive axclasses and locales.
     6 *)
     7 
     8 signature CLASS =
     9 sig
    10   (*classes*)
    11   val class: bstring -> class list -> Element.context_i list
    12     -> string list -> theory -> string * Proof.context
    13   val class_cmd: bstring -> xstring list -> Element.context list
    14     -> xstring list -> theory -> string * Proof.context
    15 
    16   val init: class -> theory -> Proof.context
    17   val declare: string -> Markup.property list
    18     -> (string * mixfix) * term -> theory -> theory
    19   val abbrev: string -> Syntax.mode -> Markup.property list
    20     -> (string * mixfix) * term -> theory -> theory
    21   val refresh_syntax: class -> Proof.context -> Proof.context
    22 
    23   val intro_classes_tac: thm list -> tactic
    24   val default_intro_classes_tac: thm list -> tactic
    25   val prove_subclass: class * class -> thm -> theory -> theory
    26 
    27   val class_prefix: string -> string
    28   val is_class: theory -> class -> bool
    29   val these_params: theory -> sort -> (string * (string * typ)) list
    30   val print_classes: theory -> unit
    31 
    32   (*instances*)
    33   val init_instantiation: string list * (string * sort) list * sort
    34     -> theory -> local_theory
    35   val instantiation_instance: (local_theory -> local_theory)
    36     -> local_theory -> Proof.state
    37   val prove_instantiation_instance: (Proof.context -> tactic)
    38     -> local_theory -> local_theory
    39   val conclude_instantiation: local_theory -> local_theory
    40   val instantiation_param: local_theory -> string -> string option
    41   val confirm_declaration: string -> local_theory -> local_theory
    42   val pretty_instantiation: local_theory -> Pretty.T
    43 
    44   (*old axclass layer*)
    45   val axclass_cmd: bstring * xstring list
    46     -> ((bstring * Attrib.src list) * string list) list
    47     -> theory -> class * theory
    48   val classrel_cmd: xstring * xstring -> theory -> Proof.state
    49 
    50   (*old instance layer*)
    51   val instance_arity: (theory -> theory) -> arity -> theory -> Proof.state
    52   val instance_arity_cmd: bstring * xstring list * xstring -> theory -> Proof.state
    53 end;
    54 
    55 structure Class : CLASS =
    56 struct
    57 
    58 (** auxiliary **)
    59 
    60 val classN = "class";
    61 val introN = "intro";
    62 
    63 fun prove_interpretation tac prfx_atts expr inst =
    64   Locale.interpretation_i I prfx_atts expr inst
    65   #> Proof.global_terminal_proof
    66       (Method.Basic (K (Method.SIMPLE_METHOD tac), Position.none), NONE)
    67   #> ProofContext.theory_of;
    68 
    69 fun prove_interpretation_in tac after_qed (name, expr) =
    70   Locale.interpretation_in_locale
    71       (ProofContext.theory after_qed) (name, expr)
    72   #> Proof.global_terminal_proof
    73       (Method.Basic (K (Method.SIMPLE_METHOD tac), Position.none), NONE)
    74   #> ProofContext.theory_of;
    75 
    76 
    77 (** primitive axclass and instance commands **)
    78 
    79 fun axclass_cmd (class, raw_superclasses) raw_specs thy =
    80   let
    81     val ctxt = ProofContext.init thy;
    82     val superclasses = map (Sign.read_class thy) raw_superclasses;
    83     val name_atts = map ((apsnd o map) (Attrib.attribute thy) o fst)
    84       raw_specs;
    85     val axiomss = ProofContext.read_propp (ctxt, map (map (rpair []) o snd)
    86           raw_specs)
    87       |> snd
    88       |> (map o map) fst;
    89   in
    90     AxClass.define_class (class, superclasses) []
    91       (name_atts ~~ axiomss) thy
    92   end;
    93 
    94 local
    95 
    96 fun gen_instance mk_prop add_thm after_qed insts thy =
    97   let
    98     fun after_qed' results =
    99       ProofContext.theory ((fold o fold) add_thm results #> after_qed);
   100   in
   101     thy
   102     |> ProofContext.init
   103     |> Proof.theorem_i NONE after_qed' ((map (fn t => [(t, [])])
   104         o mk_prop thy) insts)
   105   end;
   106 
   107 in
   108 
   109 val instance_arity =
   110   gen_instance (Logic.mk_arities oo Sign.cert_arity) AxClass.add_arity;
   111 val instance_arity_cmd =
   112   gen_instance (Logic.mk_arities oo Sign.read_arity) AxClass.add_arity I;
   113 val classrel =
   114   gen_instance (single oo (Logic.mk_classrel oo AxClass.cert_classrel)) AxClass.add_classrel I;
   115 val classrel_cmd =
   116   gen_instance (single oo (Logic.mk_classrel oo AxClass.read_classrel)) AxClass.add_classrel I;
   117 
   118 end; (*local*)
   119 
   120 
   121 (** class data **)
   122 
   123 datatype class_data = ClassData of {
   124   consts: (string * string) list
   125     (*locale parameter ~> constant name*),
   126   base_sort: sort,
   127   inst: term option list
   128     (*canonical interpretation*),
   129   morphism: theory -> thm list -> morphism,
   130     (*partial morphism of canonical interpretation*)
   131   assm_intro: thm option,
   132   of_class: thm,
   133   axiom: thm option,
   134   defs: thm list,
   135   operations: (string * (class * (typ * term))) list
   136 };
   137 
   138 fun rep_class_data (ClassData d) = d;
   139 fun mk_class_data ((consts, base_sort, inst, morphism, assm_intro, of_class, axiom),
   140     (defs, operations)) =
   141   ClassData { consts = consts, base_sort = base_sort, inst = inst,
   142     morphism = morphism, assm_intro = assm_intro, of_class = of_class, axiom = axiom, 
   143     defs = defs, operations = operations };
   144 fun map_class_data f (ClassData { consts, base_sort, inst, morphism,
   145     assm_intro, of_class, axiom, defs, operations }) =
   146   mk_class_data (f ((consts, base_sort, inst, morphism, assm_intro, of_class, axiom),
   147     (defs, operations)));
   148 fun merge_class_data _ (ClassData { consts = consts,
   149     base_sort = base_sort, inst = inst, morphism = morphism, assm_intro = assm_intro,
   150     of_class = of_class, axiom = axiom, defs = defs1, operations = operations1 },
   151   ClassData { consts = _, base_sort = _, inst = _, morphism = _, assm_intro = _,
   152     of_class = _, axiom = _, defs = defs2, operations = operations2 }) =
   153   mk_class_data ((consts, base_sort, inst, morphism, assm_intro, of_class, axiom),
   154     (Thm.merge_thms (defs1, defs2),
   155       AList.merge (op =) (K true) (operations1, operations2)));
   156 
   157 structure ClassData = TheoryDataFun
   158 (
   159   type T = class_data Graph.T
   160   val empty = Graph.empty;
   161   val copy = I;
   162   val extend = I;
   163   fun merge _ = Graph.join merge_class_data;
   164 );
   165 
   166 
   167 (* queries *)
   168 
   169 val lookup_class_data = Option.map rep_class_data oo try o Graph.get_node o ClassData.get;
   170 
   171 fun the_class_data thy class = case lookup_class_data thy class
   172  of NONE => error ("Undeclared class " ^ quote class)
   173   | SOME data => data;
   174 
   175 val is_class = is_some oo lookup_class_data;
   176 
   177 val ancestry = Graph.all_succs o ClassData.get;
   178 
   179 fun these_params thy =
   180   let
   181     fun params class =
   182       let
   183         val const_typs = (#params o AxClass.get_info thy) class;
   184         val const_names = (#consts o the_class_data thy) class;
   185       in
   186         (map o apsnd) (fn c => (c, (the o AList.lookup (op =) const_typs) c)) const_names
   187       end;
   188   in maps params o ancestry thy end;
   189 
   190 fun these_defs thy = maps (these o Option.map #defs o lookup_class_data thy) o ancestry thy;
   191 
   192 fun partial_morphism thy class = #morphism (the_class_data thy class) thy [];
   193 fun morphism thy class = #morphism (the_class_data thy class) thy (these_defs thy [class]);
   194 
   195 fun these_assm_intros thy =
   196   Graph.fold (fn (_, (data, _)) => fold (insert Thm.eq_thm)
   197     ((the_list o #assm_intro o rep_class_data) data)) (ClassData.get thy) [];
   198 
   199 fun these_operations thy =
   200   maps (#operations o the_class_data thy) o ancestry thy;
   201 
   202 fun print_classes thy =
   203   let
   204     val ctxt = ProofContext.init thy;
   205     val algebra = Sign.classes_of thy;
   206     val arities =
   207       Symtab.empty
   208       |> Symtab.fold (fn (tyco, arities) => fold (fn (class, _) =>
   209            Symtab.map_default (class, []) (insert (op =) tyco)) arities)
   210              ((#arities o Sorts.rep_algebra) algebra);
   211     val the_arities = these o Symtab.lookup arities;
   212     fun mk_arity class tyco =
   213       let
   214         val Ss = Sorts.mg_domain algebra tyco [class];
   215       in Syntax.pretty_arity ctxt (tyco, Ss, [class]) end;
   216     fun mk_param (c, ty) = Pretty.str (Sign.extern_const thy c ^ " :: "
   217       ^ setmp show_sorts false (Syntax.string_of_typ ctxt o Type.strip_sorts) ty);
   218     fun mk_entry class = (Pretty.block o Pretty.fbreaks o map_filter I) [
   219       (SOME o Pretty.str) ("class " ^ Sign.extern_class thy class ^ ":"),
   220       (SOME o Pretty.block) [Pretty.str "supersort: ",
   221         (Syntax.pretty_sort ctxt o Sign.minimize_sort thy o Sign.super_classes thy) class],
   222       if is_class thy class then (SOME o Pretty.str)
   223         ("locale: " ^ Locale.extern thy class) else NONE,
   224       ((fn [] => NONE | ps => (SOME o Pretty.block o Pretty.fbreaks)
   225           (Pretty.str "parameters:" :: ps)) o map mk_param
   226         o these o Option.map #params o try (AxClass.get_info thy)) class,
   227       (SOME o Pretty.block o Pretty.breaks) [
   228         Pretty.str "instances:",
   229         Pretty.list "" "" (map (mk_arity class) (the_arities class))
   230       ]
   231     ]
   232   in
   233     (Pretty.writeln o Pretty.chunks o separate (Pretty.str "")
   234       o map mk_entry o Sorts.all_classes) algebra
   235   end;
   236 
   237 
   238 (* updaters *)
   239 
   240 fun add_class_data ((class, superclasses),
   241     (params, base_sort, inst, phi, axiom, assm_intro, of_class)) thy =
   242   let
   243     val operations = map (fn (v_ty as (_, ty), (c, _)) =>
   244       (c, (class, (ty, Free v_ty)))) params;
   245     val add_class = Graph.new_node (class,
   246         mk_class_data (((map o pairself) fst params, base_sort,
   247           map (SOME o Const) inst, phi, assm_intro, of_class, axiom), ([], operations)))
   248       #> fold (curry Graph.add_edge class) superclasses;
   249   in ClassData.map add_class thy end;
   250 
   251 fun register_operation class (c, (t, some_def)) thy =
   252   let
   253     val base_sort = (#base_sort o the_class_data thy) class;
   254     val prep_typ = map_atyps
   255       (fn TVar (vi as (v, _), sort) => if Name.aT = v
   256         then TFree (v, base_sort) else TVar (vi, sort));
   257     val t' = map_types prep_typ t;
   258     val ty' = Term.fastype_of t';
   259   in
   260     thy
   261     |> (ClassData.map o Graph.map_node class o map_class_data o apsnd)
   262       (fn (defs, operations) =>
   263         (fold cons (the_list some_def) defs,
   264           (c, (class, (ty', t'))) :: operations))
   265   end;
   266 
   267 
   268 (** rule calculation, tactics and methods **)
   269 
   270 val class_prefix = Logic.const_of_class o Sign.base_name;
   271 
   272 fun calculate sups base_sort assm_axiom param_map class thy =
   273   let
   274     (*static parts of morphism*)
   275     val subst_typ = map_atyps (fn TFree (v, sort) =>
   276           if v = Name.aT then TVar ((v, 0), [class]) else TVar ((v, 0), sort)
   277       | ty => ty);
   278     fun subst_aterm (t as Free (v, ty)) = (case AList.lookup (op =) param_map v
   279          of SOME (c, _) => Const (c, ty)
   280           | NONE => t)
   281       | subst_aterm t = t;
   282     fun instantiate thy sort = Thm.instantiate ([pairself (Thm.ctyp_of thy o TVar o pair (Name.aT, 0))
   283       (base_sort, sort)], map (fn (v, (c, ty)) => pairself (Thm.cterm_of thy)
   284         (Var ((v, 0), map_atyps (fn _ => TVar ((Name.aT, 0), sort)) ty),
   285           Const (c, map_atyps (fn _ => TVar ((Name.aT, 0), sort)) ty))) param_map);
   286     val instantiate_base_sort = instantiate thy base_sort;
   287     val instantiate_class = instantiate thy [class];
   288     val (proto_assm_intro, locale_intro) = Locale.intros thy class
   289       |> pairself (try the_single);
   290     val axiom_premises = map_filter (#axiom o the_class_data thy) sups
   291       @ the_list assm_axiom;
   292     val axiom = locale_intro
   293       |> Option.map (Drule.standard o (fn thm => thm OF axiom_premises) o instantiate_class)
   294       |> (fn x as SOME _ => x | NONE => assm_axiom);
   295     val lift_axiom = case axiom
   296      of SOME axiom => (fn thm => Thm.implies_elim thm axiom)
   297       | NONE => I;
   298 
   299     (*dynamic parts of morphism*)
   300     fun rew_term thy defs = Pattern.rewrite_term thy
   301       (map (Logic.dest_equals o Thm.prop_of) defs) [];
   302     fun subst_term thy defs = map_aterms subst_aterm #> rew_term thy defs
   303       #> map_types subst_typ;
   304     fun subst_thm defs = Drule.standard' #> instantiate_class #> lift_axiom
   305       #> MetaSimplifier.rewrite_rule defs;
   306     fun morphism thy defs = 
   307       Morphism.typ_morphism subst_typ
   308       $> Morphism.term_morphism (subst_term thy defs)
   309       $> Morphism.thm_morphism (subst_thm defs);
   310 
   311     (*class rules*)
   312     val defs = these_defs thy sups;
   313     val assm_intro = proto_assm_intro
   314       |> Option.map instantiate_base_sort
   315       |> Option.map (MetaSimplifier.rewrite_rule defs)
   316       |> Option.map Goal.close_result;
   317     val class_intro = (#intro o AxClass.get_info thy) class;
   318     val fixate = Thm.instantiate
   319       (map (pairself (Thm.ctyp_of thy)) [(TVar ((Name.aT, 0), []), TFree (Name.aT, base_sort)),
   320         (TVar ((Name.aT, 0), base_sort), TFree (Name.aT, base_sort))], [])
   321     val of_class_sups = if null sups
   322       then map (fixate o Thm.class_triv thy) base_sort
   323       else map (fixate o #of_class o the_class_data thy) sups;
   324     val locale_dests = map Drule.standard' (Locale.dests thy class);
   325     val num_trivs = case length locale_dests
   326      of 0 => if is_none axiom then 0 else 1
   327       | n => n;
   328     val pred_trivs = if num_trivs = 0 then []
   329       else the axiom
   330         |> Thm.prop_of
   331         |> (map_types o map_atyps o K) (TFree (Name.aT, base_sort))
   332         |> (Thm.assume o Thm.cterm_of thy)
   333         |> replicate num_trivs;
   334     val of_class = (fixate class_intro OF of_class_sups OF locale_dests OF pred_trivs)
   335       |> Drule.standard'
   336       |> Goal.close_result;
   337     val this_intro = assm_intro |> the_default class_intro;
   338   in
   339     thy
   340     |> Sign.sticky_prefix (class_prefix class ^ "_" ^ AxClass.axiomsN)
   341     |> PureThy.note Thm.internalK (AxClass.introN, this_intro)
   342     |> snd
   343     |> Sign.restore_naming thy
   344     |> pair (morphism, axiom, assm_intro, of_class)
   345   end;
   346 
   347 fun class_interpretation class facts defs thy =
   348   let
   349     val params = these_params thy [class];
   350     val consts = map (fst o snd) params;
   351     val constraints = map (fn c => map_atyps (K (TFree (Name.aT,
   352       [the (AxClass.class_of_param thy c)]))) (Sign.the_const_type thy c)) consts;
   353     val no_constraints = map (map_atyps (K (TFree (Name.aT, [])))) constraints;
   354     fun add_constraint c T = Sign.add_const_constraint (c, SOME T);
   355     val inst = (#inst o the_class_data thy) class;
   356     val tac = ALLGOALS (ProofContext.fact_tac facts);
   357     val prfx = class_prefix class;
   358   in
   359     thy
   360     |> fold2 add_constraint consts no_constraints
   361     |> prove_interpretation tac ((false, prfx), []) (Locale.Locale class)
   362           (inst, map (fn def => (("", []), def)) defs)
   363     |> fold2 add_constraint consts constraints
   364   end;
   365 
   366 fun prove_subclass (sub, sup) thm thy =
   367   let
   368     val of_class = (#of_class o the_class_data thy) sup;
   369     val intro = Drule.standard' (of_class OF [Drule.standard' thm]);
   370     val classrel = intro OF (the_list o #axiom o the_class_data thy) sub;
   371   in
   372     thy
   373     |> AxClass.add_classrel classrel
   374     |> prove_interpretation_in (ALLGOALS (ProofContext.fact_tac [thm]))
   375          I (sub, Locale.Locale sup)
   376     |> ClassData.map (Graph.add_edge (sub, sup))
   377   end;
   378 
   379 fun intro_classes_tac facts st =
   380   let
   381     val thy = Thm.theory_of_thm st;
   382     val classes = Sign.all_classes thy;
   383     val class_trivs = map (Thm.class_triv thy) classes;
   384     val class_intros = map_filter (try (#intro o AxClass.get_info thy)) classes;
   385     val assm_intros = these_assm_intros thy;
   386   in
   387     Method.intros_tac (class_trivs @ class_intros @ assm_intros) facts st
   388   end;
   389 
   390 fun default_intro_classes_tac [] = intro_classes_tac []
   391   | default_intro_classes_tac _ = no_tac;
   392 
   393 fun default_tac rules ctxt facts =
   394   HEADGOAL (Method.some_rule_tac rules ctxt facts) ORELSE
   395     default_intro_classes_tac facts;
   396 
   397 val _ = Context.add_setup (Method.add_methods
   398  [("intro_classes", Method.no_args (Method.METHOD intro_classes_tac),
   399     "back-chain introduction rules of classes"),
   400   ("default", Method.thms_ctxt_args (Method.METHOD oo default_tac),
   401     "apply some intro/elim rule")]);
   402 
   403 
   404 (** classes and class target **)
   405 
   406 (* class context syntax *)
   407 
   408 fun synchronize_class_syntax sups base_sort ctxt =
   409   let
   410     val thy = ProofContext.theory_of ctxt;
   411     fun subst_class_typ sort = map_atyps
   412       (fn TFree _ => TVar ((Name.aT, 0), sort) | ty' => ty');
   413     val operations = these_operations thy sups;
   414     val local_constraints =
   415       (map o apsnd) (subst_class_typ base_sort o fst o snd) operations;
   416     val global_constraints =
   417       (map o apsnd) (fn (class, (ty, _)) => subst_class_typ [class] ty) operations;
   418     fun declare_const (c, _) =
   419       let val b = Sign.base_name c
   420       in Sign.intern_const thy b = c ? Variable.declare_const (b, c) end;
   421     fun improve (c, ty) = (case AList.lookup (op =) local_constraints c
   422      of SOME ty' => (case try (Type.raw_match (ty', ty)) Vartab.empty
   423          of SOME tyenv => (case Vartab.lookup tyenv (Name.aT, 0)
   424              of SOME (_, ty' as TVar (tvar as (vi, _))) =>
   425                   if TypeInfer.is_param vi
   426                     then SOME (ty', TFree (Name.aT, base_sort))
   427                     else NONE
   428               | _ => NONE)
   429           | NONE => NONE)
   430       | NONE => NONE)
   431     fun subst (c, ty) = Option.map snd (AList.lookup (op =) operations c);
   432     val unchecks = map (fn (c, (_, (ty, t))) => (t, Const (c, ty))) operations;
   433   in
   434     ctxt
   435     |> fold declare_const local_constraints
   436     |> fold (ProofContext.add_const_constraint o apsnd SOME) local_constraints
   437     |> Overloading.map_improvable_syntax (K (((local_constraints, global_constraints),
   438         ((improve, subst), unchecks)), false))
   439   end;
   440 
   441 fun refresh_syntax class ctxt =
   442   let
   443     val thy = ProofContext.theory_of ctxt;
   444     val base_sort = (#base_sort o the_class_data thy) class;
   445   in synchronize_class_syntax [class] base_sort ctxt end;
   446 
   447 fun init_ctxt sups base_sort ctxt =
   448   ctxt
   449   |> Variable.declare_term
   450       (Logic.mk_type (TFree (Name.aT, base_sort)))
   451   |> synchronize_class_syntax sups base_sort
   452   |> Overloading.add_improvable_syntax;
   453 
   454 fun init class thy =
   455   thy
   456   |> Locale.init class
   457   |> init_ctxt [class] ((#base_sort o the_class_data thy) class);
   458 
   459 
   460 (* class definition *)
   461 
   462 local
   463 
   464 fun gen_class_spec prep_class process_expr thy raw_supclasses raw_elems =
   465   let
   466     val supclasses = map (prep_class thy) raw_supclasses;
   467     val supsort = Sign.minimize_sort thy supclasses;
   468     val sups = filter (is_class thy) supsort;
   469     val base_sort = if null sups then supsort else
   470       foldr1 (Sorts.inter_sort (Sign.classes_of thy))
   471         (map (#base_sort o the_class_data thy) sups);
   472     val suplocales = map Locale.Locale sups;
   473     val supexpr = Locale.Merge suplocales;
   474     val supparams = (map fst o Locale.parameters_of_expr thy) supexpr;
   475     val mergeexpr = Locale.Merge (suplocales);
   476     val constrain = Element.Constrains ((map o apsnd o map_atyps)
   477       (K (TFree (Name.aT, base_sort))) supparams);
   478     fun fork_syn (Element.Fixes xs) =
   479           fold_map (fn (c, ty, syn) => cons (c, syn) #> pair (c, ty, NoSyn)) xs
   480           #>> Element.Fixes
   481       | fork_syn x = pair x;
   482     fun fork_syntax elems =
   483       let
   484         val (elems', global_syntax) = fold_map fork_syn elems [];
   485       in (constrain :: elems', global_syntax) end;
   486     val (elems, global_syntax) =
   487       ProofContext.init thy
   488       |> Locale.cert_expr supexpr [constrain]
   489       |> snd
   490       |> init_ctxt sups base_sort
   491       |> process_expr Locale.empty raw_elems
   492       |> fst
   493       |> fork_syntax
   494   in (((sups, supparams), (supsort, base_sort, mergeexpr)), (elems, global_syntax)) end;
   495 
   496 val read_class_spec = gen_class_spec Sign.intern_class Locale.read_expr;
   497 val check_class_spec = gen_class_spec (K I) Locale.cert_expr;
   498 
   499 fun adjungate_axclass bname class base_sort sups supsort supparams global_syntax other_consts thy =
   500   let
   501     val supconsts = map fst supparams
   502       |> AList.make (the o AList.lookup (op =) (these_params thy sups))
   503       |> (map o apsnd o apsnd o map_atyps o K o TFree) (Name.aT, [class]);
   504     val all_params = map fst (Locale.parameters_of thy class);
   505     fun add_const (v, raw_ty) thy =
   506       let
   507         val c = Sign.full_name thy v;
   508         val ty = map_atyps (K (TFree (Name.aT, base_sort))) raw_ty;
   509         val ty0 = Type.strip_sorts ty;
   510         val ty' = map_atyps (K (TFree (Name.aT, [class]))) ty0;
   511         val syn = (the_default NoSyn o AList.lookup (op =) global_syntax) v;
   512       in
   513         thy
   514         |> Sign.declare_const [] (v, ty0, syn)
   515         |> snd
   516         |> pair ((v, ty), (c, ty'))
   517       end;
   518     fun add_consts raw_params thy =
   519       thy
   520       |> Sign.add_path (Logic.const_of_class bname)
   521       |> fold_map add_const raw_params
   522       ||> Sign.restore_naming thy
   523       |-> (fn params => pair (supconsts @ (map o apfst) fst params, params));
   524     fun globalize param_map = map_aterms
   525       (fn Free (v, ty) => Const ((fst o the o AList.lookup (op =) param_map) v, ty)
   526         | t => t);
   527     val raw_pred = Locale.intros thy class
   528       |> fst
   529       |> map (Logic.unvarify o Logic.strip_imp_concl o Thm.prop_of);
   530     fun get_axiom thy = case (#axioms o AxClass.get_info thy) class
   531      of [] => NONE
   532       | [thm] => SOME thm;
   533   in
   534     thy
   535     |> add_consts ((snd o chop (length supparams)) all_params)
   536     |-> (fn (param_map, params) => AxClass.define_class (bname, supsort)
   537           (map (fst o snd) params @ other_consts)
   538           [((bname ^ "_" ^ AxClass.axiomsN, []), map (globalize param_map) raw_pred)]
   539     #> snd
   540     #> `get_axiom
   541     #-> (fn assm_axiom => fold (Sign.add_const_constraint o apsnd SOME o snd) params
   542     #> pair (param_map, params, assm_axiom)))
   543   end;
   544 
   545 fun gen_class prep_spec prep_param bname
   546     raw_supclasses raw_elems raw_other_consts thy =
   547   let
   548     val class = Sign.full_name thy bname;
   549     val (((sups, supparams), (supsort, base_sort, mergeexpr)), (elems, global_syntax)) =
   550       prep_spec thy raw_supclasses raw_elems;
   551     val other_consts = map (tap (Sign.the_const_type thy) o prep_param thy) raw_other_consts;
   552   in
   553     thy
   554     |> Locale.add_locale_i (SOME "") bname mergeexpr elems
   555     |> snd
   556     |> ProofContext.theory_of
   557     |> adjungate_axclass bname class base_sort sups supsort supparams global_syntax other_consts
   558     |-> (fn (param_map, params, assm_axiom) =>
   559         calculate sups base_sort assm_axiom param_map class
   560     #-> (fn (morphism, axiom, assm_intro, of_class) =>
   561         add_class_data ((class, sups), (params, base_sort,
   562           map snd param_map, morphism, axiom, assm_intro, of_class))
   563     #> class_interpretation class (the_list axiom) []))
   564     |> init class
   565     |> pair class
   566   end;
   567 
   568 fun read_const thy = #1 o Term.dest_Const o ProofContext.read_const (ProofContext.init thy);
   569 
   570 in
   571 
   572 val class_cmd = gen_class read_class_spec read_const;
   573 val class = gen_class check_class_spec (K I);
   574 
   575 end; (*local*)
   576 
   577 
   578 (* class target *)
   579 
   580 fun declare class pos ((c, mx), dict) thy =
   581   let
   582     val prfx = class_prefix class;
   583     val thy' = thy |> Sign.add_path prfx;
   584     val phi = partial_morphism thy' class;
   585 
   586     val c' = Sign.full_name thy' c;
   587     val dict' = Morphism.term phi dict;
   588     val dict_def = map_types Logic.unvarifyT dict';
   589     val ty' = Term.fastype_of dict_def;
   590     val ty'' = Type.strip_sorts ty';
   591     val def_eq = Logic.mk_equals (Const (c', ty'), dict_def);
   592     fun get_axiom thy = ((Thm.varifyT o Thm.get_axiom_i thy) c', thy);
   593   in
   594     thy'
   595     |> Sign.declare_const pos (c, ty'', mx) |> snd
   596     |> Thm.add_def false false (c, def_eq)
   597     |>> Thm.symmetric
   598     ||>> get_axiom
   599     |-> (fn (def, def') => class_interpretation class [def] [Thm.prop_of def]
   600       #> register_operation class (c', (dict', SOME (Thm.symmetric def')))
   601       #> PureThy.note Thm.internalK (c, def')
   602       #> snd)
   603     |> Sign.restore_naming thy
   604     |> Sign.add_const_constraint (c', SOME ty')
   605   end;
   606 
   607 fun abbrev class prmode pos ((c, mx), rhs) thy =
   608   let
   609     val prfx = class_prefix class;
   610     val thy' = thy |> Sign.add_path prfx;
   611     val phi = morphism thy class;
   612 
   613     val c' = Sign.full_name thy' c;
   614     val rhs' = Morphism.term phi rhs;
   615     val ty' = Logic.unvarifyT (Term.fastype_of rhs');
   616   in
   617     thy'
   618     |> Sign.add_abbrev (#1 prmode) pos (c, map_types Type.strip_sorts rhs') |> snd
   619     |> Sign.add_const_constraint (c', SOME ty')
   620     |> Sign.notation true prmode [(Const (c', ty'), mx)]
   621     |> register_operation class (c', (rhs', NONE))
   622     |> Sign.restore_naming thy
   623   end;
   624 
   625 
   626 (** instantiation target **)
   627 
   628 (* bookkeeping *)
   629 
   630 datatype instantiation = Instantiation of {
   631   arities: string list * (string * sort) list * sort,
   632   params: ((string * string) * (string * typ)) list
   633     (*(instantiation parameter, type constructor), (local instantiation parameter, typ)*)
   634 }
   635 
   636 structure Instantiation = ProofDataFun
   637 (
   638   type T = instantiation
   639   fun init _ = Instantiation { arities = ([], [], []), params = [] };
   640 );
   641 
   642 fun mk_instantiation (arities, params) =
   643   Instantiation { arities = arities, params = params };
   644 fun get_instantiation lthy = case Instantiation.get (LocalTheory.target_of lthy)
   645  of Instantiation data => data;
   646 fun map_instantiation f = (LocalTheory.target o Instantiation.map)
   647   (fn Instantiation { arities, params } => mk_instantiation (f (arities, params)));
   648 
   649 fun the_instantiation lthy = case get_instantiation lthy
   650  of { arities = ([], [], []), ... } => error "No instantiation target"
   651   | data => data;
   652 
   653 val instantiation_params = #params o get_instantiation;
   654 
   655 fun instantiation_param lthy v = instantiation_params lthy
   656   |> find_first (fn (_, (v', _)) => v = v')
   657   |> Option.map (fst o fst);
   658 
   659 
   660 (* syntax *)
   661 
   662 fun synchronize_inst_syntax ctxt =
   663   let
   664     val Instantiation { arities = (_, _, sorts), params = params } = Instantiation.get ctxt;
   665     val thy = ProofContext.theory_of ctxt;
   666     val operations = these_operations thy sorts;
   667     fun subst_class_typ sort = map_atyps
   668       (fn TFree _ => TVar ((Name.aT, 0), sort) | ty' => ty');
   669     val local_constraints =
   670       (map o apsnd) (subst_class_typ [] o fst o snd) operations;
   671     val global_constraints = map_filter (fn (c, (class, (ty, _))) =>
   672       if exists (fn ((c', _), _) => c = c') params
   673         then SOME (c, subst_class_typ [class] ty)
   674         else NONE) operations;
   675     fun improve (c, ty) = case AxClass.inst_tyco_of thy (c, ty)
   676          of SOME tyco => (case AList.lookup (op =) params (c, tyco)
   677              of SOME (_, ty') => SOME (ty, ty')
   678               | NONE => NONE)
   679           | NONE => NONE;
   680           (*| NONE => (case map_filter
   681                (fn ((c', _), (_, ty')) => if c' = c then SOME ty' else NONE) params
   682              of [ty'] => (case Sign.const_typargs thy (c, ty)
   683                  of [TVar (vi, _)] => if TypeInfer.is_param vi then SOME (ty, ty') else NONE
   684                   | _ => NONE)
   685               | _ => NONE*);
   686     fun subst (c, ty) = case AxClass.inst_tyco_of thy (c, ty)
   687          of SOME tyco => (case AList.lookup (op =) params (c, tyco)
   688              of SOME (v_ty as (_, ty)) => SOME (ty, Free v_ty)
   689               | NONE => NONE)
   690           | NONE => NONE;
   691     val unchecks =
   692       map (fn ((c, _), v_ty as (_, ty)) => (Free v_ty, Const (c, ty))) params;
   693   in
   694     ctxt
   695     |> fold (ProofContext.add_const_constraint o apsnd SOME) local_constraints
   696     |> Overloading.map_improvable_syntax (K (((local_constraints, global_constraints),
   697         ((improve, subst), unchecks)), false))
   698   end;
   699 
   700 
   701 (* target *)
   702 
   703 val sanatize_name = (*FIXME*)
   704   let
   705     fun is_valid s = Symbol.is_ascii_letter s orelse Symbol.is_ascii_digit s
   706       orelse s = "'" orelse s = "_";
   707     val is_junk = not o is_valid andf Symbol.is_regular;
   708     val junk = Scan.many is_junk;
   709     val scan_valids = Symbol.scanner "Malformed input"
   710       ((junk |--
   711         (Scan.optional (Scan.one Symbol.is_ascii_letter) "x" ^^ (Scan.many is_valid >> implode)
   712         --| junk))
   713       ::: Scan.repeat ((Scan.many1 is_valid >> implode) --| junk));
   714   in
   715     explode #> scan_valids #> implode
   716   end;
   717 
   718 fun init_instantiation (tycos, vs, sort) thy =
   719   let
   720     val _ = if null tycos then error "At least one arity must be given" else ();
   721     val _ = map (the_class_data thy) sort;
   722     fun type_name "*" = "prod"
   723       | type_name "+" = "sum"
   724       | type_name s = sanatize_name (NameSpace.base s); (*FIXME*)
   725     fun get_param tyco (param, (c, ty)) = if can (AxClass.param_of_inst thy) (c, tyco)
   726       then NONE else SOME ((c, tyco),
   727         (param ^ "_" ^ type_name tyco, map_atyps (K (Type (tyco, map TFree vs))) ty));
   728     val params = map_product get_param tycos (these_params thy sort) |> map_filter I;
   729   in
   730     thy
   731     |> ProofContext.init
   732     |> Instantiation.put (mk_instantiation ((tycos, vs, sort), params))
   733     |> fold (Variable.declare_term o Logic.mk_type o TFree) vs
   734     |> fold (Variable.declare_names o Free o snd) params
   735     |> synchronize_inst_syntax
   736     |> Overloading.add_improvable_syntax
   737   end;
   738 
   739 fun confirm_declaration c = (map_instantiation o apsnd)
   740   (filter_out (fn (_, (c', _)) => c' = c))
   741   #> LocalTheory.target synchronize_inst_syntax
   742 
   743 fun gen_instantiation_instance do_proof after_qed lthy =
   744   let
   745     val (tycos, vs, sort) = (#arities o the_instantiation) lthy;
   746     val arities_proof = maps (fn tyco => Logic.mk_arities (tyco, map snd vs, sort)) tycos;
   747     fun after_qed' results =
   748       LocalTheory.theory (fold (AxClass.add_arity o Thm.varifyT) results)
   749       #> after_qed;
   750   in
   751     lthy
   752     |> do_proof after_qed' arities_proof
   753   end;
   754 
   755 val instantiation_instance = gen_instantiation_instance (fn after_qed => fn ts =>
   756   Proof.theorem_i NONE (after_qed o map the_single) (map (fn t => [(t, [])]) ts));
   757 
   758 fun prove_instantiation_instance tac = gen_instantiation_instance (fn after_qed =>
   759   fn ts => fn lthy => after_qed (map (fn t => Goal.prove lthy [] [] t
   760     (fn {context, ...} => tac context)) ts) lthy) I;
   761 
   762 fun conclude_instantiation lthy =
   763   let
   764     val { arities, params } = the_instantiation lthy;
   765     val (tycos, vs, sort) = arities;
   766     val thy = ProofContext.theory_of lthy;
   767     val _ = map (fn tyco => if Sign.of_sort thy
   768         (Type (tyco, map TFree vs), sort)
   769       then () else error ("Missing instance proof for type " ^ quote (Sign.extern_type thy tyco)))
   770         tycos;
   771     (*this checkpoint should move to AxClass as soon as "attach" has disappeared*)
   772     val _ = case map (fst o snd) params
   773      of [] => ()
   774       | cs => Output.legacy_feature
   775           ("Missing specifications for overloaded parameters " ^ commas_quote cs)
   776   in lthy end;
   777 
   778 fun pretty_instantiation lthy =
   779   let
   780     val { arities, params } = the_instantiation lthy;
   781     val (tycos, vs, sort) = arities;
   782     val thy = ProofContext.theory_of lthy;
   783     fun pr_arity tyco = Syntax.pretty_arity lthy (tyco, map snd vs, sort);
   784     fun pr_param ((c, _), (v, ty)) =
   785       (Pretty.block o Pretty.breaks) [Pretty.str v, Pretty.str "==",
   786         (Pretty.str o Sign.extern_const thy) c, Pretty.str "::", Sign.pretty_typ thy ty];
   787   in
   788     (Pretty.block o Pretty.fbreaks)
   789       (Pretty.str "instantiation" :: map pr_arity tycos @ map pr_param params)
   790   end;
   791 
   792 end;
   793