src/HOL/Groebner_Basis.thy
author chaieb
Tue Jun 12 10:15:32 2007 +0200 (2007-06-12)
changeset 23332 b91295432e6d
parent 23330 01c09922ce59
child 23389 aaca6a8e5414
permissions -rw-r--r--
algebra_tac moved to file Tools/Groebner_Basis/groebner.ML; Method now takes theorems to be added or deleted from a simpset for simplificatio *before* the core method starts
     1 (*  Title:      HOL/Groebner_Basis.thy
     2     ID:         $Id$
     3     Author:     Amine Chaieb, TU Muenchen
     4 *)
     5 
     6 header {* Semiring normalization and Groebner Bases *}
     7 theory Groebner_Basis
     8 imports NatBin
     9 uses
    10   "Tools/Groebner_Basis/misc.ML"
    11   "Tools/Groebner_Basis/normalizer_data.ML"
    12   ("Tools/Groebner_Basis/normalizer.ML")
    13   ("Tools/Groebner_Basis/groebner.ML")
    14 begin
    15 
    16 
    17 
    18 subsection {* Semiring normalization *}
    19 
    20 setup NormalizerData.setup
    21 
    22 
    23 locale gb_semiring =
    24   fixes add mul pwr r0 r1
    25   assumes add_a:"(add x (add y z) = add (add x y) z)"
    26     and add_c: "add x y = add y x" and add_0:"add r0 x = x"
    27     and mul_a:"mul x (mul y z) = mul (mul x y) z" and mul_c:"mul x y = mul y x"
    28     and mul_1:"mul r1 x = x" and  mul_0:"mul r0 x = r0"
    29     and mul_d:"mul x (add y z) = add (mul x y) (mul x z)"
    30     and pwr_0:"pwr x 0 = r1" and pwr_Suc:"pwr x (Suc n) = mul x (pwr x n)"
    31 begin
    32 
    33 lemma mul_pwr:"mul (pwr x p) (pwr x q) = pwr x (p + q)"
    34 proof (induct p)
    35   case 0
    36   then show ?case by (auto simp add: pwr_0 mul_1)
    37 next
    38   case Suc
    39   from this [symmetric] show ?case
    40     by (auto simp add: pwr_Suc mul_1 mul_a)
    41 qed
    42 
    43 lemma pwr_mul: "pwr (mul x y) q = mul (pwr x q) (pwr y q)"
    44 proof (induct q arbitrary: x y, auto simp add:pwr_0 pwr_Suc mul_1)
    45   fix q x y
    46   assume "\<And>x y. pwr (mul x y) q = mul (pwr x q) (pwr y q)"
    47   have "mul (mul x y) (mul (pwr x q) (pwr y q)) = mul x (mul y (mul (pwr x q) (pwr y q)))"
    48     by (simp add: mul_a)
    49   also have "\<dots> = (mul (mul y (mul (pwr y q) (pwr x q))) x)" by (simp add: mul_c)
    50   also have "\<dots> = (mul (mul y (pwr y q)) (mul (pwr x q) x))" by (simp add: mul_a)
    51   finally show "mul (mul x y) (mul (pwr x q) (pwr y q)) =
    52     mul (mul x (pwr x q)) (mul y (pwr y q))" by (simp add: mul_c)
    53 qed
    54 
    55 lemma pwr_pwr: "pwr (pwr x p) q = pwr x (p * q)"
    56 proof (induct p arbitrary: q)
    57   case 0
    58   show ?case using pwr_Suc mul_1 pwr_0 by (induct q) auto
    59 next
    60   case Suc
    61   thus ?case by (auto simp add: mul_pwr [symmetric] pwr_mul pwr_Suc)
    62 qed
    63 
    64 
    65 subsubsection {* Declaring the abstract theory *}
    66 
    67 lemma semiring_ops:
    68   includes meta_term_syntax
    69   shows "TERM (add x y)" and "TERM (mul x y)" and "TERM (pwr x n)"
    70     and "TERM r0" and "TERM r1"
    71   by rule+
    72 
    73 lemma semiring_rules:
    74   "add (mul a m) (mul b m) = mul (add a b) m"
    75   "add (mul a m) m = mul (add a r1) m"
    76   "add m (mul a m) = mul (add a r1) m"
    77   "add m m = mul (add r1 r1) m"
    78   "add r0 a = a"
    79   "add a r0 = a"
    80   "mul a b = mul b a"
    81   "mul (add a b) c = add (mul a c) (mul b c)"
    82   "mul r0 a = r0"
    83   "mul a r0 = r0"
    84   "mul r1 a = a"
    85   "mul a r1 = a"
    86   "mul (mul lx ly) (mul rx ry) = mul (mul lx rx) (mul ly ry)"
    87   "mul (mul lx ly) (mul rx ry) = mul lx (mul ly (mul rx ry))"
    88   "mul (mul lx ly) (mul rx ry) = mul rx (mul (mul lx ly) ry)"
    89   "mul (mul lx ly) rx = mul (mul lx rx) ly"
    90   "mul (mul lx ly) rx = mul lx (mul ly rx)"
    91   "mul lx (mul rx ry) = mul (mul lx rx) ry"
    92   "mul lx (mul rx ry) = mul rx (mul lx ry)"
    93   "add (add a b) (add c d) = add (add a c) (add b d)"
    94   "add (add a b) c = add a (add b c)"
    95   "add a (add c d) = add c (add a d)"
    96   "add (add a b) c = add (add a c) b"
    97   "add a c = add c a"
    98   "add a (add c d) = add (add a c) d"
    99   "mul (pwr x p) (pwr x q) = pwr x (p + q)"
   100   "mul x (pwr x q) = pwr x (Suc q)"
   101   "mul (pwr x q) x = pwr x (Suc q)"
   102   "mul x x = pwr x 2"
   103   "pwr (mul x y) q = mul (pwr x q) (pwr y q)"
   104   "pwr (pwr x p) q = pwr x (p * q)"
   105   "pwr x 0 = r1"
   106   "pwr x 1 = x"
   107   "mul x (add y z) = add (mul x y) (mul x z)"
   108   "pwr x (Suc q) = mul x (pwr x q)"
   109   "pwr x (2*n) = mul (pwr x n) (pwr x n)"
   110   "pwr x (Suc (2*n)) = mul x (mul (pwr x n) (pwr x n))"
   111 proof -
   112   show "add (mul a m) (mul b m) = mul (add a b) m" using mul_d mul_c by simp
   113 next show"add (mul a m) m = mul (add a r1) m" using mul_d mul_c mul_1 by simp
   114 next show "add m (mul a m) = mul (add a r1) m" using mul_c mul_d mul_1 add_c by simp
   115 next show "add m m = mul (add r1 r1) m" using mul_c mul_d mul_1 by simp
   116 next show "add r0 a = a" using add_0 by simp
   117 next show "add a r0 = a" using add_0 add_c by simp
   118 next show "mul a b = mul b a" using mul_c by simp
   119 next show "mul (add a b) c = add (mul a c) (mul b c)" using mul_c mul_d by simp
   120 next show "mul r0 a = r0" using mul_0 by simp
   121 next show "mul a r0 = r0" using mul_0 mul_c by simp
   122 next show "mul r1 a = a" using mul_1 by simp
   123 next show "mul a r1 = a" using mul_1 mul_c by simp
   124 next show "mul (mul lx ly) (mul rx ry) = mul (mul lx rx) (mul ly ry)"
   125     using mul_c mul_a by simp
   126 next show "mul (mul lx ly) (mul rx ry) = mul lx (mul ly (mul rx ry))"
   127     using mul_a by simp
   128 next
   129   have "mul (mul lx ly) (mul rx ry) = mul (mul rx ry) (mul lx ly)" by (rule mul_c)
   130   also have "\<dots> = mul rx (mul ry (mul lx ly))" using mul_a by simp
   131   finally
   132   show "mul (mul lx ly) (mul rx ry) = mul rx (mul (mul lx ly) ry)"
   133     using mul_c by simp
   134 next show "mul (mul lx ly) rx = mul (mul lx rx) ly" using mul_c mul_a by simp
   135 next
   136   show "mul (mul lx ly) rx = mul lx (mul ly rx)" by (simp add: mul_a)
   137 next show "mul lx (mul rx ry) = mul (mul lx rx) ry" by (simp add: mul_a )
   138 next show "mul lx (mul rx ry) = mul rx (mul lx ry)" by (simp add: mul_a,simp add: mul_c)
   139 next show "add (add a b) (add c d) = add (add a c) (add b d)"
   140     using add_c add_a by simp
   141 next show "add (add a b) c = add a (add b c)" using add_a by simp
   142 next show "add a (add c d) = add c (add a d)"
   143     apply (simp add: add_a) by (simp only: add_c)
   144 next show "add (add a b) c = add (add a c) b" using add_a add_c by simp
   145 next show "add a c = add c a" by (rule add_c)
   146 next show "add a (add c d) = add (add a c) d" using add_a by simp
   147 next show "mul (pwr x p) (pwr x q) = pwr x (p + q)" by (rule mul_pwr)
   148 next show "mul x (pwr x q) = pwr x (Suc q)" using pwr_Suc by simp
   149 next show "mul (pwr x q) x = pwr x (Suc q)" using pwr_Suc mul_c by simp
   150 next show "mul x x = pwr x 2" by (simp add: nat_number pwr_Suc pwr_0 mul_1 mul_c)
   151 next show "pwr (mul x y) q = mul (pwr x q) (pwr y q)" by (rule pwr_mul)
   152 next show "pwr (pwr x p) q = pwr x (p * q)" by (rule pwr_pwr)
   153 next show "pwr x 0 = r1" using pwr_0 .
   154 next show "pwr x 1 = x" by (simp add: nat_number pwr_Suc pwr_0 mul_1 mul_c)
   155 next show "mul x (add y z) = add (mul x y) (mul x z)" using mul_d by simp
   156 next show "pwr x (Suc q) = mul x (pwr x q)" using pwr_Suc by simp
   157 next show "pwr x (2 * n) = mul (pwr x n) (pwr x n)" by (simp add: nat_number mul_pwr)
   158 next show "pwr x (Suc (2 * n)) = mul x (mul (pwr x n) (pwr x n))"
   159     by (simp add: nat_number pwr_Suc mul_pwr)
   160 qed
   161 
   162 
   163 lemma "axioms" [normalizer
   164     semiring ops: semiring_ops
   165     semiring rules: semiring_rules]:
   166   "gb_semiring add mul pwr r0 r1" .
   167 
   168 end
   169 
   170 interpretation class_semiring: gb_semiring
   171     ["op +" "op *" "op ^" "0::'a::{comm_semiring_1, recpower}" "1"]
   172   by unfold_locales (auto simp add: ring_eq_simps power_Suc)
   173 
   174 lemmas nat_arith =
   175   add_nat_number_of diff_nat_number_of mult_nat_number_of eq_nat_number_of less_nat_number_of
   176 
   177 lemma not_iszero_Numeral1: "\<not> iszero (Numeral1::'a::number_ring)"
   178   by (simp add: numeral_1_eq_1)
   179 lemmas comp_arith = Let_def arith_simps nat_arith rel_simps if_False
   180   if_True add_0 add_Suc add_number_of_left mult_number_of_left
   181   numeral_1_eq_1[symmetric] Suc_eq_add_numeral_1
   182   numeral_0_eq_0[symmetric] numerals[symmetric] not_iszero_1
   183   iszero_number_of_1 iszero_number_of_0 nonzero_number_of_Min
   184   iszero_number_of_Pls iszero_0 not_iszero_Numeral1
   185 
   186 lemmas semiring_norm = comp_arith
   187 
   188 ML {*
   189   fun numeral_is_const ct =
   190     can HOLogic.dest_number (Thm.term_of ct);
   191 
   192   val numeral_conv =
   193     Conv.then_conv (Simplifier.rewrite (HOL_basic_ss addsimps @{thms semiring_norm}),
   194    Simplifier.rewrite (HOL_basic_ss addsimps
   195   [@{thm numeral_1_eq_1},@{thm numeral_0_eq_0}] @ @{thms numerals(1-2)}));
   196 *}
   197 
   198 ML {*
   199   fun int_of_rat x =
   200     (case Rat.quotient_of_rat x of (i, 1) => i
   201     | _ => error "int_of_rat: bad int")
   202 *}
   203 
   204 declaration {*
   205   NormalizerData.funs @{thm class_semiring.axioms}
   206    {is_const = fn phi => numeral_is_const,
   207     dest_const = fn phi => fn ct =>
   208       Rat.rat_of_int (snd
   209         (HOLogic.dest_number (Thm.term_of ct)
   210           handle TERM _ => error "ring_dest_const")),
   211     mk_const = fn phi => fn cT => fn x =>
   212       Thm.cterm_of (Thm.theory_of_ctyp cT) (HOLogic.mk_number (typ_of cT) (int_of_rat x)),
   213     conv = fn phi => K numeral_conv}
   214 *}
   215 
   216 
   217 locale gb_ring = gb_semiring +
   218   fixes sub :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
   219     and neg :: "'a \<Rightarrow> 'a"
   220   assumes neg_mul: "neg x = mul (neg r1) x"
   221     and sub_add: "sub x y = add x (neg y)"
   222 begin
   223 
   224 lemma ring_ops:
   225   includes meta_term_syntax
   226   shows "TERM (sub x y)" and "TERM (neg x)" .
   227 
   228 lemmas ring_rules = neg_mul sub_add
   229 
   230 lemma "axioms" [normalizer
   231   semiring ops: semiring_ops
   232   semiring rules: semiring_rules
   233   ring ops: ring_ops
   234   ring rules: ring_rules]:
   235   "gb_ring add mul pwr r0 r1 sub neg" .
   236 
   237 end
   238 
   239 
   240 interpretation class_ring: gb_ring ["op +" "op *" "op ^"
   241     "0::'a::{comm_semiring_1,recpower,number_ring}" 1 "op -" "uminus"]
   242   by unfold_locales simp_all
   243 
   244 
   245 declaration {*
   246   NormalizerData.funs @{thm class_ring.axioms}
   247    {is_const = fn phi => numeral_is_const,
   248     dest_const = fn phi => fn ct =>
   249       Rat.rat_of_int (snd
   250         (HOLogic.dest_number (Thm.term_of ct)
   251           handle TERM _ => error "ring_dest_const")),
   252     mk_const = fn phi => fn cT => fn x =>
   253       Thm.cterm_of (Thm.theory_of_ctyp cT) (HOLogic.mk_number (typ_of cT) (int_of_rat x)),
   254     conv = fn phi => K numeral_conv}
   255 *}
   256 
   257 use "Tools/Groebner_Basis/normalizer.ML"
   258 
   259 method_setup sring_norm = {*
   260   Method.ctxt_args (fn ctxt => Method.SIMPLE_METHOD' (Normalizer.semiring_normalize_tac ctxt))
   261 *} "Semiring_normalizer"
   262 
   263 
   264 locale gb_field = gb_ring +
   265   fixes divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
   266     and inverse:: "'a \<Rightarrow> 'a"
   267   assumes divide: "divide x y = mul x (inverse y)"
   268      and inverse: "inverse x = divide r1 x"
   269 begin
   270 
   271 lemma "axioms" [normalizer
   272   semiring ops: semiring_ops
   273   semiring rules: semiring_rules
   274   ring ops: ring_ops
   275   ring rules: ring_rules]:
   276   "gb_field add mul pwr r0 r1 sub neg divide inverse" .
   277 
   278 end
   279 
   280 subsection {* Groebner Bases *}
   281 
   282 locale semiringb = gb_semiring +
   283   assumes add_cancel: "add (x::'a) y = add x z \<longleftrightarrow> y = z"
   284   and add_mul_solve: "add (mul w y) (mul x z) =
   285     add (mul w z) (mul x y) \<longleftrightarrow> w = x \<or> y = z"
   286 begin
   287 
   288 lemma noteq_reduce: "a \<noteq> b \<and> c \<noteq> d \<longleftrightarrow> add (mul a c) (mul b d) \<noteq> add (mul a d) (mul b c)"
   289 proof-
   290   have "a \<noteq> b \<and> c \<noteq> d \<longleftrightarrow> \<not> (a = b \<or> c = d)" by simp
   291   also have "\<dots> \<longleftrightarrow> add (mul a c) (mul b d) \<noteq> add (mul a d) (mul b c)"
   292     using add_mul_solve by blast
   293   finally show "a \<noteq> b \<and> c \<noteq> d \<longleftrightarrow> add (mul a c) (mul b d) \<noteq> add (mul a d) (mul b c)"
   294     by simp
   295 qed
   296 
   297 lemma add_scale_eq_noteq: "\<lbrakk>r \<noteq> r0 ; (a = b) \<and> ~(c = d)\<rbrakk>
   298   \<Longrightarrow> add a (mul r c) \<noteq> add b (mul r d)"
   299 proof(clarify)
   300   assume nz: "r\<noteq> r0" and cnd: "c\<noteq>d"
   301     and eq: "add b (mul r c) = add b (mul r d)"
   302   hence "mul r c = mul r d" using cnd add_cancel by simp
   303   hence "add (mul r0 d) (mul r c) = add (mul r0 c) (mul r d)"
   304     using mul_0 add_cancel by simp
   305   thus "False" using add_mul_solve nz cnd by simp
   306 qed
   307 
   308 declare "axioms" [normalizer del]
   309 
   310 lemma "axioms" [normalizer
   311   semiring ops: semiring_ops
   312   semiring rules: semiring_rules
   313   idom rules: noteq_reduce add_scale_eq_noteq]:
   314   "semiringb add mul pwr r0 r1" .
   315 
   316 end
   317 
   318 locale ringb = semiringb + gb_ring
   319 begin
   320 
   321 declare "axioms" [normalizer del]
   322 
   323 lemma "axioms" [normalizer
   324   semiring ops: semiring_ops
   325   semiring rules: semiring_rules
   326   ring ops: ring_ops
   327   ring rules: ring_rules
   328   idom rules: noteq_reduce add_scale_eq_noteq]:
   329   "ringb add mul pwr r0 r1 sub neg" .
   330 
   331 end
   332 
   333 lemma no_zero_divirors_neq0:
   334   assumes az: "(a::'a::no_zero_divisors) \<noteq> 0"
   335     and ab: "a*b = 0" shows "b = 0"
   336 proof -
   337   { assume bz: "b \<noteq> 0"
   338     from no_zero_divisors [OF az bz] ab have False by blast }
   339   thus "b = 0" by blast
   340 qed
   341 
   342 interpretation class_ringb: ringb
   343   ["op +" "op *" "op ^" "0::'a::{idom,recpower,number_ring}" "1" "op -" "uminus"]
   344 proof(unfold_locales, simp add: ring_eq_simps power_Suc, auto)
   345   fix w x y z ::"'a::{idom,recpower,number_ring}"
   346   assume p: "w * y + x * z = w * z + x * y" and ynz: "y \<noteq> z"
   347   hence ynz': "y - z \<noteq> 0" by simp
   348   from p have "w * y + x* z - w*z - x*y = 0" by simp
   349   hence "w* (y - z) - x * (y - z) = 0" by (simp add: ring_eq_simps)
   350   hence "(y - z) * (w - x) = 0" by (simp add: ring_eq_simps)
   351   with  no_zero_divirors_neq0 [OF ynz']
   352   have "w - x = 0" by blast
   353   thus "w = x"  by simp
   354 qed
   355 
   356 
   357 declaration {*
   358   NormalizerData.funs @{thm class_ringb.axioms}
   359    {is_const = fn phi => numeral_is_const,
   360     dest_const = fn phi => fn ct =>
   361       Rat.rat_of_int (snd
   362         (HOLogic.dest_number (Thm.term_of ct)
   363           handle TERM _ => error "ring_dest_const")),
   364     mk_const = fn phi => fn cT => fn x =>
   365       Thm.cterm_of (Thm.theory_of_ctyp cT) (HOLogic.mk_number (typ_of cT) (int_of_rat x)),
   366     conv = fn phi => K numeral_conv}
   367 *}
   368 
   369 
   370 interpretation natgb: semiringb
   371   ["op +" "op *" "op ^" "0::nat" "1"]
   372 proof (unfold_locales, simp add: ring_eq_simps power_Suc)
   373   fix w x y z ::"nat"
   374   { assume p: "w * y + x * z = w * z + x * y" and ynz: "y \<noteq> z"
   375     hence "y < z \<or> y > z" by arith
   376     moreover {
   377       assume lt:"y <z" hence "\<exists>k. z = y + k \<and> k > 0" by (rule_tac x="z - y" in exI, auto)
   378       then obtain k where kp: "k>0" and yz:"z = y + k" by blast
   379       from p have "(w * y + x *y) + x*k = (w * y + x*y) + w*k" by (simp add: yz ring_eq_simps)
   380       hence "x*k = w*k" by simp
   381       hence "w = x" using kp by (simp add: mult_cancel2) }
   382     moreover {
   383       assume lt: "y >z" hence "\<exists>k. y = z + k \<and> k>0" by (rule_tac x="y - z" in exI, auto)
   384       then obtain k where kp: "k>0" and yz:"y = z + k" by blast
   385       from p have "(w * z + x *z) + w*k = (w * z + x*z) + x*k" by (simp add: yz ring_eq_simps)
   386       hence "w*k = x*k" by simp
   387       hence "w = x" using kp by (simp add: mult_cancel2)}
   388     ultimately have "w=x" by blast }
   389   thus "(w * y + x * z = w * z + x * y) = (w = x \<or> y = z)" by auto
   390 qed
   391 
   392 declaration {*
   393   NormalizerData.funs @{thm natgb.axioms}
   394    {is_const = fn phi => numeral_is_const,
   395     dest_const = fn phi => fn ct =>
   396       Rat.rat_of_int (snd
   397         (HOLogic.dest_number (Thm.term_of ct)
   398           handle TERM _ => error "ring_dest_const")),
   399     mk_const = fn phi => fn cT => fn x =>
   400       Thm.cterm_of (Thm.theory_of_ctyp cT) (HOLogic.mk_number (typ_of cT) (int_of_rat x)),
   401     conv = fn phi => K numeral_conv}
   402 *}
   403 
   404 locale fieldgb = ringb + gb_field
   405 begin
   406 
   407 declare "axioms" [normalizer del]
   408 
   409 lemma "axioms" [normalizer
   410   semiring ops: semiring_ops
   411   semiring rules: semiring_rules
   412   ring ops: ring_ops
   413   ring rules: ring_rules
   414   idom rules: noteq_reduce add_scale_eq_noteq]:
   415   "fieldgb add mul pwr r0 r1 sub neg divide inverse" by unfold_locales
   416 end
   417 
   418 
   419 
   420 lemmas bool_simps = simp_thms(1-34)
   421 lemma dnf:
   422     "(P & (Q | R)) = ((P&Q) | (P&R))" "((Q | R) & P) = ((Q&P) | (R&P))"
   423     "(P \<and> Q) = (Q \<and> P)" "(P \<or> Q) = (Q \<or> P)"
   424   by blast+
   425 
   426 lemmas weak_dnf_simps = dnf bool_simps
   427 
   428 lemma nnf_simps:
   429     "(\<not>(P \<and> Q)) = (\<not>P \<or> \<not>Q)" "(\<not>(P \<or> Q)) = (\<not>P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)"
   430     "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not> \<not>(P)) = P"
   431   by blast+
   432 
   433 lemma PFalse:
   434     "P \<equiv> False \<Longrightarrow> \<not> P"
   435     "\<not> P \<Longrightarrow> (P \<equiv> False)"
   436   by auto
   437 
   438 use "Tools/Groebner_Basis/groebner.ML"
   439 
   440 method_setup algebra =
   441 {* 
   442 let
   443  fun keyword k = Scan.lift (Args.$$$ k -- Args.colon) >> K ()
   444  val addN = "add"
   445  val delN = "del"
   446  val any_keyword = keyword addN || keyword delN
   447  val thms = Scan.repeat (Scan.unless any_keyword Attrib.multi_thm) >> flat;
   448 in
   449 fn src => Method.syntax 
   450     ((Scan.optional (keyword addN |-- thms) []) -- 
   451     (Scan.optional (keyword delN |-- thms) [])) src 
   452  #> (fn ((add_ths, del_ths), ctxt) => 
   453        Method.SIMPLE_METHOD' (Groebner.algebra_tac add_ths del_ths ctxt))
   454 end
   455 
   456 *} ""
   457 
   458 end