src/HOL/Algebra/Sylow.thy
author paulson <lp15@cam.ac.uk>
Sat Jun 30 15:44:04 2018 +0100 (12 months ago)
changeset 68551 b680e74eb6f2
parent 68488 dfbd80c3d180
child 68561 5e85cda58af6
permissions -rw-r--r--
More on Algebra by Paulo and Martin
     1 (*  Title:      HOL/Algebra/Sylow.thy
     2     Author:     Florian Kammueller, with new proofs by L C Paulson
     3 *)
     4 
     5 theory Sylow
     6   imports Coset Exponent
     7 begin
     8 
     9 text \<open>See also @{cite "Kammueller-Paulson:1999"}.\<close>
    10 
    11 text \<open>The combinatorial argument is in theory @{theory "HOL-Algebra.Exponent"}.\<close>
    12 
    13 lemma le_extend_mult: "\<lbrakk>0 < c; a \<le> b\<rbrakk> \<Longrightarrow> a \<le> b * c"
    14   for c :: nat
    15   by (metis divisors_zero dvd_triv_left leI less_le_trans nat_dvd_not_less zero_less_iff_neq_zero)
    16 
    17 locale sylow = group +
    18   fixes p and a and m and calM and RelM
    19   assumes prime_p: "prime p"
    20     and order_G: "order G = (p^a) * m"
    21     and finite_G[iff]: "finite (carrier G)"
    22   defines "calM \<equiv> {s. s \<subseteq> carrier G \<and> card s = p^a}"
    23     and "RelM \<equiv> {(N1, N2). N1 \<in> calM \<and> N2 \<in> calM \<and> (\<exists>g \<in> carrier G. N1 = N2 #> g)}"
    24 begin
    25 
    26 lemma RelM_refl_on: "refl_on calM RelM"
    27   by (auto simp: refl_on_def RelM_def calM_def) (blast intro!: coset_mult_one [symmetric])
    28 
    29 lemma RelM_sym: "sym RelM"
    30 proof (unfold sym_def RelM_def, clarify)
    31   fix y g
    32   assume "y \<in> calM"
    33     and g: "g \<in> carrier G"
    34   then have "y = y #> g #> (inv g)"
    35     by (simp add: coset_mult_assoc calM_def)
    36   then show "\<exists>g'\<in>carrier G. y = y #> g #> g'"
    37     by (blast intro: g)
    38 qed
    39 
    40 lemma RelM_trans: "trans RelM"
    41   by (auto simp add: trans_def RelM_def calM_def coset_mult_assoc)
    42 
    43 lemma RelM_equiv: "equiv calM RelM"
    44   unfolding equiv_def by (blast intro: RelM_refl_on RelM_sym RelM_trans)
    45 
    46 lemma M_subset_calM_prep: "M' \<in> calM // RelM  \<Longrightarrow> M' \<subseteq> calM"
    47   unfolding RelM_def by (blast elim!: quotientE)
    48 
    49 end
    50 
    51 subsection \<open>Main Part of the Proof\<close>
    52 
    53 locale sylow_central = sylow +
    54   fixes H and M1 and M
    55   assumes M_in_quot: "M \<in> calM // RelM"
    56     and not_dvd_M: "\<not> (p ^ Suc (multiplicity p m) dvd card M)"
    57     and M1_in_M: "M1 \<in> M"
    58   defines "H \<equiv> {g. g \<in> carrier G \<and> M1 #> g = M1}"
    59 begin
    60 
    61 lemma M_subset_calM: "M \<subseteq> calM"
    62   by (rule M_in_quot [THEN M_subset_calM_prep])
    63 
    64 lemma card_M1: "card M1 = p^a"
    65   using M1_in_M M_subset_calM calM_def by blast
    66 
    67 lemma exists_x_in_M1: "\<exists>x. x \<in> M1"
    68   using prime_p [THEN prime_gt_Suc_0_nat] card_M1
    69   by (metis Suc_lessD card_eq_0_iff empty_subsetI equalityI gr_implies_not0 nat_zero_less_power_iff subsetI)
    70 
    71 lemma M1_subset_G [simp]: "M1 \<subseteq> carrier G"
    72   using M1_in_M M_subset_calM calM_def mem_Collect_eq subsetCE by blast
    73 
    74 lemma M1_inj_H: "\<exists>f \<in> H\<rightarrow>M1. inj_on f H"
    75 proof -
    76   from exists_x_in_M1 obtain m1 where m1M: "m1 \<in> M1"..
    77   have m1: "m1 \<in> carrier G"
    78     by (simp add: m1M M1_subset_G [THEN subsetD])
    79   show ?thesis
    80   proof
    81     show "inj_on (\<lambda>z\<in>H. m1 \<otimes> z) H"
    82       by (simp add: H_def inj_on_def m1)
    83     show "restrict ((\<otimes>) m1) H \<in> H \<rightarrow> M1"
    84     proof (rule restrictI)
    85       fix z
    86       assume zH: "z \<in> H"
    87       show "m1 \<otimes> z \<in> M1"
    88       proof -
    89         from zH
    90         have zG: "z \<in> carrier G" and M1zeq: "M1 #> z = M1"
    91           by (auto simp add: H_def)
    92         show ?thesis
    93           by (rule subst [OF M1zeq]) (simp add: m1M zG rcosI)
    94       qed
    95     qed
    96   qed
    97 qed
    98 
    99 end
   100 
   101 
   102 subsection \<open>Discharging the Assumptions of \<open>sylow_central\<close>\<close>
   103 
   104 context sylow
   105 begin
   106 
   107 lemma EmptyNotInEquivSet: "{} \<notin> calM // RelM"
   108   by (blast elim!: quotientE dest: RelM_equiv [THEN equiv_class_self])
   109 
   110 lemma existsM1inM: "M \<in> calM // RelM \<Longrightarrow> \<exists>M1. M1 \<in> M"
   111   using RelM_equiv equiv_Eps_in by blast
   112 
   113 lemma zero_less_o_G: "0 < order G"
   114   by (simp add: order_def card_gt_0_iff carrier_not_empty)
   115 
   116 lemma zero_less_m: "m > 0"
   117   using zero_less_o_G by (simp add: order_G)
   118 
   119 lemma card_calM: "card calM = (p^a) * m choose p^a"
   120   by (simp add: calM_def n_subsets order_G [symmetric] order_def)
   121 
   122 lemma zero_less_card_calM: "card calM > 0"
   123   by (simp add: card_calM zero_less_binomial le_extend_mult zero_less_m)
   124 
   125 lemma max_p_div_calM: "\<not> (p ^ Suc (multiplicity p m) dvd card calM)"
   126 proof
   127   assume "p ^ Suc (multiplicity p m) dvd card calM"
   128   with zero_less_card_calM prime_p
   129   have "Suc (multiplicity p m) \<le> multiplicity p (card calM)"
   130     by (intro multiplicity_geI) auto
   131   then have "multiplicity p m < multiplicity p (card calM)" by simp
   132   also have "multiplicity p m = multiplicity p (card calM)"
   133     by (simp add: const_p_fac prime_p zero_less_m card_calM)
   134   finally show False by simp
   135 qed
   136 
   137 lemma finite_calM: "finite calM"
   138   unfolding calM_def by (rule finite_subset [where B = "Pow (carrier G)"]) auto
   139 
   140 lemma lemma_A1: "\<exists>M \<in> calM // RelM. \<not> (p ^ Suc (multiplicity p m) dvd card M)"
   141   using RelM_equiv equiv_imp_dvd_card finite_calM max_p_div_calM by blast
   142 
   143 end
   144 
   145 
   146 subsubsection \<open>Introduction and Destruct Rules for \<open>H\<close>\<close>
   147 
   148 context sylow_central
   149 begin
   150 
   151 lemma H_I: "\<lbrakk>g \<in> carrier G; M1 #> g = M1\<rbrakk> \<Longrightarrow> g \<in> H"
   152   by (simp add: H_def)
   153 
   154 lemma H_into_carrier_G: "x \<in> H \<Longrightarrow> x \<in> carrier G"
   155   by (simp add: H_def)
   156 
   157 lemma in_H_imp_eq: "g \<in> H \<Longrightarrow> M1 #> g = M1"
   158   by (simp add: H_def)
   159 
   160 lemma H_m_closed: "\<lbrakk>x \<in> H; y \<in> H\<rbrakk> \<Longrightarrow> x \<otimes> y \<in> H"
   161   by (simp add: H_def coset_mult_assoc [symmetric])
   162 
   163 lemma H_not_empty: "H \<noteq> {}"
   164   by (force simp add: H_def intro: exI [of _ \<one>])
   165 
   166 lemma H_is_subgroup: "subgroup H G"
   167 proof (rule subgroupI)
   168   show "H \<subseteq> carrier G"
   169     using H_into_carrier_G by blast
   170   show "\<And>a. a \<in> H \<Longrightarrow> inv a \<in> H"
   171     by (metis H_I H_into_carrier_G H_m_closed M1_subset_G Units_eq Units_inv_closed Units_inv_inv coset_mult_inv1 in_H_imp_eq)
   172   show "\<And>a b. \<lbrakk>a \<in> H; b \<in> H\<rbrakk> \<Longrightarrow> a \<otimes> b \<in> H"
   173     by (blast intro: H_m_closed)
   174 qed (use H_not_empty in auto)
   175 
   176 lemma rcosetGM1g_subset_G: "\<lbrakk>g \<in> carrier G; x \<in> M1 #> g\<rbrakk> \<Longrightarrow> x \<in> carrier G"
   177   by (blast intro: M1_subset_G [THEN r_coset_subset_G, THEN subsetD])
   178 
   179 lemma finite_M1: "finite M1"
   180   by (rule finite_subset [OF M1_subset_G finite_G])
   181 
   182 lemma finite_rcosetGM1g: "g \<in> carrier G \<Longrightarrow> finite (M1 #> g)"
   183   using rcosetGM1g_subset_G finite_G M1_subset_G cosets_finite rcosetsI by blast
   184 
   185 lemma M1_cardeq_rcosetGM1g: "g \<in> carrier G \<Longrightarrow> card (M1 #> g) = card M1"
   186   by (metis M1_subset_G card_rcosets_equal rcosetsI)
   187 
   188 lemma M1_RelM_rcosetGM1g: 
   189   assumes "g \<in> carrier G"
   190   shows "(M1, M1 #> g) \<in> RelM"
   191 proof -
   192   have "M1 #> g \<subseteq> carrier G"
   193     by (simp add: assms r_coset_subset_G)
   194   moreover have "card (M1 #> g) = p ^ a"
   195     using assms by (simp add: card_M1 M1_cardeq_rcosetGM1g)
   196   moreover have "\<exists>h\<in>carrier G. M1 = M1 #> g #> h"
   197     by (metis assms M1_subset_G coset_mult_assoc coset_mult_one r_inv_ex)
   198   ultimately show ?thesis
   199     by (simp add: RelM_def calM_def card_M1)
   200 qed
   201 
   202 end
   203 
   204 
   205 subsection \<open>Equal Cardinalities of \<open>M\<close> and the Set of Cosets\<close>
   206 
   207 text \<open>Injections between @{term M} and @{term "rcosets\<^bsub>G\<^esub> H"} show that
   208  their cardinalities are equal.\<close>
   209 
   210 lemma ElemClassEquiv: "\<lbrakk>equiv A r; C \<in> A // r\<rbrakk> \<Longrightarrow> \<forall>x \<in> C. \<forall>y \<in> C. (x, y) \<in> r"
   211   unfolding equiv_def quotient_def sym_def trans_def by blast
   212 
   213 context sylow_central
   214 begin
   215 
   216 lemma M_elem_map: "M2 \<in> M \<Longrightarrow> \<exists>g. g \<in> carrier G \<and> M1 #> g = M2"
   217   using M1_in_M M_in_quot [THEN RelM_equiv [THEN ElemClassEquiv]]
   218   by (simp add: RelM_def) (blast dest!: bspec)
   219 
   220 lemmas M_elem_map_carrier = M_elem_map [THEN someI_ex, THEN conjunct1]
   221 
   222 lemmas M_elem_map_eq = M_elem_map [THEN someI_ex, THEN conjunct2]
   223 
   224 lemma M_funcset_rcosets_H:
   225   "(\<lambda>x\<in>M. H #> (SOME g. g \<in> carrier G \<and> M1 #> g = x)) \<in> M \<rightarrow> rcosets H"
   226   by (metis (lifting) H_is_subgroup M_elem_map_carrier rcosetsI restrictI subgroup.subset)
   227 
   228 lemma inj_M_GmodH: "\<exists>f \<in> M \<rightarrow> rcosets H. inj_on f M"
   229 proof
   230   let ?inv = "\<lambda>x. SOME g. g \<in> carrier G \<and> M1 #> g = x"
   231   show "inj_on (\<lambda>x\<in>M. H #> ?inv x) M"
   232   proof (rule inj_onI, simp)
   233     fix x y
   234     assume eq: "H #> ?inv x = H #> ?inv y" and xy: "x \<in> M" "y \<in> M"
   235     have "x = M1 #> ?inv x"
   236       by (simp add: M_elem_map_eq \<open>x \<in> M\<close>)
   237     also have "... = M1 #> ?inv y"
   238     proof (rule coset_mult_inv1 [OF in_H_imp_eq [OF coset_join1]])
   239       show "H #> ?inv x \<otimes> inv (?inv y) = H"
   240         by (simp add: H_into_carrier_G M_elem_map_carrier xy coset_mult_inv2 eq subsetI)
   241     qed (simp_all add: H_is_subgroup M_elem_map_carrier xy)
   242     also have "... = y"
   243       using M_elem_map_eq \<open>y \<in> M\<close> by simp
   244     finally show "x=y" .
   245   qed
   246   show "(\<lambda>x\<in>M. H #> ?inv x) \<in> M \<rightarrow> rcosets H"
   247     by (rule M_funcset_rcosets_H)
   248 qed
   249 
   250 end
   251 
   252 
   253 subsubsection \<open>The Opposite Injection\<close>
   254 
   255 context sylow_central
   256 begin
   257 
   258 lemma H_elem_map: "H1 \<in> rcosets H \<Longrightarrow> \<exists>g. g \<in> carrier G \<and> H #> g = H1"
   259   by (auto simp: RCOSETS_def)
   260 
   261 lemmas H_elem_map_carrier = H_elem_map [THEN someI_ex, THEN conjunct1]
   262 
   263 lemmas H_elem_map_eq = H_elem_map [THEN someI_ex, THEN conjunct2]
   264 
   265 lemma rcosets_H_funcset_M:
   266   "(\<lambda>C \<in> rcosets H. M1 #> (SOME g. g \<in> carrier G \<and> H #> g = C)) \<in> rcosets H \<rightarrow> M"
   267   using in_quotient_imp_closed [OF RelM_equiv M_in_quot _  M1_RelM_rcosetGM1g]
   268   by (simp add: M1_in_M H_elem_map_carrier RCOSETS_def)
   269 
   270 lemma inj_GmodH_M: "\<exists>g \<in> rcosets H\<rightarrow>M. inj_on g (rcosets H)"
   271 proof
   272   let ?inv = "\<lambda>x. SOME g. g \<in> carrier G \<and> H #> g = x"
   273   show "inj_on (\<lambda>C\<in>rcosets H. M1 #> ?inv C) (rcosets H)"
   274   proof (rule inj_onI, simp)
   275     fix x y
   276     assume eq: "M1 #> ?inv x = M1 #> ?inv y" and xy: "x \<in> rcosets H" "y \<in> rcosets H"
   277     have "x = H #> ?inv x"
   278       by (simp add: H_elem_map_eq \<open>x \<in> rcosets H\<close>)
   279     also have "... = H #> ?inv y"
   280     proof (rule coset_mult_inv1 [OF coset_join2])
   281       show "?inv x \<otimes> inv (?inv y) \<in> carrier G"
   282         by (simp add: H_elem_map_carrier \<open>x \<in> rcosets H\<close> \<open>y \<in> rcosets H\<close>)
   283       then show "(?inv x) \<otimes> inv (?inv y) \<in> H"
   284         by (simp add: H_I H_elem_map_carrier xy coset_mult_inv2 eq)
   285       show "H \<subseteq> carrier G"
   286         by (simp add: H_is_subgroup subgroup.subset)
   287     qed (simp_all add: H_is_subgroup H_elem_map_carrier xy)
   288     also have "... = y"
   289       by (simp add: H_elem_map_eq \<open>y \<in> rcosets H\<close>)
   290     finally show "x=y" .
   291   qed
   292   show "(\<lambda>C\<in>rcosets H. M1 #> ?inv C) \<in> rcosets H \<rightarrow> M"
   293     using rcosets_H_funcset_M by blast
   294 qed
   295 
   296 lemma calM_subset_PowG: "calM \<subseteq> Pow (carrier G)"
   297   by (auto simp: calM_def)
   298 
   299 
   300 lemma finite_M: "finite M"
   301   by (metis M_subset_calM finite_calM rev_finite_subset)
   302 
   303 lemma cardMeqIndexH: "card M = card (rcosets H)"
   304   using inj_M_GmodH inj_GmodH_M
   305   by (blast intro: card_bij finite_M H_is_subgroup rcosets_subset_PowG [THEN finite_subset])
   306 
   307 lemma index_lem: "card M * card H = order G"
   308   by (simp add: cardMeqIndexH lagrange H_is_subgroup)
   309 
   310 lemma card_H_eq: "card H = p^a"
   311 proof (rule antisym)
   312   show "p^a \<le> card H"
   313   proof (rule dvd_imp_le)
   314     show "p ^ a dvd card H"
   315       apply (rule div_combine [OF prime_imp_prime_elem[OF prime_p] not_dvd_M])
   316       by (simp add: index_lem multiplicity_dvd order_G power_add)
   317     show "0 < card H"
   318       by (blast intro: subgroup.finite_imp_card_positive H_is_subgroup)
   319   qed
   320 next
   321   show "card H \<le> p^a"
   322     using M1_inj_H card_M1 card_inj finite_M1 by fastforce
   323 qed
   324 
   325 end
   326 
   327 lemma (in sylow) sylow_thm: "\<exists>H. subgroup H G \<and> card H = p^a"
   328 proof -
   329   obtain M where M: "M \<in> calM // RelM" "\<not> (p ^ Suc (multiplicity p m) dvd card M)"
   330     using lemma_A1 by blast
   331   then obtain M1 where "M1 \<in> M"
   332     by (metis existsM1inM) 
   333   define H where "H \<equiv> {g. g \<in> carrier G \<and> M1 #> g = M1}"
   334   with M \<open>M1 \<in> M\<close>
   335   interpret sylow_central G p a m calM RelM H M1 M
   336     by unfold_locales (auto simp add: H_def calM_def RelM_def)
   337   show ?thesis
   338     using H_is_subgroup card_H_eq by blast
   339 qed
   340 
   341 text \<open>Needed because the locale's automatic definition refers to
   342   @{term "semigroup G"} and @{term "group_axioms G"} rather than
   343   simply to @{term "group G"}.\<close>
   344 lemma sylow_eq: "sylow G p a m \<longleftrightarrow> group G \<and> sylow_axioms G p a m"
   345   by (simp add: sylow_def group_def)
   346 
   347 
   348 subsection \<open>Sylow's Theorem\<close>
   349 
   350 theorem sylow_thm:
   351   "\<lbrakk>prime p; group G; order G = (p^a) * m; finite (carrier G)\<rbrakk>
   352     \<Longrightarrow> \<exists>H. subgroup H G \<and> card H = p^a"
   353   by (rule sylow.sylow_thm [of G p a m]) (simp add: sylow_eq sylow_axioms_def)
   354 
   355 end