src/HOL/Topological_Spaces.thy
author wenzelm
Thu Mar 20 21:07:57 2014 +0100 (2014-03-20)
changeset 56231 b98813774a63
parent 56166 9a241bc276cd
child 56289 d8d2a2b97168
permissions -rw-r--r--
enforce subgoal boundaries via SUBGOAL/SUBGOAL_CASES -- clean tactical failure if out-of-range;
     1 (*  Title:      HOL/Topological_Spaces.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 header {* Topological Spaces *}
     7 
     8 theory Topological_Spaces
     9 imports Main Conditionally_Complete_Lattices
    10 begin
    11 
    12 subsection {* Topological space *}
    13 
    14 class "open" =
    15   fixes "open" :: "'a set \<Rightarrow> bool"
    16 
    17 class topological_space = "open" +
    18   assumes open_UNIV [simp, intro]: "open UNIV"
    19   assumes open_Int [intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<inter> T)"
    20   assumes open_Union [intro]: "\<forall>S\<in>K. open S \<Longrightarrow> open (\<Union> K)"
    21 begin
    22 
    23 definition
    24   closed :: "'a set \<Rightarrow> bool" where
    25   "closed S \<longleftrightarrow> open (- S)"
    26 
    27 lemma open_empty [intro, simp]: "open {}"
    28   using open_Union [of "{}"] by simp
    29 
    30 lemma open_Un [intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<union> T)"
    31   using open_Union [of "{S, T}"] by simp
    32 
    33 lemma open_UN [intro]: "\<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Union>x\<in>A. B x)"
    34   using open_Union [of "B ` A"] by simp
    35 
    36 lemma open_Inter [intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. open T \<Longrightarrow> open (\<Inter>S)"
    37   by (induct set: finite) auto
    38 
    39 lemma open_INT [intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Inter>x\<in>A. B x)"
    40   using open_Inter [of "B ` A"] by simp
    41 
    42 lemma openI:
    43   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S"
    44   shows "open S"
    45 proof -
    46   have "open (\<Union>{T. open T \<and> T \<subseteq> S})" by auto
    47   moreover have "\<Union>{T. open T \<and> T \<subseteq> S} = S" by (auto dest!: assms)
    48   ultimately show "open S" by simp
    49 qed
    50 
    51 lemma closed_empty [intro, simp]:  "closed {}"
    52   unfolding closed_def by simp
    53 
    54 lemma closed_Un [intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<union> T)"
    55   unfolding closed_def by auto
    56 
    57 lemma closed_UNIV [intro, simp]: "closed UNIV"
    58   unfolding closed_def by simp
    59 
    60 lemma closed_Int [intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<inter> T)"
    61   unfolding closed_def by auto
    62 
    63 lemma closed_INT [intro]: "\<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Inter>x\<in>A. B x)"
    64   unfolding closed_def by auto
    65 
    66 lemma closed_Inter [intro]: "\<forall>S\<in>K. closed S \<Longrightarrow> closed (\<Inter> K)"
    67   unfolding closed_def uminus_Inf by auto
    68 
    69 lemma closed_Union [intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. closed T \<Longrightarrow> closed (\<Union>S)"
    70   by (induct set: finite) auto
    71 
    72 lemma closed_UN [intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Union>x\<in>A. B x)"
    73   using closed_Union [of "B ` A"] by simp
    74 
    75 lemma open_closed: "open S \<longleftrightarrow> closed (- S)"
    76   unfolding closed_def by simp
    77 
    78 lemma closed_open: "closed S \<longleftrightarrow> open (- S)"
    79   unfolding closed_def by simp
    80 
    81 lemma open_Diff [intro]: "open S \<Longrightarrow> closed T \<Longrightarrow> open (S - T)"
    82   unfolding closed_open Diff_eq by (rule open_Int)
    83 
    84 lemma closed_Diff [intro]: "closed S \<Longrightarrow> open T \<Longrightarrow> closed (S - T)"
    85   unfolding open_closed Diff_eq by (rule closed_Int)
    86 
    87 lemma open_Compl [intro]: "closed S \<Longrightarrow> open (- S)"
    88   unfolding closed_open .
    89 
    90 lemma closed_Compl [intro]: "open S \<Longrightarrow> closed (- S)"
    91   unfolding open_closed .
    92 
    93 end
    94 
    95 subsection{* Hausdorff and other separation properties *}
    96 
    97 class t0_space = topological_space +
    98   assumes t0_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> \<not> (x \<in> U \<longleftrightarrow> y \<in> U)"
    99 
   100 class t1_space = topological_space +
   101   assumes t1_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> x \<in> U \<and> y \<notin> U"
   102 
   103 instance t1_space \<subseteq> t0_space
   104 proof qed (fast dest: t1_space)
   105 
   106 lemma separation_t1:
   107   fixes x y :: "'a::t1_space"
   108   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> x \<in> U \<and> y \<notin> U)"
   109   using t1_space[of x y] by blast
   110 
   111 lemma closed_singleton:
   112   fixes a :: "'a::t1_space"
   113   shows "closed {a}"
   114 proof -
   115   let ?T = "\<Union>{S. open S \<and> a \<notin> S}"
   116   have "open ?T" by (simp add: open_Union)
   117   also have "?T = - {a}"
   118     by (simp add: set_eq_iff separation_t1, auto)
   119   finally show "closed {a}" unfolding closed_def .
   120 qed
   121 
   122 lemma closed_insert [simp]:
   123   fixes a :: "'a::t1_space"
   124   assumes "closed S" shows "closed (insert a S)"
   125 proof -
   126   from closed_singleton assms
   127   have "closed ({a} \<union> S)" by (rule closed_Un)
   128   thus "closed (insert a S)" by simp
   129 qed
   130 
   131 lemma finite_imp_closed:
   132   fixes S :: "'a::t1_space set"
   133   shows "finite S \<Longrightarrow> closed S"
   134 by (induct set: finite, simp_all)
   135 
   136 text {* T2 spaces are also known as Hausdorff spaces. *}
   137 
   138 class t2_space = topological_space +
   139   assumes hausdorff: "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   140 
   141 instance t2_space \<subseteq> t1_space
   142 proof qed (fast dest: hausdorff)
   143 
   144 lemma separation_t2:
   145   fixes x y :: "'a::t2_space"
   146   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {})"
   147   using hausdorff[of x y] by blast
   148 
   149 lemma separation_t0:
   150   fixes x y :: "'a::t0_space"
   151   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> ~(x\<in>U \<longleftrightarrow> y\<in>U))"
   152   using t0_space[of x y] by blast
   153 
   154 text {* A perfect space is a topological space with no isolated points. *}
   155 
   156 class perfect_space = topological_space +
   157   assumes not_open_singleton: "\<not> open {x}"
   158 
   159 
   160 subsection {* Generators for toplogies *}
   161 
   162 inductive generate_topology for S where
   163   UNIV: "generate_topology S UNIV"
   164 | Int: "generate_topology S a \<Longrightarrow> generate_topology S b \<Longrightarrow> generate_topology S (a \<inter> b)"
   165 | UN: "(\<And>k. k \<in> K \<Longrightarrow> generate_topology S k) \<Longrightarrow> generate_topology S (\<Union>K)"
   166 | Basis: "s \<in> S \<Longrightarrow> generate_topology S s"
   167 
   168 hide_fact (open) UNIV Int UN Basis 
   169 
   170 lemma generate_topology_Union: 
   171   "(\<And>k. k \<in> I \<Longrightarrow> generate_topology S (K k)) \<Longrightarrow> generate_topology S (\<Union>k\<in>I. K k)"
   172   using generate_topology.UN [of "K ` I"] by auto
   173 
   174 lemma topological_space_generate_topology:
   175   "class.topological_space (generate_topology S)"
   176   by default (auto intro: generate_topology.intros)
   177 
   178 subsection {* Order topologies *}
   179 
   180 class order_topology = order + "open" +
   181   assumes open_generated_order: "open = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   182 begin
   183 
   184 subclass topological_space
   185   unfolding open_generated_order
   186   by (rule topological_space_generate_topology)
   187 
   188 lemma open_greaterThan [simp]: "open {a <..}"
   189   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   190 
   191 lemma open_lessThan [simp]: "open {..< a}"
   192   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   193 
   194 lemma open_greaterThanLessThan [simp]: "open {a <..< b}"
   195    unfolding greaterThanLessThan_eq by (simp add: open_Int)
   196 
   197 end
   198 
   199 class linorder_topology = linorder + order_topology
   200 
   201 lemma closed_atMost [simp]: "closed {.. a::'a::linorder_topology}"
   202   by (simp add: closed_open)
   203 
   204 lemma closed_atLeast [simp]: "closed {a::'a::linorder_topology ..}"
   205   by (simp add: closed_open)
   206 
   207 lemma closed_atLeastAtMost [simp]: "closed {a::'a::linorder_topology .. b}"
   208 proof -
   209   have "{a .. b} = {a ..} \<inter> {.. b}"
   210     by auto
   211   then show ?thesis
   212     by (simp add: closed_Int)
   213 qed
   214 
   215 lemma (in linorder) less_separate:
   216   assumes "x < y"
   217   shows "\<exists>a b. x \<in> {..< a} \<and> y \<in> {b <..} \<and> {..< a} \<inter> {b <..} = {}"
   218 proof (cases "\<exists>z. x < z \<and> z < y")
   219   case True
   220   then obtain z where "x < z \<and> z < y" ..
   221   then have "x \<in> {..< z} \<and> y \<in> {z <..} \<and> {z <..} \<inter> {..< z} = {}"
   222     by auto
   223   then show ?thesis by blast
   224 next
   225   case False
   226   with `x < y` have "x \<in> {..< y} \<and> y \<in> {x <..} \<and> {x <..} \<inter> {..< y} = {}"
   227     by auto
   228   then show ?thesis by blast
   229 qed
   230 
   231 instance linorder_topology \<subseteq> t2_space
   232 proof
   233   fix x y :: 'a
   234   from less_separate[of x y] less_separate[of y x]
   235   show "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   236     by (elim neqE) (metis open_lessThan open_greaterThan Int_commute)+
   237 qed
   238 
   239 lemma (in linorder_topology) open_right:
   240   assumes "open S" "x \<in> S" and gt_ex: "x < y" shows "\<exists>b>x. {x ..< b} \<subseteq> S"
   241   using assms unfolding open_generated_order
   242 proof induction
   243   case (Int A B)
   244   then obtain a b where "a > x" "{x ..< a} \<subseteq> A"  "b > x" "{x ..< b} \<subseteq> B" by auto
   245   then show ?case by (auto intro!: exI[of _ "min a b"])
   246 next
   247   case (Basis S) then show ?case by (fastforce intro: exI[of _ y] gt_ex)
   248 qed blast+
   249 
   250 lemma (in linorder_topology) open_left:
   251   assumes "open S" "x \<in> S" and lt_ex: "y < x" shows "\<exists>b<x. {b <.. x} \<subseteq> S"
   252   using assms unfolding open_generated_order
   253 proof induction
   254   case (Int A B)
   255   then obtain a b where "a < x" "{a <.. x} \<subseteq> A"  "b < x" "{b <.. x} \<subseteq> B" by auto
   256   then show ?case by (auto intro!: exI[of _ "max a b"])
   257 next
   258   case (Basis S) then show ?case by (fastforce intro: exI[of _ y] lt_ex)
   259 qed blast+
   260 
   261 subsection {* Filters *}
   262 
   263 text {*
   264   This definition also allows non-proper filters.
   265 *}
   266 
   267 locale is_filter =
   268   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
   269   assumes True: "F (\<lambda>x. True)"
   270   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
   271   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
   272 
   273 typedef 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
   274 proof
   275   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
   276 qed
   277 
   278 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
   279   using Rep_filter [of F] by simp
   280 
   281 lemma Abs_filter_inverse':
   282   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
   283   using assms by (simp add: Abs_filter_inverse)
   284 
   285 
   286 subsubsection {* Eventually *}
   287 
   288 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
   289   where "eventually P F \<longleftrightarrow> Rep_filter F P"
   290 
   291 lemma eventually_Abs_filter:
   292   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
   293   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
   294 
   295 lemma filter_eq_iff:
   296   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
   297   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
   298 
   299 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
   300   unfolding eventually_def
   301   by (rule is_filter.True [OF is_filter_Rep_filter])
   302 
   303 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
   304 proof -
   305   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
   306   thus "eventually P F" by simp
   307 qed
   308 
   309 lemma eventually_mono:
   310   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P F \<Longrightarrow> eventually Q F"
   311   unfolding eventually_def
   312   by (rule is_filter.mono [OF is_filter_Rep_filter])
   313 
   314 lemma eventually_conj:
   315   assumes P: "eventually (\<lambda>x. P x) F"
   316   assumes Q: "eventually (\<lambda>x. Q x) F"
   317   shows "eventually (\<lambda>x. P x \<and> Q x) F"
   318   using assms unfolding eventually_def
   319   by (rule is_filter.conj [OF is_filter_Rep_filter])
   320 
   321 lemma eventually_Ball_finite:
   322   assumes "finite A" and "\<forall>y\<in>A. eventually (\<lambda>x. P x y) net"
   323   shows "eventually (\<lambda>x. \<forall>y\<in>A. P x y) net"
   324 using assms by (induct set: finite, simp, simp add: eventually_conj)
   325 
   326 lemma eventually_all_finite:
   327   fixes P :: "'a \<Rightarrow> 'b::finite \<Rightarrow> bool"
   328   assumes "\<And>y. eventually (\<lambda>x. P x y) net"
   329   shows "eventually (\<lambda>x. \<forall>y. P x y) net"
   330 using eventually_Ball_finite [of UNIV P] assms by simp
   331 
   332 lemma eventually_mp:
   333   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   334   assumes "eventually (\<lambda>x. P x) F"
   335   shows "eventually (\<lambda>x. Q x) F"
   336 proof (rule eventually_mono)
   337   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
   338   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
   339     using assms by (rule eventually_conj)
   340 qed
   341 
   342 lemma eventually_rev_mp:
   343   assumes "eventually (\<lambda>x. P x) F"
   344   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   345   shows "eventually (\<lambda>x. Q x) F"
   346 using assms(2) assms(1) by (rule eventually_mp)
   347 
   348 lemma eventually_conj_iff:
   349   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
   350   by (auto intro: eventually_conj elim: eventually_rev_mp)
   351 
   352 lemma eventually_elim1:
   353   assumes "eventually (\<lambda>i. P i) F"
   354   assumes "\<And>i. P i \<Longrightarrow> Q i"
   355   shows "eventually (\<lambda>i. Q i) F"
   356   using assms by (auto elim!: eventually_rev_mp)
   357 
   358 lemma eventually_elim2:
   359   assumes "eventually (\<lambda>i. P i) F"
   360   assumes "eventually (\<lambda>i. Q i) F"
   361   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   362   shows "eventually (\<lambda>i. R i) F"
   363   using assms by (auto elim!: eventually_rev_mp)
   364 
   365 lemma eventually_subst:
   366   assumes "eventually (\<lambda>n. P n = Q n) F"
   367   shows "eventually P F = eventually Q F" (is "?L = ?R")
   368 proof -
   369   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   370       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   371     by (auto elim: eventually_elim1)
   372   then show ?thesis by (auto elim: eventually_elim2)
   373 qed
   374 
   375 ML {*
   376   fun eventually_elim_tac ctxt thms = SUBGOAL_CASES (fn (_, _, st) =>
   377     let
   378       val thy = Proof_Context.theory_of ctxt
   379       val mp_thms = thms RL [@{thm eventually_rev_mp}]
   380       val raw_elim_thm =
   381         (@{thm allI} RS @{thm always_eventually})
   382         |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   383         |> fold (fn _ => fn thm => @{thm impI} RS thm) thms
   384       val cases_prop = prop_of (raw_elim_thm RS st)
   385       val cases = (Rule_Cases.make_common (thy, cases_prop) [(("elim", []), [])])
   386     in
   387       CASES cases (rtac raw_elim_thm 1)
   388     end) 1
   389 *}
   390 
   391 method_setup eventually_elim = {*
   392   Scan.succeed (fn ctxt => METHOD_CASES (eventually_elim_tac ctxt))
   393 *} "elimination of eventually quantifiers"
   394 
   395 
   396 subsubsection {* Finer-than relation *}
   397 
   398 text {* @{term "F \<le> F'"} means that filter @{term F} is finer than
   399 filter @{term F'}. *}
   400 
   401 instantiation filter :: (type) complete_lattice
   402 begin
   403 
   404 definition le_filter_def:
   405   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   406 
   407 definition
   408   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   409 
   410 definition
   411   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   412 
   413 definition
   414   "bot = Abs_filter (\<lambda>P. True)"
   415 
   416 definition
   417   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   418 
   419 definition
   420   "inf F F' = Abs_filter
   421       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   422 
   423 definition
   424   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   425 
   426 definition
   427   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   428 
   429 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   430   unfolding top_filter_def
   431   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   432 
   433 lemma eventually_bot [simp]: "eventually P bot"
   434   unfolding bot_filter_def
   435   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   436 
   437 lemma eventually_sup:
   438   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   439   unfolding sup_filter_def
   440   by (rule eventually_Abs_filter, rule is_filter.intro)
   441      (auto elim!: eventually_rev_mp)
   442 
   443 lemma eventually_inf:
   444   "eventually P (inf F F') \<longleftrightarrow>
   445    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   446   unfolding inf_filter_def
   447   apply (rule eventually_Abs_filter, rule is_filter.intro)
   448   apply (fast intro: eventually_True)
   449   apply clarify
   450   apply (intro exI conjI)
   451   apply (erule (1) eventually_conj)
   452   apply (erule (1) eventually_conj)
   453   apply simp
   454   apply auto
   455   done
   456 
   457 lemma eventually_Sup:
   458   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   459   unfolding Sup_filter_def
   460   apply (rule eventually_Abs_filter, rule is_filter.intro)
   461   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   462   done
   463 
   464 instance proof
   465   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   466   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   467     by (rule less_filter_def) }
   468   { show "F \<le> F"
   469     unfolding le_filter_def by simp }
   470   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   471     unfolding le_filter_def by simp }
   472   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   473     unfolding le_filter_def filter_eq_iff by fast }
   474   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   475     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   476   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   477     unfolding le_filter_def eventually_inf
   478     by (auto elim!: eventually_mono intro: eventually_conj) }
   479   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   480     unfolding le_filter_def eventually_sup by simp_all }
   481   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   482     unfolding le_filter_def eventually_sup by simp }
   483   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   484     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   485   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   486     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   487   { assume "F \<in> S" thus "F \<le> Sup S"
   488     unfolding le_filter_def eventually_Sup by simp }
   489   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   490     unfolding le_filter_def eventually_Sup by simp }
   491   { show "Inf {} = (top::'a filter)"
   492     by (auto simp: top_filter_def Inf_filter_def Sup_filter_def)
   493       (metis (full_types) top_filter_def always_eventually eventually_top) }
   494   { show "Sup {} = (bot::'a filter)"
   495     by (auto simp: bot_filter_def Sup_filter_def) }
   496 qed
   497 
   498 end
   499 
   500 lemma filter_leD:
   501   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   502   unfolding le_filter_def by simp
   503 
   504 lemma filter_leI:
   505   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   506   unfolding le_filter_def by simp
   507 
   508 lemma eventually_False:
   509   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   510   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   511 
   512 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   513   where "trivial_limit F \<equiv> F = bot"
   514 
   515 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   516   by (rule eventually_False [symmetric])
   517 
   518 lemma eventually_const: "\<not> trivial_limit net \<Longrightarrow> eventually (\<lambda>x. P) net \<longleftrightarrow> P"
   519   by (cases P) (simp_all add: eventually_False)
   520 
   521 
   522 subsubsection {* Map function for filters *}
   523 
   524 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   525   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   526 
   527 lemma eventually_filtermap:
   528   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   529   unfolding filtermap_def
   530   apply (rule eventually_Abs_filter)
   531   apply (rule is_filter.intro)
   532   apply (auto elim!: eventually_rev_mp)
   533   done
   534 
   535 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   536   by (simp add: filter_eq_iff eventually_filtermap)
   537 
   538 lemma filtermap_filtermap:
   539   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   540   by (simp add: filter_eq_iff eventually_filtermap)
   541 
   542 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   543   unfolding le_filter_def eventually_filtermap by simp
   544 
   545 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   546   by (simp add: filter_eq_iff eventually_filtermap)
   547 
   548 lemma filtermap_sup: "filtermap f (sup F1 F2) = sup (filtermap f F1) (filtermap f F2)"
   549   by (auto simp: filter_eq_iff eventually_filtermap eventually_sup)
   550 
   551 subsubsection {* Order filters *}
   552 
   553 definition at_top :: "('a::order) filter"
   554   where "at_top = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   555 
   556 lemma eventually_at_top_linorder: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::linorder. \<forall>n\<ge>N. P n)"
   557   unfolding at_top_def
   558 proof (rule eventually_Abs_filter, rule is_filter.intro)
   559   fix P Q :: "'a \<Rightarrow> bool"
   560   assume "\<exists>i. \<forall>n\<ge>i. P n" and "\<exists>j. \<forall>n\<ge>j. Q n"
   561   then obtain i j where "\<forall>n\<ge>i. P n" and "\<forall>n\<ge>j. Q n" by auto
   562   then have "\<forall>n\<ge>max i j. P n \<and> Q n" by simp
   563   then show "\<exists>k. \<forall>n\<ge>k. P n \<and> Q n" ..
   564 qed auto
   565 
   566 lemma eventually_ge_at_top:
   567   "eventually (\<lambda>x. (c::_::linorder) \<le> x) at_top"
   568   unfolding eventually_at_top_linorder by auto
   569 
   570 lemma eventually_at_top_dense: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::unbounded_dense_linorder. \<forall>n>N. P n)"
   571   unfolding eventually_at_top_linorder
   572 proof safe
   573   fix N assume "\<forall>n\<ge>N. P n"
   574   then show "\<exists>N. \<forall>n>N. P n" by (auto intro!: exI[of _ N])
   575 next
   576   fix N assume "\<forall>n>N. P n"
   577   moreover obtain y where "N < y" using gt_ex[of N] ..
   578   ultimately show "\<exists>N. \<forall>n\<ge>N. P n" by (auto intro!: exI[of _ y])
   579 qed
   580 
   581 lemma eventually_gt_at_top:
   582   "eventually (\<lambda>x. (c::_::unbounded_dense_linorder) < x) at_top"
   583   unfolding eventually_at_top_dense by auto
   584 
   585 definition at_bot :: "('a::order) filter"
   586   where "at_bot = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<le>k. P n)"
   587 
   588 lemma eventually_at_bot_linorder:
   589   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n\<le>N. P n)"
   590   unfolding at_bot_def
   591 proof (rule eventually_Abs_filter, rule is_filter.intro)
   592   fix P Q :: "'a \<Rightarrow> bool"
   593   assume "\<exists>i. \<forall>n\<le>i. P n" and "\<exists>j. \<forall>n\<le>j. Q n"
   594   then obtain i j where "\<forall>n\<le>i. P n" and "\<forall>n\<le>j. Q n" by auto
   595   then have "\<forall>n\<le>min i j. P n \<and> Q n" by simp
   596   then show "\<exists>k. \<forall>n\<le>k. P n \<and> Q n" ..
   597 qed auto
   598 
   599 lemma eventually_le_at_bot:
   600   "eventually (\<lambda>x. x \<le> (c::_::linorder)) at_bot"
   601   unfolding eventually_at_bot_linorder by auto
   602 
   603 lemma eventually_at_bot_dense:
   604   fixes P :: "'a::unbounded_dense_linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n<N. P n)"
   605   unfolding eventually_at_bot_linorder
   606 proof safe
   607   fix N assume "\<forall>n\<le>N. P n" then show "\<exists>N. \<forall>n<N. P n" by (auto intro!: exI[of _ N])
   608 next
   609   fix N assume "\<forall>n<N. P n" 
   610   moreover obtain y where "y < N" using lt_ex[of N] ..
   611   ultimately show "\<exists>N. \<forall>n\<le>N. P n" by (auto intro!: exI[of _ y])
   612 qed
   613 
   614 lemma eventually_gt_at_bot:
   615   "eventually (\<lambda>x. x < (c::_::unbounded_dense_linorder)) at_bot"
   616   unfolding eventually_at_bot_dense by auto
   617 
   618 subsection {* Sequentially *}
   619 
   620 abbreviation sequentially :: "nat filter"
   621   where "sequentially == at_top"
   622 
   623 lemma sequentially_def: "sequentially = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   624   unfolding at_top_def by simp
   625 
   626 lemma eventually_sequentially:
   627   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   628   by (rule eventually_at_top_linorder)
   629 
   630 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   631   unfolding filter_eq_iff eventually_sequentially by auto
   632 
   633 lemmas trivial_limit_sequentially = sequentially_bot
   634 
   635 lemma eventually_False_sequentially [simp]:
   636   "\<not> eventually (\<lambda>n. False) sequentially"
   637   by (simp add: eventually_False)
   638 
   639 lemma le_sequentially:
   640   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   641   unfolding le_filter_def eventually_sequentially
   642   by (safe, fast, drule_tac x=N in spec, auto elim: eventually_rev_mp)
   643 
   644 lemma eventually_sequentiallyI:
   645   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   646   shows "eventually P sequentially"
   647 using assms by (auto simp: eventually_sequentially)
   648 
   649 lemma eventually_sequentially_seg:
   650   "eventually (\<lambda>n. P (n + k)) sequentially \<longleftrightarrow> eventually P sequentially"
   651   unfolding eventually_sequentially
   652   apply safe
   653    apply (rule_tac x="N + k" in exI)
   654    apply rule
   655    apply (erule_tac x="n - k" in allE)
   656    apply auto []
   657   apply (rule_tac x=N in exI)
   658   apply auto []
   659   done
   660 
   661 subsubsection {* Standard filters *}
   662 
   663 definition principal :: "'a set \<Rightarrow> 'a filter" where
   664   "principal S = Abs_filter (\<lambda>P. \<forall>x\<in>S. P x)"
   665 
   666 lemma eventually_principal: "eventually P (principal S) \<longleftrightarrow> (\<forall>x\<in>S. P x)"
   667   unfolding principal_def
   668   by (rule eventually_Abs_filter, rule is_filter.intro) auto
   669 
   670 lemma eventually_inf_principal: "eventually P (inf F (principal s)) \<longleftrightarrow> eventually (\<lambda>x. x \<in> s \<longrightarrow> P x) F"
   671   unfolding eventually_inf eventually_principal by (auto elim: eventually_elim1)
   672 
   673 lemma principal_UNIV[simp]: "principal UNIV = top"
   674   by (auto simp: filter_eq_iff eventually_principal)
   675 
   676 lemma principal_empty[simp]: "principal {} = bot"
   677   by (auto simp: filter_eq_iff eventually_principal)
   678 
   679 lemma principal_le_iff[iff]: "principal A \<le> principal B \<longleftrightarrow> A \<subseteq> B"
   680   by (auto simp: le_filter_def eventually_principal)
   681 
   682 lemma le_principal: "F \<le> principal A \<longleftrightarrow> eventually (\<lambda>x. x \<in> A) F"
   683   unfolding le_filter_def eventually_principal
   684   apply safe
   685   apply (erule_tac x="\<lambda>x. x \<in> A" in allE)
   686   apply (auto elim: eventually_elim1)
   687   done
   688 
   689 lemma principal_inject[iff]: "principal A = principal B \<longleftrightarrow> A = B"
   690   unfolding eq_iff by simp
   691 
   692 lemma sup_principal[simp]: "sup (principal A) (principal B) = principal (A \<union> B)"
   693   unfolding filter_eq_iff eventually_sup eventually_principal by auto
   694 
   695 lemma inf_principal[simp]: "inf (principal A) (principal B) = principal (A \<inter> B)"
   696   unfolding filter_eq_iff eventually_inf eventually_principal
   697   by (auto intro: exI[of _ "\<lambda>x. x \<in> A"] exI[of _ "\<lambda>x. x \<in> B"])
   698 
   699 lemma SUP_principal[simp]: "(SUP i : I. principal (A i)) = principal (\<Union>i\<in>I. A i)"
   700   unfolding filter_eq_iff eventually_Sup SUP_def by (auto simp: eventually_principal)
   701 
   702 lemma filtermap_principal[simp]: "filtermap f (principal A) = principal (f ` A)"
   703   unfolding filter_eq_iff eventually_filtermap eventually_principal by simp
   704 
   705 subsubsection {* Topological filters *}
   706 
   707 definition (in topological_space) nhds :: "'a \<Rightarrow> 'a filter"
   708   where "nhds a = Abs_filter (\<lambda>P. \<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   709 
   710 definition (in topological_space) at_within :: "'a \<Rightarrow> 'a set \<Rightarrow> 'a filter" ("at (_) within (_)" [1000, 60] 60)
   711   where "at a within s = inf (nhds a) (principal (s - {a}))"
   712 
   713 abbreviation (in topological_space) at :: "'a \<Rightarrow> 'a filter" ("at") where
   714   "at x \<equiv> at x within (CONST UNIV)"
   715 
   716 abbreviation (in order_topology) at_right :: "'a \<Rightarrow> 'a filter" where
   717   "at_right x \<equiv> at x within {x <..}"
   718 
   719 abbreviation (in order_topology) at_left :: "'a \<Rightarrow> 'a filter" where
   720   "at_left x \<equiv> at x within {..< x}"
   721 
   722 lemma (in topological_space) eventually_nhds:
   723   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   724   unfolding nhds_def
   725 proof (rule eventually_Abs_filter, rule is_filter.intro)
   726   have "open UNIV \<and> a \<in> UNIV \<and> (\<forall>x\<in>UNIV. True)" by simp
   727   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. True)" ..
   728 next
   729   fix P Q
   730   assume "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   731      and "\<exists>T. open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)"
   732   then obtain S T where
   733     "open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   734     "open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)" by auto
   735   hence "open (S \<inter> T) \<and> a \<in> S \<inter> T \<and> (\<forall>x\<in>(S \<inter> T). P x \<and> Q x)"
   736     by (simp add: open_Int)
   737   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x \<and> Q x)" ..
   738 qed auto
   739 
   740 lemma nhds_neq_bot [simp]: "nhds a \<noteq> bot"
   741   unfolding trivial_limit_def eventually_nhds by simp
   742 
   743 lemma eventually_at_filter:
   744   "eventually P (at a within s) \<longleftrightarrow> eventually (\<lambda>x. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x) (nhds a)"
   745   unfolding at_within_def eventually_inf_principal by (simp add: imp_conjL[symmetric] conj_commute)
   746 
   747 lemma at_le: "s \<subseteq> t \<Longrightarrow> at x within s \<le> at x within t"
   748   unfolding at_within_def by (intro inf_mono) auto
   749 
   750 lemma eventually_at_topological:
   751   "eventually P (at a within s) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x))"
   752   unfolding eventually_nhds eventually_at_filter by simp
   753 
   754 lemma at_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> at a within S = at a"
   755   unfolding filter_eq_iff eventually_at_topological by (metis open_Int Int_iff UNIV_I)
   756 
   757 lemma at_within_empty [simp]: "at a within {} = bot"
   758   unfolding at_within_def by simp
   759 
   760 lemma at_within_union: "at x within (S \<union> T) = sup (at x within S) (at x within T)"
   761   unfolding filter_eq_iff eventually_sup eventually_at_filter
   762   by (auto elim!: eventually_rev_mp)
   763 
   764 lemma at_eq_bot_iff: "at a = bot \<longleftrightarrow> open {a}"
   765   unfolding trivial_limit_def eventually_at_topological
   766   by (safe, case_tac "S = {a}", simp, fast, fast)
   767 
   768 lemma at_neq_bot [simp]: "at (a::'a::perfect_space) \<noteq> bot"
   769   by (simp add: at_eq_bot_iff not_open_singleton)
   770 
   771 lemma eventually_at_right:
   772   fixes x :: "'a :: {no_top, linorder_topology}"
   773   shows "eventually P (at_right x) \<longleftrightarrow> (\<exists>b. x < b \<and> (\<forall>z. x < z \<and> z < b \<longrightarrow> P z))"
   774   unfolding eventually_at_topological
   775 proof safe
   776   obtain y where "x < y" using gt_ex[of x] ..
   777   moreover fix S assume "open S" "x \<in> S" note open_right[OF this, of y]
   778   moreover note gt_ex[of x]
   779   moreover assume "\<forall>s\<in>S. s \<noteq> x \<longrightarrow> s \<in> {x<..} \<longrightarrow> P s"
   780   ultimately show "\<exists>b>x. \<forall>z. x < z \<and> z < b \<longrightarrow> P z"
   781     by (auto simp: subset_eq Ball_def)
   782 next
   783   fix b assume "x < b" "\<forall>z. x < z \<and> z < b \<longrightarrow> P z"
   784   then show "\<exists>S. open S \<and> x \<in> S \<and> (\<forall>xa\<in>S. xa \<noteq> x \<longrightarrow> xa \<in> {x<..} \<longrightarrow> P xa)"
   785     by (intro exI[of _ "{..< b}"]) auto
   786 qed
   787 
   788 lemma eventually_at_left:
   789   fixes x :: "'a :: {no_bot, linorder_topology}"
   790   shows "eventually P (at_left x) \<longleftrightarrow> (\<exists>b. x > b \<and> (\<forall>z. b < z \<and> z < x \<longrightarrow> P z))"
   791   unfolding eventually_at_topological
   792 proof safe
   793   obtain y where "y < x" using lt_ex[of x] ..
   794   moreover fix S assume "open S" "x \<in> S" note open_left[OF this, of y]
   795   moreover assume "\<forall>s\<in>S. s \<noteq> x \<longrightarrow> s \<in> {..<x} \<longrightarrow> P s"
   796   ultimately show "\<exists>b<x. \<forall>z. b < z \<and> z < x \<longrightarrow> P z"
   797     by (auto simp: subset_eq Ball_def)
   798 next
   799   fix b assume "b < x" "\<forall>z. b < z \<and> z < x \<longrightarrow> P z"
   800   then show "\<exists>S. open S \<and> x \<in> S \<and> (\<forall>s\<in>S. s \<noteq> x \<longrightarrow> s \<in> {..<x} \<longrightarrow> P s)"
   801     by (intro exI[of _ "{b <..}"]) auto
   802 qed
   803 
   804 lemma trivial_limit_at_left_real [simp]:
   805   "\<not> trivial_limit (at_left (x::'a::{no_bot, unbounded_dense_linorder, linorder_topology}))"
   806   unfolding trivial_limit_def eventually_at_left by (auto dest: dense)
   807 
   808 lemma trivial_limit_at_right_real [simp]:
   809   "\<not> trivial_limit (at_right (x::'a::{no_top, unbounded_dense_linorder, linorder_topology}))"
   810   unfolding trivial_limit_def eventually_at_right by (auto dest: dense)
   811 
   812 lemma at_eq_sup_left_right: "at (x::'a::linorder_topology) = sup (at_left x) (at_right x)"
   813   by (auto simp: eventually_at_filter filter_eq_iff eventually_sup 
   814            elim: eventually_elim2 eventually_elim1)
   815 
   816 lemma eventually_at_split:
   817   "eventually P (at (x::'a::linorder_topology)) \<longleftrightarrow> eventually P (at_left x) \<and> eventually P (at_right x)"
   818   by (subst at_eq_sup_left_right) (simp add: eventually_sup)
   819 
   820 subsection {* Limits *}
   821 
   822 definition filterlim :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter \<Rightarrow> bool" where
   823   "filterlim f F2 F1 \<longleftrightarrow> filtermap f F1 \<le> F2"
   824 
   825 syntax
   826   "_LIM" :: "pttrns \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> bool" ("(3LIM (_)/ (_)./ (_) :> (_))" [1000, 10, 0, 10] 10)
   827 
   828 translations
   829   "LIM x F1. f :> F2"   == "CONST filterlim (%x. f) F2 F1"
   830 
   831 lemma filterlim_iff:
   832   "(LIM x F1. f x :> F2) \<longleftrightarrow> (\<forall>P. eventually P F2 \<longrightarrow> eventually (\<lambda>x. P (f x)) F1)"
   833   unfolding filterlim_def le_filter_def eventually_filtermap ..
   834 
   835 lemma filterlim_compose:
   836   "filterlim g F3 F2 \<Longrightarrow> filterlim f F2 F1 \<Longrightarrow> filterlim (\<lambda>x. g (f x)) F3 F1"
   837   unfolding filterlim_def filtermap_filtermap[symmetric] by (metis filtermap_mono order_trans)
   838 
   839 lemma filterlim_mono:
   840   "filterlim f F2 F1 \<Longrightarrow> F2 \<le> F2' \<Longrightarrow> F1' \<le> F1 \<Longrightarrow> filterlim f F2' F1'"
   841   unfolding filterlim_def by (metis filtermap_mono order_trans)
   842 
   843 lemma filterlim_ident: "LIM x F. x :> F"
   844   by (simp add: filterlim_def filtermap_ident)
   845 
   846 lemma filterlim_cong:
   847   "F1 = F1' \<Longrightarrow> F2 = F2' \<Longrightarrow> eventually (\<lambda>x. f x = g x) F2 \<Longrightarrow> filterlim f F1 F2 = filterlim g F1' F2'"
   848   by (auto simp: filterlim_def le_filter_def eventually_filtermap elim: eventually_elim2)
   849 
   850 lemma filterlim_principal:
   851   "(LIM x F. f x :> principal S) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> S) F)"
   852   unfolding filterlim_def eventually_filtermap le_principal ..
   853 
   854 lemma filterlim_inf:
   855   "(LIM x F1. f x :> inf F2 F3) \<longleftrightarrow> ((LIM x F1. f x :> F2) \<and> (LIM x F1. f x :> F3))"
   856   unfolding filterlim_def by simp
   857 
   858 lemma filterlim_filtermap: "filterlim f F1 (filtermap g F2) = filterlim (\<lambda>x. f (g x)) F1 F2"
   859   unfolding filterlim_def filtermap_filtermap ..
   860 
   861 lemma filterlim_sup:
   862   "filterlim f F F1 \<Longrightarrow> filterlim f F F2 \<Longrightarrow> filterlim f F (sup F1 F2)"
   863   unfolding filterlim_def filtermap_sup by auto
   864 
   865 lemma filterlim_Suc: "filterlim Suc sequentially sequentially"
   866   by (simp add: filterlim_iff eventually_sequentially) (metis le_Suc_eq)
   867 
   868 subsubsection {* Tendsto *}
   869 
   870 abbreviation (in topological_space)
   871   tendsto :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b filter \<Rightarrow> bool" (infixr "--->" 55) where
   872   "(f ---> l) F \<equiv> filterlim f (nhds l) F"
   873 
   874 definition (in t2_space) Lim :: "'f filter \<Rightarrow> ('f \<Rightarrow> 'a) \<Rightarrow> 'a" where
   875   "Lim A f = (THE l. (f ---> l) A)"
   876 
   877 lemma tendsto_eq_rhs: "(f ---> x) F \<Longrightarrow> x = y \<Longrightarrow> (f ---> y) F"
   878   by simp
   879 
   880 ML {*
   881 
   882 structure Tendsto_Intros = Named_Thms
   883 (
   884   val name = @{binding tendsto_intros}
   885   val description = "introduction rules for tendsto"
   886 )
   887 
   888 *}
   889 
   890 setup {*
   891   Tendsto_Intros.setup #>
   892   Global_Theory.add_thms_dynamic (@{binding tendsto_eq_intros},
   893     map_filter (try (fn thm => @{thm tendsto_eq_rhs} OF [thm])) o Tendsto_Intros.get o Context.proof_of);
   894 *}
   895 
   896 lemma (in topological_space) tendsto_def:
   897    "(f ---> l) F \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) F)"
   898   unfolding filterlim_def
   899 proof safe
   900   fix S assume "open S" "l \<in> S" "filtermap f F \<le> nhds l"
   901   then show "eventually (\<lambda>x. f x \<in> S) F"
   902     unfolding eventually_nhds eventually_filtermap le_filter_def
   903     by (auto elim!: allE[of _ "\<lambda>x. x \<in> S"] eventually_rev_mp)
   904 qed (auto elim!: eventually_rev_mp simp: eventually_nhds eventually_filtermap le_filter_def)
   905 
   906 lemma tendsto_mono: "F \<le> F' \<Longrightarrow> (f ---> l) F' \<Longrightarrow> (f ---> l) F"
   907   unfolding tendsto_def le_filter_def by fast
   908 
   909 lemma tendsto_within_subset: "(f ---> l) (at x within S) \<Longrightarrow> T \<subseteq> S \<Longrightarrow> (f ---> l) (at x within T)"
   910   by (blast intro: tendsto_mono at_le)
   911 
   912 lemma filterlim_at:
   913   "(LIM x F. f x :> at b within s) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> s \<and> f x \<noteq> b) F \<and> (f ---> b) F)"
   914   by (simp add: at_within_def filterlim_inf filterlim_principal conj_commute)
   915 
   916 lemma (in topological_space) topological_tendstoI:
   917   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F) \<Longrightarrow> (f ---> l) F"
   918   unfolding tendsto_def by auto
   919 
   920 lemma (in topological_space) topological_tendstoD:
   921   "(f ---> l) F \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F"
   922   unfolding tendsto_def by auto
   923 
   924 lemma order_tendstoI:
   925   fixes y :: "_ :: order_topology"
   926   assumes "\<And>a. a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F"
   927   assumes "\<And>a. y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F"
   928   shows "(f ---> y) F"
   929 proof (rule topological_tendstoI)
   930   fix S assume "open S" "y \<in> S"
   931   then show "eventually (\<lambda>x. f x \<in> S) F"
   932     unfolding open_generated_order
   933   proof induct
   934     case (UN K)
   935     then obtain k where "y \<in> k" "k \<in> K" by auto
   936     with UN(2)[of k] show ?case
   937       by (auto elim: eventually_elim1)
   938   qed (insert assms, auto elim: eventually_elim2)
   939 qed
   940 
   941 lemma order_tendstoD:
   942   fixes y :: "_ :: order_topology"
   943   assumes y: "(f ---> y) F"
   944   shows "a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F"
   945     and "y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F"
   946   using topological_tendstoD[OF y, of "{..< a}"] topological_tendstoD[OF y, of "{a <..}"] by auto
   947 
   948 lemma order_tendsto_iff: 
   949   fixes f :: "_ \<Rightarrow> 'a :: order_topology"
   950   shows "(f ---> x) F \<longleftrightarrow>(\<forall>l<x. eventually (\<lambda>x. l < f x) F) \<and> (\<forall>u>x. eventually (\<lambda>x. f x < u) F)"
   951   by (metis order_tendstoI order_tendstoD)
   952 
   953 lemma tendsto_bot [simp]: "(f ---> a) bot"
   954   unfolding tendsto_def by simp
   955 
   956 lemma tendsto_ident_at [tendsto_intros]: "((\<lambda>x. x) ---> a) (at a within s)"
   957   unfolding tendsto_def eventually_at_topological by auto
   958 
   959 lemma (in topological_space) tendsto_const [tendsto_intros]: "((\<lambda>x. k) ---> k) F"
   960   by (simp add: tendsto_def)
   961 
   962 lemma (in t2_space) tendsto_unique:
   963   assumes "\<not> trivial_limit F" and "(f ---> a) F" and "(f ---> b) F"
   964   shows "a = b"
   965 proof (rule ccontr)
   966   assume "a \<noteq> b"
   967   obtain U V where "open U" "open V" "a \<in> U" "b \<in> V" "U \<inter> V = {}"
   968     using hausdorff [OF `a \<noteq> b`] by fast
   969   have "eventually (\<lambda>x. f x \<in> U) F"
   970     using `(f ---> a) F` `open U` `a \<in> U` by (rule topological_tendstoD)
   971   moreover
   972   have "eventually (\<lambda>x. f x \<in> V) F"
   973     using `(f ---> b) F` `open V` `b \<in> V` by (rule topological_tendstoD)
   974   ultimately
   975   have "eventually (\<lambda>x. False) F"
   976   proof eventually_elim
   977     case (elim x)
   978     hence "f x \<in> U \<inter> V" by simp
   979     with `U \<inter> V = {}` show ?case by simp
   980   qed
   981   with `\<not> trivial_limit F` show "False"
   982     by (simp add: trivial_limit_def)
   983 qed
   984 
   985 lemma (in t2_space) tendsto_const_iff:
   986   assumes "\<not> trivial_limit F" shows "((\<lambda>x. a :: 'a) ---> b) F \<longleftrightarrow> a = b"
   987   by (safe intro!: tendsto_const tendsto_unique [OF assms tendsto_const])
   988 
   989 lemma increasing_tendsto:
   990   fixes f :: "_ \<Rightarrow> 'a::order_topology"
   991   assumes bdd: "eventually (\<lambda>n. f n \<le> l) F"
   992       and en: "\<And>x. x < l \<Longrightarrow> eventually (\<lambda>n. x < f n) F"
   993   shows "(f ---> l) F"
   994   using assms by (intro order_tendstoI) (auto elim!: eventually_elim1)
   995 
   996 lemma decreasing_tendsto:
   997   fixes f :: "_ \<Rightarrow> 'a::order_topology"
   998   assumes bdd: "eventually (\<lambda>n. l \<le> f n) F"
   999       and en: "\<And>x. l < x \<Longrightarrow> eventually (\<lambda>n. f n < x) F"
  1000   shows "(f ---> l) F"
  1001   using assms by (intro order_tendstoI) (auto elim!: eventually_elim1)
  1002 
  1003 lemma tendsto_sandwich:
  1004   fixes f g h :: "'a \<Rightarrow> 'b::order_topology"
  1005   assumes ev: "eventually (\<lambda>n. f n \<le> g n) net" "eventually (\<lambda>n. g n \<le> h n) net"
  1006   assumes lim: "(f ---> c) net" "(h ---> c) net"
  1007   shows "(g ---> c) net"
  1008 proof (rule order_tendstoI)
  1009   fix a show "a < c \<Longrightarrow> eventually (\<lambda>x. a < g x) net"
  1010     using order_tendstoD[OF lim(1), of a] ev by (auto elim: eventually_elim2)
  1011 next
  1012   fix a show "c < a \<Longrightarrow> eventually (\<lambda>x. g x < a) net"
  1013     using order_tendstoD[OF lim(2), of a] ev by (auto elim: eventually_elim2)
  1014 qed
  1015 
  1016 lemma tendsto_le:
  1017   fixes f g :: "'a \<Rightarrow> 'b::linorder_topology"
  1018   assumes F: "\<not> trivial_limit F"
  1019   assumes x: "(f ---> x) F" and y: "(g ---> y) F"
  1020   assumes ev: "eventually (\<lambda>x. g x \<le> f x) F"
  1021   shows "y \<le> x"
  1022 proof (rule ccontr)
  1023   assume "\<not> y \<le> x"
  1024   with less_separate[of x y] obtain a b where xy: "x < a" "b < y" "{..<a} \<inter> {b<..} = {}"
  1025     by (auto simp: not_le)
  1026   then have "eventually (\<lambda>x. f x < a) F" "eventually (\<lambda>x. b < g x) F"
  1027     using x y by (auto intro: order_tendstoD)
  1028   with ev have "eventually (\<lambda>x. False) F"
  1029     by eventually_elim (insert xy, fastforce)
  1030   with F show False
  1031     by (simp add: eventually_False)
  1032 qed
  1033 
  1034 lemma tendsto_le_const:
  1035   fixes f :: "'a \<Rightarrow> 'b::linorder_topology"
  1036   assumes F: "\<not> trivial_limit F"
  1037   assumes x: "(f ---> x) F" and a: "eventually (\<lambda>x. a \<le> f x) F"
  1038   shows "a \<le> x"
  1039   using F x tendsto_const a by (rule tendsto_le)
  1040 
  1041 subsubsection {* Rules about @{const Lim} *}
  1042 
  1043 lemma (in t2_space) tendsto_Lim:
  1044   "\<not>(trivial_limit net) \<Longrightarrow> (f ---> l) net \<Longrightarrow> Lim net f = l"
  1045   unfolding Lim_def using tendsto_unique[of net f] by auto
  1046 
  1047 lemma Lim_ident_at: "\<not> trivial_limit (at x within s) \<Longrightarrow> Lim (at x within s) (\<lambda>x. x) = x"
  1048   by (rule tendsto_Lim[OF _ tendsto_ident_at]) auto
  1049 
  1050 subsection {* Limits to @{const at_top} and @{const at_bot} *}
  1051 
  1052 lemma filterlim_at_top:
  1053   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1054   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z \<le> f x) F)"
  1055   by (auto simp: filterlim_iff eventually_at_top_linorder elim!: eventually_elim1)
  1056 
  1057 lemma filterlim_at_top_dense:
  1058   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)"
  1059   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z < f x) F)"
  1060   by (metis eventually_elim1[of _ F] eventually_gt_at_top order_less_imp_le
  1061             filterlim_at_top[of f F] filterlim_iff[of f at_top F])
  1062 
  1063 lemma filterlim_at_top_ge:
  1064   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1065   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1066   unfolding filterlim_at_top
  1067 proof safe
  1068   fix Z assume *: "\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F"
  1069   with *[THEN spec, of "max Z c"] show "eventually (\<lambda>x. Z \<le> f x) F"
  1070     by (auto elim!: eventually_elim1)
  1071 qed simp
  1072 
  1073 lemma filterlim_at_top_at_top:
  1074   fixes f :: "'a::linorder \<Rightarrow> 'b::linorder"
  1075   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1076   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1077   assumes Q: "eventually Q at_top"
  1078   assumes P: "eventually P at_top"
  1079   shows "filterlim f at_top at_top"
  1080 proof -
  1081   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
  1082     unfolding eventually_at_top_linorder by auto
  1083   show ?thesis
  1084   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
  1085     fix z assume "x \<le> z"
  1086     with x have "P z" by auto
  1087     have "eventually (\<lambda>x. g z \<le> x) at_top"
  1088       by (rule eventually_ge_at_top)
  1089     with Q show "eventually (\<lambda>x. z \<le> f x) at_top"
  1090       by eventually_elim (metis mono bij `P z`)
  1091   qed
  1092 qed
  1093 
  1094 lemma filterlim_at_top_gt:
  1095   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
  1096   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1097   by (metis filterlim_at_top order_less_le_trans gt_ex filterlim_at_top_ge)
  1098 
  1099 lemma filterlim_at_bot: 
  1100   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1101   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F)"
  1102   by (auto simp: filterlim_iff eventually_at_bot_linorder elim!: eventually_elim1)
  1103 
  1104 lemma filterlim_at_bot_le:
  1105   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1106   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1107   unfolding filterlim_at_bot
  1108 proof safe
  1109   fix Z assume *: "\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F"
  1110   with *[THEN spec, of "min Z c"] show "eventually (\<lambda>x. Z \<ge> f x) F"
  1111     by (auto elim!: eventually_elim1)
  1112 qed simp
  1113 
  1114 lemma filterlim_at_bot_lt:
  1115   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
  1116   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z<c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1117   by (metis filterlim_at_bot filterlim_at_bot_le lt_ex order_le_less_trans)
  1118 
  1119 lemma filterlim_at_bot_at_right:
  1120   fixes f :: "'a::{no_top, linorder_topology} \<Rightarrow> 'b::linorder"
  1121   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1122   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1123   assumes Q: "eventually Q (at_right a)" and bound: "\<And>b. Q b \<Longrightarrow> a < b"
  1124   assumes P: "eventually P at_bot"
  1125   shows "filterlim f at_bot (at_right a)"
  1126 proof -
  1127   from P obtain x where x: "\<And>y. y \<le> x \<Longrightarrow> P y"
  1128     unfolding eventually_at_bot_linorder by auto
  1129   show ?thesis
  1130   proof (intro filterlim_at_bot_le[THEN iffD2] allI impI)
  1131     fix z assume "z \<le> x"
  1132     with x have "P z" by auto
  1133     have "eventually (\<lambda>x. x \<le> g z) (at_right a)"
  1134       using bound[OF bij(2)[OF `P z`]]
  1135       unfolding eventually_at_right by (auto intro!: exI[of _ "g z"])
  1136     with Q show "eventually (\<lambda>x. f x \<le> z) (at_right a)"
  1137       by eventually_elim (metis bij `P z` mono)
  1138   qed
  1139 qed
  1140 
  1141 lemma filterlim_at_top_at_left:
  1142   fixes f :: "'a::{no_bot, linorder_topology} \<Rightarrow> 'b::linorder"
  1143   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1144   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1145   assumes Q: "eventually Q (at_left a)" and bound: "\<And>b. Q b \<Longrightarrow> b < a"
  1146   assumes P: "eventually P at_top"
  1147   shows "filterlim f at_top (at_left a)"
  1148 proof -
  1149   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
  1150     unfolding eventually_at_top_linorder by auto
  1151   show ?thesis
  1152   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
  1153     fix z assume "x \<le> z"
  1154     with x have "P z" by auto
  1155     have "eventually (\<lambda>x. g z \<le> x) (at_left a)"
  1156       using bound[OF bij(2)[OF `P z`]]
  1157       unfolding eventually_at_left by (auto intro!: exI[of _ "g z"])
  1158     with Q show "eventually (\<lambda>x. z \<le> f x) (at_left a)"
  1159       by eventually_elim (metis bij `P z` mono)
  1160   qed
  1161 qed
  1162 
  1163 lemma filterlim_split_at:
  1164   "filterlim f F (at_left x) \<Longrightarrow> filterlim f F (at_right x) \<Longrightarrow> filterlim f F (at (x::'a::linorder_topology))"
  1165   by (subst at_eq_sup_left_right) (rule filterlim_sup)
  1166 
  1167 lemma filterlim_at_split:
  1168   "filterlim f F (at (x::'a::linorder_topology)) \<longleftrightarrow> filterlim f F (at_left x) \<and> filterlim f F (at_right x)"
  1169   by (subst at_eq_sup_left_right) (simp add: filterlim_def filtermap_sup)
  1170 
  1171 
  1172 subsection {* Limits on sequences *}
  1173 
  1174 abbreviation (in topological_space)
  1175   LIMSEQ :: "[nat \<Rightarrow> 'a, 'a] \<Rightarrow> bool"
  1176     ("((_)/ ----> (_))" [60, 60] 60) where
  1177   "X ----> L \<equiv> (X ---> L) sequentially"
  1178 
  1179 abbreviation (in t2_space) lim :: "(nat \<Rightarrow> 'a) \<Rightarrow> 'a" where
  1180   "lim X \<equiv> Lim sequentially X"
  1181 
  1182 definition (in topological_space) convergent :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
  1183   "convergent X = (\<exists>L. X ----> L)"
  1184 
  1185 lemma lim_def: "lim X = (THE L. X ----> L)"
  1186   unfolding Lim_def ..
  1187 
  1188 subsubsection {* Monotone sequences and subsequences *}
  1189 
  1190 definition
  1191   monoseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1192     --{*Definition of monotonicity.
  1193         The use of disjunction here complicates proofs considerably.
  1194         One alternative is to add a Boolean argument to indicate the direction.
  1195         Another is to develop the notions of increasing and decreasing first.*}
  1196   "monoseq X = ((\<forall>m. \<forall>n\<ge>m. X m \<le> X n) \<or> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m))"
  1197 
  1198 abbreviation incseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1199   "incseq X \<equiv> mono X"
  1200 
  1201 lemma incseq_def: "incseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<ge> X m)"
  1202   unfolding mono_def ..
  1203 
  1204 abbreviation decseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1205   "decseq X \<equiv> antimono X"
  1206 
  1207 lemma decseq_def: "decseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
  1208   unfolding antimono_def ..
  1209 
  1210 definition
  1211   subseq :: "(nat \<Rightarrow> nat) \<Rightarrow> bool" where
  1212     --{*Definition of subsequence*}
  1213   "subseq f \<longleftrightarrow> (\<forall>m. \<forall>n>m. f m < f n)"
  1214 
  1215 lemma incseq_SucI:
  1216   "(\<And>n. X n \<le> X (Suc n)) \<Longrightarrow> incseq X"
  1217   using lift_Suc_mono_le[of X]
  1218   by (auto simp: incseq_def)
  1219 
  1220 lemma incseqD: "\<And>i j. incseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f i \<le> f j"
  1221   by (auto simp: incseq_def)
  1222 
  1223 lemma incseq_SucD: "incseq A \<Longrightarrow> A i \<le> A (Suc i)"
  1224   using incseqD[of A i "Suc i"] by auto
  1225 
  1226 lemma incseq_Suc_iff: "incseq f \<longleftrightarrow> (\<forall>n. f n \<le> f (Suc n))"
  1227   by (auto intro: incseq_SucI dest: incseq_SucD)
  1228 
  1229 lemma incseq_const[simp, intro]: "incseq (\<lambda>x. k)"
  1230   unfolding incseq_def by auto
  1231 
  1232 lemma decseq_SucI:
  1233   "(\<And>n. X (Suc n) \<le> X n) \<Longrightarrow> decseq X"
  1234   using order.lift_Suc_mono_le[OF dual_order, of X]
  1235   by (auto simp: decseq_def)
  1236 
  1237 lemma decseqD: "\<And>i j. decseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f j \<le> f i"
  1238   by (auto simp: decseq_def)
  1239 
  1240 lemma decseq_SucD: "decseq A \<Longrightarrow> A (Suc i) \<le> A i"
  1241   using decseqD[of A i "Suc i"] by auto
  1242 
  1243 lemma decseq_Suc_iff: "decseq f \<longleftrightarrow> (\<forall>n. f (Suc n) \<le> f n)"
  1244   by (auto intro: decseq_SucI dest: decseq_SucD)
  1245 
  1246 lemma decseq_const[simp, intro]: "decseq (\<lambda>x. k)"
  1247   unfolding decseq_def by auto
  1248 
  1249 lemma monoseq_iff: "monoseq X \<longleftrightarrow> incseq X \<or> decseq X"
  1250   unfolding monoseq_def incseq_def decseq_def ..
  1251 
  1252 lemma monoseq_Suc:
  1253   "monoseq X \<longleftrightarrow> (\<forall>n. X n \<le> X (Suc n)) \<or> (\<forall>n. X (Suc n) \<le> X n)"
  1254   unfolding monoseq_iff incseq_Suc_iff decseq_Suc_iff ..
  1255 
  1256 lemma monoI1: "\<forall>m. \<forall> n \<ge> m. X m \<le> X n ==> monoseq X"
  1257 by (simp add: monoseq_def)
  1258 
  1259 lemma monoI2: "\<forall>m. \<forall> n \<ge> m. X n \<le> X m ==> monoseq X"
  1260 by (simp add: monoseq_def)
  1261 
  1262 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) ==> monoseq X"
  1263 by (simp add: monoseq_Suc)
  1264 
  1265 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n ==> monoseq X"
  1266 by (simp add: monoseq_Suc)
  1267 
  1268 lemma monoseq_minus:
  1269   fixes a :: "nat \<Rightarrow> 'a::ordered_ab_group_add"
  1270   assumes "monoseq a"
  1271   shows "monoseq (\<lambda> n. - a n)"
  1272 proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
  1273   case True
  1274   hence "\<forall> m. \<forall> n \<ge> m. - a n \<le> - a m" by auto
  1275   thus ?thesis by (rule monoI2)
  1276 next
  1277   case False
  1278   hence "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" using `monoseq a`[unfolded monoseq_def] by auto
  1279   thus ?thesis by (rule monoI1)
  1280 qed
  1281 
  1282 text{*Subsequence (alternative definition, (e.g. Hoskins)*}
  1283 
  1284 lemma subseq_Suc_iff: "subseq f = (\<forall>n. (f n) < (f (Suc n)))"
  1285 apply (simp add: subseq_def)
  1286 apply (auto dest!: less_imp_Suc_add)
  1287 apply (induct_tac k)
  1288 apply (auto intro: less_trans)
  1289 done
  1290 
  1291 text{* for any sequence, there is a monotonic subsequence *}
  1292 lemma seq_monosub:
  1293   fixes s :: "nat => 'a::linorder"
  1294   shows "\<exists>f. subseq f \<and> monoseq (\<lambda> n. (s (f n)))"
  1295 proof cases
  1296   let "?P p n" = "p > n \<and> (\<forall>m\<ge>p. s m \<le> s p)"
  1297   assume *: "\<forall>n. \<exists>p. ?P p n"
  1298   def f \<equiv> "rec_nat (SOME p. ?P p 0) (\<lambda>_ n. SOME p. ?P p n)"
  1299   have f_0: "f 0 = (SOME p. ?P p 0)" unfolding f_def by simp
  1300   have f_Suc: "\<And>i. f (Suc i) = (SOME p. ?P p (f i))" unfolding f_def nat.rec(2) ..
  1301   have P_0: "?P (f 0) 0" unfolding f_0 using *[rule_format] by (rule someI2_ex) auto
  1302   have P_Suc: "\<And>i. ?P (f (Suc i)) (f i)" unfolding f_Suc using *[rule_format] by (rule someI2_ex) auto
  1303   then have "subseq f" unfolding subseq_Suc_iff by auto
  1304   moreover have "monoseq (\<lambda>n. s (f n))" unfolding monoseq_Suc
  1305   proof (intro disjI2 allI)
  1306     fix n show "s (f (Suc n)) \<le> s (f n)"
  1307     proof (cases n)
  1308       case 0 with P_Suc[of 0] P_0 show ?thesis by auto
  1309     next
  1310       case (Suc m)
  1311       from P_Suc[of n] Suc have "f (Suc m) \<le> f (Suc (Suc m))" by simp
  1312       with P_Suc Suc show ?thesis by simp
  1313     qed
  1314   qed
  1315   ultimately show ?thesis by auto
  1316 next
  1317   let "?P p m" = "m < p \<and> s m < s p"
  1318   assume "\<not> (\<forall>n. \<exists>p>n. (\<forall>m\<ge>p. s m \<le> s p))"
  1319   then obtain N where N: "\<And>p. p > N \<Longrightarrow> \<exists>m>p. s p < s m" by (force simp: not_le le_less)
  1320   def f \<equiv> "rec_nat (SOME p. ?P p (Suc N)) (\<lambda>_ n. SOME p. ?P p n)"
  1321   have f_0: "f 0 = (SOME p. ?P p (Suc N))" unfolding f_def by simp
  1322   have f_Suc: "\<And>i. f (Suc i) = (SOME p. ?P p (f i))" unfolding f_def nat.rec(2) ..
  1323   have P_0: "?P (f 0) (Suc N)"
  1324     unfolding f_0 some_eq_ex[of "\<lambda>p. ?P p (Suc N)"] using N[of "Suc N"] by auto
  1325   { fix i have "N < f i \<Longrightarrow> ?P (f (Suc i)) (f i)"
  1326       unfolding f_Suc some_eq_ex[of "\<lambda>p. ?P p (f i)"] using N[of "f i"] . }
  1327   note P' = this
  1328   { fix i have "N < f i \<and> ?P (f (Suc i)) (f i)"
  1329       by (induct i) (insert P_0 P', auto) }
  1330   then have "subseq f" "monoseq (\<lambda>x. s (f x))"
  1331     unfolding subseq_Suc_iff monoseq_Suc by (auto simp: not_le intro: less_imp_le)
  1332   then show ?thesis by auto
  1333 qed
  1334 
  1335 lemma seq_suble: assumes sf: "subseq f" shows "n \<le> f n"
  1336 proof(induct n)
  1337   case 0 thus ?case by simp
  1338 next
  1339   case (Suc n)
  1340   from sf[unfolded subseq_Suc_iff, rule_format, of n] Suc.hyps
  1341   have "n < f (Suc n)" by arith
  1342   thus ?case by arith
  1343 qed
  1344 
  1345 lemma eventually_subseq:
  1346   "subseq r \<Longrightarrow> eventually P sequentially \<Longrightarrow> eventually (\<lambda>n. P (r n)) sequentially"
  1347   unfolding eventually_sequentially by (metis seq_suble le_trans)
  1348 
  1349 lemma not_eventually_sequentiallyD:
  1350   assumes P: "\<not> eventually P sequentially"
  1351   shows "\<exists>r. subseq r \<and> (\<forall>n. \<not> P (r n))"
  1352 proof -
  1353   from P have "\<forall>n. \<exists>m\<ge>n. \<not> P m"
  1354     unfolding eventually_sequentially by (simp add: not_less)
  1355   then obtain r where "\<And>n. r n \<ge> n" "\<And>n. \<not> P (r n)"
  1356     by (auto simp: choice_iff)
  1357   then show ?thesis
  1358     by (auto intro!: exI[of _ "\<lambda>n. r (((Suc \<circ> r) ^^ Suc n) 0)"]
  1359              simp: less_eq_Suc_le subseq_Suc_iff)
  1360 qed
  1361 
  1362 lemma filterlim_subseq: "subseq f \<Longrightarrow> filterlim f sequentially sequentially"
  1363   unfolding filterlim_iff by (metis eventually_subseq)
  1364 
  1365 lemma subseq_o: "subseq r \<Longrightarrow> subseq s \<Longrightarrow> subseq (r \<circ> s)"
  1366   unfolding subseq_def by simp
  1367 
  1368 lemma subseq_mono: assumes "subseq r" "m < n" shows "r m < r n"
  1369   using assms by (auto simp: subseq_def)
  1370 
  1371 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
  1372   by (simp add: incseq_def monoseq_def)
  1373 
  1374 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
  1375   by (simp add: decseq_def monoseq_def)
  1376 
  1377 lemma decseq_eq_incseq:
  1378   fixes X :: "nat \<Rightarrow> 'a::ordered_ab_group_add" shows "decseq X = incseq (\<lambda>n. - X n)" 
  1379   by (simp add: decseq_def incseq_def)
  1380 
  1381 lemma INT_decseq_offset:
  1382   assumes "decseq F"
  1383   shows "(\<Inter>i. F i) = (\<Inter>i\<in>{n..}. F i)"
  1384 proof safe
  1385   fix x i assume x: "x \<in> (\<Inter>i\<in>{n..}. F i)"
  1386   show "x \<in> F i"
  1387   proof cases
  1388     from x have "x \<in> F n" by auto
  1389     also assume "i \<le> n" with `decseq F` have "F n \<subseteq> F i"
  1390       unfolding decseq_def by simp
  1391     finally show ?thesis .
  1392   qed (insert x, simp)
  1393 qed auto
  1394 
  1395 lemma LIMSEQ_const_iff:
  1396   fixes k l :: "'a::t2_space"
  1397   shows "(\<lambda>n. k) ----> l \<longleftrightarrow> k = l"
  1398   using trivial_limit_sequentially by (rule tendsto_const_iff)
  1399 
  1400 lemma LIMSEQ_SUP:
  1401   "incseq X \<Longrightarrow> X ----> (SUP i. X i :: 'a :: {complete_linorder, linorder_topology})"
  1402   by (intro increasing_tendsto)
  1403      (auto simp: SUP_upper less_SUP_iff incseq_def eventually_sequentially intro: less_le_trans)
  1404 
  1405 lemma LIMSEQ_INF:
  1406   "decseq X \<Longrightarrow> X ----> (INF i. X i :: 'a :: {complete_linorder, linorder_topology})"
  1407   by (intro decreasing_tendsto)
  1408      (auto simp: INF_lower INF_less_iff decseq_def eventually_sequentially intro: le_less_trans)
  1409 
  1410 lemma LIMSEQ_ignore_initial_segment:
  1411   "f ----> a \<Longrightarrow> (\<lambda>n. f (n + k)) ----> a"
  1412   unfolding tendsto_def
  1413   by (subst eventually_sequentially_seg[where k=k])
  1414 
  1415 lemma LIMSEQ_offset:
  1416   "(\<lambda>n. f (n + k)) ----> a \<Longrightarrow> f ----> a"
  1417   unfolding tendsto_def
  1418   by (subst (asm) eventually_sequentially_seg[where k=k])
  1419 
  1420 lemma LIMSEQ_Suc: "f ----> l \<Longrightarrow> (\<lambda>n. f (Suc n)) ----> l"
  1421 by (drule_tac k="Suc 0" in LIMSEQ_ignore_initial_segment, simp)
  1422 
  1423 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) ----> l \<Longrightarrow> f ----> l"
  1424 by (rule_tac k="Suc 0" in LIMSEQ_offset, simp)
  1425 
  1426 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) ----> l = f ----> l"
  1427 by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
  1428 
  1429 lemma LIMSEQ_unique:
  1430   fixes a b :: "'a::t2_space"
  1431   shows "\<lbrakk>X ----> a; X ----> b\<rbrakk> \<Longrightarrow> a = b"
  1432   using trivial_limit_sequentially by (rule tendsto_unique)
  1433 
  1434 lemma LIMSEQ_le_const:
  1435   "\<lbrakk>X ----> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. a \<le> X n\<rbrakk> \<Longrightarrow> a \<le> x"
  1436   using tendsto_le_const[of sequentially X x a] by (simp add: eventually_sequentially)
  1437 
  1438 lemma LIMSEQ_le:
  1439   "\<lbrakk>X ----> x; Y ----> y; \<exists>N. \<forall>n\<ge>N. X n \<le> Y n\<rbrakk> \<Longrightarrow> x \<le> (y::'a::linorder_topology)"
  1440   using tendsto_le[of sequentially Y y X x] by (simp add: eventually_sequentially)
  1441 
  1442 lemma LIMSEQ_le_const2:
  1443   "\<lbrakk>X ----> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. X n \<le> a\<rbrakk> \<Longrightarrow> x \<le> a"
  1444   by (rule LIMSEQ_le[of X x "\<lambda>n. a"]) (auto simp: tendsto_const)
  1445 
  1446 lemma convergentD: "convergent X ==> \<exists>L. (X ----> L)"
  1447 by (simp add: convergent_def)
  1448 
  1449 lemma convergentI: "(X ----> L) ==> convergent X"
  1450 by (auto simp add: convergent_def)
  1451 
  1452 lemma convergent_LIMSEQ_iff: "convergent X = (X ----> lim X)"
  1453 by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
  1454 
  1455 lemma convergent_const: "convergent (\<lambda>n. c)"
  1456   by (rule convergentI, rule tendsto_const)
  1457 
  1458 lemma monoseq_le:
  1459   "monoseq a \<Longrightarrow> a ----> (x::'a::linorder_topology) \<Longrightarrow>
  1460     ((\<forall> n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)) \<or> ((\<forall> n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m))"
  1461   by (metis LIMSEQ_le_const LIMSEQ_le_const2 decseq_def incseq_def monoseq_iff)
  1462 
  1463 lemma LIMSEQ_subseq_LIMSEQ:
  1464   "\<lbrakk> X ----> L; subseq f \<rbrakk> \<Longrightarrow> (X o f) ----> L"
  1465   unfolding comp_def by (rule filterlim_compose[of X, OF _ filterlim_subseq])
  1466 
  1467 lemma convergent_subseq_convergent:
  1468   "\<lbrakk>convergent X; subseq f\<rbrakk> \<Longrightarrow> convergent (X o f)"
  1469   unfolding convergent_def by (auto intro: LIMSEQ_subseq_LIMSEQ)
  1470 
  1471 lemma limI: "X ----> L ==> lim X = L"
  1472 apply (simp add: lim_def)
  1473 apply (blast intro: LIMSEQ_unique)
  1474 done
  1475 
  1476 lemma lim_le: "convergent f \<Longrightarrow> (\<And>n. f n \<le> (x::'a::linorder_topology)) \<Longrightarrow> lim f \<le> x"
  1477   using LIMSEQ_le_const2[of f "lim f" x] by (simp add: convergent_LIMSEQ_iff)
  1478 
  1479 subsubsection{*Increasing and Decreasing Series*}
  1480 
  1481 lemma incseq_le: "incseq X \<Longrightarrow> X ----> L \<Longrightarrow> X n \<le> (L::'a::linorder_topology)"
  1482   by (metis incseq_def LIMSEQ_le_const)
  1483 
  1484 lemma decseq_le: "decseq X \<Longrightarrow> X ----> L \<Longrightarrow> (L::'a::linorder_topology) \<le> X n"
  1485   by (metis decseq_def LIMSEQ_le_const2)
  1486 
  1487 subsection {* First countable topologies *}
  1488 
  1489 class first_countable_topology = topological_space +
  1490   assumes first_countable_basis:
  1491     "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
  1492 
  1493 lemma (in first_countable_topology) countable_basis_at_decseq:
  1494   obtains A :: "nat \<Rightarrow> 'a set" where
  1495     "\<And>i. open (A i)" "\<And>i. x \<in> (A i)"
  1496     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1497 proof atomize_elim
  1498   from first_countable_basis[of x] obtain A :: "nat \<Rightarrow> 'a set" where
  1499     nhds: "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1500     and incl: "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>i. A i \<subseteq> S"  by auto
  1501   def F \<equiv> "\<lambda>n. \<Inter>i\<le>n. A i"
  1502   show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and>
  1503       (\<forall>S. open S \<longrightarrow> x \<in> S \<longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially)"
  1504   proof (safe intro!: exI[of _ F])
  1505     fix i
  1506     show "open (F i)" using nhds(1) by (auto simp: F_def)
  1507     show "x \<in> F i" using nhds(2) by (auto simp: F_def)
  1508   next
  1509     fix S assume "open S" "x \<in> S"
  1510     from incl[OF this] obtain i where "F i \<subseteq> S" unfolding F_def by auto
  1511     moreover have "\<And>j. i \<le> j \<Longrightarrow> F j \<subseteq> F i"
  1512       by (auto simp: F_def)
  1513     ultimately show "eventually (\<lambda>i. F i \<subseteq> S) sequentially"
  1514       by (auto simp: eventually_sequentially)
  1515   qed
  1516 qed
  1517 
  1518 lemma (in first_countable_topology) countable_basis:
  1519   obtains A :: "nat \<Rightarrow> 'a set" where
  1520     "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1521     "\<And>F. (\<forall>n. F n \<in> A n) \<Longrightarrow> F ----> x"
  1522 proof atomize_elim
  1523   obtain A :: "nat \<Rightarrow> 'a set" where A:
  1524     "\<And>i. open (A i)"
  1525     "\<And>i. x \<in> A i"
  1526     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1527     by (rule countable_basis_at_decseq) blast
  1528   {
  1529     fix F S assume "\<forall>n. F n \<in> A n" "open S" "x \<in> S"
  1530     with A(3)[of S] have "eventually (\<lambda>n. F n \<in> S) sequentially"
  1531       by (auto elim: eventually_elim1 simp: subset_eq)
  1532   }
  1533   with A show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and> (\<forall>F. (\<forall>n. F n \<in> A n) \<longrightarrow> F ----> x)"
  1534     by (intro exI[of _ A]) (auto simp: tendsto_def)
  1535 qed
  1536 
  1537 lemma (in first_countable_topology) sequentially_imp_eventually_nhds_within:
  1538   assumes "\<forall>f. (\<forall>n. f n \<in> s) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  1539   shows "eventually P (inf (nhds a) (principal s))"
  1540 proof (rule ccontr)
  1541   obtain A :: "nat \<Rightarrow> 'a set" where A:
  1542     "\<And>i. open (A i)"
  1543     "\<And>i. a \<in> A i"
  1544     "\<And>F. \<forall>n. F n \<in> A n \<Longrightarrow> F ----> a"
  1545     by (rule countable_basis) blast
  1546   assume "\<not> ?thesis"
  1547   with A have P: "\<exists>F. \<forall>n. F n \<in> s \<and> F n \<in> A n \<and> \<not> P (F n)"
  1548     unfolding eventually_inf_principal eventually_nhds by (intro choice) fastforce
  1549   then obtain F where F0: "\<forall>n. F n \<in> s" and F2: "\<forall>n. F n \<in> A n" and F3: "\<forall>n. \<not> P (F n)"
  1550     by blast
  1551   with A have "F ----> a" by auto
  1552   hence "eventually (\<lambda>n. P (F n)) sequentially"
  1553     using assms F0 by simp
  1554   thus "False" by (simp add: F3)
  1555 qed
  1556 
  1557 lemma (in first_countable_topology) eventually_nhds_within_iff_sequentially:
  1558   "eventually P (inf (nhds a) (principal s)) \<longleftrightarrow> 
  1559     (\<forall>f. (\<forall>n. f n \<in> s) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1560 proof (safe intro!: sequentially_imp_eventually_nhds_within)
  1561   assume "eventually P (inf (nhds a) (principal s))" 
  1562   then obtain S where "open S" "a \<in> S" "\<forall>x\<in>S. x \<in> s \<longrightarrow> P x"
  1563     by (auto simp: eventually_inf_principal eventually_nhds)
  1564   moreover fix f assume "\<forall>n. f n \<in> s" "f ----> a"
  1565   ultimately show "eventually (\<lambda>n. P (f n)) sequentially"
  1566     by (auto dest!: topological_tendstoD elim: eventually_elim1)
  1567 qed
  1568 
  1569 lemma (in first_countable_topology) eventually_nhds_iff_sequentially:
  1570   "eventually P (nhds a) \<longleftrightarrow> (\<forall>f. f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1571   using eventually_nhds_within_iff_sequentially[of P a UNIV] by simp
  1572 
  1573 subsection {* Function limit at a point *}
  1574 
  1575 abbreviation
  1576   LIM :: "('a::topological_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
  1577         ("((_)/ -- (_)/ --> (_))" [60, 0, 60] 60) where
  1578   "f -- a --> L \<equiv> (f ---> L) (at a)"
  1579 
  1580 lemma tendsto_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> (f ---> l) (at a within S) \<longleftrightarrow> (f -- a --> l)"
  1581   unfolding tendsto_def by (simp add: at_within_open[where S=S])
  1582 
  1583 lemma LIM_const_not_eq[tendsto_intros]:
  1584   fixes a :: "'a::perfect_space"
  1585   fixes k L :: "'b::t2_space"
  1586   shows "k \<noteq> L \<Longrightarrow> \<not> (\<lambda>x. k) -- a --> L"
  1587   by (simp add: tendsto_const_iff)
  1588 
  1589 lemmas LIM_not_zero = LIM_const_not_eq [where L = 0]
  1590 
  1591 lemma LIM_const_eq:
  1592   fixes a :: "'a::perfect_space"
  1593   fixes k L :: "'b::t2_space"
  1594   shows "(\<lambda>x. k) -- a --> L \<Longrightarrow> k = L"
  1595   by (simp add: tendsto_const_iff)
  1596 
  1597 lemma LIM_unique:
  1598   fixes a :: "'a::perfect_space" and L M :: "'b::t2_space"
  1599   shows "f -- a --> L \<Longrightarrow> f -- a --> M \<Longrightarrow> L = M"
  1600   using at_neq_bot by (rule tendsto_unique)
  1601 
  1602 text {* Limits are equal for functions equal except at limit point *}
  1603 
  1604 lemma LIM_equal: "\<forall>x. x \<noteq> a --> (f x = g x) \<Longrightarrow> (f -- a --> l) \<longleftrightarrow> (g -- a --> l)"
  1605   unfolding tendsto_def eventually_at_topological by simp
  1606 
  1607 lemma LIM_cong: "a = b \<Longrightarrow> (\<And>x. x \<noteq> b \<Longrightarrow> f x = g x) \<Longrightarrow> l = m \<Longrightarrow> (f -- a --> l) \<longleftrightarrow> (g -- b --> m)"
  1608   by (simp add: LIM_equal)
  1609 
  1610 lemma LIM_cong_limit: "f -- x --> L \<Longrightarrow> K = L \<Longrightarrow> f -- x --> K"
  1611   by simp
  1612 
  1613 lemma tendsto_at_iff_tendsto_nhds:
  1614   "g -- l --> g l \<longleftrightarrow> (g ---> g l) (nhds l)"
  1615   unfolding tendsto_def eventually_at_filter
  1616   by (intro ext all_cong imp_cong) (auto elim!: eventually_elim1)
  1617 
  1618 lemma tendsto_compose:
  1619   "g -- l --> g l \<Longrightarrow> (f ---> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> g l) F"
  1620   unfolding tendsto_at_iff_tendsto_nhds by (rule filterlim_compose[of g])
  1621 
  1622 lemma LIM_o: "\<lbrakk>g -- l --> g l; f -- a --> l\<rbrakk> \<Longrightarrow> (g \<circ> f) -- a --> g l"
  1623   unfolding o_def by (rule tendsto_compose)
  1624 
  1625 lemma tendsto_compose_eventually:
  1626   "g -- l --> m \<Longrightarrow> (f ---> l) F \<Longrightarrow> eventually (\<lambda>x. f x \<noteq> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> m) F"
  1627   by (rule filterlim_compose[of g _ "at l"]) (auto simp add: filterlim_at)
  1628 
  1629 lemma LIM_compose_eventually:
  1630   assumes f: "f -- a --> b"
  1631   assumes g: "g -- b --> c"
  1632   assumes inj: "eventually (\<lambda>x. f x \<noteq> b) (at a)"
  1633   shows "(\<lambda>x. g (f x)) -- a --> c"
  1634   using g f inj by (rule tendsto_compose_eventually)
  1635 
  1636 subsubsection {* Relation of LIM and LIMSEQ *}
  1637 
  1638 lemma (in first_countable_topology) sequentially_imp_eventually_within:
  1639   "(\<forall>f. (\<forall>n. f n \<in> s \<and> f n \<noteq> a) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow>
  1640     eventually P (at a within s)"
  1641   unfolding at_within_def
  1642   by (intro sequentially_imp_eventually_nhds_within) auto
  1643 
  1644 lemma (in first_countable_topology) sequentially_imp_eventually_at:
  1645   "(\<forall>f. (\<forall>n. f n \<noteq> a) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow> eventually P (at a)"
  1646   using assms sequentially_imp_eventually_within [where s=UNIV] by simp
  1647 
  1648 lemma LIMSEQ_SEQ_conv1:
  1649   fixes f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
  1650   assumes f: "f -- a --> l"
  1651   shows "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. f (S n)) ----> l"
  1652   using tendsto_compose_eventually [OF f, where F=sequentially] by simp
  1653 
  1654 lemma LIMSEQ_SEQ_conv2:
  1655   fixes f :: "'a::first_countable_topology \<Rightarrow> 'b::topological_space"
  1656   assumes "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. f (S n)) ----> l"
  1657   shows "f -- a --> l"
  1658   using assms unfolding tendsto_def [where l=l] by (simp add: sequentially_imp_eventually_at)
  1659 
  1660 lemma LIMSEQ_SEQ_conv:
  1661   "(\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> (a::'a::first_countable_topology) \<longrightarrow> (\<lambda>n. X (S n)) ----> L) =
  1662    (X -- a --> (L::'b::topological_space))"
  1663   using LIMSEQ_SEQ_conv2 LIMSEQ_SEQ_conv1 ..
  1664 
  1665 subsection {* Continuity *}
  1666 
  1667 subsubsection {* Continuity on a set *}
  1668 
  1669 definition continuous_on :: "'a set \<Rightarrow> ('a :: topological_space \<Rightarrow> 'b :: topological_space) \<Rightarrow> bool" where
  1670   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. (f ---> f x) (at x within s))"
  1671 
  1672 lemma continuous_on_cong [cong]:
  1673   "s = t \<Longrightarrow> (\<And>x. x \<in> t \<Longrightarrow> f x = g x) \<Longrightarrow> continuous_on s f \<longleftrightarrow> continuous_on t g"
  1674   unfolding continuous_on_def by (intro ball_cong filterlim_cong) (auto simp: eventually_at_filter)
  1675 
  1676 lemma continuous_on_topological:
  1677   "continuous_on s f \<longleftrightarrow>
  1678     (\<forall>x\<in>s. \<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  1679   unfolding continuous_on_def tendsto_def eventually_at_topological by metis
  1680 
  1681 lemma continuous_on_open_invariant:
  1682   "continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s))"
  1683 proof safe
  1684   fix B :: "'b set" assume "continuous_on s f" "open B"
  1685   then have "\<forall>x\<in>f -` B \<inter> s. (\<exists>A. open A \<and> x \<in> A \<and> s \<inter> A \<subseteq> f -` B)"
  1686     by (auto simp: continuous_on_topological subset_eq Ball_def imp_conjL)
  1687   then obtain A where "\<forall>x\<in>f -` B \<inter> s. open (A x) \<and> x \<in> A x \<and> s \<inter> A x \<subseteq> f -` B"
  1688     unfolding bchoice_iff ..
  1689   then show "\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s"
  1690     by (intro exI[of _ "\<Union>x\<in>f -` B \<inter> s. A x"]) auto
  1691 next
  1692   assume B: "\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s)"
  1693   show "continuous_on s f"
  1694     unfolding continuous_on_topological
  1695   proof safe
  1696     fix x B assume "x \<in> s" "open B" "f x \<in> B"
  1697     with B obtain A where A: "open A" "A \<inter> s = f -` B \<inter> s" by auto
  1698     with `x \<in> s` `f x \<in> B` show "\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)"
  1699       by (intro exI[of _ A]) auto
  1700   qed
  1701 qed
  1702 
  1703 lemma continuous_on_open_vimage:
  1704   "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> open (f -` B \<inter> s))"
  1705   unfolding continuous_on_open_invariant
  1706   by (metis open_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  1707 
  1708 corollary continuous_imp_open_vimage:
  1709   assumes "continuous_on s f" "open s" "open B" "f -` B \<subseteq> s"
  1710     shows "open (f -` B)"
  1711 by (metis assms continuous_on_open_vimage le_iff_inf)
  1712 
  1713 corollary open_vimage:
  1714   assumes "open s" and "continuous_on UNIV f"
  1715   shows "open (f -` s)"
  1716   using assms unfolding continuous_on_open_vimage [OF open_UNIV]
  1717   by simp
  1718 
  1719 lemma continuous_on_closed_invariant:
  1720   "continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> (\<exists>A. closed A \<and> A \<inter> s = f -` B \<inter> s))"
  1721 proof -
  1722   have *: "\<And>P Q::'b set\<Rightarrow>bool. (\<And>A. P A \<longleftrightarrow> Q (- A)) \<Longrightarrow> (\<forall>A. P A) \<longleftrightarrow> (\<forall>A. Q A)"
  1723     by (metis double_compl)
  1724   show ?thesis
  1725     unfolding continuous_on_open_invariant by (intro *) (auto simp: open_closed[symmetric])
  1726 qed
  1727 
  1728 lemma continuous_on_closed_vimage:
  1729   "closed s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> closed (f -` B \<inter> s))"
  1730   unfolding continuous_on_closed_invariant
  1731   by (metis closed_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  1732 
  1733 lemma continuous_on_open_Union:
  1734   "(\<And>s. s \<in> S \<Longrightarrow> open s) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on s f) \<Longrightarrow> continuous_on (\<Union>S) f"
  1735   unfolding continuous_on_def by safe (metis open_Union at_within_open UnionI)
  1736 
  1737 lemma continuous_on_open_UN:
  1738   "(\<And>s. s \<in> S \<Longrightarrow> open (A s)) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on (A s) f) \<Longrightarrow> continuous_on (\<Union>s\<in>S. A s) f"
  1739   unfolding Union_image_eq[symmetric] by (rule continuous_on_open_Union) auto
  1740 
  1741 lemma continuous_on_closed_Un:
  1742   "closed s \<Longrightarrow> closed t \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on t f \<Longrightarrow> continuous_on (s \<union> t) f"
  1743   by (auto simp add: continuous_on_closed_vimage closed_Un Int_Un_distrib)
  1744 
  1745 lemma continuous_on_If:
  1746   assumes closed: "closed s" "closed t" and cont: "continuous_on s f" "continuous_on t g"
  1747     and P: "\<And>x. x \<in> s \<Longrightarrow> \<not> P x \<Longrightarrow> f x = g x" "\<And>x. x \<in> t \<Longrightarrow> P x \<Longrightarrow> f x = g x"
  1748   shows "continuous_on (s \<union> t) (\<lambda>x. if P x then f x else g x)" (is "continuous_on _ ?h")
  1749 proof-
  1750   from P have "\<forall>x\<in>s. f x = ?h x" "\<forall>x\<in>t. g x = ?h x"
  1751     by auto
  1752   with cont have "continuous_on s ?h" "continuous_on t ?h"
  1753     by simp_all
  1754   with closed show ?thesis
  1755     by (rule continuous_on_closed_Un)
  1756 qed
  1757 
  1758 ML {*
  1759 
  1760 structure Continuous_On_Intros = Named_Thms
  1761 (
  1762   val name = @{binding continuous_on_intros}
  1763   val description = "Structural introduction rules for setwise continuity"
  1764 )
  1765 
  1766 *}
  1767 
  1768 setup Continuous_On_Intros.setup
  1769 
  1770 lemma continuous_on_id[continuous_on_intros]: "continuous_on s (\<lambda>x. x)"
  1771   unfolding continuous_on_def by (fast intro: tendsto_ident_at)
  1772 
  1773 lemma continuous_on_const[continuous_on_intros]: "continuous_on s (\<lambda>x. c)"
  1774   unfolding continuous_on_def by (auto intro: tendsto_const)
  1775 
  1776 lemma continuous_on_compose[continuous_on_intros]:
  1777   "continuous_on s f \<Longrightarrow> continuous_on (f ` s) g \<Longrightarrow> continuous_on s (g o f)"
  1778   unfolding continuous_on_topological by simp metis
  1779 
  1780 lemma continuous_on_compose2:
  1781   "continuous_on t g \<Longrightarrow> continuous_on s f \<Longrightarrow> t = f ` s \<Longrightarrow> continuous_on s (\<lambda>x. g (f x))"
  1782   using continuous_on_compose[of s f g] by (simp add: comp_def)
  1783 
  1784 subsubsection {* Continuity at a point *}
  1785 
  1786 definition continuous :: "'a::t2_space filter \<Rightarrow> ('a \<Rightarrow> 'b::topological_space) \<Rightarrow> bool" where
  1787   "continuous F f \<longleftrightarrow> (f ---> f (Lim F (\<lambda>x. x))) F"
  1788 
  1789 ML {*
  1790 
  1791 structure Continuous_Intros = Named_Thms
  1792 (
  1793   val name = @{binding continuous_intros}
  1794   val description = "Structural introduction rules for pointwise continuity"
  1795 )
  1796 
  1797 *}
  1798 
  1799 setup Continuous_Intros.setup
  1800 
  1801 lemma continuous_bot[continuous_intros, simp]: "continuous bot f"
  1802   unfolding continuous_def by auto
  1803 
  1804 lemma continuous_trivial_limit: "trivial_limit net \<Longrightarrow> continuous net f"
  1805   by simp
  1806 
  1807 lemma continuous_within: "continuous (at x within s) f \<longleftrightarrow> (f ---> f x) (at x within s)"
  1808   by (cases "trivial_limit (at x within s)") (auto simp add: Lim_ident_at continuous_def)
  1809 
  1810 lemma continuous_within_topological:
  1811   "continuous (at x within s) f \<longleftrightarrow>
  1812     (\<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  1813   unfolding continuous_within tendsto_def eventually_at_topological by metis
  1814 
  1815 lemma continuous_within_compose[continuous_intros]:
  1816   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  1817   continuous (at x within s) (g o f)"
  1818   by (simp add: continuous_within_topological) metis
  1819 
  1820 lemma continuous_within_compose2:
  1821   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  1822   continuous (at x within s) (\<lambda>x. g (f x))"
  1823   using continuous_within_compose[of x s f g] by (simp add: comp_def)
  1824 
  1825 lemma continuous_at: "continuous (at x) f \<longleftrightarrow> f -- x --> f x"
  1826   using continuous_within[of x UNIV f] by simp
  1827 
  1828 lemma continuous_ident[continuous_intros, simp]: "continuous (at x within S) (\<lambda>x. x)"
  1829   unfolding continuous_within by (rule tendsto_ident_at)
  1830 
  1831 lemma continuous_const[continuous_intros, simp]: "continuous F (\<lambda>x. c)"
  1832   unfolding continuous_def by (rule tendsto_const)
  1833 
  1834 lemma continuous_on_eq_continuous_within:
  1835   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. continuous (at x within s) f)"
  1836   unfolding continuous_on_def continuous_within ..
  1837 
  1838 abbreviation isCont :: "('a::t2_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> bool" where
  1839   "isCont f a \<equiv> continuous (at a) f"
  1840 
  1841 lemma isCont_def: "isCont f a \<longleftrightarrow> f -- a --> f a"
  1842   by (rule continuous_at)
  1843 
  1844 lemma continuous_at_within: "isCont f x \<Longrightarrow> continuous (at x within s) f"
  1845   by (auto intro: tendsto_mono at_le simp: continuous_at continuous_within)
  1846 
  1847 lemma continuous_on_eq_continuous_at: "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. isCont f x)"
  1848   by (simp add: continuous_on_def continuous_at at_within_open[of _ s])
  1849 
  1850 lemma continuous_on_subset: "continuous_on s f \<Longrightarrow> t \<subseteq> s \<Longrightarrow> continuous_on t f"
  1851   unfolding continuous_on_def by (metis subset_eq tendsto_within_subset)
  1852 
  1853 lemma continuous_at_imp_continuous_on: "\<forall>x\<in>s. isCont f x \<Longrightarrow> continuous_on s f"
  1854   by (auto intro: continuous_at_within simp: continuous_on_eq_continuous_within)
  1855 
  1856 lemma isContI_continuous: "continuous (at x within UNIV) f \<Longrightarrow> isCont f x"
  1857   by simp
  1858 
  1859 lemma isCont_ident[continuous_intros, simp]: "isCont (\<lambda>x. x) a"
  1860   using continuous_ident by (rule isContI_continuous)
  1861 
  1862 lemmas isCont_const = continuous_const
  1863 
  1864 lemma isCont_o2: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (\<lambda>x. g (f x)) a"
  1865   unfolding isCont_def by (rule tendsto_compose)
  1866 
  1867 lemma isCont_o[continuous_intros]: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (g \<circ> f) a"
  1868   unfolding o_def by (rule isCont_o2)
  1869 
  1870 lemma isCont_tendsto_compose: "isCont g l \<Longrightarrow> (f ---> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> g l) F"
  1871   unfolding isCont_def by (rule tendsto_compose)
  1872 
  1873 lemma continuous_within_compose3:
  1874   "isCont g (f x) \<Longrightarrow> continuous (at x within s) f \<Longrightarrow> continuous (at x within s) (\<lambda>x. g (f x))"
  1875   using continuous_within_compose2[of x s f g] by (simp add: continuous_at_within)
  1876 
  1877 subsubsection{* Open-cover compactness *}
  1878 
  1879 context topological_space
  1880 begin
  1881 
  1882 definition compact :: "'a set \<Rightarrow> bool" where
  1883   compact_eq_heine_borel: -- "This name is used for backwards compatibility"
  1884     "compact S \<longleftrightarrow> (\<forall>C. (\<forall>c\<in>C. open c) \<and> S \<subseteq> \<Union>C \<longrightarrow> (\<exists>D\<subseteq>C. finite D \<and> S \<subseteq> \<Union>D))"
  1885 
  1886 lemma compactI:
  1887   assumes "\<And>C. \<forall>t\<in>C. open t \<Longrightarrow> s \<subseteq> \<Union> C \<Longrightarrow> \<exists>C'. C' \<subseteq> C \<and> finite C' \<and> s \<subseteq> \<Union> C'"
  1888   shows "compact s"
  1889   unfolding compact_eq_heine_borel using assms by metis
  1890 
  1891 lemma compact_empty[simp]: "compact {}"
  1892   by (auto intro!: compactI)
  1893 
  1894 lemma compactE:
  1895   assumes "compact s" and "\<forall>t\<in>C. open t" and "s \<subseteq> \<Union>C"
  1896   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> \<Union>C'"
  1897   using assms unfolding compact_eq_heine_borel by metis
  1898 
  1899 lemma compactE_image:
  1900   assumes "compact s" and "\<forall>t\<in>C. open (f t)" and "s \<subseteq> (\<Union>c\<in>C. f c)"
  1901   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> (\<Union>c\<in>C'. f c)"
  1902   using assms unfolding ball_simps[symmetric] SUP_def
  1903   by (metis (lifting) finite_subset_image compact_eq_heine_borel[of s])
  1904 
  1905 lemma compact_inter_closed [intro]:
  1906   assumes "compact s" and "closed t"
  1907   shows "compact (s \<inter> t)"
  1908 proof (rule compactI)
  1909   fix C assume C: "\<forall>c\<in>C. open c" and cover: "s \<inter> t \<subseteq> \<Union>C"
  1910   from C `closed t` have "\<forall>c\<in>C \<union> {-t}. open c" by auto
  1911   moreover from cover have "s \<subseteq> \<Union>(C \<union> {-t})" by auto
  1912   ultimately have "\<exists>D\<subseteq>C \<union> {-t}. finite D \<and> s \<subseteq> \<Union>D"
  1913     using `compact s` unfolding compact_eq_heine_borel by auto
  1914   then obtain D where "D \<subseteq> C \<union> {- t} \<and> finite D \<and> s \<subseteq> \<Union>D" ..
  1915   then show "\<exists>D\<subseteq>C. finite D \<and> s \<inter> t \<subseteq> \<Union>D"
  1916     by (intro exI[of _ "D - {-t}"]) auto
  1917 qed
  1918 
  1919 lemma inj_setminus: "inj_on uminus (A::'a set set)"
  1920   by (auto simp: inj_on_def)
  1921 
  1922 lemma compact_fip:
  1923   "compact U \<longleftrightarrow>
  1924     (\<forall>A. (\<forall>a\<in>A. closed a) \<longrightarrow> (\<forall>B \<subseteq> A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}) \<longrightarrow> U \<inter> \<Inter>A \<noteq> {})"
  1925   (is "_ \<longleftrightarrow> ?R")
  1926 proof (safe intro!: compact_eq_heine_borel[THEN iffD2])
  1927   fix A
  1928   assume "compact U"
  1929     and A: "\<forall>a\<in>A. closed a" "U \<inter> \<Inter>A = {}"
  1930     and fi: "\<forall>B \<subseteq> A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}"
  1931   from A have "(\<forall>a\<in>uminus`A. open a) \<and> U \<subseteq> \<Union>(uminus`A)"
  1932     by auto
  1933   with `compact U` obtain B where "B \<subseteq> A" "finite (uminus`B)" "U \<subseteq> \<Union>(uminus`B)"
  1934     unfolding compact_eq_heine_borel by (metis subset_image_iff)
  1935   with fi[THEN spec, of B] show False
  1936     by (auto dest: finite_imageD intro: inj_setminus)
  1937 next
  1938   fix A
  1939   assume ?R
  1940   assume "\<forall>a\<in>A. open a" "U \<subseteq> \<Union>A"
  1941   then have "U \<inter> \<Inter>(uminus`A) = {}" "\<forall>a\<in>uminus`A. closed a"
  1942     by auto
  1943   with `?R` obtain B where "B \<subseteq> A" "finite (uminus`B)" "U \<inter> \<Inter>(uminus`B) = {}"
  1944     by (metis subset_image_iff)
  1945   then show "\<exists>T\<subseteq>A. finite T \<and> U \<subseteq> \<Union>T"
  1946     by  (auto intro!: exI[of _ B] inj_setminus dest: finite_imageD)
  1947 qed
  1948 
  1949 lemma compact_imp_fip:
  1950   "compact s \<Longrightarrow> \<forall>t \<in> f. closed t \<Longrightarrow> \<forall>f'. finite f' \<and> f' \<subseteq> f \<longrightarrow> (s \<inter> (\<Inter> f') \<noteq> {}) \<Longrightarrow>
  1951     s \<inter> (\<Inter> f) \<noteq> {}"
  1952   unfolding compact_fip by auto
  1953 
  1954 lemma compact_imp_fip_image:
  1955   assumes "compact s"
  1956     and P: "\<And>i. i \<in> I \<Longrightarrow> closed (f i)"
  1957     and Q: "\<And>I'. finite I' \<Longrightarrow> I' \<subseteq> I \<Longrightarrow> (s \<inter> (\<Inter>i\<in>I'. f i) \<noteq> {})"
  1958   shows "s \<inter> (\<Inter>i\<in>I. f i) \<noteq> {}"
  1959 proof -
  1960   note `compact s`
  1961   moreover from P have "\<forall>i \<in> f ` I. closed i" by blast
  1962   moreover have "\<forall>A. finite A \<and> A \<subseteq> f ` I \<longrightarrow> (s \<inter> (\<Inter>A) \<noteq> {})"
  1963   proof (rule, rule, erule conjE)
  1964     fix A :: "'a set set"
  1965     assume "finite A"
  1966     moreover assume "A \<subseteq> f ` I"
  1967     ultimately obtain B where "B \<subseteq> I" and "finite B" and "A = f ` B"
  1968       using finite_subset_image [of A f I] by blast
  1969     with Q [of B] show "s \<inter> \<Inter>A \<noteq> {}" by simp
  1970   qed
  1971   ultimately have "s \<inter> (\<Inter>(f ` I)) \<noteq> {}" by (rule compact_imp_fip)
  1972   then show ?thesis by simp
  1973 qed
  1974 
  1975 end
  1976 
  1977 lemma (in t2_space) compact_imp_closed:
  1978   assumes "compact s" shows "closed s"
  1979 unfolding closed_def
  1980 proof (rule openI)
  1981   fix y assume "y \<in> - s"
  1982   let ?C = "\<Union>x\<in>s. {u. open u \<and> x \<in> u \<and> eventually (\<lambda>y. y \<notin> u) (nhds y)}"
  1983   note `compact s`
  1984   moreover have "\<forall>u\<in>?C. open u" by simp
  1985   moreover have "s \<subseteq> \<Union>?C"
  1986   proof
  1987     fix x assume "x \<in> s"
  1988     with `y \<in> - s` have "x \<noteq> y" by clarsimp
  1989     hence "\<exists>u v. open u \<and> open v \<and> x \<in> u \<and> y \<in> v \<and> u \<inter> v = {}"
  1990       by (rule hausdorff)
  1991     with `x \<in> s` show "x \<in> \<Union>?C"
  1992       unfolding eventually_nhds by auto
  1993   qed
  1994   ultimately obtain D where "D \<subseteq> ?C" and "finite D" and "s \<subseteq> \<Union>D"
  1995     by (rule compactE)
  1996   from `D \<subseteq> ?C` have "\<forall>x\<in>D. eventually (\<lambda>y. y \<notin> x) (nhds y)" by auto
  1997   with `finite D` have "eventually (\<lambda>y. y \<notin> \<Union>D) (nhds y)"
  1998     by (simp add: eventually_Ball_finite)
  1999   with `s \<subseteq> \<Union>D` have "eventually (\<lambda>y. y \<notin> s) (nhds y)"
  2000     by (auto elim!: eventually_mono [rotated])
  2001   thus "\<exists>t. open t \<and> y \<in> t \<and> t \<subseteq> - s"
  2002     by (simp add: eventually_nhds subset_eq)
  2003 qed
  2004 
  2005 lemma compact_continuous_image:
  2006   assumes f: "continuous_on s f" and s: "compact s"
  2007   shows "compact (f ` s)"
  2008 proof (rule compactI)
  2009   fix C assume "\<forall>c\<in>C. open c" and cover: "f`s \<subseteq> \<Union>C"
  2010   with f have "\<forall>c\<in>C. \<exists>A. open A \<and> A \<inter> s = f -` c \<inter> s"
  2011     unfolding continuous_on_open_invariant by blast
  2012   then obtain A where A: "\<forall>c\<in>C. open (A c) \<and> A c \<inter> s = f -` c \<inter> s"
  2013     unfolding bchoice_iff ..
  2014   with cover have "\<forall>c\<in>C. open (A c)" "s \<subseteq> (\<Union>c\<in>C. A c)"
  2015     by (fastforce simp add: subset_eq set_eq_iff)+
  2016   from compactE_image[OF s this] obtain D where "D \<subseteq> C" "finite D" "s \<subseteq> (\<Union>c\<in>D. A c)" .
  2017   with A show "\<exists>D \<subseteq> C. finite D \<and> f`s \<subseteq> \<Union>D"
  2018     by (intro exI[of _ D]) (fastforce simp add: subset_eq set_eq_iff)+
  2019 qed
  2020 
  2021 lemma continuous_on_inv:
  2022   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  2023   assumes "continuous_on s f"  "compact s"  "\<forall>x\<in>s. g (f x) = x"
  2024   shows "continuous_on (f ` s) g"
  2025 unfolding continuous_on_topological
  2026 proof (clarsimp simp add: assms(3))
  2027   fix x :: 'a and B :: "'a set"
  2028   assume "x \<in> s" and "open B" and "x \<in> B"
  2029   have 1: "\<forall>x\<in>s. f x \<in> f ` (s - B) \<longleftrightarrow> x \<in> s - B"
  2030     using assms(3) by (auto, metis)
  2031   have "continuous_on (s - B) f"
  2032     using `continuous_on s f` Diff_subset
  2033     by (rule continuous_on_subset)
  2034   moreover have "compact (s - B)"
  2035     using `open B` and `compact s`
  2036     unfolding Diff_eq by (intro compact_inter_closed closed_Compl)
  2037   ultimately have "compact (f ` (s - B))"
  2038     by (rule compact_continuous_image)
  2039   hence "closed (f ` (s - B))"
  2040     by (rule compact_imp_closed)
  2041   hence "open (- f ` (s - B))"
  2042     by (rule open_Compl)
  2043   moreover have "f x \<in> - f ` (s - B)"
  2044     using `x \<in> s` and `x \<in> B` by (simp add: 1)
  2045   moreover have "\<forall>y\<in>s. f y \<in> - f ` (s - B) \<longrightarrow> y \<in> B"
  2046     by (simp add: 1)
  2047   ultimately show "\<exists>A. open A \<and> f x \<in> A \<and> (\<forall>y\<in>s. f y \<in> A \<longrightarrow> y \<in> B)"
  2048     by fast
  2049 qed
  2050 
  2051 lemma continuous_on_inv_into:
  2052   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  2053   assumes s: "continuous_on s f" "compact s" and f: "inj_on f s"
  2054   shows "continuous_on (f ` s) (the_inv_into s f)"
  2055   by (rule continuous_on_inv[OF s]) (auto simp: the_inv_into_f_f[OF f])
  2056 
  2057 lemma (in linorder_topology) compact_attains_sup:
  2058   assumes "compact S" "S \<noteq> {}"
  2059   shows "\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s"
  2060 proof (rule classical)
  2061   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s)"
  2062   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. s < t s"
  2063     by (metis not_le)
  2064   then have "\<forall>s\<in>S. open {..< t s}" "S \<subseteq> (\<Union>s\<in>S. {..< t s})"
  2065     by auto
  2066   with `compact S` obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {..< t s})"
  2067     by (erule compactE_image)
  2068   with `S \<noteq> {}` have Max: "Max (t`C) \<in> t`C" and "\<forall>s\<in>t`C. s \<le> Max (t`C)"
  2069     by (auto intro!: Max_in)
  2070   with C have "S \<subseteq> {..< Max (t`C)}"
  2071     by (auto intro: less_le_trans simp: subset_eq)
  2072   with t Max `C \<subseteq> S` show ?thesis
  2073     by fastforce
  2074 qed
  2075 
  2076 lemma (in linorder_topology) compact_attains_inf:
  2077   assumes "compact S" "S \<noteq> {}"
  2078   shows "\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t"
  2079 proof (rule classical)
  2080   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t)"
  2081   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. t s < s"
  2082     by (metis not_le)
  2083   then have "\<forall>s\<in>S. open {t s <..}" "S \<subseteq> (\<Union>s\<in>S. {t s <..})"
  2084     by auto
  2085   with `compact S` obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {t s <..})"
  2086     by (erule compactE_image)
  2087   with `S \<noteq> {}` have Min: "Min (t`C) \<in> t`C" and "\<forall>s\<in>t`C. Min (t`C) \<le> s"
  2088     by (auto intro!: Min_in)
  2089   with C have "S \<subseteq> {Min (t`C) <..}"
  2090     by (auto intro: le_less_trans simp: subset_eq)
  2091   with t Min `C \<subseteq> S` show ?thesis
  2092     by fastforce
  2093 qed
  2094 
  2095 lemma continuous_attains_sup:
  2096   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2097   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s.  f y \<le> f x)"
  2098   using compact_attains_sup[of "f ` s"] compact_continuous_image[of s f] by auto
  2099 
  2100 lemma continuous_attains_inf:
  2101   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2102   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s. f x \<le> f y)"
  2103   using compact_attains_inf[of "f ` s"] compact_continuous_image[of s f] by auto
  2104 
  2105 
  2106 subsection {* Connectedness *}
  2107 
  2108 context topological_space
  2109 begin
  2110 
  2111 definition "connected S \<longleftrightarrow>
  2112   \<not> (\<exists>A B. open A \<and> open B \<and> S \<subseteq> A \<union> B \<and> A \<inter> B \<inter> S = {} \<and> A \<inter> S \<noteq> {} \<and> B \<inter> S \<noteq> {})"
  2113 
  2114 lemma connectedI:
  2115   "(\<And>A B. open A \<Longrightarrow> open B \<Longrightarrow> A \<inter> U \<noteq> {} \<Longrightarrow> B \<inter> U \<noteq> {} \<Longrightarrow> A \<inter> B \<inter> U = {} \<Longrightarrow> U \<subseteq> A \<union> B \<Longrightarrow> False)
  2116   \<Longrightarrow> connected U"
  2117   by (auto simp: connected_def)
  2118 
  2119 lemma connected_empty[simp]: "connected {}"
  2120   by (auto intro!: connectedI)
  2121 
  2122 end
  2123 
  2124 lemma (in linorder_topology) connectedD_interval:
  2125   assumes "connected U" and xy: "x \<in> U" "y \<in> U" and "x \<le> z" "z \<le> y"
  2126   shows "z \<in> U"
  2127 proof -
  2128   have eq: "{..<z} \<union> {z<..} = - {z}"
  2129     by auto
  2130   { assume "z \<notin> U" "x < z" "z < y"
  2131     with xy have "\<not> connected U"
  2132       unfolding connected_def simp_thms
  2133       apply (rule_tac exI[of _ "{..< z}"])
  2134       apply (rule_tac exI[of _ "{z <..}"])
  2135       apply (auto simp add: eq)
  2136       done }
  2137   with assms show "z \<in> U"
  2138     by (metis less_le)
  2139 qed
  2140 
  2141 lemma connected_continuous_image:
  2142   assumes *: "continuous_on s f"
  2143   assumes "connected s"
  2144   shows "connected (f ` s)"
  2145 proof (rule connectedI)
  2146   fix A B assume A: "open A" "A \<inter> f ` s \<noteq> {}" and B: "open B" "B \<inter> f ` s \<noteq> {}" and
  2147     AB: "A \<inter> B \<inter> f ` s = {}" "f ` s \<subseteq> A \<union> B"
  2148   obtain A' where A': "open A'" "f -` A \<inter> s = A' \<inter> s"
  2149     using * `open A` unfolding continuous_on_open_invariant by metis
  2150   obtain B' where B': "open B'" "f -` B \<inter> s = B' \<inter> s"
  2151     using * `open B` unfolding continuous_on_open_invariant by metis
  2152 
  2153   have "\<exists>A B. open A \<and> open B \<and> s \<subseteq> A \<union> B \<and> A \<inter> B \<inter> s = {} \<and> A \<inter> s \<noteq> {} \<and> B \<inter> s \<noteq> {}"
  2154   proof (rule exI[of _ A'], rule exI[of _ B'], intro conjI)
  2155     have "s \<subseteq> (f -` A \<inter> s) \<union> (f -` B \<inter> s)" using AB by auto
  2156     then show "s \<subseteq> A' \<union> B'" using A' B' by auto
  2157   next
  2158     have "(f -` A \<inter> s) \<inter> (f -` B \<inter> s) = {}" using AB by auto
  2159     then show "A' \<inter> B' \<inter> s = {}" using A' B' by auto
  2160   qed (insert A' B' A B, auto)
  2161   with `connected s` show False
  2162     unfolding connected_def by blast
  2163 qed
  2164 
  2165 
  2166 section {* Connectedness *}
  2167 
  2168 class linear_continuum_topology = linorder_topology + linear_continuum
  2169 begin
  2170 
  2171 lemma Inf_notin_open:
  2172   assumes A: "open A" and bnd: "\<forall>a\<in>A. x < a"
  2173   shows "Inf A \<notin> A"
  2174 proof
  2175   assume "Inf A \<in> A"
  2176   then obtain b where "b < Inf A" "{b <.. Inf A} \<subseteq> A"
  2177     using open_left[of A "Inf A" x] assms by auto
  2178   with dense[of b "Inf A"] obtain c where "c < Inf A" "c \<in> A"
  2179     by (auto simp: subset_eq)
  2180   then show False
  2181     using cInf_lower[OF `c \<in> A`] bnd by (metis not_le less_imp_le bdd_belowI)
  2182 qed
  2183 
  2184 lemma Sup_notin_open:
  2185   assumes A: "open A" and bnd: "\<forall>a\<in>A. a < x"
  2186   shows "Sup A \<notin> A"
  2187 proof
  2188   assume "Sup A \<in> A"
  2189   then obtain b where "Sup A < b" "{Sup A ..< b} \<subseteq> A"
  2190     using open_right[of A "Sup A" x] assms by auto
  2191   with dense[of "Sup A" b] obtain c where "Sup A < c" "c \<in> A"
  2192     by (auto simp: subset_eq)
  2193   then show False
  2194     using cSup_upper[OF `c \<in> A`] bnd by (metis less_imp_le not_le bdd_aboveI)
  2195 qed
  2196 
  2197 end
  2198 
  2199 instance linear_continuum_topology \<subseteq> perfect_space
  2200 proof
  2201   fix x :: 'a
  2202   obtain y where "x < y \<or> y < x"
  2203     using ex_gt_or_lt [of x] ..
  2204   with Inf_notin_open[of "{x}" y] Sup_notin_open[of "{x}" y]
  2205   show "\<not> open {x}"
  2206     by auto
  2207 qed
  2208 
  2209 lemma connectedI_interval:
  2210   fixes U :: "'a :: linear_continuum_topology set"
  2211   assumes *: "\<And>x y z. x \<in> U \<Longrightarrow> y \<in> U \<Longrightarrow> x \<le> z \<Longrightarrow> z \<le> y \<Longrightarrow> z \<in> U"
  2212   shows "connected U"
  2213 proof (rule connectedI)
  2214   { fix A B assume "open A" "open B" "A \<inter> B \<inter> U = {}" "U \<subseteq> A \<union> B"
  2215     fix x y assume "x < y" "x \<in> A" "y \<in> B" "x \<in> U" "y \<in> U"
  2216 
  2217     let ?z = "Inf (B \<inter> {x <..})"
  2218 
  2219     have "x \<le> ?z" "?z \<le> y"
  2220       using `y \<in> B` `x < y` by (auto intro: cInf_lower cInf_greatest)
  2221     with `x \<in> U` `y \<in> U` have "?z \<in> U"
  2222       by (rule *)
  2223     moreover have "?z \<notin> B \<inter> {x <..}"
  2224       using `open B` by (intro Inf_notin_open) auto
  2225     ultimately have "?z \<in> A"
  2226       using `x \<le> ?z` `A \<inter> B \<inter> U = {}` `x \<in> A` `U \<subseteq> A \<union> B` by auto
  2227 
  2228     { assume "?z < y"
  2229       obtain a where "?z < a" "{?z ..< a} \<subseteq> A"
  2230         using open_right[OF `open A` `?z \<in> A` `?z < y`] by auto
  2231       moreover obtain b where "b \<in> B" "x < b" "b < min a y"
  2232         using cInf_less_iff[of "B \<inter> {x <..}" "min a y"] `?z < a` `?z < y` `x < y` `y \<in> B`
  2233         by (auto intro: less_imp_le)
  2234       moreover have "?z \<le> b"
  2235         using `b \<in> B` `x < b`
  2236         by (intro cInf_lower) auto
  2237       moreover have "b \<in> U"
  2238         using `x \<le> ?z` `?z \<le> b` `b < min a y`
  2239         by (intro *[OF `x \<in> U` `y \<in> U`]) (auto simp: less_imp_le)
  2240       ultimately have "\<exists>b\<in>B. b \<in> A \<and> b \<in> U"
  2241         by (intro bexI[of _ b]) auto }
  2242     then have False
  2243       using `?z \<le> y` `?z \<in> A` `y \<in> B` `y \<in> U` `A \<inter> B \<inter> U = {}` unfolding le_less by blast }
  2244   note not_disjoint = this
  2245 
  2246   fix A B assume AB: "open A" "open B" "U \<subseteq> A \<union> B" "A \<inter> B \<inter> U = {}"
  2247   moreover assume "A \<inter> U \<noteq> {}" then obtain x where x: "x \<in> U" "x \<in> A" by auto
  2248   moreover assume "B \<inter> U \<noteq> {}" then obtain y where y: "y \<in> U" "y \<in> B" by auto
  2249   moreover note not_disjoint[of B A y x] not_disjoint[of A B x y]
  2250   ultimately show False by (cases x y rule: linorder_cases) auto
  2251 qed
  2252 
  2253 lemma connected_iff_interval:
  2254   fixes U :: "'a :: linear_continuum_topology set"
  2255   shows "connected U \<longleftrightarrow> (\<forall>x\<in>U. \<forall>y\<in>U. \<forall>z. x \<le> z \<longrightarrow> z \<le> y \<longrightarrow> z \<in> U)"
  2256   by (auto intro: connectedI_interval dest: connectedD_interval)
  2257 
  2258 lemma connected_UNIV[simp]: "connected (UNIV::'a::linear_continuum_topology set)"
  2259   unfolding connected_iff_interval by auto
  2260 
  2261 lemma connected_Ioi[simp]: "connected {a::'a::linear_continuum_topology <..}"
  2262   unfolding connected_iff_interval by auto
  2263 
  2264 lemma connected_Ici[simp]: "connected {a::'a::linear_continuum_topology ..}"
  2265   unfolding connected_iff_interval by auto
  2266 
  2267 lemma connected_Iio[simp]: "connected {..< a::'a::linear_continuum_topology}"
  2268   unfolding connected_iff_interval by auto
  2269 
  2270 lemma connected_Iic[simp]: "connected {.. a::'a::linear_continuum_topology}"
  2271   unfolding connected_iff_interval by auto
  2272 
  2273 lemma connected_Ioo[simp]: "connected {a <..< b::'a::linear_continuum_topology}"
  2274   unfolding connected_iff_interval by auto
  2275 
  2276 lemma connected_Ioc[simp]: "connected {a <.. b::'a::linear_continuum_topology}"
  2277   unfolding connected_iff_interval by auto
  2278 
  2279 lemma connected_Ico[simp]: "connected {a ..< b::'a::linear_continuum_topology}"
  2280   unfolding connected_iff_interval by auto
  2281 
  2282 lemma connected_Icc[simp]: "connected {a .. b::'a::linear_continuum_topology}"
  2283   unfolding connected_iff_interval by auto
  2284 
  2285 lemma connected_contains_Ioo: 
  2286   fixes A :: "'a :: linorder_topology set"
  2287   assumes A: "connected A" "a \<in> A" "b \<in> A" shows "{a <..< b} \<subseteq> A"
  2288   using connectedD_interval[OF A] by (simp add: subset_eq Ball_def less_imp_le)
  2289 
  2290 subsection {* Intermediate Value Theorem *}
  2291 
  2292 lemma IVT':
  2293   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2294   assumes y: "f a \<le> y" "y \<le> f b" "a \<le> b"
  2295   assumes *: "continuous_on {a .. b} f"
  2296   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2297 proof -
  2298   have "connected {a..b}"
  2299     unfolding connected_iff_interval by auto
  2300   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f a" "f b" y] y
  2301   show ?thesis
  2302     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2303 qed
  2304 
  2305 lemma IVT2':
  2306   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2307   assumes y: "f b \<le> y" "y \<le> f a" "a \<le> b"
  2308   assumes *: "continuous_on {a .. b} f"
  2309   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2310 proof -
  2311   have "connected {a..b}"
  2312     unfolding connected_iff_interval by auto
  2313   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f b" "f a" y] y
  2314   show ?thesis
  2315     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2316 qed
  2317 
  2318 lemma IVT:
  2319   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2320   shows "f a \<le> y \<Longrightarrow> y \<le> f b \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow> \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2321   by (rule IVT') (auto intro: continuous_at_imp_continuous_on)
  2322 
  2323 lemma IVT2:
  2324   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2325   shows "f b \<le> y \<Longrightarrow> y \<le> f a \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow> \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2326   by (rule IVT2') (auto intro: continuous_at_imp_continuous_on)
  2327 
  2328 lemma continuous_inj_imp_mono:
  2329   fixes f :: "'a::linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2330   assumes x: "a < x" "x < b"
  2331   assumes cont: "continuous_on {a..b} f"
  2332   assumes inj: "inj_on f {a..b}"
  2333   shows "(f a < f x \<and> f x < f b) \<or> (f b < f x \<and> f x < f a)"
  2334 proof -
  2335   note I = inj_on_iff[OF inj]
  2336   { assume "f x < f a" "f x < f b"
  2337     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f x < f s"
  2338       using IVT'[of f x "min (f a) (f b)" b] IVT2'[of f x "min (f a) (f b)" a] x
  2339       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2340     with x I have False by auto }
  2341   moreover
  2342   { assume "f a < f x" "f b < f x"
  2343     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f s < f x"
  2344       using IVT'[of f a "max (f a) (f b)" x] IVT2'[of f b "max (f a) (f b)" x] x
  2345       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2346     with x I have False by auto }
  2347   ultimately show ?thesis
  2348     using I[of a x] I[of x b] x less_trans[OF x] by (auto simp add: le_less less_imp_neq neq_iff)
  2349 qed
  2350 
  2351 subsection {* Setup @{typ "'a filter"} for lifting and transfer *}
  2352 
  2353 context begin interpretation lifting_syntax .
  2354 
  2355 definition rel_filter :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> 'b filter \<Rightarrow> bool"
  2356 where "rel_filter R F G = ((R ===> op =) ===> op =) (Rep_filter F) (Rep_filter G)"
  2357 
  2358 lemma rel_filter_eventually:
  2359   "rel_filter R F G \<longleftrightarrow> 
  2360   ((R ===> op =) ===> op =) (\<lambda>P. eventually P F) (\<lambda>P. eventually P G)"
  2361 by(simp add: rel_filter_def eventually_def)
  2362 
  2363 lemma filtermap_id [simp, id_simps]: "filtermap id = id"
  2364 by(simp add: fun_eq_iff id_def filtermap_ident)
  2365 
  2366 lemma filtermap_id' [simp]: "filtermap (\<lambda>x. x) = (\<lambda>F. F)"
  2367 using filtermap_id unfolding id_def .
  2368 
  2369 lemma Quotient_filter [quot_map]:
  2370   assumes Q: "Quotient R Abs Rep T"
  2371   shows "Quotient (rel_filter R) (filtermap Abs) (filtermap Rep) (rel_filter T)"
  2372 unfolding Quotient_alt_def
  2373 proof(intro conjI strip)
  2374   from Q have *: "\<And>x y. T x y \<Longrightarrow> Abs x = y"
  2375     unfolding Quotient_alt_def by blast
  2376 
  2377   fix F G
  2378   assume "rel_filter T F G"
  2379   thus "filtermap Abs F = G" unfolding filter_eq_iff
  2380     by(auto simp add: eventually_filtermap rel_filter_eventually * rel_funI del: iffI elim!: rel_funD)
  2381 next
  2382   from Q have *: "\<And>x. T (Rep x) x" unfolding Quotient_alt_def by blast
  2383 
  2384   fix F
  2385   show "rel_filter T (filtermap Rep F) F" 
  2386     by(auto elim: rel_funD intro: * intro!: ext arg_cong[where f="\<lambda>P. eventually P F"] rel_funI
  2387             del: iffI simp add: eventually_filtermap rel_filter_eventually)
  2388 qed(auto simp add: map_fun_def o_def eventually_filtermap filter_eq_iff fun_eq_iff rel_filter_eventually
  2389          fun_quotient[OF fun_quotient[OF Q identity_quotient] identity_quotient, unfolded Quotient_alt_def])
  2390 
  2391 lemma eventually_parametric [transfer_rule]:
  2392   "((A ===> op =) ===> rel_filter A ===> op =) eventually eventually"
  2393 by(simp add: rel_fun_def rel_filter_eventually)
  2394 
  2395 lemma rel_filter_eq [relator_eq]: "rel_filter op = = op ="
  2396 by(auto simp add: rel_filter_eventually rel_fun_eq fun_eq_iff filter_eq_iff)
  2397 
  2398 lemma rel_filter_mono [relator_mono]:
  2399   "A \<le> B \<Longrightarrow> rel_filter A \<le> rel_filter B"
  2400 unfolding rel_filter_eventually[abs_def]
  2401 by(rule le_funI)+(intro fun_mono fun_mono[THEN le_funD, THEN le_funD] order.refl)
  2402 
  2403 lemma rel_filter_conversep [simp]: "rel_filter A\<inverse>\<inverse> = (rel_filter A)\<inverse>\<inverse>"
  2404 by(auto simp add: rel_filter_eventually fun_eq_iff rel_fun_def)
  2405 
  2406 lemma is_filter_parametric_aux:
  2407   assumes "is_filter F"
  2408   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  2409   and [transfer_rule]: "((A ===> op =) ===> op =) F G"
  2410   shows "is_filter G"
  2411 proof -
  2412   interpret is_filter F by fact
  2413   show ?thesis
  2414   proof
  2415     have "F (\<lambda>_. True) = G (\<lambda>x. True)" by transfer_prover
  2416     thus "G (\<lambda>x. True)" by(simp add: True)
  2417   next
  2418     fix P' Q'
  2419     assume "G P'" "G Q'"
  2420     moreover
  2421     from bi_total_fun[OF `bi_unique A` bi_total_eq, unfolded bi_total_def]
  2422     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  2423     have "F P = G P'" "F Q = G Q'" by transfer_prover+
  2424     ultimately have "F (\<lambda>x. P x \<and> Q x)" by(simp add: conj)
  2425     moreover have "F (\<lambda>x. P x \<and> Q x) = G (\<lambda>x. P' x \<and> Q' x)" by transfer_prover
  2426     ultimately show "G (\<lambda>x. P' x \<and> Q' x)" by simp
  2427   next
  2428     fix P' Q'
  2429     assume "\<forall>x. P' x \<longrightarrow> Q' x" "G P'"
  2430     moreover
  2431     from bi_total_fun[OF `bi_unique A` bi_total_eq, unfolded bi_total_def]
  2432     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
  2433     have "F P = G P'" by transfer_prover
  2434     moreover have "(\<forall>x. P x \<longrightarrow> Q x) \<longleftrightarrow> (\<forall>x. P' x \<longrightarrow> Q' x)" by transfer_prover
  2435     ultimately have "F Q" by(simp add: mono)
  2436     moreover have "F Q = G Q'" by transfer_prover
  2437     ultimately show "G Q'" by simp
  2438   qed
  2439 qed
  2440 
  2441 lemma is_filter_parametric [transfer_rule]:
  2442   "\<lbrakk> bi_total A; bi_unique A \<rbrakk>
  2443   \<Longrightarrow> (((A ===> op =) ===> op =) ===> op =) is_filter is_filter"
  2444 apply(rule rel_funI)
  2445 apply(rule iffI)
  2446  apply(erule (3) is_filter_parametric_aux)
  2447 apply(erule is_filter_parametric_aux[where A="conversep A"])
  2448 apply(auto simp add: rel_fun_def)
  2449 done
  2450 
  2451 lemma left_total_rel_filter [reflexivity_rule]:
  2452   assumes [transfer_rule]: "bi_total A" "bi_unique A"
  2453   shows "left_total (rel_filter A)"
  2454 proof(rule left_totalI)
  2455   fix F :: "'a filter"
  2456   from bi_total_fun[OF bi_unique_fun[OF `bi_total A` bi_unique_eq] bi_total_eq]
  2457   obtain G where [transfer_rule]: "((A ===> op =) ===> op =) (\<lambda>P. eventually P F) G" 
  2458     unfolding  bi_total_def by blast
  2459   moreover have "is_filter (\<lambda>P. eventually P F) \<longleftrightarrow> is_filter G" by transfer_prover
  2460   hence "is_filter G" by(simp add: eventually_def is_filter_Rep_filter)
  2461   ultimately have "rel_filter A F (Abs_filter G)"
  2462     by(simp add: rel_filter_eventually eventually_Abs_filter)
  2463   thus "\<exists>G. rel_filter A F G" ..
  2464 qed
  2465 
  2466 lemma right_total_rel_filter [transfer_rule]:
  2467   "\<lbrakk> bi_total A; bi_unique A \<rbrakk> \<Longrightarrow> right_total (rel_filter A)"
  2468 using left_total_rel_filter[of "A\<inverse>\<inverse>"] by simp
  2469 
  2470 lemma bi_total_rel_filter [transfer_rule]:
  2471   assumes "bi_total A" "bi_unique A"
  2472   shows "bi_total (rel_filter A)"
  2473 unfolding bi_total_conv_left_right using assms
  2474 by(simp add: left_total_rel_filter right_total_rel_filter)
  2475 
  2476 lemma left_unique_rel_filter [reflexivity_rule]:
  2477   assumes "left_unique A"
  2478   shows "left_unique (rel_filter A)"
  2479 proof(rule left_uniqueI)
  2480   fix F F' G
  2481   assume [transfer_rule]: "rel_filter A F G" "rel_filter A F' G"
  2482   show "F = F'"
  2483     unfolding filter_eq_iff
  2484   proof
  2485     fix P :: "'a \<Rightarrow> bool"
  2486     obtain P' where [transfer_rule]: "(A ===> op =) P P'"
  2487       using left_total_fun[OF assms left_total_eq] unfolding left_total_def by blast
  2488     have "eventually P F = eventually P' G" 
  2489       and "eventually P F' = eventually P' G" by transfer_prover+
  2490     thus "eventually P F = eventually P F'" by simp
  2491   qed
  2492 qed
  2493 
  2494 lemma right_unique_rel_filter [transfer_rule]:
  2495   "right_unique A \<Longrightarrow> right_unique (rel_filter A)"
  2496 using left_unique_rel_filter[of "A\<inverse>\<inverse>"] by simp
  2497 
  2498 lemma bi_unique_rel_filter [transfer_rule]:
  2499   "bi_unique A \<Longrightarrow> bi_unique (rel_filter A)"
  2500 by(simp add: bi_unique_conv_left_right left_unique_rel_filter right_unique_rel_filter)
  2501 
  2502 lemma top_filter_parametric [transfer_rule]:
  2503   "bi_total A \<Longrightarrow> (rel_filter A) top top"
  2504 by(simp add: rel_filter_eventually All_transfer)
  2505 
  2506 lemma bot_filter_parametric [transfer_rule]: "(rel_filter A) bot bot"
  2507 by(simp add: rel_filter_eventually rel_fun_def)
  2508 
  2509 lemma sup_filter_parametric [transfer_rule]:
  2510   "(rel_filter A ===> rel_filter A ===> rel_filter A) sup sup"
  2511 by(fastforce simp add: rel_filter_eventually[abs_def] eventually_sup dest: rel_funD)
  2512 
  2513 lemma Sup_filter_parametric [transfer_rule]:
  2514   "(rel_set (rel_filter A) ===> rel_filter A) Sup Sup"
  2515 proof(rule rel_funI)
  2516   fix S T
  2517   assume [transfer_rule]: "rel_set (rel_filter A) S T"
  2518   show "rel_filter A (Sup S) (Sup T)"
  2519     by(simp add: rel_filter_eventually eventually_Sup) transfer_prover
  2520 qed
  2521 
  2522 lemma principal_parametric [transfer_rule]:
  2523   "(rel_set A ===> rel_filter A) principal principal"
  2524 proof(rule rel_funI)
  2525   fix S S'
  2526   assume [transfer_rule]: "rel_set A S S'"
  2527   show "rel_filter A (principal S) (principal S')"
  2528     by(simp add: rel_filter_eventually eventually_principal) transfer_prover
  2529 qed
  2530 
  2531 context
  2532   fixes A :: "'a \<Rightarrow> 'b \<Rightarrow> bool"
  2533   assumes [transfer_rule]: "bi_unique A" 
  2534 begin
  2535 
  2536 lemma le_filter_parametric [transfer_rule]:
  2537   "(rel_filter A ===> rel_filter A ===> op =) op \<le> op \<le>"
  2538 unfolding le_filter_def[abs_def] by transfer_prover
  2539 
  2540 lemma less_filter_parametric [transfer_rule]:
  2541   "(rel_filter A ===> rel_filter A ===> op =) op < op <"
  2542 unfolding less_filter_def[abs_def] by transfer_prover
  2543 
  2544 context
  2545   assumes [transfer_rule]: "bi_total A"
  2546 begin
  2547 
  2548 lemma Inf_filter_parametric [transfer_rule]:
  2549   "(rel_set (rel_filter A) ===> rel_filter A) Inf Inf"
  2550 unfolding Inf_filter_def[abs_def] by transfer_prover
  2551 
  2552 lemma inf_filter_parametric [transfer_rule]:
  2553   "(rel_filter A ===> rel_filter A ===> rel_filter A) inf inf"
  2554 proof(intro rel_funI)+
  2555   fix F F' G G'
  2556   assume [transfer_rule]: "rel_filter A F F'" "rel_filter A G G'"
  2557   have "rel_filter A (Inf {F, G}) (Inf {F', G'})" by transfer_prover
  2558   thus "rel_filter A (inf F G) (inf F' G')" by simp
  2559 qed
  2560 
  2561 end
  2562 
  2563 end
  2564 
  2565 end
  2566 
  2567 end