src/HOL/Transitive_Closure.thy
author wenzelm
Mon Aug 31 21:28:08 2015 +0200 (2015-08-31)
changeset 61070 b72a990adfe2
parent 61032 b57df8eecad6
child 61378 3e04c9ca001a
permissions -rw-r--r--
prefer symbols;
     1 (*  Title:      HOL/Transitive_Closure.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 section \<open>Reflexive and Transitive closure of a relation\<close>
     7 
     8 theory Transitive_Closure
     9 imports Relation
    10 begin
    11 
    12 ML_file "~~/src/Provers/trancl.ML"
    13 
    14 text \<open>
    15   @{text rtrancl} is reflexive/transitive closure,
    16   @{text trancl} is transitive closure,
    17   @{text reflcl} is reflexive closure.
    18 
    19   These postfix operators have \emph{maximum priority}, forcing their
    20   operands to be atomic.
    21 \<close>
    22 
    23 inductive_set
    24   rtrancl :: "('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set"   ("(_^*)" [1000] 999)
    25   for r :: "('a \<times> 'a) set"
    26 where
    27     rtrancl_refl [intro!, Pure.intro!, simp]: "(a, a) : r^*"
    28   | rtrancl_into_rtrancl [Pure.intro]: "(a, b) : r^* ==> (b, c) : r ==> (a, c) : r^*"
    29 
    30 inductive_set
    31   trancl :: "('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set"  ("(_^+)" [1000] 999)
    32   for r :: "('a \<times> 'a) set"
    33 where
    34     r_into_trancl [intro, Pure.intro]: "(a, b) : r ==> (a, b) : r^+"
    35   | trancl_into_trancl [Pure.intro]: "(a, b) : r^+ ==> (b, c) : r ==> (a, c) : r^+"
    36 
    37 declare rtrancl_def [nitpick_unfold del]
    38         rtranclp_def [nitpick_unfold del]
    39         trancl_def [nitpick_unfold del]
    40         tranclp_def [nitpick_unfold del]
    41 
    42 notation
    43   rtranclp  ("(_^**)" [1000] 1000) and
    44   tranclp  ("(_^++)" [1000] 1000)
    45 
    46 abbreviation
    47   reflclp :: "('a => 'a => bool) => 'a => 'a => bool"  ("(_^==)" [1000] 1000) where
    48   "r^== \<equiv> sup r op ="
    49 
    50 abbreviation
    51   reflcl :: "('a \<times> 'a) set => ('a \<times> 'a) set"  ("(_^=)" [1000] 999) where
    52   "r^= \<equiv> r \<union> Id"
    53 
    54 notation (xsymbols)
    55   rtranclp  ("(_\<^sup>*\<^sup>*)" [1000] 1000) and
    56   tranclp  ("(_\<^sup>+\<^sup>+)" [1000] 1000) and
    57   reflclp  ("(_\<^sup>=\<^sup>=)" [1000] 1000) and
    58   rtrancl  ("(_\<^sup>*)" [1000] 999) and
    59   trancl  ("(_\<^sup>+)" [1000] 999) and
    60   reflcl  ("(_\<^sup>=)" [1000] 999)
    61 
    62 notation (HTML output)
    63   rtranclp  ("(_\<^sup>*\<^sup>*)" [1000] 1000) and
    64   tranclp  ("(_\<^sup>+\<^sup>+)" [1000] 1000) and
    65   reflclp  ("(_\<^sup>=\<^sup>=)" [1000] 1000) and
    66   rtrancl  ("(_\<^sup>*)" [1000] 999) and
    67   trancl  ("(_\<^sup>+)" [1000] 999) and
    68   reflcl  ("(_\<^sup>=)" [1000] 999)
    69 
    70 
    71 subsection \<open>Reflexive closure\<close>
    72 
    73 lemma refl_reflcl[simp]: "refl(r^=)"
    74 by(simp add:refl_on_def)
    75 
    76 lemma antisym_reflcl[simp]: "antisym(r^=) = antisym r"
    77 by(simp add:antisym_def)
    78 
    79 lemma trans_reflclI[simp]: "trans r \<Longrightarrow> trans(r^=)"
    80 unfolding trans_def by blast
    81 
    82 lemma reflclp_idemp [simp]: "(P^==)^==  =  P^=="
    83 by blast
    84 
    85 subsection \<open>Reflexive-transitive closure\<close>
    86 
    87 lemma reflcl_set_eq [pred_set_conv]: "(sup (\<lambda>x y. (x, y) \<in> r) op =) = (\<lambda>x y. (x, y) \<in> r \<union> Id)"
    88   by (auto simp add: fun_eq_iff)
    89 
    90 lemma r_into_rtrancl [intro]: "!!p. p \<in> r ==> p \<in> r^*"
    91   -- \<open>@{text rtrancl} of @{text r} contains @{text r}\<close>
    92   apply (simp only: split_tupled_all)
    93   apply (erule rtrancl_refl [THEN rtrancl_into_rtrancl])
    94   done
    95 
    96 lemma r_into_rtranclp [intro]: "r x y ==> r^** x y"
    97   -- \<open>@{text rtrancl} of @{text r} contains @{text r}\<close>
    98   by (erule rtranclp.rtrancl_refl [THEN rtranclp.rtrancl_into_rtrancl])
    99 
   100 lemma rtranclp_mono: "r \<le> s ==> r^** \<le> s^**"
   101   -- \<open>monotonicity of @{text rtrancl}\<close>
   102   apply (rule predicate2I)
   103   apply (erule rtranclp.induct)
   104    apply (rule_tac [2] rtranclp.rtrancl_into_rtrancl, blast+)
   105   done
   106 
   107 lemma mono_rtranclp[mono]:
   108    "(\<And>a b. x a b \<longrightarrow> y a b) \<Longrightarrow> x^** a b \<longrightarrow> y^** a b"
   109    using rtranclp_mono[of x y] by auto
   110 
   111 lemmas rtrancl_mono = rtranclp_mono [to_set]
   112 
   113 theorem rtranclp_induct [consumes 1, case_names base step, induct set: rtranclp]:
   114   assumes a: "r^** a b"
   115     and cases: "P a" "!!y z. [| r^** a y; r y z; P y |] ==> P z"
   116   shows "P b" using a
   117   by (induct x\<equiv>a b) (rule cases)+
   118 
   119 lemmas rtrancl_induct [induct set: rtrancl] = rtranclp_induct [to_set]
   120 
   121 lemmas rtranclp_induct2 =
   122   rtranclp_induct[of _ "(ax,ay)" "(bx,by)", split_rule,
   123                  consumes 1, case_names refl step]
   124 
   125 lemmas rtrancl_induct2 =
   126   rtrancl_induct[of "(ax,ay)" "(bx,by)", split_format (complete),
   127                  consumes 1, case_names refl step]
   128 
   129 lemma refl_rtrancl: "refl (r^*)"
   130 by (unfold refl_on_def) fast
   131 
   132 text \<open>Transitivity of transitive closure.\<close>
   133 lemma trans_rtrancl: "trans (r^*)"
   134 proof (rule transI)
   135   fix x y z
   136   assume "(x, y) \<in> r\<^sup>*"
   137   assume "(y, z) \<in> r\<^sup>*"
   138   then show "(x, z) \<in> r\<^sup>*"
   139   proof induct
   140     case base
   141     show "(x, y) \<in> r\<^sup>*" by fact
   142   next
   143     case (step u v)
   144     from \<open>(x, u) \<in> r\<^sup>*\<close> and \<open>(u, v) \<in> r\<close>
   145     show "(x, v) \<in> r\<^sup>*" ..
   146   qed
   147 qed
   148 
   149 lemmas rtrancl_trans = trans_rtrancl [THEN transD]
   150 
   151 lemma rtranclp_trans:
   152   assumes xy: "r^** x y"
   153   and yz: "r^** y z"
   154   shows "r^** x z" using yz xy
   155   by induct iprover+
   156 
   157 lemma rtranclE [cases set: rtrancl]:
   158   assumes major: "(a::'a, b) : r^*"
   159   obtains
   160     (base) "a = b"
   161   | (step) y where "(a, y) : r^*" and "(y, b) : r"
   162   -- \<open>elimination of @{text rtrancl} -- by induction on a special formula\<close>
   163   apply (subgoal_tac "(a::'a) = b | (EX y. (a,y) : r^* & (y,b) : r)")
   164    apply (rule_tac [2] major [THEN rtrancl_induct])
   165     prefer 2 apply blast
   166    prefer 2 apply blast
   167   apply (erule asm_rl exE disjE conjE base step)+
   168   done
   169 
   170 lemma rtrancl_Int_subset: "[| Id \<subseteq> s; (r^* \<inter> s) O r \<subseteq> s|] ==> r^* \<subseteq> s"
   171   apply (rule subsetI)
   172   apply auto
   173   apply (erule rtrancl_induct)
   174   apply auto
   175   done
   176 
   177 lemma converse_rtranclp_into_rtranclp:
   178   "r a b \<Longrightarrow> r\<^sup>*\<^sup>* b c \<Longrightarrow> r\<^sup>*\<^sup>* a c"
   179   by (rule rtranclp_trans) iprover+
   180 
   181 lemmas converse_rtrancl_into_rtrancl = converse_rtranclp_into_rtranclp [to_set]
   182 
   183 text \<open>
   184   \medskip More @{term "r^*"} equations and inclusions.
   185 \<close>
   186 
   187 lemma rtranclp_idemp [simp]: "(r^**)^** = r^**"
   188   apply (auto intro!: order_antisym)
   189   apply (erule rtranclp_induct)
   190    apply (rule rtranclp.rtrancl_refl)
   191   apply (blast intro: rtranclp_trans)
   192   done
   193 
   194 lemmas rtrancl_idemp [simp] = rtranclp_idemp [to_set]
   195 
   196 lemma rtrancl_idemp_self_comp [simp]: "R^* O R^* = R^*"
   197   apply (rule set_eqI)
   198   apply (simp only: split_tupled_all)
   199   apply (blast intro: rtrancl_trans)
   200   done
   201 
   202 lemma rtrancl_subset_rtrancl: "r \<subseteq> s^* ==> r^* \<subseteq> s^*"
   203   apply (drule rtrancl_mono)
   204   apply simp
   205   done
   206 
   207 lemma rtranclp_subset: "R \<le> S ==> S \<le> R^** ==> S^** = R^**"
   208   apply (drule rtranclp_mono)
   209   apply (drule rtranclp_mono)
   210   apply simp
   211   done
   212 
   213 lemmas rtrancl_subset = rtranclp_subset [to_set]
   214 
   215 lemma rtranclp_sup_rtranclp: "(sup (R^**) (S^**))^** = (sup R S)^**"
   216 by (blast intro!: rtranclp_subset intro: rtranclp_mono [THEN predicate2D])
   217 
   218 lemmas rtrancl_Un_rtrancl = rtranclp_sup_rtranclp [to_set]
   219 
   220 lemma rtranclp_reflclp [simp]: "(R^==)^** = R^**"
   221 by (blast intro!: rtranclp_subset)
   222 
   223 lemmas rtrancl_reflcl [simp] = rtranclp_reflclp [to_set]
   224 
   225 lemma rtrancl_r_diff_Id: "(r - Id)^* = r^*"
   226   apply (rule sym)
   227   apply (rule rtrancl_subset, blast, clarify)
   228   apply (rename_tac a b)
   229   apply (case_tac "a = b")
   230    apply blast
   231   apply blast
   232   done
   233 
   234 lemma rtranclp_r_diff_Id: "(inf r op ~=)^** = r^**"
   235   apply (rule sym)
   236   apply (rule rtranclp_subset)
   237    apply blast+
   238   done
   239 
   240 theorem rtranclp_converseD:
   241   assumes r: "(r^--1)^** x y"
   242   shows "r^** y x"
   243 proof -
   244   from r show ?thesis
   245     by induct (iprover intro: rtranclp_trans dest!: conversepD)+
   246 qed
   247 
   248 lemmas rtrancl_converseD = rtranclp_converseD [to_set]
   249 
   250 theorem rtranclp_converseI:
   251   assumes "r^** y x"
   252   shows "(r^--1)^** x y"
   253   using assms
   254   by induct (iprover intro: rtranclp_trans conversepI)+
   255 
   256 lemmas rtrancl_converseI = rtranclp_converseI [to_set]
   257 
   258 lemma rtrancl_converse: "(r^-1)^* = (r^*)^-1"
   259   by (fast dest!: rtrancl_converseD intro!: rtrancl_converseI)
   260 
   261 lemma sym_rtrancl: "sym r ==> sym (r^*)"
   262   by (simp only: sym_conv_converse_eq rtrancl_converse [symmetric])
   263 
   264 theorem converse_rtranclp_induct [consumes 1, case_names base step]:
   265   assumes major: "r^** a b"
   266     and cases: "P b" "!!y z. [| r y z; r^** z b; P z |] ==> P y"
   267   shows "P a"
   268   using rtranclp_converseI [OF major]
   269   by induct (iprover intro: cases dest!: conversepD rtranclp_converseD)+
   270 
   271 lemmas converse_rtrancl_induct = converse_rtranclp_induct [to_set]
   272 
   273 lemmas converse_rtranclp_induct2 =
   274   converse_rtranclp_induct [of _ "(ax,ay)" "(bx,by)", split_rule,
   275                  consumes 1, case_names refl step]
   276 
   277 lemmas converse_rtrancl_induct2 =
   278   converse_rtrancl_induct [of "(ax,ay)" "(bx,by)", split_format (complete),
   279                  consumes 1, case_names refl step]
   280 
   281 lemma converse_rtranclpE [consumes 1, case_names base step]:
   282   assumes major: "r^** x z"
   283     and cases: "x=z ==> P"
   284       "!!y. [| r x y; r^** y z |] ==> P"
   285   shows P
   286   apply (subgoal_tac "x = z | (EX y. r x y & r^** y z)")
   287    apply (rule_tac [2] major [THEN converse_rtranclp_induct])
   288     prefer 2 apply iprover
   289    prefer 2 apply iprover
   290   apply (erule asm_rl exE disjE conjE cases)+
   291   done
   292 
   293 lemmas converse_rtranclE = converse_rtranclpE [to_set]
   294 
   295 lemmas converse_rtranclpE2 = converse_rtranclpE [of _ "(xa,xb)" "(za,zb)", split_rule]
   296 
   297 lemmas converse_rtranclE2 = converse_rtranclE [of "(xa,xb)" "(za,zb)", split_rule]
   298 
   299 lemma r_comp_rtrancl_eq: "r O r^* = r^* O r"
   300   by (blast elim: rtranclE converse_rtranclE
   301     intro: rtrancl_into_rtrancl converse_rtrancl_into_rtrancl)
   302 
   303 lemma rtrancl_unfold: "r^* = Id Un r^* O r"
   304   by (auto intro: rtrancl_into_rtrancl elim: rtranclE)
   305 
   306 lemma rtrancl_Un_separatorE:
   307   "(a,b) : (P \<union> Q)^* \<Longrightarrow> \<forall>x y. (a,x) : P^* \<longrightarrow> (x,y) : Q \<longrightarrow> x=y \<Longrightarrow> (a,b) : P^*"
   308 apply (induct rule:rtrancl.induct)
   309  apply blast
   310 apply (blast intro:rtrancl_trans)
   311 done
   312 
   313 lemma rtrancl_Un_separator_converseE:
   314   "(a,b) : (P \<union> Q)^* \<Longrightarrow> \<forall>x y. (x,b) : P^* \<longrightarrow> (y,x) : Q \<longrightarrow> y=x \<Longrightarrow> (a,b) : P^*"
   315 apply (induct rule:converse_rtrancl_induct)
   316  apply blast
   317 apply (blast intro:rtrancl_trans)
   318 done
   319 
   320 lemma Image_closed_trancl:
   321   assumes "r `` X \<subseteq> X" shows "r\<^sup>* `` X = X"
   322 proof -
   323   from assms have **: "{y. \<exists>x\<in>X. (x, y) \<in> r} \<subseteq> X" by auto
   324   have "\<And>x y. (y, x) \<in> r\<^sup>* \<Longrightarrow> y \<in> X \<Longrightarrow> x \<in> X"
   325   proof -
   326     fix x y
   327     assume *: "y \<in> X"
   328     assume "(y, x) \<in> r\<^sup>*"
   329     then show "x \<in> X"
   330     proof induct
   331       case base show ?case by (fact *)
   332     next
   333       case step with ** show ?case by auto
   334     qed
   335   qed
   336   then show ?thesis by auto
   337 qed
   338 
   339 
   340 subsection \<open>Transitive closure\<close>
   341 
   342 lemma trancl_mono: "!!p. p \<in> r^+ ==> r \<subseteq> s ==> p \<in> s^+"
   343   apply (simp add: split_tupled_all)
   344   apply (erule trancl.induct)
   345    apply (iprover dest: subsetD)+
   346   done
   347 
   348 lemma r_into_trancl': "!!p. p : r ==> p : r^+"
   349   by (simp only: split_tupled_all) (erule r_into_trancl)
   350 
   351 text \<open>
   352   \medskip Conversions between @{text trancl} and @{text rtrancl}.
   353 \<close>
   354 
   355 lemma tranclp_into_rtranclp: "r^++ a b ==> r^** a b"
   356   by (erule tranclp.induct) iprover+
   357 
   358 lemmas trancl_into_rtrancl = tranclp_into_rtranclp [to_set]
   359 
   360 lemma rtranclp_into_tranclp1: assumes r: "r^** a b"
   361   shows "!!c. r b c ==> r^++ a c" using r
   362   by induct iprover+
   363 
   364 lemmas rtrancl_into_trancl1 = rtranclp_into_tranclp1 [to_set]
   365 
   366 lemma rtranclp_into_tranclp2: "[| r a b; r^** b c |] ==> r^++ a c"
   367   -- \<open>intro rule from @{text r} and @{text rtrancl}\<close>
   368   apply (erule rtranclp.cases)
   369    apply iprover
   370   apply (rule rtranclp_trans [THEN rtranclp_into_tranclp1])
   371     apply (simp | rule r_into_rtranclp)+
   372   done
   373 
   374 lemmas rtrancl_into_trancl2 = rtranclp_into_tranclp2 [to_set]
   375 
   376 text \<open>Nice induction rule for @{text trancl}\<close>
   377 lemma tranclp_induct [consumes 1, case_names base step, induct pred: tranclp]:
   378   assumes a: "r^++ a b"
   379   and cases: "!!y. r a y ==> P y"
   380     "!!y z. r^++ a y ==> r y z ==> P y ==> P z"
   381   shows "P b" using a
   382   by (induct x\<equiv>a b) (iprover intro: cases)+
   383 
   384 lemmas trancl_induct [induct set: trancl] = tranclp_induct [to_set]
   385 
   386 lemmas tranclp_induct2 =
   387   tranclp_induct [of _ "(ax,ay)" "(bx,by)", split_rule,
   388     consumes 1, case_names base step]
   389 
   390 lemmas trancl_induct2 =
   391   trancl_induct [of "(ax,ay)" "(bx,by)", split_format (complete),
   392     consumes 1, case_names base step]
   393 
   394 lemma tranclp_trans_induct:
   395   assumes major: "r^++ x y"
   396     and cases: "!!x y. r x y ==> P x y"
   397       "!!x y z. [| r^++ x y; P x y; r^++ y z; P y z |] ==> P x z"
   398   shows "P x y"
   399   -- \<open>Another induction rule for trancl, incorporating transitivity\<close>
   400   by (iprover intro: major [THEN tranclp_induct] cases)
   401 
   402 lemmas trancl_trans_induct = tranclp_trans_induct [to_set]
   403 
   404 lemma tranclE [cases set: trancl]:
   405   assumes "(a, b) : r^+"
   406   obtains
   407     (base) "(a, b) : r"
   408   | (step) c where "(a, c) : r^+" and "(c, b) : r"
   409   using assms by cases simp_all
   410 
   411 lemma trancl_Int_subset: "[| r \<subseteq> s; (r^+ \<inter> s) O r \<subseteq> s|] ==> r^+ \<subseteq> s"
   412   apply (rule subsetI)
   413   apply auto
   414   apply (erule trancl_induct)
   415   apply auto
   416   done
   417 
   418 lemma trancl_unfold: "r^+ = r Un r^+ O r"
   419   by (auto intro: trancl_into_trancl elim: tranclE)
   420 
   421 text \<open>Transitivity of @{term "r^+"}\<close>
   422 lemma trans_trancl [simp]: "trans (r^+)"
   423 proof (rule transI)
   424   fix x y z
   425   assume "(x, y) \<in> r^+"
   426   assume "(y, z) \<in> r^+"
   427   then show "(x, z) \<in> r^+"
   428   proof induct
   429     case (base u)
   430     from \<open>(x, y) \<in> r^+\<close> and \<open>(y, u) \<in> r\<close>
   431     show "(x, u) \<in> r^+" ..
   432   next
   433     case (step u v)
   434     from \<open>(x, u) \<in> r^+\<close> and \<open>(u, v) \<in> r\<close>
   435     show "(x, v) \<in> r^+" ..
   436   qed
   437 qed
   438 
   439 lemmas trancl_trans = trans_trancl [THEN transD]
   440 
   441 lemma tranclp_trans:
   442   assumes xy: "r^++ x y"
   443   and yz: "r^++ y z"
   444   shows "r^++ x z" using yz xy
   445   by induct iprover+
   446 
   447 lemma trancl_id [simp]: "trans r \<Longrightarrow> r^+ = r"
   448   apply auto
   449   apply (erule trancl_induct)
   450    apply assumption
   451   apply (unfold trans_def)
   452   apply blast
   453   done
   454 
   455 lemma rtranclp_tranclp_tranclp:
   456   assumes "r^** x y"
   457   shows "!!z. r^++ y z ==> r^++ x z" using assms
   458   by induct (iprover intro: tranclp_trans)+
   459 
   460 lemmas rtrancl_trancl_trancl = rtranclp_tranclp_tranclp [to_set]
   461 
   462 lemma tranclp_into_tranclp2: "r a b ==> r^++ b c ==> r^++ a c"
   463   by (erule tranclp_trans [OF tranclp.r_into_trancl])
   464 
   465 lemmas trancl_into_trancl2 = tranclp_into_tranclp2 [to_set]
   466 
   467 lemma tranclp_converseI: "(r^++)^--1 x y ==> (r^--1)^++ x y"
   468   apply (drule conversepD)
   469   apply (erule tranclp_induct)
   470   apply (iprover intro: conversepI tranclp_trans)+
   471   done
   472 
   473 lemmas trancl_converseI = tranclp_converseI [to_set]
   474 
   475 lemma tranclp_converseD: "(r^--1)^++ x y ==> (r^++)^--1 x y"
   476   apply (rule conversepI)
   477   apply (erule tranclp_induct)
   478   apply (iprover dest: conversepD intro: tranclp_trans)+
   479   done
   480 
   481 lemmas trancl_converseD = tranclp_converseD [to_set]
   482 
   483 lemma tranclp_converse: "(r^--1)^++ = (r^++)^--1"
   484   by (fastforce simp add: fun_eq_iff
   485     intro!: tranclp_converseI dest!: tranclp_converseD)
   486 
   487 lemmas trancl_converse = tranclp_converse [to_set]
   488 
   489 lemma sym_trancl: "sym r ==> sym (r^+)"
   490   by (simp only: sym_conv_converse_eq trancl_converse [symmetric])
   491 
   492 lemma converse_tranclp_induct [consumes 1, case_names base step]:
   493   assumes major: "r^++ a b"
   494     and cases: "!!y. r y b ==> P(y)"
   495       "!!y z.[| r y z;  r^++ z b;  P(z) |] ==> P(y)"
   496   shows "P a"
   497   apply (rule tranclp_induct [OF tranclp_converseI, OF conversepI, OF major])
   498    apply (rule cases)
   499    apply (erule conversepD)
   500   apply (blast intro: assms dest!: tranclp_converseD)
   501   done
   502 
   503 lemmas converse_trancl_induct = converse_tranclp_induct [to_set]
   504 
   505 lemma tranclpD: "R^++ x y ==> EX z. R x z \<and> R^** z y"
   506   apply (erule converse_tranclp_induct)
   507    apply auto
   508   apply (blast intro: rtranclp_trans)
   509   done
   510 
   511 lemmas tranclD = tranclpD [to_set]
   512 
   513 lemma converse_tranclpE:
   514   assumes major: "tranclp r x z"
   515   assumes base: "r x z ==> P"
   516   assumes step: "\<And> y. [| r x y; tranclp r y z |] ==> P"
   517   shows P
   518 proof -
   519   from tranclpD[OF major]
   520   obtain y where "r x y" and "rtranclp r y z" by iprover
   521   from this(2) show P
   522   proof (cases rule: rtranclp.cases)
   523     case rtrancl_refl
   524     with \<open>r x y\<close> base show P by iprover
   525   next
   526     case rtrancl_into_rtrancl
   527     from this have "tranclp r y z"
   528       by (iprover intro: rtranclp_into_tranclp1)
   529     with \<open>r x y\<close> step show P by iprover
   530   qed
   531 qed
   532 
   533 lemmas converse_tranclE = converse_tranclpE [to_set]
   534 
   535 lemma tranclD2:
   536   "(x, y) \<in> R\<^sup>+ \<Longrightarrow> \<exists>z. (x, z) \<in> R\<^sup>* \<and> (z, y) \<in> R"
   537   by (blast elim: tranclE intro: trancl_into_rtrancl)
   538 
   539 lemma irrefl_tranclI: "r^-1 \<inter> r^* = {} ==> (x, x) \<notin> r^+"
   540   by (blast elim: tranclE dest: trancl_into_rtrancl)
   541 
   542 lemma irrefl_trancl_rD: "!!X. ALL x. (x, x) \<notin> r^+ ==> (x, y) \<in> r ==> x \<noteq> y"
   543   by (blast dest: r_into_trancl)
   544 
   545 lemma trancl_subset_Sigma_aux:
   546     "(a, b) \<in> r^* ==> r \<subseteq> A \<times> A ==> a = b \<or> a \<in> A"
   547   by (induct rule: rtrancl_induct) auto
   548 
   549 lemma trancl_subset_Sigma: "r \<subseteq> A \<times> A ==> r^+ \<subseteq> A \<times> A"
   550   apply (rule subsetI)
   551   apply (simp only: split_tupled_all)
   552   apply (erule tranclE)
   553    apply (blast dest!: trancl_into_rtrancl trancl_subset_Sigma_aux)+
   554   done
   555 
   556 lemma reflclp_tranclp [simp]: "(r^++)^== = r^**"
   557   apply (safe intro!: order_antisym)
   558    apply (erule tranclp_into_rtranclp)
   559   apply (blast elim: rtranclp.cases dest: rtranclp_into_tranclp1)
   560   done
   561 
   562 lemmas reflcl_trancl [simp] = reflclp_tranclp [to_set]
   563 
   564 lemma trancl_reflcl [simp]: "(r^=)^+ = r^*"
   565   apply safe
   566    apply (drule trancl_into_rtrancl, simp)
   567   apply (erule rtranclE, safe)
   568    apply (rule r_into_trancl, simp)
   569   apply (rule rtrancl_into_trancl1)
   570    apply (erule rtrancl_reflcl [THEN equalityD2, THEN subsetD], fast)
   571   done
   572 
   573 lemma rtrancl_trancl_reflcl [code]: "r^* = (r^+)^="
   574   by simp
   575 
   576 lemma trancl_empty [simp]: "{}^+ = {}"
   577   by (auto elim: trancl_induct)
   578 
   579 lemma rtrancl_empty [simp]: "{}^* = Id"
   580   by (rule subst [OF reflcl_trancl]) simp
   581 
   582 lemma rtranclpD: "R^** a b ==> a = b \<or> a \<noteq> b \<and> R^++ a b"
   583 by (force simp add: reflclp_tranclp [symmetric] simp del: reflclp_tranclp)
   584 
   585 lemmas rtranclD = rtranclpD [to_set]
   586 
   587 lemma rtrancl_eq_or_trancl:
   588   "(x,y) \<in> R\<^sup>* = (x=y \<or> x\<noteq>y \<and> (x,y) \<in> R\<^sup>+)"
   589   by (fast elim: trancl_into_rtrancl dest: rtranclD)
   590 
   591 lemma trancl_unfold_right: "r^+ = r^* O r"
   592 by (auto dest: tranclD2 intro: rtrancl_into_trancl1)
   593 
   594 lemma trancl_unfold_left: "r^+ = r O r^*"
   595 by (auto dest: tranclD intro: rtrancl_into_trancl2)
   596 
   597 lemma trancl_insert:
   598   "(insert (y, x) r)^+ = r^+ \<union> {(a, b). (a, y) \<in> r^* \<and> (x, b) \<in> r^*}"
   599   -- \<open>primitive recursion for @{text trancl} over finite relations\<close>
   600   apply (rule equalityI)
   601    apply (rule subsetI)
   602    apply (simp only: split_tupled_all)
   603    apply (erule trancl_induct, blast)
   604    apply (blast intro: rtrancl_into_trancl1 trancl_into_rtrancl trancl_trans)
   605   apply (rule subsetI)
   606   apply (blast intro: trancl_mono rtrancl_mono
   607     [THEN [2] rev_subsetD] rtrancl_trancl_trancl rtrancl_into_trancl2)
   608   done
   609 
   610 lemma trancl_insert2:
   611   "(insert (a,b) r)^+ = r^+ \<union> {(x,y). ((x,a) : r^+ \<or> x=a) \<and> ((b,y) \<in> r^+ \<or> y=b)}"
   612 by(auto simp add: trancl_insert rtrancl_eq_or_trancl)
   613 
   614 lemma rtrancl_insert:
   615   "(insert (a,b) r)^* = r^* \<union> {(x,y). (x,a) : r^* \<and> (b,y) \<in> r^*}"
   616 using trancl_insert[of a b r]
   617 by(simp add: rtrancl_trancl_reflcl del: reflcl_trancl) blast
   618 
   619 
   620 text \<open>Simplifying nested closures\<close>
   621 
   622 lemma rtrancl_trancl_absorb[simp]: "(R^*)^+ = R^*"
   623 by (simp add: trans_rtrancl)
   624 
   625 lemma trancl_rtrancl_absorb[simp]: "(R^+)^* = R^*"
   626 by (subst reflcl_trancl[symmetric]) simp
   627 
   628 lemma rtrancl_reflcl_absorb[simp]: "(R^*)^= = R^*"
   629 by auto
   630 
   631 
   632 text \<open>@{text Domain} and @{text Range}\<close>
   633 
   634 lemma Domain_rtrancl [simp]: "Domain (R^*) = UNIV"
   635   by blast
   636 
   637 lemma Range_rtrancl [simp]: "Range (R^*) = UNIV"
   638   by blast
   639 
   640 lemma rtrancl_Un_subset: "(R^* \<union> S^*) \<subseteq> (R Un S)^*"
   641   by (rule rtrancl_Un_rtrancl [THEN subst]) fast
   642 
   643 lemma in_rtrancl_UnI: "x \<in> R^* \<or> x \<in> S^* ==> x \<in> (R \<union> S)^*"
   644   by (blast intro: subsetD [OF rtrancl_Un_subset])
   645 
   646 lemma trancl_domain [simp]: "Domain (r^+) = Domain r"
   647   by (unfold Domain_unfold) (blast dest: tranclD)
   648 
   649 lemma trancl_range [simp]: "Range (r^+) = Range r"
   650   unfolding Domain_converse [symmetric] by (simp add: trancl_converse [symmetric])
   651 
   652 lemma Not_Domain_rtrancl:
   653     "x ~: Domain R ==> ((x, y) : R^*) = (x = y)"
   654   apply auto
   655   apply (erule rev_mp)
   656   apply (erule rtrancl_induct)
   657    apply auto
   658   done
   659 
   660 lemma trancl_subset_Field2: "r^+ <= Field r \<times> Field r"
   661   apply clarify
   662   apply (erule trancl_induct)
   663    apply (auto simp add: Field_def)
   664   done
   665 
   666 lemma finite_trancl[simp]: "finite (r^+) = finite r"
   667   apply auto
   668    prefer 2
   669    apply (rule trancl_subset_Field2 [THEN finite_subset])
   670    apply (rule finite_SigmaI)
   671     prefer 3
   672     apply (blast intro: r_into_trancl' finite_subset)
   673    apply (auto simp add: finite_Field)
   674   done
   675 
   676 text \<open>More about converse @{text rtrancl} and @{text trancl}, should
   677   be merged with main body.\<close>
   678 
   679 lemma single_valued_confluent:
   680   "\<lbrakk> single_valued r; (x,y) \<in> r^*; (x,z) \<in> r^* \<rbrakk>
   681   \<Longrightarrow> (y,z) \<in> r^* \<or> (z,y) \<in> r^*"
   682   apply (erule rtrancl_induct)
   683   apply simp
   684   apply (erule disjE)
   685    apply (blast elim:converse_rtranclE dest:single_valuedD)
   686   apply(blast intro:rtrancl_trans)
   687   done
   688 
   689 lemma r_r_into_trancl: "(a, b) \<in> R ==> (b, c) \<in> R ==> (a, c) \<in> R^+"
   690   by (fast intro: trancl_trans)
   691 
   692 lemma trancl_into_trancl [rule_format]:
   693     "(a, b) \<in> r\<^sup>+ ==> (b, c) \<in> r --> (a,c) \<in> r\<^sup>+"
   694   apply (erule trancl_induct)
   695    apply (fast intro: r_r_into_trancl)
   696   apply (fast intro: r_r_into_trancl trancl_trans)
   697   done
   698 
   699 lemma tranclp_rtranclp_tranclp:
   700     "r\<^sup>+\<^sup>+ a b ==> r\<^sup>*\<^sup>* b c ==> r\<^sup>+\<^sup>+ a c"
   701   apply (drule tranclpD)
   702   apply (elim exE conjE)
   703   apply (drule rtranclp_trans, assumption)
   704   apply (drule rtranclp_into_tranclp2, assumption, assumption)
   705   done
   706 
   707 lemmas trancl_rtrancl_trancl = tranclp_rtranclp_tranclp [to_set]
   708 
   709 lemmas transitive_closure_trans [trans] =
   710   r_r_into_trancl trancl_trans rtrancl_trans
   711   trancl.trancl_into_trancl trancl_into_trancl2
   712   rtrancl.rtrancl_into_rtrancl converse_rtrancl_into_rtrancl
   713   rtrancl_trancl_trancl trancl_rtrancl_trancl
   714 
   715 lemmas transitive_closurep_trans' [trans] =
   716   tranclp_trans rtranclp_trans
   717   tranclp.trancl_into_trancl tranclp_into_tranclp2
   718   rtranclp.rtrancl_into_rtrancl converse_rtranclp_into_rtranclp
   719   rtranclp_tranclp_tranclp tranclp_rtranclp_tranclp
   720 
   721 declare trancl_into_rtrancl [elim]
   722 
   723 subsection \<open>The power operation on relations\<close>
   724 
   725 text \<open>@{text "R ^^ n = R O ... O R"}, the n-fold composition of @{text R}\<close>
   726 
   727 overloading
   728   relpow == "compow :: nat \<Rightarrow> ('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set"
   729   relpowp == "compow :: nat \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool)"
   730 begin
   731 
   732 primrec relpow :: "nat \<Rightarrow> ('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set" where
   733     "relpow 0 R = Id"
   734   | "relpow (Suc n) R = (R ^^ n) O R"
   735 
   736 primrec relpowp :: "nat \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool)" where
   737     "relpowp 0 R = HOL.eq"
   738   | "relpowp (Suc n) R = (R ^^ n) OO R"
   739 
   740 end
   741 
   742 lemma relpowp_relpow_eq [pred_set_conv]:
   743   fixes R :: "'a rel"
   744   shows "(\<lambda>x y. (x, y) \<in> R) ^^ n = (\<lambda>x y. (x, y) \<in> R ^^ n)"
   745   by (induct n) (simp_all add: relcompp_relcomp_eq)
   746 
   747 text \<open>for code generation\<close>
   748 
   749 definition relpow :: "nat \<Rightarrow> ('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set" where
   750   relpow_code_def [code_abbrev]: "relpow = compow"
   751 
   752 definition relpowp :: "nat \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool)" where
   753   relpowp_code_def [code_abbrev]: "relpowp = compow"
   754 
   755 lemma [code]:
   756   "relpow (Suc n) R = (relpow n R) O R"
   757   "relpow 0 R = Id"
   758   by (simp_all add: relpow_code_def)
   759 
   760 lemma [code]:
   761   "relpowp (Suc n) R = (R ^^ n) OO R"
   762   "relpowp 0 R = HOL.eq"
   763   by (simp_all add: relpowp_code_def)
   764 
   765 hide_const (open) relpow
   766 hide_const (open) relpowp
   767 
   768 lemma relpow_1 [simp]:
   769   fixes R :: "('a \<times> 'a) set"
   770   shows "R ^^ 1 = R"
   771   by simp
   772 
   773 lemma relpowp_1 [simp]:
   774   fixes P :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   775   shows "P ^^ 1 = P"
   776   by (fact relpow_1 [to_pred])
   777 
   778 lemma relpow_0_I: 
   779   "(x, x) \<in> R ^^ 0"
   780   by simp
   781 
   782 lemma relpowp_0_I:
   783   "(P ^^ 0) x x"
   784   by (fact relpow_0_I [to_pred])
   785 
   786 lemma relpow_Suc_I:
   787   "(x, y) \<in>  R ^^ n \<Longrightarrow> (y, z) \<in> R \<Longrightarrow> (x, z) \<in> R ^^ Suc n"
   788   by auto
   789 
   790 lemma relpowp_Suc_I:
   791   "(P ^^ n) x y \<Longrightarrow> P y z \<Longrightarrow> (P ^^ Suc n) x z"
   792   by (fact relpow_Suc_I [to_pred])
   793 
   794 lemma relpow_Suc_I2:
   795   "(x, y) \<in> R \<Longrightarrow> (y, z) \<in> R ^^ n \<Longrightarrow> (x, z) \<in> R ^^ Suc n"
   796   by (induct n arbitrary: z) (simp, fastforce)
   797 
   798 lemma relpowp_Suc_I2:
   799   "P x y \<Longrightarrow> (P ^^ n) y z \<Longrightarrow> (P ^^ Suc n) x z"
   800   by (fact relpow_Suc_I2 [to_pred])
   801 
   802 lemma relpow_0_E:
   803   "(x, y) \<in> R ^^ 0 \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> P"
   804   by simp
   805 
   806 lemma relpowp_0_E:
   807   "(P ^^ 0) x y \<Longrightarrow> (x = y \<Longrightarrow> Q) \<Longrightarrow> Q"
   808   by (fact relpow_0_E [to_pred])
   809 
   810 lemma relpow_Suc_E:
   811   "(x, z) \<in> R ^^ Suc n \<Longrightarrow> (\<And>y. (x, y) \<in> R ^^ n \<Longrightarrow> (y, z) \<in> R \<Longrightarrow> P) \<Longrightarrow> P"
   812   by auto
   813 
   814 lemma relpowp_Suc_E:
   815   "(P ^^ Suc n) x z \<Longrightarrow> (\<And>y. (P ^^ n) x y \<Longrightarrow> P y z \<Longrightarrow> Q) \<Longrightarrow> Q"
   816   by (fact relpow_Suc_E [to_pred])
   817 
   818 lemma relpow_E:
   819   "(x, z) \<in>  R ^^ n \<Longrightarrow>  (n = 0 \<Longrightarrow> x = z \<Longrightarrow> P)
   820    \<Longrightarrow> (\<And>y m. n = Suc m \<Longrightarrow> (x, y) \<in>  R ^^ m \<Longrightarrow> (y, z) \<in> R \<Longrightarrow> P)
   821    \<Longrightarrow> P"
   822   by (cases n) auto
   823 
   824 lemma relpowp_E:
   825   "(P ^^ n) x z \<Longrightarrow> (n = 0 \<Longrightarrow> x = z \<Longrightarrow> Q)
   826   \<Longrightarrow> (\<And>y m. n = Suc m \<Longrightarrow> (P ^^ m) x y \<Longrightarrow> P y z \<Longrightarrow> Q)
   827   \<Longrightarrow> Q"
   828   by (fact relpow_E [to_pred])
   829 
   830 lemma relpow_Suc_D2:
   831   "(x, z) \<in> R ^^ Suc n \<Longrightarrow> (\<exists>y. (x, y) \<in> R \<and> (y, z) \<in> R ^^ n)"
   832   apply (induct n arbitrary: x z)
   833    apply (blast intro: relpow_0_I elim: relpow_0_E relpow_Suc_E)
   834   apply (blast intro: relpow_Suc_I elim: relpow_0_E relpow_Suc_E)
   835   done
   836 
   837 lemma relpowp_Suc_D2:
   838   "(P ^^ Suc n) x z \<Longrightarrow> \<exists>y. P x y \<and> (P ^^ n) y z"
   839   by (fact relpow_Suc_D2 [to_pred])
   840 
   841 lemma relpow_Suc_E2:
   842   "(x, z) \<in> R ^^ Suc n \<Longrightarrow> (\<And>y. (x, y) \<in> R \<Longrightarrow> (y, z) \<in> R ^^ n \<Longrightarrow> P) \<Longrightarrow> P"
   843   by (blast dest: relpow_Suc_D2)
   844 
   845 lemma relpowp_Suc_E2:
   846   "(P ^^ Suc n) x z \<Longrightarrow> (\<And>y. P x y \<Longrightarrow> (P ^^ n) y z \<Longrightarrow> Q) \<Longrightarrow> Q"
   847   by (fact relpow_Suc_E2 [to_pred])
   848 
   849 lemma relpow_Suc_D2':
   850   "\<forall>x y z. (x, y) \<in> R ^^ n \<and> (y, z) \<in> R \<longrightarrow> (\<exists>w. (x, w) \<in> R \<and> (w, z) \<in> R ^^ n)"
   851   by (induct n) (simp_all, blast)
   852 
   853 lemma relpowp_Suc_D2':
   854   "\<forall>x y z. (P ^^ n) x y \<and> P y z \<longrightarrow> (\<exists>w. P x w \<and> (P ^^ n) w z)"
   855   by (fact relpow_Suc_D2' [to_pred])
   856 
   857 lemma relpow_E2:
   858   "(x, z) \<in> R ^^ n \<Longrightarrow>  (n = 0 \<Longrightarrow> x = z \<Longrightarrow> P)
   859      \<Longrightarrow> (\<And>y m. n = Suc m \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> (y, z) \<in> R ^^ m \<Longrightarrow> P)
   860    \<Longrightarrow> P"
   861   apply (cases n, simp)
   862   apply (rename_tac nat)
   863   apply (cut_tac n=nat and R=R in relpow_Suc_D2', simp, blast)
   864   done
   865 
   866 lemma relpowp_E2:
   867   "(P ^^ n) x z \<Longrightarrow> (n = 0 \<Longrightarrow> x = z \<Longrightarrow> Q)
   868     \<Longrightarrow> (\<And>y m. n = Suc m \<Longrightarrow> P x y \<Longrightarrow> (P ^^ m) y z \<Longrightarrow> Q)
   869   \<Longrightarrow> Q"
   870   by (fact relpow_E2 [to_pred])
   871 
   872 lemma relpow_add: "R ^^ (m+n) = R^^m O R^^n"
   873   by (induct n) auto
   874 
   875 lemma relpowp_add: "P ^^ (m + n) = P ^^ m OO P ^^ n"
   876   by (fact relpow_add [to_pred])
   877 
   878 lemma relpow_commute: "R O R ^^ n = R ^^ n O R"
   879   by (induct n) (simp, simp add: O_assoc [symmetric])
   880 
   881 lemma relpowp_commute: "P OO P ^^ n = P ^^ n OO P"
   882   by (fact relpow_commute [to_pred])
   883 
   884 lemma relpow_empty:
   885   "0 < n \<Longrightarrow> ({} :: ('a \<times> 'a) set) ^^ n = {}"
   886   by (cases n) auto
   887 
   888 lemma relpowp_bot:
   889   "0 < n \<Longrightarrow> (\<bottom> :: 'a \<Rightarrow> 'a \<Rightarrow> bool) ^^ n = \<bottom>"
   890   by (fact relpow_empty [to_pred])
   891 
   892 lemma rtrancl_imp_UN_relpow:
   893   assumes "p \<in> R^*"
   894   shows "p \<in> (\<Union>n. R ^^ n)"
   895 proof (cases p)
   896   case (Pair x y)
   897   with assms have "(x, y) \<in> R^*" by simp
   898   then have "(x, y) \<in> (\<Union>n. R ^^ n)" proof induct
   899     case base show ?case by (blast intro: relpow_0_I)
   900   next
   901     case step then show ?case by (blast intro: relpow_Suc_I)
   902   qed
   903   with Pair show ?thesis by simp
   904 qed
   905 
   906 lemma rtranclp_imp_Sup_relpowp:
   907   assumes "(P^**) x y"
   908   shows "(\<Squnion>n. P ^^ n) x y"
   909   using assms and rtrancl_imp_UN_relpow [to_pred] by blast
   910 
   911 lemma relpow_imp_rtrancl:
   912   assumes "p \<in> R ^^ n"
   913   shows "p \<in> R^*"
   914 proof (cases p)
   915   case (Pair x y)
   916   with assms have "(x, y) \<in> R ^^ n" by simp
   917   then have "(x, y) \<in> R^*" proof (induct n arbitrary: x y)
   918     case 0 then show ?case by simp
   919   next
   920     case Suc then show ?case
   921       by (blast elim: relpow_Suc_E intro: rtrancl_into_rtrancl)
   922   qed
   923   with Pair show ?thesis by simp
   924 qed
   925 
   926 lemma relpowp_imp_rtranclp:
   927   assumes "(P ^^ n) x y"
   928   shows "(P^**) x y"
   929   using assms and relpow_imp_rtrancl [to_pred] by blast
   930 
   931 lemma rtrancl_is_UN_relpow:
   932   "R^* = (\<Union>n. R ^^ n)"
   933   by (blast intro: rtrancl_imp_UN_relpow relpow_imp_rtrancl)
   934 
   935 lemma rtranclp_is_Sup_relpowp:
   936   "P^** = (\<Squnion>n. P ^^ n)"
   937   using rtrancl_is_UN_relpow [to_pred, of P] by auto
   938 
   939 lemma rtrancl_power:
   940   "p \<in> R^* \<longleftrightarrow> (\<exists>n. p \<in> R ^^ n)"
   941   by (simp add: rtrancl_is_UN_relpow)
   942 
   943 lemma rtranclp_power:
   944   "(P^**) x y \<longleftrightarrow> (\<exists>n. (P ^^ n) x y)"
   945   by (simp add: rtranclp_is_Sup_relpowp)
   946 
   947 lemma trancl_power:
   948   "p \<in> R^+ \<longleftrightarrow> (\<exists>n > 0. p \<in> R ^^ n)"
   949   apply (cases p)
   950   apply simp
   951   apply (rule iffI)
   952    apply (drule tranclD2)
   953    apply (clarsimp simp: rtrancl_is_UN_relpow)
   954    apply (rule_tac x="Suc n" in exI)
   955    apply (clarsimp simp: relcomp_unfold)
   956    apply fastforce
   957   apply clarsimp
   958   apply (case_tac n, simp)
   959   apply clarsimp
   960   apply (drule relpow_imp_rtrancl)
   961   apply (drule rtrancl_into_trancl1) apply auto
   962   done
   963 
   964 lemma tranclp_power:
   965   "(P^++) x y \<longleftrightarrow> (\<exists>n > 0. (P ^^ n) x y)"
   966   using trancl_power [to_pred, of P "(x, y)"] by simp
   967 
   968 lemma rtrancl_imp_relpow:
   969   "p \<in> R^* \<Longrightarrow> \<exists>n. p \<in> R ^^ n"
   970   by (auto dest: rtrancl_imp_UN_relpow)
   971 
   972 lemma rtranclp_imp_relpowp:
   973   "(P^**) x y \<Longrightarrow> \<exists>n. (P ^^ n) x y"
   974   by (auto dest: rtranclp_imp_Sup_relpowp)
   975 
   976 text\<open>By Sternagel/Thiemann:\<close>
   977 lemma relpow_fun_conv:
   978   "((a,b) \<in> R ^^ n) = (\<exists>f. f 0 = a \<and> f n = b \<and> (\<forall>i<n. (f i, f(Suc i)) \<in> R))"
   979 proof (induct n arbitrary: b)
   980   case 0 show ?case by auto
   981 next
   982   case (Suc n)
   983   show ?case
   984   proof (simp add: relcomp_unfold Suc)
   985     show "(\<exists>y. (\<exists>f. f 0 = a \<and> f n = y \<and> (\<forall>i<n. (f i,f(Suc i)) \<in> R)) \<and> (y,b) \<in> R)
   986      = (\<exists>f. f 0 = a \<and> f(Suc n) = b \<and> (\<forall>i<Suc n. (f i, f (Suc i)) \<in> R))"
   987     (is "?l = ?r")
   988     proof
   989       assume ?l
   990       then obtain c f where 1: "f 0 = a"  "f n = c"  "\<And>i. i < n \<Longrightarrow> (f i, f (Suc i)) \<in> R"  "(c,b) \<in> R" by auto
   991       let ?g = "\<lambda> m. if m = Suc n then b else f m"
   992       show ?r by (rule exI[of _ ?g], simp add: 1)
   993     next
   994       assume ?r
   995       then obtain f where 1: "f 0 = a"  "b = f (Suc n)"  "\<And>i. i < Suc n \<Longrightarrow> (f i, f (Suc i)) \<in> R" by auto
   996       show ?l by (rule exI[of _ "f n"], rule conjI, rule exI[of _ f], insert 1, auto)
   997     qed
   998   qed
   999 qed
  1000 
  1001 lemma relpowp_fun_conv:
  1002   "(P ^^ n) x y \<longleftrightarrow> (\<exists>f. f 0 = x \<and> f n = y \<and> (\<forall>i<n. P (f i) (f (Suc i))))"
  1003   by (fact relpow_fun_conv [to_pred])
  1004 
  1005 lemma relpow_finite_bounded1:
  1006 assumes "finite(R :: ('a*'a)set)" and "k>0"
  1007 shows "R^^k \<subseteq> (UN n:{n. 0<n & n <= card R}. R^^n)" (is "_ \<subseteq> ?r")
  1008 proof-
  1009   { fix a b k
  1010     have "(a,b) : R^^(Suc k) \<Longrightarrow> EX n. 0<n & n <= card R & (a,b) : R^^n"
  1011     proof(induct k arbitrary: b)
  1012       case 0
  1013       hence "R \<noteq> {}" by auto
  1014       with card_0_eq[OF \<open>finite R\<close>] have "card R >= Suc 0" by auto
  1015       thus ?case using 0 by force
  1016     next
  1017       case (Suc k)
  1018       then obtain a' where "(a,a') : R^^(Suc k)" and "(a',b) : R" by auto
  1019       from Suc(1)[OF \<open>(a,a') : R^^(Suc k)\<close>]
  1020       obtain n where "n \<le> card R" and "(a,a') \<in> R ^^ n" by auto
  1021       have "(a,b) : R^^(Suc n)" using \<open>(a,a') \<in> R^^n\<close> and \<open>(a',b)\<in> R\<close> by auto
  1022       { assume "n < card R"
  1023         hence ?case using \<open>(a,b): R^^(Suc n)\<close> Suc_leI[OF \<open>n < card R\<close>] by blast
  1024       } moreover
  1025       { assume "n = card R"
  1026         from \<open>(a,b) \<in> R ^^ (Suc n)\<close>[unfolded relpow_fun_conv]
  1027         obtain f where "f 0 = a" and "f(Suc n) = b"
  1028           and steps: "\<And>i. i <= n \<Longrightarrow> (f i, f (Suc i)) \<in> R" by auto
  1029         let ?p = "%i. (f i, f(Suc i))"
  1030         let ?N = "{i. i \<le> n}"
  1031         have "?p ` ?N <= R" using steps by auto
  1032         from card_mono[OF assms(1) this]
  1033         have "card(?p ` ?N) <= card R" .
  1034         also have "\<dots> < card ?N" using \<open>n = card R\<close> by simp
  1035         finally have "~ inj_on ?p ?N" by(rule pigeonhole)
  1036         then obtain i j where i: "i <= n" and j: "j <= n" and ij: "i \<noteq> j" and
  1037           pij: "?p i = ?p j" by(auto simp: inj_on_def)
  1038         let ?i = "min i j" let ?j = "max i j"
  1039         have i: "?i <= n" and j: "?j <= n" and pij: "?p ?i = ?p ?j" 
  1040           and ij: "?i < ?j"
  1041           using i j ij pij unfolding min_def max_def by auto
  1042         from i j pij ij obtain i j where i: "i<=n" and j: "j<=n" and ij: "i<j"
  1043           and pij: "?p i = ?p j" by blast
  1044         let ?g = "\<lambda> l. if l \<le> i then f l else f (l + (j - i))"
  1045         let ?n = "Suc(n - (j - i))"
  1046         have abl: "(a,b) \<in> R ^^ ?n" unfolding relpow_fun_conv
  1047         proof (rule exI[of _ ?g], intro conjI impI allI)
  1048           show "?g ?n = b" using \<open>f(Suc n) = b\<close> j ij by auto
  1049         next
  1050           fix k assume "k < ?n"
  1051           show "(?g k, ?g (Suc k)) \<in> R"
  1052           proof (cases "k < i")
  1053             case True
  1054             with i have "k <= n" by auto
  1055             from steps[OF this] show ?thesis using True by simp
  1056           next
  1057             case False
  1058             hence "i \<le> k" by auto
  1059             show ?thesis
  1060             proof (cases "k = i")
  1061               case True
  1062               thus ?thesis using ij pij steps[OF i] by simp
  1063             next
  1064               case False
  1065               with \<open>i \<le> k\<close> have "i < k" by auto
  1066               hence small: "k + (j - i) <= n" using \<open>k<?n\<close> by arith
  1067               show ?thesis using steps[OF small] \<open>i<k\<close> by auto
  1068             qed
  1069           qed
  1070         qed (simp add: \<open>f 0 = a\<close>)
  1071         moreover have "?n <= n" using i j ij by arith
  1072         ultimately have ?case using \<open>n = card R\<close> by blast
  1073       }
  1074       ultimately show ?case using \<open>n \<le> card R\<close> by force
  1075     qed
  1076   }
  1077   thus ?thesis using gr0_implies_Suc[OF \<open>k>0\<close>] by auto
  1078 qed
  1079 
  1080 lemma relpow_finite_bounded:
  1081 assumes "finite(R :: ('a*'a)set)"
  1082 shows "R^^k \<subseteq> (UN n:{n. n <= card R}. R^^n)"
  1083 apply(cases k)
  1084  apply force
  1085 using relpow_finite_bounded1[OF assms, of k] by auto
  1086 
  1087 lemma rtrancl_finite_eq_relpow:
  1088   "finite R \<Longrightarrow> R^* = (UN n : {n. n <= card R}. R^^n)"
  1089 by(fastforce simp: rtrancl_power dest: relpow_finite_bounded)
  1090 
  1091 lemma trancl_finite_eq_relpow:
  1092   "finite R \<Longrightarrow> R^+ = (UN n : {n. 0 < n & n <= card R}. R^^n)"
  1093 apply(auto simp add: trancl_power)
  1094 apply(auto dest: relpow_finite_bounded1)
  1095 done
  1096 
  1097 lemma finite_relcomp[simp,intro]:
  1098 assumes "finite R" and "finite S"
  1099 shows "finite(R O S)"
  1100 proof-
  1101   have "R O S = (UN (x,y) : R. \<Union>((%(u,v). if u=y then {(x,v)} else {}) ` S))"
  1102     by(force simp add: split_def)
  1103   thus ?thesis using assms by(clarsimp)
  1104 qed
  1105 
  1106 lemma finite_relpow[simp,intro]:
  1107   assumes "finite(R :: ('a*'a)set)" shows "n>0 \<Longrightarrow> finite(R^^n)"
  1108 apply(induct n)
  1109  apply simp
  1110 apply(case_tac n)
  1111  apply(simp_all add: assms)
  1112 done
  1113 
  1114 lemma single_valued_relpow:
  1115   fixes R :: "('a * 'a) set"
  1116   shows "single_valued R \<Longrightarrow> single_valued (R ^^ n)"
  1117 apply (induct n arbitrary: R)
  1118 apply simp_all
  1119 apply (rule single_valuedI)
  1120 apply (fast dest: single_valuedD elim: relpow_Suc_E)
  1121 done
  1122 
  1123 
  1124 subsection \<open>Bounded transitive closure\<close>
  1125 
  1126 definition ntrancl :: "nat \<Rightarrow> ('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set"
  1127 where
  1128   "ntrancl n R = (\<Union>i\<in>{i. 0 < i \<and> i \<le> Suc n}. R ^^ i)"
  1129 
  1130 lemma ntrancl_Zero [simp, code]:
  1131   "ntrancl 0 R = R"
  1132 proof
  1133   show "R \<subseteq> ntrancl 0 R"
  1134     unfolding ntrancl_def by fastforce
  1135 next
  1136   { 
  1137     fix i have "0 < i \<and> i \<le> Suc 0 \<longleftrightarrow> i = 1" by auto
  1138   }
  1139   from this show "ntrancl 0 R \<le> R"
  1140     unfolding ntrancl_def by auto
  1141 qed
  1142 
  1143 lemma ntrancl_Suc [simp]:
  1144   "ntrancl (Suc n) R = ntrancl n R O (Id \<union> R)"
  1145 proof
  1146   {
  1147     fix a b
  1148     assume "(a, b) \<in> ntrancl (Suc n) R"
  1149     from this obtain i where "0 < i" "i \<le> Suc (Suc n)" "(a, b) \<in> R ^^ i"
  1150       unfolding ntrancl_def by auto
  1151     have "(a, b) \<in> ntrancl n R O (Id \<union> R)"
  1152     proof (cases "i = 1")
  1153       case True
  1154       from this \<open>(a, b) \<in> R ^^ i\<close> show ?thesis
  1155         unfolding ntrancl_def by auto
  1156     next
  1157       case False
  1158       from this \<open>0 < i\<close> obtain j where j: "i = Suc j" "0 < j"
  1159         by (cases i) auto
  1160       from this \<open>(a, b) \<in> R ^^ i\<close> obtain c where c1: "(a, c) \<in> R ^^ j" and c2:"(c, b) \<in> R"
  1161         by auto
  1162       from c1 j \<open>i \<le> Suc (Suc n)\<close> have "(a, c) \<in> ntrancl n R"
  1163         unfolding ntrancl_def by fastforce
  1164       from this c2 show ?thesis by fastforce
  1165     qed
  1166   }
  1167   from this show "ntrancl (Suc n) R \<subseteq> ntrancl n R O (Id \<union> R)"
  1168     by auto
  1169 next
  1170   show "ntrancl n R O (Id \<union> R) \<subseteq> ntrancl (Suc n) R"
  1171     unfolding ntrancl_def by fastforce
  1172 qed
  1173 
  1174 lemma [code]:
  1175   "ntrancl (Suc n) r = (let r' = ntrancl n r in r' Un r' O r)"
  1176 unfolding Let_def by auto
  1177 
  1178 lemma finite_trancl_ntranl:
  1179   "finite R \<Longrightarrow> trancl R = ntrancl (card R - 1) R"
  1180   by (cases "card R") (auto simp add: trancl_finite_eq_relpow relpow_empty ntrancl_def)
  1181 
  1182 
  1183 subsection \<open>Acyclic relations\<close>
  1184 
  1185 definition acyclic :: "('a * 'a) set => bool" where
  1186   "acyclic r \<longleftrightarrow> (!x. (x,x) ~: r^+)"
  1187 
  1188 abbreviation acyclicP :: "('a => 'a => bool) => bool" where
  1189   "acyclicP r \<equiv> acyclic {(x, y). r x y}"
  1190 
  1191 lemma acyclic_irrefl [code]:
  1192   "acyclic r \<longleftrightarrow> irrefl (r^+)"
  1193   by (simp add: acyclic_def irrefl_def)
  1194 
  1195 lemma acyclicI: "ALL x. (x, x) ~: r^+ ==> acyclic r"
  1196   by (simp add: acyclic_def)
  1197 
  1198 lemma (in order) acyclicI_order:
  1199   assumes *: "\<And>a b. (a, b) \<in> r \<Longrightarrow> f b < f a"
  1200   shows "acyclic r"
  1201 proof -
  1202   { fix a b assume "(a, b) \<in> r\<^sup>+"
  1203     then have "f b < f a"
  1204       by induct (auto intro: * less_trans) }
  1205   then show ?thesis
  1206     by (auto intro!: acyclicI)
  1207 qed
  1208 
  1209 lemma acyclic_insert [iff]:
  1210      "acyclic(insert (y,x) r) = (acyclic r & (x,y) ~: r^*)"
  1211 apply (simp add: acyclic_def trancl_insert)
  1212 apply (blast intro: rtrancl_trans)
  1213 done
  1214 
  1215 lemma acyclic_converse [iff]: "acyclic(r^-1) = acyclic r"
  1216 by (simp add: acyclic_def trancl_converse)
  1217 
  1218 lemmas acyclicP_converse [iff] = acyclic_converse [to_pred]
  1219 
  1220 lemma acyclic_impl_antisym_rtrancl: "acyclic r ==> antisym(r^*)"
  1221 apply (simp add: acyclic_def antisym_def)
  1222 apply (blast elim: rtranclE intro: rtrancl_into_trancl1 rtrancl_trancl_trancl)
  1223 done
  1224 
  1225 (* Other direction:
  1226 acyclic = no loops
  1227 antisym = only self loops
  1228 Goalw [acyclic_def,antisym_def] "antisym( r^* ) ==> acyclic(r - Id)
  1229 ==> antisym( r^* ) = acyclic(r - Id)";
  1230 *)
  1231 
  1232 lemma acyclic_subset: "[| acyclic s; r <= s |] ==> acyclic r"
  1233 apply (simp add: acyclic_def)
  1234 apply (blast intro: trancl_mono)
  1235 done
  1236 
  1237 
  1238 subsection \<open>Setup of transitivity reasoner\<close>
  1239 
  1240 ML \<open>
  1241 
  1242 structure Trancl_Tac = Trancl_Tac
  1243 (
  1244   val r_into_trancl = @{thm trancl.r_into_trancl};
  1245   val trancl_trans  = @{thm trancl_trans};
  1246   val rtrancl_refl = @{thm rtrancl.rtrancl_refl};
  1247   val r_into_rtrancl = @{thm r_into_rtrancl};
  1248   val trancl_into_rtrancl = @{thm trancl_into_rtrancl};
  1249   val rtrancl_trancl_trancl = @{thm rtrancl_trancl_trancl};
  1250   val trancl_rtrancl_trancl = @{thm trancl_rtrancl_trancl};
  1251   val rtrancl_trans = @{thm rtrancl_trans};
  1252 
  1253   fun decomp (@{const Trueprop} $ t) =
  1254     let fun dec (Const (@{const_name Set.member}, _) $ (Const (@{const_name Pair}, _) $ a $ b) $ rel ) =
  1255         let fun decr (Const (@{const_name rtrancl}, _ ) $ r) = (r,"r*")
  1256               | decr (Const (@{const_name trancl}, _ ) $ r)  = (r,"r+")
  1257               | decr r = (r,"r");
  1258             val (rel,r) = decr (Envir.beta_eta_contract rel);
  1259         in SOME (a,b,rel,r) end
  1260       | dec _ =  NONE
  1261     in dec t end
  1262     | decomp _ = NONE;
  1263 );
  1264 
  1265 structure Tranclp_Tac = Trancl_Tac
  1266 (
  1267   val r_into_trancl = @{thm tranclp.r_into_trancl};
  1268   val trancl_trans  = @{thm tranclp_trans};
  1269   val rtrancl_refl = @{thm rtranclp.rtrancl_refl};
  1270   val r_into_rtrancl = @{thm r_into_rtranclp};
  1271   val trancl_into_rtrancl = @{thm tranclp_into_rtranclp};
  1272   val rtrancl_trancl_trancl = @{thm rtranclp_tranclp_tranclp};
  1273   val trancl_rtrancl_trancl = @{thm tranclp_rtranclp_tranclp};
  1274   val rtrancl_trans = @{thm rtranclp_trans};
  1275 
  1276   fun decomp (@{const Trueprop} $ t) =
  1277     let fun dec (rel $ a $ b) =
  1278         let fun decr (Const (@{const_name rtranclp}, _ ) $ r) = (r,"r*")
  1279               | decr (Const (@{const_name tranclp}, _ ) $ r)  = (r,"r+")
  1280               | decr r = (r,"r");
  1281             val (rel,r) = decr rel;
  1282         in SOME (a, b, rel, r) end
  1283       | dec _ =  NONE
  1284     in dec t end
  1285     | decomp _ = NONE;
  1286 );
  1287 \<close>
  1288 
  1289 setup \<open>
  1290   map_theory_simpset (fn ctxt => ctxt
  1291     addSolver (mk_solver "Trancl" Trancl_Tac.trancl_tac)
  1292     addSolver (mk_solver "Rtrancl" Trancl_Tac.rtrancl_tac)
  1293     addSolver (mk_solver "Tranclp" Tranclp_Tac.trancl_tac)
  1294     addSolver (mk_solver "Rtranclp" Tranclp_Tac.rtrancl_tac))
  1295 \<close>
  1296 
  1297 
  1298 text \<open>Optional methods.\<close>
  1299 
  1300 method_setup trancl =
  1301   \<open>Scan.succeed (SIMPLE_METHOD' o Trancl_Tac.trancl_tac)\<close>
  1302   \<open>simple transitivity reasoner\<close>
  1303 method_setup rtrancl =
  1304   \<open>Scan.succeed (SIMPLE_METHOD' o Trancl_Tac.rtrancl_tac)\<close>
  1305   \<open>simple transitivity reasoner\<close>
  1306 method_setup tranclp =
  1307   \<open>Scan.succeed (SIMPLE_METHOD' o Tranclp_Tac.trancl_tac)\<close>
  1308   \<open>simple transitivity reasoner (predicate version)\<close>
  1309 method_setup rtranclp =
  1310   \<open>Scan.succeed (SIMPLE_METHOD' o Tranclp_Tac.rtrancl_tac)\<close>
  1311   \<open>simple transitivity reasoner (predicate version)\<close>
  1312 
  1313 end