src/HOL/Real_Vector_Spaces.thy
author paulson <lp15@cam.ac.uk>
Sat Apr 11 11:56:40 2015 +0100 (2015-04-11)
changeset 60017 b785d6d06430
parent 59867 58043346ca64
child 60026 41d81b4a0a21
permissions -rw-r--r--
Overloading of ln and powr, but "approximation" no longer works for powr. Code generation also fails due to type ambiguity in scala.
     1 (*  Title:      HOL/Real_Vector_Spaces.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 section {* Vector Spaces and Algebras over the Reals *}
     7 
     8 theory Real_Vector_Spaces
     9 imports Real Topological_Spaces
    10 begin
    11 
    12 subsection {* Locale for additive functions *}
    13 
    14 locale additive =
    15   fixes f :: "'a::ab_group_add \<Rightarrow> 'b::ab_group_add"
    16   assumes add: "f (x + y) = f x + f y"
    17 begin
    18 
    19 lemma zero: "f 0 = 0"
    20 proof -
    21   have "f 0 = f (0 + 0)" by simp
    22   also have "\<dots> = f 0 + f 0" by (rule add)
    23   finally show "f 0 = 0" by simp
    24 qed
    25 
    26 lemma minus: "f (- x) = - f x"
    27 proof -
    28   have "f (- x) + f x = f (- x + x)" by (rule add [symmetric])
    29   also have "\<dots> = - f x + f x" by (simp add: zero)
    30   finally show "f (- x) = - f x" by (rule add_right_imp_eq)
    31 qed
    32 
    33 lemma diff: "f (x - y) = f x - f y"
    34   using add [of x "- y"] by (simp add: minus)
    35 
    36 lemma setsum: "f (setsum g A) = (\<Sum>x\<in>A. f (g x))"
    37 apply (cases "finite A")
    38 apply (induct set: finite)
    39 apply (simp add: zero)
    40 apply (simp add: add)
    41 apply (simp add: zero)
    42 done
    43 
    44 end
    45 
    46 subsection {* Vector spaces *}
    47 
    48 locale vector_space =
    49   fixes scale :: "'a::field \<Rightarrow> 'b::ab_group_add \<Rightarrow> 'b"
    50   assumes scale_right_distrib [algebra_simps]:
    51     "scale a (x + y) = scale a x + scale a y"
    52   and scale_left_distrib [algebra_simps]:
    53     "scale (a + b) x = scale a x + scale b x"
    54   and scale_scale [simp]: "scale a (scale b x) = scale (a * b) x"
    55   and scale_one [simp]: "scale 1 x = x"
    56 begin
    57 
    58 lemma scale_left_commute:
    59   "scale a (scale b x) = scale b (scale a x)"
    60 by (simp add: mult.commute)
    61 
    62 lemma scale_zero_left [simp]: "scale 0 x = 0"
    63   and scale_minus_left [simp]: "scale (- a) x = - (scale a x)"
    64   and scale_left_diff_distrib [algebra_simps]:
    65         "scale (a - b) x = scale a x - scale b x"
    66   and scale_setsum_left: "scale (setsum f A) x = (\<Sum>a\<in>A. scale (f a) x)"
    67 proof -
    68   interpret s: additive "\<lambda>a. scale a x"
    69     proof qed (rule scale_left_distrib)
    70   show "scale 0 x = 0" by (rule s.zero)
    71   show "scale (- a) x = - (scale a x)" by (rule s.minus)
    72   show "scale (a - b) x = scale a x - scale b x" by (rule s.diff)
    73   show "scale (setsum f A) x = (\<Sum>a\<in>A. scale (f a) x)" by (rule s.setsum)
    74 qed
    75 
    76 lemma scale_zero_right [simp]: "scale a 0 = 0"
    77   and scale_minus_right [simp]: "scale a (- x) = - (scale a x)"
    78   and scale_right_diff_distrib [algebra_simps]:
    79         "scale a (x - y) = scale a x - scale a y"
    80   and scale_setsum_right: "scale a (setsum f A) = (\<Sum>x\<in>A. scale a (f x))"
    81 proof -
    82   interpret s: additive "\<lambda>x. scale a x"
    83     proof qed (rule scale_right_distrib)
    84   show "scale a 0 = 0" by (rule s.zero)
    85   show "scale a (- x) = - (scale a x)" by (rule s.minus)
    86   show "scale a (x - y) = scale a x - scale a y" by (rule s.diff)
    87   show "scale a (setsum f A) = (\<Sum>x\<in>A. scale a (f x))" by (rule s.setsum)
    88 qed
    89 
    90 lemma scale_eq_0_iff [simp]:
    91   "scale a x = 0 \<longleftrightarrow> a = 0 \<or> x = 0"
    92 proof cases
    93   assume "a = 0" thus ?thesis by simp
    94 next
    95   assume anz [simp]: "a \<noteq> 0"
    96   { assume "scale a x = 0"
    97     hence "scale (inverse a) (scale a x) = 0" by simp
    98     hence "x = 0" by simp }
    99   thus ?thesis by force
   100 qed
   101 
   102 lemma scale_left_imp_eq:
   103   "\<lbrakk>a \<noteq> 0; scale a x = scale a y\<rbrakk> \<Longrightarrow> x = y"
   104 proof -
   105   assume nonzero: "a \<noteq> 0"
   106   assume "scale a x = scale a y"
   107   hence "scale a (x - y) = 0"
   108      by (simp add: scale_right_diff_distrib)
   109   hence "x - y = 0" by (simp add: nonzero)
   110   thus "x = y" by (simp only: right_minus_eq)
   111 qed
   112 
   113 lemma scale_right_imp_eq:
   114   "\<lbrakk>x \<noteq> 0; scale a x = scale b x\<rbrakk> \<Longrightarrow> a = b"
   115 proof -
   116   assume nonzero: "x \<noteq> 0"
   117   assume "scale a x = scale b x"
   118   hence "scale (a - b) x = 0"
   119      by (simp add: scale_left_diff_distrib)
   120   hence "a - b = 0" by (simp add: nonzero)
   121   thus "a = b" by (simp only: right_minus_eq)
   122 qed
   123 
   124 lemma scale_cancel_left [simp]:
   125   "scale a x = scale a y \<longleftrightarrow> x = y \<or> a = 0"
   126 by (auto intro: scale_left_imp_eq)
   127 
   128 lemma scale_cancel_right [simp]:
   129   "scale a x = scale b x \<longleftrightarrow> a = b \<or> x = 0"
   130 by (auto intro: scale_right_imp_eq)
   131 
   132 end
   133 
   134 subsection {* Real vector spaces *}
   135 
   136 class scaleR =
   137   fixes scaleR :: "real \<Rightarrow> 'a \<Rightarrow> 'a" (infixr "*\<^sub>R" 75)
   138 begin
   139 
   140 abbreviation
   141   divideR :: "'a \<Rightarrow> real \<Rightarrow> 'a" (infixl "'/\<^sub>R" 70)
   142 where
   143   "x /\<^sub>R r == scaleR (inverse r) x"
   144 
   145 end
   146 
   147 class real_vector = scaleR + ab_group_add +
   148   assumes scaleR_add_right: "scaleR a (x + y) = scaleR a x + scaleR a y"
   149   and scaleR_add_left: "scaleR (a + b) x = scaleR a x + scaleR b x"
   150   and scaleR_scaleR: "scaleR a (scaleR b x) = scaleR (a * b) x"
   151   and scaleR_one: "scaleR 1 x = x"
   152 
   153 interpretation real_vector:
   154   vector_space "scaleR :: real \<Rightarrow> 'a \<Rightarrow> 'a::real_vector"
   155 apply unfold_locales
   156 apply (rule scaleR_add_right)
   157 apply (rule scaleR_add_left)
   158 apply (rule scaleR_scaleR)
   159 apply (rule scaleR_one)
   160 done
   161 
   162 text {* Recover original theorem names *}
   163 
   164 lemmas scaleR_left_commute = real_vector.scale_left_commute
   165 lemmas scaleR_zero_left = real_vector.scale_zero_left
   166 lemmas scaleR_minus_left = real_vector.scale_minus_left
   167 lemmas scaleR_diff_left = real_vector.scale_left_diff_distrib
   168 lemmas scaleR_setsum_left = real_vector.scale_setsum_left
   169 lemmas scaleR_zero_right = real_vector.scale_zero_right
   170 lemmas scaleR_minus_right = real_vector.scale_minus_right
   171 lemmas scaleR_diff_right = real_vector.scale_right_diff_distrib
   172 lemmas scaleR_setsum_right = real_vector.scale_setsum_right
   173 lemmas scaleR_eq_0_iff = real_vector.scale_eq_0_iff
   174 lemmas scaleR_left_imp_eq = real_vector.scale_left_imp_eq
   175 lemmas scaleR_right_imp_eq = real_vector.scale_right_imp_eq
   176 lemmas scaleR_cancel_left = real_vector.scale_cancel_left
   177 lemmas scaleR_cancel_right = real_vector.scale_cancel_right
   178 
   179 text {* Legacy names *}
   180 
   181 lemmas scaleR_left_distrib = scaleR_add_left
   182 lemmas scaleR_right_distrib = scaleR_add_right
   183 lemmas scaleR_left_diff_distrib = scaleR_diff_left
   184 lemmas scaleR_right_diff_distrib = scaleR_diff_right
   185 
   186 lemma scaleR_minus1_left [simp]:
   187   fixes x :: "'a::real_vector"
   188   shows "scaleR (-1) x = - x"
   189   using scaleR_minus_left [of 1 x] by simp
   190 
   191 class real_algebra = real_vector + ring +
   192   assumes mult_scaleR_left [simp]: "scaleR a x * y = scaleR a (x * y)"
   193   and mult_scaleR_right [simp]: "x * scaleR a y = scaleR a (x * y)"
   194 
   195 class real_algebra_1 = real_algebra + ring_1
   196 
   197 class real_div_algebra = real_algebra_1 + division_ring
   198 
   199 class real_field = real_div_algebra + field
   200 
   201 instantiation real :: real_field
   202 begin
   203 
   204 definition
   205   real_scaleR_def [simp]: "scaleR a x = a * x"
   206 
   207 instance proof
   208 qed (simp_all add: algebra_simps)
   209 
   210 end
   211 
   212 interpretation scaleR_left: additive "(\<lambda>a. scaleR a x::'a::real_vector)"
   213 proof qed (rule scaleR_left_distrib)
   214 
   215 interpretation scaleR_right: additive "(\<lambda>x. scaleR a x::'a::real_vector)"
   216 proof qed (rule scaleR_right_distrib)
   217 
   218 lemma nonzero_inverse_scaleR_distrib:
   219   fixes x :: "'a::real_div_algebra" shows
   220   "\<lbrakk>a \<noteq> 0; x \<noteq> 0\<rbrakk> \<Longrightarrow> inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   221 by (rule inverse_unique, simp)
   222 
   223 lemma inverse_scaleR_distrib:
   224   fixes x :: "'a::{real_div_algebra, division_ring}"
   225   shows "inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   226 apply (case_tac "a = 0", simp)
   227 apply (case_tac "x = 0", simp)
   228 apply (erule (1) nonzero_inverse_scaleR_distrib)
   229 done
   230 
   231 
   232 subsection {* Embedding of the Reals into any @{text real_algebra_1}:
   233 @{term of_real} *}
   234 
   235 definition
   236   of_real :: "real \<Rightarrow> 'a::real_algebra_1" where
   237   "of_real r = scaleR r 1"
   238 
   239 lemma scaleR_conv_of_real: "scaleR r x = of_real r * x"
   240 by (simp add: of_real_def)
   241 
   242 lemma of_real_0 [simp]: "of_real 0 = 0"
   243 by (simp add: of_real_def)
   244 
   245 lemma of_real_1 [simp]: "of_real 1 = 1"
   246 by (simp add: of_real_def)
   247 
   248 lemma of_real_add [simp]: "of_real (x + y) = of_real x + of_real y"
   249 by (simp add: of_real_def scaleR_left_distrib)
   250 
   251 lemma of_real_minus [simp]: "of_real (- x) = - of_real x"
   252 by (simp add: of_real_def)
   253 
   254 lemma of_real_diff [simp]: "of_real (x - y) = of_real x - of_real y"
   255 by (simp add: of_real_def scaleR_left_diff_distrib)
   256 
   257 lemma of_real_mult [simp]: "of_real (x * y) = of_real x * of_real y"
   258 by (simp add: of_real_def mult.commute)
   259 
   260 lemma of_real_setsum[simp]: "of_real (setsum f s) = (\<Sum>x\<in>s. of_real (f x))"
   261   by (induct s rule: infinite_finite_induct) auto
   262 
   263 lemma of_real_setprod[simp]: "of_real (setprod f s) = (\<Prod>x\<in>s. of_real (f x))"
   264   by (induct s rule: infinite_finite_induct) auto
   265 
   266 lemma nonzero_of_real_inverse:
   267   "x \<noteq> 0 \<Longrightarrow> of_real (inverse x) =
   268    inverse (of_real x :: 'a::real_div_algebra)"
   269 by (simp add: of_real_def nonzero_inverse_scaleR_distrib)
   270 
   271 lemma of_real_inverse [simp]:
   272   "of_real (inverse x) =
   273    inverse (of_real x :: 'a::{real_div_algebra, division_ring})"
   274 by (simp add: of_real_def inverse_scaleR_distrib)
   275 
   276 lemma nonzero_of_real_divide:
   277   "y \<noteq> 0 \<Longrightarrow> of_real (x / y) =
   278    (of_real x / of_real y :: 'a::real_field)"
   279 by (simp add: divide_inverse nonzero_of_real_inverse)
   280 
   281 lemma of_real_divide [simp]:
   282   "of_real (x / y) =
   283    (of_real x / of_real y :: 'a::{real_field, field})"
   284 by (simp add: divide_inverse)
   285 
   286 lemma of_real_power [simp]:
   287   "of_real (x ^ n) = (of_real x :: 'a::{real_algebra_1}) ^ n"
   288 by (induct n) simp_all
   289 
   290 lemma of_real_eq_iff [simp]: "(of_real x = of_real y) = (x = y)"
   291 by (simp add: of_real_def)
   292 
   293 lemma inj_of_real:
   294   "inj of_real"
   295   by (auto intro: injI)
   296 
   297 lemmas of_real_eq_0_iff [simp] = of_real_eq_iff [of _ 0, simplified]
   298 
   299 lemma of_real_eq_id [simp]: "of_real = (id :: real \<Rightarrow> real)"
   300 proof
   301   fix r
   302   show "of_real r = id r"
   303     by (simp add: of_real_def)
   304 qed
   305 
   306 text{*Collapse nested embeddings*}
   307 lemma of_real_of_nat_eq [simp]: "of_real (of_nat n) = of_nat n"
   308 by (induct n) auto
   309 
   310 lemma of_real_of_int_eq [simp]: "of_real (of_int z) = of_int z"
   311 by (cases z rule: int_diff_cases, simp)
   312 
   313 lemma of_real_real_of_nat_eq [simp]: "of_real (real n) = of_nat n"
   314   by (simp add: real_of_nat_def)
   315 
   316 lemma of_real_real_of_int_eq [simp]: "of_real (real z) = of_int z"
   317   by (simp add: real_of_int_def)
   318 
   319 lemma of_real_numeral: "of_real (numeral w) = numeral w"
   320 using of_real_of_int_eq [of "numeral w"] by simp
   321 
   322 lemma of_real_neg_numeral: "of_real (- numeral w) = - numeral w"
   323 using of_real_of_int_eq [of "- numeral w"] by simp
   324 
   325 text{*Every real algebra has characteristic zero*}
   326 
   327 instance real_algebra_1 < ring_char_0
   328 proof
   329   from inj_of_real inj_of_nat have "inj (of_real \<circ> of_nat)" by (rule inj_comp)
   330   then show "inj (of_nat :: nat \<Rightarrow> 'a)" by (simp add: comp_def)
   331 qed
   332 
   333 instance real_field < field_char_0 ..
   334 
   335 
   336 subsection {* The Set of Real Numbers *}
   337 
   338 definition Reals :: "'a::real_algebra_1 set" where
   339   "Reals = range of_real"
   340 
   341 notation (xsymbols)
   342   Reals  ("\<real>")
   343 
   344 lemma Reals_of_real [simp]: "of_real r \<in> Reals"
   345 by (simp add: Reals_def)
   346 
   347 lemma Reals_of_int [simp]: "of_int z \<in> Reals"
   348 by (subst of_real_of_int_eq [symmetric], rule Reals_of_real)
   349 
   350 lemma Reals_of_nat [simp]: "of_nat n \<in> Reals"
   351 by (subst of_real_of_nat_eq [symmetric], rule Reals_of_real)
   352 
   353 lemma Reals_numeral [simp]: "numeral w \<in> Reals"
   354 by (subst of_real_numeral [symmetric], rule Reals_of_real)
   355 
   356 lemma Reals_0 [simp]: "0 \<in> Reals"
   357 apply (unfold Reals_def)
   358 apply (rule range_eqI)
   359 apply (rule of_real_0 [symmetric])
   360 done
   361 
   362 lemma Reals_1 [simp]: "1 \<in> Reals"
   363 apply (unfold Reals_def)
   364 apply (rule range_eqI)
   365 apply (rule of_real_1 [symmetric])
   366 done
   367 
   368 lemma Reals_add [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a + b \<in> Reals"
   369 apply (auto simp add: Reals_def)
   370 apply (rule range_eqI)
   371 apply (rule of_real_add [symmetric])
   372 done
   373 
   374 lemma Reals_minus [simp]: "a \<in> Reals \<Longrightarrow> - a \<in> Reals"
   375 apply (auto simp add: Reals_def)
   376 apply (rule range_eqI)
   377 apply (rule of_real_minus [symmetric])
   378 done
   379 
   380 lemma Reals_diff [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a - b \<in> Reals"
   381 apply (auto simp add: Reals_def)
   382 apply (rule range_eqI)
   383 apply (rule of_real_diff [symmetric])
   384 done
   385 
   386 lemma Reals_mult [simp]: "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a * b \<in> Reals"
   387 apply (auto simp add: Reals_def)
   388 apply (rule range_eqI)
   389 apply (rule of_real_mult [symmetric])
   390 done
   391 
   392 lemma nonzero_Reals_inverse:
   393   fixes a :: "'a::real_div_algebra"
   394   shows "\<lbrakk>a \<in> Reals; a \<noteq> 0\<rbrakk> \<Longrightarrow> inverse a \<in> Reals"
   395 apply (auto simp add: Reals_def)
   396 apply (rule range_eqI)
   397 apply (erule nonzero_of_real_inverse [symmetric])
   398 done
   399 
   400 lemma Reals_inverse:
   401   fixes a :: "'a::{real_div_algebra, division_ring}"
   402   shows "a \<in> Reals \<Longrightarrow> inverse a \<in> Reals"
   403 apply (auto simp add: Reals_def)
   404 apply (rule range_eqI)
   405 apply (rule of_real_inverse [symmetric])
   406 done
   407 
   408 lemma Reals_inverse_iff [simp]: 
   409   fixes x:: "'a :: {real_div_algebra, division_ring}"
   410   shows "inverse x \<in> \<real> \<longleftrightarrow> x \<in> \<real>"
   411 by (metis Reals_inverse inverse_inverse_eq)
   412 
   413 lemma nonzero_Reals_divide:
   414   fixes a b :: "'a::real_field"
   415   shows "\<lbrakk>a \<in> Reals; b \<in> Reals; b \<noteq> 0\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
   416 apply (auto simp add: Reals_def)
   417 apply (rule range_eqI)
   418 apply (erule nonzero_of_real_divide [symmetric])
   419 done
   420 
   421 lemma Reals_divide [simp]:
   422   fixes a b :: "'a::{real_field, field}"
   423   shows "\<lbrakk>a \<in> Reals; b \<in> Reals\<rbrakk> \<Longrightarrow> a / b \<in> Reals"
   424 apply (auto simp add: Reals_def)
   425 apply (rule range_eqI)
   426 apply (rule of_real_divide [symmetric])
   427 done
   428 
   429 lemma Reals_power [simp]:
   430   fixes a :: "'a::{real_algebra_1}"
   431   shows "a \<in> Reals \<Longrightarrow> a ^ n \<in> Reals"
   432 apply (auto simp add: Reals_def)
   433 apply (rule range_eqI)
   434 apply (rule of_real_power [symmetric])
   435 done
   436 
   437 lemma Reals_cases [cases set: Reals]:
   438   assumes "q \<in> \<real>"
   439   obtains (of_real) r where "q = of_real r"
   440   unfolding Reals_def
   441 proof -
   442   from `q \<in> \<real>` have "q \<in> range of_real" unfolding Reals_def .
   443   then obtain r where "q = of_real r" ..
   444   then show thesis ..
   445 qed
   446 
   447 lemma setsum_in_Reals [intro,simp]:
   448   assumes "\<And>i. i \<in> s \<Longrightarrow> f i \<in> \<real>" shows "setsum f s \<in> \<real>"
   449 proof (cases "finite s")
   450   case True then show ?thesis using assms
   451     by (induct s rule: finite_induct) auto
   452 next
   453   case False then show ?thesis using assms
   454     by (metis Reals_0 setsum.infinite)
   455 qed
   456 
   457 lemma setprod_in_Reals [intro,simp]: 
   458   assumes "\<And>i. i \<in> s \<Longrightarrow> f i \<in> \<real>" shows "setprod f s \<in> \<real>"
   459 proof (cases "finite s")
   460   case True then show ?thesis using assms
   461     by (induct s rule: finite_induct) auto
   462 next
   463   case False then show ?thesis using assms
   464     by (metis Reals_1 setprod.infinite)
   465 qed
   466 
   467 lemma Reals_induct [case_names of_real, induct set: Reals]:
   468   "q \<in> \<real> \<Longrightarrow> (\<And>r. P (of_real r)) \<Longrightarrow> P q"
   469   by (rule Reals_cases) auto
   470 
   471 subsection {* Ordered real vector spaces *}
   472 
   473 class ordered_real_vector = real_vector + ordered_ab_group_add +
   474   assumes scaleR_left_mono: "x \<le> y \<Longrightarrow> 0 \<le> a \<Longrightarrow> a *\<^sub>R x \<le> a *\<^sub>R y"
   475   assumes scaleR_right_mono: "a \<le> b \<Longrightarrow> 0 \<le> x \<Longrightarrow> a *\<^sub>R x \<le> b *\<^sub>R x"
   476 begin
   477 
   478 lemma scaleR_mono:
   479   "a \<le> b \<Longrightarrow> x \<le> y \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> x \<Longrightarrow> a *\<^sub>R x \<le> b *\<^sub>R y"
   480 apply (erule scaleR_right_mono [THEN order_trans], assumption)
   481 apply (erule scaleR_left_mono, assumption)
   482 done
   483 
   484 lemma scaleR_mono':
   485   "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> c \<Longrightarrow> a *\<^sub>R c \<le> b *\<^sub>R d"
   486   by (rule scaleR_mono) (auto intro: order.trans)
   487 
   488 lemma pos_le_divideRI:
   489   assumes "0 < c"
   490   assumes "c *\<^sub>R a \<le> b"
   491   shows "a \<le> b /\<^sub>R c"
   492 proof -
   493   from scaleR_left_mono[OF assms(2)] assms(1)
   494   have "c *\<^sub>R a /\<^sub>R c \<le> b /\<^sub>R c"
   495     by simp
   496   with assms show ?thesis
   497     by (simp add: scaleR_one scaleR_scaleR inverse_eq_divide)
   498 qed
   499 
   500 lemma pos_le_divideR_eq:
   501   assumes "0 < c"
   502   shows "a \<le> b /\<^sub>R c \<longleftrightarrow> c *\<^sub>R a \<le> b"
   503 proof rule
   504   assume "a \<le> b /\<^sub>R c"
   505   from scaleR_left_mono[OF this] assms
   506   have "c *\<^sub>R a \<le> c *\<^sub>R (b /\<^sub>R c)"
   507     by simp
   508   with assms show "c *\<^sub>R a \<le> b"
   509     by (simp add: scaleR_one scaleR_scaleR inverse_eq_divide)
   510 qed (rule pos_le_divideRI[OF assms])
   511 
   512 lemma scaleR_image_atLeastAtMost:
   513   "c > 0 \<Longrightarrow> scaleR c ` {x..y} = {c *\<^sub>R x..c *\<^sub>R y}"
   514   apply (auto intro!: scaleR_left_mono)
   515   apply (rule_tac x = "inverse c *\<^sub>R xa" in image_eqI)
   516   apply (simp_all add: pos_le_divideR_eq[symmetric] scaleR_scaleR scaleR_one)
   517   done
   518 
   519 end
   520 
   521 lemma scaleR_nonneg_nonneg: "0 \<le> a \<Longrightarrow> 0 \<le> (x::'a::ordered_real_vector) \<Longrightarrow> 0 \<le> a *\<^sub>R x"
   522   using scaleR_left_mono [of 0 x a]
   523   by simp
   524 
   525 lemma scaleR_nonneg_nonpos: "0 \<le> a \<Longrightarrow> (x::'a::ordered_real_vector) \<le> 0 \<Longrightarrow> a *\<^sub>R x \<le> 0"
   526   using scaleR_left_mono [of x 0 a] by simp
   527 
   528 lemma scaleR_nonpos_nonneg: "a \<le> 0 \<Longrightarrow> 0 \<le> (x::'a::ordered_real_vector) \<Longrightarrow> a *\<^sub>R x \<le> 0"
   529   using scaleR_right_mono [of a 0 x] by simp
   530 
   531 lemma split_scaleR_neg_le: "(0 \<le> a & x \<le> 0) | (a \<le> 0 & 0 \<le> x) \<Longrightarrow>
   532   a *\<^sub>R (x::'a::ordered_real_vector) \<le> 0"
   533   by (auto simp add: scaleR_nonneg_nonpos scaleR_nonpos_nonneg)
   534 
   535 lemma le_add_iff1:
   536   fixes c d e::"'a::ordered_real_vector"
   537   shows "a *\<^sub>R e + c \<le> b *\<^sub>R e + d \<longleftrightarrow> (a - b) *\<^sub>R e + c \<le> d"
   538   by (simp add: algebra_simps)
   539 
   540 lemma le_add_iff2:
   541   fixes c d e::"'a::ordered_real_vector"
   542   shows "a *\<^sub>R e + c \<le> b *\<^sub>R e + d \<longleftrightarrow> c \<le> (b - a) *\<^sub>R e + d"
   543   by (simp add: algebra_simps)
   544 
   545 lemma scaleR_left_mono_neg:
   546   fixes a b::"'a::ordered_real_vector"
   547   shows "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b"
   548   apply (drule scaleR_left_mono [of _ _ "- c"])
   549   apply simp_all
   550   done
   551 
   552 lemma scaleR_right_mono_neg:
   553   fixes c::"'a::ordered_real_vector"
   554   shows "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> a *\<^sub>R c \<le> b *\<^sub>R c"
   555   apply (drule scaleR_right_mono [of _ _ "- c"])
   556   apply simp_all
   557   done
   558 
   559 lemma scaleR_nonpos_nonpos: "a \<le> 0 \<Longrightarrow> (b::'a::ordered_real_vector) \<le> 0 \<Longrightarrow> 0 \<le> a *\<^sub>R b"
   560 using scaleR_right_mono_neg [of a 0 b] by simp
   561 
   562 lemma split_scaleR_pos_le:
   563   fixes b::"'a::ordered_real_vector"
   564   shows "(0 \<le> a \<and> 0 \<le> b) \<or> (a \<le> 0 \<and> b \<le> 0) \<Longrightarrow> 0 \<le> a *\<^sub>R b"
   565   by (auto simp add: scaleR_nonneg_nonneg scaleR_nonpos_nonpos)
   566 
   567 lemma zero_le_scaleR_iff:
   568   fixes b::"'a::ordered_real_vector"
   569   shows "0 \<le> a *\<^sub>R b \<longleftrightarrow> 0 < a \<and> 0 \<le> b \<or> a < 0 \<and> b \<le> 0 \<or> a = 0" (is "?lhs = ?rhs")
   570 proof cases
   571   assume "a \<noteq> 0"
   572   show ?thesis
   573   proof
   574     assume lhs: ?lhs
   575     {
   576       assume "0 < a"
   577       with lhs have "inverse a *\<^sub>R 0 \<le> inverse a *\<^sub>R (a *\<^sub>R b)"
   578         by (intro scaleR_mono) auto
   579       hence ?rhs using `0 < a`
   580         by simp
   581     } moreover {
   582       assume "0 > a"
   583       with lhs have "- inverse a *\<^sub>R 0 \<le> - inverse a *\<^sub>R (a *\<^sub>R b)"
   584         by (intro scaleR_mono) auto
   585       hence ?rhs using `0 > a`
   586         by simp
   587     } ultimately show ?rhs using `a \<noteq> 0` by arith
   588   qed (auto simp: not_le `a \<noteq> 0` intro!: split_scaleR_pos_le)
   589 qed simp
   590 
   591 lemma scaleR_le_0_iff:
   592   fixes b::"'a::ordered_real_vector"
   593   shows "a *\<^sub>R b \<le> 0 \<longleftrightarrow> 0 < a \<and> b \<le> 0 \<or> a < 0 \<and> 0 \<le> b \<or> a = 0"
   594   by (insert zero_le_scaleR_iff [of "-a" b]) force
   595 
   596 lemma scaleR_le_cancel_left:
   597   fixes b::"'a::ordered_real_vector"
   598   shows "c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
   599   by (auto simp add: neq_iff scaleR_left_mono scaleR_left_mono_neg
   600     dest: scaleR_left_mono[where a="inverse c"] scaleR_left_mono_neg[where c="inverse c"])
   601 
   602 lemma scaleR_le_cancel_left_pos:
   603   fixes b::"'a::ordered_real_vector"
   604   shows "0 < c \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> a \<le> b"
   605   by (auto simp: scaleR_le_cancel_left)
   606 
   607 lemma scaleR_le_cancel_left_neg:
   608   fixes b::"'a::ordered_real_vector"
   609   shows "c < 0 \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> b \<le> a"
   610   by (auto simp: scaleR_le_cancel_left)
   611 
   612 lemma scaleR_left_le_one_le:
   613   fixes x::"'a::ordered_real_vector" and a::real
   614   shows "0 \<le> x \<Longrightarrow> a \<le> 1 \<Longrightarrow> a *\<^sub>R x \<le> x"
   615   using scaleR_right_mono[of a 1 x] by simp
   616 
   617 
   618 subsection {* Real normed vector spaces *}
   619 
   620 class dist =
   621   fixes dist :: "'a \<Rightarrow> 'a \<Rightarrow> real"
   622 
   623 class norm =
   624   fixes norm :: "'a \<Rightarrow> real"
   625 
   626 class sgn_div_norm = scaleR + norm + sgn +
   627   assumes sgn_div_norm: "sgn x = x /\<^sub>R norm x"
   628 
   629 class dist_norm = dist + norm + minus +
   630   assumes dist_norm: "dist x y = norm (x - y)"
   631 
   632 class open_dist = "open" + dist +
   633   assumes open_dist: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
   634 
   635 class real_normed_vector = real_vector + sgn_div_norm + dist_norm + open_dist +
   636   assumes norm_eq_zero [simp]: "norm x = 0 \<longleftrightarrow> x = 0"
   637   and norm_triangle_ineq: "norm (x + y) \<le> norm x + norm y"
   638   and norm_scaleR [simp]: "norm (scaleR a x) = \<bar>a\<bar> * norm x"
   639 begin
   640 
   641 lemma norm_ge_zero [simp]: "0 \<le> norm x"
   642 proof -
   643   have "0 = norm (x + -1 *\<^sub>R x)" 
   644     using scaleR_add_left[of 1 "-1" x] norm_scaleR[of 0 x] by (simp add: scaleR_one)
   645   also have "\<dots> \<le> norm x + norm (-1 *\<^sub>R x)" by (rule norm_triangle_ineq)
   646   finally show ?thesis by simp
   647 qed
   648 
   649 end
   650 
   651 class real_normed_algebra = real_algebra + real_normed_vector +
   652   assumes norm_mult_ineq: "norm (x * y) \<le> norm x * norm y"
   653 
   654 class real_normed_algebra_1 = real_algebra_1 + real_normed_algebra +
   655   assumes norm_one [simp]: "norm 1 = 1"
   656 
   657 class real_normed_div_algebra = real_div_algebra + real_normed_vector +
   658   assumes norm_mult: "norm (x * y) = norm x * norm y"
   659 
   660 class real_normed_field = real_field + real_normed_div_algebra
   661 
   662 instance real_normed_div_algebra < real_normed_algebra_1
   663 proof
   664   fix x y :: 'a
   665   show "norm (x * y) \<le> norm x * norm y"
   666     by (simp add: norm_mult)
   667 next
   668   have "norm (1 * 1::'a) = norm (1::'a) * norm (1::'a)"
   669     by (rule norm_mult)
   670   thus "norm (1::'a) = 1" by simp
   671 qed
   672 
   673 lemma norm_zero [simp]: "norm (0::'a::real_normed_vector) = 0"
   674 by simp
   675 
   676 lemma zero_less_norm_iff [simp]:
   677   fixes x :: "'a::real_normed_vector"
   678   shows "(0 < norm x) = (x \<noteq> 0)"
   679 by (simp add: order_less_le)
   680 
   681 lemma norm_not_less_zero [simp]:
   682   fixes x :: "'a::real_normed_vector"
   683   shows "\<not> norm x < 0"
   684 by (simp add: linorder_not_less)
   685 
   686 lemma norm_le_zero_iff [simp]:
   687   fixes x :: "'a::real_normed_vector"
   688   shows "(norm x \<le> 0) = (x = 0)"
   689 by (simp add: order_le_less)
   690 
   691 lemma norm_minus_cancel [simp]:
   692   fixes x :: "'a::real_normed_vector"
   693   shows "norm (- x) = norm x"
   694 proof -
   695   have "norm (- x) = norm (scaleR (- 1) x)"
   696     by (simp only: scaleR_minus_left scaleR_one)
   697   also have "\<dots> = \<bar>- 1\<bar> * norm x"
   698     by (rule norm_scaleR)
   699   finally show ?thesis by simp
   700 qed
   701 
   702 lemma norm_minus_commute:
   703   fixes a b :: "'a::real_normed_vector"
   704   shows "norm (a - b) = norm (b - a)"
   705 proof -
   706   have "norm (- (b - a)) = norm (b - a)"
   707     by (rule norm_minus_cancel)
   708   thus ?thesis by simp
   709 qed
   710 
   711 lemma norm_triangle_ineq2:
   712   fixes a b :: "'a::real_normed_vector"
   713   shows "norm a - norm b \<le> norm (a - b)"
   714 proof -
   715   have "norm (a - b + b) \<le> norm (a - b) + norm b"
   716     by (rule norm_triangle_ineq)
   717   thus ?thesis by simp
   718 qed
   719 
   720 lemma norm_triangle_ineq3:
   721   fixes a b :: "'a::real_normed_vector"
   722   shows "\<bar>norm a - norm b\<bar> \<le> norm (a - b)"
   723 apply (subst abs_le_iff)
   724 apply auto
   725 apply (rule norm_triangle_ineq2)
   726 apply (subst norm_minus_commute)
   727 apply (rule norm_triangle_ineq2)
   728 done
   729 
   730 lemma norm_triangle_ineq4:
   731   fixes a b :: "'a::real_normed_vector"
   732   shows "norm (a - b) \<le> norm a + norm b"
   733 proof -
   734   have "norm (a + - b) \<le> norm a + norm (- b)"
   735     by (rule norm_triangle_ineq)
   736   then show ?thesis by simp
   737 qed
   738 
   739 lemma norm_diff_ineq:
   740   fixes a b :: "'a::real_normed_vector"
   741   shows "norm a - norm b \<le> norm (a + b)"
   742 proof -
   743   have "norm a - norm (- b) \<le> norm (a - - b)"
   744     by (rule norm_triangle_ineq2)
   745   thus ?thesis by simp
   746 qed
   747 
   748 lemma norm_diff_triangle_ineq:
   749   fixes a b c d :: "'a::real_normed_vector"
   750   shows "norm ((a + b) - (c + d)) \<le> norm (a - c) + norm (b - d)"
   751 proof -
   752   have "norm ((a + b) - (c + d)) = norm ((a - c) + (b - d))"
   753     by (simp add: algebra_simps)
   754   also have "\<dots> \<le> norm (a - c) + norm (b - d)"
   755     by (rule norm_triangle_ineq)
   756   finally show ?thesis .
   757 qed
   758 
   759 lemma norm_triangle_mono: 
   760   fixes a b :: "'a::real_normed_vector"
   761   shows "\<lbrakk>norm a \<le> r; norm b \<le> s\<rbrakk> \<Longrightarrow> norm (a + b) \<le> r + s"
   762 by (metis add_mono_thms_linordered_semiring(1) norm_triangle_ineq order.trans)
   763 
   764 lemma norm_setsum:
   765   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
   766   shows "norm (setsum f A) \<le> (\<Sum>i\<in>A. norm (f i))"
   767   by (induct A rule: infinite_finite_induct) (auto intro: norm_triangle_mono)
   768 
   769 lemma setsum_norm_le:
   770   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
   771   assumes fg: "\<forall>x \<in> S. norm (f x) \<le> g x"
   772   shows "norm (setsum f S) \<le> setsum g S"
   773   by (rule order_trans [OF norm_setsum setsum_mono]) (simp add: fg)
   774 
   775 lemma abs_norm_cancel [simp]:
   776   fixes a :: "'a::real_normed_vector"
   777   shows "\<bar>norm a\<bar> = norm a"
   778 by (rule abs_of_nonneg [OF norm_ge_zero])
   779 
   780 lemma norm_add_less:
   781   fixes x y :: "'a::real_normed_vector"
   782   shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x + y) < r + s"
   783 by (rule order_le_less_trans [OF norm_triangle_ineq add_strict_mono])
   784 
   785 lemma norm_mult_less:
   786   fixes x y :: "'a::real_normed_algebra"
   787   shows "\<lbrakk>norm x < r; norm y < s\<rbrakk> \<Longrightarrow> norm (x * y) < r * s"
   788 apply (rule order_le_less_trans [OF norm_mult_ineq])
   789 apply (simp add: mult_strict_mono')
   790 done
   791 
   792 lemma norm_of_real [simp]:
   793   "norm (of_real r :: 'a::real_normed_algebra_1) = \<bar>r\<bar>"
   794 unfolding of_real_def by simp
   795 
   796 lemma norm_numeral [simp]:
   797   "norm (numeral w::'a::real_normed_algebra_1) = numeral w"
   798 by (subst of_real_numeral [symmetric], subst norm_of_real, simp)
   799 
   800 lemma norm_neg_numeral [simp]:
   801   "norm (- numeral w::'a::real_normed_algebra_1) = numeral w"
   802 by (subst of_real_neg_numeral [symmetric], subst norm_of_real, simp)
   803 
   804 lemma norm_of_int [simp]:
   805   "norm (of_int z::'a::real_normed_algebra_1) = \<bar>of_int z\<bar>"
   806 by (subst of_real_of_int_eq [symmetric], rule norm_of_real)
   807 
   808 lemma norm_of_nat [simp]:
   809   "norm (of_nat n::'a::real_normed_algebra_1) = of_nat n"
   810 apply (subst of_real_of_nat_eq [symmetric])
   811 apply (subst norm_of_real, simp)
   812 done
   813 
   814 lemma nonzero_norm_inverse:
   815   fixes a :: "'a::real_normed_div_algebra"
   816   shows "a \<noteq> 0 \<Longrightarrow> norm (inverse a) = inverse (norm a)"
   817 apply (rule inverse_unique [symmetric])
   818 apply (simp add: norm_mult [symmetric])
   819 done
   820 
   821 lemma norm_inverse:
   822   fixes a :: "'a::{real_normed_div_algebra, division_ring}"
   823   shows "norm (inverse a) = inverse (norm a)"
   824 apply (case_tac "a = 0", simp)
   825 apply (erule nonzero_norm_inverse)
   826 done
   827 
   828 lemma nonzero_norm_divide:
   829   fixes a b :: "'a::real_normed_field"
   830   shows "b \<noteq> 0 \<Longrightarrow> norm (a / b) = norm a / norm b"
   831 by (simp add: divide_inverse norm_mult nonzero_norm_inverse)
   832 
   833 lemma norm_divide:
   834   fixes a b :: "'a::{real_normed_field, field}"
   835   shows "norm (a / b) = norm a / norm b"
   836 by (simp add: divide_inverse norm_mult norm_inverse)
   837 
   838 lemma norm_power_ineq:
   839   fixes x :: "'a::{real_normed_algebra_1}"
   840   shows "norm (x ^ n) \<le> norm x ^ n"
   841 proof (induct n)
   842   case 0 show "norm (x ^ 0) \<le> norm x ^ 0" by simp
   843 next
   844   case (Suc n)
   845   have "norm (x * x ^ n) \<le> norm x * norm (x ^ n)"
   846     by (rule norm_mult_ineq)
   847   also from Suc have "\<dots> \<le> norm x * norm x ^ n"
   848     using norm_ge_zero by (rule mult_left_mono)
   849   finally show "norm (x ^ Suc n) \<le> norm x ^ Suc n"
   850     by simp
   851 qed
   852 
   853 lemma norm_power:
   854   fixes x :: "'a::{real_normed_div_algebra}"
   855   shows "norm (x ^ n) = norm x ^ n"
   856 by (induct n) (simp_all add: norm_mult)
   857 
   858 text{*Despite a superficial resemblance, @{text norm_eq_1} is not relevant.*}
   859 lemma square_norm_one:
   860   fixes x :: "'a::real_normed_div_algebra"
   861   assumes "x^2 = 1" shows "norm x = 1"
   862   by (metis assms norm_minus_cancel norm_one power2_eq_1_iff)
   863 
   864 lemma norm_less_p1:
   865   fixes x :: "'a::real_normed_algebra_1"
   866   shows "norm x < norm (of_real (norm x) + 1 :: 'a)"
   867 proof -
   868   have "norm x < norm (of_real (norm x + 1) :: 'a)"
   869     by (simp add: of_real_def)
   870   then show ?thesis
   871     by simp
   872 qed
   873 
   874 lemma setprod_norm:
   875   fixes f :: "'a \<Rightarrow> 'b::{comm_semiring_1,real_normed_div_algebra}"
   876   shows "setprod (\<lambda>x. norm(f x)) A = norm (setprod f A)"
   877   by (induct A rule: infinite_finite_induct) (auto simp: norm_mult)
   878 
   879 lemma norm_setprod_le: 
   880   "norm (setprod f A) \<le> (\<Prod>a\<in>A. norm (f a :: 'a :: {real_normed_algebra_1, comm_monoid_mult}))"
   881 proof (induction A rule: infinite_finite_induct)
   882   case (insert a A)
   883   then have "norm (setprod f (insert a A)) \<le> norm (f a) * norm (setprod f A)"
   884     by (simp add: norm_mult_ineq)
   885   also have "norm (setprod f A) \<le> (\<Prod>a\<in>A. norm (f a))"
   886     by (rule insert)
   887   finally show ?case
   888     by (simp add: insert mult_left_mono)
   889 qed simp_all
   890 
   891 lemma norm_setprod_diff:
   892   fixes z w :: "'i \<Rightarrow> 'a::{real_normed_algebra_1, comm_monoid_mult}"
   893   shows "(\<And>i. i \<in> I \<Longrightarrow> norm (z i) \<le> 1) \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> norm (w i) \<le> 1) \<Longrightarrow>
   894     norm ((\<Prod>i\<in>I. z i) - (\<Prod>i\<in>I. w i)) \<le> (\<Sum>i\<in>I. norm (z i - w i))" 
   895 proof (induction I rule: infinite_finite_induct)
   896   case (insert i I)
   897   note insert.hyps[simp]
   898 
   899   have "norm ((\<Prod>i\<in>insert i I. z i) - (\<Prod>i\<in>insert i I. w i)) =
   900     norm ((\<Prod>i\<in>I. z i) * (z i - w i) + ((\<Prod>i\<in>I. z i) - (\<Prod>i\<in>I. w i)) * w i)"
   901     (is "_ = norm (?t1 + ?t2)")
   902     by (auto simp add: field_simps)
   903   also have "... \<le> norm ?t1 + norm ?t2"
   904     by (rule norm_triangle_ineq)
   905   also have "norm ?t1 \<le> norm (\<Prod>i\<in>I. z i) * norm (z i - w i)"
   906     by (rule norm_mult_ineq)
   907   also have "\<dots> \<le> (\<Prod>i\<in>I. norm (z i)) * norm(z i - w i)"
   908     by (rule mult_right_mono) (auto intro: norm_setprod_le)
   909   also have "(\<Prod>i\<in>I. norm (z i)) \<le> (\<Prod>i\<in>I. 1)"
   910     by (intro setprod_mono) (auto intro!: insert)
   911   also have "norm ?t2 \<le> norm ((\<Prod>i\<in>I. z i) - (\<Prod>i\<in>I. w i)) * norm (w i)"
   912     by (rule norm_mult_ineq)
   913   also have "norm (w i) \<le> 1"
   914     by (auto intro: insert)
   915   also have "norm ((\<Prod>i\<in>I. z i) - (\<Prod>i\<in>I. w i)) \<le> (\<Sum>i\<in>I. norm (z i - w i))"
   916     using insert by auto
   917   finally show ?case
   918     by (auto simp add: ac_simps mult_right_mono mult_left_mono)
   919 qed simp_all
   920 
   921 lemma norm_power_diff: 
   922   fixes z w :: "'a::{real_normed_algebra_1, comm_monoid_mult}"
   923   assumes "norm z \<le> 1" "norm w \<le> 1"
   924   shows "norm (z^m - w^m) \<le> m * norm (z - w)"
   925 proof -
   926   have "norm (z^m - w^m) = norm ((\<Prod> i < m. z) - (\<Prod> i < m. w))"
   927     by (simp add: setprod_constant)
   928   also have "\<dots> \<le> (\<Sum>i<m. norm (z - w))"
   929     by (intro norm_setprod_diff) (auto simp add: assms)
   930   also have "\<dots> = m * norm (z - w)"
   931     by (simp add: real_of_nat_def)
   932   finally show ?thesis .
   933 qed
   934 
   935 subsection {* Metric spaces *}
   936 
   937 class metric_space = open_dist +
   938   assumes dist_eq_0_iff [simp]: "dist x y = 0 \<longleftrightarrow> x = y"
   939   assumes dist_triangle2: "dist x y \<le> dist x z + dist y z"
   940 begin
   941 
   942 lemma dist_self [simp]: "dist x x = 0"
   943 by simp
   944 
   945 lemma zero_le_dist [simp]: "0 \<le> dist x y"
   946 using dist_triangle2 [of x x y] by simp
   947 
   948 lemma zero_less_dist_iff: "0 < dist x y \<longleftrightarrow> x \<noteq> y"
   949 by (simp add: less_le)
   950 
   951 lemma dist_not_less_zero [simp]: "\<not> dist x y < 0"
   952 by (simp add: not_less)
   953 
   954 lemma dist_le_zero_iff [simp]: "dist x y \<le> 0 \<longleftrightarrow> x = y"
   955 by (simp add: le_less)
   956 
   957 lemma dist_commute: "dist x y = dist y x"
   958 proof (rule order_antisym)
   959   show "dist x y \<le> dist y x"
   960     using dist_triangle2 [of x y x] by simp
   961   show "dist y x \<le> dist x y"
   962     using dist_triangle2 [of y x y] by simp
   963 qed
   964 
   965 lemma dist_triangle: "dist x z \<le> dist x y + dist y z"
   966 using dist_triangle2 [of x z y] by (simp add: dist_commute)
   967 
   968 lemma dist_triangle3: "dist x y \<le> dist a x + dist a y"
   969 using dist_triangle2 [of x y a] by (simp add: dist_commute)
   970 
   971 lemma dist_triangle_alt:
   972   shows "dist y z <= dist x y + dist x z"
   973 by (rule dist_triangle3)
   974 
   975 lemma dist_pos_lt:
   976   shows "x \<noteq> y ==> 0 < dist x y"
   977 by (simp add: zero_less_dist_iff)
   978 
   979 lemma dist_nz:
   980   shows "x \<noteq> y \<longleftrightarrow> 0 < dist x y"
   981 by (simp add: zero_less_dist_iff)
   982 
   983 lemma dist_triangle_le:
   984   shows "dist x z + dist y z <= e \<Longrightarrow> dist x y <= e"
   985 by (rule order_trans [OF dist_triangle2])
   986 
   987 lemma dist_triangle_lt:
   988   shows "dist x z + dist y z < e ==> dist x y < e"
   989 by (rule le_less_trans [OF dist_triangle2])
   990 
   991 lemma dist_triangle_half_l:
   992   shows "dist x1 y < e / 2 \<Longrightarrow> dist x2 y < e / 2 \<Longrightarrow> dist x1 x2 < e"
   993 by (rule dist_triangle_lt [where z=y], simp)
   994 
   995 lemma dist_triangle_half_r:
   996   shows "dist y x1 < e / 2 \<Longrightarrow> dist y x2 < e / 2 \<Longrightarrow> dist x1 x2 < e"
   997 by (rule dist_triangle_half_l, simp_all add: dist_commute)
   998 
   999 subclass topological_space
  1000 proof
  1001   have "\<exists>e::real. 0 < e"
  1002     by (fast intro: zero_less_one)
  1003   then show "open UNIV"
  1004     unfolding open_dist by simp
  1005 next
  1006   fix S T assume "open S" "open T"
  1007   then show "open (S \<inter> T)"
  1008     unfolding open_dist
  1009     apply clarify
  1010     apply (drule (1) bspec)+
  1011     apply (clarify, rename_tac r s)
  1012     apply (rule_tac x="min r s" in exI, simp)
  1013     done
  1014 next
  1015   fix K assume "\<forall>S\<in>K. open S" thus "open (\<Union>K)"
  1016     unfolding open_dist by fast
  1017 qed
  1018 
  1019 lemma open_ball: "open {y. dist x y < d}"
  1020 proof (unfold open_dist, intro ballI)
  1021   fix y assume *: "y \<in> {y. dist x y < d}"
  1022   then show "\<exists>e>0. \<forall>z. dist z y < e \<longrightarrow> z \<in> {y. dist x y < d}"
  1023     by (auto intro!: exI[of _ "d - dist x y"] simp: field_simps dist_triangle_lt)
  1024 qed
  1025 
  1026 subclass first_countable_topology
  1027 proof
  1028   fix x 
  1029   show "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
  1030   proof (safe intro!: exI[of _ "\<lambda>n. {y. dist x y < inverse (Suc n)}"])
  1031     fix S assume "open S" "x \<in> S"
  1032     then obtain e where e: "0 < e" and "{y. dist x y < e} \<subseteq> S"
  1033       by (auto simp: open_dist subset_eq dist_commute)
  1034     moreover
  1035     from e obtain i where "inverse (Suc i) < e"
  1036       by (auto dest!: reals_Archimedean)
  1037     then have "{y. dist x y < inverse (Suc i)} \<subseteq> {y. dist x y < e}"
  1038       by auto
  1039     ultimately show "\<exists>i. {y. dist x y < inverse (Suc i)} \<subseteq> S"
  1040       by blast
  1041   qed (auto intro: open_ball)
  1042 qed
  1043 
  1044 end
  1045 
  1046 instance metric_space \<subseteq> t2_space
  1047 proof
  1048   fix x y :: "'a::metric_space"
  1049   assume xy: "x \<noteq> y"
  1050   let ?U = "{y'. dist x y' < dist x y / 2}"
  1051   let ?V = "{x'. dist y x' < dist x y / 2}"
  1052   have th0: "\<And>d x y z. (d x z :: real) \<le> d x y + d y z \<Longrightarrow> d y z = d z y
  1053                \<Longrightarrow> \<not>(d x y * 2 < d x z \<and> d z y * 2 < d x z)" by arith
  1054   have "open ?U \<and> open ?V \<and> x \<in> ?U \<and> y \<in> ?V \<and> ?U \<inter> ?V = {}"
  1055     using dist_pos_lt[OF xy] th0[of dist, OF dist_triangle dist_commute]
  1056     using open_ball[of _ "dist x y / 2"] by auto
  1057   then show "\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
  1058     by blast
  1059 qed
  1060 
  1061 text {* Every normed vector space is a metric space. *}
  1062 
  1063 instance real_normed_vector < metric_space
  1064 proof
  1065   fix x y :: 'a show "dist x y = 0 \<longleftrightarrow> x = y"
  1066     unfolding dist_norm by simp
  1067 next
  1068   fix x y z :: 'a show "dist x y \<le> dist x z + dist y z"
  1069     unfolding dist_norm
  1070     using norm_triangle_ineq4 [of "x - z" "y - z"] by simp
  1071 qed
  1072 
  1073 subsection {* Class instances for real numbers *}
  1074 
  1075 instantiation real :: real_normed_field
  1076 begin
  1077 
  1078 definition dist_real_def:
  1079   "dist x y = \<bar>x - y\<bar>"
  1080 
  1081 definition open_real_def [code del]:
  1082   "open (S :: real set) \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
  1083 
  1084 definition real_norm_def [simp]:
  1085   "norm r = \<bar>r\<bar>"
  1086 
  1087 instance
  1088 apply (intro_classes, unfold real_norm_def real_scaleR_def)
  1089 apply (rule dist_real_def)
  1090 apply (rule open_real_def)
  1091 apply (simp add: sgn_real_def)
  1092 apply (rule abs_eq_0)
  1093 apply (rule abs_triangle_ineq)
  1094 apply (rule abs_mult)
  1095 apply (rule abs_mult)
  1096 done
  1097 
  1098 end
  1099 
  1100 declare [[code abort: "open :: real set \<Rightarrow> bool"]]
  1101 
  1102 instance real :: linorder_topology
  1103 proof
  1104   show "(open :: real set \<Rightarrow> bool) = generate_topology (range lessThan \<union> range greaterThan)"
  1105   proof (rule ext, safe)
  1106     fix S :: "real set" assume "open S"
  1107     then obtain f where "\<forall>x\<in>S. 0 < f x \<and> (\<forall>y. dist y x < f x \<longrightarrow> y \<in> S)"
  1108       unfolding open_real_def bchoice_iff ..
  1109     then have *: "S = (\<Union>x\<in>S. {x - f x <..} \<inter> {..< x + f x})"
  1110       by (fastforce simp: dist_real_def)
  1111     show "generate_topology (range lessThan \<union> range greaterThan) S"
  1112       apply (subst *)
  1113       apply (intro generate_topology_Union generate_topology.Int)
  1114       apply (auto intro: generate_topology.Basis)
  1115       done
  1116   next
  1117     fix S :: "real set" assume "generate_topology (range lessThan \<union> range greaterThan) S"
  1118     moreover have "\<And>a::real. open {..<a}"
  1119       unfolding open_real_def dist_real_def
  1120     proof clarify
  1121       fix x a :: real assume "x < a"
  1122       hence "0 < a - x \<and> (\<forall>y. \<bar>y - x\<bar> < a - x \<longrightarrow> y \<in> {..<a})" by auto
  1123       thus "\<exists>e>0. \<forall>y. \<bar>y - x\<bar> < e \<longrightarrow> y \<in> {..<a}" ..
  1124     qed
  1125     moreover have "\<And>a::real. open {a <..}"
  1126       unfolding open_real_def dist_real_def
  1127     proof clarify
  1128       fix x a :: real assume "a < x"
  1129       hence "0 < x - a \<and> (\<forall>y. \<bar>y - x\<bar> < x - a \<longrightarrow> y \<in> {a<..})" by auto
  1130       thus "\<exists>e>0. \<forall>y. \<bar>y - x\<bar> < e \<longrightarrow> y \<in> {a<..}" ..
  1131     qed
  1132     ultimately show "open S"
  1133       by induct auto
  1134   qed
  1135 qed
  1136 
  1137 instance real :: linear_continuum_topology ..
  1138 
  1139 lemmas open_real_greaterThan = open_greaterThan[where 'a=real]
  1140 lemmas open_real_lessThan = open_lessThan[where 'a=real]
  1141 lemmas open_real_greaterThanLessThan = open_greaterThanLessThan[where 'a=real]
  1142 lemmas closed_real_atMost = closed_atMost[where 'a=real]
  1143 lemmas closed_real_atLeast = closed_atLeast[where 'a=real]
  1144 lemmas closed_real_atLeastAtMost = closed_atLeastAtMost[where 'a=real]
  1145 
  1146 subsection {* Extra type constraints *}
  1147 
  1148 text {* Only allow @{term "open"} in class @{text topological_space}. *}
  1149 
  1150 setup {* Sign.add_const_constraint
  1151   (@{const_name "open"}, SOME @{typ "'a::topological_space set \<Rightarrow> bool"}) *}
  1152 
  1153 text {* Only allow @{term dist} in class @{text metric_space}. *}
  1154 
  1155 setup {* Sign.add_const_constraint
  1156   (@{const_name dist}, SOME @{typ "'a::metric_space \<Rightarrow> 'a \<Rightarrow> real"}) *}
  1157 
  1158 text {* Only allow @{term norm} in class @{text real_normed_vector}. *}
  1159 
  1160 setup {* Sign.add_const_constraint
  1161   (@{const_name norm}, SOME @{typ "'a::real_normed_vector \<Rightarrow> real"}) *}
  1162 
  1163 subsection {* Sign function *}
  1164 
  1165 lemma norm_sgn:
  1166   "norm (sgn(x::'a::real_normed_vector)) = (if x = 0 then 0 else 1)"
  1167 by (simp add: sgn_div_norm)
  1168 
  1169 lemma sgn_zero [simp]: "sgn(0::'a::real_normed_vector) = 0"
  1170 by (simp add: sgn_div_norm)
  1171 
  1172 lemma sgn_zero_iff: "(sgn(x::'a::real_normed_vector) = 0) = (x = 0)"
  1173 by (simp add: sgn_div_norm)
  1174 
  1175 lemma sgn_minus: "sgn (- x) = - sgn(x::'a::real_normed_vector)"
  1176 by (simp add: sgn_div_norm)
  1177 
  1178 lemma sgn_scaleR:
  1179   "sgn (scaleR r x) = scaleR (sgn r) (sgn(x::'a::real_normed_vector))"
  1180 by (simp add: sgn_div_norm ac_simps)
  1181 
  1182 lemma sgn_one [simp]: "sgn (1::'a::real_normed_algebra_1) = 1"
  1183 by (simp add: sgn_div_norm)
  1184 
  1185 lemma sgn_of_real:
  1186   "sgn (of_real r::'a::real_normed_algebra_1) = of_real (sgn r)"
  1187 unfolding of_real_def by (simp only: sgn_scaleR sgn_one)
  1188 
  1189 lemma sgn_mult:
  1190   fixes x y :: "'a::real_normed_div_algebra"
  1191   shows "sgn (x * y) = sgn x * sgn y"
  1192 by (simp add: sgn_div_norm norm_mult mult.commute)
  1193 
  1194 lemma real_sgn_eq: "sgn (x::real) = x / \<bar>x\<bar>"
  1195 by (simp add: sgn_div_norm divide_inverse)
  1196 
  1197 lemma real_sgn_pos: "0 < (x::real) \<Longrightarrow> sgn x = 1"
  1198 unfolding real_sgn_eq by simp
  1199 
  1200 lemma real_sgn_neg: "(x::real) < 0 \<Longrightarrow> sgn x = -1"
  1201 unfolding real_sgn_eq by simp
  1202 
  1203 lemma zero_le_sgn_iff [simp]: "0 \<le> sgn x \<longleftrightarrow> 0 \<le> (x::real)"
  1204   by (cases "0::real" x rule: linorder_cases) simp_all
  1205   
  1206 lemma zero_less_sgn_iff [simp]: "0 < sgn x \<longleftrightarrow> 0 < (x::real)"
  1207   by (cases "0::real" x rule: linorder_cases) simp_all
  1208 
  1209 lemma sgn_le_0_iff [simp]: "sgn x \<le> 0 \<longleftrightarrow> (x::real) \<le> 0"
  1210   by (cases "0::real" x rule: linorder_cases) simp_all
  1211   
  1212 lemma sgn_less_0_iff [simp]: "sgn x < 0 \<longleftrightarrow> (x::real) < 0"
  1213   by (cases "0::real" x rule: linorder_cases) simp_all
  1214 
  1215 lemma norm_conv_dist: "norm x = dist x 0"
  1216   unfolding dist_norm by simp
  1217 
  1218 subsection {* Bounded Linear and Bilinear Operators *}
  1219 
  1220 locale linear = additive f for f :: "'a::real_vector \<Rightarrow> 'b::real_vector" +
  1221   assumes scaleR: "f (scaleR r x) = scaleR r (f x)"
  1222 
  1223 lemma linearI:
  1224   assumes "\<And>x y. f (x + y) = f x + f y"
  1225   assumes "\<And>c x. f (c *\<^sub>R x) = c *\<^sub>R f x"
  1226   shows "linear f"
  1227   by default (rule assms)+
  1228 
  1229 locale bounded_linear = linear f for f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_vector" +
  1230   assumes bounded: "\<exists>K. \<forall>x. norm (f x) \<le> norm x * K"
  1231 begin
  1232 
  1233 lemma pos_bounded:
  1234   "\<exists>K>0. \<forall>x. norm (f x) \<le> norm x * K"
  1235 proof -
  1236   obtain K where K: "\<And>x. norm (f x) \<le> norm x * K"
  1237     using bounded by fast
  1238   show ?thesis
  1239   proof (intro exI impI conjI allI)
  1240     show "0 < max 1 K"
  1241       by (rule order_less_le_trans [OF zero_less_one max.cobounded1])
  1242   next
  1243     fix x
  1244     have "norm (f x) \<le> norm x * K" using K .
  1245     also have "\<dots> \<le> norm x * max 1 K"
  1246       by (rule mult_left_mono [OF max.cobounded2 norm_ge_zero])
  1247     finally show "norm (f x) \<le> norm x * max 1 K" .
  1248   qed
  1249 qed
  1250 
  1251 lemma nonneg_bounded:
  1252   "\<exists>K\<ge>0. \<forall>x. norm (f x) \<le> norm x * K"
  1253 proof -
  1254   from pos_bounded
  1255   show ?thesis by (auto intro: order_less_imp_le)
  1256 qed
  1257 
  1258 lemma linear: "linear f" ..
  1259 
  1260 end
  1261 
  1262 lemma bounded_linear_intro:
  1263   assumes "\<And>x y. f (x + y) = f x + f y"
  1264   assumes "\<And>r x. f (scaleR r x) = scaleR r (f x)"
  1265   assumes "\<And>x. norm (f x) \<le> norm x * K"
  1266   shows "bounded_linear f"
  1267   by default (fast intro: assms)+
  1268 
  1269 locale bounded_bilinear =
  1270   fixes prod :: "['a::real_normed_vector, 'b::real_normed_vector]
  1271                  \<Rightarrow> 'c::real_normed_vector"
  1272     (infixl "**" 70)
  1273   assumes add_left: "prod (a + a') b = prod a b + prod a' b"
  1274   assumes add_right: "prod a (b + b') = prod a b + prod a b'"
  1275   assumes scaleR_left: "prod (scaleR r a) b = scaleR r (prod a b)"
  1276   assumes scaleR_right: "prod a (scaleR r b) = scaleR r (prod a b)"
  1277   assumes bounded: "\<exists>K. \<forall>a b. norm (prod a b) \<le> norm a * norm b * K"
  1278 begin
  1279 
  1280 lemma pos_bounded:
  1281   "\<exists>K>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
  1282 apply (cut_tac bounded, erule exE)
  1283 apply (rule_tac x="max 1 K" in exI, safe)
  1284 apply (rule order_less_le_trans [OF zero_less_one max.cobounded1])
  1285 apply (drule spec, drule spec, erule order_trans)
  1286 apply (rule mult_left_mono [OF max.cobounded2])
  1287 apply (intro mult_nonneg_nonneg norm_ge_zero)
  1288 done
  1289 
  1290 lemma nonneg_bounded:
  1291   "\<exists>K\<ge>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
  1292 proof -
  1293   from pos_bounded
  1294   show ?thesis by (auto intro: order_less_imp_le)
  1295 qed
  1296 
  1297 lemma additive_right: "additive (\<lambda>b. prod a b)"
  1298 by (rule additive.intro, rule add_right)
  1299 
  1300 lemma additive_left: "additive (\<lambda>a. prod a b)"
  1301 by (rule additive.intro, rule add_left)
  1302 
  1303 lemma zero_left: "prod 0 b = 0"
  1304 by (rule additive.zero [OF additive_left])
  1305 
  1306 lemma zero_right: "prod a 0 = 0"
  1307 by (rule additive.zero [OF additive_right])
  1308 
  1309 lemma minus_left: "prod (- a) b = - prod a b"
  1310 by (rule additive.minus [OF additive_left])
  1311 
  1312 lemma minus_right: "prod a (- b) = - prod a b"
  1313 by (rule additive.minus [OF additive_right])
  1314 
  1315 lemma diff_left:
  1316   "prod (a - a') b = prod a b - prod a' b"
  1317 by (rule additive.diff [OF additive_left])
  1318 
  1319 lemma diff_right:
  1320   "prod a (b - b') = prod a b - prod a b'"
  1321 by (rule additive.diff [OF additive_right])
  1322 
  1323 lemma bounded_linear_left:
  1324   "bounded_linear (\<lambda>a. a ** b)"
  1325 apply (cut_tac bounded, safe)
  1326 apply (rule_tac K="norm b * K" in bounded_linear_intro)
  1327 apply (rule add_left)
  1328 apply (rule scaleR_left)
  1329 apply (simp add: ac_simps)
  1330 done
  1331 
  1332 lemma bounded_linear_right:
  1333   "bounded_linear (\<lambda>b. a ** b)"
  1334 apply (cut_tac bounded, safe)
  1335 apply (rule_tac K="norm a * K" in bounded_linear_intro)
  1336 apply (rule add_right)
  1337 apply (rule scaleR_right)
  1338 apply (simp add: ac_simps)
  1339 done
  1340 
  1341 lemma prod_diff_prod:
  1342   "(x ** y - a ** b) = (x - a) ** (y - b) + (x - a) ** b + a ** (y - b)"
  1343 by (simp add: diff_left diff_right)
  1344 
  1345 end
  1346 
  1347 lemma bounded_linear_ident[simp]: "bounded_linear (\<lambda>x. x)"
  1348   by default (auto intro!: exI[of _ 1])
  1349 
  1350 lemma bounded_linear_zero[simp]: "bounded_linear (\<lambda>x. 0)"
  1351   by default (auto intro!: exI[of _ 1])
  1352 
  1353 lemma bounded_linear_add:
  1354   assumes "bounded_linear f"
  1355   assumes "bounded_linear g"
  1356   shows "bounded_linear (\<lambda>x. f x + g x)"
  1357 proof -
  1358   interpret f: bounded_linear f by fact
  1359   interpret g: bounded_linear g by fact
  1360   show ?thesis
  1361   proof
  1362     from f.bounded obtain Kf where Kf: "\<And>x. norm (f x) \<le> norm x * Kf" by blast
  1363     from g.bounded obtain Kg where Kg: "\<And>x. norm (g x) \<le> norm x * Kg" by blast
  1364     show "\<exists>K. \<forall>x. norm (f x + g x) \<le> norm x * K"
  1365       using add_mono[OF Kf Kg]
  1366       by (intro exI[of _ "Kf + Kg"]) (auto simp: field_simps intro: norm_triangle_ineq order_trans)
  1367   qed (simp_all add: f.add g.add f.scaleR g.scaleR scaleR_right_distrib)
  1368 qed
  1369 
  1370 lemma bounded_linear_minus:
  1371   assumes "bounded_linear f"
  1372   shows "bounded_linear (\<lambda>x. - f x)"
  1373 proof -
  1374   interpret f: bounded_linear f by fact
  1375   show ?thesis apply (unfold_locales)
  1376     apply (simp add: f.add)
  1377     apply (simp add: f.scaleR)
  1378     apply (simp add: f.bounded)
  1379     done
  1380 qed
  1381 
  1382 lemma bounded_linear_compose:
  1383   assumes "bounded_linear f"
  1384   assumes "bounded_linear g"
  1385   shows "bounded_linear (\<lambda>x. f (g x))"
  1386 proof -
  1387   interpret f: bounded_linear f by fact
  1388   interpret g: bounded_linear g by fact
  1389   show ?thesis proof (unfold_locales)
  1390     fix x y show "f (g (x + y)) = f (g x) + f (g y)"
  1391       by (simp only: f.add g.add)
  1392   next
  1393     fix r x show "f (g (scaleR r x)) = scaleR r (f (g x))"
  1394       by (simp only: f.scaleR g.scaleR)
  1395   next
  1396     from f.pos_bounded
  1397     obtain Kf where f: "\<And>x. norm (f x) \<le> norm x * Kf" and Kf: "0 < Kf" by fast
  1398     from g.pos_bounded
  1399     obtain Kg where g: "\<And>x. norm (g x) \<le> norm x * Kg" by fast
  1400     show "\<exists>K. \<forall>x. norm (f (g x)) \<le> norm x * K"
  1401     proof (intro exI allI)
  1402       fix x
  1403       have "norm (f (g x)) \<le> norm (g x) * Kf"
  1404         using f .
  1405       also have "\<dots> \<le> (norm x * Kg) * Kf"
  1406         using g Kf [THEN order_less_imp_le] by (rule mult_right_mono)
  1407       also have "(norm x * Kg) * Kf = norm x * (Kg * Kf)"
  1408         by (rule mult.assoc)
  1409       finally show "norm (f (g x)) \<le> norm x * (Kg * Kf)" .
  1410     qed
  1411   qed
  1412 qed
  1413 
  1414 lemma bounded_bilinear_mult:
  1415   "bounded_bilinear (op * :: 'a \<Rightarrow> 'a \<Rightarrow> 'a::real_normed_algebra)"
  1416 apply (rule bounded_bilinear.intro)
  1417 apply (rule distrib_right)
  1418 apply (rule distrib_left)
  1419 apply (rule mult_scaleR_left)
  1420 apply (rule mult_scaleR_right)
  1421 apply (rule_tac x="1" in exI)
  1422 apply (simp add: norm_mult_ineq)
  1423 done
  1424 
  1425 lemma bounded_linear_mult_left:
  1426   "bounded_linear (\<lambda>x::'a::real_normed_algebra. x * y)"
  1427   using bounded_bilinear_mult
  1428   by (rule bounded_bilinear.bounded_linear_left)
  1429 
  1430 lemma bounded_linear_mult_right:
  1431   "bounded_linear (\<lambda>y::'a::real_normed_algebra. x * y)"
  1432   using bounded_bilinear_mult
  1433   by (rule bounded_bilinear.bounded_linear_right)
  1434 
  1435 lemmas bounded_linear_mult_const =
  1436   bounded_linear_mult_left [THEN bounded_linear_compose]
  1437 
  1438 lemmas bounded_linear_const_mult =
  1439   bounded_linear_mult_right [THEN bounded_linear_compose]
  1440 
  1441 lemma bounded_linear_divide:
  1442   "bounded_linear (\<lambda>x::'a::real_normed_field. x / y)"
  1443   unfolding divide_inverse by (rule bounded_linear_mult_left)
  1444 
  1445 lemma bounded_bilinear_scaleR: "bounded_bilinear scaleR"
  1446 apply (rule bounded_bilinear.intro)
  1447 apply (rule scaleR_left_distrib)
  1448 apply (rule scaleR_right_distrib)
  1449 apply simp
  1450 apply (rule scaleR_left_commute)
  1451 apply (rule_tac x="1" in exI, simp)
  1452 done
  1453 
  1454 lemma bounded_linear_scaleR_left: "bounded_linear (\<lambda>r. scaleR r x)"
  1455   using bounded_bilinear_scaleR
  1456   by (rule bounded_bilinear.bounded_linear_left)
  1457 
  1458 lemma bounded_linear_scaleR_right: "bounded_linear (\<lambda>x. scaleR r x)"
  1459   using bounded_bilinear_scaleR
  1460   by (rule bounded_bilinear.bounded_linear_right)
  1461 
  1462 lemma bounded_linear_of_real: "bounded_linear (\<lambda>r. of_real r)"
  1463   unfolding of_real_def by (rule bounded_linear_scaleR_left)
  1464 
  1465 lemma real_bounded_linear:
  1466   fixes f :: "real \<Rightarrow> real"
  1467   shows "bounded_linear f \<longleftrightarrow> (\<exists>c::real. f = (\<lambda>x. x * c))"
  1468 proof -
  1469   { fix x assume "bounded_linear f"
  1470     then interpret bounded_linear f .
  1471     from scaleR[of x 1] have "f x = x * f 1"
  1472       by simp }
  1473   then show ?thesis
  1474     by (auto intro: exI[of _ "f 1"] bounded_linear_mult_left)
  1475 qed
  1476 
  1477 instance real_normed_algebra_1 \<subseteq> perfect_space
  1478 proof
  1479   fix x::'a
  1480   show "\<not> open {x}"
  1481     unfolding open_dist dist_norm
  1482     by (clarsimp, rule_tac x="x + of_real (e/2)" in exI, simp)
  1483 qed
  1484 
  1485 subsection {* Filters and Limits on Metric Space *}
  1486 
  1487 lemma (in metric_space) nhds_metric: "nhds x = (INF e:{0 <..}. principal {y. dist y x < e})"
  1488   unfolding nhds_def
  1489 proof (safe intro!: INF_eq)
  1490   fix S assume "open S" "x \<in> S"
  1491   then obtain e where "{y. dist y x < e} \<subseteq> S" "0 < e"
  1492     by (auto simp: open_dist subset_eq)
  1493   then show "\<exists>e\<in>{0<..}. principal {y. dist y x < e} \<le> principal S"
  1494     by auto
  1495 qed (auto intro!: exI[of _ "{y. dist x y < e}" for e] open_ball simp: dist_commute)
  1496 
  1497 lemma (in metric_space) tendsto_iff:
  1498   "(f ---> l) F \<longleftrightarrow> (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) F)"
  1499   unfolding nhds_metric filterlim_INF filterlim_principal by auto
  1500 
  1501 lemma (in metric_space) tendstoI: "(\<And>e. 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F) \<Longrightarrow> (f ---> l) F"
  1502   by (auto simp: tendsto_iff)
  1503 
  1504 lemma (in metric_space) tendstoD: "(f ---> l) F \<Longrightarrow> 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
  1505   by (auto simp: tendsto_iff)
  1506 
  1507 lemma (in metric_space) eventually_nhds_metric:
  1508   "eventually P (nhds a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. dist x a < d \<longrightarrow> P x)"
  1509   unfolding nhds_metric
  1510   by (subst eventually_INF_base)
  1511      (auto simp: eventually_principal Bex_def subset_eq intro: exI[of _ "min a b" for a b])
  1512 
  1513 lemma eventually_at:
  1514   fixes a :: "'a :: metric_space"
  1515   shows "eventually P (at a within S) \<longleftrightarrow> (\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<and> dist x a < d \<longrightarrow> P x)"
  1516   unfolding eventually_at_filter eventually_nhds_metric by (auto simp: dist_nz)
  1517 
  1518 lemma eventually_at_le:
  1519   fixes a :: "'a::metric_space"
  1520   shows "eventually P (at a within S) \<longleftrightarrow> (\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<and> dist x a \<le> d \<longrightarrow> P x)"
  1521   unfolding eventually_at_filter eventually_nhds_metric
  1522   apply auto
  1523   apply (rule_tac x="d / 2" in exI)
  1524   apply auto
  1525   done
  1526 
  1527 lemma metric_tendsto_imp_tendsto:
  1528   fixes a :: "'a :: metric_space" and b :: "'b :: metric_space"
  1529   assumes f: "(f ---> a) F"
  1530   assumes le: "eventually (\<lambda>x. dist (g x) b \<le> dist (f x) a) F"
  1531   shows "(g ---> b) F"
  1532 proof (rule tendstoI)
  1533   fix e :: real assume "0 < e"
  1534   with f have "eventually (\<lambda>x. dist (f x) a < e) F" by (rule tendstoD)
  1535   with le show "eventually (\<lambda>x. dist (g x) b < e) F"
  1536     using le_less_trans by (rule eventually_elim2)
  1537 qed
  1538 
  1539 lemma filterlim_real_sequentially: "LIM x sequentially. real x :> at_top"
  1540   unfolding filterlim_at_top
  1541   apply (intro allI)
  1542   apply (rule_tac c="nat(ceiling (Z + 1))" in eventually_sequentiallyI)
  1543   by linarith
  1544 
  1545 subsubsection {* Limits of Sequences *}
  1546 
  1547 lemma lim_sequentially: "X ----> (L::'a::metric_space) \<longleftrightarrow> (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. dist (X n) L < r)"
  1548   unfolding tendsto_iff eventually_sequentially ..
  1549 
  1550 lemma LIMSEQ_iff_nz: "X ----> (L::'a::metric_space) = (\<forall>r>0. \<exists>no>0. \<forall>n\<ge>no. dist (X n) L < r)"
  1551   unfolding lim_sequentially by (metis Suc_leD zero_less_Suc)
  1552 
  1553 lemma metric_LIMSEQ_I:
  1554   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r) \<Longrightarrow> X ----> (L::'a::metric_space)"
  1555 by (simp add: lim_sequentially)
  1556 
  1557 lemma metric_LIMSEQ_D:
  1558   "\<lbrakk>X ----> (L::'a::metric_space); 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r"
  1559 by (simp add: lim_sequentially)
  1560 
  1561 
  1562 subsubsection {* Limits of Functions *}
  1563 
  1564 lemma LIM_def: "f -- (a::'a::metric_space) --> (L::'b::metric_space) =
  1565      (\<forall>r > 0. \<exists>s > 0. \<forall>x. x \<noteq> a & dist x a < s
  1566         --> dist (f x) L < r)"
  1567   unfolding tendsto_iff eventually_at by simp
  1568 
  1569 lemma metric_LIM_I:
  1570   "(\<And>r. 0 < r \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r)
  1571     \<Longrightarrow> f -- (a::'a::metric_space) --> (L::'b::metric_space)"
  1572 by (simp add: LIM_def)
  1573 
  1574 lemma metric_LIM_D:
  1575   "\<lbrakk>f -- (a::'a::metric_space) --> (L::'b::metric_space); 0 < r\<rbrakk>
  1576     \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r"
  1577 by (simp add: LIM_def)
  1578 
  1579 lemma metric_LIM_imp_LIM:
  1580   assumes f: "f -- a --> (l::'a::metric_space)"
  1581   assumes le: "\<And>x. x \<noteq> a \<Longrightarrow> dist (g x) m \<le> dist (f x) l"
  1582   shows "g -- a --> (m::'b::metric_space)"
  1583   by (rule metric_tendsto_imp_tendsto [OF f]) (auto simp add: eventually_at_topological le)
  1584 
  1585 lemma metric_LIM_equal2:
  1586   assumes 1: "0 < R"
  1587   assumes 2: "\<And>x. \<lbrakk>x \<noteq> a; dist x a < R\<rbrakk> \<Longrightarrow> f x = g x"
  1588   shows "g -- a --> l \<Longrightarrow> f -- (a::'a::metric_space) --> l"
  1589 apply (rule topological_tendstoI)
  1590 apply (drule (2) topological_tendstoD)
  1591 apply (simp add: eventually_at, safe)
  1592 apply (rule_tac x="min d R" in exI, safe)
  1593 apply (simp add: 1)
  1594 apply (simp add: 2)
  1595 done
  1596 
  1597 lemma metric_LIM_compose2:
  1598   assumes f: "f -- (a::'a::metric_space) --> b"
  1599   assumes g: "g -- b --> c"
  1600   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> f x \<noteq> b"
  1601   shows "(\<lambda>x. g (f x)) -- a --> c"
  1602   using inj
  1603   by (intro tendsto_compose_eventually[OF g f]) (auto simp: eventually_at)
  1604 
  1605 lemma metric_isCont_LIM_compose2:
  1606   fixes f :: "'a :: metric_space \<Rightarrow> _"
  1607   assumes f [unfolded isCont_def]: "isCont f a"
  1608   assumes g: "g -- f a --> l"
  1609   assumes inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> f x \<noteq> f a"
  1610   shows "(\<lambda>x. g (f x)) -- a --> l"
  1611 by (rule metric_LIM_compose2 [OF f g inj])
  1612 
  1613 subsection {* Complete metric spaces *}
  1614 
  1615 subsection {* Cauchy sequences *}
  1616 
  1617 definition (in metric_space) Cauchy :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
  1618   "Cauchy X = (\<forall>e>0. \<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < e)"
  1619 
  1620 subsection {* Cauchy Sequences *}
  1621 
  1622 lemma metric_CauchyI:
  1623   "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e) \<Longrightarrow> Cauchy X"
  1624   by (simp add: Cauchy_def)
  1625 
  1626 lemma metric_CauchyD:
  1627   "Cauchy X \<Longrightarrow> 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e"
  1628   by (simp add: Cauchy_def)
  1629 
  1630 lemma metric_Cauchy_iff2:
  1631   "Cauchy X = (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < inverse(real (Suc j))))"
  1632 apply (simp add: Cauchy_def, auto)
  1633 apply (drule reals_Archimedean, safe)
  1634 apply (drule_tac x = n in spec, auto)
  1635 apply (rule_tac x = M in exI, auto)
  1636 apply (drule_tac x = m in spec, simp)
  1637 apply (drule_tac x = na in spec, auto)
  1638 done
  1639 
  1640 lemma Cauchy_iff2:
  1641   "Cauchy X = (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. \<bar>X m - X n\<bar> < inverse(real (Suc j))))"
  1642   unfolding metric_Cauchy_iff2 dist_real_def ..
  1643 
  1644 lemma Cauchy_subseq_Cauchy:
  1645   "\<lbrakk> Cauchy X; subseq f \<rbrakk> \<Longrightarrow> Cauchy (X o f)"
  1646 apply (auto simp add: Cauchy_def)
  1647 apply (drule_tac x=e in spec, clarify)
  1648 apply (rule_tac x=M in exI, clarify)
  1649 apply (blast intro: le_trans [OF _ seq_suble] dest!: spec)
  1650 done
  1651 
  1652 theorem LIMSEQ_imp_Cauchy:
  1653   assumes X: "X ----> a" shows "Cauchy X"
  1654 proof (rule metric_CauchyI)
  1655   fix e::real assume "0 < e"
  1656   hence "0 < e/2" by simp
  1657   with X have "\<exists>N. \<forall>n\<ge>N. dist (X n) a < e/2" by (rule metric_LIMSEQ_D)
  1658   then obtain N where N: "\<forall>n\<ge>N. dist (X n) a < e/2" ..
  1659   show "\<exists>N. \<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < e"
  1660   proof (intro exI allI impI)
  1661     fix m assume "N \<le> m"
  1662     hence m: "dist (X m) a < e/2" using N by fast
  1663     fix n assume "N \<le> n"
  1664     hence n: "dist (X n) a < e/2" using N by fast
  1665     have "dist (X m) (X n) \<le> dist (X m) a + dist (X n) a"
  1666       by (rule dist_triangle2)
  1667     also from m n have "\<dots> < e" by simp
  1668     finally show "dist (X m) (X n) < e" .
  1669   qed
  1670 qed
  1671 
  1672 lemma convergent_Cauchy: "convergent X \<Longrightarrow> Cauchy X"
  1673 unfolding convergent_def
  1674 by (erule exE, erule LIMSEQ_imp_Cauchy)
  1675 
  1676 subsubsection {* Cauchy Sequences are Convergent *}
  1677 
  1678 class complete_space = metric_space +
  1679   assumes Cauchy_convergent: "Cauchy X \<Longrightarrow> convergent X"
  1680 
  1681 lemma Cauchy_convergent_iff:
  1682   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1683   shows "Cauchy X = convergent X"
  1684 by (fast intro: Cauchy_convergent convergent_Cauchy)
  1685 
  1686 subsection {* The set of real numbers is a complete metric space *}
  1687 
  1688 text {*
  1689 Proof that Cauchy sequences converge based on the one from
  1690 @{url "http://pirate.shu.edu/~wachsmut/ira/numseq/proofs/cauconv.html"}
  1691 *}
  1692 
  1693 text {*
  1694   If sequence @{term "X"} is Cauchy, then its limit is the lub of
  1695   @{term "{r::real. \<exists>N. \<forall>n\<ge>N. r < X n}"}
  1696 *}
  1697 
  1698 lemma increasing_LIMSEQ:
  1699   fixes f :: "nat \<Rightarrow> real"
  1700   assumes inc: "\<And>n. f n \<le> f (Suc n)"
  1701       and bdd: "\<And>n. f n \<le> l"
  1702       and en: "\<And>e. 0 < e \<Longrightarrow> \<exists>n. l \<le> f n + e"
  1703   shows "f ----> l"
  1704 proof (rule increasing_tendsto)
  1705   fix x assume "x < l"
  1706   with dense[of 0 "l - x"] obtain e where "0 < e" "e < l - x"
  1707     by auto
  1708   from en[OF `0 < e`] obtain n where "l - e \<le> f n"
  1709     by (auto simp: field_simps)
  1710   with `e < l - x` `0 < e` have "x < f n" by simp
  1711   with incseq_SucI[of f, OF inc] show "eventually (\<lambda>n. x < f n) sequentially"
  1712     by (auto simp: eventually_sequentially incseq_def intro: less_le_trans)
  1713 qed (insert bdd, auto)
  1714 
  1715 lemma real_Cauchy_convergent:
  1716   fixes X :: "nat \<Rightarrow> real"
  1717   assumes X: "Cauchy X"
  1718   shows "convergent X"
  1719 proof -
  1720   def S \<equiv> "{x::real. \<exists>N. \<forall>n\<ge>N. x < X n}"
  1721   then have mem_S: "\<And>N x. \<forall>n\<ge>N. x < X n \<Longrightarrow> x \<in> S" by auto
  1722 
  1723   { fix N x assume N: "\<forall>n\<ge>N. X n < x"
  1724   fix y::real assume "y \<in> S"
  1725   hence "\<exists>M. \<forall>n\<ge>M. y < X n"
  1726     by (simp add: S_def)
  1727   then obtain M where "\<forall>n\<ge>M. y < X n" ..
  1728   hence "y < X (max M N)" by simp
  1729   also have "\<dots> < x" using N by simp
  1730   finally have "y \<le> x"
  1731     by (rule order_less_imp_le) }
  1732   note bound_isUb = this 
  1733 
  1734   obtain N where "\<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < 1"
  1735     using X[THEN metric_CauchyD, OF zero_less_one] by auto
  1736   hence N: "\<forall>n\<ge>N. dist (X n) (X N) < 1" by simp
  1737   have [simp]: "S \<noteq> {}"
  1738   proof (intro exI ex_in_conv[THEN iffD1])
  1739     from N have "\<forall>n\<ge>N. X N - 1 < X n"
  1740       by (simp add: abs_diff_less_iff dist_real_def)
  1741     thus "X N - 1 \<in> S" by (rule mem_S)
  1742   qed
  1743   have [simp]: "bdd_above S"
  1744   proof
  1745     from N have "\<forall>n\<ge>N. X n < X N + 1"
  1746       by (simp add: abs_diff_less_iff dist_real_def)
  1747     thus "\<And>s. s \<in> S \<Longrightarrow>  s \<le> X N + 1"
  1748       by (rule bound_isUb)
  1749   qed
  1750   have "X ----> Sup S"
  1751   proof (rule metric_LIMSEQ_I)
  1752   fix r::real assume "0 < r"
  1753   hence r: "0 < r/2" by simp
  1754   obtain N where "\<forall>n\<ge>N. \<forall>m\<ge>N. dist (X n) (X m) < r/2"
  1755     using metric_CauchyD [OF X r] by auto
  1756   hence "\<forall>n\<ge>N. dist (X n) (X N) < r/2" by simp
  1757   hence N: "\<forall>n\<ge>N. X N - r/2 < X n \<and> X n < X N + r/2"
  1758     by (simp only: dist_real_def abs_diff_less_iff)
  1759 
  1760   from N have "\<forall>n\<ge>N. X N - r/2 < X n" by fast
  1761   hence "X N - r/2 \<in> S" by (rule mem_S)
  1762   hence 1: "X N - r/2 \<le> Sup S" by (simp add: cSup_upper)
  1763 
  1764   from N have "\<forall>n\<ge>N. X n < X N + r/2" by fast
  1765   from bound_isUb[OF this]
  1766   have 2: "Sup S \<le> X N + r/2"
  1767     by (intro cSup_least) simp_all
  1768 
  1769   show "\<exists>N. \<forall>n\<ge>N. dist (X n) (Sup S) < r"
  1770   proof (intro exI allI impI)
  1771     fix n assume n: "N \<le> n"
  1772     from N n have "X n < X N + r/2" and "X N - r/2 < X n" by simp+
  1773     thus "dist (X n) (Sup S) < r" using 1 2
  1774       by (simp add: abs_diff_less_iff dist_real_def)
  1775   qed
  1776   qed
  1777   then show ?thesis unfolding convergent_def by auto
  1778 qed
  1779 
  1780 instance real :: complete_space
  1781   by intro_classes (rule real_Cauchy_convergent)
  1782 
  1783 class banach = real_normed_vector + complete_space
  1784 
  1785 instance real :: banach by default
  1786 
  1787 lemma tendsto_at_topI_sequentially:
  1788   fixes f :: "real \<Rightarrow> 'b::first_countable_topology"
  1789   assumes *: "\<And>X. filterlim X at_top sequentially \<Longrightarrow> (\<lambda>n. f (X n)) ----> y"
  1790   shows "(f ---> y) at_top"
  1791 proof -
  1792   from nhds_countable[of y] guess A . note A = this
  1793 
  1794   have "\<forall>m. \<exists>k. \<forall>x\<ge>k. f x \<in> A m"
  1795   proof (rule ccontr)
  1796     assume "\<not> (\<forall>m. \<exists>k. \<forall>x\<ge>k. f x \<in> A m)"
  1797     then obtain m where "\<And>k. \<exists>x\<ge>k. f x \<notin> A m"
  1798       by auto
  1799     then have "\<exists>X. \<forall>n. (f (X n) \<notin> A m) \<and> max n (X n) + 1 \<le> X (Suc n)"
  1800       by (intro dependent_nat_choice) (auto simp del: max.bounded_iff)
  1801     then obtain X where X: "\<And>n. f (X n) \<notin> A m" "\<And>n. max n (X n) + 1 \<le> X (Suc n)"
  1802       by auto
  1803     { fix n have "1 \<le> n \<longrightarrow> real n \<le> X n"
  1804         using X[of "n - 1"] by auto }
  1805     then have "filterlim X at_top sequentially"
  1806       by (force intro!: filterlim_at_top_mono[OF filterlim_real_sequentially]
  1807                 simp: eventually_sequentially)
  1808     from topological_tendstoD[OF *[OF this] A(2, 3), of m] X(1) show False
  1809       by auto
  1810   qed
  1811   then obtain k where "\<And>m x. k m \<le> x \<Longrightarrow> f x \<in> A m"
  1812     by metis
  1813   then show ?thesis
  1814     unfolding at_top_def A
  1815     by (intro filterlim_base[where i=k]) auto
  1816 qed
  1817 
  1818 lemma tendsto_at_topI_sequentially_real:
  1819   fixes f :: "real \<Rightarrow> real"
  1820   assumes mono: "mono f"
  1821   assumes limseq: "(\<lambda>n. f (real n)) ----> y"
  1822   shows "(f ---> y) at_top"
  1823 proof (rule tendstoI)
  1824   fix e :: real assume "0 < e"
  1825   with limseq obtain N :: nat where N: "\<And>n. N \<le> n \<Longrightarrow> \<bar>f (real n) - y\<bar> < e"
  1826     by (auto simp: lim_sequentially dist_real_def)
  1827   { fix x :: real
  1828     obtain n where "x \<le> real_of_nat n"
  1829       using ex_le_of_nat[of x] ..
  1830     note monoD[OF mono this]
  1831     also have "f (real_of_nat n) \<le> y"
  1832       by (rule LIMSEQ_le_const[OF limseq])
  1833          (auto intro: exI[of _ n] monoD[OF mono] simp: real_eq_of_nat[symmetric])
  1834     finally have "f x \<le> y" . }
  1835   note le = this
  1836   have "eventually (\<lambda>x. real N \<le> x) at_top"
  1837     by (rule eventually_ge_at_top)
  1838   then show "eventually (\<lambda>x. dist (f x) y < e) at_top"
  1839   proof eventually_elim
  1840     fix x assume N': "real N \<le> x"
  1841     with N[of N] le have "y - f (real N) < e" by auto
  1842     moreover note monoD[OF mono N']
  1843     ultimately show "dist (f x) y < e"
  1844       using le[of x] by (auto simp: dist_real_def field_simps)
  1845   qed
  1846 qed
  1847 
  1848 end
  1849