author wenzelm
Sun Nov 02 17:20:45 2014 +0100 (2014-11-02)
changeset 58881 b9556a055632
parent 58783 c6348a062131
child 59425 c5e79df8cc21
permissions -rw-r--r--
modernized header;
     1 (*  Title:      HOL/Library/FuncSet.thy
     2     Author:     Florian Kammueller and Lawrence C Paulson, Lukas Bulwahn
     3 *)
     5 section \<open>Pi and Function Sets\<close>
     7 theory FuncSet
     8 imports Hilbert_Choice Main
     9 begin
    11 definition Pi :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<Rightarrow> 'b) set"
    12   where "Pi A B = {f. \<forall>x. x \<in> A \<longrightarrow> f x \<in> B x}"
    14 definition extensional :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b) set"
    15   where "extensional A = {f. \<forall>x. x \<notin> A \<longrightarrow> f x = undefined}"
    17 definition "restrict" :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b"
    18   where "restrict f A = (\<lambda>x. if x \<in> A then f x else undefined)"
    20 abbreviation funcset :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  (infixr "->" 60)
    21   where "A -> B \<equiv> Pi A (\<lambda>_. B)"
    23 notation (xsymbols)
    24   funcset  (infixr "\<rightarrow>" 60)
    26 syntax
    27   "_Pi"  :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3PI _:_./ _)" 10)
    28   "_lam" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> ('a \<Rightarrow> 'b)"  ("(3%_:_./ _)" [0,0,3] 3)
    29 syntax (xsymbols)
    30   "_Pi" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    31   "_lam" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    32 syntax (HTML output)
    33   "_Pi" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    34   "_lam" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    35 translations
    36   "\<Pi> x\<in>A. B" \<rightleftharpoons> "CONST Pi A (\<lambda>x. B)"
    37   "\<lambda>x\<in>A. f" \<rightleftharpoons> "CONST restrict (\<lambda>x. f) A"
    39 definition "compose" :: "'a set \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'c)"
    40   where "compose A g f = (\<lambda>x\<in>A. g (f x))"
    43 subsection \<open>Basic Properties of @{term Pi}\<close>
    45 lemma Pi_I[intro!]: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> f \<in> Pi A B"
    46   by (simp add: Pi_def)
    48 lemma Pi_I'[simp]: "(\<And>x. x \<in> A \<longrightarrow> f x \<in> B x) \<Longrightarrow> f \<in> Pi A B"
    49   by (simp add:Pi_def)
    51 lemma funcsetI: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B) \<Longrightarrow> f \<in> A \<rightarrow> B"
    52   by (simp add: Pi_def)
    54 lemma Pi_mem: "f \<in> Pi A B \<Longrightarrow> x \<in> A \<Longrightarrow> f x \<in> B x"
    55   by (simp add: Pi_def)
    57 lemma Pi_iff: "f \<in> Pi I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i)"
    58   unfolding Pi_def by auto
    60 lemma PiE [elim]: "f \<in> Pi A B \<Longrightarrow> (f x \<in> B x \<Longrightarrow> Q) \<Longrightarrow> (x \<notin> A \<Longrightarrow> Q) \<Longrightarrow> Q"
    61   by (auto simp: Pi_def)
    63 lemma Pi_cong: "(\<And>w. w \<in> A \<Longrightarrow> f w = g w) \<Longrightarrow> f \<in> Pi A B \<longleftrightarrow> g \<in> Pi A B"
    64   by (auto simp: Pi_def)
    66 lemma funcset_id [simp]: "(\<lambda>x. x) \<in> A \<rightarrow> A"
    67   by auto
    69 lemma funcset_mem: "f \<in> A \<rightarrow> B \<Longrightarrow> x \<in> A \<Longrightarrow> f x \<in> B"
    70   by (simp add: Pi_def)
    72 lemma funcset_image: "f \<in> A \<rightarrow> B \<Longrightarrow> f ` A \<subseteq> B"
    73   by auto
    75 lemma image_subset_iff_funcset: "F ` A \<subseteq> B \<longleftrightarrow> F \<in> A \<rightarrow> B"
    76   by auto
    78 lemma Pi_eq_empty[simp]: "(\<Pi> x \<in> A. B x) = {} \<longleftrightarrow> (\<exists>x\<in>A. B x = {})"
    79   apply (simp add: Pi_def)
    80   apply auto
    81   txt \<open>Converse direction requires Axiom of Choice to exhibit a function
    82   picking an element from each non-empty @{term "B x"}\<close>
    83   apply (drule_tac x = "\<lambda>u. SOME y. y \<in> B u" in spec)
    84   apply auto
    85   apply (cut_tac P = "\<lambda>y. y \<in> B x" in some_eq_ex)
    86   apply auto
    87   done
    89 lemma Pi_empty [simp]: "Pi {} B = UNIV"
    90   by (simp add: Pi_def)
    92 lemma Pi_Int: "Pi I E \<inter> Pi I F = (\<Pi> i\<in>I. E i \<inter> F i)"
    93   by auto
    95 lemma Pi_UN:
    96   fixes A :: "nat \<Rightarrow> 'i \<Rightarrow> 'a set"
    97   assumes "finite I"
    98     and mono: "\<And>i n m. i \<in> I \<Longrightarrow> n \<le> m \<Longrightarrow> A n i \<subseteq> A m i"
    99   shows "(\<Union>n. Pi I (A n)) = (\<Pi> i\<in>I. \<Union>n. A n i)"
   100 proof (intro set_eqI iffI)
   101   fix f
   102   assume "f \<in> (\<Pi> i\<in>I. \<Union>n. A n i)"
   103   then have "\<forall>i\<in>I. \<exists>n. f i \<in> A n i"
   104     by auto
   105   from bchoice[OF this] obtain n where n: "\<And>i. i \<in> I \<Longrightarrow> f i \<in> (A (n i) i)"
   106     by auto
   107   obtain k where k: "\<And>i. i \<in> I \<Longrightarrow> n i \<le> k"
   108     using \<open>finite I\<close> finite_nat_set_iff_bounded_le[of "n`I"] by auto
   109   have "f \<in> Pi I (A k)"
   110   proof (intro Pi_I)
   111     fix i
   112     assume "i \<in> I"
   113     from mono[OF this, of "n i" k] k[OF this] n[OF this]
   114     show "f i \<in> A k i" by auto
   115   qed
   116   then show "f \<in> (\<Union>n. Pi I (A n))"
   117     by auto
   118 qed auto
   120 lemma Pi_UNIV [simp]: "A \<rightarrow> UNIV = UNIV"
   121   by (simp add: Pi_def)
   123 text \<open>Covariance of Pi-sets in their second argument\<close>
   124 lemma Pi_mono: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C x) \<Longrightarrow> Pi A B \<subseteq> Pi A C"
   125   by auto
   127 text \<open>Contravariance of Pi-sets in their first argument\<close>
   128 lemma Pi_anti_mono: "A' \<subseteq> A \<Longrightarrow> Pi A B \<subseteq> Pi A' B"
   129   by auto
   131 lemma prod_final:
   132   assumes 1: "fst \<circ> f \<in> Pi A B"
   133     and 2: "snd \<circ> f \<in> Pi A C"
   134   shows "f \<in> (\<Pi> z \<in> A. B z \<times> C z)"
   135 proof (rule Pi_I)
   136   fix z
   137   assume z: "z \<in> A"
   138   have "f z = (fst (f z), snd (f z))"
   139     by simp
   140   also have "\<dots> \<in> B z \<times> C z"
   141     by (metis SigmaI PiE o_apply 1 2 z)
   142   finally show "f z \<in> B z \<times> C z" .
   143 qed
   145 lemma Pi_split_domain[simp]: "x \<in> Pi (I \<union> J) X \<longleftrightarrow> x \<in> Pi I X \<and> x \<in> Pi J X"
   146   by (auto simp: Pi_def)
   148 lemma Pi_split_insert_domain[simp]: "x \<in> Pi (insert i I) X \<longleftrightarrow> x \<in> Pi I X \<and> x i \<in> X i"
   149   by (auto simp: Pi_def)
   151 lemma Pi_cancel_fupd_range[simp]: "i \<notin> I \<Longrightarrow> x \<in> Pi I (B(i := b)) \<longleftrightarrow> x \<in> Pi I B"
   152   by (auto simp: Pi_def)
   154 lemma Pi_cancel_fupd[simp]: "i \<notin> I \<Longrightarrow> x(i := a) \<in> Pi I B \<longleftrightarrow> x \<in> Pi I B"
   155   by (auto simp: Pi_def)
   157 lemma Pi_fupd_iff: "i \<in> I \<Longrightarrow> f \<in> Pi I (B(i := A)) \<longleftrightarrow> f \<in> Pi (I - {i}) B \<and> f i \<in> A"
   158   apply auto
   159   apply (drule_tac x=x in Pi_mem)
   160   apply (simp_all split: split_if_asm)
   161   apply (drule_tac x=i in Pi_mem)
   162   apply (auto dest!: Pi_mem)
   163   done
   166 subsection \<open>Composition With a Restricted Domain: @{term compose}\<close>
   168 lemma funcset_compose: "f \<in> A \<rightarrow> B \<Longrightarrow> g \<in> B \<rightarrow> C \<Longrightarrow> compose A g f \<in> A \<rightarrow> C"
   169   by (simp add: Pi_def compose_def restrict_def)
   171 lemma compose_assoc:
   172   assumes "f \<in> A \<rightarrow> B"
   173     and "g \<in> B \<rightarrow> C"
   174     and "h \<in> C \<rightarrow> D"
   175   shows "compose A h (compose A g f) = compose A (compose B h g) f"
   176   using assms by (simp add: fun_eq_iff Pi_def compose_def restrict_def)
   178 lemma compose_eq: "x \<in> A \<Longrightarrow> compose A g f x = g (f x)"
   179   by (simp add: compose_def restrict_def)
   181 lemma surj_compose: "f ` A = B \<Longrightarrow> g ` B = C \<Longrightarrow> compose A g f ` A = C"
   182   by (auto simp add: image_def compose_eq)
   185 subsection \<open>Bounded Abstraction: @{term restrict}\<close>
   187 lemma restrict_in_funcset: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B) \<Longrightarrow> (\<lambda>x\<in>A. f x) \<in> A \<rightarrow> B"
   188   by (simp add: Pi_def restrict_def)
   190 lemma restrictI[intro!]: "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> (\<lambda>x\<in>A. f x) \<in> Pi A B"
   191   by (simp add: Pi_def restrict_def)
   193 lemma restrict_apply[simp]: "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else undefined)"
   194   by (simp add: restrict_def)
   196 lemma restrict_apply': "x \<in> A \<Longrightarrow> (\<lambda>y\<in>A. f y) x = f x"
   197   by simp
   199 lemma restrict_ext: "(\<And>x. x \<in> A \<Longrightarrow> f x = g x) \<Longrightarrow> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
   200   by (simp add: fun_eq_iff Pi_def restrict_def)
   202 lemma restrict_UNIV: "restrict f UNIV = f"
   203   by (simp add: restrict_def)
   205 lemma inj_on_restrict_eq [simp]: "inj_on (restrict f A) A = inj_on f A"
   206   by (simp add: inj_on_def restrict_def)
   208 lemma Id_compose: "f \<in> A \<rightarrow> B \<Longrightarrow> f \<in> extensional A \<Longrightarrow> compose A (\<lambda>y\<in>B. y) f = f"
   209   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   211 lemma compose_Id: "g \<in> A \<rightarrow> B \<Longrightarrow> g \<in> extensional A \<Longrightarrow> compose A g (\<lambda>x\<in>A. x) = g"
   212   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   214 lemma image_restrict_eq [simp]: "(restrict f A) ` A = f ` A"
   215   by (auto simp add: restrict_def)
   217 lemma restrict_restrict[simp]: "restrict (restrict f A) B = restrict f (A \<inter> B)"
   218   unfolding restrict_def by (simp add: fun_eq_iff)
   220 lemma restrict_fupd[simp]: "i \<notin> I \<Longrightarrow> restrict (f (i := x)) I = restrict f I"
   221   by (auto simp: restrict_def)
   223 lemma restrict_upd[simp]: "i \<notin> I \<Longrightarrow> (restrict f I)(i := y) = restrict (f(i := y)) (insert i I)"
   224   by (auto simp: fun_eq_iff)
   226 lemma restrict_Pi_cancel: "restrict x I \<in> Pi I A \<longleftrightarrow> x \<in> Pi I A"
   227   by (auto simp: restrict_def Pi_def)
   230 subsection \<open>Bijections Between Sets\<close>
   232 text \<open>The definition of @{const bij_betw} is in @{text "Fun.thy"}, but most of
   233 the theorems belong here, or need at least @{term Hilbert_Choice}.\<close>
   235 lemma bij_betwI:
   236   assumes "f \<in> A \<rightarrow> B"
   237     and "g \<in> B \<rightarrow> A"
   238     and g_f: "\<And>x. x\<in>A \<Longrightarrow> g (f x) = x"
   239     and f_g: "\<And>y. y\<in>B \<Longrightarrow> f (g y) = y"
   240   shows "bij_betw f A B"
   241   unfolding bij_betw_def
   242 proof
   243   show "inj_on f A"
   244     by (metis g_f inj_on_def)
   245   have "f ` A \<subseteq> B"
   246     using \<open>f \<in> A \<rightarrow> B\<close> by auto
   247   moreover
   248   have "B \<subseteq> f ` A"
   249     by auto (metis Pi_mem \<open>g \<in> B \<rightarrow> A\<close> f_g image_iff)
   250   ultimately show "f ` A = B"
   251     by blast
   252 qed
   254 lemma bij_betw_imp_funcset: "bij_betw f A B \<Longrightarrow> f \<in> A \<rightarrow> B"
   255   by (auto simp add: bij_betw_def)
   257 lemma inj_on_compose: "bij_betw f A B \<Longrightarrow> inj_on g B \<Longrightarrow> inj_on (compose A g f) A"
   258   by (auto simp add: bij_betw_def inj_on_def compose_eq)
   260 lemma bij_betw_compose: "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (compose A g f) A C"
   261   apply (simp add: bij_betw_def compose_eq inj_on_compose)
   262   apply (auto simp add: compose_def image_def)
   263   done
   265 lemma bij_betw_restrict_eq [simp]: "bij_betw (restrict f A) A B = bij_betw f A B"
   266   by (simp add: bij_betw_def)
   269 subsection \<open>Extensionality\<close>
   271 lemma extensional_empty[simp]: "extensional {} = {\<lambda>x. undefined}"
   272   unfolding extensional_def by auto
   274 lemma extensional_arb: "f \<in> extensional A \<Longrightarrow> x \<notin> A \<Longrightarrow> f x = undefined"
   275   by (simp add: extensional_def)
   277 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
   278   by (simp add: restrict_def extensional_def)
   280 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
   281   by (simp add: compose_def)
   283 lemma extensionalityI:
   284   assumes "f \<in> extensional A"
   285     and "g \<in> extensional A"
   286     and "\<And>x. x \<in> A \<Longrightarrow> f x = g x"
   287   shows "f = g"
   288   using assms by (force simp add: fun_eq_iff extensional_def)
   290 lemma extensional_restrict:  "f \<in> extensional A \<Longrightarrow> restrict f A = f"
   291   by (rule extensionalityI[OF restrict_extensional]) auto
   293 lemma extensional_subset: "f \<in> extensional A \<Longrightarrow> A \<subseteq> B \<Longrightarrow> f \<in> extensional B"
   294   unfolding extensional_def by auto
   296 lemma inv_into_funcset: "f ` A = B \<Longrightarrow> (\<lambda>x\<in>B. inv_into A f x) \<in> B \<rightarrow> A"
   297   by (unfold inv_into_def) (fast intro: someI2)
   299 lemma compose_inv_into_id: "bij_betw f A B \<Longrightarrow> compose A (\<lambda>y\<in>B. inv_into A f y) f = (\<lambda>x\<in>A. x)"
   300   apply (simp add: bij_betw_def compose_def)
   301   apply (rule restrict_ext, auto)
   302   done
   304 lemma compose_id_inv_into: "f ` A = B \<Longrightarrow> compose B f (\<lambda>y\<in>B. inv_into A f y) = (\<lambda>x\<in>B. x)"
   305   apply (simp add: compose_def)
   306   apply (rule restrict_ext)
   307   apply (simp add: f_inv_into_f)
   308   done
   310 lemma extensional_insert[intro, simp]:
   311   assumes "a \<in> extensional (insert i I)"
   312   shows "a(i := b) \<in> extensional (insert i I)"
   313   using assms unfolding extensional_def by auto
   315 lemma extensional_Int[simp]: "extensional I \<inter> extensional I' = extensional (I \<inter> I')"
   316   unfolding extensional_def by auto
   318 lemma extensional_UNIV[simp]: "extensional UNIV = UNIV"
   319   by (auto simp: extensional_def)
   321 lemma restrict_extensional_sub[intro]: "A \<subseteq> B \<Longrightarrow> restrict f A \<in> extensional B"
   322   unfolding restrict_def extensional_def by auto
   324 lemma extensional_insert_undefined[intro, simp]:
   325   "a \<in> extensional (insert i I) \<Longrightarrow> a(i := undefined) \<in> extensional I"
   326   unfolding extensional_def by auto
   328 lemma extensional_insert_cancel[intro, simp]:
   329   "a \<in> extensional I \<Longrightarrow> a \<in> extensional (insert i I)"
   330   unfolding extensional_def by auto
   333 subsection \<open>Cardinality\<close>
   335 lemma card_inj: "f \<in> A \<rightarrow> B \<Longrightarrow> inj_on f A \<Longrightarrow> finite B \<Longrightarrow> card A \<le> card B"
   336   by (rule card_inj_on_le) auto
   338 lemma card_bij:
   339   assumes "f \<in> A \<rightarrow> B" "inj_on f A"
   340     and "g \<in> B \<rightarrow> A" "inj_on g B"
   341     and "finite A" "finite B"
   342   shows "card A = card B"
   343   using assms by (blast intro: card_inj order_antisym)
   346 subsection \<open>Extensional Function Spaces\<close>
   348 definition PiE :: "'a set \<Rightarrow> ('a \<Rightarrow> 'b set) \<Rightarrow> ('a \<Rightarrow> 'b) set"
   349   where "PiE S T = Pi S T \<inter> extensional S"
   351 abbreviation "Pi\<^sub>E A B \<equiv> PiE A B"
   353 syntax
   354   "_PiE" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3PIE _:_./ _)" 10)
   355 syntax (xsymbols)
   356   "_PiE" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3\<Pi>\<^sub>E _\<in>_./ _)" 10)
   357 syntax (HTML output)
   358   "_PiE" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set"  ("(3\<Pi>\<^sub>E _\<in>_./ _)" 10)
   359 translations "\<Pi>\<^sub>E x\<in>A. B" \<rightleftharpoons> "CONST Pi\<^sub>E A (\<lambda>x. B)"
   361 abbreviation extensional_funcset :: "'a set \<Rightarrow> 'b set \<Rightarrow> ('a \<Rightarrow> 'b) set" (infixr "->\<^sub>E" 60)
   362   where "A ->\<^sub>E B \<equiv> (\<Pi>\<^sub>E i\<in>A. B)"
   364 notation (xsymbols)
   365   extensional_funcset  (infixr "\<rightarrow>\<^sub>E" 60)
   367 lemma extensional_funcset_def: "extensional_funcset S T = (S \<rightarrow> T) \<inter> extensional S"
   368   by (simp add: PiE_def)
   370 lemma PiE_empty_domain[simp]: "PiE {} T = {\<lambda>x. undefined}"
   371   unfolding PiE_def by simp
   373 lemma PiE_UNIV_domain: "PiE UNIV T = Pi UNIV T"
   374   unfolding PiE_def by simp
   376 lemma PiE_empty_range[simp]: "i \<in> I \<Longrightarrow> F i = {} \<Longrightarrow> (\<Pi>\<^sub>E i\<in>I. F i) = {}"
   377   unfolding PiE_def by auto
   379 lemma PiE_eq_empty_iff: "Pi\<^sub>E I F = {} \<longleftrightarrow> (\<exists>i\<in>I. F i = {})"
   380 proof
   381   assume "Pi\<^sub>E I F = {}"
   382   show "\<exists>i\<in>I. F i = {}"
   383   proof (rule ccontr)
   384     assume "\<not> ?thesis"
   385     then have "\<forall>i. \<exists>y. (i \<in> I \<longrightarrow> y \<in> F i) \<and> (i \<notin> I \<longrightarrow> y = undefined)"
   386       by auto
   387     from choice[OF this]
   388     obtain f where " \<forall>x. (x \<in> I \<longrightarrow> f x \<in> F x) \<and> (x \<notin> I \<longrightarrow> f x = undefined)" ..
   389     then have "f \<in> Pi\<^sub>E I F"
   390       by (auto simp: extensional_def PiE_def)
   391     with \<open>Pi\<^sub>E I F = {}\<close> show False
   392       by auto
   393   qed
   394 qed (auto simp: PiE_def)
   396 lemma PiE_arb: "f \<in> PiE S T \<Longrightarrow> x \<notin> S \<Longrightarrow> f x = undefined"
   397   unfolding PiE_def by auto (auto dest!: extensional_arb)
   399 lemma PiE_mem: "f \<in> PiE S T \<Longrightarrow> x \<in> S \<Longrightarrow> f x \<in> T x"
   400   unfolding PiE_def by auto
   402 lemma PiE_fun_upd: "y \<in> T x \<Longrightarrow> f \<in> PiE S T \<Longrightarrow> f(x := y) \<in> PiE (insert x S) T"
   403   unfolding PiE_def extensional_def by auto
   405 lemma fun_upd_in_PiE: "x \<notin> S \<Longrightarrow> f \<in> PiE (insert x S) T \<Longrightarrow> f(x := undefined) \<in> PiE S T"
   406   unfolding PiE_def extensional_def by auto
   408 lemma PiE_insert_eq:
   409   assumes "x \<notin> S"
   410   shows "PiE (insert x S) T = (\<lambda>(y, g). g(x := y)) ` (T x \<times> PiE S T)"
   411 proof -
   412   {
   413     fix f assume "f \<in> PiE (insert x S) T"
   414     with assms have "f \<in> (\<lambda>(y, g). g(x := y)) ` (T x \<times> PiE S T)"
   415       by (auto intro!: image_eqI[where x="(f x, f(x := undefined))"] intro: fun_upd_in_PiE PiE_mem)
   416   }
   417   then show ?thesis
   418     using assms by (auto intro: PiE_fun_upd)
   419 qed
   421 lemma PiE_Int: "Pi\<^sub>E I A \<inter> Pi\<^sub>E I B = Pi\<^sub>E I (\<lambda>x. A x \<inter> B x)"
   422   by (auto simp: PiE_def)
   424 lemma PiE_cong: "(\<And>i. i\<in>I \<Longrightarrow> A i = B i) \<Longrightarrow> Pi\<^sub>E I A = Pi\<^sub>E I B"
   425   unfolding PiE_def by (auto simp: Pi_cong)
   427 lemma PiE_E [elim]:
   428   assumes "f \<in> PiE A B"
   429   obtains "x \<in> A" and "f x \<in> B x"
   430     | "x \<notin> A" and "f x = undefined"
   431   using assms by (auto simp: Pi_def PiE_def extensional_def)
   433 lemma PiE_I[intro!]:
   434   "(\<And>x. x \<in> A \<Longrightarrow> f x \<in> B x) \<Longrightarrow> (\<And>x. x \<notin> A \<Longrightarrow> f x = undefined) \<Longrightarrow> f \<in> PiE A B"
   435   by (simp add: PiE_def extensional_def)
   437 lemma PiE_mono: "(\<And>x. x \<in> A \<Longrightarrow> B x \<subseteq> C x) \<Longrightarrow> PiE A B \<subseteq> PiE A C"
   438   by auto
   440 lemma PiE_iff: "f \<in> PiE I X \<longleftrightarrow> (\<forall>i\<in>I. f i \<in> X i) \<and> f \<in> extensional I"
   441   by (simp add: PiE_def Pi_iff)
   443 lemma PiE_restrict[simp]:  "f \<in> PiE A B \<Longrightarrow> restrict f A = f"
   444   by (simp add: extensional_restrict PiE_def)
   446 lemma restrict_PiE[simp]: "restrict f I \<in> PiE I S \<longleftrightarrow> f \<in> Pi I S"
   447   by (auto simp: PiE_iff)
   449 lemma PiE_eq_subset:
   450   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
   451     and eq: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   452     and "i \<in> I"
   453   shows "F i \<subseteq> F' i"
   454 proof
   455   fix x
   456   assume "x \<in> F i"
   457   with ne have "\<forall>j. \<exists>y. (j \<in> I \<longrightarrow> y \<in> F j \<and> (i = j \<longrightarrow> x = y)) \<and> (j \<notin> I \<longrightarrow> y = undefined)"
   458     by auto
   459   from choice[OF this] obtain f
   460     where f: " \<forall>j. (j \<in> I \<longrightarrow> f j \<in> F j \<and> (i = j \<longrightarrow> x = f j)) \<and> (j \<notin> I \<longrightarrow> f j = undefined)" ..
   461   then have "f \<in> Pi\<^sub>E I F"
   462     by (auto simp: extensional_def PiE_def)
   463   then have "f \<in> Pi\<^sub>E I F'"
   464     using assms by simp
   465   then show "x \<in> F' i"
   466     using f \<open>i \<in> I\<close> by (auto simp: PiE_def)
   467 qed
   469 lemma PiE_eq_iff_not_empty:
   470   assumes ne: "\<And>i. i \<in> I \<Longrightarrow> F i \<noteq> {}" "\<And>i. i \<in> I \<Longrightarrow> F' i \<noteq> {}"
   471   shows "Pi\<^sub>E I F = Pi\<^sub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i)"
   472 proof (intro iffI ballI)
   473   fix i
   474   assume eq: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   475   assume i: "i \<in> I"
   476   show "F i = F' i"
   477     using PiE_eq_subset[of I F F', OF ne eq i]
   478     using PiE_eq_subset[of I F' F, OF ne(2,1) eq[symmetric] i]
   479     by auto
   480 qed (auto simp: PiE_def)
   482 lemma PiE_eq_iff:
   483   "Pi\<^sub>E I F = Pi\<^sub>E I F' \<longleftrightarrow> (\<forall>i\<in>I. F i = F' i) \<or> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
   484 proof (intro iffI disjCI)
   485   assume eq[simp]: "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   486   assume "\<not> ((\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {}))"
   487   then have "(\<forall>i\<in>I. F i \<noteq> {}) \<and> (\<forall>i\<in>I. F' i \<noteq> {})"
   488     using PiE_eq_empty_iff[of I F] PiE_eq_empty_iff[of I F'] by auto
   489   with PiE_eq_iff_not_empty[of I F F'] show "\<forall>i\<in>I. F i = F' i"
   490     by auto
   491 next
   492   assume "(\<forall>i\<in>I. F i = F' i) \<or> (\<exists>i\<in>I. F i = {}) \<and> (\<exists>i\<in>I. F' i = {})"
   493   then show "Pi\<^sub>E I F = Pi\<^sub>E I F'"
   494     using PiE_eq_empty_iff[of I F] PiE_eq_empty_iff[of I F'] by (auto simp: PiE_def)
   495 qed
   497 lemma extensional_funcset_fun_upd_restricts_rangeI:
   498   "\<forall>y \<in> S. f x \<noteq> f y \<Longrightarrow> f \<in> (insert x S) \<rightarrow>\<^sub>E T \<Longrightarrow> f(x := undefined) \<in> S \<rightarrow>\<^sub>E (T - {f x})"
   499   unfolding extensional_funcset_def extensional_def
   500   apply auto
   501   apply (case_tac "x = xa")
   502   apply auto
   503   done
   505 lemma extensional_funcset_fun_upd_extends_rangeI:
   506   assumes "a \<in> T" "f \<in> S \<rightarrow>\<^sub>E (T - {a})"
   507   shows "f(x := a) \<in> insert x S \<rightarrow>\<^sub>E  T"
   508   using assms unfolding extensional_funcset_def extensional_def by auto
   511 subsubsection \<open>Injective Extensional Function Spaces\<close>
   513 lemma extensional_funcset_fun_upd_inj_onI:
   514   assumes "f \<in> S \<rightarrow>\<^sub>E (T - {a})"
   515     and "inj_on f S"
   516   shows "inj_on (f(x := a)) S"
   517   using assms
   518   unfolding extensional_funcset_def by (auto intro!: inj_on_fun_updI)
   520 lemma extensional_funcset_extend_domain_inj_on_eq:
   521   assumes "x \<notin> S"
   522   shows "{f. f \<in> (insert x S) \<rightarrow>\<^sub>E T \<and> inj_on f (insert x S)} =
   523     (\<lambda>(y, g). g(x:=y)) ` {(y, g). y \<in> T \<and> g \<in> S \<rightarrow>\<^sub>E (T - {y}) \<and> inj_on g S}"
   524   using assms
   525   apply (auto del: PiE_I PiE_E)
   526   apply (auto intro: extensional_funcset_fun_upd_inj_onI
   527     extensional_funcset_fun_upd_extends_rangeI del: PiE_I PiE_E)
   528   apply (auto simp add: image_iff inj_on_def)
   529   apply (rule_tac x="xa x" in exI)
   530   apply (auto intro: PiE_mem del: PiE_I PiE_E)
   531   apply (rule_tac x="xa(x := undefined)" in exI)
   532   apply (auto intro!: extensional_funcset_fun_upd_restricts_rangeI)
   533   apply (auto dest!: PiE_mem split: split_if_asm)
   534   done
   536 lemma extensional_funcset_extend_domain_inj_onI:
   537   assumes "x \<notin> S"
   538   shows "inj_on (\<lambda>(y, g). g(x := y)) {(y, g). y \<in> T \<and> g \<in> S \<rightarrow>\<^sub>E (T - {y}) \<and> inj_on g S}"
   539   using assms
   540   apply (auto intro!: inj_onI)
   541   apply (metis fun_upd_same)
   542   apply (metis assms PiE_arb fun_upd_triv fun_upd_upd)
   543   done
   546 subsubsection \<open>Cardinality\<close>
   548 lemma finite_PiE: "finite S \<Longrightarrow> (\<And>i. i \<in> S \<Longrightarrow> finite (T i)) \<Longrightarrow> finite (\<Pi>\<^sub>E i \<in> S. T i)"
   549   by (induct S arbitrary: T rule: finite_induct) (simp_all add: PiE_insert_eq)
   551 lemma inj_combinator: "x \<notin> S \<Longrightarrow> inj_on (\<lambda>(y, g). g(x := y)) (T x \<times> Pi\<^sub>E S T)"
   552 proof (safe intro!: inj_onI ext)
   553   fix f y g z
   554   assume "x \<notin> S"
   555   assume fg: "f \<in> Pi\<^sub>E S T" "g \<in> Pi\<^sub>E S T"
   556   assume "f(x := y) = g(x := z)"
   557   then have *: "\<And>i. (f(x := y)) i = (g(x := z)) i"
   558     unfolding fun_eq_iff by auto
   559   from this[of x] show "y = z" by simp
   560   fix i from *[of i] \<open>x \<notin> S\<close> fg show "f i = g i"
   561     by (auto split: split_if_asm simp: PiE_def extensional_def)
   562 qed
   564 lemma card_PiE: "finite S \<Longrightarrow> card (\<Pi>\<^sub>E i \<in> S. T i) = (\<Prod> i\<in>S. card (T i))"
   565 proof (induct rule: finite_induct)
   566   case empty
   567   then show ?case by auto
   568 next
   569   case (insert x S)
   570   then show ?case
   571     by (simp add: PiE_insert_eq inj_combinator card_image card_cartesian_product)
   572 qed
   574 end