src/HOL/Real.thy
author nipkow
Mon Oct 17 11:46:22 2016 +0200 (2016-10-17)
changeset 64267 b9a1486e79be
parent 63961 2fd9656c4c82
child 65885 77d922eff5ac
permissions -rw-r--r--
setsum -> sum
     1 (*  Title:      HOL/Real.thy
     2     Author:     Jacques D. Fleuriot, University of Edinburgh, 1998
     3     Author:     Larry Paulson, University of Cambridge
     4     Author:     Jeremy Avigad, Carnegie Mellon University
     5     Author:     Florian Zuleger, Johannes Hoelzl, and Simon Funke, TU Muenchen
     6     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     7     Construction of Cauchy Reals by Brian Huffman, 2010
     8 *)
     9 
    10 section \<open>Development of the Reals using Cauchy Sequences\<close>
    11 
    12 theory Real
    13 imports Rat
    14 begin
    15 
    16 text \<open>
    17   This theory contains a formalization of the real numbers as equivalence
    18   classes of Cauchy sequences of rationals. See
    19   \<^file>\<open>~~/src/HOL/ex/Dedekind_Real.thy\<close> for an alternative construction using
    20   Dedekind cuts.
    21 \<close>
    22 
    23 
    24 subsection \<open>Preliminary lemmas\<close>
    25 
    26 lemma inj_add_left [simp]: "inj (op + x)"
    27   for x :: "'a::cancel_semigroup_add"
    28   by (meson add_left_imp_eq injI)
    29 
    30 lemma inj_mult_left [simp]: "inj (op * x) \<longleftrightarrow> x \<noteq> 0"
    31   for x :: "'a::idom"
    32   by (metis injI mult_cancel_left the_inv_f_f zero_neq_one)
    33 
    34 lemma add_diff_add: "(a + c) - (b + d) = (a - b) + (c - d)"
    35   for a b c d :: "'a::ab_group_add"
    36   by simp
    37 
    38 lemma minus_diff_minus: "- a - - b = - (a - b)"
    39   for a b :: "'a::ab_group_add"
    40   by simp
    41 
    42 lemma mult_diff_mult: "(x * y - a * b) = x * (y - b) + (x - a) * b"
    43   for x y a b :: "'a::ring"
    44   by (simp add: algebra_simps)
    45 
    46 lemma inverse_diff_inverse:
    47   fixes a b :: "'a::division_ring"
    48   assumes "a \<noteq> 0" and "b \<noteq> 0"
    49   shows "inverse a - inverse b = - (inverse a * (a - b) * inverse b)"
    50   using assms by (simp add: algebra_simps)
    51 
    52 lemma obtain_pos_sum:
    53   fixes r :: rat assumes r: "0 < r"
    54   obtains s t where "0 < s" and "0 < t" and "r = s + t"
    55 proof
    56   from r show "0 < r/2" by simp
    57   from r show "0 < r/2" by simp
    58   show "r = r/2 + r/2" by simp
    59 qed
    60 
    61 
    62 subsection \<open>Sequences that converge to zero\<close>
    63 
    64 definition vanishes :: "(nat \<Rightarrow> rat) \<Rightarrow> bool"
    65   where "vanishes X \<longleftrightarrow> (\<forall>r>0. \<exists>k. \<forall>n\<ge>k. \<bar>X n\<bar> < r)"
    66 
    67 lemma vanishesI: "(\<And>r. 0 < r \<Longrightarrow> \<exists>k. \<forall>n\<ge>k. \<bar>X n\<bar> < r) \<Longrightarrow> vanishes X"
    68   unfolding vanishes_def by simp
    69 
    70 lemma vanishesD: "vanishes X \<Longrightarrow> 0 < r \<Longrightarrow> \<exists>k. \<forall>n\<ge>k. \<bar>X n\<bar> < r"
    71   unfolding vanishes_def by simp
    72 
    73 lemma vanishes_const [simp]: "vanishes (\<lambda>n. c) \<longleftrightarrow> c = 0"
    74   unfolding vanishes_def
    75   apply (cases "c = 0")
    76    apply auto
    77   apply (rule exI [where x = "\<bar>c\<bar>"])
    78   apply auto
    79   done
    80 
    81 lemma vanishes_minus: "vanishes X \<Longrightarrow> vanishes (\<lambda>n. - X n)"
    82   unfolding vanishes_def by simp
    83 
    84 lemma vanishes_add:
    85   assumes X: "vanishes X"
    86     and Y: "vanishes Y"
    87   shows "vanishes (\<lambda>n. X n + Y n)"
    88 proof (rule vanishesI)
    89   fix r :: rat
    90   assume "0 < r"
    91   then obtain s t where s: "0 < s" and t: "0 < t" and r: "r = s + t"
    92     by (rule obtain_pos_sum)
    93   obtain i where i: "\<forall>n\<ge>i. \<bar>X n\<bar> < s"
    94     using vanishesD [OF X s] ..
    95   obtain j where j: "\<forall>n\<ge>j. \<bar>Y n\<bar> < t"
    96     using vanishesD [OF Y t] ..
    97   have "\<forall>n\<ge>max i j. \<bar>X n + Y n\<bar> < r"
    98   proof clarsimp
    99     fix n
   100     assume n: "i \<le> n" "j \<le> n"
   101     have "\<bar>X n + Y n\<bar> \<le> \<bar>X n\<bar> + \<bar>Y n\<bar>"
   102       by (rule abs_triangle_ineq)
   103     also have "\<dots> < s + t"
   104       by (simp add: add_strict_mono i j n)
   105     finally show "\<bar>X n + Y n\<bar> < r"
   106       by (simp only: r)
   107   qed
   108   then show "\<exists>k. \<forall>n\<ge>k. \<bar>X n + Y n\<bar> < r" ..
   109 qed
   110 
   111 lemma vanishes_diff:
   112   assumes "vanishes X" "vanishes Y"
   113   shows "vanishes (\<lambda>n. X n - Y n)"
   114   unfolding diff_conv_add_uminus by (intro vanishes_add vanishes_minus assms)
   115 
   116 lemma vanishes_mult_bounded:
   117   assumes X: "\<exists>a>0. \<forall>n. \<bar>X n\<bar> < a"
   118   assumes Y: "vanishes (\<lambda>n. Y n)"
   119   shows "vanishes (\<lambda>n. X n * Y n)"
   120 proof (rule vanishesI)
   121   fix r :: rat
   122   assume r: "0 < r"
   123   obtain a where a: "0 < a" "\<forall>n. \<bar>X n\<bar> < a"
   124     using X by blast
   125   obtain b where b: "0 < b" "r = a * b"
   126   proof
   127     show "0 < r / a" using r a by simp
   128     show "r = a * (r / a)" using a by simp
   129   qed
   130   obtain k where k: "\<forall>n\<ge>k. \<bar>Y n\<bar> < b"
   131     using vanishesD [OF Y b(1)] ..
   132   have "\<forall>n\<ge>k. \<bar>X n * Y n\<bar> < r"
   133     by (simp add: b(2) abs_mult mult_strict_mono' a k)
   134   then show "\<exists>k. \<forall>n\<ge>k. \<bar>X n * Y n\<bar> < r" ..
   135 qed
   136 
   137 
   138 subsection \<open>Cauchy sequences\<close>
   139 
   140 definition cauchy :: "(nat \<Rightarrow> rat) \<Rightarrow> bool"
   141   where "cauchy X \<longleftrightarrow> (\<forall>r>0. \<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>X m - X n\<bar> < r)"
   142 
   143 lemma cauchyI: "(\<And>r. 0 < r \<Longrightarrow> \<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>X m - X n\<bar> < r) \<Longrightarrow> cauchy X"
   144   unfolding cauchy_def by simp
   145 
   146 lemma cauchyD: "cauchy X \<Longrightarrow> 0 < r \<Longrightarrow> \<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>X m - X n\<bar> < r"
   147   unfolding cauchy_def by simp
   148 
   149 lemma cauchy_const [simp]: "cauchy (\<lambda>n. x)"
   150   unfolding cauchy_def by simp
   151 
   152 lemma cauchy_add [simp]:
   153   assumes X: "cauchy X" and Y: "cauchy Y"
   154   shows "cauchy (\<lambda>n. X n + Y n)"
   155 proof (rule cauchyI)
   156   fix r :: rat
   157   assume "0 < r"
   158   then obtain s t where s: "0 < s" and t: "0 < t" and r: "r = s + t"
   159     by (rule obtain_pos_sum)
   160   obtain i where i: "\<forall>m\<ge>i. \<forall>n\<ge>i. \<bar>X m - X n\<bar> < s"
   161     using cauchyD [OF X s] ..
   162   obtain j where j: "\<forall>m\<ge>j. \<forall>n\<ge>j. \<bar>Y m - Y n\<bar> < t"
   163     using cauchyD [OF Y t] ..
   164   have "\<forall>m\<ge>max i j. \<forall>n\<ge>max i j. \<bar>(X m + Y m) - (X n + Y n)\<bar> < r"
   165   proof clarsimp
   166     fix m n
   167     assume *: "i \<le> m" "j \<le> m" "i \<le> n" "j \<le> n"
   168     have "\<bar>(X m + Y m) - (X n + Y n)\<bar> \<le> \<bar>X m - X n\<bar> + \<bar>Y m - Y n\<bar>"
   169       unfolding add_diff_add by (rule abs_triangle_ineq)
   170     also have "\<dots> < s + t"
   171       by (rule add_strict_mono) (simp_all add: i j *)
   172     finally show "\<bar>(X m + Y m) - (X n + Y n)\<bar> < r" by (simp only: r)
   173   qed
   174   then show "\<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>(X m + Y m) - (X n + Y n)\<bar> < r" ..
   175 qed
   176 
   177 lemma cauchy_minus [simp]:
   178   assumes X: "cauchy X"
   179   shows "cauchy (\<lambda>n. - X n)"
   180   using assms unfolding cauchy_def
   181   unfolding minus_diff_minus abs_minus_cancel .
   182 
   183 lemma cauchy_diff [simp]:
   184   assumes "cauchy X" "cauchy Y"
   185   shows "cauchy (\<lambda>n. X n - Y n)"
   186   using assms unfolding diff_conv_add_uminus by (simp del: add_uminus_conv_diff)
   187 
   188 lemma cauchy_imp_bounded:
   189   assumes "cauchy X"
   190   shows "\<exists>b>0. \<forall>n. \<bar>X n\<bar> < b"
   191 proof -
   192   obtain k where k: "\<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>X m - X n\<bar> < 1"
   193     using cauchyD [OF assms zero_less_one] ..
   194   show "\<exists>b>0. \<forall>n. \<bar>X n\<bar> < b"
   195   proof (intro exI conjI allI)
   196     have "0 \<le> \<bar>X 0\<bar>" by simp
   197     also have "\<bar>X 0\<bar> \<le> Max (abs ` X ` {..k})" by simp
   198     finally have "0 \<le> Max (abs ` X ` {..k})" .
   199     then show "0 < Max (abs ` X ` {..k}) + 1" by simp
   200   next
   201     fix n :: nat
   202     show "\<bar>X n\<bar> < Max (abs ` X ` {..k}) + 1"
   203     proof (rule linorder_le_cases)
   204       assume "n \<le> k"
   205       then have "\<bar>X n\<bar> \<le> Max (abs ` X ` {..k})" by simp
   206       then show "\<bar>X n\<bar> < Max (abs ` X ` {..k}) + 1" by simp
   207     next
   208       assume "k \<le> n"
   209       have "\<bar>X n\<bar> = \<bar>X k + (X n - X k)\<bar>" by simp
   210       also have "\<bar>X k + (X n - X k)\<bar> \<le> \<bar>X k\<bar> + \<bar>X n - X k\<bar>"
   211         by (rule abs_triangle_ineq)
   212       also have "\<dots> < Max (abs ` X ` {..k}) + 1"
   213         by (rule add_le_less_mono) (simp_all add: k \<open>k \<le> n\<close>)
   214       finally show "\<bar>X n\<bar> < Max (abs ` X ` {..k}) + 1" .
   215     qed
   216   qed
   217 qed
   218 
   219 lemma cauchy_mult [simp]:
   220   assumes X: "cauchy X" and Y: "cauchy Y"
   221   shows "cauchy (\<lambda>n. X n * Y n)"
   222 proof (rule cauchyI)
   223   fix r :: rat assume "0 < r"
   224   then obtain u v where u: "0 < u" and v: "0 < v" and "r = u + v"
   225     by (rule obtain_pos_sum)
   226   obtain a where a: "0 < a" "\<forall>n. \<bar>X n\<bar> < a"
   227     using cauchy_imp_bounded [OF X] by blast
   228   obtain b where b: "0 < b" "\<forall>n. \<bar>Y n\<bar> < b"
   229     using cauchy_imp_bounded [OF Y] by blast
   230   obtain s t where s: "0 < s" and t: "0 < t" and r: "r = a * t + s * b"
   231   proof
   232     show "0 < v/b" using v b(1) by simp
   233     show "0 < u/a" using u a(1) by simp
   234     show "r = a * (u/a) + (v/b) * b"
   235       using a(1) b(1) \<open>r = u + v\<close> by simp
   236   qed
   237   obtain i where i: "\<forall>m\<ge>i. \<forall>n\<ge>i. \<bar>X m - X n\<bar> < s"
   238     using cauchyD [OF X s] ..
   239   obtain j where j: "\<forall>m\<ge>j. \<forall>n\<ge>j. \<bar>Y m - Y n\<bar> < t"
   240     using cauchyD [OF Y t] ..
   241   have "\<forall>m\<ge>max i j. \<forall>n\<ge>max i j. \<bar>X m * Y m - X n * Y n\<bar> < r"
   242   proof clarsimp
   243     fix m n
   244     assume *: "i \<le> m" "j \<le> m" "i \<le> n" "j \<le> n"
   245     have "\<bar>X m * Y m - X n * Y n\<bar> = \<bar>X m * (Y m - Y n) + (X m - X n) * Y n\<bar>"
   246       unfolding mult_diff_mult ..
   247     also have "\<dots> \<le> \<bar>X m * (Y m - Y n)\<bar> + \<bar>(X m - X n) * Y n\<bar>"
   248       by (rule abs_triangle_ineq)
   249     also have "\<dots> = \<bar>X m\<bar> * \<bar>Y m - Y n\<bar> + \<bar>X m - X n\<bar> * \<bar>Y n\<bar>"
   250       unfolding abs_mult ..
   251     also have "\<dots> < a * t + s * b"
   252       by (simp_all add: add_strict_mono mult_strict_mono' a b i j *)
   253     finally show "\<bar>X m * Y m - X n * Y n\<bar> < r"
   254       by (simp only: r)
   255   qed
   256   then show "\<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>X m * Y m - X n * Y n\<bar> < r" ..
   257 qed
   258 
   259 lemma cauchy_not_vanishes_cases:
   260   assumes X: "cauchy X"
   261   assumes nz: "\<not> vanishes X"
   262   shows "\<exists>b>0. \<exists>k. (\<forall>n\<ge>k. b < - X n) \<or> (\<forall>n\<ge>k. b < X n)"
   263 proof -
   264   obtain r where "0 < r" and r: "\<forall>k. \<exists>n\<ge>k. r \<le> \<bar>X n\<bar>"
   265     using nz unfolding vanishes_def by (auto simp add: not_less)
   266   obtain s t where s: "0 < s" and t: "0 < t" and "r = s + t"
   267     using \<open>0 < r\<close> by (rule obtain_pos_sum)
   268   obtain i where i: "\<forall>m\<ge>i. \<forall>n\<ge>i. \<bar>X m - X n\<bar> < s"
   269     using cauchyD [OF X s] ..
   270   obtain k where "i \<le> k" and "r \<le> \<bar>X k\<bar>"
   271     using r by blast
   272   have k: "\<forall>n\<ge>k. \<bar>X n - X k\<bar> < s"
   273     using i \<open>i \<le> k\<close> by auto
   274   have "X k \<le> - r \<or> r \<le> X k"
   275     using \<open>r \<le> \<bar>X k\<bar>\<close> by auto
   276   then have "(\<forall>n\<ge>k. t < - X n) \<or> (\<forall>n\<ge>k. t < X n)"
   277     unfolding \<open>r = s + t\<close> using k by auto
   278   then have "\<exists>k. (\<forall>n\<ge>k. t < - X n) \<or> (\<forall>n\<ge>k. t < X n)" ..
   279   then show "\<exists>t>0. \<exists>k. (\<forall>n\<ge>k. t < - X n) \<or> (\<forall>n\<ge>k. t < X n)"
   280     using t by auto
   281 qed
   282 
   283 lemma cauchy_not_vanishes:
   284   assumes X: "cauchy X"
   285     and nz: "\<not> vanishes X"
   286   shows "\<exists>b>0. \<exists>k. \<forall>n\<ge>k. b < \<bar>X n\<bar>"
   287   using cauchy_not_vanishes_cases [OF assms]
   288   apply clarify
   289   apply (rule exI)
   290   apply (erule conjI)
   291   apply (rule_tac x = k in exI)
   292   apply auto
   293   done
   294 
   295 lemma cauchy_inverse [simp]:
   296   assumes X: "cauchy X"
   297     and nz: "\<not> vanishes X"
   298   shows "cauchy (\<lambda>n. inverse (X n))"
   299 proof (rule cauchyI)
   300   fix r :: rat
   301   assume "0 < r"
   302   obtain b i where b: "0 < b" and i: "\<forall>n\<ge>i. b < \<bar>X n\<bar>"
   303     using cauchy_not_vanishes [OF X nz] by blast
   304   from b i have nz: "\<forall>n\<ge>i. X n \<noteq> 0" by auto
   305   obtain s where s: "0 < s" and r: "r = inverse b * s * inverse b"
   306   proof
   307     show "0 < b * r * b" by (simp add: \<open>0 < r\<close> b)
   308     show "r = inverse b * (b * r * b) * inverse b"
   309       using b by simp
   310   qed
   311   obtain j where j: "\<forall>m\<ge>j. \<forall>n\<ge>j. \<bar>X m - X n\<bar> < s"
   312     using cauchyD [OF X s] ..
   313   have "\<forall>m\<ge>max i j. \<forall>n\<ge>max i j. \<bar>inverse (X m) - inverse (X n)\<bar> < r"
   314   proof clarsimp
   315     fix m n
   316     assume *: "i \<le> m" "j \<le> m" "i \<le> n" "j \<le> n"
   317     have "\<bar>inverse (X m) - inverse (X n)\<bar> = inverse \<bar>X m\<bar> * \<bar>X m - X n\<bar> * inverse \<bar>X n\<bar>"
   318       by (simp add: inverse_diff_inverse nz * abs_mult)
   319     also have "\<dots> < inverse b * s * inverse b"
   320       by (simp add: mult_strict_mono less_imp_inverse_less i j b * s)
   321     finally show "\<bar>inverse (X m) - inverse (X n)\<bar> < r" by (simp only: r)
   322   qed
   323   then show "\<exists>k. \<forall>m\<ge>k. \<forall>n\<ge>k. \<bar>inverse (X m) - inverse (X n)\<bar> < r" ..
   324 qed
   325 
   326 lemma vanishes_diff_inverse:
   327   assumes X: "cauchy X" "\<not> vanishes X"
   328     and Y: "cauchy Y" "\<not> vanishes Y"
   329     and XY: "vanishes (\<lambda>n. X n - Y n)"
   330   shows "vanishes (\<lambda>n. inverse (X n) - inverse (Y n))"
   331 proof (rule vanishesI)
   332   fix r :: rat
   333   assume r: "0 < r"
   334   obtain a i where a: "0 < a" and i: "\<forall>n\<ge>i. a < \<bar>X n\<bar>"
   335     using cauchy_not_vanishes [OF X] by blast
   336   obtain b j where b: "0 < b" and j: "\<forall>n\<ge>j. b < \<bar>Y n\<bar>"
   337     using cauchy_not_vanishes [OF Y] by blast
   338   obtain s where s: "0 < s" and "inverse a * s * inverse b = r"
   339   proof
   340     show "0 < a * r * b"
   341       using a r b by simp
   342     show "inverse a * (a * r * b) * inverse b = r"
   343       using a r b by simp
   344   qed
   345   obtain k where k: "\<forall>n\<ge>k. \<bar>X n - Y n\<bar> < s"
   346     using vanishesD [OF XY s] ..
   347   have "\<forall>n\<ge>max (max i j) k. \<bar>inverse (X n) - inverse (Y n)\<bar> < r"
   348   proof clarsimp
   349     fix n
   350     assume n: "i \<le> n" "j \<le> n" "k \<le> n"
   351     with i j a b have "X n \<noteq> 0" and "Y n \<noteq> 0"
   352       by auto
   353     then have "\<bar>inverse (X n) - inverse (Y n)\<bar> = inverse \<bar>X n\<bar> * \<bar>X n - Y n\<bar> * inverse \<bar>Y n\<bar>"
   354       by (simp add: inverse_diff_inverse abs_mult)
   355     also have "\<dots> < inverse a * s * inverse b"
   356       by (intro mult_strict_mono' less_imp_inverse_less) (simp_all add: a b i j k n)
   357     also note \<open>inverse a * s * inverse b = r\<close>
   358     finally show "\<bar>inverse (X n) - inverse (Y n)\<bar> < r" .
   359   qed
   360   then show "\<exists>k. \<forall>n\<ge>k. \<bar>inverse (X n) - inverse (Y n)\<bar> < r" ..
   361 qed
   362 
   363 
   364 subsection \<open>Equivalence relation on Cauchy sequences\<close>
   365 
   366 definition realrel :: "(nat \<Rightarrow> rat) \<Rightarrow> (nat \<Rightarrow> rat) \<Rightarrow> bool"
   367   where "realrel = (\<lambda>X Y. cauchy X \<and> cauchy Y \<and> vanishes (\<lambda>n. X n - Y n))"
   368 
   369 lemma realrelI [intro?]: "cauchy X \<Longrightarrow> cauchy Y \<Longrightarrow> vanishes (\<lambda>n. X n - Y n) \<Longrightarrow> realrel X Y"
   370   by (simp add: realrel_def)
   371 
   372 lemma realrel_refl: "cauchy X \<Longrightarrow> realrel X X"
   373   by (simp add: realrel_def)
   374 
   375 lemma symp_realrel: "symp realrel"
   376   unfolding realrel_def
   377   apply (rule sympI)
   378   apply clarify
   379   apply (drule vanishes_minus)
   380   apply simp
   381   done
   382 
   383 lemma transp_realrel: "transp realrel"
   384   unfolding realrel_def
   385   apply (rule transpI)
   386   apply clarify
   387   apply (drule (1) vanishes_add)
   388   apply (simp add: algebra_simps)
   389   done
   390 
   391 lemma part_equivp_realrel: "part_equivp realrel"
   392   by (blast intro: part_equivpI symp_realrel transp_realrel realrel_refl cauchy_const)
   393 
   394 
   395 subsection \<open>The field of real numbers\<close>
   396 
   397 quotient_type real = "nat \<Rightarrow> rat" / partial: realrel
   398   morphisms rep_real Real
   399   by (rule part_equivp_realrel)
   400 
   401 lemma cr_real_eq: "pcr_real = (\<lambda>x y. cauchy x \<and> Real x = y)"
   402   unfolding real.pcr_cr_eq cr_real_def realrel_def by auto
   403 
   404 lemma Real_induct [induct type: real]: (* TODO: generate automatically *)
   405   assumes "\<And>X. cauchy X \<Longrightarrow> P (Real X)"
   406   shows "P x"
   407 proof (induct x)
   408   case (1 X)
   409   then have "cauchy X" by (simp add: realrel_def)
   410   then show "P (Real X)" by (rule assms)
   411 qed
   412 
   413 lemma eq_Real: "cauchy X \<Longrightarrow> cauchy Y \<Longrightarrow> Real X = Real Y \<longleftrightarrow> vanishes (\<lambda>n. X n - Y n)"
   414   using real.rel_eq_transfer
   415   unfolding real.pcr_cr_eq cr_real_def rel_fun_def realrel_def by simp
   416 
   417 lemma Domainp_pcr_real [transfer_domain_rule]: "Domainp pcr_real = cauchy"
   418   by (simp add: real.domain_eq realrel_def)
   419 
   420 instantiation real :: field
   421 begin
   422 
   423 lift_definition zero_real :: "real" is "\<lambda>n. 0"
   424   by (simp add: realrel_refl)
   425 
   426 lift_definition one_real :: "real" is "\<lambda>n. 1"
   427   by (simp add: realrel_refl)
   428 
   429 lift_definition plus_real :: "real \<Rightarrow> real \<Rightarrow> real" is "\<lambda>X Y n. X n + Y n"
   430   unfolding realrel_def add_diff_add
   431   by (simp only: cauchy_add vanishes_add simp_thms)
   432 
   433 lift_definition uminus_real :: "real \<Rightarrow> real" is "\<lambda>X n. - X n"
   434   unfolding realrel_def minus_diff_minus
   435   by (simp only: cauchy_minus vanishes_minus simp_thms)
   436 
   437 lift_definition times_real :: "real \<Rightarrow> real \<Rightarrow> real" is "\<lambda>X Y n. X n * Y n"
   438   unfolding realrel_def mult_diff_mult
   439   apply (subst (4) mult.commute)
   440   apply (simp only: cauchy_mult vanishes_add vanishes_mult_bounded cauchy_imp_bounded simp_thms)
   441   done
   442 
   443 lift_definition inverse_real :: "real \<Rightarrow> real"
   444   is "\<lambda>X. if vanishes X then (\<lambda>n. 0) else (\<lambda>n. inverse (X n))"
   445 proof -
   446   fix X Y
   447   assume "realrel X Y"
   448   then have X: "cauchy X" and Y: "cauchy Y" and XY: "vanishes (\<lambda>n. X n - Y n)"
   449     by (simp_all add: realrel_def)
   450   have "vanishes X \<longleftrightarrow> vanishes Y"
   451   proof
   452     assume "vanishes X"
   453     from vanishes_diff [OF this XY] show "vanishes Y"
   454       by simp
   455   next
   456     assume "vanishes Y"
   457     from vanishes_add [OF this XY] show "vanishes X"
   458       by simp
   459   qed
   460   then show "?thesis X Y"
   461     by (simp add: vanishes_diff_inverse X Y XY realrel_def)
   462 qed
   463 
   464 definition "x - y = x + - y" for x y :: real
   465 
   466 definition "x div y = x * inverse y" for x y :: real
   467 
   468 lemma add_Real: "cauchy X \<Longrightarrow> cauchy Y \<Longrightarrow> Real X + Real Y = Real (\<lambda>n. X n + Y n)"
   469   using plus_real.transfer by (simp add: cr_real_eq rel_fun_def)
   470 
   471 lemma minus_Real: "cauchy X \<Longrightarrow> - Real X = Real (\<lambda>n. - X n)"
   472   using uminus_real.transfer by (simp add: cr_real_eq rel_fun_def)
   473 
   474 lemma diff_Real: "cauchy X \<Longrightarrow> cauchy Y \<Longrightarrow> Real X - Real Y = Real (\<lambda>n. X n - Y n)"
   475   by (simp add: minus_Real add_Real minus_real_def)
   476 
   477 lemma mult_Real: "cauchy X \<Longrightarrow> cauchy Y \<Longrightarrow> Real X * Real Y = Real (\<lambda>n. X n * Y n)"
   478   using times_real.transfer by (simp add: cr_real_eq rel_fun_def)
   479 
   480 lemma inverse_Real:
   481   "cauchy X \<Longrightarrow> inverse (Real X) = (if vanishes X then 0 else Real (\<lambda>n. inverse (X n)))"
   482   using inverse_real.transfer zero_real.transfer
   483   unfolding cr_real_eq rel_fun_def by (simp split: if_split_asm, metis)
   484 
   485 instance
   486 proof
   487   fix a b c :: real
   488   show "a + b = b + a"
   489     by transfer (simp add: ac_simps realrel_def)
   490   show "(a + b) + c = a + (b + c)"
   491     by transfer (simp add: ac_simps realrel_def)
   492   show "0 + a = a"
   493     by transfer (simp add: realrel_def)
   494   show "- a + a = 0"
   495     by transfer (simp add: realrel_def)
   496   show "a - b = a + - b"
   497     by (rule minus_real_def)
   498   show "(a * b) * c = a * (b * c)"
   499     by transfer (simp add: ac_simps realrel_def)
   500   show "a * b = b * a"
   501     by transfer (simp add: ac_simps realrel_def)
   502   show "1 * a = a"
   503     by transfer (simp add: ac_simps realrel_def)
   504   show "(a + b) * c = a * c + b * c"
   505     by transfer (simp add: distrib_right realrel_def)
   506   show "(0::real) \<noteq> (1::real)"
   507     by transfer (simp add: realrel_def)
   508   show "a \<noteq> 0 \<Longrightarrow> inverse a * a = 1"
   509     apply transfer
   510     apply (simp add: realrel_def)
   511     apply (rule vanishesI)
   512     apply (frule (1) cauchy_not_vanishes)
   513     apply clarify
   514     apply (rule_tac x=k in exI)
   515     apply clarify
   516     apply (drule_tac x=n in spec)
   517     apply simp
   518     done
   519   show "a div b = a * inverse b"
   520     by (rule divide_real_def)
   521   show "inverse (0::real) = 0"
   522     by transfer (simp add: realrel_def)
   523 qed
   524 
   525 end
   526 
   527 
   528 subsection \<open>Positive reals\<close>
   529 
   530 lift_definition positive :: "real \<Rightarrow> bool"
   531   is "\<lambda>X. \<exists>r>0. \<exists>k. \<forall>n\<ge>k. r < X n"
   532 proof -
   533   have 1: "\<exists>r>0. \<exists>k. \<forall>n\<ge>k. r < Y n"
   534     if *: "realrel X Y" and **: "\<exists>r>0. \<exists>k. \<forall>n\<ge>k. r < X n" for X Y
   535   proof -
   536     from * have XY: "vanishes (\<lambda>n. X n - Y n)"
   537       by (simp_all add: realrel_def)
   538     from ** obtain r i where "0 < r" and i: "\<forall>n\<ge>i. r < X n"
   539       by blast
   540     obtain s t where s: "0 < s" and t: "0 < t" and r: "r = s + t"
   541       using \<open>0 < r\<close> by (rule obtain_pos_sum)
   542     obtain j where j: "\<forall>n\<ge>j. \<bar>X n - Y n\<bar> < s"
   543       using vanishesD [OF XY s] ..
   544     have "\<forall>n\<ge>max i j. t < Y n"
   545     proof clarsimp
   546       fix n
   547       assume n: "i \<le> n" "j \<le> n"
   548       have "\<bar>X n - Y n\<bar> < s" and "r < X n"
   549         using i j n by simp_all
   550       then show "t < Y n" by (simp add: r)
   551     qed
   552     then show ?thesis using t by blast
   553   qed
   554   fix X Y assume "realrel X Y"
   555   then have "realrel X Y" and "realrel Y X"
   556     using symp_realrel by (auto simp: symp_def)
   557   then show "?thesis X Y"
   558     by (safe elim!: 1)
   559 qed
   560 
   561 lemma positive_Real: "cauchy X \<Longrightarrow> positive (Real X) \<longleftrightarrow> (\<exists>r>0. \<exists>k. \<forall>n\<ge>k. r < X n)"
   562   using positive.transfer by (simp add: cr_real_eq rel_fun_def)
   563 
   564 lemma positive_zero: "\<not> positive 0"
   565   by transfer auto
   566 
   567 lemma positive_add: "positive x \<Longrightarrow> positive y \<Longrightarrow> positive (x + y)"
   568   apply transfer
   569   apply clarify
   570   apply (rename_tac a b i j)
   571   apply (rule_tac x = "a + b" in exI)
   572   apply simp
   573   apply (rule_tac x = "max i j" in exI)
   574   apply clarsimp
   575   apply (simp add: add_strict_mono)
   576   done
   577 
   578 lemma positive_mult: "positive x \<Longrightarrow> positive y \<Longrightarrow> positive (x * y)"
   579   apply transfer
   580   apply clarify
   581   apply (rename_tac a b i j)
   582   apply (rule_tac x = "a * b" in exI)
   583   apply simp
   584   apply (rule_tac x = "max i j" in exI)
   585   apply clarsimp
   586   apply (rule mult_strict_mono)
   587      apply auto
   588   done
   589 
   590 lemma positive_minus: "\<not> positive x \<Longrightarrow> x \<noteq> 0 \<Longrightarrow> positive (- x)"
   591   apply transfer
   592   apply (simp add: realrel_def)
   593   apply (drule (1) cauchy_not_vanishes_cases)
   594   apply safe
   595    apply blast+
   596   done
   597 
   598 instantiation real :: linordered_field
   599 begin
   600 
   601 definition "x < y \<longleftrightarrow> positive (y - x)"
   602 
   603 definition "x \<le> y \<longleftrightarrow> x < y \<or> x = y" for x y :: real
   604 
   605 definition "\<bar>a\<bar> = (if a < 0 then - a else a)" for a :: real
   606 
   607 definition "sgn a = (if a = 0 then 0 else if 0 < a then 1 else - 1)" for a :: real
   608 
   609 instance
   610 proof
   611   fix a b c :: real
   612   show "\<bar>a\<bar> = (if a < 0 then - a else a)"
   613     by (rule abs_real_def)
   614   show "a < b \<longleftrightarrow> a \<le> b \<and> \<not> b \<le> a"
   615     unfolding less_eq_real_def less_real_def
   616     apply auto
   617      apply (drule (1) positive_add)
   618      apply (simp_all add: positive_zero)
   619     done
   620   show "a \<le> a"
   621     unfolding less_eq_real_def by simp
   622   show "a \<le> b \<Longrightarrow> b \<le> c \<Longrightarrow> a \<le> c"
   623     unfolding less_eq_real_def less_real_def
   624     apply auto
   625     apply (drule (1) positive_add)
   626     apply (simp add: algebra_simps)
   627     done
   628   show "a \<le> b \<Longrightarrow> b \<le> a \<Longrightarrow> a = b"
   629     unfolding less_eq_real_def less_real_def
   630     apply auto
   631     apply (drule (1) positive_add)
   632     apply (simp add: positive_zero)
   633     done
   634   show "a \<le> b \<Longrightarrow> c + a \<le> c + b"
   635     by (auto simp: less_eq_real_def less_real_def)
   636     (* FIXME: Procedure int_combine_numerals: c + b - (c + a) \<equiv> b + - a *)
   637     (* Should produce c + b - (c + a) \<equiv> b - a *)
   638   show "sgn a = (if a = 0 then 0 else if 0 < a then 1 else - 1)"
   639     by (rule sgn_real_def)
   640   show "a \<le> b \<or> b \<le> a"
   641     by (auto dest!: positive_minus simp: less_eq_real_def less_real_def)
   642   show "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   643     unfolding less_real_def
   644     apply (drule (1) positive_mult)
   645     apply (simp add: algebra_simps)
   646     done
   647 qed
   648 
   649 end
   650 
   651 instantiation real :: distrib_lattice
   652 begin
   653 
   654 definition "(inf :: real \<Rightarrow> real \<Rightarrow> real) = min"
   655 
   656 definition "(sup :: real \<Rightarrow> real \<Rightarrow> real) = max"
   657 
   658 instance
   659   by standard (auto simp add: inf_real_def sup_real_def max_min_distrib2)
   660 
   661 end
   662 
   663 lemma of_nat_Real: "of_nat x = Real (\<lambda>n. of_nat x)"
   664   by (induct x) (simp_all add: zero_real_def one_real_def add_Real)
   665 
   666 lemma of_int_Real: "of_int x = Real (\<lambda>n. of_int x)"
   667   by (cases x rule: int_diff_cases) (simp add: of_nat_Real diff_Real)
   668 
   669 lemma of_rat_Real: "of_rat x = Real (\<lambda>n. x)"
   670   apply (induct x)
   671   apply (simp add: Fract_of_int_quotient of_rat_divide)
   672   apply (simp add: of_int_Real divide_inverse)
   673   apply (simp add: inverse_Real mult_Real)
   674   done
   675 
   676 instance real :: archimedean_field
   677 proof
   678   show "\<exists>z. x \<le> of_int z" for x :: real
   679     apply (induct x)
   680     apply (frule cauchy_imp_bounded, clarify)
   681     apply (rule_tac x="\<lceil>b\<rceil> + 1" in exI)
   682     apply (rule less_imp_le)
   683     apply (simp add: of_int_Real less_real_def diff_Real positive_Real)
   684     apply (rule_tac x=1 in exI)
   685     apply (simp add: algebra_simps)
   686     apply (rule_tac x=0 in exI)
   687     apply clarsimp
   688     apply (rule le_less_trans [OF abs_ge_self])
   689     apply (rule less_le_trans [OF _ le_of_int_ceiling])
   690     apply simp
   691     done
   692 qed
   693 
   694 instantiation real :: floor_ceiling
   695 begin
   696 
   697 definition [code del]: "\<lfloor>x::real\<rfloor> = (THE z. of_int z \<le> x \<and> x < of_int (z + 1))"
   698 
   699 instance
   700 proof
   701   show "of_int \<lfloor>x\<rfloor> \<le> x \<and> x < of_int (\<lfloor>x\<rfloor> + 1)" for x :: real
   702     unfolding floor_real_def using floor_exists1 by (rule theI')
   703 qed
   704 
   705 end
   706 
   707 
   708 subsection \<open>Completeness\<close>
   709 
   710 lemma not_positive_Real: "\<not> positive (Real X) \<longleftrightarrow> (\<forall>r>0. \<exists>k. \<forall>n\<ge>k. X n \<le> r)" if "cauchy X"
   711   apply (simp only: positive_Real [OF that])
   712   apply auto
   713    apply (unfold not_less)
   714    apply (erule obtain_pos_sum)
   715    apply (drule_tac x=s in spec)
   716    apply simp
   717    apply (drule_tac r=t in cauchyD [OF that])
   718    apply clarify
   719    apply (drule_tac x=k in spec)
   720    apply clarsimp
   721    apply (rule_tac x=n in exI)
   722    apply clarify
   723    apply (rename_tac m)
   724    apply (drule_tac x=m in spec)
   725    apply simp
   726    apply (drule_tac x=n in spec)
   727    apply simp
   728   apply (drule spec)
   729   apply (drule (1) mp)
   730   apply clarify
   731   apply (rename_tac i)
   732   apply (rule_tac x = "max i k" in exI)
   733   apply simp
   734   done
   735 
   736 lemma le_Real:
   737   assumes "cauchy X" "cauchy Y"
   738   shows "Real X \<le> Real Y = (\<forall>r>0. \<exists>k. \<forall>n\<ge>k. X n \<le> Y n + r)"
   739   unfolding not_less [symmetric, where 'a=real] less_real_def
   740   apply (simp add: diff_Real not_positive_Real assms)
   741   apply (simp add: diff_le_eq ac_simps)
   742   done
   743 
   744 lemma le_RealI:
   745   assumes Y: "cauchy Y"
   746   shows "\<forall>n. x \<le> of_rat (Y n) \<Longrightarrow> x \<le> Real Y"
   747 proof (induct x)
   748   fix X
   749   assume X: "cauchy X" and "\<forall>n. Real X \<le> of_rat (Y n)"
   750   then have le: "\<And>m r. 0 < r \<Longrightarrow> \<exists>k. \<forall>n\<ge>k. X n \<le> Y m + r"
   751     by (simp add: of_rat_Real le_Real)
   752   then have "\<exists>k. \<forall>n\<ge>k. X n \<le> Y n + r" if "0 < r" for r :: rat
   753   proof -
   754     from that obtain s t where s: "0 < s" and t: "0 < t" and r: "r = s + t"
   755       by (rule obtain_pos_sum)
   756     obtain i where i: "\<forall>m\<ge>i. \<forall>n\<ge>i. \<bar>Y m - Y n\<bar> < s"
   757       using cauchyD [OF Y s] ..
   758     obtain j where j: "\<forall>n\<ge>j. X n \<le> Y i + t"
   759       using le [OF t] ..
   760     have "\<forall>n\<ge>max i j. X n \<le> Y n + r"
   761     proof clarsimp
   762       fix n
   763       assume n: "i \<le> n" "j \<le> n"
   764       have "X n \<le> Y i + t"
   765         using n j by simp
   766       moreover have "\<bar>Y i - Y n\<bar> < s"
   767         using n i by simp
   768       ultimately show "X n \<le> Y n + r"
   769         unfolding r by simp
   770     qed
   771     then show ?thesis ..
   772   qed
   773   then show "Real X \<le> Real Y"
   774     by (simp add: of_rat_Real le_Real X Y)
   775 qed
   776 
   777 lemma Real_leI:
   778   assumes X: "cauchy X"
   779   assumes le: "\<forall>n. of_rat (X n) \<le> y"
   780   shows "Real X \<le> y"
   781 proof -
   782   have "- y \<le> - Real X"
   783     by (simp add: minus_Real X le_RealI of_rat_minus le)
   784   then show ?thesis by simp
   785 qed
   786 
   787 lemma less_RealD:
   788   assumes "cauchy Y"
   789   shows "x < Real Y \<Longrightarrow> \<exists>n. x < of_rat (Y n)"
   790   apply (erule contrapos_pp)
   791   apply (simp add: not_less)
   792   apply (erule Real_leI [OF assms])
   793   done
   794 
   795 lemma of_nat_less_two_power [simp]: "of_nat n < (2::'a::linordered_idom) ^ n"
   796   apply (induct n)
   797    apply simp
   798   apply (metis add_le_less_mono mult_2 of_nat_Suc one_le_numeral one_le_power power_Suc)
   799   done
   800 
   801 lemma complete_real:
   802   fixes S :: "real set"
   803   assumes "\<exists>x. x \<in> S" and "\<exists>z. \<forall>x\<in>S. x \<le> z"
   804   shows "\<exists>y. (\<forall>x\<in>S. x \<le> y) \<and> (\<forall>z. (\<forall>x\<in>S. x \<le> z) \<longrightarrow> y \<le> z)"
   805 proof -
   806   obtain x where x: "x \<in> S" using assms(1) ..
   807   obtain z where z: "\<forall>x\<in>S. x \<le> z" using assms(2) ..
   808 
   809   define P where "P x \<longleftrightarrow> (\<forall>y\<in>S. y \<le> of_rat x)" for x
   810   obtain a where a: "\<not> P a"
   811   proof
   812     have "of_int \<lfloor>x - 1\<rfloor> \<le> x - 1" by (rule of_int_floor_le)
   813     also have "x - 1 < x" by simp
   814     finally have "of_int \<lfloor>x - 1\<rfloor> < x" .
   815     then have "\<not> x \<le> of_int \<lfloor>x - 1\<rfloor>" by (simp only: not_le)
   816     then show "\<not> P (of_int \<lfloor>x - 1\<rfloor>)"
   817       unfolding P_def of_rat_of_int_eq using x by blast
   818   qed
   819   obtain b where b: "P b"
   820   proof
   821     show "P (of_int \<lceil>z\<rceil>)"
   822     unfolding P_def of_rat_of_int_eq
   823     proof
   824       fix y assume "y \<in> S"
   825       then have "y \<le> z" using z by simp
   826       also have "z \<le> of_int \<lceil>z\<rceil>" by (rule le_of_int_ceiling)
   827       finally show "y \<le> of_int \<lceil>z\<rceil>" .
   828     qed
   829   qed
   830 
   831   define avg where "avg x y = x/2 + y/2" for x y :: rat
   832   define bisect where "bisect = (\<lambda>(x, y). if P (avg x y) then (x, avg x y) else (avg x y, y))"
   833   define A where "A n = fst ((bisect ^^ n) (a, b))" for n
   834   define B where "B n = snd ((bisect ^^ n) (a, b))" for n
   835   define C where "C n = avg (A n) (B n)" for n
   836   have A_0 [simp]: "A 0 = a" unfolding A_def by simp
   837   have B_0 [simp]: "B 0 = b" unfolding B_def by simp
   838   have A_Suc [simp]: "\<And>n. A (Suc n) = (if P (C n) then A n else C n)"
   839     unfolding A_def B_def C_def bisect_def split_def by simp
   840   have B_Suc [simp]: "\<And>n. B (Suc n) = (if P (C n) then C n else B n)"
   841     unfolding A_def B_def C_def bisect_def split_def by simp
   842 
   843   have width: "B n - A n = (b - a) / 2^n" for n
   844     apply (induct n)
   845      apply (simp_all add: eq_divide_eq)
   846     apply (simp_all add: C_def avg_def algebra_simps)
   847     done
   848 
   849   have twos: "0 < r \<Longrightarrow> \<exists>n. y / 2 ^ n < r" for y r :: rat
   850     apply (simp add: divide_less_eq)
   851     apply (subst mult.commute)
   852     apply (frule_tac y=y in ex_less_of_nat_mult)
   853     apply clarify
   854     apply (rule_tac x=n in exI)
   855     apply (erule less_trans)
   856     apply (rule mult_strict_right_mono)
   857      apply (rule le_less_trans [OF _ of_nat_less_two_power])
   858      apply simp
   859     apply assumption
   860     done
   861 
   862   have PA: "\<not> P (A n)" for n
   863     by (induct n) (simp_all add: a)
   864   have PB: "P (B n)" for n
   865     by (induct n) (simp_all add: b)
   866   have ab: "a < b"
   867     using a b unfolding P_def
   868     apply (clarsimp simp add: not_le)
   869     apply (drule (1) bspec)
   870     apply (drule (1) less_le_trans)
   871     apply (simp add: of_rat_less)
   872     done
   873   have AB: "A n < B n" for n
   874     by (induct n) (simp_all add: ab C_def avg_def)
   875   have A_mono: "\<And>i j. i \<le> j \<Longrightarrow> A i \<le> A j"
   876     apply (auto simp add: le_less [where 'a=nat])
   877     apply (erule less_Suc_induct)
   878      apply (clarsimp simp add: C_def avg_def)
   879      apply (simp add: add_divide_distrib [symmetric])
   880      apply (rule AB [THEN less_imp_le])
   881     apply simp
   882     done
   883   have B_mono: "\<And>i j. i \<le> j \<Longrightarrow> B j \<le> B i"
   884     apply (auto simp add: le_less [where 'a=nat])
   885     apply (erule less_Suc_induct)
   886      apply (clarsimp simp add: C_def avg_def)
   887      apply (simp add: add_divide_distrib [symmetric])
   888      apply (rule AB [THEN less_imp_le])
   889     apply simp
   890     done
   891   have cauchy_lemma: "\<And>X. \<forall>n. \<forall>i\<ge>n. A n \<le> X i \<and> X i \<le> B n \<Longrightarrow> cauchy X"
   892     apply (rule cauchyI)
   893     apply (drule twos [where y="b - a"])
   894     apply (erule exE)
   895     apply (rule_tac x=n in exI, clarify, rename_tac i j)
   896     apply (rule_tac y="B n - A n" in le_less_trans) defer
   897      apply (simp add: width)
   898     apply (drule_tac x=n in spec)
   899     apply (frule_tac x=i in spec, drule (1) mp)
   900     apply (frule_tac x=j in spec, drule (1) mp)
   901     apply (frule A_mono, drule B_mono)
   902     apply (frule A_mono, drule B_mono)
   903     apply arith
   904     done
   905   have "cauchy A"
   906     apply (rule cauchy_lemma [rule_format])
   907     apply (simp add: A_mono)
   908     apply (erule order_trans [OF less_imp_le [OF AB] B_mono])
   909     done
   910   have "cauchy B"
   911     apply (rule cauchy_lemma [rule_format])
   912     apply (simp add: B_mono)
   913     apply (erule order_trans [OF A_mono less_imp_le [OF AB]])
   914     done
   915   have 1: "\<forall>x\<in>S. x \<le> Real B"
   916   proof
   917     fix x
   918     assume "x \<in> S"
   919     then show "x \<le> Real B"
   920       using PB [unfolded P_def] \<open>cauchy B\<close>
   921       by (simp add: le_RealI)
   922   qed
   923   have 2: "\<forall>z. (\<forall>x\<in>S. x \<le> z) \<longrightarrow> Real A \<le> z"
   924     apply clarify
   925     apply (erule contrapos_pp)
   926     apply (simp add: not_le)
   927     apply (drule less_RealD [OF \<open>cauchy A\<close>])
   928     apply clarify
   929     apply (subgoal_tac "\<not> P (A n)")
   930      apply (simp add: P_def not_le)
   931      apply clarify
   932      apply (erule rev_bexI)
   933      apply (erule (1) less_trans)
   934     apply (simp add: PA)
   935     done
   936   have "vanishes (\<lambda>n. (b - a) / 2 ^ n)"
   937   proof (rule vanishesI)
   938     fix r :: rat
   939     assume "0 < r"
   940     then obtain k where k: "\<bar>b - a\<bar> / 2 ^ k < r"
   941       using twos by blast
   942     have "\<forall>n\<ge>k. \<bar>(b - a) / 2 ^ n\<bar> < r"
   943     proof clarify
   944       fix n
   945       assume n: "k \<le> n"
   946       have "\<bar>(b - a) / 2 ^ n\<bar> = \<bar>b - a\<bar> / 2 ^ n"
   947         by simp
   948       also have "\<dots> \<le> \<bar>b - a\<bar> / 2 ^ k"
   949         using n by (simp add: divide_left_mono)
   950       also note k
   951       finally show "\<bar>(b - a) / 2 ^ n\<bar> < r" .
   952     qed
   953     then show "\<exists>k. \<forall>n\<ge>k. \<bar>(b - a) / 2 ^ n\<bar> < r" ..
   954   qed
   955   then have 3: "Real B = Real A"
   956     by (simp add: eq_Real \<open>cauchy A\<close> \<open>cauchy B\<close> width)
   957   show "\<exists>y. (\<forall>x\<in>S. x \<le> y) \<and> (\<forall>z. (\<forall>x\<in>S. x \<le> z) \<longrightarrow> y \<le> z)"
   958     apply (rule exI [where x = "Real B"])
   959     using 1 2 3
   960     apply simp
   961     done
   962 qed
   963 
   964 instantiation real :: linear_continuum
   965 begin
   966 
   967 subsection \<open>Supremum of a set of reals\<close>
   968 
   969 definition "Sup X = (LEAST z::real. \<forall>x\<in>X. x \<le> z)"
   970 definition "Inf X = - Sup (uminus ` X)" for X :: "real set"
   971 
   972 instance
   973 proof
   974   show Sup_upper: "x \<le> Sup X"
   975     if "x \<in> X" "bdd_above X"
   976     for x :: real and X :: "real set"
   977   proof -
   978     from that obtain s where s: "\<forall>y\<in>X. y \<le> s" "\<And>z. \<forall>y\<in>X. y \<le> z \<Longrightarrow> s \<le> z"
   979       using complete_real[of X] unfolding bdd_above_def by blast
   980     then show ?thesis
   981       unfolding Sup_real_def by (rule LeastI2_order) (auto simp: that)
   982   qed
   983   show Sup_least: "Sup X \<le> z"
   984     if "X \<noteq> {}" and z: "\<And>x. x \<in> X \<Longrightarrow> x \<le> z"
   985     for z :: real and X :: "real set"
   986   proof -
   987     from that obtain s where s: "\<forall>y\<in>X. y \<le> s" "\<And>z. \<forall>y\<in>X. y \<le> z \<Longrightarrow> s \<le> z"
   988       using complete_real [of X] by blast
   989     then have "Sup X = s"
   990       unfolding Sup_real_def by (best intro: Least_equality)
   991     also from s z have "\<dots> \<le> z"
   992       by blast
   993     finally show ?thesis .
   994   qed
   995   show "Inf X \<le> x" if "x \<in> X" "bdd_below X"
   996     for x :: real and X :: "real set"
   997     using Sup_upper [of "-x" "uminus ` X"] by (auto simp: Inf_real_def that)
   998   show "z \<le> Inf X" if "X \<noteq> {}" "\<And>x. x \<in> X \<Longrightarrow> z \<le> x"
   999     for z :: real and X :: "real set"
  1000     using Sup_least [of "uminus ` X" "- z"] by (force simp: Inf_real_def that)
  1001   show "\<exists>a b::real. a \<noteq> b"
  1002     using zero_neq_one by blast
  1003 qed
  1004 
  1005 end
  1006 
  1007 
  1008 subsection \<open>Hiding implementation details\<close>
  1009 
  1010 hide_const (open) vanishes cauchy positive Real
  1011 
  1012 declare Real_induct [induct del]
  1013 declare Abs_real_induct [induct del]
  1014 declare Abs_real_cases [cases del]
  1015 
  1016 lifting_update real.lifting
  1017 lifting_forget real.lifting
  1018 
  1019 
  1020 subsection \<open>More Lemmas\<close>
  1021 
  1022 text \<open>BH: These lemmas should not be necessary; they should be
  1023   covered by existing simp rules and simplification procedures.\<close>
  1024 
  1025 lemma real_mult_less_iff1 [simp]: "0 < z \<Longrightarrow> x * z < y * z \<longleftrightarrow> x < y"
  1026   for x y z :: real
  1027   by simp (* solved by linordered_ring_less_cancel_factor simproc *)
  1028 
  1029 lemma real_mult_le_cancel_iff1 [simp]: "0 < z \<Longrightarrow> x * z \<le> y * z \<longleftrightarrow> x \<le> y"
  1030   for x y z :: real
  1031   by simp (* solved by linordered_ring_le_cancel_factor simproc *)
  1032 
  1033 lemma real_mult_le_cancel_iff2 [simp]: "0 < z \<Longrightarrow> z * x \<le> z * y \<longleftrightarrow> x \<le> y"
  1034   for x y z :: real
  1035   by simp (* solved by linordered_ring_le_cancel_factor simproc *)
  1036 
  1037 
  1038 subsection \<open>Embedding numbers into the Reals\<close>
  1039 
  1040 abbreviation real_of_nat :: "nat \<Rightarrow> real"
  1041   where "real_of_nat \<equiv> of_nat"
  1042 
  1043 abbreviation real :: "nat \<Rightarrow> real"
  1044   where "real \<equiv> of_nat"
  1045 
  1046 abbreviation real_of_int :: "int \<Rightarrow> real"
  1047   where "real_of_int \<equiv> of_int"
  1048 
  1049 abbreviation real_of_rat :: "rat \<Rightarrow> real"
  1050   where "real_of_rat \<equiv> of_rat"
  1051 
  1052 declare [[coercion_enabled]]
  1053 
  1054 declare [[coercion "of_nat :: nat \<Rightarrow> int"]]
  1055 declare [[coercion "of_nat :: nat \<Rightarrow> real"]]
  1056 declare [[coercion "of_int :: int \<Rightarrow> real"]]
  1057 
  1058 (* We do not add rat to the coerced types, this has often unpleasant side effects when writing
  1059 inverse (Suc n) which sometimes gets two coercions: of_rat (inverse (of_nat (Suc n))) *)
  1060 
  1061 declare [[coercion_map map]]
  1062 declare [[coercion_map "\<lambda>f g h x. g (h (f x))"]]
  1063 declare [[coercion_map "\<lambda>f g (x,y). (f x, g y)"]]
  1064 
  1065 declare of_int_eq_0_iff [algebra, presburger]
  1066 declare of_int_eq_1_iff [algebra, presburger]
  1067 declare of_int_eq_iff [algebra, presburger]
  1068 declare of_int_less_0_iff [algebra, presburger]
  1069 declare of_int_less_1_iff [algebra, presburger]
  1070 declare of_int_less_iff [algebra, presburger]
  1071 declare of_int_le_0_iff [algebra, presburger]
  1072 declare of_int_le_1_iff [algebra, presburger]
  1073 declare of_int_le_iff [algebra, presburger]
  1074 declare of_int_0_less_iff [algebra, presburger]
  1075 declare of_int_0_le_iff [algebra, presburger]
  1076 declare of_int_1_less_iff [algebra, presburger]
  1077 declare of_int_1_le_iff [algebra, presburger]
  1078 
  1079 lemma int_less_real_le: "n < m \<longleftrightarrow> real_of_int n + 1 \<le> real_of_int m"
  1080 proof -
  1081   have "(0::real) \<le> 1"
  1082     by (metis less_eq_real_def zero_less_one)
  1083   then show ?thesis
  1084     by (metis floor_of_int less_floor_iff)
  1085 qed
  1086 
  1087 lemma int_le_real_less: "n \<le> m \<longleftrightarrow> real_of_int n < real_of_int m + 1"
  1088   by (meson int_less_real_le not_le)
  1089 
  1090 lemma real_of_int_div_aux:
  1091   "(real_of_int x) / (real_of_int d) =
  1092     real_of_int (x div d) + (real_of_int (x mod d)) / (real_of_int d)"
  1093 proof -
  1094   have "x = (x div d) * d + x mod d"
  1095     by auto
  1096   then have "real_of_int x = real_of_int (x div d) * real_of_int d + real_of_int(x mod d)"
  1097     by (metis of_int_add of_int_mult)
  1098   then have "real_of_int x / real_of_int d = \<dots> / real_of_int d"
  1099     by simp
  1100   then show ?thesis
  1101     by (auto simp add: add_divide_distrib algebra_simps)
  1102 qed
  1103 
  1104 lemma real_of_int_div:
  1105   "d dvd n \<Longrightarrow> real_of_int (n div d) = real_of_int n / real_of_int d" for d n :: int
  1106   by (simp add: real_of_int_div_aux)
  1107 
  1108 lemma real_of_int_div2: "0 \<le> real_of_int n / real_of_int x - real_of_int (n div x)"
  1109   apply (cases "x = 0")
  1110    apply simp
  1111   apply (cases "0 < x")
  1112    apply (metis add.left_neutral floor_correct floor_divide_of_int_eq le_diff_eq)
  1113   apply (metis add.left_neutral floor_correct floor_divide_of_int_eq le_diff_eq)
  1114   done
  1115 
  1116 lemma real_of_int_div3: "real_of_int n / real_of_int x - real_of_int (n div x) \<le> 1"
  1117   apply (simp add: algebra_simps)
  1118   apply (subst real_of_int_div_aux)
  1119   apply (auto simp add: divide_le_eq intro: order_less_imp_le)
  1120   done
  1121 
  1122 lemma real_of_int_div4: "real_of_int (n div x) \<le> real_of_int n / real_of_int x"
  1123   using real_of_int_div2 [of n x] by simp
  1124 
  1125 
  1126 subsection \<open>Embedding the Naturals into the Reals\<close>
  1127 
  1128 lemma real_of_card: "real (card A) = sum (\<lambda>x. 1) A"
  1129   by simp
  1130 
  1131 lemma nat_less_real_le: "n < m \<longleftrightarrow> real n + 1 \<le> real m"
  1132   by (metis discrete of_nat_1 of_nat_add of_nat_le_iff)
  1133 
  1134 lemma nat_le_real_less: "n \<le> m \<longleftrightarrow> real n < real m + 1"
  1135   for m n :: nat
  1136   by (meson nat_less_real_le not_le)
  1137 
  1138 lemma real_of_nat_div_aux: "real x / real d = real (x div d) + real (x mod d) / real d"
  1139 proof -
  1140   have "x = (x div d) * d + x mod d"
  1141     by auto
  1142   then have "real x = real (x div d) * real d + real(x mod d)"
  1143     by (metis of_nat_add of_nat_mult)
  1144   then have "real x / real d = \<dots> / real d"
  1145     by simp
  1146   then show ?thesis
  1147     by (auto simp add: add_divide_distrib algebra_simps)
  1148 qed
  1149 
  1150 lemma real_of_nat_div: "d dvd n \<Longrightarrow> real(n div d) = real n / real d"
  1151   by (subst real_of_nat_div_aux) (auto simp add: dvd_eq_mod_eq_0 [symmetric])
  1152 
  1153 lemma real_of_nat_div2: "0 \<le> real n / real x - real (n div x)" for n x :: nat
  1154   apply (simp add: algebra_simps)
  1155   apply (subst real_of_nat_div_aux)
  1156   apply simp
  1157   done
  1158 
  1159 lemma real_of_nat_div3: "real n / real x - real (n div x) \<le> 1" for n x :: nat
  1160   apply (cases "x = 0")
  1161    apply simp
  1162   apply (simp add: algebra_simps)
  1163   apply (subst real_of_nat_div_aux)
  1164   apply simp
  1165   done
  1166 
  1167 lemma real_of_nat_div4: "real (n div x) \<le> real n / real x" for n x :: nat
  1168   using real_of_nat_div2 [of n x] by simp
  1169 
  1170 
  1171 subsection \<open>The Archimedean Property of the Reals\<close>
  1172 
  1173 lemma real_arch_inverse: "0 < e \<longleftrightarrow> (\<exists>n::nat. n \<noteq> 0 \<and> 0 < inverse (real n) \<and> inverse (real n) < e)"
  1174   using reals_Archimedean[of e] less_trans[of 0 "1 / real n" e for n::nat]
  1175   by (auto simp add: field_simps cong: conj_cong simp del: of_nat_Suc)
  1176 
  1177 lemma reals_Archimedean3: "0 < x \<Longrightarrow> \<forall>y. \<exists>n. y < real n * x"
  1178   by (auto intro: ex_less_of_nat_mult)
  1179 
  1180 lemma real_archimedian_rdiv_eq_0:
  1181   assumes x0: "x \<ge> 0"
  1182     and c: "c \<ge> 0"
  1183     and xc: "\<And>m::nat. m > 0 \<Longrightarrow> real m * x \<le> c"
  1184   shows "x = 0"
  1185   by (metis reals_Archimedean3 dual_order.order_iff_strict le0 le_less_trans not_le x0 xc)
  1186 
  1187 
  1188 subsection \<open>Rationals\<close>
  1189 
  1190 lemma Rats_eq_int_div_int: "\<rat> = {real_of_int i / real_of_int j | i j. j \<noteq> 0}"  (is "_ = ?S")
  1191 proof
  1192   show "\<rat> \<subseteq> ?S"
  1193   proof
  1194     fix x :: real
  1195     assume "x \<in> \<rat>"
  1196     then obtain r where "x = of_rat r"
  1197       unfolding Rats_def ..
  1198     have "of_rat r \<in> ?S"
  1199       by (cases r) (auto simp add: of_rat_rat)
  1200     then show "x \<in> ?S"
  1201       using \<open>x = of_rat r\<close> by simp
  1202   qed
  1203 next
  1204   show "?S \<subseteq> \<rat>"
  1205   proof (auto simp: Rats_def)
  1206     fix i j :: int
  1207     assume "j \<noteq> 0"
  1208     then have "real_of_int i / real_of_int j = of_rat (Fract i j)"
  1209       by (simp add: of_rat_rat)
  1210     then show "real_of_int i / real_of_int j \<in> range of_rat"
  1211       by blast
  1212   qed
  1213 qed
  1214 
  1215 lemma Rats_eq_int_div_nat: "\<rat> = { real_of_int i / real n | i n. n \<noteq> 0}"
  1216 proof (auto simp: Rats_eq_int_div_int)
  1217   fix i j :: int
  1218   assume "j \<noteq> 0"
  1219   show "\<exists>(i'::int) (n::nat). real_of_int i / real_of_int j = real_of_int i' / real n \<and> 0 < n"
  1220   proof (cases "j > 0")
  1221     case True
  1222     then have "real_of_int i / real_of_int j = real_of_int i / real (nat j) \<and> 0 < nat j"
  1223       by simp
  1224     then show ?thesis by blast
  1225   next
  1226     case False
  1227     with \<open>j \<noteq> 0\<close>
  1228     have "real_of_int i / real_of_int j = real_of_int (- i) / real (nat (- j)) \<and> 0 < nat (- j)"
  1229       by simp
  1230     then show ?thesis by blast
  1231   qed
  1232 next
  1233   fix i :: int and n :: nat
  1234   assume "0 < n"
  1235   then have "real_of_int i / real n = real_of_int i / real_of_int(int n) \<and> int n \<noteq> 0"
  1236     by simp
  1237   then show "\<exists>i' j. real_of_int i / real n = real_of_int i' / real_of_int j \<and> j \<noteq> 0"
  1238     by blast
  1239 qed
  1240 
  1241 lemma Rats_abs_nat_div_natE:
  1242   assumes "x \<in> \<rat>"
  1243   obtains m n :: nat where "n \<noteq> 0" and "\<bar>x\<bar> = real m / real n" and "gcd m n = 1"
  1244 proof -
  1245   from \<open>x \<in> \<rat>\<close> obtain i :: int and n :: nat where "n \<noteq> 0" and "x = real_of_int i / real n"
  1246     by (auto simp add: Rats_eq_int_div_nat)
  1247   then have "\<bar>x\<bar> = real (nat \<bar>i\<bar>) / real n" by simp
  1248   then obtain m :: nat where x_rat: "\<bar>x\<bar> = real m / real n" by blast
  1249   let ?gcd = "gcd m n"
  1250   from \<open>n \<noteq> 0\<close> have gcd: "?gcd \<noteq> 0" by simp
  1251   let ?k = "m div ?gcd"
  1252   let ?l = "n div ?gcd"
  1253   let ?gcd' = "gcd ?k ?l"
  1254   have "?gcd dvd m" ..
  1255   then have gcd_k: "?gcd * ?k = m"
  1256     by (rule dvd_mult_div_cancel)
  1257   have "?gcd dvd n" ..
  1258   then have gcd_l: "?gcd * ?l = n"
  1259     by (rule dvd_mult_div_cancel)
  1260   from \<open>n \<noteq> 0\<close> and gcd_l have "?gcd * ?l \<noteq> 0" by simp
  1261   then have "?l \<noteq> 0" by (blast dest!: mult_not_zero)
  1262   moreover
  1263   have "\<bar>x\<bar> = real ?k / real ?l"
  1264   proof -
  1265     from gcd have "real ?k / real ?l = real (?gcd * ?k) / real (?gcd * ?l)"
  1266       by (simp add: real_of_nat_div)
  1267     also from gcd_k and gcd_l have "\<dots> = real m / real n" by simp
  1268     also from x_rat have "\<dots> = \<bar>x\<bar>" ..
  1269     finally show ?thesis ..
  1270   qed
  1271   moreover
  1272   have "?gcd' = 1"
  1273   proof -
  1274     have "?gcd * ?gcd' = gcd (?gcd * ?k) (?gcd * ?l)"
  1275       by (rule gcd_mult_distrib_nat)
  1276     with gcd_k gcd_l have "?gcd * ?gcd' = ?gcd" by simp
  1277     with gcd show ?thesis by auto
  1278   qed
  1279   ultimately show ?thesis ..
  1280 qed
  1281 
  1282 
  1283 subsection \<open>Density of the Rational Reals in the Reals\<close>
  1284 
  1285 text \<open>
  1286   This density proof is due to Stefan Richter and was ported by TN.  The
  1287   original source is \<^emph>\<open>Real Analysis\<close> by H.L. Royden.
  1288   It employs the Archimedean property of the reals.\<close>
  1289 
  1290 lemma Rats_dense_in_real:
  1291   fixes x :: real
  1292   assumes "x < y"
  1293   shows "\<exists>r\<in>\<rat>. x < r \<and> r < y"
  1294 proof -
  1295   from \<open>x < y\<close> have "0 < y - x" by simp
  1296   with reals_Archimedean obtain q :: nat where q: "inverse (real q) < y - x" and "0 < q"
  1297     by blast
  1298   define p where "p = \<lceil>y * real q\<rceil> - 1"
  1299   define r where "r = of_int p / real q"
  1300   from q have "x < y - inverse (real q)"
  1301     by simp
  1302   also from \<open>0 < q\<close> have "y - inverse (real q) \<le> r"
  1303     by (simp add: r_def p_def le_divide_eq left_diff_distrib)
  1304   finally have "x < r" .
  1305   moreover from \<open>0 < q\<close> have "r < y"
  1306     by (simp add: r_def p_def divide_less_eq diff_less_eq less_ceiling_iff [symmetric])
  1307   moreover have "r \<in> \<rat>"
  1308     by (simp add: r_def)
  1309   ultimately show ?thesis by blast
  1310 qed
  1311 
  1312 lemma of_rat_dense:
  1313   fixes x y :: real
  1314   assumes "x < y"
  1315   shows "\<exists>q :: rat. x < of_rat q \<and> of_rat q < y"
  1316   using Rats_dense_in_real [OF \<open>x < y\<close>]
  1317   by (auto elim: Rats_cases)
  1318 
  1319 
  1320 subsection \<open>Numerals and Arithmetic\<close>
  1321 
  1322 lemma [code_abbrev]:   (*FIXME*)
  1323   "real_of_int (numeral k) = numeral k"
  1324   "real_of_int (- numeral k) = - numeral k"
  1325   by simp_all
  1326 
  1327 declaration \<open>
  1328   K (Lin_Arith.add_inj_thms [@{thm of_nat_le_iff} RS iffD2, @{thm of_nat_eq_iff} RS iffD2]
  1329     (* not needed because x < (y::nat) can be rewritten as Suc x <= y: of_nat_less_iff RS iffD2 *)
  1330   #> Lin_Arith.add_inj_thms [@{thm of_int_le_iff} RS iffD2, @{thm of_nat_eq_iff} RS iffD2]
  1331     (* not needed because x < (y::int) can be rewritten as x + 1 <= y: of_int_less_iff RS iffD2 *)
  1332   #> Lin_Arith.add_simps [@{thm of_nat_0}, @{thm of_nat_Suc}, @{thm of_nat_add},
  1333       @{thm of_nat_mult}, @{thm of_int_0}, @{thm of_int_1},
  1334       @{thm of_int_add}, @{thm of_int_minus}, @{thm of_int_diff},
  1335       @{thm of_int_mult}, @{thm of_int_of_nat_eq},
  1336       @{thm of_nat_numeral}, @{thm of_nat_numeral}, @{thm of_int_neg_numeral}]
  1337   #> Lin_Arith.add_inj_const (@{const_name of_nat}, @{typ "nat \<Rightarrow> real"})
  1338   #> Lin_Arith.add_inj_const (@{const_name of_int}, @{typ "int \<Rightarrow> real"}))
  1339 \<close>
  1340 
  1341 
  1342 subsection \<open>Simprules combining \<open>x + y\<close> and \<open>0\<close>\<close> (* FIXME ARE THEY NEEDED? *)
  1343 
  1344 lemma real_add_minus_iff [simp]: "x + - a = 0 \<longleftrightarrow> x = a"
  1345   for x a :: real
  1346   by arith
  1347 
  1348 lemma real_add_less_0_iff: "x + y < 0 \<longleftrightarrow> y < - x"
  1349   for x y :: real
  1350   by auto
  1351 
  1352 lemma real_0_less_add_iff: "0 < x + y \<longleftrightarrow> - x < y"
  1353   for x y :: real
  1354   by auto
  1355 
  1356 lemma real_add_le_0_iff: "x + y \<le> 0 \<longleftrightarrow> y \<le> - x"
  1357   for x y :: real
  1358   by auto
  1359 
  1360 lemma real_0_le_add_iff: "0 \<le> x + y \<longleftrightarrow> - x \<le> y"
  1361   for x y :: real
  1362   by auto
  1363 
  1364 
  1365 subsection \<open>Lemmas about powers\<close>
  1366 
  1367 lemma two_realpow_ge_one: "(1::real) \<le> 2 ^ n"
  1368   by simp
  1369 
  1370 (* FIXME: declare this [simp] for all types, or not at all *)
  1371 declare sum_squares_eq_zero_iff [simp] sum_power2_eq_zero_iff [simp]
  1372 
  1373 lemma real_minus_mult_self_le [simp]: "- (u * u) \<le> x * x"
  1374   for u x :: real
  1375   by (rule order_trans [where y = 0]) auto
  1376 
  1377 lemma realpow_square_minus_le [simp]: "- u\<^sup>2 \<le> x\<^sup>2"
  1378   for u x :: real
  1379   by (auto simp add: power2_eq_square)
  1380 
  1381 lemma numeral_power_eq_real_of_int_cancel_iff [simp]:
  1382   "numeral x ^ n = real_of_int y \<longleftrightarrow> numeral x ^ n = y"
  1383   by (metis of_int_eq_iff of_int_numeral of_int_power)
  1384 
  1385 lemma real_of_int_eq_numeral_power_cancel_iff [simp]:
  1386   "real_of_int y = numeral x ^ n \<longleftrightarrow> y = numeral x ^ n"
  1387   using numeral_power_eq_real_of_int_cancel_iff [of x n y] by metis
  1388 
  1389 lemma numeral_power_eq_real_of_nat_cancel_iff [simp]:
  1390   "numeral x ^ n = real y \<longleftrightarrow> numeral x ^ n = y"
  1391   using of_nat_eq_iff by fastforce
  1392 
  1393 lemma real_of_nat_eq_numeral_power_cancel_iff [simp]:
  1394   "real y = numeral x ^ n \<longleftrightarrow> y = numeral x ^ n"
  1395   using numeral_power_eq_real_of_nat_cancel_iff [of x n y] by metis
  1396 
  1397 lemma numeral_power_le_real_of_nat_cancel_iff [simp]:
  1398   "(numeral x :: real) ^ n \<le> real a \<longleftrightarrow> (numeral x::nat) ^ n \<le> a"
  1399   by (metis of_nat_le_iff of_nat_numeral of_nat_power)
  1400 
  1401 lemma real_of_nat_le_numeral_power_cancel_iff [simp]:
  1402   "real a \<le> (numeral x::real) ^ n \<longleftrightarrow> a \<le> (numeral x::nat) ^ n"
  1403   by (metis of_nat_le_iff of_nat_numeral of_nat_power)
  1404 
  1405 lemma numeral_power_le_real_of_int_cancel_iff [simp]:
  1406   "(numeral x::real) ^ n \<le> real_of_int a \<longleftrightarrow> (numeral x::int) ^ n \<le> a"
  1407   by (metis ceiling_le_iff ceiling_of_int of_int_numeral of_int_power)
  1408 
  1409 lemma real_of_int_le_numeral_power_cancel_iff [simp]:
  1410   "real_of_int a \<le> (numeral x::real) ^ n \<longleftrightarrow> a \<le> (numeral x::int) ^ n"
  1411   by (metis floor_of_int le_floor_iff of_int_numeral of_int_power)
  1412 
  1413 lemma numeral_power_less_real_of_nat_cancel_iff [simp]:
  1414   "(numeral x::real) ^ n < real a \<longleftrightarrow> (numeral x::nat) ^ n < a"
  1415   by (metis of_nat_less_iff of_nat_numeral of_nat_power)
  1416 
  1417 lemma real_of_nat_less_numeral_power_cancel_iff [simp]:
  1418   "real a < (numeral x::real) ^ n \<longleftrightarrow> a < (numeral x::nat) ^ n"
  1419   by (metis of_nat_less_iff of_nat_numeral of_nat_power)
  1420 
  1421 lemma numeral_power_less_real_of_int_cancel_iff [simp]:
  1422   "(numeral x::real) ^ n < real_of_int a \<longleftrightarrow> (numeral x::int) ^ n < a"
  1423   by (meson not_less real_of_int_le_numeral_power_cancel_iff)
  1424 
  1425 lemma real_of_int_less_numeral_power_cancel_iff [simp]:
  1426   "real_of_int a < (numeral x::real) ^ n \<longleftrightarrow> a < (numeral x::int) ^ n"
  1427   by (meson not_less numeral_power_le_real_of_int_cancel_iff)
  1428 
  1429 lemma neg_numeral_power_le_real_of_int_cancel_iff [simp]:
  1430   "(- numeral x::real) ^ n \<le> real_of_int a \<longleftrightarrow> (- numeral x::int) ^ n \<le> a"
  1431   by (metis of_int_le_iff of_int_neg_numeral of_int_power)
  1432 
  1433 lemma real_of_int_le_neg_numeral_power_cancel_iff [simp]:
  1434   "real_of_int a \<le> (- numeral x::real) ^ n \<longleftrightarrow> a \<le> (- numeral x::int) ^ n"
  1435   by (metis of_int_le_iff of_int_neg_numeral of_int_power)
  1436 
  1437 
  1438 subsection \<open>Density of the Reals\<close>
  1439 
  1440 lemma real_lbound_gt_zero: "0 < d1 \<Longrightarrow> 0 < d2 \<Longrightarrow> \<exists>e. 0 < e \<and> e < d1 \<and> e < d2"
  1441   for d1 d2 :: real
  1442   by (rule exI [where x = "min d1 d2 / 2"]) (simp add: min_def)
  1443 
  1444 text \<open>Similar results are proved in @{theory Fields}\<close>
  1445 lemma real_less_half_sum: "x < y \<Longrightarrow> x < (x + y) / 2"
  1446   for x y :: real
  1447   by auto
  1448 
  1449 lemma real_gt_half_sum: "x < y \<Longrightarrow> (x + y) / 2 < y"
  1450   for x y :: real
  1451   by auto
  1452 
  1453 lemma real_sum_of_halves: "x / 2 + x / 2 = x"
  1454   for x :: real
  1455   by simp
  1456 
  1457 
  1458 subsection \<open>Floor and Ceiling Functions from the Reals to the Integers\<close>
  1459 
  1460 (* FIXME: theorems for negative numerals. Many duplicates, e.g. from Archimedean_Field.thy. *)
  1461 
  1462 lemma real_of_nat_less_numeral_iff [simp]: "real n < numeral w \<longleftrightarrow> n < numeral w"
  1463   for n :: nat
  1464   by (metis of_nat_less_iff of_nat_numeral)
  1465 
  1466 lemma numeral_less_real_of_nat_iff [simp]: "numeral w < real n \<longleftrightarrow> numeral w < n"
  1467   for n :: nat
  1468   by (metis of_nat_less_iff of_nat_numeral)
  1469 
  1470 lemma numeral_le_real_of_nat_iff [simp]: "numeral n \<le> real m \<longleftrightarrow> numeral n \<le> m"
  1471   for m :: nat
  1472   by (metis not_le real_of_nat_less_numeral_iff)
  1473 
  1474 declare of_int_floor_le [simp]  (* FIXME duplicate!? *)
  1475 
  1476 lemma of_int_floor_cancel [simp]: "of_int \<lfloor>x\<rfloor> = x \<longleftrightarrow> (\<exists>n::int. x = of_int n)"
  1477   by (metis floor_of_int)
  1478 
  1479 lemma floor_eq: "real_of_int n < x \<Longrightarrow> x < real_of_int n + 1 \<Longrightarrow> \<lfloor>x\<rfloor> = n"
  1480   by linarith
  1481 
  1482 lemma floor_eq2: "real_of_int n \<le> x \<Longrightarrow> x < real_of_int n + 1 \<Longrightarrow> \<lfloor>x\<rfloor> = n"
  1483   by linarith
  1484 
  1485 lemma floor_eq3: "real n < x \<Longrightarrow> x < real (Suc n) \<Longrightarrow> nat \<lfloor>x\<rfloor> = n"
  1486   by linarith
  1487 
  1488 lemma floor_eq4: "real n \<le> x \<Longrightarrow> x < real (Suc n) \<Longrightarrow> nat \<lfloor>x\<rfloor> = n"
  1489   by linarith
  1490 
  1491 lemma real_of_int_floor_ge_diff_one [simp]: "r - 1 \<le> real_of_int \<lfloor>r\<rfloor>"
  1492   by linarith
  1493 
  1494 lemma real_of_int_floor_gt_diff_one [simp]: "r - 1 < real_of_int \<lfloor>r\<rfloor>"
  1495   by linarith
  1496 
  1497 lemma real_of_int_floor_add_one_ge [simp]: "r \<le> real_of_int \<lfloor>r\<rfloor> + 1"
  1498   by linarith
  1499 
  1500 lemma real_of_int_floor_add_one_gt [simp]: "r < real_of_int \<lfloor>r\<rfloor> + 1"
  1501   by linarith
  1502 
  1503 lemma floor_eq_iff: "\<lfloor>x\<rfloor> = b \<longleftrightarrow> of_int b \<le> x \<and> x < of_int (b + 1)"
  1504   by (simp add: floor_unique_iff)
  1505 
  1506 lemma floor_divide_real_eq_div:
  1507   assumes "0 \<le> b"
  1508   shows "\<lfloor>a / real_of_int b\<rfloor> = \<lfloor>a\<rfloor> div b"
  1509 proof (cases "b = 0")
  1510   case True
  1511   then show ?thesis by simp
  1512 next
  1513   case False
  1514   with assms have b: "b > 0" by simp
  1515   have "j = i div b"
  1516     if "real_of_int i \<le> a" "a < 1 + real_of_int i"
  1517       "real_of_int j * real_of_int b \<le> a" "a < real_of_int b + real_of_int j * real_of_int b"
  1518     for i j :: int
  1519   proof -
  1520     from that have "i < b + j * b"
  1521       by (metis le_less_trans of_int_add of_int_less_iff of_int_mult)
  1522     moreover have "j * b < 1 + i"
  1523     proof -
  1524       have "real_of_int (j * b) < real_of_int i + 1"
  1525         using \<open>a < 1 + real_of_int i\<close> \<open>real_of_int j * real_of_int b \<le> a\<close> by force
  1526       then show "j * b < 1 + i" by linarith
  1527     qed
  1528     ultimately have "(j - i div b) * b \<le> i mod b" "i mod b < ((j - i div b) + 1) * b"
  1529       by (auto simp: field_simps)
  1530     then have "(j - i div b) * b < 1 * b" "0 * b < ((j - i div b) + 1) * b"
  1531       using pos_mod_bound [OF b, of i] pos_mod_sign [OF b, of i]
  1532       by linarith+
  1533     then show ?thesis using b unfolding mult_less_cancel_right by auto
  1534   qed
  1535   with b show ?thesis by (auto split: floor_split simp: field_simps)
  1536 qed
  1537 
  1538 lemma floor_one_divide_eq_div_numeral [simp]:
  1539   "\<lfloor>1 / numeral b::real\<rfloor> = 1 div numeral b"
  1540 by (metis floor_divide_of_int_eq of_int_1 of_int_numeral)
  1541 
  1542 lemma floor_minus_one_divide_eq_div_numeral [simp]:
  1543   "\<lfloor>- (1 / numeral b)::real\<rfloor> = - 1 div numeral b"
  1544 by (metis (mono_tags, hide_lams) div_minus_right minus_divide_right
  1545     floor_divide_of_int_eq of_int_neg_numeral of_int_1)
  1546 
  1547 lemma floor_divide_eq_div_numeral [simp]:
  1548   "\<lfloor>numeral a / numeral b::real\<rfloor> = numeral a div numeral b"
  1549 by (metis floor_divide_of_int_eq of_int_numeral)
  1550 
  1551 lemma floor_minus_divide_eq_div_numeral [simp]:
  1552   "\<lfloor>- (numeral a / numeral b)::real\<rfloor> = - numeral a div numeral b"
  1553 by (metis divide_minus_left floor_divide_of_int_eq of_int_neg_numeral of_int_numeral)
  1554 
  1555 lemma of_int_ceiling_cancel [simp]: "of_int \<lceil>x\<rceil> = x \<longleftrightarrow> (\<exists>n::int. x = of_int n)"
  1556   using ceiling_of_int by metis
  1557 
  1558 lemma ceiling_eq: "of_int n < x \<Longrightarrow> x \<le> of_int n + 1 \<Longrightarrow> \<lceil>x\<rceil> = n + 1"
  1559   by (simp add: ceiling_unique)
  1560 
  1561 lemma of_int_ceiling_diff_one_le [simp]: "of_int \<lceil>r\<rceil> - 1 \<le> r"
  1562   by linarith
  1563 
  1564 lemma of_int_ceiling_le_add_one [simp]: "of_int \<lceil>r\<rceil> \<le> r + 1"
  1565   by linarith
  1566 
  1567 lemma ceiling_le: "x \<le> of_int a \<Longrightarrow> \<lceil>x\<rceil> \<le> a"
  1568   by (simp add: ceiling_le_iff)
  1569 
  1570 lemma ceiling_divide_eq_div: "\<lceil>of_int a / of_int b\<rceil> = - (- a div b)"
  1571   by (metis ceiling_def floor_divide_of_int_eq minus_divide_left of_int_minus)
  1572 
  1573 lemma ceiling_divide_eq_div_numeral [simp]:
  1574   "\<lceil>numeral a / numeral b :: real\<rceil> = - (- numeral a div numeral b)"
  1575   using ceiling_divide_eq_div[of "numeral a" "numeral b"] by simp
  1576 
  1577 lemma ceiling_minus_divide_eq_div_numeral [simp]:
  1578   "\<lceil>- (numeral a / numeral b :: real)\<rceil> = - (numeral a div numeral b)"
  1579   using ceiling_divide_eq_div[of "- numeral a" "numeral b"] by simp
  1580 
  1581 text \<open>
  1582   The following lemmas are remnants of the erstwhile functions natfloor
  1583   and natceiling.
  1584 \<close>
  1585 
  1586 lemma nat_floor_neg: "x \<le> 0 \<Longrightarrow> nat \<lfloor>x\<rfloor> = 0"
  1587   for x :: real
  1588   by linarith
  1589 
  1590 lemma le_nat_floor: "real x \<le> a \<Longrightarrow> x \<le> nat \<lfloor>a\<rfloor>"
  1591   by linarith
  1592 
  1593 lemma le_mult_nat_floor: "nat \<lfloor>a\<rfloor> * nat \<lfloor>b\<rfloor> \<le> nat \<lfloor>a * b\<rfloor>"
  1594   by (cases "0 \<le> a \<and> 0 \<le> b")
  1595      (auto simp add: nat_mult_distrib[symmetric] nat_mono le_mult_floor)
  1596 
  1597 lemma nat_ceiling_le_eq [simp]: "nat \<lceil>x\<rceil> \<le> a \<longleftrightarrow> x \<le> real a"
  1598   by linarith
  1599 
  1600 lemma real_nat_ceiling_ge: "x \<le> real (nat \<lceil>x\<rceil>)"
  1601   by linarith
  1602 
  1603 lemma Rats_no_top_le: "\<exists>q \<in> \<rat>. x \<le> q"
  1604   for x :: real
  1605   by (auto intro!: bexI[of _ "of_nat (nat \<lceil>x\<rceil>)"]) linarith
  1606 
  1607 lemma Rats_no_bot_less: "\<exists>q \<in> \<rat>. q < x" for x :: real
  1608   apply (auto intro!: bexI[of _ "of_int (\<lfloor>x\<rfloor> - 1)"])
  1609   apply (rule less_le_trans[OF _ of_int_floor_le])
  1610   apply simp
  1611   done
  1612 
  1613 
  1614 subsection \<open>Exponentiation with floor\<close>
  1615 
  1616 lemma floor_power:
  1617   assumes "x = of_int \<lfloor>x\<rfloor>"
  1618   shows "\<lfloor>x ^ n\<rfloor> = \<lfloor>x\<rfloor> ^ n"
  1619 proof -
  1620   have "x ^ n = of_int (\<lfloor>x\<rfloor> ^ n)"
  1621     using assms by (induct n arbitrary: x) simp_all
  1622   then show ?thesis by (metis floor_of_int)
  1623 qed
  1624 
  1625 lemma floor_numeral_power [simp]: "\<lfloor>numeral x ^ n\<rfloor> = numeral x ^ n"
  1626   by (metis floor_of_int of_int_numeral of_int_power)
  1627 
  1628 lemma ceiling_numeral_power [simp]: "\<lceil>numeral x ^ n\<rceil> = numeral x ^ n"
  1629   by (metis ceiling_of_int of_int_numeral of_int_power)
  1630 
  1631 
  1632 subsection \<open>Implementation of rational real numbers\<close>
  1633 
  1634 text \<open>Formal constructor\<close>
  1635 
  1636 definition Ratreal :: "rat \<Rightarrow> real"
  1637   where [code_abbrev, simp]: "Ratreal = of_rat"
  1638 
  1639 code_datatype Ratreal
  1640 
  1641 
  1642 text \<open>Numerals\<close>
  1643 
  1644 lemma [code_abbrev]: "(of_rat (of_int a) :: real) = of_int a"
  1645   by simp
  1646 
  1647 lemma [code_abbrev]: "(of_rat 0 :: real) = 0"
  1648   by simp
  1649 
  1650 lemma [code_abbrev]: "(of_rat 1 :: real) = 1"
  1651   by simp
  1652 
  1653 lemma [code_abbrev]: "(of_rat (- 1) :: real) = - 1"
  1654   by simp
  1655 
  1656 lemma [code_abbrev]: "(of_rat (numeral k) :: real) = numeral k"
  1657   by simp
  1658 
  1659 lemma [code_abbrev]: "(of_rat (- numeral k) :: real) = - numeral k"
  1660   by simp
  1661 
  1662 lemma [code_post]:
  1663   "(of_rat (1 / numeral k) :: real) = 1 / numeral k"
  1664   "(of_rat (numeral k / numeral l) :: real) = numeral k / numeral l"
  1665   "(of_rat (- (1 / numeral k)) :: real) = - (1 / numeral k)"
  1666   "(of_rat (- (numeral k / numeral l)) :: real) = - (numeral k / numeral l)"
  1667   by (simp_all add: of_rat_divide of_rat_minus)
  1668 
  1669 
  1670 text \<open>Operations\<close>
  1671 
  1672 lemma zero_real_code [code]: "0 = Ratreal 0"
  1673   by simp
  1674 
  1675 lemma one_real_code [code]: "1 = Ratreal 1"
  1676   by simp
  1677 
  1678 instantiation real :: equal
  1679 begin
  1680 
  1681 definition "HOL.equal x y \<longleftrightarrow> x - y = 0" for x :: real
  1682 
  1683 instance by standard (simp add: equal_real_def)
  1684 
  1685 lemma real_equal_code [code]: "HOL.equal (Ratreal x) (Ratreal y) \<longleftrightarrow> HOL.equal x y"
  1686   by (simp add: equal_real_def equal)
  1687 
  1688 lemma [code nbe]: "HOL.equal x x \<longleftrightarrow> True"
  1689   for x :: real
  1690   by (rule equal_refl)
  1691 
  1692 end
  1693 
  1694 lemma real_less_eq_code [code]: "Ratreal x \<le> Ratreal y \<longleftrightarrow> x \<le> y"
  1695   by (simp add: of_rat_less_eq)
  1696 
  1697 lemma real_less_code [code]: "Ratreal x < Ratreal y \<longleftrightarrow> x < y"
  1698   by (simp add: of_rat_less)
  1699 
  1700 lemma real_plus_code [code]: "Ratreal x + Ratreal y = Ratreal (x + y)"
  1701   by (simp add: of_rat_add)
  1702 
  1703 lemma real_times_code [code]: "Ratreal x * Ratreal y = Ratreal (x * y)"
  1704   by (simp add: of_rat_mult)
  1705 
  1706 lemma real_uminus_code [code]: "- Ratreal x = Ratreal (- x)"
  1707   by (simp add: of_rat_minus)
  1708 
  1709 lemma real_minus_code [code]: "Ratreal x - Ratreal y = Ratreal (x - y)"
  1710   by (simp add: of_rat_diff)
  1711 
  1712 lemma real_inverse_code [code]: "inverse (Ratreal x) = Ratreal (inverse x)"
  1713   by (simp add: of_rat_inverse)
  1714 
  1715 lemma real_divide_code [code]: "Ratreal x / Ratreal y = Ratreal (x / y)"
  1716   by (simp add: of_rat_divide)
  1717 
  1718 lemma real_floor_code [code]: "\<lfloor>Ratreal x\<rfloor> = \<lfloor>x\<rfloor>"
  1719   by (metis Ratreal_def floor_le_iff floor_unique le_floor_iff
  1720       of_int_floor_le of_rat_of_int_eq real_less_eq_code)
  1721 
  1722 
  1723 text \<open>Quickcheck\<close>
  1724 
  1725 definition (in term_syntax)
  1726   valterm_ratreal :: "rat \<times> (unit \<Rightarrow> Code_Evaluation.term) \<Rightarrow> real \<times> (unit \<Rightarrow> Code_Evaluation.term)"
  1727   where [code_unfold]: "valterm_ratreal k = Code_Evaluation.valtermify Ratreal {\<cdot>} k"
  1728 
  1729 notation fcomp (infixl "\<circ>>" 60)
  1730 notation scomp (infixl "\<circ>\<rightarrow>" 60)
  1731 
  1732 instantiation real :: random
  1733 begin
  1734 
  1735 definition
  1736   "Quickcheck_Random.random i = Quickcheck_Random.random i \<circ>\<rightarrow> (\<lambda>r. Pair (valterm_ratreal r))"
  1737 
  1738 instance ..
  1739 
  1740 end
  1741 
  1742 no_notation fcomp (infixl "\<circ>>" 60)
  1743 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
  1744 
  1745 instantiation real :: exhaustive
  1746 begin
  1747 
  1748 definition
  1749   "exhaustive_real f d = Quickcheck_Exhaustive.exhaustive (\<lambda>r. f (Ratreal r)) d"
  1750 
  1751 instance ..
  1752 
  1753 end
  1754 
  1755 instantiation real :: full_exhaustive
  1756 begin
  1757 
  1758 definition
  1759   "full_exhaustive_real f d = Quickcheck_Exhaustive.full_exhaustive (\<lambda>r. f (valterm_ratreal r)) d"
  1760 
  1761 instance ..
  1762 
  1763 end
  1764 
  1765 instantiation real :: narrowing
  1766 begin
  1767 
  1768 definition
  1769   "narrowing_real = Quickcheck_Narrowing.apply (Quickcheck_Narrowing.cons Ratreal) narrowing"
  1770 
  1771 instance ..
  1772 
  1773 end
  1774 
  1775 
  1776 subsection \<open>Setup for Nitpick\<close>
  1777 
  1778 declaration \<open>
  1779   Nitpick_HOL.register_frac_type @{type_name real}
  1780     [(@{const_name zero_real_inst.zero_real}, @{const_name Nitpick.zero_frac}),
  1781      (@{const_name one_real_inst.one_real}, @{const_name Nitpick.one_frac}),
  1782      (@{const_name plus_real_inst.plus_real}, @{const_name Nitpick.plus_frac}),
  1783      (@{const_name times_real_inst.times_real}, @{const_name Nitpick.times_frac}),
  1784      (@{const_name uminus_real_inst.uminus_real}, @{const_name Nitpick.uminus_frac}),
  1785      (@{const_name inverse_real_inst.inverse_real}, @{const_name Nitpick.inverse_frac}),
  1786      (@{const_name ord_real_inst.less_real}, @{const_name Nitpick.less_frac}),
  1787      (@{const_name ord_real_inst.less_eq_real}, @{const_name Nitpick.less_eq_frac})]
  1788 \<close>
  1789 
  1790 lemmas [nitpick_unfold] = inverse_real_inst.inverse_real one_real_inst.one_real
  1791   ord_real_inst.less_real ord_real_inst.less_eq_real plus_real_inst.plus_real
  1792   times_real_inst.times_real uminus_real_inst.uminus_real
  1793   zero_real_inst.zero_real
  1794 
  1795 
  1796 subsection \<open>Setup for SMT\<close>
  1797 
  1798 ML_file "Tools/SMT/smt_real.ML"
  1799 ML_file "Tools/SMT/z3_real.ML"
  1800 
  1801 lemma [z3_rule]:
  1802   "0 + x = x"
  1803   "x + 0 = x"
  1804   "0 * x = 0"
  1805   "1 * x = x"
  1806   "x + y = y + x"
  1807   for x y :: real
  1808   by auto
  1809 
  1810 
  1811 subsection \<open>Setup for Argo\<close>
  1812 
  1813 ML_file "Tools/Argo/argo_real.ML"
  1814 
  1815 end