src/Tools/nbe.ML
author haftmann
Wed Jul 08 08:18:07 2009 +0200 (2009-07-08)
changeset 31962 baa8dce5bc45
parent 31957 a9742afd403e
child 32123 8bac9ee4b28d
permissions -rw-r--r--
tuned structure Code internally
     1 (*  Title:      Tools/nbe.ML
     2     Authors:    Klaus Aehlig, LMU Muenchen; Tobias Nipkow, Florian Haftmann, TU Muenchen
     3 
     4 Normalization by evaluation, based on generic code generator.
     5 *)
     6 
     7 signature NBE =
     8 sig
     9   val norm_conv: cterm -> thm
    10   val norm: theory -> term -> term
    11 
    12   datatype Univ =
    13       Const of int * Univ list               (*named (uninterpreted) constants*)
    14     | DFree of string * int                  (*free (uninterpreted) dictionary parameters*)
    15     | BVar of int * Univ list
    16     | Abs of (int * (Univ list -> Univ)) * Univ list
    17   val apps: Univ -> Univ list -> Univ        (*explicit applications*)
    18   val abss: int -> (Univ list -> Univ) -> Univ
    19                                              (*abstractions as closures*)
    20   val same: Univ -> Univ -> bool
    21 
    22   val univs_ref: (unit -> Univ list -> Univ list) option ref
    23   val trace: bool ref
    24 
    25   val setup: theory -> theory
    26 end;
    27 
    28 structure Nbe: NBE =
    29 struct
    30 
    31 (* generic non-sense *)
    32 
    33 val trace = ref false;
    34 fun tracing f x = if !trace then (Output.tracing (f x); x) else x;
    35 
    36 
    37 (** the semantical universe **)
    38 
    39 (*
    40    Functions are given by their semantical function value. To avoid
    41    trouble with the ML-type system, these functions have the most
    42    generic type, that is "Univ list -> Univ". The calling convention is
    43    that the arguments come as a list, the last argument first. In
    44    other words, a function call that usually would look like
    45 
    46    f x_1 x_2 ... x_n   or   f(x_1,x_2, ..., x_n)
    47 
    48    would be in our convention called as
    49 
    50               f [x_n,..,x_2,x_1]
    51 
    52    Moreover, to handle functions that are still waiting for some
    53    arguments we have additionally a list of arguments collected to far
    54    and the number of arguments we're still waiting for.
    55 *)
    56 
    57 datatype Univ =
    58     Const of int * Univ list           (*named (uninterpreted) constants*)
    59   | DFree of string * int              (*free (uninterpreted) dictionary parameters*)
    60   | BVar of int * Univ list            (*bound variables, named*)
    61   | Abs of (int * (Univ list -> Univ)) * Univ list
    62                                        (*abstractions as closures*);
    63 
    64 fun same (Const (k, xs)) (Const (l, ys)) = k = l andalso sames xs ys
    65   | same (DFree (s, k)) (DFree (t, l)) = s = t andalso k = l
    66   | same (BVar (k, xs)) (BVar (l, ys)) = k = l andalso sames xs ys
    67   | same _ _ = false
    68 and sames xs ys = length xs = length ys andalso forall (uncurry same) (xs ~~ ys);
    69 
    70 (* constructor functions *)
    71 
    72 fun abss n f = Abs ((n, f), []);
    73 fun apps (Abs ((n, f), xs)) ys = let val k = n - length ys in
    74       case int_ord (k, 0)
    75        of EQUAL => f (ys @ xs)
    76         | LESS => let val (zs, ws) = chop (~ k) ys in apps (f (ws @ xs)) zs end
    77         | GREATER => Abs ((k, f), ys @ xs) (*note: reverse convention also for apps!*)
    78       end
    79   | apps (Const (name, xs)) ys = Const (name, ys @ xs)
    80   | apps (BVar (n, xs)) ys = BVar (n, ys @ xs);
    81 
    82 
    83 (** assembling and compiling ML code from terms **)
    84 
    85 (* abstract ML syntax *)
    86 
    87 infix 9 `$` `$$`;
    88 fun e1 `$` e2 = "(" ^ e1 ^ " " ^ e2 ^ ")";
    89 fun e `$$` [] = e
    90   | e `$$` es = "(" ^ e ^ " " ^ space_implode " " es ^ ")";
    91 fun ml_abs v e = "(fn " ^ v ^ " => " ^ e ^ ")";
    92 
    93 fun ml_cases t cs =
    94   "(case " ^ t ^ " of " ^ space_implode " | " (map (fn (p, t) => p ^ " => " ^ t) cs) ^ ")";
    95 fun ml_Let d e = "let\n" ^ d ^ " in " ^ e ^ " end";
    96 fun ml_as v t = "(" ^ v ^ " as " ^ t ^ ")";
    97 
    98 fun ml_and [] = "true"
    99   | ml_and [x] = x
   100   | ml_and xs = "(" ^ space_implode " andalso " xs ^ ")";
   101 fun ml_if b x y = "(if " ^ b ^ " then " ^ x ^ " else " ^ y ^ ")";
   102 
   103 fun ml_list es = "[" ^ commas es ^ "]";
   104 
   105 fun ml_fundefs ([(name, [([], e)])]) =
   106       "val " ^ name ^ " = " ^ e ^ "\n"
   107   | ml_fundefs (eqs :: eqss) =
   108       let
   109         fun fundef (name, eqs) =
   110           let
   111             fun eqn (es, e) = name ^ " " ^ space_implode " " es ^ " = " ^ e
   112           in space_implode "\n  | " (map eqn eqs) end;
   113       in
   114         (prefix "fun " o fundef) eqs :: map (prefix "and " o fundef) eqss
   115         |> cat_lines
   116         |> suffix "\n"
   117       end;
   118 
   119 (* nbe specific syntax and sandbox communication *)
   120 
   121 val univs_ref = ref (NONE : (unit -> Univ list -> Univ list) option);
   122 
   123 local
   124   val prefix =      "Nbe.";
   125   val name_ref =    prefix ^ "univs_ref";
   126   val name_const =  prefix ^ "Const";
   127   val name_abss =   prefix ^ "abss";
   128   val name_apps =   prefix ^ "apps";
   129   val name_same =   prefix ^ "same";
   130 in
   131 
   132 val univs_cookie = (name_ref, univs_ref);
   133 
   134 fun nbe_fun 0 "" = "nbe_value"
   135   | nbe_fun i c = "c_" ^ translate_string (fn "." => "_" | c => c) c ^ "_" ^ string_of_int i;
   136 fun nbe_dict v n = "d_" ^ v ^ "_" ^ string_of_int n;
   137 fun nbe_bound v = "v_" ^ v;
   138 fun nbe_bound_optional NONE = "_"
   139   | nbe_bound_optional  (SOME v) = nbe_bound v;
   140 fun nbe_default v = "w_" ^ v;
   141 
   142 (*note: these three are the "turning spots" where proper argument order is established!*)
   143 fun nbe_apps t [] = t
   144   | nbe_apps t ts = name_apps `$$` [t, ml_list (rev ts)];
   145 fun nbe_apps_local i c ts = nbe_fun i c `$` ml_list (rev ts);
   146 fun nbe_apps_constr idx_of c ts =
   147   let
   148     val c' = if !trace then string_of_int (idx_of c) ^ " (*" ^ c ^ "*)"
   149       else string_of_int (idx_of c);
   150   in name_const `$` ("(" ^ c' ^ ", " ^ ml_list (rev ts) ^ ")") end;
   151 
   152 fun nbe_abss 0 f = f `$` ml_list []
   153   | nbe_abss n f = name_abss `$$` [string_of_int n, f];
   154 
   155 fun nbe_same v1 v2 = "(" ^ name_same ^ " " ^ nbe_bound v1 ^ " " ^ nbe_bound v2 ^ ")";
   156 
   157 end;
   158 
   159 open Basic_Code_Thingol;
   160 
   161 (* code generation *)
   162 
   163 fun assemble_eqnss idx_of deps eqnss =
   164   let
   165     fun prep_eqns (c, (vs, eqns)) =
   166       let
   167         val dicts = maps (fn (v, sort) => map_index (nbe_dict v o fst) sort) vs;
   168         val num_args = length dicts + ((length o fst o hd) eqns);
   169       in (c, (num_args, (dicts, eqns))) end;
   170     val eqnss' = map prep_eqns eqnss;
   171 
   172     fun assemble_constapp c dss ts = 
   173       let
   174         val ts' = (maps o map) assemble_idict dss @ ts;
   175       in case AList.lookup (op =) eqnss' c
   176        of SOME (num_args, _) => if num_args <= length ts'
   177             then let val (ts1, ts2) = chop num_args ts'
   178             in nbe_apps (nbe_apps_local 0 c ts1) ts2
   179             end else nbe_apps (nbe_abss num_args (nbe_fun 0 c)) ts'
   180         | NONE => if member (op =) deps c
   181             then nbe_apps (nbe_fun 0 c) ts'
   182             else nbe_apps_constr idx_of c ts'
   183       end
   184     and assemble_idict (DictConst (inst, dss)) =
   185           assemble_constapp inst dss []
   186       | assemble_idict (DictVar (supers, (v, (n, _)))) =
   187           fold_rev (fn super => assemble_constapp super [] o single) supers (nbe_dict v n);
   188 
   189     fun assemble_iterm constapp =
   190       let
   191         fun of_iterm match_cont t =
   192           let
   193             val (t', ts) = Code_Thingol.unfold_app t
   194           in of_iapp match_cont t' (fold_rev (cons o of_iterm NONE) ts []) end
   195         and of_iapp match_cont (IConst (c, ((_, dss), _))) ts = constapp c dss ts
   196           | of_iapp match_cont (IVar v) ts = nbe_apps (nbe_bound_optional v) ts
   197           | of_iapp match_cont ((v, _) `|=> t) ts =
   198               nbe_apps (nbe_abss 1 (ml_abs (ml_list [nbe_bound_optional v]) (of_iterm NONE t))) ts
   199           | of_iapp match_cont (ICase (((t, _), cs), t0)) ts =
   200               nbe_apps (ml_cases (of_iterm NONE t)
   201                 (map (fn (p, t) => (of_iterm NONE p, of_iterm match_cont t)) cs
   202                   @ [("_", case match_cont of SOME s => s | NONE => of_iterm NONE t0)])) ts
   203       in of_iterm end;
   204 
   205     fun subst_nonlin_vars args =
   206       let
   207         val vs = (fold o Code_Thingol.fold_varnames)
   208           (fn v => AList.map_default (op =) (v, 0) (curry (op +) 1)) args [];
   209         val names = Name.make_context (map fst vs);
   210         fun declare v k ctxt = let val vs = Name.invents ctxt v k
   211           in (vs, fold Name.declare vs ctxt) end;
   212         val (vs_renames, _) = fold_map (fn (v, k) => if k > 1
   213           then declare v (k - 1) #>> (fn vs => (v, vs))
   214           else pair (v, [])) vs names;
   215         val samepairs = maps (fn (v, vs) => map (pair v) vs) vs_renames;
   216         fun subst_vars (t as IConst _) samepairs = (t, samepairs)
   217           | subst_vars (t as IVar NONE) samepairs = (t, samepairs)
   218           | subst_vars (t as IVar (SOME v)) samepairs = (case AList.lookup (op =) samepairs v
   219              of SOME v' => (IVar (SOME v'), AList.delete (op =) v samepairs)
   220               | NONE => (t, samepairs))
   221           | subst_vars (t1 `$ t2) samepairs = samepairs
   222               |> subst_vars t1
   223               ||>> subst_vars t2
   224               |>> (op `$)
   225           | subst_vars (ICase (_, t)) samepairs = subst_vars t samepairs;
   226         val (args', _) = fold_map subst_vars args samepairs;
   227       in (samepairs, args') end;
   228 
   229     fun assemble_eqn c dicts default_args (i, (args, rhs)) =
   230       let
   231         val is_eval = (c = "");
   232         val default_rhs = nbe_apps_local (i+1) c (dicts @ default_args);
   233         val match_cont = if is_eval then NONE else SOME default_rhs;
   234         val assemble_arg = assemble_iterm
   235           (fn c => fn _ => fn ts => nbe_apps_constr idx_of c ts) NONE;
   236         val assemble_rhs = assemble_iterm assemble_constapp match_cont ;
   237         val (samepairs, args') = subst_nonlin_vars args;
   238         val s_args = map assemble_arg args';
   239         val s_rhs = if null samepairs then assemble_rhs rhs
   240           else ml_if (ml_and (map (uncurry nbe_same) samepairs))
   241             (assemble_rhs rhs) default_rhs;
   242         val eqns = if is_eval then
   243             [([ml_list (rev (dicts @ s_args))], s_rhs)]
   244           else
   245             [([ml_list (rev (dicts @ map2 ml_as default_args s_args))], s_rhs),
   246               ([ml_list (rev (dicts @ default_args))], default_rhs)]
   247       in (nbe_fun i c, eqns) end;
   248 
   249     fun assemble_eqns (c, (num_args, (dicts, eqns))) =
   250       let
   251         val default_args = map nbe_default
   252           (Name.invent_list [] "a" (num_args - length dicts));
   253         val eqns' = map_index (assemble_eqn c dicts default_args) eqns
   254           @ (if c = "" then [] else [(nbe_fun (length eqns) c,
   255             [([ml_list (rev (dicts @ default_args))],
   256               nbe_apps_constr idx_of c (dicts @ default_args))])]);
   257       in (eqns', nbe_abss num_args (nbe_fun 0 c)) end;
   258 
   259     val (fun_vars, fun_vals) = map_split assemble_eqns eqnss';
   260     val deps_vars = ml_list (map (nbe_fun 0) deps);
   261   in ml_abs deps_vars (ml_Let (ml_fundefs (flat fun_vars)) (ml_list fun_vals)) end;
   262 
   263 (* code compilation *)
   264 
   265 fun compile_eqnss _ gr raw_deps [] = []
   266   | compile_eqnss ctxt gr raw_deps eqnss =
   267       let
   268         val (deps, deps_vals) = split_list (map_filter
   269           (fn dep => Option.map (fn univ => (dep, univ)) (fst ((Graph.get_node gr dep)))) raw_deps);
   270         val idx_of = raw_deps
   271           |> map (fn dep => (dep, snd (Graph.get_node gr dep)))
   272           |> AList.lookup (op =)
   273           |> (fn f => the o f);
   274         val s = assemble_eqnss idx_of deps eqnss;
   275         val cs = map fst eqnss;
   276       in
   277         s
   278         |> tracing (fn s => "\n--- code to be evaluated:\n" ^ s)
   279         |> ML_Context.evaluate ctxt (!trace) univs_cookie
   280         |> (fn f => f deps_vals)
   281         |> (fn univs => cs ~~ univs)
   282       end;
   283 
   284 
   285 (* preparing function equations *)
   286 
   287 fun eqns_of_stmt (_, Code_Thingol.Fun (_, (_, []))) =
   288       []
   289   | eqns_of_stmt (const, Code_Thingol.Fun (_, ((vs, _), eqns))) =
   290       [(const, (vs, map fst eqns))]
   291   | eqns_of_stmt (_, Code_Thingol.Datatypecons _) =
   292       []
   293   | eqns_of_stmt (_, Code_Thingol.Datatype _) =
   294       []
   295   | eqns_of_stmt (class, Code_Thingol.Class (_, (v, (superclasses, classops)))) =
   296       let
   297         val names = map snd superclasses @ map fst classops;
   298         val params = Name.invent_list [] "d" (length names);
   299         fun mk (k, name) =
   300           (name, ([(v, [])],
   301             [([IConst (class, (([], []), [])) `$$ map (IVar o SOME) params],
   302               IVar (SOME (nth params k)))]));
   303       in map_index mk names end
   304   | eqns_of_stmt (_, Code_Thingol.Classrel _) =
   305       []
   306   | eqns_of_stmt (_, Code_Thingol.Classparam _) =
   307       []
   308   | eqns_of_stmt (inst, Code_Thingol.Classinst ((class, (_, arities)), (superinsts, instops))) =
   309       [(inst, (arities, [([], IConst (class, (([], []), [])) `$$
   310         map (fn (_, (_, (inst, dicts))) => IConst (inst, (([], dicts), []))) superinsts
   311         @ map (IConst o snd o fst) instops)]))];
   312 
   313 fun compile_stmts ctxt stmts_deps =
   314   let
   315     val names = map (fst o fst) stmts_deps;
   316     val names_deps = map (fn ((name, _), deps) => (name, deps)) stmts_deps;
   317     val eqnss = maps (eqns_of_stmt o fst) stmts_deps;
   318     val refl_deps = names_deps
   319       |> maps snd
   320       |> distinct (op =)
   321       |> fold (insert (op =)) names;
   322     fun new_node name (gr, (maxidx, idx_tab)) = if can (Graph.get_node gr) name
   323       then (gr, (maxidx, idx_tab))
   324       else (Graph.new_node (name, (NONE, maxidx)) gr,
   325         (maxidx + 1, Inttab.update_new (maxidx, name) idx_tab));
   326     fun compile gr = eqnss
   327       |> compile_eqnss ctxt gr refl_deps
   328       |> rpair gr;
   329   in
   330     fold new_node refl_deps
   331     #> apfst (fold (fn (name, deps) => fold (curry Graph.add_edge name) deps) names_deps
   332       #> compile
   333       #-> fold (fn (name, univ) => (Graph.map_node name o apfst) (K (SOME univ))))
   334   end;
   335 
   336 fun ensure_stmts ctxt naming program =
   337   let
   338     fun add_stmts names (gr, (maxidx, idx_tab)) = if exists ((can o Graph.get_node) gr) names
   339       then (gr, (maxidx, idx_tab))
   340       else (gr, (maxidx, idx_tab))
   341         |> compile_stmts ctxt (map (fn name => ((name, Graph.get_node program name),
   342           Graph.imm_succs program name)) names);
   343   in
   344     fold_rev add_stmts (Graph.strong_conn program)
   345     #> pair naming
   346   end;
   347 
   348 
   349 (** evaluation **)
   350 
   351 (* term evaluation *)
   352 
   353 fun eval_term ctxt gr deps (vs : (string * sort) list, t) =
   354   let 
   355     val dict_frees = maps (fn (v, sort) => map_index (curry DFree v o fst) sort) vs;
   356   in
   357     ("", (vs, [([], t)]))
   358     |> singleton (compile_eqnss ctxt gr deps)
   359     |> snd
   360     |> (fn t => apps t (rev dict_frees))
   361   end;
   362 
   363 (* reification *)
   364 
   365 fun typ_of_itype program vs (ityco `%% itys) =
   366       let
   367         val Code_Thingol.Datatype (tyco, _) = Graph.get_node program ityco;
   368       in Type (tyco, map (typ_of_itype program vs) itys) end
   369   | typ_of_itype program vs (ITyVar v) =
   370       let
   371         val sort = (the o AList.lookup (op =) vs) v;
   372       in TFree ("'" ^ v, sort) end;
   373 
   374 fun term_of_univ thy program idx_tab t =
   375   let
   376     fun take_until f [] = []
   377       | take_until f (x::xs) = if f x then [] else x :: take_until f xs;
   378     fun is_dict (Const (idx, _)) = (case (Graph.get_node program o the o Inttab.lookup idx_tab) idx
   379          of Code_Thingol.Class _ => true
   380           | Code_Thingol.Classrel _ => true
   381           | Code_Thingol.Classinst _ => true
   382           | _ => false)
   383       | is_dict (DFree _) = true
   384       | is_dict _ = false;
   385     fun const_of_idx idx = (case (Graph.get_node program o the o Inttab.lookup idx_tab) idx
   386          of Code_Thingol.Fun (c, _) => c
   387           | Code_Thingol.Datatypecons (c, _) => c
   388           | Code_Thingol.Classparam (c, _) => c);
   389     fun of_apps bounds (t, ts) =
   390       fold_map (of_univ bounds) ts
   391       #>> (fn ts' => list_comb (t, rev ts'))
   392     and of_univ bounds (Const (idx, ts)) typidx =
   393           let
   394             val ts' = take_until is_dict ts;
   395             val c = const_of_idx idx;
   396             val T = map_type_tvar (fn ((v, i), _) =>
   397               TypeInfer.param typidx (v ^ string_of_int i, []))
   398                 (Sign.the_const_type thy c);
   399             val typidx' = typidx + 1;
   400           in of_apps bounds (Term.Const (c, T), ts') typidx' end
   401       | of_univ bounds (BVar (n, ts)) typidx =
   402           of_apps bounds (Bound (bounds - n - 1), ts) typidx
   403       | of_univ bounds (t as Abs _) typidx =
   404           typidx
   405           |> of_univ (bounds + 1) (apps t [BVar (bounds, [])])
   406           |-> (fn t' => pair (Term.Abs ("u", dummyT, t')))
   407   in of_univ 0 t 0 |> fst end;
   408 
   409 (* function store *)
   410 
   411 structure Nbe_Functions = Code_Data_Fun
   412 (
   413   type T = Code_Thingol.naming * ((Univ option * int) Graph.T * (int * string Inttab.table));
   414   val empty = (Code_Thingol.empty_naming, (Graph.empty, (0, Inttab.empty)));
   415   fun purge thy cs (naming, (gr, (maxidx, idx_tab))) =
   416     let
   417       val names_delete = cs
   418         |> map_filter (Code_Thingol.lookup_const naming)
   419         |> filter (can (Graph.get_node gr))
   420         |> Graph.all_preds gr;
   421       val gr' = Graph.del_nodes names_delete gr;
   422     in (naming, (gr', (maxidx, idx_tab))) end;
   423 );
   424 
   425 (* compilation, evaluation and reification *)
   426 
   427 fun compile_eval thy naming program vs_t deps =
   428   let
   429     val ctxt = ProofContext.init thy;
   430     val (_, (gr, (_, idx_tab))) =
   431       Nbe_Functions.change thy (ensure_stmts ctxt naming program o snd);
   432   in
   433     vs_t
   434     |> eval_term ctxt gr deps
   435     |> term_of_univ thy program idx_tab
   436   end;
   437 
   438 (* evaluation with type reconstruction *)
   439 
   440 fun normalize thy naming program ((vs0, (vs, ty)), t) deps =
   441   let
   442     fun subst_const f = map_aterms (fn t as Term.Const (c, ty) => Term.Const (f c, ty)
   443       | t => t);
   444     val resubst_triv_consts = subst_const (Code.resubst_alias thy);
   445     val ty' = typ_of_itype program vs0 ty;
   446     fun type_infer t =
   447       singleton (TypeInfer.infer_types (Syntax.pp_global thy) (Sign.tsig_of thy) I
   448         (try (Type.strip_sorts o Sign.the_const_type thy)) (K NONE) Name.context 0)
   449       (TypeInfer.constrain ty' t);
   450     fun check_tvars t = if null (Term.add_tvars t []) then t else
   451       error ("Illegal schematic type variables in normalized term: "
   452         ^ setmp show_types true (Syntax.string_of_term_global thy) t);
   453     val string_of_term = setmp show_types true (Syntax.string_of_term_global thy);
   454   in
   455     compile_eval thy naming program (vs, t) deps
   456     |> tracing (fn t => "Normalized:\n" ^ string_of_term t)
   457     |> resubst_triv_consts
   458     |> type_infer
   459     |> tracing (fn t => "Types inferred:\n" ^ string_of_term t)
   460     |> check_tvars
   461     |> tracing (fn t => "---\n")
   462   end;
   463 
   464 (* evaluation oracle *)
   465 
   466 fun add_triv_classes thy = curry (Sorts.inter_sort (Sign.classes_of thy))
   467   (Code.triv_classes thy);
   468 
   469 fun mk_equals thy lhs raw_rhs =
   470   let
   471     val ty = Thm.typ_of (Thm.ctyp_of_term lhs);
   472     val eq = Thm.cterm_of thy (Term.Const ("==", ty --> ty --> propT));
   473     val rhs = Thm.cterm_of thy raw_rhs;
   474   in Thm.mk_binop eq lhs rhs end;
   475 
   476 val (_, raw_norm_oracle) = Context.>>> (Context.map_theory_result
   477   (Thm.add_oracle (Binding.name "norm", fn (thy, naming, program, vsp_ty_t, deps, ct) =>
   478     mk_equals thy ct (normalize thy naming program vsp_ty_t deps))));
   479 
   480 fun norm_oracle thy naming program vsp_ty_t deps ct =
   481   raw_norm_oracle (thy, naming, program, vsp_ty_t, deps, ct);
   482 
   483 fun no_frees_conv conv ct =
   484   let
   485     val frees = Thm.add_cterm_frees ct [];
   486     fun apply_beta free thm = Thm.combination thm (Thm.reflexive free)
   487       |> Conv.fconv_rule (Conv.arg_conv (Conv.try_conv (Thm.beta_conversion false)))
   488       |> Conv.fconv_rule (Conv.arg1_conv (Thm.beta_conversion false));
   489   in
   490     ct
   491     |> fold_rev Thm.cabs frees
   492     |> conv
   493     |> fold apply_beta frees
   494   end;
   495 
   496 fun no_frees_rew rew t =
   497   let
   498     val frees = map Free (Term.add_frees t []);
   499   in
   500     t
   501     |> fold_rev lambda frees
   502     |> rew
   503     |> (fn t' => Term.betapplys (t', frees))
   504   end;
   505 
   506 val norm_conv = no_frees_conv (fn ct =>
   507   let
   508     val thy = Thm.theory_of_cterm ct;
   509   in Code_Thingol.eval_conv thy (add_triv_classes thy) (norm_oracle thy) ct end);
   510 
   511 fun norm thy = no_frees_rew (Code_Thingol.eval thy (add_triv_classes thy) I (normalize thy));
   512 
   513 (* evaluation command *)
   514 
   515 fun norm_print_term ctxt modes t =
   516   let
   517     val thy = ProofContext.theory_of ctxt;
   518     val t' = norm thy t;
   519     val ty' = Term.type_of t';
   520     val ctxt' = Variable.auto_fixes t ctxt;
   521     val p = PrintMode.with_modes modes (fn () =>
   522       Pretty.block [Pretty.quote (Syntax.pretty_term ctxt' t'), Pretty.fbrk,
   523         Pretty.str "::", Pretty.brk 1, Pretty.quote (Syntax.pretty_typ ctxt' ty')]) ();
   524   in Pretty.writeln p end;
   525 
   526 
   527 (** Isar setup **)
   528 
   529 fun norm_print_term_cmd (modes, s) state =
   530   let val ctxt = Toplevel.context_of state
   531   in norm_print_term ctxt modes (Syntax.read_term ctxt s) end;
   532 
   533 val setup = Value.add_evaluator ("nbe", norm o ProofContext.theory_of);
   534 
   535 local structure P = OuterParse and K = OuterKeyword in
   536 
   537 val opt_modes = Scan.optional (P.$$$ "(" |-- P.!!! (Scan.repeat1 P.xname --| P.$$$ ")")) [];
   538 
   539 val _ =
   540   OuterSyntax.improper_command "normal_form" "normalize term by evaluation" K.diag
   541     (opt_modes -- P.term >> (Toplevel.keep o norm_print_term_cmd));
   542 
   543 end;
   544 
   545 end;
   546