src/HOL/Rat.thy
author wenzelm
Mon Aug 31 21:28:08 2015 +0200 (2015-08-31)
changeset 61070 b72a990adfe2
parent 60758 d8d85a8172b5
child 61144 5e94dfead1c2
permissions -rw-r--r--
prefer symbols;
     1 (*  Title:  HOL/Rat.thy
     2     Author: Markus Wenzel, TU Muenchen
     3 *)
     4 
     5 section \<open>Rational numbers\<close>
     6 
     7 theory Rat
     8 imports GCD Archimedean_Field
     9 begin
    10 
    11 subsection \<open>Rational numbers as quotient\<close>
    12 
    13 subsubsection \<open>Construction of the type of rational numbers\<close>
    14 
    15 definition
    16   ratrel :: "(int \<times> int) \<Rightarrow> (int \<times> int) \<Rightarrow> bool" where
    17   "ratrel = (\<lambda>x y. snd x \<noteq> 0 \<and> snd y \<noteq> 0 \<and> fst x * snd y = fst y * snd x)"
    18 
    19 lemma ratrel_iff [simp]:
    20   "ratrel x y \<longleftrightarrow> snd x \<noteq> 0 \<and> snd y \<noteq> 0 \<and> fst x * snd y = fst y * snd x"
    21   by (simp add: ratrel_def)
    22 
    23 lemma exists_ratrel_refl: "\<exists>x. ratrel x x"
    24   by (auto intro!: one_neq_zero)
    25 
    26 lemma symp_ratrel: "symp ratrel"
    27   by (simp add: ratrel_def symp_def)
    28 
    29 lemma transp_ratrel: "transp ratrel"
    30 proof (rule transpI, unfold split_paired_all)
    31   fix a b a' b' a'' b'' :: int
    32   assume A: "ratrel (a, b) (a', b')"
    33   assume B: "ratrel (a', b') (a'', b'')"
    34   have "b' * (a * b'') = b'' * (a * b')" by simp
    35   also from A have "a * b' = a' * b" by auto
    36   also have "b'' * (a' * b) = b * (a' * b'')" by simp
    37   also from B have "a' * b'' = a'' * b'" by auto
    38   also have "b * (a'' * b') = b' * (a'' * b)" by simp
    39   finally have "b' * (a * b'') = b' * (a'' * b)" .
    40   moreover from B have "b' \<noteq> 0" by auto
    41   ultimately have "a * b'' = a'' * b" by simp
    42   with A B show "ratrel (a, b) (a'', b'')" by auto
    43 qed
    44 
    45 lemma part_equivp_ratrel: "part_equivp ratrel"
    46   by (rule part_equivpI [OF exists_ratrel_refl symp_ratrel transp_ratrel])
    47 
    48 quotient_type rat = "int \<times> int" / partial: "ratrel"
    49   morphisms Rep_Rat Abs_Rat
    50   by (rule part_equivp_ratrel)
    51 
    52 lemma Domainp_cr_rat [transfer_domain_rule]: "Domainp pcr_rat = (\<lambda>x. snd x \<noteq> 0)"
    53 by (simp add: rat.domain_eq)
    54 
    55 subsubsection \<open>Representation and basic operations\<close>
    56 
    57 lift_definition Fract :: "int \<Rightarrow> int \<Rightarrow> rat"
    58   is "\<lambda>a b. if b = 0 then (0, 1) else (a, b)"
    59   by simp
    60 
    61 lemma eq_rat:
    62   shows "\<And>a b c d. b \<noteq> 0 \<Longrightarrow> d \<noteq> 0 \<Longrightarrow> Fract a b = Fract c d \<longleftrightarrow> a * d = c * b"
    63   and "\<And>a. Fract a 0 = Fract 0 1"
    64   and "\<And>a c. Fract 0 a = Fract 0 c"
    65   by (transfer, simp)+
    66 
    67 lemma Rat_cases [case_names Fract, cases type: rat]:
    68   assumes "\<And>a b. q = Fract a b \<Longrightarrow> b > 0 \<Longrightarrow> coprime a b \<Longrightarrow> C"
    69   shows C
    70 proof -
    71   obtain a b :: int where "q = Fract a b" and "b \<noteq> 0"
    72     by transfer simp
    73   let ?a = "a div gcd a b"
    74   let ?b = "b div gcd a b"
    75   from \<open>b \<noteq> 0\<close> have "?b * gcd a b = b"
    76     by simp
    77   with \<open>b \<noteq> 0\<close> have "?b \<noteq> 0" by fastforce
    78   from \<open>q = Fract a b\<close> \<open>b \<noteq> 0\<close> \<open>?b \<noteq> 0\<close> have q: "q = Fract ?a ?b"
    79     by (simp add: eq_rat dvd_div_mult mult.commute [of a])
    80   from \<open>b \<noteq> 0\<close> have coprime: "coprime ?a ?b"
    81     by (auto intro: div_gcd_coprime_int)
    82   show C proof (cases "b > 0")
    83     case True
    84     note assms
    85     moreover note q
    86     moreover from True have "?b > 0" by (simp add: nonneg1_imp_zdiv_pos_iff)
    87     moreover note coprime
    88     ultimately show C .
    89   next
    90     case False
    91     note assms
    92     moreover have "q = Fract (- ?a) (- ?b)" unfolding q by transfer simp
    93     moreover from False \<open>b \<noteq> 0\<close> have "- ?b > 0" by (simp add: pos_imp_zdiv_neg_iff)
    94     moreover from coprime have "coprime (- ?a) (- ?b)" by simp
    95     ultimately show C .
    96   qed
    97 qed
    98 
    99 lemma Rat_induct [case_names Fract, induct type: rat]:
   100   assumes "\<And>a b. b > 0 \<Longrightarrow> coprime a b \<Longrightarrow> P (Fract a b)"
   101   shows "P q"
   102   using assms by (cases q) simp
   103 
   104 instantiation rat :: field
   105 begin
   106 
   107 lift_definition zero_rat :: "rat" is "(0, 1)"
   108   by simp
   109 
   110 lift_definition one_rat :: "rat" is "(1, 1)"
   111   by simp
   112 
   113 lemma Zero_rat_def: "0 = Fract 0 1"
   114   by transfer simp
   115 
   116 lemma One_rat_def: "1 = Fract 1 1"
   117   by transfer simp
   118 
   119 lift_definition plus_rat :: "rat \<Rightarrow> rat \<Rightarrow> rat"
   120   is "\<lambda>x y. (fst x * snd y + fst y * snd x, snd x * snd y)"
   121   by (clarsimp, simp add: distrib_right, simp add: ac_simps)
   122 
   123 lemma add_rat [simp]:
   124   assumes "b \<noteq> 0" and "d \<noteq> 0"
   125   shows "Fract a b + Fract c d = Fract (a * d + c * b) (b * d)"
   126   using assms by transfer simp
   127 
   128 lift_definition uminus_rat :: "rat \<Rightarrow> rat" is "\<lambda>x. (- fst x, snd x)"
   129   by simp
   130 
   131 lemma minus_rat [simp]: "- Fract a b = Fract (- a) b"
   132   by transfer simp
   133 
   134 lemma minus_rat_cancel [simp]: "Fract (- a) (- b) = Fract a b"
   135   by (cases "b = 0") (simp_all add: eq_rat)
   136 
   137 definition
   138   diff_rat_def: "q - r = q + - (r::rat)"
   139 
   140 lemma diff_rat [simp]:
   141   assumes "b \<noteq> 0" and "d \<noteq> 0"
   142   shows "Fract a b - Fract c d = Fract (a * d - c * b) (b * d)"
   143   using assms by (simp add: diff_rat_def)
   144 
   145 lift_definition times_rat :: "rat \<Rightarrow> rat \<Rightarrow> rat"
   146   is "\<lambda>x y. (fst x * fst y, snd x * snd y)"
   147   by (simp add: ac_simps)
   148 
   149 lemma mult_rat [simp]: "Fract a b * Fract c d = Fract (a * c) (b * d)"
   150   by transfer simp
   151 
   152 lemma mult_rat_cancel:
   153   assumes "c \<noteq> 0"
   154   shows "Fract (c * a) (c * b) = Fract a b"
   155   using assms by transfer simp
   156 
   157 lift_definition inverse_rat :: "rat \<Rightarrow> rat"
   158   is "\<lambda>x. if fst x = 0 then (0, 1) else (snd x, fst x)"
   159   by (auto simp add: mult.commute)
   160 
   161 lemma inverse_rat [simp]: "inverse (Fract a b) = Fract b a"
   162   by transfer simp
   163 
   164 definition
   165   divide_rat_def: "q div r = q * inverse (r::rat)"
   166 
   167 lemma divide_rat [simp]: "Fract a b div Fract c d = Fract (a * d) (b * c)"
   168   by (simp add: divide_rat_def)
   169 
   170 instance proof
   171   fix q r s :: rat
   172   show "(q * r) * s = q * (r * s)"
   173     by transfer simp
   174   show "q * r = r * q"
   175     by transfer simp
   176   show "1 * q = q"
   177     by transfer simp
   178   show "(q + r) + s = q + (r + s)"
   179     by transfer (simp add: algebra_simps)
   180   show "q + r = r + q"
   181     by transfer simp
   182   show "0 + q = q"
   183     by transfer simp
   184   show "- q + q = 0"
   185     by transfer simp
   186   show "q - r = q + - r"
   187     by (fact diff_rat_def)
   188   show "(q + r) * s = q * s + r * s"
   189     by transfer (simp add: algebra_simps)
   190   show "(0::rat) \<noteq> 1"
   191     by transfer simp
   192   { assume "q \<noteq> 0" thus "inverse q * q = 1"
   193     by transfer simp }
   194   show "q div r = q * inverse r"
   195     by (fact divide_rat_def)
   196   show "inverse 0 = (0::rat)"
   197     by transfer simp
   198 qed
   199 
   200 end
   201 
   202 lemma of_nat_rat: "of_nat k = Fract (of_nat k) 1"
   203   by (induct k) (simp_all add: Zero_rat_def One_rat_def)
   204 
   205 lemma of_int_rat: "of_int k = Fract k 1"
   206   by (cases k rule: int_diff_cases) (simp add: of_nat_rat)
   207 
   208 lemma Fract_of_nat_eq: "Fract (of_nat k) 1 = of_nat k"
   209   by (rule of_nat_rat [symmetric])
   210 
   211 lemma Fract_of_int_eq: "Fract k 1 = of_int k"
   212   by (rule of_int_rat [symmetric])
   213 
   214 lemma rat_number_collapse:
   215   "Fract 0 k = 0"
   216   "Fract 1 1 = 1"
   217   "Fract (numeral w) 1 = numeral w"
   218   "Fract (- numeral w) 1 = - numeral w"
   219   "Fract (- 1) 1 = - 1"
   220   "Fract k 0 = 0"
   221   using Fract_of_int_eq [of "numeral w"]
   222   using Fract_of_int_eq [of "- numeral w"]
   223   by (simp_all add: Zero_rat_def One_rat_def eq_rat)
   224 
   225 lemma rat_number_expand:
   226   "0 = Fract 0 1"
   227   "1 = Fract 1 1"
   228   "numeral k = Fract (numeral k) 1"
   229   "- 1 = Fract (- 1) 1"
   230   "- numeral k = Fract (- numeral k) 1"
   231   by (simp_all add: rat_number_collapse)
   232 
   233 lemma Rat_cases_nonzero [case_names Fract 0]:
   234   assumes Fract: "\<And>a b. q = Fract a b \<Longrightarrow> b > 0 \<Longrightarrow> a \<noteq> 0 \<Longrightarrow> coprime a b \<Longrightarrow> C"
   235   assumes 0: "q = 0 \<Longrightarrow> C"
   236   shows C
   237 proof (cases "q = 0")
   238   case True then show C using 0 by auto
   239 next
   240   case False
   241   then obtain a b where "q = Fract a b" and "b > 0" and "coprime a b" by (cases q) auto
   242   with False have "0 \<noteq> Fract a b" by simp
   243   with \<open>b > 0\<close> have "a \<noteq> 0" by (simp add: Zero_rat_def eq_rat)
   244   with Fract \<open>q = Fract a b\<close> \<open>b > 0\<close> \<open>coprime a b\<close> show C by blast
   245 qed
   246 
   247 subsubsection \<open>Function @{text normalize}\<close>
   248 
   249 lemma Fract_coprime: "Fract (a div gcd a b) (b div gcd a b) = Fract a b"
   250 proof (cases "b = 0")
   251   case True then show ?thesis by (simp add: eq_rat)
   252 next
   253   case False
   254   moreover have "b div gcd a b * gcd a b = b"
   255     by (rule dvd_div_mult_self) simp
   256   ultimately have "b div gcd a b * gcd a b \<noteq> 0" by simp
   257   then have "b div gcd a b \<noteq> 0" by fastforce
   258   with False show ?thesis by (simp add: eq_rat dvd_div_mult mult.commute [of a])
   259 qed
   260 
   261 definition normalize :: "int \<times> int \<Rightarrow> int \<times> int" where
   262   "normalize p = (if snd p > 0 then (let a = gcd (fst p) (snd p) in (fst p div a, snd p div a))
   263     else if snd p = 0 then (0, 1)
   264     else (let a = - gcd (fst p) (snd p) in (fst p div a, snd p div a)))"
   265 
   266 lemma normalize_crossproduct:
   267   assumes "q \<noteq> 0" "s \<noteq> 0"
   268   assumes "normalize (p, q) = normalize (r, s)"
   269   shows "p * s = r * q"
   270 proof -
   271   have aux: "p * gcd r s = sgn (q * s) * r * gcd p q \<Longrightarrow> q * gcd r s = sgn (q * s) * s * gcd p q \<Longrightarrow> p * s = q * r"
   272   proof -
   273     assume "p * gcd r s = sgn (q * s) * r * gcd p q" and "q * gcd r s = sgn (q * s) * s * gcd p q"
   274     then have "(p * gcd r s) * (sgn (q * s) * s * gcd p q) = (q * gcd r s) * (sgn (q * s) * r * gcd p q)" by simp
   275     with assms show "p * s = q * r" by (auto simp add: ac_simps sgn_times sgn_0_0)
   276   qed
   277   from assms show ?thesis
   278     by (auto simp add: normalize_def Let_def dvd_div_div_eq_mult mult.commute sgn_times split: if_splits intro: aux)
   279 qed
   280 
   281 lemma normalize_eq: "normalize (a, b) = (p, q) \<Longrightarrow> Fract p q = Fract a b"
   282   by (auto simp add: normalize_def Let_def Fract_coprime dvd_div_neg rat_number_collapse
   283     split:split_if_asm)
   284 
   285 lemma normalize_denom_pos: "normalize r = (p, q) \<Longrightarrow> q > 0"
   286   by (auto simp add: normalize_def Let_def dvd_div_neg pos_imp_zdiv_neg_iff nonneg1_imp_zdiv_pos_iff
   287     split:split_if_asm)
   288 
   289 lemma normalize_coprime: "normalize r = (p, q) \<Longrightarrow> coprime p q"
   290   by (auto simp add: normalize_def Let_def dvd_div_neg div_gcd_coprime_int
   291     split:split_if_asm)
   292 
   293 lemma normalize_stable [simp]:
   294   "q > 0 \<Longrightarrow> coprime p q \<Longrightarrow> normalize (p, q) = (p, q)"
   295   by (simp add: normalize_def)
   296 
   297 lemma normalize_denom_zero [simp]:
   298   "normalize (p, 0) = (0, 1)"
   299   by (simp add: normalize_def)
   300 
   301 lemma normalize_negative [simp]:
   302   "q < 0 \<Longrightarrow> normalize (p, q) = normalize (- p, - q)"
   303   by (simp add: normalize_def Let_def dvd_div_neg dvd_neg_div)
   304 
   305 text\<open>
   306   Decompose a fraction into normalized, i.e. coprime numerator and denominator:
   307 \<close>
   308 
   309 definition quotient_of :: "rat \<Rightarrow> int \<times> int" where
   310   "quotient_of x = (THE pair. x = Fract (fst pair) (snd pair) &
   311                    snd pair > 0 & coprime (fst pair) (snd pair))"
   312 
   313 lemma quotient_of_unique:
   314   "\<exists>!p. r = Fract (fst p) (snd p) \<and> snd p > 0 \<and> coprime (fst p) (snd p)"
   315 proof (cases r)
   316   case (Fract a b)
   317   then have "r = Fract (fst (a, b)) (snd (a, b)) \<and> snd (a, b) > 0 \<and> coprime (fst (a, b)) (snd (a, b))" by auto
   318   then show ?thesis proof (rule ex1I)
   319     fix p
   320     obtain c d :: int where p: "p = (c, d)" by (cases p)
   321     assume "r = Fract (fst p) (snd p) \<and> snd p > 0 \<and> coprime (fst p) (snd p)"
   322     with p have Fract': "r = Fract c d" "d > 0" "coprime c d" by simp_all
   323     have "c = a \<and> d = b"
   324     proof (cases "a = 0")
   325       case True with Fract Fract' show ?thesis by (simp add: eq_rat)
   326     next
   327       case False
   328       with Fract Fract' have *: "c * b = a * d" and "c \<noteq> 0" by (auto simp add: eq_rat)
   329       then have "c * b > 0 \<longleftrightarrow> a * d > 0" by auto
   330       with \<open>b > 0\<close> \<open>d > 0\<close> have "a > 0 \<longleftrightarrow> c > 0" by (simp add: zero_less_mult_iff)
   331       with \<open>a \<noteq> 0\<close> \<open>c \<noteq> 0\<close> have sgn: "sgn a = sgn c" by (auto simp add: not_less)
   332       from \<open>coprime a b\<close> \<open>coprime c d\<close> have "\<bar>a\<bar> * \<bar>d\<bar> = \<bar>c\<bar> * \<bar>b\<bar> \<longleftrightarrow> \<bar>a\<bar> = \<bar>c\<bar> \<and> \<bar>d\<bar> = \<bar>b\<bar>"
   333         by (simp add: coprime_crossproduct_int)
   334       with \<open>b > 0\<close> \<open>d > 0\<close> have "\<bar>a\<bar> * d = \<bar>c\<bar> * b \<longleftrightarrow> \<bar>a\<bar> = \<bar>c\<bar> \<and> d = b" by simp
   335       then have "a * sgn a * d = c * sgn c * b \<longleftrightarrow> a * sgn a = c * sgn c \<and> d = b" by (simp add: abs_sgn)
   336       with sgn * show ?thesis by (auto simp add: sgn_0_0)
   337     qed
   338     with p show "p = (a, b)" by simp
   339   qed
   340 qed
   341 
   342 lemma quotient_of_Fract [code]:
   343   "quotient_of (Fract a b) = normalize (a, b)"
   344 proof -
   345   have "Fract a b = Fract (fst (normalize (a, b))) (snd (normalize (a, b)))" (is ?Fract)
   346     by (rule sym) (auto intro: normalize_eq)
   347   moreover have "0 < snd (normalize (a, b))" (is ?denom_pos)
   348     by (cases "normalize (a, b)") (rule normalize_denom_pos, simp)
   349   moreover have "coprime (fst (normalize (a, b))) (snd (normalize (a, b)))" (is ?coprime)
   350     by (rule normalize_coprime) simp
   351   ultimately have "?Fract \<and> ?denom_pos \<and> ?coprime" by blast
   352   with quotient_of_unique have
   353     "(THE p. Fract a b = Fract (fst p) (snd p) \<and> 0 < snd p \<and> coprime (fst p) (snd p)) = normalize (a, b)"
   354     by (rule the1_equality)
   355   then show ?thesis by (simp add: quotient_of_def)
   356 qed
   357 
   358 lemma quotient_of_number [simp]:
   359   "quotient_of 0 = (0, 1)"
   360   "quotient_of 1 = (1, 1)"
   361   "quotient_of (numeral k) = (numeral k, 1)"
   362   "quotient_of (- 1) = (- 1, 1)"
   363   "quotient_of (- numeral k) = (- numeral k, 1)"
   364   by (simp_all add: rat_number_expand quotient_of_Fract)
   365 
   366 lemma quotient_of_eq: "quotient_of (Fract a b) = (p, q) \<Longrightarrow> Fract p q = Fract a b"
   367   by (simp add: quotient_of_Fract normalize_eq)
   368 
   369 lemma quotient_of_denom_pos: "quotient_of r = (p, q) \<Longrightarrow> q > 0"
   370   by (cases r) (simp add: quotient_of_Fract normalize_denom_pos)
   371 
   372 lemma quotient_of_coprime: "quotient_of r = (p, q) \<Longrightarrow> coprime p q"
   373   by (cases r) (simp add: quotient_of_Fract normalize_coprime)
   374 
   375 lemma quotient_of_inject:
   376   assumes "quotient_of a = quotient_of b"
   377   shows "a = b"
   378 proof -
   379   obtain p q r s where a: "a = Fract p q"
   380     and b: "b = Fract r s"
   381     and "q > 0" and "s > 0" by (cases a, cases b)
   382   with assms show ?thesis by (simp add: eq_rat quotient_of_Fract normalize_crossproduct)
   383 qed
   384 
   385 lemma quotient_of_inject_eq:
   386   "quotient_of a = quotient_of b \<longleftrightarrow> a = b"
   387   by (auto simp add: quotient_of_inject)
   388 
   389 
   390 subsubsection \<open>Various\<close>
   391 
   392 lemma Fract_of_int_quotient: "Fract k l = of_int k / of_int l"
   393   by (simp add: Fract_of_int_eq [symmetric])
   394 
   395 lemma Fract_add_one: "n \<noteq> 0 ==> Fract (m + n) n = Fract m n + 1"
   396   by (simp add: rat_number_expand)
   397 
   398 lemma quotient_of_div:
   399   assumes r: "quotient_of r = (n,d)"
   400   shows "r = of_int n / of_int d"
   401 proof -
   402   from theI'[OF quotient_of_unique[of r], unfolded r[unfolded quotient_of_def]]
   403   have "r = Fract n d" by simp
   404   thus ?thesis using Fract_of_int_quotient by simp
   405 qed
   406 
   407 subsubsection \<open>The ordered field of rational numbers\<close>
   408 
   409 lift_definition positive :: "rat \<Rightarrow> bool"
   410   is "\<lambda>x. 0 < fst x * snd x"
   411 proof (clarsimp)
   412   fix a b c d :: int
   413   assume "b \<noteq> 0" and "d \<noteq> 0" and "a * d = c * b"
   414   hence "a * d * b * d = c * b * b * d"
   415     by simp
   416   hence "a * b * d\<^sup>2 = c * d * b\<^sup>2"
   417     unfolding power2_eq_square by (simp add: ac_simps)
   418   hence "0 < a * b * d\<^sup>2 \<longleftrightarrow> 0 < c * d * b\<^sup>2"
   419     by simp
   420   thus "0 < a * b \<longleftrightarrow> 0 < c * d"
   421     using \<open>b \<noteq> 0\<close> and \<open>d \<noteq> 0\<close>
   422     by (simp add: zero_less_mult_iff)
   423 qed
   424 
   425 lemma positive_zero: "\<not> positive 0"
   426   by transfer simp
   427 
   428 lemma positive_add:
   429   "positive x \<Longrightarrow> positive y \<Longrightarrow> positive (x + y)"
   430 apply transfer
   431 apply (simp add: zero_less_mult_iff)
   432 apply (elim disjE, simp_all add: add_pos_pos add_neg_neg
   433   mult_pos_neg mult_neg_pos mult_neg_neg)
   434 done
   435 
   436 lemma positive_mult:
   437   "positive x \<Longrightarrow> positive y \<Longrightarrow> positive (x * y)"
   438 by transfer (drule (1) mult_pos_pos, simp add: ac_simps)
   439 
   440 lemma positive_minus:
   441   "\<not> positive x \<Longrightarrow> x \<noteq> 0 \<Longrightarrow> positive (- x)"
   442 by transfer (force simp: neq_iff zero_less_mult_iff mult_less_0_iff)
   443 
   444 instantiation rat :: linordered_field
   445 begin
   446 
   447 definition
   448   "x < y \<longleftrightarrow> positive (y - x)"
   449 
   450 definition
   451   "x \<le> (y::rat) \<longleftrightarrow> x < y \<or> x = y"
   452 
   453 definition
   454   "abs (a::rat) = (if a < 0 then - a else a)"
   455 
   456 definition
   457   "sgn (a::rat) = (if a = 0 then 0 else if 0 < a then 1 else - 1)"
   458 
   459 instance proof
   460   fix a b c :: rat
   461   show "\<bar>a\<bar> = (if a < 0 then - a else a)"
   462     by (rule abs_rat_def)
   463   show "a < b \<longleftrightarrow> a \<le> b \<and> \<not> b \<le> a"
   464     unfolding less_eq_rat_def less_rat_def
   465     by (auto, drule (1) positive_add, simp_all add: positive_zero)
   466   show "a \<le> a"
   467     unfolding less_eq_rat_def by simp
   468   show "a \<le> b \<Longrightarrow> b \<le> c \<Longrightarrow> a \<le> c"
   469     unfolding less_eq_rat_def less_rat_def
   470     by (auto, drule (1) positive_add, simp add: algebra_simps)
   471   show "a \<le> b \<Longrightarrow> b \<le> a \<Longrightarrow> a = b"
   472     unfolding less_eq_rat_def less_rat_def
   473     by (auto, drule (1) positive_add, simp add: positive_zero)
   474   show "a \<le> b \<Longrightarrow> c + a \<le> c + b"
   475     unfolding less_eq_rat_def less_rat_def by auto
   476   show "sgn a = (if a = 0 then 0 else if 0 < a then 1 else - 1)"
   477     by (rule sgn_rat_def)
   478   show "a \<le> b \<or> b \<le> a"
   479     unfolding less_eq_rat_def less_rat_def
   480     by (auto dest!: positive_minus)
   481   show "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   482     unfolding less_rat_def
   483     by (drule (1) positive_mult, simp add: algebra_simps)
   484 qed
   485 
   486 end
   487 
   488 instantiation rat :: distrib_lattice
   489 begin
   490 
   491 definition
   492   "(inf :: rat \<Rightarrow> rat \<Rightarrow> rat) = min"
   493 
   494 definition
   495   "(sup :: rat \<Rightarrow> rat \<Rightarrow> rat) = max"
   496 
   497 instance proof
   498 qed (auto simp add: inf_rat_def sup_rat_def max_min_distrib2)
   499 
   500 end
   501 
   502 lemma positive_rat: "positive (Fract a b) \<longleftrightarrow> 0 < a * b"
   503   by transfer simp
   504 
   505 lemma less_rat [simp]:
   506   assumes "b \<noteq> 0" and "d \<noteq> 0"
   507   shows "Fract a b < Fract c d \<longleftrightarrow> (a * d) * (b * d) < (c * b) * (b * d)"
   508   using assms unfolding less_rat_def
   509   by (simp add: positive_rat algebra_simps)
   510 
   511 lemma le_rat [simp]:
   512   assumes "b \<noteq> 0" and "d \<noteq> 0"
   513   shows "Fract a b \<le> Fract c d \<longleftrightarrow> (a * d) * (b * d) \<le> (c * b) * (b * d)"
   514   using assms unfolding le_less by (simp add: eq_rat)
   515 
   516 lemma abs_rat [simp, code]: "\<bar>Fract a b\<bar> = Fract \<bar>a\<bar> \<bar>b\<bar>"
   517   by (auto simp add: abs_rat_def zabs_def Zero_rat_def not_less le_less eq_rat zero_less_mult_iff)
   518 
   519 lemma sgn_rat [simp, code]: "sgn (Fract a b) = of_int (sgn a * sgn b)"
   520   unfolding Fract_of_int_eq
   521   by (auto simp: zsgn_def sgn_rat_def Zero_rat_def eq_rat)
   522     (auto simp: rat_number_collapse not_less le_less zero_less_mult_iff)
   523 
   524 lemma Rat_induct_pos [case_names Fract, induct type: rat]:
   525   assumes step: "\<And>a b. 0 < b \<Longrightarrow> P (Fract a b)"
   526   shows "P q"
   527 proof (cases q)
   528   have step': "\<And>a b. b < 0 \<Longrightarrow> P (Fract a b)"
   529   proof -
   530     fix a::int and b::int
   531     assume b: "b < 0"
   532     hence "0 < -b" by simp
   533     hence "P (Fract (-a) (-b))" by (rule step)
   534     thus "P (Fract a b)" by (simp add: order_less_imp_not_eq [OF b])
   535   qed
   536   case (Fract a b)
   537   thus "P q" by (force simp add: linorder_neq_iff step step')
   538 qed
   539 
   540 lemma zero_less_Fract_iff:
   541   "0 < b \<Longrightarrow> 0 < Fract a b \<longleftrightarrow> 0 < a"
   542   by (simp add: Zero_rat_def zero_less_mult_iff)
   543 
   544 lemma Fract_less_zero_iff:
   545   "0 < b \<Longrightarrow> Fract a b < 0 \<longleftrightarrow> a < 0"
   546   by (simp add: Zero_rat_def mult_less_0_iff)
   547 
   548 lemma zero_le_Fract_iff:
   549   "0 < b \<Longrightarrow> 0 \<le> Fract a b \<longleftrightarrow> 0 \<le> a"
   550   by (simp add: Zero_rat_def zero_le_mult_iff)
   551 
   552 lemma Fract_le_zero_iff:
   553   "0 < b \<Longrightarrow> Fract a b \<le> 0 \<longleftrightarrow> a \<le> 0"
   554   by (simp add: Zero_rat_def mult_le_0_iff)
   555 
   556 lemma one_less_Fract_iff:
   557   "0 < b \<Longrightarrow> 1 < Fract a b \<longleftrightarrow> b < a"
   558   by (simp add: One_rat_def mult_less_cancel_right_disj)
   559 
   560 lemma Fract_less_one_iff:
   561   "0 < b \<Longrightarrow> Fract a b < 1 \<longleftrightarrow> a < b"
   562   by (simp add: One_rat_def mult_less_cancel_right_disj)
   563 
   564 lemma one_le_Fract_iff:
   565   "0 < b \<Longrightarrow> 1 \<le> Fract a b \<longleftrightarrow> b \<le> a"
   566   by (simp add: One_rat_def mult_le_cancel_right)
   567 
   568 lemma Fract_le_one_iff:
   569   "0 < b \<Longrightarrow> Fract a b \<le> 1 \<longleftrightarrow> a \<le> b"
   570   by (simp add: One_rat_def mult_le_cancel_right)
   571 
   572 
   573 subsubsection \<open>Rationals are an Archimedean field\<close>
   574 
   575 lemma rat_floor_lemma:
   576   shows "of_int (a div b) \<le> Fract a b \<and> Fract a b < of_int (a div b + 1)"
   577 proof -
   578   have "Fract a b = of_int (a div b) + Fract (a mod b) b"
   579     by (cases "b = 0", simp, simp add: of_int_rat)
   580   moreover have "0 \<le> Fract (a mod b) b \<and> Fract (a mod b) b < 1"
   581     unfolding Fract_of_int_quotient
   582     by (rule linorder_cases [of b 0]) (simp_all add: divide_nonpos_neg)
   583   ultimately show ?thesis by simp
   584 qed
   585 
   586 instance rat :: archimedean_field
   587 proof
   588   fix r :: rat
   589   show "\<exists>z. r \<le> of_int z"
   590   proof (induct r)
   591     case (Fract a b)
   592     have "Fract a b \<le> of_int (a div b + 1)"
   593       using rat_floor_lemma [of a b] by simp
   594     then show "\<exists>z. Fract a b \<le> of_int z" ..
   595   qed
   596 qed
   597 
   598 instantiation rat :: floor_ceiling
   599 begin
   600 
   601 definition [code del]:
   602   "floor (x::rat) = (THE z. of_int z \<le> x \<and> x < of_int (z + 1))"
   603 
   604 instance proof
   605   fix x :: rat
   606   show "of_int (floor x) \<le> x \<and> x < of_int (floor x + 1)"
   607     unfolding floor_rat_def using floor_exists1 by (rule theI')
   608 qed
   609 
   610 end
   611 
   612 lemma floor_Fract: "floor (Fract a b) = a div b"
   613   by (simp add: Fract_of_int_quotient floor_divide_of_int_eq)
   614 
   615 
   616 subsection \<open>Linear arithmetic setup\<close>
   617 
   618 declaration \<open>
   619   K (Lin_Arith.add_inj_thms [@{thm of_nat_le_iff} RS iffD2, @{thm of_nat_eq_iff} RS iffD2]
   620     (* not needed because x < (y::nat) can be rewritten as Suc x <= y: of_nat_less_iff RS iffD2 *)
   621   #> Lin_Arith.add_inj_thms [@{thm of_int_le_iff} RS iffD2, @{thm of_int_eq_iff} RS iffD2]
   622     (* not needed because x < (y::int) can be rewritten as x + 1 <= y: of_int_less_iff RS iffD2 *)
   623   #> Lin_Arith.add_simps [@{thm neg_less_iff_less},
   624       @{thm True_implies_equals},
   625       @{thm distrib_left [where a = "numeral v" for v]},
   626       @{thm distrib_left [where a = "- numeral v" for v]},
   627       @{thm divide_1}, @{thm divide_zero_left},
   628       @{thm times_divide_eq_right}, @{thm times_divide_eq_left},
   629       @{thm minus_divide_left} RS sym, @{thm minus_divide_right} RS sym,
   630       @{thm of_int_minus}, @{thm of_int_diff},
   631       @{thm of_int_of_nat_eq}]
   632   #> Lin_Arith.add_simprocs Numeral_Simprocs.field_divide_cancel_numeral_factor
   633   #> Lin_Arith.add_inj_const (@{const_name of_nat}, @{typ "nat => rat"})
   634   #> Lin_Arith.add_inj_const (@{const_name of_int}, @{typ "int => rat"}))
   635 \<close>
   636 
   637 
   638 subsection \<open>Embedding from Rationals to other Fields\<close>
   639 
   640 context field_char_0
   641 begin
   642 
   643 lift_definition of_rat :: "rat \<Rightarrow> 'a"
   644   is "\<lambda>x. of_int (fst x) / of_int (snd x)"
   645 apply (clarsimp simp add: nonzero_divide_eq_eq nonzero_eq_divide_eq)
   646 apply (simp only: of_int_mult [symmetric])
   647 done
   648 
   649 end
   650 
   651 lemma of_rat_rat: "b \<noteq> 0 \<Longrightarrow> of_rat (Fract a b) = of_int a / of_int b"
   652   by transfer simp
   653 
   654 lemma of_rat_0 [simp]: "of_rat 0 = 0"
   655   by transfer simp
   656 
   657 lemma of_rat_1 [simp]: "of_rat 1 = 1"
   658   by transfer simp
   659 
   660 lemma of_rat_add: "of_rat (a + b) = of_rat a + of_rat b"
   661   by transfer (simp add: add_frac_eq)
   662 
   663 lemma of_rat_minus: "of_rat (- a) = - of_rat a"
   664   by transfer simp
   665 
   666 lemma of_rat_neg_one [simp]:
   667   "of_rat (- 1) = - 1"
   668   by (simp add: of_rat_minus)
   669 
   670 lemma of_rat_diff: "of_rat (a - b) = of_rat a - of_rat b"
   671   using of_rat_add [of a "- b"] by (simp add: of_rat_minus)
   672 
   673 lemma of_rat_mult: "of_rat (a * b) = of_rat a * of_rat b"
   674 apply transfer
   675 apply (simp add: divide_inverse nonzero_inverse_mult_distrib ac_simps)
   676 done
   677 
   678 lemma of_rat_setsum: "of_rat (\<Sum>a\<in>A. f a) = (\<Sum>a\<in>A. of_rat (f a))"
   679   by (induct rule: infinite_finite_induct) (auto simp: of_rat_add)
   680 
   681 lemma of_rat_setprod: "of_rat (\<Prod>a\<in>A. f a) = (\<Prod>a\<in>A. of_rat (f a))"
   682   by (induct rule: infinite_finite_induct) (auto simp: of_rat_mult)
   683 
   684 lemma nonzero_of_rat_inverse:
   685   "a \<noteq> 0 \<Longrightarrow> of_rat (inverse a) = inverse (of_rat a)"
   686 apply (rule inverse_unique [symmetric])
   687 apply (simp add: of_rat_mult [symmetric])
   688 done
   689 
   690 lemma of_rat_inverse:
   691   "(of_rat (inverse a)::'a::{field_char_0, field}) =
   692    inverse (of_rat a)"
   693 by (cases "a = 0", simp_all add: nonzero_of_rat_inverse)
   694 
   695 lemma nonzero_of_rat_divide:
   696   "b \<noteq> 0 \<Longrightarrow> of_rat (a / b) = of_rat a / of_rat b"
   697 by (simp add: divide_inverse of_rat_mult nonzero_of_rat_inverse)
   698 
   699 lemma of_rat_divide:
   700   "(of_rat (a / b)::'a::{field_char_0, field})
   701    = of_rat a / of_rat b"
   702 by (cases "b = 0") (simp_all add: nonzero_of_rat_divide)
   703 
   704 lemma of_rat_power:
   705   "(of_rat (a ^ n)::'a::field_char_0) = of_rat a ^ n"
   706 by (induct n) (simp_all add: of_rat_mult)
   707 
   708 lemma of_rat_eq_iff [simp]: "(of_rat a = of_rat b) = (a = b)"
   709 apply transfer
   710 apply (simp add: nonzero_divide_eq_eq nonzero_eq_divide_eq)
   711 apply (simp only: of_int_mult [symmetric] of_int_eq_iff)
   712 done
   713 
   714 lemma of_rat_eq_0_iff [simp]: "(of_rat a = 0) = (a = 0)"
   715   using of_rat_eq_iff [of _ 0] by simp
   716 
   717 lemma zero_eq_of_rat_iff [simp]: "(0 = of_rat a) = (0 = a)"
   718   by simp
   719 
   720 lemma of_rat_eq_1_iff [simp]: "(of_rat a = 1) = (a = 1)"
   721   using of_rat_eq_iff [of _ 1] by simp
   722 
   723 lemma one_eq_of_rat_iff [simp]: "(1 = of_rat a) = (1 = a)"
   724   by simp
   725 
   726 lemma of_rat_less:
   727   "(of_rat r :: 'a::linordered_field) < of_rat s \<longleftrightarrow> r < s"
   728 proof (induct r, induct s)
   729   fix a b c d :: int
   730   assume not_zero: "b > 0" "d > 0"
   731   then have "b * d > 0" by simp
   732   have of_int_divide_less_eq:
   733     "(of_int a :: 'a) / of_int b < of_int c / of_int d
   734       \<longleftrightarrow> (of_int a :: 'a) * of_int d < of_int c * of_int b"
   735     using not_zero by (simp add: pos_less_divide_eq pos_divide_less_eq)
   736   show "(of_rat (Fract a b) :: 'a::linordered_field) < of_rat (Fract c d)
   737     \<longleftrightarrow> Fract a b < Fract c d"
   738     using not_zero \<open>b * d > 0\<close>
   739     by (simp add: of_rat_rat of_int_divide_less_eq of_int_mult [symmetric] del: of_int_mult)
   740 qed
   741 
   742 lemma of_rat_less_eq:
   743   "(of_rat r :: 'a::linordered_field) \<le> of_rat s \<longleftrightarrow> r \<le> s"
   744   unfolding le_less by (auto simp add: of_rat_less)
   745 
   746 lemma of_rat_le_0_iff [simp]: "((of_rat r :: 'a::linordered_field) \<le> 0) = (r \<le> 0)"
   747   using of_rat_less_eq [of r 0, where 'a='a] by simp
   748 
   749 lemma zero_le_of_rat_iff [simp]: "(0 \<le> (of_rat r :: 'a::linordered_field)) = (0 \<le> r)"
   750   using of_rat_less_eq [of 0 r, where 'a='a] by simp
   751 
   752 lemma of_rat_le_1_iff [simp]: "((of_rat r :: 'a::linordered_field) \<le> 1) = (r \<le> 1)"
   753   using of_rat_less_eq [of r 1] by simp
   754 
   755 lemma one_le_of_rat_iff [simp]: "(1 \<le> (of_rat r :: 'a::linordered_field)) = (1 \<le> r)"
   756   using of_rat_less_eq [of 1 r] by simp
   757 
   758 lemma of_rat_less_0_iff [simp]: "((of_rat r :: 'a::linordered_field) < 0) = (r < 0)"
   759   using of_rat_less [of r 0, where 'a='a] by simp
   760 
   761 lemma zero_less_of_rat_iff [simp]: "(0 < (of_rat r :: 'a::linordered_field)) = (0 < r)"
   762   using of_rat_less [of 0 r, where 'a='a] by simp
   763 
   764 lemma of_rat_less_1_iff [simp]: "((of_rat r :: 'a::linordered_field) < 1) = (r < 1)"
   765   using of_rat_less [of r 1] by simp
   766 
   767 lemma one_less_of_rat_iff [simp]: "(1 < (of_rat r :: 'a::linordered_field)) = (1 < r)"
   768   using of_rat_less [of 1 r] by simp
   769 
   770 lemma of_rat_eq_id [simp]: "of_rat = id"
   771 proof
   772   fix a
   773   show "of_rat a = id a"
   774   by (induct a)
   775      (simp add: of_rat_rat Fract_of_int_eq [symmetric])
   776 qed
   777 
   778 text\<open>Collapse nested embeddings\<close>
   779 lemma of_rat_of_nat_eq [simp]: "of_rat (of_nat n) = of_nat n"
   780 by (induct n) (simp_all add: of_rat_add)
   781 
   782 lemma of_rat_of_int_eq [simp]: "of_rat (of_int z) = of_int z"
   783 by (cases z rule: int_diff_cases) (simp add: of_rat_diff)
   784 
   785 lemma of_rat_numeral_eq [simp]:
   786   "of_rat (numeral w) = numeral w"
   787 using of_rat_of_int_eq [of "numeral w"] by simp
   788 
   789 lemma of_rat_neg_numeral_eq [simp]:
   790   "of_rat (- numeral w) = - numeral w"
   791 using of_rat_of_int_eq [of "- numeral w"] by simp
   792 
   793 lemmas zero_rat = Zero_rat_def
   794 lemmas one_rat = One_rat_def
   795 
   796 abbreviation
   797   rat_of_nat :: "nat \<Rightarrow> rat"
   798 where
   799   "rat_of_nat \<equiv> of_nat"
   800 
   801 abbreviation
   802   rat_of_int :: "int \<Rightarrow> rat"
   803 where
   804   "rat_of_int \<equiv> of_int"
   805 
   806 subsection \<open>The Set of Rational Numbers\<close>
   807 
   808 context field_char_0
   809 begin
   810 
   811 definition Rats :: "'a set" ("\<rat>")
   812   where "\<rat> = range of_rat"
   813 
   814 end
   815 
   816 lemma Rats_of_rat [simp]: "of_rat r \<in> \<rat>"
   817 by (simp add: Rats_def)
   818 
   819 lemma Rats_of_int [simp]: "of_int z \<in> \<rat>"
   820 by (subst of_rat_of_int_eq [symmetric], rule Rats_of_rat)
   821 
   822 lemma Rats_of_nat [simp]: "of_nat n \<in> \<rat>"
   823 by (subst of_rat_of_nat_eq [symmetric], rule Rats_of_rat)
   824 
   825 lemma Rats_number_of [simp]: "numeral w \<in> \<rat>"
   826 by (subst of_rat_numeral_eq [symmetric], rule Rats_of_rat)
   827 
   828 lemma Rats_0 [simp]: "0 \<in> \<rat>"
   829 apply (unfold Rats_def)
   830 apply (rule range_eqI)
   831 apply (rule of_rat_0 [symmetric])
   832 done
   833 
   834 lemma Rats_1 [simp]: "1 \<in> \<rat>"
   835 apply (unfold Rats_def)
   836 apply (rule range_eqI)
   837 apply (rule of_rat_1 [symmetric])
   838 done
   839 
   840 lemma Rats_add [simp]: "\<lbrakk>a \<in> \<rat>; b \<in> \<rat>\<rbrakk> \<Longrightarrow> a + b \<in> \<rat>"
   841 apply (auto simp add: Rats_def)
   842 apply (rule range_eqI)
   843 apply (rule of_rat_add [symmetric])
   844 done
   845 
   846 lemma Rats_minus [simp]: "a \<in> \<rat> \<Longrightarrow> - a \<in> \<rat>"
   847 apply (auto simp add: Rats_def)
   848 apply (rule range_eqI)
   849 apply (rule of_rat_minus [symmetric])
   850 done
   851 
   852 lemma Rats_diff [simp]: "\<lbrakk>a \<in> \<rat>; b \<in> \<rat>\<rbrakk> \<Longrightarrow> a - b \<in> \<rat>"
   853 apply (auto simp add: Rats_def)
   854 apply (rule range_eqI)
   855 apply (rule of_rat_diff [symmetric])
   856 done
   857 
   858 lemma Rats_mult [simp]: "\<lbrakk>a \<in> \<rat>; b \<in> \<rat>\<rbrakk> \<Longrightarrow> a * b \<in> \<rat>"
   859 apply (auto simp add: Rats_def)
   860 apply (rule range_eqI)
   861 apply (rule of_rat_mult [symmetric])
   862 done
   863 
   864 lemma nonzero_Rats_inverse:
   865   fixes a :: "'a::field_char_0"
   866   shows "\<lbrakk>a \<in> \<rat>; a \<noteq> 0\<rbrakk> \<Longrightarrow> inverse a \<in> \<rat>"
   867 apply (auto simp add: Rats_def)
   868 apply (rule range_eqI)
   869 apply (erule nonzero_of_rat_inverse [symmetric])
   870 done
   871 
   872 lemma Rats_inverse [simp]:
   873   fixes a :: "'a::{field_char_0, field}"
   874   shows "a \<in> \<rat> \<Longrightarrow> inverse a \<in> \<rat>"
   875 apply (auto simp add: Rats_def)
   876 apply (rule range_eqI)
   877 apply (rule of_rat_inverse [symmetric])
   878 done
   879 
   880 lemma nonzero_Rats_divide:
   881   fixes a b :: "'a::field_char_0"
   882   shows "\<lbrakk>a \<in> \<rat>; b \<in> \<rat>; b \<noteq> 0\<rbrakk> \<Longrightarrow> a / b \<in> \<rat>"
   883 apply (auto simp add: Rats_def)
   884 apply (rule range_eqI)
   885 apply (erule nonzero_of_rat_divide [symmetric])
   886 done
   887 
   888 lemma Rats_divide [simp]:
   889   fixes a b :: "'a::{field_char_0, field}"
   890   shows "\<lbrakk>a \<in> \<rat>; b \<in> \<rat>\<rbrakk> \<Longrightarrow> a / b \<in> \<rat>"
   891 apply (auto simp add: Rats_def)
   892 apply (rule range_eqI)
   893 apply (rule of_rat_divide [symmetric])
   894 done
   895 
   896 lemma Rats_power [simp]:
   897   fixes a :: "'a::field_char_0"
   898   shows "a \<in> \<rat> \<Longrightarrow> a ^ n \<in> \<rat>"
   899 apply (auto simp add: Rats_def)
   900 apply (rule range_eqI)
   901 apply (rule of_rat_power [symmetric])
   902 done
   903 
   904 lemma Rats_cases [cases set: Rats]:
   905   assumes "q \<in> \<rat>"
   906   obtains (of_rat) r where "q = of_rat r"
   907 proof -
   908   from \<open>q \<in> \<rat>\<close> have "q \<in> range of_rat" unfolding Rats_def .
   909   then obtain r where "q = of_rat r" ..
   910   then show thesis ..
   911 qed
   912 
   913 lemma Rats_induct [case_names of_rat, induct set: Rats]:
   914   "q \<in> \<rat> \<Longrightarrow> (\<And>r. P (of_rat r)) \<Longrightarrow> P q"
   915   by (rule Rats_cases) auto
   916 
   917 lemma Rats_infinite: "\<not> finite \<rat>"
   918   by (auto dest!: finite_imageD simp: inj_on_def infinite_UNIV_char_0 Rats_def)
   919 
   920 subsection \<open>Implementation of rational numbers as pairs of integers\<close>
   921 
   922 text \<open>Formal constructor\<close>
   923 
   924 definition Frct :: "int \<times> int \<Rightarrow> rat" where
   925   [simp]: "Frct p = Fract (fst p) (snd p)"
   926 
   927 lemma [code abstype]:
   928   "Frct (quotient_of q) = q"
   929   by (cases q) (auto intro: quotient_of_eq)
   930 
   931 
   932 text \<open>Numerals\<close>
   933 
   934 declare quotient_of_Fract [code abstract]
   935 
   936 definition of_int :: "int \<Rightarrow> rat"
   937 where
   938   [code_abbrev]: "of_int = Int.of_int"
   939 hide_const (open) of_int
   940 
   941 lemma quotient_of_int [code abstract]:
   942   "quotient_of (Rat.of_int a) = (a, 1)"
   943   by (simp add: of_int_def of_int_rat quotient_of_Fract)
   944 
   945 lemma [code_unfold]:
   946   "numeral k = Rat.of_int (numeral k)"
   947   by (simp add: Rat.of_int_def)
   948 
   949 lemma [code_unfold]:
   950   "- numeral k = Rat.of_int (- numeral k)"
   951   by (simp add: Rat.of_int_def)
   952 
   953 lemma Frct_code_post [code_post]:
   954   "Frct (0, a) = 0"
   955   "Frct (a, 0) = 0"
   956   "Frct (1, 1) = 1"
   957   "Frct (numeral k, 1) = numeral k"
   958   "Frct (1, numeral k) = 1 / numeral k"
   959   "Frct (numeral k, numeral l) = numeral k / numeral l"
   960   "Frct (- a, b) = - Frct (a, b)"
   961   "Frct (a, - b) = - Frct (a, b)"
   962   "- (- Frct q) = Frct q"
   963   by (simp_all add: Fract_of_int_quotient)
   964 
   965 
   966 text \<open>Operations\<close>
   967 
   968 lemma rat_zero_code [code abstract]:
   969   "quotient_of 0 = (0, 1)"
   970   by (simp add: Zero_rat_def quotient_of_Fract normalize_def)
   971 
   972 lemma rat_one_code [code abstract]:
   973   "quotient_of 1 = (1, 1)"
   974   by (simp add: One_rat_def quotient_of_Fract normalize_def)
   975 
   976 lemma rat_plus_code [code abstract]:
   977   "quotient_of (p + q) = (let (a, c) = quotient_of p; (b, d) = quotient_of q
   978      in normalize (a * d + b * c, c * d))"
   979   by (cases p, cases q) (simp add: quotient_of_Fract)
   980 
   981 lemma rat_uminus_code [code abstract]:
   982   "quotient_of (- p) = (let (a, b) = quotient_of p in (- a, b))"
   983   by (cases p) (simp add: quotient_of_Fract)
   984 
   985 lemma rat_minus_code [code abstract]:
   986   "quotient_of (p - q) = (let (a, c) = quotient_of p; (b, d) = quotient_of q
   987      in normalize (a * d - b * c, c * d))"
   988   by (cases p, cases q) (simp add: quotient_of_Fract)
   989 
   990 lemma rat_times_code [code abstract]:
   991   "quotient_of (p * q) = (let (a, c) = quotient_of p; (b, d) = quotient_of q
   992      in normalize (a * b, c * d))"
   993   by (cases p, cases q) (simp add: quotient_of_Fract)
   994 
   995 lemma rat_inverse_code [code abstract]:
   996   "quotient_of (inverse p) = (let (a, b) = quotient_of p
   997     in if a = 0 then (0, 1) else (sgn a * b, \<bar>a\<bar>))"
   998 proof (cases p)
   999   case (Fract a b) then show ?thesis
  1000     by (cases "0::int" a rule: linorder_cases) (simp_all add: quotient_of_Fract gcd.commute)
  1001 qed
  1002 
  1003 lemma rat_divide_code [code abstract]:
  1004   "quotient_of (p / q) = (let (a, c) = quotient_of p; (b, d) = quotient_of q
  1005      in normalize (a * d, c * b))"
  1006   by (cases p, cases q) (simp add: quotient_of_Fract)
  1007 
  1008 lemma rat_abs_code [code abstract]:
  1009   "quotient_of \<bar>p\<bar> = (let (a, b) = quotient_of p in (\<bar>a\<bar>, b))"
  1010   by (cases p) (simp add: quotient_of_Fract)
  1011 
  1012 lemma rat_sgn_code [code abstract]:
  1013   "quotient_of (sgn p) = (sgn (fst (quotient_of p)), 1)"
  1014 proof (cases p)
  1015   case (Fract a b) then show ?thesis
  1016   by (cases "0::int" a rule: linorder_cases) (simp_all add: quotient_of_Fract)
  1017 qed
  1018 
  1019 lemma rat_floor_code [code]:
  1020   "floor p = (let (a, b) = quotient_of p in a div b)"
  1021 by (cases p) (simp add: quotient_of_Fract floor_Fract)
  1022 
  1023 instantiation rat :: equal
  1024 begin
  1025 
  1026 definition [code]:
  1027   "HOL.equal a b \<longleftrightarrow> quotient_of a = quotient_of b"
  1028 
  1029 instance proof
  1030 qed (simp add: equal_rat_def quotient_of_inject_eq)
  1031 
  1032 lemma rat_eq_refl [code nbe]:
  1033   "HOL.equal (r::rat) r \<longleftrightarrow> True"
  1034   by (rule equal_refl)
  1035 
  1036 end
  1037 
  1038 lemma rat_less_eq_code [code]:
  1039   "p \<le> q \<longleftrightarrow> (let (a, c) = quotient_of p; (b, d) = quotient_of q in a * d \<le> c * b)"
  1040   by (cases p, cases q) (simp add: quotient_of_Fract mult.commute)
  1041 
  1042 lemma rat_less_code [code]:
  1043   "p < q \<longleftrightarrow> (let (a, c) = quotient_of p; (b, d) = quotient_of q in a * d < c * b)"
  1044   by (cases p, cases q) (simp add: quotient_of_Fract mult.commute)
  1045 
  1046 lemma [code]:
  1047   "of_rat p = (let (a, b) = quotient_of p in of_int a / of_int b)"
  1048   by (cases p) (simp add: quotient_of_Fract of_rat_rat)
  1049 
  1050 
  1051 text \<open>Quickcheck\<close>
  1052 
  1053 definition (in term_syntax)
  1054   valterm_fract :: "int \<times> (unit \<Rightarrow> Code_Evaluation.term) \<Rightarrow> int \<times> (unit \<Rightarrow> Code_Evaluation.term) \<Rightarrow> rat \<times> (unit \<Rightarrow> Code_Evaluation.term)" where
  1055   [code_unfold]: "valterm_fract k l = Code_Evaluation.valtermify Fract {\<cdot>} k {\<cdot>} l"
  1056 
  1057 notation fcomp (infixl "\<circ>>" 60)
  1058 notation scomp (infixl "\<circ>\<rightarrow>" 60)
  1059 
  1060 instantiation rat :: random
  1061 begin
  1062 
  1063 definition
  1064   "Quickcheck_Random.random i = Quickcheck_Random.random i \<circ>\<rightarrow> (\<lambda>num. Random.range i \<circ>\<rightarrow> (\<lambda>denom. Pair (
  1065      let j = int_of_integer (integer_of_natural (denom + 1))
  1066      in valterm_fract num (j, \<lambda>u. Code_Evaluation.term_of j))))"
  1067 
  1068 instance ..
  1069 
  1070 end
  1071 
  1072 no_notation fcomp (infixl "\<circ>>" 60)
  1073 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
  1074 
  1075 instantiation rat :: exhaustive
  1076 begin
  1077 
  1078 definition
  1079   "exhaustive_rat f d = Quickcheck_Exhaustive.exhaustive
  1080     (\<lambda>l. Quickcheck_Exhaustive.exhaustive (\<lambda>k. f (Fract k (int_of_integer (integer_of_natural l) + 1))) d) d"
  1081 
  1082 instance ..
  1083 
  1084 end
  1085 
  1086 instantiation rat :: full_exhaustive
  1087 begin
  1088 
  1089 definition
  1090   "full_exhaustive_rat f d = Quickcheck_Exhaustive.full_exhaustive (%(l, _). Quickcheck_Exhaustive.full_exhaustive (%k.
  1091      f (let j = int_of_integer (integer_of_natural l) + 1
  1092         in valterm_fract k (j, %_. Code_Evaluation.term_of j))) d) d"
  1093 
  1094 instance ..
  1095 
  1096 end
  1097 
  1098 instantiation rat :: partial_term_of
  1099 begin
  1100 
  1101 instance ..
  1102 
  1103 end
  1104 
  1105 lemma [code]:
  1106   "partial_term_of (ty :: rat itself) (Quickcheck_Narrowing.Narrowing_variable p tt) == Code_Evaluation.Free (STR ''_'') (Typerep.Typerep (STR ''Rat.rat'') [])"
  1107   "partial_term_of (ty :: rat itself) (Quickcheck_Narrowing.Narrowing_constructor 0 [l, k]) ==
  1108      Code_Evaluation.App (Code_Evaluation.Const (STR ''Rat.Frct'')
  1109      (Typerep.Typerep (STR ''fun'') [Typerep.Typerep (STR ''Product_Type.prod'') [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''Int.int'') []],
  1110         Typerep.Typerep (STR ''Rat.rat'') []])) (Code_Evaluation.App (Code_Evaluation.App (Code_Evaluation.Const (STR ''Product_Type.Pair'') (Typerep.Typerep (STR ''fun'') [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''fun'') [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''Product_Type.prod'') [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''Int.int'') []]]])) (partial_term_of (TYPE(int)) l)) (partial_term_of (TYPE(int)) k))"
  1111 by (rule partial_term_of_anything)+
  1112 
  1113 instantiation rat :: narrowing
  1114 begin
  1115 
  1116 definition
  1117   "narrowing = Quickcheck_Narrowing.apply (Quickcheck_Narrowing.apply
  1118     (Quickcheck_Narrowing.cons (%nom denom. Fract nom denom)) narrowing) narrowing"
  1119 
  1120 instance ..
  1121 
  1122 end
  1123 
  1124 
  1125 subsection \<open>Setup for Nitpick\<close>
  1126 
  1127 declaration \<open>
  1128   Nitpick_HOL.register_frac_type @{type_name rat}
  1129    [(@{const_name zero_rat_inst.zero_rat}, @{const_name Nitpick.zero_frac}),
  1130     (@{const_name one_rat_inst.one_rat}, @{const_name Nitpick.one_frac}),
  1131     (@{const_name plus_rat_inst.plus_rat}, @{const_name Nitpick.plus_frac}),
  1132     (@{const_name times_rat_inst.times_rat}, @{const_name Nitpick.times_frac}),
  1133     (@{const_name uminus_rat_inst.uminus_rat}, @{const_name Nitpick.uminus_frac}),
  1134     (@{const_name inverse_rat_inst.inverse_rat}, @{const_name Nitpick.inverse_frac}),
  1135     (@{const_name ord_rat_inst.less_rat}, @{const_name Nitpick.less_frac}),
  1136     (@{const_name ord_rat_inst.less_eq_rat}, @{const_name Nitpick.less_eq_frac}),
  1137     (@{const_name field_char_0_class.of_rat}, @{const_name Nitpick.of_frac})]
  1138 \<close>
  1139 
  1140 lemmas [nitpick_unfold] = inverse_rat_inst.inverse_rat
  1141   one_rat_inst.one_rat ord_rat_inst.less_rat
  1142   ord_rat_inst.less_eq_rat plus_rat_inst.plus_rat times_rat_inst.times_rat
  1143   uminus_rat_inst.uminus_rat zero_rat_inst.zero_rat
  1144 
  1145 
  1146 subsection \<open>Float syntax\<close>
  1147 
  1148 syntax "_Float" :: "float_const \<Rightarrow> 'a"    ("_")
  1149 
  1150 parse_translation \<open>
  1151   let
  1152     fun mk_frac str =
  1153       let
  1154         val {mant = i, exp = n} = Lexicon.read_float str;
  1155         val exp = Syntax.const @{const_syntax Power.power};
  1156         val ten = Numeral.mk_number_syntax 10;
  1157         val exp10 = if n = 1 then ten else exp $ ten $ Numeral.mk_number_syntax n;
  1158       in Syntax.const @{const_syntax Fields.inverse_divide} $ Numeral.mk_number_syntax i $ exp10 end;
  1159 
  1160     fun float_tr [(c as Const (@{syntax_const "_constrain"}, _)) $ t $ u] = c $ float_tr [t] $ u
  1161       | float_tr [t as Const (str, _)] = mk_frac str
  1162       | float_tr ts = raise TERM ("float_tr", ts);
  1163   in [(@{syntax_const "_Float"}, K float_tr)] end
  1164 \<close>
  1165 
  1166 text\<open>Test:\<close>
  1167 lemma "123.456 = -111.111 + 200 + 30 + 4 + 5/10 + 6/100 + (7/1000::rat)"
  1168   by simp
  1169 
  1170 
  1171 subsection \<open>Hiding implementation details\<close>
  1172 
  1173 hide_const (open) normalize positive
  1174 
  1175 lifting_update rat.lifting
  1176 lifting_forget rat.lifting
  1177 
  1178 end
  1179