author nipkow
Mon Oct 17 11:46:22 2016 +0200 (2016-10-17)
changeset 64267 b9a1486e79be
parent 64008 17a20ca86d62
child 64283 979cdfdf7a79
permissions -rw-r--r--
setsum -> sum
     1 (*  Title:      HOL/Analysis/Measure_Space.thy
     2     Author:     Lawrence C Paulson
     3     Author:     Johannes Hölzl, TU München
     4     Author:     Armin Heller, TU München
     5 *)
     7 section \<open>Measure spaces and their properties\<close>
     9 theory Measure_Space
    10 imports
    11   Measurable "~~/src/HOL/Library/Extended_Nonnegative_Real"
    12 begin
    14 subsection "Relate extended reals and the indicator function"
    16 lemma suminf_cmult_indicator:
    17   fixes f :: "nat \<Rightarrow> ennreal"
    18   assumes "disjoint_family A" "x \<in> A i"
    19   shows "(\<Sum>n. f n * indicator (A n) x) = f i"
    20 proof -
    21   have **: "\<And>n. f n * indicator (A n) x = (if n = i then f n else 0 :: ennreal)"
    22     using \<open>x \<in> A i\<close> assms unfolding disjoint_family_on_def indicator_def by auto
    23   then have "\<And>n. (\<Sum>j<n. f j * indicator (A j) x) = (if i < n then f i else 0 :: ennreal)"
    24     by (auto simp: sum.If_cases)
    25   moreover have "(SUP n. if i < n then f i else 0) = (f i :: ennreal)"
    26   proof (rule SUP_eqI)
    27     fix y :: ennreal assume "\<And>n. n \<in> UNIV \<Longrightarrow> (if i < n then f i else 0) \<le> y"
    28     from this[of "Suc i"] show "f i \<le> y" by auto
    29   qed (insert assms, simp)
    30   ultimately show ?thesis using assms
    31     by (subst suminf_eq_SUP) (auto simp: indicator_def)
    32 qed
    34 lemma suminf_indicator:
    35   assumes "disjoint_family A"
    36   shows "(\<Sum>n. indicator (A n) x :: ennreal) = indicator (\<Union>i. A i) x"
    37 proof cases
    38   assume *: "x \<in> (\<Union>i. A i)"
    39   then obtain i where "x \<in> A i" by auto
    40   from suminf_cmult_indicator[OF assms(1), OF \<open>x \<in> A i\<close>, of "\<lambda>k. 1"]
    41   show ?thesis using * by simp
    42 qed simp
    44 lemma sum_indicator_disjoint_family:
    45   fixes f :: "'d \<Rightarrow> 'e::semiring_1"
    46   assumes d: "disjoint_family_on A P" and "x \<in> A j" and "finite P" and "j \<in> P"
    47   shows "(\<Sum>i\<in>P. f i * indicator (A i) x) = f j"
    48 proof -
    49   have "P \<inter> {i. x \<in> A i} = {j}"
    50     using d \<open>x \<in> A j\<close> \<open>j \<in> P\<close> unfolding disjoint_family_on_def
    51     by auto
    52   thus ?thesis
    53     unfolding indicator_def
    54     by (simp add: if_distrib sum.If_cases[OF \<open>finite P\<close>])
    55 qed
    57 text \<open>
    58   The type for emeasure spaces is already defined in @{theory Sigma_Algebra}, as it is also used to
    59   represent sigma algebras (with an arbitrary emeasure).
    60 \<close>
    62 subsection "Extend binary sets"
    64 lemma LIMSEQ_binaryset:
    65   assumes f: "f {} = 0"
    66   shows  "(\<lambda>n. \<Sum>i<n. f (binaryset A B i)) \<longlonglongrightarrow> f A + f B"
    67 proof -
    68   have "(\<lambda>n. \<Sum>i < Suc (Suc n). f (binaryset A B i)) = (\<lambda>n. f A + f B)"
    69     proof
    70       fix n
    71       show "(\<Sum>i < Suc (Suc n). f (binaryset A B i)) = f A + f B"
    72         by (induct n)  (auto simp add: binaryset_def f)
    73     qed
    74   moreover
    75   have "... \<longlonglongrightarrow> f A + f B" by (rule tendsto_const)
    76   ultimately
    77   have "(\<lambda>n. \<Sum>i< Suc (Suc n). f (binaryset A B i)) \<longlonglongrightarrow> f A + f B"
    78     by metis
    79   hence "(\<lambda>n. \<Sum>i< n+2. f (binaryset A B i)) \<longlonglongrightarrow> f A + f B"
    80     by simp
    81   thus ?thesis by (rule LIMSEQ_offset [where k=2])
    82 qed
    84 lemma binaryset_sums:
    85   assumes f: "f {} = 0"
    86   shows  "(\<lambda>n. f (binaryset A B n)) sums (f A + f B)"
    87     by (simp add: sums_def LIMSEQ_binaryset [where f=f, OF f] atLeast0LessThan)
    89 lemma suminf_binaryset_eq:
    90   fixes f :: "'a set \<Rightarrow> 'b::{comm_monoid_add, t2_space}"
    91   shows "f {} = 0 \<Longrightarrow> (\<Sum>n. f (binaryset A B n)) = f A + f B"
    92   by (metis binaryset_sums sums_unique)
    94 subsection \<open>Properties of a premeasure @{term \<mu>}\<close>
    96 text \<open>
    97   The definitions for @{const positive} and @{const countably_additive} should be here, by they are
    98   necessary to define @{typ "'a measure"} in @{theory Sigma_Algebra}.
    99 \<close>
   101 definition subadditive where
   102   "subadditive M f \<longleftrightarrow> (\<forall>x\<in>M. \<forall>y\<in>M. x \<inter> y = {} \<longrightarrow> f (x \<union> y) \<le> f x + f y)"
   104 lemma subadditiveD: "subadditive M f \<Longrightarrow> x \<inter> y = {} \<Longrightarrow> x \<in> M \<Longrightarrow> y \<in> M \<Longrightarrow> f (x \<union> y) \<le> f x + f y"
   105   by (auto simp add: subadditive_def)
   107 definition countably_subadditive where
   108   "countably_subadditive M f \<longleftrightarrow>
   109     (\<forall>A. range A \<subseteq> M \<longrightarrow> disjoint_family A \<longrightarrow> (\<Union>i. A i) \<in> M \<longrightarrow> (f (\<Union>i. A i) \<le> (\<Sum>i. f (A i))))"
   111 lemma (in ring_of_sets) countably_subadditive_subadditive:
   112   fixes f :: "'a set \<Rightarrow> ennreal"
   113   assumes f: "positive M f" and cs: "countably_subadditive M f"
   114   shows  "subadditive M f"
   115 proof (auto simp add: subadditive_def)
   116   fix x y
   117   assume x: "x \<in> M" and y: "y \<in> M" and "x \<inter> y = {}"
   118   hence "disjoint_family (binaryset x y)"
   119     by (auto simp add: disjoint_family_on_def binaryset_def)
   120   hence "range (binaryset x y) \<subseteq> M \<longrightarrow>
   121          (\<Union>i. binaryset x y i) \<in> M \<longrightarrow>
   122          f (\<Union>i. binaryset x y i) \<le> (\<Sum> n. f (binaryset x y n))"
   123     using cs by (auto simp add: countably_subadditive_def)
   124   hence "{x,y,{}} \<subseteq> M \<longrightarrow> x \<union> y \<in> M \<longrightarrow>
   125          f (x \<union> y) \<le> (\<Sum> n. f (binaryset x y n))"
   126     by (simp add: range_binaryset_eq UN_binaryset_eq)
   127   thus "f (x \<union> y) \<le>  f x + f y" using f x y
   128     by (auto simp add: Un o_def suminf_binaryset_eq positive_def)
   129 qed
   131 definition additive where
   132   "additive M \<mu> \<longleftrightarrow> (\<forall>x\<in>M. \<forall>y\<in>M. x \<inter> y = {} \<longrightarrow> \<mu> (x \<union> y) = \<mu> x + \<mu> y)"
   134 definition increasing where
   135   "increasing M \<mu> \<longleftrightarrow> (\<forall>x\<in>M. \<forall>y\<in>M. x \<subseteq> y \<longrightarrow> \<mu> x \<le> \<mu> y)"
   137 lemma positiveD1: "positive M f \<Longrightarrow> f {} = 0" by (auto simp: positive_def)
   139 lemma positiveD_empty:
   140   "positive M f \<Longrightarrow> f {} = 0"
   141   by (auto simp add: positive_def)
   143 lemma additiveD:
   144   "additive M f \<Longrightarrow> x \<inter> y = {} \<Longrightarrow> x \<in> M \<Longrightarrow> y \<in> M \<Longrightarrow> f (x \<union> y) = f x + f y"
   145   by (auto simp add: additive_def)
   147 lemma increasingD:
   148   "increasing M f \<Longrightarrow> x \<subseteq> y \<Longrightarrow> x\<in>M \<Longrightarrow> y\<in>M \<Longrightarrow> f x \<le> f y"
   149   by (auto simp add: increasing_def)
   151 lemma countably_additiveI[case_names countably]:
   152   "(\<And>A. range A \<subseteq> M \<Longrightarrow> disjoint_family A \<Longrightarrow> (\<Union>i. A i) \<in> M \<Longrightarrow> (\<Sum>i. f (A i)) = f (\<Union>i. A i))
   153   \<Longrightarrow> countably_additive M f"
   154   by (simp add: countably_additive_def)
   156 lemma (in ring_of_sets) disjointed_additive:
   157   assumes f: "positive M f" "additive M f" and A: "range A \<subseteq> M" "incseq A"
   158   shows "(\<Sum>i\<le>n. f (disjointed A i)) = f (A n)"
   159 proof (induct n)
   160   case (Suc n)
   161   then have "(\<Sum>i\<le>Suc n. f (disjointed A i)) = f (A n) + f (disjointed A (Suc n))"
   162     by simp
   163   also have "\<dots> = f (A n \<union> disjointed A (Suc n))"
   164     using A by (subst f(2)[THEN additiveD]) (auto simp: disjointed_mono)
   165   also have "A n \<union> disjointed A (Suc n) = A (Suc n)"
   166     using \<open>incseq A\<close> by (auto dest: incseq_SucD simp: disjointed_mono)
   167   finally show ?case .
   168 qed simp
   170 lemma (in ring_of_sets) additive_sum:
   171   fixes A:: "'i \<Rightarrow> 'a set"
   172   assumes f: "positive M f" and ad: "additive M f" and "finite S"
   173       and A: "A`S \<subseteq> M"
   174       and disj: "disjoint_family_on A S"
   175   shows  "(\<Sum>i\<in>S. f (A i)) = f (\<Union>i\<in>S. A i)"
   176   using \<open>finite S\<close> disj A
   177 proof induct
   178   case empty show ?case using f by (simp add: positive_def)
   179 next
   180   case (insert s S)
   181   then have "A s \<inter> (\<Union>i\<in>S. A i) = {}"
   182     by (auto simp add: disjoint_family_on_def neq_iff)
   183   moreover
   184   have "A s \<in> M" using insert by blast
   185   moreover have "(\<Union>i\<in>S. A i) \<in> M"
   186     using insert \<open>finite S\<close> by auto
   187   ultimately have "f (A s \<union> (\<Union>i\<in>S. A i)) = f (A s) + f(\<Union>i\<in>S. A i)"
   188     using ad UNION_in_sets A by (auto simp add: additive_def)
   189   with insert show ?case using ad disjoint_family_on_mono[of S "insert s S" A]
   190     by (auto simp add: additive_def subset_insertI)
   191 qed
   193 lemma (in ring_of_sets) additive_increasing:
   194   fixes f :: "'a set \<Rightarrow> ennreal"
   195   assumes posf: "positive M f" and addf: "additive M f"
   196   shows "increasing M f"
   197 proof (auto simp add: increasing_def)
   198   fix x y
   199   assume xy: "x \<in> M" "y \<in> M" "x \<subseteq> y"
   200   then have "y - x \<in> M" by auto
   201   then have "f x + 0 \<le> f x + f (y-x)" by (intro add_left_mono zero_le)
   202   also have "... = f (x \<union> (y-x))" using addf
   203     by (auto simp add: additive_def) (metis Diff_disjoint Un_Diff_cancel Diff xy(1,2))
   204   also have "... = f y"
   205     by (metis Un_Diff_cancel Un_absorb1 xy(3))
   206   finally show "f x \<le> f y" by simp
   207 qed
   209 lemma (in ring_of_sets) subadditive:
   210   fixes f :: "'a set \<Rightarrow> ennreal"
   211   assumes f: "positive M f" "additive M f" and A: "A`S \<subseteq> M" and S: "finite S"
   212   shows "f (\<Union>i\<in>S. A i) \<le> (\<Sum>i\<in>S. f (A i))"
   213 using S A
   214 proof (induct S)
   215   case empty thus ?case using f by (auto simp: positive_def)
   216 next
   217   case (insert x F)
   218   hence in_M: "A x \<in> M" "(\<Union>i\<in>F. A i) \<in> M" "(\<Union>i\<in>F. A i) - A x \<in> M" using A by force+
   219   have subs: "(\<Union>i\<in>F. A i) - A x \<subseteq> (\<Union>i\<in>F. A i)" by auto
   220   have "(\<Union>i\<in>(insert x F). A i) = A x \<union> ((\<Union>i\<in>F. A i) - A x)" by auto
   221   hence "f (\<Union>i\<in>(insert x F). A i) = f (A x \<union> ((\<Union>i\<in>F. A i) - A x))"
   222     by simp
   223   also have "\<dots> = f (A x) + f ((\<Union>i\<in>F. A i) - A x)"
   224     using f(2) by (rule additiveD) (insert in_M, auto)
   225   also have "\<dots> \<le> f (A x) + f (\<Union>i\<in>F. A i)"
   226     using additive_increasing[OF f] in_M subs by (auto simp: increasing_def intro: add_left_mono)
   227   also have "\<dots> \<le> f (A x) + (\<Sum>i\<in>F. f (A i))" using insert by (auto intro: add_left_mono)
   228   finally show "f (\<Union>i\<in>(insert x F). A i) \<le> (\<Sum>i\<in>(insert x F). f (A i))" using insert by simp
   229 qed
   231 lemma (in ring_of_sets) countably_additive_additive:
   232   fixes f :: "'a set \<Rightarrow> ennreal"
   233   assumes posf: "positive M f" and ca: "countably_additive M f"
   234   shows "additive M f"
   235 proof (auto simp add: additive_def)
   236   fix x y
   237   assume x: "x \<in> M" and y: "y \<in> M" and "x \<inter> y = {}"
   238   hence "disjoint_family (binaryset x y)"
   239     by (auto simp add: disjoint_family_on_def binaryset_def)
   240   hence "range (binaryset x y) \<subseteq> M \<longrightarrow>
   241          (\<Union>i. binaryset x y i) \<in> M \<longrightarrow>
   242          f (\<Union>i. binaryset x y i) = (\<Sum> n. f (binaryset x y n))"
   243     using ca
   244     by (simp add: countably_additive_def)
   245   hence "{x,y,{}} \<subseteq> M \<longrightarrow> x \<union> y \<in> M \<longrightarrow>
   246          f (x \<union> y) = (\<Sum>n. f (binaryset x y n))"
   247     by (simp add: range_binaryset_eq UN_binaryset_eq)
   248   thus "f (x \<union> y) = f x + f y" using posf x y
   249     by (auto simp add: Un suminf_binaryset_eq positive_def)
   250 qed
   252 lemma (in algebra) increasing_additive_bound:
   253   fixes A:: "nat \<Rightarrow> 'a set" and  f :: "'a set \<Rightarrow> ennreal"
   254   assumes f: "positive M f" and ad: "additive M f"
   255       and inc: "increasing M f"
   256       and A: "range A \<subseteq> M"
   257       and disj: "disjoint_family A"
   258   shows  "(\<Sum>i. f (A i)) \<le> f \<Omega>"
   259 proof (safe intro!: suminf_le_const)
   260   fix N
   261   note disj_N = disjoint_family_on_mono[OF _ disj, of "{..<N}"]
   262   have "(\<Sum>i<N. f (A i)) = f (\<Union>i\<in>{..<N}. A i)"
   263     using A by (intro additive_sum [OF f ad _ _]) (auto simp: disj_N)
   264   also have "... \<le> f \<Omega>" using space_closed A
   265     by (intro increasingD[OF inc] finite_UN) auto
   266   finally show "(\<Sum>i<N. f (A i)) \<le> f \<Omega>" by simp
   267 qed (insert f A, auto simp: positive_def)
   269 lemma (in ring_of_sets) countably_additiveI_finite:
   270   fixes \<mu> :: "'a set \<Rightarrow> ennreal"
   271   assumes "finite \<Omega>" "positive M \<mu>" "additive M \<mu>"
   272   shows "countably_additive M \<mu>"
   273 proof (rule countably_additiveI)
   274   fix F :: "nat \<Rightarrow> 'a set" assume F: "range F \<subseteq> M" "(\<Union>i. F i) \<in> M" and disj: "disjoint_family F"
   276   have "\<forall>i\<in>{i. F i \<noteq> {}}. \<exists>x. x \<in> F i" by auto
   277   from bchoice[OF this] obtain f where f: "\<And>i. F i \<noteq> {} \<Longrightarrow> f i \<in> F i" by auto
   279   have inj_f: "inj_on f {i. F i \<noteq> {}}"
   280   proof (rule inj_onI, simp)
   281     fix i j a b assume *: "f i = f j" "F i \<noteq> {}" "F j \<noteq> {}"
   282     then have "f i \<in> F i" "f j \<in> F j" using f by force+
   283     with disj * show "i = j" by (auto simp: disjoint_family_on_def)
   284   qed
   285   have "finite (\<Union>i. F i)"
   286     by (metis F(2) assms(1) infinite_super sets_into_space)
   288   have F_subset: "{i. \<mu> (F i) \<noteq> 0} \<subseteq> {i. F i \<noteq> {}}"
   289     by (auto simp: positiveD_empty[OF \<open>positive M \<mu>\<close>])
   290   moreover have fin_not_empty: "finite {i. F i \<noteq> {}}"
   291   proof (rule finite_imageD)
   292     from f have "f`{i. F i \<noteq> {}} \<subseteq> (\<Union>i. F i)" by auto
   293     then show "finite (f`{i. F i \<noteq> {}})"
   294       by (rule finite_subset) fact
   295   qed fact
   296   ultimately have fin_not_0: "finite {i. \<mu> (F i) \<noteq> 0}"
   297     by (rule finite_subset)
   299   have disj_not_empty: "disjoint_family_on F {i. F i \<noteq> {}}"
   300     using disj by (auto simp: disjoint_family_on_def)
   302   from fin_not_0 have "(\<Sum>i. \<mu> (F i)) = (\<Sum>i | \<mu> (F i) \<noteq> 0. \<mu> (F i))"
   303     by (rule suminf_finite) auto
   304   also have "\<dots> = (\<Sum>i | F i \<noteq> {}. \<mu> (F i))"
   305     using fin_not_empty F_subset by (rule sum.mono_neutral_left) auto
   306   also have "\<dots> = \<mu> (\<Union>i\<in>{i. F i \<noteq> {}}. F i)"
   307     using \<open>positive M \<mu>\<close> \<open>additive M \<mu>\<close> fin_not_empty disj_not_empty F by (intro additive_sum) auto
   308   also have "\<dots> = \<mu> (\<Union>i. F i)"
   309     by (rule arg_cong[where f=\<mu>]) auto
   310   finally show "(\<Sum>i. \<mu> (F i)) = \<mu> (\<Union>i. F i)" .
   311 qed
   313 lemma (in ring_of_sets) countably_additive_iff_continuous_from_below:
   314   fixes f :: "'a set \<Rightarrow> ennreal"
   315   assumes f: "positive M f" "additive M f"
   316   shows "countably_additive M f \<longleftrightarrow>
   317     (\<forall>A. range A \<subseteq> M \<longrightarrow> incseq A \<longrightarrow> (\<Union>i. A i) \<in> M \<longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Union>i. A i))"
   318   unfolding countably_additive_def
   319 proof safe
   320   assume count_sum: "\<forall>A. range A \<subseteq> M \<longrightarrow> disjoint_family A \<longrightarrow> UNION UNIV A \<in> M \<longrightarrow> (\<Sum>i. f (A i)) = f (UNION UNIV A)"
   321   fix A :: "nat \<Rightarrow> 'a set" assume A: "range A \<subseteq> M" "incseq A" "(\<Union>i. A i) \<in> M"
   322   then have dA: "range (disjointed A) \<subseteq> M" by (auto simp: range_disjointed_sets)
   323   with count_sum[THEN spec, of "disjointed A"] A(3)
   324   have f_UN: "(\<Sum>i. f (disjointed A i)) = f (\<Union>i. A i)"
   325     by (auto simp: UN_disjointed_eq disjoint_family_disjointed)
   326   moreover have "(\<lambda>n. (\<Sum>i<n. f (disjointed A i))) \<longlonglongrightarrow> (\<Sum>i. f (disjointed A i))"
   327     using f(1)[unfolded positive_def] dA
   328     by (auto intro!: summable_LIMSEQ)
   329   from LIMSEQ_Suc[OF this]
   330   have "(\<lambda>n. (\<Sum>i\<le>n. f (disjointed A i))) \<longlonglongrightarrow> (\<Sum>i. f (disjointed A i))"
   331     unfolding lessThan_Suc_atMost .
   332   moreover have "\<And>n. (\<Sum>i\<le>n. f (disjointed A i)) = f (A n)"
   333     using disjointed_additive[OF f A(1,2)] .
   334   ultimately show "(\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Union>i. A i)" by simp
   335 next
   336   assume cont: "\<forall>A. range A \<subseteq> M \<longrightarrow> incseq A \<longrightarrow> (\<Union>i. A i) \<in> M \<longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Union>i. A i)"
   337   fix A :: "nat \<Rightarrow> 'a set" assume A: "range A \<subseteq> M" "disjoint_family A" "(\<Union>i. A i) \<in> M"
   338   have *: "(\<Union>n. (\<Union>i<n. A i)) = (\<Union>i. A i)" by auto
   339   have "(\<lambda>n. f (\<Union>i<n. A i)) \<longlonglongrightarrow> f (\<Union>i. A i)"
   340   proof (unfold *[symmetric], intro cont[rule_format])
   341     show "range (\<lambda>i. \<Union>i<i. A i) \<subseteq> M" "(\<Union>i. \<Union>i<i. A i) \<in> M"
   342       using A * by auto
   343   qed (force intro!: incseq_SucI)
   344   moreover have "\<And>n. f (\<Union>i<n. A i) = (\<Sum>i<n. f (A i))"
   345     using A
   346     by (intro additive_sum[OF f, of _ A, symmetric])
   347        (auto intro: disjoint_family_on_mono[where B=UNIV])
   348   ultimately
   349   have "(\<lambda>i. f (A i)) sums f (\<Union>i. A i)"
   350     unfolding sums_def by simp
   351   from sums_unique[OF this]
   352   show "(\<Sum>i. f (A i)) = f (\<Union>i. A i)" by simp
   353 qed
   355 lemma (in ring_of_sets) continuous_from_above_iff_empty_continuous:
   356   fixes f :: "'a set \<Rightarrow> ennreal"
   357   assumes f: "positive M f" "additive M f"
   358   shows "(\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) \<in> M \<longrightarrow> (\<forall>i. f (A i) \<noteq> \<infinity>) \<longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Inter>i. A i))
   359      \<longleftrightarrow> (\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) = {} \<longrightarrow> (\<forall>i. f (A i) \<noteq> \<infinity>) \<longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> 0)"
   360 proof safe
   361   assume cont: "(\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) \<in> M \<longrightarrow> (\<forall>i. f (A i) \<noteq> \<infinity>) \<longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Inter>i. A i))"
   362   fix A :: "nat \<Rightarrow> 'a set" assume A: "range A \<subseteq> M" "decseq A" "(\<Inter>i. A i) = {}" "\<forall>i. f (A i) \<noteq> \<infinity>"
   363   with cont[THEN spec, of A] show "(\<lambda>i. f (A i)) \<longlonglongrightarrow> 0"
   364     using \<open>positive M f\<close>[unfolded positive_def] by auto
   365 next
   366   assume cont: "\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) = {} \<longrightarrow> (\<forall>i. f (A i) \<noteq> \<infinity>) \<longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> 0"
   367   fix A :: "nat \<Rightarrow> 'a set" assume A: "range A \<subseteq> M" "decseq A" "(\<Inter>i. A i) \<in> M" "\<forall>i. f (A i) \<noteq> \<infinity>"
   369   have f_mono: "\<And>a b. a \<in> M \<Longrightarrow> b \<in> M \<Longrightarrow> a \<subseteq> b \<Longrightarrow> f a \<le> f b"
   370     using additive_increasing[OF f] unfolding increasing_def by simp
   372   have decseq_fA: "decseq (\<lambda>i. f (A i))"
   373     using A by (auto simp: decseq_def intro!: f_mono)
   374   have decseq: "decseq (\<lambda>i. A i - (\<Inter>i. A i))"
   375     using A by (auto simp: decseq_def)
   376   then have decseq_f: "decseq (\<lambda>i. f (A i - (\<Inter>i. A i)))"
   377     using A unfolding decseq_def by (auto intro!: f_mono Diff)
   378   have "f (\<Inter>x. A x) \<le> f (A 0)"
   379     using A by (auto intro!: f_mono)
   380   then have f_Int_fin: "f (\<Inter>x. A x) \<noteq> \<infinity>"
   381     using A by (auto simp: top_unique)
   382   { fix i
   383     have "f (A i - (\<Inter>i. A i)) \<le> f (A i)" using A by (auto intro!: f_mono)
   384     then have "f (A i - (\<Inter>i. A i)) \<noteq> \<infinity>"
   385       using A by (auto simp: top_unique) }
   386   note f_fin = this
   387   have "(\<lambda>i. f (A i - (\<Inter>i. A i))) \<longlonglongrightarrow> 0"
   388   proof (intro cont[rule_format, OF _ decseq _ f_fin])
   389     show "range (\<lambda>i. A i - (\<Inter>i. A i)) \<subseteq> M" "(\<Inter>i. A i - (\<Inter>i. A i)) = {}"
   390       using A by auto
   391   qed
   392   from INF_Lim_ereal[OF decseq_f this]
   393   have "(INF n. f (A n - (\<Inter>i. A i))) = 0" .
   394   moreover have "(INF n. f (\<Inter>i. A i)) = f (\<Inter>i. A i)"
   395     by auto
   396   ultimately have "(INF n. f (A n - (\<Inter>i. A i)) + f (\<Inter>i. A i)) = 0 + f (\<Inter>i. A i)"
   397     using A(4) f_fin f_Int_fin
   398     by (subst INF_ennreal_add_const) (auto simp: decseq_f)
   399   moreover {
   400     fix n
   401     have "f (A n - (\<Inter>i. A i)) + f (\<Inter>i. A i) = f ((A n - (\<Inter>i. A i)) \<union> (\<Inter>i. A i))"
   402       using A by (subst f(2)[THEN additiveD]) auto
   403     also have "(A n - (\<Inter>i. A i)) \<union> (\<Inter>i. A i) = A n"
   404       by auto
   405     finally have "f (A n - (\<Inter>i. A i)) + f (\<Inter>i. A i) = f (A n)" . }
   406   ultimately have "(INF n. f (A n)) = f (\<Inter>i. A i)"
   407     by simp
   408   with LIMSEQ_INF[OF decseq_fA]
   409   show "(\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Inter>i. A i)" by simp
   410 qed
   412 lemma (in ring_of_sets) empty_continuous_imp_continuous_from_below:
   413   fixes f :: "'a set \<Rightarrow> ennreal"
   414   assumes f: "positive M f" "additive M f" "\<forall>A\<in>M. f A \<noteq> \<infinity>"
   415   assumes cont: "\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) = {} \<longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> 0"
   416   assumes A: "range A \<subseteq> M" "incseq A" "(\<Union>i. A i) \<in> M"
   417   shows "(\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Union>i. A i)"
   418 proof -
   419   from A have "(\<lambda>i. f ((\<Union>i. A i) - A i)) \<longlonglongrightarrow> 0"
   420     by (intro cont[rule_format]) (auto simp: decseq_def incseq_def)
   421   moreover
   422   { fix i
   423     have "f ((\<Union>i. A i) - A i \<union> A i) = f ((\<Union>i. A i) - A i) + f (A i)"
   424       using A by (intro f(2)[THEN additiveD]) auto
   425     also have "((\<Union>i. A i) - A i) \<union> A i = (\<Union>i. A i)"
   426       by auto
   427     finally have "f ((\<Union>i. A i) - A i) = f (\<Union>i. A i) - f (A i)"
   428       using f(3)[rule_format, of "A i"] A by (auto simp: ennreal_add_diff_cancel subset_eq) }
   429   moreover have "\<forall>\<^sub>F i in sequentially. f (A i) \<le> f (\<Union>i. A i)"
   430     using increasingD[OF additive_increasing[OF f(1, 2)], of "A _" "\<Union>i. A i"] A
   431     by (auto intro!: always_eventually simp: subset_eq)
   432   ultimately show "(\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Union>i. A i)"
   433     by (auto intro: ennreal_tendsto_const_minus)
   434 qed
   436 lemma (in ring_of_sets) empty_continuous_imp_countably_additive:
   437   fixes f :: "'a set \<Rightarrow> ennreal"
   438   assumes f: "positive M f" "additive M f" and fin: "\<forall>A\<in>M. f A \<noteq> \<infinity>"
   439   assumes cont: "\<And>A. range A \<subseteq> M \<Longrightarrow> decseq A \<Longrightarrow> (\<Inter>i. A i) = {} \<Longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> 0"
   440   shows "countably_additive M f"
   441   using countably_additive_iff_continuous_from_below[OF f]
   442   using empty_continuous_imp_continuous_from_below[OF f fin] cont
   443   by blast
   445 subsection \<open>Properties of @{const emeasure}\<close>
   447 lemma emeasure_positive: "positive (sets M) (emeasure M)"
   448   by (cases M) (auto simp: sets_def emeasure_def Abs_measure_inverse measure_space_def)
   450 lemma emeasure_empty[simp, intro]: "emeasure M {} = 0"
   451   using emeasure_positive[of M] by (simp add: positive_def)
   453 lemma emeasure_single_in_space: "emeasure M {x} \<noteq> 0 \<Longrightarrow> x \<in> space M"
   454   using emeasure_notin_sets[of "{x}" M] by (auto dest: sets.sets_into_space zero_less_iff_neq_zero[THEN iffD2])
   456 lemma emeasure_countably_additive: "countably_additive (sets M) (emeasure M)"
   457   by (cases M) (auto simp: sets_def emeasure_def Abs_measure_inverse measure_space_def)
   459 lemma suminf_emeasure:
   460   "range A \<subseteq> sets M \<Longrightarrow> disjoint_family A \<Longrightarrow> (\<Sum>i. emeasure M (A i)) = emeasure M (\<Union>i. A i)"
   461   using sets.countable_UN[of A UNIV M] emeasure_countably_additive[of M]
   462   by (simp add: countably_additive_def)
   464 lemma sums_emeasure:
   465   "disjoint_family F \<Longrightarrow> (\<And>i. F i \<in> sets M) \<Longrightarrow> (\<lambda>i. emeasure M (F i)) sums emeasure M (\<Union>i. F i)"
   466   unfolding sums_iff by (intro conjI suminf_emeasure) auto
   468 lemma emeasure_additive: "additive (sets M) (emeasure M)"
   469   by (metis sets.countably_additive_additive emeasure_positive emeasure_countably_additive)
   471 lemma plus_emeasure:
   472   "a \<in> sets M \<Longrightarrow> b \<in> sets M \<Longrightarrow> a \<inter> b = {} \<Longrightarrow> emeasure M a + emeasure M b = emeasure M (a \<union> b)"
   473   using additiveD[OF emeasure_additive] ..
   475 lemma emeasure_Union:
   476   "A \<in> sets M \<Longrightarrow> B \<in> sets M \<Longrightarrow> emeasure M (A \<union> B) = emeasure M A + emeasure M (B - A)"
   477   using plus_emeasure[of A M "B - A"] by auto
   479 lemma sum_emeasure:
   480   "F`I \<subseteq> sets M \<Longrightarrow> disjoint_family_on F I \<Longrightarrow> finite I \<Longrightarrow>
   481     (\<Sum>i\<in>I. emeasure M (F i)) = emeasure M (\<Union>i\<in>I. F i)"
   482   by (metis sets.additive_sum emeasure_positive emeasure_additive)
   484 lemma emeasure_mono:
   485   "a \<subseteq> b \<Longrightarrow> b \<in> sets M \<Longrightarrow> emeasure M a \<le> emeasure M b"
   486   by (metis zero_le sets.additive_increasing emeasure_additive emeasure_notin_sets emeasure_positive increasingD)
   488 lemma emeasure_space:
   489   "emeasure M A \<le> emeasure M (space M)"
   490   by (metis emeasure_mono emeasure_notin_sets sets.sets_into_space zero_le)
   492 lemma emeasure_Diff:
   493   assumes finite: "emeasure M B \<noteq> \<infinity>"
   494   and [measurable]: "A \<in> sets M" "B \<in> sets M" and "B \<subseteq> A"
   495   shows "emeasure M (A - B) = emeasure M A - emeasure M B"
   496 proof -
   497   have "(A - B) \<union> B = A" using \<open>B \<subseteq> A\<close> by auto
   498   then have "emeasure M A = emeasure M ((A - B) \<union> B)" by simp
   499   also have "\<dots> = emeasure M (A - B) + emeasure M B"
   500     by (subst plus_emeasure[symmetric]) auto
   501   finally show "emeasure M (A - B) = emeasure M A - emeasure M B"
   502     using finite by simp
   503 qed
   505 lemma emeasure_compl:
   506   "s \<in> sets M \<Longrightarrow> emeasure M s \<noteq> \<infinity> \<Longrightarrow> emeasure M (space M - s) = emeasure M (space M) - emeasure M s"
   507   by (rule emeasure_Diff) (auto dest: sets.sets_into_space)
   509 lemma Lim_emeasure_incseq:
   510   "range A \<subseteq> sets M \<Longrightarrow> incseq A \<Longrightarrow> (\<lambda>i. (emeasure M (A i))) \<longlonglongrightarrow> emeasure M (\<Union>i. A i)"
   511   using emeasure_countably_additive
   512   by (auto simp add: sets.countably_additive_iff_continuous_from_below emeasure_positive
   513     emeasure_additive)
   515 lemma incseq_emeasure:
   516   assumes "range B \<subseteq> sets M" "incseq B"
   517   shows "incseq (\<lambda>i. emeasure M (B i))"
   518   using assms by (auto simp: incseq_def intro!: emeasure_mono)
   520 lemma SUP_emeasure_incseq:
   521   assumes A: "range A \<subseteq> sets M" "incseq A"
   522   shows "(SUP n. emeasure M (A n)) = emeasure M (\<Union>i. A i)"
   523   using LIMSEQ_SUP[OF incseq_emeasure, OF A] Lim_emeasure_incseq[OF A]
   524   by (simp add: LIMSEQ_unique)
   526 lemma decseq_emeasure:
   527   assumes "range B \<subseteq> sets M" "decseq B"
   528   shows "decseq (\<lambda>i. emeasure M (B i))"
   529   using assms by (auto simp: decseq_def intro!: emeasure_mono)
   531 lemma INF_emeasure_decseq:
   532   assumes A: "range A \<subseteq> sets M" and "decseq A"
   533   and finite: "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
   534   shows "(INF n. emeasure M (A n)) = emeasure M (\<Inter>i. A i)"
   535 proof -
   536   have le_MI: "emeasure M (\<Inter>i. A i) \<le> emeasure M (A 0)"
   537     using A by (auto intro!: emeasure_mono)
   538   hence *: "emeasure M (\<Inter>i. A i) \<noteq> \<infinity>" using finite[of 0] by (auto simp: top_unique)
   540   have "emeasure M (A 0) - (INF n. emeasure M (A n)) = (SUP n. emeasure M (A 0) - emeasure M (A n))"
   541     by (simp add: ennreal_INF_const_minus)
   542   also have "\<dots> = (SUP n. emeasure M (A 0 - A n))"
   543     using A finite \<open>decseq A\<close>[unfolded decseq_def] by (subst emeasure_Diff) auto
   544   also have "\<dots> = emeasure M (\<Union>i. A 0 - A i)"
   545   proof (rule SUP_emeasure_incseq)
   546     show "range (\<lambda>n. A 0 - A n) \<subseteq> sets M"
   547       using A by auto
   548     show "incseq (\<lambda>n. A 0 - A n)"
   549       using \<open>decseq A\<close> by (auto simp add: incseq_def decseq_def)
   550   qed
   551   also have "\<dots> = emeasure M (A 0) - emeasure M (\<Inter>i. A i)"
   552     using A finite * by (simp, subst emeasure_Diff) auto
   553   finally show ?thesis
   554     by (rule ennreal_minus_cancel[rotated 3])
   555        (insert finite A, auto intro: INF_lower emeasure_mono)
   556 qed
   558 lemma INF_emeasure_decseq':
   559   assumes A: "\<And>i. A i \<in> sets M" and "decseq A"
   560   and finite: "\<exists>i. emeasure M (A i) \<noteq> \<infinity>"
   561   shows "(INF n. emeasure M (A n)) = emeasure M (\<Inter>i. A i)"
   562 proof -
   563   from finite obtain i where i: "emeasure M (A i) < \<infinity>"
   564     by (auto simp: less_top)
   565   have fin: "i \<le> j \<Longrightarrow> emeasure M (A j) < \<infinity>" for j
   566     by (rule le_less_trans[OF emeasure_mono i]) (auto intro!: decseqD[OF \<open>decseq A\<close>] A)
   568   have "(INF n. emeasure M (A n)) = (INF n. emeasure M (A (n + i)))"
   569   proof (rule INF_eq)
   570     show "\<exists>j\<in>UNIV. emeasure M (A (j + i)) \<le> emeasure M (A i')" for i'
   571       by (intro bexI[of _ i'] emeasure_mono decseqD[OF \<open>decseq A\<close>] A) auto
   572   qed auto
   573   also have "\<dots> = emeasure M (INF n. (A (n + i)))"
   574     using A \<open>decseq A\<close> fin by (intro INF_emeasure_decseq) (auto simp: decseq_def less_top)
   575   also have "(INF n. (A (n + i))) = (INF n. A n)"
   576     by (meson INF_eq UNIV_I assms(2) decseqD le_add1)
   577   finally show ?thesis .
   578 qed
   580 lemma emeasure_INT_decseq_subset:
   581   fixes F :: "nat \<Rightarrow> 'a set"
   582   assumes I: "I \<noteq> {}" and F: "\<And>i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> i \<le> j \<Longrightarrow> F j \<subseteq> F i"
   583   assumes F_sets[measurable]: "\<And>i. i \<in> I \<Longrightarrow> F i \<in> sets M"
   584     and fin: "\<And>i. i \<in> I \<Longrightarrow> emeasure M (F i) \<noteq> \<infinity>"
   585   shows "emeasure M (\<Inter>i\<in>I. F i) = (INF i:I. emeasure M (F i))"
   586 proof cases
   587   assume "finite I"
   588   have "(\<Inter>i\<in>I. F i) = F (Max I)"
   589     using I \<open>finite I\<close> by (intro antisym INF_lower INF_greatest F) auto
   590   moreover have "(INF i:I. emeasure M (F i)) = emeasure M (F (Max I))"
   591     using I \<open>finite I\<close> by (intro antisym INF_lower INF_greatest F emeasure_mono) auto
   592   ultimately show ?thesis
   593     by simp
   594 next
   595   assume "infinite I"
   596   define L where "L n = (LEAST i. i \<in> I \<and> i \<ge> n)" for n
   597   have L: "L n \<in> I \<and> n \<le> L n" for n
   598     unfolding L_def
   599   proof (rule LeastI_ex)
   600     show "\<exists>x. x \<in> I \<and> n \<le> x"
   601       using \<open>infinite I\<close> finite_subset[of I "{..< n}"]
   602       by (rule_tac ccontr) (auto simp: not_le)
   603   qed
   604   have L_eq[simp]: "i \<in> I \<Longrightarrow> L i = i" for i
   605     unfolding L_def by (intro Least_equality) auto
   606   have L_mono: "i \<le> j \<Longrightarrow> L i \<le> L j" for i j
   607     using L[of j] unfolding L_def by (intro Least_le) (auto simp: L_def)
   609   have "emeasure M (\<Inter>i. F (L i)) = (INF i. emeasure M (F (L i)))"
   610   proof (intro INF_emeasure_decseq[symmetric])
   611     show "decseq (\<lambda>i. F (L i))"
   612       using L by (intro antimonoI F L_mono) auto
   613   qed (insert L fin, auto)
   614   also have "\<dots> = (INF i:I. emeasure M (F i))"
   615   proof (intro antisym INF_greatest)
   616     show "i \<in> I \<Longrightarrow> (INF i. emeasure M (F (L i))) \<le> emeasure M (F i)" for i
   617       by (intro INF_lower2[of i]) auto
   618   qed (insert L, auto intro: INF_lower)
   619   also have "(\<Inter>i. F (L i)) = (\<Inter>i\<in>I. F i)"
   620   proof (intro antisym INF_greatest)
   621     show "i \<in> I \<Longrightarrow> (\<Inter>i. F (L i)) \<subseteq> F i" for i
   622       by (intro INF_lower2[of i]) auto
   623   qed (insert L, auto)
   624   finally show ?thesis .
   625 qed
   627 lemma Lim_emeasure_decseq:
   628   assumes A: "range A \<subseteq> sets M" "decseq A" and fin: "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
   629   shows "(\<lambda>i. emeasure M (A i)) \<longlonglongrightarrow> emeasure M (\<Inter>i. A i)"
   630   using LIMSEQ_INF[OF decseq_emeasure, OF A]
   631   using INF_emeasure_decseq[OF A fin] by simp
   633 lemma emeasure_lfp'[consumes 1, case_names cont measurable]:
   634   assumes "P M"
   635   assumes cont: "sup_continuous F"
   636   assumes *: "\<And>M A. P M \<Longrightarrow> (\<And>N. P N \<Longrightarrow> Measurable.pred N A) \<Longrightarrow> Measurable.pred M (F A)"
   637   shows "emeasure M {x\<in>space M. lfp F x} = (SUP i. emeasure M {x\<in>space M. (F ^^ i) (\<lambda>x. False) x})"
   638 proof -
   639   have "emeasure M {x\<in>space M. lfp F x} = emeasure M (\<Union>i. {x\<in>space M. (F ^^ i) (\<lambda>x. False) x})"
   640     using sup_continuous_lfp[OF cont] by (auto simp add: bot_fun_def intro!: arg_cong2[where f=emeasure])
   641   moreover { fix i from \<open>P M\<close> have "{x\<in>space M. (F ^^ i) (\<lambda>x. False) x} \<in> sets M"
   642     by (induct i arbitrary: M) (auto simp add: pred_def[symmetric] intro: *) }
   643   moreover have "incseq (\<lambda>i. {x\<in>space M. (F ^^ i) (\<lambda>x. False) x})"
   644   proof (rule incseq_SucI)
   645     fix i
   646     have "(F ^^ i) (\<lambda>x. False) \<le> (F ^^ (Suc i)) (\<lambda>x. False)"
   647     proof (induct i)
   648       case 0 show ?case by (simp add: le_fun_def)
   649     next
   650       case Suc thus ?case using monoD[OF sup_continuous_mono[OF cont] Suc] by auto
   651     qed
   652     then show "{x \<in> space M. (F ^^ i) (\<lambda>x. False) x} \<subseteq> {x \<in> space M. (F ^^ Suc i) (\<lambda>x. False) x}"
   653       by auto
   654   qed
   655   ultimately show ?thesis
   656     by (subst SUP_emeasure_incseq) auto
   657 qed
   659 lemma emeasure_lfp:
   660   assumes [simp]: "\<And>s. sets (M s) = sets N"
   661   assumes cont: "sup_continuous F" "sup_continuous f"
   662   assumes meas: "\<And>P. Measurable.pred N P \<Longrightarrow> Measurable.pred N (F P)"
   663   assumes iter: "\<And>P s. Measurable.pred N P \<Longrightarrow> P \<le> lfp F \<Longrightarrow> emeasure (M s) {x\<in>space N. F P x} = f (\<lambda>s. emeasure (M s) {x\<in>space N. P x}) s"
   664   shows "emeasure (M s) {x\<in>space N. lfp F x} = lfp f s"
   665 proof (subst lfp_transfer_bounded[where \<alpha>="\<lambda>F s. emeasure (M s) {x\<in>space N. F x}" and g=f and f=F and P="Measurable.pred N", symmetric])
   666   fix C assume "incseq C" "\<And>i. Measurable.pred N (C i)"
   667   then show "(\<lambda>s. emeasure (M s) {x \<in> space N. (SUP i. C i) x}) = (SUP i. (\<lambda>s. emeasure (M s) {x \<in> space N. C i x}))"
   668     unfolding SUP_apply[abs_def]
   669     by (subst SUP_emeasure_incseq) (auto simp: mono_def fun_eq_iff intro!: arg_cong2[where f=emeasure])
   670 qed (auto simp add: iter le_fun_def SUP_apply[abs_def] intro!: meas cont)
   672 lemma emeasure_subadditive_finite:
   673   "finite I \<Longrightarrow> A ` I \<subseteq> sets M \<Longrightarrow> emeasure M (\<Union>i\<in>I. A i) \<le> (\<Sum>i\<in>I. emeasure M (A i))"
   674   by (rule sets.subadditive[OF emeasure_positive emeasure_additive]) auto
   676 lemma emeasure_subadditive:
   677   "A \<in> sets M \<Longrightarrow> B \<in> sets M \<Longrightarrow> emeasure M (A \<union> B) \<le> emeasure M A + emeasure M B"
   678   using emeasure_subadditive_finite[of "{True, False}" "\<lambda>True \<Rightarrow> A | False \<Rightarrow> B" M] by simp
   680 lemma emeasure_subadditive_countably:
   681   assumes "range f \<subseteq> sets M"
   682   shows "emeasure M (\<Union>i. f i) \<le> (\<Sum>i. emeasure M (f i))"
   683 proof -
   684   have "emeasure M (\<Union>i. f i) = emeasure M (\<Union>i. disjointed f i)"
   685     unfolding UN_disjointed_eq ..
   686   also have "\<dots> = (\<Sum>i. emeasure M (disjointed f i))"
   687     using sets.range_disjointed_sets[OF assms] suminf_emeasure[of "disjointed f"]
   688     by (simp add:  disjoint_family_disjointed comp_def)
   689   also have "\<dots> \<le> (\<Sum>i. emeasure M (f i))"
   690     using sets.range_disjointed_sets[OF assms] assms
   691     by (auto intro!: suminf_le emeasure_mono disjointed_subset)
   692   finally show ?thesis .
   693 qed
   695 lemma emeasure_insert:
   696   assumes sets: "{x} \<in> sets M" "A \<in> sets M" and "x \<notin> A"
   697   shows "emeasure M (insert x A) = emeasure M {x} + emeasure M A"
   698 proof -
   699   have "{x} \<inter> A = {}" using \<open>x \<notin> A\<close> by auto
   700   from plus_emeasure[OF sets this] show ?thesis by simp
   701 qed
   703 lemma emeasure_insert_ne:
   704   "A \<noteq> {} \<Longrightarrow> {x} \<in> sets M \<Longrightarrow> A \<in> sets M \<Longrightarrow> x \<notin> A \<Longrightarrow> emeasure M (insert x A) = emeasure M {x} + emeasure M A"
   705   by (rule emeasure_insert)
   707 lemma emeasure_eq_sum_singleton:
   708   assumes "finite S" "\<And>x. x \<in> S \<Longrightarrow> {x} \<in> sets M"
   709   shows "emeasure M S = (\<Sum>x\<in>S. emeasure M {x})"
   710   using sum_emeasure[of "\<lambda>x. {x}" S M] assms
   711   by (auto simp: disjoint_family_on_def subset_eq)
   713 lemma sum_emeasure_cover:
   714   assumes "finite S" and "A \<in> sets M" and br_in_M: "B ` S \<subseteq> sets M"
   715   assumes A: "A \<subseteq> (\<Union>i\<in>S. B i)"
   716   assumes disj: "disjoint_family_on B S"
   717   shows "emeasure M A = (\<Sum>i\<in>S. emeasure M (A \<inter> (B i)))"
   718 proof -
   719   have "(\<Sum>i\<in>S. emeasure M (A \<inter> (B i))) = emeasure M (\<Union>i\<in>S. A \<inter> (B i))"
   720   proof (rule sum_emeasure)
   721     show "disjoint_family_on (\<lambda>i. A \<inter> B i) S"
   722       using \<open>disjoint_family_on B S\<close>
   723       unfolding disjoint_family_on_def by auto
   724   qed (insert assms, auto)
   725   also have "(\<Union>i\<in>S. A \<inter> (B i)) = A"
   726     using A by auto
   727   finally show ?thesis by simp
   728 qed
   730 lemma emeasure_eq_0:
   731   "N \<in> sets M \<Longrightarrow> emeasure M N = 0 \<Longrightarrow> K \<subseteq> N \<Longrightarrow> emeasure M K = 0"
   732   by (metis emeasure_mono order_eq_iff zero_le)
   734 lemma emeasure_UN_eq_0:
   735   assumes "\<And>i::nat. emeasure M (N i) = 0" and "range N \<subseteq> sets M"
   736   shows "emeasure M (\<Union>i. N i) = 0"
   737 proof -
   738   have "emeasure M (\<Union>i. N i) \<le> 0"
   739     using emeasure_subadditive_countably[OF assms(2)] assms(1) by simp
   740   then show ?thesis
   741     by (auto intro: antisym zero_le)
   742 qed
   744 lemma measure_eqI_finite:
   745   assumes [simp]: "sets M = Pow A" "sets N = Pow A" and "finite A"
   746   assumes eq: "\<And>a. a \<in> A \<Longrightarrow> emeasure M {a} = emeasure N {a}"
   747   shows "M = N"
   748 proof (rule measure_eqI)
   749   fix X assume "X \<in> sets M"
   750   then have X: "X \<subseteq> A" by auto
   751   then have "emeasure M X = (\<Sum>a\<in>X. emeasure M {a})"
   752     using \<open>finite A\<close> by (subst emeasure_eq_sum_singleton) (auto dest: finite_subset)
   753   also have "\<dots> = (\<Sum>a\<in>X. emeasure N {a})"
   754     using X eq by (auto intro!: sum.cong)
   755   also have "\<dots> = emeasure N X"
   756     using X \<open>finite A\<close> by (subst emeasure_eq_sum_singleton) (auto dest: finite_subset)
   757   finally show "emeasure M X = emeasure N X" .
   758 qed simp
   760 lemma measure_eqI_generator_eq:
   761   fixes M N :: "'a measure" and E :: "'a set set" and A :: "nat \<Rightarrow> 'a set"
   762   assumes "Int_stable E" "E \<subseteq> Pow \<Omega>"
   763   and eq: "\<And>X. X \<in> E \<Longrightarrow> emeasure M X = emeasure N X"
   764   and M: "sets M = sigma_sets \<Omega> E"
   765   and N: "sets N = sigma_sets \<Omega> E"
   766   and A: "range A \<subseteq> E" "(\<Union>i. A i) = \<Omega>" "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
   767   shows "M = N"
   768 proof -
   769   let ?\<mu>  = "emeasure M" and ?\<nu> = "emeasure N"
   770   interpret S: sigma_algebra \<Omega> "sigma_sets \<Omega> E" by (rule sigma_algebra_sigma_sets) fact
   771   have "space M = \<Omega>"
   772     using[of M] sets.space_closed[of M] S.space_closed \<open>sets M = sigma_sets \<Omega> E\<close>
   773     by blast
   775   { fix F D assume "F \<in> E" and "?\<mu> F \<noteq> \<infinity>"
   776     then have [intro]: "F \<in> sigma_sets \<Omega> E" by auto
   777     have "?\<nu> F \<noteq> \<infinity>" using \<open>?\<mu> F \<noteq> \<infinity>\<close> \<open>F \<in> E\<close> eq by simp
   778     assume "D \<in> sets M"
   779     with \<open>Int_stable E\<close> \<open>E \<subseteq> Pow \<Omega>\<close> have "emeasure M (F \<inter> D) = emeasure N (F \<inter> D)"
   780       unfolding M
   781     proof (induct rule: sigma_sets_induct_disjoint)
   782       case (basic A)
   783       then have "F \<inter> A \<in> E" using \<open>Int_stable E\<close> \<open>F \<in> E\<close> by (auto simp: Int_stable_def)
   784       then show ?case using eq by auto
   785     next
   786       case empty then show ?case by simp
   787     next
   788       case (compl A)
   789       then have **: "F \<inter> (\<Omega> - A) = F - (F \<inter> A)"
   790         and [intro]: "F \<inter> A \<in> sigma_sets \<Omega> E"
   791         using \<open>F \<in> E\<close> S.sets_into_space by (auto simp: M)
   792       have "?\<nu> (F \<inter> A) \<le> ?\<nu> F" by (auto intro!: emeasure_mono simp: M N)
   793       then have "?\<nu> (F \<inter> A) \<noteq> \<infinity>" using \<open>?\<nu> F \<noteq> \<infinity>\<close> by (auto simp: top_unique)
   794       have "?\<mu> (F \<inter> A) \<le> ?\<mu> F" by (auto intro!: emeasure_mono simp: M N)
   795       then have "?\<mu> (F \<inter> A) \<noteq> \<infinity>" using \<open>?\<mu> F \<noteq> \<infinity>\<close> by (auto simp: top_unique)
   796       then have "?\<mu> (F \<inter> (\<Omega> - A)) = ?\<mu> F - ?\<mu> (F \<inter> A)" unfolding **
   797         using \<open>F \<inter> A \<in> sigma_sets \<Omega> E\<close> by (auto intro!: emeasure_Diff simp: M N)
   798       also have "\<dots> = ?\<nu> F - ?\<nu> (F \<inter> A)" using eq \<open>F \<in> E\<close> compl by simp
   799       also have "\<dots> = ?\<nu> (F \<inter> (\<Omega> - A))" unfolding **
   800         using \<open>F \<inter> A \<in> sigma_sets \<Omega> E\<close> \<open>?\<nu> (F \<inter> A) \<noteq> \<infinity>\<close>
   801         by (auto intro!: emeasure_Diff[symmetric] simp: M N)
   802       finally show ?case
   803         using \<open>space M = \<Omega>\<close> by auto
   804     next
   805       case (union A)
   806       then have "?\<mu> (\<Union>x. F \<inter> A x) = ?\<nu> (\<Union>x. F \<inter> A x)"
   807         by (subst (1 2) suminf_emeasure[symmetric]) (auto simp: disjoint_family_on_def subset_eq M N)
   808       with A show ?case
   809         by auto
   810     qed }
   811   note * = this
   812   show "M = N"
   813   proof (rule measure_eqI)
   814     show "sets M = sets N"
   815       using M N by simp
   816     have [simp, intro]: "\<And>i. A i \<in> sets M"
   817       using A(1) by (auto simp: subset_eq M)
   818     fix F assume "F \<in> sets M"
   819     let ?D = "disjointed (\<lambda>i. F \<inter> A i)"
   820     from \<open>space M = \<Omega>\<close> have F_eq: "F = (\<Union>i. ?D i)"
   821       using \<open>F \<in> sets M\<close>[THEN sets.sets_into_space] A(2)[symmetric] by (auto simp: UN_disjointed_eq)
   822     have [simp, intro]: "\<And>i. ?D i \<in> sets M"
   823       using sets.range_disjointed_sets[of "\<lambda>i. F \<inter> A i" M] \<open>F \<in> sets M\<close>
   824       by (auto simp: subset_eq)
   825     have "disjoint_family ?D"
   826       by (auto simp: disjoint_family_disjointed)
   827     moreover
   828     have "(\<Sum>i. emeasure M (?D i)) = (\<Sum>i. emeasure N (?D i))"
   829     proof (intro arg_cong[where f=suminf] ext)
   830       fix i
   831       have "A i \<inter> ?D i = ?D i"
   832         by (auto simp: disjointed_def)
   833       then show "emeasure M (?D i) = emeasure N (?D i)"
   834         using *[of "A i" "?D i", OF _ A(3)] A(1) by auto
   835     qed
   836     ultimately show "emeasure M F = emeasure N F"
   837       by (simp add: image_subset_iff \<open>sets M = sets N\<close>[symmetric] F_eq[symmetric] suminf_emeasure)
   838   qed
   839 qed
   841 lemma space_empty: "space M = {} \<Longrightarrow> M = count_space {}"
   842   by (rule measure_eqI) (simp_all add: space_empty_iff)
   844 lemma measure_eqI_generator_eq_countable:
   845   fixes M N :: "'a measure" and E :: "'a set set" and A :: "'a set set"
   846   assumes E: "Int_stable E" "E \<subseteq> Pow \<Omega>" "\<And>X. X \<in> E \<Longrightarrow> emeasure M X = emeasure N X"
   847     and sets: "sets M = sigma_sets \<Omega> E" "sets N = sigma_sets \<Omega> E"
   848   and A: "A \<subseteq> E" "(\<Union>A) = \<Omega>" "countable A" "\<And>a. a \<in> A \<Longrightarrow> emeasure M a \<noteq> \<infinity>"
   849   shows "M = N"
   850 proof cases
   851   assume "\<Omega> = {}"
   852   have *: "sigma_sets \<Omega> E = sets (sigma \<Omega> E)"
   853     using E(2) by simp
   854   have "space M = \<Omega>" "space N = \<Omega>"
   855     using sets E(2) unfolding * by (auto dest: sets_eq_imp_space_eq simp del: sets_measure_of)
   856   then show "M = N"
   857     unfolding \<open>\<Omega> = {}\<close> by (auto dest: space_empty)
   858 next
   859   assume "\<Omega> \<noteq> {}" with \<open>\<Union>A = \<Omega>\<close> have "A \<noteq> {}" by auto
   860   from this \<open>countable A\<close> have rng: "range (from_nat_into A) = A"
   861     by (rule range_from_nat_into)
   862   show "M = N"
   863   proof (rule measure_eqI_generator_eq[OF E sets])
   864     show "range (from_nat_into A) \<subseteq> E"
   865       unfolding rng using \<open>A \<subseteq> E\<close> .
   866     show "(\<Union>i. from_nat_into A i) = \<Omega>"
   867       unfolding rng using \<open>\<Union>A = \<Omega>\<close> .
   868     show "emeasure M (from_nat_into A i) \<noteq> \<infinity>" for i
   869       using rng by (intro A) auto
   870   qed
   871 qed
   873 lemma measure_of_of_measure: "measure_of (space M) (sets M) (emeasure M) = M"
   874 proof (intro measure_eqI emeasure_measure_of_sigma)
   875   show "sigma_algebra (space M) (sets M)" ..
   876   show "positive (sets M) (emeasure M)"
   877     by (simp add: positive_def)
   878   show "countably_additive (sets M) (emeasure M)"
   879     by (simp add: emeasure_countably_additive)
   880 qed simp_all
   882 subsection \<open>\<open>\<mu>\<close>-null sets\<close>
   884 definition null_sets :: "'a measure \<Rightarrow> 'a set set" where
   885   "null_sets M = {N\<in>sets M. emeasure M N = 0}"
   887 lemma null_setsD1[dest]: "A \<in> null_sets M \<Longrightarrow> emeasure M A = 0"
   888   by (simp add: null_sets_def)
   890 lemma null_setsD2[dest]: "A \<in> null_sets M \<Longrightarrow> A \<in> sets M"
   891   unfolding null_sets_def by simp
   893 lemma null_setsI[intro]: "emeasure M A = 0 \<Longrightarrow> A \<in> sets M \<Longrightarrow> A \<in> null_sets M"
   894   unfolding null_sets_def by simp
   896 interpretation null_sets: ring_of_sets "space M" "null_sets M" for M
   897 proof (rule ring_of_setsI)
   898   show "null_sets M \<subseteq> Pow (space M)"
   899     using sets.sets_into_space by auto
   900   show "{} \<in> null_sets M"
   901     by auto
   902   fix A B assume null_sets: "A \<in> null_sets M" "B \<in> null_sets M"
   903   then have sets: "A \<in> sets M" "B \<in> sets M"
   904     by auto
   905   then have *: "emeasure M (A \<union> B) \<le> emeasure M A + emeasure M B"
   906     "emeasure M (A - B) \<le> emeasure M A"
   907     by (auto intro!: emeasure_subadditive emeasure_mono)
   908   then have "emeasure M B = 0" "emeasure M A = 0"
   909     using null_sets by auto
   910   with sets * show "A - B \<in> null_sets M" "A \<union> B \<in> null_sets M"
   911     by (auto intro!: antisym zero_le)
   912 qed
   914 lemma UN_from_nat_into:
   915   assumes I: "countable I" "I \<noteq> {}"
   916   shows "(\<Union>i\<in>I. N i) = (\<Union>i. N (from_nat_into I i))"
   917 proof -
   918   have "(\<Union>i\<in>I. N i) = \<Union>(N ` range (from_nat_into I))"
   919     using I by simp
   920   also have "\<dots> = (\<Union>i. (N \<circ> from_nat_into I) i)"
   921     by simp
   922   finally show ?thesis by simp
   923 qed
   925 lemma null_sets_UN':
   926   assumes "countable I"
   927   assumes "\<And>i. i \<in> I \<Longrightarrow> N i \<in> null_sets M"
   928   shows "(\<Union>i\<in>I. N i) \<in> null_sets M"
   929 proof cases
   930   assume "I = {}" then show ?thesis by simp
   931 next
   932   assume "I \<noteq> {}"
   933   show ?thesis
   934   proof (intro conjI CollectI null_setsI)
   935     show "(\<Union>i\<in>I. N i) \<in> sets M"
   936       using assms by (intro sets.countable_UN') auto
   937     have "emeasure M (\<Union>i\<in>I. N i) \<le> (\<Sum>n. emeasure M (N (from_nat_into I n)))"
   938       unfolding UN_from_nat_into[OF \<open>countable I\<close> \<open>I \<noteq> {}\<close>]
   939       using assms \<open>I \<noteq> {}\<close> by (intro emeasure_subadditive_countably) (auto intro: from_nat_into)
   940     also have "(\<lambda>n. emeasure M (N (from_nat_into I n))) = (\<lambda>_. 0)"
   941       using assms \<open>I \<noteq> {}\<close> by (auto intro: from_nat_into)
   942     finally show "emeasure M (\<Union>i\<in>I. N i) = 0"
   943       by (intro antisym zero_le) simp
   944   qed
   945 qed
   947 lemma null_sets_UN[intro]:
   948   "(\<And>i::'i::countable. N i \<in> null_sets M) \<Longrightarrow> (\<Union>i. N i) \<in> null_sets M"
   949   by (rule null_sets_UN') auto
   951 lemma null_set_Int1:
   952   assumes "B \<in> null_sets M" "A \<in> sets M" shows "A \<inter> B \<in> null_sets M"
   953 proof (intro CollectI conjI null_setsI)
   954   show "emeasure M (A \<inter> B) = 0" using assms
   955     by (intro emeasure_eq_0[of B _ "A \<inter> B"]) auto
   956 qed (insert assms, auto)
   958 lemma null_set_Int2:
   959   assumes "B \<in> null_sets M" "A \<in> sets M" shows "B \<inter> A \<in> null_sets M"
   960   using assms by (subst Int_commute) (rule null_set_Int1)
   962 lemma emeasure_Diff_null_set:
   963   assumes "B \<in> null_sets M" "A \<in> sets M"
   964   shows "emeasure M (A - B) = emeasure M A"
   965 proof -
   966   have *: "A - B = (A - (A \<inter> B))" by auto
   967   have "A \<inter> B \<in> null_sets M" using assms by (rule null_set_Int1)
   968   then show ?thesis
   969     unfolding * using assms
   970     by (subst emeasure_Diff) auto
   971 qed
   973 lemma null_set_Diff:
   974   assumes "B \<in> null_sets M" "A \<in> sets M" shows "B - A \<in> null_sets M"
   975 proof (intro CollectI conjI null_setsI)
   976   show "emeasure M (B - A) = 0" using assms by (intro emeasure_eq_0[of B _ "B - A"]) auto
   977 qed (insert assms, auto)
   979 lemma emeasure_Un_null_set:
   980   assumes "A \<in> sets M" "B \<in> null_sets M"
   981   shows "emeasure M (A \<union> B) = emeasure M A"
   982 proof -
   983   have *: "A \<union> B = A \<union> (B - A)" by auto
   984   have "B - A \<in> null_sets M" using assms(2,1) by (rule null_set_Diff)
   985   then show ?thesis
   986     unfolding * using assms
   987     by (subst plus_emeasure[symmetric]) auto
   988 qed
   990 subsection \<open>The almost everywhere filter (i.e.\ quantifier)\<close>
   992 definition ae_filter :: "'a measure \<Rightarrow> 'a filter" where
   993   "ae_filter M = (INF N:null_sets M. principal (space M - N))"
   995 abbreviation almost_everywhere :: "'a measure \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> bool" where
   996   "almost_everywhere M P \<equiv> eventually P (ae_filter M)"
   998 syntax
   999   "_almost_everywhere" :: "pttrn \<Rightarrow> 'a \<Rightarrow> bool \<Rightarrow> bool" ("AE _ in _. _" [0,0,10] 10)
  1001 translations
  1002   "AE x in M. P" \<rightleftharpoons> "CONST almost_everywhere M (\<lambda>x. P)"
  1004 abbreviation
  1005   "set_almost_everywhere A M P \<equiv> AE x in M. x \<in> A \<longrightarrow> P x"
  1007 syntax
  1008   "_set_almost_everywhere" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> bool \<Rightarrow> bool"
  1009   ("AE _\<in>_ in _./ _" [0,0,0,10] 10)
  1011 translations
  1012   "AE x\<in>A in M. P" \<rightleftharpoons> "CONST set_almost_everywhere A M (\<lambda>x. P)"
  1014 lemma eventually_ae_filter: "eventually P (ae_filter M) \<longleftrightarrow> (\<exists>N\<in>null_sets M. {x \<in> space M. \<not> P x} \<subseteq> N)"
  1015   unfolding ae_filter_def by (subst eventually_INF_base) (auto simp: eventually_principal subset_eq)
  1017 lemma AE_I':
  1018   "N \<in> null_sets M \<Longrightarrow> {x\<in>space M. \<not> P x} \<subseteq> N \<Longrightarrow> (AE x in M. P x)"
  1019   unfolding eventually_ae_filter by auto
  1021 lemma AE_iff_null:
  1022   assumes "{x\<in>space M. \<not> P x} \<in> sets M" (is "?P \<in> sets M")
  1023   shows "(AE x in M. P x) \<longleftrightarrow> {x\<in>space M. \<not> P x} \<in> null_sets M"
  1024 proof
  1025   assume "AE x in M. P x" then obtain N where N: "N \<in> sets M" "?P \<subseteq> N" "emeasure M N = 0"
  1026     unfolding eventually_ae_filter by auto
  1027   have "emeasure M ?P \<le> emeasure M N"
  1028     using assms N(1,2) by (auto intro: emeasure_mono)
  1029   then have "emeasure M ?P = 0"
  1030     unfolding \<open>emeasure M N = 0\<close> by auto
  1031   then show "?P \<in> null_sets M" using assms by auto
  1032 next
  1033   assume "?P \<in> null_sets M" with assms show "AE x in M. P x" by (auto intro: AE_I')
  1034 qed
  1036 lemma AE_iff_null_sets:
  1037   "N \<in> sets M \<Longrightarrow> N \<in> null_sets M \<longleftrightarrow> (AE x in M. x \<notin> N)"
  1038   using Int_absorb1[OF sets.sets_into_space, of N M]
  1039   by (subst AE_iff_null) (auto simp: Int_def[symmetric])
  1041 lemma AE_not_in:
  1042   "N \<in> null_sets M \<Longrightarrow> AE x in M. x \<notin> N"
  1043   by (metis AE_iff_null_sets null_setsD2)
  1045 lemma AE_iff_measurable:
  1046   "N \<in> sets M \<Longrightarrow> {x\<in>space M. \<not> P x} = N \<Longrightarrow> (AE x in M. P x) \<longleftrightarrow> emeasure M N = 0"
  1047   using AE_iff_null[of _ P] by auto
  1049 lemma AE_E[consumes 1]:
  1050   assumes "AE x in M. P x"
  1051   obtains N where "{x \<in> space M. \<not> P x} \<subseteq> N" "emeasure M N = 0" "N \<in> sets M"
  1052   using assms unfolding eventually_ae_filter by auto
  1054 lemma AE_E2:
  1055   assumes "AE x in M. P x" "{x\<in>space M. P x} \<in> sets M"
  1056   shows "emeasure M {x\<in>space M. \<not> P x} = 0" (is "emeasure M ?P = 0")
  1057 proof -
  1058   have "{x\<in>space M. \<not> P x} = space M - {x\<in>space M. P x}" by auto
  1059   with AE_iff_null[of M P] assms show ?thesis by auto
  1060 qed
  1062 lemma AE_I:
  1063   assumes "{x \<in> space M. \<not> P x} \<subseteq> N" "emeasure M N = 0" "N \<in> sets M"
  1064   shows "AE x in M. P x"
  1065   using assms unfolding eventually_ae_filter by auto
  1067 lemma AE_mp[elim!]:
  1068   assumes AE_P: "AE x in M. P x" and AE_imp: "AE x in M. P x \<longrightarrow> Q x"
  1069   shows "AE x in M. Q x"
  1070 proof -
  1071   from AE_P obtain A where P: "{x\<in>space M. \<not> P x} \<subseteq> A"
  1072     and A: "A \<in> sets M" "emeasure M A = 0"
  1073     by (auto elim!: AE_E)
  1075   from AE_imp obtain B where imp: "{x\<in>space M. P x \<and> \<not> Q x} \<subseteq> B"
  1076     and B: "B \<in> sets M" "emeasure M B = 0"
  1077     by (auto elim!: AE_E)
  1079   show ?thesis
  1080   proof (intro AE_I)
  1081     have "emeasure M (A \<union> B) \<le> 0"
  1082       using emeasure_subadditive[of A M B] A B by auto
  1083     then show "A \<union> B \<in> sets M" "emeasure M (A \<union> B) = 0"
  1084       using A B by auto
  1085     show "{x\<in>space M. \<not> Q x} \<subseteq> A \<union> B"
  1086       using P imp by auto
  1087   qed
  1088 qed
  1090 (* depricated replace by laws about eventually *)
  1091 lemma
  1092   shows AE_iffI: "AE x in M. P x \<Longrightarrow> AE x in M. P x \<longleftrightarrow> Q x \<Longrightarrow> AE x in M. Q x"
  1093     and AE_disjI1: "AE x in M. P x \<Longrightarrow> AE x in M. P x \<or> Q x"
  1094     and AE_disjI2: "AE x in M. Q x \<Longrightarrow> AE x in M. P x \<or> Q x"
  1095     and AE_conjI: "AE x in M. P x \<Longrightarrow> AE x in M. Q x \<Longrightarrow> AE x in M. P x \<and> Q x"
  1096     and AE_conj_iff[simp]: "(AE x in M. P x \<and> Q x) \<longleftrightarrow> (AE x in M. P x) \<and> (AE x in M. Q x)"
  1097   by auto
  1099 lemma AE_impI:
  1100   "(P \<Longrightarrow> AE x in M. Q x) \<Longrightarrow> AE x in M. P \<longrightarrow> Q x"
  1101   by (cases P) auto
  1103 lemma AE_measure:
  1104   assumes AE: "AE x in M. P x" and sets: "{x\<in>space M. P x} \<in> sets M" (is "?P \<in> sets M")
  1105   shows "emeasure M {x\<in>space M. P x} = emeasure M (space M)"
  1106 proof -
  1107   from AE_E[OF AE] guess N . note N = this
  1108   with sets have "emeasure M (space M) \<le> emeasure M (?P \<union> N)"
  1109     by (intro emeasure_mono) auto
  1110   also have "\<dots> \<le> emeasure M ?P + emeasure M N"
  1111     using sets N by (intro emeasure_subadditive) auto
  1112   also have "\<dots> = emeasure M ?P" using N by simp
  1113   finally show "emeasure M ?P = emeasure M (space M)"
  1114     using emeasure_space[of M "?P"] by auto
  1115 qed
  1117 lemma AE_space: "AE x in M. x \<in> space M"
  1118   by (rule AE_I[where N="{}"]) auto
  1120 lemma AE_I2[simp, intro]:
  1121   "(\<And>x. x \<in> space M \<Longrightarrow> P x) \<Longrightarrow> AE x in M. P x"
  1122   using AE_space by force
  1124 lemma AE_Ball_mp:
  1125   "\<forall>x\<in>space M. P x \<Longrightarrow> AE x in M. P x \<longrightarrow> Q x \<Longrightarrow> AE x in M. Q x"
  1126   by auto
  1128 lemma AE_cong[cong]:
  1129   "(\<And>x. x \<in> space M \<Longrightarrow> P x \<longleftrightarrow> Q x) \<Longrightarrow> (AE x in M. P x) \<longleftrightarrow> (AE x in M. Q x)"
  1130   by auto
  1132 lemma AE_cong_strong: "M = N \<Longrightarrow> (\<And>x. x \<in> space N =simp=> P x = Q x) \<Longrightarrow> (AE x in M. P x) \<longleftrightarrow> (AE x in N. Q x)"
  1133   by (auto simp: simp_implies_def)
  1135 lemma AE_all_countable:
  1136   "(AE x in M. \<forall>i. P i x) \<longleftrightarrow> (\<forall>i::'i::countable. AE x in M. P i x)"
  1137 proof
  1138   assume "\<forall>i. AE x in M. P i x"
  1139   from this[unfolded eventually_ae_filter Bex_def, THEN choice]
  1140   obtain N where N: "\<And>i. N i \<in> null_sets M" "\<And>i. {x\<in>space M. \<not> P i x} \<subseteq> N i" by auto
  1141   have "{x\<in>space M. \<not> (\<forall>i. P i x)} \<subseteq> (\<Union>i. {x\<in>space M. \<not> P i x})" by auto
  1142   also have "\<dots> \<subseteq> (\<Union>i. N i)" using N by auto
  1143   finally have "{x\<in>space M. \<not> (\<forall>i. P i x)} \<subseteq> (\<Union>i. N i)" .
  1144   moreover from N have "(\<Union>i. N i) \<in> null_sets M"
  1145     by (intro null_sets_UN) auto
  1146   ultimately show "AE x in M. \<forall>i. P i x"
  1147     unfolding eventually_ae_filter by auto
  1148 qed auto
  1150 lemma AE_ball_countable:
  1151   assumes [intro]: "countable X"
  1152   shows "(AE x in M. \<forall>y\<in>X. P x y) \<longleftrightarrow> (\<forall>y\<in>X. AE x in M. P x y)"
  1153 proof
  1154   assume "\<forall>y\<in>X. AE x in M. P x y"
  1155   from this[unfolded eventually_ae_filter Bex_def, THEN bchoice]
  1156   obtain N where N: "\<And>y. y \<in> X \<Longrightarrow> N y \<in> null_sets M" "\<And>y. y \<in> X \<Longrightarrow> {x\<in>space M. \<not> P x y} \<subseteq> N y"
  1157     by auto
  1158   have "{x\<in>space M. \<not> (\<forall>y\<in>X. P x y)} \<subseteq> (\<Union>y\<in>X. {x\<in>space M. \<not> P x y})"
  1159     by auto
  1160   also have "\<dots> \<subseteq> (\<Union>y\<in>X. N y)"
  1161     using N by auto
  1162   finally have "{x\<in>space M. \<not> (\<forall>y\<in>X. P x y)} \<subseteq> (\<Union>y\<in>X. N y)" .
  1163   moreover from N have "(\<Union>y\<in>X. N y) \<in> null_sets M"
  1164     by (intro null_sets_UN') auto
  1165   ultimately show "AE x in M. \<forall>y\<in>X. P x y"
  1166     unfolding eventually_ae_filter by auto
  1167 qed auto
  1169 lemma pairwise_alt: "pairwise R S \<longleftrightarrow> (\<forall>x\<in>S. \<forall>y\<in>S-{x}. R x y)"
  1170   by (auto simp add: pairwise_def)
  1172 lemma AE_pairwise: "countable F \<Longrightarrow> pairwise (\<lambda>A B. AE x in M. R x A B) F \<longleftrightarrow> (AE x in M. pairwise (R x) F)"
  1173   unfolding pairwise_alt by (simp add: AE_ball_countable)
  1175 lemma AE_discrete_difference:
  1176   assumes X: "countable X"
  1177   assumes null: "\<And>x. x \<in> X \<Longrightarrow> emeasure M {x} = 0"
  1178   assumes sets: "\<And>x. x \<in> X \<Longrightarrow> {x} \<in> sets M"
  1179   shows "AE x in M. x \<notin> X"
  1180 proof -
  1181   have "(\<Union>x\<in>X. {x}) \<in> null_sets M"
  1182     using assms by (intro null_sets_UN') auto
  1183   from AE_not_in[OF this] show "AE x in M. x \<notin> X"
  1184     by auto
  1185 qed
  1187 lemma AE_finite_all:
  1188   assumes f: "finite S" shows "(AE x in M. \<forall>i\<in>S. P i x) \<longleftrightarrow> (\<forall>i\<in>S. AE x in M. P i x)"
  1189   using f by induct auto
  1191 lemma AE_finite_allI:
  1192   assumes "finite S"
  1193   shows "(\<And>s. s \<in> S \<Longrightarrow> AE x in M. Q s x) \<Longrightarrow> AE x in M. \<forall>s\<in>S. Q s x"
  1194   using AE_finite_all[OF \<open>finite S\<close>] by auto
  1196 lemma emeasure_mono_AE:
  1197   assumes imp: "AE x in M. x \<in> A \<longrightarrow> x \<in> B"
  1198     and B: "B \<in> sets M"
  1199   shows "emeasure M A \<le> emeasure M B"
  1200 proof cases
  1201   assume A: "A \<in> sets M"
  1202   from imp obtain N where N: "{x\<in>space M. \<not> (x \<in> A \<longrightarrow> x \<in> B)} \<subseteq> N" "N \<in> null_sets M"
  1203     by (auto simp: eventually_ae_filter)
  1204   have "emeasure M A = emeasure M (A - N)"
  1205     using N A by (subst emeasure_Diff_null_set) auto
  1206   also have "emeasure M (A - N) \<le> emeasure M (B - N)"
  1207     using N A B sets.sets_into_space by (auto intro!: emeasure_mono)
  1208   also have "emeasure M (B - N) = emeasure M B"
  1209     using N B by (subst emeasure_Diff_null_set) auto
  1210   finally show ?thesis .
  1211 qed (simp add: emeasure_notin_sets)
  1213 lemma emeasure_eq_AE:
  1214   assumes iff: "AE x in M. x \<in> A \<longleftrightarrow> x \<in> B"
  1215   assumes A: "A \<in> sets M" and B: "B \<in> sets M"
  1216   shows "emeasure M A = emeasure M B"
  1217   using assms by (safe intro!: antisym emeasure_mono_AE) auto
  1219 lemma emeasure_Collect_eq_AE:
  1220   "AE x in M. P x \<longleftrightarrow> Q x \<Longrightarrow> Measurable.pred M Q \<Longrightarrow> Measurable.pred M P \<Longrightarrow>
  1221    emeasure M {x\<in>space M. P x} = emeasure M {x\<in>space M. Q x}"
  1222    by (intro emeasure_eq_AE) auto
  1224 lemma emeasure_eq_0_AE: "AE x in M. \<not> P x \<Longrightarrow> emeasure M {x\<in>space M. P x} = 0"
  1225   using AE_iff_measurable[OF _ refl, of M "\<lambda>x. \<not> P x"]
  1226   by (cases "{x\<in>space M. P x} \<in> sets M") (simp_all add: emeasure_notin_sets)
  1228 lemma emeasure_add_AE:
  1229   assumes [measurable]: "A \<in> sets M" "B \<in> sets M" "C \<in> sets M"
  1230   assumes 1: "AE x in M. x \<in> C \<longleftrightarrow> x \<in> A \<or> x \<in> B"
  1231   assumes 2: "AE x in M. \<not> (x \<in> A \<and> x \<in> B)"
  1232   shows "emeasure M C = emeasure M A + emeasure M B"
  1233 proof -
  1234   have "emeasure M C = emeasure M (A \<union> B)"
  1235     by (rule emeasure_eq_AE) (insert 1, auto)
  1236   also have "\<dots> = emeasure M A + emeasure M (B - A)"
  1237     by (subst plus_emeasure) auto
  1238   also have "emeasure M (B - A) = emeasure M B"
  1239     by (rule emeasure_eq_AE) (insert 2, auto)
  1240   finally show ?thesis .
  1241 qed
  1243 subsection \<open>\<open>\<sigma>\<close>-finite Measures\<close>
  1245 locale sigma_finite_measure =
  1246   fixes M :: "'a measure"
  1247   assumes sigma_finite_countable:
  1248     "\<exists>A::'a set set. countable A \<and> A \<subseteq> sets M \<and> (\<Union>A) = space M \<and> (\<forall>a\<in>A. emeasure M a \<noteq> \<infinity>)"
  1250 lemma (in sigma_finite_measure) sigma_finite:
  1251   obtains A :: "nat \<Rightarrow> 'a set"
  1252   where "range A \<subseteq> sets M" "(\<Union>i. A i) = space M" "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
  1253 proof -
  1254   obtain A :: "'a set set" where
  1255     [simp]: "countable A" and
  1256     A: "A \<subseteq> sets M" "(\<Union>A) = space M" "\<And>a. a \<in> A \<Longrightarrow> emeasure M a \<noteq> \<infinity>"
  1257     using sigma_finite_countable by metis
  1258   show thesis
  1259   proof cases
  1260     assume "A = {}" with \<open>(\<Union>A) = space M\<close> show thesis
  1261       by (intro that[of "\<lambda>_. {}"]) auto
  1262   next
  1263     assume "A \<noteq> {}"
  1264     show thesis
  1265     proof
  1266       show "range (from_nat_into A) \<subseteq> sets M"
  1267         using \<open>A \<noteq> {}\<close> A by auto
  1268       have "(\<Union>i. from_nat_into A i) = \<Union>A"
  1269         using range_from_nat_into[OF \<open>A \<noteq> {}\<close> \<open>countable A\<close>] by auto
  1270       with A show "(\<Union>i. from_nat_into A i) = space M"
  1271         by auto
  1272     qed (intro A from_nat_into \<open>A \<noteq> {}\<close>)
  1273   qed
  1274 qed
  1276 lemma (in sigma_finite_measure) sigma_finite_disjoint:
  1277   obtains A :: "nat \<Rightarrow> 'a set"
  1278   where "range A \<subseteq> sets M" "(\<Union>i. A i) = space M" "\<And>i. emeasure M (A i) \<noteq> \<infinity>" "disjoint_family A"
  1279 proof -
  1280   obtain A :: "nat \<Rightarrow> 'a set" where
  1281     range: "range A \<subseteq> sets M" and
  1282     space: "(\<Union>i. A i) = space M" and
  1283     measure: "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
  1284     using sigma_finite by blast
  1285   show thesis
  1286   proof (rule that[of "disjointed A"])
  1287     show "range (disjointed A) \<subseteq> sets M"
  1288       by (rule sets.range_disjointed_sets[OF range])
  1289     show "(\<Union>i. disjointed A i) = space M"
  1290       and "disjoint_family (disjointed A)"
  1291       using disjoint_family_disjointed UN_disjointed_eq[of A] space range
  1292       by auto
  1293     show "emeasure M (disjointed A i) \<noteq> \<infinity>" for i
  1294     proof -
  1295       have "emeasure M (disjointed A i) \<le> emeasure M (A i)"
  1296         using range disjointed_subset[of A i] by (auto intro!: emeasure_mono)
  1297       then show ?thesis using measure[of i] by (auto simp: top_unique)
  1298     qed
  1299   qed
  1300 qed
  1302 lemma (in sigma_finite_measure) sigma_finite_incseq:
  1303   obtains A :: "nat \<Rightarrow> 'a set"
  1304   where "range A \<subseteq> sets M" "(\<Union>i. A i) = space M" "\<And>i. emeasure M (A i) \<noteq> \<infinity>" "incseq A"
  1305 proof -
  1306   obtain F :: "nat \<Rightarrow> 'a set" where
  1307     F: "range F \<subseteq> sets M" "(\<Union>i. F i) = space M" "\<And>i. emeasure M (F i) \<noteq> \<infinity>"
  1308     using sigma_finite by blast
  1309   show thesis
  1310   proof (rule that[of "\<lambda>n. \<Union>i\<le>n. F i"])
  1311     show "range (\<lambda>n. \<Union>i\<le>n. F i) \<subseteq> sets M"
  1312       using F by (force simp: incseq_def)
  1313     show "(\<Union>n. \<Union>i\<le>n. F i) = space M"
  1314     proof -
  1315       from F have "\<And>x. x \<in> space M \<Longrightarrow> \<exists>i. x \<in> F i" by auto
  1316       with F show ?thesis by fastforce
  1317     qed
  1318     show "emeasure M (\<Union>i\<le>n. F i) \<noteq> \<infinity>" for n
  1319     proof -
  1320       have "emeasure M (\<Union>i\<le>n. F i) \<le> (\<Sum>i\<le>n. emeasure M (F i))"
  1321         using F by (auto intro!: emeasure_subadditive_finite)
  1322       also have "\<dots> < \<infinity>"
  1323         using F by (auto simp: sum_Pinfty less_top)
  1324       finally show ?thesis by simp
  1325     qed
  1326     show "incseq (\<lambda>n. \<Union>i\<le>n. F i)"
  1327       by (force simp: incseq_def)
  1328   qed
  1329 qed
  1331 subsection \<open>Measure space induced by distribution of @{const measurable}-functions\<close>
  1333 definition distr :: "'a measure \<Rightarrow> 'b measure \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b measure" where
  1334   "distr M N f = measure_of (space N) (sets N) (\<lambda>A. emeasure M (f -` A \<inter> space M))"
  1336 lemma
  1337   shows sets_distr[simp, measurable_cong]: "sets (distr M N f) = sets N"
  1338     and space_distr[simp]: "space (distr M N f) = space N"
  1339   by (auto simp: distr_def)
  1341 lemma
  1342   shows measurable_distr_eq1[simp]: "measurable (distr Mf Nf f) Mf' = measurable Nf Mf'"
  1343     and measurable_distr_eq2[simp]: "measurable Mg' (distr Mg Ng g) = measurable Mg' Ng"
  1344   by (auto simp: measurable_def)
  1346 lemma distr_cong:
  1347   "M = K \<Longrightarrow> sets N = sets L \<Longrightarrow> (\<And>x. x \<in> space M \<Longrightarrow> f x = g x) \<Longrightarrow> distr M N f = distr K L g"
  1348   using sets_eq_imp_space_eq[of N L] by (simp add: distr_def Int_def cong: rev_conj_cong)
  1350 lemma emeasure_distr:
  1351   fixes f :: "'a \<Rightarrow> 'b"
  1352   assumes f: "f \<in> measurable M N" and A: "A \<in> sets N"
  1353   shows "emeasure (distr M N f) A = emeasure M (f -` A \<inter> space M)" (is "_ = ?\<mu> A")
  1354   unfolding distr_def
  1355 proof (rule emeasure_measure_of_sigma)
  1356   show "positive (sets N) ?\<mu>"
  1357     by (auto simp: positive_def)
  1359   show "countably_additive (sets N) ?\<mu>"
  1360   proof (intro countably_additiveI)
  1361     fix A :: "nat \<Rightarrow> 'b set" assume "range A \<subseteq> sets N" "disjoint_family A"
  1362     then have A: "\<And>i. A i \<in> sets N" "(\<Union>i. A i) \<in> sets N" by auto
  1363     then have *: "range (\<lambda>i. f -` (A i) \<inter> space M) \<subseteq> sets M"
  1364       using f by (auto simp: measurable_def)
  1365     moreover have "(\<Union>i. f -`  A i \<inter> space M) \<in> sets M"
  1366       using * by blast
  1367     moreover have **: "disjoint_family (\<lambda>i. f -` A i \<inter> space M)"
  1368       using \<open>disjoint_family A\<close> by (auto simp: disjoint_family_on_def)
  1369     ultimately show "(\<Sum>i. ?\<mu> (A i)) = ?\<mu> (\<Union>i. A i)"
  1370       using suminf_emeasure[OF _ **] A f
  1371       by (auto simp: comp_def vimage_UN)
  1372   qed
  1373   show "sigma_algebra (space N) (sets N)" ..
  1374 qed fact
  1376 lemma emeasure_Collect_distr:
  1377   assumes X[measurable]: "X \<in> measurable M N" "Measurable.pred N P"
  1378   shows "emeasure (distr M N X) {x\<in>space N. P x} = emeasure M {x\<in>space M. P (X x)}"
  1379   by (subst emeasure_distr)
  1380      (auto intro!: arg_cong2[where f=emeasure] X(1)[THEN measurable_space])
  1382 lemma emeasure_lfp2[consumes 1, case_names cont f measurable]:
  1383   assumes "P M"
  1384   assumes cont: "sup_continuous F"
  1385   assumes f: "\<And>M. P M \<Longrightarrow> f \<in> measurable M' M"
  1386   assumes *: "\<And>M A. P M \<Longrightarrow> (\<And>N. P N \<Longrightarrow> Measurable.pred N A) \<Longrightarrow> Measurable.pred M (F A)"
  1387   shows "emeasure M' {x\<in>space M'. lfp F (f x)} = (SUP i. emeasure M' {x\<in>space M'. (F ^^ i) (\<lambda>x. False) (f x)})"
  1388 proof (subst (1 2) emeasure_Collect_distr[symmetric, where X=f])
  1389   show "f \<in> measurable M' M"  "f \<in> measurable M' M"
  1390     using f[OF \<open>P M\<close>] by auto
  1391   { fix i show "Measurable.pred M ((F ^^ i) (\<lambda>x. False))"
  1392     using \<open>P M\<close> by (induction i arbitrary: M) (auto intro!: *) }
  1393   show "Measurable.pred M (lfp F)"
  1394     using \<open>P M\<close> cont * by (rule measurable_lfp_coinduct[of P])
  1396   have "emeasure (distr M' M f) {x \<in> space (distr M' M f). lfp F x} =
  1397     (SUP i. emeasure (distr M' M f) {x \<in> space (distr M' M f). (F ^^ i) (\<lambda>x. False) x})"
  1398     using \<open>P M\<close>
  1399   proof (coinduction arbitrary: M rule: emeasure_lfp')
  1400     case (measurable A N) then have "\<And>N. P N \<Longrightarrow> Measurable.pred (distr M' N f) A"
  1401       by metis
  1402     then have "\<And>N. P N \<Longrightarrow> Measurable.pred N A"
  1403       by simp
  1404     with \<open>P N\<close>[THEN *] show ?case
  1405       by auto
  1406   qed fact
  1407   then show "emeasure (distr M' M f) {x \<in> space M. lfp F x} =
  1408     (SUP i. emeasure (distr M' M f) {x \<in> space M. (F ^^ i) (\<lambda>x. False) x})"
  1409    by simp
  1410 qed
  1412 lemma distr_id[simp]: "distr N N (\<lambda>x. x) = N"
  1413   by (rule measure_eqI) (auto simp: emeasure_distr)
  1415 lemma measure_distr:
  1416   "f \<in> measurable M N \<Longrightarrow> S \<in> sets N \<Longrightarrow> measure (distr M N f) S = measure M (f -` S \<inter> space M)"
  1417   by (simp add: emeasure_distr measure_def)
  1419 lemma distr_cong_AE:
  1420   assumes 1: "M = K" "sets N = sets L" and
  1421     2: "(AE x in M. f x = g x)" and "f \<in> measurable M N" and "g \<in> measurable K L"
  1422   shows "distr M N f = distr K L g"
  1423 proof (rule measure_eqI)
  1424   fix A assume "A \<in> sets (distr M N f)"
  1425   with assms show "emeasure (distr M N f) A = emeasure (distr K L g) A"
  1426     by (auto simp add: emeasure_distr intro!: emeasure_eq_AE measurable_sets)
  1427 qed (insert 1, simp)
  1429 lemma AE_distrD:
  1430   assumes f: "f \<in> measurable M M'"
  1431     and AE: "AE x in distr M M' f. P x"
  1432   shows "AE x in M. P (f x)"
  1433 proof -
  1434   from AE[THEN AE_E] guess N .
  1435   with f show ?thesis
  1436     unfolding eventually_ae_filter
  1437     by (intro bexI[of _ "f -` N \<inter> space M"])
  1438        (auto simp: emeasure_distr measurable_def)
  1439 qed
  1441 lemma AE_distr_iff:
  1442   assumes f[measurable]: "f \<in> measurable M N" and P[measurable]: "{x \<in> space N. P x} \<in> sets N"
  1443   shows "(AE x in distr M N f. P x) \<longleftrightarrow> (AE x in M. P (f x))"
  1444 proof (subst (1 2) AE_iff_measurable[OF _ refl])
  1445   have "f -` {x\<in>space N. \<not> P x} \<inter> space M = {x \<in> space M. \<not> P (f x)}"
  1446     using f[THEN measurable_space] by auto
  1447   then show "(emeasure (distr M N f) {x \<in> space (distr M N f). \<not> P x} = 0) =
  1448     (emeasure M {x \<in> space M. \<not> P (f x)} = 0)"
  1449     by (simp add: emeasure_distr)
  1450 qed auto
  1452 lemma null_sets_distr_iff:
  1453   "f \<in> measurable M N \<Longrightarrow> A \<in> null_sets (distr M N f) \<longleftrightarrow> f -` A \<inter> space M \<in> null_sets M \<and> A \<in> sets N"
  1454   by (auto simp add: null_sets_def emeasure_distr)
  1456 lemma distr_distr:
  1457   "g \<in> measurable N L \<Longrightarrow> f \<in> measurable M N \<Longrightarrow> distr (distr M N f) L g = distr M L (g \<circ> f)"
  1458   by (auto simp add: emeasure_distr measurable_space
  1459            intro!: arg_cong[where f="emeasure M"] measure_eqI)
  1461 subsection \<open>Real measure values\<close>
  1463 lemma ring_of_finite_sets: "ring_of_sets (space M) {A\<in>sets M. emeasure M A \<noteq> top}"
  1464 proof (rule ring_of_setsI)
  1465   show "a \<in> {A \<in> sets M. emeasure M A \<noteq> top} \<Longrightarrow> b \<in> {A \<in> sets M. emeasure M A \<noteq> top} \<Longrightarrow>
  1466     a \<union> b \<in> {A \<in> sets M. emeasure M A \<noteq> top}" for a b
  1467     using emeasure_subadditive[of a M b] by (auto simp: top_unique)
  1469   show "a \<in> {A \<in> sets M. emeasure M A \<noteq> top} \<Longrightarrow> b \<in> {A \<in> sets M. emeasure M A \<noteq> top} \<Longrightarrow>
  1470     a - b \<in> {A \<in> sets M. emeasure M A \<noteq> top}" for a b
  1471     using emeasure_mono[of "a - b" a M] by (auto simp: Diff_subset top_unique)
  1472 qed (auto dest: sets.sets_into_space)
  1474 lemma measure_nonneg[simp]: "0 \<le> measure M A"
  1475   unfolding measure_def by auto
  1477 lemma zero_less_measure_iff: "0 < measure M A \<longleftrightarrow> measure M A \<noteq> 0"
  1478   using measure_nonneg[of M A] by (auto simp add: le_less)
  1480 lemma measure_le_0_iff: "measure M X \<le> 0 \<longleftrightarrow> measure M X = 0"
  1481   using measure_nonneg[of M X] by linarith
  1483 lemma measure_empty[simp]: "measure M {} = 0"
  1484   unfolding measure_def by (simp add: zero_ennreal.rep_eq)
  1486 lemma emeasure_eq_ennreal_measure:
  1487   "emeasure M A \<noteq> top \<Longrightarrow> emeasure M A = ennreal (measure M A)"
  1488   by (cases "emeasure M A" rule: ennreal_cases) (auto simp: measure_def)
  1490 lemma measure_zero_top: "emeasure M A = top \<Longrightarrow> measure M A = 0"
  1491   by (simp add: measure_def enn2ereal_top)
  1493 lemma measure_eq_emeasure_eq_ennreal: "0 \<le> x \<Longrightarrow> emeasure M A = ennreal x \<Longrightarrow> measure M A = x"
  1494   using emeasure_eq_ennreal_measure[of M A]
  1495   by (cases "A \<in> M") (auto simp: measure_notin_sets emeasure_notin_sets)
  1497 lemma enn2real_plus:"a < top \<Longrightarrow> b < top \<Longrightarrow> enn2real (a + b) = enn2real a + enn2real b"
  1498   by (simp add: enn2real_def plus_ennreal.rep_eq real_of_ereal_add less_top
  1499            del: real_of_ereal_enn2ereal)
  1501 lemma measure_eq_AE:
  1502   assumes iff: "AE x in M. x \<in> A \<longleftrightarrow> x \<in> B"
  1503   assumes A: "A \<in> sets M" and B: "B \<in> sets M"
  1504   shows "measure M A = measure M B"
  1505   using assms emeasure_eq_AE[OF assms] by (simp add: measure_def)
  1507 lemma measure_Union:
  1508   "emeasure M A \<noteq> \<infinity> \<Longrightarrow> emeasure M B \<noteq> \<infinity> \<Longrightarrow> A \<in> sets M \<Longrightarrow> B \<in> sets M \<Longrightarrow> A \<inter> B = {} \<Longrightarrow>
  1509     measure M (A \<union> B) = measure M A + measure M B"
  1510   by (simp add: measure_def plus_emeasure[symmetric] enn2real_plus less_top)
  1512 lemma disjoint_family_on_insert:
  1513   "i \<notin> I \<Longrightarrow> disjoint_family_on A (insert i I) \<longleftrightarrow> A i \<inter> (\<Union>i\<in>I. A i) = {} \<and> disjoint_family_on A I"
  1514   by (fastforce simp: disjoint_family_on_def)
  1516 lemma measure_finite_Union:
  1517   "finite S \<Longrightarrow> A`S \<subseteq> sets M \<Longrightarrow> disjoint_family_on A S \<Longrightarrow> (\<And>i. i \<in> S \<Longrightarrow> emeasure M (A i) \<noteq> \<infinity>) \<Longrightarrow>
  1518     measure M (\<Union>i\<in>S. A i) = (\<Sum>i\<in>S. measure M (A i))"
  1519   by (induction S rule: finite_induct)
  1520      (auto simp: disjoint_family_on_insert measure_Union sum_emeasure[symmetric] sets.countable_UN'[OF countable_finite])
  1522 lemma measure_Diff:
  1523   assumes finite: "emeasure M A \<noteq> \<infinity>"
  1524   and measurable: "A \<in> sets M" "B \<in> sets M" "B \<subseteq> A"
  1525   shows "measure M (A - B) = measure M A - measure M B"
  1526 proof -
  1527   have "emeasure M (A - B) \<le> emeasure M A" "emeasure M B \<le> emeasure M A"
  1528     using measurable by (auto intro!: emeasure_mono)
  1529   hence "measure M ((A - B) \<union> B) = measure M (A - B) + measure M B"
  1530     using measurable finite by (rule_tac measure_Union) (auto simp: top_unique)
  1531   thus ?thesis using \<open>B \<subseteq> A\<close> by (auto simp: Un_absorb2)
  1532 qed
  1534 lemma measure_UNION:
  1535   assumes measurable: "range A \<subseteq> sets M" "disjoint_family A"
  1536   assumes finite: "emeasure M (\<Union>i. A i) \<noteq> \<infinity>"
  1537   shows "(\<lambda>i. measure M (A i)) sums (measure M (\<Union>i. A i))"
  1538 proof -
  1539   have "(\<lambda>i. emeasure M (A i)) sums (emeasure M (\<Union>i. A i))"
  1540     unfolding suminf_emeasure[OF measurable, symmetric] by (simp add: summable_sums)
  1541   moreover
  1542   { fix i
  1543     have "emeasure M (A i) \<le> emeasure M (\<Union>i. A i)"
  1544       using measurable by (auto intro!: emeasure_mono)
  1545     then have "emeasure M (A i) = ennreal ((measure M (A i)))"
  1546       using finite by (intro emeasure_eq_ennreal_measure) (auto simp: top_unique) }
  1547   ultimately show ?thesis using finite
  1548     by (subst (asm) (2) emeasure_eq_ennreal_measure) simp_all
  1549 qed
  1551 lemma measure_subadditive:
  1552   assumes measurable: "A \<in> sets M" "B \<in> sets M"
  1553   and fin: "emeasure M A \<noteq> \<infinity>" "emeasure M B \<noteq> \<infinity>"
  1554   shows "measure M (A \<union> B) \<le> measure M A + measure M B"
  1555 proof -
  1556   have "emeasure M (A \<union> B) \<noteq> \<infinity>"
  1557     using emeasure_subadditive[OF measurable] fin by (auto simp: top_unique)
  1558   then show "(measure M (A \<union> B)) \<le> (measure M A) + (measure M B)"
  1559     using emeasure_subadditive[OF measurable] fin
  1560     apply simp
  1561     apply (subst (asm) (2 3 4) emeasure_eq_ennreal_measure)
  1562     apply (auto simp add: ennreal_plus[symmetric] simp del: ennreal_plus)
  1563     done
  1564 qed
  1566 lemma measure_subadditive_finite:
  1567   assumes A: "finite I" "A`I \<subseteq> sets M" and fin: "\<And>i. i \<in> I \<Longrightarrow> emeasure M (A i) \<noteq> \<infinity>"
  1568   shows "measure M (\<Union>i\<in>I. A i) \<le> (\<Sum>i\<in>I. measure M (A i))"
  1569 proof -
  1570   { have "emeasure M (\<Union>i\<in>I. A i) \<le> (\<Sum>i\<in>I. emeasure M (A i))"
  1571       using emeasure_subadditive_finite[OF A] .
  1572     also have "\<dots> < \<infinity>"
  1573       using fin by (simp add: less_top A)
  1574     finally have "emeasure M (\<Union>i\<in>I. A i) \<noteq> top" by simp }
  1575   note * = this
  1576   show ?thesis
  1577     using emeasure_subadditive_finite[OF A] fin
  1578     unfolding emeasure_eq_ennreal_measure[OF *]
  1579     by (simp_all add: sum_nonneg emeasure_eq_ennreal_measure)
  1580 qed
  1582 lemma measure_subadditive_countably:
  1583   assumes A: "range A \<subseteq> sets M" and fin: "(\<Sum>i. emeasure M (A i)) \<noteq> \<infinity>"
  1584   shows "measure M (\<Union>i. A i) \<le> (\<Sum>i. measure M (A i))"
  1585 proof -
  1586   from fin have **: "\<And>i. emeasure M (A i) \<noteq> top"
  1587     using ennreal_suminf_lessD[of "\<lambda>i. emeasure M (A i)"] by (simp add: less_top)
  1588   { have "emeasure M (\<Union>i. A i) \<le> (\<Sum>i. emeasure M (A i))"
  1589       using emeasure_subadditive_countably[OF A] .
  1590     also have "\<dots> < \<infinity>"
  1591       using fin by (simp add: less_top)
  1592     finally have "emeasure M (\<Union>i. A i) \<noteq> top" by simp }
  1593   then have "ennreal (measure M (\<Union>i. A i)) = emeasure M (\<Union>i. A i)"
  1594     by (rule emeasure_eq_ennreal_measure[symmetric])
  1595   also have "\<dots> \<le> (\<Sum>i. emeasure M (A i))"
  1596     using emeasure_subadditive_countably[OF A] .
  1597   also have "\<dots> = ennreal (\<Sum>i. measure M (A i))"
  1598     using fin unfolding emeasure_eq_ennreal_measure[OF **]
  1599     by (subst suminf_ennreal) (auto simp: **)
  1600   finally show ?thesis
  1601     apply (rule ennreal_le_iff[THEN iffD1, rotated])
  1602     apply (intro suminf_nonneg allI measure_nonneg summable_suminf_not_top)
  1603     using fin
  1604     apply (simp add: emeasure_eq_ennreal_measure[OF **])
  1605     done
  1606 qed
  1608 lemma measure_Un_null_set: "A \<in> sets M \<Longrightarrow> B \<in> null_sets M \<Longrightarrow> measure M (A \<union> B) = measure M A"
  1609   by (simp add: measure_def emeasure_Un_null_set)
  1611 lemma measure_Diff_null_set: "A \<in> sets M \<Longrightarrow> B \<in> null_sets M \<Longrightarrow> measure M (A - B) = measure M A"
  1612   by (simp add: measure_def emeasure_Diff_null_set)
  1614 lemma measure_eq_sum_singleton:
  1615   "finite S \<Longrightarrow> (\<And>x. x \<in> S \<Longrightarrow> {x} \<in> sets M) \<Longrightarrow> (\<And>x. x \<in> S \<Longrightarrow> emeasure M {x} \<noteq> \<infinity>) \<Longrightarrow>
  1616     measure M S = (\<Sum>x\<in>S. measure M {x})"
  1617   using emeasure_eq_sum_singleton[of S M]
  1618   by (intro measure_eq_emeasure_eq_ennreal) (auto simp: sum_nonneg emeasure_eq_ennreal_measure)
  1620 lemma Lim_measure_incseq:
  1621   assumes A: "range A \<subseteq> sets M" "incseq A" and fin: "emeasure M (\<Union>i. A i) \<noteq> \<infinity>"
  1622   shows "(\<lambda>i. measure M (A i)) \<longlonglongrightarrow> measure M (\<Union>i. A i)"
  1623 proof (rule tendsto_ennrealD)
  1624   have "ennreal (measure M (\<Union>i. A i)) = emeasure M (\<Union>i. A i)"
  1625     using fin by (auto simp: emeasure_eq_ennreal_measure)
  1626   moreover have "ennreal (measure M (A i)) = emeasure M (A i)" for i
  1627     using assms emeasure_mono[of "A _" "\<Union>i. A i" M]
  1628     by (intro emeasure_eq_ennreal_measure[symmetric]) (auto simp: less_top UN_upper intro: le_less_trans)
  1629   ultimately show "(\<lambda>x. ennreal (Sigma_Algebra.measure M (A x))) \<longlonglongrightarrow> ennreal (Sigma_Algebra.measure M (\<Union>i. A i))"
  1630     using A by (auto intro!: Lim_emeasure_incseq)
  1631 qed auto
  1633 lemma Lim_measure_decseq:
  1634   assumes A: "range A \<subseteq> sets M" "decseq A" and fin: "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
  1635   shows "(\<lambda>n. measure M (A n)) \<longlonglongrightarrow> measure M (\<Inter>i. A i)"
  1636 proof (rule tendsto_ennrealD)
  1637   have "ennreal (measure M (\<Inter>i. A i)) = emeasure M (\<Inter>i. A i)"
  1638     using fin[of 0] A emeasure_mono[of "\<Inter>i. A i" "A 0" M]
  1639     by (auto intro!: emeasure_eq_ennreal_measure[symmetric] simp: INT_lower less_top intro: le_less_trans)
  1640   moreover have "ennreal (measure M (A i)) = emeasure M (A i)" for i
  1641     using A fin[of i] by (intro emeasure_eq_ennreal_measure[symmetric]) auto
  1642   ultimately show "(\<lambda>x. ennreal (Sigma_Algebra.measure M (A x))) \<longlonglongrightarrow> ennreal (Sigma_Algebra.measure M (\<Inter>i. A i))"
  1643     using fin A by (auto intro!: Lim_emeasure_decseq)
  1644 qed auto
  1646 subsection \<open>Set of measurable sets with finite measure\<close>
  1648 definition fmeasurable :: "'a measure \<Rightarrow> 'a set set"
  1649 where
  1650   "fmeasurable M = {A\<in>sets M. emeasure M A < \<infinity>}"
  1652 lemma fmeasurableD[dest, measurable_dest]: "A \<in> fmeasurable M \<Longrightarrow> A \<in> sets M"
  1653   by (auto simp: fmeasurable_def)
  1655 lemma fmeasurableD2: "A \<in> fmeasurable M \<Longrightarrow> emeasure M A \<noteq> top"
  1656   by (auto simp: fmeasurable_def)
  1658 lemma fmeasurableI: "A \<in> sets M \<Longrightarrow> emeasure M A < \<infinity> \<Longrightarrow> A \<in> fmeasurable M"
  1659   by (auto simp: fmeasurable_def)
  1661 lemma fmeasurableI_null_sets: "A \<in> null_sets M \<Longrightarrow> A \<in> fmeasurable M"
  1662   by (auto simp: fmeasurable_def)
  1664 lemma fmeasurableI2: "A \<in> fmeasurable M \<Longrightarrow> B \<subseteq> A \<Longrightarrow> B \<in> sets M \<Longrightarrow> B \<in> fmeasurable M"
  1665   using emeasure_mono[of B A M] by (auto simp: fmeasurable_def)
  1667 lemma measure_mono_fmeasurable:
  1668   "A \<subseteq> B \<Longrightarrow> A \<in> sets M \<Longrightarrow> B \<in> fmeasurable M \<Longrightarrow> measure M A \<le> measure M B"
  1669   by (auto simp: measure_def fmeasurable_def intro!: emeasure_mono enn2real_mono)
  1671 lemma emeasure_eq_measure2: "A \<in> fmeasurable M \<Longrightarrow> emeasure M A = measure M A"
  1672   by (simp add: emeasure_eq_ennreal_measure fmeasurable_def less_top)
  1674 interpretation fmeasurable: ring_of_sets "space M" "fmeasurable M"
  1675 proof (rule ring_of_setsI)
  1676   show "fmeasurable M \<subseteq> Pow (space M)" "{} \<in> fmeasurable M"
  1677     by (auto simp: fmeasurable_def dest: sets.sets_into_space)
  1678   fix a b assume *: "a \<in> fmeasurable M" "b \<in> fmeasurable M"
  1679   then have "emeasure M (a \<union> b) \<le> emeasure M a + emeasure M b"
  1680     by (intro emeasure_subadditive) auto
  1681   also have "\<dots> < top"
  1682     using * by (auto simp: fmeasurable_def)
  1683   finally show  "a \<union> b \<in> fmeasurable M"
  1684     using * by (auto intro: fmeasurableI)
  1685   show "a - b \<in> fmeasurable M"
  1686     using emeasure_mono[of "a - b" a M] * by (auto simp: fmeasurable_def Diff_subset)
  1687 qed
  1689 lemma fmeasurable_Diff: "A \<in> fmeasurable M \<Longrightarrow> B \<in> sets M \<Longrightarrow> A - B \<in> fmeasurable M"
  1690   using fmeasurableI2[of A M "A - B"] by auto
  1692 lemma fmeasurable_UN:
  1693   assumes "countable I" "\<And>i. i \<in> I \<Longrightarrow> F i \<subseteq> A" "\<And>i. i \<in> I \<Longrightarrow> F i \<in> sets M" "A \<in> fmeasurable M"
  1694   shows "(\<Union>i\<in>I. F i) \<in> fmeasurable M"
  1695 proof (rule fmeasurableI2)
  1696   show "A \<in> fmeasurable M" "(\<Union>i\<in>I. F i) \<subseteq> A" using assms by auto
  1697   show "(\<Union>i\<in>I. F i) \<in> sets M"
  1698     using assms by (intro sets.countable_UN') auto
  1699 qed
  1701 lemma fmeasurable_INT:
  1702   assumes "countable I" "i \<in> I" "\<And>i. i \<in> I \<Longrightarrow> F i \<in> sets M" "F i \<in> fmeasurable M"
  1703   shows "(\<Inter>i\<in>I. F i) \<in> fmeasurable M"
  1704 proof (rule fmeasurableI2)
  1705   show "F i \<in> fmeasurable M" "(\<Inter>i\<in>I. F i) \<subseteq> F i"
  1706     using assms by auto
  1707   show "(\<Inter>i\<in>I. F i) \<in> sets M"
  1708     using assms by (intro sets.countable_INT') auto
  1709 qed
  1711 lemma measure_Un2:
  1712   "A \<in> fmeasurable M \<Longrightarrow> B \<in> fmeasurable M \<Longrightarrow> measure M (A \<union> B) = measure M A + measure M (B - A)"
  1713   using measure_Union[of M A "B - A"] by (auto simp: fmeasurableD2 fmeasurable.Diff)
  1715 lemma measure_Un3:
  1716   assumes "A \<in> fmeasurable M" "B \<in> fmeasurable M"
  1717   shows "measure M (A \<union> B) = measure M A + measure M B - measure M (A \<inter> B)"
  1718 proof -
  1719   have "measure M (A \<union> B) = measure M A + measure M (B - A)"
  1720     using assms by (rule measure_Un2)
  1721   also have "B - A = B - (A \<inter> B)"
  1722     by auto
  1723   also have "measure M (B - (A \<inter> B)) = measure M B - measure M (A \<inter> B)"
  1724     using assms by (intro measure_Diff) (auto simp: fmeasurable_def)
  1725   finally show ?thesis
  1726     by simp
  1727 qed
  1729 lemma measure_Un_AE:
  1730   "AE x in M. x \<notin> A \<or> x \<notin> B \<Longrightarrow> A \<in> fmeasurable M \<Longrightarrow> B \<in> fmeasurable M \<Longrightarrow>
  1731   measure M (A \<union> B) = measure M A + measure M B"
  1732   by (subst measure_Un2) (auto intro!: measure_eq_AE)
  1734 lemma measure_UNION_AE:
  1735   assumes I: "finite I"
  1736   shows "(\<And>i. i \<in> I \<Longrightarrow> F i \<in> fmeasurable M) \<Longrightarrow> pairwise (\<lambda>i j. AE x in M. x \<notin> F i \<or> x \<notin> F j) I \<Longrightarrow>
  1737     measure M (\<Union>i\<in>I. F i) = (\<Sum>i\<in>I. measure M (F i))"
  1738   unfolding AE_pairwise[OF countable_finite, OF I]
  1739   using I
  1740   apply (induction I rule: finite_induct)
  1741    apply simp
  1742   apply (simp add: pairwise_insert)
  1743   apply (subst measure_Un_AE)
  1744   apply auto
  1745   done
  1747 lemma measure_UNION':
  1748   "finite I \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> F i \<in> fmeasurable M) \<Longrightarrow> pairwise (\<lambda>i j. disjnt (F i) (F j)) I \<Longrightarrow>
  1749     measure M (\<Union>i\<in>I. F i) = (\<Sum>i\<in>I. measure M (F i))"
  1750   by (intro measure_UNION_AE) (auto simp: disjnt_def elim!: pairwise_mono intro!: always_eventually)
  1752 lemma measure_Union_AE:
  1753   "finite F \<Longrightarrow> (\<And>S. S \<in> F \<Longrightarrow> S \<in> fmeasurable M) \<Longrightarrow> pairwise (\<lambda>S T. AE x in M. x \<notin> S \<or> x \<notin> T) F \<Longrightarrow>
  1754     measure M (\<Union>F) = (\<Sum>S\<in>F. measure M S)"
  1755   using measure_UNION_AE[of F "\<lambda>x. x" M] by simp
  1757 lemma measure_Union':
  1758   "finite F \<Longrightarrow> (\<And>S. S \<in> F \<Longrightarrow> S \<in> fmeasurable M) \<Longrightarrow> pairwise disjnt F \<Longrightarrow> measure M (\<Union>F) = (\<Sum>S\<in>F. measure M S)"
  1759   using measure_UNION'[of F "\<lambda>x. x" M] by simp
  1761 lemma measure_Un_le:
  1762   assumes "A \<in> sets M" "B \<in> sets M" shows "measure M (A \<union> B) \<le> measure M A + measure M B"
  1763 proof cases
  1764   assume "A \<in> fmeasurable M \<and> B \<in> fmeasurable M"
  1765   with measure_subadditive[of A M B] assms show ?thesis
  1766     by (auto simp: fmeasurableD2)
  1767 next
  1768   assume "\<not> (A \<in> fmeasurable M \<and> B \<in> fmeasurable M)"
  1769   then have "A \<union> B \<notin> fmeasurable M"
  1770     using fmeasurableI2[of "A \<union> B" M A] fmeasurableI2[of "A \<union> B" M B] assms by auto
  1771   with assms show ?thesis
  1772     by (auto simp: fmeasurable_def measure_def less_top[symmetric])
  1773 qed
  1775 lemma measure_UNION_le:
  1776   "finite I \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> F i \<in> sets M) \<Longrightarrow> measure M (\<Union>i\<in>I. F i) \<le> (\<Sum>i\<in>I. measure M (F i))"
  1777 proof (induction I rule: finite_induct)
  1778   case (insert i I)
  1779   then have "measure M (\<Union>i\<in>insert i I. F i) \<le> measure M (F i) + measure M (\<Union>i\<in>I. F i)"
  1780     by (auto intro!: measure_Un_le)
  1781   also have "measure M (\<Union>i\<in>I. F i) \<le> (\<Sum>i\<in>I. measure M (F i))"
  1782     using insert by auto
  1783   finally show ?case
  1784     using insert by simp
  1785 qed simp
  1787 lemma measure_Union_le:
  1788   "finite F \<Longrightarrow> (\<And>S. S \<in> F \<Longrightarrow> S \<in> sets M) \<Longrightarrow> measure M (\<Union>F) \<le> (\<Sum>S\<in>F. measure M S)"
  1789   using measure_UNION_le[of F "\<lambda>x. x" M] by simp
  1791 lemma
  1792   assumes "countable I" and I: "\<And>i. i \<in> I \<Longrightarrow> A i \<in> fmeasurable M"
  1793     and bound: "\<And>I'. I' \<subseteq> I \<Longrightarrow> finite I' \<Longrightarrow> measure M (\<Union>i\<in>I'. A i) \<le> B" and "0 \<le> B"
  1794   shows fmeasurable_UN_bound: "(\<Union>i\<in>I. A i) \<in> fmeasurable M" (is ?fm)
  1795     and measure_UN_bound: "measure M (\<Union>i\<in>I. A i) \<le> B" (is ?m)
  1796 proof -
  1797   have "?fm \<and> ?m"
  1798   proof cases
  1799     assume "I = {}" with \<open>0 \<le> B\<close> show ?thesis by simp
  1800   next
  1801     assume "I \<noteq> {}"
  1802     have "(\<Union>i\<in>I. A i) = (\<Union>i. (\<Union>n\<le>i. A (from_nat_into I n)))"
  1803       by (subst range_from_nat_into[symmetric, OF \<open>I \<noteq> {}\<close> \<open>countable I\<close>]) auto
  1804     then have "emeasure M (\<Union>i\<in>I. A i) = emeasure M (\<Union>i. (\<Union>n\<le>i. A (from_nat_into I n)))" by simp
  1805     also have "\<dots> = (SUP i. emeasure M (\<Union>n\<le>i. A (from_nat_into I n)))"
  1806       using I \<open>I \<noteq> {}\<close>[THEN from_nat_into] by (intro SUP_emeasure_incseq[symmetric]) (fastforce simp: incseq_Suc_iff)+
  1807     also have "\<dots> \<le> B"
  1808     proof (intro SUP_least)
  1809       fix i :: nat
  1810       have "emeasure M (\<Union>n\<le>i. A (from_nat_into I n)) = measure M (\<Union>n\<le>i. A (from_nat_into I n))"
  1811         using I \<open>I \<noteq> {}\<close>[THEN from_nat_into] by (intro emeasure_eq_measure2 fmeasurable.finite_UN) auto
  1812       also have "\<dots> = measure M (\<Union>n\<in>from_nat_into I ` {..i}. A n)"
  1813         by simp
  1814       also have "\<dots> \<le> B"
  1815         by (intro ennreal_leI bound) (auto intro:  from_nat_into[OF \<open>I \<noteq> {}\<close>])
  1816       finally show "emeasure M (\<Union>n\<le>i. A (from_nat_into I n)) \<le> ennreal B" .
  1817     qed
  1818     finally have *: "emeasure M (\<Union>i\<in>I. A i) \<le> B" .
  1819     then have ?fm
  1820       using I \<open>countable I\<close> by (intro fmeasurableI conjI) (auto simp: less_top[symmetric] top_unique)
  1821     with * \<open>0\<le>B\<close> show ?thesis
  1822       by (simp add: emeasure_eq_measure2)
  1823   qed
  1824   then show ?fm ?m by auto
  1825 qed
  1827 subsection \<open>Measure spaces with @{term "emeasure M (space M) < \<infinity>"}\<close>
  1829 locale finite_measure = sigma_finite_measure M for M +
  1830   assumes finite_emeasure_space: "emeasure M (space M) \<noteq> top"
  1832 lemma finite_measureI[Pure.intro!]:
  1833   "emeasure M (space M) \<noteq> \<infinity> \<Longrightarrow> finite_measure M"
  1834   proof qed (auto intro!: exI[of _ "{space M}"])
  1836 lemma (in finite_measure) emeasure_finite[simp, intro]: "emeasure M A \<noteq> top"
  1837   using finite_emeasure_space emeasure_space[of M A] by (auto simp: top_unique)
  1839 lemma (in finite_measure) fmeasurable_eq_sets: "fmeasurable M = sets M"
  1840   by (auto simp: fmeasurable_def less_top[symmetric])
  1842 lemma (in finite_measure) emeasure_eq_measure: "emeasure M A = ennreal (measure M A)"
  1843   by (intro emeasure_eq_ennreal_measure) simp
  1845 lemma (in finite_measure) emeasure_real: "\<exists>r. 0 \<le> r \<and> emeasure M A = ennreal r"
  1846   using emeasure_finite[of A] by (cases "emeasure M A" rule: ennreal_cases) auto
  1848 lemma (in finite_measure) bounded_measure: "measure M A \<le> measure M (space M)"
  1849   using emeasure_space[of M A] emeasure_real[of A] emeasure_real[of "space M"] by (auto simp: measure_def)
  1851 lemma (in finite_measure) finite_measure_Diff:
  1852   assumes sets: "A \<in> sets M" "B \<in> sets M" and "B \<subseteq> A"
  1853   shows "measure M (A - B) = measure M A - measure M B"
  1854   using measure_Diff[OF _ assms] by simp
  1856 lemma (in finite_measure) finite_measure_Union:
  1857   assumes sets: "A \<in> sets M" "B \<in> sets M" and "A \<inter> B = {}"
  1858   shows "measure M (A \<union> B) = measure M A + measure M B"
  1859   using measure_Union[OF _ _ assms] by simp
  1861 lemma (in finite_measure) finite_measure_finite_Union:
  1862   assumes measurable: "finite S" "A`S \<subseteq> sets M" "disjoint_family_on A S"
  1863   shows "measure M (\<Union>i\<in>S. A i) = (\<Sum>i\<in>S. measure M (A i))"
  1864   using measure_finite_Union[OF assms] by simp
  1866 lemma (in finite_measure) finite_measure_UNION:
  1867   assumes A: "range A \<subseteq> sets M" "disjoint_family A"
  1868   shows "(\<lambda>i. measure M (A i)) sums (measure M (\<Union>i. A i))"
  1869   using measure_UNION[OF A] by simp
  1871 lemma (in finite_measure) finite_measure_mono:
  1872   assumes "A \<subseteq> B" "B \<in> sets M" shows "measure M A \<le> measure M B"
  1873   using emeasure_mono[OF assms] emeasure_real[of A] emeasure_real[of B] by (auto simp: measure_def)
  1875 lemma (in finite_measure) finite_measure_subadditive:
  1876   assumes m: "A \<in> sets M" "B \<in> sets M"
  1877   shows "measure M (A \<union> B) \<le> measure M A + measure M B"
  1878   using measure_subadditive[OF m] by simp
  1880 lemma (in finite_measure) finite_measure_subadditive_finite:
  1881   assumes "finite I" "A`I \<subseteq> sets M" shows "measure M (\<Union>i\<in>I. A i) \<le> (\<Sum>i\<in>I. measure M (A i))"
  1882   using measure_subadditive_finite[OF assms] by simp
  1884 lemma (in finite_measure) finite_measure_subadditive_countably:
  1885   "range A \<subseteq> sets M \<Longrightarrow> summable (\<lambda>i. measure M (A i)) \<Longrightarrow> measure M (\<Union>i. A i) \<le> (\<Sum>i. measure M (A i))"
  1886   by (rule measure_subadditive_countably)
  1887      (simp_all add: ennreal_suminf_neq_top emeasure_eq_measure)
  1889 lemma (in finite_measure) finite_measure_eq_sum_singleton:
  1890   assumes "finite S" and *: "\<And>x. x \<in> S \<Longrightarrow> {x} \<in> sets M"
  1891   shows "measure M S = (\<Sum>x\<in>S. measure M {x})"
  1892   using measure_eq_sum_singleton[OF assms] by simp
  1894 lemma (in finite_measure) finite_Lim_measure_incseq:
  1895   assumes A: "range A \<subseteq> sets M" "incseq A"
  1896   shows "(\<lambda>i. measure M (A i)) \<longlonglongrightarrow> measure M (\<Union>i. A i)"
  1897   using Lim_measure_incseq[OF A] by simp
  1899 lemma (in finite_measure) finite_Lim_measure_decseq:
  1900   assumes A: "range A \<subseteq> sets M" "decseq A"
  1901   shows "(\<lambda>n. measure M (A n)) \<longlonglongrightarrow> measure M (\<Inter>i. A i)"
  1902   using Lim_measure_decseq[OF A] by simp
  1904 lemma (in finite_measure) finite_measure_compl:
  1905   assumes S: "S \<in> sets M"
  1906   shows "measure M (space M - S) = measure M (space M) - measure M S"
  1907   using measure_Diff[OF _ S sets.sets_into_space] S by simp
  1909 lemma (in finite_measure) finite_measure_mono_AE:
  1910   assumes imp: "AE x in M. x \<in> A \<longrightarrow> x \<in> B" and B: "B \<in> sets M"
  1911   shows "measure M A \<le> measure M B"
  1912   using assms emeasure_mono_AE[OF imp B]
  1913   by (simp add: emeasure_eq_measure)
  1915 lemma (in finite_measure) finite_measure_eq_AE:
  1916   assumes iff: "AE x in M. x \<in> A \<longleftrightarrow> x \<in> B"
  1917   assumes A: "A \<in> sets M" and B: "B \<in> sets M"
  1918   shows "measure M A = measure M B"
  1919   using assms emeasure_eq_AE[OF assms] by (simp add: emeasure_eq_measure)
  1921 lemma (in finite_measure) measure_increasing: "increasing M (measure M)"
  1922   by (auto intro!: finite_measure_mono simp: increasing_def)
  1924 lemma (in finite_measure) measure_zero_union:
  1925   assumes "s \<in> sets M" "t \<in> sets M" "measure M t = 0"
  1926   shows "measure M (s \<union> t) = measure M s"
  1927 using assms
  1928 proof -
  1929   have "measure M (s \<union> t) \<le> measure M s"
  1930     using finite_measure_subadditive[of s t] assms by auto
  1931   moreover have "measure M (s \<union> t) \<ge> measure M s"
  1932     using assms by (blast intro: finite_measure_mono)
  1933   ultimately show ?thesis by simp
  1934 qed
  1936 lemma (in finite_measure) measure_eq_compl:
  1937   assumes "s \<in> sets M" "t \<in> sets M"
  1938   assumes "measure M (space M - s) = measure M (space M - t)"
  1939   shows "measure M s = measure M t"
  1940   using assms finite_measure_compl by auto
  1942 lemma (in finite_measure) measure_eq_bigunion_image:
  1943   assumes "range f \<subseteq> sets M" "range g \<subseteq> sets M"
  1944   assumes "disjoint_family f" "disjoint_family g"
  1945   assumes "\<And> n :: nat. measure M (f n) = measure M (g n)"
  1946   shows "measure M (\<Union>i. f i) = measure M (\<Union>i. g i)"
  1947 using assms
  1948 proof -
  1949   have a: "(\<lambda> i. measure M (f i)) sums (measure M (\<Union>i. f i))"
  1950     by (rule finite_measure_UNION[OF assms(1,3)])
  1951   have b: "(\<lambda> i. measure M (g i)) sums (measure M (\<Union>i. g i))"
  1952     by (rule finite_measure_UNION[OF assms(2,4)])
  1953   show ?thesis using sums_unique[OF b] sums_unique[OF a] assms by simp
  1954 qed
  1956 lemma (in finite_measure) measure_countably_zero:
  1957   assumes "range c \<subseteq> sets M"
  1958   assumes "\<And> i. measure M (c i) = 0"
  1959   shows "measure M (\<Union>i :: nat. c i) = 0"
  1960 proof (rule antisym)
  1961   show "measure M (\<Union>i :: nat. c i) \<le> 0"
  1962     using finite_measure_subadditive_countably[OF assms(1)] by (simp add: assms(2))
  1963 qed simp
  1965 lemma (in finite_measure) measure_space_inter:
  1966   assumes events:"s \<in> sets M" "t \<in> sets M"
  1967   assumes "measure M t = measure M (space M)"
  1968   shows "measure M (s \<inter> t) = measure M s"
  1969 proof -
  1970   have "measure M ((space M - s) \<union> (space M - t)) = measure M (space M - s)"
  1971     using events assms finite_measure_compl[of "t"] by (auto intro!: measure_zero_union)
  1972   also have "(space M - s) \<union> (space M - t) = space M - (s \<inter> t)"
  1973     by blast
  1974   finally show "measure M (s \<inter> t) = measure M s"
  1975     using events by (auto intro!: measure_eq_compl[of "s \<inter> t" s])
  1976 qed
  1978 lemma (in finite_measure) measure_equiprobable_finite_unions:
  1979   assumes s: "finite s" "\<And>x. x \<in> s \<Longrightarrow> {x} \<in> sets M"
  1980   assumes "\<And> x y. \<lbrakk>x \<in> s; y \<in> s\<rbrakk> \<Longrightarrow> measure M {x} = measure M {y}"
  1981   shows "measure M s = real (card s) * measure M {SOME x. x \<in> s}"
  1982 proof cases
  1983   assume "s \<noteq> {}"
  1984   then have "\<exists> x. x \<in> s" by blast
  1985   from someI_ex[OF this] assms
  1986   have prob_some: "\<And> x. x \<in> s \<Longrightarrow> measure M {x} = measure M {SOME y. y \<in> s}" by blast
  1987   have "measure M s = (\<Sum> x \<in> s. measure M {x})"
  1988     using finite_measure_eq_sum_singleton[OF s] by simp
  1989   also have "\<dots> = (\<Sum> x \<in> s. measure M {SOME y. y \<in> s})" using prob_some by auto
  1990   also have "\<dots> = real (card s) * measure M {(SOME x. x \<in> s)}"
  1991     using sum_constant assms by simp
  1992   finally show ?thesis by simp
  1993 qed simp
  1995 lemma (in finite_measure) measure_real_sum_image_fn:
  1996   assumes "e \<in> sets M"
  1997   assumes "\<And> x. x \<in> s \<Longrightarrow> e \<inter> f x \<in> sets M"
  1998   assumes "finite s"
  1999   assumes disjoint: "\<And> x y. \<lbrakk>x \<in> s ; y \<in> s ; x \<noteq> y\<rbrakk> \<Longrightarrow> f x \<inter> f y = {}"
  2000   assumes upper: "space M \<subseteq> (\<Union>i \<in> s. f i)"
  2001   shows "measure M e = (\<Sum> x \<in> s. measure M (e \<inter> f x))"
  2002 proof -
  2003   have "e \<subseteq> (\<Union>i\<in>s. f i)"
  2004     using \<open>e \<in> sets M\<close> sets.sets_into_space upper by blast
  2005   then have e: "e = (\<Union>i \<in> s. e \<inter> f i)"
  2006     by auto
  2007   hence "measure M e = measure M (\<Union>i \<in> s. e \<inter> f i)" by simp
  2008   also have "\<dots> = (\<Sum> x \<in> s. measure M (e \<inter> f x))"
  2009   proof (rule finite_measure_finite_Union)
  2010     show "finite s" by fact
  2011     show "(\<lambda>i. e \<inter> f i)`s \<subseteq> sets M" using assms(2) by auto
  2012     show "disjoint_family_on (\<lambda>i. e \<inter> f i) s"
  2013       using disjoint by (auto simp: disjoint_family_on_def)
  2014   qed
  2015   finally show ?thesis .
  2016 qed
  2018 lemma (in finite_measure) measure_exclude:
  2019   assumes "A \<in> sets M" "B \<in> sets M"
  2020   assumes "measure M A = measure M (space M)" "A \<inter> B = {}"
  2021   shows "measure M B = 0"
  2022   using measure_space_inter[of B A] assms by (auto simp: ac_simps)
  2023 lemma (in finite_measure) finite_measure_distr:
  2024   assumes f: "f \<in> measurable M M'"
  2025   shows "finite_measure (distr M M' f)"
  2026 proof (rule finite_measureI)
  2027   have "f -` space M' \<inter> space M = space M" using f by (auto dest: measurable_space)
  2028   with f show "emeasure (distr M M' f) (space (distr M M' f)) \<noteq> \<infinity>" by (auto simp: emeasure_distr)
  2029 qed
  2031 lemma emeasure_gfp[consumes 1, case_names cont measurable]:
  2032   assumes sets[simp]: "\<And>s. sets (M s) = sets N"
  2033   assumes "\<And>s. finite_measure (M s)"
  2034   assumes cont: "inf_continuous F" "inf_continuous f"
  2035   assumes meas: "\<And>P. Measurable.pred N P \<Longrightarrow> Measurable.pred N (F P)"
  2036   assumes iter: "\<And>P s. Measurable.pred N P \<Longrightarrow> emeasure (M s) {x\<in>space N. F P x} = f (\<lambda>s. emeasure (M s) {x\<in>space N. P x}) s"
  2037   assumes bound: "\<And>P. f P \<le> f (\<lambda>s. emeasure (M s) (space (M s)))"
  2038   shows "emeasure (M s) {x\<in>space N. gfp F x} = gfp f s"
  2039 proof (subst gfp_transfer_bounded[where \<alpha>="\<lambda>F s. emeasure (M s) {x\<in>space N. F x}" and g=f and f=F and
  2040     P="Measurable.pred N", symmetric])
  2041   interpret finite_measure "M s" for s by fact
  2042   fix C assume "decseq C" "\<And>i. Measurable.pred N (C i)"
  2043   then show "(\<lambda>s. emeasure (M s) {x \<in> space N. (INF i. C i) x}) = (INF i. (\<lambda>s. emeasure (M s) {x \<in> space N. C i x}))"
  2044     unfolding INF_apply[abs_def]
  2045     by (subst INF_emeasure_decseq) (auto simp: antimono_def fun_eq_iff intro!: arg_cong2[where f=emeasure])
  2046 next
  2047   show "f x \<le> (\<lambda>s. emeasure (M s) {x \<in> space N. F top x})" for x
  2048     using bound[of x] sets_eq_imp_space_eq[OF sets] by (simp add: iter)
  2049 qed (auto simp add: iter le_fun_def INF_apply[abs_def] intro!: meas cont)
  2051 subsection \<open>Counting space\<close>
  2053 lemma strict_monoI_Suc:
  2054   assumes ord [simp]: "(\<And>n. f n < f (Suc n))" shows "strict_mono f"
  2055   unfolding strict_mono_def
  2056 proof safe
  2057   fix n m :: nat assume "n < m" then show "f n < f m"
  2058     by (induct m) (auto simp: less_Suc_eq intro: less_trans ord)
  2059 qed
  2061 lemma emeasure_count_space:
  2062   assumes "X \<subseteq> A" shows "emeasure (count_space A) X = (if finite X then of_nat (card X) else \<infinity>)"
  2063     (is "_ = ?M X")
  2064   unfolding count_space_def
  2065 proof (rule emeasure_measure_of_sigma)
  2066   show "X \<in> Pow A" using \<open>X \<subseteq> A\<close> by auto
  2067   show "sigma_algebra A (Pow A)" by (rule sigma_algebra_Pow)
  2068   show positive: "positive (Pow A) ?M"
  2069     by (auto simp: positive_def)
  2070   have additive: "additive (Pow A) ?M"
  2071     by (auto simp: card_Un_disjoint additive_def)
  2073   interpret ring_of_sets A "Pow A"
  2074     by (rule ring_of_setsI) auto
  2075   show "countably_additive (Pow A) ?M"
  2076     unfolding countably_additive_iff_continuous_from_below[OF positive additive]
  2077   proof safe
  2078     fix F :: "nat \<Rightarrow> 'a set" assume "incseq F"
  2079     show "(\<lambda>i. ?M (F i)) \<longlonglongrightarrow> ?M (\<Union>i. F i)"
  2080     proof cases
  2081       assume "\<exists>i. \<forall>j\<ge>i. F i = F j"
  2082       then guess i .. note i = this
  2083       { fix j from i \<open>incseq F\<close> have "F j \<subseteq> F i"
  2084           by (cases "i \<le> j") (auto simp: incseq_def) }
  2085       then have eq: "(\<Union>i. F i) = F i"
  2086         by auto
  2087       with i show ?thesis
  2088         by (auto intro!: Lim_transform_eventually[OF _ tendsto_const] eventually_sequentiallyI[where c=i])
  2089     next
  2090       assume "\<not> (\<exists>i. \<forall>j\<ge>i. F i = F j)"
  2091       then obtain f where f: "\<And>i. i \<le> f i" "\<And>i. F i \<noteq> F (f i)" by metis
  2092       then have "\<And>i. F i \<subseteq> F (f i)" using \<open>incseq F\<close> by (auto simp: incseq_def)
  2093       with f have *: "\<And>i. F i \<subset> F (f i)" by auto
  2095       have "incseq (\<lambda>i. ?M (F i))"
  2096         using \<open>incseq F\<close> unfolding incseq_def by (auto simp: card_mono dest: finite_subset)
  2097       then have "(\<lambda>i. ?M (F i)) \<longlonglongrightarrow> (SUP n. ?M (F n))"
  2098         by (rule LIMSEQ_SUP)
  2100       moreover have "(SUP n. ?M (F n)) = top"
  2101       proof (rule ennreal_SUP_eq_top)
  2102         fix n :: nat show "\<exists>k::nat\<in>UNIV. of_nat n \<le> ?M (F k)"
  2103         proof (induct n)
  2104           case (Suc n)
  2105           then guess k .. note k = this
  2106           moreover have "finite (F k) \<Longrightarrow> finite (F (f k)) \<Longrightarrow> card (F k) < card (F (f k))"
  2107             using \<open>F k \<subset> F (f k)\<close> by (simp add: psubset_card_mono)
  2108           moreover have "finite (F (f k)) \<Longrightarrow> finite (F k)"
  2109             using \<open>k \<le> f k\<close> \<open>incseq F\<close> by (auto simp: incseq_def dest: finite_subset)
  2110           ultimately show ?case
  2111             by (auto intro!: exI[of _ "f k"] simp del: of_nat_Suc)
  2112         qed auto
  2113       qed
  2115       moreover
  2116       have "inj (\<lambda>n. F ((f ^^ n) 0))"
  2117         by (intro strict_mono_imp_inj_on strict_monoI_Suc) (simp add: *)
  2118       then have 1: "infinite (range (\<lambda>i. F ((f ^^ i) 0)))"
  2119         by (rule range_inj_infinite)
  2120       have "infinite (Pow (\<Union>i. F i))"
  2121         by (rule infinite_super[OF _ 1]) auto
  2122       then have "infinite (\<Union>i. F i)"
  2123         by auto
  2125       ultimately show ?thesis by auto
  2126     qed
  2127   qed
  2128 qed
  2130 lemma distr_bij_count_space:
  2131   assumes f: "bij_betw f A B"
  2132   shows "distr (count_space A) (count_space B) f = count_space B"
  2133 proof (rule measure_eqI)
  2134   have f': "f \<in> measurable (count_space A) (count_space B)"
  2135     using f unfolding Pi_def bij_betw_def by auto
  2136   fix X assume "X \<in> sets (distr (count_space A) (count_space B) f)"
  2137   then have X: "X \<in> sets (count_space B)" by auto
  2138   moreover from X have "f -` X \<inter> A = the_inv_into A f ` X"
  2139     using f by (auto simp: bij_betw_def subset_image_iff image_iff the_inv_into_f_f intro: the_inv_into_f_f[symmetric])
  2140   moreover have "inj_on (the_inv_into A f) B"
  2141     using X f by (auto simp: bij_betw_def inj_on_the_inv_into)
  2142   with X have "inj_on (the_inv_into A f) X"
  2143     by (auto intro: subset_inj_on)
  2144   ultimately show "emeasure (distr (count_space A) (count_space B) f) X = emeasure (count_space B) X"
  2145     using f unfolding emeasure_distr[OF f' X]
  2146     by (subst (1 2) emeasure_count_space) (auto simp: card_image dest: finite_imageD)
  2147 qed simp
  2149 lemma emeasure_count_space_finite[simp]:
  2150   "X \<subseteq> A \<Longrightarrow> finite X \<Longrightarrow> emeasure (count_space A) X = of_nat (card X)"
  2151   using emeasure_count_space[of X A] by simp
  2153 lemma emeasure_count_space_infinite[simp]:
  2154   "X \<subseteq> A \<Longrightarrow> infinite X \<Longrightarrow> emeasure (count_space A) X = \<infinity>"
  2155   using emeasure_count_space[of X A] by simp
  2157 lemma measure_count_space: "measure (count_space A) X = (if X \<subseteq> A then of_nat (card X) else 0)"
  2158   by (cases "finite X") (auto simp: measure_notin_sets ennreal_of_nat_eq_real_of_nat
  2159                                     measure_zero_top measure_eq_emeasure_eq_ennreal)
  2161 lemma emeasure_count_space_eq_0:
  2162   "emeasure (count_space A) X = 0 \<longleftrightarrow> (X \<subseteq> A \<longrightarrow> X = {})"
  2163 proof cases
  2164   assume X: "X \<subseteq> A"
  2165   then show ?thesis
  2166   proof (intro iffI impI)
  2167     assume "emeasure (count_space A) X = 0"
  2168     with X show "X = {}"
  2169       by (subst (asm) emeasure_count_space) (auto split: if_split_asm)
  2170   qed simp
  2171 qed (simp add: emeasure_notin_sets)
  2173 lemma null_sets_count_space: "null_sets (count_space A) = { {} }"
  2174   unfolding null_sets_def by (auto simp add: emeasure_count_space_eq_0)
  2176 lemma AE_count_space: "(AE x in count_space A. P x) \<longleftrightarrow> (\<forall>x\<in>A. P x)"
  2177   unfolding eventually_ae_filter by (auto simp add: null_sets_count_space)
  2179 lemma sigma_finite_measure_count_space_countable:
  2180   assumes A: "countable A"
  2181   shows "sigma_finite_measure (count_space A)"
  2182   proof qed (insert A, auto intro!: exI[of _ "(\<lambda>a. {a}) ` A"])
  2184 lemma sigma_finite_measure_count_space:
  2185   fixes A :: "'a::countable set" shows "sigma_finite_measure (count_space A)"
  2186   by (rule sigma_finite_measure_count_space_countable) auto
  2188 lemma finite_measure_count_space:
  2189   assumes [simp]: "finite A"
  2190   shows "finite_measure (count_space A)"
  2191   by rule simp
  2193 lemma sigma_finite_measure_count_space_finite:
  2194   assumes A: "finite A" shows "sigma_finite_measure (count_space A)"
  2195 proof -
  2196   interpret finite_measure "count_space A" using A by (rule finite_measure_count_space)
  2197   show "sigma_finite_measure (count_space A)" ..
  2198 qed
  2200 subsection \<open>Measure restricted to space\<close>
  2202 lemma emeasure_restrict_space:
  2203   assumes "\<Omega> \<inter> space M \<in> sets M" "A \<subseteq> \<Omega>"
  2204   shows "emeasure (restrict_space M \<Omega>) A = emeasure M A"
  2205 proof (cases "A \<in> sets M")
  2206   case True
  2207   show ?thesis
  2208   proof (rule emeasure_measure_of[OF restrict_space_def])
  2209     show "op \<inter> \<Omega> ` sets M \<subseteq> Pow (\<Omega> \<inter> space M)" "A \<in> sets (restrict_space M \<Omega>)"
  2210       using \<open>A \<subseteq> \<Omega>\<close> \<open>A \<in> sets M\<close> sets.space_closed by (auto simp: sets_restrict_space)
  2211     show "positive (sets (restrict_space M \<Omega>)) (emeasure M)"
  2212       by (auto simp: positive_def)
  2213     show "countably_additive (sets (restrict_space M \<Omega>)) (emeasure M)"
  2214     proof (rule countably_additiveI)
  2215       fix A :: "nat \<Rightarrow> _" assume "range A \<subseteq> sets (restrict_space M \<Omega>)" "disjoint_family A"
  2216       with assms have "\<And>i. A i \<in> sets M" "\<And>i. A i \<subseteq> space M" "disjoint_family A"
  2217         by (fastforce simp: sets_restrict_space_iff[OF assms(1)] image_subset_iff
  2218                       dest: sets.sets_into_space)+
  2219       then show "(\<Sum>i. emeasure M (A i)) = emeasure M (\<Union>i. A i)"
  2220         by (subst suminf_emeasure) (auto simp: disjoint_family_subset)
  2221     qed
  2222   qed
  2223 next
  2224   case False
  2225   with assms have "A \<notin> sets (restrict_space M \<Omega>)"
  2226     by (simp add: sets_restrict_space_iff)
  2227   with False show ?thesis
  2228     by (simp add: emeasure_notin_sets)
  2229 qed
  2231 lemma measure_restrict_space:
  2232   assumes "\<Omega> \<inter> space M \<in> sets M" "A \<subseteq> \<Omega>"
  2233   shows "measure (restrict_space M \<Omega>) A = measure M A"
  2234   using emeasure_restrict_space[OF assms] by (simp add: measure_def)
  2236 lemma AE_restrict_space_iff:
  2237   assumes "\<Omega> \<inter> space M \<in> sets M"
  2238   shows "(AE x in restrict_space M \<Omega>. P x) \<longleftrightarrow> (AE x in M. x \<in> \<Omega> \<longrightarrow> P x)"
  2239 proof -
  2240   have ex_cong: "\<And>P Q f. (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> (\<And>x. Q x \<Longrightarrow> P (f x)) \<Longrightarrow> (\<exists>x. P x) \<longleftrightarrow> (\<exists>x. Q x)"
  2241     by auto
  2242   { fix X assume X: "X \<in> sets M" "emeasure M X = 0"
  2243     then have "emeasure M (\<Omega> \<inter> space M \<inter> X) \<le> emeasure M X"
  2244       by (intro emeasure_mono) auto
  2245     then have "emeasure M (\<Omega> \<inter> space M \<inter> X) = 0"
  2246       using X by (auto intro!: antisym) }
  2247   with assms show ?thesis
  2248     unfolding eventually_ae_filter
  2249     by (auto simp add: space_restrict_space null_sets_def sets_restrict_space_iff
  2250                        emeasure_restrict_space cong: conj_cong
  2251              intro!: ex_cong[where f="\<lambda>X. (\<Omega> \<inter> space M) \<inter> X"])
  2252 qed
  2254 lemma restrict_restrict_space:
  2255   assumes "A \<inter> space M \<in> sets M" "B \<inter> space M \<in> sets M"
  2256   shows "restrict_space (restrict_space M A) B = restrict_space M (A \<inter> B)" (is "?l = ?r")
  2257 proof (rule measure_eqI[symmetric])
  2258   show "sets ?r = sets ?l"
  2259     unfolding sets_restrict_space image_comp by (intro image_cong) auto
  2260 next
  2261   fix X assume "X \<in> sets (restrict_space M (A \<inter> B))"
  2262   then obtain Y where "Y \<in> sets M" "X = Y \<inter> A \<inter> B"
  2263     by (auto simp: sets_restrict_space)
  2264   with assms sets.Int[OF assms] show "emeasure ?r X = emeasure ?l X"
  2265     by (subst (1 2) emeasure_restrict_space)
  2266        (auto simp: space_restrict_space sets_restrict_space_iff emeasure_restrict_space ac_simps)
  2267 qed
  2269 lemma restrict_count_space: "restrict_space (count_space B) A = count_space (A \<inter> B)"
  2270 proof (rule measure_eqI)
  2271   show "sets (restrict_space (count_space B) A) = sets (count_space (A \<inter> B))"
  2272     by (subst sets_restrict_space) auto
  2273   moreover fix X assume "X \<in> sets (restrict_space (count_space B) A)"
  2274   ultimately have "X \<subseteq> A \<inter> B" by auto
  2275   then show "emeasure (restrict_space (count_space B) A) X = emeasure (count_space (A \<inter> B)) X"
  2276     by (cases "finite X") (auto simp add: emeasure_restrict_space)
  2277 qed
  2279 lemma sigma_finite_measure_restrict_space:
  2280   assumes "sigma_finite_measure M"
  2281   and A: "A \<in> sets M"
  2282   shows "sigma_finite_measure (restrict_space M A)"
  2283 proof -
  2284   interpret sigma_finite_measure M by fact
  2285   from sigma_finite_countable obtain C
  2286     where C: "countable C" "C \<subseteq> sets M" "(\<Union>C) = space M" "\<forall>a\<in>C. emeasure M a \<noteq> \<infinity>"
  2287     by blast
  2288   let ?C = "op \<inter> A ` C"
  2289   from C have "countable ?C" "?C \<subseteq> sets (restrict_space M A)" "(\<Union>?C) = space (restrict_space M A)"
  2290     by(auto simp add: sets_restrict_space space_restrict_space)
  2291   moreover {
  2292     fix a
  2293     assume "a \<in> ?C"
  2294     then obtain a' where "a = A \<inter> a'" "a' \<in> C" ..
  2295     then have "emeasure (restrict_space M A) a \<le> emeasure M a'"
  2296       using A C by(auto simp add: emeasure_restrict_space intro: emeasure_mono)
  2297     also have "\<dots> < \<infinity>" using C(4)[rule_format, of a'] \<open>a' \<in> C\<close> by (simp add: less_top)
  2298     finally have "emeasure (restrict_space M A) a \<noteq> \<infinity>" by simp }
  2299   ultimately show ?thesis
  2300     by unfold_locales (rule exI conjI|assumption|blast)+
  2301 qed
  2303 lemma finite_measure_restrict_space:
  2304   assumes "finite_measure M"
  2305   and A: "A \<in> sets M"
  2306   shows "finite_measure (restrict_space M A)"
  2307 proof -
  2308   interpret finite_measure M by fact
  2309   show ?thesis
  2310     by(rule finite_measureI)(simp add: emeasure_restrict_space A space_restrict_space)
  2311 qed
  2313 lemma restrict_distr:
  2314   assumes [measurable]: "f \<in> measurable M N"
  2315   assumes [simp]: "\<Omega> \<inter> space N \<in> sets N" and restrict: "f \<in> space M \<rightarrow> \<Omega>"
  2316   shows "restrict_space (distr M N f) \<Omega> = distr M (restrict_space N \<Omega>) f"
  2317   (is "?l = ?r")
  2318 proof (rule measure_eqI)
  2319   fix A assume "A \<in> sets (restrict_space (distr M N f) \<Omega>)"
  2320   with restrict show "emeasure ?l A = emeasure ?r A"
  2321     by (subst emeasure_distr)
  2322        (auto simp: sets_restrict_space_iff emeasure_restrict_space emeasure_distr
  2323              intro!: measurable_restrict_space2)
  2324 qed (simp add: sets_restrict_space)
  2326 lemma measure_eqI_restrict_generator:
  2327   assumes E: "Int_stable E" "E \<subseteq> Pow \<Omega>" "\<And>X. X \<in> E \<Longrightarrow> emeasure M X = emeasure N X"
  2328   assumes sets_eq: "sets M = sets N" and \<Omega>: "\<Omega> \<in> sets M"
  2329   assumes "sets (restrict_space M \<Omega>) = sigma_sets \<Omega> E"
  2330   assumes "sets (restrict_space N \<Omega>) = sigma_sets \<Omega> E"
  2331   assumes ae: "AE x in M. x \<in> \<Omega>" "AE x in N. x \<in> \<Omega>"
  2332   assumes A: "countable A" "A \<noteq> {}" "A \<subseteq> E" "\<Union>A = \<Omega>" "\<And>a. a \<in> A \<Longrightarrow> emeasure M a \<noteq> \<infinity>"
  2333   shows "M = N"
  2334 proof (rule measure_eqI)
  2335   fix X assume X: "X \<in> sets M"
  2336   then have "emeasure M X = emeasure (restrict_space M \<Omega>) (X \<inter> \<Omega>)"
  2337     using ae \<Omega> by (auto simp add: emeasure_restrict_space intro!: emeasure_eq_AE)
  2338   also have "restrict_space M \<Omega> = restrict_space N \<Omega>"
  2339   proof (rule measure_eqI_generator_eq)
  2340     fix X assume "X \<in> E"
  2341     then show "emeasure (restrict_space M \<Omega>) X = emeasure (restrict_space N \<Omega>) X"
  2342       using E \<Omega> by (subst (1 2) emeasure_restrict_space) (auto simp: sets_eq sets_eq[THEN sets_eq_imp_space_eq])
  2343   next
  2344     show "range (from_nat_into A) \<subseteq> E" "(\<Union>i. from_nat_into A i) = \<Omega>"
  2345       using A by (auto cong del: strong_SUP_cong)
  2346   next
  2347     fix i
  2348     have "emeasure (restrict_space M \<Omega>) (from_nat_into A i) = emeasure M (from_nat_into A i)"
  2349       using A \<Omega> by (subst emeasure_restrict_space)
  2350                    (auto simp: sets_eq sets_eq[THEN sets_eq_imp_space_eq] intro: from_nat_into)
  2351     with A show "emeasure (restrict_space M \<Omega>) (from_nat_into A i) \<noteq> \<infinity>"
  2352       by (auto intro: from_nat_into)
  2353   qed fact+
  2354   also have "emeasure (restrict_space N \<Omega>) (X \<inter> \<Omega>) = emeasure N X"
  2355     using X ae \<Omega> by (auto simp add: emeasure_restrict_space sets_eq intro!: emeasure_eq_AE)
  2356   finally show "emeasure M X = emeasure N X" .
  2357 qed fact
  2359 subsection \<open>Null measure\<close>
  2361 definition "null_measure M = sigma (space M) (sets M)"
  2363 lemma space_null_measure[simp]: "space (null_measure M) = space M"
  2364   by (simp add: null_measure_def)
  2366 lemma sets_null_measure[simp, measurable_cong]: "sets (null_measure M) = sets M"
  2367   by (simp add: null_measure_def)
  2369 lemma emeasure_null_measure[simp]: "emeasure (null_measure M) X = 0"
  2370   by (cases "X \<in> sets M", rule emeasure_measure_of)
  2371      (auto simp: positive_def countably_additive_def emeasure_notin_sets null_measure_def
  2372            dest: sets.sets_into_space)
  2374 lemma measure_null_measure[simp]: "measure (null_measure M) X = 0"
  2375   by (intro measure_eq_emeasure_eq_ennreal) auto
  2377 lemma null_measure_idem [simp]: "null_measure (null_measure M) = null_measure M"
  2378   by(rule measure_eqI) simp_all
  2380 subsection \<open>Scaling a measure\<close>
  2382 definition scale_measure :: "ennreal \<Rightarrow> 'a measure \<Rightarrow> 'a measure"
  2383 where
  2384   "scale_measure r M = measure_of (space M) (sets M) (\<lambda>A. r * emeasure M A)"
  2386 lemma space_scale_measure: "space (scale_measure r M) = space M"
  2387   by (simp add: scale_measure_def)
  2389 lemma sets_scale_measure [simp, measurable_cong]: "sets (scale_measure r M) = sets M"
  2390   by (simp add: scale_measure_def)
  2392 lemma emeasure_scale_measure [simp]:
  2393   "emeasure (scale_measure r M) A = r * emeasure M A"
  2394   (is "_ = ?\<mu> A")
  2395 proof(cases "A \<in> sets M")
  2396   case True
  2397   show ?thesis unfolding scale_measure_def
  2398   proof(rule emeasure_measure_of_sigma)
  2399     show "sigma_algebra (space M) (sets M)" ..
  2400     show "positive (sets M) ?\<mu>" by (simp add: positive_def)
  2401     show "countably_additive (sets M) ?\<mu>"
  2402     proof (rule countably_additiveI)
  2403       fix A :: "nat \<Rightarrow> _"  assume *: "range A \<subseteq> sets M" "disjoint_family A"
  2404       have "(\<Sum>i. ?\<mu> (A i)) = r * (\<Sum>i. emeasure M (A i))"
  2405         by simp
  2406       also have "\<dots> = ?\<mu> (\<Union>i. A i)" using * by(simp add: suminf_emeasure)
  2407       finally show "(\<Sum>i. ?\<mu> (A i)) = ?\<mu> (\<Union>i. A i)" .
  2408     qed
  2409   qed(fact True)
  2410 qed(simp add: emeasure_notin_sets)
  2412 lemma scale_measure_1 [simp]: "scale_measure 1 M = M"
  2413   by(rule measure_eqI) simp_all
  2415 lemma scale_measure_0[simp]: "scale_measure 0 M = null_measure M"
  2416   by(rule measure_eqI) simp_all
  2418 lemma measure_scale_measure [simp]: "0 \<le> r \<Longrightarrow> measure (scale_measure r M) A = r * measure M A"
  2419   using emeasure_scale_measure[of r M A]
  2420     emeasure_eq_ennreal_measure[of M A]
  2421     measure_eq_emeasure_eq_ennreal[of _ "scale_measure r M" A]
  2422   by (cases "emeasure (scale_measure r M) A = top")
  2423      (auto simp del: emeasure_scale_measure
  2424            simp: ennreal_top_eq_mult_iff ennreal_mult_eq_top_iff measure_zero_top ennreal_mult[symmetric])
  2426 lemma scale_scale_measure [simp]:
  2427   "scale_measure r (scale_measure r' M) = scale_measure (r * r') M"
  2428   by (rule measure_eqI) (simp_all add: max_def mult.assoc)
  2430 lemma scale_null_measure [simp]: "scale_measure r (null_measure M) = null_measure M"
  2431   by (rule measure_eqI) simp_all
  2434 subsection \<open>Complete lattice structure on measures\<close>
  2436 lemma (in finite_measure) finite_measure_Diff':
  2437   "A \<in> sets M \<Longrightarrow> B \<in> sets M \<Longrightarrow> measure M (A - B) = measure M A - measure M (A \<inter> B)"
  2438   using finite_measure_Diff[of A "A \<inter> B"] by (auto simp: Diff_Int)
  2440 lemma (in finite_measure) finite_measure_Union':
  2441   "A \<in> sets M \<Longrightarrow> B \<in> sets M \<Longrightarrow> measure M (A \<union> B) = measure M A + measure M (B - A)"
  2442   using finite_measure_Union[of A "B - A"] by auto
  2444 lemma finite_unsigned_Hahn_decomposition:
  2445   assumes "finite_measure M" "finite_measure N" and [simp]: "sets N = sets M"
  2446   shows "\<exists>Y\<in>sets M. (\<forall>X\<in>sets M. X \<subseteq> Y \<longrightarrow> N X \<le> M X) \<and> (\<forall>X\<in>sets M. X \<inter> Y = {} \<longrightarrow> M X \<le> N X)"
  2447 proof -
  2448   interpret M: finite_measure M by fact
  2449   interpret N: finite_measure N by fact
  2451   define d where "d X = measure M X - measure N X" for X
  2453   have [intro]: "bdd_above (d`sets M)"
  2454     using sets.sets_into_space[of _ M]
  2455     by (intro bdd_aboveI[where M="measure M (space M)"])
  2456        (auto simp: d_def field_simps subset_eq intro!: add_increasing M.finite_measure_mono)
  2458   define \<gamma> where "\<gamma> = (SUP X:sets M. d X)"
  2459   have le_\<gamma>[intro]: "X \<in> sets M \<Longrightarrow> d X \<le> \<gamma>" for X
  2460     by (auto simp: \<gamma>_def intro!: cSUP_upper)
  2462   have "\<exists>f. \<forall>n. f n \<in> sets M \<and> d (f n) > \<gamma> - 1 / 2^n"
  2463   proof (intro choice_iff[THEN iffD1] allI)
  2464     fix n
  2465     have "\<exists>X\<in>sets M. \<gamma> - 1 / 2^n < d X"
  2466       unfolding \<gamma>_def by (intro less_cSUP_iff[THEN iffD1]) auto
  2467     then show "\<exists>y. y \<in> sets M \<and> \<gamma> - 1 / 2 ^ n < d y"
  2468       by auto
  2469   qed
  2470   then obtain E where [measurable]: "E n \<in> sets M" and E: "d (E n) > \<gamma> - 1 / 2^n" for n
  2471     by auto
  2473   define F where "F m n = (if m \<le> n then \<Inter>i\<in>{m..n}. E i else space M)" for m n
  2475   have [measurable]: "m \<le> n \<Longrightarrow> F m n \<in> sets M" for m n
  2476     by (auto simp: F_def)
  2478   have 1: "\<gamma> - 2 / 2 ^ m + 1 / 2 ^ n \<le> d (F m n)" if "m \<le> n" for m n
  2479     using that
  2480   proof (induct rule: dec_induct)
  2481     case base with E[of m] show ?case
  2482       by (simp add: F_def field_simps)
  2483   next
  2484     case (step i)
  2485     have F_Suc: "F m (Suc i) = F m i \<inter> E (Suc i)"
  2486       using \<open>m \<le> i\<close> by (auto simp: F_def le_Suc_eq)
  2488     have "\<gamma> + (\<gamma> - 2 / 2^m + 1 / 2 ^ Suc i) \<le> (\<gamma> - 1 / 2^Suc i) + (\<gamma> - 2 / 2^m + 1 / 2^i)"
  2489       by (simp add: field_simps)
  2490     also have "\<dots> \<le> d (E (Suc i)) + d (F m i)"
  2491       using E[of "Suc i"] by (intro add_mono step) auto
  2492     also have "\<dots> = d (E (Suc i)) + d (F m i - E (Suc i)) + d (F m (Suc i))"
  2493       using \<open>m \<le> i\<close> by (simp add: d_def field_simps F_Suc M.finite_measure_Diff' N.finite_measure_Diff')
  2494     also have "\<dots> = d (E (Suc i) \<union> F m i) + d (F m (Suc i))"
  2495       using \<open>m \<le> i\<close> by (simp add: d_def field_simps M.finite_measure_Union' N.finite_measure_Union')
  2496     also have "\<dots> \<le> \<gamma> + d (F m (Suc i))"
  2497       using \<open>m \<le> i\<close> by auto
  2498     finally show ?case
  2499       by auto
  2500   qed
  2502   define F' where "F' m = (\<Inter>i\<in>{m..}. E i)" for m
  2503   have F'_eq: "F' m = (\<Inter>i. F m (i + m))" for m
  2504     by (fastforce simp: le_iff_add[of m] F'_def F_def)
  2506   have [measurable]: "F' m \<in> sets M" for m
  2507     by (auto simp: F'_def)
  2509   have \<gamma>_le: "\<gamma> - 0 \<le> d (\<Union>m. F' m)"
  2510   proof (rule LIMSEQ_le)
  2511     show "(\<lambda>n. \<gamma> - 2 / 2 ^ n) \<longlonglongrightarrow> \<gamma> - 0"
  2512       by (intro tendsto_intros LIMSEQ_divide_realpow_zero) auto
  2513     have "incseq F'"
  2514       by (auto simp: incseq_def F'_def)
  2515     then show "(\<lambda>m. d (F' m)) \<longlonglongrightarrow> d (\<Union>m. F' m)"
  2516       unfolding d_def
  2517       by (intro tendsto_diff M.finite_Lim_measure_incseq N.finite_Lim_measure_incseq) auto
  2519     have "\<gamma> - 2 / 2 ^ m + 0 \<le> d (F' m)" for m
  2520     proof (rule LIMSEQ_le)
  2521       have *: "decseq (\<lambda>n. F m (n + m))"
  2522         by (auto simp: decseq_def F_def)
  2523       show "(\<lambda>n. d (F m n)) \<longlonglongrightarrow> d (F' m)"
  2524         unfolding d_def F'_eq
  2525         by (rule LIMSEQ_offset[where k=m])
  2526            (auto intro!: tendsto_diff M.finite_Lim_measure_decseq N.finite_Lim_measure_decseq *)
  2527       show "(\<lambda>n. \<gamma> - 2 / 2 ^ m + 1 / 2 ^ n) \<longlonglongrightarrow> \<gamma> - 2 / 2 ^ m + 0"
  2528         by (intro tendsto_add LIMSEQ_divide_realpow_zero tendsto_const) auto
  2529       show "\<exists>N. \<forall>n\<ge>N. \<gamma> - 2 / 2 ^ m + 1 / 2 ^ n \<le> d (F m n)"
  2530         using 1[of m] by (intro exI[of _ m]) auto
  2531     qed
  2532     then show "\<exists>N. \<forall>n\<ge>N. \<gamma> - 2 / 2 ^ n \<le> d (F' n)"
  2533       by auto
  2534   qed
  2536   show ?thesis
  2537   proof (safe intro!: bexI[of _ "\<Union>m. F' m"])
  2538     fix X assume [measurable]: "X \<in> sets M" and X: "X \<subseteq> (\<Union>m. F' m)"
  2539     have "d (\<Union>m. F' m) - d X = d ((\<Union>m. F' m) - X)"
  2540       using X by (auto simp: d_def M.finite_measure_Diff N.finite_measure_Diff)
  2541     also have "\<dots> \<le> \<gamma>"
  2542       by auto
  2543     finally have "0 \<le> d X"
  2544       using \<gamma>_le by auto
  2545     then show "emeasure N X \<le> emeasure M X"
  2546       by (auto simp: d_def M.emeasure_eq_measure N.emeasure_eq_measure)
  2547   next
  2548     fix X assume [measurable]: "X \<in> sets M" and X: "X \<inter> (\<Union>m. F' m) = {}"
  2549     then have "d (\<Union>m. F' m) + d X = d (X \<union> (\<Union>m. F' m))"
  2550       by (auto simp: d_def M.finite_measure_Union N.finite_measure_Union)
  2551     also have "\<dots> \<le> \<gamma>"
  2552       by auto
  2553     finally have "d X \<le> 0"
  2554       using \<gamma>_le by auto
  2555     then show "emeasure M X \<le> emeasure N X"
  2556       by (auto simp: d_def M.emeasure_eq_measure N.emeasure_eq_measure)
  2557   qed auto
  2558 qed
  2560 lemma unsigned_Hahn_decomposition:
  2561   assumes [simp]: "sets N = sets M" and [measurable]: "A \<in> sets M"
  2562     and [simp]: "emeasure M A \<noteq> top" "emeasure N A \<noteq> top"
  2563   shows "\<exists>Y\<in>sets M. Y \<subseteq> A \<and> (\<forall>X\<in>sets M. X \<subseteq> Y \<longrightarrow> N X \<le> M X) \<and> (\<forall>X\<in>sets M. X \<subseteq> A \<longrightarrow> X \<inter> Y = {} \<longrightarrow> M X \<le> N X)"
  2564 proof -
  2565   have "\<exists>Y\<in>sets (restrict_space M A).
  2566     (\<forall>X\<in>sets (restrict_space M A). X \<subseteq> Y \<longrightarrow> (restrict_space N A) X \<le> (restrict_space M A) X) \<and>
  2567     (\<forall>X\<in>sets (restrict_space M A). X \<inter> Y = {} \<longrightarrow> (restrict_space M A) X \<le> (restrict_space N A) X)"
  2568   proof (rule finite_unsigned_Hahn_decomposition)
  2569     show "finite_measure (restrict_space M A)" "finite_measure (restrict_space N A)"
  2570       by (auto simp: space_restrict_space emeasure_restrict_space less_top intro!: finite_measureI)
  2571   qed (simp add: sets_restrict_space)
  2572   then guess Y ..
  2573   then show ?thesis
  2574     apply (intro bexI[of _ Y] conjI ballI conjI)
  2575     apply (simp_all add: sets_restrict_space emeasure_restrict_space)
  2576     apply safe
  2577     subgoal for X Z
  2578       by (erule ballE[of _ _ X]) (auto simp add: Int_absorb1)
  2579     subgoal for X Z
  2580       by (erule ballE[of _ _ X])  (auto simp add: Int_absorb1 ac_simps)
  2581     apply auto
  2582     done
  2583 qed
  2585 text \<open>
  2586   Define a lexicographical order on @{type measure}, in the order space, sets and measure. The parts
  2587   of the lexicographical order are point-wise ordered.
  2588 \<close>
  2590 instantiation measure :: (type) order_bot
  2591 begin
  2593 inductive less_eq_measure :: "'a measure \<Rightarrow> 'a measure \<Rightarrow> bool" where
  2594   "space M \<subset> space N \<Longrightarrow> less_eq_measure M N"
  2595 | "space M = space N \<Longrightarrow> sets M \<subset> sets N \<Longrightarrow> less_eq_measure M N"
  2596 | "space M = space N \<Longrightarrow> sets M = sets N \<Longrightarrow> emeasure M \<le> emeasure N \<Longrightarrow> less_eq_measure M N"
  2598 lemma le_measure_iff:
  2599   "M \<le> N \<longleftrightarrow> (if space M = space N then
  2600     if sets M = sets N then emeasure M \<le> emeasure N else sets M \<subseteq> sets N else space M \<subseteq> space N)"
  2601   by (auto elim: less_eq_measure.cases intro: less_eq_measure.intros)
  2603 definition less_measure :: "'a measure \<Rightarrow> 'a measure \<Rightarrow> bool" where
  2604   "less_measure M N \<longleftrightarrow> (M \<le> N \<and> \<not> N \<le> M)"
  2606 definition bot_measure :: "'a measure" where
  2607   "bot_measure = sigma {} {}"
  2609 lemma
  2610   shows space_bot[simp]: "space bot = {}"
  2611     and sets_bot[simp]: "sets bot = {{}}"
  2612     and emeasure_bot[simp]: "emeasure bot X = 0"
  2613   by (auto simp: bot_measure_def sigma_sets_empty_eq emeasure_sigma)
  2615 instance
  2616 proof standard
  2617   show "bot \<le> a" for a :: "'a measure"
  2618     by (simp add: le_measure_iff bot_measure_def sigma_sets_empty_eq emeasure_sigma le_fun_def)
  2619 qed (auto simp: le_measure_iff less_measure_def split: if_split_asm intro: measure_eqI)
  2621 end
  2623 lemma le_measure: "sets M = sets N \<Longrightarrow> M \<le> N \<longleftrightarrow> (\<forall>A\<in>sets M. emeasure M A \<le> emeasure N A)"
  2624   apply (auto simp: le_measure_iff le_fun_def dest: sets_eq_imp_space_eq)
  2625   subgoal for X
  2626     by (cases "X \<in> sets M") (auto simp: emeasure_notin_sets)
  2627   done
  2629 definition sup_measure' :: "'a measure \<Rightarrow> 'a measure \<Rightarrow> 'a measure"
  2630 where
  2631   "sup_measure' A B = measure_of (space A) (sets A) (\<lambda>X. SUP Y:sets A. emeasure A (X \<inter> Y) + emeasure B (X \<inter> - Y))"
  2633 lemma assumes [simp]: "sets B = sets A"
  2634   shows space_sup_measure'[simp]: "space (sup_measure' A B) = space A"
  2635     and sets_sup_measure'[simp]: "sets (sup_measure' A B) = sets A"
  2636   using sets_eq_imp_space_eq[OF assms] by (simp_all add: sup_measure'_def)
  2638 lemma emeasure_sup_measure':
  2639   assumes sets_eq[simp]: "sets B = sets A" and [simp, intro]: "X \<in> sets A"
  2640   shows "emeasure (sup_measure' A B) X = (SUP Y:sets A. emeasure A (X \<inter> Y) + emeasure B (X \<inter> - Y))"
  2641     (is "_ = ?S X")
  2642 proof -
  2643   note sets_eq_imp_space_eq[OF sets_eq, simp]
  2644   show ?thesis
  2645     using sup_measure'_def
  2646   proof (rule emeasure_measure_of)
  2647     let ?d = "\<lambda>X Y. emeasure A (X \<inter> Y) + emeasure B (X \<inter> - Y)"
  2648     show "countably_additive (sets (sup_measure' A B)) (\<lambda>X. SUP Y : sets A. emeasure A (X \<inter> Y) + emeasure B (X \<inter> - Y))"
  2649     proof (rule countably_additiveI, goal_cases)
  2650       case (1 X)
  2651       then have [measurable]: "\<And>i. X i \<in> sets A" and "disjoint_family X"
  2652         by auto
  2653       have "(\<Sum>i. ?S (X i)) = (SUP Y:sets A. \<Sum>i. ?d (X i) Y)"
  2654       proof (rule ennreal_suminf_SUP_eq_directed)
  2655         fix J :: "nat set" and a b assume "finite J" and [measurable]: "a \<in> sets A" "b \<in> sets A"
  2656         have "\<exists>c\<in>sets A. c \<subseteq> X i \<and> (\<forall>a\<in>sets A. ?d (X i) a \<le> ?d (X i) c)" for i
  2657         proof cases
  2658           assume "emeasure A (X i) = top \<or> emeasure B (X i) = top"
  2659           then show ?thesis
  2660           proof
  2661             assume "emeasure A (X i) = top" then show ?thesis
  2662               by (intro bexI[of _ "X i"]) auto
  2663           next
  2664             assume "emeasure B (X i) = top" then show ?thesis
  2665               by (intro bexI[of _ "{}"]) auto
  2666           qed
  2667         next
  2668           assume finite: "\<not> (emeasure A (X i) = top \<or> emeasure B (X i) = top)"
  2669           then have "\<exists>Y\<in>sets A. Y \<subseteq> X i \<and> (\<forall>C\<in>sets A. C \<subseteq> Y \<longrightarrow> B C \<le> A C) \<and> (\<forall>C\<in>sets A. C \<subseteq> X i \<longrightarrow> C \<inter> Y = {} \<longrightarrow> A C \<le> B C)"
  2670             using unsigned_Hahn_decomposition[of B A "X i"] by simp
  2671           then obtain Y where [measurable]: "Y \<in> sets A" and [simp]: "Y \<subseteq> X i"
  2672             and B_le_A: "\<And>C. C \<in> sets A \<Longrightarrow> C \<subseteq> Y \<Longrightarrow> B C \<le> A C"
  2673             and A_le_B: "\<And>C. C \<in> sets A \<Longrightarrow> C \<subseteq> X i \<Longrightarrow> C \<inter> Y = {} \<Longrightarrow> A C \<le> B C"
  2674             by auto
  2676           show ?thesis
  2677           proof (intro bexI[of _ Y] ballI conjI)
  2678             fix a assume [measurable]: "a \<in> sets A"
  2679             have *: "(X i \<inter> a \<inter> Y \<union> (X i \<inter> a - Y)) = X i \<inter> a" "(X i - a) \<inter> Y \<union> (X i - a - Y) = X i \<inter> - a"
  2680               for a Y by auto
  2681             then have "?d (X i) a =
  2682               (A (X i \<inter> a \<inter> Y) + A (X i \<inter> a \<inter> - Y)) + (B (X i \<inter> - a \<inter> Y) + B (X i \<inter> - a \<inter> - Y))"
  2683               by (subst (1 2) plus_emeasure) (auto simp: Diff_eq[symmetric])
  2684             also have "\<dots> \<le> (A (X i \<inter> a \<inter> Y) + B (X i \<inter> a \<inter> - Y)) + (A (X i \<inter> - a \<inter> Y) + B (X i \<inter> - a \<inter> - Y))"
  2685               by (intro add_mono order_refl B_le_A A_le_B) (auto simp: Diff_eq[symmetric])
  2686             also have "\<dots> \<le> (A (X i \<inter> Y \<inter> a) + A (X i \<inter> Y \<inter> - a)) + (B (X i \<inter> - Y \<inter> a) + B (X i \<inter> - Y \<inter> - a))"
  2687               by (simp add: ac_simps)
  2688             also have "\<dots> \<le> A (X i \<inter> Y) + B (X i \<inter> - Y)"
  2689               by (subst (1 2) plus_emeasure) (auto simp: Diff_eq[symmetric] *)
  2690             finally show "?d (X i) a \<le> ?d (X i) Y" .
  2691           qed auto
  2692         qed
  2693         then obtain C where [measurable]: "C i \<in> sets A" and "C i \<subseteq> X i"
  2694           and C: "\<And>a. a \<in> sets A \<Longrightarrow> ?d (X i) a \<le> ?d (X i) (C i)" for i
  2695           by metis
  2696         have *: "X i \<inter> (\<Union>i. C i) = X i \<inter> C i" for i
  2697         proof safe
  2698           fix x j assume "x \<in> X i" "x \<in> C j"
  2699           moreover have "i = j \<or> X i \<inter> X j = {}"
  2700             using \<open>disjoint_family X\<close> by (auto simp: disjoint_family_on_def)
  2701           ultimately show "x \<in> C i"
  2702             using \<open>C i \<subseteq> X i\<close> \<open>C j \<subseteq> X j\<close> by auto
  2703         qed auto
  2704         have **: "X i \<inter> - (\<Union>i. C i) = X i \<inter> - C i" for i
  2705         proof safe
  2706           fix x j assume "x \<in> X i" "x \<notin> C i" "x \<in> C j"
  2707           moreover have "i = j \<or> X i \<inter> X j = {}"
  2708             using \<open>disjoint_family X\<close> by (auto simp: disjoint_family_on_def)
  2709           ultimately show False
  2710             using \<open>C i \<subseteq> X i\<close> \<open>C j \<subseteq> X j\<close> by auto
  2711         qed auto
  2712         show "\<exists>c\<in>sets A. \<forall>i\<in>J. ?d (X i) a \<le> ?d (X i) c \<and> ?d (X i) b \<le> ?d (X i) c"
  2713           apply (intro bexI[of _ "\<Union>i. C i"])
  2714           unfolding * **
  2715           apply (intro C ballI conjI)
  2716           apply auto
  2717           done
  2718       qed
  2719       also have "\<dots> = ?S (\<Union>i. X i)"
  2720         unfolding UN_extend_simps(4)
  2721         by (auto simp add: suminf_add[symmetric] Diff_eq[symmetric] simp del: UN_simps
  2722                  intro!: SUP_cong arg_cong2[where f="op +"] suminf_emeasure
  2723                          disjoint_family_on_bisimulation[OF \<open>disjoint_family X\<close>])
  2724       finally show "(\<Sum>i. ?S (X i)) = ?S (\<Union>i. X i)" .
  2725     qed
  2726   qed (auto dest: sets.sets_into_space simp: positive_def intro!: SUP_const)
  2727 qed
  2729 lemma le_emeasure_sup_measure'1:
  2730   assumes "sets B = sets A" "X \<in> sets A" shows "emeasure A X \<le> emeasure (sup_measure' A B) X"
  2731   by (subst emeasure_sup_measure'[OF assms]) (auto intro!: SUP_upper2[of "X"] assms)
  2733 lemma le_emeasure_sup_measure'2:
  2734   assumes "sets B = sets A" "X \<in> sets A" shows "emeasure B X \<le> emeasure (sup_measure' A B) X"
  2735   by (subst emeasure_sup_measure'[OF assms]) (auto intro!: SUP_upper2[of "{}"] assms)
  2737 lemma emeasure_sup_measure'_le2:
  2738   assumes [simp]: "sets B = sets C" "sets A = sets C" and [measurable]: "X \<in> sets C"
  2739   assumes A: "\<And>Y. Y \<subseteq> X \<Longrightarrow> Y \<in> sets A \<Longrightarrow> emeasure A Y \<le> emeasure C Y"
  2740   assumes B: "\<And>Y. Y \<subseteq> X \<Longrightarrow> Y \<in> sets A \<Longrightarrow> emeasure B Y \<le> emeasure C Y"
  2741   shows "emeasure (sup_measure' A B) X \<le> emeasure C X"
  2742 proof (subst emeasure_sup_measure')
  2743   show "(SUP Y:sets A. emeasure A (X \<inter> Y) + emeasure B (X \<inter> - Y)) \<le> emeasure C X"
  2744     unfolding \<open>sets A = sets C\<close>
  2745   proof (intro SUP_least)
  2746     fix Y assume [measurable]: "Y \<in> sets C"
  2747     have [simp]: "X \<inter> Y \<union> (X - Y) = X"
  2748       by auto
  2749     have "emeasure A (X \<inter> Y) + emeasure B (X \<inter> - Y) \<le> emeasure C (X \<inter> Y) + emeasure C (X \<inter> - Y)"
  2750       by (intro add_mono A B) (auto simp: Diff_eq[symmetric])
  2751     also have "\<dots> = emeasure C X"
  2752       by (subst plus_emeasure) (auto simp: Diff_eq[symmetric])
  2753     finally show "emeasure A (X \<inter> Y) + emeasure B (X \<inter> - Y) \<le> emeasure C X" .
  2754   qed
  2755 qed simp_all
  2757 definition sup_lexord :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b::order) \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'a"
  2758 where
  2759   "sup_lexord A B k s c =
  2760     (if k A = k B then c else if \<not> k A \<le> k B \<and> \<not> k B \<le> k A then s else if k B \<le> k A then A else B)"
  2762 lemma sup_lexord:
  2763   "(k A < k B \<Longrightarrow> P B) \<Longrightarrow> (k B < k A \<Longrightarrow> P A) \<Longrightarrow> (k A = k B \<Longrightarrow> P c) \<Longrightarrow>
  2764     (\<not> k B \<le> k A \<Longrightarrow> \<not> k A \<le> k B \<Longrightarrow> P s) \<Longrightarrow> P (sup_lexord A B k s c)"
  2765   by (auto simp: sup_lexord_def)
  2767 lemmas le_sup_lexord = sup_lexord[where P="\<lambda>a. c \<le> a" for c]
  2769 lemma sup_lexord1: "k A = k B \<Longrightarrow> sup_lexord A B k s c = c"
  2770   by (simp add: sup_lexord_def)
  2772 lemma sup_lexord_commute: "sup_lexord A B k s c = sup_lexord B A k s c"
  2773   by (auto simp: sup_lexord_def)
  2775 lemma sigma_sets_le_sets_iff: "(sigma_sets (space x) \<A> \<subseteq> sets x) = (\<A> \<subseteq> sets x)"
  2776   using sets.sigma_sets_subset[of \<A> x] by auto
  2778 lemma sigma_le_iff: "\<A> \<subseteq> Pow \<Omega> \<Longrightarrow> sigma \<Omega> \<A> \<le> x \<longleftrightarrow> (\<Omega> \<subseteq> space x \<and> (space x = \<Omega> \<longrightarrow> \<A> \<subseteq> sets x))"
  2779   by (cases "\<Omega> = space x")
  2780      (simp_all add: eq_commute[of _ "sets x"] le_measure_iff emeasure_sigma le_fun_def
  2781                     sigma_sets_superset_generator sigma_sets_le_sets_iff)
  2783 instantiation measure :: (type) semilattice_sup
  2784 begin
  2786 definition sup_measure :: "'a measure \<Rightarrow> 'a measure \<Rightarrow> 'a measure"
  2787 where
  2788   "sup_measure A B =
  2789     sup_lexord A B space (sigma (space A \<union> space B) {})
  2790       (sup_lexord A B sets (sigma (space A) (sets A \<union> sets B)) (sup_measure' A B))"
  2792 instance
  2793 proof
  2794   fix x y z :: "'a measure"
  2795   show "x \<le> sup x y"
  2796     unfolding sup_measure_def
  2797   proof (intro le_sup_lexord)
  2798     assume "space x = space y"
  2799     then have *: "sets x \<union> sets y \<subseteq> Pow (space x)"
  2800       using sets.space_closed by auto
  2801     assume "\<not> sets y \<subseteq> sets x" "\<not> sets x \<subseteq> sets y"
  2802     then have "sets x \<subset> sets x \<union> sets y"
  2803       by auto
  2804     also have "\<dots> \<le> sigma (space x) (sets x \<union> sets y)"
  2805       by (subst sets_measure_of[OF *]) (rule sigma_sets_superset_generator)
  2806     finally show "x \<le> sigma (space x) (sets x \<union> sets y)"
  2807       by (simp add: space_measure_of[OF *] less_eq_measure.intros(2))
  2808   next
  2809     assume "\<not> space y \<subseteq> space x" "\<not> space x \<subseteq> space y"
  2810     then show "x \<le> sigma (space x \<union> space y) {}"
  2811       by (intro less_eq_measure.intros) auto
  2812   next
  2813     assume "sets x = sets y" then show "x \<le> sup_measure' x y"
  2814       by (simp add: le_measure le_emeasure_sup_measure'1)
  2815   qed (auto intro: less_eq_measure.intros)
  2816   show "y \<le> sup x y"
  2817     unfolding sup_measure_def
  2818   proof (intro le_sup_lexord)
  2819     assume **: "space x = space y"
  2820     then have *: "sets x \<union> sets y \<subseteq> Pow (space y)"
  2821       using sets.space_closed by auto
  2822     assume "\<not> sets y \<subseteq> sets x" "\<not> sets x \<subseteq> sets y"
  2823     then have "sets y \<subset> sets x \<union> sets y"
  2824       by auto
  2825     also have "\<dots> \<le> sigma (space y) (sets x \<union> sets y)"
  2826       by (subst sets_measure_of[OF *]) (rule sigma_sets_superset_generator)
  2827     finally show "y \<le> sigma (space x) (sets x \<union> sets y)"
  2828       by (simp add: ** space_measure_of[OF *] less_eq_measure.intros(2))
  2829   next
  2830     assume "\<not> space y \<subseteq> space x" "\<not> space x \<subseteq> space y"
  2831     then show "y \<le> sigma (space x \<union> space y) {}"
  2832       by (intro less_eq_measure.intros) auto
  2833   next
  2834     assume "sets x = sets y" then show "y \<le> sup_measure' x y"
  2835       by (simp add: le_measure le_emeasure_sup_measure'2)
  2836   qed (auto intro: less_eq_measure.intros)
  2837   show "x \<le> y \<Longrightarrow> z \<le> y \<Longrightarrow> sup x z \<le> y"
  2838     unfolding sup_measure_def
  2839   proof (intro sup_lexord[where P="\<lambda>x. x \<le> y"])
  2840     assume "x \<le> y" "z \<le> y" and [simp]: "space x = space z" "sets x = sets z"
  2841     from \<open>x \<le> y\<close> show "sup_measure' x z \<le> y"
  2842     proof cases
  2843       case 1 then show ?thesis
  2844         by (intro less_eq_measure.intros(1)) simp
  2845     next
  2846       case 2 then show ?thesis
  2847         by (intro less_eq_measure.intros(2)) simp_all
  2848     next
  2849       case 3 with \<open>z \<le> y\<close> \<open>x \<le> y\<close> show ?thesis
  2850         by (auto simp add: le_measure intro!: emeasure_sup_measure'_le2)
  2851     qed
  2852   next
  2853     assume **: "x \<le> y" "z \<le> y" "space x = space z" "\<not> sets z \<subseteq> sets x" "\<not> sets x \<subseteq> sets z"
  2854     then have *: "sets x \<union> sets z \<subseteq> Pow (space x)"
  2855       using sets.space_closed by auto
  2856     show "sigma (space x) (sets x \<union> sets z) \<le> y"
  2857       unfolding sigma_le_iff[OF *] using ** by (auto simp: le_measure_iff split: if_split_asm)
  2858   next
  2859     assume "x \<le> y" "z \<le> y" "\<not> space z \<subseteq> space x" "\<not> space x \<subseteq> space z"
  2860     then have "space x \<subseteq> space y" "space z \<subseteq> space y"
  2861       by (auto simp: le_measure_iff split: if_split_asm)
  2862     then show "sigma (space x \<union> space z) {} \<le> y"
  2863       by (simp add: sigma_le_iff)
  2864   qed
  2865 qed
  2867 end
  2869 lemma space_empty_eq_bot: "space a = {} \<longleftrightarrow> a = bot"
  2870   using space_empty[of a] by (auto intro!: measure_eqI)
  2872 lemma sets_eq_iff_bounded: "A \<le> B \<Longrightarrow> B \<le> C \<Longrightarrow> sets A = sets C \<Longrightarrow> sets B = sets A"
  2873   by (auto dest: sets_eq_imp_space_eq simp add: le_measure_iff split: if_split_asm)
  2875 lemma sets_sup: "sets A = sets M \<Longrightarrow> sets B = sets M \<Longrightarrow> sets (sup A B) = sets M"
  2876   by (auto simp add: sup_measure_def sup_lexord_def dest: sets_eq_imp_space_eq)
  2878 lemma le_measureD1: "A \<le> B \<Longrightarrow> space A \<le> space B"
  2879   by (auto simp: le_measure_iff split: if_split_asm)
  2881 lemma le_measureD2: "A \<le> B \<Longrightarrow> space A = space B \<Longrightarrow> sets A \<le> sets B"
  2882   by (auto simp: le_measure_iff split: if_split_asm)
  2884 lemma le_measureD3: "A \<le> B \<Longrightarrow> sets A = sets B \<Longrightarrow> emeasure A X \<le> emeasure B X"
  2885   by (auto simp: le_measure_iff le_fun_def dest: sets_eq_imp_space_eq split: if_split_asm)
  2887 lemma UN_space_closed: "UNION S sets \<subseteq> Pow (UNION S space)"
  2888   using sets.space_closed by auto
  2890 definition Sup_lexord :: "('a \<Rightarrow> 'b::complete_lattice) \<Rightarrow> ('a set \<Rightarrow> 'a) \<Rightarrow> ('a set \<Rightarrow> 'a) \<Rightarrow> 'a set \<Rightarrow> 'a"
  2891 where
  2892   "Sup_lexord k c s A = (let U = (SUP a:A. k a) in if \<exists>a\<in>A. k a = U then c {a\<in>A. k a = U} else s A)"
  2894 lemma Sup_lexord:
  2895   "(\<And>a S. a \<in> A \<Longrightarrow> k a = (SUP a:A. k a) \<Longrightarrow> S = {a'\<in>A. k a' = k a} \<Longrightarrow> P (c S)) \<Longrightarrow> ((\<And>a. a \<in> A \<Longrightarrow> k a \<noteq> (SUP a:A. k a)) \<Longrightarrow> P (s A)) \<Longrightarrow>
  2896     P (Sup_lexord k c s A)"
  2897   by (auto simp: Sup_lexord_def Let_def)
  2899 lemma Sup_lexord1:
  2900   assumes A: "A \<noteq> {}" "(\<And>a. a \<in> A \<Longrightarrow> k a = (\<Union>a\<in>A. k a))" "P (c A)"
  2901   shows "P (Sup_lexord k c s A)"
  2902   unfolding Sup_lexord_def Let_def
  2903 proof (clarsimp, safe)
  2904   show "\<forall>a\<in>A. k a \<noteq> (\<Union>x\<in>A. k x) \<Longrightarrow> P (s A)"
  2905     by (metis assms(1,2) ex_in_conv)
  2906 next
  2907   fix a assume "a \<in> A" "k a = (\<Union>x\<in>A. k x)"
  2908   then have "{a \<in> A. k a = (\<Union>x\<in>A. k x)} = {a \<in> A. k a = k a}"
  2909     by (metis A(2)[symmetric])
  2910   then show "P (c {a \<in> A. k a = (\<Union>x\<in>A. k x)})"
  2911     by (simp add: A(3))
  2912 qed
  2914 instantiation measure :: (type) complete_lattice
  2915 begin
  2917 interpretation sup_measure: comm_monoid_set sup "bot :: 'a measure"
  2918   by standard (auto intro!: antisym)
  2920 lemma sup_measure_F_mono':
  2921   "finite J \<Longrightarrow> finite I \<Longrightarrow> sup_measure.F id I \<le> sup_measure.F id (I \<union> J)"
  2922 proof (induction J rule: finite_induct)
  2923   case empty then show ?case
  2924     by simp
  2925 next
  2926   case (insert i J)
  2927   show ?case
  2928   proof cases
  2929     assume "i \<in> I" with insert show ?thesis
  2930       by (auto simp: insert_absorb)
  2931   next
  2932     assume "i \<notin> I"
  2933     have "sup_measure.F id I \<le> sup_measure.F id (I \<union> J)"
  2934       by (intro insert)
  2935     also have "\<dots> \<le> sup_measure.F id (insert i (I \<union> J))"
  2936       using insert \<open>i \<notin> I\<close> by (subst sup_measure.insert) auto
  2937     finally show ?thesis
  2938       by auto
  2939   qed
  2940 qed
  2942 lemma sup_measure_F_mono: "finite I \<Longrightarrow> J \<subseteq> I \<Longrightarrow> sup_measure.F id J \<le> sup_measure.F id I"
  2943   using sup_measure_F_mono'[of I J] by (auto simp: finite_subset Un_absorb1)
  2945 lemma sets_sup_measure_F:
  2946   "finite I \<Longrightarrow> I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> sets i = sets M) \<Longrightarrow> sets (sup_measure.F id I) = sets M"
  2947   by (induction I rule: finite_ne_induct) (simp_all add: sets_sup)
  2949 definition Sup_measure' :: "'a measure set \<Rightarrow> 'a measure"
  2950 where
  2951   "Sup_measure' M = measure_of (\<Union>a\<in>M. space a) (\<Union>a\<in>M. sets a)
  2952     (\<lambda>X. (SUP P:{P. finite P \<and> P \<subseteq> M }. sup_measure.F id P X))"
  2954 lemma space_Sup_measure'2: "space (Sup_measure' M) = (\<Union>m\<in>M. space m)"
  2955   unfolding Sup_measure'_def by (intro space_measure_of[OF UN_space_closed])
  2957 lemma sets_Sup_measure'2: "sets (Sup_measure' M) = sigma_sets (\<Union>m\<in>M. space m) (\<Union>m\<in>M. sets m)"
  2958   unfolding Sup_measure'_def by (intro sets_measure_of[OF UN_space_closed])
  2960 lemma sets_Sup_measure':
  2961   assumes sets_eq[simp]: "\<And>m. m \<in> M \<Longrightarrow> sets m = sets A" and "M \<noteq> {}"
  2962   shows "sets (Sup_measure' M) = sets A"
  2963   using sets_eq[THEN sets_eq_imp_space_eq, simp] \<open>M \<noteq> {}\<close> by (simp add: Sup_measure'_def)
  2965 lemma space_Sup_measure':
  2966   assumes sets_eq[simp]: "\<And>m. m \<in> M \<Longrightarrow> sets m = sets A" and "M \<noteq> {}"
  2967   shows "space (Sup_measure' M) = space A"
  2968   using sets_eq[THEN sets_eq_imp_space_eq, simp] \<open>M \<noteq> {}\<close>
  2969   by (simp add: Sup_measure'_def )
  2971 lemma emeasure_Sup_measure':
  2972   assumes sets_eq[simp]: "\<And>m. m \<in> M \<Longrightarrow> sets m = sets A" and "X \<in> sets A" "M \<noteq> {}"
  2973   shows "emeasure (Sup_measure' M) X = (SUP P:{P. finite P \<and> P \<subseteq> M}. sup_measure.F id P X)"
  2974     (is "_ = ?S X")
  2975   using Sup_measure'_def
  2976 proof (rule emeasure_measure_of)
  2977   note sets_eq[THEN sets_eq_imp_space_eq, simp]
  2978   have *: "sets (Sup_measure' M) = sets A" "space (Sup_measure' M) = space A"
  2979     using \<open>M \<noteq> {}\<close> by (simp_all add: Sup_measure'_def)
  2980   let ?\<mu> = "sup_measure.F id"
  2981   show "countably_additive (sets (Sup_measure' M)) ?S"
  2982   proof (rule countably_additiveI, goal_cases)
  2983     case (1 F)
  2984     then have **: "range F \<subseteq> sets A"
  2985       by (auto simp: *)
  2986     show "(\<Sum>i. ?S (F i)) = ?S (\<Union>i. F i)"
  2987     proof (subst ennreal_suminf_SUP_eq_directed)
  2988       fix i j and N :: "nat set" assume ij: "i \<in> {P. finite P \<and> P \<subseteq> M}" "j \<in> {P. finite P \<and> P \<subseteq> M}"
  2989       have "(i \<noteq> {} \<longrightarrow> sets (?\<mu> i) = sets A) \<and> (j \<noteq> {} \<longrightarrow> sets (?\<mu> j) = sets A) \<and>
  2990         (i \<noteq> {} \<or> j \<noteq> {} \<longrightarrow> sets (?\<mu> (i \<union> j)) = sets A)"
  2991         using ij by (intro impI sets_sup_measure_F conjI) auto
  2992       then have "?\<mu> j (F n) \<le> ?\<mu> (i \<union> j) (F n) \<and> ?\<mu> i (F n) \<le> ?\<mu> (i \<union> j) (F n)" for n
  2993         using ij
  2994         by (cases "i = {}"; cases "j = {}")
  2995            (auto intro!: le_measureD3 sup_measure_F_mono simp: sets_sup_measure_F
  2996                  simp del: id_apply)
  2997       with ij show "\<exists>k\<in>{P. finite P \<and> P \<subseteq> M}. \<forall>n\<in>N. ?\<mu> i (F n) \<le> ?\<mu> k (F n) \<and> ?\<mu> j (F n) \<le> ?\<mu> k (F n)"
  2998         by (safe intro!: bexI[of _ "i \<union> j"]) auto
  2999     next
  3000       show "(SUP P : {P. finite P \<and> P \<subseteq> M}. \<Sum>n. ?\<mu> P (F n)) = (SUP P : {P. finite P \<and> P \<subseteq> M}. ?\<mu> P (UNION UNIV F))"
  3001       proof (intro SUP_cong refl)
  3002         fix i assume i: "i \<in> {P. finite P \<and> P \<subseteq> M}"
  3003         show "(\<Sum>n. ?\<mu> i (F n)) = ?\<mu> i (UNION UNIV F)"
  3004         proof cases
  3005           assume "i \<noteq> {}" with i ** show ?thesis
  3006             apply (intro suminf_emeasure \<open>disjoint_family F\<close>)
  3007             apply (subst sets_sup_measure_F[OF _ _ sets_eq])
  3008             apply auto
  3009             done
  3010         qed simp
  3011       qed
  3012     qed
  3013   qed
  3014   show "positive (sets (Sup_measure' M)) ?S"
  3015     by (auto simp: positive_def bot_ennreal[symmetric])
  3016   show "X \<in> sets (Sup_measure' M)"
  3017     using assms * by auto
  3018 qed (rule UN_space_closed)
  3020 definition Sup_measure :: "'a measure set \<Rightarrow> 'a measure"
  3021 where
  3022   "Sup_measure = Sup_lexord space (Sup_lexord sets Sup_measure'
  3023     (\<lambda>U. sigma (\<Union>u\<in>U. space u) (\<Union>u\<in>U. sets u))) (\<lambda>U. sigma (\<Union>u\<in>U. space u) {})"
  3025 definition Inf_measure :: "'a measure set \<Rightarrow> 'a measure"
  3026 where
  3027   "Inf_measure A = Sup {x. \<forall>a\<in>A. x \<le> a}"
  3029 definition inf_measure :: "'a measure \<Rightarrow> 'a measure \<Rightarrow> 'a measure"
  3030 where
  3031   "inf_measure a b = Inf {a, b}"
  3033 definition top_measure :: "'a measure"
  3034 where
  3035   "top_measure = Inf {}"
  3037 instance
  3038 proof
  3039   note UN_space_closed [simp]
  3040   show upper: "x \<le> Sup A" if x: "x \<in> A" for x :: "'a measure" and A
  3041     unfolding Sup_measure_def
  3042   proof (intro Sup_lexord[where P="\<lambda>y. x \<le> y"])
  3043     assume "\<And>a. a \<in> A \<Longrightarrow> space a \<noteq> (\<Union>a\<in>A. space a)"
  3044     from this[OF \<open>x \<in> A\<close>] \<open>x \<in> A\<close> show "x \<le> sigma (\<Union>a\<in>A. space a) {}"
  3045       by (intro less_eq_measure.intros) auto
  3046   next
  3047     fix a S assume "a \<in> A" and a: "space a = (\<Union>a\<in>A. space a)" and S: "S = {a' \<in> A. space a' = space a}"
  3048       and neq: "\<And>aa. aa \<in> S \<Longrightarrow> sets aa \<noteq> (\<Union>a\<in>S. sets a)"
  3049     have sp_a: "space a = (UNION S space)"
  3050       using \<open>a\<in>A\<close> by (auto simp: S)
  3051     show "x \<le> sigma (UNION S space) (UNION S sets)"
  3052     proof cases
  3053       assume [simp]: "space x = space a"
  3054       have "sets x \<subset> (\<Union>a\<in>S. sets a)"
  3055         using \<open>x\<in>A\<close> neq[of x] by (auto simp: S)
  3056       also have "\<dots> \<subseteq> sigma_sets (\<Union>x\<in>S. space x) (\<Union>x\<in>S. sets x)"
  3057         by (rule sigma_sets_superset_generator)
  3058       finally show ?thesis
  3059         by (intro less_eq_measure.intros(2)) (simp_all add: sp_a)
  3060     next
  3061       assume "space x \<noteq> space a"
  3062       moreover have "space x \<le> space a"
  3063         unfolding a using \<open>x\<in>A\<close> by auto
  3064       ultimately show ?thesis
  3065         by (intro less_eq_measure.intros) (simp add: less_le sp_a)
  3066     qed
  3067   next
  3068     fix a b S S' assume "a \<in> A" and a: "space a = (\<Union>a\<in>A. space a)" and S: "S = {a' \<in> A. space a' = space a}"
  3069       and "b \<in> S" and b: "sets b = (\<Union>a\<in>S. sets a)" and S': "S' = {a' \<in> S. sets a' = sets b}"
  3070     then have "S' \<noteq> {}" "space b = space a"
  3071       by auto
  3072     have sets_eq: "\<And>x. x \<in> S' \<Longrightarrow> sets x = sets b"
  3073       by (auto simp: S')
  3074     note sets_eq[THEN sets_eq_imp_space_eq, simp]
  3075     have *: "sets (Sup_measure' S') = sets b" "space (Sup_measure' S') = space b"
  3076       using \<open>S' \<noteq> {}\<close> by (simp_all add: Sup_measure'_def sets_eq)
  3077     show "x \<le> Sup_measure' S'"
  3078     proof cases
  3079       assume "x \<in> S"
  3080       with \<open>b \<in> S\<close> have "space x = space b"
  3081         by (simp add: S)
  3082       show ?thesis
  3083       proof cases
  3084         assume "x \<in> S'"
  3085         show "x \<le> Sup_measure' S'"
  3086         proof (intro le_measure[THEN iffD2] ballI)
  3087           show "sets x = sets (Sup_measure' S')"
  3088             using \<open>x\<in>S'\<close> * by (simp add: S')
  3089           fix X assume "X \<in> sets x"
  3090           show "emeasure x X \<le> emeasure (Sup_measure' S') X"
  3091           proof (subst emeasure_Sup_measure'[OF _ \<open>X \<in> sets x\<close>])
  3092             show "emeasure x X \<le> (SUP P : {P. finite P \<and> P \<subseteq> S'}. emeasure (sup_measure.F id P) X)"
  3093               using \<open>x\<in>S'\<close> by (intro SUP_upper2[where i="{x}"]) auto
  3094           qed (insert \<open>x\<in>S'\<close> S', auto)
  3095         qed
  3096       next
  3097         assume "x \<notin> S'"
  3098         then have "sets x \<noteq> sets b"
  3099           using \<open>x\<in>S\<close> by (auto simp: S')
  3100         moreover have "sets x \<le> sets b"
  3101           using \<open>x\<in>S\<close> unfolding b by auto
  3102         ultimately show ?thesis
  3103           using * \<open>x \<in> S\<close>
  3104           by (intro less_eq_measure.intros(2))
  3105              (simp_all add: * \<open>space x = space b\<close> less_le)
  3106       qed
  3107     next
  3108       assume "x \<notin> S"
  3109       with \<open>x\<in>A\<close> \<open>x \<notin> S\<close> \<open>space b = space a\<close> show ?thesis
  3110         by (intro less_eq_measure.intros)
  3111            (simp_all add: * less_le a SUP_upper S)
  3112     qed
  3113   qed
  3114   show least: "Sup A \<le> x" if x: "\<And>z. z \<in> A \<Longrightarrow> z \<le> x" for x :: "'a measure" and A
  3115     unfolding Sup_measure_def
  3116   proof (intro Sup_lexord[where P="\<lambda>y. y \<le> x"])
  3117     assume "\<And>a. a \<in> A \<Longrightarrow> space a \<noteq> (\<Union>a\<in>A. space a)"
  3118     show "sigma (UNION A space) {} \<le> x"
  3119       using x[THEN le_measureD1] by (subst sigma_le_iff) auto
  3120   next
  3121     fix a S assume "a \<in> A" "space a = (\<Union>a\<in>A. space a)" and S: "S = {a' \<in> A. space a' = space a}"
  3122       "\<And>a. a \<in> S \<Longrightarrow> sets a \<noteq> (\<Union>a\<in>S. sets a)"
  3123     have "UNION S space \<subseteq> space x"
  3124       using S le_measureD1[OF x] by auto
  3125     moreover
  3126     have "UNION S space = space a"
  3127       using \<open>a\<in>A\<close> S by auto
  3128     then have "space x = UNION S space \<Longrightarrow> UNION S sets \<subseteq> sets x"
  3129       using \<open>a \<in> A\<close> le_measureD2[OF x] by (auto simp: S)
  3130     ultimately show "sigma (UNION S space) (UNION S sets) \<le> x"
  3131       by (subst sigma_le_iff) simp_all
  3132   next
  3133     fix a b S S' assume "a \<in> A" and a: "space a = (\<Union>a\<in>A. space a)" and S: "S = {a' \<in> A. space a' = space a}"
  3134       and "b \<in> S" and b: "sets b = (\<Union>a\<in>S. sets a)" and S': "S' = {a' \<in> S. sets a' = sets b}"
  3135     then have "S' \<noteq> {}" "space b = space a"
  3136       by auto
  3137     have sets_eq: "\<And>x. x \<in> S' \<Longrightarrow> sets x = sets b"
  3138       by (auto simp: S')
  3139     note sets_eq[THEN sets_eq_imp_space_eq, simp]
  3140     have *: "sets (Sup_measure' S') = sets b" "space (Sup_measure' S') = space b"
  3141       using \<open>S' \<noteq> {}\<close> by (simp_all add: Sup_measure'_def sets_eq)
  3142     show "Sup_measure' S' \<le> x"
  3143     proof cases
  3144       assume "space x = space a"
  3145       show ?thesis
  3146       proof cases
  3147         assume **: "sets x = sets b"
  3148         show ?thesis
  3149         proof (intro le_measure[THEN iffD2] ballI)
  3150           show ***: "sets (Sup_measure' S') = sets x"
  3151             by (simp add: * **)
  3152           fix X assume "X \<in> sets (Sup_measure' S')"
  3153           show "emeasure (Sup_measure' S') X \<le> emeasure x X"
  3154             unfolding ***
  3155           proof (subst emeasure_Sup_measure'[OF _ \<open>X \<in> sets (Sup_measure' S')\<close>])
  3156             show "(SUP P : {P. finite P \<and> P \<subseteq> S'}. emeasure (sup_measure.F id P) X) \<le> emeasure x X"
  3157             proof (safe intro!: SUP_least)
  3158               fix P assume P: "finite P" "P \<subseteq> S'"
  3159               show "emeasure (sup_measure.F id P) X \<le> emeasure x X"
  3160               proof cases
  3161                 assume "P = {}" then show ?thesis
  3162                   by auto
  3163               next
  3164                 assume "P \<noteq> {}"
  3165                 from P have "finite P" "P \<subseteq> A"
  3166                   unfolding S' S by (simp_all add: subset_eq)
  3167                 then have "sup_measure.F id P \<le> x"
  3168                   by (induction P) (auto simp: x)
  3169                 moreover have "sets (sup_measure.F id P) = sets x"
  3170                   using \<open>finite P\<close> \<open>P \<noteq> {}\<close> \<open>P \<subseteq> S'\<close> \<open>sets x = sets b\<close>
  3171                   by (intro sets_sup_measure_F) (auto simp: S')
  3172                 ultimately show "emeasure (sup_measure.F id P) X \<le> emeasure x X"
  3173                   by (rule le_measureD3)
  3174               qed
  3175             qed
  3176             show "m \<in> S' \<Longrightarrow> sets m = sets (Sup_measure' S')" for m
  3177               unfolding * by (simp add: S')
  3178           qed fact
  3179         qed
  3180       next
  3181         assume "sets x \<noteq> sets b"
  3182         moreover have "sets b \<le> sets x"
  3183           unfolding b S using x[THEN le_measureD2] \<open>space x = space a\<close> by auto
  3184         ultimately show "Sup_measure' S' \<le> x"
  3185           using \<open>space x = space a\<close> \<open>b \<in> S\<close>
  3186           by (intro less_eq_measure.intros(2)) (simp_all add: * S)
  3187       qed
  3188     next
  3189       assume "space x \<noteq> space a"
  3190       then have "space a < space x"
  3191         using le_measureD1[OF x[OF \<open>a\<in>A\<close>]] by auto
  3192       then show "Sup_measure' S' \<le> x"
  3193         by (intro less_eq_measure.intros) (simp add: * \<open>space b = space a\<close>)
  3194     qed
  3195   qed
  3196   show "Sup {} = (bot::'a measure)" "Inf {} = (top::'a measure)"
  3197     by (auto intro!: antisym least simp: top_measure_def)
  3198   show lower: "x \<in> A \<Longrightarrow> Inf A \<le> x" for x :: "'a measure" and A
  3199     unfolding Inf_measure_def by (intro least) auto
  3200   show greatest: "(\<And>z. z \<in> A \<Longrightarrow> x \<le> z) \<Longrightarrow> x \<le> Inf A" for x :: "'a measure" and A
  3201     unfolding Inf_measure_def by (intro upper) auto
  3202   show "inf x y \<le> x" "inf x y \<le> y" "x \<le> y \<Longrightarrow> x \<le> z \<Longrightarrow> x \<le> inf y z" for x y z :: "'a measure"
  3203     by (auto simp: inf_measure_def intro!: lower greatest)
  3204 qed
  3206 end
  3208 lemma sets_SUP:
  3209   assumes "\<And>x. x \<in> I \<Longrightarrow> sets (M x) = sets N"
  3210   shows "I \<noteq> {} \<Longrightarrow> sets (SUP i:I. M i) = sets N"
  3211   unfolding Sup_measure_def
  3212   using assms assms[THEN sets_eq_imp_space_eq]
  3213     sets_Sup_measure'[where A=N and M="M`I"]
  3214   by (intro Sup_lexord1[where P="\<lambda>x. sets x = sets N"]) auto
  3216 lemma emeasure_SUP:
  3217   assumes sets: "\<And>i. i \<in> I \<Longrightarrow> sets (M i) = sets N" "X \<in> sets N" "I \<noteq> {}"
  3218   shows "emeasure (SUP i:I. M i) X = (SUP J:{J. J \<noteq> {} \<and> finite J \<and> J \<subseteq> I}. emeasure (SUP i:J. M i) X)"
  3219 proof -
  3220   interpret sup_measure: comm_monoid_set sup "bot :: 'b measure"
  3221     by standard (auto intro!: antisym)
  3222   have eq: "finite J \<Longrightarrow> sup_measure.F id J = (SUP i:J. i)" for J :: "'b measure set"
  3223     by (induction J rule: finite_induct) auto
  3224   have 1: "J \<noteq> {} \<Longrightarrow> J \<subseteq> I \<Longrightarrow> sets (SUP x:J. M x) = sets N" for J
  3225     by (intro sets_SUP sets) (auto )
  3226   from \<open>I \<noteq> {}\<close> obtain i where "i\<in>I" by auto
  3227   have "Sup_measure' (M`I) X = (SUP P:{P. finite P \<and> P \<subseteq> M`I}. sup_measure.F id P X)"
  3228     using sets by (intro emeasure_Sup_measure') auto
  3229   also have "Sup_measure' (M`I) = (SUP i:I. M i)"
  3230     unfolding Sup_measure_def using \<open>I \<noteq> {}\<close> sets sets(1)[THEN sets_eq_imp_space_eq]
  3231     by (intro Sup_lexord1[where P="\<lambda>x. _ = x"]) auto
  3232   also have "(SUP P:{P. finite P \<and> P \<subseteq> M`I}. sup_measure.F id P X) =
  3233     (SUP J:{J. J \<noteq> {} \<and> finite J \<and> J \<subseteq> I}. (SUP i:J. M i) X)"
  3234   proof (intro SUP_eq)
  3235     fix J assume "J \<in> {P. finite P \<and> P \<subseteq> M`I}"
  3236     then obtain J' where J': "J' \<subseteq> I" "finite J'" and J: "J = M`J'" and "finite J"
  3237       using finite_subset_image[of J M I] by auto
  3238     show "\<exists>j\<in>{J. J \<noteq> {} \<and> finite J \<and> J \<subseteq> I}. sup_measure.F id J X \<le> (SUP i:j. M i) X"
  3239     proof cases
  3240       assume "J' = {}" with \<open>i \<in> I\<close> show ?thesis
  3241         by (auto simp add: J)
  3242     next
  3243       assume "J' \<noteq> {}" with J J' show ?thesis
  3244         by (intro bexI[of _ "J'"]) (auto simp add: eq simp del: id_apply)
  3245     qed
  3246   next
  3247     fix J assume J: "J \<in> {P. P \<noteq> {} \<and> finite P \<and> P \<subseteq> I}"
  3248     show "\<exists>J'\<in>{J. finite J \<and> J \<subseteq> M`I}. (SUP i:J. M i) X \<le> sup_measure.F id J' X"
  3249       using J by (intro bexI[of _ "M`J"]) (auto simp add: eq simp del: id_apply)
  3250   qed
  3251   finally show ?thesis .
  3252 qed
  3254 lemma emeasure_SUP_chain:
  3255   assumes sets: "\<And>i. i \<in> A \<Longrightarrow> sets (M i) = sets N" "X \<in> sets N"
  3256   assumes ch: "Complete_Partial_Order.chain op \<le> (M ` A)" and "A \<noteq> {}"
  3257   shows "emeasure (SUP i:A. M i) X = (SUP i:A. emeasure (M i) X)"
  3258 proof (subst emeasure_SUP[OF sets \<open>A \<noteq> {}\<close>])
  3259   show "(SUP J:{J. J \<noteq> {} \<and> finite J \<and> J \<subseteq> A}. emeasure (SUPREMUM J M) X) = (SUP i:A. emeasure (M i) X)"
  3260   proof (rule SUP_eq)
  3261     fix J assume "J \<in> {J. J \<noteq> {} \<and> finite J \<and> J \<subseteq> A}"
  3262     then have J: "Complete_Partial_Order.chain op \<le> (M ` J)" "finite J" "J \<noteq> {}" and "J \<subseteq> A"
  3263       using ch[THEN chain_subset, of "M`J"] by auto
  3264     with in_chain_finite[OF J(1)] obtain j where "j \<in> J" "(SUP j:J. M j) = M j"
  3265       by auto
  3266     with \<open>J \<subseteq> A\<close> show "\<exists>j\<in>A. emeasure (SUPREMUM J M) X \<le> emeasure (M j) X"
  3267       by auto
  3268   next
  3269     fix j assume "j\<in>A" then show "\<exists>i\<in>{J. J \<noteq> {} \<and> finite J \<and> J \<subseteq> A}. emeasure (M j) X \<le> emeasure (SUPREMUM i M) X"
  3270       by (intro bexI[of _ "{j}"]) auto
  3271   qed
  3272 qed
  3274 subsubsection \<open>Supremum of a set of $\sigma$-algebras\<close>
  3276 lemma space_Sup_eq_UN: "space (Sup M) = (\<Union>x\<in>M. space x)"
  3277   unfolding Sup_measure_def
  3278   apply (intro Sup_lexord[where P="\<lambda>x. space x = _"])
  3279   apply (subst space_Sup_measure'2)
  3280   apply auto []
  3281   apply (subst space_measure_of[OF UN_space_closed])
  3282   apply auto
  3283   done
  3285 lemma sets_Sup_eq:
  3286   assumes *: "\<And>m. m \<in> M \<Longrightarrow> space m = X" and "M \<noteq> {}"
  3287   shows "sets (Sup M) = sigma_sets X (\<Union>x\<in>M. sets x)"
  3288   unfolding Sup_measure_def
  3289   apply (rule Sup_lexord1)
  3290   apply fact
  3291   apply (simp add: assms)
  3292   apply (rule Sup_lexord)
  3293   subgoal premises that for a S
  3294     unfolding that(3) that(2)[symmetric]
  3295     using that(1)
  3296     apply (subst sets_Sup_measure'2)
  3297     apply (intro arg_cong2[where f=sigma_sets])
  3298     apply (auto simp: *)
  3299     done
  3300   apply (subst sets_measure_of[OF UN_space_closed])
  3301   apply (simp add:  assms)
  3302   done
  3304 lemma in_sets_Sup: "(\<And>m. m \<in> M \<Longrightarrow> space m = X) \<Longrightarrow> m \<in> M \<Longrightarrow> A \<in> sets m \<Longrightarrow> A \<in> sets (Sup M)"
  3305   by (subst sets_Sup_eq[where X=X]) auto
  3307 lemma Sup_lexord_rel:
  3308   assumes "\<And>i. i \<in> I \<Longrightarrow> k (A i) = k (B i)"
  3309     "R (c (A ` {a \<in> I. k (B a) = (SUP x:I. k (B x))})) (c (B ` {a \<in> I. k (B a) = (SUP x:I. k (B x))}))"
  3310     "R (s (A`I)) (s (B`I))"
  3311   shows "R (Sup_lexord k c s (A`I)) (Sup_lexord k c s (B`I))"
  3312 proof -
  3313   have "A ` {a \<in> I. k (B a) = (SUP x:I. k (B x))} =  {a \<in> A ` I. k a = (SUP x:I. k (B x))}"
  3314     using assms(1) by auto
  3315   moreover have "B ` {a \<in> I. k (B a) = (SUP x:I. k (B x))} =  {a \<in> B ` I. k a = (SUP x:I. k (B x))}"
  3316     by auto
  3317   ultimately show ?thesis
  3318     using assms by (auto simp: Sup_lexord_def Let_def)
  3319 qed
  3321 lemma sets_SUP_cong:
  3322   assumes eq: "\<And>i. i \<in> I \<Longrightarrow> sets (M i) = sets (N i)" shows "sets (SUP i:I. M i) = sets (SUP i:I. N i)"
  3323   unfolding Sup_measure_def
  3324   using eq eq[THEN sets_eq_imp_space_eq]
  3325   apply (intro Sup_lexord_rel[where R="\<lambda>x y. sets x = sets y"])
  3326   apply simp
  3327   apply simp
  3328   apply (simp add: sets_Sup_measure'2)
  3329   apply (intro arg_cong2[where f="\<lambda>x y. sets (sigma x y)"])
  3330   apply auto
  3331   done
  3333 lemma sets_Sup_in_sets:
  3334   assumes "M \<noteq> {}"
  3335   assumes "\<And>m. m \<in> M \<Longrightarrow> space m = space N"
  3336   assumes "\<And>m. m \<in> M \<Longrightarrow> sets m \<subseteq> sets N"
  3337   shows "sets (Sup M) \<subseteq> sets N"
  3338 proof -
  3339   have *: "UNION M space = space N"
  3340     using assms by auto
  3341   show ?thesis
  3342     unfolding * using assms by (subst sets_Sup_eq[of M "space N"]) (auto intro!: sets.sigma_sets_subset)
  3343 qed
  3345 lemma measurable_Sup1:
  3346   assumes m: "m \<in> M" and f: "f \<in> measurable m N"
  3347     and const_space: "\<And>m n. m \<in> M \<Longrightarrow> n \<in> M \<Longrightarrow> space m = space n"
  3348   shows "f \<in> measurable (Sup M) N"
  3349 proof -
  3350   have "space (Sup M) = space m"
  3351     using m by (auto simp add: space_Sup_eq_UN dest: const_space)
  3352   then show ?thesis
  3353     using m f unfolding measurable_def by (auto intro: in_sets_Sup[OF const_space])
  3354 qed
  3356 lemma measurable_Sup2:
  3357   assumes M: "M \<noteq> {}"
  3358   assumes f: "\<And>m. m \<in> M \<Longrightarrow> f \<in> measurable N m"
  3359     and const_space: "\<And>m n. m \<in> M \<Longrightarrow> n \<in> M \<Longrightarrow> space m = space n"
  3360   shows "f \<in> measurable N (Sup M)"
  3361 proof -
  3362   from M obtain m where "m \<in> M" by auto
  3363   have space_eq: "\<And>n. n \<in> M \<Longrightarrow> space n = space m"
  3364     by (intro const_space \<open>m \<in> M\<close>)
  3365   have "f \<in> measurable N (sigma (\<Union>m\<in>M. space m) (\<Union>m\<in>M. sets m))"
  3366   proof (rule measurable_measure_of)
  3367     show "f \<in> space N \<rightarrow> UNION M space"
  3368       using measurable_space[OF f] M by auto
  3369   qed (auto intro: measurable_sets f dest: sets.sets_into_space)
  3370   also have "measurable N (sigma (\<Union>m\<in>M. space m) (\<Union>m\<in>M. sets m)) = measurable N (Sup M)"
  3371     apply (intro measurable_cong_sets refl)
  3372     apply (subst sets_Sup_eq[OF space_eq M])
  3373     apply simp
  3374     apply (subst sets_measure_of[OF UN_space_closed])
  3375     apply (simp add: space_eq M)
  3376     done
  3377   finally show ?thesis .
  3378 qed
  3380 lemma sets_Sup_sigma:
  3381   assumes [simp]: "M \<noteq> {}" and M: "\<And>m. m \<in> M \<Longrightarrow> m \<subseteq> Pow \<Omega>"
  3382   shows "sets (SUP m:M. sigma \<Omega> m) = sets (sigma \<Omega> (\<Union>M))"
  3383 proof -
  3384   { fix a m assume "a \<in> sigma_sets \<Omega> m" "m \<in> M"
  3385     then have "a \<in> sigma_sets \<Omega> (\<Union>M)"
  3386      by induction (auto intro: sigma_sets.intros(2-)) }
  3387   then show "sets (SUP m:M. sigma \<Omega> m) = sets (sigma \<Omega> (\<Union>M))"
  3388     apply (subst sets_Sup_eq[where X="\<Omega>"])
  3389     apply (auto simp add: M) []
  3390     apply auto []
  3391     apply (simp add: space_measure_of_conv M Union_least)
  3392     apply (rule sigma_sets_eqI)
  3393     apply auto
  3394     done
  3395 qed
  3397 lemma Sup_sigma:
  3398   assumes [simp]: "M \<noteq> {}" and M: "\<And>m. m \<in> M \<Longrightarrow> m \<subseteq> Pow \<Omega>"
  3399   shows "(SUP m:M. sigma \<Omega> m) = (sigma \<Omega> (\<Union>M))"
  3400 proof (intro antisym SUP_least)
  3401   have *: "\<Union>M \<subseteq> Pow \<Omega>"
  3402     using M by auto
  3403   show "sigma \<Omega> (\<Union>M) \<le> (SUP m:M. sigma \<Omega> m)"
  3404   proof (intro less_eq_measure.intros(3))
  3405     show "space (sigma \<Omega> (\<Union>M)) = space (SUP m:M. sigma \<Omega> m)"
  3406       "sets (sigma \<Omega> (\<Union>M)) = sets (SUP m:M. sigma \<Omega> m)"
  3407       using sets_Sup_sigma[OF assms] sets_Sup_sigma[OF assms, THEN sets_eq_imp_space_eq]
  3408       by auto
  3409   qed (simp add: emeasure_sigma le_fun_def)
  3410   fix m assume "m \<in> M" then show "sigma \<Omega> m \<le> sigma \<Omega> (\<Union>M)"
  3411     by (subst sigma_le_iff) (auto simp add: M *)
  3412 qed
  3414 lemma SUP_sigma_sigma:
  3415   "M \<noteq> {} \<Longrightarrow> (\<And>m. m \<in> M \<Longrightarrow> f m \<subseteq> Pow \<Omega>) \<Longrightarrow> (SUP m:M. sigma \<Omega> (f m)) = sigma \<Omega> (\<Union>m\<in>M. f m)"
  3416   using Sup_sigma[of "f`M" \<Omega>] by auto
  3418 lemma sets_vimage_Sup_eq:
  3419   assumes *: "M \<noteq> {}" "f \<in> X \<rightarrow> Y" "\<And>m. m \<in> M \<Longrightarrow> space m = Y"
  3420   shows "sets (vimage_algebra X f (Sup M)) = sets (SUP m : M. vimage_algebra X f m)"
  3421   (is "?IS = ?SI")
  3422 proof
  3423   show "?IS \<subseteq> ?SI"
  3424     apply (intro sets_image_in_sets measurable_Sup2)
  3425     apply (simp add: space_Sup_eq_UN *)
  3426     apply (simp add: *)
  3427     apply (intro measurable_Sup1)
  3428     apply (rule imageI)
  3429     apply assumption
  3430     apply (rule measurable_vimage_algebra1)
  3431     apply (auto simp: *)
  3432     done
  3433   show "?SI \<subseteq> ?IS"
  3434     apply (intro sets_Sup_in_sets)
  3435     apply (auto simp: *) []
  3436     apply (auto simp: *) []
  3437     apply (elim imageE)
  3438     apply simp
  3439     apply (rule sets_image_in_sets)
  3440     apply simp
  3441     apply (simp add: measurable_def)
  3442     apply (simp add: * space_Sup_eq_UN sets_vimage_algebra2)
  3443     apply (auto intro: in_sets_Sup[OF *(3)])
  3444     done
  3445 qed
  3447 lemma restrict_space_eq_vimage_algebra':
  3448   "sets (restrict_space M \<Omega>) = sets (vimage_algebra (\<Omega> \<inter> space M) (\<lambda>x. x) M)"
  3449 proof -
  3450   have *: "{A \<inter> (\<Omega> \<inter> space M) |A. A \<in> sets M} = {A \<inter> \<Omega> |A. A \<in> sets M}"
  3451     using sets.sets_into_space[of _ M] by blast
  3453   show ?thesis
  3454     unfolding restrict_space_def
  3455     by (subst sets_measure_of)
  3456        (auto simp add: image_subset_iff sets_vimage_algebra * dest: sets.sets_into_space intro!: arg_cong2[where f=sigma_sets])
  3457 qed
  3459 lemma sigma_le_sets:
  3460   assumes [simp]: "A \<subseteq> Pow X" shows "sets (sigma X A) \<subseteq> sets N \<longleftrightarrow> X \<in> sets N \<and> A \<subseteq> sets N"
  3461 proof
  3462   have "X \<in> sigma_sets X A" "A \<subseteq> sigma_sets X A"
  3463     by (auto intro: sigma_sets_top)
  3464   moreover assume "sets (sigma X A) \<subseteq> sets N"
  3465   ultimately show "X \<in> sets N \<and> A \<subseteq> sets N"
  3466     by auto
  3467 next
  3468   assume *: "X \<in> sets N \<and> A \<subseteq> sets N"
  3469   { fix Y assume "Y \<in> sigma_sets X A" from this * have "Y \<in> sets N"
  3470       by induction auto }
  3471   then show "sets (sigma X A) \<subseteq> sets N"
  3472     by auto
  3473 qed
  3475 lemma measurable_iff_sets:
  3476   "f \<in> measurable M N \<longleftrightarrow> (f \<in> space M \<rightarrow> space N \<and> sets (vimage_algebra (space M) f N) \<subseteq> sets M)"
  3477 proof -
  3478   have *: "{f -` A \<inter> space M |A. A \<in> sets N} \<subseteq> Pow (space M)"
  3479     by auto
  3480   show ?thesis
  3481     unfolding measurable_def
  3482     by (auto simp add: vimage_algebra_def sigma_le_sets[OF *])
  3483 qed
  3485 lemma sets_vimage_algebra_space: "X \<in> sets (vimage_algebra X f M)"
  3486   using[of "vimage_algebra X f M"] by simp
  3488 lemma measurable_mono:
  3489   assumes N: "sets N' \<le> sets N" "space N = space N'"
  3490   assumes M: "sets M \<le> sets M'" "space M = space M'"
  3491   shows "measurable M N \<subseteq> measurable M' N'"
  3492   unfolding measurable_def
  3493 proof safe
  3494   fix f A assume "f \<in> space M \<rightarrow> space N" "A \<in> sets N'"
  3495   moreover assume "\<forall>y\<in>sets N. f -` y \<inter> space M \<in> sets M" note this[THEN bspec, of A]
  3496   ultimately show "f -` A \<inter> space M' \<in> sets M'"
  3497     using assms by auto
  3498 qed (insert N M, auto)
  3500 lemma measurable_Sup_measurable:
  3501   assumes f: "f \<in> space N \<rightarrow> A"
  3502   shows "f \<in> measurable N (Sup {M. space M = A \<and> f \<in> measurable N M})"
  3503 proof (rule measurable_Sup2)
  3504   show "{M. space M = A \<and> f \<in> measurable N M} \<noteq> {}"
  3505     using f unfolding ex_in_conv[symmetric]
  3506     by (intro exI[of _ "sigma A {}"]) (auto intro!: measurable_measure_of)
  3507 qed auto
  3509 lemma (in sigma_algebra) sigma_sets_subset':
  3510   assumes a: "a \<subseteq> M" "\<Omega>' \<in> M"
  3511   shows "sigma_sets \<Omega>' a \<subseteq> M"
  3512 proof
  3513   show "x \<in> M" if x: "x \<in> sigma_sets \<Omega>' a" for x
  3514     using x by (induct rule: sigma_sets.induct) (insert a, auto)
  3515 qed
  3517 lemma in_sets_SUP: "i \<in> I \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> space (M i) = Y) \<Longrightarrow> X \<in> sets (M i) \<Longrightarrow> X \<in> sets (SUP i:I. M i)"
  3518   by (intro in_sets_Sup[where X=Y]) auto
  3520 lemma measurable_SUP1:
  3521   "i \<in> I \<Longrightarrow> f \<in> measurable (M i) N \<Longrightarrow> (\<And>m n. m \<in> I \<Longrightarrow> n \<in> I \<Longrightarrow> space (M m) = space (M n)) \<Longrightarrow>
  3522     f \<in> measurable (SUP i:I. M i) N"
  3523   by (auto intro: measurable_Sup1)
  3525 lemma sets_image_in_sets':
  3526   assumes X: "X \<in> sets N"
  3527   assumes f: "\<And>A. A \<in> sets M \<Longrightarrow> f -` A \<inter> X \<in> sets N"
  3528   shows "sets (vimage_algebra X f M) \<subseteq> sets N"
  3529   unfolding sets_vimage_algebra
  3530   by (rule sets.sigma_sets_subset') (auto intro!: measurable_sets X f)
  3532 lemma mono_vimage_algebra:
  3533   "sets M \<le> sets N \<Longrightarrow> sets (vimage_algebra X f M) \<subseteq> sets (vimage_algebra X f N)"
  3534   using[of "sigma X {f -` A \<inter> X |A. A \<in> sets N}"]
  3535   unfolding vimage_algebra_def
  3536   apply (subst (asm) space_measure_of)
  3537   apply auto []
  3538   apply (subst sigma_le_sets)
  3539   apply auto
  3540   done
  3542 lemma mono_restrict_space: "sets M \<le> sets N \<Longrightarrow> sets (restrict_space M X) \<subseteq> sets (restrict_space N X)"
  3543   unfolding sets_restrict_space by (rule image_mono)
  3545 lemma sets_eq_bot: "sets M = {{}} \<longleftrightarrow> M = bot"
  3546   apply safe
  3547   apply (intro measure_eqI)
  3548   apply auto
  3549   done
  3551 lemma sets_eq_bot2: "{{}} = sets M \<longleftrightarrow> M = bot"
  3552   using sets_eq_bot[of M] by blast
  3555 lemma (in finite_measure) countable_support:
  3556   "countable {x. measure M {x} \<noteq> 0}"
  3557 proof cases
  3558   assume "measure M (space M) = 0"
  3559   with bounded_measure measure_le_0_iff have "{x. measure M {x} \<noteq> 0} = {}"
  3560     by auto
  3561   then show ?thesis
  3562     by simp
  3563 next
  3564   let ?M = "measure M (space M)" and ?m = "\<lambda>x. measure M {x}"
  3565   assume "?M \<noteq> 0"
  3566   then have *: "{x. ?m x \<noteq> 0} = (\<Union>n. {x. ?M / Suc n < ?m x})"
  3567     using reals_Archimedean[of "?m x / ?M" for x]
  3568     by (auto simp: field_simps not_le[symmetric] divide_le_0_iff measure_le_0_iff)
  3569   have **: "\<And>n. finite {x. ?M / Suc n < ?m x}"
  3570   proof (rule ccontr)
  3571     fix n assume "infinite {x. ?M / Suc n < ?m x}" (is "infinite ?X")
  3572     then obtain X where "finite X" "card X = Suc (Suc n)" "X \<subseteq> ?X"
  3573       by (metis infinite_arbitrarily_large)
  3574     from this(3) have *: "\<And>x. x \<in> X \<Longrightarrow> ?M / Suc n \<le> ?m x"
  3575       by auto
  3576     { fix x assume "x \<in> X"
  3577       from \<open>?M \<noteq> 0\<close> *[OF this] have "?m x \<noteq> 0" by (auto simp: field_simps measure_le_0_iff)
  3578       then have "{x} \<in> sets M" by (auto dest: measure_notin_sets) }
  3579     note singleton_sets = this
  3580     have "?M < (\<Sum>x\<in>X. ?M / Suc n)"
  3581       using \<open>?M \<noteq> 0\<close>
  3582       by (simp add: \<open>card X = Suc (Suc n)\<close> field_simps less_le)
  3583     also have "\<dots> \<le> (\<Sum>x\<in>X. ?m x)"
  3584       by (rule sum_mono) fact
  3585     also have "\<dots> = measure M (\<Union>x\<in>X. {x})"
  3586       using singleton_sets \<open>finite X\<close>
  3587       by (intro finite_measure_finite_Union[symmetric]) (auto simp: disjoint_family_on_def)
  3588     finally have "?M < measure M (\<Union>x\<in>X. {x})" .
  3589     moreover have "measure M (\<Union>x\<in>X. {x}) \<le> ?M"
  3590       using singleton_sets[THEN sets.sets_into_space] by (intro finite_measure_mono) auto
  3591     ultimately show False by simp
  3592   qed
  3593   show ?thesis
  3594     unfolding * by (intro countable_UN countableI_type countable_finite[OF **])
  3595 qed
  3597 end