doc-src/antiquote_setup.ML
author wenzelm
Tue Oct 19 21:13:10 2010 +0100 (2010-10-19)
changeset 39873 b70cd46e8e44
parent 39869 c269f6bd0a1f
child 40801 6cfacec435e6
permissions -rw-r--r--
more robust treatment of "op IDENT";
     1 (*  Title:      doc-src/antiquote_setup.ML
     2     Author:     Makarius
     3 
     4 Auxiliary antiquotations for the Isabelle manuals.
     5 *)
     6 
     7 structure AntiquoteSetup: sig end =
     8 struct
     9 
    10 (* misc utils *)
    11 
    12 fun translate f = Symbol.explode #> map f #> implode;
    13 
    14 val clean_string = translate
    15   (fn "_" => "\\_"
    16     | "#" => "\\#"
    17     | "<" => "$<$"
    18     | ">" => "$>$"
    19     | "{" => "\\{"
    20     | "|" => "$\\mid$"
    21     | "}" => "\\}"
    22     | "\<dash>" => "-"
    23     | c => c);
    24 
    25 fun clean_name "\<dots>" = "dots"
    26   | clean_name ".." = "ddot"
    27   | clean_name "." = "dot"
    28   | clean_name "_" = "underscore"
    29   | clean_name "{" = "braceleft"
    30   | clean_name "}" = "braceright"
    31   | clean_name s = s |> translate (fn "_" => "-" | "\<dash>" => "-" | c => c);
    32 
    33 
    34 (* verbatim text *)
    35 
    36 val verbatim = space_implode "\\verb,|," o map (enclose "\\verb|" "|") o space_explode "|";
    37 
    38 val _ = Thy_Output.antiquotation "verbatim" (Scan.lift Args.name)
    39   (K (split_lines #> map verbatim #> space_implode "\\isasep\\isanewline%\n"));
    40 
    41 
    42 (* ML text *)
    43 
    44 local
    45 
    46 fun ml_val (txt1, "") = "fn _ => (" ^ txt1 ^ ");"
    47   | ml_val (txt1, txt2) = "fn _ => (" ^ txt1 ^ " : " ^ txt2 ^ ");";
    48 
    49 fun ml_type (txt1, "") = "val _ = NONE : (" ^ txt1 ^ ") option;"
    50   | ml_type (txt1, txt2) = "val _ = [NONE : (" ^ txt1 ^ ") option, NONE : (" ^ txt2 ^ ") option];";
    51 
    52 fun ml_exn (txt1, "") = "fn _ => (" ^ txt1 ^ " : exn);"
    53   | ml_exn (txt1, txt2) = "fn _ => (" ^ txt1 ^ " : " ^ txt2 ^ " -> exn);";
    54 
    55 fun ml_structure (txt, _) = "functor XXX() = struct structure XX = " ^ txt ^ " end;";
    56 
    57 fun ml_functor (txt, _) = "ML_Env.check_functor " ^ ML_Syntax.print_string txt;
    58 
    59 val is_name = ML_Lex.kind_of #> (fn kind => kind = ML_Lex.Ident orelse kind = ML_Lex.LongIdent);
    60 
    61 fun ml_name txt =
    62   (case filter is_name (ML_Lex.tokenize txt) of
    63     toks as [_] => ML_Lex.flatten toks
    64   | _ => error ("Single ML name expected in input: " ^ quote txt));
    65 
    66 fun index_ml name kind ml = Thy_Output.antiquotation name
    67   (Scan.lift (Args.name -- Scan.optional (Args.colon |-- Args.name) ""))
    68   (fn {context = ctxt, ...} => fn (txt1, txt2) =>
    69     let
    70       val txt =
    71         if txt2 = "" then txt1
    72         else if kind = "type" then txt1 ^ " = " ^ txt2
    73         else if kind = "exception" then txt1 ^ " of " ^ txt2
    74         else if Syntax.is_identifier (Long_Name.base_name (ml_name txt1)) then txt1 ^ ": " ^ txt2
    75         else txt1 ^ " : " ^ txt2;
    76       val txt' = if kind = "" then txt else kind ^ " " ^ txt;
    77       val _ = ML_Context.eval_text_in (SOME ctxt) false Position.none (ml (txt1, txt2));  (* ML_Lex.read (!?) *)
    78       val kind' = if kind = "" then "ML" else "ML " ^ kind;
    79     in
    80       "\\indexdef{}{" ^ kind' ^ "}{" ^ clean_string (ml_name txt1) ^ "}" ^
    81       (txt'
    82       |> (if Config.get ctxt Thy_Output.quotes then quote else I)
    83       |> (if Config.get ctxt Thy_Output.display then enclose "\\begin{verbatim}\n" "\n\\end{verbatim}"
    84           else split_lines #> map verbatim #> space_implode "\\isasep\\isanewline%\n"))
    85     end);
    86 
    87 in
    88 
    89 val _ = index_ml "index_ML" "" ml_val;
    90 val _ = index_ml "index_ML_type" "type" ml_type;
    91 val _ = index_ml "index_ML_exn" "exception" ml_exn;
    92 val _ = index_ml "index_ML_structure" "structure" ml_structure;
    93 val _ = index_ml "index_ML_functor" "functor" ml_functor;
    94 
    95 end;
    96 
    97 
    98 (* named theorems *)
    99 
   100 val _ = Thy_Output.antiquotation "named_thms"
   101   (Scan.repeat (Attrib.thm -- Scan.lift (Args.parens Args.name)))
   102   (fn {context = ctxt, ...} =>
   103     map (apfst (Thy_Output.pretty_thm ctxt))
   104     #> (if Config.get ctxt Thy_Output.quotes then map (apfst Pretty.quote) else I)
   105     #> (if Config.get ctxt Thy_Output.display
   106         then
   107           map (fn (p, name) =>
   108             Output.output (Pretty.string_of (Pretty.indent (Config.get ctxt Thy_Output.indent) p)) ^
   109             "\\rulename{" ^ Output.output (Pretty.str_of (Thy_Output.pretty_text ctxt name)) ^ "}")
   110           #> space_implode "\\par\\smallskip%\n"
   111           #> enclose "\\begin{isabelle}%\n" "%\n\\end{isabelle}"
   112         else
   113           map (fn (p, name) =>
   114             Output.output (Pretty.str_of p) ^
   115             "\\rulename{" ^ Output.output (Pretty.str_of (Thy_Output.pretty_text ctxt name)) ^ "}")
   116           #> space_implode "\\par\\smallskip%\n"
   117           #> enclose "\\isa{" "}"));
   118 
   119 
   120 (* theory file *)
   121 
   122 val _ = Thy_Output.antiquotation "thy_file" (Scan.lift Args.name)
   123   (fn {context = ctxt, ...} =>
   124     fn name => (Thy_Load.check_thy Path.current name; Thy_Output.output ctxt [Pretty.str name]));
   125 
   126 
   127 (* Isabelle/Isar entities (with index) *)
   128 
   129 local
   130 
   131 fun no_check _ _ = true;
   132 
   133 fun thy_check intern defined ctxt =
   134   let val thy = ProofContext.theory_of ctxt
   135   in defined thy o intern thy end;
   136 
   137 fun check_tool name =
   138   File.exists (Path.append (Path.explode "~~/lib/Tools") (Path.basic name));
   139 
   140 val arg = enclose "{" "}" o clean_string;
   141 
   142 fun entity check markup kind index =
   143   Thy_Output.antiquotation
   144     (translate (fn " " => "_" | c => c) kind ^
   145       (case index of NONE => "" | SOME true => "_def" | SOME false => "_ref"))
   146     (Scan.lift (Scan.optional (Args.parens Args.name) "" -- Args.name))
   147     (fn {context = ctxt, ...} => fn (logic, name) =>
   148       let
   149         val hyper_name =
   150           "{" ^ Long_Name.append kind (Long_Name.append logic (clean_name name)) ^ "}";
   151         val hyper =
   152           enclose ("\\hyperlink" ^ hyper_name ^ "{") "}" #>
   153           index = SOME true ? enclose ("\\hypertarget" ^ hyper_name ^ "{") "}";
   154         val idx =
   155           (case index of
   156             NONE => ""
   157           | SOME is_def =>
   158               "\\index" ^ (if is_def then "def" else "ref") ^ arg logic ^ arg kind ^ arg name);
   159       in
   160         if check ctxt name then
   161           idx ^
   162           (Output.output name
   163             |> (if markup = "" then I else enclose ("\\" ^ markup ^ "{") "}")
   164             |> (if Config.get ctxt Thy_Output.quotes then quote else I)
   165             |> (if Config.get ctxt Thy_Output.display
   166                 then enclose "\\begin{isabelle}%\n" "%\n\\end{isabelle}"
   167                 else hyper o enclose "\\mbox{\\isa{" "}}"))
   168         else error ("Bad " ^ kind ^ " " ^ quote name)
   169       end);
   170 
   171 fun entity_antiqs check markup kind =
   172  ((entity check markup kind NONE);
   173   (entity check markup kind (SOME true));
   174   (entity check markup kind (SOME false)));
   175 
   176 in
   177 
   178 val _ = entity_antiqs no_check "" "syntax";
   179 val _ = entity_antiqs (K (is_some o Keyword.command_keyword)) "isacommand" "command";
   180 val _ = entity_antiqs (K Keyword.is_keyword) "isakeyword" "keyword";
   181 val _ = entity_antiqs (K Keyword.is_keyword) "isakeyword" "element";
   182 val _ = entity_antiqs (thy_check Method.intern Method.defined) "" "method";
   183 val _ = entity_antiqs (thy_check Attrib.intern Attrib.defined) "" "attribute";
   184 val _ = entity_antiqs no_check "" "fact";
   185 val _ = entity_antiqs no_check "" "variable";
   186 val _ = entity_antiqs no_check "" "case";
   187 val _ = entity_antiqs (K Thy_Output.defined_command) "" "antiquotation";
   188 val _ = entity_antiqs (K Thy_Output.defined_option) "" "antiquotation option";
   189 val _ = entity_antiqs (fn _ => fn name => is_some (OS.Process.getEnv name)) "isatt" "setting";
   190 val _ = entity_antiqs no_check "" "inference";
   191 val _ = entity_antiqs no_check "isatt" "executable";
   192 val _ = entity_antiqs (K check_tool) "isatt" "tool";
   193 val _ = entity_antiqs (K (File.exists o Path.explode)) "isatt" "file";
   194 val _ = entity_antiqs (K (can Thy_Info.get_theory)) "" "theory";
   195 val _ = entity_antiqs no_check "" "ML antiquotation";  (* FIXME proper check *)
   196 
   197 end;
   198 
   199 end;