src/HOL/Complex.thy
 author wenzelm Mon Aug 31 21:28:08 2015 +0200 (2015-08-31) changeset 61070 b72a990adfe2 parent 60758 d8d85a8172b5 child 61076 bdc1e2f0a86a permissions -rw-r--r--
prefer symbols;
     1 (*  Title:       HOL/Complex.thy

     2     Author:      Jacques D. Fleuriot

     3     Copyright:   2001 University of Edinburgh

     4     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4

     5 *)

     6

     7 section \<open>Complex Numbers: Rectangular and Polar Representations\<close>

     8

     9 theory Complex

    10 imports Transcendental

    11 begin

    12

    13 text \<open>

    14 We use the @{text codatatype} command to define the type of complex numbers. This allows us to use

    15 @{text primcorec} to define complex functions by defining their real and imaginary result

    16 separately.

    17 \<close>

    18

    19 codatatype complex = Complex (Re: real) (Im: real)

    20

    21 lemma complex_surj: "Complex (Re z) (Im z) = z"

    22   by (rule complex.collapse)

    23

    24 lemma complex_eqI [intro?]: "\<lbrakk>Re x = Re y; Im x = Im y\<rbrakk> \<Longrightarrow> x = y"

    25   by (rule complex.expand) simp

    26

    27 lemma complex_eq_iff: "x = y \<longleftrightarrow> Re x = Re y \<and> Im x = Im y"

    28   by (auto intro: complex.expand)

    29

    30 subsection \<open>Addition and Subtraction\<close>

    31

    32 instantiation complex :: ab_group_add

    33 begin

    34

    35 primcorec zero_complex where

    36   "Re 0 = 0"

    37 | "Im 0 = 0"

    38

    39 primcorec plus_complex where

    40   "Re (x + y) = Re x + Re y"

    41 | "Im (x + y) = Im x + Im y"

    42

    43 primcorec uminus_complex where

    44   "Re (- x) = - Re x"

    45 | "Im (- x) = - Im x"

    46

    47 primcorec minus_complex where

    48   "Re (x - y) = Re x - Re y"

    49 | "Im (x - y) = Im x - Im y"

    50

    51 instance

    52   by intro_classes (simp_all add: complex_eq_iff)

    53

    54 end

    55

    56 subsection \<open>Multiplication and Division\<close>

    57

    58 instantiation complex :: field

    59 begin

    60

    61 primcorec one_complex where

    62   "Re 1 = 1"

    63 | "Im 1 = 0"

    64

    65 primcorec times_complex where

    66   "Re (x * y) = Re x * Re y - Im x * Im y"

    67 | "Im (x * y) = Re x * Im y + Im x * Re y"

    68

    69 primcorec inverse_complex where

    70   "Re (inverse x) = Re x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)"

    71 | "Im (inverse x) = - Im x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)"

    72

    73 definition "x div (y\<Colon>complex) = x * inverse y"

    74

    75 instance

    76   by intro_classes

    77      (simp_all add: complex_eq_iff divide_complex_def

    78       distrib_left distrib_right right_diff_distrib left_diff_distrib

    79       power2_eq_square add_divide_distrib [symmetric])

    80

    81 end

    82

    83 lemma Re_divide: "Re (x / y) = (Re x * Re y + Im x * Im y) / ((Re y)\<^sup>2 + (Im y)\<^sup>2)"

    84   unfolding divide_complex_def by (simp add: add_divide_distrib)

    85

    86 lemma Im_divide: "Im (x / y) = (Im x * Re y - Re x * Im y) / ((Re y)\<^sup>2 + (Im y)\<^sup>2)"

    87   unfolding divide_complex_def times_complex.sel inverse_complex.sel

    88   by (simp_all add: divide_simps)

    89

    90 lemma Re_power2: "Re (x ^ 2) = (Re x)^2 - (Im x)^2"

    91   by (simp add: power2_eq_square)

    92

    93 lemma Im_power2: "Im (x ^ 2) = 2 * Re x * Im x"

    94   by (simp add: power2_eq_square)

    95

    96 lemma Re_power_real [simp]: "Im x = 0 \<Longrightarrow> Re (x ^ n) = Re x ^ n "

    97   by (induct n) simp_all

    98

    99 lemma Im_power_real [simp]: "Im x = 0 \<Longrightarrow> Im (x ^ n) = 0"

   100   by (induct n) simp_all

   101

   102 subsection \<open>Scalar Multiplication\<close>

   103

   104 instantiation complex :: real_field

   105 begin

   106

   107 primcorec scaleR_complex where

   108   "Re (scaleR r x) = r * Re x"

   109 | "Im (scaleR r x) = r * Im x"

   110

   111 instance

   112 proof

   113   fix a b :: real and x y :: complex

   114   show "scaleR a (x + y) = scaleR a x + scaleR a y"

   115     by (simp add: complex_eq_iff distrib_left)

   116   show "scaleR (a + b) x = scaleR a x + scaleR b x"

   117     by (simp add: complex_eq_iff distrib_right)

   118   show "scaleR a (scaleR b x) = scaleR (a * b) x"

   119     by (simp add: complex_eq_iff mult.assoc)

   120   show "scaleR 1 x = x"

   121     by (simp add: complex_eq_iff)

   122   show "scaleR a x * y = scaleR a (x * y)"

   123     by (simp add: complex_eq_iff algebra_simps)

   124   show "x * scaleR a y = scaleR a (x * y)"

   125     by (simp add: complex_eq_iff algebra_simps)

   126 qed

   127

   128 end

   129

   130 subsection \<open>Numerals, Arithmetic, and Embedding from Reals\<close>

   131

   132 abbreviation complex_of_real :: "real \<Rightarrow> complex"

   133   where "complex_of_real \<equiv> of_real"

   134

   135 declare [[coercion "of_real :: real \<Rightarrow> complex"]]

   136 declare [[coercion "of_rat :: rat \<Rightarrow> complex"]]

   137 declare [[coercion "of_int :: int \<Rightarrow> complex"]]

   138 declare [[coercion "of_nat :: nat \<Rightarrow> complex"]]

   139

   140 lemma complex_Re_of_nat [simp]: "Re (of_nat n) = of_nat n"

   141   by (induct n) simp_all

   142

   143 lemma complex_Im_of_nat [simp]: "Im (of_nat n) = 0"

   144   by (induct n) simp_all

   145

   146 lemma complex_Re_of_int [simp]: "Re (of_int z) = of_int z"

   147   by (cases z rule: int_diff_cases) simp

   148

   149 lemma complex_Im_of_int [simp]: "Im (of_int z) = 0"

   150   by (cases z rule: int_diff_cases) simp

   151

   152 lemma complex_Re_numeral [simp]: "Re (numeral v) = numeral v"

   153   using complex_Re_of_int [of "numeral v"] by simp

   154

   155 lemma complex_Im_numeral [simp]: "Im (numeral v) = 0"

   156   using complex_Im_of_int [of "numeral v"] by simp

   157

   158 lemma Re_complex_of_real [simp]: "Re (complex_of_real z) = z"

   159   by (simp add: of_real_def)

   160

   161 lemma Im_complex_of_real [simp]: "Im (complex_of_real z) = 0"

   162   by (simp add: of_real_def)

   163

   164 lemma Re_divide_numeral [simp]: "Re (z / numeral w) = Re z / numeral w"

   165   by (simp add: Re_divide sqr_conv_mult)

   166

   167 lemma Im_divide_numeral [simp]: "Im (z / numeral w) = Im z / numeral w"

   168   by (simp add: Im_divide sqr_conv_mult)

   169

   170 lemma of_real_Re [simp]:

   171     "z \<in> \<real> \<Longrightarrow> of_real (Re z) = z"

   172   by (auto simp: Reals_def)

   173

   174 subsection \<open>The Complex Number $i$\<close>

   175

   176 primcorec "ii" :: complex  ("\<i>") where

   177   "Re ii = 0"

   178 | "Im ii = 1"

   179

   180 lemma Complex_eq[simp]: "Complex a b = a + \<i> * b"

   181   by (simp add: complex_eq_iff)

   182

   183 lemma complex_eq: "a = Re a + \<i> * Im a"

   184   by (simp add: complex_eq_iff)

   185

   186 lemma fun_complex_eq: "f = (\<lambda>x. Re (f x) + \<i> * Im (f x))"

   187   by (simp add: fun_eq_iff complex_eq)

   188

   189 lemma i_squared [simp]: "ii * ii = -1"

   190   by (simp add: complex_eq_iff)

   191

   192 lemma power2_i [simp]: "ii\<^sup>2 = -1"

   193   by (simp add: power2_eq_square)

   194

   195 lemma inverse_i [simp]: "inverse ii = - ii"

   196   by (rule inverse_unique) simp

   197

   198 lemma divide_i [simp]: "x / ii = - ii * x"

   199   by (simp add: divide_complex_def)

   200

   201 lemma complex_i_mult_minus [simp]: "ii * (ii * x) = - x"

   202   by (simp add: mult.assoc [symmetric])

   203

   204 lemma complex_i_not_zero [simp]: "ii \<noteq> 0"

   205   by (simp add: complex_eq_iff)

   206

   207 lemma complex_i_not_one [simp]: "ii \<noteq> 1"

   208   by (simp add: complex_eq_iff)

   209

   210 lemma complex_i_not_numeral [simp]: "ii \<noteq> numeral w"

   211   by (simp add: complex_eq_iff)

   212

   213 lemma complex_i_not_neg_numeral [simp]: "ii \<noteq> - numeral w"

   214   by (simp add: complex_eq_iff)

   215

   216 lemma complex_split_polar: "\<exists>r a. z = complex_of_real r * (cos a + \<i> * sin a)"

   217   by (simp add: complex_eq_iff polar_Ex)

   218

   219 lemma i_even_power [simp]: "\<i> ^ (n * 2) = (-1) ^ n"

   220   by (metis mult.commute power2_i power_mult)

   221

   222 lemma Re_ii_times [simp]: "Re (ii*z) = - Im z"

   223   by simp

   224

   225 lemma Im_ii_times [simp]: "Im (ii*z) = Re z"

   226   by simp

   227

   228 lemma ii_times_eq_iff: "ii*w = z \<longleftrightarrow> w = -(ii*z)"

   229   by auto

   230

   231 lemma divide_numeral_i [simp]: "z / (numeral n * ii) = -(ii*z) / numeral n"

   232   by (metis divide_divide_eq_left divide_i mult.commute mult_minus_right)

   233

   234 subsection \<open>Vector Norm\<close>

   235

   236 instantiation complex :: real_normed_field

   237 begin

   238

   239 definition "norm z = sqrt ((Re z)\<^sup>2 + (Im z)\<^sup>2)"

   240

   241 abbreviation cmod :: "complex \<Rightarrow> real"

   242   where "cmod \<equiv> norm"

   243

   244 definition complex_sgn_def:

   245   "sgn x = x /\<^sub>R cmod x"

   246

   247 definition dist_complex_def:

   248   "dist x y = cmod (x - y)"

   249

   250 definition open_complex_def:

   251   "open (S :: complex set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"

   252

   253 instance proof

   254   fix r :: real and x y :: complex and S :: "complex set"

   255   show "(norm x = 0) = (x = 0)"

   256     by (simp add: norm_complex_def complex_eq_iff)

   257   show "norm (x + y) \<le> norm x + norm y"

   258     by (simp add: norm_complex_def complex_eq_iff real_sqrt_sum_squares_triangle_ineq)

   259   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"

   260     by (simp add: norm_complex_def complex_eq_iff power_mult_distrib distrib_left [symmetric] real_sqrt_mult)

   261   show "norm (x * y) = norm x * norm y"

   262     by (simp add: norm_complex_def complex_eq_iff real_sqrt_mult [symmetric] power2_eq_square algebra_simps)

   263 qed (rule complex_sgn_def dist_complex_def open_complex_def)+

   264

   265 end

   266

   267 lemma norm_ii [simp]: "norm ii = 1"

   268   by (simp add: norm_complex_def)

   269

   270 lemma cmod_unit_one: "cmod (cos a + \<i> * sin a) = 1"

   271   by (simp add: norm_complex_def)

   272

   273 lemma cmod_complex_polar: "cmod (r * (cos a + \<i> * sin a)) = \<bar>r\<bar>"

   274   by (simp add: norm_mult cmod_unit_one)

   275

   276 lemma complex_Re_le_cmod: "Re x \<le> cmod x"

   277   unfolding norm_complex_def

   278   by (rule real_sqrt_sum_squares_ge1)

   279

   280 lemma complex_mod_minus_le_complex_mod: "- cmod x \<le> cmod x"

   281   by (rule order_trans [OF _ norm_ge_zero]) simp

   282

   283 lemma complex_mod_triangle_ineq2: "cmod (b + a) - cmod b \<le> cmod a"

   284   by (rule ord_le_eq_trans [OF norm_triangle_ineq2]) simp

   285

   286 lemma abs_Re_le_cmod: "\<bar>Re x\<bar> \<le> cmod x"

   287   by (simp add: norm_complex_def)

   288

   289 lemma abs_Im_le_cmod: "\<bar>Im x\<bar> \<le> cmod x"

   290   by (simp add: norm_complex_def)

   291

   292 lemma cmod_le: "cmod z \<le> \<bar>Re z\<bar> + \<bar>Im z\<bar>"

   293   apply (subst complex_eq)

   294   apply (rule order_trans)

   295   apply (rule norm_triangle_ineq)

   296   apply (simp add: norm_mult)

   297   done

   298

   299 lemma cmod_eq_Re: "Im z = 0 \<Longrightarrow> cmod z = \<bar>Re z\<bar>"

   300   by (simp add: norm_complex_def)

   301

   302 lemma cmod_eq_Im: "Re z = 0 \<Longrightarrow> cmod z = \<bar>Im z\<bar>"

   303   by (simp add: norm_complex_def)

   304

   305 lemma cmod_power2: "cmod z ^ 2 = (Re z)^2 + (Im z)^2"

   306   by (simp add: norm_complex_def)

   307

   308 lemma cmod_plus_Re_le_0_iff: "cmod z + Re z \<le> 0 \<longleftrightarrow> Re z = - cmod z"

   309   using abs_Re_le_cmod[of z] by auto

   310

   311 lemma Im_eq_0: "\<bar>Re z\<bar> = cmod z \<Longrightarrow> Im z = 0"

   312   by (subst (asm) power_eq_iff_eq_base[symmetric, where n=2])

   313      (auto simp add: norm_complex_def)

   314

   315 lemma abs_sqrt_wlog:

   316   fixes x::"'a::linordered_idom"

   317   assumes "\<And>x::'a. x \<ge> 0 \<Longrightarrow> P x (x\<^sup>2)" shows "P \<bar>x\<bar> (x\<^sup>2)"

   318 by (metis abs_ge_zero assms power2_abs)

   319

   320 lemma complex_abs_le_norm: "\<bar>Re z\<bar> + \<bar>Im z\<bar> \<le> sqrt 2 * norm z"

   321   unfolding norm_complex_def

   322   apply (rule abs_sqrt_wlog [where x="Re z"])

   323   apply (rule abs_sqrt_wlog [where x="Im z"])

   324   apply (rule power2_le_imp_le)

   325   apply (simp_all add: power2_sum add.commute sum_squares_bound real_sqrt_mult [symmetric])

   326   done

   327

   328 lemma complex_unit_circle: "z \<noteq> 0 \<Longrightarrow> (Re z / cmod z)\<^sup>2 + (Im z / cmod z)\<^sup>2 = 1"

   329   by (simp add: norm_complex_def divide_simps complex_eq_iff)

   330

   331

   332 text \<open>Properties of complex signum.\<close>

   333

   334 lemma sgn_eq: "sgn z = z / complex_of_real (cmod z)"

   335   by (simp add: sgn_div_norm divide_inverse scaleR_conv_of_real mult.commute)

   336

   337 lemma Re_sgn [simp]: "Re(sgn z) = Re(z)/cmod z"

   338   by (simp add: complex_sgn_def divide_inverse)

   339

   340 lemma Im_sgn [simp]: "Im(sgn z) = Im(z)/cmod z"

   341   by (simp add: complex_sgn_def divide_inverse)

   342

   343

   344 subsection \<open>Completeness of the Complexes\<close>

   345

   346 lemma bounded_linear_Re: "bounded_linear Re"

   347   by (rule bounded_linear_intro [where K=1], simp_all add: norm_complex_def)

   348

   349 lemma bounded_linear_Im: "bounded_linear Im"

   350   by (rule bounded_linear_intro [where K=1], simp_all add: norm_complex_def)

   351

   352 lemmas Cauchy_Re = bounded_linear.Cauchy [OF bounded_linear_Re]

   353 lemmas Cauchy_Im = bounded_linear.Cauchy [OF bounded_linear_Im]

   354 lemmas tendsto_Re [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_Re]

   355 lemmas tendsto_Im [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_Im]

   356 lemmas isCont_Re [simp] = bounded_linear.isCont [OF bounded_linear_Re]

   357 lemmas isCont_Im [simp] = bounded_linear.isCont [OF bounded_linear_Im]

   358 lemmas continuous_Re [simp] = bounded_linear.continuous [OF bounded_linear_Re]

   359 lemmas continuous_Im [simp] = bounded_linear.continuous [OF bounded_linear_Im]

   360 lemmas continuous_on_Re [continuous_intros] = bounded_linear.continuous_on[OF bounded_linear_Re]

   361 lemmas continuous_on_Im [continuous_intros] = bounded_linear.continuous_on[OF bounded_linear_Im]

   362 lemmas has_derivative_Re [derivative_intros] = bounded_linear.has_derivative[OF bounded_linear_Re]

   363 lemmas has_derivative_Im [derivative_intros] = bounded_linear.has_derivative[OF bounded_linear_Im]

   364 lemmas sums_Re = bounded_linear.sums [OF bounded_linear_Re]

   365 lemmas sums_Im = bounded_linear.sums [OF bounded_linear_Im]

   366

   367 lemma tendsto_Complex [tendsto_intros]:

   368   "(f ---> a) F \<Longrightarrow> (g ---> b) F \<Longrightarrow> ((\<lambda>x. Complex (f x) (g x)) ---> Complex a b) F"

   369   by (auto intro!: tendsto_intros)

   370

   371 lemma tendsto_complex_iff:

   372   "(f ---> x) F \<longleftrightarrow> (((\<lambda>x. Re (f x)) ---> Re x) F \<and> ((\<lambda>x. Im (f x)) ---> Im x) F)"

   373 proof safe

   374   assume "((\<lambda>x. Re (f x)) ---> Re x) F" "((\<lambda>x. Im (f x)) ---> Im x) F"

   375   from tendsto_Complex[OF this] show "(f ---> x) F"

   376     unfolding complex.collapse .

   377 qed (auto intro: tendsto_intros)

   378

   379 lemma continuous_complex_iff: "continuous F f \<longleftrightarrow>

   380     continuous F (\<lambda>x. Re (f x)) \<and> continuous F (\<lambda>x. Im (f x))"

   381   unfolding continuous_def tendsto_complex_iff ..

   382

   383 lemma has_vector_derivative_complex_iff: "(f has_vector_derivative x) F \<longleftrightarrow>

   384     ((\<lambda>x. Re (f x)) has_field_derivative (Re x)) F \<and>

   385     ((\<lambda>x. Im (f x)) has_field_derivative (Im x)) F"

   386   unfolding has_vector_derivative_def has_field_derivative_def has_derivative_def tendsto_complex_iff

   387   by (simp add: field_simps bounded_linear_scaleR_left bounded_linear_mult_right)

   388

   389 lemma has_field_derivative_Re[derivative_intros]:

   390   "(f has_vector_derivative D) F \<Longrightarrow> ((\<lambda>x. Re (f x)) has_field_derivative (Re D)) F"

   391   unfolding has_vector_derivative_complex_iff by safe

   392

   393 lemma has_field_derivative_Im[derivative_intros]:

   394   "(f has_vector_derivative D) F \<Longrightarrow> ((\<lambda>x. Im (f x)) has_field_derivative (Im D)) F"

   395   unfolding has_vector_derivative_complex_iff by safe

   396

   397 instance complex :: banach

   398 proof

   399   fix X :: "nat \<Rightarrow> complex"

   400   assume X: "Cauchy X"

   401   then have "(\<lambda>n. Complex (Re (X n)) (Im (X n))) ----> Complex (lim (\<lambda>n. Re (X n))) (lim (\<lambda>n. Im (X n)))"

   402     by (intro tendsto_Complex convergent_LIMSEQ_iff[THEN iffD1] Cauchy_convergent_iff[THEN iffD1] Cauchy_Re Cauchy_Im)

   403   then show "convergent X"

   404     unfolding complex.collapse by (rule convergentI)

   405 qed

   406

   407 declare

   408   DERIV_power[where 'a=complex, unfolded of_nat_def[symmetric], derivative_intros]

   409

   410 subsection \<open>Complex Conjugation\<close>

   411

   412 primcorec cnj :: "complex \<Rightarrow> complex" where

   413   "Re (cnj z) = Re z"

   414 | "Im (cnj z) = - Im z"

   415

   416 lemma complex_cnj_cancel_iff [simp]: "(cnj x = cnj y) = (x = y)"

   417   by (simp add: complex_eq_iff)

   418

   419 lemma complex_cnj_cnj [simp]: "cnj (cnj z) = z"

   420   by (simp add: complex_eq_iff)

   421

   422 lemma complex_cnj_zero [simp]: "cnj 0 = 0"

   423   by (simp add: complex_eq_iff)

   424

   425 lemma complex_cnj_zero_iff [iff]: "(cnj z = 0) = (z = 0)"

   426   by (simp add: complex_eq_iff)

   427

   428 lemma complex_cnj_add [simp]: "cnj (x + y) = cnj x + cnj y"

   429   by (simp add: complex_eq_iff)

   430

   431 lemma cnj_setsum [simp]: "cnj (setsum f s) = (\<Sum>x\<in>s. cnj (f x))"

   432   by (induct s rule: infinite_finite_induct) auto

   433

   434 lemma complex_cnj_diff [simp]: "cnj (x - y) = cnj x - cnj y"

   435   by (simp add: complex_eq_iff)

   436

   437 lemma complex_cnj_minus [simp]: "cnj (- x) = - cnj x"

   438   by (simp add: complex_eq_iff)

   439

   440 lemma complex_cnj_one [simp]: "cnj 1 = 1"

   441   by (simp add: complex_eq_iff)

   442

   443 lemma complex_cnj_mult [simp]: "cnj (x * y) = cnj x * cnj y"

   444   by (simp add: complex_eq_iff)

   445

   446 lemma cnj_setprod [simp]: "cnj (setprod f s) = (\<Prod>x\<in>s. cnj (f x))"

   447   by (induct s rule: infinite_finite_induct) auto

   448

   449 lemma complex_cnj_inverse [simp]: "cnj (inverse x) = inverse (cnj x)"

   450   by (simp add: complex_eq_iff)

   451

   452 lemma complex_cnj_divide [simp]: "cnj (x / y) = cnj x / cnj y"

   453   by (simp add: divide_complex_def)

   454

   455 lemma complex_cnj_power [simp]: "cnj (x ^ n) = cnj x ^ n"

   456   by (induct n) simp_all

   457

   458 lemma complex_cnj_of_nat [simp]: "cnj (of_nat n) = of_nat n"

   459   by (simp add: complex_eq_iff)

   460

   461 lemma complex_cnj_of_int [simp]: "cnj (of_int z) = of_int z"

   462   by (simp add: complex_eq_iff)

   463

   464 lemma complex_cnj_numeral [simp]: "cnj (numeral w) = numeral w"

   465   by (simp add: complex_eq_iff)

   466

   467 lemma complex_cnj_neg_numeral [simp]: "cnj (- numeral w) = - numeral w"

   468   by (simp add: complex_eq_iff)

   469

   470 lemma complex_cnj_scaleR [simp]: "cnj (scaleR r x) = scaleR r (cnj x)"

   471   by (simp add: complex_eq_iff)

   472

   473 lemma complex_mod_cnj [simp]: "cmod (cnj z) = cmod z"

   474   by (simp add: norm_complex_def)

   475

   476 lemma complex_cnj_complex_of_real [simp]: "cnj (of_real x) = of_real x"

   477   by (simp add: complex_eq_iff)

   478

   479 lemma complex_cnj_i [simp]: "cnj ii = - ii"

   480   by (simp add: complex_eq_iff)

   481

   482 lemma complex_add_cnj: "z + cnj z = complex_of_real (2 * Re z)"

   483   by (simp add: complex_eq_iff)

   484

   485 lemma complex_diff_cnj: "z - cnj z = complex_of_real (2 * Im z) * ii"

   486   by (simp add: complex_eq_iff)

   487

   488 lemma complex_mult_cnj: "z * cnj z = complex_of_real ((Re z)\<^sup>2 + (Im z)\<^sup>2)"

   489   by (simp add: complex_eq_iff power2_eq_square)

   490

   491 lemma complex_mod_mult_cnj: "cmod (z * cnj z) = (cmod z)\<^sup>2"

   492   by (simp add: norm_mult power2_eq_square)

   493

   494 lemma complex_mod_sqrt_Re_mult_cnj: "cmod z = sqrt (Re (z * cnj z))"

   495   by (simp add: norm_complex_def power2_eq_square)

   496

   497 lemma complex_In_mult_cnj_zero [simp]: "Im (z * cnj z) = 0"

   498   by simp

   499

   500 lemma bounded_linear_cnj: "bounded_linear cnj"

   501   using complex_cnj_add complex_cnj_scaleR

   502   by (rule bounded_linear_intro [where K=1], simp)

   503

   504 lemmas tendsto_cnj [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_cnj]

   505 lemmas isCont_cnj [simp] = bounded_linear.isCont [OF bounded_linear_cnj]

   506 lemmas continuous_cnj [simp, continuous_intros] = bounded_linear.continuous [OF bounded_linear_cnj]

   507 lemmas continuous_on_cnj [simp, continuous_intros] = bounded_linear.continuous_on [OF bounded_linear_cnj]

   508 lemmas has_derivative_cnj [simp, derivative_intros] = bounded_linear.has_derivative [OF bounded_linear_cnj]

   509

   510 lemma lim_cnj: "((\<lambda>x. cnj(f x)) ---> cnj l) F \<longleftrightarrow> (f ---> l) F"

   511   by (simp add: tendsto_iff dist_complex_def complex_cnj_diff [symmetric] del: complex_cnj_diff)

   512

   513 lemma sums_cnj: "((\<lambda>x. cnj(f x)) sums cnj l) \<longleftrightarrow> (f sums l)"

   514   by (simp add: sums_def lim_cnj cnj_setsum [symmetric] del: cnj_setsum)

   515

   516

   517 subsection\<open>Basic Lemmas\<close>

   518

   519 lemma complex_eq_0: "z=0 \<longleftrightarrow> (Re z)\<^sup>2 + (Im z)\<^sup>2 = 0"

   520   by (metis zero_complex.sel complex_eqI sum_power2_eq_zero_iff)

   521

   522 lemma complex_neq_0: "z\<noteq>0 \<longleftrightarrow> (Re z)\<^sup>2 + (Im z)\<^sup>2 > 0"

   523   by (metis complex_eq_0 less_numeral_extra(3) sum_power2_gt_zero_iff)

   524

   525 lemma complex_norm_square: "of_real ((norm z)\<^sup>2) = z * cnj z"

   526 by (cases z)

   527    (auto simp: complex_eq_iff norm_complex_def power2_eq_square[symmetric] of_real_power[symmetric]

   528          simp del: of_real_power)

   529

   530 lemma Re_complex_div_eq_0: "Re (a / b) = 0 \<longleftrightarrow> Re (a * cnj b) = 0"

   531   by (auto simp add: Re_divide)

   532

   533 lemma Im_complex_div_eq_0: "Im (a / b) = 0 \<longleftrightarrow> Im (a * cnj b) = 0"

   534   by (auto simp add: Im_divide)

   535

   536 lemma complex_div_gt_0:

   537   "(Re (a / b) > 0 \<longleftrightarrow> Re (a * cnj b) > 0) \<and> (Im (a / b) > 0 \<longleftrightarrow> Im (a * cnj b) > 0)"

   538 proof cases

   539   assume "b = 0" then show ?thesis by auto

   540 next

   541   assume "b \<noteq> 0"

   542   then have "0 < (Re b)\<^sup>2 + (Im b)\<^sup>2"

   543     by (simp add: complex_eq_iff sum_power2_gt_zero_iff)

   544   then show ?thesis

   545     by (simp add: Re_divide Im_divide zero_less_divide_iff)

   546 qed

   547

   548 lemma Re_complex_div_gt_0: "Re (a / b) > 0 \<longleftrightarrow> Re (a * cnj b) > 0"

   549   and Im_complex_div_gt_0: "Im (a / b) > 0 \<longleftrightarrow> Im (a * cnj b) > 0"

   550   using complex_div_gt_0 by auto

   551

   552 lemma Re_complex_div_ge_0: "Re(a / b) \<ge> 0 \<longleftrightarrow> Re(a * cnj b) \<ge> 0"

   553   by (metis le_less Re_complex_div_eq_0 Re_complex_div_gt_0)

   554

   555 lemma Im_complex_div_ge_0: "Im(a / b) \<ge> 0 \<longleftrightarrow> Im(a * cnj b) \<ge> 0"

   556   by (metis Im_complex_div_eq_0 Im_complex_div_gt_0 le_less)

   557

   558 lemma Re_complex_div_lt_0: "Re(a / b) < 0 \<longleftrightarrow> Re(a * cnj b) < 0"

   559   by (metis less_asym neq_iff Re_complex_div_eq_0 Re_complex_div_gt_0)

   560

   561 lemma Im_complex_div_lt_0: "Im(a / b) < 0 \<longleftrightarrow> Im(a * cnj b) < 0"

   562   by (metis Im_complex_div_eq_0 Im_complex_div_gt_0 less_asym neq_iff)

   563

   564 lemma Re_complex_div_le_0: "Re(a / b) \<le> 0 \<longleftrightarrow> Re(a * cnj b) \<le> 0"

   565   by (metis not_le Re_complex_div_gt_0)

   566

   567 lemma Im_complex_div_le_0: "Im(a / b) \<le> 0 \<longleftrightarrow> Im(a * cnj b) \<le> 0"

   568   by (metis Im_complex_div_gt_0 not_le)

   569

   570 lemma Re_setsum[simp]: "Re (setsum f s) = (\<Sum>x\<in>s. Re (f x))"

   571   by (induct s rule: infinite_finite_induct) auto

   572

   573 lemma Im_setsum[simp]: "Im (setsum f s) = (\<Sum>x\<in>s. Im(f x))"

   574   by (induct s rule: infinite_finite_induct) auto

   575

   576 lemma sums_complex_iff: "f sums x \<longleftrightarrow> ((\<lambda>x. Re (f x)) sums Re x) \<and> ((\<lambda>x. Im (f x)) sums Im x)"

   577   unfolding sums_def tendsto_complex_iff Im_setsum Re_setsum ..

   578

   579 lemma summable_complex_iff: "summable f \<longleftrightarrow> summable (\<lambda>x. Re (f x)) \<and>  summable (\<lambda>x. Im (f x))"

   580   unfolding summable_def sums_complex_iff[abs_def] by (metis complex.sel)

   581

   582 lemma summable_complex_of_real [simp]: "summable (\<lambda>n. complex_of_real (f n)) \<longleftrightarrow> summable f"

   583   unfolding summable_complex_iff by simp

   584

   585 lemma summable_Re: "summable f \<Longrightarrow> summable (\<lambda>x. Re (f x))"

   586   unfolding summable_complex_iff by blast

   587

   588 lemma summable_Im: "summable f \<Longrightarrow> summable (\<lambda>x. Im (f x))"

   589   unfolding summable_complex_iff by blast

   590

   591 lemma complex_is_Real_iff: "z \<in> \<real> \<longleftrightarrow> Im z = 0"

   592   by (auto simp: Reals_def complex_eq_iff)

   593

   594 lemma Reals_cnj_iff: "z \<in> \<real> \<longleftrightarrow> cnj z = z"

   595   by (auto simp: complex_is_Real_iff complex_eq_iff)

   596

   597 lemma in_Reals_norm: "z \<in> \<real> \<Longrightarrow> norm(z) = abs(Re z)"

   598   by (simp add: complex_is_Real_iff norm_complex_def)

   599

   600 lemma series_comparison_complex:

   601   fixes f:: "nat \<Rightarrow> 'a::banach"

   602   assumes sg: "summable g"

   603      and "\<And>n. g n \<in> \<real>" "\<And>n. Re (g n) \<ge> 0"

   604      and fg: "\<And>n. n \<ge> N \<Longrightarrow> norm(f n) \<le> norm(g n)"

   605   shows "summable f"

   606 proof -

   607   have g: "\<And>n. cmod (g n) = Re (g n)" using assms

   608     by (metis abs_of_nonneg in_Reals_norm)

   609   show ?thesis

   610     apply (rule summable_comparison_test' [where g = "\<lambda>n. norm (g n)" and N=N])

   611     using sg

   612     apply (auto simp: summable_def)

   613     apply (rule_tac x="Re s" in exI)

   614     apply (auto simp: g sums_Re)

   615     apply (metis fg g)

   616     done

   617 qed

   618

   619 subsection\<open>Polar Form for Complex Numbers\<close>

   620

   621 lemma complex_unimodular_polar: "(norm z = 1) \<Longrightarrow> \<exists>x. z = Complex (cos x) (sin x)"

   622   using sincos_total_2pi [of "Re z" "Im z"]

   623   by auto (metis cmod_power2 complex_eq power_one)

   624

   625 subsubsection \<open>$\cos \theta + i \sin \theta$\<close>

   626

   627 primcorec cis :: "real \<Rightarrow> complex" where

   628   "Re (cis a) = cos a"

   629 | "Im (cis a) = sin a"

   630

   631 lemma cis_zero [simp]: "cis 0 = 1"

   632   by (simp add: complex_eq_iff)

   633

   634 lemma norm_cis [simp]: "norm (cis a) = 1"

   635   by (simp add: norm_complex_def)

   636

   637 lemma sgn_cis [simp]: "sgn (cis a) = cis a"

   638   by (simp add: sgn_div_norm)

   639

   640 lemma cis_neq_zero [simp]: "cis a \<noteq> 0"

   641   by (metis norm_cis norm_zero zero_neq_one)

   642

   643 lemma cis_mult: "cis a * cis b = cis (a + b)"

   644   by (simp add: complex_eq_iff cos_add sin_add)

   645

   646 lemma DeMoivre: "(cis a) ^ n = cis (real n * a)"

   647   by (induct n, simp_all add: real_of_nat_Suc algebra_simps cis_mult)

   648

   649 lemma cis_inverse [simp]: "inverse(cis a) = cis (-a)"

   650   by (simp add: complex_eq_iff)

   651

   652 lemma cis_divide: "cis a / cis b = cis (a - b)"

   653   by (simp add: divide_complex_def cis_mult)

   654

   655 lemma cos_n_Re_cis_pow_n: "cos (real n * a) = Re(cis a ^ n)"

   656   by (auto simp add: DeMoivre)

   657

   658 lemma sin_n_Im_cis_pow_n: "sin (real n * a) = Im(cis a ^ n)"

   659   by (auto simp add: DeMoivre)

   660

   661 lemma cis_pi: "cis pi = -1"

   662   by (simp add: complex_eq_iff)

   663

   664 subsubsection \<open>$r(\cos \theta + i \sin \theta)$\<close>

   665

   666 definition rcis :: "real \<Rightarrow> real \<Rightarrow> complex" where

   667   "rcis r a = complex_of_real r * cis a"

   668

   669 lemma Re_rcis [simp]: "Re(rcis r a) = r * cos a"

   670   by (simp add: rcis_def)

   671

   672 lemma Im_rcis [simp]: "Im(rcis r a) = r * sin a"

   673   by (simp add: rcis_def)

   674

   675 lemma rcis_Ex: "\<exists>r a. z = rcis r a"

   676   by (simp add: complex_eq_iff polar_Ex)

   677

   678 lemma complex_mod_rcis [simp]: "cmod(rcis r a) = abs r"

   679   by (simp add: rcis_def norm_mult)

   680

   681 lemma cis_rcis_eq: "cis a = rcis 1 a"

   682   by (simp add: rcis_def)

   683

   684 lemma rcis_mult: "rcis r1 a * rcis r2 b = rcis (r1*r2) (a + b)"

   685   by (simp add: rcis_def cis_mult)

   686

   687 lemma rcis_zero_mod [simp]: "rcis 0 a = 0"

   688   by (simp add: rcis_def)

   689

   690 lemma rcis_zero_arg [simp]: "rcis r 0 = complex_of_real r"

   691   by (simp add: rcis_def)

   692

   693 lemma rcis_eq_zero_iff [simp]: "rcis r a = 0 \<longleftrightarrow> r = 0"

   694   by (simp add: rcis_def)

   695

   696 lemma DeMoivre2: "(rcis r a) ^ n = rcis (r ^ n) (real n * a)"

   697   by (simp add: rcis_def power_mult_distrib DeMoivre)

   698

   699 lemma rcis_inverse: "inverse(rcis r a) = rcis (1/r) (-a)"

   700   by (simp add: divide_inverse rcis_def)

   701

   702 lemma rcis_divide: "rcis r1 a / rcis r2 b = rcis (r1/r2) (a - b)"

   703   by (simp add: rcis_def cis_divide [symmetric])

   704

   705 subsubsection \<open>Complex exponential\<close>

   706

   707 abbreviation Exp :: "complex \<Rightarrow> complex"

   708   where "Exp \<equiv> exp"

   709

   710 lemma cis_conv_exp: "cis b = exp (\<i> * b)"

   711 proof -

   712   { fix n :: nat

   713     have "\<i> ^ n = fact n *\<^sub>R (cos_coeff n + \<i> * sin_coeff n)"

   714       by (induct n)

   715          (simp_all add: sin_coeff_Suc cos_coeff_Suc complex_eq_iff Re_divide Im_divide field_simps

   716                         power2_eq_square real_of_nat_Suc add_nonneg_eq_0_iff

   717                         real_of_nat_def[symmetric])

   718     then have "(\<i> * complex_of_real b) ^ n /\<^sub>R fact n =

   719         of_real (cos_coeff n * b^n) + \<i> * of_real (sin_coeff n * b^n)"

   720       by (simp add: field_simps) }

   721   then show ?thesis using sin_converges [of b] cos_converges [of b]

   722     by (auto simp add: cis.ctr exp_def simp del: of_real_mult

   723              intro!: sums_unique sums_add sums_mult sums_of_real)

   724 qed

   725

   726 lemma Exp_eq_polar: "Exp z = exp (Re z) * cis (Im z)"

   727   unfolding cis_conv_exp exp_of_real [symmetric] mult_exp_exp by (cases z) simp

   728

   729 lemma Re_exp: "Re (exp z) = exp (Re z) * cos (Im z)"

   730   unfolding Exp_eq_polar by simp

   731

   732 lemma Im_exp: "Im (exp z) = exp (Re z) * sin (Im z)"

   733   unfolding Exp_eq_polar by simp

   734

   735 lemma norm_cos_sin [simp]: "norm (Complex (cos t) (sin t)) = 1"

   736   by (simp add: norm_complex_def)

   737

   738 lemma norm_exp_eq_Re [simp]: "norm (exp z) = exp (Re z)"

   739   by (simp add: cis.code cmod_complex_polar Exp_eq_polar)

   740

   741 lemma complex_Exp_Ex: "\<exists>a r. z = complex_of_real r * Exp a"

   742   apply (insert rcis_Ex [of z])

   743   apply (auto simp add: Exp_eq_polar rcis_def mult.assoc [symmetric])

   744   apply (rule_tac x = "ii * complex_of_real a" in exI, auto)

   745   done

   746

   747 lemma Exp_two_pi_i [simp]: "Exp((2::complex) * complex_of_real pi * ii) = 1"

   748   by (simp add: Exp_eq_polar complex_eq_iff)

   749

   750 subsubsection \<open>Complex argument\<close>

   751

   752 definition arg :: "complex \<Rightarrow> real" where

   753   "arg z = (if z = 0 then 0 else (SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi))"

   754

   755 lemma arg_zero: "arg 0 = 0"

   756   by (simp add: arg_def)

   757

   758 lemma arg_unique:

   759   assumes "sgn z = cis x" and "-pi < x" and "x \<le> pi"

   760   shows "arg z = x"

   761 proof -

   762   from assms have "z \<noteq> 0" by auto

   763   have "(SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi) = x"

   764   proof

   765     fix a def d \<equiv> "a - x"

   766     assume a: "sgn z = cis a \<and> - pi < a \<and> a \<le> pi"

   767     from a assms have "- (2*pi) < d \<and> d < 2*pi"

   768       unfolding d_def by simp

   769     moreover from a assms have "cos a = cos x" and "sin a = sin x"

   770       by (simp_all add: complex_eq_iff)

   771     hence cos: "cos d = 1" unfolding d_def cos_diff by simp

   772     moreover from cos have "sin d = 0" by (rule cos_one_sin_zero)

   773     ultimately have "d = 0"

   774       unfolding sin_zero_iff

   775       by (auto elim!: evenE dest!: less_2_cases)

   776     thus "a = x" unfolding d_def by simp

   777   qed (simp add: assms del: Re_sgn Im_sgn)

   778   with \<open>z \<noteq> 0\<close> show "arg z = x"

   779     unfolding arg_def by simp

   780 qed

   781

   782 lemma arg_correct:

   783   assumes "z \<noteq> 0" shows "sgn z = cis (arg z) \<and> -pi < arg z \<and> arg z \<le> pi"

   784 proof (simp add: arg_def assms, rule someI_ex)

   785   obtain r a where z: "z = rcis r a" using rcis_Ex by fast

   786   with assms have "r \<noteq> 0" by auto

   787   def b \<equiv> "if 0 < r then a else a + pi"

   788   have b: "sgn z = cis b"

   789     unfolding z b_def rcis_def using \<open>r \<noteq> 0\<close>

   790     by (simp add: of_real_def sgn_scaleR sgn_if complex_eq_iff)

   791   have cis_2pi_nat: "\<And>n. cis (2 * pi * real_of_nat n) = 1"

   792     by (induct_tac n) (simp_all add: distrib_left cis_mult [symmetric] complex_eq_iff)

   793   have cis_2pi_int: "\<And>x. cis (2 * pi * real_of_int x) = 1"

   794     by (case_tac x rule: int_diff_cases)

   795        (simp add: right_diff_distrib cis_divide [symmetric] cis_2pi_nat)

   796   def c \<equiv> "b - 2*pi * of_int \<lceil>(b - pi) / (2*pi)\<rceil>"

   797   have "sgn z = cis c"

   798     unfolding b c_def

   799     by (simp add: cis_divide [symmetric] cis_2pi_int)

   800   moreover have "- pi < c \<and> c \<le> pi"

   801     using ceiling_correct [of "(b - pi) / (2*pi)"]

   802     by (simp add: c_def less_divide_eq divide_le_eq algebra_simps)

   803   ultimately show "\<exists>a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi" by fast

   804 qed

   805

   806 lemma arg_bounded: "- pi < arg z \<and> arg z \<le> pi"

   807   by (cases "z = 0") (simp_all add: arg_zero arg_correct)

   808

   809 lemma cis_arg: "z \<noteq> 0 \<Longrightarrow> cis (arg z) = sgn z"

   810   by (simp add: arg_correct)

   811

   812 lemma rcis_cmod_arg: "rcis (cmod z) (arg z) = z"

   813   by (cases "z = 0") (simp_all add: rcis_def cis_arg sgn_div_norm of_real_def)

   814

   815 lemma cos_arg_i_mult_zero [simp]: "y \<noteq> 0 \<Longrightarrow> Re y = 0 \<Longrightarrow> cos (arg y) = 0"

   816   using cis_arg [of y] by (simp add: complex_eq_iff)

   817

   818 subsection \<open>Square root of complex numbers\<close>

   819

   820 primcorec csqrt :: "complex \<Rightarrow> complex" where

   821   "Re (csqrt z) = sqrt ((cmod z + Re z) / 2)"

   822 | "Im (csqrt z) = (if Im z = 0 then 1 else sgn (Im z)) * sqrt ((cmod z - Re z) / 2)"

   823

   824 lemma csqrt_of_real_nonneg [simp]: "Im x = 0 \<Longrightarrow> Re x \<ge> 0 \<Longrightarrow> csqrt x = sqrt (Re x)"

   825   by (simp add: complex_eq_iff norm_complex_def)

   826

   827 lemma csqrt_of_real_nonpos [simp]: "Im x = 0 \<Longrightarrow> Re x \<le> 0 \<Longrightarrow> csqrt x = \<i> * sqrt \<bar>Re x\<bar>"

   828   by (simp add: complex_eq_iff norm_complex_def)

   829

   830 lemma of_real_sqrt: "x \<ge> 0 \<Longrightarrow> of_real (sqrt x) = csqrt (of_real x)"

   831   by (simp add: complex_eq_iff norm_complex_def)

   832

   833 lemma csqrt_0 [simp]: "csqrt 0 = 0"

   834   by simp

   835

   836 lemma csqrt_1 [simp]: "csqrt 1 = 1"

   837   by simp

   838

   839 lemma csqrt_ii [simp]: "csqrt \<i> = (1 + \<i>) / sqrt 2"

   840   by (simp add: complex_eq_iff Re_divide Im_divide real_sqrt_divide real_div_sqrt)

   841

   842 lemma power2_csqrt[simp,algebra]: "(csqrt z)\<^sup>2 = z"

   843 proof cases

   844   assume "Im z = 0" then show ?thesis

   845     using real_sqrt_pow2[of "Re z"] real_sqrt_pow2[of "- Re z"]

   846     by (cases "0::real" "Re z" rule: linorder_cases)

   847        (simp_all add: complex_eq_iff Re_power2 Im_power2 power2_eq_square cmod_eq_Re)

   848 next

   849   assume "Im z \<noteq> 0"

   850   moreover

   851   have "cmod z * cmod z - Re z * Re z = Im z * Im z"

   852     by (simp add: norm_complex_def power2_eq_square)

   853   moreover

   854   have "\<bar>Re z\<bar> \<le> cmod z"

   855     by (simp add: norm_complex_def)

   856   ultimately show ?thesis

   857     by (simp add: Re_power2 Im_power2 complex_eq_iff real_sgn_eq

   858                   field_simps real_sqrt_mult[symmetric] real_sqrt_divide)

   859 qed

   860

   861 lemma csqrt_eq_0 [simp]: "csqrt z = 0 \<longleftrightarrow> z = 0"

   862   by auto (metis power2_csqrt power_eq_0_iff)

   863

   864 lemma csqrt_eq_1 [simp]: "csqrt z = 1 \<longleftrightarrow> z = 1"

   865   by auto (metis power2_csqrt power2_eq_1_iff)

   866

   867 lemma csqrt_principal: "0 < Re (csqrt z) \<or> Re (csqrt z) = 0 \<and> 0 \<le> Im (csqrt z)"

   868   by (auto simp add: not_less cmod_plus_Re_le_0_iff Im_eq_0)

   869

   870 lemma Re_csqrt: "0 \<le> Re (csqrt z)"

   871   by (metis csqrt_principal le_less)

   872

   873 lemma csqrt_square:

   874   assumes "0 < Re b \<or> (Re b = 0 \<and> 0 \<le> Im b)"

   875   shows "csqrt (b^2) = b"

   876 proof -

   877   have "csqrt (b^2) = b \<or> csqrt (b^2) = - b"

   878     unfolding power2_eq_iff[symmetric] by (simp add: power2_csqrt)

   879   moreover have "csqrt (b^2) \<noteq> -b \<or> b = 0"

   880     using csqrt_principal[of "b ^ 2"] assms by (intro disjCI notI) (auto simp: complex_eq_iff)

   881   ultimately show ?thesis

   882     by auto

   883 qed

   884

   885 lemma csqrt_unique:

   886     "w^2 = z \<Longrightarrow> (0 < Re w \<or> Re w = 0 \<and> 0 \<le> Im w) \<Longrightarrow> csqrt z = w"

   887   by (auto simp: csqrt_square)

   888

   889 lemma csqrt_minus [simp]:

   890   assumes "Im x < 0 \<or> (Im x = 0 \<and> 0 \<le> Re x)"

   891   shows "csqrt (- x) = \<i> * csqrt x"

   892 proof -

   893   have "csqrt ((\<i> * csqrt x)^2) = \<i> * csqrt x"

   894   proof (rule csqrt_square)

   895     have "Im (csqrt x) \<le> 0"

   896       using assms by (auto simp add: cmod_eq_Re mult_le_0_iff field_simps complex_Re_le_cmod)

   897     then show "0 < Re (\<i> * csqrt x) \<or> Re (\<i> * csqrt x) = 0 \<and> 0 \<le> Im (\<i> * csqrt x)"

   898       by (auto simp add: Re_csqrt simp del: csqrt.simps)

   899   qed

   900   also have "(\<i> * csqrt x)^2 = - x"

   901     by (simp add: power_mult_distrib)

   902   finally show ?thesis .

   903 qed

   904

   905 text \<open>Legacy theorem names\<close>

   906

   907 lemmas expand_complex_eq = complex_eq_iff

   908 lemmas complex_Re_Im_cancel_iff = complex_eq_iff

   909 lemmas complex_equality = complex_eqI

   910 lemmas cmod_def = norm_complex_def

   911 lemmas complex_norm_def = norm_complex_def

   912 lemmas complex_divide_def = divide_complex_def

   913

   914 lemma legacy_Complex_simps:

   915   shows Complex_eq_0: "Complex a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"

   916     and complex_add: "Complex a b + Complex c d = Complex (a + c) (b + d)"

   917     and complex_minus: "- (Complex a b) = Complex (- a) (- b)"

   918     and complex_diff: "Complex a b - Complex c d = Complex (a - c) (b - d)"

   919     and Complex_eq_1: "Complex a b = 1 \<longleftrightarrow> a = 1 \<and> b = 0"

   920     and Complex_eq_neg_1: "Complex a b = - 1 \<longleftrightarrow> a = - 1 \<and> b = 0"

   921     and complex_mult: "Complex a b * Complex c d = Complex (a * c - b * d) (a * d + b * c)"

   922     and complex_inverse: "inverse (Complex a b) = Complex (a / (a\<^sup>2 + b\<^sup>2)) (- b / (a\<^sup>2 + b\<^sup>2))"

   923     and Complex_eq_numeral: "Complex a b = numeral w \<longleftrightarrow> a = numeral w \<and> b = 0"

   924     and Complex_eq_neg_numeral: "Complex a b = - numeral w \<longleftrightarrow> a = - numeral w \<and> b = 0"

   925     and complex_scaleR: "scaleR r (Complex a b) = Complex (r * a) (r * b)"

   926     and Complex_eq_i: "(Complex x y = ii) = (x = 0 \<and> y = 1)"

   927     and i_mult_Complex: "ii * Complex a b = Complex (- b) a"

   928     and Complex_mult_i: "Complex a b * ii = Complex (- b) a"

   929     and i_complex_of_real: "ii * complex_of_real r = Complex 0 r"

   930     and complex_of_real_i: "complex_of_real r * ii = Complex 0 r"

   931     and Complex_add_complex_of_real: "Complex x y + complex_of_real r = Complex (x+r) y"

   932     and complex_of_real_add_Complex: "complex_of_real r + Complex x y = Complex (r+x) y"

   933     and Complex_mult_complex_of_real: "Complex x y * complex_of_real r = Complex (x*r) (y*r)"

   934     and complex_of_real_mult_Complex: "complex_of_real r * Complex x y = Complex (r*x) (r*y)"

   935     and complex_eq_cancel_iff2: "(Complex x y = complex_of_real xa) = (x = xa & y = 0)"

   936     and complex_cn: "cnj (Complex a b) = Complex a (- b)"

   937     and Complex_setsum': "setsum (%x. Complex (f x) 0) s = Complex (setsum f s) 0"

   938     and Complex_setsum: "Complex (setsum f s) 0 = setsum (%x. Complex (f x) 0) s"

   939     and complex_of_real_def: "complex_of_real r = Complex r 0"

   940     and complex_norm: "cmod (Complex x y) = sqrt (x\<^sup>2 + y\<^sup>2)"

   941   by (simp_all add: norm_complex_def field_simps complex_eq_iff Re_divide Im_divide del: Complex_eq)

   942

   943 lemma Complex_in_Reals: "Complex x 0 \<in> \<real>"

   944   by (metis Reals_of_real complex_of_real_def)

   945

   946 end