src/Pure/Isar/proof_context.ML
author wenzelm
Mon Mar 01 17:07:36 2010 +0100 (2010-03-01)
changeset 35412 b8dead547d9e
parent 35399 3881972fcfca
child 35429 afa8cf9e63d8
permissions -rw-r--r--
more uniform treatment of syntax for types vs. consts;
     1 (*  Title:      Pure/Isar/proof_context.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 The key concept of Isar proof contexts: elevates primitive local
     5 reasoning Gamma |- phi to a structured concept, with generic context
     6 elements.  See also structure Variable and Assumption.
     7 *)
     8 
     9 signature PROOF_CONTEXT =
    10 sig
    11   val theory_of: Proof.context -> theory
    12   val init: theory -> Proof.context
    13   type mode
    14   val mode_default: mode
    15   val mode_stmt: mode
    16   val mode_pattern: mode
    17   val mode_schematic: mode
    18   val mode_abbrev: mode
    19   val set_mode: mode -> Proof.context -> Proof.context
    20   val get_mode: Proof.context -> mode
    21   val restore_mode: Proof.context -> Proof.context -> Proof.context
    22   val abbrev_mode: Proof.context -> bool
    23   val set_stmt: bool -> Proof.context -> Proof.context
    24   val local_naming: Name_Space.naming
    25   val map_naming: (Name_Space.naming -> Name_Space.naming) -> Proof.context -> Proof.context
    26   val naming_of: Proof.context -> Name_Space.naming
    27   val restore_naming: Proof.context -> Proof.context -> Proof.context
    28   val full_name: Proof.context -> binding -> string
    29   val syn_of: Proof.context -> Syntax.syntax
    30   val consts_of: Proof.context -> Consts.T
    31   val the_const_constraint: Proof.context -> string -> typ
    32   val set_syntax_mode: Syntax.mode -> Proof.context -> Proof.context
    33   val restore_syntax_mode: Proof.context -> Proof.context -> Proof.context
    34   val facts_of: Proof.context -> Facts.T
    35   val cases_of: Proof.context -> (string * (Rule_Cases.T * bool)) list
    36   val transfer_syntax: theory -> Proof.context -> Proof.context
    37   val transfer: theory -> Proof.context -> Proof.context
    38   val theory: (theory -> theory) -> Proof.context -> Proof.context
    39   val theory_result: (theory -> 'a * theory) -> Proof.context -> 'a * Proof.context
    40   val extern_fact: Proof.context -> string -> xstring
    41   val pretty_term_abbrev: Proof.context -> term -> Pretty.T
    42   val pretty_fact_aux: Proof.context -> bool -> string * thm list -> Pretty.T
    43   val pretty_fact: Proof.context -> string * thm list -> Pretty.T
    44   val read_typ: Proof.context -> string -> typ
    45   val read_typ_syntax: Proof.context -> string -> typ
    46   val read_typ_abbrev: Proof.context -> string -> typ
    47   val cert_typ: Proof.context -> typ -> typ
    48   val cert_typ_syntax: Proof.context -> typ -> typ
    49   val cert_typ_abbrev: Proof.context -> typ -> typ
    50   val get_skolem: Proof.context -> string -> string
    51   val revert_skolem: Proof.context -> string -> string
    52   val infer_type: Proof.context -> string -> typ
    53   val inferred_param: string -> Proof.context -> typ * Proof.context
    54   val inferred_fixes: Proof.context -> (string * typ) list * Proof.context
    55   val read_type_name: Proof.context -> bool -> string -> typ
    56   val read_const_proper: Proof.context -> bool -> string -> term
    57   val read_const: Proof.context -> bool -> string -> term
    58   val allow_dummies: Proof.context -> Proof.context
    59   val decode_term: Proof.context -> term -> term
    60   val standard_infer_types: Proof.context -> term list -> term list
    61   val read_term_pattern: Proof.context -> string -> term
    62   val read_term_schematic: Proof.context -> string -> term
    63   val read_term_abbrev: Proof.context -> string -> term
    64   val expand_abbrevs: Proof.context -> term -> term
    65   val cert_term: Proof.context -> term -> term
    66   val cert_prop: Proof.context -> term -> term
    67   val goal_export: Proof.context -> Proof.context -> thm list -> thm list
    68   val export: Proof.context -> Proof.context -> thm list -> thm list
    69   val export_morphism: Proof.context -> Proof.context -> morphism
    70   val norm_export_morphism: Proof.context -> Proof.context -> morphism
    71   val bind_terms: (indexname * term option) list -> Proof.context -> Proof.context
    72   val auto_bind_goal: term list -> Proof.context -> Proof.context
    73   val auto_bind_facts: term list -> Proof.context -> Proof.context
    74   val match_bind: bool -> (string list * string) list -> Proof.context -> term list * Proof.context
    75   val match_bind_i: bool -> (term list * term) list -> Proof.context -> term list * Proof.context
    76   val read_propp: Proof.context * (string * string list) list list
    77     -> Proof.context * (term * term list) list list
    78   val cert_propp: Proof.context * (term * term list) list list
    79     -> Proof.context * (term * term list) list list
    80   val read_propp_schematic: Proof.context * (string * string list) list list
    81     -> Proof.context * (term * term list) list list
    82   val cert_propp_schematic: Proof.context * (term * term list) list list
    83     -> Proof.context * (term * term list) list list
    84   val bind_propp: Proof.context * (string * string list) list list
    85     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    86   val bind_propp_i: Proof.context * (term * term list) list list
    87     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    88   val bind_propp_schematic: Proof.context * (string * string list) list list
    89     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    90   val bind_propp_schematic_i: Proof.context * (term * term list) list list
    91     -> Proof.context * (term list list * (Proof.context -> Proof.context))
    92   val fact_tac: thm list -> int -> tactic
    93   val some_fact_tac: Proof.context -> int -> tactic
    94   val get_fact: Proof.context -> Facts.ref -> thm list
    95   val get_fact_single: Proof.context -> Facts.ref -> thm
    96   val get_thms: Proof.context -> xstring -> thm list
    97   val get_thm: Proof.context -> xstring -> thm
    98   val note_thmss: string -> (Thm.binding * (thm list * attribute list) list) list ->
    99     Proof.context -> (string * thm list) list * Proof.context
   100   val put_thms: bool -> string * thm list option -> Proof.context -> Proof.context
   101   val read_vars: (binding * string option * mixfix) list -> Proof.context ->
   102     (binding * typ option * mixfix) list * Proof.context
   103   val cert_vars: (binding * typ option * mixfix) list -> Proof.context ->
   104     (binding * typ option * mixfix) list * Proof.context
   105   val add_fixes: (binding * typ option * mixfix) list -> Proof.context ->
   106     string list * Proof.context
   107   val auto_fixes: Proof.context * (term list list * 'a) -> Proof.context * (term list list * 'a)
   108   val bind_fixes: string list -> Proof.context -> (term -> term) * Proof.context
   109   val add_assms: Assumption.export ->
   110     (Thm.binding * (string * string list) list) list ->
   111     Proof.context -> (string * thm list) list * Proof.context
   112   val add_assms_i: Assumption.export ->
   113     (Thm.binding * (term * term list) list) list ->
   114     Proof.context -> (string * thm list) list * Proof.context
   115   val add_cases: bool -> (string * Rule_Cases.T option) list -> Proof.context -> Proof.context
   116   val apply_case: Rule_Cases.T -> Proof.context -> (string * term list) list * Proof.context
   117   val get_case: Proof.context -> string -> string option list -> Rule_Cases.T
   118   val type_notation: bool -> Syntax.mode -> (typ * mixfix) list -> Proof.context -> Proof.context
   119   val notation: bool -> Syntax.mode -> (term * mixfix) list -> Proof.context -> Proof.context
   120   val target_type_notation: bool -> Syntax.mode -> (typ * mixfix) list -> morphism ->
   121     Context.generic -> Context.generic
   122   val target_notation: bool -> Syntax.mode -> (term * mixfix) list -> morphism ->
   123     Context.generic -> Context.generic
   124   val add_const_constraint: string * typ option -> Proof.context -> Proof.context
   125   val add_abbrev: string -> binding * term -> Proof.context -> (term * term) * Proof.context
   126   val revert_abbrev: string -> string -> Proof.context -> Proof.context
   127   val print_syntax: Proof.context -> unit
   128   val print_abbrevs: Proof.context -> unit
   129   val print_binds: Proof.context -> unit
   130   val print_lthms: Proof.context -> unit
   131   val print_cases: Proof.context -> unit
   132   val debug: bool Unsynchronized.ref
   133   val verbose: bool Unsynchronized.ref
   134   val prems_limit: int Unsynchronized.ref
   135   val pretty_ctxt: Proof.context -> Pretty.T list
   136   val pretty_context: Proof.context -> Pretty.T list
   137 end;
   138 
   139 structure ProofContext: PROOF_CONTEXT =
   140 struct
   141 
   142 open ProofContext;
   143 
   144 
   145 (** inner syntax mode **)
   146 
   147 datatype mode =
   148   Mode of
   149    {stmt: bool,                (*inner statement mode*)
   150     pattern: bool,             (*pattern binding schematic variables*)
   151     schematic: bool,           (*term referencing loose schematic variables*)
   152     abbrev: bool};             (*abbrev mode -- no normalization*)
   153 
   154 fun make_mode (stmt, pattern, schematic, abbrev) =
   155   Mode {stmt = stmt, pattern = pattern, schematic = schematic, abbrev = abbrev};
   156 
   157 val mode_default   = make_mode (false, false, false, false);
   158 val mode_stmt      = make_mode (true, false, false, false);
   159 val mode_pattern   = make_mode (false, true, false, false);
   160 val mode_schematic = make_mode (false, false, true, false);
   161 val mode_abbrev    = make_mode (false, false, false, true);
   162 
   163 
   164 
   165 (** Isar proof context information **)
   166 
   167 datatype ctxt =
   168   Ctxt of
   169    {mode: mode,                                       (*inner syntax mode*)
   170     naming: Name_Space.naming,                        (*local naming conventions*)
   171     syntax: Local_Syntax.T,                           (*local syntax*)
   172     consts: Consts.T * Consts.T,                      (*local/global consts*)
   173     facts: Facts.T,                                   (*local facts*)
   174     cases: (string * (Rule_Cases.T * bool)) list};    (*named case contexts*)
   175 
   176 fun make_ctxt (mode, naming, syntax, consts, facts, cases) =
   177   Ctxt {mode = mode, naming = naming, syntax = syntax,
   178     consts = consts, facts = facts, cases = cases};
   179 
   180 val local_naming = Name_Space.default_naming |> Name_Space.add_path "local";
   181 
   182 structure ContextData = Proof_Data
   183 (
   184   type T = ctxt;
   185   fun init thy =
   186     make_ctxt (mode_default, local_naming, Local_Syntax.init thy,
   187       (Sign.consts_of thy, Sign.consts_of thy), Facts.empty, []);
   188 );
   189 
   190 fun rep_context ctxt = ContextData.get ctxt |> (fn Ctxt args => args);
   191 
   192 fun map_context f =
   193   ContextData.map (fn Ctxt {mode, naming, syntax, consts, facts, cases} =>
   194     make_ctxt (f (mode, naming, syntax, consts, facts, cases)));
   195 
   196 fun set_mode mode = map_context (fn (_, naming, syntax, consts, facts, cases) =>
   197   (mode, naming, syntax, consts, facts, cases));
   198 
   199 fun map_mode f =
   200   map_context (fn (Mode {stmt, pattern, schematic, abbrev}, naming, syntax, consts, facts, cases) =>
   201     (make_mode (f (stmt, pattern, schematic, abbrev)), naming, syntax, consts, facts, cases));
   202 
   203 fun map_naming f =
   204   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   205     (mode, f naming, syntax, consts, facts, cases));
   206 
   207 fun map_syntax f =
   208   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   209     (mode, naming, f syntax, consts, facts, cases));
   210 
   211 fun map_consts f =
   212   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   213     (mode, naming, syntax, f consts, facts, cases));
   214 
   215 fun map_facts f =
   216   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   217     (mode, naming, syntax, consts, f facts, cases));
   218 
   219 fun map_cases f =
   220   map_context (fn (mode, naming, syntax, consts, facts, cases) =>
   221     (mode, naming, syntax, consts, facts, f cases));
   222 
   223 val get_mode = #mode o rep_context;
   224 val restore_mode = set_mode o get_mode;
   225 val abbrev_mode = get_mode #> (fn Mode {abbrev, ...} => abbrev);
   226 
   227 fun set_stmt stmt =
   228   map_mode (fn (_, pattern, schematic, abbrev) => (stmt, pattern, schematic, abbrev));
   229 
   230 val naming_of = #naming o rep_context;
   231 val restore_naming = map_naming o K o naming_of
   232 val full_name = Name_Space.full_name o naming_of;
   233 
   234 val syntax_of = #syntax o rep_context;
   235 val syn_of = Local_Syntax.syn_of o syntax_of;
   236 val set_syntax_mode = map_syntax o Local_Syntax.set_mode;
   237 val restore_syntax_mode = map_syntax o Local_Syntax.restore_mode o syntax_of;
   238 
   239 val consts_of = #1 o #consts o rep_context;
   240 val the_const_constraint = Consts.the_constraint o consts_of;
   241 
   242 val facts_of = #facts o rep_context;
   243 val cases_of = #cases o rep_context;
   244 
   245 
   246 (* theory transfer *)
   247 
   248 fun transfer_syntax thy =
   249   map_syntax (Local_Syntax.rebuild thy) #>
   250   map_consts (fn consts as (local_consts, global_consts) =>
   251     let val thy_consts = Sign.consts_of thy in
   252       if Consts.eq_consts (thy_consts, global_consts) then consts
   253       else (Consts.merge (local_consts, thy_consts), thy_consts)
   254     end);
   255 
   256 fun transfer thy = Context.raw_transfer thy #> transfer_syntax thy;
   257 
   258 fun theory f ctxt = transfer (f (theory_of ctxt)) ctxt;
   259 
   260 fun theory_result f ctxt =
   261   let val (res, thy') = f (theory_of ctxt)
   262   in (res, ctxt |> transfer thy') end;
   263 
   264 
   265 
   266 (** pretty printing **)
   267 
   268 (* extern *)
   269 
   270 fun extern_fact ctxt name =
   271   let
   272     val local_facts = facts_of ctxt;
   273     val global_facts = PureThy.facts_of (theory_of ctxt);
   274   in
   275     if is_some (Facts.lookup (Context.Proof ctxt) local_facts name)
   276     then Facts.extern local_facts name
   277     else Facts.extern global_facts name
   278   end;
   279 
   280 
   281 (* pretty *)
   282 
   283 fun pretty_term_abbrev ctxt = Syntax.pretty_term (set_mode mode_abbrev ctxt);
   284 
   285 fun pretty_fact_name ctxt a = Pretty.block
   286   [Pretty.markup (Markup.fact a) [Pretty.str (extern_fact ctxt a)], Pretty.str ":"];
   287 
   288 fun pretty_fact_aux ctxt flag ("", ths) =
   289       Display.pretty_thms_aux ctxt flag ths
   290   | pretty_fact_aux ctxt flag (a, [th]) = Pretty.block
   291       [pretty_fact_name ctxt a, Pretty.brk 1, Display.pretty_thm_aux ctxt flag th]
   292   | pretty_fact_aux ctxt flag (a, ths) = Pretty.block
   293       (Pretty.fbreaks (pretty_fact_name ctxt a :: map (Display.pretty_thm_aux ctxt flag) ths));
   294 
   295 fun pretty_fact ctxt = pretty_fact_aux ctxt true;
   296 
   297 
   298 
   299 (** prepare types **)
   300 
   301 (* read_typ *)
   302 
   303 fun read_typ_mode mode ctxt s =
   304   Syntax.read_typ (Type.set_mode mode ctxt) s;
   305 
   306 val read_typ        = read_typ_mode Type.mode_default;
   307 val read_typ_syntax = read_typ_mode Type.mode_syntax;
   308 val read_typ_abbrev = read_typ_mode Type.mode_abbrev;
   309 
   310 
   311 (* cert_typ *)
   312 
   313 fun cert_typ_mode mode ctxt T =
   314   Sign.certify_typ_mode mode (theory_of ctxt) T
   315     handle TYPE (msg, _, _) => error msg;
   316 
   317 val cert_typ        = cert_typ_mode Type.mode_default;
   318 val cert_typ_syntax = cert_typ_mode Type.mode_syntax;
   319 val cert_typ_abbrev = cert_typ_mode Type.mode_abbrev;
   320 
   321 
   322 
   323 (** prepare variables **)
   324 
   325 (* internalize Skolem constants *)
   326 
   327 val lookup_skolem = AList.lookup (op =) o Variable.fixes_of;
   328 fun get_skolem ctxt x = the_default x (lookup_skolem ctxt x);
   329 
   330 fun no_skolem internal x =
   331   if can Name.dest_skolem x then
   332     error ("Illegal reference to internal Skolem constant: " ^ quote x)
   333   else if not internal andalso can Name.dest_internal x then
   334     error ("Illegal reference to internal variable: " ^ quote x)
   335   else x;
   336 
   337 
   338 (* revert Skolem constants -- if possible *)
   339 
   340 fun revert_skolem ctxt x =
   341   (case find_first (fn (_, y) => y = x) (Variable.fixes_of ctxt) of
   342     SOME (x', _) => if lookup_skolem ctxt x' = SOME x then x' else x
   343   | NONE => x);
   344 
   345 
   346 (* default token translations *)
   347 
   348 local
   349 
   350 fun free_or_skolem ctxt x =
   351   (if can Name.dest_skolem x then Pretty.mark Markup.skolem (Pretty.str (revert_skolem ctxt x))
   352    else Pretty.mark Markup.free (Pretty.str x))
   353   |> Pretty.mark
   354     (if Variable.is_fixed ctxt x orelse Syntax.is_pretty_global ctxt then Markup.fixed x
   355      else Markup.hilite);
   356 
   357 fun var_or_skolem _ s =
   358   (case Lexicon.read_variable s of
   359     SOME (x, i) =>
   360       (case try Name.dest_skolem x of
   361         NONE => Pretty.mark Markup.var (Pretty.str s)
   362       | SOME x' => Pretty.mark Markup.skolem
   363           (Pretty.str (setmp_CRITICAL show_question_marks true Term.string_of_vname (x', i))))
   364   | NONE => Pretty.mark Markup.var (Pretty.str s));
   365 
   366 fun class_markup _ c =    (* FIXME authentic syntax *)
   367   Pretty.mark (Markup.tclassN, []) (Pretty.str c);
   368 
   369 fun plain_markup m _ s = Pretty.mark m (Pretty.str s);
   370 
   371 val token_trans =
   372  Syntax.tokentrans_mode ""
   373   [("class", class_markup),
   374    ("tfree", plain_markup Markup.tfree),
   375    ("tvar", plain_markup Markup.tvar),
   376    ("free", free_or_skolem),
   377    ("bound", plain_markup Markup.bound),
   378    ("var", var_or_skolem),
   379    ("numeral", plain_markup Markup.numeral),
   380    ("inner_string", plain_markup Markup.inner_string)];
   381 
   382 in val _ = Context.>> (Context.map_theory (Sign.add_tokentrfuns token_trans)) end;
   383 
   384 
   385 
   386 (** prepare terms and propositions **)
   387 
   388 (* inferred types of parameters *)
   389 
   390 fun infer_type ctxt x =
   391   Term.fastype_of (singleton (Syntax.check_terms (set_mode mode_schematic ctxt))
   392     (Free (x, dummyT)));
   393 
   394 fun inferred_param x ctxt =
   395   let val T = infer_type ctxt x
   396   in (T, ctxt |> Variable.declare_term (Free (x, T))) end;
   397 
   398 fun inferred_fixes ctxt =
   399   let
   400     val xs = rev (map #2 (Variable.fixes_of ctxt));
   401     val (Ts, ctxt') = fold_map inferred_param xs ctxt;
   402   in (xs ~~ Ts, ctxt') end;
   403 
   404 
   405 (* type and constant names *)
   406 
   407 local
   408 
   409 val token_content = Syntax.read_token #>> Symbol_Pos.content;
   410 
   411 fun prep_const_proper ctxt strict (c, pos) =
   412   let
   413     fun err msg = error (msg ^ Position.str_of pos);
   414     val consts = consts_of ctxt;
   415     val t as Const (d, _) =
   416       (case Variable.lookup_const ctxt c of
   417         SOME d =>
   418           Const (d, Consts.type_scheme (consts_of ctxt) d handle TYPE (msg, _, _) => err msg)
   419       | NONE => Consts.read_const consts c);
   420     val _ =
   421       if strict then ignore (Consts.the_type consts d) handle TYPE (msg, _, _) => err msg
   422       else ();
   423     val _ = Position.report (Markup.const d) pos;
   424   in t end;
   425 
   426 in
   427 
   428 fun read_type_name ctxt strict text =
   429   let
   430     val thy = theory_of ctxt;
   431     val (c, pos) = token_content text;
   432   in
   433     if Syntax.is_tid c then
   434      (Position.report Markup.tfree pos;
   435       TFree (c, the_default (Sign.defaultS thy) (Variable.def_sort ctxt (c, ~1))))
   436     else
   437       let
   438         val d = Sign.intern_type thy c;
   439         val decl = Sign.the_type_decl thy d;
   440         val _ = Position.report (Markup.tycon d) pos;
   441         fun err () = error ("Bad type name: " ^ quote d);
   442         val args =
   443           (case decl of
   444             Type.LogicalType n => n
   445           | Type.Abbreviation (vs, _, _) => if strict then err () else length vs
   446           | Type.Nonterminal => if strict then err () else 0);
   447       in Type (d, replicate args dummyT) end
   448   end;
   449 
   450 fun read_const_proper ctxt strict = prep_const_proper ctxt strict o token_content;
   451 
   452 fun read_const ctxt strict text =
   453   let val (c, pos) = token_content text in
   454     (case (lookup_skolem ctxt c, Variable.is_const ctxt c) of
   455       (SOME x, false) =>
   456         (Position.report (Markup.name x
   457             (if can Name.dest_skolem x then Markup.skolem else Markup.free)) pos;
   458           Free (x, infer_type ctxt x))
   459     | _ => prep_const_proper ctxt strict (c, pos))
   460   end;
   461 
   462 end;
   463 
   464 
   465 (* read_term *)
   466 
   467 fun read_term_mode mode ctxt = Syntax.read_term (set_mode mode ctxt);
   468 
   469 val read_term_pattern   = read_term_mode mode_pattern;
   470 val read_term_schematic = read_term_mode mode_schematic;
   471 val read_term_abbrev    = read_term_mode mode_abbrev;
   472 
   473 
   474 (* local abbreviations *)
   475 
   476 val tsig_of = Sign.tsig_of o ProofContext.theory_of;
   477 
   478 local
   479 
   480 fun certify_consts ctxt = Consts.certify (Syntax.pp ctxt) (tsig_of ctxt)
   481   (not (abbrev_mode ctxt)) (consts_of ctxt);
   482 
   483 fun reject_schematic (Var (xi, _)) =
   484       error ("Unbound schematic variable: " ^ Term.string_of_vname xi)
   485   | reject_schematic (Abs (_, _, t)) = reject_schematic t
   486   | reject_schematic (t $ u) = (reject_schematic t; reject_schematic u)
   487   | reject_schematic _ = ();
   488 
   489 fun expand_binds ctxt =
   490   let val Mode {pattern, schematic, ...} = get_mode ctxt in
   491     if pattern then I
   492     else Variable.expand_binds ctxt #> (if schematic then I else tap reject_schematic)
   493   end;
   494 
   495 in
   496 
   497 fun expand_abbrevs ctxt = certify_consts ctxt #> expand_binds ctxt;
   498 
   499 end;
   500 
   501 
   502 fun contract_abbrevs ctxt t =
   503   let
   504     val thy = theory_of ctxt;
   505     val consts = consts_of ctxt;
   506     val Mode {abbrev, ...} = get_mode ctxt;
   507     val retrieve = Consts.retrieve_abbrevs consts (print_mode_value () @ [""]);
   508     fun match_abbrev u = Option.map #1 (get_first (Pattern.match_rew thy u) (retrieve u));
   509   in
   510     if abbrev orelse print_mode_active "no_abbrevs" orelse not (can Term.type_of t) then t
   511     else Pattern.rewrite_term_top thy [] [match_abbrev] t
   512   end;
   513 
   514 
   515 (* patterns *)
   516 
   517 fun prepare_patternT ctxt T =
   518   let
   519     val Mode {pattern, schematic, ...} = get_mode ctxt;
   520     val _ =
   521       pattern orelse schematic orelse
   522         T |> Term.exists_subtype
   523           (fn TVar (xi, _) =>
   524             not (TypeInfer.is_param xi) andalso
   525               error ("Illegal schematic type variable: " ^ Term.string_of_vname xi)
   526           | _ => false)
   527   in T end;
   528 
   529 
   530 local
   531 
   532 structure Allow_Dummies = Proof_Data(type T = bool fun init _ = false);
   533 
   534 fun check_dummies ctxt t =
   535   if Allow_Dummies.get ctxt then t
   536   else Term.no_dummy_patterns t handle TERM _ => error "Illegal dummy pattern(s) in term";
   537 
   538 fun prepare_dummies ts = #1 (fold_map Term.replace_dummy_patterns ts 1);
   539 
   540 in
   541 
   542 val allow_dummies = Allow_Dummies.put true;
   543 
   544 fun prepare_patterns ctxt =
   545   let val Mode {pattern, ...} = get_mode ctxt in
   546     TypeInfer.fixate_params (Variable.names_of ctxt) #>
   547     pattern ? Variable.polymorphic ctxt #>
   548     (map o Term.map_types) (prepare_patternT ctxt) #>
   549     (if pattern then prepare_dummies else map (check_dummies ctxt))
   550   end;
   551 
   552 end;
   553 
   554 
   555 (* decoding raw terms (syntax trees) *)
   556 
   557 (* types *)
   558 
   559 fun get_sort thy def_sort raw_env =
   560   let
   561     val tsig = Sign.tsig_of thy;
   562 
   563     fun eq ((xi, S), (xi', S')) =
   564       Term.eq_ix (xi, xi') andalso Type.eq_sort tsig (S, S');
   565     val env = distinct eq raw_env;
   566     val _ = (case duplicates (eq_fst (op =)) env of [] => ()
   567       | dups => error ("Inconsistent sort constraints for type variable(s) "
   568           ^ commas_quote (map (Term.string_of_vname' o fst) dups)));
   569 
   570     fun get xi =
   571       (case (AList.lookup (op =) env xi, def_sort xi) of
   572         (NONE, NONE) => Type.defaultS tsig
   573       | (NONE, SOME S) => S
   574       | (SOME S, NONE) => S
   575       | (SOME S, SOME S') =>
   576           if Type.eq_sort tsig (S, S') then S'
   577           else error ("Sort constraint " ^ Syntax.string_of_sort_global thy S ^
   578             " inconsistent with default " ^ Syntax.string_of_sort_global thy S' ^
   579             " for type variable " ^ quote (Term.string_of_vname' xi)));
   580   in get end;
   581 
   582 local
   583 
   584 fun intern_skolem ctxt def_type x =
   585   let
   586     val _ = no_skolem false x;
   587     val sko = lookup_skolem ctxt x;
   588     val is_const = can (read_const_proper ctxt false) x orelse Long_Name.is_qualified x;
   589     val is_declared = is_some (def_type (x, ~1));
   590   in
   591     if Variable.is_const ctxt x then NONE
   592     else if is_some sko then sko
   593     else if not is_const orelse is_declared then SOME x
   594     else NONE
   595   end;
   596 
   597 in
   598 
   599 fun term_context ctxt =
   600   let val thy = theory_of ctxt in
   601    {get_sort = get_sort thy (Variable.def_sort ctxt),
   602     map_const = fn a => ((true, #1 (Term.dest_Const (read_const_proper ctxt false a)))
   603       handle ERROR _ => (false, Consts.intern (consts_of ctxt) a)),
   604     map_free = intern_skolem ctxt (Variable.def_type ctxt false),
   605     map_type = Sign.intern_tycons thy,
   606     map_sort = Sign.intern_sort thy}
   607   end;
   608 
   609 fun decode_term ctxt =
   610   let val {get_sort, map_const, map_free, map_type, map_sort} = term_context ctxt
   611   in Syntax.decode_term get_sort map_const map_free map_type map_sort end;
   612 
   613 end;
   614 
   615 
   616 (* certify terms *)
   617 
   618 local
   619 
   620 fun gen_cert prop ctxt t =
   621   t
   622   |> expand_abbrevs ctxt
   623   |> (fn t' => #1 (Sign.certify' prop (Syntax.pp ctxt) false (consts_of ctxt) (theory_of ctxt) t')
   624     handle TYPE (msg, _, _) => error msg
   625       | TERM (msg, _) => error msg);
   626 
   627 in
   628 
   629 val cert_term = gen_cert false;
   630 val cert_prop = gen_cert true;
   631 
   632 end;
   633 
   634 
   635 (* type checking/inference *)
   636 
   637 fun standard_infer_types ctxt ts =
   638   let val Mode {pattern, ...} = get_mode ctxt in
   639     TypeInfer.infer_types (Syntax.pp ctxt) (tsig_of ctxt) (Syntax.check_typs ctxt)
   640       (try (Consts.the_constraint (consts_of ctxt))) (Variable.def_type ctxt pattern)
   641       (Variable.names_of ctxt) (Variable.maxidx_of ctxt) ts
   642     handle TYPE (msg, _, _) => error msg
   643   end;
   644 
   645 local
   646 
   647 fun standard_typ_check ctxt =
   648   map (cert_typ_mode (Type.get_mode ctxt) ctxt) #>
   649   map (prepare_patternT ctxt);
   650 
   651 fun standard_term_check ctxt =
   652   standard_infer_types ctxt #>
   653   map (expand_abbrevs ctxt);
   654 
   655 fun standard_term_uncheck ctxt =
   656   map (contract_abbrevs ctxt);
   657 
   658 fun add eq what f = Context.>> (what (fn xs => fn ctxt =>
   659   let val xs' = f ctxt xs in if eq_list eq (xs, xs') then NONE else SOME (xs', ctxt) end));
   660 
   661 in
   662 
   663 val _ = add (op =) (Syntax.add_typ_check 0 "standard") standard_typ_check;
   664 val _ = add (op aconv) (Syntax.add_term_check 0 "standard") standard_term_check;
   665 val _ = add (op aconv) (Syntax.add_term_check 100 "fixate") prepare_patterns;
   666 
   667 val _ = add (op aconv) (Syntax.add_term_uncheck 0 "standard") standard_term_uncheck;
   668 
   669 end;
   670 
   671 
   672 
   673 (** inner syntax operations **)
   674 
   675 local
   676 
   677 fun parse_sort ctxt text =
   678   let
   679     val (syms, pos) = Syntax.parse_token Markup.sort text;
   680     val S = Syntax.standard_parse_sort ctxt (syn_of ctxt)
   681         (Sign.intern_sort (theory_of ctxt)) (syms, pos)
   682       handle ERROR msg => cat_error msg  ("Failed to parse sort" ^ Position.str_of pos)
   683   in S end;
   684 
   685 fun parse_typ ctxt text =
   686   let
   687     val thy = ProofContext.theory_of ctxt;
   688     val get_sort = get_sort thy (Variable.def_sort ctxt);
   689 
   690     val (syms, pos) = Syntax.parse_token Markup.typ text;
   691     val T = Sign.intern_tycons thy
   692         (Syntax.standard_parse_typ ctxt (syn_of ctxt) get_sort (Sign.intern_sort thy) (syms, pos))
   693       handle ERROR msg => cat_error msg  ("Failed to parse type" ^ Position.str_of pos);
   694   in T end;
   695 
   696 fun parse_term T ctxt text =
   697   let
   698     val thy = theory_of ctxt;
   699     val {get_sort, map_const, map_free, map_type, map_sort} = term_context ctxt;
   700 
   701     val (T', _) = TypeInfer.paramify_dummies T 0;
   702     val (markup, kind) = if T' = propT then (Markup.prop, "proposition") else (Markup.term, "term");
   703     val (syms, pos) = Syntax.parse_token markup text;
   704 
   705     fun check t = (Syntax.check_term ctxt (TypeInfer.constrain T' t); NONE)
   706       handle ERROR msg => SOME msg;
   707     val t = Syntax.standard_parse_term (Syntax.pp ctxt) check get_sort map_const map_free
   708         map_type map_sort ctxt (Sign.is_logtype thy) (syn_of ctxt) T' (syms, pos)
   709       handle ERROR msg => cat_error msg  ("Failed to parse " ^ kind ^ Position.str_of pos);
   710   in t end;
   711 
   712 
   713 fun unparse_sort ctxt S =
   714   Syntax.standard_unparse_sort ctxt (syn_of ctxt) (Sign.extern_sort (theory_of ctxt) S);
   715 
   716 fun unparse_typ ctxt T =
   717   Syntax.standard_unparse_typ ctxt (syn_of ctxt) (Sign.extern_typ (theory_of ctxt) T);
   718 
   719 fun unparse_term ctxt t =
   720   let
   721     val thy = theory_of ctxt;
   722     val syntax = syntax_of ctxt;
   723     val consts = consts_of ctxt;
   724   in
   725     t
   726     |> Sign.extern_term thy
   727     |> Local_Syntax.extern_term syntax
   728     |> Syntax.standard_unparse_term (Consts.extern consts) ctxt
   729         (Local_Syntax.syn_of syntax) (not (PureThy.old_appl_syntax thy))
   730   end;
   731 
   732 in
   733 
   734 val _ = Syntax.install_operations
   735   {parse_sort = parse_sort,
   736    parse_typ = parse_typ,
   737    parse_term = parse_term dummyT,
   738    parse_prop = parse_term propT,
   739    unparse_sort = unparse_sort,
   740    unparse_typ = unparse_typ,
   741    unparse_term = unparse_term};
   742 
   743 end;
   744 
   745 
   746 
   747 (** export results **)
   748 
   749 fun common_export is_goal inner outer =
   750   map (Assumption.export is_goal inner outer) #>
   751   Variable.export inner outer;
   752 
   753 val goal_export = common_export true;
   754 val export = common_export false;
   755 
   756 fun export_morphism inner outer =
   757   Assumption.export_morphism inner outer $>
   758   Variable.export_morphism inner outer;
   759 
   760 fun norm_export_morphism inner outer =
   761   export_morphism inner outer $>
   762   Morphism.thm_morphism Goal.norm_result;
   763 
   764 
   765 
   766 (** term bindings **)
   767 
   768 (* simult_matches *)
   769 
   770 fun simult_matches ctxt (t, pats) =
   771   (case Seq.pull (Unify.matchers (theory_of ctxt) (map (rpair t) pats)) of
   772     NONE => error "Pattern match failed!"
   773   | SOME (env, _) => Vartab.fold (fn (v, (_, t)) => cons (v, t)) (Envir.term_env env) []);
   774 
   775 
   776 (* bind_terms *)
   777 
   778 val bind_terms = fold (fn (xi, t) => fn ctxt =>
   779   ctxt
   780   |> Variable.bind_term (xi, Option.map (cert_term (set_mode mode_default ctxt)) t));
   781 
   782 
   783 (* auto_bind *)
   784 
   785 fun drop_schematic (b as (xi, SOME t)) = if Term.exists_subterm is_Var t then (xi, NONE) else b
   786   | drop_schematic b = b;
   787 
   788 fun auto_bind f ts ctxt = ctxt |> bind_terms (map drop_schematic (f (theory_of ctxt) ts));
   789 
   790 val auto_bind_goal = auto_bind Auto_Bind.goal;
   791 val auto_bind_facts = auto_bind Auto_Bind.facts;
   792 
   793 
   794 (* match_bind(_i) *)
   795 
   796 local
   797 
   798 fun gen_bind prep_terms gen raw_binds ctxt =
   799   let
   800     fun prep_bind (raw_pats, t) ctxt1 =
   801       let
   802         val T = Term.fastype_of t;
   803         val ctxt2 = Variable.declare_term t ctxt1;
   804         val pats = prep_terms (set_mode mode_pattern ctxt2) T raw_pats;
   805         val binds = simult_matches ctxt2 (t, pats);
   806       in (binds, ctxt2) end;
   807 
   808     val ts = prep_terms ctxt dummyT (map snd raw_binds);
   809     val (binds, ctxt') = apfst flat (fold_map prep_bind (map fst raw_binds ~~ ts) ctxt);
   810     val binds' =
   811       if gen then map #1 binds ~~ Variable.exportT_terms ctxt' ctxt (map #2 binds)
   812       else binds;
   813     val binds'' = map (apsnd SOME) binds';
   814     val ctxt'' =
   815       tap (Variable.warn_extra_tfrees ctxt)
   816        (if gen then
   817           ctxt (*sic!*) |> fold Variable.declare_term (map #2 binds') |> bind_terms binds''
   818         else ctxt' |> bind_terms binds'');
   819   in (ts, ctxt'') end;
   820 
   821 in
   822 
   823 fun read_terms ctxt T =
   824   map (Syntax.parse_term ctxt #> TypeInfer.constrain T) #> Syntax.check_terms ctxt;
   825 
   826 val match_bind = gen_bind read_terms;
   827 val match_bind_i = gen_bind (fn ctxt => fn _ => map (cert_term ctxt));
   828 
   829 end;
   830 
   831 
   832 (* propositions with patterns *)
   833 
   834 local
   835 
   836 fun prep_propp mode prep_props (context, args) =
   837   let
   838     fun prep (_, raw_pats) (ctxt, prop :: props) =
   839       let val ctxt' = Variable.declare_term prop ctxt
   840       in ((prop, prep_props (set_mode mode_pattern ctxt') raw_pats), (ctxt', props)) end;
   841 
   842     val (propp, (context', _)) = (fold_map o fold_map) prep args
   843       (context, prep_props (set_mode mode context) (maps (map fst) args));
   844   in (context', propp) end;
   845 
   846 fun gen_bind_propp mode parse_prop (ctxt, raw_args) =
   847   let
   848     val (ctxt', args) = prep_propp mode parse_prop (ctxt, raw_args);
   849     val binds = flat (flat (map (map (simult_matches ctxt')) args));
   850     val propss = map (map #1) args;
   851 
   852     (*generalize result: context evaluated now, binds added later*)
   853     val gen = Variable.exportT_terms ctxt' ctxt;
   854     fun gen_binds c = c |> bind_terms (map #1 binds ~~ map SOME (gen (map #2 binds)));
   855   in (ctxt' |> bind_terms (map (apsnd SOME) binds), (propss, gen_binds)) end;
   856 
   857 in
   858 
   859 val read_propp           = prep_propp mode_default Syntax.read_props;
   860 val cert_propp           = prep_propp mode_default (map o cert_prop);
   861 val read_propp_schematic = prep_propp mode_schematic Syntax.read_props;
   862 val cert_propp_schematic = prep_propp mode_schematic (map o cert_prop);
   863 
   864 val bind_propp             = gen_bind_propp mode_default Syntax.read_props;
   865 val bind_propp_i           = gen_bind_propp mode_default (map o cert_prop);
   866 val bind_propp_schematic   = gen_bind_propp mode_schematic Syntax.read_props;
   867 val bind_propp_schematic_i = gen_bind_propp mode_schematic (map o cert_prop);
   868 
   869 end;
   870 
   871 
   872 
   873 (** theorems **)
   874 
   875 (* fact_tac *)
   876 
   877 fun comp_incr_tac [] _ = no_tac
   878   | comp_incr_tac (th :: ths) i =
   879       (fn st => Goal.compose_hhf_tac (Drule.incr_indexes st th) i st) APPEND comp_incr_tac ths i;
   880 
   881 fun fact_tac facts = Goal.norm_hhf_tac THEN' comp_incr_tac facts;
   882 
   883 fun potential_facts ctxt prop =
   884   Facts.could_unify (facts_of ctxt) (Term.strip_all_body prop);
   885 
   886 fun some_fact_tac ctxt = SUBGOAL (fn (goal, i) => fact_tac (potential_facts ctxt goal) i);
   887 
   888 
   889 (* get_thm(s) *)
   890 
   891 local
   892 
   893 fun retrieve_thms pick ctxt (Facts.Fact s) =
   894       let
   895         val (_, pos) = Syntax.read_token s;
   896         val prop = Syntax.read_prop (set_mode mode_default ctxt) s
   897           |> singleton (Variable.polymorphic ctxt);
   898 
   899         fun prove_fact th =
   900           Goal.prove ctxt [] [] prop (K (ALLGOALS (fact_tac [th])));
   901         val res =
   902           (case get_first (try prove_fact) (potential_facts ctxt prop) of
   903             SOME res => res
   904           | NONE => error ("Failed to retrieve literal fact" ^ Position.str_of pos ^ ":\n" ^
   905               Syntax.string_of_term ctxt prop))
   906       in pick "" [res] end
   907   | retrieve_thms pick ctxt xthmref =
   908       let
   909         val thy = theory_of ctxt;
   910         val local_facts = facts_of ctxt;
   911         val thmref = Facts.map_name_of_ref (Facts.intern local_facts) xthmref;
   912         val name = Facts.name_of_ref thmref;
   913         val pos = Facts.pos_of_ref xthmref;
   914         val thms =
   915           if name = "" then [Thm.transfer thy Drule.dummy_thm]
   916           else
   917             (case Facts.lookup (Context.Proof ctxt) local_facts name of
   918               SOME (_, ths) => (Position.report (Markup.local_fact name) pos;
   919                 map (Thm.transfer thy) (Facts.select thmref ths))
   920             | NONE => PureThy.get_fact (Context.Proof ctxt) thy xthmref);
   921       in pick name thms end;
   922 
   923 in
   924 
   925 val get_fact = retrieve_thms (K I);
   926 val get_fact_single = retrieve_thms Facts.the_single;
   927 
   928 fun get_thms ctxt = get_fact ctxt o Facts.named;
   929 fun get_thm ctxt = get_fact_single ctxt o Facts.named;
   930 
   931 end;
   932 
   933 
   934 (* facts *)
   935 
   936 local
   937 
   938 fun update_thms _ (b, NONE) ctxt = ctxt |> map_facts (Facts.del (full_name ctxt b))
   939   | update_thms do_props (b, SOME ths) ctxt = ctxt |> map_facts
   940       (Facts.add_local do_props (naming_of ctxt) (b, ths) #> snd);
   941 
   942 in
   943 
   944 fun note_thmss kind = fold_map (fn ((b, more_attrs), raw_facts) => fn ctxt =>
   945   let
   946     val pos = Binding.pos_of b;
   947     val name = full_name ctxt b;
   948     val _ = Context_Position.report_visible ctxt (Markup.local_fact_decl name) pos;
   949 
   950     val facts = PureThy.name_thmss false name raw_facts;
   951     fun app (th, attrs) x =
   952       swap (Library.foldl_map
   953         (Thm.proof_attributes (surround (Thm.kind kind) (attrs @ more_attrs))) (x, th));
   954     val (res, ctxt') = fold_map app facts ctxt;
   955     val thms = PureThy.name_thms false false name (flat res);
   956     val Mode {stmt, ...} = get_mode ctxt;
   957   in ((name, thms), ctxt' |> update_thms stmt (b, SOME thms)) end);
   958 
   959 fun put_thms do_props thms ctxt = ctxt
   960   |> map_naming (K local_naming)
   961   |> Context_Position.set_visible false
   962   |> update_thms do_props (apfst Binding.name thms)
   963   |> Context_Position.restore_visible ctxt
   964   |> restore_naming ctxt;
   965 
   966 end;
   967 
   968 
   969 
   970 (** parameters **)
   971 
   972 (* variables *)
   973 
   974 fun declare_var (x, opt_T, mx) ctxt =
   975   let val T = (case opt_T of SOME T => T | NONE => Syntax.mixfixT mx)
   976   in ((x, T, mx), ctxt |> Variable.declare_constraints (Free (x, T))) end;
   977 
   978 local
   979 
   980 fun prep_vars prep_typ internal =
   981   fold_map (fn (b, raw_T, mx) => fn ctxt =>
   982     let
   983       val x = Name.of_binding b;
   984       val _ = Syntax.is_identifier (no_skolem internal x) orelse
   985         error ("Illegal variable name: " ^ quote (Binding.str_of b));
   986 
   987       fun cond_tvars T =
   988         if internal then T
   989         else Type.no_tvars T handle TYPE (msg, _, _) => error msg;
   990       val opt_T = Option.map (cond_tvars o cert_typ ctxt o prep_typ ctxt) raw_T;
   991       val (_, ctxt') = ctxt |> declare_var (x, opt_T, mx);
   992     in ((b, opt_T, mx), ctxt') end);
   993 
   994 in
   995 
   996 val read_vars = prep_vars Syntax.parse_typ false;
   997 val cert_vars = prep_vars (K I) true;
   998 
   999 end;
  1000 
  1001 
  1002 (* authentic constants *)
  1003 
  1004 local
  1005 
  1006 fun const_ast_tr intern ctxt [Syntax.Variable c] =
  1007       let
  1008         val Const (c', _) = read_const_proper ctxt false c;
  1009         val d = if intern then Syntax.mark_const c' else c;
  1010       in Syntax.Constant d end
  1011   | const_ast_tr _ _ asts = raise Syntax.AST ("const_ast_tr", asts);
  1012 
  1013 in
  1014 
  1015 val _ = Context.>> (Context.map_theory
  1016  (Sign.add_syntax
  1017    [("_context_const", "id => logic", Delimfix "CONST _"),
  1018     ("_context_const", "id => aprop", Delimfix "CONST _"),
  1019     ("_context_const", "longid => logic", Delimfix "CONST _"),
  1020     ("_context_const", "longid => aprop", Delimfix "CONST _"),
  1021     ("_context_xconst", "id => logic", Delimfix "XCONST _"),
  1022     ("_context_xconst", "id => aprop", Delimfix "XCONST _"),
  1023     ("_context_xconst", "longid => logic", Delimfix "XCONST _"),
  1024     ("_context_xconst", "longid => aprop", Delimfix "XCONST _")] #>
  1025   Sign.add_advanced_trfuns
  1026     ([("_context_const", const_ast_tr true), ("_context_xconst", const_ast_tr false)], [], [], [])));
  1027 
  1028 end;
  1029 
  1030 
  1031 (* notation *)
  1032 
  1033 local
  1034 
  1035 fun type_syntax (Type (c, args), mx) =  (* FIXME authentic syntax *)
  1036       SOME (Local_Syntax.Type, (Long_Name.base_name c, Syntax.make_type (length args), mx))
  1037   | type_syntax _ = NONE;
  1038 
  1039 fun const_syntax _ (Free (x, T), mx) = SOME (Local_Syntax.Fixed, (x, T, mx))
  1040   | const_syntax ctxt (Const (c, _), mx) =
  1041       (case try (Consts.type_scheme (consts_of ctxt)) c of
  1042         SOME T => SOME (Local_Syntax.Const, (Syntax.mark_const c, T, mx))
  1043       | NONE => NONE)
  1044   | const_syntax _ _ = NONE;
  1045 
  1046 fun gen_notation syntax add mode args ctxt =
  1047   ctxt |> map_syntax
  1048     (Local_Syntax.update_modesyntax (theory_of ctxt) add mode (map_filter (syntax ctxt) args));
  1049 
  1050 in
  1051 
  1052 val type_notation = gen_notation (K type_syntax);
  1053 val notation = gen_notation const_syntax;
  1054 
  1055 fun target_type_notation add  mode args phi =
  1056   let
  1057     val args' = args |> map_filter (fn (T, mx) =>
  1058       let
  1059         val T' = Morphism.typ phi T;
  1060         val similar = (case (T, T') of (Type (c, _), Type (c', _)) => c = c' | _ => false);
  1061       in if similar then SOME (T', mx) else NONE end);
  1062   in Context.mapping (Sign.type_notation add mode args') (type_notation add mode args') end;
  1063 
  1064 fun target_notation add mode args phi =
  1065   let
  1066     val args' = args |> map_filter (fn (t, mx) =>
  1067       let val t' = Morphism.term phi t
  1068       in if Term.aconv_untyped (t, t') then SOME (t', mx) else NONE end);
  1069   in Context.mapping (Sign.notation add mode args') (notation add mode args') end;
  1070 
  1071 
  1072 end;
  1073 
  1074 
  1075 (* local constants *)
  1076 
  1077 fun add_const_constraint (c, opt_T) ctxt =
  1078   let
  1079     fun prepT raw_T =
  1080       let val T = cert_typ ctxt raw_T
  1081       in cert_term ctxt (Const (c, T)); T end;
  1082   in ctxt |> (map_consts o apfst) (Consts.constrain (c, Option.map prepT opt_T)) end;
  1083 
  1084 fun add_abbrev mode (b, raw_t) ctxt =
  1085   let
  1086     val t0 = cert_term (ctxt |> set_mode mode_abbrev) raw_t
  1087       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote (Binding.str_of b));
  1088     val [t] = Variable.exportT_terms (Variable.declare_term t0 ctxt) ctxt [t0];
  1089     val ((lhs, rhs), consts') = consts_of ctxt
  1090       |> Consts.abbreviate (Syntax.pp ctxt) (tsig_of ctxt) (naming_of ctxt) mode (b, t);
  1091   in
  1092     ctxt
  1093     |> (map_consts o apfst) (K consts')
  1094     |> Variable.declare_term rhs
  1095     |> pair (lhs, rhs)
  1096   end;
  1097 
  1098 fun revert_abbrev mode c = (map_consts o apfst) (Consts.revert_abbrev mode c);
  1099 
  1100 
  1101 (* fixes *)
  1102 
  1103 local
  1104 
  1105 fun prep_mixfix (x, T, mx) =
  1106   if mx <> NoSyn andalso mx <> Structure andalso
  1107       (can Name.dest_internal x orelse can Name.dest_skolem x) then
  1108     error ("Illegal mixfix syntax for internal/skolem constant " ^ quote x)
  1109   else (Local_Syntax.Fixed, (x, T, mx));
  1110 
  1111 in
  1112 
  1113 fun add_fixes raw_vars ctxt =
  1114   let
  1115     val (vars, _) = cert_vars raw_vars ctxt;
  1116     val (xs', ctxt') = Variable.add_fixes (map (Name.of_binding o #1) vars) ctxt;
  1117     val ctxt'' =
  1118       ctxt'
  1119       |> fold_map declare_var (map2 (fn x' => fn (_, T, mx) => (x', T, mx)) xs' vars)
  1120       |-> (map_syntax o Local_Syntax.add_syntax (theory_of ctxt) o map prep_mixfix);
  1121     val _ = (vars ~~ xs') |> List.app (fn ((b, _, _), x') =>
  1122       Context_Position.report_visible ctxt (Markup.fixed_decl x') (Binding.pos_of b));
  1123   in (xs', ctxt'') end;
  1124 
  1125 end;
  1126 
  1127 
  1128 (* fixes vs. frees *)
  1129 
  1130 fun auto_fixes (ctxt, (propss, x)) =
  1131   ((fold o fold) Variable.auto_fixes propss ctxt, (propss, x));
  1132 
  1133 fun bind_fixes xs ctxt =
  1134   let
  1135     val (_, ctxt') = ctxt |> add_fixes (map (fn x => (Binding.name x, NONE, NoSyn)) xs);
  1136     fun bind (t as Free (x, T)) =
  1137           if member (op =) xs x then
  1138             (case lookup_skolem ctxt' x of SOME x' => Free (x', T) | NONE => t)
  1139           else t
  1140       | bind (t $ u) = bind t $ bind u
  1141       | bind (Abs (x, T, t)) = Abs (x, T, bind t)
  1142       | bind a = a;
  1143   in (bind, ctxt') end;
  1144 
  1145 
  1146 
  1147 (** assumptions **)
  1148 
  1149 local
  1150 
  1151 fun gen_assms prepp exp args ctxt =
  1152   let
  1153     val cert = Thm.cterm_of (theory_of ctxt);
  1154     val (propss, ctxt1) = swap (prepp (ctxt, map snd args));
  1155     val _ = Variable.warn_extra_tfrees ctxt ctxt1;
  1156     val (premss, ctxt2) = fold_burrow (Assumption.add_assms exp o map cert) propss ctxt1;
  1157   in
  1158     ctxt2
  1159     |> auto_bind_facts (flat propss)
  1160     |> note_thmss "" (map fst args ~~ map (map (fn th => ([th], []))) premss)
  1161   end;
  1162 
  1163 in
  1164 
  1165 val add_assms = gen_assms (apsnd #1 o bind_propp);
  1166 val add_assms_i = gen_assms (apsnd #1 o bind_propp_i);
  1167 
  1168 end;
  1169 
  1170 
  1171 
  1172 (** cases **)
  1173 
  1174 local
  1175 
  1176 fun rem_case name = remove (fn (x: string, (y, _)) => x = y) name;
  1177 
  1178 fun add_case _ ("", _) cases = cases
  1179   | add_case _ (name, NONE) cases = rem_case name cases
  1180   | add_case is_proper (name, SOME c) cases = (name, (c, is_proper)) :: rem_case name cases;
  1181 
  1182 fun prep_case name fxs c =
  1183   let
  1184     fun replace (opt_x :: xs) ((y, T) :: ys) = (the_default y opt_x, T) :: replace xs ys
  1185       | replace [] ys = ys
  1186       | replace (_ :: _) [] = error ("Too many parameters for case " ^ quote name);
  1187     val Rule_Cases.Case {fixes, assumes, binds, cases} = c;
  1188     val fixes' = replace fxs fixes;
  1189     val binds' = map drop_schematic binds;
  1190   in
  1191     if null (fold (Term.add_tvarsT o snd) fixes []) andalso
  1192       null (fold (fold Term.add_vars o snd) assumes []) then
  1193         Rule_Cases.Case {fixes = fixes', assumes = assumes, binds = binds', cases = cases}
  1194     else error ("Illegal schematic variable(s) in case " ^ quote name)
  1195   end;
  1196 
  1197 fun fix (x, T) ctxt =
  1198   let
  1199     val (bind, ctxt') = bind_fixes [x] ctxt;
  1200     val t = bind (Free (x, T));
  1201   in (t, ctxt' |> Variable.declare_constraints t) end;
  1202 
  1203 in
  1204 
  1205 fun add_cases is_proper = map_cases o fold (add_case is_proper);
  1206 
  1207 fun case_result c ctxt =
  1208   let
  1209     val Rule_Cases.Case {fixes, ...} = c;
  1210     val (ts, ctxt') = ctxt |> fold_map fix fixes;
  1211     val Rule_Cases.Case {assumes, binds, cases, ...} = Rule_Cases.apply ts c;
  1212   in
  1213     ctxt'
  1214     |> bind_terms (map drop_schematic binds)
  1215     |> add_cases true (map (apsnd SOME) cases)
  1216     |> pair (assumes, (binds, cases))
  1217   end;
  1218 
  1219 val apply_case = apfst fst oo case_result;
  1220 
  1221 fun get_case ctxt name xs =
  1222   (case AList.lookup (op =) (cases_of ctxt) name of
  1223     NONE => error ("Unknown case: " ^ quote name)
  1224   | SOME (c, _) => prep_case name xs c);
  1225 
  1226 end;
  1227 
  1228 
  1229 
  1230 (** print context information **)
  1231 
  1232 (* local syntax *)
  1233 
  1234 val print_syntax = Syntax.print_syntax o syn_of;
  1235 
  1236 
  1237 (* abbreviations *)
  1238 
  1239 fun pretty_abbrevs show_globals ctxt =
  1240   let
  1241     val ((space, consts), (_, globals)) =
  1242       pairself (#constants o Consts.dest) (#consts (rep_context ctxt));
  1243     fun add_abbr (_, (_, NONE)) = I
  1244       | add_abbr (c, (T, SOME t)) =
  1245           if not show_globals andalso Symtab.defined globals c then I
  1246           else cons (c, Logic.mk_equals (Const (c, T), t));
  1247     val abbrevs = Name_Space.extern_table (space, Symtab.make (Symtab.fold add_abbr consts []));
  1248   in
  1249     if null abbrevs then []
  1250     else [Pretty.big_list "abbreviations:" (map (pretty_term_abbrev ctxt o #2) abbrevs)]
  1251   end;
  1252 
  1253 val print_abbrevs = Pretty.writeln o Pretty.chunks o pretty_abbrevs true;
  1254 
  1255 
  1256 (* term bindings *)
  1257 
  1258 fun pretty_binds ctxt =
  1259   let
  1260     val binds = Variable.binds_of ctxt;
  1261     fun prt_bind (xi, (T, t)) = pretty_term_abbrev ctxt (Logic.mk_equals (Var (xi, T), t));
  1262   in
  1263     if Vartab.is_empty binds then []
  1264     else [Pretty.big_list "term bindings:" (map prt_bind (Vartab.dest binds))]
  1265   end;
  1266 
  1267 val print_binds = Pretty.writeln o Pretty.chunks o pretty_binds;
  1268 
  1269 
  1270 (* local theorems *)
  1271 
  1272 fun pretty_lthms ctxt =
  1273   let
  1274     val local_facts = facts_of ctxt;
  1275     val props = Facts.props local_facts;
  1276     val facts =
  1277       (if null props then [] else [("<unnamed>", props)]) @
  1278       Facts.dest_static [] local_facts;
  1279   in
  1280     if null facts then []
  1281     else [Pretty.big_list "facts:" (map #1 (sort_wrt (#1 o #2) (map (`(pretty_fact ctxt)) facts)))]
  1282   end;
  1283 
  1284 val print_lthms = Pretty.writeln o Pretty.chunks o pretty_lthms;
  1285 
  1286 
  1287 (* local contexts *)
  1288 
  1289 local
  1290 
  1291 fun pretty_case (name, (fixes, ((asms, (lets, cs)), ctxt))) =
  1292   let
  1293     val prt_term = Syntax.pretty_term ctxt;
  1294 
  1295     fun prt_let (xi, t) = Pretty.block
  1296       [Pretty.quote (prt_term (Var (xi, Term.fastype_of t))), Pretty.str " =", Pretty.brk 1,
  1297         Pretty.quote (prt_term t)];
  1298 
  1299     fun prt_asm (a, ts) = Pretty.block (Pretty.breaks
  1300       ((if a = "" then [] else [Pretty.str (a ^ ":")]) @ map (Pretty.quote o prt_term) ts));
  1301 
  1302     fun prt_sect _ _ _ [] = []
  1303       | prt_sect s sep prt xs =
  1304           [Pretty.block (Pretty.breaks (Pretty.str s ::
  1305             flat (separate sep (map (single o prt) xs))))];
  1306   in
  1307     Pretty.block (Pretty.fbreaks
  1308       (Pretty.str (name ^ ":") ::
  1309         prt_sect "fix" [] (Pretty.str o fst) fixes @
  1310         prt_sect "let" [Pretty.str "and"] prt_let
  1311           (map_filter (fn (xi, SOME t) => SOME (xi, t) | _ => NONE) lets) @
  1312         (if forall (null o #2) asms then []
  1313           else prt_sect "assume" [Pretty.str "and"] prt_asm asms) @
  1314         prt_sect "subcases:" [] (Pretty.str o fst) cs))
  1315   end;
  1316 
  1317 in
  1318 
  1319 fun pretty_cases ctxt =
  1320   let
  1321     fun add_case (_, (_, false)) = I
  1322       | add_case (name, (c as Rule_Cases.Case {fixes, ...}, true)) =
  1323           cons (name, (fixes, case_result c ctxt));
  1324     val cases = fold add_case (cases_of ctxt) [];
  1325   in
  1326     if null cases then []
  1327     else [Pretty.big_list "cases:" (map pretty_case cases)]
  1328   end;
  1329 
  1330 val print_cases = Pretty.writeln o Pretty.chunks o pretty_cases;
  1331 
  1332 end;
  1333 
  1334 
  1335 (* core context *)
  1336 
  1337 val debug = Unsynchronized.ref false;
  1338 val verbose = Unsynchronized.ref false;
  1339 val prems_limit = Unsynchronized.ref ~1;
  1340 
  1341 fun pretty_ctxt ctxt =
  1342   if ! prems_limit < 0 andalso not (! debug) then []
  1343   else
  1344     let
  1345       val prt_term = Syntax.pretty_term ctxt;
  1346 
  1347       (*structures*)
  1348       val structs = Local_Syntax.structs_of (syntax_of ctxt);
  1349       val prt_structs =
  1350         if null structs then []
  1351         else [Pretty.block (Pretty.str "structures:" :: Pretty.brk 1 ::
  1352           Pretty.commas (map Pretty.str structs))];
  1353 
  1354       (*fixes*)
  1355       fun prt_fix (x, x') =
  1356         if x = x' then Pretty.str x
  1357         else Pretty.block [Pretty.str x, Pretty.str " =", Pretty.brk 1, prt_term (Syntax.free x')];
  1358       val fixes =
  1359         rev (filter_out ((can Name.dest_internal orf member (op =) structs) o #1)
  1360           (Variable.fixes_of ctxt));
  1361       val prt_fixes =
  1362         if null fixes then []
  1363         else [Pretty.block (Pretty.str "fixed variables:" :: Pretty.brk 1 ::
  1364           Pretty.commas (map prt_fix fixes))];
  1365 
  1366       (*prems*)
  1367       val prems = Assumption.all_prems_of ctxt;
  1368       val len = length prems;
  1369       val suppressed = len - ! prems_limit;
  1370       val prt_prems =
  1371         if null prems then []
  1372         else [Pretty.big_list "prems:" ((if suppressed <= 0 then [] else [Pretty.str "..."]) @
  1373           map (Display.pretty_thm ctxt) (drop suppressed prems))];
  1374     in prt_structs @ prt_fixes @ prt_prems end;
  1375 
  1376 
  1377 (* main context *)
  1378 
  1379 fun pretty_context ctxt =
  1380   let
  1381     val is_verbose = ! verbose;
  1382     fun verb f x = if is_verbose then f (x ()) else [];
  1383 
  1384     val prt_term = Syntax.pretty_term ctxt;
  1385     val prt_typ = Syntax.pretty_typ ctxt;
  1386     val prt_sort = Syntax.pretty_sort ctxt;
  1387 
  1388     (*theory*)
  1389     val pretty_thy = Pretty.block
  1390       [Pretty.str "theory:", Pretty.brk 1, Context.pretty_thy (theory_of ctxt)];
  1391 
  1392     (*defaults*)
  1393     fun prt_atom prt prtT (x, X) = Pretty.block
  1394       [prt x, Pretty.str " ::", Pretty.brk 1, prtT X];
  1395 
  1396     fun prt_var (x, ~1) = prt_term (Syntax.free x)
  1397       | prt_var xi = prt_term (Syntax.var xi);
  1398 
  1399     fun prt_varT (x, ~1) = prt_typ (TFree (x, []))
  1400       | prt_varT xi = prt_typ (TVar (xi, []));
  1401 
  1402     val prt_defT = prt_atom prt_var prt_typ;
  1403     val prt_defS = prt_atom prt_varT prt_sort;
  1404 
  1405     val (types, sorts) = Variable.constraints_of ctxt;
  1406   in
  1407     verb single (K pretty_thy) @
  1408     pretty_ctxt ctxt @
  1409     verb (pretty_abbrevs false) (K ctxt) @
  1410     verb pretty_binds (K ctxt) @
  1411     verb pretty_lthms (K ctxt) @
  1412     verb pretty_cases (K ctxt) @
  1413     verb single (fn () => Pretty.big_list "type constraints:" (map prt_defT (Vartab.dest types))) @
  1414     verb single (fn () => Pretty.big_list "default sorts:" (map prt_defS (Vartab.dest sorts)))
  1415   end;
  1416 
  1417 end;