src/HOL/Set.ML
author paulson
Wed Jul 15 10:15:13 1998 +0200 (1998-07-15)
changeset 5143 b94cd208f073
parent 5069 3ea049f7979d
child 5148 74919e8f221c
permissions -rw-r--r--
Removal of leading "\!\!..." from most Goal commands
     1 (*  Title:      HOL/set
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1991  University of Cambridge
     5 
     6 Set theory for higher-order logic.  A set is simply a predicate.
     7 *)
     8 
     9 open Set;
    10 
    11 section "Relating predicates and sets";
    12 
    13 Addsimps [Collect_mem_eq];
    14 AddIffs  [mem_Collect_eq];
    15 
    16 Goal "P(a) ==> a : {x. P(x)}";
    17 by (Asm_simp_tac 1);
    18 qed "CollectI";
    19 
    20 val prems = goal Set.thy "!!a. a : {x. P(x)} ==> P(a)";
    21 by (Asm_full_simp_tac 1);
    22 qed "CollectD";
    23 
    24 val [prem] = goal Set.thy "[| !!x. (x:A) = (x:B) |] ==> A = B";
    25 by (rtac (prem RS ext RS arg_cong RS box_equals) 1);
    26 by (rtac Collect_mem_eq 1);
    27 by (rtac Collect_mem_eq 1);
    28 qed "set_ext";
    29 
    30 val [prem] = goal Set.thy "[| !!x. P(x)=Q(x) |] ==> {x. P(x)} = {x. Q(x)}";
    31 by (rtac (prem RS ext RS arg_cong) 1);
    32 qed "Collect_cong";
    33 
    34 val CollectE = make_elim CollectD;
    35 
    36 AddSIs [CollectI];
    37 AddSEs [CollectE];
    38 
    39 
    40 section "Bounded quantifiers";
    41 
    42 val prems = goalw Set.thy [Ball_def]
    43     "[| !!x. x:A ==> P(x) |] ==> ! x:A. P(x)";
    44 by (REPEAT (ares_tac (prems @ [allI,impI]) 1));
    45 qed "ballI";
    46 
    47 val [major,minor] = goalw Set.thy [Ball_def]
    48     "[| ! x:A. P(x);  x:A |] ==> P(x)";
    49 by (rtac (minor RS (major RS spec RS mp)) 1);
    50 qed "bspec";
    51 
    52 val major::prems = goalw Set.thy [Ball_def]
    53     "[| ! x:A. P(x);  P(x) ==> Q;  x~:A ==> Q |] ==> Q";
    54 by (rtac (major RS spec RS impCE) 1);
    55 by (REPEAT (eresolve_tac prems 1));
    56 qed "ballE";
    57 
    58 (*Takes assumptions ! x:A.P(x) and a:A; creates assumption P(a)*)
    59 fun ball_tac i = etac ballE i THEN contr_tac (i+1);
    60 
    61 AddSIs [ballI];
    62 AddEs  [ballE];
    63 
    64 val prems = goalw Set.thy [Bex_def]
    65     "[| P(x);  x:A |] ==> ? x:A. P(x)";
    66 by (REPEAT (ares_tac (prems @ [exI,conjI]) 1));
    67 qed "bexI";
    68 
    69 qed_goal "bexCI" Set.thy 
    70    "[| ! x:A. ~P(x) ==> P(a);  a:A |] ==> ? x:A. P(x)"
    71  (fn prems=>
    72   [ (rtac classical 1),
    73     (REPEAT (ares_tac (prems@[bexI,ballI,notI,notE]) 1))  ]);
    74 
    75 val major::prems = goalw Set.thy [Bex_def]
    76     "[| ? x:A. P(x);  !!x. [| x:A; P(x) |] ==> Q  |] ==> Q";
    77 by (rtac (major RS exE) 1);
    78 by (REPEAT (eresolve_tac (prems @ [asm_rl,conjE]) 1));
    79 qed "bexE";
    80 
    81 AddIs  [bexI];
    82 AddSEs [bexE];
    83 
    84 (*Trival rewrite rule*)
    85 Goal "(! x:A. P) = ((? x. x:A) --> P)";
    86 by (simp_tac (simpset() addsimps [Ball_def]) 1);
    87 qed "ball_triv";
    88 
    89 (*Dual form for existentials*)
    90 Goal "(? x:A. P) = ((? x. x:A) & P)";
    91 by (simp_tac (simpset() addsimps [Bex_def]) 1);
    92 qed "bex_triv";
    93 
    94 Addsimps [ball_triv, bex_triv];
    95 
    96 (** Congruence rules **)
    97 
    98 val prems = goal Set.thy
    99     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   100 \    (! x:A. P(x)) = (! x:B. Q(x))";
   101 by (resolve_tac (prems RL [ssubst]) 1);
   102 by (REPEAT (ares_tac [ballI,iffI] 1
   103      ORELSE eresolve_tac ([make_elim bspec, mp] @ (prems RL [iffE])) 1));
   104 qed "ball_cong";
   105 
   106 val prems = goal Set.thy
   107     "[| A=B;  !!x. x:B ==> P(x) = Q(x) |] ==> \
   108 \    (? x:A. P(x)) = (? x:B. Q(x))";
   109 by (resolve_tac (prems RL [ssubst]) 1);
   110 by (REPEAT (etac bexE 1
   111      ORELSE ares_tac ([bexI,iffI] @ (prems RL [iffD1,iffD2])) 1));
   112 qed "bex_cong";
   113 
   114 section "Subsets";
   115 
   116 val prems = goalw Set.thy [subset_def] "(!!x. x:A ==> x:B) ==> A <= B";
   117 by (REPEAT (ares_tac (prems @ [ballI]) 1));
   118 qed "subsetI";
   119 
   120 Blast.overloaded ("op <=", domain_type); (*The <= relation is overloaded*)
   121 
   122 (*While (:) is not, its type must be kept
   123   for overloading of = to work.*)
   124 Blast.overloaded ("op :", domain_type);
   125 seq (fn a => Blast.overloaded (a, HOLogic.dest_setT o domain_type))
   126     ["Ball", "Bex"];
   127 (*need UNION, INTER also?*)
   128 
   129 (*Image: retain the type of the set being expressed*)
   130 Blast.overloaded ("op ``", domain_type o domain_type);
   131 
   132 (*Rule in Modus Ponens style*)
   133 val major::prems = goalw Set.thy [subset_def] "[| A <= B;  c:A |] ==> c:B";
   134 by (rtac (major RS bspec) 1);
   135 by (resolve_tac prems 1);
   136 qed "subsetD";
   137 
   138 (*The same, with reversed premises for use with etac -- cf rev_mp*)
   139 qed_goal "rev_subsetD" Set.thy "[| c:A;  A <= B |] ==> c:B"
   140  (fn prems=>  [ (REPEAT (resolve_tac (prems@[subsetD]) 1)) ]);
   141 
   142 (*Converts A<=B to x:A ==> x:B*)
   143 fun impOfSubs th = th RSN (2, rev_subsetD);
   144 
   145 qed_goal "contra_subsetD" Set.thy "!!c. [| A <= B; c ~: B |] ==> c ~: A"
   146  (fn prems=>  [ (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ]);
   147 
   148 qed_goal "rev_contra_subsetD" Set.thy "!!c. [| c ~: B;  A <= B |] ==> c ~: A"
   149  (fn prems=>  [ (REPEAT (eresolve_tac [asm_rl, contrapos, subsetD] 1)) ]);
   150 
   151 (*Classical elimination rule*)
   152 val major::prems = goalw Set.thy [subset_def] 
   153     "[| A <= B;  c~:A ==> P;  c:B ==> P |] ==> P";
   154 by (rtac (major RS ballE) 1);
   155 by (REPEAT (eresolve_tac prems 1));
   156 qed "subsetCE";
   157 
   158 (*Takes assumptions A<=B; c:A and creates the assumption c:B *)
   159 fun set_mp_tac i = etac subsetCE i  THEN  mp_tac i;
   160 
   161 AddSIs [subsetI];
   162 AddEs  [subsetD, subsetCE];
   163 
   164 qed_goal "subset_refl" Set.thy "A <= (A::'a set)"
   165  (fn _=> [Fast_tac 1]);		(*Blast_tac would try order_refl and fail*)
   166 
   167 val prems = goal Set.thy "!!B. [| A<=B;  B<=C |] ==> A<=(C::'a set)";
   168 by (Blast_tac 1);
   169 qed "subset_trans";
   170 
   171 
   172 section "Equality";
   173 
   174 (*Anti-symmetry of the subset relation*)
   175 val prems = goal Set.thy "[| A <= B;  B <= A |] ==> A = (B::'a set)";
   176 by (rtac (iffI RS set_ext) 1);
   177 by (REPEAT (ares_tac (prems RL [subsetD]) 1));
   178 qed "subset_antisym";
   179 val equalityI = subset_antisym;
   180 
   181 AddSIs [equalityI];
   182 
   183 (* Equality rules from ZF set theory -- are they appropriate here? *)
   184 val prems = goal Set.thy "A = B ==> A<=(B::'a set)";
   185 by (resolve_tac (prems RL [subst]) 1);
   186 by (rtac subset_refl 1);
   187 qed "equalityD1";
   188 
   189 val prems = goal Set.thy "A = B ==> B<=(A::'a set)";
   190 by (resolve_tac (prems RL [subst]) 1);
   191 by (rtac subset_refl 1);
   192 qed "equalityD2";
   193 
   194 val prems = goal Set.thy
   195     "[| A = B;  [| A<=B; B<=(A::'a set) |] ==> P |]  ==>  P";
   196 by (resolve_tac prems 1);
   197 by (REPEAT (resolve_tac (prems RL [equalityD1,equalityD2]) 1));
   198 qed "equalityE";
   199 
   200 val major::prems = goal Set.thy
   201     "[| A = B;  [| c:A; c:B |] ==> P;  [| c~:A; c~:B |] ==> P |]  ==>  P";
   202 by (rtac (major RS equalityE) 1);
   203 by (REPEAT (contr_tac 1 ORELSE eresolve_tac ([asm_rl,subsetCE]@prems) 1));
   204 qed "equalityCE";
   205 
   206 (*Lemma for creating induction formulae -- for "pattern matching" on p
   207   To make the induction hypotheses usable, apply "spec" or "bspec" to
   208   put universal quantifiers over the free variables in p. *)
   209 val prems = goal Set.thy 
   210     "[| p:A;  !!z. z:A ==> p=z --> R |] ==> R";
   211 by (rtac mp 1);
   212 by (REPEAT (resolve_tac (refl::prems) 1));
   213 qed "setup_induction";
   214 
   215 
   216 section "The universal set -- UNIV";
   217 
   218 qed_goalw "UNIV_I" Set.thy [UNIV_def] "x : UNIV"
   219   (fn _ => [rtac CollectI 1, rtac TrueI 1]);
   220 
   221 Addsimps [UNIV_I];
   222 AddIs    [UNIV_I];  (*unsafe makes it less likely to cause problems*)
   223 
   224 qed_goal "subset_UNIV" Set.thy "A <= UNIV"
   225   (fn _ => [rtac subsetI 1, rtac UNIV_I 1]);
   226 
   227 (** Eta-contracting these two rules (to remove P) causes them to be ignored
   228     because of their interaction with congruence rules. **)
   229 
   230 Goalw [Ball_def] "Ball UNIV P = All P";
   231 by (Simp_tac 1);
   232 qed "ball_UNIV";
   233 
   234 Goalw [Bex_def] "Bex UNIV P = Ex P";
   235 by (Simp_tac 1);
   236 qed "bex_UNIV";
   237 Addsimps [ball_UNIV, bex_UNIV];
   238 
   239 
   240 section "The empty set -- {}";
   241 
   242 qed_goalw "empty_iff" Set.thy [empty_def] "(c : {}) = False"
   243  (fn _ => [ (Blast_tac 1) ]);
   244 
   245 Addsimps [empty_iff];
   246 
   247 qed_goal "emptyE" Set.thy "!!a. a:{} ==> P"
   248  (fn _ => [Full_simp_tac 1]);
   249 
   250 AddSEs [emptyE];
   251 
   252 qed_goal "empty_subsetI" Set.thy "{} <= A"
   253  (fn _ => [ (Blast_tac 1) ]);
   254 
   255 qed_goal "equals0I" Set.thy "[| !!y. y:A ==> False |] ==> A={}"
   256  (fn [prem]=>
   257   [ (blast_tac (claset() addIs [prem RS FalseE]) 1) ]);
   258 
   259 qed_goal "equals0D" Set.thy "!!a. [| A={};  a:A |] ==> P"
   260  (fn _ => [ (Blast_tac 1) ]);
   261 
   262 Goalw [Ball_def] "Ball {} P = True";
   263 by (Simp_tac 1);
   264 qed "ball_empty";
   265 
   266 Goalw [Bex_def] "Bex {} P = False";
   267 by (Simp_tac 1);
   268 qed "bex_empty";
   269 Addsimps [ball_empty, bex_empty];
   270 
   271 Goal "UNIV ~= {}";
   272 by (blast_tac (claset() addEs [equalityE]) 1);
   273 qed "UNIV_not_empty";
   274 AddIffs [UNIV_not_empty];
   275 
   276 
   277 
   278 section "The Powerset operator -- Pow";
   279 
   280 qed_goalw "Pow_iff" Set.thy [Pow_def] "(A : Pow(B)) = (A <= B)"
   281  (fn _ => [ (Asm_simp_tac 1) ]);
   282 
   283 AddIffs [Pow_iff]; 
   284 
   285 qed_goalw "PowI" Set.thy [Pow_def] "!!A B. A <= B ==> A : Pow(B)"
   286  (fn _ => [ (etac CollectI 1) ]);
   287 
   288 qed_goalw "PowD" Set.thy [Pow_def] "!!A B. A : Pow(B)  ==>  A<=B"
   289  (fn _=> [ (etac CollectD 1) ]);
   290 
   291 val Pow_bottom = empty_subsetI RS PowI;        (* {}: Pow(B) *)
   292 val Pow_top = subset_refl RS PowI;             (* A : Pow(A) *)
   293 
   294 
   295 section "Set complement -- Compl";
   296 
   297 qed_goalw "Compl_iff" Set.thy [Compl_def] "(c : Compl(A)) = (c~:A)"
   298  (fn _ => [ (Blast_tac 1) ]);
   299 
   300 Addsimps [Compl_iff];
   301 
   302 val prems = goalw Set.thy [Compl_def]
   303     "[| c:A ==> False |] ==> c : Compl(A)";
   304 by (REPEAT (ares_tac (prems @ [CollectI,notI]) 1));
   305 qed "ComplI";
   306 
   307 (*This form, with negated conclusion, works well with the Classical prover.
   308   Negated assumptions behave like formulae on the right side of the notional
   309   turnstile...*)
   310 val major::prems = goalw Set.thy [Compl_def]
   311     "c : Compl(A) ==> c~:A";
   312 by (rtac (major RS CollectD) 1);
   313 qed "ComplD";
   314 
   315 val ComplE = make_elim ComplD;
   316 
   317 AddSIs [ComplI];
   318 AddSEs [ComplE];
   319 
   320 
   321 section "Binary union -- Un";
   322 
   323 qed_goalw "Un_iff" Set.thy [Un_def] "(c : A Un B) = (c:A | c:B)"
   324  (fn _ => [ Blast_tac 1 ]);
   325 
   326 Addsimps [Un_iff];
   327 
   328 Goal "c:A ==> c : A Un B";
   329 by (Asm_simp_tac 1);
   330 qed "UnI1";
   331 
   332 Goal "c:B ==> c : A Un B";
   333 by (Asm_simp_tac 1);
   334 qed "UnI2";
   335 
   336 (*Classical introduction rule: no commitment to A vs B*)
   337 qed_goal "UnCI" Set.thy "(c~:B ==> c:A) ==> c : A Un B"
   338  (fn prems=>
   339   [ (Simp_tac 1),
   340     (REPEAT (ares_tac (prems@[disjCI]) 1)) ]);
   341 
   342 val major::prems = goalw Set.thy [Un_def]
   343     "[| c : A Un B;  c:A ==> P;  c:B ==> P |] ==> P";
   344 by (rtac (major RS CollectD RS disjE) 1);
   345 by (REPEAT (eresolve_tac prems 1));
   346 qed "UnE";
   347 
   348 AddSIs [UnCI];
   349 AddSEs [UnE];
   350 
   351 
   352 section "Binary intersection -- Int";
   353 
   354 qed_goalw "Int_iff" Set.thy [Int_def] "(c : A Int B) = (c:A & c:B)"
   355  (fn _ => [ (Blast_tac 1) ]);
   356 
   357 Addsimps [Int_iff];
   358 
   359 Goal "[| c:A;  c:B |] ==> c : A Int B";
   360 by (Asm_simp_tac 1);
   361 qed "IntI";
   362 
   363 Goal "c : A Int B ==> c:A";
   364 by (Asm_full_simp_tac 1);
   365 qed "IntD1";
   366 
   367 Goal "c : A Int B ==> c:B";
   368 by (Asm_full_simp_tac 1);
   369 qed "IntD2";
   370 
   371 val [major,minor] = goal Set.thy
   372     "[| c : A Int B;  [| c:A; c:B |] ==> P |] ==> P";
   373 by (rtac minor 1);
   374 by (rtac (major RS IntD1) 1);
   375 by (rtac (major RS IntD2) 1);
   376 qed "IntE";
   377 
   378 AddSIs [IntI];
   379 AddSEs [IntE];
   380 
   381 section "Set difference";
   382 
   383 qed_goalw "Diff_iff" Set.thy [set_diff_def] "(c : A-B) = (c:A & c~:B)"
   384  (fn _ => [ (Blast_tac 1) ]);
   385 
   386 Addsimps [Diff_iff];
   387 
   388 qed_goal "DiffI" Set.thy "!!c. [| c : A;  c ~: B |] ==> c : A - B"
   389  (fn _=> [ Asm_simp_tac 1 ]);
   390 
   391 qed_goal "DiffD1" Set.thy "!!c. c : A - B ==> c : A"
   392  (fn _=> [ (Asm_full_simp_tac 1) ]);
   393 
   394 qed_goal "DiffD2" Set.thy "!!c. [| c : A - B;  c : B |] ==> P"
   395  (fn _=> [ (Asm_full_simp_tac 1) ]);
   396 
   397 qed_goal "DiffE" Set.thy "[| c : A - B;  [| c:A; c~:B |] ==> P |] ==> P"
   398  (fn prems=>
   399   [ (resolve_tac prems 1),
   400     (REPEAT (ares_tac (prems RL [DiffD1, DiffD2 RS notI]) 1)) ]);
   401 
   402 AddSIs [DiffI];
   403 AddSEs [DiffE];
   404 
   405 
   406 section "Augmenting a set -- insert";
   407 
   408 qed_goalw "insert_iff" Set.thy [insert_def] "a : insert b A = (a=b | a:A)"
   409  (fn _ => [Blast_tac 1]);
   410 
   411 Addsimps [insert_iff];
   412 
   413 qed_goal "insertI1" Set.thy "a : insert a B"
   414  (fn _ => [Simp_tac 1]);
   415 
   416 qed_goal "insertI2" Set.thy "!!a. a : B ==> a : insert b B"
   417  (fn _=> [Asm_simp_tac 1]);
   418 
   419 qed_goalw "insertE" Set.thy [insert_def]
   420     "[| a : insert b A;  a=b ==> P;  a:A ==> P |] ==> P"
   421  (fn major::prems=>
   422   [ (rtac (major RS UnE) 1),
   423     (REPEAT (eresolve_tac (prems @ [CollectE]) 1)) ]);
   424 
   425 (*Classical introduction rule*)
   426 qed_goal "insertCI" Set.thy "(a~:B ==> a=b) ==> a: insert b B"
   427  (fn prems=>
   428   [ (Simp_tac 1),
   429     (REPEAT (ares_tac (prems@[disjCI]) 1)) ]);
   430 
   431 AddSIs [insertCI]; 
   432 AddSEs [insertE];
   433 
   434 section "Singletons, using insert";
   435 
   436 qed_goal "singletonI" Set.thy "a : {a}"
   437  (fn _=> [ (rtac insertI1 1) ]);
   438 
   439 Goal "b : {a} ==> b=a";
   440 by (Blast_tac 1);
   441 qed "singletonD";
   442 
   443 bind_thm ("singletonE", make_elim singletonD);
   444 
   445 qed_goal "singleton_iff" thy "(b : {a}) = (b=a)" 
   446 (fn _ => [Blast_tac 1]);
   447 
   448 Goal "{a}={b} ==> a=b";
   449 by (blast_tac (claset() addEs [equalityE]) 1);
   450 qed "singleton_inject";
   451 
   452 (*Redundant? But unlike insertCI, it proves the subgoal immediately!*)
   453 AddSIs [singletonI];   
   454 AddSDs [singleton_inject];
   455 AddSEs [singletonE];
   456 
   457 Goal "{x. x=a} = {a}";
   458 by (Blast_tac 1);
   459 qed "singleton_conv";
   460 Addsimps [singleton_conv];
   461 
   462 
   463 section "Unions of families -- UNION x:A. B(x) is Union(B``A)";
   464 
   465 Goalw [UNION_def] "(b: (UN x:A. B(x))) = (EX x:A. b: B(x))";
   466 by (Blast_tac 1);
   467 qed "UN_iff";
   468 
   469 Addsimps [UN_iff];
   470 
   471 (*The order of the premises presupposes that A is rigid; b may be flexible*)
   472 Goal "[| a:A;  b: B(a) |] ==> b: (UN x:A. B(x))";
   473 by Auto_tac;
   474 qed "UN_I";
   475 
   476 val major::prems = goalw Set.thy [UNION_def]
   477     "[| b : (UN x:A. B(x));  !!x.[| x:A;  b: B(x) |] ==> R |] ==> R";
   478 by (rtac (major RS CollectD RS bexE) 1);
   479 by (REPEAT (ares_tac prems 1));
   480 qed "UN_E";
   481 
   482 AddIs  [UN_I];
   483 AddSEs [UN_E];
   484 
   485 val prems = goal Set.thy
   486     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   487 \    (UN x:A. C(x)) = (UN x:B. D(x))";
   488 by (REPEAT (etac UN_E 1
   489      ORELSE ares_tac ([UN_I,equalityI,subsetI] @ 
   490                       (prems RL [equalityD1,equalityD2] RL [subsetD])) 1));
   491 qed "UN_cong";
   492 
   493 
   494 section "Intersections of families -- INTER x:A. B(x) is Inter(B``A)";
   495 
   496 Goalw [INTER_def] "(b: (INT x:A. B(x))) = (ALL x:A. b: B(x))";
   497 by Auto_tac;
   498 qed "INT_iff";
   499 
   500 Addsimps [INT_iff];
   501 
   502 val prems = goalw Set.thy [INTER_def]
   503     "(!!x. x:A ==> b: B(x)) ==> b : (INT x:A. B(x))";
   504 by (REPEAT (ares_tac ([CollectI,ballI] @ prems) 1));
   505 qed "INT_I";
   506 
   507 Goal "[| b : (INT x:A. B(x));  a:A |] ==> b: B(a)";
   508 by Auto_tac;
   509 qed "INT_D";
   510 
   511 (*"Classical" elimination -- by the Excluded Middle on a:A *)
   512 val major::prems = goalw Set.thy [INTER_def]
   513     "[| b : (INT x:A. B(x));  b: B(a) ==> R;  a~:A ==> R |] ==> R";
   514 by (rtac (major RS CollectD RS ballE) 1);
   515 by (REPEAT (eresolve_tac prems 1));
   516 qed "INT_E";
   517 
   518 AddSIs [INT_I];
   519 AddEs  [INT_D, INT_E];
   520 
   521 val prems = goal Set.thy
   522     "[| A=B;  !!x. x:B ==> C(x) = D(x) |] ==> \
   523 \    (INT x:A. C(x)) = (INT x:B. D(x))";
   524 by (REPEAT_FIRST (resolve_tac [INT_I,equalityI,subsetI]));
   525 by (REPEAT (dtac INT_D 1
   526      ORELSE ares_tac (prems RL [equalityD1,equalityD2] RL [subsetD]) 1));
   527 qed "INT_cong";
   528 
   529 
   530 section "Union";
   531 
   532 Goalw [Union_def] "(A : Union(C)) = (EX X:C. A:X)";
   533 by (Blast_tac 1);
   534 qed "Union_iff";
   535 
   536 Addsimps [Union_iff];
   537 
   538 (*The order of the premises presupposes that C is rigid; A may be flexible*)
   539 Goal "[| X:C;  A:X |] ==> A : Union(C)";
   540 by Auto_tac;
   541 qed "UnionI";
   542 
   543 val major::prems = goalw Set.thy [Union_def]
   544     "[| A : Union(C);  !!X.[| A:X;  X:C |] ==> R |] ==> R";
   545 by (rtac (major RS UN_E) 1);
   546 by (REPEAT (ares_tac prems 1));
   547 qed "UnionE";
   548 
   549 AddIs  [UnionI];
   550 AddSEs [UnionE];
   551 
   552 
   553 section "Inter";
   554 
   555 Goalw [Inter_def] "(A : Inter(C)) = (ALL X:C. A:X)";
   556 by (Blast_tac 1);
   557 qed "Inter_iff";
   558 
   559 Addsimps [Inter_iff];
   560 
   561 val prems = goalw Set.thy [Inter_def]
   562     "[| !!X. X:C ==> A:X |] ==> A : Inter(C)";
   563 by (REPEAT (ares_tac ([INT_I] @ prems) 1));
   564 qed "InterI";
   565 
   566 (*A "destruct" rule -- every X in C contains A as an element, but
   567   A:X can hold when X:C does not!  This rule is analogous to "spec". *)
   568 Goal "[| A : Inter(C);  X:C |] ==> A:X";
   569 by Auto_tac;
   570 qed "InterD";
   571 
   572 (*"Classical" elimination rule -- does not require proving X:C *)
   573 val major::prems = goalw Set.thy [Inter_def]
   574     "[| A : Inter(C);  X~:C ==> R;  A:X ==> R |] ==> R";
   575 by (rtac (major RS INT_E) 1);
   576 by (REPEAT (eresolve_tac prems 1));
   577 qed "InterE";
   578 
   579 AddSIs [InterI];
   580 AddEs  [InterD, InterE];
   581 
   582 
   583 (*** Image of a set under a function ***)
   584 
   585 (*Frequently b does not have the syntactic form of f(x).*)
   586 val prems = goalw thy [image_def] "[| b=f(x);  x:A |] ==> b : f``A";
   587 by (REPEAT (resolve_tac (prems @ [CollectI,bexI,prem]) 1));
   588 qed "image_eqI";
   589 Addsimps [image_eqI];
   590 
   591 bind_thm ("imageI", refl RS image_eqI);
   592 
   593 (*The eta-expansion gives variable-name preservation.*)
   594 val major::prems = goalw thy [image_def]
   595     "[| b : (%x. f(x))``A;  !!x.[| b=f(x);  x:A |] ==> P |] ==> P"; 
   596 by (rtac (major RS CollectD RS bexE) 1);
   597 by (REPEAT (ares_tac prems 1));
   598 qed "imageE";
   599 
   600 AddIs  [image_eqI];
   601 AddSEs [imageE]; 
   602 
   603 Goalw [o_def] "(f o g)``r = f``(g``r)";
   604 by (Blast_tac 1);
   605 qed "image_compose";
   606 
   607 Goal "f``(A Un B) = f``A Un f``B";
   608 by (Blast_tac 1);
   609 qed "image_Un";
   610 
   611 Goal "(z : f``A) = (EX x:A. z = f x)";
   612 by (Blast_tac 1);
   613 qed "image_iff";
   614 
   615 (*This rewrite rule would confuse users if made default.*)
   616 Goal "(f``A <= B) = (ALL x:A. f(x): B)";
   617 by (Blast_tac 1);
   618 qed "image_subset_iff";
   619 
   620 (*Replaces the three steps subsetI, imageE, hyp_subst_tac, but breaks too
   621   many existing proofs.*)
   622 val prems = goal thy "(!!x. x:A ==> f(x) : B) ==> f``A <= B";
   623 by (blast_tac (claset() addIs prems) 1);
   624 qed "image_subsetI";
   625 
   626 
   627 (*** Range of a function -- just a translation for image! ***)
   628 
   629 Goal "b=f(x) ==> b : range(f)";
   630 by (EVERY1 [etac image_eqI, rtac UNIV_I]);
   631 bind_thm ("range_eqI", UNIV_I RSN (2,image_eqI));
   632 
   633 bind_thm ("rangeI", UNIV_I RS imageI);
   634 
   635 val [major,minor] = goal thy 
   636     "[| b : range(%x. f(x));  !!x. b=f(x) ==> P |] ==> P"; 
   637 by (rtac (major RS imageE) 1);
   638 by (etac minor 1);
   639 qed "rangeE";
   640 
   641 
   642 (*** Set reasoning tools ***)
   643 
   644 
   645 (** Rewrite rules for boolean case-splitting: faster than 
   646 	addsplits[split_if]
   647 **)
   648 
   649 bind_thm ("split_if_eq1", read_instantiate [("P", "%x. x = ?b")] split_if);
   650 bind_thm ("split_if_eq2", read_instantiate [("P", "%x. ?a = x")] split_if);
   651 
   652 bind_thm ("split_if_mem1", 
   653     read_instantiate_sg (sign_of Set.thy) [("P", "%x. x : ?b")] split_if);
   654 bind_thm ("split_if_mem2", 
   655     read_instantiate_sg (sign_of Set.thy) [("P", "%x. ?a : x")] split_if);
   656 
   657 val split_ifs = [if_bool_eq_conj, split_if_eq1, split_if_eq2,
   658 		  split_if_mem1, split_if_mem2];
   659 
   660 
   661 (*Each of these has ALREADY been added to simpset() above.*)
   662 val mem_simps = [insert_iff, empty_iff, Un_iff, Int_iff, Compl_iff, Diff_iff, 
   663                  mem_Collect_eq, UN_iff, Union_iff, INT_iff, Inter_iff];
   664 
   665 (*Not for Addsimps -- it can cause goals to blow up!*)
   666 Goal "(a : (if Q then x else y)) = ((Q --> a:x) & (~Q --> a : y))";
   667 by (Simp_tac 1);
   668 qed "mem_if";
   669 
   670 val mksimps_pairs = ("Ball",[bspec]) :: mksimps_pairs;
   671 
   672 simpset_ref() := simpset() addcongs [ball_cong,bex_cong]
   673                     setmksimps (mksimps mksimps_pairs);
   674 
   675 Addsimps[subset_UNIV, empty_subsetI, subset_refl];
   676 
   677 
   678 (*** < ***)
   679 
   680 Goalw [psubset_def] "!!A::'a set. [| A <= B; A ~= B |] ==> A<B";
   681 by (Blast_tac 1);
   682 qed "psubsetI";
   683 
   684 Goalw [psubset_def]
   685     "!!x. A < insert x B ==> (x ~: A) & A<=B | x:A & A-{x}<B";
   686 by Auto_tac;
   687 qed "psubset_insertD";
   688 
   689 bind_thm ("psubset_eq", psubset_def RS meta_eq_to_obj_eq);