src/Pure/General/symbol_pos.ML
author wenzelm
Fri Oct 31 22:02:49 2014 +0100 (2014-10-31)
changeset 58854 b979c781c2db
parent 58850 1bb0ad7827b4
child 58864 505a8150368a
permissions -rw-r--r--
discontinued obsolete \<^sync> marker;
     1 (*  Title:      Pure/General/symbol_pos.ML
     2     Author:     Makarius
     3 
     4 Symbols with explicit position information.
     5 *)
     6 
     7 signature SYMBOL_POS =
     8 sig
     9   type T = Symbol.symbol * Position.T
    10   val symbol: T -> Symbol.symbol
    11   val $$ : Symbol.symbol -> T list -> T * T list
    12   val ~$$ : Symbol.symbol -> T list -> T * T list
    13   val $$$ : Symbol.symbol -> T list -> T list * T list
    14   val ~$$$ : Symbol.symbol -> T list -> T list * T list
    15   val content: T list -> string
    16   val range: T list -> Position.range
    17   val is_eof: T -> bool
    18   val stopper: T Scan.stopper
    19   val !!! : Scan.message -> (T list -> 'a) -> T list -> 'a
    20   val scan_pos: T list -> Position.T * T list
    21   val scan_string_q: string -> T list -> (Position.T * (T list * Position.T)) * T list
    22   val scan_string_qq: string -> T list -> (Position.T * (T list * Position.T)) * T list
    23   val scan_string_bq: string -> T list -> (Position.T * (T list * Position.T)) * T list
    24   val recover_string_q: T list -> T list * T list
    25   val recover_string_qq: T list -> T list * T list
    26   val recover_string_bq: T list -> T list * T list
    27   val quote_string_q: string -> string
    28   val quote_string_qq: string -> string
    29   val quote_string_bq: string -> string
    30   val scan_cartouche: string -> T list -> T list * T list
    31   val recover_cartouche: T list -> T list * T list
    32   val cartouche_content: T list -> T list
    33   val scan_comment: string -> T list -> T list * T list
    34   val scan_comment_body: string -> T list -> T list * T list
    35   val recover_comment: T list -> T list * T list
    36   val source: Position.T -> (Symbol.symbol, 'a) Source.source ->
    37     (T, Position.T * (Symbol.symbol, 'a) Source.source) Source.source
    38   type text = string
    39   val implode: T list -> text
    40   val implode_range: Position.T -> Position.T -> T list -> text * Position.range
    41   val explode: text * Position.T -> T list
    42   type source = {delimited: bool, text: text, pos: Position.T}
    43   val source_explode: source -> T list
    44   val source_content: source -> string * Position.T
    45   val scan_ident: T list -> T list * T list
    46   val is_identifier: string -> bool
    47 end;
    48 
    49 structure Symbol_Pos: SYMBOL_POS =
    50 struct
    51 
    52 (* type T *)
    53 
    54 type T = Symbol.symbol * Position.T;
    55 
    56 fun symbol ((s, _): T) = s;
    57 
    58 val content = implode o map symbol;
    59 
    60 fun range (syms as (_, pos) :: _) =
    61       let val pos' = List.last syms |-> Position.advance
    62       in Position.range pos pos' end
    63   | range [] = Position.no_range;
    64 
    65 
    66 (* stopper *)
    67 
    68 fun mk_eof pos = (Symbol.eof, pos);
    69 val eof = mk_eof Position.none;
    70 
    71 val is_eof = Symbol.is_eof o symbol;
    72 
    73 val stopper =
    74   Scan.stopper (fn [] => eof | inp => mk_eof (List.last inp |-> Position.advance)) is_eof;
    75 
    76 
    77 (* basic scanners *)
    78 
    79 fun !!! text scan =
    80   let
    81     fun get_pos [] = " (end-of-input)"
    82       | get_pos ((_, pos) :: _) = Position.here pos;
    83 
    84     fun err (syms, msg) = fn () =>
    85       text () ^ get_pos syms ^
    86       Markup.markup Markup.no_report (" at " ^ Symbol.beginning 10 (map symbol syms)) ^
    87       (case msg of NONE => "" | SOME m => "\n" ^ m ());
    88   in Scan.!! err scan end;
    89 
    90 fun $$ s = Scan.one (fn x => symbol x = s);
    91 fun ~$$ s = Scan.one (fn x => symbol x <> s);
    92 
    93 fun $$$ s = Scan.one (fn x => symbol x = s) >> single;
    94 fun ~$$$ s = Scan.one (fn x => symbol x <> s) >> single;
    95 
    96 val scan_pos = Scan.ahead (Scan.one (K true)) >> (fn (_, pos): T => pos);
    97 
    98 
    99 (* scan string literals *)
   100 
   101 local
   102 
   103 val char_code =
   104   Scan.one (Symbol.is_ascii_digit o symbol) --
   105   Scan.one (Symbol.is_ascii_digit o symbol) --
   106   Scan.one (Symbol.is_ascii_digit o symbol) :|--
   107   (fn (((a, pos), (b, _)), (c, _)) =>
   108     let val (n, _) = Library.read_int [a, b, c]
   109     in if n <= 255 then Scan.succeed [(chr n, pos)] else Scan.fail end);
   110 
   111 fun scan_str q err_prefix =
   112   $$$ "\\" |-- !!! (fn () => err_prefix ^ "bad escape character in string")
   113     ($$$ q || $$$ "\\" || char_code) ||
   114   Scan.one (fn (s, _) => s <> q andalso s <> "\\" andalso Symbol.not_eof s) >> single;
   115 
   116 fun scan_strs q err_prefix =
   117   Scan.ahead ($$ q) |--
   118     !!! (fn () => err_prefix ^ "unclosed string literal")
   119       ((scan_pos --| $$$ q) --
   120         ((Scan.repeat (scan_str q err_prefix) >> flat) -- ($$$ q |-- scan_pos)));
   121 
   122 fun recover_strs q =
   123   $$$ q @@@ (Scan.repeat (Scan.permissive (scan_str q "")) >> flat);
   124 
   125 in
   126 
   127 val scan_string_q = scan_strs "'";
   128 val scan_string_qq = scan_strs "\"";
   129 val scan_string_bq = scan_strs "`";
   130 
   131 val recover_string_q = recover_strs "'";
   132 val recover_string_qq = recover_strs "\"";
   133 val recover_string_bq = recover_strs "`";
   134 
   135 end;
   136 
   137 
   138 (* quote string literals *)
   139 
   140 local
   141 
   142 fun char_code i =
   143   (if i < 10 then "00" else if i < 100 then "0" else "") ^ string_of_int i;
   144 
   145 fun quote_str q s =
   146   if Symbol.is_ascii_control s then "\\" ^ char_code (ord s)
   147   else if s = q orelse s = "\\" then "\\" ^ s
   148   else s;
   149 
   150 fun quote_string q = enclose q q o implode o map (quote_str q) o Symbol.explode;
   151 
   152 in
   153 
   154 val quote_string_q = quote_string "'";
   155 val quote_string_qq = quote_string "\"";
   156 val quote_string_bq = quote_string "`";
   157 
   158 end;
   159 
   160 
   161 (* nested text cartouches *)
   162 
   163 val scan_cartouche_depth =
   164   Scan.repeat1 (Scan.depend (fn (d: int) =>
   165     $$ "\\<open>" >> pair (d + 1) ||
   166       (if d > 0 then
   167         Scan.one (fn (s, _) => s <> "\\<close>" andalso Symbol.not_eof s) >> pair d ||
   168         $$ "\\<close>" >> pair (d - 1)
   169       else Scan.fail)));
   170 
   171 fun scan_cartouche err_prefix =
   172   Scan.ahead ($$ "\\<open>") |--
   173     !!! (fn () => err_prefix ^ "unclosed text cartouche")
   174       (Scan.provide (fn d => d = 0) 0 scan_cartouche_depth);
   175 
   176 val recover_cartouche = Scan.pass 0 scan_cartouche_depth;
   177 
   178 fun cartouche_content syms =
   179   let
   180     fun err () =
   181       error ("Malformed text cartouche: "
   182         ^ quote (content syms) ^ Position.here (#1 (range syms)));
   183   in
   184     (case syms of
   185       ("\\<open>", _) :: rest =>
   186         (case rev rest of
   187           ("\\<close>", _) :: rrest => rev rrest
   188         | _ => err ())
   189     | _ => err ())
   190   end;
   191 
   192 
   193 (* ML-style comments *)
   194 
   195 local
   196 
   197 val scan_cmt =
   198   Scan.depend (fn (d: int) => $$$ "(" @@@ $$$ "*" >> pair (d + 1)) ||
   199   Scan.depend (fn 0 => Scan.fail | d => $$$ "*" @@@ $$$ ")" >> pair (d - 1)) ||
   200   Scan.lift ($$$ "*" --| Scan.ahead (~$$$ ")")) ||
   201   Scan.lift (Scan.one (fn (s, _) => s <> "*" andalso Symbol.not_eof s)) >> single;
   202 
   203 val scan_cmts = Scan.pass 0 (Scan.repeat scan_cmt >> flat);
   204 
   205 in
   206 
   207 fun scan_comment err_prefix =
   208   Scan.ahead ($$ "(" -- $$ "*") |--
   209     !!! (fn () => err_prefix ^ "unclosed comment")
   210       ($$$ "(" @@@ $$$ "*" @@@ scan_cmts @@@ $$$ "*" @@@ $$$ ")");
   211 
   212 fun scan_comment_body err_prefix =
   213   Scan.ahead ($$ "(" -- $$ "*") |--
   214     !!! (fn () => err_prefix ^ "unclosed comment")
   215       ($$ "(" |-- $$ "*" |-- scan_cmts --| $$ "*" --| $$ ")");
   216 
   217 val recover_comment =
   218   $$$ "(" @@@ $$$ "*" @@@ scan_cmts;
   219 
   220 end;
   221 
   222 
   223 (* source *)
   224 
   225 fun source pos =
   226   Source.source' pos Symbol.stopper (Scan.bulk (Scan.depend (fn pos =>
   227     Scan.one Symbol.not_eof >> (fn s => (Position.advance s pos, (s, pos)))))) NONE;
   228 
   229 
   230 (* compact representation -- with Symbol.DEL padding *)
   231 
   232 type text = string;
   233 
   234 fun pad [] = []
   235   | pad [(s, _)] = [s]
   236   | pad ((s1, pos1) :: (rest as (_, pos2) :: _)) =
   237       let
   238         val end_pos1 = Position.advance s1 pos1;
   239         val d = Int.max (0, Position.distance_of end_pos1 pos2);
   240       in s1 :: replicate d Symbol.DEL @ pad rest end;
   241 
   242 val implode = implode o pad;
   243 
   244 fun implode_range pos1 pos2 syms =
   245   let val syms' = (("", pos1) :: syms @ [("", pos2)])
   246   in (implode syms', range syms') end;
   247 
   248 fun explode (str, pos) =
   249   let
   250     val (res, _) =
   251       fold (fn s => fn (res, p) => ((s, p) :: res, Position.advance s p))
   252         (Symbol.explode str) ([], Position.reset_range pos);
   253   in fold (fn (s, p) => if s = Symbol.DEL then I else cons (s, p)) res [] end;
   254 
   255 
   256 (* full source information *)
   257 
   258 type source = {delimited: bool, text: text, pos: Position.T};
   259 
   260 fun source_explode {delimited = _, text, pos} = explode (text, pos);
   261 
   262 fun source_content {delimited = _, text, pos} =
   263   let val syms = explode (text, pos) in (content syms, pos) end;
   264 
   265 
   266 (* identifiers *)
   267 
   268 local
   269 
   270 val letter = Scan.one (symbol #> Symbol.is_letter);
   271 val letdigs1 = Scan.many1 (symbol #> Symbol.is_letdig);
   272 
   273 val sub = Scan.one (symbol #> (fn s => s = "\\<^sub>"));
   274 
   275 in
   276 
   277 val scan_ident = letter ::: (Scan.repeat (letdigs1 || sub ::: letdigs1) >> flat);
   278 
   279 end;
   280 
   281 fun is_identifier s =
   282   Symbol.is_ascii_identifier s orelse
   283     (case try (Scan.finite stopper scan_ident) (explode (s, Position.none)) of
   284       SOME (_, []) => true
   285     | _ => false);
   286 
   287 end;
   288 
   289 structure Basic_Symbol_Pos =   (*not open by default*)
   290 struct
   291   val $$ = Symbol_Pos.$$;
   292   val ~$$ = Symbol_Pos.~$$;
   293   val $$$ = Symbol_Pos.$$$;
   294   val ~$$$ = Symbol_Pos.~$$$;
   295 end;
   296