src/HOL/Product_Type.thy
author haftmann
Thu Sep 25 09:28:03 2008 +0200 (2008-09-25)
changeset 28346 b8390cd56b8f
parent 28262 aa7ca36d67fd
child 28537 1e84256d1a8a
permissions -rw-r--r--
discontinued special treatment of op = vs. eq_class.eq
     1 (*  Title:      HOL/Product_Type.thy
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1992  University of Cambridge
     5 *)
     6 
     7 header {* Cartesian products *}
     8 
     9 theory Product_Type
    10 imports Inductive
    11 uses
    12   ("Tools/split_rule.ML")
    13   ("Tools/inductive_set_package.ML")
    14   ("Tools/inductive_realizer.ML")
    15   ("Tools/datatype_realizer.ML")
    16 begin
    17 
    18 subsection {* @{typ bool} is a datatype *}
    19 
    20 rep_datatype True False by (auto intro: bool_induct)
    21 
    22 declare case_split [cases type: bool]
    23   -- "prefer plain propositional version"
    24 
    25 lemma
    26   shows [code func]: "eq_class.eq False P \<longleftrightarrow> \<not> P"
    27     and [code func]: "eq_class.eq True P \<longleftrightarrow> P" 
    28     and [code func]: "eq_class.eq P False \<longleftrightarrow> \<not> P" 
    29     and [code func]: "eq_class.eq P True \<longleftrightarrow> P"
    30     and [code nbe]: "eq_class.eq P P \<longleftrightarrow> True"
    31   by (simp_all add: eq)
    32 
    33 code_const "eq_class.eq \<Colon> bool \<Rightarrow> bool \<Rightarrow> bool"
    34   (Haskell infixl 4 "==")
    35 
    36 code_instance bool :: eq
    37   (Haskell -)
    38 
    39 
    40 subsection {* Unit *}
    41 
    42 typedef unit = "{True}"
    43 proof
    44   show "True : ?unit" ..
    45 qed
    46 
    47 definition
    48   Unity :: unit    ("'(')")
    49 where
    50   "() = Abs_unit True"
    51 
    52 lemma unit_eq [noatp]: "u = ()"
    53   by (induct u) (simp add: unit_def Unity_def)
    54 
    55 text {*
    56   Simplification procedure for @{thm [source] unit_eq}.  Cannot use
    57   this rule directly --- it loops!
    58 *}
    59 
    60 ML {*
    61   val unit_eq_proc =
    62     let val unit_meta_eq = mk_meta_eq @{thm unit_eq} in
    63       Simplifier.simproc @{theory} "unit_eq" ["x::unit"]
    64       (fn _ => fn _ => fn t => if HOLogic.is_unit t then NONE else SOME unit_meta_eq)
    65     end;
    66 
    67   Addsimprocs [unit_eq_proc];
    68 *}
    69 
    70 rep_datatype "()" by simp
    71 
    72 lemma unit_all_eq1: "(!!x::unit. PROP P x) == PROP P ()"
    73   by simp
    74 
    75 lemma unit_all_eq2: "(!!x::unit. PROP P) == PROP P"
    76   by (rule triv_forall_equality)
    77 
    78 text {*
    79   This rewrite counters the effect of @{text unit_eq_proc} on @{term
    80   [source] "%u::unit. f u"}, replacing it by @{term [source]
    81   f} rather than by @{term [source] "%u. f ()"}.
    82 *}
    83 
    84 lemma unit_abs_eta_conv [simp,noatp]: "(%u::unit. f ()) = f"
    85   by (rule ext) simp
    86 
    87 
    88 text {* code generator setup *}
    89 
    90 instance unit :: eq ..
    91 
    92 lemma [code func]:
    93   "eq_class.eq (u\<Colon>unit) v \<longleftrightarrow> True" unfolding eq unit_eq [of u] unit_eq [of v] by rule+
    94 
    95 code_type unit
    96   (SML "unit")
    97   (OCaml "unit")
    98   (Haskell "()")
    99 
   100 code_instance unit :: eq
   101   (Haskell -)
   102 
   103 code_const "eq_class.eq \<Colon> unit \<Rightarrow> unit \<Rightarrow> bool"
   104   (Haskell infixl 4 "==")
   105 
   106 code_const Unity
   107   (SML "()")
   108   (OCaml "()")
   109   (Haskell "()")
   110 
   111 code_reserved SML
   112   unit
   113 
   114 code_reserved OCaml
   115   unit
   116 
   117 
   118 subsection {* Pairs *}
   119 
   120 subsubsection {* Product type, basic operations and concrete syntax *}
   121 
   122 definition
   123   Pair_Rep :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
   124 where
   125   "Pair_Rep a b = (\<lambda>x y. x = a \<and> y = b)"
   126 
   127 global
   128 
   129 typedef (Prod)
   130   ('a, 'b) "*"    (infixr "*" 20)
   131     = "{f. \<exists>a b. f = Pair_Rep (a\<Colon>'a) (b\<Colon>'b)}"
   132 proof
   133   fix a b show "Pair_Rep a b \<in> ?Prod"
   134     by rule+
   135 qed
   136 
   137 syntax (xsymbols)
   138   "*"      :: "[type, type] => type"         ("(_ \<times>/ _)" [21, 20] 20)
   139 syntax (HTML output)
   140   "*"      :: "[type, type] => type"         ("(_ \<times>/ _)" [21, 20] 20)
   141 
   142 consts
   143   Pair     :: "'a \<Rightarrow> 'b \<Rightarrow> 'a \<times> 'b"
   144   fst      :: "'a \<times> 'b \<Rightarrow> 'a"
   145   snd      :: "'a \<times> 'b \<Rightarrow> 'b"
   146   split    :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c"
   147   curry    :: "('a \<times> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'c"
   148 
   149 local
   150 
   151 defs
   152   Pair_def:     "Pair a b == Abs_Prod (Pair_Rep a b)"
   153   fst_def:      "fst p == THE a. EX b. p = Pair a b"
   154   snd_def:      "snd p == THE b. EX a. p = Pair a b"
   155   split_def:    "split == (%c p. c (fst p) (snd p))"
   156   curry_def:    "curry == (%c x y. c (Pair x y))"
   157 
   158 text {*
   159   Patterns -- extends pre-defined type @{typ pttrn} used in
   160   abstractions.
   161 *}
   162 
   163 nonterminals
   164   tuple_args patterns
   165 
   166 syntax
   167   "_tuple"      :: "'a => tuple_args => 'a * 'b"        ("(1'(_,/ _'))")
   168   "_tuple_arg"  :: "'a => tuple_args"                   ("_")
   169   "_tuple_args" :: "'a => tuple_args => tuple_args"     ("_,/ _")
   170   "_pattern"    :: "[pttrn, patterns] => pttrn"         ("'(_,/ _')")
   171   ""            :: "pttrn => patterns"                  ("_")
   172   "_patterns"   :: "[pttrn, patterns] => patterns"      ("_,/ _")
   173 
   174 translations
   175   "(x, y)"       == "Pair x y"
   176   "_tuple x (_tuple_args y z)" == "_tuple x (_tuple_arg (_tuple y z))"
   177   "%(x,y,zs).b"  == "split(%x (y,zs).b)"
   178   "%(x,y).b"     == "split(%x y. b)"
   179   "_abs (Pair x y) t" => "%(x,y).t"
   180   (* The last rule accommodates tuples in `case C ... (x,y) ... => ...'
   181      The (x,y) is parsed as `Pair x y' because it is logic, not pttrn *)
   182 
   183 (* reconstructs pattern from (nested) splits, avoiding eta-contraction of body*)
   184 (* works best with enclosing "let", if "let" does not avoid eta-contraction   *)
   185 print_translation {*
   186 let fun split_tr' [Abs (x,T,t as (Abs abs))] =
   187       (* split (%x y. t) => %(x,y) t *)
   188       let val (y,t') = atomic_abs_tr' abs;
   189           val (x',t'') = atomic_abs_tr' (x,T,t');
   190     
   191       in Syntax.const "_abs" $ (Syntax.const "_pattern" $x'$y) $ t'' end
   192     | split_tr' [Abs (x,T,(s as Const ("split",_)$t))] =
   193        (* split (%x. (split (%y z. t))) => %(x,y,z). t *)
   194        let val (Const ("_abs",_)$(Const ("_pattern",_)$y$z)$t') = split_tr' [t];
   195            val (x',t'') = atomic_abs_tr' (x,T,t');
   196        in Syntax.const "_abs"$ 
   197            (Syntax.const "_pattern"$x'$(Syntax.const "_patterns"$y$z))$t'' end
   198     | split_tr' [Const ("split",_)$t] =
   199        (* split (split (%x y z. t)) => %((x,y),z). t *)   
   200        split_tr' [(split_tr' [t])] (* inner split_tr' creates next pattern *)
   201     | split_tr' [Const ("_abs",_)$x_y$(Abs abs)] =
   202        (* split (%pttrn z. t) => %(pttrn,z). t *)
   203        let val (z,t) = atomic_abs_tr' abs;
   204        in Syntax.const "_abs" $ (Syntax.const "_pattern" $x_y$z) $ t end
   205     | split_tr' _ =  raise Match;
   206 in [("split", split_tr')]
   207 end
   208 *}
   209 
   210 (* print "split f" as "\<lambda>(x,y). f x y" and "split (\<lambda>x. f x)" as "\<lambda>(x,y). f x y" *) 
   211 typed_print_translation {*
   212 let
   213   fun split_guess_names_tr' _ T [Abs (x,_,Abs _)] = raise Match
   214     | split_guess_names_tr' _ T  [Abs (x,xT,t)] =
   215         (case (head_of t) of
   216            Const ("split",_) => raise Match
   217          | _ => let 
   218                   val (_::yT::_) = binder_types (domain_type T) handle Bind => raise Match;
   219                   val (y,t') = atomic_abs_tr' ("y",yT,(incr_boundvars 1 t)$Bound 0); 
   220                   val (x',t'') = atomic_abs_tr' (x,xT,t');
   221                 in Syntax.const "_abs" $ (Syntax.const "_pattern" $x'$y) $ t'' end)
   222     | split_guess_names_tr' _ T [t] =
   223        (case (head_of t) of
   224            Const ("split",_) => raise Match 
   225          | _ => let 
   226                   val (xT::yT::_) = binder_types (domain_type T) handle Bind => raise Match;
   227                   val (y,t') = 
   228                         atomic_abs_tr' ("y",yT,(incr_boundvars 2 t)$Bound 1$Bound 0); 
   229                   val (x',t'') = atomic_abs_tr' ("x",xT,t');
   230                 in Syntax.const "_abs" $ (Syntax.const "_pattern" $x'$y) $ t'' end)
   231     | split_guess_names_tr' _ _ _ = raise Match;
   232 in [("split", split_guess_names_tr')]
   233 end 
   234 *}
   235 
   236 
   237 text {* Towards a datatype declaration *}
   238 
   239 lemma surj_pair [simp]: "EX x y. p = (x, y)"
   240   apply (unfold Pair_def)
   241   apply (rule Rep_Prod [unfolded Prod_def, THEN CollectE])
   242   apply (erule exE, erule exE, rule exI, rule exI)
   243   apply (rule Rep_Prod_inverse [symmetric, THEN trans])
   244   apply (erule arg_cong)
   245   done
   246 
   247 lemma PairE [cases type: *]:
   248   obtains x y where "p = (x, y)"
   249   using surj_pair [of p] by blast
   250 
   251 lemma ProdI: "Pair_Rep a b \<in> Prod"
   252   unfolding Prod_def by rule+
   253 
   254 lemma Pair_Rep_inject: "Pair_Rep a b = Pair_Rep a' b' \<Longrightarrow> a = a' \<and> b = b'"
   255   unfolding Pair_Rep_def by (drule fun_cong, drule fun_cong) blast
   256 
   257 lemma inj_on_Abs_Prod: "inj_on Abs_Prod Prod"
   258   apply (rule inj_on_inverseI)
   259   apply (erule Abs_Prod_inverse)
   260   done
   261 
   262 lemma Pair_inject:
   263   assumes "(a, b) = (a', b')"
   264     and "a = a' ==> b = b' ==> R"
   265   shows R
   266   apply (insert prems [unfolded Pair_def])
   267   apply (rule inj_on_Abs_Prod [THEN inj_onD, THEN Pair_Rep_inject, THEN conjE])
   268   apply (assumption | rule ProdI)+
   269   done
   270 
   271 rep_datatype (prod) Pair
   272 proof -
   273   fix P p
   274   assume "\<And>x y. P (x, y)"
   275   then show "P p" by (cases p) simp
   276 qed (auto elim: Pair_inject)
   277 
   278 lemmas Pair_eq = prod.inject
   279 
   280 lemma fst_conv [simp, code]: "fst (a, b) = a"
   281   unfolding fst_def by blast
   282 
   283 lemma snd_conv [simp, code]: "snd (a, b) = b"
   284   unfolding snd_def by blast
   285 
   286 
   287 subsubsection {* Basic rules and proof tools *}
   288 
   289 lemma fst_eqD: "fst (x, y) = a ==> x = a"
   290   by simp
   291 
   292 lemma snd_eqD: "snd (x, y) = a ==> y = a"
   293   by simp
   294 
   295 lemma pair_collapse [simp]: "(fst p, snd p) = p"
   296   by (cases p) simp
   297 
   298 lemmas surjective_pairing = pair_collapse [symmetric]
   299 
   300 lemma split_paired_all: "(!!x. PROP P x) == (!!a b. PROP P (a, b))"
   301 proof
   302   fix a b
   303   assume "!!x. PROP P x"
   304   then show "PROP P (a, b)" .
   305 next
   306   fix x
   307   assume "!!a b. PROP P (a, b)"
   308   from `PROP P (fst x, snd x)` show "PROP P x" by simp
   309 qed
   310 
   311 text {*
   312   The rule @{thm [source] split_paired_all} does not work with the
   313   Simplifier because it also affects premises in congrence rules,
   314   where this can lead to premises of the form @{text "!!a b. ... =
   315   ?P(a, b)"} which cannot be solved by reflexivity.
   316 *}
   317 
   318 lemmas split_tupled_all = split_paired_all unit_all_eq2
   319 
   320 ML {*
   321   (* replace parameters of product type by individual component parameters *)
   322   val safe_full_simp_tac = generic_simp_tac true (true, false, false);
   323   local (* filtering with exists_paired_all is an essential optimization *)
   324     fun exists_paired_all (Const ("all", _) $ Abs (_, T, t)) =
   325           can HOLogic.dest_prodT T orelse exists_paired_all t
   326       | exists_paired_all (t $ u) = exists_paired_all t orelse exists_paired_all u
   327       | exists_paired_all (Abs (_, _, t)) = exists_paired_all t
   328       | exists_paired_all _ = false;
   329     val ss = HOL_basic_ss
   330       addsimps [@{thm split_paired_all}, @{thm unit_all_eq2}, @{thm unit_abs_eta_conv}]
   331       addsimprocs [unit_eq_proc];
   332   in
   333     val split_all_tac = SUBGOAL (fn (t, i) =>
   334       if exists_paired_all t then safe_full_simp_tac ss i else no_tac);
   335     val unsafe_split_all_tac = SUBGOAL (fn (t, i) =>
   336       if exists_paired_all t then full_simp_tac ss i else no_tac);
   337     fun split_all th =
   338    if exists_paired_all (Thm.prop_of th) then full_simplify ss th else th;
   339   end;
   340 *}
   341 
   342 declaration {* fn _ =>
   343   Classical.map_cs (fn cs => cs addSbefore ("split_all_tac", split_all_tac))
   344 *}
   345 
   346 lemma split_paired_All [simp]: "(ALL x. P x) = (ALL a b. P (a, b))"
   347   -- {* @{text "[iff]"} is not a good idea because it makes @{text blast} loop *}
   348   by fast
   349 
   350 lemma split_paired_Ex [simp]: "(EX x. P x) = (EX a b. P (a, b))"
   351   by fast
   352 
   353 lemma Pair_fst_snd_eq: "s = t \<longleftrightarrow> fst s = fst t \<and> snd s = snd t"
   354   by (cases s, cases t) simp
   355 
   356 lemma prod_eqI [intro?]: "fst p = fst q \<Longrightarrow> snd p = snd q \<Longrightarrow> p = q"
   357   by (simp add: Pair_fst_snd_eq)
   358 
   359 
   360 subsubsection {* @{text split} and @{text curry} *}
   361 
   362 lemma split_conv [simp, code func]: "split f (a, b) = f a b"
   363   by (simp add: split_def)
   364 
   365 lemma curry_conv [simp, code func]: "curry f a b = f (a, b)"
   366   by (simp add: curry_def)
   367 
   368 lemmas split = split_conv  -- {* for backwards compatibility *}
   369 
   370 lemma splitI: "f a b \<Longrightarrow> split f (a, b)"
   371   by (rule split_conv [THEN iffD2])
   372 
   373 lemma splitD: "split f (a, b) \<Longrightarrow> f a b"
   374   by (rule split_conv [THEN iffD1])
   375 
   376 lemma curryI [intro!]: "f (a, b) \<Longrightarrow> curry f a b"
   377   by (simp add: curry_def)
   378 
   379 lemma curryD [dest!]: "curry f a b \<Longrightarrow> f (a, b)"
   380   by (simp add: curry_def)
   381 
   382 lemma curryE: "curry f a b \<Longrightarrow> (f (a, b) \<Longrightarrow> Q) \<Longrightarrow> Q"
   383   by (simp add: curry_def)
   384 
   385 lemma curry_split [simp]: "curry (split f) = f"
   386   by (simp add: curry_def split_def)
   387 
   388 lemma split_curry [simp]: "split (curry f) = f"
   389   by (simp add: curry_def split_def)
   390 
   391 lemma split_Pair [simp]: "(\<lambda>(x, y). (x, y)) = id"
   392   by (simp add: split_def id_def)
   393 
   394 lemma split_eta: "(\<lambda>(x, y). f (x, y)) = f"
   395   -- {* Subsumes the old @{text split_Pair} when @{term f} is the identity function. *}
   396   by (rule ext) auto
   397 
   398 lemma split_comp: "split (f \<circ> g) x = f (g (fst x)) (snd x)"
   399   by (cases x) simp
   400 
   401 lemma split_twice: "split f (split g p) = split (\<lambda>x y. split f (g x y)) p"
   402   unfolding split_def ..
   403 
   404 lemma split_paired_The: "(THE x. P x) = (THE (a, b). P (a, b))"
   405   -- {* Can't be added to simpset: loops! *}
   406   by (simp add: split_eta)
   407 
   408 lemma The_split: "The (split P) = (THE xy. P (fst xy) (snd xy))"
   409   by (simp add: split_def)
   410 
   411 lemma split_weak_cong: "p = q \<Longrightarrow> split c p = split c q"
   412   -- {* Prevents simplification of @{term c}: much faster *}
   413   by (erule arg_cong)
   414 
   415 lemma cond_split_eta: "(!!x y. f x y = g (x, y)) ==> (%(x, y). f x y) = g"
   416   by (simp add: split_eta)
   417 
   418 text {*
   419   Simplification procedure for @{thm [source] cond_split_eta}.  Using
   420   @{thm [source] split_eta} as a rewrite rule is not general enough,
   421   and using @{thm [source] cond_split_eta} directly would render some
   422   existing proofs very inefficient; similarly for @{text
   423   split_beta}.
   424 *}
   425 
   426 ML {*
   427 
   428 local
   429   val cond_split_eta_ss = HOL_basic_ss addsimps [thm "cond_split_eta"]
   430   fun  Pair_pat k 0 (Bound m) = (m = k)
   431   |    Pair_pat k i (Const ("Pair",  _) $ Bound m $ t) = i > 0 andalso
   432                         m = k+i andalso Pair_pat k (i-1) t
   433   |    Pair_pat _ _ _ = false;
   434   fun no_args k i (Abs (_, _, t)) = no_args (k+1) i t
   435   |   no_args k i (t $ u) = no_args k i t andalso no_args k i u
   436   |   no_args k i (Bound m) = m < k orelse m > k+i
   437   |   no_args _ _ _ = true;
   438   fun split_pat tp i (Abs  (_,_,t)) = if tp 0 i t then SOME (i,t) else NONE
   439   |   split_pat tp i (Const ("split", _) $ Abs (_, _, t)) = split_pat tp (i+1) t
   440   |   split_pat tp i _ = NONE;
   441   fun metaeq ss lhs rhs = mk_meta_eq (Goal.prove (Simplifier.the_context ss) [] []
   442         (HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs,rhs)))
   443         (K (simp_tac (Simplifier.inherit_context ss cond_split_eta_ss) 1)));
   444 
   445   fun beta_term_pat k i (Abs (_, _, t)) = beta_term_pat (k+1) i t
   446   |   beta_term_pat k i (t $ u) = Pair_pat k i (t $ u) orelse
   447                         (beta_term_pat k i t andalso beta_term_pat k i u)
   448   |   beta_term_pat k i t = no_args k i t;
   449   fun  eta_term_pat k i (f $ arg) = no_args k i f andalso Pair_pat k i arg
   450   |    eta_term_pat _ _ _ = false;
   451   fun subst arg k i (Abs (x, T, t)) = Abs (x, T, subst arg (k+1) i t)
   452   |   subst arg k i (t $ u) = if Pair_pat k i (t $ u) then incr_boundvars k arg
   453                               else (subst arg k i t $ subst arg k i u)
   454   |   subst arg k i t = t;
   455   fun beta_proc ss (s as Const ("split", _) $ Abs (_, _, t) $ arg) =
   456         (case split_pat beta_term_pat 1 t of
   457         SOME (i,f) => SOME (metaeq ss s (subst arg 0 i f))
   458         | NONE => NONE)
   459   |   beta_proc _ _ = NONE;
   460   fun eta_proc ss (s as Const ("split", _) $ Abs (_, _, t)) =
   461         (case split_pat eta_term_pat 1 t of
   462           SOME (_,ft) => SOME (metaeq ss s (let val (f $ arg) = ft in f end))
   463         | NONE => NONE)
   464   |   eta_proc _ _ = NONE;
   465 in
   466   val split_beta_proc = Simplifier.simproc (the_context ()) "split_beta" ["split f z"] (K beta_proc);
   467   val split_eta_proc = Simplifier.simproc (the_context ()) "split_eta" ["split f"] (K eta_proc);
   468 end;
   469 
   470 Addsimprocs [split_beta_proc, split_eta_proc];
   471 *}
   472 
   473 lemma split_beta [mono]: "(%(x, y). P x y) z = P (fst z) (snd z)"
   474   by (subst surjective_pairing, rule split_conv)
   475 
   476 lemma split_split [noatp]: "R(split c p) = (ALL x y. p = (x, y) --> R(c x y))"
   477   -- {* For use with @{text split} and the Simplifier. *}
   478   by (insert surj_pair [of p], clarify, simp)
   479 
   480 text {*
   481   @{thm [source] split_split} could be declared as @{text "[split]"}
   482   done after the Splitter has been speeded up significantly;
   483   precompute the constants involved and don't do anything unless the
   484   current goal contains one of those constants.
   485 *}
   486 
   487 lemma split_split_asm [noatp]: "R (split c p) = (~(EX x y. p = (x, y) & (~R (c x y))))"
   488 by (subst split_split, simp)
   489 
   490 
   491 text {*
   492   \medskip @{term split} used as a logical connective or set former.
   493 
   494   \medskip These rules are for use with @{text blast}; could instead
   495   call @{text simp} using @{thm [source] split} as rewrite. *}
   496 
   497 lemma splitI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> split c p"
   498   apply (simp only: split_tupled_all)
   499   apply (simp (no_asm_simp))
   500   done
   501 
   502 lemma splitI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> split c p x"
   503   apply (simp only: split_tupled_all)
   504   apply (simp (no_asm_simp))
   505   done
   506 
   507 lemma splitE: "split c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   508   by (induct p) (auto simp add: split_def)
   509 
   510 lemma splitE': "split c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   511   by (induct p) (auto simp add: split_def)
   512 
   513 lemma splitE2:
   514   "[| Q (split P z);  !!x y. [|z = (x, y); Q (P x y)|] ==> R |] ==> R"
   515 proof -
   516   assume q: "Q (split P z)"
   517   assume r: "!!x y. [|z = (x, y); Q (P x y)|] ==> R"
   518   show R
   519     apply (rule r surjective_pairing)+
   520     apply (rule split_beta [THEN subst], rule q)
   521     done
   522 qed
   523 
   524 lemma splitD': "split R (a,b) c ==> R a b c"
   525   by simp
   526 
   527 lemma mem_splitI: "z: c a b ==> z: split c (a, b)"
   528   by simp
   529 
   530 lemma mem_splitI2: "!!p. [| !!a b. p = (a, b) ==> z: c a b |] ==> z: split c p"
   531 by (simp only: split_tupled_all, simp)
   532 
   533 lemma mem_splitE:
   534   assumes major: "z: split c p"
   535     and cases: "!!x y. [| p = (x,y); z: c x y |] ==> Q"
   536   shows Q
   537   by (rule major [unfolded split_def] cases surjective_pairing)+
   538 
   539 declare mem_splitI2 [intro!] mem_splitI [intro!] splitI2' [intro!] splitI2 [intro!] splitI [intro!]
   540 declare mem_splitE [elim!] splitE' [elim!] splitE [elim!]
   541 
   542 ML {*
   543 local (* filtering with exists_p_split is an essential optimization *)
   544   fun exists_p_split (Const ("split",_) $ _ $ (Const ("Pair",_)$_$_)) = true
   545     | exists_p_split (t $ u) = exists_p_split t orelse exists_p_split u
   546     | exists_p_split (Abs (_, _, t)) = exists_p_split t
   547     | exists_p_split _ = false;
   548   val ss = HOL_basic_ss addsimps [thm "split_conv"];
   549 in
   550 val split_conv_tac = SUBGOAL (fn (t, i) =>
   551     if exists_p_split t then safe_full_simp_tac ss i else no_tac);
   552 end;
   553 *}
   554 
   555 (* This prevents applications of splitE for already splitted arguments leading
   556    to quite time-consuming computations (in particular for nested tuples) *)
   557 declaration {* fn _ =>
   558   Classical.map_cs (fn cs => cs addSbefore ("split_conv_tac", split_conv_tac))
   559 *}
   560 
   561 lemma split_eta_SetCompr [simp,noatp]: "(%u. EX x y. u = (x, y) & P (x, y)) = P"
   562   by (rule ext) fast
   563 
   564 lemma split_eta_SetCompr2 [simp,noatp]: "(%u. EX x y. u = (x, y) & P x y) = split P"
   565   by (rule ext) fast
   566 
   567 lemma split_part [simp]: "(%(a,b). P & Q a b) = (%ab. P & split Q ab)"
   568   -- {* Allows simplifications of nested splits in case of independent predicates. *}
   569   by (rule ext) blast
   570 
   571 (* Do NOT make this a simp rule as it
   572    a) only helps in special situations
   573    b) can lead to nontermination in the presence of split_def
   574 *)
   575 lemma split_comp_eq: 
   576   fixes f :: "'a => 'b => 'c" and g :: "'d => 'a"
   577   shows "(%u. f (g (fst u)) (snd u)) = (split (%x. f (g x)))"
   578   by (rule ext) auto
   579 
   580 lemma pair_imageI [intro]: "(a, b) : A ==> f a b : (%(a, b). f a b) ` A"
   581   apply (rule_tac x = "(a, b)" in image_eqI)
   582    apply auto
   583   done
   584 
   585 lemma The_split_eq [simp]: "(THE (x',y'). x = x' & y = y') = (x, y)"
   586   by blast
   587 
   588 (*
   589 the following  would be slightly more general,
   590 but cannot be used as rewrite rule:
   591 ### Cannot add premise as rewrite rule because it contains (type) unknowns:
   592 ### ?y = .x
   593 Goal "[| P y; !!x. P x ==> x = y |] ==> (@(x',y). x = x' & P y) = (x,y)"
   594 by (rtac some_equality 1)
   595 by ( Simp_tac 1)
   596 by (split_all_tac 1)
   597 by (Asm_full_simp_tac 1)
   598 qed "The_split_eq";
   599 *)
   600 
   601 text {*
   602   Setup of internal @{text split_rule}.
   603 *}
   604 
   605 definition
   606   internal_split :: "('a \<Rightarrow> 'b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c"
   607 where
   608   "internal_split == split"
   609 
   610 lemma internal_split_conv: "internal_split c (a, b) = c a b"
   611   by (simp only: internal_split_def split_conv)
   612 
   613 hide const internal_split
   614 
   615 use "Tools/split_rule.ML"
   616 setup SplitRule.setup
   617 
   618 lemmas prod_caseI = prod.cases [THEN iffD2, standard]
   619 
   620 lemma prod_caseI2: "!!p. [| !!a b. p = (a, b) ==> c a b |] ==> prod_case c p"
   621   by auto
   622 
   623 lemma prod_caseI2': "!!p. [| !!a b. (a, b) = p ==> c a b x |] ==> prod_case c p x"
   624   by (auto simp: split_tupled_all)
   625 
   626 lemma prod_caseE: "prod_case c p ==> (!!x y. p = (x, y) ==> c x y ==> Q) ==> Q"
   627   by (induct p) auto
   628 
   629 lemma prod_caseE': "prod_case c p z ==> (!!x y. p = (x, y) ==> c x y z ==> Q) ==> Q"
   630   by (induct p) auto
   631 
   632 lemma prod_case_unfold: "prod_case = (%c p. c (fst p) (snd p))"
   633   by (simp add: expand_fun_eq)
   634 
   635 declare prod_caseI2' [intro!] prod_caseI2 [intro!] prod_caseI [intro!]
   636 declare prod_caseE' [elim!] prod_caseE [elim!]
   637 
   638 lemma prod_case_split:
   639   "prod_case = split"
   640   by (auto simp add: expand_fun_eq)
   641 
   642 lemma prod_case_beta:
   643   "prod_case f p = f (fst p) (snd p)"
   644   unfolding prod_case_split split_beta ..
   645 
   646 
   647 subsection {* Further cases/induct rules for tuples *}
   648 
   649 lemma prod_cases3 [cases type]:
   650   obtains (fields) a b c where "y = (a, b, c)"
   651   by (cases y, case_tac b) blast
   652 
   653 lemma prod_induct3 [case_names fields, induct type]:
   654     "(!!a b c. P (a, b, c)) ==> P x"
   655   by (cases x) blast
   656 
   657 lemma prod_cases4 [cases type]:
   658   obtains (fields) a b c d where "y = (a, b, c, d)"
   659   by (cases y, case_tac c) blast
   660 
   661 lemma prod_induct4 [case_names fields, induct type]:
   662     "(!!a b c d. P (a, b, c, d)) ==> P x"
   663   by (cases x) blast
   664 
   665 lemma prod_cases5 [cases type]:
   666   obtains (fields) a b c d e where "y = (a, b, c, d, e)"
   667   by (cases y, case_tac d) blast
   668 
   669 lemma prod_induct5 [case_names fields, induct type]:
   670     "(!!a b c d e. P (a, b, c, d, e)) ==> P x"
   671   by (cases x) blast
   672 
   673 lemma prod_cases6 [cases type]:
   674   obtains (fields) a b c d e f where "y = (a, b, c, d, e, f)"
   675   by (cases y, case_tac e) blast
   676 
   677 lemma prod_induct6 [case_names fields, induct type]:
   678     "(!!a b c d e f. P (a, b, c, d, e, f)) ==> P x"
   679   by (cases x) blast
   680 
   681 lemma prod_cases7 [cases type]:
   682   obtains (fields) a b c d e f g where "y = (a, b, c, d, e, f, g)"
   683   by (cases y, case_tac f) blast
   684 
   685 lemma prod_induct7 [case_names fields, induct type]:
   686     "(!!a b c d e f g. P (a, b, c, d, e, f, g)) ==> P x"
   687   by (cases x) blast
   688 
   689 
   690 subsubsection {* Derived operations *}
   691 
   692 text {*
   693   The composition-uncurry combinator.
   694 *}
   695 
   696 notation fcomp (infixl "o>" 60)
   697 
   698 definition
   699   scomp :: "('a \<Rightarrow> 'b \<times> 'c) \<Rightarrow> ('b \<Rightarrow> 'c \<Rightarrow> 'd) \<Rightarrow> 'a \<Rightarrow> 'd" (infixl "o\<rightarrow>" 60)
   700 where
   701   "f o\<rightarrow> g = (\<lambda>x. split g (f x))"
   702 
   703 lemma scomp_apply:  "(f o\<rightarrow> g) x = split g (f x)"
   704   by (simp add: scomp_def)
   705 
   706 lemma Pair_scomp: "Pair x o\<rightarrow> f = f x"
   707   by (simp add: expand_fun_eq scomp_apply)
   708 
   709 lemma scomp_Pair: "x o\<rightarrow> Pair = x"
   710   by (simp add: expand_fun_eq scomp_apply)
   711 
   712 lemma scomp_scomp: "(f o\<rightarrow> g) o\<rightarrow> h = f o\<rightarrow> (\<lambda>x. g x o\<rightarrow> h)"
   713   by (simp add: expand_fun_eq split_twice scomp_def)
   714 
   715 lemma scomp_fcomp: "(f o\<rightarrow> g) o> h = f o\<rightarrow> (\<lambda>x. g x o> h)"
   716   by (simp add: expand_fun_eq scomp_apply fcomp_def split_def)
   717 
   718 lemma fcomp_scomp: "(f o> g) o\<rightarrow> h = f o> (g o\<rightarrow> h)"
   719   by (simp add: expand_fun_eq scomp_apply fcomp_apply)
   720 
   721 no_notation fcomp (infixl "o>" 60)
   722 no_notation scomp (infixl "o\<rightarrow>" 60)
   723 
   724 
   725 text {*
   726   @{term prod_fun} --- action of the product functor upon
   727   functions.
   728 *}
   729 
   730 definition prod_fun :: "('a \<Rightarrow> 'c) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'd" where
   731   [code func del]: "prod_fun f g = (\<lambda>(x, y). (f x, g y))"
   732 
   733 lemma prod_fun [simp, code func]: "prod_fun f g (a, b) = (f a, g b)"
   734   by (simp add: prod_fun_def)
   735 
   736 lemma prod_fun_compose: "prod_fun (f1 o f2) (g1 o g2) = (prod_fun f1 g1 o prod_fun f2 g2)"
   737   by (rule ext) auto
   738 
   739 lemma prod_fun_ident [simp]: "prod_fun (%x. x) (%y. y) = (%z. z)"
   740   by (rule ext) auto
   741 
   742 lemma prod_fun_imageI [intro]: "(a, b) : r ==> (f a, g b) : prod_fun f g ` r"
   743   apply (rule image_eqI)
   744   apply (rule prod_fun [symmetric], assumption)
   745   done
   746 
   747 lemma prod_fun_imageE [elim!]:
   748   assumes major: "c: (prod_fun f g)`r"
   749     and cases: "!!x y. [| c=(f(x),g(y));  (x,y):r |] ==> P"
   750   shows P
   751   apply (rule major [THEN imageE])
   752   apply (rule_tac p = x in PairE)
   753   apply (rule cases)
   754    apply (blast intro: prod_fun)
   755   apply blast
   756   done
   757 
   758 definition
   759   apfst :: "('a \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'c \<times> 'b"
   760 where
   761   [code func del]: "apfst f = prod_fun f id"
   762 
   763 definition
   764   apsnd :: "('b \<Rightarrow> 'c) \<Rightarrow> 'a \<times> 'b \<Rightarrow> 'a \<times> 'c"
   765 where
   766   [code func del]: "apsnd f = prod_fun id f"
   767 
   768 lemma apfst_conv [simp, code]:
   769   "apfst f (x, y) = (f x, y)" 
   770   by (simp add: apfst_def)
   771 
   772 lemma upd_snd_conv [simp, code]:
   773   "apsnd f (x, y) = (x, f y)" 
   774   by (simp add: apsnd_def)
   775 
   776 
   777 text {*
   778   Disjoint union of a family of sets -- Sigma.
   779 *}
   780 
   781 definition  Sigma :: "['a set, 'a => 'b set] => ('a \<times> 'b) set" where
   782   Sigma_def: "Sigma A B == UN x:A. UN y:B x. {Pair x y}"
   783 
   784 abbreviation
   785   Times :: "['a set, 'b set] => ('a * 'b) set"
   786     (infixr "<*>" 80) where
   787   "A <*> B == Sigma A (%_. B)"
   788 
   789 notation (xsymbols)
   790   Times  (infixr "\<times>" 80)
   791 
   792 notation (HTML output)
   793   Times  (infixr "\<times>" 80)
   794 
   795 syntax
   796   "@Sigma" ::"[pttrn, 'a set, 'b set] => ('a * 'b) set" ("(3SIGMA _:_./ _)" [0, 0, 10] 10)
   797 
   798 translations
   799   "SIGMA x:A. B" == "Product_Type.Sigma A (%x. B)"
   800 
   801 lemma SigmaI [intro!]: "[| a:A;  b:B(a) |] ==> (a,b) : Sigma A B"
   802   by (unfold Sigma_def) blast
   803 
   804 lemma SigmaE [elim!]:
   805     "[| c: Sigma A B;
   806         !!x y.[| x:A;  y:B(x);  c=(x,y) |] ==> P
   807      |] ==> P"
   808   -- {* The general elimination rule. *}
   809   by (unfold Sigma_def) blast
   810 
   811 text {*
   812   Elimination of @{term "(a, b) : A \<times> B"} -- introduces no
   813   eigenvariables.
   814 *}
   815 
   816 lemma SigmaD1: "(a, b) : Sigma A B ==> a : A"
   817   by blast
   818 
   819 lemma SigmaD2: "(a, b) : Sigma A B ==> b : B a"
   820   by blast
   821 
   822 lemma SigmaE2:
   823     "[| (a, b) : Sigma A B;
   824         [| a:A;  b:B(a) |] ==> P
   825      |] ==> P"
   826   by blast
   827 
   828 lemma Sigma_cong:
   829      "\<lbrakk>A = B; !!x. x \<in> B \<Longrightarrow> C x = D x\<rbrakk>
   830       \<Longrightarrow> (SIGMA x: A. C x) = (SIGMA x: B. D x)"
   831   by auto
   832 
   833 lemma Sigma_mono: "[| A <= C; !!x. x:A ==> B x <= D x |] ==> Sigma A B <= Sigma C D"
   834   by blast
   835 
   836 lemma Sigma_empty1 [simp]: "Sigma {} B = {}"
   837   by blast
   838 
   839 lemma Sigma_empty2 [simp]: "A <*> {} = {}"
   840   by blast
   841 
   842 lemma UNIV_Times_UNIV [simp]: "UNIV <*> UNIV = UNIV"
   843   by auto
   844 
   845 lemma Compl_Times_UNIV1 [simp]: "- (UNIV <*> A) = UNIV <*> (-A)"
   846   by auto
   847 
   848 lemma Compl_Times_UNIV2 [simp]: "- (A <*> UNIV) = (-A) <*> UNIV"
   849   by auto
   850 
   851 lemma mem_Sigma_iff [iff]: "((a,b): Sigma A B) = (a:A & b:B(a))"
   852   by blast
   853 
   854 lemma Times_subset_cancel2: "x:C ==> (A <*> C <= B <*> C) = (A <= B)"
   855   by blast
   856 
   857 lemma Times_eq_cancel2: "x:C ==> (A <*> C = B <*> C) = (A = B)"
   858   by (blast elim: equalityE)
   859 
   860 lemma SetCompr_Sigma_eq:
   861     "Collect (split (%x y. P x & Q x y)) = (SIGMA x:Collect P. Collect (Q x))"
   862   by blast
   863 
   864 lemma Collect_split [simp]: "{(a,b). P a & Q b} = Collect P <*> Collect Q"
   865   by blast
   866 
   867 lemma UN_Times_distrib:
   868   "(UN (a,b):(A <*> B). E a <*> F b) = (UNION A E) <*> (UNION B F)"
   869   -- {* Suggested by Pierre Chartier *}
   870   by blast
   871 
   872 lemma split_paired_Ball_Sigma [simp,noatp]:
   873     "(ALL z: Sigma A B. P z) = (ALL x:A. ALL y: B x. P(x,y))"
   874   by blast
   875 
   876 lemma split_paired_Bex_Sigma [simp,noatp]:
   877     "(EX z: Sigma A B. P z) = (EX x:A. EX y: B x. P(x,y))"
   878   by blast
   879 
   880 lemma Sigma_Un_distrib1: "(SIGMA i:I Un J. C(i)) = (SIGMA i:I. C(i)) Un (SIGMA j:J. C(j))"
   881   by blast
   882 
   883 lemma Sigma_Un_distrib2: "(SIGMA i:I. A(i) Un B(i)) = (SIGMA i:I. A(i)) Un (SIGMA i:I. B(i))"
   884   by blast
   885 
   886 lemma Sigma_Int_distrib1: "(SIGMA i:I Int J. C(i)) = (SIGMA i:I. C(i)) Int (SIGMA j:J. C(j))"
   887   by blast
   888 
   889 lemma Sigma_Int_distrib2: "(SIGMA i:I. A(i) Int B(i)) = (SIGMA i:I. A(i)) Int (SIGMA i:I. B(i))"
   890   by blast
   891 
   892 lemma Sigma_Diff_distrib1: "(SIGMA i:I - J. C(i)) = (SIGMA i:I. C(i)) - (SIGMA j:J. C(j))"
   893   by blast
   894 
   895 lemma Sigma_Diff_distrib2: "(SIGMA i:I. A(i) - B(i)) = (SIGMA i:I. A(i)) - (SIGMA i:I. B(i))"
   896   by blast
   897 
   898 lemma Sigma_Union: "Sigma (Union X) B = (UN A:X. Sigma A B)"
   899   by blast
   900 
   901 text {*
   902   Non-dependent versions are needed to avoid the need for higher-order
   903   matching, especially when the rules are re-oriented.
   904 *}
   905 
   906 lemma Times_Un_distrib1: "(A Un B) <*> C = (A <*> C) Un (B <*> C)"
   907   by blast
   908 
   909 lemma Times_Int_distrib1: "(A Int B) <*> C = (A <*> C) Int (B <*> C)"
   910   by blast
   911 
   912 lemma Times_Diff_distrib1: "(A - B) <*> C = (A <*> C) - (B <*> C)"
   913   by blast
   914 
   915 
   916 subsubsection {* Code generator setup *}
   917 
   918 instance * :: (eq, eq) eq ..
   919 
   920 lemma [code func]:
   921   "eq_class.eq (x1\<Colon>'a\<Colon>eq, y1\<Colon>'b\<Colon>eq) (x2, y2) \<longleftrightarrow> x1 = x2 \<and> y1 = y2" by (simp add: eq)
   922 
   923 lemma split_case_cert:
   924   assumes "CASE \<equiv> split f"
   925   shows "CASE (a, b) \<equiv> f a b"
   926   using assms by simp
   927 
   928 setup {*
   929   Code.add_case @{thm split_case_cert}
   930 *}
   931 
   932 code_type *
   933   (SML infix 2 "*")
   934   (OCaml infix 2 "*")
   935   (Haskell "!((_),/ (_))")
   936 
   937 code_instance * :: eq
   938   (Haskell -)
   939 
   940 code_const "eq_class.eq \<Colon> 'a\<Colon>eq \<times> 'b\<Colon>eq \<Rightarrow> 'a \<times> 'b \<Rightarrow> bool"
   941   (Haskell infixl 4 "==")
   942 
   943 code_const Pair
   944   (SML "!((_),/ (_))")
   945   (OCaml "!((_),/ (_))")
   946   (Haskell "!((_),/ (_))")
   947 
   948 code_const fst and snd
   949   (Haskell "fst" and "snd")
   950 
   951 types_code
   952   "*"     ("(_ */ _)")
   953 attach (term_of) {*
   954 fun term_of_id_42 aF aT bF bT (x, y) = HOLogic.pair_const aT bT $ aF x $ bF y;
   955 *}
   956 attach (test) {*
   957 fun gen_id_42 aG aT bG bT i =
   958   let
   959     val (x, t) = aG i;
   960     val (y, u) = bG i
   961   in ((x, y), fn () => HOLogic.pair_const aT bT $ t () $ u ()) end;
   962 *}
   963 
   964 consts_code
   965   "Pair"    ("(_,/ _)")
   966 
   967 setup {*
   968 
   969 let
   970 
   971 fun strip_abs_split 0 t = ([], t)
   972   | strip_abs_split i (Abs (s, T, t)) =
   973       let
   974         val s' = Codegen.new_name t s;
   975         val v = Free (s', T)
   976       in apfst (cons v) (strip_abs_split (i-1) (subst_bound (v, t))) end
   977   | strip_abs_split i (u as Const ("split", _) $ t) = (case strip_abs_split (i+1) t of
   978         (v :: v' :: vs, u) => (HOLogic.mk_prod (v, v') :: vs, u)
   979       | _ => ([], u))
   980   | strip_abs_split i t = ([], t);
   981 
   982 fun let_codegen thy defs gr dep thyname brack t = (case strip_comb t of
   983     (t1 as Const ("Let", _), t2 :: t3 :: ts) =>
   984     let
   985       fun dest_let (l as Const ("Let", _) $ t $ u) =
   986           (case strip_abs_split 1 u of
   987              ([p], u') => apfst (cons (p, t)) (dest_let u')
   988            | _ => ([], l))
   989         | dest_let t = ([], t);
   990       fun mk_code (gr, (l, r)) =
   991         let
   992           val (gr1, pl) = Codegen.invoke_codegen thy defs dep thyname false (gr, l);
   993           val (gr2, pr) = Codegen.invoke_codegen thy defs dep thyname false (gr1, r);
   994         in (gr2, (pl, pr)) end
   995     in case dest_let (t1 $ t2 $ t3) of
   996         ([], _) => NONE
   997       | (ps, u) =>
   998           let
   999             val (gr1, qs) = foldl_map mk_code (gr, ps);
  1000             val (gr2, pu) = Codegen.invoke_codegen thy defs dep thyname false (gr1, u);
  1001             val (gr3, pargs) = foldl_map
  1002               (Codegen.invoke_codegen thy defs dep thyname true) (gr2, ts)
  1003           in
  1004             SOME (gr3, Codegen.mk_app brack
  1005               (Pretty.blk (0, [Codegen.str "let ", Pretty.blk (0, List.concat
  1006                   (separate [Codegen.str ";", Pretty.brk 1] (map (fn (pl, pr) =>
  1007                     [Pretty.block [Codegen.str "val ", pl, Codegen.str " =",
  1008                        Pretty.brk 1, pr]]) qs))),
  1009                 Pretty.brk 1, Codegen.str "in ", pu,
  1010                 Pretty.brk 1, Codegen.str "end"])) pargs)
  1011           end
  1012     end
  1013   | _ => NONE);
  1014 
  1015 fun split_codegen thy defs gr dep thyname brack t = (case strip_comb t of
  1016     (t1 as Const ("split", _), t2 :: ts) =>
  1017       (case strip_abs_split 1 (t1 $ t2) of
  1018          ([p], u) =>
  1019            let
  1020              val (gr1, q) = Codegen.invoke_codegen thy defs dep thyname false (gr, p);
  1021              val (gr2, pu) = Codegen.invoke_codegen thy defs dep thyname false (gr1, u);
  1022              val (gr3, pargs) = foldl_map
  1023                (Codegen.invoke_codegen thy defs dep thyname true) (gr2, ts)
  1024            in
  1025              SOME (gr2, Codegen.mk_app brack
  1026                (Pretty.block [Codegen.str "(fn ", q, Codegen.str " =>",
  1027                  Pretty.brk 1, pu, Codegen.str ")"]) pargs)
  1028            end
  1029        | _ => NONE)
  1030   | _ => NONE);
  1031 
  1032 in
  1033 
  1034   Codegen.add_codegen "let_codegen" let_codegen
  1035   #> Codegen.add_codegen "split_codegen" split_codegen
  1036 
  1037 end
  1038 *}
  1039 
  1040 
  1041 subsection {* Legacy bindings *}
  1042 
  1043 ML {*
  1044 val Collect_split = thm "Collect_split";
  1045 val Compl_Times_UNIV1 = thm "Compl_Times_UNIV1";
  1046 val Compl_Times_UNIV2 = thm "Compl_Times_UNIV2";
  1047 val PairE = thm "PairE";
  1048 val Pair_Rep_inject = thm "Pair_Rep_inject";
  1049 val Pair_def = thm "Pair_def";
  1050 val Pair_eq = @{thm "prod.inject"};
  1051 val Pair_fst_snd_eq = thm "Pair_fst_snd_eq";
  1052 val ProdI = thm "ProdI";
  1053 val SetCompr_Sigma_eq = thm "SetCompr_Sigma_eq";
  1054 val SigmaD1 = thm "SigmaD1";
  1055 val SigmaD2 = thm "SigmaD2";
  1056 val SigmaE = thm "SigmaE";
  1057 val SigmaE2 = thm "SigmaE2";
  1058 val SigmaI = thm "SigmaI";
  1059 val Sigma_Diff_distrib1 = thm "Sigma_Diff_distrib1";
  1060 val Sigma_Diff_distrib2 = thm "Sigma_Diff_distrib2";
  1061 val Sigma_Int_distrib1 = thm "Sigma_Int_distrib1";
  1062 val Sigma_Int_distrib2 = thm "Sigma_Int_distrib2";
  1063 val Sigma_Un_distrib1 = thm "Sigma_Un_distrib1";
  1064 val Sigma_Un_distrib2 = thm "Sigma_Un_distrib2";
  1065 val Sigma_Union = thm "Sigma_Union";
  1066 val Sigma_def = thm "Sigma_def";
  1067 val Sigma_empty1 = thm "Sigma_empty1";
  1068 val Sigma_empty2 = thm "Sigma_empty2";
  1069 val Sigma_mono = thm "Sigma_mono";
  1070 val The_split = thm "The_split";
  1071 val The_split_eq = thm "The_split_eq";
  1072 val The_split_eq = thm "The_split_eq";
  1073 val Times_Diff_distrib1 = thm "Times_Diff_distrib1";
  1074 val Times_Int_distrib1 = thm "Times_Int_distrib1";
  1075 val Times_Un_distrib1 = thm "Times_Un_distrib1";
  1076 val Times_eq_cancel2 = thm "Times_eq_cancel2";
  1077 val Times_subset_cancel2 = thm "Times_subset_cancel2";
  1078 val UNIV_Times_UNIV = thm "UNIV_Times_UNIV";
  1079 val UN_Times_distrib = thm "UN_Times_distrib";
  1080 val Unity_def = thm "Unity_def";
  1081 val cond_split_eta = thm "cond_split_eta";
  1082 val fst_conv = thm "fst_conv";
  1083 val fst_def = thm "fst_def";
  1084 val fst_eqD = thm "fst_eqD";
  1085 val inj_on_Abs_Prod = thm "inj_on_Abs_Prod";
  1086 val mem_Sigma_iff = thm "mem_Sigma_iff";
  1087 val mem_splitE = thm "mem_splitE";
  1088 val mem_splitI = thm "mem_splitI";
  1089 val mem_splitI2 = thm "mem_splitI2";
  1090 val prod_eqI = thm "prod_eqI";
  1091 val prod_fun = thm "prod_fun";
  1092 val prod_fun_compose = thm "prod_fun_compose";
  1093 val prod_fun_def = thm "prod_fun_def";
  1094 val prod_fun_ident = thm "prod_fun_ident";
  1095 val prod_fun_imageE = thm "prod_fun_imageE";
  1096 val prod_fun_imageI = thm "prod_fun_imageI";
  1097 val prod_induct = thm "prod.induct";
  1098 val snd_conv = thm "snd_conv";
  1099 val snd_def = thm "snd_def";
  1100 val snd_eqD = thm "snd_eqD";
  1101 val split = thm "split";
  1102 val splitD = thm "splitD";
  1103 val splitD' = thm "splitD'";
  1104 val splitE = thm "splitE";
  1105 val splitE' = thm "splitE'";
  1106 val splitE2 = thm "splitE2";
  1107 val splitI = thm "splitI";
  1108 val splitI2 = thm "splitI2";
  1109 val splitI2' = thm "splitI2'";
  1110 val split_beta = thm "split_beta";
  1111 val split_conv = thm "split_conv";
  1112 val split_def = thm "split_def";
  1113 val split_eta = thm "split_eta";
  1114 val split_eta_SetCompr = thm "split_eta_SetCompr";
  1115 val split_eta_SetCompr2 = thm "split_eta_SetCompr2";
  1116 val split_paired_All = thm "split_paired_All";
  1117 val split_paired_Ball_Sigma = thm "split_paired_Ball_Sigma";
  1118 val split_paired_Bex_Sigma = thm "split_paired_Bex_Sigma";
  1119 val split_paired_Ex = thm "split_paired_Ex";
  1120 val split_paired_The = thm "split_paired_The";
  1121 val split_paired_all = thm "split_paired_all";
  1122 val split_part = thm "split_part";
  1123 val split_split = thm "split_split";
  1124 val split_split_asm = thm "split_split_asm";
  1125 val split_tupled_all = thms "split_tupled_all";
  1126 val split_weak_cong = thm "split_weak_cong";
  1127 val surj_pair = thm "surj_pair";
  1128 val surjective_pairing = thm "surjective_pairing";
  1129 val unit_abs_eta_conv = thm "unit_abs_eta_conv";
  1130 val unit_all_eq1 = thm "unit_all_eq1";
  1131 val unit_all_eq2 = thm "unit_all_eq2";
  1132 val unit_eq = thm "unit_eq";
  1133 *}
  1134 
  1135 
  1136 subsection {* Further inductive packages *}
  1137 
  1138 use "Tools/inductive_realizer.ML"
  1139 setup InductiveRealizer.setup
  1140 
  1141 use "Tools/inductive_set_package.ML"
  1142 setup InductiveSetPackage.setup
  1143 
  1144 use "Tools/datatype_realizer.ML"
  1145 setup DatatypeRealizer.setup
  1146 
  1147 end