src/HOL/Limits.thy
author wenzelm
Mon Aug 31 21:28:08 2015 +0200 (2015-08-31)
changeset 61070 b72a990adfe2
parent 60974 6a6f15d8fbc4
child 61076 bdc1e2f0a86a
permissions -rw-r--r--
prefer symbols;
     1 (*  Title:      HOL/Limits.thy
     2     Author:     Brian Huffman
     3     Author:     Jacques D. Fleuriot, University of Cambridge
     4     Author:     Lawrence C Paulson
     5     Author:     Jeremy Avigad
     6 *)
     7 
     8 section \<open>Limits on Real Vector Spaces\<close>
     9 
    10 theory Limits
    11 imports Real_Vector_Spaces
    12 begin
    13 
    14 subsection \<open>Filter going to infinity norm\<close>
    15 
    16 definition at_infinity :: "'a::real_normed_vector filter" where
    17   "at_infinity = (INF r. principal {x. r \<le> norm x})"
    18 
    19 lemma eventually_at_infinity: "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> P x)"
    20   unfolding at_infinity_def
    21   by (subst eventually_INF_base)
    22      (auto simp: subset_eq eventually_principal intro!: exI[of _ "max a b" for a b])
    23 
    24 lemma at_infinity_eq_at_top_bot:
    25   "(at_infinity \<Colon> real filter) = sup at_top at_bot"
    26   apply (simp add: filter_eq_iff eventually_sup eventually_at_infinity
    27                    eventually_at_top_linorder eventually_at_bot_linorder)
    28   apply safe
    29   apply (rule_tac x="b" in exI, simp)
    30   apply (rule_tac x="- b" in exI, simp)
    31   apply (rule_tac x="max (- Na) N" in exI, auto simp: abs_real_def)
    32   done
    33 
    34 lemma at_top_le_at_infinity: "at_top \<le> (at_infinity :: real filter)"
    35   unfolding at_infinity_eq_at_top_bot by simp
    36 
    37 lemma at_bot_le_at_infinity: "at_bot \<le> (at_infinity :: real filter)"
    38   unfolding at_infinity_eq_at_top_bot by simp
    39 
    40 lemma filterlim_at_top_imp_at_infinity:
    41   fixes f :: "_ \<Rightarrow> real"
    42   shows "filterlim f at_top F \<Longrightarrow> filterlim f at_infinity F"
    43   by (rule filterlim_mono[OF _ at_top_le_at_infinity order_refl])
    44 
    45 lemma lim_infinity_imp_sequentially:
    46   "(f ---> l) at_infinity \<Longrightarrow> ((\<lambda>n. f(n)) ---> l) sequentially"
    47 by (simp add: filterlim_at_top_imp_at_infinity filterlim_compose filterlim_real_sequentially)
    48 
    49 
    50 subsubsection \<open>Boundedness\<close>
    51 
    52 definition Bfun :: "('a \<Rightarrow> 'b::metric_space) \<Rightarrow> 'a filter \<Rightarrow> bool" where
    53   Bfun_metric_def: "Bfun f F = (\<exists>y. \<exists>K>0. eventually (\<lambda>x. dist (f x) y \<le> K) F)"
    54 
    55 abbreviation Bseq :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    56   "Bseq X \<equiv> Bfun X sequentially"
    57 
    58 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially" ..
    59 
    60 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
    61   unfolding Bfun_metric_def by (subst eventually_sequentially_seg)
    62 
    63 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
    64   unfolding Bfun_metric_def by (subst (asm) eventually_sequentially_seg)
    65 
    66 lemma Bfun_def:
    67   "Bfun f F \<longleftrightarrow> (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
    68   unfolding Bfun_metric_def norm_conv_dist
    69 proof safe
    70   fix y K assume "0 < K" and *: "eventually (\<lambda>x. dist (f x) y \<le> K) F"
    71   moreover have "eventually (\<lambda>x. dist (f x) 0 \<le> dist (f x) y + dist 0 y) F"
    72     by (intro always_eventually) (metis dist_commute dist_triangle)
    73   with * have "eventually (\<lambda>x. dist (f x) 0 \<le> K + dist 0 y) F"
    74     by eventually_elim auto
    75   with \<open>0 < K\<close> show "\<exists>K>0. eventually (\<lambda>x. dist (f x) 0 \<le> K) F"
    76     by (intro exI[of _ "K + dist 0 y"] add_pos_nonneg conjI zero_le_dist) auto
    77 qed auto
    78 
    79 lemma BfunI:
    80   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F" shows "Bfun f F"
    81 unfolding Bfun_def
    82 proof (intro exI conjI allI)
    83   show "0 < max K 1" by simp
    84 next
    85   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
    86     using K by (rule eventually_elim1, simp)
    87 qed
    88 
    89 lemma BfunE:
    90   assumes "Bfun f F"
    91   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
    92 using assms unfolding Bfun_def by fast
    93 
    94 lemma Cauchy_Bseq: "Cauchy X \<Longrightarrow> Bseq X"
    95   unfolding Cauchy_def Bfun_metric_def eventually_sequentially
    96   apply (erule_tac x=1 in allE)
    97   apply simp
    98   apply safe
    99   apply (rule_tac x="X M" in exI)
   100   apply (rule_tac x=1 in exI)
   101   apply (erule_tac x=M in allE)
   102   apply simp
   103   apply (rule_tac x=M in exI)
   104   apply (auto simp: dist_commute)
   105   done
   106 
   107 
   108 subsubsection \<open>Bounded Sequences\<close>
   109 
   110 lemma BseqI': "(\<And>n. norm (X n) \<le> K) \<Longrightarrow> Bseq X"
   111   by (intro BfunI) (auto simp: eventually_sequentially)
   112 
   113 lemma BseqI2': "\<forall>n\<ge>N. norm (X n) \<le> K \<Longrightarrow> Bseq X"
   114   by (intro BfunI) (auto simp: eventually_sequentially)
   115 
   116 lemma Bseq_def: "Bseq X \<longleftrightarrow> (\<exists>K>0. \<forall>n. norm (X n) \<le> K)"
   117   unfolding Bfun_def eventually_sequentially
   118 proof safe
   119   fix N K assume "0 < K" "\<forall>n\<ge>N. norm (X n) \<le> K"
   120   then show "\<exists>K>0. \<forall>n. norm (X n) \<le> K"
   121     by (intro exI[of _ "max (Max (norm ` X ` {..N})) K"] max.strict_coboundedI2)
   122        (auto intro!: imageI not_less[where 'a=nat, THEN iffD1] Max_ge simp: le_max_iff_disj)
   123 qed auto
   124 
   125 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
   126 unfolding Bseq_def by auto
   127 
   128 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
   129 by (simp add: Bseq_def)
   130 
   131 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
   132 by (auto simp add: Bseq_def)
   133 
   134 lemma Bseq_bdd_above: "Bseq (X::nat \<Rightarrow> real) \<Longrightarrow> bdd_above (range X)"
   135 proof (elim BseqE, intro bdd_aboveI2)
   136   fix K n assume "0 < K" "\<forall>n. norm (X n) \<le> K" then show "X n \<le> K"
   137     by (auto elim!: allE[of _ n])
   138 qed
   139 
   140 lemma Bseq_bdd_below: "Bseq (X::nat \<Rightarrow> real) \<Longrightarrow> bdd_below (range X)"
   141 proof (elim BseqE, intro bdd_belowI2)
   142   fix K n assume "0 < K" "\<forall>n. norm (X n) \<le> K" then show "- K \<le> X n"
   143     by (auto elim!: allE[of _ n])
   144 qed
   145 
   146 lemma lemma_NBseq_def:
   147   "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   148 proof safe
   149   fix K :: real
   150   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   151   then have "K \<le> real (Suc n)" by auto
   152   moreover assume "\<forall>m. norm (X m) \<le> K"
   153   ultimately have "\<forall>m. norm (X m) \<le> real (Suc n)"
   154     by (blast intro: order_trans)
   155   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   156 qed (force simp add: real_of_nat_Suc)
   157 
   158 text\<open>alternative definition for Bseq\<close>
   159 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   160 apply (simp add: Bseq_def)
   161 apply (simp (no_asm) add: lemma_NBseq_def)
   162 done
   163 
   164 lemma lemma_NBseq_def2:
   165      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   166 apply (subst lemma_NBseq_def, auto)
   167 apply (rule_tac x = "Suc N" in exI)
   168 apply (rule_tac [2] x = N in exI)
   169 apply (auto simp add: real_of_nat_Suc)
   170  prefer 2 apply (blast intro: order_less_imp_le)
   171 apply (drule_tac x = n in spec, simp)
   172 done
   173 
   174 (* yet another definition for Bseq *)
   175 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   176 by (simp add: Bseq_def lemma_NBseq_def2)
   177 
   178 subsubsection\<open>A Few More Equivalence Theorems for Boundedness\<close>
   179 
   180 text\<open>alternative formulation for boundedness\<close>
   181 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
   182 apply (unfold Bseq_def, safe)
   183 apply (rule_tac [2] x = "k + norm x" in exI)
   184 apply (rule_tac x = K in exI, simp)
   185 apply (rule exI [where x = 0], auto)
   186 apply (erule order_less_le_trans, simp)
   187 apply (drule_tac x=n in spec)
   188 apply (drule order_trans [OF norm_triangle_ineq2])
   189 apply simp
   190 done
   191 
   192 text\<open>alternative formulation for boundedness\<close>
   193 lemma Bseq_iff3:
   194   "Bseq X \<longleftrightarrow> (\<exists>k>0. \<exists>N. \<forall>n. norm (X n + - X N) \<le> k)" (is "?P \<longleftrightarrow> ?Q")
   195 proof
   196   assume ?P
   197   then obtain K
   198     where *: "0 < K" and **: "\<And>n. norm (X n) \<le> K" by (auto simp add: Bseq_def)
   199   from * have "0 < K + norm (X 0)" by (rule order_less_le_trans) simp
   200   from ** have "\<forall>n. norm (X n - X 0) \<le> K + norm (X 0)"
   201     by (auto intro: order_trans norm_triangle_ineq4)
   202   then have "\<forall>n. norm (X n + - X 0) \<le> K + norm (X 0)"
   203     by simp
   204   with \<open>0 < K + norm (X 0)\<close> show ?Q by blast
   205 next
   206   assume ?Q then show ?P by (auto simp add: Bseq_iff2)
   207 qed
   208 
   209 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
   210 apply (simp add: Bseq_def)
   211 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
   212 apply (drule_tac x = n in spec, arith)
   213 done
   214 
   215 
   216 subsubsection\<open>Upper Bounds and Lubs of Bounded Sequences\<close>
   217 
   218 lemma Bseq_minus_iff: "Bseq (%n. -(X n) :: 'a :: real_normed_vector) = Bseq X"
   219   by (simp add: Bseq_def)
   220 
   221 lemma Bseq_eq_bounded: "range f \<subseteq> {a .. b::real} \<Longrightarrow> Bseq f"
   222   apply (simp add: subset_eq)
   223   apply (rule BseqI'[where K="max (norm a) (norm b)"])
   224   apply (erule_tac x=n in allE)
   225   apply auto
   226   done
   227 
   228 lemma incseq_bounded: "incseq X \<Longrightarrow> \<forall>i. X i \<le> (B::real) \<Longrightarrow> Bseq X"
   229   by (intro Bseq_eq_bounded[of X "X 0" B]) (auto simp: incseq_def)
   230 
   231 lemma decseq_bounded: "decseq X \<Longrightarrow> \<forall>i. (B::real) \<le> X i \<Longrightarrow> Bseq X"
   232   by (intro Bseq_eq_bounded[of X B "X 0"]) (auto simp: decseq_def)
   233 
   234 subsection \<open>Bounded Monotonic Sequences\<close>
   235 
   236 subsubsection\<open>A Bounded and Monotonic Sequence Converges\<close>
   237 
   238 (* TODO: delete *)
   239 (* FIXME: one use in NSA/HSEQ.thy *)
   240 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X ----> L)"
   241   apply (rule_tac x="X m" in exI)
   242   apply (rule filterlim_cong[THEN iffD2, OF refl refl _ tendsto_const])
   243   unfolding eventually_sequentially
   244   apply blast
   245   done
   246 
   247 subsection \<open>Convergence to Zero\<close>
   248 
   249 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   250   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
   251 
   252 lemma ZfunI:
   253   "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
   254   unfolding Zfun_def by simp
   255 
   256 lemma ZfunD:
   257   "\<lbrakk>Zfun f F; 0 < r\<rbrakk> \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
   258   unfolding Zfun_def by simp
   259 
   260 lemma Zfun_ssubst:
   261   "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
   262   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   263 
   264 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
   265   unfolding Zfun_def by simp
   266 
   267 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   268   unfolding Zfun_def by simp
   269 
   270 lemma Zfun_imp_Zfun:
   271   assumes f: "Zfun f F"
   272   assumes g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   273   shows "Zfun (\<lambda>x. g x) F"
   274 proof (cases)
   275   assume K: "0 < K"
   276   show ?thesis
   277   proof (rule ZfunI)
   278     fix r::real assume "0 < r"
   279     hence "0 < r / K" using K by simp
   280     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   281       using ZfunD [OF f] by fast
   282     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   283     proof eventually_elim
   284       case (elim x)
   285       hence "norm (f x) * K < r"
   286         by (simp add: pos_less_divide_eq K)
   287       thus ?case
   288         by (simp add: order_le_less_trans [OF elim(1)])
   289     qed
   290   qed
   291 next
   292   assume "\<not> 0 < K"
   293   hence K: "K \<le> 0" by (simp only: not_less)
   294   show ?thesis
   295   proof (rule ZfunI)
   296     fix r :: real
   297     assume "0 < r"
   298     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   299     proof eventually_elim
   300       case (elim x)
   301       also have "norm (f x) * K \<le> norm (f x) * 0"
   302         using K norm_ge_zero by (rule mult_left_mono)
   303       finally show ?case
   304         using \<open>0 < r\<close> by simp
   305     qed
   306   qed
   307 qed
   308 
   309 lemma Zfun_le: "\<lbrakk>Zfun g F; \<forall>x. norm (f x) \<le> norm (g x)\<rbrakk> \<Longrightarrow> Zfun f F"
   310   by (erule_tac K="1" in Zfun_imp_Zfun, simp)
   311 
   312 lemma Zfun_add:
   313   assumes f: "Zfun f F" and g: "Zfun g F"
   314   shows "Zfun (\<lambda>x. f x + g x) F"
   315 proof (rule ZfunI)
   316   fix r::real assume "0 < r"
   317   hence r: "0 < r / 2" by simp
   318   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   319     using f r by (rule ZfunD)
   320   moreover
   321   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   322     using g r by (rule ZfunD)
   323   ultimately
   324   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   325   proof eventually_elim
   326     case (elim x)
   327     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   328       by (rule norm_triangle_ineq)
   329     also have "\<dots> < r/2 + r/2"
   330       using elim by (rule add_strict_mono)
   331     finally show ?case
   332       by simp
   333   qed
   334 qed
   335 
   336 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   337   unfolding Zfun_def by simp
   338 
   339 lemma Zfun_diff: "\<lbrakk>Zfun f F; Zfun g F\<rbrakk> \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   340   using Zfun_add [of f F "\<lambda>x. - g x"] by (simp add: Zfun_minus)
   341 
   342 lemma (in bounded_linear) Zfun:
   343   assumes g: "Zfun g F"
   344   shows "Zfun (\<lambda>x. f (g x)) F"
   345 proof -
   346   obtain K where "\<And>x. norm (f x) \<le> norm x * K"
   347     using bounded by fast
   348   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   349     by simp
   350   with g show ?thesis
   351     by (rule Zfun_imp_Zfun)
   352 qed
   353 
   354 lemma (in bounded_bilinear) Zfun:
   355   assumes f: "Zfun f F"
   356   assumes g: "Zfun g F"
   357   shows "Zfun (\<lambda>x. f x ** g x) F"
   358 proof (rule ZfunI)
   359   fix r::real assume r: "0 < r"
   360   obtain K where K: "0 < K"
   361     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   362     using pos_bounded by fast
   363   from K have K': "0 < inverse K"
   364     by (rule positive_imp_inverse_positive)
   365   have "eventually (\<lambda>x. norm (f x) < r) F"
   366     using f r by (rule ZfunD)
   367   moreover
   368   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   369     using g K' by (rule ZfunD)
   370   ultimately
   371   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   372   proof eventually_elim
   373     case (elim x)
   374     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   375       by (rule norm_le)
   376     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   377       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
   378     also from K have "r * inverse K * K = r"
   379       by simp
   380     finally show ?case .
   381   qed
   382 qed
   383 
   384 lemma (in bounded_bilinear) Zfun_left:
   385   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   386   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   387 
   388 lemma (in bounded_bilinear) Zfun_right:
   389   "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   390   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   391 
   392 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   393 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   394 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   395 
   396 lemma tendsto_Zfun_iff: "(f ---> a) F = Zfun (\<lambda>x. f x - a) F"
   397   by (simp only: tendsto_iff Zfun_def dist_norm)
   398 
   399 lemma tendsto_0_le: "\<lbrakk>(f ---> 0) F; eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F\<rbrakk>
   400                      \<Longrightarrow> (g ---> 0) F"
   401   by (simp add: Zfun_imp_Zfun tendsto_Zfun_iff)
   402 
   403 subsubsection \<open>Distance and norms\<close>
   404 
   405 lemma tendsto_dist [tendsto_intros]:
   406   fixes l m :: "'a :: metric_space"
   407   assumes f: "(f ---> l) F" and g: "(g ---> m) F"
   408   shows "((\<lambda>x. dist (f x) (g x)) ---> dist l m) F"
   409 proof (rule tendstoI)
   410   fix e :: real assume "0 < e"
   411   hence e2: "0 < e/2" by simp
   412   from tendstoD [OF f e2] tendstoD [OF g e2]
   413   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) F"
   414   proof (eventually_elim)
   415     case (elim x)
   416     then show "dist (dist (f x) (g x)) (dist l m) < e"
   417       unfolding dist_real_def
   418       using dist_triangle2 [of "f x" "g x" "l"]
   419       using dist_triangle2 [of "g x" "l" "m"]
   420       using dist_triangle3 [of "l" "m" "f x"]
   421       using dist_triangle [of "f x" "m" "g x"]
   422       by arith
   423   qed
   424 qed
   425 
   426 lemma continuous_dist[continuous_intros]:
   427   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   428   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. dist (f x) (g x))"
   429   unfolding continuous_def by (rule tendsto_dist)
   430 
   431 lemma continuous_on_dist[continuous_intros]:
   432   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   433   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. dist (f x) (g x))"
   434   unfolding continuous_on_def by (auto intro: tendsto_dist)
   435 
   436 lemma tendsto_norm [tendsto_intros]:
   437   "(f ---> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> norm a) F"
   438   unfolding norm_conv_dist by (intro tendsto_intros)
   439 
   440 lemma continuous_norm [continuous_intros]:
   441   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. norm (f x))"
   442   unfolding continuous_def by (rule tendsto_norm)
   443 
   444 lemma continuous_on_norm [continuous_intros]:
   445   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. norm (f x))"
   446   unfolding continuous_on_def by (auto intro: tendsto_norm)
   447 
   448 lemma tendsto_norm_zero:
   449   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) ---> 0) F"
   450   by (drule tendsto_norm, simp)
   451 
   452 lemma tendsto_norm_zero_cancel:
   453   "((\<lambda>x. norm (f x)) ---> 0) F \<Longrightarrow> (f ---> 0) F"
   454   unfolding tendsto_iff dist_norm by simp
   455 
   456 lemma tendsto_norm_zero_iff:
   457   "((\<lambda>x. norm (f x)) ---> 0) F \<longleftrightarrow> (f ---> 0) F"
   458   unfolding tendsto_iff dist_norm by simp
   459 
   460 lemma tendsto_rabs [tendsto_intros]:
   461   "(f ---> (l::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> \<bar>l\<bar>) F"
   462   by (fold real_norm_def, rule tendsto_norm)
   463 
   464 lemma continuous_rabs [continuous_intros]:
   465   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. \<bar>f x :: real\<bar>)"
   466   unfolding real_norm_def[symmetric] by (rule continuous_norm)
   467 
   468 lemma continuous_on_rabs [continuous_intros]:
   469   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. \<bar>f x :: real\<bar>)"
   470   unfolding real_norm_def[symmetric] by (rule continuous_on_norm)
   471 
   472 lemma tendsto_rabs_zero:
   473   "(f ---> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) ---> 0) F"
   474   by (fold real_norm_def, rule tendsto_norm_zero)
   475 
   476 lemma tendsto_rabs_zero_cancel:
   477   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<Longrightarrow> (f ---> 0) F"
   478   by (fold real_norm_def, rule tendsto_norm_zero_cancel)
   479 
   480 lemma tendsto_rabs_zero_iff:
   481   "((\<lambda>x. \<bar>f x\<bar>) ---> (0::real)) F \<longleftrightarrow> (f ---> 0) F"
   482   by (fold real_norm_def, rule tendsto_norm_zero_iff)
   483 
   484 subsubsection \<open>Addition and subtraction\<close>
   485 
   486 lemma tendsto_add [tendsto_intros]:
   487   fixes a b :: "'a::real_normed_vector"
   488   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> a + b) F"
   489   by (simp only: tendsto_Zfun_iff add_diff_add Zfun_add)
   490 
   491 lemma continuous_add [continuous_intros]:
   492   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   493   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x + g x)"
   494   unfolding continuous_def by (rule tendsto_add)
   495 
   496 lemma continuous_on_add [continuous_intros]:
   497   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   498   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x + g x)"
   499   unfolding continuous_on_def by (auto intro: tendsto_add)
   500 
   501 lemma tendsto_add_zero:
   502   fixes f g :: "_ \<Rightarrow> 'b::real_normed_vector"
   503   shows "\<lbrakk>(f ---> 0) F; (g ---> 0) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x + g x) ---> 0) F"
   504   by (drule (1) tendsto_add, simp)
   505 
   506 lemma tendsto_minus [tendsto_intros]:
   507   fixes a :: "'a::real_normed_vector"
   508   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. - f x) ---> - a) F"
   509   by (simp only: tendsto_Zfun_iff minus_diff_minus Zfun_minus)
   510 
   511 lemma continuous_minus [continuous_intros]:
   512   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   513   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. - f x)"
   514   unfolding continuous_def by (rule tendsto_minus)
   515 
   516 lemma continuous_on_minus [continuous_intros]:
   517   fixes f :: "_ \<Rightarrow> 'b::real_normed_vector"
   518   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. - f x)"
   519   unfolding continuous_on_def by (auto intro: tendsto_minus)
   520 
   521 lemma tendsto_minus_cancel:
   522   fixes a :: "'a::real_normed_vector"
   523   shows "((\<lambda>x. - f x) ---> - a) F \<Longrightarrow> (f ---> a) F"
   524   by (drule tendsto_minus, simp)
   525 
   526 lemma tendsto_minus_cancel_left:
   527     "(f ---> - (y::_::real_normed_vector)) F \<longleftrightarrow> ((\<lambda>x. - f x) ---> y) F"
   528   using tendsto_minus_cancel[of f "- y" F]  tendsto_minus[of f "- y" F]
   529   by auto
   530 
   531 lemma tendsto_diff [tendsto_intros]:
   532   fixes a b :: "'a::real_normed_vector"
   533   shows "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x - g x) ---> a - b) F"
   534   using tendsto_add [of f a F "\<lambda>x. - g x" "- b"] by (simp add: tendsto_minus)
   535 
   536 lemma continuous_diff [continuous_intros]:
   537   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   538   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x - g x)"
   539   unfolding continuous_def by (rule tendsto_diff)
   540 
   541 lemma continuous_on_diff [continuous_intros]:
   542   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   543   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x - g x)"
   544   unfolding continuous_on_def by (auto intro: tendsto_diff)
   545 
   546 lemma tendsto_setsum [tendsto_intros]:
   547   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::real_normed_vector"
   548   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> a i) F"
   549   shows "((\<lambda>x. \<Sum>i\<in>S. f i x) ---> (\<Sum>i\<in>S. a i)) F"
   550 proof (cases "finite S")
   551   assume "finite S" thus ?thesis using assms
   552     by (induct, simp, simp add: tendsto_add)
   553 qed simp
   554 
   555 lemma continuous_setsum [continuous_intros]:
   556   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
   557   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Sum>i\<in>S. f i x)"
   558   unfolding continuous_def by (rule tendsto_setsum)
   559 
   560 lemma continuous_on_setsum [continuous_intros]:
   561   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::real_normed_vector"
   562   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Sum>i\<in>S. f i x)"
   563   unfolding continuous_on_def by (auto intro: tendsto_setsum)
   564 
   565 lemmas real_tendsto_sandwich = tendsto_sandwich[where 'b=real]
   566 
   567 subsubsection \<open>Linear operators and multiplication\<close>
   568 
   569 lemma (in bounded_linear) tendsto:
   570   "(g ---> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> f a) F"
   571   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   572 
   573 lemma (in bounded_linear) continuous:
   574   "continuous F g \<Longrightarrow> continuous F (\<lambda>x. f (g x))"
   575   using tendsto[of g _ F] by (auto simp: continuous_def)
   576 
   577 lemma (in bounded_linear) continuous_on:
   578   "continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f (g x))"
   579   using tendsto[of g] by (auto simp: continuous_on_def)
   580 
   581 lemma (in bounded_linear) tendsto_zero:
   582   "(g ---> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) ---> 0) F"
   583   by (drule tendsto, simp only: zero)
   584 
   585 lemma (in bounded_bilinear) tendsto:
   586   "\<lbrakk>(f ---> a) F; (g ---> b) F\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ** g x) ---> a ** b) F"
   587   by (simp only: tendsto_Zfun_iff prod_diff_prod
   588                  Zfun_add Zfun Zfun_left Zfun_right)
   589 
   590 lemma (in bounded_bilinear) continuous:
   591   "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x ** g x)"
   592   using tendsto[of f _ F g] by (auto simp: continuous_def)
   593 
   594 lemma (in bounded_bilinear) continuous_on:
   595   "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x ** g x)"
   596   using tendsto[of f _ _ g] by (auto simp: continuous_on_def)
   597 
   598 lemma (in bounded_bilinear) tendsto_zero:
   599   assumes f: "(f ---> 0) F"
   600   assumes g: "(g ---> 0) F"
   601   shows "((\<lambda>x. f x ** g x) ---> 0) F"
   602   using tendsto [OF f g] by (simp add: zero_left)
   603 
   604 lemma (in bounded_bilinear) tendsto_left_zero:
   605   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) ---> 0) F"
   606   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
   607 
   608 lemma (in bounded_bilinear) tendsto_right_zero:
   609   "(f ---> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) ---> 0) F"
   610   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
   611 
   612 lemmas tendsto_of_real [tendsto_intros] =
   613   bounded_linear.tendsto [OF bounded_linear_of_real]
   614 
   615 lemmas tendsto_scaleR [tendsto_intros] =
   616   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
   617 
   618 lemmas tendsto_mult [tendsto_intros] =
   619   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
   620 
   621 lemmas continuous_of_real [continuous_intros] =
   622   bounded_linear.continuous [OF bounded_linear_of_real]
   623 
   624 lemmas continuous_scaleR [continuous_intros] =
   625   bounded_bilinear.continuous [OF bounded_bilinear_scaleR]
   626 
   627 lemmas continuous_mult [continuous_intros] =
   628   bounded_bilinear.continuous [OF bounded_bilinear_mult]
   629 
   630 lemmas continuous_on_of_real [continuous_intros] =
   631   bounded_linear.continuous_on [OF bounded_linear_of_real]
   632 
   633 lemmas continuous_on_scaleR [continuous_intros] =
   634   bounded_bilinear.continuous_on [OF bounded_bilinear_scaleR]
   635 
   636 lemmas continuous_on_mult [continuous_intros] =
   637   bounded_bilinear.continuous_on [OF bounded_bilinear_mult]
   638 
   639 lemmas tendsto_mult_zero =
   640   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
   641 
   642 lemmas tendsto_mult_left_zero =
   643   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
   644 
   645 lemmas tendsto_mult_right_zero =
   646   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
   647 
   648 lemma tendsto_power [tendsto_intros]:
   649   fixes f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
   650   shows "(f ---> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) ---> a ^ n) F"
   651   by (induct n) (simp_all add: tendsto_mult)
   652 
   653 lemma continuous_power [continuous_intros]:
   654   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
   655   shows "continuous F f \<Longrightarrow> continuous F (\<lambda>x. (f x)^n)"
   656   unfolding continuous_def by (rule tendsto_power)
   657 
   658 lemma continuous_on_power [continuous_intros]:
   659   fixes f :: "_ \<Rightarrow> 'b::{power,real_normed_algebra}"
   660   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. (f x)^n)"
   661   unfolding continuous_on_def by (auto intro: tendsto_power)
   662 
   663 lemma tendsto_setprod [tendsto_intros]:
   664   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   665   assumes "\<And>i. i \<in> S \<Longrightarrow> (f i ---> L i) F"
   666   shows "((\<lambda>x. \<Prod>i\<in>S. f i x) ---> (\<Prod>i\<in>S. L i)) F"
   667 proof (cases "finite S")
   668   assume "finite S" thus ?thesis using assms
   669     by (induct, simp, simp add: tendsto_mult)
   670 qed simp
   671 
   672 lemma continuous_setprod [continuous_intros]:
   673   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   674   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Prod>i\<in>S. f i x)"
   675   unfolding continuous_def by (rule tendsto_setprod)
   676 
   677 lemma continuous_on_setprod [continuous_intros]:
   678   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   679   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Prod>i\<in>S. f i x)"
   680   unfolding continuous_on_def by (auto intro: tendsto_setprod)
   681 
   682 subsubsection \<open>Inverse and division\<close>
   683 
   684 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   685   assumes f: "Zfun f F"
   686   assumes g: "Bfun g F"
   687   shows "Zfun (\<lambda>x. f x ** g x) F"
   688 proof -
   689   obtain K where K: "0 \<le> K"
   690     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   691     using nonneg_bounded by fast
   692   obtain B where B: "0 < B"
   693     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
   694     using g by (rule BfunE)
   695   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
   696   using norm_g proof eventually_elim
   697     case (elim x)
   698     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   699       by (rule norm_le)
   700     also have "\<dots> \<le> norm (f x) * B * K"
   701       by (intro mult_mono' order_refl norm_g norm_ge_zero
   702                 mult_nonneg_nonneg K elim)
   703     also have "\<dots> = norm (f x) * (B * K)"
   704       by (rule mult.assoc)
   705     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   706   qed
   707   with f show ?thesis
   708     by (rule Zfun_imp_Zfun)
   709 qed
   710 
   711 lemma (in bounded_bilinear) flip:
   712   "bounded_bilinear (\<lambda>x y. y ** x)"
   713   apply default
   714   apply (rule add_right)
   715   apply (rule add_left)
   716   apply (rule scaleR_right)
   717   apply (rule scaleR_left)
   718   apply (subst mult.commute)
   719   using bounded by fast
   720 
   721 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   722   assumes f: "Bfun f F"
   723   assumes g: "Zfun g F"
   724   shows "Zfun (\<lambda>x. f x ** g x) F"
   725   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
   726 
   727 lemma Bfun_inverse_lemma:
   728   fixes x :: "'a::real_normed_div_algebra"
   729   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   730   apply (subst nonzero_norm_inverse, clarsimp)
   731   apply (erule (1) le_imp_inverse_le)
   732   done
   733 
   734 lemma Bfun_inverse:
   735   fixes a :: "'a::real_normed_div_algebra"
   736   assumes f: "(f ---> a) F"
   737   assumes a: "a \<noteq> 0"
   738   shows "Bfun (\<lambda>x. inverse (f x)) F"
   739 proof -
   740   from a have "0 < norm a" by simp
   741   hence "\<exists>r>0. r < norm a" by (rule dense)
   742   then obtain r where r1: "0 < r" and r2: "r < norm a" by fast
   743   have "eventually (\<lambda>x. dist (f x) a < r) F"
   744     using tendstoD [OF f r1] by fast
   745   hence "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
   746   proof eventually_elim
   747     case (elim x)
   748     hence 1: "norm (f x - a) < r"
   749       by (simp add: dist_norm)
   750     hence 2: "f x \<noteq> 0" using r2 by auto
   751     hence "norm (inverse (f x)) = inverse (norm (f x))"
   752       by (rule nonzero_norm_inverse)
   753     also have "\<dots> \<le> inverse (norm a - r)"
   754     proof (rule le_imp_inverse_le)
   755       show "0 < norm a - r" using r2 by simp
   756     next
   757       have "norm a - norm (f x) \<le> norm (a - f x)"
   758         by (rule norm_triangle_ineq2)
   759       also have "\<dots> = norm (f x - a)"
   760         by (rule norm_minus_commute)
   761       also have "\<dots> < r" using 1 .
   762       finally show "norm a - r \<le> norm (f x)" by simp
   763     qed
   764     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
   765   qed
   766   thus ?thesis by (rule BfunI)
   767 qed
   768 
   769 lemma tendsto_inverse [tendsto_intros]:
   770   fixes a :: "'a::real_normed_div_algebra"
   771   assumes f: "(f ---> a) F"
   772   assumes a: "a \<noteq> 0"
   773   shows "((\<lambda>x. inverse (f x)) ---> inverse a) F"
   774 proof -
   775   from a have "0 < norm a" by simp
   776   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
   777     by (rule tendstoD)
   778   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
   779     unfolding dist_norm by (auto elim!: eventually_elim1)
   780   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
   781     - (inverse (f x) * (f x - a) * inverse a)) F"
   782     by (auto elim!: eventually_elim1 simp: inverse_diff_inverse)
   783   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
   784     by (intro Zfun_minus Zfun_mult_left
   785       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
   786       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
   787   ultimately show ?thesis
   788     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
   789 qed
   790 
   791 lemma continuous_inverse:
   792   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   793   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   794   shows "continuous F (\<lambda>x. inverse (f x))"
   795   using assms unfolding continuous_def by (rule tendsto_inverse)
   796 
   797 lemma continuous_at_within_inverse[continuous_intros]:
   798   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   799   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   800   shows "continuous (at a within s) (\<lambda>x. inverse (f x))"
   801   using assms unfolding continuous_within by (rule tendsto_inverse)
   802 
   803 lemma isCont_inverse[continuous_intros, simp]:
   804   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   805   assumes "isCont f a" and "f a \<noteq> 0"
   806   shows "isCont (\<lambda>x. inverse (f x)) a"
   807   using assms unfolding continuous_at by (rule tendsto_inverse)
   808 
   809 lemma continuous_on_inverse[continuous_intros]:
   810   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_div_algebra"
   811   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   812   shows "continuous_on s (\<lambda>x. inverse (f x))"
   813   using assms unfolding continuous_on_def by (fast intro: tendsto_inverse)
   814 
   815 lemma tendsto_divide [tendsto_intros]:
   816   fixes a b :: "'a::real_normed_field"
   817   shows "\<lbrakk>(f ---> a) F; (g ---> b) F; b \<noteq> 0\<rbrakk>
   818     \<Longrightarrow> ((\<lambda>x. f x / g x) ---> a / b) F"
   819   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
   820 
   821 lemma continuous_divide:
   822   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   823   assumes "continuous F f" and "continuous F g" and "g (Lim F (\<lambda>x. x)) \<noteq> 0"
   824   shows "continuous F (\<lambda>x. (f x) / (g x))"
   825   using assms unfolding continuous_def by (rule tendsto_divide)
   826 
   827 lemma continuous_at_within_divide[continuous_intros]:
   828   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   829   assumes "continuous (at a within s) f" "continuous (at a within s) g" and "g a \<noteq> 0"
   830   shows "continuous (at a within s) (\<lambda>x. (f x) / (g x))"
   831   using assms unfolding continuous_within by (rule tendsto_divide)
   832 
   833 lemma isCont_divide[continuous_intros, simp]:
   834   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
   835   assumes "isCont f a" "isCont g a" "g a \<noteq> 0"
   836   shows "isCont (\<lambda>x. (f x) / g x) a"
   837   using assms unfolding continuous_at by (rule tendsto_divide)
   838 
   839 lemma continuous_on_divide[continuous_intros]:
   840   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_field"
   841   assumes "continuous_on s f" "continuous_on s g" and "\<forall>x\<in>s. g x \<noteq> 0"
   842   shows "continuous_on s (\<lambda>x. (f x) / (g x))"
   843   using assms unfolding continuous_on_def by (fast intro: tendsto_divide)
   844 
   845 lemma tendsto_sgn [tendsto_intros]:
   846   fixes l :: "'a::real_normed_vector"
   847   shows "\<lbrakk>(f ---> l) F; l \<noteq> 0\<rbrakk> \<Longrightarrow> ((\<lambda>x. sgn (f x)) ---> sgn l) F"
   848   unfolding sgn_div_norm by (simp add: tendsto_intros)
   849 
   850 lemma continuous_sgn:
   851   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   852   assumes "continuous F f" and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   853   shows "continuous F (\<lambda>x. sgn (f x))"
   854   using assms unfolding continuous_def by (rule tendsto_sgn)
   855 
   856 lemma continuous_at_within_sgn[continuous_intros]:
   857   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   858   assumes "continuous (at a within s) f" and "f a \<noteq> 0"
   859   shows "continuous (at a within s) (\<lambda>x. sgn (f x))"
   860   using assms unfolding continuous_within by (rule tendsto_sgn)
   861 
   862 lemma isCont_sgn[continuous_intros]:
   863   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
   864   assumes "isCont f a" and "f a \<noteq> 0"
   865   shows "isCont (\<lambda>x. sgn (f x)) a"
   866   using assms unfolding continuous_at by (rule tendsto_sgn)
   867 
   868 lemma continuous_on_sgn[continuous_intros]:
   869   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
   870   assumes "continuous_on s f" and "\<forall>x\<in>s. f x \<noteq> 0"
   871   shows "continuous_on s (\<lambda>x. sgn (f x))"
   872   using assms unfolding continuous_on_def by (fast intro: tendsto_sgn)
   873 
   874 lemma filterlim_at_infinity:
   875   fixes f :: "_ \<Rightarrow> 'a\<Colon>real_normed_vector"
   876   assumes "0 \<le> c"
   877   shows "(LIM x F. f x :> at_infinity) \<longleftrightarrow> (\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F)"
   878   unfolding filterlim_iff eventually_at_infinity
   879 proof safe
   880   fix P :: "'a \<Rightarrow> bool" and b
   881   assume *: "\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F"
   882     and P: "\<forall>x. b \<le> norm x \<longrightarrow> P x"
   883   have "max b (c + 1) > c" by auto
   884   with * have "eventually (\<lambda>x. max b (c + 1) \<le> norm (f x)) F"
   885     by auto
   886   then show "eventually (\<lambda>x. P (f x)) F"
   887   proof eventually_elim
   888     fix x assume "max b (c + 1) \<le> norm (f x)"
   889     with P show "P (f x)" by auto
   890   qed
   891 qed force
   892 
   893 subsection \<open>Relate @{const at}, @{const at_left} and @{const at_right}\<close>
   894 
   895 text \<open>
   896 
   897 This lemmas are useful for conversion between @{term "at x"} to @{term "at_left x"} and
   898 @{term "at_right x"} and also @{term "at_right 0"}.
   899 
   900 \<close>
   901 
   902 lemmas filterlim_split_at_real = filterlim_split_at[where 'a=real]
   903 
   904 lemma filtermap_nhds_shift: "filtermap (\<lambda>x. x - d) (nhds a) = nhds (a - d::'a::real_normed_vector)"
   905   by (rule filtermap_fun_inverse[where g="\<lambda>x. x + d"])
   906      (auto intro!: tendsto_eq_intros filterlim_ident)
   907 
   908 lemma filtermap_nhds_minus: "filtermap (\<lambda>x. - x) (nhds a) = nhds (- a::'a::real_normed_vector)"
   909   by (rule filtermap_fun_inverse[where g=uminus])
   910      (auto intro!: tendsto_eq_intros filterlim_ident)
   911 
   912 lemma filtermap_at_shift: "filtermap (\<lambda>x. x - d) (at a) = at (a - d::'a::real_normed_vector)"
   913   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
   914 
   915 lemma filtermap_at_right_shift: "filtermap (\<lambda>x. x - d) (at_right a) = at_right (a - d::real)"
   916   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
   917 
   918 lemma at_right_to_0: "at_right (a::real) = filtermap (\<lambda>x. x + a) (at_right 0)"
   919   using filtermap_at_right_shift[of "-a" 0] by simp
   920 
   921 lemma filterlim_at_right_to_0:
   922   "filterlim f F (at_right (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (x + a)) F (at_right 0)"
   923   unfolding filterlim_def filtermap_filtermap at_right_to_0[of a] ..
   924 
   925 lemma eventually_at_right_to_0:
   926   "eventually P (at_right (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (x + a)) (at_right 0)"
   927   unfolding at_right_to_0[of a] by (simp add: eventually_filtermap)
   928 
   929 lemma filtermap_at_minus: "filtermap (\<lambda>x. - x) (at a) = at (- a::'a::real_normed_vector)"
   930   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   931 
   932 lemma at_left_minus: "at_left (a::real) = filtermap (\<lambda>x. - x) (at_right (- a))"
   933   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   934 
   935 lemma at_right_minus: "at_right (a::real) = filtermap (\<lambda>x. - x) (at_left (- a))"
   936   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
   937 
   938 lemma filterlim_at_left_to_right:
   939   "filterlim f F (at_left (a::real)) \<longleftrightarrow> filterlim (\<lambda>x. f (- x)) F (at_right (-a))"
   940   unfolding filterlim_def filtermap_filtermap at_left_minus[of a] ..
   941 
   942 lemma eventually_at_left_to_right:
   943   "eventually P (at_left (a::real)) \<longleftrightarrow> eventually (\<lambda>x. P (- x)) (at_right (-a))"
   944   unfolding at_left_minus[of a] by (simp add: eventually_filtermap)
   945 
   946 lemma filterlim_uminus_at_top_at_bot: "LIM x at_bot. - x :: real :> at_top"
   947   unfolding filterlim_at_top eventually_at_bot_dense
   948   by (metis leI minus_less_iff order_less_asym)
   949 
   950 lemma filterlim_uminus_at_bot_at_top: "LIM x at_top. - x :: real :> at_bot"
   951   unfolding filterlim_at_bot eventually_at_top_dense
   952   by (metis leI less_minus_iff order_less_asym)
   953 
   954 lemma at_top_mirror: "at_top = filtermap uminus (at_bot :: real filter)"
   955   by (rule filtermap_fun_inverse[symmetric, of uminus])
   956      (auto intro: filterlim_uminus_at_bot_at_top filterlim_uminus_at_top_at_bot)
   957 
   958 lemma at_bot_mirror: "at_bot = filtermap uminus (at_top :: real filter)"
   959   unfolding at_top_mirror filtermap_filtermap by (simp add: filtermap_ident)
   960 
   961 lemma filterlim_at_top_mirror: "(LIM x at_top. f x :> F) \<longleftrightarrow> (LIM x at_bot. f (-x::real) :> F)"
   962   unfolding filterlim_def at_top_mirror filtermap_filtermap ..
   963 
   964 lemma filterlim_at_bot_mirror: "(LIM x at_bot. f x :> F) \<longleftrightarrow> (LIM x at_top. f (-x::real) :> F)"
   965   unfolding filterlim_def at_bot_mirror filtermap_filtermap ..
   966 
   967 lemma filterlim_uminus_at_top: "(LIM x F. f x :> at_top) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_bot)"
   968   using filterlim_compose[OF filterlim_uminus_at_bot_at_top, of f F]
   969   using filterlim_compose[OF filterlim_uminus_at_top_at_bot, of "\<lambda>x. - f x" F]
   970   by auto
   971 
   972 lemma filterlim_uminus_at_bot: "(LIM x F. f x :> at_bot) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_top)"
   973   unfolding filterlim_uminus_at_top by simp
   974 
   975 lemma filterlim_inverse_at_top_right: "LIM x at_right (0::real). inverse x :> at_top"
   976   unfolding filterlim_at_top_gt[where c=0] eventually_at_filter
   977 proof safe
   978   fix Z :: real assume [arith]: "0 < Z"
   979   then have "eventually (\<lambda>x. x < inverse Z) (nhds 0)"
   980     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
   981   then show "eventually (\<lambda>x. x \<noteq> 0 \<longrightarrow> x \<in> {0<..} \<longrightarrow> Z \<le> inverse x) (nhds 0)"
   982     by (auto elim!: eventually_elim1 simp: inverse_eq_divide field_simps)
   983 qed
   984 
   985 lemma tendsto_inverse_0:
   986   fixes x :: "_ \<Rightarrow> 'a\<Colon>real_normed_div_algebra"
   987   shows "(inverse ---> (0::'a)) at_infinity"
   988   unfolding tendsto_Zfun_iff diff_0_right Zfun_def eventually_at_infinity
   989 proof safe
   990   fix r :: real assume "0 < r"
   991   show "\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> norm (inverse x :: 'a) < r"
   992   proof (intro exI[of _ "inverse (r / 2)"] allI impI)
   993     fix x :: 'a
   994     from \<open>0 < r\<close> have "0 < inverse (r / 2)" by simp
   995     also assume *: "inverse (r / 2) \<le> norm x"
   996     finally show "norm (inverse x) < r"
   997       using * \<open>0 < r\<close> by (subst nonzero_norm_inverse) (simp_all add: inverse_eq_divide field_simps)
   998   qed
   999 qed
  1000 
  1001 lemma filterlim_inverse_at_right_top: "LIM x at_top. inverse x :> at_right (0::real)"
  1002   unfolding filterlim_at
  1003   by (auto simp: eventually_at_top_dense)
  1004      (metis tendsto_inverse_0 filterlim_mono at_top_le_at_infinity order_refl)
  1005 
  1006 lemma filterlim_inverse_at_top:
  1007   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. 0 < f x) F \<Longrightarrow> LIM x F. inverse (f x) :> at_top"
  1008   by (intro filterlim_compose[OF filterlim_inverse_at_top_right])
  1009      (simp add: filterlim_def eventually_filtermap eventually_elim1 at_within_def le_principal)
  1010 
  1011 lemma filterlim_inverse_at_bot_neg:
  1012   "LIM x (at_left (0::real)). inverse x :> at_bot"
  1013   by (simp add: filterlim_inverse_at_top_right filterlim_uminus_at_bot filterlim_at_left_to_right)
  1014 
  1015 lemma filterlim_inverse_at_bot:
  1016   "(f ---> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. f x < 0) F \<Longrightarrow> LIM x F. inverse (f x) :> at_bot"
  1017   unfolding filterlim_uminus_at_bot inverse_minus_eq[symmetric]
  1018   by (rule filterlim_inverse_at_top) (simp_all add: tendsto_minus_cancel_left[symmetric])
  1019 
  1020 lemma at_right_to_top: "(at_right (0::real)) = filtermap inverse at_top"
  1021   by (intro filtermap_fun_inverse[symmetric, where g=inverse])
  1022      (auto intro: filterlim_inverse_at_top_right filterlim_inverse_at_right_top)
  1023 
  1024 lemma eventually_at_right_to_top:
  1025   "eventually P (at_right (0::real)) \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) at_top"
  1026   unfolding at_right_to_top eventually_filtermap ..
  1027 
  1028 lemma filterlim_at_right_to_top:
  1029   "filterlim f F (at_right (0::real)) \<longleftrightarrow> (LIM x at_top. f (inverse x) :> F)"
  1030   unfolding filterlim_def at_right_to_top filtermap_filtermap ..
  1031 
  1032 lemma at_top_to_right: "at_top = filtermap inverse (at_right (0::real))"
  1033   unfolding at_right_to_top filtermap_filtermap inverse_inverse_eq filtermap_ident ..
  1034 
  1035 lemma eventually_at_top_to_right:
  1036   "eventually P at_top \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) (at_right (0::real))"
  1037   unfolding at_top_to_right eventually_filtermap ..
  1038 
  1039 lemma filterlim_at_top_to_right:
  1040   "filterlim f F at_top \<longleftrightarrow> (LIM x (at_right (0::real)). f (inverse x) :> F)"
  1041   unfolding filterlim_def at_top_to_right filtermap_filtermap ..
  1042 
  1043 lemma filterlim_inverse_at_infinity:
  1044   fixes x :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring}"
  1045   shows "filterlim inverse at_infinity (at (0::'a))"
  1046   unfolding filterlim_at_infinity[OF order_refl]
  1047 proof safe
  1048   fix r :: real assume "0 < r"
  1049   then show "eventually (\<lambda>x::'a. r \<le> norm (inverse x)) (at 0)"
  1050     unfolding eventually_at norm_inverse
  1051     by (intro exI[of _ "inverse r"])
  1052        (auto simp: norm_conv_dist[symmetric] field_simps inverse_eq_divide)
  1053 qed
  1054 
  1055 lemma filterlim_inverse_at_iff:
  1056   fixes g :: "'a \<Rightarrow> 'b\<Colon>{real_normed_div_algebra, division_ring}"
  1057   shows "(LIM x F. inverse (g x) :> at 0) \<longleftrightarrow> (LIM x F. g x :> at_infinity)"
  1058   unfolding filterlim_def filtermap_filtermap[symmetric]
  1059 proof
  1060   assume "filtermap g F \<le> at_infinity"
  1061   then have "filtermap inverse (filtermap g F) \<le> filtermap inverse at_infinity"
  1062     by (rule filtermap_mono)
  1063   also have "\<dots> \<le> at 0"
  1064     using tendsto_inverse_0[where 'a='b]
  1065     by (auto intro!: exI[of _ 1]
  1066              simp: le_principal eventually_filtermap filterlim_def at_within_def eventually_at_infinity)
  1067   finally show "filtermap inverse (filtermap g F) \<le> at 0" .
  1068 next
  1069   assume "filtermap inverse (filtermap g F) \<le> at 0"
  1070   then have "filtermap inverse (filtermap inverse (filtermap g F)) \<le> filtermap inverse (at 0)"
  1071     by (rule filtermap_mono)
  1072   with filterlim_inverse_at_infinity show "filtermap g F \<le> at_infinity"
  1073     by (auto intro: order_trans simp: filterlim_def filtermap_filtermap)
  1074 qed
  1075 
  1076 lemma tendsto_inverse_0_at_top: "LIM x F. f x :> at_top \<Longrightarrow> ((\<lambda>x. inverse (f x) :: real) ---> 0) F"
  1077  by (metis filterlim_at filterlim_mono[OF _ at_top_le_at_infinity order_refl] filterlim_inverse_at_iff)
  1078 
  1079 
  1080 lemma at_to_infinity:
  1081   fixes x :: "'a \<Colon> {real_normed_field,field}"
  1082   shows "(at (0::'a)) = filtermap inverse at_infinity"
  1083 proof (rule antisym)
  1084   have "(inverse ---> (0::'a)) at_infinity"
  1085     by (fact tendsto_inverse_0)
  1086   then show "filtermap inverse at_infinity \<le> at (0::'a)"
  1087     apply (simp add: le_principal eventually_filtermap eventually_at_infinity filterlim_def at_within_def)
  1088     apply (rule_tac x="1" in exI, auto)
  1089     done
  1090 next
  1091   have "filtermap inverse (filtermap inverse (at (0::'a))) \<le> filtermap inverse at_infinity"
  1092     using filterlim_inverse_at_infinity unfolding filterlim_def
  1093     by (rule filtermap_mono)
  1094   then show "at (0::'a) \<le> filtermap inverse at_infinity"
  1095     by (simp add: filtermap_ident filtermap_filtermap)
  1096 qed
  1097 
  1098 lemma lim_at_infinity_0:
  1099   fixes l :: "'a :: {real_normed_field,field}"
  1100   shows "(f ---> l) at_infinity \<longleftrightarrow> ((f o inverse) ---> l) (at (0::'a))"
  1101 by (simp add: tendsto_compose_filtermap at_to_infinity filtermap_filtermap)
  1102 
  1103 lemma lim_zero_infinity:
  1104   fixes l :: "'a :: {real_normed_field,field}"
  1105   shows "((\<lambda>x. f(1 / x)) ---> l) (at (0::'a)) \<Longrightarrow> (f ---> l) at_infinity"
  1106 by (simp add: inverse_eq_divide lim_at_infinity_0 comp_def)
  1107 
  1108 
  1109 text \<open>
  1110 
  1111 We only show rules for multiplication and addition when the functions are either against a real
  1112 value or against infinity. Further rules are easy to derive by using @{thm filterlim_uminus_at_top}.
  1113 
  1114 \<close>
  1115 
  1116 lemma filterlim_tendsto_pos_mult_at_top:
  1117   assumes f: "(f ---> c) F" and c: "0 < c"
  1118   assumes g: "LIM x F. g x :> at_top"
  1119   shows "LIM x F. (f x * g x :: real) :> at_top"
  1120   unfolding filterlim_at_top_gt[where c=0]
  1121 proof safe
  1122   fix Z :: real assume "0 < Z"
  1123   from f \<open>0 < c\<close> have "eventually (\<lambda>x. c / 2 < f x) F"
  1124     by (auto dest!: tendstoD[where e="c / 2"] elim!: eventually_elim1
  1125              simp: dist_real_def abs_real_def split: split_if_asm)
  1126   moreover from g have "eventually (\<lambda>x. (Z / c * 2) \<le> g x) F"
  1127     unfolding filterlim_at_top by auto
  1128   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1129   proof eventually_elim
  1130     fix x assume "c / 2 < f x" "Z / c * 2 \<le> g x"
  1131     with \<open>0 < Z\<close> \<open>0 < c\<close> have "c / 2 * (Z / c * 2) \<le> f x * g x"
  1132       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1133     with \<open>0 < c\<close> show "Z \<le> f x * g x"
  1134        by simp
  1135   qed
  1136 qed
  1137 
  1138 lemma filterlim_at_top_mult_at_top:
  1139   assumes f: "LIM x F. f x :> at_top"
  1140   assumes g: "LIM x F. g x :> at_top"
  1141   shows "LIM x F. (f x * g x :: real) :> at_top"
  1142   unfolding filterlim_at_top_gt[where c=0]
  1143 proof safe
  1144   fix Z :: real assume "0 < Z"
  1145   from f have "eventually (\<lambda>x. 1 \<le> f x) F"
  1146     unfolding filterlim_at_top by auto
  1147   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1148     unfolding filterlim_at_top by auto
  1149   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1150   proof eventually_elim
  1151     fix x assume "1 \<le> f x" "Z \<le> g x"
  1152     with \<open>0 < Z\<close> have "1 * Z \<le> f x * g x"
  1153       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1154     then show "Z \<le> f x * g x"
  1155        by simp
  1156   qed
  1157 qed
  1158 
  1159 lemma filterlim_tendsto_pos_mult_at_bot:
  1160   assumes "(f ---> c) F" "0 < (c::real)" "filterlim g at_bot F"
  1161   shows "LIM x F. f x * g x :> at_bot"
  1162   using filterlim_tendsto_pos_mult_at_top[OF assms(1,2), of "\<lambda>x. - g x"] assms(3)
  1163   unfolding filterlim_uminus_at_bot by simp
  1164 
  1165 lemma filterlim_tendsto_neg_mult_at_bot:
  1166   assumes c: "(f ---> c) F" "(c::real) < 0" and g: "filterlim g at_top F"
  1167   shows "LIM x F. f x * g x :> at_bot"
  1168   using c filterlim_tendsto_pos_mult_at_top[of "\<lambda>x. - f x" "- c" F, OF _ _ g]
  1169   unfolding filterlim_uminus_at_bot tendsto_minus_cancel_left by simp
  1170 
  1171 lemma filterlim_pow_at_top:
  1172   fixes f :: "real \<Rightarrow> real"
  1173   assumes "0 < n" and f: "LIM x F. f x :> at_top"
  1174   shows "LIM x F. (f x)^n :: real :> at_top"
  1175 using \<open>0 < n\<close> proof (induct n)
  1176   case (Suc n) with f show ?case
  1177     by (cases "n = 0") (auto intro!: filterlim_at_top_mult_at_top)
  1178 qed simp
  1179 
  1180 lemma filterlim_pow_at_bot_even:
  1181   fixes f :: "real \<Rightarrow> real"
  1182   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> even n \<Longrightarrow> LIM x F. (f x)^n :> at_top"
  1183   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_top)
  1184 
  1185 lemma filterlim_pow_at_bot_odd:
  1186   fixes f :: "real \<Rightarrow> real"
  1187   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> odd n \<Longrightarrow> LIM x F. (f x)^n :> at_bot"
  1188   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_bot)
  1189 
  1190 lemma filterlim_tendsto_add_at_top:
  1191   assumes f: "(f ---> c) F"
  1192   assumes g: "LIM x F. g x :> at_top"
  1193   shows "LIM x F. (f x + g x :: real) :> at_top"
  1194   unfolding filterlim_at_top_gt[where c=0]
  1195 proof safe
  1196   fix Z :: real assume "0 < Z"
  1197   from f have "eventually (\<lambda>x. c - 1 < f x) F"
  1198     by (auto dest!: tendstoD[where e=1] elim!: eventually_elim1 simp: dist_real_def)
  1199   moreover from g have "eventually (\<lambda>x. Z - (c - 1) \<le> g x) F"
  1200     unfolding filterlim_at_top by auto
  1201   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1202     by eventually_elim simp
  1203 qed
  1204 
  1205 lemma LIM_at_top_divide:
  1206   fixes f g :: "'a \<Rightarrow> real"
  1207   assumes f: "(f ---> a) F" "0 < a"
  1208   assumes g: "(g ---> 0) F" "eventually (\<lambda>x. 0 < g x) F"
  1209   shows "LIM x F. f x / g x :> at_top"
  1210   unfolding divide_inverse
  1211   by (rule filterlim_tendsto_pos_mult_at_top[OF f]) (rule filterlim_inverse_at_top[OF g])
  1212 
  1213 lemma filterlim_at_top_add_at_top:
  1214   assumes f: "LIM x F. f x :> at_top"
  1215   assumes g: "LIM x F. g x :> at_top"
  1216   shows "LIM x F. (f x + g x :: real) :> at_top"
  1217   unfolding filterlim_at_top_gt[where c=0]
  1218 proof safe
  1219   fix Z :: real assume "0 < Z"
  1220   from f have "eventually (\<lambda>x. 0 \<le> f x) F"
  1221     unfolding filterlim_at_top by auto
  1222   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1223     unfolding filterlim_at_top by auto
  1224   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1225     by eventually_elim simp
  1226 qed
  1227 
  1228 lemma tendsto_divide_0:
  1229   fixes f :: "_ \<Rightarrow> 'a\<Colon>{real_normed_div_algebra, division_ring}"
  1230   assumes f: "(f ---> c) F"
  1231   assumes g: "LIM x F. g x :> at_infinity"
  1232   shows "((\<lambda>x. f x / g x) ---> 0) F"
  1233   using tendsto_mult[OF f filterlim_compose[OF tendsto_inverse_0 g]] by (simp add: divide_inverse)
  1234 
  1235 lemma linear_plus_1_le_power:
  1236   fixes x :: real
  1237   assumes x: "0 \<le> x"
  1238   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1239 proof (induct n)
  1240   case (Suc n)
  1241   have "real (Suc n) * x + 1 \<le> (x + 1) * (real n * x + 1)"
  1242     by (simp add: field_simps real_of_nat_Suc x)
  1243   also have "\<dots> \<le> (x + 1)^Suc n"
  1244     using Suc x by (simp add: mult_left_mono)
  1245   finally show ?case .
  1246 qed simp
  1247 
  1248 lemma filterlim_realpow_sequentially_gt1:
  1249   fixes x :: "'a :: real_normed_div_algebra"
  1250   assumes x[arith]: "1 < norm x"
  1251   shows "LIM n sequentially. x ^ n :> at_infinity"
  1252 proof (intro filterlim_at_infinity[THEN iffD2] allI impI)
  1253   fix y :: real assume "0 < y"
  1254   have "0 < norm x - 1" by simp
  1255   then obtain N::nat where "y < real N * (norm x - 1)" by (blast dest: reals_Archimedean3)
  1256   also have "\<dots> \<le> real N * (norm x - 1) + 1" by simp
  1257   also have "\<dots> \<le> (norm x - 1 + 1) ^ N" by (rule linear_plus_1_le_power) simp
  1258   also have "\<dots> = norm x ^ N" by simp
  1259   finally have "\<forall>n\<ge>N. y \<le> norm x ^ n"
  1260     by (metis order_less_le_trans power_increasing order_less_imp_le x)
  1261   then show "eventually (\<lambda>n. y \<le> norm (x ^ n)) sequentially"
  1262     unfolding eventually_sequentially
  1263     by (auto simp: norm_power)
  1264 qed simp
  1265 
  1266 
  1267 subsection \<open>Limits of Sequences\<close>
  1268 
  1269 lemma [trans]: "X=Y ==> Y ----> z ==> X ----> z"
  1270   by simp
  1271 
  1272 lemma LIMSEQ_iff:
  1273   fixes L :: "'a::real_normed_vector"
  1274   shows "(X ----> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
  1275 unfolding lim_sequentially dist_norm ..
  1276 
  1277 lemma LIMSEQ_I:
  1278   fixes L :: "'a::real_normed_vector"
  1279   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X ----> L"
  1280 by (simp add: LIMSEQ_iff)
  1281 
  1282 lemma LIMSEQ_D:
  1283   fixes L :: "'a::real_normed_vector"
  1284   shows "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
  1285 by (simp add: LIMSEQ_iff)
  1286 
  1287 lemma LIMSEQ_linear: "\<lbrakk> X ----> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) ----> x"
  1288   unfolding tendsto_def eventually_sequentially
  1289   by (metis div_le_dividend div_mult_self1_is_m le_trans mult.commute)
  1290 
  1291 lemma Bseq_inverse_lemma:
  1292   fixes x :: "'a::real_normed_div_algebra"
  1293   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
  1294 apply (subst nonzero_norm_inverse, clarsimp)
  1295 apply (erule (1) le_imp_inverse_le)
  1296 done
  1297 
  1298 lemma Bseq_inverse:
  1299   fixes a :: "'a::real_normed_div_algebra"
  1300   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
  1301   by (rule Bfun_inverse)
  1302 
  1303 text\<open>Transformation of limit.\<close>
  1304 
  1305 lemma eventually_at2:
  1306   "eventually P (at a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. 0 < dist x a \<and> dist x a < d \<longrightarrow> P x)"
  1307   unfolding eventually_at dist_nz by auto
  1308 
  1309 lemma Lim_transform:
  1310   fixes a b :: "'a::real_normed_vector"
  1311   shows "\<lbrakk>(g ---> a) F; ((\<lambda>x. f x - g x) ---> 0) F\<rbrakk> \<Longrightarrow> (f ---> a) F"
  1312   using tendsto_add [of g a F "\<lambda>x. f x - g x" 0] by simp
  1313 
  1314 lemma Lim_transform2:
  1315   fixes a b :: "'a::real_normed_vector"
  1316   shows "\<lbrakk>(f ---> a) F; ((\<lambda>x. f x - g x) ---> 0) F\<rbrakk> \<Longrightarrow> (g ---> a) F"
  1317   by (erule Lim_transform) (simp add: tendsto_minus_cancel)
  1318 
  1319 lemma Lim_transform_eventually:
  1320   "eventually (\<lambda>x. f x = g x) net \<Longrightarrow> (f ---> l) net \<Longrightarrow> (g ---> l) net"
  1321   apply (rule topological_tendstoI)
  1322   apply (drule (2) topological_tendstoD)
  1323   apply (erule (1) eventually_elim2, simp)
  1324   done
  1325 
  1326 lemma Lim_transform_within:
  1327   assumes "0 < d"
  1328     and "\<forall>x'\<in>S. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  1329     and "(f ---> l) (at x within S)"
  1330   shows "(g ---> l) (at x within S)"
  1331 proof (rule Lim_transform_eventually)
  1332   show "eventually (\<lambda>x. f x = g x) (at x within S)"
  1333     using assms(1,2) by (auto simp: dist_nz eventually_at)
  1334   show "(f ---> l) (at x within S)" by fact
  1335 qed
  1336 
  1337 lemma Lim_transform_at:
  1338   assumes "0 < d"
  1339     and "\<forall>x'. 0 < dist x' x \<and> dist x' x < d \<longrightarrow> f x' = g x'"
  1340     and "(f ---> l) (at x)"
  1341   shows "(g ---> l) (at x)"
  1342   using _ assms(3)
  1343 proof (rule Lim_transform_eventually)
  1344   show "eventually (\<lambda>x. f x = g x) (at x)"
  1345     unfolding eventually_at2
  1346     using assms(1,2) by auto
  1347 qed
  1348 
  1349 text\<open>Common case assuming being away from some crucial point like 0.\<close>
  1350 
  1351 lemma Lim_transform_away_within:
  1352   fixes a b :: "'a::t1_space"
  1353   assumes "a \<noteq> b"
  1354     and "\<forall>x\<in>S. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1355     and "(f ---> l) (at a within S)"
  1356   shows "(g ---> l) (at a within S)"
  1357 proof (rule Lim_transform_eventually)
  1358   show "(f ---> l) (at a within S)" by fact
  1359   show "eventually (\<lambda>x. f x = g x) (at a within S)"
  1360     unfolding eventually_at_topological
  1361     by (rule exI [where x="- {b}"], simp add: open_Compl assms)
  1362 qed
  1363 
  1364 lemma Lim_transform_away_at:
  1365   fixes a b :: "'a::t1_space"
  1366   assumes ab: "a\<noteq>b"
  1367     and fg: "\<forall>x. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1368     and fl: "(f ---> l) (at a)"
  1369   shows "(g ---> l) (at a)"
  1370   using Lim_transform_away_within[OF ab, of UNIV f g l] fg fl by simp
  1371 
  1372 text\<open>Alternatively, within an open set.\<close>
  1373 
  1374 lemma Lim_transform_within_open:
  1375   assumes "open S" and "a \<in> S"
  1376     and "\<forall>x\<in>S. x \<noteq> a \<longrightarrow> f x = g x"
  1377     and "(f ---> l) (at a)"
  1378   shows "(g ---> l) (at a)"
  1379 proof (rule Lim_transform_eventually)
  1380   show "eventually (\<lambda>x. f x = g x) (at a)"
  1381     unfolding eventually_at_topological
  1382     using assms(1,2,3) by auto
  1383   show "(f ---> l) (at a)" by fact
  1384 qed
  1385 
  1386 text\<open>A congruence rule allowing us to transform limits assuming not at point.\<close>
  1387 
  1388 (* FIXME: Only one congruence rule for tendsto can be used at a time! *)
  1389 
  1390 lemma Lim_cong_within(*[cong add]*):
  1391   assumes "a = b"
  1392     and "x = y"
  1393     and "S = T"
  1394     and "\<And>x. x \<noteq> b \<Longrightarrow> x \<in> T \<Longrightarrow> f x = g x"
  1395   shows "(f ---> x) (at a within S) \<longleftrightarrow> (g ---> y) (at b within T)"
  1396   unfolding tendsto_def eventually_at_topological
  1397   using assms by simp
  1398 
  1399 lemma Lim_cong_at(*[cong add]*):
  1400   assumes "a = b" "x = y"
  1401     and "\<And>x. x \<noteq> a \<Longrightarrow> f x = g x"
  1402   shows "((\<lambda>x. f x) ---> x) (at a) \<longleftrightarrow> ((g ---> y) (at a))"
  1403   unfolding tendsto_def eventually_at_topological
  1404   using assms by simp
  1405 text\<open>An unbounded sequence's inverse tends to 0\<close>
  1406 
  1407 lemma LIMSEQ_inverse_zero:
  1408   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> 0"
  1409   apply (rule filterlim_compose[OF tendsto_inverse_0])
  1410   apply (simp add: filterlim_at_infinity[OF order_refl] eventually_sequentially)
  1411   apply (metis abs_le_D1 linorder_le_cases linorder_not_le)
  1412   done
  1413 
  1414 text\<open>The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity\<close>
  1415 
  1416 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) ----> 0"
  1417   by (metis filterlim_compose tendsto_inverse_0 filterlim_mono order_refl filterlim_Suc
  1418             filterlim_compose[OF filterlim_real_sequentially] at_top_le_at_infinity)
  1419 
  1420 text\<open>The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
  1421 infinity is now easily proved\<close>
  1422 
  1423 lemma LIMSEQ_inverse_real_of_nat_add:
  1424      "(%n. r + inverse(real(Suc n))) ----> r"
  1425   using tendsto_add [OF tendsto_const LIMSEQ_inverse_real_of_nat] by auto
  1426 
  1427 lemma LIMSEQ_inverse_real_of_nat_add_minus:
  1428      "(%n. r + -inverse(real(Suc n))) ----> r"
  1429   using tendsto_add [OF tendsto_const tendsto_minus [OF LIMSEQ_inverse_real_of_nat]]
  1430   by auto
  1431 
  1432 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
  1433      "(%n. r*( 1 + -inverse(real(Suc n)))) ----> r"
  1434   using tendsto_mult [OF tendsto_const LIMSEQ_inverse_real_of_nat_add_minus [of 1]]
  1435   by auto
  1436 
  1437 subsection \<open>Convergence on sequences\<close>
  1438 
  1439 lemma convergent_add:
  1440   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
  1441   assumes "convergent (\<lambda>n. X n)"
  1442   assumes "convergent (\<lambda>n. Y n)"
  1443   shows "convergent (\<lambda>n. X n + Y n)"
  1444   using assms unfolding convergent_def by (fast intro: tendsto_add)
  1445 
  1446 lemma convergent_setsum:
  1447   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
  1448   assumes "\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)"
  1449   shows "convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
  1450 proof (cases "finite A")
  1451   case True from this and assms show ?thesis
  1452     by (induct A set: finite) (simp_all add: convergent_const convergent_add)
  1453 qed (simp add: convergent_const)
  1454 
  1455 lemma (in bounded_linear) convergent:
  1456   assumes "convergent (\<lambda>n. X n)"
  1457   shows "convergent (\<lambda>n. f (X n))"
  1458   using assms unfolding convergent_def by (fast intro: tendsto)
  1459 
  1460 lemma (in bounded_bilinear) convergent:
  1461   assumes "convergent (\<lambda>n. X n)" and "convergent (\<lambda>n. Y n)"
  1462   shows "convergent (\<lambda>n. X n ** Y n)"
  1463   using assms unfolding convergent_def by (fast intro: tendsto)
  1464 
  1465 lemma convergent_minus_iff:
  1466   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1467   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
  1468 apply (simp add: convergent_def)
  1469 apply (auto dest: tendsto_minus)
  1470 apply (drule tendsto_minus, auto)
  1471 done
  1472 
  1473 
  1474 text \<open>A monotone sequence converges to its least upper bound.\<close>
  1475 
  1476 lemma LIMSEQ_incseq_SUP:
  1477   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder, linorder_topology}"
  1478   assumes u: "bdd_above (range X)"
  1479   assumes X: "incseq X"
  1480   shows "X ----> (SUP i. X i)"
  1481   by (rule order_tendstoI)
  1482      (auto simp: eventually_sequentially u less_cSUP_iff intro: X[THEN incseqD] less_le_trans cSUP_lessD[OF u])
  1483 
  1484 lemma LIMSEQ_decseq_INF:
  1485   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder, linorder_topology}"
  1486   assumes u: "bdd_below (range X)"
  1487   assumes X: "decseq X"
  1488   shows "X ----> (INF i. X i)"
  1489   by (rule order_tendstoI)
  1490      (auto simp: eventually_sequentially u cINF_less_iff intro: X[THEN decseqD] le_less_trans less_cINF_D[OF u])
  1491 
  1492 text\<open>Main monotonicity theorem\<close>
  1493 
  1494 lemma Bseq_monoseq_convergent: "Bseq X \<Longrightarrow> monoseq X \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
  1495   by (auto simp: monoseq_iff convergent_def intro: LIMSEQ_decseq_INF LIMSEQ_incseq_SUP dest: Bseq_bdd_above Bseq_bdd_below)
  1496 
  1497 lemma Bseq_mono_convergent: "Bseq X \<Longrightarrow> (\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n) \<Longrightarrow> convergent (X::nat\<Rightarrow>real)"
  1498   by (auto intro!: Bseq_monoseq_convergent incseq_imp_monoseq simp: incseq_def)
  1499 
  1500 lemma Cauchy_iff:
  1501   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1502   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  1503   unfolding Cauchy_def dist_norm ..
  1504 
  1505 lemma CauchyI:
  1506   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1507   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  1508 by (simp add: Cauchy_iff)
  1509 
  1510 lemma CauchyD:
  1511   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1512   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  1513 by (simp add: Cauchy_iff)
  1514 
  1515 lemma incseq_convergent:
  1516   fixes X :: "nat \<Rightarrow> real"
  1517   assumes "incseq X" and "\<forall>i. X i \<le> B"
  1518   obtains L where "X ----> L" "\<forall>i. X i \<le> L"
  1519 proof atomize_elim
  1520   from incseq_bounded[OF assms] \<open>incseq X\<close> Bseq_monoseq_convergent[of X]
  1521   obtain L where "X ----> L"
  1522     by (auto simp: convergent_def monoseq_def incseq_def)
  1523   with \<open>incseq X\<close> show "\<exists>L. X ----> L \<and> (\<forall>i. X i \<le> L)"
  1524     by (auto intro!: exI[of _ L] incseq_le)
  1525 qed
  1526 
  1527 lemma decseq_convergent:
  1528   fixes X :: "nat \<Rightarrow> real"
  1529   assumes "decseq X" and "\<forall>i. B \<le> X i"
  1530   obtains L where "X ----> L" "\<forall>i. L \<le> X i"
  1531 proof atomize_elim
  1532   from decseq_bounded[OF assms] \<open>decseq X\<close> Bseq_monoseq_convergent[of X]
  1533   obtain L where "X ----> L"
  1534     by (auto simp: convergent_def monoseq_def decseq_def)
  1535   with \<open>decseq X\<close> show "\<exists>L. X ----> L \<and> (\<forall>i. L \<le> X i)"
  1536     by (auto intro!: exI[of _ L] decseq_le)
  1537 qed
  1538 
  1539 subsubsection \<open>Cauchy Sequences are Bounded\<close>
  1540 
  1541 text\<open>A Cauchy sequence is bounded -- this is the standard
  1542   proof mechanization rather than the nonstandard proof\<close>
  1543 
  1544 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
  1545           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
  1546 apply (clarify, drule spec, drule (1) mp)
  1547 apply (simp only: norm_minus_commute)
  1548 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
  1549 apply simp
  1550 done
  1551 
  1552 subsection \<open>Power Sequences\<close>
  1553 
  1554 text\<open>The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1555 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1556   also fact that bounded and monotonic sequence converges.\<close>
  1557 
  1558 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1559 apply (simp add: Bseq_def)
  1560 apply (rule_tac x = 1 in exI)
  1561 apply (simp add: power_abs)
  1562 apply (auto dest: power_mono)
  1563 done
  1564 
  1565 lemma monoseq_realpow: fixes x :: real shows "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1566 apply (clarify intro!: mono_SucI2)
  1567 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1568 done
  1569 
  1570 lemma convergent_realpow:
  1571   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1572 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1573 
  1574 lemma LIMSEQ_inverse_realpow_zero: "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) ----> 0"
  1575   by (rule filterlim_compose[OF tendsto_inverse_0 filterlim_realpow_sequentially_gt1]) simp
  1576 
  1577 lemma LIMSEQ_realpow_zero:
  1578   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1579 proof cases
  1580   assume "0 \<le> x" and "x \<noteq> 0"
  1581   hence x0: "0 < x" by simp
  1582   assume x1: "x < 1"
  1583   from x0 x1 have "1 < inverse x"
  1584     by (rule one_less_inverse)
  1585   hence "(\<lambda>n. inverse (inverse x ^ n)) ----> 0"
  1586     by (rule LIMSEQ_inverse_realpow_zero)
  1587   thus ?thesis by (simp add: power_inverse)
  1588 qed (rule LIMSEQ_imp_Suc, simp)
  1589 
  1590 lemma LIMSEQ_power_zero:
  1591   fixes x :: "'a::{real_normed_algebra_1}"
  1592   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1593 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1594 apply (simp only: tendsto_Zfun_iff, erule Zfun_le)
  1595 apply (simp add: power_abs norm_power_ineq)
  1596 done
  1597 
  1598 lemma LIMSEQ_divide_realpow_zero: "1 < x \<Longrightarrow> (\<lambda>n. a / (x ^ n) :: real) ----> 0"
  1599   by (rule tendsto_divide_0 [OF tendsto_const filterlim_realpow_sequentially_gt1]) simp
  1600 
  1601 text\<open>Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}\<close>
  1602 
  1603 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. \<bar>c\<bar> ^ n :: real) ----> 0"
  1604   by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1605 
  1606 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. c ^ n :: real) ----> 0"
  1607   by (rule LIMSEQ_power_zero) simp
  1608 
  1609 
  1610 subsection \<open>Limits of Functions\<close>
  1611 
  1612 lemma LIM_eq:
  1613   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1614   shows "f -- a --> L =
  1615      (\<forall>r>0.\<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)"
  1616 by (simp add: LIM_def dist_norm)
  1617 
  1618 lemma LIM_I:
  1619   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1620   shows "(!!r. 0<r ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r)
  1621       ==> f -- a --> L"
  1622 by (simp add: LIM_eq)
  1623 
  1624 lemma LIM_D:
  1625   fixes a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  1626   shows "[| f -- a --> L; 0<r |]
  1627       ==> \<exists>s>0.\<forall>x. x \<noteq> a & norm (x-a) < s --> norm (f x - L) < r"
  1628 by (simp add: LIM_eq)
  1629 
  1630 lemma LIM_offset:
  1631   fixes a :: "'a::real_normed_vector"
  1632   shows "f -- a --> L \<Longrightarrow> (\<lambda>x. f (x + k)) -- a - k --> L"
  1633   unfolding filtermap_at_shift[symmetric, of a k] filterlim_def filtermap_filtermap by simp
  1634 
  1635 lemma LIM_offset_zero:
  1636   fixes a :: "'a::real_normed_vector"
  1637   shows "f -- a --> L \<Longrightarrow> (\<lambda>h. f (a + h)) -- 0 --> L"
  1638 by (drule_tac k="a" in LIM_offset, simp add: add.commute)
  1639 
  1640 lemma LIM_offset_zero_cancel:
  1641   fixes a :: "'a::real_normed_vector"
  1642   shows "(\<lambda>h. f (a + h)) -- 0 --> L \<Longrightarrow> f -- a --> L"
  1643 by (drule_tac k="- a" in LIM_offset, simp)
  1644 
  1645 lemma LIM_offset_zero_iff:
  1646   fixes f :: "'a :: real_normed_vector \<Rightarrow> _"
  1647   shows  "f -- a --> L \<longleftrightarrow> (\<lambda>h. f (a + h)) -- 0 --> L"
  1648   using LIM_offset_zero_cancel[of f a L] LIM_offset_zero[of f L a] by auto
  1649 
  1650 lemma LIM_zero:
  1651   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1652   shows "(f ---> l) F \<Longrightarrow> ((\<lambda>x. f x - l) ---> 0) F"
  1653 unfolding tendsto_iff dist_norm by simp
  1654 
  1655 lemma LIM_zero_cancel:
  1656   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1657   shows "((\<lambda>x. f x - l) ---> 0) F \<Longrightarrow> (f ---> l) F"
  1658 unfolding tendsto_iff dist_norm by simp
  1659 
  1660 lemma LIM_zero_iff:
  1661   fixes f :: "'a::metric_space \<Rightarrow> 'b::real_normed_vector"
  1662   shows "((\<lambda>x. f x - l) ---> 0) F = (f ---> l) F"
  1663 unfolding tendsto_iff dist_norm by simp
  1664 
  1665 lemma LIM_imp_LIM:
  1666   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1667   fixes g :: "'a::topological_space \<Rightarrow> 'c::real_normed_vector"
  1668   assumes f: "f -- a --> l"
  1669   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> norm (g x - m) \<le> norm (f x - l)"
  1670   shows "g -- a --> m"
  1671   by (rule metric_LIM_imp_LIM [OF f],
  1672     simp add: dist_norm le)
  1673 
  1674 lemma LIM_equal2:
  1675   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1676   assumes 1: "0 < R"
  1677   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; norm (x - a) < R\<rbrakk> \<Longrightarrow> f x = g x"
  1678   shows "g -- a --> l \<Longrightarrow> f -- a --> l"
  1679 by (rule metric_LIM_equal2 [OF 1 2], simp_all add: dist_norm)
  1680 
  1681 lemma LIM_compose2:
  1682   fixes a :: "'a::real_normed_vector"
  1683   assumes f: "f -- a --> b"
  1684   assumes g: "g -- b --> c"
  1685   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> b"
  1686   shows "(\<lambda>x. g (f x)) -- a --> c"
  1687 by (rule metric_LIM_compose2 [OF f g inj [folded dist_norm]])
  1688 
  1689 lemma real_LIM_sandwich_zero:
  1690   fixes f g :: "'a::topological_space \<Rightarrow> real"
  1691   assumes f: "f -- a --> 0"
  1692   assumes 1: "\<And>x. x \<noteq> a \<Longrightarrow> 0 \<le> g x"
  1693   assumes 2: "\<And>x. x \<noteq> a \<Longrightarrow> g x \<le> f x"
  1694   shows "g -- a --> 0"
  1695 proof (rule LIM_imp_LIM [OF f]) (* FIXME: use tendsto_sandwich *)
  1696   fix x assume x: "x \<noteq> a"
  1697   have "norm (g x - 0) = g x" by (simp add: 1 x)
  1698   also have "g x \<le> f x" by (rule 2 [OF x])
  1699   also have "f x \<le> \<bar>f x\<bar>" by (rule abs_ge_self)
  1700   also have "\<bar>f x\<bar> = norm (f x - 0)" by simp
  1701   finally show "norm (g x - 0) \<le> norm (f x - 0)" .
  1702 qed
  1703 
  1704 
  1705 subsection \<open>Continuity\<close>
  1706 
  1707 lemma LIM_isCont_iff:
  1708   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1709   shows "(f -- a --> f a) = ((\<lambda>h. f (a + h)) -- 0 --> f a)"
  1710 by (rule iffI [OF LIM_offset_zero LIM_offset_zero_cancel])
  1711 
  1712 lemma isCont_iff:
  1713   fixes f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  1714   shows "isCont f x = (\<lambda>h. f (x + h)) -- 0 --> f x"
  1715 by (simp add: isCont_def LIM_isCont_iff)
  1716 
  1717 lemma isCont_LIM_compose2:
  1718   fixes a :: "'a::real_normed_vector"
  1719   assumes f [unfolded isCont_def]: "isCont f a"
  1720   assumes g: "g -- f a --> l"
  1721   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> f a"
  1722   shows "(\<lambda>x. g (f x)) -- a --> l"
  1723 by (rule LIM_compose2 [OF f g inj])
  1724 
  1725 
  1726 lemma isCont_norm [simp]:
  1727   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1728   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. norm (f x)) a"
  1729   by (fact continuous_norm)
  1730 
  1731 lemma isCont_rabs [simp]:
  1732   fixes f :: "'a::t2_space \<Rightarrow> real"
  1733   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. \<bar>f x\<bar>) a"
  1734   by (fact continuous_rabs)
  1735 
  1736 lemma isCont_add [simp]:
  1737   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1738   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x + g x) a"
  1739   by (fact continuous_add)
  1740 
  1741 lemma isCont_minus [simp]:
  1742   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1743   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. - f x) a"
  1744   by (fact continuous_minus)
  1745 
  1746 lemma isCont_diff [simp]:
  1747   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1748   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x - g x) a"
  1749   by (fact continuous_diff)
  1750 
  1751 lemma isCont_mult [simp]:
  1752   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_algebra"
  1753   shows "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x * g x) a"
  1754   by (fact continuous_mult)
  1755 
  1756 lemma (in bounded_linear) isCont:
  1757   "isCont g a \<Longrightarrow> isCont (\<lambda>x. f (g x)) a"
  1758   by (fact continuous)
  1759 
  1760 lemma (in bounded_bilinear) isCont:
  1761   "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. f x ** g x) a"
  1762   by (fact continuous)
  1763 
  1764 lemmas isCont_scaleR [simp] =
  1765   bounded_bilinear.isCont [OF bounded_bilinear_scaleR]
  1766 
  1767 lemmas isCont_of_real [simp] =
  1768   bounded_linear.isCont [OF bounded_linear_of_real]
  1769 
  1770 lemma isCont_power [simp]:
  1771   fixes f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
  1772   shows "isCont f a \<Longrightarrow> isCont (\<lambda>x. f x ^ n) a"
  1773   by (fact continuous_power)
  1774 
  1775 lemma isCont_setsum [simp]:
  1776   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::real_normed_vector"
  1777   shows "\<forall>i\<in>A. isCont (f i) a \<Longrightarrow> isCont (\<lambda>x. \<Sum>i\<in>A. f i x) a"
  1778   by (auto intro: continuous_setsum)
  1779 
  1780 subsection \<open>Uniform Continuity\<close>
  1781 
  1782 definition
  1783   isUCont :: "['a::metric_space \<Rightarrow> 'b::metric_space] \<Rightarrow> bool" where
  1784   "isUCont f = (\<forall>r>0. \<exists>s>0. \<forall>x y. dist x y < s \<longrightarrow> dist (f x) (f y) < r)"
  1785 
  1786 lemma isUCont_isCont: "isUCont f ==> isCont f x"
  1787 by (simp add: isUCont_def isCont_def LIM_def, force)
  1788 
  1789 lemma isUCont_Cauchy:
  1790   "\<lbrakk>isUCont f; Cauchy X\<rbrakk> \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  1791 unfolding isUCont_def
  1792 apply (rule metric_CauchyI)
  1793 apply (drule_tac x=e in spec, safe)
  1794 apply (drule_tac e=s in metric_CauchyD, safe)
  1795 apply (rule_tac x=M in exI, simp)
  1796 done
  1797 
  1798 lemma (in bounded_linear) isUCont: "isUCont f"
  1799 unfolding isUCont_def dist_norm
  1800 proof (intro allI impI)
  1801   fix r::real assume r: "0 < r"
  1802   obtain K where K: "0 < K" and norm_le: "\<And>x. norm (f x) \<le> norm x * K"
  1803     using pos_bounded by fast
  1804   show "\<exists>s>0. \<forall>x y. norm (x - y) < s \<longrightarrow> norm (f x - f y) < r"
  1805   proof (rule exI, safe)
  1806     from r K show "0 < r / K" by simp
  1807   next
  1808     fix x y :: 'a
  1809     assume xy: "norm (x - y) < r / K"
  1810     have "norm (f x - f y) = norm (f (x - y))" by (simp only: diff)
  1811     also have "\<dots> \<le> norm (x - y) * K" by (rule norm_le)
  1812     also from K xy have "\<dots> < r" by (simp only: pos_less_divide_eq)
  1813     finally show "norm (f x - f y) < r" .
  1814   qed
  1815 qed
  1816 
  1817 lemma (in bounded_linear) Cauchy: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  1818 by (rule isUCont [THEN isUCont_Cauchy])
  1819 
  1820 lemma LIM_less_bound:
  1821   fixes f :: "real \<Rightarrow> real"
  1822   assumes ev: "b < x" "\<forall> x' \<in> { b <..< x}. 0 \<le> f x'" and "isCont f x"
  1823   shows "0 \<le> f x"
  1824 proof (rule tendsto_le_const)
  1825   show "(f ---> f x) (at_left x)"
  1826     using \<open>isCont f x\<close> by (simp add: filterlim_at_split isCont_def)
  1827   show "eventually (\<lambda>x. 0 \<le> f x) (at_left x)"
  1828     using ev by (auto simp: eventually_at dist_real_def intro!: exI[of _ "x - b"])
  1829 qed simp
  1830 
  1831 
  1832 subsection \<open>Nested Intervals and Bisection -- Needed for Compactness\<close>
  1833 
  1834 lemma nested_sequence_unique:
  1835   assumes "\<forall>n. f n \<le> f (Suc n)" "\<forall>n. g (Suc n) \<le> g n" "\<forall>n. f n \<le> g n" "(\<lambda>n. f n - g n) ----> 0"
  1836   shows "\<exists>l::real. ((\<forall>n. f n \<le> l) \<and> f ----> l) \<and> ((\<forall>n. l \<le> g n) \<and> g ----> l)"
  1837 proof -
  1838   have "incseq f" unfolding incseq_Suc_iff by fact
  1839   have "decseq g" unfolding decseq_Suc_iff by fact
  1840 
  1841   { fix n
  1842     from \<open>decseq g\<close> have "g n \<le> g 0" by (rule decseqD) simp
  1843     with \<open>\<forall>n. f n \<le> g n\<close>[THEN spec, of n] have "f n \<le> g 0" by auto }
  1844   then obtain u where "f ----> u" "\<forall>i. f i \<le> u"
  1845     using incseq_convergent[OF \<open>incseq f\<close>] by auto
  1846   moreover
  1847   { fix n
  1848     from \<open>incseq f\<close> have "f 0 \<le> f n" by (rule incseqD) simp
  1849     with \<open>\<forall>n. f n \<le> g n\<close>[THEN spec, of n] have "f 0 \<le> g n" by simp }
  1850   then obtain l where "g ----> l" "\<forall>i. l \<le> g i"
  1851     using decseq_convergent[OF \<open>decseq g\<close>] by auto
  1852   moreover note LIMSEQ_unique[OF assms(4) tendsto_diff[OF \<open>f ----> u\<close> \<open>g ----> l\<close>]]
  1853   ultimately show ?thesis by auto
  1854 qed
  1855 
  1856 lemma Bolzano[consumes 1, case_names trans local]:
  1857   fixes P :: "real \<Rightarrow> real \<Rightarrow> bool"
  1858   assumes [arith]: "a \<le> b"
  1859   assumes trans: "\<And>a b c. \<lbrakk>P a b; P b c; a \<le> b; b \<le> c\<rbrakk> \<Longrightarrow> P a c"
  1860   assumes local: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> \<exists>d>0. \<forall>a b. a \<le> x \<and> x \<le> b \<and> b - a < d \<longrightarrow> P a b"
  1861   shows "P a b"
  1862 proof -
  1863   def bisect \<equiv> "rec_nat (a, b) (\<lambda>n (x, y). if P x ((x+y) / 2) then ((x+y)/2, y) else (x, (x+y)/2))"
  1864   def l \<equiv> "\<lambda>n. fst (bisect n)" and u \<equiv> "\<lambda>n. snd (bisect n)"
  1865   have l[simp]: "l 0 = a" "\<And>n. l (Suc n) = (if P (l n) ((l n + u n) / 2) then (l n + u n) / 2 else l n)"
  1866     and u[simp]: "u 0 = b" "\<And>n. u (Suc n) = (if P (l n) ((l n + u n) / 2) then u n else (l n + u n) / 2)"
  1867     by (simp_all add: l_def u_def bisect_def split: prod.split)
  1868 
  1869   { fix n have "l n \<le> u n" by (induct n) auto } note this[simp]
  1870 
  1871   have "\<exists>x. ((\<forall>n. l n \<le> x) \<and> l ----> x) \<and> ((\<forall>n. x \<le> u n) \<and> u ----> x)"
  1872   proof (safe intro!: nested_sequence_unique)
  1873     fix n show "l n \<le> l (Suc n)" "u (Suc n) \<le> u n" by (induct n) auto
  1874   next
  1875     { fix n have "l n - u n = (a - b) / 2^n" by (induct n) (auto simp: field_simps) }
  1876     then show "(\<lambda>n. l n - u n) ----> 0" by (simp add: LIMSEQ_divide_realpow_zero)
  1877   qed fact
  1878   then obtain x where x: "\<And>n. l n \<le> x" "\<And>n. x \<le> u n" and "l ----> x" "u ----> x" by auto
  1879   obtain d where "0 < d" and d: "\<And>a b. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> b - a < d \<Longrightarrow> P a b"
  1880     using \<open>l 0 \<le> x\<close> \<open>x \<le> u 0\<close> local[of x] by auto
  1881 
  1882   show "P a b"
  1883   proof (rule ccontr)
  1884     assume "\<not> P a b"
  1885     { fix n have "\<not> P (l n) (u n)"
  1886       proof (induct n)
  1887         case (Suc n) with trans[of "l n" "(l n + u n) / 2" "u n"] show ?case by auto
  1888       qed (simp add: \<open>\<not> P a b\<close>) }
  1889     moreover
  1890     { have "eventually (\<lambda>n. x - d / 2 < l n) sequentially"
  1891         using \<open>0 < d\<close> \<open>l ----> x\<close> by (intro order_tendstoD[of _ x]) auto
  1892       moreover have "eventually (\<lambda>n. u n < x + d / 2) sequentially"
  1893         using \<open>0 < d\<close> \<open>u ----> x\<close> by (intro order_tendstoD[of _ x]) auto
  1894       ultimately have "eventually (\<lambda>n. P (l n) (u n)) sequentially"
  1895       proof eventually_elim
  1896         fix n assume "x - d / 2 < l n" "u n < x + d / 2"
  1897         from add_strict_mono[OF this] have "u n - l n < d" by simp
  1898         with x show "P (l n) (u n)" by (rule d)
  1899       qed }
  1900     ultimately show False by simp
  1901   qed
  1902 qed
  1903 
  1904 lemma compact_Icc[simp, intro]: "compact {a .. b::real}"
  1905 proof (cases "a \<le> b", rule compactI)
  1906   fix C assume C: "a \<le> b" "\<forall>t\<in>C. open t" "{a..b} \<subseteq> \<Union>C"
  1907   def T == "{a .. b}"
  1908   from C(1,3) show "\<exists>C'\<subseteq>C. finite C' \<and> {a..b} \<subseteq> \<Union>C'"
  1909   proof (induct rule: Bolzano)
  1910     case (trans a b c)
  1911     then have *: "{a .. c} = {a .. b} \<union> {b .. c}" by auto
  1912     from trans obtain C1 C2 where "C1\<subseteq>C \<and> finite C1 \<and> {a..b} \<subseteq> \<Union>C1" "C2\<subseteq>C \<and> finite C2 \<and> {b..c} \<subseteq> \<Union>C2"
  1913       by (auto simp: *)
  1914     with trans show ?case
  1915       unfolding * by (intro exI[of _ "C1 \<union> C2"]) auto
  1916   next
  1917     case (local x)
  1918     then have "x \<in> \<Union>C" using C by auto
  1919     with C(2) obtain c where "x \<in> c" "open c" "c \<in> C" by auto
  1920     then obtain e where "0 < e" "{x - e <..< x + e} \<subseteq> c"
  1921       by (auto simp: open_real_def dist_real_def subset_eq Ball_def abs_less_iff)
  1922     with \<open>c \<in> C\<close> show ?case
  1923       by (safe intro!: exI[of _ "e/2"] exI[of _ "{c}"]) auto
  1924   qed
  1925 qed simp
  1926 
  1927 
  1928 lemma continuous_image_closed_interval:
  1929   fixes a b and f :: "real \<Rightarrow> real"
  1930   defines "S \<equiv> {a..b}"
  1931   assumes "a \<le> b" and f: "continuous_on S f"
  1932   shows "\<exists>c d. f`S = {c..d} \<and> c \<le> d"
  1933 proof -
  1934   have S: "compact S" "S \<noteq> {}"
  1935     using \<open>a \<le> b\<close> by (auto simp: S_def)
  1936   obtain c where "c \<in> S" "\<forall>d\<in>S. f d \<le> f c"
  1937     using continuous_attains_sup[OF S f] by auto
  1938   moreover obtain d where "d \<in> S" "\<forall>c\<in>S. f d \<le> f c"
  1939     using continuous_attains_inf[OF S f] by auto
  1940   moreover have "connected (f`S)"
  1941     using connected_continuous_image[OF f] connected_Icc by (auto simp: S_def)
  1942   ultimately have "f ` S = {f d .. f c} \<and> f d \<le> f c"
  1943     by (auto simp: connected_iff_interval)
  1944   then show ?thesis
  1945     by auto
  1946 qed
  1947 
  1948 lemma open_Collect_positive:
  1949  fixes f :: "'a::t2_space \<Rightarrow> real"
  1950  assumes f: "continuous_on s f"
  1951  shows "\<exists>A. open A \<and> A \<inter> s = {x\<in>s. 0 < f x}"
  1952  using continuous_on_open_invariant[THEN iffD1, OF f, rule_format, of "{0 <..}"]
  1953  by (auto simp: Int_def field_simps)
  1954 
  1955 lemma open_Collect_less_Int:
  1956  fixes f g :: "'a::t2_space \<Rightarrow> real"
  1957  assumes f: "continuous_on s f" and g: "continuous_on s g"
  1958  shows "\<exists>A. open A \<and> A \<inter> s = {x\<in>s. f x < g x}"
  1959  using open_Collect_positive[OF continuous_on_diff[OF g f]] by (simp add: field_simps)
  1960 
  1961 
  1962 subsection \<open>Boundedness of continuous functions\<close>
  1963 
  1964 text\<open>By bisection, function continuous on closed interval is bounded above\<close>
  1965 
  1966 lemma isCont_eq_Ub:
  1967   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1968   shows "a \<le> b \<Longrightarrow> \<forall>x::real. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1969     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  1970   using continuous_attains_sup[of "{a .. b}" f]
  1971   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  1972 
  1973 lemma isCont_eq_Lb:
  1974   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1975   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1976     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> M \<le> f x) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  1977   using continuous_attains_inf[of "{a .. b}" f]
  1978   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  1979 
  1980 lemma isCont_bounded:
  1981   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1982   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow> \<exists>M. \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M"
  1983   using isCont_eq_Ub[of a b f] by auto
  1984 
  1985 lemma isCont_has_Ub:
  1986   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  1987   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  1988     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<forall>N. N < M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> N < f x))"
  1989   using isCont_eq_Ub[of a b f] by auto
  1990 
  1991 (*HOL style here: object-level formulations*)
  1992 lemma IVT_objl: "(f(a::real) \<le> (y::real) & y \<le> f(b) & a \<le> b &
  1993       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  1994       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  1995   by (blast intro: IVT)
  1996 
  1997 lemma IVT2_objl: "(f(b::real) \<le> (y::real) & y \<le> f(a) & a \<le> b &
  1998       (\<forall>x. a \<le> x & x \<le> b --> isCont f x))
  1999       --> (\<exists>x. a \<le> x & x \<le> b & f(x) = y)"
  2000   by (blast intro: IVT2)
  2001 
  2002 lemma isCont_Lb_Ub:
  2003   fixes f :: "real \<Rightarrow> real"
  2004   assumes "a \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  2005   shows "\<exists>L M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> L \<le> f x \<and> f x \<le> M) \<and>
  2006                (\<forall>y. L \<le> y \<and> y \<le> M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> (f x = y)))"
  2007 proof -
  2008   obtain M where M: "a \<le> M" "M \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> f M"
  2009     using isCont_eq_Ub[OF assms] by auto
  2010   obtain L where L: "a \<le> L" "L \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f L \<le> f x"
  2011     using isCont_eq_Lb[OF assms] by auto
  2012   show ?thesis
  2013     using IVT[of f L _ M] IVT2[of f L _ M] M L assms
  2014     apply (rule_tac x="f L" in exI)
  2015     apply (rule_tac x="f M" in exI)
  2016     apply (cases "L \<le> M")
  2017     apply (simp, metis order_trans)
  2018     apply (simp, metis order_trans)
  2019     done
  2020 qed
  2021 
  2022 
  2023 text\<open>Continuity of inverse function\<close>
  2024 
  2025 lemma isCont_inverse_function:
  2026   fixes f g :: "real \<Rightarrow> real"
  2027   assumes d: "0 < d"
  2028       and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> g (f z) = z"
  2029       and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> isCont f z"
  2030   shows "isCont g (f x)"
  2031 proof -
  2032   let ?A = "f (x - d)" and ?B = "f (x + d)" and ?D = "{x - d..x + d}"
  2033 
  2034   have f: "continuous_on ?D f"
  2035     using cont by (intro continuous_at_imp_continuous_on ballI) auto
  2036   then have g: "continuous_on (f`?D) g"
  2037     using inj by (intro continuous_on_inv) auto
  2038 
  2039   from d f have "{min ?A ?B <..< max ?A ?B} \<subseteq> f ` ?D"
  2040     by (intro connected_contains_Ioo connected_continuous_image) (auto split: split_min split_max)
  2041   with g have "continuous_on {min ?A ?B <..< max ?A ?B} g"
  2042     by (rule continuous_on_subset)
  2043   moreover
  2044   have "(?A < f x \<and> f x < ?B) \<or> (?B < f x \<and> f x < ?A)"
  2045     using d inj by (intro continuous_inj_imp_mono[OF _ _ f] inj_on_imageI2[of g, OF inj_onI]) auto
  2046   then have "f x \<in> {min ?A ?B <..< max ?A ?B}"
  2047     by auto
  2048   ultimately
  2049   show ?thesis
  2050     by (simp add: continuous_on_eq_continuous_at)
  2051 qed
  2052 
  2053 lemma isCont_inverse_function2:
  2054   fixes f g :: "real \<Rightarrow> real" shows
  2055   "\<lbrakk>a < x; x < b;
  2056     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z;
  2057     \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z\<rbrakk>
  2058    \<Longrightarrow> isCont g (f x)"
  2059 apply (rule isCont_inverse_function
  2060        [where f=f and d="min (x - a) (b - x)"])
  2061 apply (simp_all add: abs_le_iff)
  2062 done
  2063 
  2064 (* need to rename second isCont_inverse *)
  2065 
  2066 lemma isCont_inv_fun:
  2067   fixes f g :: "real \<Rightarrow> real"
  2068   shows "[| 0 < d; \<forall>z. \<bar>z - x\<bar> \<le> d --> g(f(z)) = z;
  2069          \<forall>z. \<bar>z - x\<bar> \<le> d --> isCont f z |]
  2070       ==> isCont g (f x)"
  2071 by (rule isCont_inverse_function)
  2072 
  2073 text\<open>Bartle/Sherbert: Introduction to Real Analysis, Theorem 4.2.9, p. 110\<close>
  2074 lemma LIM_fun_gt_zero:
  2075   fixes f :: "real \<Rightarrow> real"
  2076   shows "f -- c --> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> 0 < f x)"
  2077 apply (drule (1) LIM_D, clarify)
  2078 apply (rule_tac x = s in exI)
  2079 apply (simp add: abs_less_iff)
  2080 done
  2081 
  2082 lemma LIM_fun_less_zero:
  2083   fixes f :: "real \<Rightarrow> real"
  2084   shows "f -- c --> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x < 0)"
  2085 apply (drule LIM_D [where r="-l"], simp, clarify)
  2086 apply (rule_tac x = s in exI)
  2087 apply (simp add: abs_less_iff)
  2088 done
  2089 
  2090 lemma LIM_fun_not_zero:
  2091   fixes f :: "real \<Rightarrow> real"
  2092   shows "f -- c --> l \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x \<noteq> 0)"
  2093   using LIM_fun_gt_zero[of f l c] LIM_fun_less_zero[of f l c] by (auto simp add: neq_iff)
  2094 
  2095 end
  2096