author hoelzl
Thu Oct 20 18:41:59 2016 +0200 (2016-10-20)
changeset 64320 ba194424b895
parent 64283 979cdfdf7a79
child 64911 f0e07600de47
permissions -rw-r--r--
HOL-Probability: move stopping time from AFP/Markov_Models
     1 (*  Title:      HOL/Analysis/Measure_Space.thy
     2     Author:     Lawrence C Paulson
     3     Author:     Johannes Hölzl, TU München
     4     Author:     Armin Heller, TU München
     5 *)
     7 section \<open>Measure spaces and their properties\<close>
     9 theory Measure_Space
    10 imports
    11   Measurable "~~/src/HOL/Library/Extended_Nonnegative_Real"
    12 begin
    14 subsection "Relate extended reals and the indicator function"
    16 lemma suminf_cmult_indicator:
    17   fixes f :: "nat \<Rightarrow> ennreal"
    18   assumes "disjoint_family A" "x \<in> A i"
    19   shows "(\<Sum>n. f n * indicator (A n) x) = f i"
    20 proof -
    21   have **: "\<And>n. f n * indicator (A n) x = (if n = i then f n else 0 :: ennreal)"
    22     using \<open>x \<in> A i\<close> assms unfolding disjoint_family_on_def indicator_def by auto
    23   then have "\<And>n. (\<Sum>j<n. f j * indicator (A j) x) = (if i < n then f i else 0 :: ennreal)"
    24     by (auto simp: sum.If_cases)
    25   moreover have "(SUP n. if i < n then f i else 0) = (f i :: ennreal)"
    26   proof (rule SUP_eqI)
    27     fix y :: ennreal assume "\<And>n. n \<in> UNIV \<Longrightarrow> (if i < n then f i else 0) \<le> y"
    28     from this[of "Suc i"] show "f i \<le> y" by auto
    29   qed (insert assms, simp)
    30   ultimately show ?thesis using assms
    31     by (subst suminf_eq_SUP) (auto simp: indicator_def)
    32 qed
    34 lemma suminf_indicator:
    35   assumes "disjoint_family A"
    36   shows "(\<Sum>n. indicator (A n) x :: ennreal) = indicator (\<Union>i. A i) x"
    37 proof cases
    38   assume *: "x \<in> (\<Union>i. A i)"
    39   then obtain i where "x \<in> A i" by auto
    40   from suminf_cmult_indicator[OF assms(1), OF \<open>x \<in> A i\<close>, of "\<lambda>k. 1"]
    41   show ?thesis using * by simp
    42 qed simp
    44 lemma sum_indicator_disjoint_family:
    45   fixes f :: "'d \<Rightarrow> 'e::semiring_1"
    46   assumes d: "disjoint_family_on A P" and "x \<in> A j" and "finite P" and "j \<in> P"
    47   shows "(\<Sum>i\<in>P. f i * indicator (A i) x) = f j"
    48 proof -
    49   have "P \<inter> {i. x \<in> A i} = {j}"
    50     using d \<open>x \<in> A j\<close> \<open>j \<in> P\<close> unfolding disjoint_family_on_def
    51     by auto
    52   thus ?thesis
    53     unfolding indicator_def
    54     by (simp add: if_distrib sum.If_cases[OF \<open>finite P\<close>])
    55 qed
    57 text \<open>
    58   The type for emeasure spaces is already defined in @{theory Sigma_Algebra}, as it is also used to
    59   represent sigma algebras (with an arbitrary emeasure).
    60 \<close>
    62 subsection "Extend binary sets"
    64 lemma LIMSEQ_binaryset:
    65   assumes f: "f {} = 0"
    66   shows  "(\<lambda>n. \<Sum>i<n. f (binaryset A B i)) \<longlonglongrightarrow> f A + f B"
    67 proof -
    68   have "(\<lambda>n. \<Sum>i < Suc (Suc n). f (binaryset A B i)) = (\<lambda>n. f A + f B)"
    69     proof
    70       fix n
    71       show "(\<Sum>i < Suc (Suc n). f (binaryset A B i)) = f A + f B"
    72         by (induct n)  (auto simp add: binaryset_def f)
    73     qed
    74   moreover
    75   have "... \<longlonglongrightarrow> f A + f B" by (rule tendsto_const)
    76   ultimately
    77   have "(\<lambda>n. \<Sum>i< Suc (Suc n). f (binaryset A B i)) \<longlonglongrightarrow> f A + f B"
    78     by metis
    79   hence "(\<lambda>n. \<Sum>i< n+2. f (binaryset A B i)) \<longlonglongrightarrow> f A + f B"
    80     by simp
    81   thus ?thesis by (rule LIMSEQ_offset [where k=2])
    82 qed
    84 lemma binaryset_sums:
    85   assumes f: "f {} = 0"
    86   shows  "(\<lambda>n. f (binaryset A B n)) sums (f A + f B)"
    87     by (simp add: sums_def LIMSEQ_binaryset [where f=f, OF f] atLeast0LessThan)
    89 lemma suminf_binaryset_eq:
    90   fixes f :: "'a set \<Rightarrow> 'b::{comm_monoid_add, t2_space}"
    91   shows "f {} = 0 \<Longrightarrow> (\<Sum>n. f (binaryset A B n)) = f A + f B"
    92   by (metis binaryset_sums sums_unique)
    94 subsection \<open>Properties of a premeasure @{term \<mu>}\<close>
    96 text \<open>
    97   The definitions for @{const positive} and @{const countably_additive} should be here, by they are
    98   necessary to define @{typ "'a measure"} in @{theory Sigma_Algebra}.
    99 \<close>
   101 definition subadditive where
   102   "subadditive M f \<longleftrightarrow> (\<forall>x\<in>M. \<forall>y\<in>M. x \<inter> y = {} \<longrightarrow> f (x \<union> y) \<le> f x + f y)"
   104 lemma subadditiveD: "subadditive M f \<Longrightarrow> x \<inter> y = {} \<Longrightarrow> x \<in> M \<Longrightarrow> y \<in> M \<Longrightarrow> f (x \<union> y) \<le> f x + f y"
   105   by (auto simp add: subadditive_def)
   107 definition countably_subadditive where
   108   "countably_subadditive M f \<longleftrightarrow>
   109     (\<forall>A. range A \<subseteq> M \<longrightarrow> disjoint_family A \<longrightarrow> (\<Union>i. A i) \<in> M \<longrightarrow> (f (\<Union>i. A i) \<le> (\<Sum>i. f (A i))))"
   111 lemma (in ring_of_sets) countably_subadditive_subadditive:
   112   fixes f :: "'a set \<Rightarrow> ennreal"
   113   assumes f: "positive M f" and cs: "countably_subadditive M f"
   114   shows  "subadditive M f"
   115 proof (auto simp add: subadditive_def)
   116   fix x y
   117   assume x: "x \<in> M" and y: "y \<in> M" and "x \<inter> y = {}"
   118   hence "disjoint_family (binaryset x y)"
   119     by (auto simp add: disjoint_family_on_def binaryset_def)
   120   hence "range (binaryset x y) \<subseteq> M \<longrightarrow>
   121          (\<Union>i. binaryset x y i) \<in> M \<longrightarrow>
   122          f (\<Union>i. binaryset x y i) \<le> (\<Sum> n. f (binaryset x y n))"
   123     using cs by (auto simp add: countably_subadditive_def)
   124   hence "{x,y,{}} \<subseteq> M \<longrightarrow> x \<union> y \<in> M \<longrightarrow>
   125          f (x \<union> y) \<le> (\<Sum> n. f (binaryset x y n))"
   126     by (simp add: range_binaryset_eq UN_binaryset_eq)
   127   thus "f (x \<union> y) \<le>  f x + f y" using f x y
   128     by (auto simp add: Un o_def suminf_binaryset_eq positive_def)
   129 qed
   131 definition additive where
   132   "additive M \<mu> \<longleftrightarrow> (\<forall>x\<in>M. \<forall>y\<in>M. x \<inter> y = {} \<longrightarrow> \<mu> (x \<union> y) = \<mu> x + \<mu> y)"
   134 definition increasing where
   135   "increasing M \<mu> \<longleftrightarrow> (\<forall>x\<in>M. \<forall>y\<in>M. x \<subseteq> y \<longrightarrow> \<mu> x \<le> \<mu> y)"
   137 lemma positiveD1: "positive M f \<Longrightarrow> f {} = 0" by (auto simp: positive_def)
   139 lemma positiveD_empty:
   140   "positive M f \<Longrightarrow> f {} = 0"
   141   by (auto simp add: positive_def)
   143 lemma additiveD:
   144   "additive M f \<Longrightarrow> x \<inter> y = {} \<Longrightarrow> x \<in> M \<Longrightarrow> y \<in> M \<Longrightarrow> f (x \<union> y) = f x + f y"
   145   by (auto simp add: additive_def)
   147 lemma increasingD:
   148   "increasing M f \<Longrightarrow> x \<subseteq> y \<Longrightarrow> x\<in>M \<Longrightarrow> y\<in>M \<Longrightarrow> f x \<le> f y"
   149   by (auto simp add: increasing_def)
   151 lemma countably_additiveI[case_names countably]:
   152   "(\<And>A. range A \<subseteq> M \<Longrightarrow> disjoint_family A \<Longrightarrow> (\<Union>i. A i) \<in> M \<Longrightarrow> (\<Sum>i. f (A i)) = f (\<Union>i. A i))
   153   \<Longrightarrow> countably_additive M f"
   154   by (simp add: countably_additive_def)
   156 lemma (in ring_of_sets) disjointed_additive:
   157   assumes f: "positive M f" "additive M f" and A: "range A \<subseteq> M" "incseq A"
   158   shows "(\<Sum>i\<le>n. f (disjointed A i)) = f (A n)"
   159 proof (induct n)
   160   case (Suc n)
   161   then have "(\<Sum>i\<le>Suc n. f (disjointed A i)) = f (A n) + f (disjointed A (Suc n))"
   162     by simp
   163   also have "\<dots> = f (A n \<union> disjointed A (Suc n))"
   164     using A by (subst f(2)[THEN additiveD]) (auto simp: disjointed_mono)
   165   also have "A n \<union> disjointed A (Suc n) = A (Suc n)"
   166     using \<open>incseq A\<close> by (auto dest: incseq_SucD simp: disjointed_mono)
   167   finally show ?case .
   168 qed simp
   170 lemma (in ring_of_sets) additive_sum:
   171   fixes A:: "'i \<Rightarrow> 'a set"
   172   assumes f: "positive M f" and ad: "additive M f" and "finite S"
   173       and A: "A`S \<subseteq> M"
   174       and disj: "disjoint_family_on A S"
   175   shows  "(\<Sum>i\<in>S. f (A i)) = f (\<Union>i\<in>S. A i)"
   176   using \<open>finite S\<close> disj A
   177 proof induct
   178   case empty show ?case using f by (simp add: positive_def)
   179 next
   180   case (insert s S)
   181   then have "A s \<inter> (\<Union>i\<in>S. A i) = {}"
   182     by (auto simp add: disjoint_family_on_def neq_iff)
   183   moreover
   184   have "A s \<in> M" using insert by blast
   185   moreover have "(\<Union>i\<in>S. A i) \<in> M"
   186     using insert \<open>finite S\<close> by auto
   187   ultimately have "f (A s \<union> (\<Union>i\<in>S. A i)) = f (A s) + f(\<Union>i\<in>S. A i)"
   188     using ad UNION_in_sets A by (auto simp add: additive_def)
   189   with insert show ?case using ad disjoint_family_on_mono[of S "insert s S" A]
   190     by (auto simp add: additive_def subset_insertI)
   191 qed
   193 lemma (in ring_of_sets) additive_increasing:
   194   fixes f :: "'a set \<Rightarrow> ennreal"
   195   assumes posf: "positive M f" and addf: "additive M f"
   196   shows "increasing M f"
   197 proof (auto simp add: increasing_def)
   198   fix x y
   199   assume xy: "x \<in> M" "y \<in> M" "x \<subseteq> y"
   200   then have "y - x \<in> M" by auto
   201   then have "f x + 0 \<le> f x + f (y-x)" by (intro add_left_mono zero_le)
   202   also have "... = f (x \<union> (y-x))" using addf
   203     by (auto simp add: additive_def) (metis Diff_disjoint Un_Diff_cancel Diff xy(1,2))
   204   also have "... = f y"
   205     by (metis Un_Diff_cancel Un_absorb1 xy(3))
   206   finally show "f x \<le> f y" by simp
   207 qed
   209 lemma (in ring_of_sets) subadditive:
   210   fixes f :: "'a set \<Rightarrow> ennreal"
   211   assumes f: "positive M f" "additive M f" and A: "A`S \<subseteq> M" and S: "finite S"
   212   shows "f (\<Union>i\<in>S. A i) \<le> (\<Sum>i\<in>S. f (A i))"
   213 using S A
   214 proof (induct S)
   215   case empty thus ?case using f by (auto simp: positive_def)
   216 next
   217   case (insert x F)
   218   hence in_M: "A x \<in> M" "(\<Union>i\<in>F. A i) \<in> M" "(\<Union>i\<in>F. A i) - A x \<in> M" using A by force+
   219   have subs: "(\<Union>i\<in>F. A i) - A x \<subseteq> (\<Union>i\<in>F. A i)" by auto
   220   have "(\<Union>i\<in>(insert x F). A i) = A x \<union> ((\<Union>i\<in>F. A i) - A x)" by auto
   221   hence "f (\<Union>i\<in>(insert x F). A i) = f (A x \<union> ((\<Union>i\<in>F. A i) - A x))"
   222     by simp
   223   also have "\<dots> = f (A x) + f ((\<Union>i\<in>F. A i) - A x)"
   224     using f(2) by (rule additiveD) (insert in_M, auto)
   225   also have "\<dots> \<le> f (A x) + f (\<Union>i\<in>F. A i)"
   226     using additive_increasing[OF f] in_M subs by (auto simp: increasing_def intro: add_left_mono)
   227   also have "\<dots> \<le> f (A x) + (\<Sum>i\<in>F. f (A i))" using insert by (auto intro: add_left_mono)
   228   finally show "f (\<Union>i\<in>(insert x F). A i) \<le> (\<Sum>i\<in>(insert x F). f (A i))" using insert by simp
   229 qed
   231 lemma (in ring_of_sets) countably_additive_additive:
   232   fixes f :: "'a set \<Rightarrow> ennreal"
   233   assumes posf: "positive M f" and ca: "countably_additive M f"
   234   shows "additive M f"
   235 proof (auto simp add: additive_def)
   236   fix x y
   237   assume x: "x \<in> M" and y: "y \<in> M" and "x \<inter> y = {}"
   238   hence "disjoint_family (binaryset x y)"
   239     by (auto simp add: disjoint_family_on_def binaryset_def)
   240   hence "range (binaryset x y) \<subseteq> M \<longrightarrow>
   241          (\<Union>i. binaryset x y i) \<in> M \<longrightarrow>
   242          f (\<Union>i. binaryset x y i) = (\<Sum> n. f (binaryset x y n))"
   243     using ca
   244     by (simp add: countably_additive_def)
   245   hence "{x,y,{}} \<subseteq> M \<longrightarrow> x \<union> y \<in> M \<longrightarrow>
   246          f (x \<union> y) = (\<Sum>n. f (binaryset x y n))"
   247     by (simp add: range_binaryset_eq UN_binaryset_eq)
   248   thus "f (x \<union> y) = f x + f y" using posf x y
   249     by (auto simp add: Un suminf_binaryset_eq positive_def)
   250 qed
   252 lemma (in algebra) increasing_additive_bound:
   253   fixes A:: "nat \<Rightarrow> 'a set" and  f :: "'a set \<Rightarrow> ennreal"
   254   assumes f: "positive M f" and ad: "additive M f"
   255       and inc: "increasing M f"
   256       and A: "range A \<subseteq> M"
   257       and disj: "disjoint_family A"
   258   shows  "(\<Sum>i. f (A i)) \<le> f \<Omega>"
   259 proof (safe intro!: suminf_le_const)
   260   fix N
   261   note disj_N = disjoint_family_on_mono[OF _ disj, of "{..<N}"]
   262   have "(\<Sum>i<N. f (A i)) = f (\<Union>i\<in>{..<N}. A i)"
   263     using A by (intro additive_sum [OF f ad _ _]) (auto simp: disj_N)
   264   also have "... \<le> f \<Omega>" using space_closed A
   265     by (intro increasingD[OF inc] finite_UN) auto
   266   finally show "(\<Sum>i<N. f (A i)) \<le> f \<Omega>" by simp
   267 qed (insert f A, auto simp: positive_def)
   269 lemma (in ring_of_sets) countably_additiveI_finite:
   270   fixes \<mu> :: "'a set \<Rightarrow> ennreal"
   271   assumes "finite \<Omega>" "positive M \<mu>" "additive M \<mu>"
   272   shows "countably_additive M \<mu>"
   273 proof (rule countably_additiveI)
   274   fix F :: "nat \<Rightarrow> 'a set" assume F: "range F \<subseteq> M" "(\<Union>i. F i) \<in> M" and disj: "disjoint_family F"
   276   have "\<forall>i\<in>{i. F i \<noteq> {}}. \<exists>x. x \<in> F i" by auto
   277   from bchoice[OF this] obtain f where f: "\<And>i. F i \<noteq> {} \<Longrightarrow> f i \<in> F i" by auto
   279   have inj_f: "inj_on f {i. F i \<noteq> {}}"
   280   proof (rule inj_onI, simp)
   281     fix i j a b assume *: "f i = f j" "F i \<noteq> {}" "F j \<noteq> {}"
   282     then have "f i \<in> F i" "f j \<in> F j" using f by force+
   283     with disj * show "i = j" by (auto simp: disjoint_family_on_def)
   284   qed
   285   have "finite (\<Union>i. F i)"
   286     by (metis F(2) assms(1) infinite_super sets_into_space)
   288   have F_subset: "{i. \<mu> (F i) \<noteq> 0} \<subseteq> {i. F i \<noteq> {}}"
   289     by (auto simp: positiveD_empty[OF \<open>positive M \<mu>\<close>])
   290   moreover have fin_not_empty: "finite {i. F i \<noteq> {}}"
   291   proof (rule finite_imageD)
   292     from f have "f`{i. F i \<noteq> {}} \<subseteq> (\<Union>i. F i)" by auto
   293     then show "finite (f`{i. F i \<noteq> {}})"
   294       by (rule finite_subset) fact
   295   qed fact
   296   ultimately have fin_not_0: "finite {i. \<mu> (F i) \<noteq> 0}"
   297     by (rule finite_subset)
   299   have disj_not_empty: "disjoint_family_on F {i. F i \<noteq> {}}"
   300     using disj by (auto simp: disjoint_family_on_def)
   302   from fin_not_0 have "(\<Sum>i. \<mu> (F i)) = (\<Sum>i | \<mu> (F i) \<noteq> 0. \<mu> (F i))"
   303     by (rule suminf_finite) auto
   304   also have "\<dots> = (\<Sum>i | F i \<noteq> {}. \<mu> (F i))"
   305     using fin_not_empty F_subset by (rule sum.mono_neutral_left) auto
   306   also have "\<dots> = \<mu> (\<Union>i\<in>{i. F i \<noteq> {}}. F i)"
   307     using \<open>positive M \<mu>\<close> \<open>additive M \<mu>\<close> fin_not_empty disj_not_empty F by (intro additive_sum) auto
   308   also have "\<dots> = \<mu> (\<Union>i. F i)"
   309     by (rule arg_cong[where f=\<mu>]) auto
   310   finally show "(\<Sum>i. \<mu> (F i)) = \<mu> (\<Union>i. F i)" .
   311 qed
   313 lemma (in ring_of_sets) countably_additive_iff_continuous_from_below:
   314   fixes f :: "'a set \<Rightarrow> ennreal"
   315   assumes f: "positive M f" "additive M f"
   316   shows "countably_additive M f \<longleftrightarrow>
   317     (\<forall>A. range A \<subseteq> M \<longrightarrow> incseq A \<longrightarrow> (\<Union>i. A i) \<in> M \<longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Union>i. A i))"
   318   unfolding countably_additive_def
   319 proof safe
   320   assume count_sum: "\<forall>A. range A \<subseteq> M \<longrightarrow> disjoint_family A \<longrightarrow> UNION UNIV A \<in> M \<longrightarrow> (\<Sum>i. f (A i)) = f (UNION UNIV A)"
   321   fix A :: "nat \<Rightarrow> 'a set" assume A: "range A \<subseteq> M" "incseq A" "(\<Union>i. A i) \<in> M"
   322   then have dA: "range (disjointed A) \<subseteq> M" by (auto simp: range_disjointed_sets)
   323   with count_sum[THEN spec, of "disjointed A"] A(3)
   324   have f_UN: "(\<Sum>i. f (disjointed A i)) = f (\<Union>i. A i)"
   325     by (auto simp: UN_disjointed_eq disjoint_family_disjointed)
   326   moreover have "(\<lambda>n. (\<Sum>i<n. f (disjointed A i))) \<longlonglongrightarrow> (\<Sum>i. f (disjointed A i))"
   327     using f(1)[unfolded positive_def] dA
   328     by (auto intro!: summable_LIMSEQ)
   329   from LIMSEQ_Suc[OF this]
   330   have "(\<lambda>n. (\<Sum>i\<le>n. f (disjointed A i))) \<longlonglongrightarrow> (\<Sum>i. f (disjointed A i))"
   331     unfolding lessThan_Suc_atMost .
   332   moreover have "\<And>n. (\<Sum>i\<le>n. f (disjointed A i)) = f (A n)"
   333     using disjointed_additive[OF f A(1,2)] .
   334   ultimately show "(\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Union>i. A i)" by simp
   335 next
   336   assume cont: "\<forall>A. range A \<subseteq> M \<longrightarrow> incseq A \<longrightarrow> (\<Union>i. A i) \<in> M \<longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Union>i. A i)"
   337   fix A :: "nat \<Rightarrow> 'a set" assume A: "range A \<subseteq> M" "disjoint_family A" "(\<Union>i. A i) \<in> M"
   338   have *: "(\<Union>n. (\<Union>i<n. A i)) = (\<Union>i. A i)" by auto
   339   have "(\<lambda>n. f (\<Union>i<n. A i)) \<longlonglongrightarrow> f (\<Union>i. A i)"
   340   proof (unfold *[symmetric], intro cont[rule_format])
   341     show "range (\<lambda>i. \<Union>i<i. A i) \<subseteq> M" "(\<Union>i. \<Union>i<i. A i) \<in> M"
   342       using A * by auto
   343   qed (force intro!: incseq_SucI)
   344   moreover have "\<And>n. f (\<Union>i<n. A i) = (\<Sum>i<n. f (A i))"
   345     using A
   346     by (intro additive_sum[OF f, of _ A, symmetric])
   347        (auto intro: disjoint_family_on_mono[where B=UNIV])
   348   ultimately
   349   have "(\<lambda>i. f (A i)) sums f (\<Union>i. A i)"
   350     unfolding sums_def by simp
   351   from sums_unique[OF this]
   352   show "(\<Sum>i. f (A i)) = f (\<Union>i. A i)" by simp
   353 qed
   355 lemma (in ring_of_sets) continuous_from_above_iff_empty_continuous:
   356   fixes f :: "'a set \<Rightarrow> ennreal"
   357   assumes f: "positive M f" "additive M f"
   358   shows "(\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) \<in> M \<longrightarrow> (\<forall>i. f (A i) \<noteq> \<infinity>) \<longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Inter>i. A i))
   359      \<longleftrightarrow> (\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) = {} \<longrightarrow> (\<forall>i. f (A i) \<noteq> \<infinity>) \<longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> 0)"
   360 proof safe
   361   assume cont: "(\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) \<in> M \<longrightarrow> (\<forall>i. f (A i) \<noteq> \<infinity>) \<longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Inter>i. A i))"
   362   fix A :: "nat \<Rightarrow> 'a set" assume A: "range A \<subseteq> M" "decseq A" "(\<Inter>i. A i) = {}" "\<forall>i. f (A i) \<noteq> \<infinity>"
   363   with cont[THEN spec, of A] show "(\<lambda>i. f (A i)) \<longlonglongrightarrow> 0"
   364     using \<open>positive M f\<close>[unfolded positive_def] by auto
   365 next
   366   assume cont: "\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) = {} \<longrightarrow> (\<forall>i. f (A i) \<noteq> \<infinity>) \<longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> 0"
   367   fix A :: "nat \<Rightarrow> 'a set" assume A: "range A \<subseteq> M" "decseq A" "(\<Inter>i. A i) \<in> M" "\<forall>i. f (A i) \<noteq> \<infinity>"
   369   have f_mono: "\<And>a b. a \<in> M \<Longrightarrow> b \<in> M \<Longrightarrow> a \<subseteq> b \<Longrightarrow> f a \<le> f b"
   370     using additive_increasing[OF f] unfolding increasing_def by simp
   372   have decseq_fA: "decseq (\<lambda>i. f (A i))"
   373     using A by (auto simp: decseq_def intro!: f_mono)
   374   have decseq: "decseq (\<lambda>i. A i - (\<Inter>i. A i))"
   375     using A by (auto simp: decseq_def)
   376   then have decseq_f: "decseq (\<lambda>i. f (A i - (\<Inter>i. A i)))"
   377     using A unfolding decseq_def by (auto intro!: f_mono Diff)
   378   have "f (\<Inter>x. A x) \<le> f (A 0)"
   379     using A by (auto intro!: f_mono)
   380   then have f_Int_fin: "f (\<Inter>x. A x) \<noteq> \<infinity>"
   381     using A by (auto simp: top_unique)
   382   { fix i
   383     have "f (A i - (\<Inter>i. A i)) \<le> f (A i)" using A by (auto intro!: f_mono)
   384     then have "f (A i - (\<Inter>i. A i)) \<noteq> \<infinity>"
   385       using A by (auto simp: top_unique) }
   386   note f_fin = this
   387   have "(\<lambda>i. f (A i - (\<Inter>i. A i))) \<longlonglongrightarrow> 0"
   388   proof (intro cont[rule_format, OF _ decseq _ f_fin])
   389     show "range (\<lambda>i. A i - (\<Inter>i. A i)) \<subseteq> M" "(\<Inter>i. A i - (\<Inter>i. A i)) = {}"
   390       using A by auto
   391   qed
   392   from INF_Lim_ereal[OF decseq_f this]
   393   have "(INF n. f (A n - (\<Inter>i. A i))) = 0" .
   394   moreover have "(INF n. f (\<Inter>i. A i)) = f (\<Inter>i. A i)"
   395     by auto
   396   ultimately have "(INF n. f (A n - (\<Inter>i. A i)) + f (\<Inter>i. A i)) = 0 + f (\<Inter>i. A i)"
   397     using A(4) f_fin f_Int_fin
   398     by (subst INF_ennreal_add_const) (auto simp: decseq_f)
   399   moreover {
   400     fix n
   401     have "f (A n - (\<Inter>i. A i)) + f (\<Inter>i. A i) = f ((A n - (\<Inter>i. A i)) \<union> (\<Inter>i. A i))"
   402       using A by (subst f(2)[THEN additiveD]) auto
   403     also have "(A n - (\<Inter>i. A i)) \<union> (\<Inter>i. A i) = A n"
   404       by auto
   405     finally have "f (A n - (\<Inter>i. A i)) + f (\<Inter>i. A i) = f (A n)" . }
   406   ultimately have "(INF n. f (A n)) = f (\<Inter>i. A i)"
   407     by simp
   408   with LIMSEQ_INF[OF decseq_fA]
   409   show "(\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Inter>i. A i)" by simp
   410 qed
   412 lemma (in ring_of_sets) empty_continuous_imp_continuous_from_below:
   413   fixes f :: "'a set \<Rightarrow> ennreal"
   414   assumes f: "positive M f" "additive M f" "\<forall>A\<in>M. f A \<noteq> \<infinity>"
   415   assumes cont: "\<forall>A. range A \<subseteq> M \<longrightarrow> decseq A \<longrightarrow> (\<Inter>i. A i) = {} \<longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> 0"
   416   assumes A: "range A \<subseteq> M" "incseq A" "(\<Union>i. A i) \<in> M"
   417   shows "(\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Union>i. A i)"
   418 proof -
   419   from A have "(\<lambda>i. f ((\<Union>i. A i) - A i)) \<longlonglongrightarrow> 0"
   420     by (intro cont[rule_format]) (auto simp: decseq_def incseq_def)
   421   moreover
   422   { fix i
   423     have "f ((\<Union>i. A i) - A i \<union> A i) = f ((\<Union>i. A i) - A i) + f (A i)"
   424       using A by (intro f(2)[THEN additiveD]) auto
   425     also have "((\<Union>i. A i) - A i) \<union> A i = (\<Union>i. A i)"
   426       by auto
   427     finally have "f ((\<Union>i. A i) - A i) = f (\<Union>i. A i) - f (A i)"
   428       using f(3)[rule_format, of "A i"] A by (auto simp: ennreal_add_diff_cancel subset_eq) }
   429   moreover have "\<forall>\<^sub>F i in sequentially. f (A i) \<le> f (\<Union>i. A i)"
   430     using increasingD[OF additive_increasing[OF f(1, 2)], of "A _" "\<Union>i. A i"] A
   431     by (auto intro!: always_eventually simp: subset_eq)
   432   ultimately show "(\<lambda>i. f (A i)) \<longlonglongrightarrow> f (\<Union>i. A i)"
   433     by (auto intro: ennreal_tendsto_const_minus)
   434 qed
   436 lemma (in ring_of_sets) empty_continuous_imp_countably_additive:
   437   fixes f :: "'a set \<Rightarrow> ennreal"
   438   assumes f: "positive M f" "additive M f" and fin: "\<forall>A\<in>M. f A \<noteq> \<infinity>"
   439   assumes cont: "\<And>A. range A \<subseteq> M \<Longrightarrow> decseq A \<Longrightarrow> (\<Inter>i. A i) = {} \<Longrightarrow> (\<lambda>i. f (A i)) \<longlonglongrightarrow> 0"
   440   shows "countably_additive M f"
   441   using countably_additive_iff_continuous_from_below[OF f]
   442   using empty_continuous_imp_continuous_from_below[OF f fin] cont
   443   by blast
   445 subsection \<open>Properties of @{const emeasure}\<close>
   447 lemma emeasure_positive: "positive (sets M) (emeasure M)"
   448   by (cases M) (auto simp: sets_def emeasure_def Abs_measure_inverse measure_space_def)
   450 lemma emeasure_empty[simp, intro]: "emeasure M {} = 0"
   451   using emeasure_positive[of M] by (simp add: positive_def)
   453 lemma emeasure_single_in_space: "emeasure M {x} \<noteq> 0 \<Longrightarrow> x \<in> space M"
   454   using emeasure_notin_sets[of "{x}" M] by (auto dest: sets.sets_into_space zero_less_iff_neq_zero[THEN iffD2])
   456 lemma emeasure_countably_additive: "countably_additive (sets M) (emeasure M)"
   457   by (cases M) (auto simp: sets_def emeasure_def Abs_measure_inverse measure_space_def)
   459 lemma suminf_emeasure:
   460   "range A \<subseteq> sets M \<Longrightarrow> disjoint_family A \<Longrightarrow> (\<Sum>i. emeasure M (A i)) = emeasure M (\<Union>i. A i)"
   461   using sets.countable_UN[of A UNIV M] emeasure_countably_additive[of M]
   462   by (simp add: countably_additive_def)
   464 lemma sums_emeasure:
   465   "disjoint_family F \<Longrightarrow> (\<And>i. F i \<in> sets M) \<Longrightarrow> (\<lambda>i. emeasure M (F i)) sums emeasure M (\<Union>i. F i)"
   466   unfolding sums_iff by (intro conjI suminf_emeasure) auto
   468 lemma emeasure_additive: "additive (sets M) (emeasure M)"
   469   by (metis sets.countably_additive_additive emeasure_positive emeasure_countably_additive)
   471 lemma plus_emeasure:
   472   "a \<in> sets M \<Longrightarrow> b \<in> sets M \<Longrightarrow> a \<inter> b = {} \<Longrightarrow> emeasure M a + emeasure M b = emeasure M (a \<union> b)"
   473   using additiveD[OF emeasure_additive] ..
   475 lemma emeasure_Union:
   476   "A \<in> sets M \<Longrightarrow> B \<in> sets M \<Longrightarrow> emeasure M (A \<union> B) = emeasure M A + emeasure M (B - A)"
   477   using plus_emeasure[of A M "B - A"] by auto
   479 lemma sum_emeasure:
   480   "F`I \<subseteq> sets M \<Longrightarrow> disjoint_family_on F I \<Longrightarrow> finite I \<Longrightarrow>
   481     (\<Sum>i\<in>I. emeasure M (F i)) = emeasure M (\<Union>i\<in>I. F i)"
   482   by (metis sets.additive_sum emeasure_positive emeasure_additive)
   484 lemma emeasure_mono:
   485   "a \<subseteq> b \<Longrightarrow> b \<in> sets M \<Longrightarrow> emeasure M a \<le> emeasure M b"
   486   by (metis zero_le sets.additive_increasing emeasure_additive emeasure_notin_sets emeasure_positive increasingD)
   488 lemma emeasure_space:
   489   "emeasure M A \<le> emeasure M (space M)"
   490   by (metis emeasure_mono emeasure_notin_sets sets.sets_into_space zero_le)
   492 lemma emeasure_Diff:
   493   assumes finite: "emeasure M B \<noteq> \<infinity>"
   494   and [measurable]: "A \<in> sets M" "B \<in> sets M" and "B \<subseteq> A"
   495   shows "emeasure M (A - B) = emeasure M A - emeasure M B"
   496 proof -
   497   have "(A - B) \<union> B = A" using \<open>B \<subseteq> A\<close> by auto
   498   then have "emeasure M A = emeasure M ((A - B) \<union> B)" by simp
   499   also have "\<dots> = emeasure M (A - B) + emeasure M B"
   500     by (subst plus_emeasure[symmetric]) auto
   501   finally show "emeasure M (A - B) = emeasure M A - emeasure M B"
   502     using finite by simp
   503 qed
   505 lemma emeasure_compl:
   506   "s \<in> sets M \<Longrightarrow> emeasure M s \<noteq> \<infinity> \<Longrightarrow> emeasure M (space M - s) = emeasure M (space M) - emeasure M s"
   507   by (rule emeasure_Diff) (auto dest: sets.sets_into_space)
   509 lemma Lim_emeasure_incseq:
   510   "range A \<subseteq> sets M \<Longrightarrow> incseq A \<Longrightarrow> (\<lambda>i. (emeasure M (A i))) \<longlonglongrightarrow> emeasure M (\<Union>i. A i)"
   511   using emeasure_countably_additive
   512   by (auto simp add: sets.countably_additive_iff_continuous_from_below emeasure_positive
   513     emeasure_additive)
   515 lemma incseq_emeasure:
   516   assumes "range B \<subseteq> sets M" "incseq B"
   517   shows "incseq (\<lambda>i. emeasure M (B i))"
   518   using assms by (auto simp: incseq_def intro!: emeasure_mono)
   520 lemma SUP_emeasure_incseq:
   521   assumes A: "range A \<subseteq> sets M" "incseq A"
   522   shows "(SUP n. emeasure M (A n)) = emeasure M (\<Union>i. A i)"
   523   using LIMSEQ_SUP[OF incseq_emeasure, OF A] Lim_emeasure_incseq[OF A]
   524   by (simp add: LIMSEQ_unique)
   526 lemma decseq_emeasure:
   527   assumes "range B \<subseteq> sets M" "decseq B"
   528   shows "decseq (\<lambda>i. emeasure M (B i))"
   529   using assms by (auto simp: decseq_def intro!: emeasure_mono)
   531 lemma INF_emeasure_decseq:
   532   assumes A: "range A \<subseteq> sets M" and "decseq A"
   533   and finite: "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
   534   shows "(INF n. emeasure M (A n)) = emeasure M (\<Inter>i. A i)"
   535 proof -
   536   have le_MI: "emeasure M (\<Inter>i. A i) \<le> emeasure M (A 0)"
   537     using A by (auto intro!: emeasure_mono)
   538   hence *: "emeasure M (\<Inter>i. A i) \<noteq> \<infinity>" using finite[of 0] by (auto simp: top_unique)
   540   have "emeasure M (A 0) - (INF n. emeasure M (A n)) = (SUP n. emeasure M (A 0) - emeasure M (A n))"
   541     by (simp add: ennreal_INF_const_minus)
   542   also have "\<dots> = (SUP n. emeasure M (A 0 - A n))"
   543     using A finite \<open>decseq A\<close>[unfolded decseq_def] by (subst emeasure_Diff) auto
   544   also have "\<dots> = emeasure M (\<Union>i. A 0 - A i)"
   545   proof (rule SUP_emeasure_incseq)
   546     show "range (\<lambda>n. A 0 - A n) \<subseteq> sets M"
   547       using A by auto
   548     show "incseq (\<lambda>n. A 0 - A n)"
   549       using \<open>decseq A\<close> by (auto simp add: incseq_def decseq_def)
   550   qed
   551   also have "\<dots> = emeasure M (A 0) - emeasure M (\<Inter>i. A i)"
   552     using A finite * by (simp, subst emeasure_Diff) auto
   553   finally show ?thesis
   554     by (rule ennreal_minus_cancel[rotated 3])
   555        (insert finite A, auto intro: INF_lower emeasure_mono)
   556 qed
   558 lemma INF_emeasure_decseq':
   559   assumes A: "\<And>i. A i \<in> sets M" and "decseq A"
   560   and finite: "\<exists>i. emeasure M (A i) \<noteq> \<infinity>"
   561   shows "(INF n. emeasure M (A n)) = emeasure M (\<Inter>i. A i)"
   562 proof -
   563   from finite obtain i where i: "emeasure M (A i) < \<infinity>"
   564     by (auto simp: less_top)
   565   have fin: "i \<le> j \<Longrightarrow> emeasure M (A j) < \<infinity>" for j
   566     by (rule le_less_trans[OF emeasure_mono i]) (auto intro!: decseqD[OF \<open>decseq A\<close>] A)
   568   have "(INF n. emeasure M (A n)) = (INF n. emeasure M (A (n + i)))"
   569   proof (rule INF_eq)
   570     show "\<exists>j\<in>UNIV. emeasure M (A (j + i)) \<le> emeasure M (A i')" for i'
   571       by (intro bexI[of _ i'] emeasure_mono decseqD[OF \<open>decseq A\<close>] A) auto
   572   qed auto
   573   also have "\<dots> = emeasure M (INF n. (A (n + i)))"
   574     using A \<open>decseq A\<close> fin by (intro INF_emeasure_decseq) (auto simp: decseq_def less_top)
   575   also have "(INF n. (A (n + i))) = (INF n. A n)"
   576     by (meson INF_eq UNIV_I assms(2) decseqD le_add1)
   577   finally show ?thesis .
   578 qed
   580 lemma emeasure_INT_decseq_subset:
   581   fixes F :: "nat \<Rightarrow> 'a set"
   582   assumes I: "I \<noteq> {}" and F: "\<And>i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> i \<le> j \<Longrightarrow> F j \<subseteq> F i"
   583   assumes F_sets[measurable]: "\<And>i. i \<in> I \<Longrightarrow> F i \<in> sets M"
   584     and fin: "\<And>i. i \<in> I \<Longrightarrow> emeasure M (F i) \<noteq> \<infinity>"
   585   shows "emeasure M (\<Inter>i\<in>I. F i) = (INF i:I. emeasure M (F i))"
   586 proof cases
   587   assume "finite I"
   588   have "(\<Inter>i\<in>I. F i) = F (Max I)"
   589     using I \<open>finite I\<close> by (intro antisym INF_lower INF_greatest F) auto
   590   moreover have "(INF i:I. emeasure M (F i)) = emeasure M (F (Max I))"
   591     using I \<open>finite I\<close> by (intro antisym INF_lower INF_greatest F emeasure_mono) auto
   592   ultimately show ?thesis
   593     by simp
   594 next
   595   assume "infinite I"
   596   define L where "L n = (LEAST i. i \<in> I \<and> i \<ge> n)" for n
   597   have L: "L n \<in> I \<and> n \<le> L n" for n
   598     unfolding L_def
   599   proof (rule LeastI_ex)
   600     show "\<exists>x. x \<in> I \<and> n \<le> x"
   601       using \<open>infinite I\<close> finite_subset[of I "{..< n}"]
   602       by (rule_tac ccontr) (auto simp: not_le)
   603   qed
   604   have L_eq[simp]: "i \<in> I \<Longrightarrow> L i = i" for i
   605     unfolding L_def by (intro Least_equality) auto
   606   have L_mono: "i \<le> j \<Longrightarrow> L i \<le> L j" for i j
   607     using L[of j] unfolding L_def by (intro Least_le) (auto simp: L_def)
   609   have "emeasure M (\<Inter>i. F (L i)) = (INF i. emeasure M (F (L i)))"
   610   proof (intro INF_emeasure_decseq[symmetric])
   611     show "decseq (\<lambda>i. F (L i))"
   612       using L by (intro antimonoI F L_mono) auto
   613   qed (insert L fin, auto)
   614   also have "\<dots> = (INF i:I. emeasure M (F i))"
   615   proof (intro antisym INF_greatest)
   616     show "i \<in> I \<Longrightarrow> (INF i. emeasure M (F (L i))) \<le> emeasure M (F i)" for i
   617       by (intro INF_lower2[of i]) auto
   618   qed (insert L, auto intro: INF_lower)
   619   also have "(\<Inter>i. F (L i)) = (\<Inter>i\<in>I. F i)"
   620   proof (intro antisym INF_greatest)
   621     show "i \<in> I \<Longrightarrow> (\<Inter>i. F (L i)) \<subseteq> F i" for i
   622       by (intro INF_lower2[of i]) auto
   623   qed (insert L, auto)
   624   finally show ?thesis .
   625 qed
   627 lemma Lim_emeasure_decseq:
   628   assumes A: "range A \<subseteq> sets M" "decseq A" and fin: "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
   629   shows "(\<lambda>i. emeasure M (A i)) \<longlonglongrightarrow> emeasure M (\<Inter>i. A i)"
   630   using LIMSEQ_INF[OF decseq_emeasure, OF A]
   631   using INF_emeasure_decseq[OF A fin] by simp
   633 lemma emeasure_lfp'[consumes 1, case_names cont measurable]:
   634   assumes "P M"
   635   assumes cont: "sup_continuous F"
   636   assumes *: "\<And>M A. P M \<Longrightarrow> (\<And>N. P N \<Longrightarrow> Measurable.pred N A) \<Longrightarrow> Measurable.pred M (F A)"
   637   shows "emeasure M {x\<in>space M. lfp F x} = (SUP i. emeasure M {x\<in>space M. (F ^^ i) (\<lambda>x. False) x})"
   638 proof -
   639   have "emeasure M {x\<in>space M. lfp F x} = emeasure M (\<Union>i. {x\<in>space M. (F ^^ i) (\<lambda>x. False) x})"
   640     using sup_continuous_lfp[OF cont] by (auto simp add: bot_fun_def intro!: arg_cong2[where f=emeasure])
   641   moreover { fix i from \<open>P M\<close> have "{x\<in>space M. (F ^^ i) (\<lambda>x. False) x} \<in> sets M"
   642     by (induct i arbitrary: M) (auto simp add: pred_def[symmetric] intro: *) }
   643   moreover have "incseq (\<lambda>i. {x\<in>space M. (F ^^ i) (\<lambda>x. False) x})"
   644   proof (rule incseq_SucI)
   645     fix i
   646     have "(F ^^ i) (\<lambda>x. False) \<le> (F ^^ (Suc i)) (\<lambda>x. False)"
   647     proof (induct i)
   648       case 0 show ?case by (simp add: le_fun_def)
   649     next
   650       case Suc thus ?case using monoD[OF sup_continuous_mono[OF cont] Suc] by auto
   651     qed
   652     then show "{x \<in> space M. (F ^^ i) (\<lambda>x. False) x} \<subseteq> {x \<in> space M. (F ^^ Suc i) (\<lambda>x. False) x}"
   653       by auto
   654   qed
   655   ultimately show ?thesis
   656     by (subst SUP_emeasure_incseq) auto
   657 qed
   659 lemma emeasure_lfp:
   660   assumes [simp]: "\<And>s. sets (M s) = sets N"
   661   assumes cont: "sup_continuous F" "sup_continuous f"
   662   assumes meas: "\<And>P. Measurable.pred N P \<Longrightarrow> Measurable.pred N (F P)"
   663   assumes iter: "\<And>P s. Measurable.pred N P \<Longrightarrow> P \<le> lfp F \<Longrightarrow> emeasure (M s) {x\<in>space N. F P x} = f (\<lambda>s. emeasure (M s) {x\<in>space N. P x}) s"
   664   shows "emeasure (M s) {x\<in>space N. lfp F x} = lfp f s"
   665 proof (subst lfp_transfer_bounded[where \<alpha>="\<lambda>F s. emeasure (M s) {x\<in>space N. F x}" and g=f and f=F and P="Measurable.pred N", symmetric])
   666   fix C assume "incseq C" "\<And>i. Measurable.pred N (C i)"
   667   then show "(\<lambda>s. emeasure (M s) {x \<in> space N. (SUP i. C i) x}) = (SUP i. (\<lambda>s. emeasure (M s) {x \<in> space N. C i x}))"
   668     unfolding SUP_apply[abs_def]
   669     by (subst SUP_emeasure_incseq) (auto simp: mono_def fun_eq_iff intro!: arg_cong2[where f=emeasure])
   670 qed (auto simp add: iter le_fun_def SUP_apply[abs_def] intro!: meas cont)
   672 lemma emeasure_subadditive_finite:
   673   "finite I \<Longrightarrow> A ` I \<subseteq> sets M \<Longrightarrow> emeasure M (\<Union>i\<in>I. A i) \<le> (\<Sum>i\<in>I. emeasure M (A i))"
   674   by (rule sets.subadditive[OF emeasure_positive emeasure_additive]) auto
   676 lemma emeasure_subadditive:
   677   "A \<in> sets M \<Longrightarrow> B \<in> sets M \<Longrightarrow> emeasure M (A \<union> B) \<le> emeasure M A + emeasure M B"
   678   using emeasure_subadditive_finite[of "{True, False}" "\<lambda>True \<Rightarrow> A | False \<Rightarrow> B" M] by simp
   680 lemma emeasure_subadditive_countably:
   681   assumes "range f \<subseteq> sets M"
   682   shows "emeasure M (\<Union>i. f i) \<le> (\<Sum>i. emeasure M (f i))"
   683 proof -
   684   have "emeasure M (\<Union>i. f i) = emeasure M (\<Union>i. disjointed f i)"
   685     unfolding UN_disjointed_eq ..
   686   also have "\<dots> = (\<Sum>i. emeasure M (disjointed f i))"
   687     using sets.range_disjointed_sets[OF assms] suminf_emeasure[of "disjointed f"]
   688     by (simp add:  disjoint_family_disjointed comp_def)
   689   also have "\<dots> \<le> (\<Sum>i. emeasure M (f i))"
   690     using sets.range_disjointed_sets[OF assms] assms
   691     by (auto intro!: suminf_le emeasure_mono disjointed_subset)
   692   finally show ?thesis .
   693 qed
   695 lemma emeasure_insert:
   696   assumes sets: "{x} \<in> sets M" "A \<in> sets M" and "x \<notin> A"
   697   shows "emeasure M (insert x A) = emeasure M {x} + emeasure M A"
   698 proof -
   699   have "{x} \<inter> A = {}" using \<open>x \<notin> A\<close> by auto
   700   from plus_emeasure[OF sets this] show ?thesis by simp
   701 qed
   703 lemma emeasure_insert_ne:
   704   "A \<noteq> {} \<Longrightarrow> {x} \<in> sets M \<Longrightarrow> A \<in> sets M \<Longrightarrow> x \<notin> A \<Longrightarrow> emeasure M (insert x A) = emeasure M {x} + emeasure M A"
   705   by (rule emeasure_insert)
   707 lemma emeasure_eq_sum_singleton:
   708   assumes "finite S" "\<And>x. x \<in> S \<Longrightarrow> {x} \<in> sets M"
   709   shows "emeasure M S = (\<Sum>x\<in>S. emeasure M {x})"
   710   using sum_emeasure[of "\<lambda>x. {x}" S M] assms
   711   by (auto simp: disjoint_family_on_def subset_eq)
   713 lemma sum_emeasure_cover:
   714   assumes "finite S" and "A \<in> sets M" and br_in_M: "B ` S \<subseteq> sets M"
   715   assumes A: "A \<subseteq> (\<Union>i\<in>S. B i)"
   716   assumes disj: "disjoint_family_on B S"
   717   shows "emeasure M A = (\<Sum>i\<in>S. emeasure M (A \<inter> (B i)))"
   718 proof -
   719   have "(\<Sum>i\<in>S. emeasure M (A \<inter> (B i))) = emeasure M (\<Union>i\<in>S. A \<inter> (B i))"
   720   proof (rule sum_emeasure)
   721     show "disjoint_family_on (\<lambda>i. A \<inter> B i) S"
   722       using \<open>disjoint_family_on B S\<close>
   723       unfolding disjoint_family_on_def by auto
   724   qed (insert assms, auto)
   725   also have "(\<Union>i\<in>S. A \<inter> (B i)) = A"
   726     using A by auto
   727   finally show ?thesis by simp
   728 qed
   730 lemma emeasure_eq_0:
   731   "N \<in> sets M \<Longrightarrow> emeasure M N = 0 \<Longrightarrow> K \<subseteq> N \<Longrightarrow> emeasure M K = 0"
   732   by (metis emeasure_mono order_eq_iff zero_le)
   734 lemma emeasure_UN_eq_0:
   735   assumes "\<And>i::nat. emeasure M (N i) = 0" and "range N \<subseteq> sets M"
   736   shows "emeasure M (\<Union>i. N i) = 0"
   737 proof -
   738   have "emeasure M (\<Union>i. N i) \<le> 0"
   739     using emeasure_subadditive_countably[OF assms(2)] assms(1) by simp
   740   then show ?thesis
   741     by (auto intro: antisym zero_le)
   742 qed
   744 lemma measure_eqI_finite:
   745   assumes [simp]: "sets M = Pow A" "sets N = Pow A" and "finite A"
   746   assumes eq: "\<And>a. a \<in> A \<Longrightarrow> emeasure M {a} = emeasure N {a}"
   747   shows "M = N"
   748 proof (rule measure_eqI)
   749   fix X assume "X \<in> sets M"
   750   then have X: "X \<subseteq> A" by auto
   751   then have "emeasure M X = (\<Sum>a\<in>X. emeasure M {a})"
   752     using \<open>finite A\<close> by (subst emeasure_eq_sum_singleton) (auto dest: finite_subset)
   753   also have "\<dots> = (\<Sum>a\<in>X. emeasure N {a})"
   754     using X eq by (auto intro!: sum.cong)
   755   also have "\<dots> = emeasure N X"
   756     using X \<open>finite A\<close> by (subst emeasure_eq_sum_singleton) (auto dest: finite_subset)
   757   finally show "emeasure M X = emeasure N X" .
   758 qed simp
   760 lemma measure_eqI_generator_eq:
   761   fixes M N :: "'a measure" and E :: "'a set set" and A :: "nat \<Rightarrow> 'a set"
   762   assumes "Int_stable E" "E \<subseteq> Pow \<Omega>"
   763   and eq: "\<And>X. X \<in> E \<Longrightarrow> emeasure M X = emeasure N X"
   764   and M: "sets M = sigma_sets \<Omega> E"
   765   and N: "sets N = sigma_sets \<Omega> E"
   766   and A: "range A \<subseteq> E" "(\<Union>i. A i) = \<Omega>" "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
   767   shows "M = N"
   768 proof -
   769   let ?\<mu>  = "emeasure M" and ?\<nu> = "emeasure N"
   770   interpret S: sigma_algebra \<Omega> "sigma_sets \<Omega> E" by (rule sigma_algebra_sigma_sets) fact
   771   have "space M = \<Omega>"
   772     using[of M] sets.space_closed[of M] S.space_closed \<open>sets M = sigma_sets \<Omega> E\<close>
   773     by blast
   775   { fix F D assume "F \<in> E" and "?\<mu> F \<noteq> \<infinity>"
   776     then have [intro]: "F \<in> sigma_sets \<Omega> E" by auto
   777     have "?\<nu> F \<noteq> \<infinity>" using \<open>?\<mu> F \<noteq> \<infinity>\<close> \<open>F \<in> E\<close> eq by simp
   778     assume "D \<in> sets M"
   779     with \<open>Int_stable E\<close> \<open>E \<subseteq> Pow \<Omega>\<close> have "emeasure M (F \<inter> D) = emeasure N (F \<inter> D)"
   780       unfolding M
   781     proof (induct rule: sigma_sets_induct_disjoint)
   782       case (basic A)
   783       then have "F \<inter> A \<in> E" using \<open>Int_stable E\<close> \<open>F \<in> E\<close> by (auto simp: Int_stable_def)
   784       then show ?case using eq by auto
   785     next
   786       case empty then show ?case by simp
   787     next
   788       case (compl A)
   789       then have **: "F \<inter> (\<Omega> - A) = F - (F \<inter> A)"
   790         and [intro]: "F \<inter> A \<in> sigma_sets \<Omega> E"
   791         using \<open>F \<in> E\<close> S.sets_into_space by (auto simp: M)
   792       have "?\<nu> (F \<inter> A) \<le> ?\<nu> F" by (auto intro!: emeasure_mono simp: M N)
   793       then have "?\<nu> (F \<inter> A) \<noteq> \<infinity>" using \<open>?\<nu> F \<noteq> \<infinity>\<close> by (auto simp: top_unique)
   794       have "?\<mu> (F \<inter> A) \<le> ?\<mu> F" by (auto intro!: emeasure_mono simp: M N)
   795       then have "?\<mu> (F \<inter> A) \<noteq> \<infinity>" using \<open>?\<mu> F \<noteq> \<infinity>\<close> by (auto simp: top_unique)
   796       then have "?\<mu> (F \<inter> (\<Omega> - A)) = ?\<mu> F - ?\<mu> (F \<inter> A)" unfolding **
   797         using \<open>F \<inter> A \<in> sigma_sets \<Omega> E\<close> by (auto intro!: emeasure_Diff simp: M N)
   798       also have "\<dots> = ?\<nu> F - ?\<nu> (F \<inter> A)" using eq \<open>F \<in> E\<close> compl by simp
   799       also have "\<dots> = ?\<nu> (F \<inter> (\<Omega> - A))" unfolding **
   800         using \<open>F \<inter> A \<in> sigma_sets \<Omega> E\<close> \<open>?\<nu> (F \<inter> A) \<noteq> \<infinity>\<close>
   801         by (auto intro!: emeasure_Diff[symmetric] simp: M N)
   802       finally show ?case
   803         using \<open>space M = \<Omega>\<close> by auto
   804     next
   805       case (union A)
   806       then have "?\<mu> (\<Union>x. F \<inter> A x) = ?\<nu> (\<Union>x. F \<inter> A x)"
   807         by (subst (1 2) suminf_emeasure[symmetric]) (auto simp: disjoint_family_on_def subset_eq M N)
   808       with A show ?case
   809         by auto
   810     qed }
   811   note * = this
   812   show "M = N"
   813   proof (rule measure_eqI)
   814     show "sets M = sets N"
   815       using M N by simp
   816     have [simp, intro]: "\<And>i. A i \<in> sets M"
   817       using A(1) by (auto simp: subset_eq M)
   818     fix F assume "F \<in> sets M"
   819     let ?D = "disjointed (\<lambda>i. F \<inter> A i)"
   820     from \<open>space M = \<Omega>\<close> have F_eq: "F = (\<Union>i. ?D i)"
   821       using \<open>F \<in> sets M\<close>[THEN sets.sets_into_space] A(2)[symmetric] by (auto simp: UN_disjointed_eq)
   822     have [simp, intro]: "\<And>i. ?D i \<in> sets M"
   823       using sets.range_disjointed_sets[of "\<lambda>i. F \<inter> A i" M] \<open>F \<in> sets M\<close>
   824       by (auto simp: subset_eq)
   825     have "disjoint_family ?D"
   826       by (auto simp: disjoint_family_disjointed)
   827     moreover
   828     have "(\<Sum>i. emeasure M (?D i)) = (\<Sum>i. emeasure N (?D i))"
   829     proof (intro arg_cong[where f=suminf] ext)
   830       fix i
   831       have "A i \<inter> ?D i = ?D i"
   832         by (auto simp: disjointed_def)
   833       then show "emeasure M (?D i) = emeasure N (?D i)"
   834         using *[of "A i" "?D i", OF _ A(3)] A(1) by auto
   835     qed
   836     ultimately show "emeasure M F = emeasure N F"
   837       by (simp add: image_subset_iff \<open>sets M = sets N\<close>[symmetric] F_eq[symmetric] suminf_emeasure)
   838   qed
   839 qed
   841 lemma space_empty: "space M = {} \<Longrightarrow> M = count_space {}"
   842   by (rule measure_eqI) (simp_all add: space_empty_iff)
   844 lemma measure_eqI_generator_eq_countable:
   845   fixes M N :: "'a measure" and E :: "'a set set" and A :: "'a set set"
   846   assumes E: "Int_stable E" "E \<subseteq> Pow \<Omega>" "\<And>X. X \<in> E \<Longrightarrow> emeasure M X = emeasure N X"
   847     and sets: "sets M = sigma_sets \<Omega> E" "sets N = sigma_sets \<Omega> E"
   848   and A: "A \<subseteq> E" "(\<Union>A) = \<Omega>" "countable A" "\<And>a. a \<in> A \<Longrightarrow> emeasure M a \<noteq> \<infinity>"
   849   shows "M = N"
   850 proof cases
   851   assume "\<Omega> = {}"
   852   have *: "sigma_sets \<Omega> E = sets (sigma \<Omega> E)"
   853     using E(2) by simp
   854   have "space M = \<Omega>" "space N = \<Omega>"
   855     using sets E(2) unfolding * by (auto dest: sets_eq_imp_space_eq simp del: sets_measure_of)
   856   then show "M = N"
   857     unfolding \<open>\<Omega> = {}\<close> by (auto dest: space_empty)
   858 next
   859   assume "\<Omega> \<noteq> {}" with \<open>\<Union>A = \<Omega>\<close> have "A \<noteq> {}" by auto
   860   from this \<open>countable A\<close> have rng: "range (from_nat_into A) = A"
   861     by (rule range_from_nat_into)
   862   show "M = N"
   863   proof (rule measure_eqI_generator_eq[OF E sets])
   864     show "range (from_nat_into A) \<subseteq> E"
   865       unfolding rng using \<open>A \<subseteq> E\<close> .
   866     show "(\<Union>i. from_nat_into A i) = \<Omega>"
   867       unfolding rng using \<open>\<Union>A = \<Omega>\<close> .
   868     show "emeasure M (from_nat_into A i) \<noteq> \<infinity>" for i
   869       using rng by (intro A) auto
   870   qed
   871 qed
   873 lemma measure_of_of_measure: "measure_of (space M) (sets M) (emeasure M) = M"
   874 proof (intro measure_eqI emeasure_measure_of_sigma)
   875   show "sigma_algebra (space M) (sets M)" ..
   876   show "positive (sets M) (emeasure M)"
   877     by (simp add: positive_def)
   878   show "countably_additive (sets M) (emeasure M)"
   879     by (simp add: emeasure_countably_additive)
   880 qed simp_all
   882 subsection \<open>\<open>\<mu>\<close>-null sets\<close>
   884 definition null_sets :: "'a measure \<Rightarrow> 'a set set" where
   885   "null_sets M = {N\<in>sets M. emeasure M N = 0}"
   887 lemma null_setsD1[dest]: "A \<in> null_sets M \<Longrightarrow> emeasure M A = 0"
   888   by (simp add: null_sets_def)
   890 lemma null_setsD2[dest]: "A \<in> null_sets M \<Longrightarrow> A \<in> sets M"
   891   unfolding null_sets_def by simp
   893 lemma null_setsI[intro]: "emeasure M A = 0 \<Longrightarrow> A \<in> sets M \<Longrightarrow> A \<in> null_sets M"
   894   unfolding null_sets_def by simp
   896 interpretation null_sets: ring_of_sets "space M" "null_sets M" for M
   897 proof (rule ring_of_setsI)
   898   show "null_sets M \<subseteq> Pow (space M)"
   899     using sets.sets_into_space by auto
   900   show "{} \<in> null_sets M"
   901     by auto
   902   fix A B assume null_sets: "A \<in> null_sets M" "B \<in> null_sets M"
   903   then have sets: "A \<in> sets M" "B \<in> sets M"
   904     by auto
   905   then have *: "emeasure M (A \<union> B) \<le> emeasure M A + emeasure M B"
   906     "emeasure M (A - B) \<le> emeasure M A"
   907     by (auto intro!: emeasure_subadditive emeasure_mono)
   908   then have "emeasure M B = 0" "emeasure M A = 0"
   909     using null_sets by auto
   910   with sets * show "A - B \<in> null_sets M" "A \<union> B \<in> null_sets M"
   911     by (auto intro!: antisym zero_le)
   912 qed
   914 lemma UN_from_nat_into:
   915   assumes I: "countable I" "I \<noteq> {}"
   916   shows "(\<Union>i\<in>I. N i) = (\<Union>i. N (from_nat_into I i))"
   917 proof -
   918   have "(\<Union>i\<in>I. N i) = \<Union>(N ` range (from_nat_into I))"
   919     using I by simp
   920   also have "\<dots> = (\<Union>i. (N \<circ> from_nat_into I) i)"
   921     by simp
   922   finally show ?thesis by simp
   923 qed
   925 lemma null_sets_UN':
   926   assumes "countable I"
   927   assumes "\<And>i. i \<in> I \<Longrightarrow> N i \<in> null_sets M"
   928   shows "(\<Union>i\<in>I. N i) \<in> null_sets M"
   929 proof cases
   930   assume "I = {}" then show ?thesis by simp
   931 next
   932   assume "I \<noteq> {}"
   933   show ?thesis
   934   proof (intro conjI CollectI null_setsI)
   935     show "(\<Union>i\<in>I. N i) \<in> sets M"
   936       using assms by (intro sets.countable_UN') auto
   937     have "emeasure M (\<Union>i\<in>I. N i) \<le> (\<Sum>n. emeasure M (N (from_nat_into I n)))"
   938       unfolding UN_from_nat_into[OF \<open>countable I\<close> \<open>I \<noteq> {}\<close>]
   939       using assms \<open>I \<noteq> {}\<close> by (intro emeasure_subadditive_countably) (auto intro: from_nat_into)
   940     also have "(\<lambda>n. emeasure M (N (from_nat_into I n))) = (\<lambda>_. 0)"
   941       using assms \<open>I \<noteq> {}\<close> by (auto intro: from_nat_into)
   942     finally show "emeasure M (\<Union>i\<in>I. N i) = 0"
   943       by (intro antisym zero_le) simp
   944   qed
   945 qed
   947 lemma null_sets_UN[intro]:
   948   "(\<And>i::'i::countable. N i \<in> null_sets M) \<Longrightarrow> (\<Union>i. N i) \<in> null_sets M"
   949   by (rule null_sets_UN') auto
   951 lemma null_set_Int1:
   952   assumes "B \<in> null_sets M" "A \<in> sets M" shows "A \<inter> B \<in> null_sets M"
   953 proof (intro CollectI conjI null_setsI)
   954   show "emeasure M (A \<inter> B) = 0" using assms
   955     by (intro emeasure_eq_0[of B _ "A \<inter> B"]) auto
   956 qed (insert assms, auto)
   958 lemma null_set_Int2:
   959   assumes "B \<in> null_sets M" "A \<in> sets M" shows "B \<inter> A \<in> null_sets M"
   960   using assms by (subst Int_commute) (rule null_set_Int1)
   962 lemma emeasure_Diff_null_set:
   963   assumes "B \<in> null_sets M" "A \<in> sets M"
   964   shows "emeasure M (A - B) = emeasure M A"
   965 proof -
   966   have *: "A - B = (A - (A \<inter> B))" by auto
   967   have "A \<inter> B \<in> null_sets M" using assms by (rule null_set_Int1)
   968   then show ?thesis
   969     unfolding * using assms
   970     by (subst emeasure_Diff) auto
   971 qed
   973 lemma null_set_Diff:
   974   assumes "B \<in> null_sets M" "A \<in> sets M" shows "B - A \<in> null_sets M"
   975 proof (intro CollectI conjI null_setsI)
   976   show "emeasure M (B - A) = 0" using assms by (intro emeasure_eq_0[of B _ "B - A"]) auto
   977 qed (insert assms, auto)
   979 lemma emeasure_Un_null_set:
   980   assumes "A \<in> sets M" "B \<in> null_sets M"
   981   shows "emeasure M (A \<union> B) = emeasure M A"
   982 proof -
   983   have *: "A \<union> B = A \<union> (B - A)" by auto
   984   have "B - A \<in> null_sets M" using assms(2,1) by (rule null_set_Diff)
   985   then show ?thesis
   986     unfolding * using assms
   987     by (subst plus_emeasure[symmetric]) auto
   988 qed
   990 subsection \<open>The almost everywhere filter (i.e.\ quantifier)\<close>
   992 definition ae_filter :: "'a measure \<Rightarrow> 'a filter" where
   993   "ae_filter M = (INF N:null_sets M. principal (space M - N))"
   995 abbreviation almost_everywhere :: "'a measure \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> bool" where
   996   "almost_everywhere M P \<equiv> eventually P (ae_filter M)"
   998 syntax
   999   "_almost_everywhere" :: "pttrn \<Rightarrow> 'a \<Rightarrow> bool \<Rightarrow> bool" ("AE _ in _. _" [0,0,10] 10)
  1001 translations
  1002   "AE x in M. P" \<rightleftharpoons> "CONST almost_everywhere M (\<lambda>x. P)"
  1004 abbreviation
  1005   "set_almost_everywhere A M P \<equiv> AE x in M. x \<in> A \<longrightarrow> P x"
  1007 syntax
  1008   "_set_almost_everywhere" :: "pttrn \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> bool \<Rightarrow> bool"
  1009   ("AE _\<in>_ in _./ _" [0,0,0,10] 10)
  1011 translations
  1012   "AE x\<in>A in M. P" \<rightleftharpoons> "CONST set_almost_everywhere A M (\<lambda>x. P)"
  1014 lemma eventually_ae_filter: "eventually P (ae_filter M) \<longleftrightarrow> (\<exists>N\<in>null_sets M. {x \<in> space M. \<not> P x} \<subseteq> N)"
  1015   unfolding ae_filter_def by (subst eventually_INF_base) (auto simp: eventually_principal subset_eq)
  1017 lemma AE_I':
  1018   "N \<in> null_sets M \<Longrightarrow> {x\<in>space M. \<not> P x} \<subseteq> N \<Longrightarrow> (AE x in M. P x)"
  1019   unfolding eventually_ae_filter by auto
  1021 lemma AE_iff_null:
  1022   assumes "{x\<in>space M. \<not> P x} \<in> sets M" (is "?P \<in> sets M")
  1023   shows "(AE x in M. P x) \<longleftrightarrow> {x\<in>space M. \<not> P x} \<in> null_sets M"
  1024 proof
  1025   assume "AE x in M. P x" then obtain N where N: "N \<in> sets M" "?P \<subseteq> N" "emeasure M N = 0"
  1026     unfolding eventually_ae_filter by auto
  1027   have "emeasure M ?P \<le> emeasure M N"
  1028     using assms N(1,2) by (auto intro: emeasure_mono)
  1029   then have "emeasure M ?P = 0"
  1030     unfolding \<open>emeasure M N = 0\<close> by auto
  1031   then show "?P \<in> null_sets M" using assms by auto
  1032 next
  1033   assume "?P \<in> null_sets M" with assms show "AE x in M. P x" by (auto intro: AE_I')
  1034 qed
  1036 lemma AE_iff_null_sets:
  1037   "N \<in> sets M \<Longrightarrow> N \<in> null_sets M \<longleftrightarrow> (AE x in M. x \<notin> N)"
  1038   using Int_absorb1[OF sets.sets_into_space, of N M]
  1039   by (subst AE_iff_null) (auto simp: Int_def[symmetric])
  1041 lemma AE_not_in:
  1042   "N \<in> null_sets M \<Longrightarrow> AE x in M. x \<notin> N"
  1043   by (metis AE_iff_null_sets null_setsD2)
  1045 lemma AE_iff_measurable:
  1046   "N \<in> sets M \<Longrightarrow> {x\<in>space M. \<not> P x} = N \<Longrightarrow> (AE x in M. P x) \<longleftrightarrow> emeasure M N = 0"
  1047   using AE_iff_null[of _ P] by auto
  1049 lemma AE_E[consumes 1]:
  1050   assumes "AE x in M. P x"
  1051   obtains N where "{x \<in> space M. \<not> P x} \<subseteq> N" "emeasure M N = 0" "N \<in> sets M"
  1052   using assms unfolding eventually_ae_filter by auto
  1054 lemma AE_E2:
  1055   assumes "AE x in M. P x" "{x\<in>space M. P x} \<in> sets M"
  1056   shows "emeasure M {x\<in>space M. \<not> P x} = 0" (is "emeasure M ?P = 0")
  1057 proof -
  1058   have "{x\<in>space M. \<not> P x} = space M - {x\<in>space M. P x}" by auto
  1059   with AE_iff_null[of M P] assms show ?thesis by auto
  1060 qed
  1062 lemma AE_E3:
  1063   assumes "AE x in M. P x"
  1064   obtains N where "\<And>x. x \<in> space M - N \<Longrightarrow> P x" "N \<in> null_sets M"
  1065 using assms unfolding eventually_ae_filter by auto
  1067 lemma AE_I:
  1068   assumes "{x \<in> space M. \<not> P x} \<subseteq> N" "emeasure M N = 0" "N \<in> sets M"
  1069   shows "AE x in M. P x"
  1070   using assms unfolding eventually_ae_filter by auto
  1072 lemma AE_mp[elim!]:
  1073   assumes AE_P: "AE x in M. P x" and AE_imp: "AE x in M. P x \<longrightarrow> Q x"
  1074   shows "AE x in M. Q x"
  1075 proof -
  1076   from AE_P obtain A where P: "{x\<in>space M. \<not> P x} \<subseteq> A"
  1077     and A: "A \<in> sets M" "emeasure M A = 0"
  1078     by (auto elim!: AE_E)
  1080   from AE_imp obtain B where imp: "{x\<in>space M. P x \<and> \<not> Q x} \<subseteq> B"
  1081     and B: "B \<in> sets M" "emeasure M B = 0"
  1082     by (auto elim!: AE_E)
  1084   show ?thesis
  1085   proof (intro AE_I)
  1086     have "emeasure M (A \<union> B) \<le> 0"
  1087       using emeasure_subadditive[of A M B] A B by auto
  1088     then show "A \<union> B \<in> sets M" "emeasure M (A \<union> B) = 0"
  1089       using A B by auto
  1090     show "{x\<in>space M. \<not> Q x} \<subseteq> A \<union> B"
  1091       using P imp by auto
  1092   qed
  1093 qed
  1095 text {*The next lemma is convenient to combine with a lemma whose conclusion is of the
  1096 form \<open>AE x in M. P x = Q x\<close>: for such a lemma, there is no \verb+[symmetric]+ variant,
  1097 but using \<open>AE_symmetric[OF...]\<close> will replace it.*}
  1099 (* depricated replace by laws about eventually *)
  1100 lemma
  1101   shows AE_iffI: "AE x in M. P x \<Longrightarrow> AE x in M. P x \<longleftrightarrow> Q x \<Longrightarrow> AE x in M. Q x"
  1102     and AE_disjI1: "AE x in M. P x \<Longrightarrow> AE x in M. P x \<or> Q x"
  1103     and AE_disjI2: "AE x in M. Q x \<Longrightarrow> AE x in M. P x \<or> Q x"
  1104     and AE_conjI: "AE x in M. P x \<Longrightarrow> AE x in M. Q x \<Longrightarrow> AE x in M. P x \<and> Q x"
  1105     and AE_conj_iff[simp]: "(AE x in M. P x \<and> Q x) \<longleftrightarrow> (AE x in M. P x) \<and> (AE x in M. Q x)"
  1106   by auto
  1108 lemma AE_symmetric:
  1109   assumes "AE x in M. P x = Q x"
  1110   shows "AE x in M. Q x = P x"
  1111   using assms by auto
  1113 lemma AE_impI:
  1114   "(P \<Longrightarrow> AE x in M. Q x) \<Longrightarrow> AE x in M. P \<longrightarrow> Q x"
  1115   by (cases P) auto
  1117 lemma AE_measure:
  1118   assumes AE: "AE x in M. P x" and sets: "{x\<in>space M. P x} \<in> sets M" (is "?P \<in> sets M")
  1119   shows "emeasure M {x\<in>space M. P x} = emeasure M (space M)"
  1120 proof -
  1121   from AE_E[OF AE] guess N . note N = this
  1122   with sets have "emeasure M (space M) \<le> emeasure M (?P \<union> N)"
  1123     by (intro emeasure_mono) auto
  1124   also have "\<dots> \<le> emeasure M ?P + emeasure M N"
  1125     using sets N by (intro emeasure_subadditive) auto
  1126   also have "\<dots> = emeasure M ?P" using N by simp
  1127   finally show "emeasure M ?P = emeasure M (space M)"
  1128     using emeasure_space[of M "?P"] by auto
  1129 qed
  1131 lemma AE_space: "AE x in M. x \<in> space M"
  1132   by (rule AE_I[where N="{}"]) auto
  1134 lemma AE_I2[simp, intro]:
  1135   "(\<And>x. x \<in> space M \<Longrightarrow> P x) \<Longrightarrow> AE x in M. P x"
  1136   using AE_space by force
  1138 lemma AE_Ball_mp:
  1139   "\<forall>x\<in>space M. P x \<Longrightarrow> AE x in M. P x \<longrightarrow> Q x \<Longrightarrow> AE x in M. Q x"
  1140   by auto
  1142 lemma AE_cong[cong]:
  1143   "(\<And>x. x \<in> space M \<Longrightarrow> P x \<longleftrightarrow> Q x) \<Longrightarrow> (AE x in M. P x) \<longleftrightarrow> (AE x in M. Q x)"
  1144   by auto
  1146 lemma AE_cong_strong: "M = N \<Longrightarrow> (\<And>x. x \<in> space N =simp=> P x = Q x) \<Longrightarrow> (AE x in M. P x) \<longleftrightarrow> (AE x in N. Q x)"
  1147   by (auto simp: simp_implies_def)
  1149 lemma AE_all_countable:
  1150   "(AE x in M. \<forall>i. P i x) \<longleftrightarrow> (\<forall>i::'i::countable. AE x in M. P i x)"
  1151 proof
  1152   assume "\<forall>i. AE x in M. P i x"
  1153   from this[unfolded eventually_ae_filter Bex_def, THEN choice]
  1154   obtain N where N: "\<And>i. N i \<in> null_sets M" "\<And>i. {x\<in>space M. \<not> P i x} \<subseteq> N i" by auto
  1155   have "{x\<in>space M. \<not> (\<forall>i. P i x)} \<subseteq> (\<Union>i. {x\<in>space M. \<not> P i x})" by auto
  1156   also have "\<dots> \<subseteq> (\<Union>i. N i)" using N by auto
  1157   finally have "{x\<in>space M. \<not> (\<forall>i. P i x)} \<subseteq> (\<Union>i. N i)" .
  1158   moreover from N have "(\<Union>i. N i) \<in> null_sets M"
  1159     by (intro null_sets_UN) auto
  1160   ultimately show "AE x in M. \<forall>i. P i x"
  1161     unfolding eventually_ae_filter by auto
  1162 qed auto
  1164 lemma AE_ball_countable:
  1165   assumes [intro]: "countable X"
  1166   shows "(AE x in M. \<forall>y\<in>X. P x y) \<longleftrightarrow> (\<forall>y\<in>X. AE x in M. P x y)"
  1167 proof
  1168   assume "\<forall>y\<in>X. AE x in M. P x y"
  1169   from this[unfolded eventually_ae_filter Bex_def, THEN bchoice]
  1170   obtain N where N: "\<And>y. y \<in> X \<Longrightarrow> N y \<in> null_sets M" "\<And>y. y \<in> X \<Longrightarrow> {x\<in>space M. \<not> P x y} \<subseteq> N y"
  1171     by auto
  1172   have "{x\<in>space M. \<not> (\<forall>y\<in>X. P x y)} \<subseteq> (\<Union>y\<in>X. {x\<in>space M. \<not> P x y})"
  1173     by auto
  1174   also have "\<dots> \<subseteq> (\<Union>y\<in>X. N y)"
  1175     using N by auto
  1176   finally have "{x\<in>space M. \<not> (\<forall>y\<in>X. P x y)} \<subseteq> (\<Union>y\<in>X. N y)" .
  1177   moreover from N have "(\<Union>y\<in>X. N y) \<in> null_sets M"
  1178     by (intro null_sets_UN') auto
  1179   ultimately show "AE x in M. \<forall>y\<in>X. P x y"
  1180     unfolding eventually_ae_filter by auto
  1181 qed auto
  1183 lemma AE_ball_countable':
  1184   "(\<And>N. N \<in> I \<Longrightarrow> AE x in M. P N x) \<Longrightarrow> countable I \<Longrightarrow> AE x in M. \<forall>N \<in> I. P N x"
  1185   unfolding AE_ball_countable by simp
  1187 lemma pairwise_alt: "pairwise R S \<longleftrightarrow> (\<forall>x\<in>S. \<forall>y\<in>S-{x}. R x y)"
  1188   by (auto simp add: pairwise_def)
  1190 lemma AE_pairwise: "countable F \<Longrightarrow> pairwise (\<lambda>A B. AE x in M. R x A B) F \<longleftrightarrow> (AE x in M. pairwise (R x) F)"
  1191   unfolding pairwise_alt by (simp add: AE_ball_countable)
  1193 lemma AE_discrete_difference:
  1194   assumes X: "countable X"
  1195   assumes null: "\<And>x. x \<in> X \<Longrightarrow> emeasure M {x} = 0"
  1196   assumes sets: "\<And>x. x \<in> X \<Longrightarrow> {x} \<in> sets M"
  1197   shows "AE x in M. x \<notin> X"
  1198 proof -
  1199   have "(\<Union>x\<in>X. {x}) \<in> null_sets M"
  1200     using assms by (intro null_sets_UN') auto
  1201   from AE_not_in[OF this] show "AE x in M. x \<notin> X"
  1202     by auto
  1203 qed
  1205 lemma AE_finite_all:
  1206   assumes f: "finite S" shows "(AE x in M. \<forall>i\<in>S. P i x) \<longleftrightarrow> (\<forall>i\<in>S. AE x in M. P i x)"
  1207   using f by induct auto
  1209 lemma AE_finite_allI:
  1210   assumes "finite S"
  1211   shows "(\<And>s. s \<in> S \<Longrightarrow> AE x in M. Q s x) \<Longrightarrow> AE x in M. \<forall>s\<in>S. Q s x"
  1212   using AE_finite_all[OF \<open>finite S\<close>] by auto
  1214 lemma emeasure_mono_AE:
  1215   assumes imp: "AE x in M. x \<in> A \<longrightarrow> x \<in> B"
  1216     and B: "B \<in> sets M"
  1217   shows "emeasure M A \<le> emeasure M B"
  1218 proof cases
  1219   assume A: "A \<in> sets M"
  1220   from imp obtain N where N: "{x\<in>space M. \<not> (x \<in> A \<longrightarrow> x \<in> B)} \<subseteq> N" "N \<in> null_sets M"
  1221     by (auto simp: eventually_ae_filter)
  1222   have "emeasure M A = emeasure M (A - N)"
  1223     using N A by (subst emeasure_Diff_null_set) auto
  1224   also have "emeasure M (A - N) \<le> emeasure M (B - N)"
  1225     using N A B sets.sets_into_space by (auto intro!: emeasure_mono)
  1226   also have "emeasure M (B - N) = emeasure M B"
  1227     using N B by (subst emeasure_Diff_null_set) auto
  1228   finally show ?thesis .
  1229 qed (simp add: emeasure_notin_sets)
  1231 lemma emeasure_eq_AE:
  1232   assumes iff: "AE x in M. x \<in> A \<longleftrightarrow> x \<in> B"
  1233   assumes A: "A \<in> sets M" and B: "B \<in> sets M"
  1234   shows "emeasure M A = emeasure M B"
  1235   using assms by (safe intro!: antisym emeasure_mono_AE) auto
  1237 lemma emeasure_Collect_eq_AE:
  1238   "AE x in M. P x \<longleftrightarrow> Q x \<Longrightarrow> Measurable.pred M Q \<Longrightarrow> Measurable.pred M P \<Longrightarrow>
  1239    emeasure M {x\<in>space M. P x} = emeasure M {x\<in>space M. Q x}"
  1240    by (intro emeasure_eq_AE) auto
  1242 lemma emeasure_eq_0_AE: "AE x in M. \<not> P x \<Longrightarrow> emeasure M {x\<in>space M. P x} = 0"
  1243   using AE_iff_measurable[OF _ refl, of M "\<lambda>x. \<not> P x"]
  1244   by (cases "{x\<in>space M. P x} \<in> sets M") (simp_all add: emeasure_notin_sets)
  1246 lemma emeasure_0_AE:
  1247   assumes "emeasure M (space M) = 0"
  1248   shows "AE x in M. P x"
  1249 using eventually_ae_filter assms by blast
  1251 lemma emeasure_add_AE:
  1252   assumes [measurable]: "A \<in> sets M" "B \<in> sets M" "C \<in> sets M"
  1253   assumes 1: "AE x in M. x \<in> C \<longleftrightarrow> x \<in> A \<or> x \<in> B"
  1254   assumes 2: "AE x in M. \<not> (x \<in> A \<and> x \<in> B)"
  1255   shows "emeasure M C = emeasure M A + emeasure M B"
  1256 proof -
  1257   have "emeasure M C = emeasure M (A \<union> B)"
  1258     by (rule emeasure_eq_AE) (insert 1, auto)
  1259   also have "\<dots> = emeasure M A + emeasure M (B - A)"
  1260     by (subst plus_emeasure) auto
  1261   also have "emeasure M (B - A) = emeasure M B"
  1262     by (rule emeasure_eq_AE) (insert 2, auto)
  1263   finally show ?thesis .
  1264 qed
  1266 subsection \<open>\<open>\<sigma>\<close>-finite Measures\<close>
  1268 locale sigma_finite_measure =
  1269   fixes M :: "'a measure"
  1270   assumes sigma_finite_countable:
  1271     "\<exists>A::'a set set. countable A \<and> A \<subseteq> sets M \<and> (\<Union>A) = space M \<and> (\<forall>a\<in>A. emeasure M a \<noteq> \<infinity>)"
  1273 lemma (in sigma_finite_measure) sigma_finite:
  1274   obtains A :: "nat \<Rightarrow> 'a set"
  1275   where "range A \<subseteq> sets M" "(\<Union>i. A i) = space M" "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
  1276 proof -
  1277   obtain A :: "'a set set" where
  1278     [simp]: "countable A" and
  1279     A: "A \<subseteq> sets M" "(\<Union>A) = space M" "\<And>a. a \<in> A \<Longrightarrow> emeasure M a \<noteq> \<infinity>"
  1280     using sigma_finite_countable by metis
  1281   show thesis
  1282   proof cases
  1283     assume "A = {}" with \<open>(\<Union>A) = space M\<close> show thesis
  1284       by (intro that[of "\<lambda>_. {}"]) auto
  1285   next
  1286     assume "A \<noteq> {}"
  1287     show thesis
  1288     proof
  1289       show "range (from_nat_into A) \<subseteq> sets M"
  1290         using \<open>A \<noteq> {}\<close> A by auto
  1291       have "(\<Union>i. from_nat_into A i) = \<Union>A"
  1292         using range_from_nat_into[OF \<open>A \<noteq> {}\<close> \<open>countable A\<close>] by auto
  1293       with A show "(\<Union>i. from_nat_into A i) = space M"
  1294         by auto
  1295     qed (intro A from_nat_into \<open>A \<noteq> {}\<close>)
  1296   qed
  1297 qed
  1299 lemma (in sigma_finite_measure) sigma_finite_disjoint:
  1300   obtains A :: "nat \<Rightarrow> 'a set"
  1301   where "range A \<subseteq> sets M" "(\<Union>i. A i) = space M" "\<And>i. emeasure M (A i) \<noteq> \<infinity>" "disjoint_family A"
  1302 proof -
  1303   obtain A :: "nat \<Rightarrow> 'a set" where
  1304     range: "range A \<subseteq> sets M" and
  1305     space: "(\<Union>i. A i) = space M" and
  1306     measure: "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
  1307     using sigma_finite by blast
  1308   show thesis
  1309   proof (rule that[of "disjointed A"])
  1310     show "range (disjointed A) \<subseteq> sets M"
  1311       by (rule sets.range_disjointed_sets[OF range])
  1312     show "(\<Union>i. disjointed A i) = space M"
  1313       and "disjoint_family (disjointed A)"
  1314       using disjoint_family_disjointed UN_disjointed_eq[of A] space range
  1315       by auto
  1316     show "emeasure M (disjointed A i) \<noteq> \<infinity>" for i
  1317     proof -
  1318       have "emeasure M (disjointed A i) \<le> emeasure M (A i)"
  1319         using range disjointed_subset[of A i] by (auto intro!: emeasure_mono)
  1320       then show ?thesis using measure[of i] by (auto simp: top_unique)
  1321     qed
  1322   qed
  1323 qed
  1325 lemma (in sigma_finite_measure) sigma_finite_incseq:
  1326   obtains A :: "nat \<Rightarrow> 'a set"
  1327   where "range A \<subseteq> sets M" "(\<Union>i. A i) = space M" "\<And>i. emeasure M (A i) \<noteq> \<infinity>" "incseq A"
  1328 proof -
  1329   obtain F :: "nat \<Rightarrow> 'a set" where
  1330     F: "range F \<subseteq> sets M" "(\<Union>i. F i) = space M" "\<And>i. emeasure M (F i) \<noteq> \<infinity>"
  1331     using sigma_finite by blast
  1332   show thesis
  1333   proof (rule that[of "\<lambda>n. \<Union>i\<le>n. F i"])
  1334     show "range (\<lambda>n. \<Union>i\<le>n. F i) \<subseteq> sets M"
  1335       using F by (force simp: incseq_def)
  1336     show "(\<Union>n. \<Union>i\<le>n. F i) = space M"
  1337     proof -
  1338       from F have "\<And>x. x \<in> space M \<Longrightarrow> \<exists>i. x \<in> F i" by auto
  1339       with F show ?thesis by fastforce
  1340     qed
  1341     show "emeasure M (\<Union>i\<le>n. F i) \<noteq> \<infinity>" for n
  1342     proof -
  1343       have "emeasure M (\<Union>i\<le>n. F i) \<le> (\<Sum>i\<le>n. emeasure M (F i))"
  1344         using F by (auto intro!: emeasure_subadditive_finite)
  1345       also have "\<dots> < \<infinity>"
  1346         using F by (auto simp: sum_Pinfty less_top)
  1347       finally show ?thesis by simp
  1348     qed
  1349     show "incseq (\<lambda>n. \<Union>i\<le>n. F i)"
  1350       by (force simp: incseq_def)
  1351   qed
  1352 qed
  1354 lemma (in sigma_finite_measure) approx_PInf_emeasure_with_finite:
  1355   fixes C::real
  1356   assumes W_meas: "W \<in> sets M"
  1357       and W_inf: "emeasure M W = \<infinity>"
  1358   obtains Z where "Z \<in> sets M" "Z \<subseteq> W" "emeasure M Z < \<infinity>" "emeasure M Z > C"
  1359 proof -
  1360   obtain A :: "nat \<Rightarrow> 'a set"
  1361     where A: "range A \<subseteq> sets M" "(\<Union>i. A i) = space M" "\<And>i. emeasure M (A i) \<noteq> \<infinity>" "incseq A"
  1362     using sigma_finite_incseq by blast
  1363   define B where "B = (\<lambda>i. W \<inter> A i)"
  1364   have B_meas: "\<And>i. B i \<in> sets M" using W_meas `range A \<subseteq> sets M` B_def by blast
  1365   have b: "\<And>i. B i \<subseteq> W" using B_def by blast
  1367   { fix i
  1368     have "emeasure M (B i) \<le> emeasure M (A i)"
  1369       using A by (intro emeasure_mono) (auto simp: B_def)
  1370     also have "emeasure M (A i) < \<infinity>"
  1371       using `\<And>i. emeasure M (A i) \<noteq> \<infinity>` by (simp add: less_top)
  1372     finally have "emeasure M (B i) < \<infinity>" . }
  1373   note c = this
  1375   have "W = (\<Union>i. B i)" using B_def `(\<Union>i. A i) = space M` W_meas by auto
  1376   moreover have "incseq B" using B_def `incseq A` by (simp add: incseq_def subset_eq)
  1377   ultimately have "(\<lambda>i. emeasure M (B i)) \<longlonglongrightarrow> emeasure M W" using W_meas B_meas
  1378     by (simp add: B_meas Lim_emeasure_incseq image_subset_iff)
  1379   then have "(\<lambda>i. emeasure M (B i)) \<longlonglongrightarrow> \<infinity>" using W_inf by simp
  1380   from order_tendstoD(1)[OF this, of C]
  1381   obtain i where d: "emeasure M (B i) > C"
  1382     by (auto simp: eventually_sequentially)
  1383   have "B i \<in> sets M" "B i \<subseteq> W" "emeasure M (B i) < \<infinity>" "emeasure M (B i) > C"
  1384     using B_meas b c d by auto
  1385   then show ?thesis using that by blast
  1386 qed
  1388 subsection \<open>Measure space induced by distribution of @{const measurable}-functions\<close>
  1390 definition distr :: "'a measure \<Rightarrow> 'b measure \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b measure" where
  1391   "distr M N f = measure_of (space N) (sets N) (\<lambda>A. emeasure M (f -` A \<inter> space M))"
  1393 lemma
  1394   shows sets_distr[simp, measurable_cong]: "sets (distr M N f) = sets N"
  1395     and space_distr[simp]: "space (distr M N f) = space N"
  1396   by (auto simp: distr_def)
  1398 lemma
  1399   shows measurable_distr_eq1[simp]: "measurable (distr Mf Nf f) Mf' = measurable Nf Mf'"
  1400     and measurable_distr_eq2[simp]: "measurable Mg' (distr Mg Ng g) = measurable Mg' Ng"
  1401   by (auto simp: measurable_def)
  1403 lemma distr_cong:
  1404   "M = K \<Longrightarrow> sets N = sets L \<Longrightarrow> (\<And>x. x \<in> space M \<Longrightarrow> f x = g x) \<Longrightarrow> distr M N f = distr K L g"
  1405   using sets_eq_imp_space_eq[of N L] by (simp add: distr_def Int_def cong: rev_conj_cong)
  1407 lemma emeasure_distr:
  1408   fixes f :: "'a \<Rightarrow> 'b"
  1409   assumes f: "f \<in> measurable M N" and A: "A \<in> sets N"
  1410   shows "emeasure (distr M N f) A = emeasure M (f -` A \<inter> space M)" (is "_ = ?\<mu> A")
  1411   unfolding distr_def
  1412 proof (rule emeasure_measure_of_sigma)
  1413   show "positive (sets N) ?\<mu>"
  1414     by (auto simp: positive_def)
  1416   show "countably_additive (sets N) ?\<mu>"
  1417   proof (intro countably_additiveI)
  1418     fix A :: "nat \<Rightarrow> 'b set" assume "range A \<subseteq> sets N" "disjoint_family A"
  1419     then have A: "\<And>i. A i \<in> sets N" "(\<Union>i. A i) \<in> sets N" by auto
  1420     then have *: "range (\<lambda>i. f -` (A i) \<inter> space M) \<subseteq> sets M"
  1421       using f by (auto simp: measurable_def)
  1422     moreover have "(\<Union>i. f -`  A i \<inter> space M) \<in> sets M"
  1423       using * by blast
  1424     moreover have **: "disjoint_family (\<lambda>i. f -` A i \<inter> space M)"
  1425       using \<open>disjoint_family A\<close> by (auto simp: disjoint_family_on_def)
  1426     ultimately show "(\<Sum>i. ?\<mu> (A i)) = ?\<mu> (\<Union>i. A i)"
  1427       using suminf_emeasure[OF _ **] A f
  1428       by (auto simp: comp_def vimage_UN)
  1429   qed
  1430   show "sigma_algebra (space N) (sets N)" ..
  1431 qed fact
  1433 lemma emeasure_Collect_distr:
  1434   assumes X[measurable]: "X \<in> measurable M N" "Measurable.pred N P"
  1435   shows "emeasure (distr M N X) {x\<in>space N. P x} = emeasure M {x\<in>space M. P (X x)}"
  1436   by (subst emeasure_distr)
  1437      (auto intro!: arg_cong2[where f=emeasure] X(1)[THEN measurable_space])
  1439 lemma emeasure_lfp2[consumes 1, case_names cont f measurable]:
  1440   assumes "P M"
  1441   assumes cont: "sup_continuous F"
  1442   assumes f: "\<And>M. P M \<Longrightarrow> f \<in> measurable M' M"
  1443   assumes *: "\<And>M A. P M \<Longrightarrow> (\<And>N. P N \<Longrightarrow> Measurable.pred N A) \<Longrightarrow> Measurable.pred M (F A)"
  1444   shows "emeasure M' {x\<in>space M'. lfp F (f x)} = (SUP i. emeasure M' {x\<in>space M'. (F ^^ i) (\<lambda>x. False) (f x)})"
  1445 proof (subst (1 2) emeasure_Collect_distr[symmetric, where X=f])
  1446   show "f \<in> measurable M' M"  "f \<in> measurable M' M"
  1447     using f[OF \<open>P M\<close>] by auto
  1448   { fix i show "Measurable.pred M ((F ^^ i) (\<lambda>x. False))"
  1449     using \<open>P M\<close> by (induction i arbitrary: M) (auto intro!: *) }
  1450   show "Measurable.pred M (lfp F)"
  1451     using \<open>P M\<close> cont * by (rule measurable_lfp_coinduct[of P])
  1453   have "emeasure (distr M' M f) {x \<in> space (distr M' M f). lfp F x} =
  1454     (SUP i. emeasure (distr M' M f) {x \<in> space (distr M' M f). (F ^^ i) (\<lambda>x. False) x})"
  1455     using \<open>P M\<close>
  1456   proof (coinduction arbitrary: M rule: emeasure_lfp')
  1457     case (measurable A N) then have "\<And>N. P N \<Longrightarrow> Measurable.pred (distr M' N f) A"
  1458       by metis
  1459     then have "\<And>N. P N \<Longrightarrow> Measurable.pred N A"
  1460       by simp
  1461     with \<open>P N\<close>[THEN *] show ?case
  1462       by auto
  1463   qed fact
  1464   then show "emeasure (distr M' M f) {x \<in> space M. lfp F x} =
  1465     (SUP i. emeasure (distr M' M f) {x \<in> space M. (F ^^ i) (\<lambda>x. False) x})"
  1466    by simp
  1467 qed
  1469 lemma distr_id[simp]: "distr N N (\<lambda>x. x) = N"
  1470   by (rule measure_eqI) (auto simp: emeasure_distr)
  1472 lemma distr_id2: "sets M = sets N \<Longrightarrow> distr N M (\<lambda>x. x) = N"
  1473   by (rule measure_eqI) (auto simp: emeasure_distr)
  1475 lemma measure_distr:
  1476   "f \<in> measurable M N \<Longrightarrow> S \<in> sets N \<Longrightarrow> measure (distr M N f) S = measure M (f -` S \<inter> space M)"
  1477   by (simp add: emeasure_distr measure_def)
  1479 lemma distr_cong_AE:
  1480   assumes 1: "M = K" "sets N = sets L" and
  1481     2: "(AE x in M. f x = g x)" and "f \<in> measurable M N" and "g \<in> measurable K L"
  1482   shows "distr M N f = distr K L g"
  1483 proof (rule measure_eqI)
  1484   fix A assume "A \<in> sets (distr M N f)"
  1485   with assms show "emeasure (distr M N f) A = emeasure (distr K L g) A"
  1486     by (auto simp add: emeasure_distr intro!: emeasure_eq_AE measurable_sets)
  1487 qed (insert 1, simp)
  1489 lemma AE_distrD:
  1490   assumes f: "f \<in> measurable M M'"
  1491     and AE: "AE x in distr M M' f. P x"
  1492   shows "AE x in M. P (f x)"
  1493 proof -
  1494   from AE[THEN AE_E] guess N .
  1495   with f show ?thesis
  1496     unfolding eventually_ae_filter
  1497     by (intro bexI[of _ "f -` N \<inter> space M"])
  1498        (auto simp: emeasure_distr measurable_def)
  1499 qed
  1501 lemma AE_distr_iff:
  1502   assumes f[measurable]: "f \<in> measurable M N" and P[measurable]: "{x \<in> space N. P x} \<in> sets N"
  1503   shows "(AE x in distr M N f. P x) \<longleftrightarrow> (AE x in M. P (f x))"
  1504 proof (subst (1 2) AE_iff_measurable[OF _ refl])
  1505   have "f -` {x\<in>space N. \<not> P x} \<inter> space M = {x \<in> space M. \<not> P (f x)}"
  1506     using f[THEN measurable_space] by auto
  1507   then show "(emeasure (distr M N f) {x \<in> space (distr M N f). \<not> P x} = 0) =
  1508     (emeasure M {x \<in> space M. \<not> P (f x)} = 0)"
  1509     by (simp add: emeasure_distr)
  1510 qed auto
  1512 lemma null_sets_distr_iff:
  1513   "f \<in> measurable M N \<Longrightarrow> A \<in> null_sets (distr M N f) \<longleftrightarrow> f -` A \<inter> space M \<in> null_sets M \<and> A \<in> sets N"
  1514   by (auto simp add: null_sets_def emeasure_distr)
  1516 lemma distr_distr:
  1517   "g \<in> measurable N L \<Longrightarrow> f \<in> measurable M N \<Longrightarrow> distr (distr M N f) L g = distr M L (g \<circ> f)"
  1518   by (auto simp add: emeasure_distr measurable_space
  1519            intro!: arg_cong[where f="emeasure M"] measure_eqI)
  1521 subsection \<open>Real measure values\<close>
  1523 lemma ring_of_finite_sets: "ring_of_sets (space M) {A\<in>sets M. emeasure M A \<noteq> top}"
  1524 proof (rule ring_of_setsI)
  1525   show "a \<in> {A \<in> sets M. emeasure M A \<noteq> top} \<Longrightarrow> b \<in> {A \<in> sets M. emeasure M A \<noteq> top} \<Longrightarrow>
  1526     a \<union> b \<in> {A \<in> sets M. emeasure M A \<noteq> top}" for a b
  1527     using emeasure_subadditive[of a M b] by (auto simp: top_unique)
  1529   show "a \<in> {A \<in> sets M. emeasure M A \<noteq> top} \<Longrightarrow> b \<in> {A \<in> sets M. emeasure M A \<noteq> top} \<Longrightarrow>
  1530     a - b \<in> {A \<in> sets M. emeasure M A \<noteq> top}" for a b
  1531     using emeasure_mono[of "a - b" a M] by (auto simp: Diff_subset top_unique)
  1532 qed (auto dest: sets.sets_into_space)
  1534 lemma measure_nonneg[simp]: "0 \<le> measure M A"
  1535   unfolding measure_def by auto
  1537 lemma zero_less_measure_iff: "0 < measure M A \<longleftrightarrow> measure M A \<noteq> 0"
  1538   using measure_nonneg[of M A] by (auto simp add: le_less)
  1540 lemma measure_le_0_iff: "measure M X \<le> 0 \<longleftrightarrow> measure M X = 0"
  1541   using measure_nonneg[of M X] by linarith
  1543 lemma measure_empty[simp]: "measure M {} = 0"
  1544   unfolding measure_def by (simp add: zero_ennreal.rep_eq)
  1546 lemma emeasure_eq_ennreal_measure:
  1547   "emeasure M A \<noteq> top \<Longrightarrow> emeasure M A = ennreal (measure M A)"
  1548   by (cases "emeasure M A" rule: ennreal_cases) (auto simp: measure_def)
  1550 lemma measure_zero_top: "emeasure M A = top \<Longrightarrow> measure M A = 0"
  1551   by (simp add: measure_def enn2ereal_top)
  1553 lemma measure_eq_emeasure_eq_ennreal: "0 \<le> x \<Longrightarrow> emeasure M A = ennreal x \<Longrightarrow> measure M A = x"
  1554   using emeasure_eq_ennreal_measure[of M A]
  1555   by (cases "A \<in> M") (auto simp: measure_notin_sets emeasure_notin_sets)
  1557 lemma enn2real_plus:"a < top \<Longrightarrow> b < top \<Longrightarrow> enn2real (a + b) = enn2real a + enn2real b"
  1558   by (simp add: enn2real_def plus_ennreal.rep_eq real_of_ereal_add less_top
  1559            del: real_of_ereal_enn2ereal)
  1561 lemma measure_eq_AE:
  1562   assumes iff: "AE x in M. x \<in> A \<longleftrightarrow> x \<in> B"
  1563   assumes A: "A \<in> sets M" and B: "B \<in> sets M"
  1564   shows "measure M A = measure M B"
  1565   using assms emeasure_eq_AE[OF assms] by (simp add: measure_def)
  1567 lemma measure_Union:
  1568   "emeasure M A \<noteq> \<infinity> \<Longrightarrow> emeasure M B \<noteq> \<infinity> \<Longrightarrow> A \<in> sets M \<Longrightarrow> B \<in> sets M \<Longrightarrow> A \<inter> B = {} \<Longrightarrow>
  1569     measure M (A \<union> B) = measure M A + measure M B"
  1570   by (simp add: measure_def plus_emeasure[symmetric] enn2real_plus less_top)
  1572 lemma disjoint_family_on_insert:
  1573   "i \<notin> I \<Longrightarrow> disjoint_family_on A (insert i I) \<longleftrightarrow> A i \<inter> (\<Union>i\<in>I. A i) = {} \<and> disjoint_family_on A I"
  1574   by (fastforce simp: disjoint_family_on_def)
  1576 lemma measure_finite_Union:
  1577   "finite S \<Longrightarrow> A`S \<subseteq> sets M \<Longrightarrow> disjoint_family_on A S \<Longrightarrow> (\<And>i. i \<in> S \<Longrightarrow> emeasure M (A i) \<noteq> \<infinity>) \<Longrightarrow>
  1578     measure M (\<Union>i\<in>S. A i) = (\<Sum>i\<in>S. measure M (A i))"
  1579   by (induction S rule: finite_induct)
  1580      (auto simp: disjoint_family_on_insert measure_Union sum_emeasure[symmetric] sets.countable_UN'[OF countable_finite])
  1582 lemma measure_Diff:
  1583   assumes finite: "emeasure M A \<noteq> \<infinity>"
  1584   and measurable: "A \<in> sets M" "B \<in> sets M" "B \<subseteq> A"
  1585   shows "measure M (A - B) = measure M A - measure M B"
  1586 proof -
  1587   have "emeasure M (A - B) \<le> emeasure M A" "emeasure M B \<le> emeasure M A"
  1588     using measurable by (auto intro!: emeasure_mono)
  1589   hence "measure M ((A - B) \<union> B) = measure M (A - B) + measure M B"
  1590     using measurable finite by (rule_tac measure_Union) (auto simp: top_unique)
  1591   thus ?thesis using \<open>B \<subseteq> A\<close> by (auto simp: Un_absorb2)
  1592 qed
  1594 lemma measure_UNION:
  1595   assumes measurable: "range A \<subseteq> sets M" "disjoint_family A"
  1596   assumes finite: "emeasure M (\<Union>i. A i) \<noteq> \<infinity>"
  1597   shows "(\<lambda>i. measure M (A i)) sums (measure M (\<Union>i. A i))"
  1598 proof -
  1599   have "(\<lambda>i. emeasure M (A i)) sums (emeasure M (\<Union>i. A i))"
  1600     unfolding suminf_emeasure[OF measurable, symmetric] by (simp add: summable_sums)
  1601   moreover
  1602   { fix i
  1603     have "emeasure M (A i) \<le> emeasure M (\<Union>i. A i)"
  1604       using measurable by (auto intro!: emeasure_mono)
  1605     then have "emeasure M (A i) = ennreal ((measure M (A i)))"
  1606       using finite by (intro emeasure_eq_ennreal_measure) (auto simp: top_unique) }
  1607   ultimately show ?thesis using finite
  1608     by (subst (asm) (2) emeasure_eq_ennreal_measure) simp_all
  1609 qed
  1611 lemma measure_subadditive:
  1612   assumes measurable: "A \<in> sets M" "B \<in> sets M"
  1613   and fin: "emeasure M A \<noteq> \<infinity>" "emeasure M B \<noteq> \<infinity>"
  1614   shows "measure M (A \<union> B) \<le> measure M A + measure M B"
  1615 proof -
  1616   have "emeasure M (A \<union> B) \<noteq> \<infinity>"
  1617     using emeasure_subadditive[OF measurable] fin by (auto simp: top_unique)
  1618   then show "(measure M (A \<union> B)) \<le> (measure M A) + (measure M B)"
  1619     using emeasure_subadditive[OF measurable] fin
  1620     apply simp
  1621     apply (subst (asm) (2 3 4) emeasure_eq_ennreal_measure)
  1622     apply (auto simp add: ennreal_plus[symmetric] simp del: ennreal_plus)
  1623     done
  1624 qed
  1626 lemma measure_subadditive_finite:
  1627   assumes A: "finite I" "A`I \<subseteq> sets M" and fin: "\<And>i. i \<in> I \<Longrightarrow> emeasure M (A i) \<noteq> \<infinity>"
  1628   shows "measure M (\<Union>i\<in>I. A i) \<le> (\<Sum>i\<in>I. measure M (A i))"
  1629 proof -
  1630   { have "emeasure M (\<Union>i\<in>I. A i) \<le> (\<Sum>i\<in>I. emeasure M (A i))"
  1631       using emeasure_subadditive_finite[OF A] .
  1632     also have "\<dots> < \<infinity>"
  1633       using fin by (simp add: less_top A)
  1634     finally have "emeasure M (\<Union>i\<in>I. A i) \<noteq> top" by simp }
  1635   note * = this
  1636   show ?thesis
  1637     using emeasure_subadditive_finite[OF A] fin
  1638     unfolding emeasure_eq_ennreal_measure[OF *]
  1639     by (simp_all add: sum_nonneg emeasure_eq_ennreal_measure)
  1640 qed
  1642 lemma measure_subadditive_countably:
  1643   assumes A: "range A \<subseteq> sets M" and fin: "(\<Sum>i. emeasure M (A i)) \<noteq> \<infinity>"
  1644   shows "measure M (\<Union>i. A i) \<le> (\<Sum>i. measure M (A i))"
  1645 proof -
  1646   from fin have **: "\<And>i. emeasure M (A i) \<noteq> top"
  1647     using ennreal_suminf_lessD[of "\<lambda>i. emeasure M (A i)"] by (simp add: less_top)
  1648   { have "emeasure M (\<Union>i. A i) \<le> (\<Sum>i. emeasure M (A i))"
  1649       using emeasure_subadditive_countably[OF A] .
  1650     also have "\<dots> < \<infinity>"
  1651       using fin by (simp add: less_top)
  1652     finally have "emeasure M (\<Union>i. A i) \<noteq> top" by simp }
  1653   then have "ennreal (measure M (\<Union>i. A i)) = emeasure M (\<Union>i. A i)"
  1654     by (rule emeasure_eq_ennreal_measure[symmetric])
  1655   also have "\<dots> \<le> (\<Sum>i. emeasure M (A i))"
  1656     using emeasure_subadditive_countably[OF A] .
  1657   also have "\<dots> = ennreal (\<Sum>i. measure M (A i))"
  1658     using fin unfolding emeasure_eq_ennreal_measure[OF **]
  1659     by (subst suminf_ennreal) (auto simp: **)
  1660   finally show ?thesis
  1661     apply (rule ennreal_le_iff[THEN iffD1, rotated])
  1662     apply (intro suminf_nonneg allI measure_nonneg summable_suminf_not_top)
  1663     using fin
  1664     apply (simp add: emeasure_eq_ennreal_measure[OF **])
  1665     done
  1666 qed
  1668 lemma measure_Un_null_set: "A \<in> sets M \<Longrightarrow> B \<in> null_sets M \<Longrightarrow> measure M (A \<union> B) = measure M A"
  1669   by (simp add: measure_def emeasure_Un_null_set)
  1671 lemma measure_Diff_null_set: "A \<in> sets M \<Longrightarrow> B \<in> null_sets M \<Longrightarrow> measure M (A - B) = measure M A"
  1672   by (simp add: measure_def emeasure_Diff_null_set)
  1674 lemma measure_eq_sum_singleton:
  1675   "finite S \<Longrightarrow> (\<And>x. x \<in> S \<Longrightarrow> {x} \<in> sets M) \<Longrightarrow> (\<And>x. x \<in> S \<Longrightarrow> emeasure M {x} \<noteq> \<infinity>) \<Longrightarrow>
  1676     measure M S = (\<Sum>x\<in>S. measure M {x})"
  1677   using emeasure_eq_sum_singleton[of S M]
  1678   by (intro measure_eq_emeasure_eq_ennreal) (auto simp: sum_nonneg emeasure_eq_ennreal_measure)
  1680 lemma Lim_measure_incseq:
  1681   assumes A: "range A \<subseteq> sets M" "incseq A" and fin: "emeasure M (\<Union>i. A i) \<noteq> \<infinity>"
  1682   shows "(\<lambda>i. measure M (A i)) \<longlonglongrightarrow> measure M (\<Union>i. A i)"
  1683 proof (rule tendsto_ennrealD)
  1684   have "ennreal (measure M (\<Union>i. A i)) = emeasure M (\<Union>i. A i)"
  1685     using fin by (auto simp: emeasure_eq_ennreal_measure)
  1686   moreover have "ennreal (measure M (A i)) = emeasure M (A i)" for i
  1687     using assms emeasure_mono[of "A _" "\<Union>i. A i" M]
  1688     by (intro emeasure_eq_ennreal_measure[symmetric]) (auto simp: less_top UN_upper intro: le_less_trans)
  1689   ultimately show "(\<lambda>x. ennreal (Sigma_Algebra.measure M (A x))) \<longlonglongrightarrow> ennreal (Sigma_Algebra.measure M (\<Union>i. A i))"
  1690     using A by (auto intro!: Lim_emeasure_incseq)
  1691 qed auto
  1693 lemma Lim_measure_decseq:
  1694   assumes A: "range A \<subseteq> sets M" "decseq A" and fin: "\<And>i. emeasure M (A i) \<noteq> \<infinity>"
  1695   shows "(\<lambda>n. measure M (A n)) \<longlonglongrightarrow> measure M (\<Inter>i. A i)"
  1696 proof (rule tendsto_ennrealD)
  1697   have "ennreal (measure M (\<Inter>i. A i)) = emeasure M (\<Inter>i. A i)"
  1698     using fin[of 0] A emeasure_mono[of "\<Inter>i. A i" "A 0" M]
  1699     by (auto intro!: emeasure_eq_ennreal_measure[symmetric] simp: INT_lower less_top intro: le_less_trans)
  1700   moreover have "ennreal (measure M (A i)) = emeasure M (A i)" for i
  1701     using A fin[of i] by (intro emeasure_eq_ennreal_measure[symmetric]) auto
  1702   ultimately show "(\<lambda>x. ennreal (Sigma_Algebra.measure M (A x))) \<longlonglongrightarrow> ennreal (Sigma_Algebra.measure M (\<Inter>i. A i))"
  1703     using fin A by (auto intro!: Lim_emeasure_decseq)
  1704 qed auto
  1706 subsection \<open>Set of measurable sets with finite measure\<close>
  1708 definition fmeasurable :: "'a measure \<Rightarrow> 'a set set"
  1709 where
  1710   "fmeasurable M = {A\<in>sets M. emeasure M A < \<infinity>}"
  1712 lemma fmeasurableD[dest, measurable_dest]: "A \<in> fmeasurable M \<Longrightarrow> A \<in> sets M"
  1713   by (auto simp: fmeasurable_def)
  1715 lemma fmeasurableD2: "A \<in> fmeasurable M \<Longrightarrow> emeasure M A \<noteq> top"
  1716   by (auto simp: fmeasurable_def)
  1718 lemma fmeasurableI: "A \<in> sets M \<Longrightarrow> emeasure M A < \<infinity> \<Longrightarrow> A \<in> fmeasurable M"
  1719   by (auto simp: fmeasurable_def)
  1721 lemma fmeasurableI_null_sets: "A \<in> null_sets M \<Longrightarrow> A \<in> fmeasurable M"
  1722   by (auto simp: fmeasurable_def)
  1724 lemma fmeasurableI2: "A \<in> fmeasurable M \<Longrightarrow> B \<subseteq> A \<Longrightarrow> B \<in> sets M \<Longrightarrow> B \<in> fmeasurable M"
  1725   using emeasure_mono[of B A M] by (auto simp: fmeasurable_def)
  1727 lemma measure_mono_fmeasurable:
  1728   "A \<subseteq> B \<Longrightarrow> A \<in> sets M \<Longrightarrow> B \<in> fmeasurable M \<Longrightarrow> measure M A \<le> measure M B"
  1729   by (auto simp: measure_def fmeasurable_def intro!: emeasure_mono enn2real_mono)
  1731 lemma emeasure_eq_measure2: "A \<in> fmeasurable M \<Longrightarrow> emeasure M A = measure M A"
  1732   by (simp add: emeasure_eq_ennreal_measure fmeasurable_def less_top)
  1734 interpretation fmeasurable: ring_of_sets "space M" "fmeasurable M"
  1735 proof (rule ring_of_setsI)
  1736   show "fmeasurable M \<subseteq> Pow (space M)" "{} \<in> fmeasurable M"
  1737     by (auto simp: fmeasurable_def dest: sets.sets_into_space)
  1738   fix a b assume *: "a \<in> fmeasurable M" "b \<in> fmeasurable M"
  1739   then have "emeasure M (a \<union> b) \<le> emeasure M a + emeasure M b"
  1740     by (intro emeasure_subadditive) auto
  1741   also have "\<dots> < top"
  1742     using * by (auto simp: fmeasurable_def)
  1743   finally show  "a \<union> b \<in> fmeasurable M"
  1744     using * by (auto intro: fmeasurableI)
  1745   show "a - b \<in> fmeasurable M"
  1746     using emeasure_mono[of "a - b" a M] * by (auto simp: fmeasurable_def Diff_subset)
  1747 qed
  1749 lemma fmeasurable_Diff: "A \<in> fmeasurable M \<Longrightarrow> B \<in> sets M \<Longrightarrow> A - B \<in> fmeasurable M"
  1750   using fmeasurableI2[of A M "A - B"] by auto
  1752 lemma fmeasurable_UN:
  1753   assumes "countable I" "\<And>i. i \<in> I \<Longrightarrow> F i \<subseteq> A" "\<And>i. i \<in> I \<Longrightarrow> F i \<in> sets M" "A \<in> fmeasurable M"
  1754   shows "(\<Union>i\<in>I. F i) \<in> fmeasurable M"
  1755 proof (rule fmeasurableI2)
  1756   show "A \<in> fmeasurable M" "(\<Union>i\<in>I. F i) \<subseteq> A" using assms by auto
  1757   show "(\<Union>i\<in>I. F i) \<in> sets M"
  1758     using assms by (intro sets.countable_UN') auto
  1759 qed
  1761 lemma fmeasurable_INT:
  1762   assumes "countable I" "i \<in> I" "\<And>i. i \<in> I \<Longrightarrow> F i \<in> sets M" "F i \<in> fmeasurable M"
  1763   shows "(\<Inter>i\<in>I. F i) \<in> fmeasurable M"
  1764 proof (rule fmeasurableI2)
  1765   show "F i \<in> fmeasurable M" "(\<Inter>i\<in>I. F i) \<subseteq> F i"
  1766     using assms by auto
  1767   show "(\<Inter>i\<in>I. F i) \<in> sets M"
  1768     using assms by (intro sets.countable_INT') auto
  1769 qed
  1771 lemma measure_Un2:
  1772   "A \<in> fmeasurable M \<Longrightarrow> B \<in> fmeasurable M \<Longrightarrow> measure M (A \<union> B) = measure M A + measure M (B - A)"
  1773   using measure_Union[of M A "B - A"] by (auto simp: fmeasurableD2 fmeasurable.Diff)
  1775 lemma measure_Un3:
  1776   assumes "A \<in> fmeasurable M" "B \<in> fmeasurable M"
  1777   shows "measure M (A \<union> B) = measure M A + measure M B - measure M (A \<inter> B)"
  1778 proof -
  1779   have "measure M (A \<union> B) = measure M A + measure M (B - A)"
  1780     using assms by (rule measure_Un2)
  1781   also have "B - A = B - (A \<inter> B)"
  1782     by auto
  1783   also have "measure M (B - (A \<inter> B)) = measure M B - measure M (A \<inter> B)"
  1784     using assms by (intro measure_Diff) (auto simp: fmeasurable_def)
  1785   finally show ?thesis
  1786     by simp
  1787 qed
  1789 lemma measure_Un_AE:
  1790   "AE x in M. x \<notin> A \<or> x \<notin> B \<Longrightarrow> A \<in> fmeasurable M \<Longrightarrow> B \<in> fmeasurable M \<Longrightarrow>
  1791   measure M (A \<union> B) = measure M A + measure M B"
  1792   by (subst measure_Un2) (auto intro!: measure_eq_AE)
  1794 lemma measure_UNION_AE:
  1795   assumes I: "finite I"
  1796   shows "(\<And>i. i \<in> I \<Longrightarrow> F i \<in> fmeasurable M) \<Longrightarrow> pairwise (\<lambda>i j. AE x in M. x \<notin> F i \<or> x \<notin> F j) I \<Longrightarrow>
  1797     measure M (\<Union>i\<in>I. F i) = (\<Sum>i\<in>I. measure M (F i))"
  1798   unfolding AE_pairwise[OF countable_finite, OF I]
  1799   using I
  1800   apply (induction I rule: finite_induct)
  1801    apply simp
  1802   apply (simp add: pairwise_insert)
  1803   apply (subst measure_Un_AE)
  1804   apply auto
  1805   done
  1807 lemma measure_UNION':
  1808   "finite I \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> F i \<in> fmeasurable M) \<Longrightarrow> pairwise (\<lambda>i j. disjnt (F i) (F j)) I \<Longrightarrow>
  1809     measure M (\<Union>i\<in>I. F i) = (\<Sum>i\<in>I. measure M (F i))"
  1810   by (intro measure_UNION_AE) (auto simp: disjnt_def elim!: pairwise_mono intro!: always_eventually)
  1812 lemma measure_Union_AE:
  1813   "finite F \<Longrightarrow> (\<And>S. S \<in> F \<Longrightarrow> S \<in> fmeasurable M) \<Longrightarrow> pairwise (\<lambda>S T. AE x in M. x \<notin> S \<or> x \<notin> T) F \<Longrightarrow>
  1814     measure M (\<Union>F) = (\<Sum>S\<in>F. measure M S)"
  1815   using measure_UNION_AE[of F "\<lambda>x. x" M] by simp
  1817 lemma measure_Union':
  1818   "finite F \<Longrightarrow> (\<And>S. S \<in> F \<Longrightarrow> S \<in> fmeasurable M) \<Longrightarrow> pairwise disjnt F \<Longrightarrow> measure M (\<Union>F) = (\<Sum>S\<in>F. measure M S)"
  1819   using measure_UNION'[of F "\<lambda>x. x" M] by simp
  1821 lemma measure_Un_le:
  1822   assumes "A \<in> sets M" "B \<in> sets M" shows "measure M (A \<union> B) \<le> measure M A + measure M B"
  1823 proof cases
  1824   assume "A \<in> fmeasurable M \<and> B \<in> fmeasurable M"
  1825   with measure_subadditive[of A M B] assms show ?thesis
  1826     by (auto simp: fmeasurableD2)
  1827 next
  1828   assume "\<not> (A \<in> fmeasurable M \<and> B \<in> fmeasurable M)"
  1829   then have "A \<union> B \<notin> fmeasurable M"
  1830     using fmeasurableI2[of "A \<union> B" M A] fmeasurableI2[of "A \<union> B" M B] assms by auto
  1831   with assms show ?thesis
  1832     by (auto simp: fmeasurable_def measure_def less_top[symmetric])
  1833 qed
  1835 lemma measure_UNION_le:
  1836   "finite I \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> F i \<in> sets M) \<Longrightarrow> measure M (\<Union>i\<in>I. F i) \<le> (\<Sum>i\<in>I. measure M (F i))"
  1837 proof (induction I rule: finite_induct)
  1838   case (insert i I)
  1839   then have "measure M (\<Union>i\<in>insert i I. F i) \<le> measure M (F i) + measure M (\<Union>i\<in>I. F i)"
  1840     by (auto intro!: measure_Un_le)
  1841   also have "measure M (\<Union>i\<in>I. F i) \<le> (\<Sum>i\<in>I. measure M (F i))"
  1842     using insert by auto
  1843   finally show ?case
  1844     using insert by simp
  1845 qed simp
  1847 lemma measure_Union_le:
  1848   "finite F \<Longrightarrow> (\<And>S. S \<in> F \<Longrightarrow> S \<in> sets M) \<Longrightarrow> measure M (\<Union>F) \<le> (\<Sum>S\<in>F. measure M S)"
  1849   using measure_UNION_le[of F "\<lambda>x. x" M] by simp
  1851 lemma
  1852   assumes "countable I" and I: "\<And>i. i \<in> I \<Longrightarrow> A i \<in> fmeasurable M"
  1853     and bound: "\<And>I'. I' \<subseteq> I \<Longrightarrow> finite I' \<Longrightarrow> measure M (\<Union>i\<in>I'. A i) \<le> B" and "0 \<le> B"
  1854   shows fmeasurable_UN_bound: "(\<Union>i\<in>I. A i) \<in> fmeasurable M" (is ?fm)
  1855     and measure_UN_bound: "measure M (\<Union>i\<in>I. A i) \<le> B" (is ?m)
  1856 proof -
  1857   have "?fm \<and> ?m"
  1858   proof cases
  1859     assume "I = {}" with \<open>0 \<le> B\<close> show ?thesis by simp
  1860   next
  1861     assume "I \<noteq> {}"
  1862     have "(\<Union>i\<in>I. A i) = (\<Union>i. (\<Union>n\<le>i. A (from_nat_into I n)))"
  1863       by (subst range_from_nat_into[symmetric, OF \<open>I \<noteq> {}\<close> \<open>countable I\<close>]) auto
  1864     then have "emeasure M (\<Union>i\<in>I. A i) = emeasure M (\<Union>i. (\<Union>n\<le>i. A (from_nat_into I n)))" by simp
  1865     also have "\<dots> = (SUP i. emeasure M (\<Union>n\<le>i. A (from_nat_into I n)))"
  1866       using I \<open>I \<noteq> {}\<close>[THEN from_nat_into] by (intro SUP_emeasure_incseq[symmetric]) (fastforce simp: incseq_Suc_iff)+
  1867     also have "\<dots> \<le> B"
  1868     proof (intro SUP_least)
  1869       fix i :: nat
  1870       have "emeasure M (\<Union>n\<le>i. A (from_nat_into I n)) = measure M (\<Union>n\<le>i. A (from_nat_into I n))"
  1871         using I \<open>I \<noteq> {}\<close>[THEN from_nat_into] by (intro emeasure_eq_measure2 fmeasurable.finite_UN) auto
  1872       also have "\<dots> = measure M (\<Union>n\<in>from_nat_into I ` {..i}. A n)"
  1873         by simp
  1874       also have "\<dots> \<le> B"
  1875         by (intro ennreal_leI bound) (auto intro:  from_nat_into[OF \<open>I \<noteq> {}\<close>])
  1876       finally show "emeasure M (\<Union>n\<le>i. A (from_nat_into I n)) \<le> ennreal B" .
  1877     qed
  1878     finally have *: "emeasure M (\<Union>i\<in>I. A i) \<le> B" .
  1879     then have ?fm
  1880       using I \<open>countable I\<close> by (intro fmeasurableI conjI) (auto simp: less_top[symmetric] top_unique)
  1881     with * \<open>0\<le>B\<close> show ?thesis
  1882       by (simp add: emeasure_eq_measure2)
  1883   qed
  1884   then show ?fm ?m by auto
  1885 qed
  1887 lemma suminf_exist_split2:
  1888   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
  1889   assumes "summable f"
  1890   shows "(\<lambda>n. (\<Sum>k. f(k+n))) \<longlonglongrightarrow> 0"
  1891 by (subst lim_sequentially, auto simp add: dist_norm suminf_exist_split[OF _ assms])
  1893 lemma emeasure_union_summable:
  1894   assumes [measurable]: "\<And>n. A n \<in> sets M"
  1895     and "\<And>n. emeasure M (A n) < \<infinity>" "summable (\<lambda>n. measure M (A n))"
  1896   shows "emeasure M (\<Union>n. A n) < \<infinity>" "emeasure M (\<Union>n. A n) \<le> (\<Sum>n. measure M (A n))"
  1897 proof -
  1898   define B where "B = (\<lambda>N. (\<Union>n\<in>{..<N}. A n))"
  1899   have [measurable]: "B N \<in> sets M" for N unfolding B_def by auto
  1900   have "(\<lambda>N. emeasure M (B N)) \<longlonglongrightarrow> emeasure M (\<Union>N. B N)"
  1901     apply (rule Lim_emeasure_incseq) unfolding B_def by (auto simp add: SUP_subset_mono incseq_def)
  1902   moreover have "emeasure M (B N) \<le> ennreal (\<Sum>n. measure M (A n))" for N
  1903   proof -
  1904     have *: "(\<Sum>n\<in>{..<N}. measure M (A n)) \<le> (\<Sum>n. measure M (A n))"
  1905       using assms(3) measure_nonneg sum_le_suminf by blast
  1907     have "emeasure M (B N) \<le> (\<Sum>n\<in>{..<N}. emeasure M (A n))"
  1908       unfolding B_def by (rule emeasure_subadditive_finite, auto)
  1909     also have "... = (\<Sum>n\<in>{..<N}. ennreal(measure M (A n)))"
  1910       using assms(2) by (simp add: emeasure_eq_ennreal_measure less_top)
  1911     also have "... = ennreal (\<Sum>n\<in>{..<N}. measure M (A n))"
  1912       by auto
  1913     also have "... \<le> ennreal (\<Sum>n. measure M (A n))"
  1914       using * by (auto simp: ennreal_leI)
  1915     finally show ?thesis by simp
  1916   qed
  1917   ultimately have "emeasure M (\<Union>N. B N) \<le> ennreal (\<Sum>n. measure M (A n))"
  1918     by (simp add: Lim_bounded_ereal)
  1919   then show "emeasure M (\<Union>n. A n) \<le> (\<Sum>n. measure M (A n))"
  1920     unfolding B_def by (metis UN_UN_flatten UN_lessThan_UNIV)
  1921   then show "emeasure M (\<Union>n. A n) < \<infinity>"
  1922     by (auto simp: less_top[symmetric] top_unique)
  1923 qed
  1925 lemma borel_cantelli_limsup1:
  1926   assumes [measurable]: "\<And>n. A n \<in> sets M"
  1927     and "\<And>n. emeasure M (A n) < \<infinity>" "summable (\<lambda>n. measure M (A n))"
  1928   shows "limsup A \<in> null_sets M"
  1929 proof -
  1930   have "emeasure M (limsup A) \<le> 0"
  1931   proof (rule LIMSEQ_le_const)
  1932     have "(\<lambda>n. (\<Sum>k. measure M (A (k+n)))) \<longlonglongrightarrow> 0" by (rule suminf_exist_split2[OF assms(3)])
  1933     then show "(\<lambda>n. ennreal (\<Sum>k. measure M (A (k+n)))) \<longlonglongrightarrow> 0"
  1934       unfolding ennreal_0[symmetric] by (intro tendsto_ennrealI)
  1935     have "emeasure M (limsup A) \<le> (\<Sum>k. measure M (A (k+n)))" for n
  1936     proof -
  1937       have I: "(\<Union>k\<in>{n..}. A k) = (\<Union>k. A (k+n))" by (auto, metis le_add_diff_inverse2, fastforce)
  1938       have "emeasure M (limsup A) \<le> emeasure M (\<Union>k\<in>{n..}. A k)"
  1939         by (rule emeasure_mono, auto simp add: limsup_INF_SUP)
  1940       also have "... = emeasure M (\<Union>k. A (k+n))"
  1941         using I by auto
  1942       also have "... \<le> (\<Sum>k. measure M (A (k+n)))"
  1943         apply (rule emeasure_union_summable)
  1944         using assms summable_ignore_initial_segment[OF assms(3), of n] by auto
  1945       finally show ?thesis by simp
  1946     qed
  1947     then show "\<exists>N. \<forall>n\<ge>N. emeasure M (limsup A) \<le> (\<Sum>k. measure M (A (k+n)))"
  1948       by auto
  1949   qed
  1950   then show ?thesis using assms(1) measurable_limsup by auto
  1951 qed
  1953 lemma borel_cantelli_AE1:
  1954   assumes [measurable]: "\<And>n. A n \<in> sets M"
  1955     and "\<And>n. emeasure M (A n) < \<infinity>" "summable (\<lambda>n. measure M (A n))"
  1956   shows "AE x in M. eventually (\<lambda>n. x \<in> space M - A n) sequentially"
  1957 proof -
  1958   have "AE x in M. x \<notin> limsup A"
  1959     using borel_cantelli_limsup1[OF assms] unfolding eventually_ae_filter by auto
  1960   moreover
  1961   {
  1962     fix x assume "x \<notin> limsup A"
  1963     then obtain N where "x \<notin> (\<Union>n\<in>{N..}. A n)" unfolding limsup_INF_SUP by blast
  1964     then have "eventually (\<lambda>n. x \<notin> A n) sequentially" using eventually_sequentially by auto
  1965   }
  1966   ultimately show ?thesis by auto
  1967 qed
  1969 subsection \<open>Measure spaces with @{term "emeasure M (space M) < \<infinity>"}\<close>
  1971 locale finite_measure = sigma_finite_measure M for M +
  1972   assumes finite_emeasure_space: "emeasure M (space M) \<noteq> top"
  1974 lemma finite_measureI[Pure.intro!]:
  1975   "emeasure M (space M) \<noteq> \<infinity> \<Longrightarrow> finite_measure M"
  1976   proof qed (auto intro!: exI[of _ "{space M}"])
  1978 lemma (in finite_measure) emeasure_finite[simp, intro]: "emeasure M A \<noteq> top"
  1979   using finite_emeasure_space emeasure_space[of M A] by (auto simp: top_unique)
  1981 lemma (in finite_measure) fmeasurable_eq_sets: "fmeasurable M = sets M"
  1982   by (auto simp: fmeasurable_def less_top[symmetric])
  1984 lemma (in finite_measure) emeasure_eq_measure: "emeasure M A = ennreal (measure M A)"
  1985   by (intro emeasure_eq_ennreal_measure) simp
  1987 lemma (in finite_measure) emeasure_real: "\<exists>r. 0 \<le> r \<and> emeasure M A = ennreal r"
  1988   using emeasure_finite[of A] by (cases "emeasure M A" rule: ennreal_cases) auto
  1990 lemma (in finite_measure) bounded_measure: "measure M A \<le> measure M (space M)"
  1991   using emeasure_space[of M A] emeasure_real[of A] emeasure_real[of "space M"] by (auto simp: measure_def)
  1993 lemma (in finite_measure) finite_measure_Diff:
  1994   assumes sets: "A \<in> sets M" "B \<in> sets M" and "B \<subseteq> A"
  1995   shows "measure M (A - B) = measure M A - measure M B"
  1996   using measure_Diff[OF _ assms] by simp
  1998 lemma (in finite_measure) finite_measure_Union:
  1999   assumes sets: "A \<in> sets M" "B \<in> sets M" and "A \<inter> B = {}"
  2000   shows "measure M (A \<union> B) = measure M A + measure M B"
  2001   using measure_Union[OF _ _ assms] by simp
  2003 lemma (in finite_measure) finite_measure_finite_Union:
  2004   assumes measurable: "finite S" "A`S \<subseteq> sets M" "disjoint_family_on A S"
  2005   shows "measure M (\<Union>i\<in>S. A i) = (\<Sum>i\<in>S. measure M (A i))"
  2006   using measure_finite_Union[OF assms] by simp
  2008 lemma (in finite_measure) finite_measure_UNION:
  2009   assumes A: "range A \<subseteq> sets M" "disjoint_family A"
  2010   shows "(\<lambda>i. measure M (A i)) sums (measure M (\<Union>i. A i))"
  2011   using measure_UNION[OF A] by simp
  2013 lemma (in finite_measure) finite_measure_mono:
  2014   assumes "A \<subseteq> B" "B \<in> sets M" shows "measure M A \<le> measure M B"
  2015   using emeasure_mono[OF assms] emeasure_real[of A] emeasure_real[of B] by (auto simp: measure_def)
  2017 lemma (in finite_measure) finite_measure_subadditive:
  2018   assumes m: "A \<in> sets M" "B \<in> sets M"
  2019   shows "measure M (A \<union> B) \<le> measure M A + measure M B"
  2020   using measure_subadditive[OF m] by simp
  2022 lemma (in finite_measure) finite_measure_subadditive_finite:
  2023   assumes "finite I" "A`I \<subseteq> sets M" shows "measure M (\<Union>i\<in>I. A i) \<le> (\<Sum>i\<in>I. measure M (A i))"
  2024   using measure_subadditive_finite[OF assms] by simp
  2026 lemma (in finite_measure) finite_measure_subadditive_countably:
  2027   "range A \<subseteq> sets M \<Longrightarrow> summable (\<lambda>i. measure M (A i)) \<Longrightarrow> measure M (\<Union>i. A i) \<le> (\<Sum>i. measure M (A i))"
  2028   by (rule measure_subadditive_countably)
  2029      (simp_all add: ennreal_suminf_neq_top emeasure_eq_measure)
  2031 lemma (in finite_measure) finite_measure_eq_sum_singleton:
  2032   assumes "finite S" and *: "\<And>x. x \<in> S \<Longrightarrow> {x} \<in> sets M"
  2033   shows "measure M S = (\<Sum>x\<in>S. measure M {x})"
  2034   using measure_eq_sum_singleton[OF assms] by simp
  2036 lemma (in finite_measure) finite_Lim_measure_incseq:
  2037   assumes A: "range A \<subseteq> sets M" "incseq A"
  2038   shows "(\<lambda>i. measure M (A i)) \<longlonglongrightarrow> measure M (\<Union>i. A i)"
  2039   using Lim_measure_incseq[OF A] by simp
  2041 lemma (in finite_measure) finite_Lim_measure_decseq:
  2042   assumes A: "range A \<subseteq> sets M" "decseq A"
  2043   shows "(\<lambda>n. measure M (A n)) \<longlonglongrightarrow> measure M (\<Inter>i. A i)"
  2044   using Lim_measure_decseq[OF A] by simp
  2046 lemma (in finite_measure) finite_measure_compl:
  2047   assumes S: "S \<in> sets M"
  2048   shows "measure M (space M - S) = measure M (space M) - measure M S"
  2049   using measure_Diff[OF _ S sets.sets_into_space] S by simp
  2051 lemma (in finite_measure) finite_measure_mono_AE:
  2052   assumes imp: "AE x in M. x \<in> A \<longrightarrow> x \<in> B" and B: "B \<in> sets M"
  2053   shows "measure M A \<le> measure M B"
  2054   using assms emeasure_mono_AE[OF imp B]
  2055   by (simp add: emeasure_eq_measure)
  2057 lemma (in finite_measure) finite_measure_eq_AE:
  2058   assumes iff: "AE x in M. x \<in> A \<longleftrightarrow> x \<in> B"
  2059   assumes A: "A \<in> sets M" and B: "B \<in> sets M"
  2060   shows "measure M A = measure M B"
  2061   using assms emeasure_eq_AE[OF assms] by (simp add: emeasure_eq_measure)
  2063 lemma (in finite_measure) measure_increasing: "increasing M (measure M)"
  2064   by (auto intro!: finite_measure_mono simp: increasing_def)
  2066 lemma (in finite_measure) measure_zero_union:
  2067   assumes "s \<in> sets M" "t \<in> sets M" "measure M t = 0"
  2068   shows "measure M (s \<union> t) = measure M s"
  2069 using assms
  2070 proof -
  2071   have "measure M (s \<union> t) \<le> measure M s"
  2072     using finite_measure_subadditive[of s t] assms by auto
  2073   moreover have "measure M (s \<union> t) \<ge> measure M s"
  2074     using assms by (blast intro: finite_measure_mono)
  2075   ultimately show ?thesis by simp
  2076 qed
  2078 lemma (in finite_measure) measure_eq_compl:
  2079   assumes "s \<in> sets M" "t \<in> sets M"
  2080   assumes "measure M (space M - s) = measure M (space M - t)"
  2081   shows "measure M s = measure M t"
  2082   using assms finite_measure_compl by auto
  2084 lemma (in finite_measure) measure_eq_bigunion_image:
  2085   assumes "range f \<subseteq> sets M" "range g \<subseteq> sets M"
  2086   assumes "disjoint_family f" "disjoint_family g"
  2087   assumes "\<And> n :: nat. measure M (f n) = measure M (g n)"
  2088   shows "measure M (\<Union>i. f i) = measure M (\<Union>i. g i)"
  2089 using assms
  2090 proof -
  2091   have a: "(\<lambda> i. measure M (f i)) sums (measure M (\<Union>i. f i))"
  2092     by (rule finite_measure_UNION[OF assms(1,3)])
  2093   have b: "(\<lambda> i. measure M (g i)) sums (measure M (\<Union>i. g i))"
  2094     by (rule finite_measure_UNION[OF assms(2,4)])
  2095   show ?thesis using sums_unique[OF b] sums_unique[OF a] assms by simp
  2096 qed
  2098 lemma (in finite_measure) measure_countably_zero:
  2099   assumes "range c \<subseteq> sets M"
  2100   assumes "\<And> i. measure M (c i) = 0"
  2101   shows "measure M (\<Union>i :: nat. c i) = 0"
  2102 proof (rule antisym)
  2103   show "measure M (\<Union>i :: nat. c i) \<le> 0"
  2104     using finite_measure_subadditive_countably[OF assms(1)] by (simp add: assms(2))
  2105 qed simp
  2107 lemma (in finite_measure) measure_space_inter:
  2108   assumes events:"s \<in> sets M" "t \<in> sets M"
  2109   assumes "measure M t = measure M (space M)"
  2110   shows "measure M (s \<inter> t) = measure M s"
  2111 proof -
  2112   have "measure M ((space M - s) \<union> (space M - t)) = measure M (space M - s)"
  2113     using events assms finite_measure_compl[of "t"] by (auto intro!: measure_zero_union)
  2114   also have "(space M - s) \<union> (space M - t) = space M - (s \<inter> t)"
  2115     by blast
  2116   finally show "measure M (s \<inter> t) = measure M s"
  2117     using events by (auto intro!: measure_eq_compl[of "s \<inter> t" s])
  2118 qed
  2120 lemma (in finite_measure) measure_equiprobable_finite_unions:
  2121   assumes s: "finite s" "\<And>x. x \<in> s \<Longrightarrow> {x} \<in> sets M"
  2122   assumes "\<And> x y. \<lbrakk>x \<in> s; y \<in> s\<rbrakk> \<Longrightarrow> measure M {x} = measure M {y}"
  2123   shows "measure M s = real (card s) * measure M {SOME x. x \<in> s}"
  2124 proof cases
  2125   assume "s \<noteq> {}"
  2126   then have "\<exists> x. x \<in> s" by blast
  2127   from someI_ex[OF this] assms
  2128   have prob_some: "\<And> x. x \<in> s \<Longrightarrow> measure M {x} = measure M {SOME y. y \<in> s}" by blast
  2129   have "measure M s = (\<Sum> x \<in> s. measure M {x})"
  2130     using finite_measure_eq_sum_singleton[OF s] by simp
  2131   also have "\<dots> = (\<Sum> x \<in> s. measure M {SOME y. y \<in> s})" using prob_some by auto
  2132   also have "\<dots> = real (card s) * measure M {(SOME x. x \<in> s)}"
  2133     using sum_constant assms by simp
  2134   finally show ?thesis by simp
  2135 qed simp
  2137 lemma (in finite_measure) measure_real_sum_image_fn:
  2138   assumes "e \<in> sets M"
  2139   assumes "\<And> x. x \<in> s \<Longrightarrow> e \<inter> f x \<in> sets M"
  2140   assumes "finite s"
  2141   assumes disjoint: "\<And> x y. \<lbrakk>x \<in> s ; y \<in> s ; x \<noteq> y\<rbrakk> \<Longrightarrow> f x \<inter> f y = {}"
  2142   assumes upper: "space M \<subseteq> (\<Union>i \<in> s. f i)"
  2143   shows "measure M e = (\<Sum> x \<in> s. measure M (e \<inter> f x))"
  2144 proof -
  2145   have "e \<subseteq> (\<Union>i\<in>s. f i)"
  2146     using \<open>e \<in> sets M\<close> sets.sets_into_space upper by blast
  2147   then have e: "e = (\<Union>i \<in> s. e \<inter> f i)"
  2148     by auto
  2149   hence "measure M e = measure M (\<Union>i \<in> s. e \<inter> f i)" by simp
  2150   also have "\<dots> = (\<Sum> x \<in> s. measure M (e \<inter> f x))"
  2151   proof (rule finite_measure_finite_Union)
  2152     show "finite s" by fact
  2153     show "(\<lambda>i. e \<inter> f i)`s \<subseteq> sets M" using assms(2) by auto
  2154     show "disjoint_family_on (\<lambda>i. e \<inter> f i) s"
  2155       using disjoint by (auto simp: disjoint_family_on_def)
  2156   qed
  2157   finally show ?thesis .
  2158 qed
  2160 lemma (in finite_measure) measure_exclude:
  2161   assumes "A \<in> sets M" "B \<in> sets M"
  2162   assumes "measure M A = measure M (space M)" "A \<inter> B = {}"
  2163   shows "measure M B = 0"
  2164   using measure_space_inter[of B A] assms by (auto simp: ac_simps)
  2165 lemma (in finite_measure) finite_measure_distr:
  2166   assumes f: "f \<in> measurable M M'"
  2167   shows "finite_measure (distr M M' f)"
  2168 proof (rule finite_measureI)
  2169   have "f -` space M' \<inter> space M = space M" using f by (auto dest: measurable_space)
  2170   with f show "emeasure (distr M M' f) (space (distr M M' f)) \<noteq> \<infinity>" by (auto simp: emeasure_distr)
  2171 qed
  2173 lemma emeasure_gfp[consumes 1, case_names cont measurable]:
  2174   assumes sets[simp]: "\<And>s. sets (M s) = sets N"
  2175   assumes "\<And>s. finite_measure (M s)"
  2176   assumes cont: "inf_continuous F" "inf_continuous f"
  2177   assumes meas: "\<And>P. Measurable.pred N P \<Longrightarrow> Measurable.pred N (F P)"
  2178   assumes iter: "\<And>P s. Measurable.pred N P \<Longrightarrow> emeasure (M s) {x\<in>space N. F P x} = f (\<lambda>s. emeasure (M s) {x\<in>space N. P x}) s"
  2179   assumes bound: "\<And>P. f P \<le> f (\<lambda>s. emeasure (M s) (space (M s)))"
  2180   shows "emeasure (M s) {x\<in>space N. gfp F x} = gfp f s"
  2181 proof (subst gfp_transfer_bounded[where \<alpha>="\<lambda>F s. emeasure (M s) {x\<in>space N. F x}" and g=f and f=F and
  2182     P="Measurable.pred N", symmetric])
  2183   interpret finite_measure "M s" for s by fact
  2184   fix C assume "decseq C" "\<And>i. Measurable.pred N (C i)"
  2185   then show "(\<lambda>s. emeasure (M s) {x \<in> space N. (INF i. C i) x}) = (INF i. (\<lambda>s. emeasure (M s) {x \<in> space N. C i x}))"
  2186     unfolding INF_apply[abs_def]
  2187     by (subst INF_emeasure_decseq) (auto simp: antimono_def fun_eq_iff intro!: arg_cong2[where f=emeasure])
  2188 next
  2189   show "f x \<le> (\<lambda>s. emeasure (M s) {x \<in> space N. F top x})" for x
  2190     using bound[of x] sets_eq_imp_space_eq[OF sets] by (simp add: iter)
  2191 qed (auto simp add: iter le_fun_def INF_apply[abs_def] intro!: meas cont)
  2193 subsection \<open>Counting space\<close>
  2195 lemma strict_monoI_Suc:
  2196   assumes ord [simp]: "(\<And>n. f n < f (Suc n))" shows "strict_mono f"
  2197   unfolding strict_mono_def
  2198 proof safe
  2199   fix n m :: nat assume "n < m" then show "f n < f m"
  2200     by (induct m) (auto simp: less_Suc_eq intro: less_trans ord)
  2201 qed
  2203 lemma emeasure_count_space:
  2204   assumes "X \<subseteq> A" shows "emeasure (count_space A) X = (if finite X then of_nat (card X) else \<infinity>)"
  2205     (is "_ = ?M X")
  2206   unfolding count_space_def
  2207 proof (rule emeasure_measure_of_sigma)
  2208   show "X \<in> Pow A" using \<open>X \<subseteq> A\<close> by auto
  2209   show "sigma_algebra A (Pow A)" by (rule sigma_algebra_Pow)
  2210   show positive: "positive (Pow A) ?M"
  2211     by (auto simp: positive_def)
  2212   have additive: "additive (Pow A) ?M"
  2213     by (auto simp: card_Un_disjoint additive_def)
  2215   interpret ring_of_sets A "Pow A"
  2216     by (rule ring_of_setsI) auto
  2217   show "countably_additive (Pow A) ?M"
  2218     unfolding countably_additive_iff_continuous_from_below[OF positive additive]
  2219   proof safe
  2220     fix F :: "nat \<Rightarrow> 'a set" assume "incseq F"
  2221     show "(\<lambda>i. ?M (F i)) \<longlonglongrightarrow> ?M (\<Union>i. F i)"
  2222     proof cases
  2223       assume "\<exists>i. \<forall>j\<ge>i. F i = F j"
  2224       then guess i .. note i = this
  2225       { fix j from i \<open>incseq F\<close> have "F j \<subseteq> F i"
  2226           by (cases "i \<le> j") (auto simp: incseq_def) }
  2227       then have eq: "(\<Union>i. F i) = F i"
  2228         by auto
  2229       with i show ?thesis
  2230         by (auto intro!: Lim_transform_eventually[OF _ tendsto_const] eventually_sequentiallyI[where c=i])
  2231     next
  2232       assume "\<not> (\<exists>i. \<forall>j\<ge>i. F i = F j)"
  2233       then obtain f where f: "\<And>i. i \<le> f i" "\<And>i. F i \<noteq> F (f i)" by metis
  2234       then have "\<And>i. F i \<subseteq> F (f i)" using \<open>incseq F\<close> by (auto simp: incseq_def)
  2235       with f have *: "\<And>i. F i \<subset> F (f i)" by auto
  2237       have "incseq (\<lambda>i. ?M (F i))"
  2238         using \<open>incseq F\<close> unfolding incseq_def by (auto simp: card_mono dest: finite_subset)
  2239       then have "(\<lambda>i. ?M (F i)) \<longlonglongrightarrow> (SUP n. ?M (F n))"
  2240         by (rule LIMSEQ_SUP)
  2242       moreover have "(SUP n. ?M (F n)) = top"
  2243       proof (rule ennreal_SUP_eq_top)
  2244         fix n :: nat show "\<exists>k::nat\<in>UNIV. of_nat n \<le> ?M (F k)"
  2245         proof (induct n)
  2246           case (Suc n)
  2247           then guess k .. note k = this
  2248           moreover have "finite (F k) \<Longrightarrow> finite (F (f k)) \<Longrightarrow> card (F k) < card (F (f k))"
  2249             using \<open>F k \<subset> F (f k)\<close> by (simp add: psubset_card_mono)
  2250           moreover have "finite (F (f k)) \<Longrightarrow> finite (F k)"
  2251             using \<open>k \<le> f k\<close> \<open>incseq F\<close> by (auto simp: incseq_def dest: finite_subset)
  2252           ultimately show ?case
  2253             by (auto intro!: exI[of _ "f k"] simp del: of_nat_Suc)
  2254         qed auto
  2255       qed
  2257       moreover
  2258       have "inj (\<lambda>n. F ((f ^^ n) 0))"
  2259         by (intro strict_mono_imp_inj_on strict_monoI_Suc) (simp add: *)
  2260       then have 1: "infinite (range (\<lambda>i. F ((f ^^ i) 0)))"
  2261         by (rule range_inj_infinite)
  2262       have "infinite (Pow (\<Union>i. F i))"
  2263         by (rule infinite_super[OF _ 1]) auto
  2264       then have "infinite (\<Union>i. F i)"
  2265         by auto
  2267       ultimately show ?thesis by auto
  2268     qed
  2269   qed
  2270 qed
  2272 lemma distr_bij_count_space:
  2273   assumes f: "bij_betw f A B"
  2274   shows "distr (count_space A) (count_space B) f = count_space B"
  2275 proof (rule measure_eqI)
  2276   have f': "f \<in> measurable (count_space A) (count_space B)"
  2277     using f unfolding Pi_def bij_betw_def by auto
  2278   fix X assume "X \<in> sets (distr (count_space A) (count_space B) f)"
  2279   then have X: "X \<in> sets (count_space B)" by auto
  2280   moreover from X have "f -` X \<inter> A = the_inv_into A f ` X"
  2281     using f by (auto simp: bij_betw_def subset_image_iff image_iff the_inv_into_f_f intro: the_inv_into_f_f[symmetric])
  2282   moreover have "inj_on (the_inv_into A f) B"
  2283     using X f by (auto simp: bij_betw_def inj_on_the_inv_into)
  2284   with X have "inj_on (the_inv_into A f) X"
  2285     by (auto intro: subset_inj_on)
  2286   ultimately show "emeasure (distr (count_space A) (count_space B) f) X = emeasure (count_space B) X"
  2287     using f unfolding emeasure_distr[OF f' X]
  2288     by (subst (1 2) emeasure_count_space) (auto simp: card_image dest: finite_imageD)
  2289 qed simp
  2291 lemma emeasure_count_space_finite[simp]:
  2292   "X \<subseteq> A \<Longrightarrow> finite X \<Longrightarrow> emeasure (count_space A) X = of_nat (card X)"
  2293   using emeasure_count_space[of X A] by simp
  2295 lemma emeasure_count_space_infinite[simp]:
  2296   "X \<subseteq> A \<Longrightarrow> infinite X \<Longrightarrow> emeasure (count_space A) X = \<infinity>"
  2297   using emeasure_count_space[of X A] by simp
  2299 lemma measure_count_space: "measure (count_space A) X = (if X \<subseteq> A then of_nat (card X) else 0)"
  2300   by (cases "finite X") (auto simp: measure_notin_sets ennreal_of_nat_eq_real_of_nat
  2301                                     measure_zero_top measure_eq_emeasure_eq_ennreal)
  2303 lemma emeasure_count_space_eq_0:
  2304   "emeasure (count_space A) X = 0 \<longleftrightarrow> (X \<subseteq> A \<longrightarrow> X = {})"
  2305 proof cases
  2306   assume X: "X \<subseteq> A"
  2307   then show ?thesis
  2308   proof (intro iffI impI)
  2309     assume "emeasure (count_space A) X = 0"
  2310     with X show "X = {}"
  2311       by (subst (asm) emeasure_count_space) (auto split: if_split_asm)
  2312   qed simp
  2313 qed (simp add: emeasure_notin_sets)
  2315 lemma null_sets_count_space: "null_sets (count_space A) = { {} }"
  2316   unfolding null_sets_def by (auto simp add: emeasure_count_space_eq_0)
  2318 lemma AE_count_space: "(AE x in count_space A. P x) \<longleftrightarrow> (\<forall>x\<in>A. P x)"
  2319   unfolding eventually_ae_filter by (auto simp add: null_sets_count_space)
  2321 lemma sigma_finite_measure_count_space_countable:
  2322   assumes A: "countable A"
  2323   shows "sigma_finite_measure (count_space A)"
  2324   proof qed (insert A, auto intro!: exI[of _ "(\<lambda>a. {a}) ` A"])
  2326 lemma sigma_finite_measure_count_space:
  2327   fixes A :: "'a::countable set" shows "sigma_finite_measure (count_space A)"
  2328   by (rule sigma_finite_measure_count_space_countable) auto
  2330 lemma finite_measure_count_space:
  2331   assumes [simp]: "finite A"
  2332   shows "finite_measure (count_space A)"
  2333   by rule simp
  2335 lemma sigma_finite_measure_count_space_finite:
  2336   assumes A: "finite A" shows "sigma_finite_measure (count_space A)"
  2337 proof -
  2338   interpret finite_measure "count_space A" using A by (rule finite_measure_count_space)
  2339   show "sigma_finite_measure (count_space A)" ..
  2340 qed
  2342 subsection \<open>Measure restricted to space\<close>
  2344 lemma emeasure_restrict_space:
  2345   assumes "\<Omega> \<inter> space M \<in> sets M" "A \<subseteq> \<Omega>"
  2346   shows "emeasure (restrict_space M \<Omega>) A = emeasure M A"
  2347 proof (cases "A \<in> sets M")
  2348   case True
  2349   show ?thesis
  2350   proof (rule emeasure_measure_of[OF restrict_space_def])
  2351     show "op \<inter> \<Omega> ` sets M \<subseteq> Pow (\<Omega> \<inter> space M)" "A \<in> sets (restrict_space M \<Omega>)"
  2352       using \<open>A \<subseteq> \<Omega>\<close> \<open>A \<in> sets M\<close> sets.space_closed by (auto simp: sets_restrict_space)
  2353     show "positive (sets (restrict_space M \<Omega>)) (emeasure M)"
  2354       by (auto simp: positive_def)
  2355     show "countably_additive (sets (restrict_space M \<Omega>)) (emeasure M)"
  2356     proof (rule countably_additiveI)
  2357       fix A :: "nat \<Rightarrow> _" assume "range A \<subseteq> sets (restrict_space M \<Omega>)" "disjoint_family A"
  2358       with assms have "\<And>i. A i \<in> sets M" "\<And>i. A i \<subseteq> space M" "disjoint_family A"
  2359         by (fastforce simp: sets_restrict_space_iff[OF assms(1)] image_subset_iff
  2360                       dest: sets.sets_into_space)+
  2361       then show "(\<Sum>i. emeasure M (A i)) = emeasure M (\<Union>i. A i)"
  2362         by (subst suminf_emeasure) (auto simp: disjoint_family_subset)
  2363     qed
  2364   qed
  2365 next
  2366   case False
  2367   with assms have "A \<notin> sets (restrict_space M \<Omega>)"
  2368     by (simp add: sets_restrict_space_iff)
  2369   with False show ?thesis
  2370     by (simp add: emeasure_notin_sets)
  2371 qed
  2373 lemma measure_restrict_space:
  2374   assumes "\<Omega> \<inter> space M \<in> sets M" "A \<subseteq> \<Omega>"
  2375   shows "measure (restrict_space M \<Omega>) A = measure M A"
  2376   using emeasure_restrict_space[OF assms] by (simp add: measure_def)
  2378 lemma AE_restrict_space_iff:
  2379   assumes "\<Omega> \<inter> space M \<in> sets M"
  2380   shows "(AE x in restrict_space M \<Omega>. P x) \<longleftrightarrow> (AE x in M. x \<in> \<Omega> \<longrightarrow> P x)"
  2381 proof -
  2382   have ex_cong: "\<And>P Q f. (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> (\<And>x. Q x \<Longrightarrow> P (f x)) \<Longrightarrow> (\<exists>x. P x) \<longleftrightarrow> (\<exists>x. Q x)"
  2383     by auto
  2384   { fix X assume X: "X \<in> sets M" "emeasure M X = 0"
  2385     then have "emeasure M (\<Omega> \<inter> space M \<inter> X) \<le> emeasure M X"
  2386       by (intro emeasure_mono) auto
  2387     then have "emeasure M (\<Omega> \<inter> space M \<inter> X) = 0"
  2388       using X by (auto intro!: antisym) }
  2389   with assms show ?thesis
  2390     unfolding eventually_ae_filter
  2391     by (auto simp add: space_restrict_space null_sets_def sets_restrict_space_iff
  2392                        emeasure_restrict_space cong: conj_cong
  2393              intro!: ex_cong[where f="\<lambda>X. (\<Omega> \<inter> space M) \<inter> X"])
  2394 qed
  2396 lemma restrict_restrict_space:
  2397   assumes "A \<inter> space M \<in> sets M" "B \<inter> space M \<in> sets M"
  2398   shows "restrict_space (restrict_space M A) B = restrict_space M (A \<inter> B)" (is "?l = ?r")
  2399 proof (rule measure_eqI[symmetric])
  2400   show "sets ?r = sets ?l"
  2401     unfolding sets_restrict_space image_comp by (intro image_cong) auto
  2402 next
  2403   fix X assume "X \<in> sets (restrict_space M (A \<inter> B))"
  2404   then obtain Y where "Y \<in> sets M" "X = Y \<inter> A \<inter> B"
  2405     by (auto simp: sets_restrict_space)
  2406   with assms sets.Int[OF assms] show "emeasure ?r X = emeasure ?l X"
  2407     by (subst (1 2) emeasure_restrict_space)
  2408        (auto simp: space_restrict_space sets_restrict_space_iff emeasure_restrict_space ac_simps)
  2409 qed
  2411 lemma restrict_count_space: "restrict_space (count_space B) A = count_space (A \<inter> B)"
  2412 proof (rule measure_eqI)
  2413   show "sets (restrict_space (count_space B) A) = sets (count_space (A \<inter> B))"
  2414     by (subst sets_restrict_space) auto
  2415   moreover fix X assume "X \<in> sets (restrict_space (count_space B) A)"
  2416   ultimately have "X \<subseteq> A \<inter> B" by auto
  2417   then show "emeasure (restrict_space (count_space B) A) X = emeasure (count_space (A \<inter> B)) X"
  2418     by (cases "finite X") (auto simp add: emeasure_restrict_space)
  2419 qed
  2421 lemma sigma_finite_measure_restrict_space:
  2422   assumes "sigma_finite_measure M"
  2423   and A: "A \<in> sets M"
  2424   shows "sigma_finite_measure (restrict_space M A)"
  2425 proof -
  2426   interpret sigma_finite_measure M by fact
  2427   from sigma_finite_countable obtain C
  2428     where C: "countable C" "C \<subseteq> sets M" "(\<Union>C) = space M" "\<forall>a\<in>C. emeasure M a \<noteq> \<infinity>"
  2429     by blast
  2430   let ?C = "op \<inter> A ` C"
  2431   from C have "countable ?C" "?C \<subseteq> sets (restrict_space M A)" "(\<Union>?C) = space (restrict_space M A)"
  2432     by(auto simp add: sets_restrict_space space_restrict_space)
  2433   moreover {
  2434     fix a
  2435     assume "a \<in> ?C"
  2436     then obtain a' where "a = A \<inter> a'" "a' \<in> C" ..
  2437     then have "emeasure (restrict_space M A) a \<le> emeasure M a'"
  2438       using A C by(auto simp add: emeasure_restrict_space intro: emeasure_mono)
  2439     also have "\<dots> < \<infinity>" using C(4)[rule_format, of a'] \<open>a' \<in> C\<close> by (simp add: less_top)
  2440     finally have "emeasure (restrict_space M A) a \<noteq> \<infinity>" by simp }
  2441   ultimately show ?thesis
  2442     by unfold_locales (rule exI conjI|assumption|blast)+
  2443 qed
  2445 lemma finite_measure_restrict_space:
  2446   assumes "finite_measure M"
  2447   and A: "A \<in> sets M"
  2448   shows "finite_measure (restrict_space M A)"
  2449 proof -
  2450   interpret finite_measure M by fact
  2451   show ?thesis
  2452     by(rule finite_measureI)(simp add: emeasure_restrict_space A space_restrict_space)
  2453 qed
  2455 lemma restrict_distr:
  2456   assumes [measurable]: "f \<in> measurable M N"
  2457   assumes [simp]: "\<Omega> \<inter> space N \<in> sets N" and restrict: "f \<in> space M \<rightarrow> \<Omega>"
  2458   shows "restrict_space (distr M N f) \<Omega> = distr M (restrict_space N \<Omega>) f"
  2459   (is "?l = ?r")
  2460 proof (rule measure_eqI)
  2461   fix A assume "A \<in> sets (restrict_space (distr M N f) \<Omega>)"
  2462   with restrict show "emeasure ?l A = emeasure ?r A"
  2463     by (subst emeasure_distr)
  2464        (auto simp: sets_restrict_space_iff emeasure_restrict_space emeasure_distr
  2465              intro!: measurable_restrict_space2)
  2466 qed (simp add: sets_restrict_space)
  2468 lemma measure_eqI_restrict_generator:
  2469   assumes E: "Int_stable E" "E \<subseteq> Pow \<Omega>" "\<And>X. X \<in> E \<Longrightarrow> emeasure M X = emeasure N X"
  2470   assumes sets_eq: "sets M = sets N" and \<Omega>: "\<Omega> \<in> sets M"
  2471   assumes "sets (restrict_space M \<Omega>) = sigma_sets \<Omega> E"
  2472   assumes "sets (restrict_space N \<Omega>) = sigma_sets \<Omega> E"
  2473   assumes ae: "AE x in M. x \<in> \<Omega>" "AE x in N. x \<in> \<Omega>"
  2474   assumes A: "countable A" "A \<noteq> {}" "A \<subseteq> E" "\<Union>A = \<Omega>" "\<And>a. a \<in> A \<Longrightarrow> emeasure M a \<noteq> \<infinity>"
  2475   shows "M = N"
  2476 proof (rule measure_eqI)
  2477   fix X assume X: "X \<in> sets M"
  2478   then have "emeasure M X = emeasure (restrict_space M \<Omega>) (X \<inter> \<Omega>)"
  2479     using ae \<Omega> by (auto simp add: emeasure_restrict_space intro!: emeasure_eq_AE)
  2480   also have "restrict_space M \<Omega> = restrict_space N \<Omega>"
  2481   proof (rule measure_eqI_generator_eq)
  2482     fix X assume "X \<in> E"
  2483     then show "emeasure (restrict_space M \<Omega>) X = emeasure (restrict_space N \<Omega>) X"
  2484       using E \<Omega> by (subst (1 2) emeasure_restrict_space) (auto simp: sets_eq sets_eq[THEN sets_eq_imp_space_eq])
  2485   next
  2486     show "range (from_nat_into A) \<subseteq> E" "(\<Union>i. from_nat_into A i) = \<Omega>"
  2487       using A by (auto cong del: strong_SUP_cong)
  2488   next
  2489     fix i
  2490     have "emeasure (restrict_space M \<Omega>) (from_nat_into A i) = emeasure M (from_nat_into A i)"
  2491       using A \<Omega> by (subst emeasure_restrict_space)
  2492                    (auto simp: sets_eq sets_eq[THEN sets_eq_imp_space_eq] intro: from_nat_into)
  2493     with A show "emeasure (restrict_space M \<Omega>) (from_nat_into A i) \<noteq> \<infinity>"
  2494       by (auto intro: from_nat_into)
  2495   qed fact+
  2496   also have "emeasure (restrict_space N \<Omega>) (X \<inter> \<Omega>) = emeasure N X"
  2497     using X ae \<Omega> by (auto simp add: emeasure_restrict_space sets_eq intro!: emeasure_eq_AE)
  2498   finally show "emeasure M X = emeasure N X" .
  2499 qed fact
  2501 subsection \<open>Null measure\<close>
  2503 definition "null_measure M = sigma (space M) (sets M)"
  2505 lemma space_null_measure[simp]: "space (null_measure M) = space M"
  2506   by (simp add: null_measure_def)
  2508 lemma sets_null_measure[simp, measurable_cong]: "sets (null_measure M) = sets M"
  2509   by (simp add: null_measure_def)
  2511 lemma emeasure_null_measure[simp]: "emeasure (null_measure M) X = 0"
  2512   by (cases "X \<in> sets M", rule emeasure_measure_of)
  2513      (auto simp: positive_def countably_additive_def emeasure_notin_sets null_measure_def
  2514            dest: sets.sets_into_space)
  2516 lemma measure_null_measure[simp]: "measure (null_measure M) X = 0"
  2517   by (intro measure_eq_emeasure_eq_ennreal) auto
  2519 lemma null_measure_idem [simp]: "null_measure (null_measure M) = null_measure M"
  2520   by(rule measure_eqI) simp_all
  2522 subsection \<open>Scaling a measure\<close>
  2524 definition scale_measure :: "ennreal \<Rightarrow> 'a measure \<Rightarrow> 'a measure"
  2525 where
  2526   "scale_measure r M = measure_of (space M) (sets M) (\<lambda>A. r * emeasure M A)"
  2528 lemma space_scale_measure: "space (scale_measure r M) = space M"
  2529   by (simp add: scale_measure_def)
  2531 lemma sets_scale_measure [simp, measurable_cong]: "sets (scale_measure r M) = sets M"
  2532   by (simp add: scale_measure_def)
  2534 lemma emeasure_scale_measure [simp]:
  2535   "emeasure (scale_measure r M) A = r * emeasure M A"
  2536   (is "_ = ?\<mu> A")
  2537 proof(cases "A \<in> sets M")
  2538   case True
  2539   show ?thesis unfolding scale_measure_def
  2540   proof(rule emeasure_measure_of_sigma)
  2541     show "sigma_algebra (space M) (sets M)" ..
  2542     show "positive (sets M) ?\<mu>" by (simp add: positive_def)
  2543     show "countably_additive (sets M) ?\<mu>"
  2544     proof (rule countably_additiveI)
  2545       fix A :: "nat \<Rightarrow> _"  assume *: "range A \<subseteq> sets M" "disjoint_family A"
  2546       have "(\<Sum>i. ?\<mu> (A i)) = r * (\<Sum>i. emeasure M (A i))"
  2547         by simp
  2548       also have "\<dots> = ?\<mu> (\<Union>i. A i)" using * by(simp add: suminf_emeasure)
  2549       finally show "(\<Sum>i. ?\<mu> (A i)) = ?\<mu> (\<Union>i. A i)" .
  2550     qed
  2551   qed(fact True)
  2552 qed(simp add: emeasure_notin_sets)
  2554 lemma scale_measure_1 [simp]: "scale_measure 1 M = M"
  2555   by(rule measure_eqI) simp_all
  2557 lemma scale_measure_0[simp]: "scale_measure 0 M = null_measure M"
  2558   by(rule measure_eqI) simp_all
  2560 lemma measure_scale_measure [simp]: "0 \<le> r \<Longrightarrow> measure (scale_measure r M) A = r * measure M A"
  2561   using emeasure_scale_measure[of r M A]
  2562     emeasure_eq_ennreal_measure[of M A]
  2563     measure_eq_emeasure_eq_ennreal[of _ "scale_measure r M" A]
  2564   by (cases "emeasure (scale_measure r M) A = top")
  2565      (auto simp del: emeasure_scale_measure
  2566            simp: ennreal_top_eq_mult_iff ennreal_mult_eq_top_iff measure_zero_top ennreal_mult[symmetric])
  2568 lemma scale_scale_measure [simp]:
  2569   "scale_measure r (scale_measure r' M) = scale_measure (r * r') M"
  2570   by (rule measure_eqI) (simp_all add: max_def mult.assoc)
  2572 lemma scale_null_measure [simp]: "scale_measure r (null_measure M) = null_measure M"
  2573   by (rule measure_eqI) simp_all
  2576 subsection \<open>Complete lattice structure on measures\<close>
  2578 lemma (in finite_measure) finite_measure_Diff':
  2579   "A \<in> sets M \<Longrightarrow> B \<in> sets M \<Longrightarrow> measure M (A - B) = measure M A - measure M (A \<inter> B)"
  2580   using finite_measure_Diff[of A "A \<inter> B"] by (auto simp: Diff_Int)
  2582 lemma (in finite_measure) finite_measure_Union':
  2583   "A \<in> sets M \<Longrightarrow> B \<in> sets M \<Longrightarrow> measure M (A \<union> B) = measure M A + measure M (B - A)"
  2584   using finite_measure_Union[of A "B - A"] by auto
  2586 lemma finite_unsigned_Hahn_decomposition:
  2587   assumes "finite_measure M" "finite_measure N" and [simp]: "sets N = sets M"
  2588   shows "\<exists>Y\<in>sets M. (\<forall>X\<in>sets M. X \<subseteq> Y \<longrightarrow> N X \<le> M X) \<and> (\<forall>X\<in>sets M. X \<inter> Y = {} \<longrightarrow> M X \<le> N X)"
  2589 proof -
  2590   interpret M: finite_measure M by fact
  2591   interpret N: finite_measure N by fact
  2593   define d where "d X = measure M X - measure N X" for X
  2595   have [intro]: "bdd_above (d`sets M)"
  2596     using sets.sets_into_space[of _ M]
  2597     by (intro bdd_aboveI[where M="measure M (space M)"])
  2598        (auto simp: d_def field_simps subset_eq intro!: add_increasing M.finite_measure_mono)
  2600   define \<gamma> where "\<gamma> = (SUP X:sets M. d X)"
  2601   have le_\<gamma>[intro]: "X \<in> sets M \<Longrightarrow> d X \<le> \<gamma>" for X
  2602     by (auto simp: \<gamma>_def intro!: cSUP_upper)
  2604   have "\<exists>f. \<forall>n. f n \<in> sets M \<and> d (f n) > \<gamma> - 1 / 2^n"
  2605   proof (intro choice_iff[THEN iffD1] allI)
  2606     fix n
  2607     have "\<exists>X\<in>sets M. \<gamma> - 1 / 2^n < d X"
  2608       unfolding \<gamma>_def by (intro less_cSUP_iff[THEN iffD1]) auto
  2609     then show "\<exists>y. y \<in> sets M \<and> \<gamma> - 1 / 2 ^ n < d y"
  2610       by auto
  2611   qed
  2612   then obtain E where [measurable]: "E n \<in> sets M" and E: "d (E n) > \<gamma> - 1 / 2^n" for n
  2613     by auto
  2615   define F where "F m n = (if m \<le> n then \<Inter>i\<in>{m..n}. E i else space M)" for m n
  2617   have [measurable]: "m \<le> n \<Longrightarrow> F m n \<in> sets M" for m n
  2618     by (auto simp: F_def)
  2620   have 1: "\<gamma> - 2 / 2 ^ m + 1 / 2 ^ n \<le> d (F m n)" if "m \<le> n" for m n
  2621     using that
  2622   proof (induct rule: dec_induct)
  2623     case base with E[of m] show ?case
  2624       by (simp add: F_def field_simps)
  2625   next
  2626     case (step i)
  2627     have F_Suc: "F m (Suc i) = F m i \<inter> E (Suc i)"
  2628       using \<open>m \<le> i\<close> by (auto simp: F_def le_Suc_eq)
  2630     have "\<gamma> + (\<gamma> - 2 / 2^m + 1 / 2 ^ Suc i) \<le> (\<gamma> - 1 / 2^Suc i) + (\<gamma> - 2 / 2^m + 1 / 2^i)"
  2631       by (simp add: field_simps)
  2632     also have "\<dots> \<le> d (E (Suc i)) + d (F m i)"
  2633       using E[of "Suc i"] by (intro add_mono step) auto
  2634     also have "\<dots> = d (E (Suc i)) + d (F m i - E (Suc i)) + d (F m (Suc i))"
  2635       using \<open>m \<le> i\<close> by (simp add: d_def field_simps F_Suc M.finite_measure_Diff' N.finite_measure_Diff')
  2636     also have "\<dots> = d (E (Suc i) \<union> F m i) + d (F m (Suc i))"
  2637       using \<open>m \<le> i\<close> by (simp add: d_def field_simps M.finite_measure_Union' N.finite_measure_Union')
  2638     also have "\<dots> \<le> \<gamma> + d (F m (Suc i))"
  2639       using \<open>m \<le> i\<close> by auto
  2640     finally show ?case
  2641       by auto
  2642   qed
  2644   define F' where "F' m = (\<Inter>i\<in>{m..}. E i)" for m
  2645   have F'_eq: "F' m = (\<Inter>i. F m (i + m))" for m
  2646     by (fastforce simp: le_iff_add[of m] F'_def F_def)
  2648   have [measurable]: "F' m \<in> sets M" for m
  2649     by (auto simp: F'_def)
  2651   have \<gamma>_le: "\<gamma> - 0 \<le> d (\<Union>m. F' m)"
  2652   proof (rule LIMSEQ_le)
  2653     show "(\<lambda>n. \<gamma> - 2 / 2 ^ n) \<longlonglongrightarrow> \<gamma> - 0"
  2654       by (intro tendsto_intros LIMSEQ_divide_realpow_zero) auto
  2655     have "incseq F'"
  2656       by (auto simp: incseq_def F'_def)
  2657     then show "(\<lambda>m. d (F' m)) \<longlonglongrightarrow> d (\<Union>m. F' m)"
  2658       unfolding d_def
  2659       by (intro tendsto_diff M.finite_Lim_measure_incseq N.finite_Lim_measure_incseq) auto
  2661     have "\<gamma> - 2 / 2 ^ m + 0 \<le> d (F' m)" for m
  2662     proof (rule LIMSEQ_le)
  2663       have *: "decseq (\<lambda>n. F m (n + m))"
  2664         by (auto simp: decseq_def F_def)
  2665       show "(\<lambda>n. d (F m n)) \<longlonglongrightarrow> d (F' m)"
  2666         unfolding d_def F'_eq
  2667         by (rule LIMSEQ_offset[where k=m])
  2668            (auto intro!: tendsto_diff M.finite_Lim_measure_decseq N.finite_Lim_measure_decseq *)
  2669       show "(\<lambda>n. \<gamma> - 2 / 2 ^ m + 1 / 2 ^ n) \<longlonglongrightarrow> \<gamma> - 2 / 2 ^ m + 0"
  2670         by (intro tendsto_add LIMSEQ_divide_realpow_zero tendsto_const) auto
  2671       show "\<exists>N. \<forall>n\<ge>N. \<gamma> - 2 / 2 ^ m + 1 / 2 ^ n \<le> d (F m n)"
  2672         using 1[of m] by (intro exI[of _ m]) auto
  2673     qed
  2674     then show "\<exists>N. \<forall>n\<ge>N. \<gamma> - 2 / 2 ^ n \<le> d (F' n)"
  2675       by auto
  2676   qed
  2678   show ?thesis
  2679   proof (safe intro!: bexI[of _ "\<Union>m. F' m"])
  2680     fix X assume [measurable]: "X \<in> sets M" and X: "X \<subseteq> (\<Union>m. F' m)"
  2681     have "d (\<Union>m. F' m) - d X = d ((\<Union>m. F' m) - X)"
  2682       using X by (auto simp: d_def M.finite_measure_Diff N.finite_measure_Diff)
  2683     also have "\<dots> \<le> \<gamma>"
  2684       by auto
  2685     finally have "0 \<le> d X"
  2686       using \<gamma>_le by auto
  2687     then show "emeasure N X \<le> emeasure M X"
  2688       by (auto simp: d_def M.emeasure_eq_measure N.emeasure_eq_measure)
  2689   next
  2690     fix X assume [measurable]: "X \<in> sets M" and X: "X \<inter> (\<Union>m. F' m) = {}"
  2691     then have "d (\<Union>m. F' m) + d X = d (X \<union> (\<Union>m. F' m))"
  2692       by (auto simp: d_def M.finite_measure_Union N.finite_measure_Union)
  2693     also have "\<dots> \<le> \<gamma>"
  2694       by auto
  2695     finally have "d X \<le> 0"
  2696       using \<gamma>_le by auto
  2697     then show "emeasure M X \<le> emeasure N X"
  2698       by (auto simp: d_def M.emeasure_eq_measure N.emeasure_eq_measure)
  2699   qed auto
  2700 qed
  2702 lemma unsigned_Hahn_decomposition:
  2703   assumes [simp]: "sets N = sets M" and [measurable]: "A \<in> sets M"
  2704     and [simp]: "emeasure M A \<noteq> top" "emeasure N A \<noteq> top"
  2705   shows "\<exists>Y\<in>sets M. Y \<subseteq> A \<and> (\<forall>X\<in>sets M. X \<subseteq> Y \<longrightarrow> N X \<le> M X) \<and> (\<forall>X\<in>sets M. X \<subseteq> A \<longrightarrow> X \<inter> Y = {} \<longrightarrow> M X \<le> N X)"
  2706 proof -
  2707   have "\<exists>Y\<in>sets (restrict_space M A).
  2708     (\<forall>X\<in>sets (restrict_space M A). X \<subseteq> Y \<longrightarrow> (restrict_space N A) X \<le> (restrict_space M A) X) \<and>
  2709     (\<forall>X\<in>sets (restrict_space M A). X \<inter> Y = {} \<longrightarrow> (restrict_space M A) X \<le> (restrict_space N A) X)"
  2710   proof (rule finite_unsigned_Hahn_decomposition)
  2711     show "finite_measure (restrict_space M A)" "finite_measure (restrict_space N A)"
  2712       by (auto simp: space_restrict_space emeasure_restrict_space less_top intro!: finite_measureI)
  2713   qed (simp add: sets_restrict_space)
  2714   then guess Y ..
  2715   then show ?thesis
  2716     apply (intro bexI[of _ Y] conjI ballI conjI)
  2717     apply (simp_all add: sets_restrict_space emeasure_restrict_space)
  2718     apply safe
  2719     subgoal for X Z
  2720       by (erule ballE[of _ _ X]) (auto simp add: Int_absorb1)
  2721     subgoal for X Z
  2722       by (erule ballE[of _ _ X])  (auto simp add: Int_absorb1 ac_simps)
  2723     apply auto
  2724     done
  2725 qed
  2727 text \<open>
  2728   Define a lexicographical order on @{type measure}, in the order space, sets and measure. The parts
  2729   of the lexicographical order are point-wise ordered.
  2730 \<close>
  2732 instantiation measure :: (type) order_bot
  2733 begin
  2735 inductive less_eq_measure :: "'a measure \<Rightarrow> 'a measure \<Rightarrow> bool" where
  2736   "space M \<subset> space N \<Longrightarrow> less_eq_measure M N"
  2737 | "space M = space N \<Longrightarrow> sets M \<subset> sets N \<Longrightarrow> less_eq_measure M N"
  2738 | "space M = space N \<Longrightarrow> sets M = sets N \<Longrightarrow> emeasure M \<le> emeasure N \<Longrightarrow> less_eq_measure M N"
  2740 lemma le_measure_iff:
  2741   "M \<le> N \<longleftrightarrow> (if space M = space N then
  2742     if sets M = sets N then emeasure M \<le> emeasure N else sets M \<subseteq> sets N else space M \<subseteq> space N)"
  2743   by (auto elim: less_eq_measure.cases intro: less_eq_measure.intros)
  2745 definition less_measure :: "'a measure \<Rightarrow> 'a measure \<Rightarrow> bool" where
  2746   "less_measure M N \<longleftrightarrow> (M \<le> N \<and> \<not> N \<le> M)"
  2748 definition bot_measure :: "'a measure" where
  2749   "bot_measure = sigma {} {}"
  2751 lemma
  2752   shows space_bot[simp]: "space bot = {}"
  2753     and sets_bot[simp]: "sets bot = {{}}"
  2754     and emeasure_bot[simp]: "emeasure bot X = 0"
  2755   by (auto simp: bot_measure_def sigma_sets_empty_eq emeasure_sigma)
  2757 instance
  2758 proof standard
  2759   show "bot \<le> a" for a :: "'a measure"
  2760     by (simp add: le_measure_iff bot_measure_def sigma_sets_empty_eq emeasure_sigma le_fun_def)
  2761 qed (auto simp: le_measure_iff less_measure_def split: if_split_asm intro: measure_eqI)
  2763 end
  2765 lemma le_measure: "sets M = sets N \<Longrightarrow> M \<le> N \<longleftrightarrow> (\<forall>A\<in>sets M. emeasure M A \<le> emeasure N A)"
  2766   apply (auto simp: le_measure_iff le_fun_def dest: sets_eq_imp_space_eq)
  2767   subgoal for X
  2768     by (cases "X \<in> sets M") (auto simp: emeasure_notin_sets)
  2769   done
  2771 definition sup_measure' :: "'a measure \<Rightarrow> 'a measure \<Rightarrow> 'a measure"
  2772 where
  2773   "sup_measure' A B = measure_of (space A) (sets A) (\<lambda>X. SUP Y:sets A. emeasure A (X \<inter> Y) + emeasure B (X \<inter> - Y))"
  2775 lemma assumes [simp]: "sets B = sets A"
  2776   shows space_sup_measure'[simp]: "space (sup_measure' A B) = space A"
  2777     and sets_sup_measure'[simp]: "sets (sup_measure' A B) = sets A"
  2778   using sets_eq_imp_space_eq[OF assms] by (simp_all add: sup_measure'_def)
  2780 lemma emeasure_sup_measure':
  2781   assumes sets_eq[simp]: "sets B = sets A" and [simp, intro]: "X \<in> sets A"
  2782   shows "emeasure (sup_measure' A B) X = (SUP Y:sets A. emeasure A (X \<inter> Y) + emeasure B (X \<inter> - Y))"
  2783     (is "_ = ?S X")
  2784 proof -
  2785   note sets_eq_imp_space_eq[OF sets_eq, simp]
  2786   show ?thesis
  2787     using sup_measure'_def
  2788   proof (rule emeasure_measure_of)
  2789     let ?d = "\<lambda>X Y. emeasure A (X \<inter> Y) + emeasure B (X \<inter> - Y)"
  2790     show "countably_additive (sets (sup_measure' A B)) (\<lambda>X. SUP Y : sets A. emeasure A (X \<inter> Y) + emeasure B (X \<inter> - Y))"
  2791     proof (rule countably_additiveI, goal_cases)
  2792       case (1 X)
  2793       then have [measurable]: "\<And>i. X i \<in> sets A" and "disjoint_family X"
  2794         by auto
  2795       have "(\<Sum>i. ?S (X i)) = (SUP Y:sets A. \<Sum>i. ?d (X i) Y)"
  2796       proof (rule ennreal_suminf_SUP_eq_directed)
  2797         fix J :: "nat set" and a b assume "finite J" and [measurable]: "a \<in> sets A" "b \<in> sets A"
  2798         have "\<exists>c\<in>sets A. c \<subseteq> X i \<and> (\<forall>a\<in>sets A. ?d (X i) a \<le> ?d (X i) c)" for i
  2799         proof cases
  2800           assume "emeasure A (X i) = top \<or> emeasure B (X i) = top"
  2801           then show ?thesis
  2802           proof
  2803             assume "emeasure A (X i) = top" then show ?thesis
  2804               by (intro bexI[of _ "X i"]) auto
  2805           next
  2806             assume "emeasure B (X i) = top" then show ?thesis
  2807               by (intro bexI[of _ "{}"]) auto
  2808           qed
  2809         next
  2810           assume finite: "\<not> (emeasure A (X i) = top \<or> emeasure B (X i) = top)"
  2811           then have "\<exists>Y\<in>sets A. Y \<subseteq> X i \<and> (\<forall>C\<in>sets A. C \<subseteq> Y \<longrightarrow> B C \<le> A C) \<and> (\<forall>C\<in>sets A. C \<subseteq> X i \<longrightarrow> C \<inter> Y = {} \<longrightarrow> A C \<le> B C)"
  2812             using unsigned_Hahn_decomposition[of B A "X i"] by simp
  2813           then obtain Y where [measurable]: "Y \<in> sets A" and [simp]: "Y \<subseteq> X i"
  2814             and B_le_A: "\<And>C. C \<in> sets A \<Longrightarrow> C \<subseteq> Y \<Longrightarrow> B C \<le> A C"
  2815             and A_le_B: "\<And>C. C \<in> sets A \<Longrightarrow> C \<subseteq> X i \<Longrightarrow> C \<inter> Y = {} \<Longrightarrow> A C \<le> B C"
  2816             by auto
  2818           show ?thesis
  2819           proof (intro bexI[of _ Y] ballI conjI)
  2820             fix a assume [measurable]: "a \<in> sets A"
  2821             have *: "(X i \<inter> a \<inter> Y \<union> (X i \<inter> a - Y)) = X i \<inter> a" "(X i - a) \<inter> Y \<union> (X i - a - Y) = X i \<inter> - a"
  2822               for a Y by auto
  2823             then have "?d (X i) a =
  2824               (A (X i \<inter> a \<inter> Y) + A (X i \<inter> a \<inter> - Y)) + (B (X i \<inter> - a \<inter> Y) + B (X i \<inter> - a \<inter> - Y))"
  2825               by (subst (1 2) plus_emeasure) (auto simp: Diff_eq[symmetric])
  2826             also have "\<dots> \<le> (A (X i \<inter> a \<inter> Y) + B (X i \<inter> a \<inter> - Y)) + (A (X i \<inter> - a \<inter> Y) + B (X i \<inter> - a \<inter> - Y))"
  2827               by (intro add_mono order_refl B_le_A A_le_B) (auto simp: Diff_eq[symmetric])
  2828             also have "\<dots> \<le> (A (X i \<inter> Y \<inter> a) + A (X i \<inter> Y \<inter> - a)) + (B (X i \<inter> - Y \<inter> a) + B (X i \<inter> - Y \<inter> - a))"
  2829               by (simp add: ac_simps)
  2830             also have "\<dots> \<le> A (X i \<inter> Y) + B (X i \<inter> - Y)"
  2831               by (subst (1 2) plus_emeasure) (auto simp: Diff_eq[symmetric] *)
  2832             finally show "?d (X i) a \<le> ?d (X i) Y" .
  2833           qed auto
  2834         qed
  2835         then obtain C where [measurable]: "C i \<in> sets A" and "C i \<subseteq> X i"
  2836           and C: "\<And>a. a \<in> sets A \<Longrightarrow> ?d (X i) a \<le> ?d (X i) (C i)" for i
  2837           by metis
  2838         have *: "X i \<inter> (\<Union>i. C i) = X i \<inter> C i" for i
  2839         proof safe
  2840           fix x j assume "x \<in> X i" "x \<in> C j"
  2841           moreover have "i = j \<or> X i \<inter> X j = {}"
  2842             using \<open>disjoint_family X\<close> by (auto simp: disjoint_family_on_def)
  2843           ultimately show "x \<in> C i"
  2844             using \<open>C i \<subseteq> X i\<close> \<open>C j \<subseteq> X j\<close> by auto
  2845         qed auto
  2846         have **: "X i \<inter> - (\<Union>i. C i) = X i \<inter> - C i" for i
  2847         proof safe
  2848           fix x j assume "x \<in> X i" "x \<notin> C i" "x \<in> C j"
  2849           moreover have "i = j \<or> X i \<inter> X j = {}"
  2850             using \<open>disjoint_family X\<close> by (auto simp: disjoint_family_on_def)
  2851           ultimately show False
  2852             using \<open>C i \<subseteq> X i\<close> \<open>C j \<subseteq> X j\<close> by auto
  2853         qed auto
  2854         show "\<exists>c\<in>sets A. \<forall>i\<in>J. ?d (X i) a \<le> ?d (X i) c \<and> ?d (X i) b \<le> ?d (X i) c"
  2855           apply (intro bexI[of _ "\<Union>i. C i"])
  2856           unfolding * **
  2857           apply (intro C ballI conjI)
  2858           apply auto
  2859           done
  2860       qed
  2861       also have "\<dots> = ?S (\<Union>i. X i)"
  2862         unfolding UN_extend_simps(4)
  2863         by (auto simp add: suminf_add[symmetric] Diff_eq[symmetric] simp del: UN_simps
  2864                  intro!: SUP_cong arg_cong2[where f="op +"] suminf_emeasure
  2865                          disjoint_family_on_bisimulation[OF \<open>disjoint_family X\<close>])
  2866       finally show "(\<Sum>i. ?S (X i)) = ?S (\<Union>i. X i)" .
  2867     qed
  2868   qed (auto dest: sets.sets_into_space simp: positive_def intro!: SUP_const)
  2869 qed
  2871 lemma le_emeasure_sup_measure'1:
  2872   assumes "sets B = sets A" "X \<in> sets A" shows "emeasure A X \<le> emeasure (sup_measure' A B) X"
  2873   by (subst emeasure_sup_measure'[OF assms]) (auto intro!: SUP_upper2[of "X"] assms)
  2875 lemma le_emeasure_sup_measure'2:
  2876   assumes "sets B = sets A" "X \<in> sets A" shows "emeasure B X \<le> emeasure (sup_measure' A B) X"
  2877   by (subst emeasure_sup_measure'[OF assms]) (auto intro!: SUP_upper2[of "{}"] assms)
  2879 lemma emeasure_sup_measure'_le2:
  2880   assumes [simp]: "sets B = sets C" "sets A = sets C" and [measurable]: "X \<in> sets C"
  2881   assumes A: "\<And>Y. Y \<subseteq> X \<Longrightarrow> Y \<in> sets A \<Longrightarrow> emeasure A Y \<le> emeasure C Y"
  2882   assumes B: "\<And>Y. Y \<subseteq> X \<Longrightarrow> Y \<in> sets A \<Longrightarrow> emeasure B Y \<le> emeasure C Y"
  2883   shows "emeasure (sup_measure' A B) X \<le> emeasure C X"
  2884 proof (subst emeasure_sup_measure')
  2885   show "(SUP Y:sets A. emeasure A (X \<inter> Y) + emeasure B (X \<inter> - Y)) \<le> emeasure C X"
  2886     unfolding \<open>sets A = sets C\<close>
  2887   proof (intro SUP_least)
  2888     fix Y assume [measurable]: "Y \<in> sets C"
  2889     have [simp]: "X \<inter> Y \<union> (X - Y) = X"
  2890       by auto
  2891     have "emeasure A (X \<inter> Y) + emeasure B (X \<inter> - Y) \<le> emeasure C (X \<inter> Y) + emeasure C (X \<inter> - Y)"
  2892       by (intro add_mono A B) (auto simp: Diff_eq[symmetric])
  2893     also have "\<dots> = emeasure C X"
  2894       by (subst plus_emeasure) (auto simp: Diff_eq[symmetric])
  2895     finally show "emeasure A (X \<inter> Y) + emeasure B (X \<inter> - Y) \<le> emeasure C X" .
  2896   qed
  2897 qed simp_all
  2899 definition sup_lexord :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b::order) \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'a"
  2900 where
  2901   "sup_lexord A B k s c =
  2902     (if k A = k B then c else if \<not> k A \<le> k B \<and> \<not> k B \<le> k A then s else if k B \<le> k A then A else B)"
  2904 lemma sup_lexord:
  2905   "(k A < k B \<Longrightarrow> P B) \<Longrightarrow> (k B < k A \<Longrightarrow> P A) \<Longrightarrow> (k A = k B \<Longrightarrow> P c) \<Longrightarrow>
  2906     (\<not> k B \<le> k A \<Longrightarrow> \<not> k A \<le> k B \<Longrightarrow> P s) \<Longrightarrow> P (sup_lexord A B k s c)"
  2907   by (auto simp: sup_lexord_def)
  2909 lemmas le_sup_lexord = sup_lexord[where P="\<lambda>a. c \<le> a" for c]
  2911 lemma sup_lexord1: "k A = k B \<Longrightarrow> sup_lexord A B k s c = c"
  2912   by (simp add: sup_lexord_def)
  2914 lemma sup_lexord_commute: "sup_lexord A B k s c = sup_lexord B A k s c"
  2915   by (auto simp: sup_lexord_def)
  2917 lemma sigma_sets_le_sets_iff: "(sigma_sets (space x) \<A> \<subseteq> sets x) = (\<A> \<subseteq> sets x)"
  2918   using sets.sigma_sets_subset[of \<A> x] by auto
  2920 lemma sigma_le_iff: "\<A> \<subseteq> Pow \<Omega> \<Longrightarrow> sigma \<Omega> \<A> \<le> x \<longleftrightarrow> (\<Omega> \<subseteq> space x \<and> (space x = \<Omega> \<longrightarrow> \<A> \<subseteq> sets x))"
  2921   by (cases "\<Omega> = space x")
  2922      (simp_all add: eq_commute[of _ "sets x"] le_measure_iff emeasure_sigma le_fun_def
  2923                     sigma_sets_superset_generator sigma_sets_le_sets_iff)
  2925 instantiation measure :: (type) semilattice_sup
  2926 begin
  2928 definition sup_measure :: "'a measure \<Rightarrow> 'a measure \<Rightarrow> 'a measure"
  2929 where
  2930   "sup_measure A B =
  2931     sup_lexord A B space (sigma (space A \<union> space B) {})
  2932       (sup_lexord A B sets (sigma (space A) (sets A \<union> sets B)) (sup_measure' A B))"
  2934 instance
  2935 proof
  2936   fix x y z :: "'a measure"
  2937   show "x \<le> sup x y"
  2938     unfolding sup_measure_def
  2939   proof (intro le_sup_lexord)
  2940     assume "space x = space y"
  2941     then have *: "sets x \<union> sets y \<subseteq> Pow (space x)"
  2942       using sets.space_closed by auto
  2943     assume "\<not> sets y \<subseteq> sets x" "\<not> sets x \<subseteq> sets y"
  2944     then have "sets x \<subset> sets x \<union> sets y"
  2945       by auto
  2946     also have "\<dots> \<le> sigma (space x) (sets x \<union> sets y)"
  2947       by (subst sets_measure_of[OF *]) (rule sigma_sets_superset_generator)
  2948     finally show "x \<le> sigma (space x) (sets x \<union> sets y)"
  2949       by (simp add: space_measure_of[OF *] less_eq_measure.intros(2))
  2950   next
  2951     assume "\<not> space y \<subseteq> space x" "\<not> space x \<subseteq> space y"
  2952     then show "x \<le> sigma (space x \<union> space y) {}"
  2953       by (intro less_eq_measure.intros) auto
  2954   next
  2955     assume "sets x = sets y" then show "x \<le> sup_measure' x y"
  2956       by (simp add: le_measure le_emeasure_sup_measure'1)
  2957   qed (auto intro: less_eq_measure.intros)
  2958   show "y \<le> sup x y"
  2959     unfolding sup_measure_def
  2960   proof (intro le_sup_lexord)
  2961     assume **: "space x = space y"
  2962     then have *: "sets x \<union> sets y \<subseteq> Pow (space y)"
  2963       using sets.space_closed by auto
  2964     assume "\<not> sets y \<subseteq> sets x" "\<not> sets x \<subseteq> sets y"
  2965     then have "sets y \<subset> sets x \<union> sets y"
  2966       by auto
  2967     also have "\<dots> \<le> sigma (space y) (sets x \<union> sets y)"
  2968       by (subst sets_measure_of[OF *]) (rule sigma_sets_superset_generator)
  2969     finally show "y \<le> sigma (space x) (sets x \<union> sets y)"
  2970       by (simp add: ** space_measure_of[OF *] less_eq_measure.intros(2))
  2971   next
  2972     assume "\<not> space y \<subseteq> space x" "\<not> space x \<subseteq> space y"
  2973     then show "y \<le> sigma (space x \<union> space y) {}"
  2974       by (intro less_eq_measure.intros) auto
  2975   next
  2976     assume "sets x = sets y" then show "y \<le> sup_measure' x y"
  2977       by (simp add: le_measure le_emeasure_sup_measure'2)
  2978   qed (auto intro: less_eq_measure.intros)
  2979   show "x \<le> y \<Longrightarrow> z \<le> y \<Longrightarrow> sup x z \<le> y"
  2980     unfolding sup_measure_def
  2981   proof (intro sup_lexord[where P="\<lambda>x. x \<le> y"])
  2982     assume "x \<le> y" "z \<le> y" and [simp]: "space x = space z" "sets x = sets z"
  2983     from \<open>x \<le> y\<close> show "sup_measure' x z \<le> y"
  2984     proof cases
  2985       case 1 then show ?thesis
  2986         by (intro less_eq_measure.intros(1)) simp
  2987     next
  2988       case 2 then show ?thesis
  2989         by (intro less_eq_measure.intros(2)) simp_all
  2990     next
  2991       case 3 with \<open>z \<le> y\<close> \<open>x \<le> y\<close> show ?thesis
  2992         by (auto simp add: le_measure intro!: emeasure_sup_measure'_le2)
  2993     qed
  2994   next
  2995     assume **: "x \<le> y" "z \<le> y" "space x = space z" "\<not> sets z \<subseteq> sets x" "\<not> sets x \<subseteq> sets z"
  2996     then have *: "sets x \<union> sets z \<subseteq> Pow (space x)"
  2997       using sets.space_closed by auto
  2998     show "sigma (space x) (sets x \<union> sets z) \<le> y"
  2999       unfolding sigma_le_iff[OF *] using ** by (auto simp: le_measure_iff split: if_split_asm)
  3000   next
  3001     assume "x \<le> y" "z \<le> y" "\<not> space z \<subseteq> space x" "\<not> space x \<subseteq> space z"
  3002     then have "space x \<subseteq> space y" "space z \<subseteq> space y"
  3003       by (auto simp: le_measure_iff split: if_split_asm)
  3004     then show "sigma (space x \<union> space z) {} \<le> y"
  3005       by (simp add: sigma_le_iff)
  3006   qed
  3007 qed
  3009 end
  3011 lemma space_empty_eq_bot: "space a = {} \<longleftrightarrow> a = bot"
  3012   using space_empty[of a] by (auto intro!: measure_eqI)
  3014 lemma sets_eq_iff_bounded: "A \<le> B \<Longrightarrow> B \<le> C \<Longrightarrow> sets A = sets C \<Longrightarrow> sets B = sets A"
  3015   by (auto dest: sets_eq_imp_space_eq simp add: le_measure_iff split: if_split_asm)
  3017 lemma sets_sup: "sets A = sets M \<Longrightarrow> sets B = sets M \<Longrightarrow> sets (sup A B) = sets M"
  3018   by (auto simp add: sup_measure_def sup_lexord_def dest: sets_eq_imp_space_eq)
  3020 lemma le_measureD1: "A \<le> B \<Longrightarrow> space A \<le> space B"
  3021   by (auto simp: le_measure_iff split: if_split_asm)
  3023 lemma le_measureD2: "A \<le> B \<Longrightarrow> space A = space B \<Longrightarrow> sets A \<le> sets B"
  3024   by (auto simp: le_measure_iff split: if_split_asm)
  3026 lemma le_measureD3: "A \<le> B \<Longrightarrow> sets A = sets B \<Longrightarrow> emeasure A X \<le> emeasure B X"
  3027   by (auto simp: le_measure_iff le_fun_def dest: sets_eq_imp_space_eq split: if_split_asm)
  3029 lemma UN_space_closed: "UNION S sets \<subseteq> Pow (UNION S space)"
  3030   using sets.space_closed by auto
  3032 definition Sup_lexord :: "('a \<Rightarrow> 'b::complete_lattice) \<Rightarrow> ('a set \<Rightarrow> 'a) \<Rightarrow> ('a set \<Rightarrow> 'a) \<Rightarrow> 'a set \<Rightarrow> 'a"
  3033 where
  3034   "Sup_lexord k c s A = (let U = (SUP a:A. k a) in if \<exists>a\<in>A. k a = U then c {a\<in>A. k a = U} else s A)"
  3036 lemma Sup_lexord:
  3037   "(\<And>a S. a \<in> A \<Longrightarrow> k a = (SUP a:A. k a) \<Longrightarrow> S = {a'\<in>A. k a' = k a} \<Longrightarrow> P (c S)) \<Longrightarrow> ((\<And>a. a \<in> A \<Longrightarrow> k a \<noteq> (SUP a:A. k a)) \<Longrightarrow> P (s A)) \<Longrightarrow>
  3038     P (Sup_lexord k c s A)"
  3039   by (auto simp: Sup_lexord_def Let_def)
  3041 lemma Sup_lexord1:
  3042   assumes A: "A \<noteq> {}" "(\<And>a. a \<in> A \<Longrightarrow> k a = (\<Union>a\<in>A. k a))" "P (c A)"
  3043   shows "P (Sup_lexord k c s A)"
  3044   unfolding Sup_lexord_def Let_def
  3045 proof (clarsimp, safe)
  3046   show "\<forall>a\<in>A. k a \<noteq> (\<Union>x\<in>A. k x) \<Longrightarrow> P (s A)"
  3047     by (metis assms(1,2) ex_in_conv)
  3048 next
  3049   fix a assume "a \<in> A" "k a = (\<Union>x\<in>A. k x)"
  3050   then have "{a \<in> A. k a = (\<Union>x\<in>A. k x)} = {a \<in> A. k a = k a}"
  3051     by (metis A(2)[symmetric])
  3052   then show "P (c {a \<in> A. k a = (\<Union>x\<in>A. k x)})"
  3053     by (simp add: A(3))
  3054 qed
  3056 instantiation measure :: (type) complete_lattice
  3057 begin
  3059 interpretation sup_measure: comm_monoid_set sup "bot :: 'a measure"
  3060   by standard (auto intro!: antisym)
  3062 lemma sup_measure_F_mono':
  3063   "finite J \<Longrightarrow> finite I \<Longrightarrow> sup_measure.F id I \<le> sup_measure.F id (I \<union> J)"
  3064 proof (induction J rule: finite_induct)
  3065   case empty then show ?case
  3066     by simp
  3067 next
  3068   case (insert i J)
  3069   show ?case
  3070   proof cases
  3071     assume "i \<in> I" with insert show ?thesis
  3072       by (auto simp: insert_absorb)
  3073   next
  3074     assume "i \<notin> I"
  3075     have "sup_measure.F id I \<le> sup_measure.F id (I \<union> J)"
  3076       by (intro insert)
  3077     also have "\<dots> \<le> sup_measure.F id (insert i (I \<union> J))"
  3078       using insert \<open>i \<notin> I\<close> by (subst sup_measure.insert) auto
  3079     finally show ?thesis
  3080       by auto
  3081   qed
  3082 qed
  3084 lemma sup_measure_F_mono: "finite I \<Longrightarrow> J \<subseteq> I \<Longrightarrow> sup_measure.F id J \<le> sup_measure.F id I"
  3085   using sup_measure_F_mono'[of I J] by (auto simp: finite_subset Un_absorb1)
  3087 lemma sets_sup_measure_F:
  3088   "finite I \<Longrightarrow> I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> sets i = sets M) \<Longrightarrow> sets (sup_measure.F id I) = sets M"
  3089   by (induction I rule: finite_ne_induct) (simp_all add: sets_sup)
  3091 definition Sup_measure' :: "'a measure set \<Rightarrow> 'a measure"
  3092 where
  3093   "Sup_measure' M = measure_of (\<Union>a\<in>M. space a) (\<Union>a\<in>M. sets a)
  3094     (\<lambda>X. (SUP P:{P. finite P \<and> P \<subseteq> M }. sup_measure.F id P X))"
  3096 lemma space_Sup_measure'2: "space (Sup_measure' M) = (\<Union>m\<in>M. space m)"
  3097   unfolding Sup_measure'_def by (intro space_measure_of[OF UN_space_closed])
  3099 lemma sets_Sup_measure'2: "sets (Sup_measure' M) = sigma_sets (\<Union>m\<in>M. space m) (\<Union>m\<in>M. sets m)"
  3100   unfolding Sup_measure'_def by (intro sets_measure_of[OF UN_space_closed])
  3102 lemma sets_Sup_measure':
  3103   assumes sets_eq[simp]: "\<And>m. m \<in> M \<Longrightarrow> sets m = sets A" and "M \<noteq> {}"
  3104   shows "sets (Sup_measure' M) = sets A"
  3105   using sets_eq[THEN sets_eq_imp_space_eq, simp] \<open>M \<noteq> {}\<close> by (simp add: Sup_measure'_def)
  3107 lemma space_Sup_measure':
  3108   assumes sets_eq[simp]: "\<And>m. m \<in> M \<Longrightarrow> sets m = sets A" and "M \<noteq> {}"
  3109   shows "space (Sup_measure' M) = space A"
  3110   using sets_eq[THEN sets_eq_imp_space_eq, simp] \<open>M \<noteq> {}\<close>
  3111   by (simp add: Sup_measure'_def )
  3113 lemma emeasure_Sup_measure':
  3114   assumes sets_eq[simp]: "\<And>m. m \<in> M \<Longrightarrow> sets m = sets A" and "X \<in> sets A" "M \<noteq> {}"
  3115   shows "emeasure (Sup_measure' M) X = (SUP P:{P. finite P \<and> P \<subseteq> M}. sup_measure.F id P X)"
  3116     (is "_ = ?S X")
  3117   using Sup_measure'_def
  3118 proof (rule emeasure_measure_of)
  3119   note sets_eq[THEN sets_eq_imp_space_eq, simp]
  3120   have *: "sets (Sup_measure' M) = sets A" "space (Sup_measure' M) = space A"
  3121     using \<open>M \<noteq> {}\<close> by (simp_all add: Sup_measure'_def)
  3122   let ?\<mu> = "sup_measure.F id"
  3123   show "countably_additive (sets (Sup_measure' M)) ?S"
  3124   proof (rule countably_additiveI, goal_cases)
  3125     case (1 F)
  3126     then have **: "range F \<subseteq> sets A"
  3127       by (auto simp: *)
  3128     show "(\<Sum>i. ?S (F i)) = ?S (\<Union>i. F i)"
  3129     proof (subst ennreal_suminf_SUP_eq_directed)
  3130       fix i j and N :: "nat set" assume ij: "i \<in> {P. finite P \<and> P \<subseteq> M}" "j \<in> {P. finite P \<and> P \<subseteq> M}"
  3131       have "(i \<noteq> {} \<longrightarrow> sets (?\<mu> i) = sets A) \<and> (j \<noteq> {} \<longrightarrow> sets (?\<mu> j) = sets A) \<and>
  3132         (i \<noteq> {} \<or> j \<noteq> {} \<longrightarrow> sets (?\<mu> (i \<union> j)) = sets A)"
  3133         using ij by (intro impI sets_sup_measure_F conjI) auto
  3134       then have "?\<mu> j (F n) \<le> ?\<mu> (i \<union> j) (F n) \<and> ?\<mu> i (F n) \<le> ?\<mu> (i \<union> j) (F n)" for n
  3135         using ij
  3136         by (cases "i = {}"; cases "j = {}")
  3137            (auto intro!: le_measureD3 sup_measure_F_mono simp: sets_sup_measure_F
  3138                  simp del: id_apply)
  3139       with ij show "\<exists>k\<in>{P. finite P \<and> P \<subseteq> M}. \<forall>n\<in>N. ?\<mu> i (F n) \<le> ?\<mu> k (F n) \<and> ?\<mu> j (F n) \<le> ?\<mu> k (F n)"
  3140         by (safe intro!: bexI[of _ "i \<union> j"]) auto
  3141     next
  3142       show "(SUP P : {P. finite P \<and> P \<subseteq> M}. \<Sum>n. ?\<mu> P (F n)) = (SUP P : {P. finite P \<and> P \<subseteq> M}. ?\<mu> P (UNION UNIV F))"
  3143       proof (intro SUP_cong refl)
  3144         fix i assume i: "i \<in> {P. finite P \<and> P \<subseteq> M}"
  3145         show "(\<Sum>n. ?\<mu> i (F n)) = ?\<mu> i (UNION UNIV F)"
  3146         proof cases
  3147           assume "i \<noteq> {}" with i ** show ?thesis
  3148             apply (intro suminf_emeasure \<open>disjoint_family F\<close>)
  3149             apply (subst sets_sup_measure_F[OF _ _ sets_eq])
  3150             apply auto
  3151             done
  3152         qed simp
  3153       qed
  3154     qed
  3155   qed
  3156   show "positive (sets (Sup_measure' M)) ?S"
  3157     by (auto simp: positive_def bot_ennreal[symmetric])
  3158   show "X \<in> sets (Sup_measure' M)"
  3159     using assms * by auto
  3160 qed (rule UN_space_closed)
  3162 definition Sup_measure :: "'a measure set \<Rightarrow> 'a measure"
  3163 where
  3164   "Sup_measure = Sup_lexord space (Sup_lexord sets Sup_measure'
  3165     (\<lambda>U. sigma (\<Union>u\<in>U. space u) (\<Union>u\<in>U. sets u))) (\<lambda>U. sigma (\<Union>u\<in>U. space u) {})"
  3167 definition Inf_measure :: "'a measure set \<Rightarrow> 'a measure"
  3168 where
  3169   "Inf_measure A = Sup {x. \<forall>a\<in>A. x \<le> a}"
  3171 definition inf_measure :: "'a measure \<Rightarrow> 'a measure \<Rightarrow> 'a measure"
  3172 where
  3173   "inf_measure a b = Inf {a, b}"
  3175 definition top_measure :: "'a measure"
  3176 where
  3177   "top_measure = Inf {}"
  3179 instance
  3180 proof
  3181   note UN_space_closed [simp]
  3182   show upper: "x \<le> Sup A" if x: "x \<in> A" for x :: "'a measure" and A
  3183     unfolding Sup_measure_def
  3184   proof (intro Sup_lexord[where P="\<lambda>y. x \<le> y"])
  3185     assume "\<And>a. a \<in> A \<Longrightarrow> space a \<noteq> (\<Union>a\<in>A. space a)"
  3186     from this[OF \<open>x \<in> A\<close>] \<open>x \<in> A\<close> show "x \<le> sigma (\<Union>a\<in>A. space a) {}"
  3187       by (intro less_eq_measure.intros) auto
  3188   next
  3189     fix a S assume "a \<in> A" and a: "space a = (\<Union>a\<in>A. space a)" and S: "S = {a' \<in> A. space a' = space a}"
  3190       and neq: "\<And>aa. aa \<in> S \<Longrightarrow> sets aa \<noteq> (\<Union>a\<in>S. sets a)"
  3191     have sp_a: "space a = (UNION S space)"
  3192       using \<open>a\<in>A\<close> by (auto simp: S)
  3193     show "x \<le> sigma (UNION S space) (UNION S sets)"
  3194     proof cases
  3195       assume [simp]: "space x = space a"
  3196       have "sets x \<subset> (\<Union>a\<in>S. sets a)"
  3197         using \<open>x\<in>A\<close> neq[of x] by (auto simp: S)
  3198       also have "\<dots> \<subseteq> sigma_sets (\<Union>x\<in>S. space x) (\<Union>x\<in>S. sets x)"
  3199         by (rule sigma_sets_superset_generator)
  3200       finally show ?thesis
  3201         by (intro less_eq_measure.intros(2)) (simp_all add: sp_a)
  3202     next
  3203       assume "space x \<noteq> space a"
  3204       moreover have "space x \<le> space a"
  3205         unfolding a using \<open>x\<in>A\<close> by auto
  3206       ultimately show ?thesis
  3207         by (intro less_eq_measure.intros) (simp add: less_le sp_a)
  3208     qed
  3209   next
  3210     fix a b S S' assume "a \<in> A" and a: "space a = (\<Union>a\<in>A. space a)" and S: "S = {a' \<in> A. space a' = space a}"
  3211       and "b \<in> S" and b: "sets b = (\<Union>a\<in>S. sets a)" and S': "S' = {a' \<in> S. sets a' = sets b}"
  3212     then have "S' \<noteq> {}" "space b = space a"
  3213       by auto
  3214     have sets_eq: "\<And>x. x \<in> S' \<Longrightarrow> sets x = sets b"
  3215       by (auto simp: S')
  3216     note sets_eq[THEN sets_eq_imp_space_eq, simp]
  3217     have *: "sets (Sup_measure' S') = sets b" "space (Sup_measure' S') = space b"
  3218       using \<open>S' \<noteq> {}\<close> by (simp_all add: Sup_measure'_def sets_eq)
  3219     show "x \<le> Sup_measure' S'"
  3220     proof cases
  3221       assume "x \<in> S"
  3222       with \<open>b \<in> S\<close> have "space x = space b"
  3223         by (simp add: S)
  3224       show ?thesis
  3225       proof cases
  3226         assume "x \<in> S'"
  3227         show "x \<le> Sup_measure' S'"
  3228         proof (intro le_measure[THEN iffD2] ballI)
  3229           show "sets x = sets (Sup_measure' S')"
  3230             using \<open>x\<in>S'\<close> * by (simp add: S')
  3231           fix X assume "X \<in> sets x"
  3232           show "emeasure x X \<le> emeasure (Sup_measure' S') X"
  3233           proof (subst emeasure_Sup_measure'[OF _ \<open>X \<in> sets x\<close>])
  3234             show "emeasure x X \<le> (SUP P : {P. finite P \<and> P \<subseteq> S'}. emeasure (sup_measure.F id P) X)"
  3235               using \<open>x\<in>S'\<close> by (intro SUP_upper2[where i="{x}"]) auto
  3236           qed (insert \<open>x\<in>S'\<close> S', auto)
  3237         qed
  3238       next
  3239         assume "x \<notin> S'"
  3240         then have "sets x \<noteq> sets b"
  3241           using \<open>x\<in>S\<close> by (auto simp: S')
  3242         moreover have "sets x \<le> sets b"
  3243           using \<open>x\<in>S\<close> unfolding b by auto
  3244         ultimately show ?thesis
  3245           using * \<open>x \<in> S\<close>
  3246           by (intro less_eq_measure.intros(2))
  3247              (simp_all add: * \<open>space x = space b\<close> less_le)
  3248       qed
  3249     next
  3250       assume "x \<notin> S"
  3251       with \<open>x\<in>A\<close> \<open>x \<notin> S\<close> \<open>space b = space a\<close> show ?thesis
  3252         by (intro less_eq_measure.intros)
  3253            (simp_all add: * less_le a SUP_upper S)
  3254     qed
  3255   qed
  3256   show least: "Sup A \<le> x" if x: "\<And>z. z \<in> A \<Longrightarrow> z \<le> x" for x :: "'a measure" and A
  3257     unfolding Sup_measure_def
  3258   proof (intro Sup_lexord[where P="\<lambda>y. y \<le> x"])
  3259     assume "\<And>a. a \<in> A \<Longrightarrow> space a \<noteq> (\<Union>a\<in>A. space a)"
  3260     show "sigma (UNION A space) {} \<le> x"
  3261       using x[THEN le_measureD1] by (subst sigma_le_iff) auto
  3262   next
  3263     fix a S assume "a \<in> A" "space a = (\<Union>a\<in>A. space a)" and S: "S = {a' \<in> A. space a' = space a}"
  3264       "\<And>a. a \<in> S \<Longrightarrow> sets a \<noteq> (\<Union>a\<in>S. sets a)"
  3265     have "UNION S space \<subseteq> space x"
  3266       using S le_measureD1[OF x] by auto
  3267     moreover
  3268     have "UNION S space = space a"
  3269       using \<open>a\<in>A\<close> S by auto
  3270     then have "space x = UNION S space \<Longrightarrow> UNION S sets \<subseteq> sets x"
  3271       using \<open>a \<in> A\<close> le_measureD2[OF x] by (auto simp: S)
  3272     ultimately show "sigma (UNION S space) (UNION S sets) \<le> x"
  3273       by (subst sigma_le_iff) simp_all
  3274   next
  3275     fix a b S S' assume "a \<in> A" and a: "space a = (\<Union>a\<in>A. space a)" and S: "S = {a' \<in> A. space a' = space a}"
  3276       and "b \<in> S" and b: "sets b = (\<Union>a\<in>S. sets a)" and S': "S' = {a' \<in> S. sets a' = sets b}"
  3277     then have "S' \<noteq> {}" "space b = space a"
  3278       by auto
  3279     have sets_eq: "\<And>x. x \<in> S' \<Longrightarrow> sets x = sets b"
  3280       by (auto simp: S')
  3281     note sets_eq[THEN sets_eq_imp_space_eq, simp]
  3282     have *: "sets (Sup_measure' S') = sets b" "space (Sup_measure' S') = space b"
  3283       using \<open>S' \<noteq> {}\<close> by (simp_all add: Sup_measure'_def sets_eq)
  3284     show "Sup_measure' S' \<le> x"
  3285     proof cases
  3286       assume "space x = space a"
  3287       show ?thesis
  3288       proof cases
  3289         assume **: "sets x = sets b"
  3290         show ?thesis
  3291         proof (intro le_measure[THEN iffD2] ballI)
  3292           show ***: "sets (Sup_measure' S') = sets x"
  3293             by (simp add: * **)
  3294           fix X assume "X \<in> sets (Sup_measure' S')"
  3295           show "emeasure (Sup_measure' S') X \<le> emeasure x X"
  3296             unfolding ***
  3297           proof (subst emeasure_Sup_measure'[OF _ \<open>X \<in> sets (Sup_measure' S')\<close>])
  3298             show "(SUP P : {P. finite P \<and> P \<subseteq> S'}. emeasure (sup_measure.F id P) X) \<le> emeasure x X"
  3299             proof (safe intro!: SUP_least)
  3300               fix P assume P: "finite P" "P \<subseteq> S'"
  3301               show "emeasure (sup_measure.F id P) X \<le> emeasure x X"
  3302               proof cases
  3303                 assume "P = {}" then show ?thesis
  3304                   by auto
  3305               next
  3306                 assume "P \<noteq> {}"
  3307                 from P have "finite P" "P \<subseteq> A"
  3308                   unfolding S' S by (simp_all add: subset_eq)
  3309                 then have "sup_measure.F id P \<le> x"
  3310                   by (induction P) (auto simp: x)
  3311                 moreover have "sets (sup_measure.F id P) = sets x"
  3312                   using \<open>finite P\<close> \<open>P \<noteq> {}\<close> \<open>P \<subseteq> S'\<close> \<open>sets x = sets b\<close>
  3313                   by (intro sets_sup_measure_F) (auto simp: S')
  3314                 ultimately show "emeasure (sup_measure.F id P) X \<le> emeasure x X"
  3315                   by (rule le_measureD3)
  3316               qed
  3317             qed
  3318             show "m \<in> S' \<Longrightarrow> sets m = sets (Sup_measure' S')" for m
  3319               unfolding * by (simp add: S')
  3320           qed fact
  3321         qed
  3322       next
  3323         assume "sets x \<noteq> sets b"
  3324         moreover have "sets b \<le> sets x"
  3325           unfolding b S using x[THEN le_measureD2] \<open>space x = space a\<close> by auto
  3326         ultimately show "Sup_measure' S' \<le> x"
  3327           using \<open>space x = space a\<close> \<open>b \<in> S\<close>
  3328           by (intro less_eq_measure.intros(2)) (simp_all add: * S)
  3329       qed
  3330     next
  3331       assume "space x \<noteq> space a"
  3332       then have "space a < space x"
  3333         using le_measureD1[OF x[OF \<open>a\<in>A\<close>]] by auto
  3334       then show "Sup_measure' S' \<le> x"
  3335         by (intro less_eq_measure.intros) (simp add: * \<open>space b = space a\<close>)
  3336     qed
  3337   qed
  3338   show "Sup {} = (bot::'a measure)" "Inf {} = (top::'a measure)"
  3339     by (auto intro!: antisym least simp: top_measure_def)
  3340   show lower: "x \<in> A \<Longrightarrow> Inf A \<le> x" for x :: "'a measure" and A
  3341     unfolding Inf_measure_def by (intro least) auto
  3342   show greatest: "(\<And>z. z \<in> A \<Longrightarrow> x \<le> z) \<Longrightarrow> x \<le> Inf A" for x :: "'a measure" and A
  3343     unfolding Inf_measure_def by (intro upper) auto
  3344   show "inf x y \<le> x" "inf x y \<le> y" "x \<le> y \<Longrightarrow> x \<le> z \<Longrightarrow> x \<le> inf y z" for x y z :: "'a measure"
  3345     by (auto simp: inf_measure_def intro!: lower greatest)
  3346 qed
  3348 end
  3350 lemma sets_SUP:
  3351   assumes "\<And>x. x \<in> I \<Longrightarrow> sets (M x) = sets N"
  3352   shows "I \<noteq> {} \<Longrightarrow> sets (SUP i:I. M i) = sets N"
  3353   unfolding Sup_measure_def
  3354   using assms assms[THEN sets_eq_imp_space_eq]
  3355     sets_Sup_measure'[where A=N and M="M`I"]
  3356   by (intro Sup_lexord1[where P="\<lambda>x. sets x = sets N"]) auto
  3358 lemma emeasure_SUP:
  3359   assumes sets: "\<And>i. i \<in> I \<Longrightarrow> sets (M i) = sets N" "X \<in> sets N" "I \<noteq> {}"
  3360   shows "emeasure (SUP i:I. M i) X = (SUP J:{J. J \<noteq> {} \<and> finite J \<and> J \<subseteq> I}. emeasure (SUP i:J. M i) X)"
  3361 proof -
  3362   interpret sup_measure: comm_monoid_set sup "bot :: 'b measure"
  3363     by standard (auto intro!: antisym)
  3364   have eq: "finite J \<Longrightarrow> sup_measure.F id J = (SUP i:J. i)" for J :: "'b measure set"
  3365     by (induction J rule: finite_induct) auto
  3366   have 1: "J \<noteq> {} \<Longrightarrow> J \<subseteq> I \<Longrightarrow> sets (SUP x:J. M x) = sets N" for J
  3367     by (intro sets_SUP sets) (auto )
  3368   from \<open>I \<noteq> {}\<close> obtain i where "i\<in>I" by auto
  3369   have "Sup_measure' (M`I) X = (SUP P:{P. finite P \<and> P \<subseteq> M`I}. sup_measure.F id P X)"
  3370     using sets by (intro emeasure_Sup_measure') auto
  3371   also have "Sup_measure' (M`I) = (SUP i:I. M i)"
  3372     unfolding Sup_measure_def using \<open>I \<noteq> {}\<close> sets sets(1)[THEN sets_eq_imp_space_eq]
  3373     by (intro Sup_lexord1[where P="\<lambda>x. _ = x"]) auto
  3374   also have "(SUP P:{P. finite P \<and> P \<subseteq> M`I}. sup_measure.F id P X) =
  3375     (SUP J:{J. J \<noteq> {} \<and> finite J \<and> J \<subseteq> I}. (SUP i:J. M i) X)"
  3376   proof (intro SUP_eq)
  3377     fix J assume "J \<in> {P. finite P \<and> P \<subseteq> M`I}"
  3378     then obtain J' where J': "J' \<subseteq> I" "finite J'" and J: "J = M`J'" and "finite J"
  3379       using finite_subset_image[of J M I] by auto
  3380     show "\<exists>j\<in>{J. J \<noteq> {} \<and> finite J \<and> J \<subseteq> I}. sup_measure.F id J X \<le> (SUP i:j. M i) X"
  3381     proof cases
  3382       assume "J' = {}" with \<open>i \<in> I\<close> show ?thesis
  3383         by (auto simp add: J)
  3384     next
  3385       assume "J' \<noteq> {}" with J J' show ?thesis
  3386         by (intro bexI[of _ "J'"]) (auto simp add: eq simp del: id_apply)
  3387     qed
  3388   next
  3389     fix J assume J: "J \<in> {P. P \<noteq> {} \<and> finite P \<and> P \<subseteq> I}"
  3390     show "\<exists>J'\<in>{J. finite J \<and> J \<subseteq> M`I}. (SUP i:J. M i) X \<le> sup_measure.F id J' X"
  3391       using J by (intro bexI[of _ "M`J"]) (auto simp add: eq simp del: id_apply)
  3392   qed
  3393   finally show ?thesis .
  3394 qed
  3396 lemma emeasure_SUP_chain:
  3397   assumes sets: "\<And>i. i \<in> A \<Longrightarrow> sets (M i) = sets N" "X \<in> sets N"
  3398   assumes ch: "Complete_Partial_Order.chain op \<le> (M ` A)" and "A \<noteq> {}"
  3399   shows "emeasure (SUP i:A. M i) X = (SUP i:A. emeasure (M i) X)"
  3400 proof (subst emeasure_SUP[OF sets \<open>A \<noteq> {}\<close>])
  3401   show "(SUP J:{J. J \<noteq> {} \<and> finite J \<and> J \<subseteq> A}. emeasure (SUPREMUM J M) X) = (SUP i:A. emeasure (M i) X)"
  3402   proof (rule SUP_eq)
  3403     fix J assume "J \<in> {J. J \<noteq> {} \<and> finite J \<and> J \<subseteq> A}"
  3404     then have J: "Complete_Partial_Order.chain op \<le> (M ` J)" "finite J" "J \<noteq> {}" and "J \<subseteq> A"
  3405       using ch[THEN chain_subset, of "M`J"] by auto
  3406     with in_chain_finite[OF J(1)] obtain j where "j \<in> J" "(SUP j:J. M j) = M j"
  3407       by auto
  3408     with \<open>J \<subseteq> A\<close> show "\<exists>j\<in>A. emeasure (SUPREMUM J M) X \<le> emeasure (M j) X"
  3409       by auto
  3410   next
  3411     fix j assume "j\<in>A" then show "\<exists>i\<in>{J. J \<noteq> {} \<and> finite J \<and> J \<subseteq> A}. emeasure (M j) X \<le> emeasure (SUPREMUM i M) X"
  3412       by (intro bexI[of _ "{j}"]) auto
  3413   qed
  3414 qed
  3416 subsubsection \<open>Supremum of a set of $\sigma$-algebras\<close>
  3418 lemma space_Sup_eq_UN: "space (Sup M) = (\<Union>x\<in>M. space x)"
  3419   unfolding Sup_measure_def
  3420   apply (intro Sup_lexord[where P="\<lambda>x. space x = _"])
  3421   apply (subst space_Sup_measure'2)
  3422   apply auto []
  3423   apply (subst space_measure_of[OF UN_space_closed])
  3424   apply auto
  3425   done
  3427 lemma sets_Sup_eq:
  3428   assumes *: "\<And>m. m \<in> M \<Longrightarrow> space m = X" and "M \<noteq> {}"
  3429   shows "sets (Sup M) = sigma_sets X (\<Union>x\<in>M. sets x)"
  3430   unfolding Sup_measure_def
  3431   apply (rule Sup_lexord1)
  3432   apply fact
  3433   apply (simp add: assms)
  3434   apply (rule Sup_lexord)
  3435   subgoal premises that for a S
  3436     unfolding that(3) that(2)[symmetric]
  3437     using that(1)
  3438     apply (subst sets_Sup_measure'2)
  3439     apply (intro arg_cong2[where f=sigma_sets])
  3440     apply (auto simp: *)
  3441     done
  3442   apply (subst sets_measure_of[OF UN_space_closed])
  3443   apply (simp add:  assms)
  3444   done
  3446 lemma in_sets_Sup: "(\<And>m. m \<in> M \<Longrightarrow> space m = X) \<Longrightarrow> m \<in> M \<Longrightarrow> A \<in> sets m \<Longrightarrow> A \<in> sets (Sup M)"
  3447   by (subst sets_Sup_eq[where X=X]) auto
  3449 lemma Sup_lexord_rel:
  3450   assumes "\<And>i. i \<in> I \<Longrightarrow> k (A i) = k (B i)"
  3451     "R (c (A ` {a \<in> I. k (B a) = (SUP x:I. k (B x))})) (c (B ` {a \<in> I. k (B a) = (SUP x:I. k (B x))}))"
  3452     "R (s (A`I)) (s (B`I))"
  3453   shows "R (Sup_lexord k c s (A`I)) (Sup_lexord k c s (B`I))"
  3454 proof -
  3455   have "A ` {a \<in> I. k (B a) = (SUP x:I. k (B x))} =  {a \<in> A ` I. k a = (SUP x:I. k (B x))}"
  3456     using assms(1) by auto
  3457   moreover have "B ` {a \<in> I. k (B a) = (SUP x:I. k (B x))} =  {a \<in> B ` I. k a = (SUP x:I. k (B x))}"
  3458     by auto
  3459   ultimately show ?thesis
  3460     using assms by (auto simp: Sup_lexord_def Let_def)
  3461 qed
  3463 lemma sets_SUP_cong:
  3464   assumes eq: "\<And>i. i \<in> I \<Longrightarrow> sets (M i) = sets (N i)" shows "sets (SUP i:I. M i) = sets (SUP i:I. N i)"
  3465   unfolding Sup_measure_def
  3466   using eq eq[THEN sets_eq_imp_space_eq]
  3467   apply (intro Sup_lexord_rel[where R="\<lambda>x y. sets x = sets y"])
  3468   apply simp
  3469   apply simp
  3470   apply (simp add: sets_Sup_measure'2)
  3471   apply (intro arg_cong2[where f="\<lambda>x y. sets (sigma x y)"])
  3472   apply auto
  3473   done
  3475 lemma sets_Sup_in_sets:
  3476   assumes "M \<noteq> {}"
  3477   assumes "\<And>m. m \<in> M \<Longrightarrow> space m = space N"
  3478   assumes "\<And>m. m \<in> M \<Longrightarrow> sets m \<subseteq> sets N"
  3479   shows "sets (Sup M) \<subseteq> sets N"
  3480 proof -
  3481   have *: "UNION M space = space N"
  3482     using assms by auto
  3483   show ?thesis
  3484     unfolding * using assms by (subst sets_Sup_eq[of M "space N"]) (auto intro!: sets.sigma_sets_subset)
  3485 qed
  3487 lemma measurable_Sup1:
  3488   assumes m: "m \<in> M" and f: "f \<in> measurable m N"
  3489     and const_space: "\<And>m n. m \<in> M \<Longrightarrow> n \<in> M \<Longrightarrow> space m = space n"
  3490   shows "f \<in> measurable (Sup M) N"
  3491 proof -
  3492   have "space (Sup M) = space m"
  3493     using m by (auto simp add: space_Sup_eq_UN dest: const_space)
  3494   then show ?thesis
  3495     using m f unfolding measurable_def by (auto intro: in_sets_Sup[OF const_space])
  3496 qed
  3498 lemma measurable_Sup2:
  3499   assumes M: "M \<noteq> {}"
  3500   assumes f: "\<And>m. m \<in> M \<Longrightarrow> f \<in> measurable N m"
  3501     and const_space: "\<And>m n. m \<in> M \<Longrightarrow> n \<in> M \<Longrightarrow> space m = space n"
  3502   shows "f \<in> measurable N (Sup M)"
  3503 proof -
  3504   from M obtain m where "m \<in> M" by auto
  3505   have space_eq: "\<And>n. n \<in> M \<Longrightarrow> space n = space m"
  3506     by (intro const_space \<open>m \<in> M\<close>)
  3507   have "f \<in> measurable N (sigma (\<Union>m\<in>M. space m) (\<Union>m\<in>M. sets m))"
  3508   proof (rule measurable_measure_of)
  3509     show "f \<in> space N \<rightarrow> UNION M space"
  3510       using measurable_space[OF f] M by auto
  3511   qed (auto intro: measurable_sets f dest: sets.sets_into_space)
  3512   also have "measurable N (sigma (\<Union>m\<in>M. space m) (\<Union>m\<in>M. sets m)) = measurable N (Sup M)"
  3513     apply (intro measurable_cong_sets refl)
  3514     apply (subst sets_Sup_eq[OF space_eq M])
  3515     apply simp
  3516     apply (subst sets_measure_of[OF UN_space_closed])
  3517     apply (simp add: space_eq M)
  3518     done
  3519   finally show ?thesis .
  3520 qed
  3522 lemma measurable_SUP2:
  3523   "I \<noteq> {} \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> f \<in> measurable N (M i)) \<Longrightarrow>
  3524     (\<And>i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> space (M i) = space (M j)) \<Longrightarrow> f \<in> measurable N (SUP i:I. M i)"
  3525   by (auto intro!: measurable_Sup2)
  3527 lemma sets_Sup_sigma:
  3528   assumes [simp]: "M \<noteq> {}" and M: "\<And>m. m \<in> M \<Longrightarrow> m \<subseteq> Pow \<Omega>"
  3529   shows "sets (SUP m:M. sigma \<Omega> m) = sets (sigma \<Omega> (\<Union>M))"
  3530 proof -
  3531   { fix a m assume "a \<in> sigma_sets \<Omega> m" "m \<in> M"
  3532     then have "a \<in> sigma_sets \<Omega> (\<Union>M)"
  3533      by induction (auto intro: sigma_sets.intros(2-)) }
  3534   then show "sets (SUP m:M. sigma \<Omega> m) = sets (sigma \<Omega> (\<Union>M))"
  3535     apply (subst sets_Sup_eq[where X="\<Omega>"])
  3536     apply (auto simp add: M) []
  3537     apply auto []
  3538     apply (simp add: space_measure_of_conv M Union_least)
  3539     apply (rule sigma_sets_eqI)
  3540     apply auto
  3541     done
  3542 qed
  3544 lemma Sup_sigma:
  3545   assumes [simp]: "M \<noteq> {}" and M: "\<And>m. m \<in> M \<Longrightarrow> m \<subseteq> Pow \<Omega>"
  3546   shows "(SUP m:M. sigma \<Omega> m) = (sigma \<Omega> (\<Union>M))"
  3547 proof (intro antisym SUP_least)
  3548   have *: "\<Union>M \<subseteq> Pow \<Omega>"
  3549     using M by auto
  3550   show "sigma \<Omega> (\<Union>M) \<le> (SUP m:M. sigma \<Omega> m)"
  3551   proof (intro less_eq_measure.intros(3))
  3552     show "space (sigma \<Omega> (\<Union>M)) = space (SUP m:M. sigma \<Omega> m)"
  3553       "sets (sigma \<Omega> (\<Union>M)) = sets (SUP m:M. sigma \<Omega> m)"
  3554       using sets_Sup_sigma[OF assms] sets_Sup_sigma[OF assms, THEN sets_eq_imp_space_eq]
  3555       by auto
  3556   qed (simp add: emeasure_sigma le_fun_def)
  3557   fix m assume "m \<in> M" then show "sigma \<Omega> m \<le> sigma \<Omega> (\<Union>M)"
  3558     by (subst sigma_le_iff) (auto simp add: M *)
  3559 qed
  3561 lemma SUP_sigma_sigma:
  3562   "M \<noteq> {} \<Longrightarrow> (\<And>m. m \<in> M \<Longrightarrow> f m \<subseteq> Pow \<Omega>) \<Longrightarrow> (SUP m:M. sigma \<Omega> (f m)) = sigma \<Omega> (\<Union>m\<in>M. f m)"
  3563   using Sup_sigma[of "f`M" \<Omega>] by auto
  3565 lemma sets_vimage_Sup_eq:
  3566   assumes *: "M \<noteq> {}" "f \<in> X \<rightarrow> Y" "\<And>m. m \<in> M \<Longrightarrow> space m = Y"
  3567   shows "sets (vimage_algebra X f (Sup M)) = sets (SUP m : M. vimage_algebra X f m)"
  3568   (is "?IS = ?SI")
  3569 proof
  3570   show "?IS \<subseteq> ?SI"
  3571     apply (intro sets_image_in_sets measurable_Sup2)
  3572     apply (simp add: space_Sup_eq_UN *)
  3573     apply (simp add: *)
  3574     apply (intro measurable_Sup1)
  3575     apply (rule imageI)
  3576     apply assumption
  3577     apply (rule measurable_vimage_algebra1)
  3578     apply (auto simp: *)
  3579     done
  3580   show "?SI \<subseteq> ?IS"
  3581     apply (intro sets_Sup_in_sets)
  3582     apply (auto simp: *) []
  3583     apply (auto simp: *) []
  3584     apply (elim imageE)
  3585     apply simp
  3586     apply (rule sets_image_in_sets)
  3587     apply simp
  3588     apply (simp add: measurable_def)
  3589     apply (simp add: * space_Sup_eq_UN sets_vimage_algebra2)
  3590     apply (auto intro: in_sets_Sup[OF *(3)])
  3591     done
  3592 qed
  3594 lemma restrict_space_eq_vimage_algebra':
  3595   "sets (restrict_space M \<Omega>) = sets (vimage_algebra (\<Omega> \<inter> space M) (\<lambda>x. x) M)"
  3596 proof -
  3597   have *: "{A \<inter> (\<Omega> \<inter> space M) |A. A \<in> sets M} = {A \<inter> \<Omega> |A. A \<in> sets M}"
  3598     using sets.sets_into_space[of _ M] by blast
  3600   show ?thesis
  3601     unfolding restrict_space_def
  3602     by (subst sets_measure_of)
  3603        (auto simp add: image_subset_iff sets_vimage_algebra * dest: sets.sets_into_space intro!: arg_cong2[where f=sigma_sets])
  3604 qed
  3606 lemma sigma_le_sets:
  3607   assumes [simp]: "A \<subseteq> Pow X" shows "sets (sigma X A) \<subseteq> sets N \<longleftrightarrow> X \<in> sets N \<and> A \<subseteq> sets N"
  3608 proof
  3609   have "X \<in> sigma_sets X A" "A \<subseteq> sigma_sets X A"
  3610     by (auto intro: sigma_sets_top)
  3611   moreover assume "sets (sigma X A) \<subseteq> sets N"
  3612   ultimately show "X \<in> sets N \<and> A \<subseteq> sets N"
  3613     by auto
  3614 next
  3615   assume *: "X \<in> sets N \<and> A \<subseteq> sets N"
  3616   { fix Y assume "Y \<in> sigma_sets X A" from this * have "Y \<in> sets N"
  3617       by induction auto }
  3618   then show "sets (sigma X A) \<subseteq> sets N"
  3619     by auto
  3620 qed
  3622 lemma measurable_iff_sets:
  3623   "f \<in> measurable M N \<longleftrightarrow> (f \<in> space M \<rightarrow> space N \<and> sets (vimage_algebra (space M) f N) \<subseteq> sets M)"
  3624 proof -
  3625   have *: "{f -` A \<inter> space M |A. A \<in> sets N} \<subseteq> Pow (space M)"
  3626     by auto
  3627   show ?thesis
  3628     unfolding measurable_def
  3629     by (auto simp add: vimage_algebra_def sigma_le_sets[OF *])
  3630 qed
  3632 lemma sets_vimage_algebra_space: "X \<in> sets (vimage_algebra X f M)"
  3633   using[of "vimage_algebra X f M"] by simp
  3635 lemma measurable_mono:
  3636   assumes N: "sets N' \<le> sets N" "space N = space N'"
  3637   assumes M: "sets M \<le> sets M'" "space M = space M'"
  3638   shows "measurable M N \<subseteq> measurable M' N'"
  3639   unfolding measurable_def
  3640 proof safe
  3641   fix f A assume "f \<in> space M \<rightarrow> space N" "A \<in> sets N'"
  3642   moreover assume "\<forall>y\<in>sets N. f -` y \<inter> space M \<in> sets M" note this[THEN bspec, of A]
  3643   ultimately show "f -` A \<inter> space M' \<in> sets M'"
  3644     using assms by auto
  3645 qed (insert N M, auto)
  3647 lemma measurable_Sup_measurable:
  3648   assumes f: "f \<in> space N \<rightarrow> A"
  3649   shows "f \<in> measurable N (Sup {M. space M = A \<and> f \<in> measurable N M})"
  3650 proof (rule measurable_Sup2)
  3651   show "{M. space M = A \<and> f \<in> measurable N M} \<noteq> {}"
  3652     using f unfolding ex_in_conv[symmetric]
  3653     by (intro exI[of _ "sigma A {}"]) (auto intro!: measurable_measure_of)
  3654 qed auto
  3656 lemma (in sigma_algebra) sigma_sets_subset':
  3657   assumes a: "a \<subseteq> M" "\<Omega>' \<in> M"
  3658   shows "sigma_sets \<Omega>' a \<subseteq> M"
  3659 proof
  3660   show "x \<in> M" if x: "x \<in> sigma_sets \<Omega>' a" for x
  3661     using x by (induct rule: sigma_sets.induct) (insert a, auto)
  3662 qed
  3664 lemma in_sets_SUP: "i \<in> I \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> space (M i) = Y) \<Longrightarrow> X \<in> sets (M i) \<Longrightarrow> X \<in> sets (SUP i:I. M i)"
  3665   by (intro in_sets_Sup[where X=Y]) auto
  3667 lemma measurable_SUP1:
  3668   "i \<in> I \<Longrightarrow> f \<in> measurable (M i) N \<Longrightarrow> (\<And>m n. m \<in> I \<Longrightarrow> n \<in> I \<Longrightarrow> space (M m) = space (M n)) \<Longrightarrow>
  3669     f \<in> measurable (SUP i:I. M i) N"
  3670   by (auto intro: measurable_Sup1)
  3672 lemma sets_image_in_sets':
  3673   assumes X: "X \<in> sets N"
  3674   assumes f: "\<And>A. A \<in> sets M \<Longrightarrow> f -` A \<inter> X \<in> sets N"
  3675   shows "sets (vimage_algebra X f M) \<subseteq> sets N"
  3676   unfolding sets_vimage_algebra
  3677   by (rule sets.sigma_sets_subset') (auto intro!: measurable_sets X f)
  3679 lemma mono_vimage_algebra:
  3680   "sets M \<le> sets N \<Longrightarrow> sets (vimage_algebra X f M) \<subseteq> sets (vimage_algebra X f N)"
  3681   using[of "sigma X {f -` A \<inter> X |A. A \<in> sets N}"]
  3682   unfolding vimage_algebra_def
  3683   apply (subst (asm) space_measure_of)
  3684   apply auto []
  3685   apply (subst sigma_le_sets)
  3686   apply auto
  3687   done
  3689 lemma mono_restrict_space: "sets M \<le> sets N \<Longrightarrow> sets (restrict_space M X) \<subseteq> sets (restrict_space N X)"
  3690   unfolding sets_restrict_space by (rule image_mono)
  3692 lemma sets_eq_bot: "sets M = {{}} \<longleftrightarrow> M = bot"
  3693   apply safe
  3694   apply (intro measure_eqI)
  3695   apply auto
  3696   done
  3698 lemma sets_eq_bot2: "{{}} = sets M \<longleftrightarrow> M = bot"
  3699   using sets_eq_bot[of M] by blast
  3702 lemma (in finite_measure) countable_support:
  3703   "countable {x. measure M {x} \<noteq> 0}"
  3704 proof cases
  3705   assume "measure M (space M) = 0"
  3706   with bounded_measure measure_le_0_iff have "{x. measure M {x} \<noteq> 0} = {}"
  3707     by auto
  3708   then show ?thesis
  3709     by simp
  3710 next
  3711   let ?M = "measure M (space M)" and ?m = "\<lambda>x. measure M {x}"
  3712   assume "?M \<noteq> 0"
  3713   then have *: "{x. ?m x \<noteq> 0} = (\<Union>n. {x. ?M / Suc n < ?m x})"
  3714     using reals_Archimedean[of "?m x / ?M" for x]
  3715     by (auto simp: field_simps not_le[symmetric] divide_le_0_iff measure_le_0_iff)
  3716   have **: "\<And>n. finite {x. ?M / Suc n < ?m x}"
  3717   proof (rule ccontr)
  3718     fix n assume "infinite {x. ?M / Suc n < ?m x}" (is "infinite ?X")
  3719     then obtain X where "finite X" "card X = Suc (Suc n)" "X \<subseteq> ?X"
  3720       by (metis infinite_arbitrarily_large)
  3721     from this(3) have *: "\<And>x. x \<in> X \<Longrightarrow> ?M / Suc n \<le> ?m x"
  3722       by auto
  3723     { fix x assume "x \<in> X"
  3724       from \<open>?M \<noteq> 0\<close> *[OF this] have "?m x \<noteq> 0" by (auto simp: field_simps measure_le_0_iff)
  3725       then have "{x} \<in> sets M" by (auto dest: measure_notin_sets) }
  3726     note singleton_sets = this
  3727     have "?M < (\<Sum>x\<in>X. ?M / Suc n)"
  3728       using \<open>?M \<noteq> 0\<close>
  3729       by (simp add: \<open>card X = Suc (Suc n)\<close> field_simps less_le)
  3730     also have "\<dots> \<le> (\<Sum>x\<in>X. ?m x)"
  3731       by (rule sum_mono) fact
  3732     also have "\<dots> = measure M (\<Union>x\<in>X. {x})"
  3733       using singleton_sets \<open>finite X\<close>
  3734       by (intro finite_measure_finite_Union[symmetric]) (auto simp: disjoint_family_on_def)
  3735     finally have "?M < measure M (\<Union>x\<in>X. {x})" .
  3736     moreover have "measure M (\<Union>x\<in>X. {x}) \<le> ?M"
  3737       using singleton_sets[THEN sets.sets_into_space] by (intro finite_measure_mono) auto
  3738     ultimately show False by simp
  3739   qed
  3740   show ?thesis
  3741     unfolding * by (intro countable_UN countableI_type countable_finite[OF **])
  3742 qed
  3744 end