src/HOL/Algebra/UnivPoly.thy
author paulson <lp15@cam.ac.uk>
Sat Jun 30 15:44:04 2018 +0100 (12 months ago)
changeset 68551 b680e74eb6f2
parent 68445 c183a6a69f2d
child 69064 5840724b1d71
permissions -rw-r--r--
More on Algebra by Paulo and Martin
     1 (*  Title:      HOL/Algebra/UnivPoly.thy
     2     Author:     Clemens Ballarin, started 9 December 1996
     3     Copyright:  Clemens Ballarin
     4 
     5 Contributions, in particular on long division, by Jesus Aransay.
     6 *)
     7 
     8 theory UnivPoly
     9 imports Module RingHom
    10 begin
    11 
    12 section \<open>Univariate Polynomials\<close>
    13 
    14 text \<open>
    15   Polynomials are formalised as modules with additional operations for
    16   extracting coefficients from polynomials and for obtaining monomials
    17   from coefficients and exponents (record \<open>up_ring\<close>).  The
    18   carrier set is a set of bounded functions from Nat to the
    19   coefficient domain.  Bounded means that these functions return zero
    20   above a certain bound (the degree).  There is a chapter on the
    21   formalisation of polynomials in the PhD thesis @{cite "Ballarin:1999"},
    22   which was implemented with axiomatic type classes.  This was later
    23   ported to Locales.
    24 \<close>
    25 
    26 
    27 subsection \<open>The Constructor for Univariate Polynomials\<close>
    28 
    29 text \<open>
    30   Functions with finite support.
    31 \<close>
    32 
    33 locale bound =
    34   fixes z :: 'a
    35     and n :: nat
    36     and f :: "nat => 'a"
    37   assumes bound: "!!m. n < m \<Longrightarrow> f m = z"
    38 
    39 declare bound.intro [intro!]
    40   and bound.bound [dest]
    41 
    42 lemma bound_below:
    43   assumes bound: "bound z m f" and nonzero: "f n \<noteq> z" shows "n \<le> m"
    44 proof (rule classical)
    45   assume "\<not> ?thesis"
    46   then have "m < n" by arith
    47   with bound have "f n = z" ..
    48   with nonzero show ?thesis by contradiction
    49 qed
    50 
    51 record ('a, 'p) up_ring = "('a, 'p) module" +
    52   monom :: "['a, nat] => 'p"
    53   coeff :: "['p, nat] => 'a"
    54 
    55 definition
    56   up :: "('a, 'm) ring_scheme => (nat => 'a) set"
    57   where "up R = {f. f \<in> UNIV \<rightarrow> carrier R \<and> (\<exists>n. bound \<zero>\<^bsub>R\<^esub> n f)}"
    58 
    59 definition UP :: "('a, 'm) ring_scheme => ('a, nat => 'a) up_ring"
    60   where "UP R = \<lparr>
    61    carrier = up R,
    62    mult = (\<lambda>p\<in>up R. \<lambda>q\<in>up R. \<lambda>n. \<Oplus>\<^bsub>R\<^esub>i \<in> {..n}. p i \<otimes>\<^bsub>R\<^esub> q (n-i)),
    63    one = (\<lambda>i. if i=0 then \<one>\<^bsub>R\<^esub> else \<zero>\<^bsub>R\<^esub>),
    64    zero = (\<lambda>i. \<zero>\<^bsub>R\<^esub>),
    65    add = (\<lambda>p\<in>up R. \<lambda>q\<in>up R. \<lambda>i. p i \<oplus>\<^bsub>R\<^esub> q i),
    66    smult = (\<lambda>a\<in>carrier R. \<lambda>p\<in>up R. \<lambda>i. a \<otimes>\<^bsub>R\<^esub> p i),
    67    monom = (\<lambda>a\<in>carrier R. \<lambda>n i. if i=n then a else \<zero>\<^bsub>R\<^esub>),
    68    coeff = (\<lambda>p\<in>up R. \<lambda>n. p n)\<rparr>"
    69 
    70 text \<open>
    71   Properties of the set of polynomials @{term up}.
    72 \<close>
    73 
    74 lemma mem_upI [intro]:
    75   "[| \<And>n. f n \<in> carrier R; \<exists>n. bound (zero R) n f |] ==> f \<in> up R"
    76   by (simp add: up_def Pi_def)
    77 
    78 lemma mem_upD [dest]:
    79   "f \<in> up R ==> f n \<in> carrier R"
    80   by (simp add: up_def Pi_def)
    81 
    82 context ring
    83 begin
    84 
    85 lemma bound_upD [dest]: "f \<in> up R \<Longrightarrow> \<exists>n. bound \<zero> n f" by (simp add: up_def)
    86 
    87 lemma up_one_closed: "(\<lambda>n. if n = 0 then \<one> else \<zero>) \<in> up R" using up_def by force
    88 
    89 lemma up_smult_closed: "[| a \<in> carrier R; p \<in> up R |] ==> (\<lambda>i. a \<otimes> p i) \<in> up R" by force
    90 
    91 lemma up_add_closed:
    92   "[| p \<in> up R; q \<in> up R |] ==> (\<lambda>i. p i \<oplus> q i) \<in> up R"
    93 proof
    94   fix n
    95   assume "p \<in> up R" and "q \<in> up R"
    96   then show "p n \<oplus> q n \<in> carrier R"
    97     by auto
    98 next
    99   assume UP: "p \<in> up R" "q \<in> up R"
   100   show "\<exists>n. bound \<zero> n (\<lambda>i. p i \<oplus> q i)"
   101   proof -
   102     from UP obtain n where boundn: "bound \<zero> n p" by fast
   103     from UP obtain m where boundm: "bound \<zero> m q" by fast
   104     have "bound \<zero> (max n m) (\<lambda>i. p i \<oplus> q i)"
   105     proof
   106       fix i
   107       assume "max n m < i"
   108       with boundn and boundm and UP show "p i \<oplus> q i = \<zero>" by fastforce
   109     qed
   110     then show ?thesis ..
   111   qed
   112 qed
   113 
   114 lemma up_a_inv_closed:
   115   "p \<in> up R ==> (\<lambda>i. \<ominus> (p i)) \<in> up R"
   116 proof
   117   assume R: "p \<in> up R"
   118   then obtain n where "bound \<zero> n p" by auto
   119   then have "bound \<zero> n (\<lambda>i. \<ominus> p i)"
   120     by (simp add: bound_def minus_equality)
   121   then show "\<exists>n. bound \<zero> n (\<lambda>i. \<ominus> p i)" by auto
   122 qed auto
   123 
   124 lemma up_minus_closed:
   125   "[| p \<in> up R; q \<in> up R |] ==> (\<lambda>i. p i \<ominus> q i) \<in> up R"
   126   unfolding a_minus_def
   127   using mem_upD [of p R] mem_upD [of q R] up_add_closed up_a_inv_closed  by auto
   128 
   129 lemma up_mult_closed:
   130   "[| p \<in> up R; q \<in> up R |] ==>
   131   (\<lambda>n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n-i)) \<in> up R"
   132 proof
   133   fix n
   134   assume "p \<in> up R" "q \<in> up R"
   135   then show "(\<Oplus>i \<in> {..n}. p i \<otimes> q (n-i)) \<in> carrier R"
   136     by (simp add: mem_upD  funcsetI)
   137 next
   138   assume UP: "p \<in> up R" "q \<in> up R"
   139   show "\<exists>n. bound \<zero> n (\<lambda>n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n-i))"
   140   proof -
   141     from UP obtain n where boundn: "bound \<zero> n p" by fast
   142     from UP obtain m where boundm: "bound \<zero> m q" by fast
   143     have "bound \<zero> (n + m) (\<lambda>n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n - i))"
   144     proof
   145       fix k assume bound: "n + m < k"
   146       {
   147         fix i
   148         have "p i \<otimes> q (k-i) = \<zero>"
   149         proof (cases "n < i")
   150           case True
   151           with boundn have "p i = \<zero>" by auto
   152           moreover from UP have "q (k-i) \<in> carrier R" by auto
   153           ultimately show ?thesis by simp
   154         next
   155           case False
   156           with bound have "m < k-i" by arith
   157           with boundm have "q (k-i) = \<zero>" by auto
   158           moreover from UP have "p i \<in> carrier R" by auto
   159           ultimately show ?thesis by simp
   160         qed
   161       }
   162       then show "(\<Oplus>i \<in> {..k}. p i \<otimes> q (k-i)) = \<zero>"
   163         by (simp add: Pi_def)
   164     qed
   165     then show ?thesis by fast
   166   qed
   167 qed
   168 
   169 end
   170 
   171 
   172 subsection \<open>Effect of Operations on Coefficients\<close>
   173 
   174 locale UP =
   175   fixes R (structure) and P (structure)
   176   defines P_def: "P == UP R"
   177 
   178 locale UP_ring = UP + R?: ring R
   179 
   180 locale UP_cring = UP + R?: cring R
   181 
   182 sublocale UP_cring < UP_ring
   183   by intro_locales [1] (rule P_def)
   184 
   185 locale UP_domain = UP + R?: "domain" R
   186 
   187 sublocale UP_domain < UP_cring
   188   by intro_locales [1] (rule P_def)
   189 
   190 context UP
   191 begin
   192 
   193 text \<open>Temporarily declare @{thm P_def} as simp rule.\<close>
   194 
   195 declare P_def [simp]
   196 
   197 lemma up_eqI:
   198   assumes prem: "!!n. coeff P p n = coeff P q n" and R: "p \<in> carrier P" "q \<in> carrier P"
   199   shows "p = q"
   200 proof
   201   fix x
   202   from prem and R show "p x = q x" by (simp add: UP_def)
   203 qed
   204 
   205 lemma coeff_closed [simp]:
   206   "p \<in> carrier P ==> coeff P p n \<in> carrier R" by (auto simp add: UP_def)
   207 
   208 end
   209 
   210 context UP_ring
   211 begin
   212 
   213 (* Theorems generalised from commutative rings to rings by Jesus Aransay. *)
   214 
   215 lemma coeff_monom [simp]:
   216   "a \<in> carrier R ==> coeff P (monom P a m) n = (if m=n then a else \<zero>)"
   217 proof -
   218   assume R: "a \<in> carrier R"
   219   then have "(\<lambda>n. if n = m then a else \<zero>) \<in> up R"
   220     using up_def by force
   221   with R show ?thesis by (simp add: UP_def)
   222 qed
   223 
   224 lemma coeff_zero [simp]: "coeff P \<zero>\<^bsub>P\<^esub> n = \<zero>" by (auto simp add: UP_def)
   225 
   226 lemma coeff_one [simp]: "coeff P \<one>\<^bsub>P\<^esub> n = (if n=0 then \<one> else \<zero>)"
   227   using up_one_closed by (simp add: UP_def)
   228 
   229 lemma coeff_smult [simp]:
   230   "[| a \<in> carrier R; p \<in> carrier P |] ==> coeff P (a \<odot>\<^bsub>P\<^esub> p) n = a \<otimes> coeff P p n"
   231   by (simp add: UP_def up_smult_closed)
   232 
   233 lemma coeff_add [simp]:
   234   "[| p \<in> carrier P; q \<in> carrier P |] ==> coeff P (p \<oplus>\<^bsub>P\<^esub> q) n = coeff P p n \<oplus> coeff P q n"
   235   by (simp add: UP_def up_add_closed)
   236 
   237 lemma coeff_mult [simp]:
   238   "[| p \<in> carrier P; q \<in> carrier P |] ==> coeff P (p \<otimes>\<^bsub>P\<^esub> q) n = (\<Oplus>i \<in> {..n}. coeff P p i \<otimes> coeff P q (n-i))"
   239   by (simp add: UP_def up_mult_closed)
   240 
   241 end
   242 
   243 
   244 subsection \<open>Polynomials Form a Ring.\<close>
   245 
   246 context UP_ring
   247 begin
   248 
   249 text \<open>Operations are closed over @{term P}.\<close>
   250 
   251 lemma UP_mult_closed [simp]:
   252   "[| p \<in> carrier P; q \<in> carrier P |] ==> p \<otimes>\<^bsub>P\<^esub> q \<in> carrier P" by (simp add: UP_def up_mult_closed)
   253 
   254 lemma UP_one_closed [simp]:
   255   "\<one>\<^bsub>P\<^esub> \<in> carrier P" by (simp add: UP_def up_one_closed)
   256 
   257 lemma UP_zero_closed [intro, simp]:
   258   "\<zero>\<^bsub>P\<^esub> \<in> carrier P" by (auto simp add: UP_def)
   259 
   260 lemma UP_a_closed [intro, simp]:
   261   "[| p \<in> carrier P; q \<in> carrier P |] ==> p \<oplus>\<^bsub>P\<^esub> q \<in> carrier P" by (simp add: UP_def up_add_closed)
   262 
   263 lemma monom_closed [simp]:
   264   "a \<in> carrier R ==> monom P a n \<in> carrier P" by (auto simp add: UP_def up_def Pi_def)
   265 
   266 lemma UP_smult_closed [simp]:
   267   "[| a \<in> carrier R; p \<in> carrier P |] ==> a \<odot>\<^bsub>P\<^esub> p \<in> carrier P" by (simp add: UP_def up_smult_closed)
   268 
   269 end
   270 
   271 declare (in UP) P_def [simp del]
   272 
   273 text \<open>Algebraic ring properties\<close>
   274 
   275 context UP_ring
   276 begin
   277 
   278 lemma UP_a_assoc:
   279   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   280   shows "(p \<oplus>\<^bsub>P\<^esub> q) \<oplus>\<^bsub>P\<^esub> r = p \<oplus>\<^bsub>P\<^esub> (q \<oplus>\<^bsub>P\<^esub> r)" by (rule up_eqI, simp add: a_assoc R, simp_all add: R)
   281 
   282 lemma UP_l_zero [simp]:
   283   assumes R: "p \<in> carrier P"
   284   shows "\<zero>\<^bsub>P\<^esub> \<oplus>\<^bsub>P\<^esub> p = p" by (rule up_eqI, simp_all add: R)
   285 
   286 lemma UP_l_neg_ex:
   287   assumes R: "p \<in> carrier P"
   288   shows "\<exists>q \<in> carrier P. q \<oplus>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>"
   289 proof -
   290   let ?q = "\<lambda>i. \<ominus> (p i)"
   291   from R have closed: "?q \<in> carrier P"
   292     by (simp add: UP_def P_def up_a_inv_closed)
   293   from R have coeff: "!!n. coeff P ?q n = \<ominus> (coeff P p n)"
   294     by (simp add: UP_def P_def up_a_inv_closed)
   295   show ?thesis
   296   proof
   297     show "?q \<oplus>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>"
   298       by (auto intro!: up_eqI simp add: R closed coeff R.l_neg)
   299   qed (rule closed)
   300 qed
   301 
   302 lemma UP_a_comm:
   303   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   304   shows "p \<oplus>\<^bsub>P\<^esub> q = q \<oplus>\<^bsub>P\<^esub> p" by (rule up_eqI, simp add: a_comm R, simp_all add: R)
   305 
   306 lemma UP_m_assoc:
   307   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   308   shows "(p \<otimes>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r = p \<otimes>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)"
   309 proof (rule up_eqI)
   310   fix n
   311   {
   312     fix k and a b c :: "nat=>'a"
   313     assume R: "a \<in> UNIV \<rightarrow> carrier R" "b \<in> UNIV \<rightarrow> carrier R"
   314       "c \<in> UNIV \<rightarrow> carrier R"
   315     then have "k <= n ==>
   316       (\<Oplus>j \<in> {..k}. (\<Oplus>i \<in> {..j}. a i \<otimes> b (j-i)) \<otimes> c (n-j)) =
   317       (\<Oplus>j \<in> {..k}. a j \<otimes> (\<Oplus>i \<in> {..k-j}. b i \<otimes> c (n-j-i)))"
   318       (is "_ \<Longrightarrow> ?eq k")
   319     proof (induct k)
   320       case 0 then show ?case by (simp add: Pi_def m_assoc)
   321     next
   322       case (Suc k)
   323       then have "k <= n" by arith
   324       from this R have "?eq k" by (rule Suc)
   325       with R show ?case
   326         by (simp cong: finsum_cong
   327              add: Suc_diff_le Pi_def l_distr r_distr m_assoc)
   328            (simp cong: finsum_cong add: Pi_def a_ac finsum_ldistr m_assoc)
   329     qed
   330   }
   331   with R show "coeff P ((p \<otimes>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r) n = coeff P (p \<otimes>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)) n"
   332     by (simp add: Pi_def)
   333 qed (simp_all add: R)
   334 
   335 lemma UP_r_one [simp]:
   336   assumes R: "p \<in> carrier P" shows "p \<otimes>\<^bsub>P\<^esub> \<one>\<^bsub>P\<^esub> = p"
   337 proof (rule up_eqI)
   338   fix n
   339   show "coeff P (p \<otimes>\<^bsub>P\<^esub> \<one>\<^bsub>P\<^esub>) n = coeff P p n"
   340   proof (cases n)
   341     case 0
   342     {
   343       with R show ?thesis by simp
   344     }
   345   next
   346     case Suc
   347     {
   348       (*JE: in the locale UP_cring the proof was solved only with "by (simp del: finsum_Suc add: finsum_Suc2 Pi_def)", but I did not get it to work here*)
   349       fix nn assume Succ: "n = Suc nn"
   350       have "coeff P (p \<otimes>\<^bsub>P\<^esub> \<one>\<^bsub>P\<^esub>) (Suc nn) = coeff P p (Suc nn)"
   351       proof -
   352         have "coeff P (p \<otimes>\<^bsub>P\<^esub> \<one>\<^bsub>P\<^esub>) (Suc nn) = (\<Oplus>i\<in>{..Suc nn}. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>))" using R by simp
   353         also have "\<dots> = coeff P p (Suc nn) \<otimes> (if Suc nn \<le> Suc nn then \<one> else \<zero>) \<oplus> (\<Oplus>i\<in>{..nn}. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>))"
   354           using finsum_Suc [of "(\<lambda>i::nat. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>))" "nn"] unfolding Pi_def using R by simp
   355         also have "\<dots> = coeff P p (Suc nn) \<otimes> (if Suc nn \<le> Suc nn then \<one> else \<zero>)"
   356         proof -
   357           have "(\<Oplus>i\<in>{..nn}. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>)) = (\<Oplus>i\<in>{..nn}. \<zero>)"
   358             using finsum_cong [of "{..nn}" "{..nn}" "(\<lambda>i::nat. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>))" "(\<lambda>i::nat. \<zero>)"] using R
   359             unfolding Pi_def by simp
   360           also have "\<dots> = \<zero>" by simp
   361           finally show ?thesis using r_zero R by simp
   362         qed
   363         also have "\<dots> = coeff P p (Suc nn)" using R by simp
   364         finally show ?thesis by simp
   365       qed
   366       then show ?thesis using Succ by simp
   367     }
   368   qed
   369 qed (simp_all add: R)
   370 
   371 lemma UP_l_one [simp]:
   372   assumes R: "p \<in> carrier P"
   373   shows "\<one>\<^bsub>P\<^esub> \<otimes>\<^bsub>P\<^esub> p = p"
   374 proof (rule up_eqI)
   375   fix n
   376   show "coeff P (\<one>\<^bsub>P\<^esub> \<otimes>\<^bsub>P\<^esub> p) n = coeff P p n"
   377   proof (cases n)
   378     case 0 with R show ?thesis by simp
   379   next
   380     case Suc with R show ?thesis
   381       by (simp del: finsum_Suc add: finsum_Suc2 Pi_def)
   382   qed
   383 qed (simp_all add: R)
   384 
   385 lemma UP_l_distr:
   386   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   387   shows "(p \<oplus>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r = (p \<otimes>\<^bsub>P\<^esub> r) \<oplus>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)"
   388   by (rule up_eqI) (simp add: l_distr R Pi_def, simp_all add: R)
   389 
   390 lemma UP_r_distr:
   391   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   392   shows "r \<otimes>\<^bsub>P\<^esub> (p \<oplus>\<^bsub>P\<^esub> q) = (r \<otimes>\<^bsub>P\<^esub> p) \<oplus>\<^bsub>P\<^esub> (r \<otimes>\<^bsub>P\<^esub> q)"
   393   by (rule up_eqI) (simp add: r_distr R Pi_def, simp_all add: R)
   394 
   395 theorem UP_ring: "ring P"
   396   by (auto intro!: ringI abelian_groupI monoidI UP_a_assoc)
   397     (auto intro: UP_a_comm UP_l_neg_ex UP_m_assoc UP_l_distr UP_r_distr)
   398 
   399 end
   400 
   401 
   402 subsection \<open>Polynomials Form a Commutative Ring.\<close>
   403 
   404 context UP_cring
   405 begin
   406 
   407 lemma UP_m_comm:
   408   assumes R1: "p \<in> carrier P" and R2: "q \<in> carrier P" shows "p \<otimes>\<^bsub>P\<^esub> q = q \<otimes>\<^bsub>P\<^esub> p"
   409 proof (rule up_eqI)
   410   fix n
   411   {
   412     fix k and a b :: "nat=>'a"
   413     assume R: "a \<in> UNIV \<rightarrow> carrier R" "b \<in> UNIV \<rightarrow> carrier R"
   414     then have "k <= n ==>
   415       (\<Oplus>i \<in> {..k}. a i \<otimes> b (n-i)) = (\<Oplus>i \<in> {..k}. a (k-i) \<otimes> b (i+n-k))"
   416       (is "_ \<Longrightarrow> ?eq k")
   417     proof (induct k)
   418       case 0 then show ?case by (simp add: Pi_def)
   419     next
   420       case (Suc k) then show ?case
   421         by (subst (2) finsum_Suc2) (simp add: Pi_def a_comm)+
   422     qed
   423   }
   424   note l = this
   425   from R1 R2 show "coeff P (p \<otimes>\<^bsub>P\<^esub> q) n =  coeff P (q \<otimes>\<^bsub>P\<^esub> p) n"
   426     unfolding coeff_mult [OF R1 R2, of n]
   427     unfolding coeff_mult [OF R2 R1, of n]
   428     using l [of "(\<lambda>i. coeff P p i)" "(\<lambda>i. coeff P q i)" "n"] by (simp add: Pi_def m_comm)
   429 qed (simp_all add: R1 R2)
   430 
   431 
   432 subsection \<open>Polynomials over a commutative ring for a commutative ring\<close>
   433 
   434 theorem UP_cring:
   435   "cring P" using UP_ring unfolding cring_def by (auto intro!: comm_monoidI UP_m_assoc UP_m_comm)
   436 
   437 end
   438 
   439 context UP_ring
   440 begin
   441 
   442 lemma UP_a_inv_closed [intro, simp]:
   443   "p \<in> carrier P ==> \<ominus>\<^bsub>P\<^esub> p \<in> carrier P"
   444   by (rule abelian_group.a_inv_closed [OF ring.is_abelian_group [OF UP_ring]])
   445 
   446 lemma coeff_a_inv [simp]:
   447   assumes R: "p \<in> carrier P"
   448   shows "coeff P (\<ominus>\<^bsub>P\<^esub> p) n = \<ominus> (coeff P p n)"
   449 proof -
   450   from R coeff_closed UP_a_inv_closed have
   451     "coeff P (\<ominus>\<^bsub>P\<^esub> p) n = \<ominus> coeff P p n \<oplus> (coeff P p n \<oplus> coeff P (\<ominus>\<^bsub>P\<^esub> p) n)"
   452     by algebra
   453   also from R have "... =  \<ominus> (coeff P p n)"
   454     by (simp del: coeff_add add: coeff_add [THEN sym]
   455       abelian_group.r_neg [OF ring.is_abelian_group [OF UP_ring]])
   456   finally show ?thesis .
   457 qed
   458 
   459 end
   460 
   461 sublocale UP_ring < P?: ring P using UP_ring .
   462 sublocale UP_cring < P?: cring P using UP_cring .
   463 
   464 
   465 subsection \<open>Polynomials Form an Algebra\<close>
   466 
   467 context UP_ring
   468 begin
   469 
   470 lemma UP_smult_l_distr:
   471   "[| a \<in> carrier R; b \<in> carrier R; p \<in> carrier P |] ==>
   472   (a \<oplus> b) \<odot>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> p \<oplus>\<^bsub>P\<^esub> b \<odot>\<^bsub>P\<^esub> p"
   473   by (rule up_eqI) (simp_all add: R.l_distr)
   474 
   475 lemma UP_smult_r_distr:
   476   "[| a \<in> carrier R; p \<in> carrier P; q \<in> carrier P |] ==>
   477   a \<odot>\<^bsub>P\<^esub> (p \<oplus>\<^bsub>P\<^esub> q) = a \<odot>\<^bsub>P\<^esub> p \<oplus>\<^bsub>P\<^esub> a \<odot>\<^bsub>P\<^esub> q"
   478   by (rule up_eqI) (simp_all add: R.r_distr)
   479 
   480 lemma UP_smult_assoc1:
   481       "[| a \<in> carrier R; b \<in> carrier R; p \<in> carrier P |] ==>
   482       (a \<otimes> b) \<odot>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> (b \<odot>\<^bsub>P\<^esub> p)"
   483   by (rule up_eqI) (simp_all add: R.m_assoc)
   484 
   485 lemma UP_smult_zero [simp]:
   486       "p \<in> carrier P ==> \<zero> \<odot>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>"
   487   by (rule up_eqI) simp_all
   488 
   489 lemma UP_smult_one [simp]:
   490       "p \<in> carrier P ==> \<one> \<odot>\<^bsub>P\<^esub> p = p"
   491   by (rule up_eqI) simp_all
   492 
   493 lemma UP_smult_assoc2:
   494   "[| a \<in> carrier R; p \<in> carrier P; q \<in> carrier P |] ==>
   495   (a \<odot>\<^bsub>P\<^esub> p) \<otimes>\<^bsub>P\<^esub> q = a \<odot>\<^bsub>P\<^esub> (p \<otimes>\<^bsub>P\<^esub> q)"
   496   by (rule up_eqI) (simp_all add: R.finsum_rdistr R.m_assoc Pi_def)
   497 
   498 end
   499 
   500 text \<open>
   501   Interpretation of lemmas from @{term algebra}.
   502 \<close>
   503 
   504 lemma (in cring) cring:
   505   "cring R" ..
   506 
   507 lemma (in UP_cring) UP_algebra:
   508   "algebra R P" by (auto intro!: algebraI R.cring UP_cring UP_smult_l_distr UP_smult_r_distr
   509     UP_smult_assoc1 UP_smult_assoc2)
   510 
   511 sublocale UP_cring < algebra R P using UP_algebra .
   512 
   513 
   514 subsection \<open>Further Lemmas Involving Monomials\<close>
   515 
   516 context UP_ring
   517 begin
   518 
   519 lemma monom_zero [simp]:
   520   "monom P \<zero> n = \<zero>\<^bsub>P\<^esub>" by (simp add: UP_def P_def)
   521 
   522 lemma monom_mult_is_smult:
   523   assumes R: "a \<in> carrier R" "p \<in> carrier P"
   524   shows "monom P a 0 \<otimes>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> p"
   525 proof (rule up_eqI)
   526   fix n
   527   show "coeff P (monom P a 0 \<otimes>\<^bsub>P\<^esub> p) n = coeff P (a \<odot>\<^bsub>P\<^esub> p) n"
   528   proof (cases n)
   529     case 0 with R show ?thesis by simp
   530   next
   531     case Suc with R show ?thesis
   532       using R.finsum_Suc2 by (simp del: R.finsum_Suc add: Pi_def)
   533   qed
   534 qed (simp_all add: R)
   535 
   536 lemma monom_one [simp]:
   537   "monom P \<one> 0 = \<one>\<^bsub>P\<^esub>"
   538   by (rule up_eqI) simp_all
   539 
   540 lemma monom_add [simp]:
   541   "[| a \<in> carrier R; b \<in> carrier R |] ==>
   542   monom P (a \<oplus> b) n = monom P a n \<oplus>\<^bsub>P\<^esub> monom P b n"
   543   by (rule up_eqI) simp_all
   544 
   545 lemma monom_one_Suc:
   546   "monom P \<one> (Suc n) = monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1"
   547 proof (rule up_eqI)
   548   fix k
   549   show "coeff P (monom P \<one> (Suc n)) k = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k"
   550   proof (cases "k = Suc n")
   551     case True show ?thesis
   552     proof -
   553       fix m
   554       from True have less_add_diff:
   555         "!!i. [| n < i; i <= n + m |] ==> n + m - i < m" by arith
   556       from True have "coeff P (monom P \<one> (Suc n)) k = \<one>" by simp
   557       also from True
   558       have "... = (\<Oplus>i \<in> {..<n} \<union> {n}. coeff P (monom P \<one> n) i \<otimes>
   559         coeff P (monom P \<one> 1) (k - i))"
   560         by (simp cong: R.finsum_cong add: Pi_def)
   561       also have "... = (\<Oplus>i \<in>  {..n}. coeff P (monom P \<one> n) i \<otimes>
   562         coeff P (monom P \<one> 1) (k - i))"
   563         by (simp only: ivl_disj_un_singleton)
   564       also from True
   565       have "... = (\<Oplus>i \<in> {..n} \<union> {n<..k}. coeff P (monom P \<one> n) i \<otimes>
   566         coeff P (monom P \<one> 1) (k - i))"
   567         by (simp cong: R.finsum_cong add: R.finsum_Un_disjoint ivl_disj_int_one
   568           order_less_imp_not_eq Pi_def)
   569       also from True have "... = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k"
   570         by (simp add: ivl_disj_un_one)
   571       finally show ?thesis .
   572     qed
   573   next
   574     case False
   575     note neq = False
   576     let ?s =
   577       "\<lambda>i. (if n = i then \<one> else \<zero>) \<otimes> (if Suc 0 = k - i then \<one> else \<zero>)"
   578     from neq have "coeff P (monom P \<one> (Suc n)) k = \<zero>" by simp
   579     also have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   580     proof -
   581       have f1: "(\<Oplus>i \<in> {..<n}. ?s i) = \<zero>"
   582         by (simp cong: R.finsum_cong add: Pi_def)
   583       from neq have f2: "(\<Oplus>i \<in> {n}. ?s i) = \<zero>"
   584         by (simp cong: R.finsum_cong add: Pi_def) arith
   585       have f3: "n < k ==> (\<Oplus>i \<in> {n<..k}. ?s i) = \<zero>"
   586         by (simp cong: R.finsum_cong add: order_less_imp_not_eq Pi_def)
   587       show ?thesis
   588       proof (cases "k < n")
   589         case True then show ?thesis by (simp cong: R.finsum_cong add: Pi_def)
   590       next
   591         case False then have n_le_k: "n <= k" by arith
   592         show ?thesis
   593         proof (cases "n = k")
   594           case True
   595           then have "\<zero> = (\<Oplus>i \<in> {..<n} \<union> {n}. ?s i)"
   596             by (simp cong: R.finsum_cong add: Pi_def)
   597           also from True have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   598             by (simp only: ivl_disj_un_singleton)
   599           finally show ?thesis .
   600         next
   601           case False with n_le_k have n_less_k: "n < k" by arith
   602           with neq have "\<zero> = (\<Oplus>i \<in> {..<n} \<union> {n}. ?s i)"
   603             by (simp add: R.finsum_Un_disjoint f1 f2 Pi_def del: Un_insert_right)
   604           also have "... = (\<Oplus>i \<in> {..n}. ?s i)"
   605             by (simp only: ivl_disj_un_singleton)
   606           also from n_less_k neq have "... = (\<Oplus>i \<in> {..n} \<union> {n<..k}. ?s i)"
   607             by (simp add: R.finsum_Un_disjoint f3 ivl_disj_int_one Pi_def)
   608           also from n_less_k have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   609             by (simp only: ivl_disj_un_one)
   610           finally show ?thesis .
   611         qed
   612       qed
   613     qed
   614     also have "... = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k" by simp
   615     finally show ?thesis .
   616   qed
   617 qed (simp_all)
   618 
   619 lemma monom_one_Suc2:
   620   "monom P \<one> (Suc n) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> n"
   621 proof (induct n)
   622   case 0 show ?case by simp
   623 next
   624   case Suc
   625   {
   626     fix k:: nat
   627     assume hypo: "monom P \<one> (Suc k) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> k"
   628     then show "monom P \<one> (Suc (Suc k)) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> (Suc k)"
   629     proof -
   630       have lhs: "monom P \<one> (Suc (Suc k)) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> k \<otimes>\<^bsub>P\<^esub> monom P \<one> 1"
   631         unfolding monom_one_Suc [of "Suc k"] unfolding hypo ..
   632       note cl = monom_closed [OF R.one_closed, of 1]
   633       note clk = monom_closed [OF R.one_closed, of k]
   634       have rhs: "monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> (Suc k) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> k \<otimes>\<^bsub>P\<^esub> monom P \<one> 1"
   635         unfolding monom_one_Suc [of k] unfolding sym [OF m_assoc  [OF cl clk cl]] ..
   636       from lhs rhs show ?thesis by simp
   637     qed
   638   }
   639 qed
   640 
   641 text\<open>The following corollary follows from lemmas @{thm "monom_one_Suc"}
   642   and @{thm "monom_one_Suc2"}, and is trivial in @{term UP_cring}\<close>
   643 
   644 corollary monom_one_comm: shows "monom P \<one> k \<otimes>\<^bsub>P\<^esub> monom P \<one> 1 = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> k"
   645   unfolding monom_one_Suc [symmetric] monom_one_Suc2 [symmetric] ..
   646 
   647 lemma monom_mult_smult:
   648   "[| a \<in> carrier R; b \<in> carrier R |] ==> monom P (a \<otimes> b) n = a \<odot>\<^bsub>P\<^esub> monom P b n"
   649   by (rule up_eqI) simp_all
   650 
   651 lemma monom_one_mult:
   652   "monom P \<one> (n + m) = monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> m"
   653 proof (induct n)
   654   case 0 show ?case by simp
   655 next
   656   case Suc then show ?case
   657     unfolding add_Suc unfolding monom_one_Suc unfolding Suc.hyps
   658     using m_assoc monom_one_comm [of m] by simp
   659 qed
   660 
   661 lemma monom_one_mult_comm: "monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> m = monom P \<one> m \<otimes>\<^bsub>P\<^esub> monom P \<one> n"
   662   unfolding monom_one_mult [symmetric] by (rule up_eqI) simp_all
   663 
   664 lemma monom_mult [simp]:
   665   assumes a_in_R: "a \<in> carrier R" and b_in_R: "b \<in> carrier R"
   666   shows "monom P (a \<otimes> b) (n + m) = monom P a n \<otimes>\<^bsub>P\<^esub> monom P b m"
   667 proof (rule up_eqI)
   668   fix k
   669   show "coeff P (monom P (a \<otimes> b) (n + m)) k = coeff P (monom P a n \<otimes>\<^bsub>P\<^esub> monom P b m) k"
   670   proof (cases "n + m = k")
   671     case True
   672     {
   673       show ?thesis
   674         unfolding True [symmetric]
   675           coeff_mult [OF monom_closed [OF a_in_R, of n] monom_closed [OF b_in_R, of m], of "n + m"]
   676           coeff_monom [OF a_in_R, of n] coeff_monom [OF b_in_R, of m]
   677         using R.finsum_cong [of "{.. n + m}" "{.. n + m}" "(\<lambda>i. (if n = i then a else \<zero>) \<otimes> (if m = n + m - i then b else \<zero>))"
   678           "(\<lambda>i. if n = i then a \<otimes> b else \<zero>)"]
   679           a_in_R b_in_R
   680         unfolding simp_implies_def
   681         using R.finsum_singleton [of n "{.. n + m}" "(\<lambda>i. a \<otimes> b)"]
   682         unfolding Pi_def by auto
   683     }
   684   next
   685     case False
   686     {
   687       show ?thesis
   688         unfolding coeff_monom [OF R.m_closed [OF a_in_R b_in_R], of "n + m" k] apply (simp add: False)
   689         unfolding coeff_mult [OF monom_closed [OF a_in_R, of n] monom_closed [OF b_in_R, of m], of k]
   690         unfolding coeff_monom [OF a_in_R, of n] unfolding coeff_monom [OF b_in_R, of m] using False
   691         using R.finsum_cong [of "{..k}" "{..k}" "(\<lambda>i. (if n = i then a else \<zero>) \<otimes> (if m = k - i then b else \<zero>))" "(\<lambda>i. \<zero>)"]
   692         unfolding Pi_def simp_implies_def using a_in_R b_in_R by force
   693     }
   694   qed
   695 qed (simp_all add: a_in_R b_in_R)
   696 
   697 lemma monom_a_inv [simp]:
   698   "a \<in> carrier R ==> monom P (\<ominus> a) n = \<ominus>\<^bsub>P\<^esub> monom P a n"
   699   by (rule up_eqI) auto
   700 
   701 lemma monom_inj:
   702   "inj_on (\<lambda>a. monom P a n) (carrier R)"
   703 proof (rule inj_onI)
   704   fix x y
   705   assume R: "x \<in> carrier R" "y \<in> carrier R" and eq: "monom P x n = monom P y n"
   706   then have "coeff P (monom P x n) n = coeff P (monom P y n) n" by simp
   707   with R show "x = y" by simp
   708 qed
   709 
   710 end
   711 
   712 
   713 subsection \<open>The Degree Function\<close>
   714 
   715 definition
   716   deg :: "[('a, 'm) ring_scheme, nat => 'a] => nat"
   717   where "deg R p = (LEAST n. bound \<zero>\<^bsub>R\<^esub> n (coeff (UP R) p))"
   718 
   719 context UP_ring
   720 begin
   721 
   722 lemma deg_aboveI:
   723   "[| (!!m. n < m ==> coeff P p m = \<zero>); p \<in> carrier P |] ==> deg R p <= n"
   724   by (unfold deg_def P_def) (fast intro: Least_le)
   725 
   726 (*
   727 lemma coeff_bound_ex: "EX n. bound n (coeff p)"
   728 proof -
   729   have "(\<lambda>n. coeff p n) : UP" by (simp add: coeff_def Rep_UP)
   730   then obtain n where "bound n (coeff p)" by (unfold UP_def) fast
   731   then show ?thesis ..
   732 qed
   733 
   734 lemma bound_coeff_obtain:
   735   assumes prem: "(!!n. bound n (coeff p) ==> P)" shows "P"
   736 proof -
   737   have "(\<lambda>n. coeff p n) : UP" by (simp add: coeff_def Rep_UP)
   738   then obtain n where "bound n (coeff p)" by (unfold UP_def) fast
   739   with prem show P .
   740 qed
   741 *)
   742 
   743 lemma deg_aboveD:
   744   assumes "deg R p < m" and "p \<in> carrier P"
   745   shows "coeff P p m = \<zero>"
   746 proof -
   747   from \<open>p \<in> carrier P\<close> obtain n where "bound \<zero> n (coeff P p)"
   748     by (auto simp add: UP_def P_def)
   749   then have "bound \<zero> (deg R p) (coeff P p)"
   750     by (auto simp: deg_def P_def dest: LeastI)
   751   from this and \<open>deg R p < m\<close> show ?thesis ..
   752 qed
   753 
   754 lemma deg_belowI:
   755   assumes non_zero: "n \<noteq> 0 \<Longrightarrow> coeff P p n \<noteq> \<zero>"
   756     and R: "p \<in> carrier P"
   757   shows "n \<le> deg R p"
   758 \<comment> \<open>Logically, this is a slightly stronger version of
   759    @{thm [source] deg_aboveD}\<close>
   760 proof (cases "n=0")
   761   case True then show ?thesis by simp
   762 next
   763   case False then have "coeff P p n \<noteq> \<zero>" by (rule non_zero)
   764   then have "\<not> deg R p < n" by (fast dest: deg_aboveD intro: R)
   765   then show ?thesis by arith
   766 qed
   767 
   768 lemma lcoeff_nonzero_deg:
   769   assumes deg: "deg R p \<noteq> 0" and R: "p \<in> carrier P"
   770   shows "coeff P p (deg R p) \<noteq> \<zero>"
   771 proof -
   772   from R obtain m where "deg R p \<le> m" and m_coeff: "coeff P p m \<noteq> \<zero>"
   773   proof -
   774     have minus: "\<And>(n::nat) m. n \<noteq> 0 \<Longrightarrow> (n - Suc 0 < m) = (n \<le> m)"
   775       by arith
   776     from deg have "deg R p - 1 < (LEAST n. bound \<zero> n (coeff P p))"
   777       by (unfold deg_def P_def) simp
   778     then have "\<not> bound \<zero> (deg R p - 1) (coeff P p)" by (rule not_less_Least)
   779     then have "\<exists>m. deg R p - 1 < m \<and> coeff P p m \<noteq> \<zero>"
   780       by (unfold bound_def) fast
   781     then have "\<exists>m. deg R p \<le> m \<and> coeff P p m \<noteq> \<zero>" by (simp add: deg minus)
   782     then show ?thesis by (auto intro: that)
   783   qed
   784   with deg_belowI R have "deg R p = m" by fastforce
   785   with m_coeff show ?thesis by simp
   786 qed
   787 
   788 lemma lcoeff_nonzero_nonzero:
   789   assumes deg: "deg R p = 0" and nonzero: "p \<noteq> \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P"
   790   shows "coeff P p 0 \<noteq> \<zero>"
   791 proof -
   792   have "\<exists>m. coeff P p m \<noteq> \<zero>"
   793   proof (rule classical)
   794     assume "\<not> ?thesis"
   795     with R have "p = \<zero>\<^bsub>P\<^esub>" by (auto intro: up_eqI)
   796     with nonzero show ?thesis by contradiction
   797   qed
   798   then obtain m where coeff: "coeff P p m \<noteq> \<zero>" ..
   799   from this and R have "m \<le> deg R p" by (rule deg_belowI)
   800   then have "m = 0" by (simp add: deg)
   801   with coeff show ?thesis by simp
   802 qed
   803 
   804 lemma lcoeff_nonzero:
   805   assumes neq: "p \<noteq> \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P"
   806   shows "coeff P p (deg R p) \<noteq> \<zero>"
   807 proof (cases "deg R p = 0")
   808   case True with neq R show ?thesis by (simp add: lcoeff_nonzero_nonzero)
   809 next
   810   case False with neq R show ?thesis by (simp add: lcoeff_nonzero_deg)
   811 qed
   812 
   813 lemma deg_eqI:
   814   "[| \<And>m. n < m \<Longrightarrow> coeff P p m = \<zero>;
   815       \<And>n. n \<noteq> 0 \<Longrightarrow> coeff P p n \<noteq> \<zero>; p \<in> carrier P |] ==> deg R p = n"
   816 by (fast intro: le_antisym deg_aboveI deg_belowI)
   817 
   818 text \<open>Degree and polynomial operations\<close>
   819 
   820 lemma deg_add [simp]:
   821   "p \<in> carrier P \<Longrightarrow> q \<in> carrier P \<Longrightarrow>
   822   deg R (p \<oplus>\<^bsub>P\<^esub> q) \<le> max (deg R p) (deg R q)"
   823 by(rule deg_aboveI)(simp_all add: deg_aboveD)
   824 
   825 lemma deg_monom_le:
   826   "a \<in> carrier R \<Longrightarrow> deg R (monom P a n) \<le> n"
   827   by (intro deg_aboveI) simp_all
   828 
   829 lemma deg_monom [simp]:
   830   "[| a \<noteq> \<zero>; a \<in> carrier R |] ==> deg R (monom P a n) = n"
   831   by (fastforce intro: le_antisym deg_aboveI deg_belowI)
   832 
   833 lemma deg_const [simp]:
   834   assumes R: "a \<in> carrier R" shows "deg R (monom P a 0) = 0"
   835 proof (rule le_antisym)
   836   show "deg R (monom P a 0) \<le> 0" by (rule deg_aboveI) (simp_all add: R)
   837 next
   838   show "0 \<le> deg R (monom P a 0)" by (rule deg_belowI) (simp_all add: R)
   839 qed
   840 
   841 lemma deg_zero [simp]:
   842   "deg R \<zero>\<^bsub>P\<^esub> = 0"
   843 proof (rule le_antisym)
   844   show "deg R \<zero>\<^bsub>P\<^esub> \<le> 0" by (rule deg_aboveI) simp_all
   845 next
   846   show "0 \<le> deg R \<zero>\<^bsub>P\<^esub>" by (rule deg_belowI) simp_all
   847 qed
   848 
   849 lemma deg_one [simp]:
   850   "deg R \<one>\<^bsub>P\<^esub> = 0"
   851 proof (rule le_antisym)
   852   show "deg R \<one>\<^bsub>P\<^esub> \<le> 0" by (rule deg_aboveI) simp_all
   853 next
   854   show "0 \<le> deg R \<one>\<^bsub>P\<^esub>" by (rule deg_belowI) simp_all
   855 qed
   856 
   857 lemma deg_uminus [simp]:
   858   assumes R: "p \<in> carrier P" shows "deg R (\<ominus>\<^bsub>P\<^esub> p) = deg R p"
   859 proof (rule le_antisym)
   860   show "deg R (\<ominus>\<^bsub>P\<^esub> p) \<le> deg R p" by (simp add: deg_aboveI deg_aboveD R)
   861 next
   862   show "deg R p \<le> deg R (\<ominus>\<^bsub>P\<^esub> p)"
   863     by (simp add: deg_belowI lcoeff_nonzero_deg
   864       inj_on_eq_iff [OF R.a_inv_inj, of _ "\<zero>", simplified] R)
   865 qed
   866 
   867 text\<open>The following lemma is later \emph{overwritten} by the most
   868   specific one for domains, \<open>deg_smult\<close>.\<close>
   869 
   870 lemma deg_smult_ring [simp]:
   871   "[| a \<in> carrier R; p \<in> carrier P |] ==>
   872   deg R (a \<odot>\<^bsub>P\<^esub> p) \<le> (if a = \<zero> then 0 else deg R p)"
   873   by (cases "a = \<zero>") (simp add: deg_aboveI deg_aboveD)+
   874 
   875 end
   876 
   877 context UP_domain
   878 begin
   879 
   880 lemma deg_smult [simp]:
   881   assumes R: "a \<in> carrier R" "p \<in> carrier P"
   882   shows "deg R (a \<odot>\<^bsub>P\<^esub> p) = (if a = \<zero> then 0 else deg R p)"
   883 proof (rule le_antisym)
   884   show "deg R (a \<odot>\<^bsub>P\<^esub> p) \<le> (if a = \<zero> then 0 else deg R p)"
   885     using R by (rule deg_smult_ring)
   886 next
   887   show "(if a = \<zero> then 0 else deg R p) \<le> deg R (a \<odot>\<^bsub>P\<^esub> p)"
   888   proof (cases "a = \<zero>")
   889   qed (simp, simp add: deg_belowI lcoeff_nonzero_deg integral_iff R)
   890 qed
   891 
   892 end
   893 
   894 context UP_ring
   895 begin
   896 
   897 lemma deg_mult_ring:
   898   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   899   shows "deg R (p \<otimes>\<^bsub>P\<^esub> q) \<le> deg R p + deg R q"
   900 proof (rule deg_aboveI)
   901   fix m
   902   assume boundm: "deg R p + deg R q < m"
   903   {
   904     fix k i
   905     assume boundk: "deg R p + deg R q < k"
   906     then have "coeff P p i \<otimes> coeff P q (k - i) = \<zero>"
   907     proof (cases "deg R p < i")
   908       case True then show ?thesis by (simp add: deg_aboveD R)
   909     next
   910       case False with boundk have "deg R q < k - i" by arith
   911       then show ?thesis by (simp add: deg_aboveD R)
   912     qed
   913   }
   914   with boundm R show "coeff P (p \<otimes>\<^bsub>P\<^esub> q) m = \<zero>" by simp
   915 qed (simp add: R)
   916 
   917 end
   918 
   919 context UP_domain
   920 begin
   921 
   922 lemma deg_mult [simp]:
   923   "[| p \<noteq> \<zero>\<^bsub>P\<^esub>; q \<noteq> \<zero>\<^bsub>P\<^esub>; p \<in> carrier P; q \<in> carrier P |] ==>
   924   deg R (p \<otimes>\<^bsub>P\<^esub> q) = deg R p + deg R q"
   925 proof (rule le_antisym)
   926   assume "p \<in> carrier P" " q \<in> carrier P"
   927   then show "deg R (p \<otimes>\<^bsub>P\<^esub> q) \<le> deg R p + deg R q" by (rule deg_mult_ring)
   928 next
   929   let ?s = "(\<lambda>i. coeff P p i \<otimes> coeff P q (deg R p + deg R q - i))"
   930   assume R: "p \<in> carrier P" "q \<in> carrier P" and nz: "p \<noteq> \<zero>\<^bsub>P\<^esub>" "q \<noteq> \<zero>\<^bsub>P\<^esub>"
   931   have less_add_diff: "!!(k::nat) n m. k < n ==> m < n + m - k" by arith
   932   show "deg R p + deg R q \<le> deg R (p \<otimes>\<^bsub>P\<^esub> q)"
   933   proof (rule deg_belowI, simp add: R)
   934     have "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i)
   935       = (\<Oplus>i \<in> {..< deg R p} \<union> {deg R p .. deg R p + deg R q}. ?s i)"
   936       by (simp only: ivl_disj_un_one)
   937     also have "... = (\<Oplus>i \<in> {deg R p .. deg R p + deg R q}. ?s i)"
   938       by (simp cong: R.finsum_cong add: R.finsum_Un_disjoint ivl_disj_int_one
   939         deg_aboveD less_add_diff R Pi_def)
   940     also have "...= (\<Oplus>i \<in> {deg R p} \<union> {deg R p <.. deg R p + deg R q}. ?s i)"
   941       by (simp only: ivl_disj_un_singleton)
   942     also have "... = coeff P p (deg R p) \<otimes> coeff P q (deg R q)"
   943       by (simp cong: R.finsum_cong add: deg_aboveD R Pi_def)
   944     finally have "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i)
   945       = coeff P p (deg R p) \<otimes> coeff P q (deg R q)" .
   946     with nz show "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i) \<noteq> \<zero>"
   947       by (simp add: integral_iff lcoeff_nonzero R)
   948   qed (simp add: R)
   949 qed
   950 
   951 end
   952 
   953 text\<open>The following lemmas also can be lifted to @{term UP_ring}.\<close>
   954 
   955 context UP_ring
   956 begin
   957 
   958 lemma coeff_finsum:
   959   assumes fin: "finite A"
   960   shows "p \<in> A \<rightarrow> carrier P ==>
   961     coeff P (finsum P p A) k = (\<Oplus>i \<in> A. coeff P (p i) k)"
   962   using fin by induct (auto simp: Pi_def)
   963 
   964 lemma up_repr:
   965   assumes R: "p \<in> carrier P"
   966   shows "(\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. monom P (coeff P p i) i) = p"
   967 proof (rule up_eqI)
   968   let ?s = "(\<lambda>i. monom P (coeff P p i) i)"
   969   fix k
   970   from R have RR: "!!i. (if i = k then coeff P p i else \<zero>) \<in> carrier R"
   971     by simp
   972   show "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k = coeff P p k"
   973   proof (cases "k \<le> deg R p")
   974     case True
   975     hence "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k =
   976           coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..k} \<union> {k<..deg R p}. ?s i) k"
   977       by (simp only: ivl_disj_un_one)
   978     also from True
   979     have "... = coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..k}. ?s i) k"
   980       by (simp cong: R.finsum_cong add: R.finsum_Un_disjoint
   981         ivl_disj_int_one order_less_imp_not_eq2 coeff_finsum R RR Pi_def)
   982     also
   983     have "... = coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..<k} \<union> {k}. ?s i) k"
   984       by (simp only: ivl_disj_un_singleton)
   985     also have "... = coeff P p k"
   986       by (simp cong: R.finsum_cong add: coeff_finsum deg_aboveD R RR Pi_def)
   987     finally show ?thesis .
   988   next
   989     case False
   990     hence "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k =
   991           coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..<deg R p} \<union> {deg R p}. ?s i) k"
   992       by (simp only: ivl_disj_un_singleton)
   993     also from False have "... = coeff P p k"
   994       by (simp cong: R.finsum_cong add: coeff_finsum deg_aboveD R Pi_def)
   995     finally show ?thesis .
   996   qed
   997 qed (simp_all add: R Pi_def)
   998 
   999 lemma up_repr_le:
  1000   "[| deg R p <= n; p \<in> carrier P |] ==>
  1001   (\<Oplus>\<^bsub>P\<^esub> i \<in> {..n}. monom P (coeff P p i) i) = p"
  1002 proof -
  1003   let ?s = "(\<lambda>i. monom P (coeff P p i) i)"
  1004   assume R: "p \<in> carrier P" and "deg R p <= n"
  1005   then have "finsum P ?s {..n} = finsum P ?s ({..deg R p} \<union> {deg R p<..n})"
  1006     by (simp only: ivl_disj_un_one)
  1007   also have "... = finsum P ?s {..deg R p}"
  1008     by (simp cong: P.finsum_cong add: P.finsum_Un_disjoint ivl_disj_int_one
  1009       deg_aboveD R Pi_def)
  1010   also have "... = p" using R by (rule up_repr)
  1011   finally show ?thesis .
  1012 qed
  1013 
  1014 end
  1015 
  1016 
  1017 subsection \<open>Polynomials over Integral Domains\<close>
  1018 
  1019 lemma domainI:
  1020   assumes cring: "cring R"
  1021     and one_not_zero: "one R \<noteq> zero R"
  1022     and integral: "\<And>a b. [| mult R a b = zero R; a \<in> carrier R;
  1023       b \<in> carrier R |] ==> a = zero R \<or> b = zero R"
  1024   shows "domain R"
  1025   by (auto intro!: domain.intro domain_axioms.intro cring.axioms assms
  1026     del: disjCI)
  1027 
  1028 context UP_domain
  1029 begin
  1030 
  1031 lemma UP_one_not_zero:
  1032   "\<one>\<^bsub>P\<^esub> \<noteq> \<zero>\<^bsub>P\<^esub>"
  1033 proof
  1034   assume "\<one>\<^bsub>P\<^esub> = \<zero>\<^bsub>P\<^esub>"
  1035   hence "coeff P \<one>\<^bsub>P\<^esub> 0 = (coeff P \<zero>\<^bsub>P\<^esub> 0)" by simp
  1036   hence "\<one> = \<zero>" by simp
  1037   with R.one_not_zero show "False" by contradiction
  1038 qed
  1039 
  1040 lemma UP_integral:
  1041   "[| p \<otimes>\<^bsub>P\<^esub> q = \<zero>\<^bsub>P\<^esub>; p \<in> carrier P; q \<in> carrier P |] ==> p = \<zero>\<^bsub>P\<^esub> \<or> q = \<zero>\<^bsub>P\<^esub>"
  1042 proof -
  1043   fix p q
  1044   assume pq: "p \<otimes>\<^bsub>P\<^esub> q = \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P" "q \<in> carrier P"
  1045   show "p = \<zero>\<^bsub>P\<^esub> \<or> q = \<zero>\<^bsub>P\<^esub>"
  1046   proof (rule classical)
  1047     assume c: "\<not> (p = \<zero>\<^bsub>P\<^esub> \<or> q = \<zero>\<^bsub>P\<^esub>)"
  1048     with R have "deg R p + deg R q = deg R (p \<otimes>\<^bsub>P\<^esub> q)" by simp
  1049     also from pq have "... = 0" by simp
  1050     finally have "deg R p + deg R q = 0" .
  1051     then have f1: "deg R p = 0 \<and> deg R q = 0" by simp
  1052     from f1 R have "p = (\<Oplus>\<^bsub>P\<^esub> i \<in> {..0}. monom P (coeff P p i) i)"
  1053       by (simp only: up_repr_le)
  1054     also from R have "... = monom P (coeff P p 0) 0" by simp
  1055     finally have p: "p = monom P (coeff P p 0) 0" .
  1056     from f1 R have "q = (\<Oplus>\<^bsub>P\<^esub> i \<in> {..0}. monom P (coeff P q i) i)"
  1057       by (simp only: up_repr_le)
  1058     also from R have "... = monom P (coeff P q 0) 0" by simp
  1059     finally have q: "q = monom P (coeff P q 0) 0" .
  1060     from R have "coeff P p 0 \<otimes> coeff P q 0 = coeff P (p \<otimes>\<^bsub>P\<^esub> q) 0" by simp
  1061     also from pq have "... = \<zero>" by simp
  1062     finally have "coeff P p 0 \<otimes> coeff P q 0 = \<zero>" .
  1063     with R have "coeff P p 0 = \<zero> \<or> coeff P q 0 = \<zero>"
  1064       by (simp add: R.integral_iff)
  1065     with p q show "p = \<zero>\<^bsub>P\<^esub> \<or> q = \<zero>\<^bsub>P\<^esub>" by fastforce
  1066   qed
  1067 qed
  1068 
  1069 theorem UP_domain:
  1070   "domain P"
  1071   by (auto intro!: domainI UP_cring UP_one_not_zero UP_integral del: disjCI)
  1072 
  1073 end
  1074 
  1075 text \<open>
  1076   Interpretation of theorems from @{term domain}.
  1077 \<close>
  1078 
  1079 sublocale UP_domain < "domain" P
  1080   by intro_locales (rule domain.axioms UP_domain)+
  1081 
  1082 
  1083 subsection \<open>The Evaluation Homomorphism and Universal Property\<close>
  1084 
  1085 (* alternative congruence rule (possibly more efficient)
  1086 lemma (in abelian_monoid) finsum_cong2:
  1087   "[| !!i. i \<in> A ==> f i \<in> carrier G = True; A = B;
  1088   !!i. i \<in> B ==> f i = g i |] ==> finsum G f A = finsum G g B"
  1089   sorry*)
  1090 
  1091 lemma (in abelian_monoid) boundD_carrier:
  1092   "[| bound \<zero> n f; n < m |] ==> f m \<in> carrier G"
  1093   by auto
  1094 
  1095 context ring
  1096 begin
  1097 
  1098 theorem diagonal_sum:
  1099   "[| f \<in> {..n + m::nat} \<rightarrow> carrier R; g \<in> {..n + m} \<rightarrow> carrier R |] ==>
  1100   (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1101   (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1102 proof -
  1103   assume Rf: "f \<in> {..n + m} \<rightarrow> carrier R" and Rg: "g \<in> {..n + m} \<rightarrow> carrier R"
  1104   {
  1105     fix j
  1106     have "j <= n + m ==>
  1107       (\<Oplus>k \<in> {..j}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1108       (\<Oplus>k \<in> {..j}. \<Oplus>i \<in> {..j - k}. f k \<otimes> g i)"
  1109     proof (induct j)
  1110       case 0 from Rf Rg show ?case by (simp add: Pi_def)
  1111     next
  1112       case (Suc j)
  1113       have R6: "!!i k. [| k <= j; i <= Suc j - k |] ==> g i \<in> carrier R"
  1114         using Suc by (auto intro!: funcset_mem [OF Rg])
  1115       have R8: "!!i k. [| k <= Suc j; i <= k |] ==> g (k - i) \<in> carrier R"
  1116         using Suc by (auto intro!: funcset_mem [OF Rg])
  1117       have R9: "!!i k. [| k <= Suc j |] ==> f k \<in> carrier R"
  1118         using Suc by (auto intro!: funcset_mem [OF Rf])
  1119       have R10: "!!i k. [| k <= Suc j; i <= Suc j - k |] ==> g i \<in> carrier R"
  1120         using Suc by (auto intro!: funcset_mem [OF Rg])
  1121       have R11: "g 0 \<in> carrier R"
  1122         using Suc by (auto intro!: funcset_mem [OF Rg])
  1123       from Suc show ?case
  1124         by (simp cong: finsum_cong add: Suc_diff_le a_ac
  1125           Pi_def R6 R8 R9 R10 R11)
  1126     qed
  1127   }
  1128   then show ?thesis by fast
  1129 qed
  1130 
  1131 theorem cauchy_product:
  1132   assumes bf: "bound \<zero> n f" and bg: "bound \<zero> m g"
  1133     and Rf: "f \<in> {..n} \<rightarrow> carrier R" and Rg: "g \<in> {..m} \<rightarrow> carrier R"
  1134   shows "(\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1135     (\<Oplus>i \<in> {..n}. f i) \<otimes> (\<Oplus>i \<in> {..m}. g i)"      (* State reverse direction? *)
  1136 proof -
  1137   have f: "!!x. f x \<in> carrier R"
  1138   proof -
  1139     fix x
  1140     show "f x \<in> carrier R"
  1141       using Rf bf boundD_carrier by (cases "x <= n") (auto simp: Pi_def)
  1142   qed
  1143   have g: "!!x. g x \<in> carrier R"
  1144   proof -
  1145     fix x
  1146     show "g x \<in> carrier R"
  1147       using Rg bg boundD_carrier by (cases "x <= m") (auto simp: Pi_def)
  1148   qed
  1149   from f g have "(\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1150       (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1151     by (simp add: diagonal_sum Pi_def)
  1152   also have "... = (\<Oplus>k \<in> {..n} \<union> {n<..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1153     by (simp only: ivl_disj_un_one)
  1154   also from f g have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1155     by (simp cong: finsum_cong
  1156       add: bound.bound [OF bf] finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1157   also from f g
  1158   have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..m} \<union> {m<..n + m - k}. f k \<otimes> g i)"
  1159     by (simp cong: finsum_cong add: ivl_disj_un_one le_add_diff Pi_def)
  1160   also from f g have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..m}. f k \<otimes> g i)"
  1161     by (simp cong: finsum_cong
  1162       add: bound.bound [OF bg] finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1163   also from f g have "... = (\<Oplus>i \<in> {..n}. f i) \<otimes> (\<Oplus>i \<in> {..m}. g i)"
  1164     by (simp add: finsum_ldistr diagonal_sum Pi_def,
  1165       simp cong: finsum_cong add: finsum_rdistr Pi_def)
  1166   finally show ?thesis .
  1167 qed
  1168 
  1169 end
  1170 
  1171 lemma (in UP_ring) const_ring_hom:
  1172   "(\<lambda>a. monom P a 0) \<in> ring_hom R P"
  1173   by (auto intro!: ring_hom_memI intro: up_eqI simp: monom_mult_is_smult)
  1174 
  1175 definition
  1176   eval :: "[('a, 'm) ring_scheme, ('b, 'n) ring_scheme,
  1177            'a => 'b, 'b, nat => 'a] => 'b"
  1178   where "eval R S phi s = (\<lambda>p \<in> carrier (UP R).
  1179     \<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R p}. phi (coeff (UP R) p i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i)"
  1180 
  1181 context UP
  1182 begin
  1183 
  1184 lemma eval_on_carrier:
  1185   fixes S (structure)
  1186   shows "p \<in> carrier P ==>
  1187   eval R S phi s p = (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. phi (coeff P p i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i)"
  1188   by (unfold eval_def, fold P_def) simp
  1189 
  1190 lemma eval_extensional:
  1191   "eval R S phi p \<in> extensional (carrier P)"
  1192   by (unfold eval_def, fold P_def) simp
  1193 
  1194 end
  1195 
  1196 text \<open>The universal property of the polynomial ring\<close>
  1197 
  1198 locale UP_pre_univ_prop = ring_hom_cring + UP_cring
  1199 
  1200 locale UP_univ_prop = UP_pre_univ_prop +
  1201   fixes s and Eval
  1202   assumes indet_img_carrier [simp, intro]: "s \<in> carrier S"
  1203   defines Eval_def: "Eval == eval R S h s"
  1204 
  1205 text\<open>JE: I have moved the following lemma from Ring.thy and lifted then to the locale @{term ring_hom_ring} from @{term ring_hom_cring}.\<close>
  1206 text\<open>JE: I was considering using it in \<open>eval_ring_hom\<close>, but that property does not hold for non commutative rings, so
  1207   maybe it is not that necessary.\<close>
  1208 
  1209 lemma (in ring_hom_ring) hom_finsum [simp]:
  1210   "f \<in> A \<rightarrow> carrier R \<Longrightarrow>
  1211   h (finsum R f A) = finsum S (h \<circ> f) A"
  1212   by (induct A rule: infinite_finite_induct, auto simp: Pi_def)
  1213 
  1214 context UP_pre_univ_prop
  1215 begin
  1216 
  1217 theorem eval_ring_hom:
  1218   assumes S: "s \<in> carrier S"
  1219   shows "eval R S h s \<in> ring_hom P S"
  1220 proof (rule ring_hom_memI)
  1221   fix p
  1222   assume R: "p \<in> carrier P"
  1223   then show "eval R S h s p \<in> carrier S"
  1224     by (simp only: eval_on_carrier) (simp add: S Pi_def)
  1225 next
  1226   fix p q
  1227   assume R: "p \<in> carrier P" "q \<in> carrier P"
  1228   then show "eval R S h s (p \<oplus>\<^bsub>P\<^esub> q) = eval R S h s p \<oplus>\<^bsub>S\<^esub> eval R S h s q"
  1229   proof (simp only: eval_on_carrier P.a_closed)
  1230     from S R have
  1231       "(\<Oplus>\<^bsub>S \<^esub>i\<in>{..deg R (p \<oplus>\<^bsub>P\<^esub> q)}. h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i) =
  1232       (\<Oplus>\<^bsub>S \<^esub>i\<in>{..deg R (p \<oplus>\<^bsub>P\<^esub> q)} \<union> {deg R (p \<oplus>\<^bsub>P\<^esub> q)<..max (deg R p) (deg R q)}.
  1233         h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i)"
  1234       by (simp cong: S.finsum_cong
  1235         add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def del: coeff_add)
  1236     also from R have "... =
  1237         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..max (deg R p) (deg R q)}.
  1238           h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i)"
  1239       by (simp add: ivl_disj_un_one)
  1240     also from R S have "... =
  1241       (\<Oplus>\<^bsub>S\<^esub>i\<in>{..max (deg R p) (deg R q)}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1242       (\<Oplus>\<^bsub>S\<^esub>i\<in>{..max (deg R p) (deg R q)}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i)"
  1243       by (simp cong: S.finsum_cong
  1244         add: S.l_distr deg_aboveD ivl_disj_int_one Pi_def)
  1245     also have "... =
  1246         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p} \<union> {deg R p<..max (deg R p) (deg R q)}.
  1247           h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1248         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q} \<union> {deg R q<..max (deg R p) (deg R q)}.
  1249           h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i)"
  1250       by (simp only: ivl_disj_un_one max.cobounded1 max.cobounded2)
  1251     also from R S have "... =
  1252       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1253       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i)"
  1254       by (simp cong: S.finsum_cong
  1255         add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1256     finally show
  1257       "(\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R (p \<oplus>\<^bsub>P\<^esub> q)}. h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i) =
  1258       (\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1259       (\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i)" .
  1260   qed
  1261 next
  1262   show "eval R S h s \<one>\<^bsub>P\<^esub> = \<one>\<^bsub>S\<^esub>"
  1263     by (simp only: eval_on_carrier UP_one_closed) simp
  1264 next
  1265   fix p q
  1266   assume R: "p \<in> carrier P" "q \<in> carrier P"
  1267   then show "eval R S h s (p \<otimes>\<^bsub>P\<^esub> q) = eval R S h s p \<otimes>\<^bsub>S\<^esub> eval R S h s q"
  1268   proof (simp only: eval_on_carrier UP_mult_closed)
  1269     from R S have
  1270       "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i) =
  1271       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)} \<union> {deg R (p \<otimes>\<^bsub>P\<^esub> q)<..deg R p + deg R q}.
  1272         h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i)"
  1273       by (simp cong: S.finsum_cong
  1274         add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def
  1275         del: coeff_mult)
  1276     also from R have "... =
  1277       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p + deg R q}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i)"
  1278       by (simp only: ivl_disj_un_one deg_mult_ring)
  1279     also from R S have "... =
  1280       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p + deg R q}.
  1281          \<Oplus>\<^bsub>S\<^esub> k \<in> {..i}.
  1282            h (coeff P p k) \<otimes>\<^bsub>S\<^esub> h (coeff P q (i - k)) \<otimes>\<^bsub>S\<^esub>
  1283            (s [^]\<^bsub>S\<^esub> k \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> (i - k)))"
  1284       by (simp cong: S.finsum_cong add: S.nat_pow_mult Pi_def
  1285         S.m_ac S.finsum_rdistr)
  1286     also from R S have "... =
  1287       (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i) \<otimes>\<^bsub>S\<^esub>
  1288       (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i)"
  1289       by (simp add: S.cauchy_product [THEN sym] bound.intro deg_aboveD S.m_ac
  1290         Pi_def)
  1291     finally show
  1292       "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i) =
  1293       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i) \<otimes>\<^bsub>S\<^esub>
  1294       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i)" .
  1295   qed
  1296 qed
  1297 
  1298 text \<open>
  1299   The following lemma could be proved in \<open>UP_cring\<close> with the additional
  1300   assumption that \<open>h\<close> is closed.\<close>
  1301 
  1302 lemma (in UP_pre_univ_prop) eval_const:
  1303   "[| s \<in> carrier S; r \<in> carrier R |] ==> eval R S h s (monom P r 0) = h r"
  1304   by (simp only: eval_on_carrier monom_closed) simp
  1305 
  1306 text \<open>Further properties of the evaluation homomorphism.\<close>
  1307 
  1308 text \<open>The following proof is complicated by the fact that in arbitrary
  1309   rings one might have @{term "one R = zero R"}.\<close>
  1310 
  1311 (* TODO: simplify by cases "one R = zero R" *)
  1312 
  1313 lemma (in UP_pre_univ_prop) eval_monom1:
  1314   assumes S: "s \<in> carrier S"
  1315   shows "eval R S h s (monom P \<one> 1) = s"
  1316 proof (simp only: eval_on_carrier monom_closed R.one_closed)
  1317    from S have
  1318     "(\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R (monom P \<one> 1)}. h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i) =
  1319     (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R (monom P \<one> 1)} \<union> {deg R (monom P \<one> 1)<..1}.
  1320       h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i)"
  1321     by (simp cong: S.finsum_cong del: coeff_monom
  1322       add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1323   also have "... =
  1324     (\<Oplus>\<^bsub>S\<^esub> i \<in> {..1}. h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i)"
  1325     by (simp only: ivl_disj_un_one deg_monom_le R.one_closed)
  1326   also have "... = s"
  1327   proof (cases "s = \<zero>\<^bsub>S\<^esub>")
  1328     case True then show ?thesis by (simp add: Pi_def)
  1329   next
  1330     case False then show ?thesis by (simp add: S Pi_def)
  1331   qed
  1332   finally show "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (monom P \<one> 1)}.
  1333     h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> i) = s" .
  1334 qed
  1335 
  1336 end
  1337 
  1338 text \<open>Interpretation of ring homomorphism lemmas.\<close>
  1339 
  1340 sublocale UP_univ_prop < ring_hom_cring P S Eval
  1341   unfolding Eval_def
  1342   by unfold_locales (fast intro: eval_ring_hom)
  1343 
  1344 lemma (in UP_cring) monom_pow:
  1345   assumes R: "a \<in> carrier R"
  1346   shows "(monom P a n) [^]\<^bsub>P\<^esub> m = monom P (a [^] m) (n * m)"
  1347 proof (induct m)
  1348   case 0 from R show ?case by simp
  1349 next
  1350   case Suc with R show ?case
  1351     by (simp del: monom_mult add: monom_mult [THEN sym] add.commute)
  1352 qed
  1353 
  1354 lemma (in ring_hom_cring) hom_pow [simp]:
  1355   "x \<in> carrier R ==> h (x [^] n) = h x [^]\<^bsub>S\<^esub> (n::nat)"
  1356   by (induct n) simp_all
  1357 
  1358 lemma (in UP_univ_prop) Eval_monom:
  1359   "r \<in> carrier R ==> Eval (monom P r n) = h r \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> n"
  1360 proof -
  1361   assume R: "r \<in> carrier R"
  1362   from R have "Eval (monom P r n) = Eval (monom P r 0 \<otimes>\<^bsub>P\<^esub> (monom P \<one> 1) [^]\<^bsub>P\<^esub> n)"
  1363     by (simp del: monom_mult add: monom_mult [THEN sym] monom_pow)
  1364   also
  1365   from R eval_monom1 [where s = s, folded Eval_def]
  1366   have "... = h r \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> n"
  1367     by (simp add: eval_const [where s = s, folded Eval_def])
  1368   finally show ?thesis .
  1369 qed
  1370 
  1371 lemma (in UP_pre_univ_prop) eval_monom:
  1372   assumes R: "r \<in> carrier R" and S: "s \<in> carrier S"
  1373   shows "eval R S h s (monom P r n) = h r \<otimes>\<^bsub>S\<^esub> s [^]\<^bsub>S\<^esub> n"
  1374 proof -
  1375   interpret UP_univ_prop R S h P s "eval R S h s"
  1376     using UP_pre_univ_prop_axioms P_def R S
  1377     by (auto intro: UP_univ_prop.intro UP_univ_prop_axioms.intro)
  1378   from R
  1379   show ?thesis by (rule Eval_monom)
  1380 qed
  1381 
  1382 lemma (in UP_univ_prop) Eval_smult:
  1383   "[| r \<in> carrier R; p \<in> carrier P |] ==> Eval (r \<odot>\<^bsub>P\<^esub> p) = h r \<otimes>\<^bsub>S\<^esub> Eval p"
  1384 proof -
  1385   assume R: "r \<in> carrier R" and P: "p \<in> carrier P"
  1386   then show ?thesis
  1387     by (simp add: monom_mult_is_smult [THEN sym]
  1388       eval_const [where s = s, folded Eval_def])
  1389 qed
  1390 
  1391 lemma ring_hom_cringI:
  1392   assumes "cring R"
  1393     and "cring S"
  1394     and "h \<in> ring_hom R S"
  1395   shows "ring_hom_cring R S h"
  1396   by (fast intro: ring_hom_cring.intro ring_hom_cring_axioms.intro
  1397     cring.axioms assms)
  1398 
  1399 context UP_pre_univ_prop
  1400 begin
  1401 
  1402 lemma UP_hom_unique:
  1403   assumes "ring_hom_cring P S Phi"
  1404   assumes Phi: "Phi (monom P \<one> (Suc 0)) = s"
  1405       "!!r. r \<in> carrier R ==> Phi (monom P r 0) = h r"
  1406   assumes "ring_hom_cring P S Psi"
  1407   assumes Psi: "Psi (monom P \<one> (Suc 0)) = s"
  1408       "!!r. r \<in> carrier R ==> Psi (monom P r 0) = h r"
  1409     and P: "p \<in> carrier P" and S: "s \<in> carrier S"
  1410   shows "Phi p = Psi p"
  1411 proof -
  1412   interpret ring_hom_cring P S Phi by fact
  1413   interpret ring_hom_cring P S Psi by fact
  1414   have "Phi p =
  1415       Phi (\<Oplus>\<^bsub>P \<^esub>i \<in> {..deg R p}. monom P (coeff P p i) 0 \<otimes>\<^bsub>P\<^esub> monom P \<one> 1 [^]\<^bsub>P\<^esub> i)"
  1416     by (simp add: up_repr P monom_mult [THEN sym] monom_pow del: monom_mult)
  1417   also
  1418   have "... =
  1419       Psi (\<Oplus>\<^bsub>P \<^esub>i\<in>{..deg R p}. monom P (coeff P p i) 0 \<otimes>\<^bsub>P\<^esub> monom P \<one> 1 [^]\<^bsub>P\<^esub> i)"
  1420     by (simp add: Phi Psi P Pi_def comp_def)
  1421   also have "... = Psi p"
  1422     by (simp add: up_repr P monom_mult [THEN sym] monom_pow del: monom_mult)
  1423   finally show ?thesis .
  1424 qed
  1425 
  1426 lemma ring_homD:
  1427   assumes Phi: "Phi \<in> ring_hom P S"
  1428   shows "ring_hom_cring P S Phi"
  1429   by unfold_locales (rule Phi)
  1430 
  1431 theorem UP_universal_property:
  1432   assumes S: "s \<in> carrier S"
  1433   shows "\<exists>!Phi. Phi \<in> ring_hom P S \<inter> extensional (carrier P) \<and>
  1434     Phi (monom P \<one> 1) = s \<and>
  1435     (\<forall>r \<in> carrier R. Phi (monom P r 0) = h r)"
  1436   using S eval_monom1
  1437   apply (auto intro: eval_ring_hom eval_const eval_extensional)
  1438   apply (rule extensionalityI)
  1439   apply (auto intro: UP_hom_unique ring_homD)
  1440   done
  1441 
  1442 end
  1443 
  1444 text\<open>JE: The following lemma was added by me; it might be even lifted to a simpler locale\<close>
  1445 
  1446 context monoid
  1447 begin
  1448 
  1449 lemma nat_pow_eone[simp]: assumes x_in_G: "x \<in> carrier G" shows "x [^] (1::nat) = x"
  1450   using nat_pow_Suc [of x 0] unfolding nat_pow_0 [of x] unfolding l_one [OF x_in_G] by simp
  1451 
  1452 end
  1453 
  1454 context UP_ring
  1455 begin
  1456 
  1457 abbreviation lcoeff :: "(nat =>'a) => 'a" where "lcoeff p == coeff P p (deg R p)"
  1458 
  1459 lemma lcoeff_nonzero2: assumes p_in_R: "p \<in> carrier P" and p_not_zero: "p \<noteq> \<zero>\<^bsub>P\<^esub>" shows "lcoeff p \<noteq> \<zero>"
  1460   using lcoeff_nonzero [OF p_not_zero p_in_R] .
  1461 
  1462 
  1463 subsection\<open>The long division algorithm: some previous facts.\<close>
  1464 
  1465 lemma coeff_minus [simp]:
  1466   assumes p: "p \<in> carrier P" and q: "q \<in> carrier P" 
  1467   shows "coeff P (p \<ominus>\<^bsub>P\<^esub> q) n = coeff P p n \<ominus> coeff P q n"
  1468   by (simp add: a_minus_def p q)
  1469 
  1470 lemma lcoeff_closed [simp]: assumes p: "p \<in> carrier P" shows "lcoeff p \<in> carrier R"
  1471   using coeff_closed [OF p, of "deg R p"] by simp
  1472 
  1473 lemma deg_smult_decr: assumes a_in_R: "a \<in> carrier R" and f_in_P: "f \<in> carrier P" shows "deg R (a \<odot>\<^bsub>P\<^esub> f) \<le> deg R f"
  1474   using deg_smult_ring [OF a_in_R f_in_P] by (cases "a = \<zero>", auto)
  1475 
  1476 lemma coeff_monom_mult: assumes R: "c \<in> carrier R" and P: "p \<in> carrier P"
  1477   shows "coeff P (monom P c n \<otimes>\<^bsub>P\<^esub> p) (m + n) = c \<otimes> (coeff P p m)"
  1478 proof -
  1479   have "coeff P (monom P c n \<otimes>\<^bsub>P\<^esub> p) (m + n) = (\<Oplus>i\<in>{..m + n}. (if n = i then c else \<zero>) \<otimes> coeff P p (m + n - i))"
  1480     unfolding coeff_mult [OF monom_closed [OF R, of n] P, of "m + n"] unfolding coeff_monom [OF R, of n] by simp
  1481   also have "(\<Oplus>i\<in>{..m + n}. (if n = i then c else \<zero>) \<otimes> coeff P p (m + n - i)) =
  1482     (\<Oplus>i\<in>{..m + n}. (if n = i then c \<otimes> coeff P p (m + n - i) else \<zero>))"
  1483     using  R.finsum_cong [of "{..m + n}" "{..m + n}" "(\<lambda>i::nat. (if n = i then c else \<zero>) \<otimes> coeff P p (m + n - i))"
  1484       "(\<lambda>i::nat. (if n = i then c \<otimes> coeff P p (m + n - i) else \<zero>))"]
  1485     using coeff_closed [OF P] unfolding Pi_def simp_implies_def using R by auto
  1486   also have "\<dots> = c \<otimes> coeff P p m" using R.finsum_singleton [of n "{..m + n}" "(\<lambda>i. c \<otimes> coeff P p (m + n - i))"]
  1487     unfolding Pi_def using coeff_closed [OF P] using P R by auto
  1488   finally show ?thesis by simp
  1489 qed
  1490 
  1491 lemma deg_lcoeff_cancel:
  1492   assumes p_in_P: "p \<in> carrier P" and q_in_P: "q \<in> carrier P" and r_in_P: "r \<in> carrier P"
  1493   and deg_r_nonzero: "deg R r \<noteq> 0"
  1494   and deg_R_p: "deg R p \<le> deg R r" and deg_R_q: "deg R q \<le> deg R r"
  1495   and coeff_R_p_eq_q: "coeff P p (deg R r) = \<ominus>\<^bsub>R\<^esub> (coeff P q (deg R r))"
  1496   shows "deg R (p \<oplus>\<^bsub>P\<^esub> q) < deg R r"
  1497 proof -
  1498   have deg_le: "deg R (p \<oplus>\<^bsub>P\<^esub> q) \<le> deg R r"
  1499   proof (rule deg_aboveI)
  1500     fix m
  1501     assume deg_r_le: "deg R r < m"
  1502     show "coeff P (p \<oplus>\<^bsub>P\<^esub> q) m = \<zero>"
  1503     proof -
  1504       have slp: "deg R p < m" and "deg R q < m" using deg_R_p deg_R_q using deg_r_le by auto
  1505       then have max_sl: "max (deg R p) (deg R q) < m" by simp
  1506       then have "deg R (p \<oplus>\<^bsub>P\<^esub> q) < m" using deg_add [OF p_in_P q_in_P] by arith
  1507       with deg_R_p deg_R_q show ?thesis using coeff_add [OF p_in_P q_in_P, of m]
  1508         using deg_aboveD [of "p \<oplus>\<^bsub>P\<^esub> q" m] using p_in_P q_in_P by simp
  1509     qed
  1510   qed (simp add: p_in_P q_in_P)
  1511   moreover have deg_ne: "deg R (p \<oplus>\<^bsub>P\<^esub> q) \<noteq> deg R r"
  1512   proof (rule ccontr)
  1513     assume nz: "\<not> deg R (p \<oplus>\<^bsub>P\<^esub> q) \<noteq> deg R r" then have deg_eq: "deg R (p \<oplus>\<^bsub>P\<^esub> q) = deg R r" by simp
  1514     from deg_r_nonzero have r_nonzero: "r \<noteq> \<zero>\<^bsub>P\<^esub>" by (cases "r = \<zero>\<^bsub>P\<^esub>", simp_all)
  1515     have "coeff P (p \<oplus>\<^bsub>P\<^esub> q) (deg R r) = \<zero>\<^bsub>R\<^esub>" using coeff_add [OF p_in_P q_in_P, of "deg R r"] using coeff_R_p_eq_q
  1516       using coeff_closed [OF p_in_P, of "deg R r"] coeff_closed [OF q_in_P, of "deg R r"] by algebra
  1517     with lcoeff_nonzero [OF r_nonzero r_in_P]  and deg_eq show False using lcoeff_nonzero [of "p \<oplus>\<^bsub>P\<^esub> q"] using p_in_P q_in_P
  1518       using deg_r_nonzero by (cases "p \<oplus>\<^bsub>P\<^esub> q \<noteq> \<zero>\<^bsub>P\<^esub>", auto)
  1519   qed
  1520   ultimately show ?thesis by simp
  1521 qed
  1522 
  1523 lemma monom_deg_mult:
  1524   assumes f_in_P: "f \<in> carrier P" and g_in_P: "g \<in> carrier P" and deg_le: "deg R g \<le> deg R f"
  1525   and a_in_R: "a \<in> carrier R"
  1526   shows "deg R (g \<otimes>\<^bsub>P\<^esub> monom P a (deg R f - deg R g)) \<le> deg R f"
  1527   using deg_mult_ring [OF g_in_P monom_closed [OF a_in_R, of "deg R f - deg R g"]]
  1528   apply (cases "a = \<zero>") using g_in_P apply simp
  1529   using deg_monom [OF _ a_in_R, of "deg R f - deg R g"] using deg_le by simp
  1530 
  1531 lemma deg_zero_impl_monom:
  1532   assumes f_in_P: "f \<in> carrier P" and deg_f: "deg R f = 0"
  1533   shows "f = monom P (coeff P f 0) 0"
  1534   apply (rule up_eqI) using coeff_monom [OF coeff_closed [OF f_in_P], of 0 0]
  1535   using f_in_P deg_f using deg_aboveD [of f _] by auto
  1536 
  1537 end
  1538 
  1539 
  1540 subsection \<open>The long division proof for commutative rings\<close>
  1541 
  1542 context UP_cring
  1543 begin
  1544 
  1545 lemma exI3: assumes exist: "Pred x y z"
  1546   shows "\<exists> x y z. Pred x y z"
  1547   using exist by blast
  1548 
  1549 text \<open>Jacobson's Theorem 2.14\<close>
  1550 
  1551 lemma long_div_theorem:
  1552   assumes g_in_P [simp]: "g \<in> carrier P" and f_in_P [simp]: "f \<in> carrier P"
  1553   and g_not_zero: "g \<noteq> \<zero>\<^bsub>P\<^esub>"
  1554   shows "\<exists>q r (k::nat). (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> (lcoeff g)[^]\<^bsub>R\<^esub>k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (r = \<zero>\<^bsub>P\<^esub> \<or> deg R r < deg R g)"
  1555   using f_in_P
  1556 proof (induct "deg R f" arbitrary: "f" rule: nat_less_induct)
  1557   case (1 f)
  1558   note f_in_P [simp] = "1.prems"
  1559   let ?pred = "(\<lambda> q r (k::nat).
  1560     (q \<in> carrier P) \<and> (r \<in> carrier P)
  1561     \<and> (lcoeff g)[^]\<^bsub>R\<^esub>k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (r = \<zero>\<^bsub>P\<^esub> \<or> deg R r < deg R g))"
  1562   let ?lg = "lcoeff g" and ?lf = "lcoeff f"
  1563   show ?case
  1564   proof (cases "deg R f < deg R g")
  1565     case True
  1566     have "?pred \<zero>\<^bsub>P\<^esub> f 0" using True by force
  1567     then show ?thesis by blast
  1568   next
  1569     case False then have deg_g_le_deg_f: "deg R g \<le> deg R f" by simp
  1570     {
  1571       let ?k = "1::nat"
  1572       let ?f1 = "(g \<otimes>\<^bsub>P\<^esub> (monom P (?lf) (deg R f - deg R g))) \<oplus>\<^bsub>P\<^esub> \<ominus>\<^bsub>P\<^esub> (?lg \<odot>\<^bsub>P\<^esub> f)"
  1573       let ?q = "monom P (?lf) (deg R f - deg R g)"
  1574       have f1_in_carrier: "?f1 \<in> carrier P" and q_in_carrier: "?q \<in> carrier P" by simp_all
  1575       show ?thesis
  1576       proof (cases "deg R f = 0")
  1577         case True
  1578         {
  1579           have deg_g: "deg R g = 0" using True using deg_g_le_deg_f by simp
  1580           have "?pred f \<zero>\<^bsub>P\<^esub> 1"
  1581             using deg_zero_impl_monom [OF g_in_P deg_g]
  1582             using sym [OF monom_mult_is_smult [OF coeff_closed [OF g_in_P, of 0] f_in_P]]
  1583             using deg_g by simp
  1584           then show ?thesis by blast
  1585         }
  1586       next
  1587         case False note deg_f_nzero = False
  1588         {
  1589           have exist: "lcoeff g [^] ?k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> \<ominus>\<^bsub>P\<^esub> ?f1"
  1590             by (simp add: minus_add r_neg sym [
  1591               OF a_assoc [of "g \<otimes>\<^bsub>P\<^esub> ?q" "\<ominus>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q)" "lcoeff g \<odot>\<^bsub>P\<^esub> f"]])
  1592           have deg_remainder_l_f: "deg R (\<ominus>\<^bsub>P\<^esub> ?f1) < deg R f"
  1593           proof (unfold deg_uminus [OF f1_in_carrier])
  1594             show "deg R ?f1 < deg R f"
  1595             proof (rule deg_lcoeff_cancel)
  1596               show "deg R (\<ominus>\<^bsub>P\<^esub> (?lg \<odot>\<^bsub>P\<^esub> f)) \<le> deg R f"
  1597                 using deg_smult_ring [of ?lg f]
  1598                 using lcoeff_nonzero2 [OF g_in_P g_not_zero] by simp
  1599               show "deg R (g \<otimes>\<^bsub>P\<^esub> ?q) \<le> deg R f"
  1600                 by (simp add: monom_deg_mult [OF f_in_P g_in_P deg_g_le_deg_f, of ?lf])
  1601               show "coeff P (g \<otimes>\<^bsub>P\<^esub> ?q) (deg R f) = \<ominus> coeff P (\<ominus>\<^bsub>P\<^esub> (?lg \<odot>\<^bsub>P\<^esub> f)) (deg R f)"
  1602                 unfolding coeff_mult [OF g_in_P monom_closed
  1603                   [OF lcoeff_closed [OF f_in_P],
  1604                     of "deg R f - deg R g"], of "deg R f"]
  1605                 unfolding coeff_monom [OF lcoeff_closed
  1606                   [OF f_in_P], of "(deg R f - deg R g)"]
  1607                 using R.finsum_cong' [of "{..deg R f}" "{..deg R f}"
  1608                   "(\<lambda>i. coeff P g i \<otimes> (if deg R f - deg R g = deg R f - i then ?lf else \<zero>))"
  1609                   "(\<lambda>i. if deg R g = i then coeff P g i \<otimes> ?lf else \<zero>)"]
  1610                 using R.finsum_singleton [of "deg R g" "{.. deg R f}" "(\<lambda>i. coeff P g i \<otimes> ?lf)"]
  1611                 unfolding Pi_def using deg_g_le_deg_f by force
  1612             qed (simp_all add: deg_f_nzero)
  1613           qed
  1614           then obtain q' r' k'
  1615             where rem_desc: "?lg [^] (k'::nat) \<odot>\<^bsub>P\<^esub> (\<ominus>\<^bsub>P\<^esub> ?f1) = g \<otimes>\<^bsub>P\<^esub> q' \<oplus>\<^bsub>P\<^esub> r'"
  1616             and rem_deg: "(r' = \<zero>\<^bsub>P\<^esub> \<or> deg R r' < deg R g)"
  1617             and q'_in_carrier: "q' \<in> carrier P" and r'_in_carrier: "r' \<in> carrier P"
  1618             using "1.hyps" using f1_in_carrier by blast
  1619           show ?thesis
  1620           proof (rule exI3 [of _ "((?lg [^] k') \<odot>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> q')" r' "Suc k'"], intro conjI)
  1621             show "(?lg [^] (Suc k')) \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> ((?lg [^] k') \<odot>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> q') \<oplus>\<^bsub>P\<^esub> r'"
  1622             proof -
  1623               have "(?lg [^] (Suc k')) \<odot>\<^bsub>P\<^esub> f = (?lg [^] k') \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> \<ominus>\<^bsub>P\<^esub> ?f1)"
  1624                 using smult_assoc1 [OF _ _ f_in_P] using exist by simp
  1625               also have "\<dots> = (?lg [^] k') \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q) \<oplus>\<^bsub>P\<^esub> ((?lg [^] k') \<odot>\<^bsub>P\<^esub> ( \<ominus>\<^bsub>P\<^esub> ?f1))"
  1626                 using UP_smult_r_distr by simp
  1627               also have "\<dots> = (?lg [^] k') \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q) \<oplus>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> q' \<oplus>\<^bsub>P\<^esub> r')"
  1628                 unfolding rem_desc ..
  1629               also have "\<dots> = (?lg [^] k') \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q) \<oplus>\<^bsub>P\<^esub> g \<otimes>\<^bsub>P\<^esub> q' \<oplus>\<^bsub>P\<^esub> r'"
  1630                 using sym [OF a_assoc [of "?lg [^] k' \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q)" "g \<otimes>\<^bsub>P\<^esub> q'" "r'"]]
  1631                 using r'_in_carrier q'_in_carrier by simp
  1632               also have "\<dots> = (?lg [^] k') \<odot>\<^bsub>P\<^esub> (?q \<otimes>\<^bsub>P\<^esub> g) \<oplus>\<^bsub>P\<^esub> q' \<otimes>\<^bsub>P\<^esub> g \<oplus>\<^bsub>P\<^esub> r'"
  1633                 using q'_in_carrier by (auto simp add: m_comm)
  1634               also have "\<dots> = (((?lg [^] k') \<odot>\<^bsub>P\<^esub> ?q) \<otimes>\<^bsub>P\<^esub> g) \<oplus>\<^bsub>P\<^esub> q' \<otimes>\<^bsub>P\<^esub> g \<oplus>\<^bsub>P\<^esub> r'"
  1635                 using smult_assoc2 q'_in_carrier "1.prems" by auto
  1636               also have "\<dots> = ((?lg [^] k') \<odot>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> q') \<otimes>\<^bsub>P\<^esub> g \<oplus>\<^bsub>P\<^esub> r'"
  1637                 using sym [OF l_distr] and q'_in_carrier by auto
  1638               finally show ?thesis using m_comm q'_in_carrier by auto
  1639             qed
  1640           qed (simp_all add: rem_deg q'_in_carrier r'_in_carrier)
  1641         }
  1642       qed
  1643     }
  1644   qed
  1645 qed
  1646 
  1647 end
  1648 
  1649 
  1650 text \<open>The remainder theorem as corollary of the long division theorem.\<close>
  1651 
  1652 context UP_cring
  1653 begin
  1654 
  1655 lemma deg_minus_monom:
  1656   assumes a: "a \<in> carrier R"
  1657   and R_not_trivial: "(carrier R \<noteq> {\<zero>})"
  1658   shows "deg R (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) = 1"
  1659   (is "deg R ?g = 1")
  1660 proof -
  1661   have "deg R ?g \<le> 1"
  1662   proof (rule deg_aboveI)
  1663     fix m
  1664     assume "(1::nat) < m"
  1665     then show "coeff P ?g m = \<zero>"
  1666       using coeff_minus using a by auto algebra
  1667   qed (simp add: a)
  1668   moreover have "deg R ?g \<ge> 1"
  1669   proof (rule deg_belowI)
  1670     show "coeff P ?g 1 \<noteq> \<zero>"
  1671       using a using R.carrier_one_not_zero R_not_trivial by simp algebra
  1672   qed (simp add: a)
  1673   ultimately show ?thesis by simp
  1674 qed
  1675 
  1676 lemma lcoeff_monom:
  1677   assumes a: "a \<in> carrier R" and R_not_trivial: "(carrier R \<noteq> {\<zero>})"
  1678   shows "lcoeff (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) = \<one>"
  1679   using deg_minus_monom [OF a R_not_trivial]
  1680   using coeff_minus a by auto algebra
  1681 
  1682 lemma deg_nzero_nzero:
  1683   assumes deg_p_nzero: "deg R p \<noteq> 0"
  1684   shows "p \<noteq> \<zero>\<^bsub>P\<^esub>"
  1685   using deg_zero deg_p_nzero by auto
  1686 
  1687 lemma deg_monom_minus:
  1688   assumes a: "a \<in> carrier R"
  1689   and R_not_trivial: "carrier R \<noteq> {\<zero>}"
  1690   shows "deg R (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) = 1"
  1691   (is "deg R ?g = 1")
  1692 proof -
  1693   have "deg R ?g \<le> 1"
  1694   proof (rule deg_aboveI)
  1695     fix m::nat assume "1 < m" then show "coeff P ?g m = \<zero>"
  1696       using coeff_minus [OF monom_closed [OF R.one_closed, of 1] monom_closed [OF a, of 0], of m]
  1697       using coeff_monom [OF R.one_closed, of 1 m] using coeff_monom [OF a, of 0 m] by auto algebra
  1698   qed (simp add: a)
  1699   moreover have "1 \<le> deg R ?g"
  1700   proof (rule deg_belowI)
  1701     show "coeff P ?g 1 \<noteq> \<zero>"
  1702       using coeff_minus [OF monom_closed [OF R.one_closed, of 1] monom_closed [OF a, of 0], of 1]
  1703       using coeff_monom [OF R.one_closed, of 1 1] using coeff_monom [OF a, of 0 1]
  1704       using R_not_trivial using R.carrier_one_not_zero
  1705       by auto algebra
  1706   qed (simp add: a)
  1707   ultimately show ?thesis by simp
  1708 qed
  1709 
  1710 lemma eval_monom_expr:
  1711   assumes a: "a \<in> carrier R"
  1712   shows "eval R R id a (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) = \<zero>"
  1713   (is "eval R R id a ?g = _")
  1714 proof -
  1715   interpret UP_pre_univ_prop R R id by unfold_locales simp
  1716   have eval_ring_hom: "eval R R id a \<in> ring_hom P R" using eval_ring_hom [OF a] by simp
  1717   interpret ring_hom_cring P R "eval R R id a" by unfold_locales (rule eval_ring_hom)
  1718   have mon1_closed: "monom P \<one>\<^bsub>R\<^esub> 1 \<in> carrier P"
  1719     and mon0_closed: "monom P a 0 \<in> carrier P"
  1720     and min_mon0_closed: "\<ominus>\<^bsub>P\<^esub> monom P a 0 \<in> carrier P"
  1721     using a R.a_inv_closed by auto
  1722   have "eval R R id a ?g = eval R R id a (monom P \<one> 1) \<ominus> eval R R id a (monom P a 0)"
  1723     by (simp add: a_minus_def mon0_closed)
  1724   also have "\<dots> = a \<ominus> a"
  1725     using eval_monom [OF R.one_closed a, of 1] using eval_monom [OF a a, of 0] using a by simp
  1726   also have "\<dots> = \<zero>"
  1727     using a by algebra
  1728   finally show ?thesis by simp
  1729 qed
  1730 
  1731 lemma remainder_theorem_exist:
  1732   assumes f: "f \<in> carrier P" and a: "a \<in> carrier R"
  1733   and R_not_trivial: "carrier R \<noteq> {\<zero>}"
  1734   shows "\<exists> q r. (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> f = (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (deg R r = 0)"
  1735   (is "\<exists> q r. (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (deg R r = 0)")
  1736 proof -
  1737   let ?g = "monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0"
  1738   from deg_minus_monom [OF a R_not_trivial]
  1739   have deg_g_nzero: "deg R ?g \<noteq> 0" by simp
  1740   have "\<exists>q r (k::nat). q \<in> carrier P \<and> r \<in> carrier P \<and>
  1741     lcoeff ?g [^] k \<odot>\<^bsub>P\<^esub> f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (r = \<zero>\<^bsub>P\<^esub> \<or> deg R r < deg R ?g)"
  1742     using long_div_theorem [OF _ f deg_nzero_nzero [OF deg_g_nzero]] a
  1743     by auto
  1744   then show ?thesis
  1745     unfolding lcoeff_monom [OF a R_not_trivial]
  1746     unfolding deg_monom_minus [OF a R_not_trivial]
  1747     using smult_one [OF f] using deg_zero by force
  1748 qed
  1749 
  1750 lemma remainder_theorem_expression:
  1751   assumes f [simp]: "f \<in> carrier P" and a [simp]: "a \<in> carrier R"
  1752   and q [simp]: "q \<in> carrier P" and r [simp]: "r \<in> carrier P"
  1753   and R_not_trivial: "carrier R \<noteq> {\<zero>}"
  1754   and f_expr: "f = (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r"
  1755   (is "f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r" is "f = ?gq \<oplus>\<^bsub>P\<^esub> r")
  1756     and deg_r_0: "deg R r = 0"
  1757     shows "r = monom P (eval R R id a f) 0"
  1758 proof -
  1759   interpret UP_pre_univ_prop R R id P by standard simp
  1760   have eval_ring_hom: "eval R R id a \<in> ring_hom P R"
  1761     using eval_ring_hom [OF a] by simp
  1762   have "eval R R id a f = eval R R id a ?gq \<oplus>\<^bsub>R\<^esub> eval R R id a r"
  1763     unfolding f_expr using ring_hom_add [OF eval_ring_hom] by auto
  1764   also have "\<dots> = ((eval R R id a ?g) \<otimes> (eval R R id a q)) \<oplus>\<^bsub>R\<^esub> eval R R id a r"
  1765     using ring_hom_mult [OF eval_ring_hom] by auto
  1766   also have "\<dots> = \<zero> \<oplus> eval R R id a r"
  1767     unfolding eval_monom_expr [OF a] using eval_ring_hom
  1768     unfolding ring_hom_def using q unfolding Pi_def by simp
  1769   also have "\<dots> = eval R R id a r"
  1770     using eval_ring_hom unfolding ring_hom_def using r unfolding Pi_def by simp
  1771   finally have eval_eq: "eval R R id a f = eval R R id a r" by simp
  1772   from deg_zero_impl_monom [OF r deg_r_0]
  1773   have "r = monom P (coeff P r 0) 0" by simp
  1774   with eval_const [OF a, of "coeff P r 0"] eval_eq
  1775   show ?thesis by auto
  1776 qed
  1777 
  1778 corollary remainder_theorem:
  1779   assumes f [simp]: "f \<in> carrier P" and a [simp]: "a \<in> carrier R"
  1780   and R_not_trivial: "carrier R \<noteq> {\<zero>}"
  1781   shows "\<exists> q r. (q \<in> carrier P) \<and> (r \<in> carrier P) \<and>
  1782      f = (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> monom P (eval R R id a f) 0"
  1783   (is "\<exists> q r. (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> monom P (eval R R id a f) 0")
  1784 proof -
  1785   from remainder_theorem_exist [OF f a R_not_trivial]
  1786   obtain q r
  1787     where q_r: "q \<in> carrier P \<and> r \<in> carrier P \<and> f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r"
  1788     and deg_r: "deg R r = 0" by force
  1789   with remainder_theorem_expression [OF f a _ _ R_not_trivial, of q r]
  1790   show ?thesis by auto
  1791 qed
  1792 
  1793 end
  1794 
  1795 
  1796 subsection \<open>Sample Application of Evaluation Homomorphism\<close>
  1797 
  1798 lemma UP_pre_univ_propI:
  1799   assumes "cring R"
  1800     and "cring S"
  1801     and "h \<in> ring_hom R S"
  1802   shows "UP_pre_univ_prop R S h"
  1803   using assms
  1804   by (auto intro!: UP_pre_univ_prop.intro ring_hom_cring.intro
  1805     ring_hom_cring_axioms.intro UP_cring.intro)
  1806 
  1807 definition
  1808   INTEG :: "int ring"
  1809   where "INTEG = \<lparr>carrier = UNIV, mult = ( * ), one = 1, zero = 0, add = (+)\<rparr>"
  1810 
  1811 lemma INTEG_cring: "cring INTEG"
  1812   by (unfold INTEG_def) (auto intro!: cringI abelian_groupI comm_monoidI
  1813     left_minus distrib_right)
  1814 
  1815 lemma INTEG_id_eval:
  1816   "UP_pre_univ_prop INTEG INTEG id"
  1817   by (fast intro: UP_pre_univ_propI INTEG_cring id_ring_hom)
  1818 
  1819 text \<open>
  1820   Interpretation now enables to import all theorems and lemmas
  1821   valid in the context of homomorphisms between @{term INTEG} and @{term
  1822   "UP INTEG"} globally.
  1823 \<close>
  1824 
  1825 interpretation INTEG: UP_pre_univ_prop INTEG INTEG id "UP INTEG"
  1826   using INTEG_id_eval by simp_all
  1827 
  1828 lemma INTEG_closed [intro, simp]:
  1829   "z \<in> carrier INTEG"
  1830   by (unfold INTEG_def) simp
  1831 
  1832 lemma INTEG_mult [simp]:
  1833   "mult INTEG z w = z * w"
  1834   by (unfold INTEG_def) simp
  1835 
  1836 lemma INTEG_pow [simp]:
  1837   "pow INTEG z n = z ^ n"
  1838   by (induct n) (simp_all add: INTEG_def nat_pow_def)
  1839 
  1840 lemma "eval INTEG INTEG id 10 (monom (UP INTEG) 5 2) = 500"
  1841   by (simp add: INTEG.eval_monom)
  1842 
  1843 end