src/HOL/Set_Interval.thy
author wenzelm
Mon Aug 31 21:28:08 2015 +0200 (2015-08-31)
changeset 61070 b72a990adfe2
parent 60809 457abb82fb9e
child 61204 3e491e34a62e
permissions -rw-r--r--
prefer symbols;
     1 (*  Title:      HOL/Set_Interval.thy
     2     Author:     Tobias Nipkow
     3     Author:     Clemens Ballarin
     4     Author:     Jeremy Avigad
     5 
     6 lessThan, greaterThan, atLeast, atMost and two-sided intervals
     7 
     8 Modern convention: Ixy stands for an interval where x and y
     9 describe the lower and upper bound and x,y : {c,o,i}
    10 where c = closed, o = open, i = infinite.
    11 Examples: Ico = {_ ..< _} and Ici = {_ ..}
    12 *)
    13 
    14 section \<open>Set intervals\<close>
    15 
    16 theory Set_Interval
    17 imports Lattices_Big Nat_Transfer
    18 begin
    19 
    20 context ord
    21 begin
    22 
    23 definition
    24   lessThan    :: "'a => 'a set" ("(1{..<_})") where
    25   "{..<u} == {x. x < u}"
    26 
    27 definition
    28   atMost      :: "'a => 'a set" ("(1{.._})") where
    29   "{..u} == {x. x \<le> u}"
    30 
    31 definition
    32   greaterThan :: "'a => 'a set" ("(1{_<..})") where
    33   "{l<..} == {x. l<x}"
    34 
    35 definition
    36   atLeast     :: "'a => 'a set" ("(1{_..})") where
    37   "{l..} == {x. l\<le>x}"
    38 
    39 definition
    40   greaterThanLessThan :: "'a => 'a => 'a set"  ("(1{_<..<_})") where
    41   "{l<..<u} == {l<..} Int {..<u}"
    42 
    43 definition
    44   atLeastLessThan :: "'a => 'a => 'a set"      ("(1{_..<_})") where
    45   "{l..<u} == {l..} Int {..<u}"
    46 
    47 definition
    48   greaterThanAtMost :: "'a => 'a => 'a set"    ("(1{_<.._})") where
    49   "{l<..u} == {l<..} Int {..u}"
    50 
    51 definition
    52   atLeastAtMost :: "'a => 'a => 'a set"        ("(1{_.._})") where
    53   "{l..u} == {l..} Int {..u}"
    54 
    55 end
    56 
    57 
    58 text\<open>A note of warning when using @{term"{..<n}"} on type @{typ
    59 nat}: it is equivalent to @{term"{0::nat..<n}"} but some lemmas involving
    60 @{term"{m..<n}"} may not exist in @{term"{..<n}"}-form as well.\<close>
    61 
    62 syntax
    63   "_UNION_le"   :: "'a => 'a => 'b set => 'b set"       ("(3UN _<=_./ _)" [0, 0, 10] 10)
    64   "_UNION_less" :: "'a => 'a => 'b set => 'b set"       ("(3UN _<_./ _)" [0, 0, 10] 10)
    65   "_INTER_le"   :: "'a => 'a => 'b set => 'b set"       ("(3INT _<=_./ _)" [0, 0, 10] 10)
    66   "_INTER_less" :: "'a => 'a => 'b set => 'b set"       ("(3INT _<_./ _)" [0, 0, 10] 10)
    67 
    68 syntax (xsymbols)
    69   "_UNION_le"   :: "'a => 'a => 'b set => 'b set"       ("(3\<Union>_\<le>_./ _)" [0, 0, 10] 10)
    70   "_UNION_less" :: "'a => 'a => 'b set => 'b set"       ("(3\<Union>_<_./ _)" [0, 0, 10] 10)
    71   "_INTER_le"   :: "'a => 'a => 'b set => 'b set"       ("(3\<Inter>_\<le>_./ _)" [0, 0, 10] 10)
    72   "_INTER_less" :: "'a => 'a => 'b set => 'b set"       ("(3\<Inter>_<_./ _)" [0, 0, 10] 10)
    73 
    74 syntax (latex output)
    75   "_UNION_le"   :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Union>(00_ \<le> _)/ _)" [0, 0, 10] 10)
    76   "_UNION_less" :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Union>(00_ < _)/ _)" [0, 0, 10] 10)
    77   "_INTER_le"   :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Inter>(00_ \<le> _)/ _)" [0, 0, 10] 10)
    78   "_INTER_less" :: "'a \<Rightarrow> 'a => 'b set => 'b set"       ("(3\<Inter>(00_ < _)/ _)" [0, 0, 10] 10)
    79 
    80 translations
    81   "UN i<=n. A"  == "UN i:{..n}. A"
    82   "UN i<n. A"   == "UN i:{..<n}. A"
    83   "INT i<=n. A" == "INT i:{..n}. A"
    84   "INT i<n. A"  == "INT i:{..<n}. A"
    85 
    86 
    87 subsection \<open>Various equivalences\<close>
    88 
    89 lemma (in ord) lessThan_iff [iff]: "(i: lessThan k) = (i<k)"
    90 by (simp add: lessThan_def)
    91 
    92 lemma Compl_lessThan [simp]:
    93     "!!k:: 'a::linorder. -lessThan k = atLeast k"
    94 apply (auto simp add: lessThan_def atLeast_def)
    95 done
    96 
    97 lemma single_Diff_lessThan [simp]: "!!k:: 'a::order. {k} - lessThan k = {k}"
    98 by auto
    99 
   100 lemma (in ord) greaterThan_iff [iff]: "(i: greaterThan k) = (k<i)"
   101 by (simp add: greaterThan_def)
   102 
   103 lemma Compl_greaterThan [simp]:
   104     "!!k:: 'a::linorder. -greaterThan k = atMost k"
   105   by (auto simp add: greaterThan_def atMost_def)
   106 
   107 lemma Compl_atMost [simp]: "!!k:: 'a::linorder. -atMost k = greaterThan k"
   108 apply (subst Compl_greaterThan [symmetric])
   109 apply (rule double_complement)
   110 done
   111 
   112 lemma (in ord) atLeast_iff [iff]: "(i: atLeast k) = (k<=i)"
   113 by (simp add: atLeast_def)
   114 
   115 lemma Compl_atLeast [simp]:
   116     "!!k:: 'a::linorder. -atLeast k = lessThan k"
   117   by (auto simp add: lessThan_def atLeast_def)
   118 
   119 lemma (in ord) atMost_iff [iff]: "(i: atMost k) = (i<=k)"
   120 by (simp add: atMost_def)
   121 
   122 lemma atMost_Int_atLeast: "!!n:: 'a::order. atMost n Int atLeast n = {n}"
   123 by (blast intro: order_antisym)
   124 
   125 lemma (in linorder) lessThan_Int_lessThan: "{ a <..} \<inter> { b <..} = { max a b <..}"
   126   by auto
   127 
   128 lemma (in linorder) greaterThan_Int_greaterThan: "{..< a} \<inter> {..< b} = {..< min a b}"
   129   by auto
   130 
   131 subsection \<open>Logical Equivalences for Set Inclusion and Equality\<close>
   132 
   133 lemma atLeast_subset_iff [iff]:
   134      "(atLeast x \<subseteq> atLeast y) = (y \<le> (x::'a::order))"
   135 by (blast intro: order_trans)
   136 
   137 lemma atLeast_eq_iff [iff]:
   138      "(atLeast x = atLeast y) = (x = (y::'a::linorder))"
   139 by (blast intro: order_antisym order_trans)
   140 
   141 lemma greaterThan_subset_iff [iff]:
   142      "(greaterThan x \<subseteq> greaterThan y) = (y \<le> (x::'a::linorder))"
   143 apply (auto simp add: greaterThan_def)
   144  apply (subst linorder_not_less [symmetric], blast)
   145 done
   146 
   147 lemma greaterThan_eq_iff [iff]:
   148      "(greaterThan x = greaterThan y) = (x = (y::'a::linorder))"
   149 apply (rule iffI)
   150  apply (erule equalityE)
   151  apply simp_all
   152 done
   153 
   154 lemma atMost_subset_iff [iff]: "(atMost x \<subseteq> atMost y) = (x \<le> (y::'a::order))"
   155 by (blast intro: order_trans)
   156 
   157 lemma atMost_eq_iff [iff]: "(atMost x = atMost y) = (x = (y::'a::linorder))"
   158 by (blast intro: order_antisym order_trans)
   159 
   160 lemma lessThan_subset_iff [iff]:
   161      "(lessThan x \<subseteq> lessThan y) = (x \<le> (y::'a::linorder))"
   162 apply (auto simp add: lessThan_def)
   163  apply (subst linorder_not_less [symmetric], blast)
   164 done
   165 
   166 lemma lessThan_eq_iff [iff]:
   167      "(lessThan x = lessThan y) = (x = (y::'a::linorder))"
   168 apply (rule iffI)
   169  apply (erule equalityE)
   170  apply simp_all
   171 done
   172 
   173 lemma lessThan_strict_subset_iff:
   174   fixes m n :: "'a::linorder"
   175   shows "{..<m} < {..<n} \<longleftrightarrow> m < n"
   176   by (metis leD lessThan_subset_iff linorder_linear not_less_iff_gr_or_eq psubset_eq)
   177 
   178 lemma (in linorder) Ici_subset_Ioi_iff: "{a ..} \<subseteq> {b <..} \<longleftrightarrow> b < a"
   179   by auto
   180 
   181 lemma (in linorder) Iic_subset_Iio_iff: "{.. a} \<subseteq> {..< b} \<longleftrightarrow> a < b"
   182   by auto
   183 
   184 subsection \<open>Two-sided intervals\<close>
   185 
   186 context ord
   187 begin
   188 
   189 lemma greaterThanLessThan_iff [simp]:
   190   "(i : {l<..<u}) = (l < i & i < u)"
   191 by (simp add: greaterThanLessThan_def)
   192 
   193 lemma atLeastLessThan_iff [simp]:
   194   "(i : {l..<u}) = (l <= i & i < u)"
   195 by (simp add: atLeastLessThan_def)
   196 
   197 lemma greaterThanAtMost_iff [simp]:
   198   "(i : {l<..u}) = (l < i & i <= u)"
   199 by (simp add: greaterThanAtMost_def)
   200 
   201 lemma atLeastAtMost_iff [simp]:
   202   "(i : {l..u}) = (l <= i & i <= u)"
   203 by (simp add: atLeastAtMost_def)
   204 
   205 text \<open>The above four lemmas could be declared as iffs. Unfortunately this
   206 breaks many proofs. Since it only helps blast, it is better to leave them
   207 alone.\<close>
   208 
   209 lemma greaterThanLessThan_eq: "{ a <..< b} = { a <..} \<inter> {..< b }"
   210   by auto
   211 
   212 end
   213 
   214 subsubsection\<open>Emptyness, singletons, subset\<close>
   215 
   216 context order
   217 begin
   218 
   219 lemma atLeastatMost_empty[simp]:
   220   "b < a \<Longrightarrow> {a..b} = {}"
   221 by(auto simp: atLeastAtMost_def atLeast_def atMost_def)
   222 
   223 lemma atLeastatMost_empty_iff[simp]:
   224   "{a..b} = {} \<longleftrightarrow> (~ a <= b)"
   225 by auto (blast intro: order_trans)
   226 
   227 lemma atLeastatMost_empty_iff2[simp]:
   228   "{} = {a..b} \<longleftrightarrow> (~ a <= b)"
   229 by auto (blast intro: order_trans)
   230 
   231 lemma atLeastLessThan_empty[simp]:
   232   "b <= a \<Longrightarrow> {a..<b} = {}"
   233 by(auto simp: atLeastLessThan_def)
   234 
   235 lemma atLeastLessThan_empty_iff[simp]:
   236   "{a..<b} = {} \<longleftrightarrow> (~ a < b)"
   237 by auto (blast intro: le_less_trans)
   238 
   239 lemma atLeastLessThan_empty_iff2[simp]:
   240   "{} = {a..<b} \<longleftrightarrow> (~ a < b)"
   241 by auto (blast intro: le_less_trans)
   242 
   243 lemma greaterThanAtMost_empty[simp]: "l \<le> k ==> {k<..l} = {}"
   244 by(auto simp:greaterThanAtMost_def greaterThan_def atMost_def)
   245 
   246 lemma greaterThanAtMost_empty_iff[simp]: "{k<..l} = {} \<longleftrightarrow> ~ k < l"
   247 by auto (blast intro: less_le_trans)
   248 
   249 lemma greaterThanAtMost_empty_iff2[simp]: "{} = {k<..l} \<longleftrightarrow> ~ k < l"
   250 by auto (blast intro: less_le_trans)
   251 
   252 lemma greaterThanLessThan_empty[simp]:"l \<le> k ==> {k<..<l} = {}"
   253 by(auto simp:greaterThanLessThan_def greaterThan_def lessThan_def)
   254 
   255 lemma atLeastAtMost_singleton [simp]: "{a..a} = {a}"
   256 by (auto simp add: atLeastAtMost_def atMost_def atLeast_def)
   257 
   258 lemma atLeastAtMost_singleton': "a = b \<Longrightarrow> {a .. b} = {a}" by simp
   259 
   260 lemma atLeastatMost_subset_iff[simp]:
   261   "{a..b} <= {c..d} \<longleftrightarrow> (~ a <= b) | c <= a & b <= d"
   262 unfolding atLeastAtMost_def atLeast_def atMost_def
   263 by (blast intro: order_trans)
   264 
   265 lemma atLeastatMost_psubset_iff:
   266   "{a..b} < {c..d} \<longleftrightarrow>
   267    ((~ a <= b) | c <= a & b <= d & (c < a | b < d))  &  c <= d"
   268 by(simp add: psubset_eq set_eq_iff less_le_not_le)(blast intro: order_trans)
   269 
   270 lemma Icc_eq_Icc[simp]:
   271   "{l..h} = {l'..h'} = (l=l' \<and> h=h' \<or> \<not> l\<le>h \<and> \<not> l'\<le>h')"
   272 by(simp add: order_class.eq_iff)(auto intro: order_trans)
   273 
   274 lemma atLeastAtMost_singleton_iff[simp]:
   275   "{a .. b} = {c} \<longleftrightarrow> a = b \<and> b = c"
   276 proof
   277   assume "{a..b} = {c}"
   278   hence *: "\<not> (\<not> a \<le> b)" unfolding atLeastatMost_empty_iff[symmetric] by simp
   279   with \<open>{a..b} = {c}\<close> have "c \<le> a \<and> b \<le> c" by auto
   280   with * show "a = b \<and> b = c" by auto
   281 qed simp
   282 
   283 lemma Icc_subset_Ici_iff[simp]:
   284   "{l..h} \<subseteq> {l'..} = (~ l\<le>h \<or> l\<ge>l')"
   285 by(auto simp: subset_eq intro: order_trans)
   286 
   287 lemma Icc_subset_Iic_iff[simp]:
   288   "{l..h} \<subseteq> {..h'} = (~ l\<le>h \<or> h\<le>h')"
   289 by(auto simp: subset_eq intro: order_trans)
   290 
   291 lemma not_Ici_eq_empty[simp]: "{l..} \<noteq> {}"
   292 by(auto simp: set_eq_iff)
   293 
   294 lemma not_Iic_eq_empty[simp]: "{..h} \<noteq> {}"
   295 by(auto simp: set_eq_iff)
   296 
   297 lemmas not_empty_eq_Ici_eq_empty[simp] = not_Ici_eq_empty[symmetric]
   298 lemmas not_empty_eq_Iic_eq_empty[simp] = not_Iic_eq_empty[symmetric]
   299 
   300 end
   301 
   302 context no_top
   303 begin
   304 
   305 (* also holds for no_bot but no_top should suffice *)
   306 lemma not_UNIV_le_Icc[simp]: "\<not> UNIV \<subseteq> {l..h}"
   307 using gt_ex[of h] by(auto simp: subset_eq less_le_not_le)
   308 
   309 lemma not_UNIV_le_Iic[simp]: "\<not> UNIV \<subseteq> {..h}"
   310 using gt_ex[of h] by(auto simp: subset_eq less_le_not_le)
   311 
   312 lemma not_Ici_le_Icc[simp]: "\<not> {l..} \<subseteq> {l'..h'}"
   313 using gt_ex[of h']
   314 by(auto simp: subset_eq less_le)(blast dest:antisym_conv intro: order_trans)
   315 
   316 lemma not_Ici_le_Iic[simp]: "\<not> {l..} \<subseteq> {..h'}"
   317 using gt_ex[of h']
   318 by(auto simp: subset_eq less_le)(blast dest:antisym_conv intro: order_trans)
   319 
   320 end
   321 
   322 context no_bot
   323 begin
   324 
   325 lemma not_UNIV_le_Ici[simp]: "\<not> UNIV \<subseteq> {l..}"
   326 using lt_ex[of l] by(auto simp: subset_eq less_le_not_le)
   327 
   328 lemma not_Iic_le_Icc[simp]: "\<not> {..h} \<subseteq> {l'..h'}"
   329 using lt_ex[of l']
   330 by(auto simp: subset_eq less_le)(blast dest:antisym_conv intro: order_trans)
   331 
   332 lemma not_Iic_le_Ici[simp]: "\<not> {..h} \<subseteq> {l'..}"
   333 using lt_ex[of l']
   334 by(auto simp: subset_eq less_le)(blast dest:antisym_conv intro: order_trans)
   335 
   336 end
   337 
   338 
   339 context no_top
   340 begin
   341 
   342 (* also holds for no_bot but no_top should suffice *)
   343 lemma not_UNIV_eq_Icc[simp]: "\<not> UNIV = {l'..h'}"
   344 using gt_ex[of h'] by(auto simp: set_eq_iff  less_le_not_le)
   345 
   346 lemmas not_Icc_eq_UNIV[simp] = not_UNIV_eq_Icc[symmetric]
   347 
   348 lemma not_UNIV_eq_Iic[simp]: "\<not> UNIV = {..h'}"
   349 using gt_ex[of h'] by(auto simp: set_eq_iff  less_le_not_le)
   350 
   351 lemmas not_Iic_eq_UNIV[simp] = not_UNIV_eq_Iic[symmetric]
   352 
   353 lemma not_Icc_eq_Ici[simp]: "\<not> {l..h} = {l'..}"
   354 unfolding atLeastAtMost_def using not_Ici_le_Iic[of l'] by blast
   355 
   356 lemmas not_Ici_eq_Icc[simp] = not_Icc_eq_Ici[symmetric]
   357 
   358 (* also holds for no_bot but no_top should suffice *)
   359 lemma not_Iic_eq_Ici[simp]: "\<not> {..h} = {l'..}"
   360 using not_Ici_le_Iic[of l' h] by blast
   361 
   362 lemmas not_Ici_eq_Iic[simp] = not_Iic_eq_Ici[symmetric]
   363 
   364 end
   365 
   366 context no_bot
   367 begin
   368 
   369 lemma not_UNIV_eq_Ici[simp]: "\<not> UNIV = {l'..}"
   370 using lt_ex[of l'] by(auto simp: set_eq_iff  less_le_not_le)
   371 
   372 lemmas not_Ici_eq_UNIV[simp] = not_UNIV_eq_Ici[symmetric]
   373 
   374 lemma not_Icc_eq_Iic[simp]: "\<not> {l..h} = {..h'}"
   375 unfolding atLeastAtMost_def using not_Iic_le_Ici[of h'] by blast
   376 
   377 lemmas not_Iic_eq_Icc[simp] = not_Icc_eq_Iic[symmetric]
   378 
   379 end
   380 
   381 
   382 context dense_linorder
   383 begin
   384 
   385 lemma greaterThanLessThan_empty_iff[simp]:
   386   "{ a <..< b } = {} \<longleftrightarrow> b \<le> a"
   387   using dense[of a b] by (cases "a < b") auto
   388 
   389 lemma greaterThanLessThan_empty_iff2[simp]:
   390   "{} = { a <..< b } \<longleftrightarrow> b \<le> a"
   391   using dense[of a b] by (cases "a < b") auto
   392 
   393 lemma atLeastLessThan_subseteq_atLeastAtMost_iff:
   394   "{a ..< b} \<subseteq> { c .. d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b \<le> d)"
   395   using dense[of "max a d" "b"]
   396   by (force simp: subset_eq Ball_def not_less[symmetric])
   397 
   398 lemma greaterThanAtMost_subseteq_atLeastAtMost_iff:
   399   "{a <.. b} \<subseteq> { c .. d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b \<le> d)"
   400   using dense[of "a" "min c b"]
   401   by (force simp: subset_eq Ball_def not_less[symmetric])
   402 
   403 lemma greaterThanLessThan_subseteq_atLeastAtMost_iff:
   404   "{a <..< b} \<subseteq> { c .. d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b \<le> d)"
   405   using dense[of "a" "min c b"] dense[of "max a d" "b"]
   406   by (force simp: subset_eq Ball_def not_less[symmetric])
   407 
   408 lemma atLeastAtMost_subseteq_atLeastLessThan_iff:
   409   "{a .. b} \<subseteq> { c ..< d } \<longleftrightarrow> (a \<le> b \<longrightarrow> c \<le> a \<and> b < d)"
   410   using dense[of "max a d" "b"]
   411   by (force simp: subset_eq Ball_def not_less[symmetric])
   412 
   413 lemma greaterThanAtMost_subseteq_atLeastLessThan_iff:
   414   "{a <.. b} \<subseteq> { c ..< d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b < d)"
   415   using dense[of "a" "min c b"]
   416   by (force simp: subset_eq Ball_def not_less[symmetric])
   417 
   418 lemma greaterThanLessThan_subseteq_atLeastLessThan_iff:
   419   "{a <..< b} \<subseteq> { c ..< d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b \<le> d)"
   420   using dense[of "a" "min c b"] dense[of "max a d" "b"]
   421   by (force simp: subset_eq Ball_def not_less[symmetric])
   422 
   423 lemma greaterThanLessThan_subseteq_greaterThanAtMost_iff:
   424   "{a <..< b} \<subseteq> { c <.. d } \<longleftrightarrow> (a < b \<longrightarrow> c \<le> a \<and> b \<le> d)"
   425   using dense[of "a" "min c b"] dense[of "max a d" "b"]
   426   by (force simp: subset_eq Ball_def not_less[symmetric])
   427 
   428 end
   429 
   430 context no_top
   431 begin
   432 
   433 lemma greaterThan_non_empty[simp]: "{x <..} \<noteq> {}"
   434   using gt_ex[of x] by auto
   435 
   436 end
   437 
   438 context no_bot
   439 begin
   440 
   441 lemma lessThan_non_empty[simp]: "{..< x} \<noteq> {}"
   442   using lt_ex[of x] by auto
   443 
   444 end
   445 
   446 lemma (in linorder) atLeastLessThan_subset_iff:
   447   "{a..<b} <= {c..<d} \<Longrightarrow> b <= a | c<=a & b<=d"
   448 apply (auto simp:subset_eq Ball_def)
   449 apply(frule_tac x=a in spec)
   450 apply(erule_tac x=d in allE)
   451 apply (simp add: less_imp_le)
   452 done
   453 
   454 lemma atLeastLessThan_inj:
   455   fixes a b c d :: "'a::linorder"
   456   assumes eq: "{a ..< b} = {c ..< d}" and "a < b" "c < d"
   457   shows "a = c" "b = d"
   458 using assms by (metis atLeastLessThan_subset_iff eq less_le_not_le linorder_antisym_conv2 subset_refl)+
   459 
   460 lemma atLeastLessThan_eq_iff:
   461   fixes a b c d :: "'a::linorder"
   462   assumes "a < b" "c < d"
   463   shows "{a ..< b} = {c ..< d} \<longleftrightarrow> a = c \<and> b = d"
   464   using atLeastLessThan_inj assms by auto
   465 
   466 lemma (in linorder) Ioc_inj: "{a <.. b} = {c <.. d} \<longleftrightarrow> (b \<le> a \<and> d \<le> c) \<or> a = c \<and> b = d"
   467   by (metis eq_iff greaterThanAtMost_empty_iff2 greaterThanAtMost_iff le_cases not_le)
   468 
   469 lemma (in order) Iio_Int_singleton: "{..<k} \<inter> {x} = (if x < k then {x} else {})"
   470   by auto
   471 
   472 lemma (in linorder) Ioc_subset_iff: "{a<..b} \<subseteq> {c<..d} \<longleftrightarrow> (b \<le> a \<or> c \<le> a \<and> b \<le> d)"
   473   by (auto simp: subset_eq Ball_def) (metis less_le not_less)
   474 
   475 lemma (in order_bot) atLeast_eq_UNIV_iff: "{x..} = UNIV \<longleftrightarrow> x = bot"
   476 by (auto simp: set_eq_iff intro: le_bot)
   477 
   478 lemma (in order_top) atMost_eq_UNIV_iff: "{..x} = UNIV \<longleftrightarrow> x = top"
   479 by (auto simp: set_eq_iff intro: top_le)
   480 
   481 lemma (in bounded_lattice) atLeastAtMost_eq_UNIV_iff:
   482   "{x..y} = UNIV \<longleftrightarrow> (x = bot \<and> y = top)"
   483 by (auto simp: set_eq_iff intro: top_le le_bot)
   484 
   485 lemma Iio_eq_empty_iff: "{..< n::'a::{linorder, order_bot}} = {} \<longleftrightarrow> n = bot"
   486   by (auto simp: set_eq_iff not_less le_bot)
   487 
   488 lemma Iio_eq_empty_iff_nat: "{..< n::nat} = {} \<longleftrightarrow> n = 0"
   489   by (simp add: Iio_eq_empty_iff bot_nat_def)
   490 
   491 lemma mono_image_least:
   492   assumes f_mono: "mono f" and f_img: "f ` {m ..< n} = {m' ..< n'}" "m < n"
   493   shows "f m = m'"
   494 proof -
   495   from f_img have "{m' ..< n'} \<noteq> {}"
   496     by (metis atLeastLessThan_empty_iff image_is_empty)
   497   with f_img have "m' \<in> f ` {m ..< n}" by auto
   498   then obtain k where "f k = m'" "m \<le> k" by auto
   499   moreover have "m' \<le> f m" using f_img by auto
   500   ultimately show "f m = m'"
   501     using f_mono by (auto elim: monoE[where x=m and y=k])
   502 qed
   503 
   504 
   505 subsection \<open>Infinite intervals\<close>
   506 
   507 context dense_linorder
   508 begin
   509 
   510 lemma infinite_Ioo:
   511   assumes "a < b"
   512   shows "\<not> finite {a<..<b}"
   513 proof
   514   assume fin: "finite {a<..<b}"
   515   moreover have ne: "{a<..<b} \<noteq> {}"
   516     using \<open>a < b\<close> by auto
   517   ultimately have "a < Max {a <..< b}" "Max {a <..< b} < b"
   518     using Max_in[of "{a <..< b}"] by auto
   519   then obtain x where "Max {a <..< b} < x" "x < b"
   520     using dense[of "Max {a<..<b}" b] by auto
   521   then have "x \<in> {a <..< b}"
   522     using \<open>a < Max {a <..< b}\<close> by auto
   523   then have "x \<le> Max {a <..< b}"
   524     using fin by auto
   525   with \<open>Max {a <..< b} < x\<close> show False by auto
   526 qed
   527 
   528 lemma infinite_Icc: "a < b \<Longrightarrow> \<not> finite {a .. b}"
   529   using greaterThanLessThan_subseteq_atLeastAtMost_iff[of a b a b] infinite_Ioo[of a b]
   530   by (auto dest: finite_subset)
   531 
   532 lemma infinite_Ico: "a < b \<Longrightarrow> \<not> finite {a ..< b}"
   533   using greaterThanLessThan_subseteq_atLeastLessThan_iff[of a b a b] infinite_Ioo[of a b]
   534   by (auto dest: finite_subset)
   535 
   536 lemma infinite_Ioc: "a < b \<Longrightarrow> \<not> finite {a <.. b}"
   537   using greaterThanLessThan_subseteq_greaterThanAtMost_iff[of a b a b] infinite_Ioo[of a b]
   538   by (auto dest: finite_subset)
   539 
   540 end
   541 
   542 lemma infinite_Iio: "\<not> finite {..< a :: 'a :: {no_bot, linorder}}"
   543 proof
   544   assume "finite {..< a}"
   545   then have *: "\<And>x. x < a \<Longrightarrow> Min {..< a} \<le> x"
   546     by auto
   547   obtain x where "x < a"
   548     using lt_ex by auto
   549 
   550   obtain y where "y < Min {..< a}"
   551     using lt_ex by auto
   552   also have "Min {..< a} \<le> x"
   553     using \<open>x < a\<close> by fact
   554   also note \<open>x < a\<close>
   555   finally have "Min {..< a} \<le> y"
   556     by fact
   557   with \<open>y < Min {..< a}\<close> show False by auto
   558 qed
   559 
   560 lemma infinite_Iic: "\<not> finite {.. a :: 'a :: {no_bot, linorder}}"
   561   using infinite_Iio[of a] finite_subset[of "{..< a}" "{.. a}"]
   562   by (auto simp: subset_eq less_imp_le)
   563 
   564 lemma infinite_Ioi: "\<not> finite {a :: 'a :: {no_top, linorder} <..}"
   565 proof
   566   assume "finite {a <..}"
   567   then have *: "\<And>x. a < x \<Longrightarrow> x \<le> Max {a <..}"
   568     by auto
   569 
   570   obtain y where "Max {a <..} < y"
   571     using gt_ex by auto
   572 
   573   obtain x where "a < x"
   574     using gt_ex by auto
   575   also then have "x \<le> Max {a <..}"
   576     by fact
   577   also note \<open>Max {a <..} < y\<close>
   578   finally have "y \<le> Max { a <..}"
   579     by fact
   580   with \<open>Max {a <..} < y\<close> show False by auto
   581 qed
   582 
   583 lemma infinite_Ici: "\<not> finite {a :: 'a :: {no_top, linorder} ..}"
   584   using infinite_Ioi[of a] finite_subset[of "{a <..}" "{a ..}"]
   585   by (auto simp: subset_eq less_imp_le)
   586 
   587 subsubsection \<open>Intersection\<close>
   588 
   589 context linorder
   590 begin
   591 
   592 lemma Int_atLeastAtMost[simp]: "{a..b} Int {c..d} = {max a c .. min b d}"
   593 by auto
   594 
   595 lemma Int_atLeastAtMostR1[simp]: "{..b} Int {c..d} = {c .. min b d}"
   596 by auto
   597 
   598 lemma Int_atLeastAtMostR2[simp]: "{a..} Int {c..d} = {max a c .. d}"
   599 by auto
   600 
   601 lemma Int_atLeastAtMostL1[simp]: "{a..b} Int {..d} = {a .. min b d}"
   602 by auto
   603 
   604 lemma Int_atLeastAtMostL2[simp]: "{a..b} Int {c..} = {max a c .. b}"
   605 by auto
   606 
   607 lemma Int_atLeastLessThan[simp]: "{a..<b} Int {c..<d} = {max a c ..< min b d}"
   608 by auto
   609 
   610 lemma Int_greaterThanAtMost[simp]: "{a<..b} Int {c<..d} = {max a c <.. min b d}"
   611 by auto
   612 
   613 lemma Int_greaterThanLessThan[simp]: "{a<..<b} Int {c<..<d} = {max a c <..< min b d}"
   614 by auto
   615 
   616 lemma Int_atMost[simp]: "{..a} \<inter> {..b} = {.. min a b}"
   617   by (auto simp: min_def)
   618 
   619 lemma Ioc_disjoint: "{a<..b} \<inter> {c<..d} = {} \<longleftrightarrow> b \<le> a \<or> d \<le> c \<or> b \<le> c \<or> d \<le> a"
   620   using assms by auto
   621 
   622 end
   623 
   624 context complete_lattice
   625 begin
   626 
   627 lemma
   628   shows Sup_atLeast[simp]: "Sup {x ..} = top"
   629     and Sup_greaterThanAtLeast[simp]: "x < top \<Longrightarrow> Sup {x <..} = top"
   630     and Sup_atMost[simp]: "Sup {.. y} = y"
   631     and Sup_atLeastAtMost[simp]: "x \<le> y \<Longrightarrow> Sup { x .. y} = y"
   632     and Sup_greaterThanAtMost[simp]: "x < y \<Longrightarrow> Sup { x <.. y} = y"
   633   by (auto intro!: Sup_eqI)
   634 
   635 lemma
   636   shows Inf_atMost[simp]: "Inf {.. x} = bot"
   637     and Inf_atMostLessThan[simp]: "top < x \<Longrightarrow> Inf {..< x} = bot"
   638     and Inf_atLeast[simp]: "Inf {x ..} = x"
   639     and Inf_atLeastAtMost[simp]: "x \<le> y \<Longrightarrow> Inf { x .. y} = x"
   640     and Inf_atLeastLessThan[simp]: "x < y \<Longrightarrow> Inf { x ..< y} = x"
   641   by (auto intro!: Inf_eqI)
   642 
   643 end
   644 
   645 lemma
   646   fixes x y :: "'a :: {complete_lattice, dense_linorder}"
   647   shows Sup_lessThan[simp]: "Sup {..< y} = y"
   648     and Sup_atLeastLessThan[simp]: "x < y \<Longrightarrow> Sup { x ..< y} = y"
   649     and Sup_greaterThanLessThan[simp]: "x < y \<Longrightarrow> Sup { x <..< y} = y"
   650     and Inf_greaterThan[simp]: "Inf {x <..} = x"
   651     and Inf_greaterThanAtMost[simp]: "x < y \<Longrightarrow> Inf { x <.. y} = x"
   652     and Inf_greaterThanLessThan[simp]: "x < y \<Longrightarrow> Inf { x <..< y} = x"
   653   by (auto intro!: Inf_eqI Sup_eqI intro: dense_le dense_le_bounded dense_ge dense_ge_bounded)
   654 
   655 subsection \<open>Intervals of natural numbers\<close>
   656 
   657 subsubsection \<open>The Constant @{term lessThan}\<close>
   658 
   659 lemma lessThan_0 [simp]: "lessThan (0::nat) = {}"
   660 by (simp add: lessThan_def)
   661 
   662 lemma lessThan_Suc: "lessThan (Suc k) = insert k (lessThan k)"
   663 by (simp add: lessThan_def less_Suc_eq, blast)
   664 
   665 text \<open>The following proof is convenient in induction proofs where
   666 new elements get indices at the beginning. So it is used to transform
   667 @{term "{..<Suc n}"} to @{term "0::nat"} and @{term "{..< n}"}.\<close>
   668 
   669 lemma zero_notin_Suc_image: "0 \<notin> Suc ` A"
   670   by auto
   671 
   672 lemma lessThan_Suc_eq_insert_0: "{..<Suc n} = insert 0 (Suc ` {..<n})"
   673   by (auto simp: image_iff less_Suc_eq_0_disj)
   674 
   675 lemma lessThan_Suc_atMost: "lessThan (Suc k) = atMost k"
   676 by (simp add: lessThan_def atMost_def less_Suc_eq_le)
   677 
   678 lemma Iic_Suc_eq_insert_0: "{.. Suc n} = insert 0 (Suc ` {.. n})"
   679   unfolding lessThan_Suc_atMost[symmetric] lessThan_Suc_eq_insert_0[of "Suc n"] ..
   680 
   681 lemma UN_lessThan_UNIV: "(UN m::nat. lessThan m) = UNIV"
   682 by blast
   683 
   684 subsubsection \<open>The Constant @{term greaterThan}\<close>
   685 
   686 lemma greaterThan_0 [simp]: "greaterThan 0 = range Suc"
   687 apply (simp add: greaterThan_def)
   688 apply (blast dest: gr0_conv_Suc [THEN iffD1])
   689 done
   690 
   691 lemma greaterThan_Suc: "greaterThan (Suc k) = greaterThan k - {Suc k}"
   692 apply (simp add: greaterThan_def)
   693 apply (auto elim: linorder_neqE)
   694 done
   695 
   696 lemma INT_greaterThan_UNIV: "(INT m::nat. greaterThan m) = {}"
   697 by blast
   698 
   699 subsubsection \<open>The Constant @{term atLeast}\<close>
   700 
   701 lemma atLeast_0 [simp]: "atLeast (0::nat) = UNIV"
   702 by (unfold atLeast_def UNIV_def, simp)
   703 
   704 lemma atLeast_Suc: "atLeast (Suc k) = atLeast k - {k}"
   705 apply (simp add: atLeast_def)
   706 apply (simp add: Suc_le_eq)
   707 apply (simp add: order_le_less, blast)
   708 done
   709 
   710 lemma atLeast_Suc_greaterThan: "atLeast (Suc k) = greaterThan k"
   711   by (auto simp add: greaterThan_def atLeast_def less_Suc_eq_le)
   712 
   713 lemma UN_atLeast_UNIV: "(UN m::nat. atLeast m) = UNIV"
   714 by blast
   715 
   716 subsubsection \<open>The Constant @{term atMost}\<close>
   717 
   718 lemma atMost_0 [simp]: "atMost (0::nat) = {0}"
   719 by (simp add: atMost_def)
   720 
   721 lemma atMost_Suc: "atMost (Suc k) = insert (Suc k) (atMost k)"
   722 apply (simp add: atMost_def)
   723 apply (simp add: less_Suc_eq order_le_less, blast)
   724 done
   725 
   726 lemma UN_atMost_UNIV: "(UN m::nat. atMost m) = UNIV"
   727 by blast
   728 
   729 subsubsection \<open>The Constant @{term atLeastLessThan}\<close>
   730 
   731 text\<open>The orientation of the following 2 rules is tricky. The lhs is
   732 defined in terms of the rhs.  Hence the chosen orientation makes sense
   733 in this theory --- the reverse orientation complicates proofs (eg
   734 nontermination). But outside, when the definition of the lhs is rarely
   735 used, the opposite orientation seems preferable because it reduces a
   736 specific concept to a more general one.\<close>
   737 
   738 lemma atLeast0LessThan: "{0::nat..<n} = {..<n}"
   739 by(simp add:lessThan_def atLeastLessThan_def)
   740 
   741 lemma atLeast0AtMost: "{0..n::nat} = {..n}"
   742 by(simp add:atMost_def atLeastAtMost_def)
   743 
   744 declare atLeast0LessThan[symmetric, code_unfold]
   745         atLeast0AtMost[symmetric, code_unfold]
   746 
   747 lemma atLeastLessThan0: "{m..<0::nat} = {}"
   748 by (simp add: atLeastLessThan_def)
   749 
   750 subsubsection \<open>Intervals of nats with @{term Suc}\<close>
   751 
   752 text\<open>Not a simprule because the RHS is too messy.\<close>
   753 lemma atLeastLessThanSuc:
   754     "{m..<Suc n} = (if m \<le> n then insert n {m..<n} else {})"
   755 by (auto simp add: atLeastLessThan_def)
   756 
   757 lemma atLeastLessThan_singleton [simp]: "{m..<Suc m} = {m}"
   758 by (auto simp add: atLeastLessThan_def)
   759 (*
   760 lemma atLeast_sum_LessThan [simp]: "{m + k..<k::nat} = {}"
   761 by (induct k, simp_all add: atLeastLessThanSuc)
   762 
   763 lemma atLeastSucLessThan [simp]: "{Suc n..<n} = {}"
   764 by (auto simp add: atLeastLessThan_def)
   765 *)
   766 lemma atLeastLessThanSuc_atLeastAtMost: "{l..<Suc u} = {l..u}"
   767   by (simp add: lessThan_Suc_atMost atLeastAtMost_def atLeastLessThan_def)
   768 
   769 lemma atLeastSucAtMost_greaterThanAtMost: "{Suc l..u} = {l<..u}"
   770   by (simp add: atLeast_Suc_greaterThan atLeastAtMost_def
   771     greaterThanAtMost_def)
   772 
   773 lemma atLeastSucLessThan_greaterThanLessThan: "{Suc l..<u} = {l<..<u}"
   774   by (simp add: atLeast_Suc_greaterThan atLeastLessThan_def
   775     greaterThanLessThan_def)
   776 
   777 lemma atLeastAtMostSuc_conv: "m \<le> Suc n \<Longrightarrow> {m..Suc n} = insert (Suc n) {m..n}"
   778 by (auto simp add: atLeastAtMost_def)
   779 
   780 lemma atLeastAtMost_insertL: "m \<le> n \<Longrightarrow> insert m {Suc m..n} = {m ..n}"
   781 by auto
   782 
   783 text \<open>The analogous result is useful on @{typ int}:\<close>
   784 (* here, because we don't have an own int section *)
   785 lemma atLeastAtMostPlus1_int_conv:
   786   "m <= 1+n \<Longrightarrow> {m..1+n} = insert (1+n) {m..n::int}"
   787   by (auto intro: set_eqI)
   788 
   789 lemma atLeastLessThan_add_Un: "i \<le> j \<Longrightarrow> {i..<j+k} = {i..<j} \<union> {j..<j+k::nat}"
   790   apply (induct k) 
   791   apply (simp_all add: atLeastLessThanSuc)   
   792   done
   793 
   794 subsubsection \<open>Intervals and numerals\<close>
   795 
   796 lemma lessThan_nat_numeral:  --\<open>Evaluation for specific numerals\<close>
   797   "lessThan (numeral k :: nat) = insert (pred_numeral k) (lessThan (pred_numeral k))"
   798   by (simp add: numeral_eq_Suc lessThan_Suc)
   799 
   800 lemma atMost_nat_numeral:  --\<open>Evaluation for specific numerals\<close>
   801   "atMost (numeral k :: nat) = insert (numeral k) (atMost (pred_numeral k))"
   802   by (simp add: numeral_eq_Suc atMost_Suc)
   803 
   804 lemma atLeastLessThan_nat_numeral:  --\<open>Evaluation for specific numerals\<close>
   805   "atLeastLessThan m (numeral k :: nat) = 
   806      (if m \<le> (pred_numeral k) then insert (pred_numeral k) (atLeastLessThan m (pred_numeral k))
   807                  else {})"
   808   by (simp add: numeral_eq_Suc atLeastLessThanSuc)
   809 
   810 subsubsection \<open>Image\<close>
   811 
   812 lemma image_add_atLeastAtMost [simp]:
   813   fixes k ::"'a::linordered_semidom"
   814   shows "(\<lambda>n. n+k) ` {i..j} = {i+k..j+k}" (is "?A = ?B")
   815 proof
   816   show "?A \<subseteq> ?B" by auto
   817 next
   818   show "?B \<subseteq> ?A"
   819   proof
   820     fix n assume a: "n : ?B"
   821     hence "n - k : {i..j}"
   822       by (auto simp: add_le_imp_le_diff add_le_add_imp_diff_le)
   823     moreover have "n = (n - k) + k" using a
   824     proof -
   825       have "k + i \<le> n"
   826         by (metis a add.commute atLeastAtMost_iff)
   827       hence "k + (n - k) = n"
   828         by (metis (no_types) ab_semigroup_add_class.add_ac(1) add_diff_cancel_left' le_add_diff_inverse)
   829       thus ?thesis
   830         by (simp add: add.commute)
   831     qed
   832     ultimately show "n : ?A" by blast
   833   qed
   834 qed
   835 
   836 lemma image_diff_atLeastAtMost [simp]:
   837   fixes d::"'a::linordered_idom" shows "(op - d ` {a..b}) = {d-b..d-a}"
   838   apply auto
   839   apply (rule_tac x="d-x" in rev_image_eqI, auto)
   840   done
   841 
   842 lemma image_mult_atLeastAtMost [simp]:
   843   fixes d::"'a::linordered_field"
   844   assumes "d>0" shows "(op * d ` {a..b}) = {d*a..d*b}"
   845   using assms
   846   by (auto simp: field_simps mult_le_cancel_right intro: rev_image_eqI [where x="x/d" for x])
   847 
   848 lemma image_affinity_atLeastAtMost:
   849   fixes c :: "'a::linordered_field"
   850   shows "((\<lambda>x. m*x + c) ` {a..b}) = (if {a..b}={} then {}
   851             else if 0 \<le> m then {m*a + c .. m *b + c}
   852             else {m*b + c .. m*a + c})"
   853   apply (case_tac "m=0", auto simp: mult_le_cancel_left)
   854   apply (rule_tac x="inverse m*(x-c)" in rev_image_eqI, auto simp: field_simps)
   855   apply (rule_tac x="inverse m*(x-c)" in rev_image_eqI, auto simp: field_simps)
   856   done
   857 
   858 lemma image_affinity_atLeastAtMost_diff:
   859   fixes c :: "'a::linordered_field"
   860   shows "((\<lambda>x. m*x - c) ` {a..b}) = (if {a..b}={} then {}
   861             else if 0 \<le> m then {m*a - c .. m*b - c}
   862             else {m*b - c .. m*a - c})"
   863   using image_affinity_atLeastAtMost [of m "-c" a b]
   864   by simp
   865 
   866 lemma image_affinity_atLeastAtMost_div_diff:
   867   fixes c :: "'a::linordered_field"
   868   shows "((\<lambda>x. x/m - c) ` {a..b}) = (if {a..b}={} then {}
   869             else if 0 \<le> m then {a/m - c .. b/m - c}
   870             else {b/m - c .. a/m - c})"
   871   using image_affinity_atLeastAtMost_diff [of "inverse m" c a b]
   872   by (simp add: field_class.field_divide_inverse algebra_simps)
   873 
   874 lemma image_add_atLeastLessThan:
   875   "(%n::nat. n+k) ` {i..<j} = {i+k..<j+k}" (is "?A = ?B")
   876 proof
   877   show "?A \<subseteq> ?B" by auto
   878 next
   879   show "?B \<subseteq> ?A"
   880   proof
   881     fix n assume a: "n : ?B"
   882     hence "n - k : {i..<j}" by auto
   883     moreover have "n = (n - k) + k" using a by auto
   884     ultimately show "n : ?A" by blast
   885   qed
   886 qed
   887 
   888 corollary image_Suc_atLeastAtMost[simp]:
   889   "Suc ` {i..j} = {Suc i..Suc j}"
   890 using image_add_atLeastAtMost[where k="Suc 0"] by simp
   891 
   892 corollary image_Suc_atLeastLessThan[simp]:
   893   "Suc ` {i..<j} = {Suc i..<Suc j}"
   894 using image_add_atLeastLessThan[where k="Suc 0"] by simp
   895 
   896 lemma image_add_int_atLeastLessThan:
   897     "(%x. x + (l::int)) ` {0..<u-l} = {l..<u}"
   898   apply (auto simp add: image_def)
   899   apply (rule_tac x = "x - l" in bexI)
   900   apply auto
   901   done
   902 
   903 lemma image_minus_const_atLeastLessThan_nat:
   904   fixes c :: nat
   905   shows "(\<lambda>i. i - c) ` {x ..< y} =
   906       (if c < y then {x - c ..< y - c} else if x < y then {0} else {})"
   907     (is "_ = ?right")
   908 proof safe
   909   fix a assume a: "a \<in> ?right"
   910   show "a \<in> (\<lambda>i. i - c) ` {x ..< y}"
   911   proof cases
   912     assume "c < y" with a show ?thesis
   913       by (auto intro!: image_eqI[of _ _ "a + c"])
   914   next
   915     assume "\<not> c < y" with a show ?thesis
   916       by (auto intro!: image_eqI[of _ _ x] split: split_if_asm)
   917   qed
   918 qed auto
   919 
   920 lemma image_int_atLeastLessThan: "int ` {a..<b} = {int a..<int b}"
   921   by (auto intro!: image_eqI [where x = "nat x" for x])
   922 
   923 context ordered_ab_group_add
   924 begin
   925 
   926 lemma
   927   fixes x :: 'a
   928   shows image_uminus_greaterThan[simp]: "uminus ` {x<..} = {..<-x}"
   929   and image_uminus_atLeast[simp]: "uminus ` {x..} = {..-x}"
   930 proof safe
   931   fix y assume "y < -x"
   932   hence *:  "x < -y" using neg_less_iff_less[of "-y" x] by simp
   933   have "- (-y) \<in> uminus ` {x<..}"
   934     by (rule imageI) (simp add: *)
   935   thus "y \<in> uminus ` {x<..}" by simp
   936 next
   937   fix y assume "y \<le> -x"
   938   have "- (-y) \<in> uminus ` {x..}"
   939     by (rule imageI) (insert \<open>y \<le> -x\<close>[THEN le_imp_neg_le], simp)
   940   thus "y \<in> uminus ` {x..}" by simp
   941 qed simp_all
   942 
   943 lemma
   944   fixes x :: 'a
   945   shows image_uminus_lessThan[simp]: "uminus ` {..<x} = {-x<..}"
   946   and image_uminus_atMost[simp]: "uminus ` {..x} = {-x..}"
   947 proof -
   948   have "uminus ` {..<x} = uminus ` uminus ` {-x<..}"
   949     and "uminus ` {..x} = uminus ` uminus ` {-x..}" by simp_all
   950   thus "uminus ` {..<x} = {-x<..}" and "uminus ` {..x} = {-x..}"
   951     by (simp_all add: image_image
   952         del: image_uminus_greaterThan image_uminus_atLeast)
   953 qed
   954 
   955 lemma
   956   fixes x :: 'a
   957   shows image_uminus_atLeastAtMost[simp]: "uminus ` {x..y} = {-y..-x}"
   958   and image_uminus_greaterThanAtMost[simp]: "uminus ` {x<..y} = {-y..<-x}"
   959   and image_uminus_atLeastLessThan[simp]: "uminus ` {x..<y} = {-y<..-x}"
   960   and image_uminus_greaterThanLessThan[simp]: "uminus ` {x<..<y} = {-y<..<-x}"
   961   by (simp_all add: atLeastAtMost_def greaterThanAtMost_def atLeastLessThan_def
   962       greaterThanLessThan_def image_Int[OF inj_uminus] Int_commute)
   963 end
   964 
   965 subsubsection \<open>Finiteness\<close>
   966 
   967 lemma finite_lessThan [iff]: fixes k :: nat shows "finite {..<k}"
   968   by (induct k) (simp_all add: lessThan_Suc)
   969 
   970 lemma finite_atMost [iff]: fixes k :: nat shows "finite {..k}"
   971   by (induct k) (simp_all add: atMost_Suc)
   972 
   973 lemma finite_greaterThanLessThan [iff]:
   974   fixes l :: nat shows "finite {l<..<u}"
   975 by (simp add: greaterThanLessThan_def)
   976 
   977 lemma finite_atLeastLessThan [iff]:
   978   fixes l :: nat shows "finite {l..<u}"
   979 by (simp add: atLeastLessThan_def)
   980 
   981 lemma finite_greaterThanAtMost [iff]:
   982   fixes l :: nat shows "finite {l<..u}"
   983 by (simp add: greaterThanAtMost_def)
   984 
   985 lemma finite_atLeastAtMost [iff]:
   986   fixes l :: nat shows "finite {l..u}"
   987 by (simp add: atLeastAtMost_def)
   988 
   989 text \<open>A bounded set of natural numbers is finite.\<close>
   990 lemma bounded_nat_set_is_finite:
   991   "(ALL i:N. i < (n::nat)) ==> finite N"
   992 apply (rule finite_subset)
   993  apply (rule_tac [2] finite_lessThan, auto)
   994 done
   995 
   996 text \<open>A set of natural numbers is finite iff it is bounded.\<close>
   997 lemma finite_nat_set_iff_bounded:
   998   "finite(N::nat set) = (EX m. ALL n:N. n<m)" (is "?F = ?B")
   999 proof
  1000   assume f:?F  show ?B
  1001     using Max_ge[OF \<open>?F\<close>, simplified less_Suc_eq_le[symmetric]] by blast
  1002 next
  1003   assume ?B show ?F using \<open>?B\<close> by(blast intro:bounded_nat_set_is_finite)
  1004 qed
  1005 
  1006 lemma finite_nat_set_iff_bounded_le:
  1007   "finite(N::nat set) = (EX m. ALL n:N. n<=m)"
  1008 apply(simp add:finite_nat_set_iff_bounded)
  1009 apply(blast dest:less_imp_le_nat le_imp_less_Suc)
  1010 done
  1011 
  1012 lemma finite_less_ub:
  1013      "!!f::nat=>nat. (!!n. n \<le> f n) ==> finite {n. f n \<le> u}"
  1014 by (rule_tac B="{..u}" in finite_subset, auto intro: order_trans)
  1015 
  1016 
  1017 text\<open>Any subset of an interval of natural numbers the size of the
  1018 subset is exactly that interval.\<close>
  1019 
  1020 lemma subset_card_intvl_is_intvl:
  1021   assumes "A \<subseteq> {k..<k + card A}"
  1022   shows "A = {k..<k + card A}"
  1023 proof (cases "finite A")
  1024   case True
  1025   from this and assms show ?thesis
  1026   proof (induct A rule: finite_linorder_max_induct)
  1027     case empty thus ?case by auto
  1028   next
  1029     case (insert b A)
  1030     hence *: "b \<notin> A" by auto
  1031     with insert have "A <= {k..<k + card A}" and "b = k + card A"
  1032       by fastforce+
  1033     with insert * show ?case by auto
  1034   qed
  1035 next
  1036   case False
  1037   with assms show ?thesis by simp
  1038 qed
  1039 
  1040 
  1041 subsubsection \<open>Proving Inclusions and Equalities between Unions\<close>
  1042 
  1043 lemma UN_le_eq_Un0:
  1044   "(\<Union>i\<le>n::nat. M i) = (\<Union>i\<in>{1..n}. M i) \<union> M 0" (is "?A = ?B")
  1045 proof
  1046   show "?A <= ?B"
  1047   proof
  1048     fix x assume "x : ?A"
  1049     then obtain i where i: "i\<le>n" "x : M i" by auto
  1050     show "x : ?B"
  1051     proof(cases i)
  1052       case 0 with i show ?thesis by simp
  1053     next
  1054       case (Suc j) with i show ?thesis by auto
  1055     qed
  1056   qed
  1057 next
  1058   show "?B <= ?A" by auto
  1059 qed
  1060 
  1061 lemma UN_le_add_shift:
  1062   "(\<Union>i\<le>n::nat. M(i+k)) = (\<Union>i\<in>{k..n+k}. M i)" (is "?A = ?B")
  1063 proof
  1064   show "?A <= ?B" by fastforce
  1065 next
  1066   show "?B <= ?A"
  1067   proof
  1068     fix x assume "x : ?B"
  1069     then obtain i where i: "i : {k..n+k}" "x : M(i)" by auto
  1070     hence "i-k\<le>n & x : M((i-k)+k)" by auto
  1071     thus "x : ?A" by blast
  1072   qed
  1073 qed
  1074 
  1075 lemma UN_UN_finite_eq: "(\<Union>n::nat. \<Union>i\<in>{0..<n}. A i) = (\<Union>n. A n)"
  1076   by (auto simp add: atLeast0LessThan) 
  1077 
  1078 lemma UN_finite_subset: "(!!n::nat. (\<Union>i\<in>{0..<n}. A i) \<subseteq> C) \<Longrightarrow> (\<Union>n. A n) \<subseteq> C"
  1079   by (subst UN_UN_finite_eq [symmetric]) blast
  1080 
  1081 lemma UN_finite2_subset: 
  1082      "(!!n::nat. (\<Union>i\<in>{0..<n}. A i) \<subseteq> (\<Union>i\<in>{0..<n+k}. B i)) \<Longrightarrow> (\<Union>n. A n) \<subseteq> (\<Union>n. B n)"
  1083   apply (rule UN_finite_subset)
  1084   apply (subst UN_UN_finite_eq [symmetric, of B]) 
  1085   apply blast
  1086   done
  1087 
  1088 lemma UN_finite2_eq:
  1089   "(!!n::nat. (\<Union>i\<in>{0..<n}. A i) = (\<Union>i\<in>{0..<n+k}. B i)) \<Longrightarrow> (\<Union>n. A n) = (\<Union>n. B n)"
  1090   apply (rule subset_antisym)
  1091    apply (rule UN_finite2_subset, blast)
  1092  apply (rule UN_finite2_subset [where k=k])
  1093  apply (force simp add: atLeastLessThan_add_Un [of 0])
  1094  done
  1095 
  1096 
  1097 subsubsection \<open>Cardinality\<close>
  1098 
  1099 lemma card_lessThan [simp]: "card {..<u} = u"
  1100   by (induct u, simp_all add: lessThan_Suc)
  1101 
  1102 lemma card_atMost [simp]: "card {..u} = Suc u"
  1103   by (simp add: lessThan_Suc_atMost [THEN sym])
  1104 
  1105 lemma card_atLeastLessThan [simp]: "card {l..<u} = u - l"
  1106 proof -
  1107   have "{l..<u} = (%x. x + l) ` {..<u-l}"
  1108     apply (auto simp add: image_def atLeastLessThan_def lessThan_def)
  1109     apply (rule_tac x = "x - l" in exI)
  1110     apply arith
  1111     done
  1112   then have "card {l..<u} = card {..<u-l}"
  1113     by (simp add: card_image inj_on_def)
  1114   then show ?thesis
  1115     by simp
  1116 qed
  1117 
  1118 lemma card_atLeastAtMost [simp]: "card {l..u} = Suc u - l"
  1119   by (subst atLeastLessThanSuc_atLeastAtMost [THEN sym], simp)
  1120 
  1121 lemma card_greaterThanAtMost [simp]: "card {l<..u} = u - l"
  1122   by (subst atLeastSucAtMost_greaterThanAtMost [THEN sym], simp)
  1123 
  1124 lemma card_greaterThanLessThan [simp]: "card {l<..<u} = u - Suc l"
  1125   by (subst atLeastSucLessThan_greaterThanLessThan [THEN sym], simp)
  1126 
  1127 lemma ex_bij_betw_nat_finite:
  1128   "finite M \<Longrightarrow> \<exists>h. bij_betw h {0..<card M} M"
  1129 apply(drule finite_imp_nat_seg_image_inj_on)
  1130 apply(auto simp:atLeast0LessThan[symmetric] lessThan_def[symmetric] card_image bij_betw_def)
  1131 done
  1132 
  1133 lemma ex_bij_betw_finite_nat:
  1134   "finite M \<Longrightarrow> \<exists>h. bij_betw h M {0..<card M}"
  1135 by (blast dest: ex_bij_betw_nat_finite bij_betw_inv)
  1136 
  1137 lemma finite_same_card_bij:
  1138   "finite A \<Longrightarrow> finite B \<Longrightarrow> card A = card B \<Longrightarrow> EX h. bij_betw h A B"
  1139 apply(drule ex_bij_betw_finite_nat)
  1140 apply(drule ex_bij_betw_nat_finite)
  1141 apply(auto intro!:bij_betw_trans)
  1142 done
  1143 
  1144 lemma ex_bij_betw_nat_finite_1:
  1145   "finite M \<Longrightarrow> \<exists>h. bij_betw h {1 .. card M} M"
  1146 by (rule finite_same_card_bij) auto
  1147 
  1148 lemma bij_betw_iff_card:
  1149   assumes FIN: "finite A" and FIN': "finite B"
  1150   shows BIJ: "(\<exists>f. bij_betw f A B) \<longleftrightarrow> (card A = card B)"
  1151 using assms
  1152 proof(auto simp add: bij_betw_same_card)
  1153   assume *: "card A = card B"
  1154   obtain f where "bij_betw f A {0 ..< card A}"
  1155   using FIN ex_bij_betw_finite_nat by blast
  1156   moreover obtain g where "bij_betw g {0 ..< card B} B"
  1157   using FIN' ex_bij_betw_nat_finite by blast
  1158   ultimately have "bij_betw (g o f) A B"
  1159   using * by (auto simp add: bij_betw_trans)
  1160   thus "(\<exists>f. bij_betw f A B)" by blast
  1161 qed
  1162 
  1163 lemma inj_on_iff_card_le:
  1164   assumes FIN: "finite A" and FIN': "finite B"
  1165   shows "(\<exists>f. inj_on f A \<and> f ` A \<le> B) = (card A \<le> card B)"
  1166 proof (safe intro!: card_inj_on_le)
  1167   assume *: "card A \<le> card B"
  1168   obtain f where 1: "inj_on f A" and 2: "f ` A = {0 ..< card A}"
  1169   using FIN ex_bij_betw_finite_nat unfolding bij_betw_def by force
  1170   moreover obtain g where "inj_on g {0 ..< card B}" and 3: "g ` {0 ..< card B} = B"
  1171   using FIN' ex_bij_betw_nat_finite unfolding bij_betw_def by force
  1172   ultimately have "inj_on g (f ` A)" using subset_inj_on[of g _ "f ` A"] * by force
  1173   hence "inj_on (g o f) A" using 1 comp_inj_on by blast
  1174   moreover
  1175   {have "{0 ..< card A} \<le> {0 ..< card B}" using * by force
  1176    with 2 have "f ` A  \<le> {0 ..< card B}" by blast
  1177    hence "(g o f) ` A \<le> B" unfolding comp_def using 3 by force
  1178   }
  1179   ultimately show "(\<exists>f. inj_on f A \<and> f ` A \<le> B)" by blast
  1180 qed (insert assms, auto)
  1181 
  1182 subsection \<open>Intervals of integers\<close>
  1183 
  1184 lemma atLeastLessThanPlusOne_atLeastAtMost_int: "{l..<u+1} = {l..(u::int)}"
  1185   by (auto simp add: atLeastAtMost_def atLeastLessThan_def)
  1186 
  1187 lemma atLeastPlusOneAtMost_greaterThanAtMost_int: "{l+1..u} = {l<..(u::int)}"
  1188   by (auto simp add: atLeastAtMost_def greaterThanAtMost_def)
  1189 
  1190 lemma atLeastPlusOneLessThan_greaterThanLessThan_int:
  1191     "{l+1..<u} = {l<..<u::int}"
  1192   by (auto simp add: atLeastLessThan_def greaterThanLessThan_def)
  1193 
  1194 subsubsection \<open>Finiteness\<close>
  1195 
  1196 lemma image_atLeastZeroLessThan_int: "0 \<le> u ==>
  1197     {(0::int)..<u} = int ` {..<nat u}"
  1198   apply (unfold image_def lessThan_def)
  1199   apply auto
  1200   apply (rule_tac x = "nat x" in exI)
  1201   apply (auto simp add: zless_nat_eq_int_zless [THEN sym])
  1202   done
  1203 
  1204 lemma finite_atLeastZeroLessThan_int: "finite {(0::int)..<u}"
  1205   apply (cases "0 \<le> u")
  1206   apply (subst image_atLeastZeroLessThan_int, assumption)
  1207   apply (rule finite_imageI)
  1208   apply auto
  1209   done
  1210 
  1211 lemma finite_atLeastLessThan_int [iff]: "finite {l..<u::int}"
  1212   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
  1213   apply (erule subst)
  1214   apply (rule finite_imageI)
  1215   apply (rule finite_atLeastZeroLessThan_int)
  1216   apply (rule image_add_int_atLeastLessThan)
  1217   done
  1218 
  1219 lemma finite_atLeastAtMost_int [iff]: "finite {l..(u::int)}"
  1220   by (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym], simp)
  1221 
  1222 lemma finite_greaterThanAtMost_int [iff]: "finite {l<..(u::int)}"
  1223   by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
  1224 
  1225 lemma finite_greaterThanLessThan_int [iff]: "finite {l<..<u::int}"
  1226   by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
  1227 
  1228 
  1229 subsubsection \<open>Cardinality\<close>
  1230 
  1231 lemma card_atLeastZeroLessThan_int: "card {(0::int)..<u} = nat u"
  1232   apply (cases "0 \<le> u")
  1233   apply (subst image_atLeastZeroLessThan_int, assumption)
  1234   apply (subst card_image)
  1235   apply (auto simp add: inj_on_def)
  1236   done
  1237 
  1238 lemma card_atLeastLessThan_int [simp]: "card {l..<u} = nat (u - l)"
  1239   apply (subgoal_tac "card {l..<u} = card {0..<u-l}")
  1240   apply (erule ssubst, rule card_atLeastZeroLessThan_int)
  1241   apply (subgoal_tac "(%x. x + l) ` {0..<u-l} = {l..<u}")
  1242   apply (erule subst)
  1243   apply (rule card_image)
  1244   apply (simp add: inj_on_def)
  1245   apply (rule image_add_int_atLeastLessThan)
  1246   done
  1247 
  1248 lemma card_atLeastAtMost_int [simp]: "card {l..u} = nat (u - l + 1)"
  1249 apply (subst atLeastLessThanPlusOne_atLeastAtMost_int [THEN sym])
  1250 apply (auto simp add: algebra_simps)
  1251 done
  1252 
  1253 lemma card_greaterThanAtMost_int [simp]: "card {l<..u} = nat (u - l)"
  1254 by (subst atLeastPlusOneAtMost_greaterThanAtMost_int [THEN sym], simp)
  1255 
  1256 lemma card_greaterThanLessThan_int [simp]: "card {l<..<u} = nat (u - (l + 1))"
  1257 by (subst atLeastPlusOneLessThan_greaterThanLessThan_int [THEN sym], simp)
  1258 
  1259 lemma finite_M_bounded_by_nat: "finite {k. P k \<and> k < (i::nat)}"
  1260 proof -
  1261   have "{k. P k \<and> k < i} \<subseteq> {..<i}" by auto
  1262   with finite_lessThan[of "i"] show ?thesis by (simp add: finite_subset)
  1263 qed
  1264 
  1265 lemma card_less:
  1266 assumes zero_in_M: "0 \<in> M"
  1267 shows "card {k \<in> M. k < Suc i} \<noteq> 0"
  1268 proof -
  1269   from zero_in_M have "{k \<in> M. k < Suc i} \<noteq> {}" by auto
  1270   with finite_M_bounded_by_nat show ?thesis by (auto simp add: card_eq_0_iff)
  1271 qed
  1272 
  1273 lemma card_less_Suc2: "0 \<notin> M \<Longrightarrow> card {k. Suc k \<in> M \<and> k < i} = card {k \<in> M. k < Suc i}"
  1274 apply (rule card_bij_eq [of Suc _ _ "\<lambda>x. x - Suc 0"])
  1275 apply auto
  1276 apply (rule inj_on_diff_nat)
  1277 apply auto
  1278 apply (case_tac x)
  1279 apply auto
  1280 apply (case_tac xa)
  1281 apply auto
  1282 apply (case_tac xa)
  1283 apply auto
  1284 done
  1285 
  1286 lemma card_less_Suc:
  1287   assumes zero_in_M: "0 \<in> M"
  1288     shows "Suc (card {k. Suc k \<in> M \<and> k < i}) = card {k \<in> M. k < Suc i}"
  1289 proof -
  1290   from assms have a: "0 \<in> {k \<in> M. k < Suc i}" by simp
  1291   hence c: "{k \<in> M. k < Suc i} = insert 0 ({k \<in> M. k < Suc i} - {0})"
  1292     by (auto simp only: insert_Diff)
  1293   have b: "{k \<in> M. k < Suc i} - {0} = {k \<in> M - {0}. k < Suc i}"  by auto
  1294   from finite_M_bounded_by_nat[of "\<lambda>x. x \<in> M" "Suc i"] 
  1295   have "Suc (card {k. Suc k \<in> M \<and> k < i}) = card (insert 0 ({k \<in> M. k < Suc i} - {0}))"
  1296     apply (subst card_insert)
  1297     apply simp_all
  1298     apply (subst b)
  1299     apply (subst card_less_Suc2[symmetric])
  1300     apply simp_all
  1301     done
  1302   with c show ?thesis by simp
  1303 qed
  1304 
  1305 
  1306 subsection \<open>Lemmas useful with the summation operator setsum\<close>
  1307 
  1308 text \<open>For examples, see Algebra/poly/UnivPoly2.thy\<close>
  1309 
  1310 subsubsection \<open>Disjoint Unions\<close>
  1311 
  1312 text \<open>Singletons and open intervals\<close>
  1313 
  1314 lemma ivl_disj_un_singleton:
  1315   "{l::'a::linorder} Un {l<..} = {l..}"
  1316   "{..<u} Un {u::'a::linorder} = {..u}"
  1317   "(l::'a::linorder) < u ==> {l} Un {l<..<u} = {l..<u}"
  1318   "(l::'a::linorder) < u ==> {l<..<u} Un {u} = {l<..u}"
  1319   "(l::'a::linorder) <= u ==> {l} Un {l<..u} = {l..u}"
  1320   "(l::'a::linorder) <= u ==> {l..<u} Un {u} = {l..u}"
  1321 by auto
  1322 
  1323 text \<open>One- and two-sided intervals\<close>
  1324 
  1325 lemma ivl_disj_un_one:
  1326   "(l::'a::linorder) < u ==> {..l} Un {l<..<u} = {..<u}"
  1327   "(l::'a::linorder) <= u ==> {..<l} Un {l..<u} = {..<u}"
  1328   "(l::'a::linorder) <= u ==> {..l} Un {l<..u} = {..u}"
  1329   "(l::'a::linorder) <= u ==> {..<l} Un {l..u} = {..u}"
  1330   "(l::'a::linorder) <= u ==> {l<..u} Un {u<..} = {l<..}"
  1331   "(l::'a::linorder) < u ==> {l<..<u} Un {u..} = {l<..}"
  1332   "(l::'a::linorder) <= u ==> {l..u} Un {u<..} = {l..}"
  1333   "(l::'a::linorder) <= u ==> {l..<u} Un {u..} = {l..}"
  1334 by auto
  1335 
  1336 text \<open>Two- and two-sided intervals\<close>
  1337 
  1338 lemma ivl_disj_un_two:
  1339   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..<u} = {l<..<u}"
  1340   "[| (l::'a::linorder) <= m; m < u |] ==> {l<..m} Un {m<..<u} = {l<..<u}"
  1341   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..<u} = {l..<u}"
  1342   "[| (l::'a::linorder) <= m; m < u |] ==> {l..m} Un {m<..<u} = {l..<u}"
  1343   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..<m} Un {m..u} = {l<..u}"
  1344   "[| (l::'a::linorder) <= m; m <= u |] ==> {l<..m} Un {m<..u} = {l<..u}"
  1345   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..<m} Un {m..u} = {l..u}"
  1346   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..m} Un {m<..u} = {l..u}"
  1347 by auto
  1348 
  1349 lemma ivl_disj_un_two_touch:
  1350   "[| (l::'a::linorder) < m; m < u |] ==> {l<..m} Un {m..<u} = {l<..<u}"
  1351   "[| (l::'a::linorder) <= m; m < u |] ==> {l..m} Un {m..<u} = {l..<u}"
  1352   "[| (l::'a::linorder) < m; m <= u |] ==> {l<..m} Un {m..u} = {l<..u}"
  1353   "[| (l::'a::linorder) <= m; m <= u |] ==> {l..m} Un {m..u} = {l..u}"
  1354 by auto
  1355 
  1356 lemmas ivl_disj_un = ivl_disj_un_singleton ivl_disj_un_one ivl_disj_un_two ivl_disj_un_two_touch
  1357 
  1358 subsubsection \<open>Disjoint Intersections\<close>
  1359 
  1360 text \<open>One- and two-sided intervals\<close>
  1361 
  1362 lemma ivl_disj_int_one:
  1363   "{..l::'a::order} Int {l<..<u} = {}"
  1364   "{..<l} Int {l..<u} = {}"
  1365   "{..l} Int {l<..u} = {}"
  1366   "{..<l} Int {l..u} = {}"
  1367   "{l<..u} Int {u<..} = {}"
  1368   "{l<..<u} Int {u..} = {}"
  1369   "{l..u} Int {u<..} = {}"
  1370   "{l..<u} Int {u..} = {}"
  1371   by auto
  1372 
  1373 text \<open>Two- and two-sided intervals\<close>
  1374 
  1375 lemma ivl_disj_int_two:
  1376   "{l::'a::order<..<m} Int {m..<u} = {}"
  1377   "{l<..m} Int {m<..<u} = {}"
  1378   "{l..<m} Int {m..<u} = {}"
  1379   "{l..m} Int {m<..<u} = {}"
  1380   "{l<..<m} Int {m..u} = {}"
  1381   "{l<..m} Int {m<..u} = {}"
  1382   "{l..<m} Int {m..u} = {}"
  1383   "{l..m} Int {m<..u} = {}"
  1384   by auto
  1385 
  1386 lemmas ivl_disj_int = ivl_disj_int_one ivl_disj_int_two
  1387 
  1388 subsubsection \<open>Some Differences\<close>
  1389 
  1390 lemma ivl_diff[simp]:
  1391  "i \<le> n \<Longrightarrow> {i..<m} - {i..<n} = {n..<(m::'a::linorder)}"
  1392 by(auto)
  1393 
  1394 lemma (in linorder) lessThan_minus_lessThan [simp]:
  1395   "{..< n} - {..< m} = {m ..< n}"
  1396   by auto
  1397 
  1398 lemma (in linorder) atLeastAtMost_diff_ends:
  1399   "{a..b} - {a, b} = {a<..<b}"
  1400   by auto
  1401 
  1402 
  1403 subsubsection \<open>Some Subset Conditions\<close>
  1404 
  1405 lemma ivl_subset [simp]:
  1406  "({i..<j} \<subseteq> {m..<n}) = (j \<le> i | m \<le> i & j \<le> (n::'a::linorder))"
  1407 apply(auto simp:linorder_not_le)
  1408 apply(rule ccontr)
  1409 apply(insert linorder_le_less_linear[of i n])
  1410 apply(clarsimp simp:linorder_not_le)
  1411 apply(fastforce)
  1412 done
  1413 
  1414 
  1415 subsection \<open>Summation indexed over intervals\<close>
  1416 
  1417 syntax
  1418   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _.._./ _)" [0,0,0,10] 10)
  1419   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _ = _..<_./ _)" [0,0,0,10] 10)
  1420   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<_./ _)" [0,0,10] 10)
  1421   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(SUM _<=_./ _)" [0,0,10] 10)
  1422 syntax (xsymbols)
  1423   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
  1424   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
  1425   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
  1426   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
  1427 syntax (HTML output)
  1428   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _.._./ _)" [0,0,0,10] 10)
  1429   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_ = _..<_./ _)" [0,0,0,10] 10)
  1430   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_<_./ _)" [0,0,10] 10)
  1431   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Sum>_\<le>_./ _)" [0,0,10] 10)
  1432 syntax (latex_sum output)
  1433   "_from_to_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1434  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{>_\<^raw:}$> _)" [0,0,0,10] 10)
  1435   "_from_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1436  ("(3\<^raw:$\sum_{>_ = _\<^raw:}^{<>_\<^raw:}$> _)" [0,0,0,10] 10)
  1437   "_upt_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1438  ("(3\<^raw:$\sum_{>_ < _\<^raw:}$> _)" [0,0,10] 10)
  1439   "_upto_setsum" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1440  ("(3\<^raw:$\sum_{>_ \<le> _\<^raw:}$> _)" [0,0,10] 10)
  1441 
  1442 translations
  1443   "\<Sum>x=a..b. t" == "CONST setsum (%x. t) {a..b}"
  1444   "\<Sum>x=a..<b. t" == "CONST setsum (%x. t) {a..<b}"
  1445   "\<Sum>i\<le>n. t" == "CONST setsum (\<lambda>i. t) {..n}"
  1446   "\<Sum>i<n. t" == "CONST setsum (\<lambda>i. t) {..<n}"
  1447 
  1448 text\<open>The above introduces some pretty alternative syntaxes for
  1449 summation over intervals:
  1450 \begin{center}
  1451 \begin{tabular}{lll}
  1452 Old & New & \LaTeX\\
  1453 @{term[source]"\<Sum>x\<in>{a..b}. e"} & @{term"\<Sum>x=a..b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..b. e"}\\
  1454 @{term[source]"\<Sum>x\<in>{a..<b}. e"} & @{term"\<Sum>x=a..<b. e"} & @{term[mode=latex_sum]"\<Sum>x=a..<b. e"}\\
  1455 @{term[source]"\<Sum>x\<in>{..b}. e"} & @{term"\<Sum>x\<le>b. e"} & @{term[mode=latex_sum]"\<Sum>x\<le>b. e"}\\
  1456 @{term[source]"\<Sum>x\<in>{..<b}. e"} & @{term"\<Sum>x<b. e"} & @{term[mode=latex_sum]"\<Sum>x<b. e"}
  1457 \end{tabular}
  1458 \end{center}
  1459 The left column shows the term before introduction of the new syntax,
  1460 the middle column shows the new (default) syntax, and the right column
  1461 shows a special syntax. The latter is only meaningful for latex output
  1462 and has to be activated explicitly by setting the print mode to
  1463 @{text latex_sum} (e.g.\ via @{text "mode = latex_sum"} in
  1464 antiquotations). It is not the default \LaTeX\ output because it only
  1465 works well with italic-style formulae, not tt-style.
  1466 
  1467 Note that for uniformity on @{typ nat} it is better to use
  1468 @{term"\<Sum>x::nat=0..<n. e"} rather than @{text"\<Sum>x<n. e"}: @{text setsum} may
  1469 not provide all lemmas available for @{term"{m..<n}"} also in the
  1470 special form for @{term"{..<n}"}.\<close>
  1471 
  1472 text\<open>This congruence rule should be used for sums over intervals as
  1473 the standard theorem @{text[source]setsum.cong} does not work well
  1474 with the simplifier who adds the unsimplified premise @{term"x:B"} to
  1475 the context.\<close>
  1476 
  1477 lemma setsum_ivl_cong:
  1478  "\<lbrakk>a = c; b = d; !!x. \<lbrakk> c \<le> x; x < d \<rbrakk> \<Longrightarrow> f x = g x \<rbrakk> \<Longrightarrow>
  1479  setsum f {a..<b} = setsum g {c..<d}"
  1480 by(rule setsum.cong, simp_all)
  1481 
  1482 (* FIXME why are the following simp rules but the corresponding eqns
  1483 on intervals are not? *)
  1484 
  1485 lemma setsum_atMost_Suc[simp]: "(\<Sum>i \<le> Suc n. f i) = (\<Sum>i \<le> n. f i) + f(Suc n)"
  1486 by (simp add:atMost_Suc ac_simps)
  1487 
  1488 lemma setsum_lessThan_Suc[simp]: "(\<Sum>i < Suc n. f i) = (\<Sum>i < n. f i) + f n"
  1489 by (simp add:lessThan_Suc ac_simps)
  1490 
  1491 lemma setsum_cl_ivl_Suc[simp]:
  1492   "setsum f {m..Suc n} = (if Suc n < m then 0 else setsum f {m..n} + f(Suc n))"
  1493 by (auto simp:ac_simps atLeastAtMostSuc_conv)
  1494 
  1495 lemma setsum_op_ivl_Suc[simp]:
  1496   "setsum f {m..<Suc n} = (if n < m then 0 else setsum f {m..<n} + f(n))"
  1497 by (auto simp:ac_simps atLeastLessThanSuc)
  1498 (*
  1499 lemma setsum_cl_ivl_add_one_nat: "(n::nat) <= m + 1 ==>
  1500     (\<Sum>i=n..m+1. f i) = (\<Sum>i=n..m. f i) + f(m + 1)"
  1501 by (auto simp:ac_simps atLeastAtMostSuc_conv)
  1502 *)
  1503 
  1504 lemma setsum_head:
  1505   fixes n :: nat
  1506   assumes mn: "m <= n" 
  1507   shows "(\<Sum>x\<in>{m..n}. P x) = P m + (\<Sum>x\<in>{m<..n}. P x)" (is "?lhs = ?rhs")
  1508 proof -
  1509   from mn
  1510   have "{m..n} = {m} \<union> {m<..n}"
  1511     by (auto intro: ivl_disj_un_singleton)
  1512   hence "?lhs = (\<Sum>x\<in>{m} \<union> {m<..n}. P x)"
  1513     by (simp add: atLeast0LessThan)
  1514   also have "\<dots> = ?rhs" by simp
  1515   finally show ?thesis .
  1516 qed
  1517 
  1518 lemma setsum_head_Suc:
  1519   "m \<le> n \<Longrightarrow> setsum f {m..n} = f m + setsum f {Suc m..n}"
  1520 by (simp add: setsum_head atLeastSucAtMost_greaterThanAtMost)
  1521 
  1522 lemma setsum_head_upt_Suc:
  1523   "m < n \<Longrightarrow> setsum f {m..<n} = f m + setsum f {Suc m..<n}"
  1524 apply(insert setsum_head_Suc[of m "n - Suc 0" f])
  1525 apply (simp add: atLeastLessThanSuc_atLeastAtMost[symmetric] algebra_simps)
  1526 done
  1527 
  1528 lemma setsum_ub_add_nat: assumes "(m::nat) \<le> n + 1"
  1529   shows "setsum f {m..n + p} = setsum f {m..n} + setsum f {n + 1..n + p}"
  1530 proof-
  1531   have "{m .. n+p} = {m..n} \<union> {n+1..n+p}" using \<open>m \<le> n+1\<close> by auto
  1532   thus ?thesis by (auto simp: ivl_disj_int setsum.union_disjoint
  1533     atLeastSucAtMost_greaterThanAtMost)
  1534 qed
  1535 
  1536 lemma setsum_add_nat_ivl: "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
  1537   setsum f {m..<n} + setsum f {n..<p} = setsum f {m..<p::nat}"
  1538 by (simp add:setsum.union_disjoint[symmetric] ivl_disj_int ivl_disj_un)
  1539 
  1540 lemma setsum_diff_nat_ivl:
  1541 fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
  1542 shows "\<lbrakk> m \<le> n; n \<le> p \<rbrakk> \<Longrightarrow>
  1543   setsum f {m..<p} - setsum f {m..<n} = setsum f {n..<p}"
  1544 using setsum_add_nat_ivl [of m n p f,symmetric]
  1545 apply (simp add: ac_simps)
  1546 done
  1547 
  1548 lemma setsum_natinterval_difff:
  1549   fixes f:: "nat \<Rightarrow> ('a::ab_group_add)"
  1550   shows  "setsum (\<lambda>k. f k - f(k + 1)) {(m::nat) .. n} =
  1551           (if m <= n then f m - f(n + 1) else 0)"
  1552 by (induct n, auto simp add: algebra_simps not_le le_Suc_eq)
  1553 
  1554 lemma setsum_nat_group: "(\<Sum>m<n::nat. setsum f {m * k ..< m*k + k}) = setsum f {..< n * k}"
  1555   apply (subgoal_tac "k = 0 | 0 < k", auto)
  1556   apply (induct "n")
  1557   apply (simp_all add: setsum_add_nat_ivl add.commute atLeast0LessThan[symmetric])
  1558   done
  1559 
  1560 lemma setsum_triangle_reindex:
  1561   fixes n :: nat
  1562   shows "(\<Sum>(i,j)\<in>{(i,j). i+j < n}. f i j) = (\<Sum>k<n. \<Sum>i\<le>k. f i (k - i))"
  1563   apply (simp add: setsum.Sigma)
  1564   apply (rule setsum.reindex_bij_witness[where j="\<lambda>(i, j). (i+j, i)" and i="\<lambda>(k, i). (i, k - i)"])
  1565   apply auto
  1566   done
  1567 
  1568 lemma setsum_triangle_reindex_eq:
  1569   fixes n :: nat
  1570   shows "(\<Sum>(i,j)\<in>{(i,j). i+j \<le> n}. f i j) = (\<Sum>k\<le>n. \<Sum>i\<le>k. f i (k - i))"
  1571 using setsum_triangle_reindex [of f "Suc n"]
  1572 by (simp only: Nat.less_Suc_eq_le lessThan_Suc_atMost)
  1573 
  1574 lemma nat_diff_setsum_reindex: "(\<Sum>i<n. f (n - Suc i)) = (\<Sum>i<n. f i)"
  1575   by (rule setsum.reindex_bij_witness[where i="\<lambda>i. n - Suc i" and j="\<lambda>i. n - Suc i"]) auto
  1576 
  1577 subsection\<open>Shifting bounds\<close>
  1578 
  1579 lemma setsum_shift_bounds_nat_ivl:
  1580   "setsum f {m+k..<n+k} = setsum (%i. f(i + k)){m..<n::nat}"
  1581 by (induct "n", auto simp:atLeastLessThanSuc)
  1582 
  1583 lemma setsum_shift_bounds_cl_nat_ivl:
  1584   "setsum f {m+k..n+k} = setsum (%i. f(i + k)){m..n::nat}"
  1585   by (rule setsum.reindex_bij_witness[where i="\<lambda>i. i + k" and j="\<lambda>i. i - k"]) auto
  1586 
  1587 corollary setsum_shift_bounds_cl_Suc_ivl:
  1588   "setsum f {Suc m..Suc n} = setsum (%i. f(Suc i)){m..n}"
  1589 by (simp add:setsum_shift_bounds_cl_nat_ivl[where k="Suc 0", simplified])
  1590 
  1591 corollary setsum_shift_bounds_Suc_ivl:
  1592   "setsum f {Suc m..<Suc n} = setsum (%i. f(Suc i)){m..<n}"
  1593 by (simp add:setsum_shift_bounds_nat_ivl[where k="Suc 0", simplified])
  1594 
  1595 lemma setsum_shift_lb_Suc0_0:
  1596   "f(0::nat) = (0::nat) \<Longrightarrow> setsum f {Suc 0..k} = setsum f {0..k}"
  1597 by(simp add:setsum_head_Suc)
  1598 
  1599 lemma setsum_shift_lb_Suc0_0_upt:
  1600   "f(0::nat) = 0 \<Longrightarrow> setsum f {Suc 0..<k} = setsum f {0..<k}"
  1601 apply(cases k)apply simp
  1602 apply(simp add:setsum_head_upt_Suc)
  1603 done
  1604 
  1605 lemma setsum_atMost_Suc_shift:
  1606   fixes f :: "nat \<Rightarrow> 'a::comm_monoid_add"
  1607   shows "(\<Sum>i\<le>Suc n. f i) = f 0 + (\<Sum>i\<le>n. f (Suc i))"
  1608 proof (induct n)
  1609   case 0 show ?case by simp
  1610 next
  1611   case (Suc n) note IH = this
  1612   have "(\<Sum>i\<le>Suc (Suc n). f i) = (\<Sum>i\<le>Suc n. f i) + f (Suc (Suc n))"
  1613     by (rule setsum_atMost_Suc)
  1614   also have "(\<Sum>i\<le>Suc n. f i) = f 0 + (\<Sum>i\<le>n. f (Suc i))"
  1615     by (rule IH)
  1616   also have "f 0 + (\<Sum>i\<le>n. f (Suc i)) + f (Suc (Suc n)) =
  1617              f 0 + ((\<Sum>i\<le>n. f (Suc i)) + f (Suc (Suc n)))"
  1618     by (rule add.assoc)
  1619   also have "(\<Sum>i\<le>n. f (Suc i)) + f (Suc (Suc n)) = (\<Sum>i\<le>Suc n. f (Suc i))"
  1620     by (rule setsum_atMost_Suc [symmetric])
  1621   finally show ?case .
  1622 qed
  1623 
  1624 lemma setsum_last_plus: fixes n::nat shows "m <= n \<Longrightarrow> (\<Sum>i = m..n. f i) = f n + (\<Sum>i = m..<n. f i)"
  1625   by (cases n) (auto simp: atLeastLessThanSuc_atLeastAtMost add.commute)
  1626 
  1627 lemma setsum_Suc_diff:
  1628   fixes f :: "nat \<Rightarrow> 'a::ab_group_add"
  1629   assumes "m \<le> Suc n"
  1630   shows "(\<Sum>i = m..n. f(Suc i) - f i) = f (Suc n) - f m"
  1631 using assms by (induct n) (auto simp: le_Suc_eq)
  1632 
  1633 lemma nested_setsum_swap:
  1634      "(\<Sum>i = 0..n. (\<Sum>j = 0..<i. a i j)) = (\<Sum>j = 0..<n. \<Sum>i = Suc j..n. a i j)"
  1635   by (induction n) (auto simp: setsum.distrib)
  1636 
  1637 lemma nested_setsum_swap':
  1638      "(\<Sum>i\<le>n. (\<Sum>j<i. a i j)) = (\<Sum>j<n. \<Sum>i = Suc j..n. a i j)"
  1639   by (induction n) (auto simp: setsum.distrib)
  1640 
  1641 lemma setsum_zero_power' [simp]:
  1642   fixes c :: "nat \<Rightarrow> 'a::field"
  1643   shows "(\<Sum>i\<in>A. c i * 0^i / d i) = (if finite A \<and> 0 \<in> A then c 0 / d 0 else 0)"
  1644   using setsum_zero_power [of "\<lambda>i. c i / d i" A]
  1645   by auto
  1646 
  1647 
  1648 subsection \<open>The formula for geometric sums\<close>
  1649 
  1650 lemma geometric_sum:
  1651   assumes "x \<noteq> 1"
  1652   shows "(\<Sum>i<n. x ^ i) = (x ^ n - 1) / (x - 1::'a::field)"
  1653 proof -
  1654   from assms obtain y where "y = x - 1" and "y \<noteq> 0" by simp_all
  1655   moreover have "(\<Sum>i<n. (y + 1) ^ i) = ((y + 1) ^ n - 1) / y"
  1656     by (induct n) (simp_all add: power_Suc field_simps \<open>y \<noteq> 0\<close>)
  1657   ultimately show ?thesis by simp
  1658 qed
  1659 
  1660 lemma diff_power_eq_setsum:
  1661   fixes y :: "'a::{comm_ring,monoid_mult}"
  1662   shows
  1663     "x ^ (Suc n) - y ^ (Suc n) =
  1664       (x - y) * (\<Sum>p<Suc n. (x ^ p) * y ^ (n - p))"
  1665 proof (induct n)
  1666   case (Suc n)
  1667   have "x ^ Suc (Suc n) - y ^ Suc (Suc n) = x * (x * x^n) - y * (y * y ^ n)"
  1668     by (simp add: power_Suc)
  1669   also have "... = y * (x ^ (Suc n) - y ^ (Suc n)) + (x - y) * (x * x^n)"
  1670     by (simp add: power_Suc algebra_simps)
  1671   also have "... = y * ((x - y) * (\<Sum>p<Suc n. (x ^ p) * y ^ (n - p))) + (x - y) * (x * x^n)"
  1672     by (simp only: Suc)
  1673   also have "... = (x - y) * (y * (\<Sum>p<Suc n. (x ^ p) * y ^ (n - p))) + (x - y) * (x * x^n)"
  1674     by (simp only: mult.left_commute)
  1675   also have "... = (x - y) * (\<Sum>p<Suc (Suc n). x ^ p * y ^ (Suc n - p))"
  1676     by (simp add: power_Suc field_simps Suc_diff_le setsum_left_distrib setsum_right_distrib)
  1677   finally show ?case .
  1678 qed simp
  1679 
  1680 corollary power_diff_sumr2: --\<open>@{text COMPLEX_POLYFUN} in HOL Light\<close>
  1681   fixes x :: "'a::{comm_ring,monoid_mult}"
  1682   shows   "x^n - y^n = (x - y) * (\<Sum>i<n. y^(n - Suc i) * x^i)"
  1683 using diff_power_eq_setsum[of x "n - 1" y]
  1684 by (cases "n = 0") (simp_all add: field_simps)
  1685 
  1686 lemma power_diff_1_eq:
  1687   fixes x :: "'a::{comm_ring,monoid_mult}"
  1688   shows "n \<noteq> 0 \<Longrightarrow> x^n - 1 = (x - 1) * (\<Sum>i<n. (x^i))"
  1689 using diff_power_eq_setsum [of x _ 1]
  1690   by (cases n) auto
  1691 
  1692 lemma one_diff_power_eq':
  1693   fixes x :: "'a::{comm_ring,monoid_mult}"
  1694   shows "n \<noteq> 0 \<Longrightarrow> 1 - x^n = (1 - x) * (\<Sum>i<n. x^(n - Suc i))"
  1695 using diff_power_eq_setsum [of 1 _ x]
  1696   by (cases n) auto
  1697 
  1698 lemma one_diff_power_eq:
  1699   fixes x :: "'a::{comm_ring,monoid_mult}"
  1700   shows "n \<noteq> 0 \<Longrightarrow> 1 - x^n = (1 - x) * (\<Sum>i<n. x^i)"
  1701 by (metis one_diff_power_eq' [of n x] nat_diff_setsum_reindex)
  1702 
  1703 
  1704 subsection \<open>The formula for arithmetic sums\<close>
  1705 
  1706 lemma gauss_sum:
  1707   "(2::'a::comm_semiring_1)*(\<Sum>i\<in>{1..n}. of_nat i) = of_nat n*((of_nat n)+1)"
  1708 proof (induct n)
  1709   case 0
  1710   show ?case by simp
  1711 next
  1712   case (Suc n)
  1713   then show ?case
  1714     by (simp add: algebra_simps add: one_add_one [symmetric] del: one_add_one)
  1715       (* FIXME: make numeral cancellation simprocs work for semirings *)
  1716 qed
  1717 
  1718 theorem arith_series_general:
  1719   "(2::'a::comm_semiring_1) * (\<Sum>i\<in>{..<n}. a + of_nat i * d) =
  1720   of_nat n * (a + (a + of_nat(n - 1)*d))"
  1721 proof cases
  1722   assume ngt1: "n > 1"
  1723   let ?I = "\<lambda>i. of_nat i" and ?n = "of_nat n"
  1724   have
  1725     "(\<Sum>i\<in>{..<n}. a+?I i*d) =
  1726      ((\<Sum>i\<in>{..<n}. a) + (\<Sum>i\<in>{..<n}. ?I i*d))"
  1727     by (rule setsum.distrib)
  1728   also from ngt1 have "\<dots> = ?n*a + (\<Sum>i\<in>{..<n}. ?I i*d)" by simp
  1729   also from ngt1 have "\<dots> = (?n*a + d*(\<Sum>i\<in>{1..<n}. ?I i))"
  1730     unfolding One_nat_def
  1731     by (simp add: setsum_right_distrib atLeast0LessThan[symmetric] setsum_shift_lb_Suc0_0_upt ac_simps)
  1732   also have "2*\<dots> = 2*?n*a + d*2*(\<Sum>i\<in>{1..<n}. ?I i)"
  1733     by (simp add: algebra_simps)
  1734   also from ngt1 have "{1..<n} = {1..n - 1}"
  1735     by (cases n) (auto simp: atLeastLessThanSuc_atLeastAtMost)
  1736   also from ngt1
  1737   have "2*?n*a + d*2*(\<Sum>i\<in>{1..n - 1}. ?I i) = (2*?n*a + d*?I (n - 1)*?I n)"
  1738     by (simp only: mult.assoc gauss_sum [of "n - 1"], unfold One_nat_def)
  1739       (simp add:  mult.commute trans [OF add.commute of_nat_Suc [symmetric]])
  1740   finally show ?thesis
  1741     unfolding mult_2 by (simp add: algebra_simps)
  1742 next
  1743   assume "\<not>(n > 1)"
  1744   hence "n = 1 \<or> n = 0" by auto
  1745   thus ?thesis by (auto simp: mult_2)
  1746 qed
  1747 
  1748 lemma arith_series_nat:
  1749   "(2::nat) * (\<Sum>i\<in>{..<n}. a+i*d) = n * (a + (a+(n - 1)*d))"
  1750 proof -
  1751   have
  1752     "2 * (\<Sum>i\<in>{..<n::nat}. a + of_nat(i)*d) =
  1753     of_nat(n) * (a + (a + of_nat(n - 1)*d))"
  1754     by (rule arith_series_general)
  1755   thus ?thesis
  1756     unfolding One_nat_def by auto
  1757 qed
  1758 
  1759 lemma arith_series_int:
  1760   "2 * (\<Sum>i\<in>{..<n}. a + int i * d) = int n * (a + (a + int(n - 1)*d))"
  1761   by (fact arith_series_general) (* FIXME: duplicate *)
  1762 
  1763 lemma sum_diff_distrib: "\<forall>x. Q x \<le> P x  \<Longrightarrow> (\<Sum>x<n. P x) - (\<Sum>x<n. Q x) = (\<Sum>x<n. P x - Q x :: nat)"
  1764   by (subst setsum_subtractf_nat) auto
  1765 
  1766 subsection \<open>Products indexed over intervals\<close>
  1767 
  1768 syntax
  1769   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _ = _.._./ _)" [0,0,0,10] 10)
  1770   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _ = _..<_./ _)" [0,0,0,10] 10)
  1771   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _<_./ _)" [0,0,10] 10)
  1772   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(PROD _<=_./ _)" [0,0,10] 10)
  1773 syntax (xsymbols)
  1774   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _.._./ _)" [0,0,0,10] 10)
  1775   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _..<_./ _)" [0,0,0,10] 10)
  1776   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_<_./ _)" [0,0,10] 10)
  1777   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_\<le>_./ _)" [0,0,10] 10)
  1778 syntax (HTML output)
  1779   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _.._./ _)" [0,0,0,10] 10)
  1780   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_ = _..<_./ _)" [0,0,0,10] 10)
  1781   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_<_./ _)" [0,0,10] 10)
  1782   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b" ("(3\<Prod>_\<le>_./ _)" [0,0,10] 10)
  1783 syntax (latex_prod output)
  1784   "_from_to_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1785  ("(3\<^raw:$\prod_{>_ = _\<^raw:}^{>_\<^raw:}$> _)" [0,0,0,10] 10)
  1786   "_from_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1787  ("(3\<^raw:$\prod_{>_ = _\<^raw:}^{<>_\<^raw:}$> _)" [0,0,0,10] 10)
  1788   "_upt_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1789  ("(3\<^raw:$\prod_{>_ < _\<^raw:}$> _)" [0,0,10] 10)
  1790   "_upto_setprod" :: "idt \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'b"
  1791  ("(3\<^raw:$\prod_{>_ \<le> _\<^raw:}$> _)" [0,0,10] 10)
  1792 
  1793 translations
  1794   "\<Prod>x=a..b. t" == "CONST setprod (%x. t) {a..b}"
  1795   "\<Prod>x=a..<b. t" == "CONST setprod (%x. t) {a..<b}"
  1796   "\<Prod>i\<le>n. t" == "CONST setprod (\<lambda>i. t) {..n}"
  1797   "\<Prod>i<n. t" == "CONST setprod (\<lambda>i. t) {..<n}"
  1798 
  1799 subsection \<open>Transfer setup\<close>
  1800 
  1801 lemma transfer_nat_int_set_functions:
  1802     "{..n} = nat ` {0..int n}"
  1803     "{m..n} = nat ` {int m..int n}"  (* need all variants of these! *)
  1804   apply (auto simp add: image_def)
  1805   apply (rule_tac x = "int x" in bexI)
  1806   apply auto
  1807   apply (rule_tac x = "int x" in bexI)
  1808   apply auto
  1809   done
  1810 
  1811 lemma transfer_nat_int_set_function_closures:
  1812     "x >= 0 \<Longrightarrow> nat_set {x..y}"
  1813   by (simp add: nat_set_def)
  1814 
  1815 declare transfer_morphism_nat_int[transfer add
  1816   return: transfer_nat_int_set_functions
  1817     transfer_nat_int_set_function_closures
  1818 ]
  1819 
  1820 lemma transfer_int_nat_set_functions:
  1821     "is_nat m \<Longrightarrow> is_nat n \<Longrightarrow> {m..n} = int ` {nat m..nat n}"
  1822   by (simp only: is_nat_def transfer_nat_int_set_functions
  1823     transfer_nat_int_set_function_closures
  1824     transfer_nat_int_set_return_embed nat_0_le
  1825     cong: transfer_nat_int_set_cong)
  1826 
  1827 lemma transfer_int_nat_set_function_closures:
  1828     "is_nat x \<Longrightarrow> nat_set {x..y}"
  1829   by (simp only: transfer_nat_int_set_function_closures is_nat_def)
  1830 
  1831 declare transfer_morphism_int_nat[transfer add
  1832   return: transfer_int_nat_set_functions
  1833     transfer_int_nat_set_function_closures
  1834 ]
  1835 
  1836 lemma setprod_int_plus_eq: "setprod int {i..i+j} =  \<Prod>{int i..int (i+j)}"
  1837   by (induct j) (auto simp add: atLeastAtMostSuc_conv atLeastAtMostPlus1_int_conv)
  1838 
  1839 lemma setprod_int_eq: "setprod int {i..j} =  \<Prod>{int i..int j}"
  1840 proof (cases "i \<le> j")
  1841   case True
  1842   then show ?thesis
  1843     by (metis Nat.le_iff_add setprod_int_plus_eq)
  1844 next
  1845   case False
  1846   then show ?thesis
  1847     by auto
  1848 qed
  1849 
  1850 end