src/HOL/Binomial.thy
 author wenzelm Sun Sep 18 20:33:48 2016 +0200 (2016-09-18) changeset 63915 bab633745c7f parent 63882 018998c00003 child 63918 6bf55e6e0b75 permissions -rw-r--r--
tuned proofs;
     1 (*  Title:      HOL/Binomial.thy

     2     Author:     Jacques D. Fleuriot

     3     Author:     Lawrence C Paulson

     4     Author:     Jeremy Avigad

     5     Author:     Chaitanya Mangla

     6     Author:     Manuel Eberl

     7 *)

     8

     9 section \<open>Combinatorial Functions: Factorial Function, Rising Factorials, Binomial Coefficients and Binomial Theorem\<close>

    10

    11 theory Binomial

    12   imports Main

    13 begin

    14

    15 subsection \<open>Factorial\<close>

    16

    17 context semiring_char_0

    18 begin

    19

    20 definition fact :: "nat \<Rightarrow> 'a"

    21   where fact_setprod: "fact n = of_nat (\<Prod>{1..n})"

    22

    23 lemma fact_setprod_Suc: "fact n = of_nat (setprod Suc {0..<n})"

    24   by (cases n)

    25     (simp_all add: fact_setprod setprod.atLeast_Suc_atMost_Suc_shift

    26       atLeastLessThanSuc_atLeastAtMost)

    27

    28 lemma fact_setprod_rev: "fact n = of_nat (\<Prod>i = 0..<n. n - i)"

    29   using setprod.atLeast_atMost_rev [of "\<lambda>i. i" 1 n]

    30   by (cases n)

    31     (simp_all add: fact_setprod_Suc setprod.atLeast_Suc_atMost_Suc_shift

    32       atLeastLessThanSuc_atLeastAtMost)

    33

    34 lemma fact_0 [simp]: "fact 0 = 1"

    35   by (simp add: fact_setprod)

    36

    37 lemma fact_1 [simp]: "fact 1 = 1"

    38   by (simp add: fact_setprod)

    39

    40 lemma fact_Suc_0 [simp]: "fact (Suc 0) = 1"

    41   by (simp add: fact_setprod)

    42

    43 lemma fact_Suc [simp]: "fact (Suc n) = of_nat (Suc n) * fact n"

    44   by (simp add: fact_setprod atLeastAtMostSuc_conv algebra_simps)

    45

    46 lemma fact_2 [simp]: "fact 2 = 2"

    47   by (simp add: numeral_2_eq_2)

    48

    49 lemma fact_split: "k \<le> n \<Longrightarrow> fact n = of_nat (setprod Suc {n - k..<n}) * fact (n - k)"

    50   by (simp add: fact_setprod_Suc setprod.union_disjoint [symmetric]

    51     ivl_disj_un ac_simps of_nat_mult [symmetric])

    52

    53 end

    54

    55 lemma of_nat_fact [simp]: "of_nat (fact n) = fact n"

    56   by (simp add: fact_setprod)

    57

    58 lemma of_int_fact [simp]: "of_int (fact n) = fact n"

    59   by (simp only: fact_setprod of_int_of_nat_eq)

    60

    61 lemma fact_reduce: "n > 0 \<Longrightarrow> fact n = of_nat n * fact (n - 1)"

    62   by (cases n) auto

    63

    64 lemma fact_nonzero [simp]: "fact n \<noteq> (0::'a::{semiring_char_0,semiring_no_zero_divisors})"

    65   apply (induct n)

    66   apply auto

    67   using of_nat_eq_0_iff

    68   apply fastforce

    69   done

    70

    71 lemma fact_mono_nat: "m \<le> n \<Longrightarrow> fact m \<le> (fact n :: nat)"

    72   by (induct n) (auto simp: le_Suc_eq)

    73

    74 lemma fact_in_Nats: "fact n \<in> \<nat>"

    75   by (induct n) auto

    76

    77 lemma fact_in_Ints: "fact n \<in> \<int>"

    78   by (induct n) auto

    79

    80 context

    81   assumes "SORT_CONSTRAINT('a::linordered_semidom)"

    82 begin

    83

    84 lemma fact_mono: "m \<le> n \<Longrightarrow> fact m \<le> (fact n :: 'a)"

    85   by (metis of_nat_fact of_nat_le_iff fact_mono_nat)

    86

    87 lemma fact_ge_1 [simp]: "fact n \<ge> (1 :: 'a)"

    88   by (metis le0 fact_0 fact_mono)

    89

    90 lemma fact_gt_zero [simp]: "fact n > (0 :: 'a)"

    91   using fact_ge_1 less_le_trans zero_less_one by blast

    92

    93 lemma fact_ge_zero [simp]: "fact n \<ge> (0 :: 'a)"

    94   by (simp add: less_imp_le)

    95

    96 lemma fact_not_neg [simp]: "\<not> fact n < (0 :: 'a)"

    97   by (simp add: not_less_iff_gr_or_eq)

    98

    99 lemma fact_le_power: "fact n \<le> (of_nat (n^n) :: 'a)"

   100 proof (induct n)

   101   case 0

   102   then show ?case by simp

   103 next

   104   case (Suc n)

   105   then have *: "fact n \<le> (of_nat (Suc n ^ n) ::'a)"

   106     by (rule order_trans) (simp add: power_mono del: of_nat_power)

   107   have "fact (Suc n) = (of_nat (Suc n) * fact n ::'a)"

   108     by (simp add: algebra_simps)

   109   also have "\<dots> \<le> of_nat (Suc n) * of_nat (Suc n ^ n)"

   110     by (simp add: * ordered_comm_semiring_class.comm_mult_left_mono del: of_nat_power)

   111   also have "\<dots> \<le> of_nat (Suc n ^ Suc n)"

   112     by (metis of_nat_mult order_refl power_Suc)

   113   finally show ?case .

   114 qed

   115

   116 end

   117

   118 text \<open>Note that @{term "fact 0 = fact 1"}\<close>

   119 lemma fact_less_mono_nat: "0 < m \<Longrightarrow> m < n \<Longrightarrow> fact m < (fact n :: nat)"

   120   by (induct n) (auto simp: less_Suc_eq)

   121

   122 lemma fact_less_mono: "0 < m \<Longrightarrow> m < n \<Longrightarrow> fact m < (fact n :: 'a::linordered_semidom)"

   123   by (metis of_nat_fact of_nat_less_iff fact_less_mono_nat)

   124

   125 lemma fact_ge_Suc_0_nat [simp]: "fact n \<ge> Suc 0"

   126   by (metis One_nat_def fact_ge_1)

   127

   128 lemma dvd_fact: "1 \<le> m \<Longrightarrow> m \<le> n \<Longrightarrow> m dvd fact n"

   129   by (induct n) (auto simp: dvdI le_Suc_eq)

   130

   131 lemma fact_ge_self: "fact n \<ge> n"

   132   by (cases "n = 0") (simp_all add: dvd_imp_le dvd_fact)

   133

   134 lemma fact_dvd: "n \<le> m \<Longrightarrow> fact n dvd (fact m :: 'a::{semiring_div,linordered_semidom})"

   135   by (induct m) (auto simp: le_Suc_eq)

   136

   137 lemma fact_mod: "m \<le> n \<Longrightarrow> fact n mod (fact m :: 'a::{semiring_div,linordered_semidom}) = 0"

   138   by (auto simp add: fact_dvd)

   139

   140 lemma fact_div_fact:

   141   assumes "m \<ge> n"

   142   shows "fact m div fact n = \<Prod>{n + 1..m}"

   143 proof -

   144   obtain d where "d = m - n"

   145     by auto

   146   with assms have "m = n + d"

   147     by auto

   148   have "fact (n + d) div (fact n) = \<Prod>{n + 1..n + d}"

   149   proof (induct d)

   150     case 0

   151     show ?case by simp

   152   next

   153     case (Suc d')

   154     have "fact (n + Suc d') div fact n = Suc (n + d') * fact (n + d') div fact n"

   155       by simp

   156     also from Suc.hyps have "\<dots> = Suc (n + d') * \<Prod>{n + 1..n + d'}"

   157       unfolding div_mult1_eq[of _ "fact (n + d')"] by (simp add: fact_mod)

   158     also have "\<dots> = \<Prod>{n + 1..n + Suc d'}"

   159       by (simp add: atLeastAtMostSuc_conv)

   160     finally show ?case .

   161   qed

   162   with \<open>m = n + d\<close> show ?thesis by simp

   163 qed

   164

   165 lemma fact_num_eq_if: "fact m = (if m = 0 then 1 else of_nat m * fact (m - 1))"

   166   by (cases m) auto

   167

   168 lemma fact_div_fact_le_pow:

   169   assumes "r \<le> n"

   170   shows "fact n div fact (n - r) \<le> n ^ r"

   171 proof -

   172   have "r \<le> n \<Longrightarrow> \<Prod>{n - r..n} = (n - r) * \<Prod>{Suc (n - r)..n}" for r

   173     by (subst setprod.insert[symmetric]) (auto simp: atLeastAtMost_insertL)

   174   with assms show ?thesis

   175     by (induct r rule: nat.induct) (auto simp add: fact_div_fact Suc_diff_Suc mult_le_mono)

   176 qed

   177

   178 lemma fact_numeral: "fact (numeral k) = numeral k * fact (pred_numeral k)"

   179   \<comment> \<open>Evaluation for specific numerals\<close>

   180   by (metis fact_Suc numeral_eq_Suc of_nat_numeral)

   181

   182

   183 subsection \<open>Binomial coefficients\<close>

   184

   185 text \<open>This development is based on the work of Andy Gordon and Florian Kammueller.\<close>

   186

   187 text \<open>Combinatorial definition\<close>

   188

   189 definition binomial :: "nat \<Rightarrow> nat \<Rightarrow> nat"  (infixl "choose" 65)

   190   where "n choose k = card {K\<in>Pow {0..<n}. card K = k}"

   191

   192 theorem n_subsets:

   193   assumes "finite A"

   194   shows "card {B. B \<subseteq> A \<and> card B = k} = card A choose k"

   195 proof -

   196   from assms obtain f where bij: "bij_betw f {0..<card A} A"

   197     by (blast dest: ex_bij_betw_nat_finite)

   198   then have [simp]: "card (f  C) = card C" if "C \<subseteq> {0..<card A}" for C

   199     by (meson bij_betw_imp_inj_on bij_betw_subset card_image that)

   200   from bij have "bij_betw (image f) (Pow {0..<card A}) (Pow A)"

   201     by (rule bij_betw_Pow)

   202   then have "inj_on (image f) (Pow {0..<card A})"

   203     by (rule bij_betw_imp_inj_on)

   204   moreover have "{K. K \<subseteq> {0..<card A} \<and> card K = k} \<subseteq> Pow {0..<card A}"

   205     by auto

   206   ultimately have "inj_on (image f) {K. K \<subseteq> {0..<card A} \<and> card K = k}"

   207     by (rule inj_on_subset)

   208   then have "card {K. K \<subseteq> {0..<card A} \<and> card K = k} =

   209       card (image f  {K. K \<subseteq> {0..<card A} \<and> card K = k})" (is "_ = card ?C")

   210     by (simp add: card_image)

   211   also have "?C = {K. K \<subseteq> f  {0..<card A} \<and> card K = k}"

   212     by (auto elim!: subset_imageE)

   213   also have "f  {0..<card A} = A"

   214     by (meson bij bij_betw_def)

   215   finally show ?thesis

   216     by (simp add: binomial_def)

   217 qed

   218

   219 text \<open>Recursive characterization\<close>

   220

   221 lemma binomial_n_0 [simp, code]: "n choose 0 = 1"

   222 proof -

   223   have "{K \<in> Pow {0..<n}. card K = 0} = {{}}"

   224     by (auto dest: finite_subset)

   225   then show ?thesis

   226     by (simp add: binomial_def)

   227 qed

   228

   229 lemma binomial_0_Suc [simp, code]: "0 choose Suc k = 0"

   230   by (simp add: binomial_def)

   231

   232 lemma binomial_Suc_Suc [simp, code]: "Suc n choose Suc k = (n choose k) + (n choose Suc k)"

   233 proof -

   234   let ?P = "\<lambda>n k. {K. K \<subseteq> {0..<n} \<and> card K = k}"

   235   let ?Q = "?P (Suc n) (Suc k)"

   236   have inj: "inj_on (insert n) (?P n k)"

   237     by rule (auto; metis atLeastLessThan_iff insert_iff less_irrefl subsetCE)

   238   have disjoint: "insert n  ?P n k \<inter> ?P n (Suc k) = {}"

   239     by auto

   240   have "?Q = {K\<in>?Q. n \<in> K} \<union> {K\<in>?Q. n \<notin> K}"

   241     by auto

   242   also have "{K\<in>?Q. n \<in> K} = insert n  ?P n k" (is "?A = ?B")

   243   proof (rule set_eqI)

   244     fix K

   245     have K_finite: "finite K" if "K \<subseteq> insert n {0..<n}"

   246       using that by (rule finite_subset) simp_all

   247     have Suc_card_K: "Suc (card K - Suc 0) = card K" if "n \<in> K"

   248       and "finite K"

   249     proof -

   250       from \<open>n \<in> K\<close> obtain L where "K = insert n L" and "n \<notin> L"

   251         by (blast elim: Set.set_insert)

   252       with that show ?thesis by (simp add: card_insert)

   253     qed

   254     show "K \<in> ?A \<longleftrightarrow> K \<in> ?B"

   255       by (subst in_image_insert_iff)

   256         (auto simp add: card_insert subset_eq_atLeast0_lessThan_finite

   257           Diff_subset_conv K_finite Suc_card_K)

   258   qed

   259   also have "{K\<in>?Q. n \<notin> K} = ?P n (Suc k)"

   260     by (auto simp add: atLeast0_lessThan_Suc)

   261   finally show ?thesis using inj disjoint

   262     by (simp add: binomial_def card_Un_disjoint card_image)

   263 qed

   264

   265 lemma binomial_eq_0: "n < k \<Longrightarrow> n choose k = 0"

   266   by (auto simp add: binomial_def dest: subset_eq_atLeast0_lessThan_card)

   267

   268 lemma zero_less_binomial: "k \<le> n \<Longrightarrow> n choose k > 0"

   269   by (induct n k rule: diff_induct) simp_all

   270

   271 lemma binomial_eq_0_iff [simp]: "n choose k = 0 \<longleftrightarrow> n < k"

   272   by (metis binomial_eq_0 less_numeral_extra(3) not_less zero_less_binomial)

   273

   274 lemma zero_less_binomial_iff [simp]: "n choose k > 0 \<longleftrightarrow> k \<le> n"

   275   by (metis binomial_eq_0_iff not_less0 not_less zero_less_binomial)

   276

   277 lemma binomial_n_n [simp]: "n choose n = 1"

   278   by (induct n) (simp_all add: binomial_eq_0)

   279

   280 lemma binomial_Suc_n [simp]: "Suc n choose n = Suc n"

   281   by (induct n) simp_all

   282

   283 lemma binomial_1 [simp]: "n choose Suc 0 = n"

   284   by (induct n) simp_all

   285

   286 lemma choose_reduce_nat:

   287   "0 < n \<Longrightarrow> 0 < k \<Longrightarrow>

   288     n choose k = ((n - 1) choose (k - 1)) + ((n - 1) choose k)"

   289   using binomial_Suc_Suc [of "n - 1" "k - 1"] by simp

   290

   291 lemma Suc_times_binomial_eq: "Suc n * (n choose k) = (Suc n choose Suc k) * Suc k"

   292   apply (induct n arbitrary: k)

   293    apply simp

   294    apply arith

   295   apply (case_tac k)

   296    apply (auto simp add: add_mult_distrib add_mult_distrib2 le_Suc_eq binomial_eq_0)

   297   done

   298

   299 lemma binomial_le_pow2: "n choose k \<le> 2^n"

   300   apply (induct n arbitrary: k)

   301    apply (case_tac k)

   302     apply simp_all

   303   apply (case_tac k)

   304    apply auto

   305   apply (simp add: add_le_mono mult_2)

   306   done

   307

   308 text \<open>The absorption property.\<close>

   309 lemma Suc_times_binomial: "Suc k * (Suc n choose Suc k) = Suc n * (n choose k)"

   310   using Suc_times_binomial_eq by auto

   311

   312 text \<open>This is the well-known version of absorption, but it's harder to use

   313   because of the need to reason about division.\<close>

   314 lemma binomial_Suc_Suc_eq_times: "(Suc n choose Suc k) = (Suc n * (n choose k)) div Suc k"

   315   by (simp add: Suc_times_binomial_eq del: mult_Suc mult_Suc_right)

   316

   317 text \<open>Another version of absorption, with \<open>-1\<close> instead of \<open>Suc\<close>.\<close>

   318 lemma times_binomial_minus1_eq: "0 < k \<Longrightarrow> k * (n choose k) = n * ((n - 1) choose (k - 1))"

   319   using Suc_times_binomial_eq [where n = "n - 1" and k = "k - 1"]

   320   by (auto split: nat_diff_split)

   321

   322

   323 subsection \<open>The binomial theorem (courtesy of Tobias Nipkow):\<close>

   324

   325 text \<open>Avigad's version, generalized to any commutative ring\<close>

   326 theorem binomial_ring: "(a + b :: 'a::{comm_ring_1,power})^n =

   327   (\<Sum>k=0..n. (of_nat (n choose k)) * a^k * b^(n-k))"

   328 proof (induct n)

   329   case 0

   330   then show ?case by simp

   331 next

   332   case (Suc n)

   333   have decomp: "{0..n+1} = {0} \<union> {n + 1} \<union> {1..n}"

   334     by auto

   335   have decomp2: "{0..n} = {0} \<union> {1..n}"

   336     by auto

   337   have "(a + b)^(n+1) = (a + b) * (\<Sum>k=0..n. of_nat (n choose k) * a^k * b^(n - k))"

   338     using Suc.hyps by simp

   339   also have "\<dots> = a * (\<Sum>k=0..n. of_nat (n choose k) * a^k * b^(n-k)) +

   340       b * (\<Sum>k=0..n. of_nat (n choose k) * a^k * b^(n-k))"

   341     by (rule distrib_right)

   342   also have "\<dots> = (\<Sum>k=0..n. of_nat (n choose k) * a^(k+1) * b^(n-k)) +

   343       (\<Sum>k=0..n. of_nat (n choose k) * a^k * b^(n - k + 1))"

   344     by (auto simp add: setsum_right_distrib ac_simps)

   345   also have "\<dots> = (\<Sum>k=0..n. of_nat (n choose k) * a^k * b^(n + 1 - k)) +

   346       (\<Sum>k=1..n+1. of_nat (n choose (k - 1)) * a^k * b^(n + 1 - k))"

   347     by (simp add:setsum_shift_bounds_cl_Suc_ivl Suc_diff_le field_simps del: setsum_cl_ivl_Suc)

   348   also have "\<dots> = a^(n + 1) + b^(n + 1) +

   349       (\<Sum>k=1..n. of_nat (n choose (k - 1)) * a^k * b^(n + 1 - k)) +

   350       (\<Sum>k=1..n. of_nat (n choose k) * a^k * b^(n + 1 - k))"

   351     by (simp add: decomp2)

   352   also have "\<dots> = a^(n + 1) + b^(n + 1) +

   353       (\<Sum>k=1..n. of_nat (n + 1 choose k) * a^k * b^(n + 1 - k))"

   354     by (auto simp add: field_simps setsum.distrib [symmetric] choose_reduce_nat)

   355   also have "\<dots> = (\<Sum>k=0..n+1. of_nat (n + 1 choose k) * a^k * b^(n + 1 - k))"

   356     using decomp by (simp add: field_simps)

   357   finally show ?case

   358     by simp

   359 qed

   360

   361 text \<open>Original version for the naturals.\<close>

   362 corollary binomial: "(a + b :: nat)^n = (\<Sum>k=0..n. (of_nat (n choose k)) * a^k * b^(n - k))"

   363   using binomial_ring [of "int a" "int b" n]

   364   by (simp only: of_nat_add [symmetric] of_nat_mult [symmetric] of_nat_power [symmetric]

   365       of_nat_setsum [symmetric] of_nat_eq_iff of_nat_id)

   366

   367 lemma binomial_fact_lemma: "k \<le> n \<Longrightarrow> fact k * fact (n - k) * (n choose k) = fact n"

   368 proof (induct n arbitrary: k rule: nat_less_induct)

   369   fix n k

   370   assume H: "\<forall>m<n. \<forall>x\<le>m. fact x * fact (m - x) * (m choose x) = fact m"

   371   assume kn: "k \<le> n"

   372   let ?ths = "fact k * fact (n - k) * (n choose k) = fact n"

   373   consider "n = 0 \<or> k = 0 \<or> n = k" | m h where "n = Suc m" "k = Suc h" "h < m"

   374     using kn by atomize_elim presburger

   375   then show "fact k * fact (n - k) * (n choose k) = fact n"

   376   proof cases

   377     case 1

   378     with kn show ?thesis by auto

   379   next

   380     case 2

   381     note n = \<open>n = Suc m\<close>

   382     note k = \<open>k = Suc h\<close>

   383     note hm = \<open>h < m\<close>

   384     have mn: "m < n"

   385       using n by arith

   386     have hm': "h \<le> m"

   387       using hm by arith

   388     have km: "k \<le> m"

   389       using hm k n kn by arith

   390     have "m - h = Suc (m - Suc h)"

   391       using  k km hm by arith

   392     with km k have "fact (m - h) = (m - h) * fact (m - k)"

   393       by simp

   394     with n k have "fact k * fact (n - k) * (n choose k) =

   395         k * (fact h * fact (m - h) * (m choose h)) +

   396         (m - h) * (fact k * fact (m - k) * (m choose k))"

   397       by (simp add: field_simps)

   398     also have "\<dots> = (k + (m - h)) * fact m"

   399       using H[rule_format, OF mn hm'] H[rule_format, OF mn km]

   400       by (simp add: field_simps)

   401     finally show ?thesis

   402       using k n km by simp

   403   qed

   404 qed

   405

   406 lemma binomial_fact':

   407   assumes "k \<le> n"

   408   shows "n choose k = fact n div (fact k * fact (n - k))"

   409   using binomial_fact_lemma [OF assms]

   410   by (metis fact_nonzero mult_eq_0_iff nonzero_mult_divide_cancel_left)

   411

   412 lemma binomial_fact:

   413   assumes kn: "k \<le> n"

   414   shows "(of_nat (n choose k) :: 'a::field_char_0) = fact n / (fact k * fact (n - k))"

   415   using binomial_fact_lemma[OF kn]

   416   apply (simp add: field_simps)

   417   apply (metis mult.commute of_nat_fact of_nat_mult)

   418   done

   419

   420 lemma fact_binomial:

   421   assumes "k \<le> n"

   422   shows "fact k * of_nat (n choose k) = (fact n / fact (n - k) :: 'a::field_char_0)"

   423   unfolding binomial_fact [OF assms] by (simp add: field_simps)

   424

   425 lemma choose_two: "n choose 2 = n * (n - 1) div 2"

   426 proof (cases "n \<ge> 2")

   427   case False

   428   then have "n = 0 \<or> n = 1"

   429     by auto

   430   then show ?thesis by auto

   431 next

   432   case True

   433   define m where "m = n - 2"

   434   with True have "n = m + 2"

   435     by simp

   436   then have "fact n = n * (n - 1) * fact (n - 2)"

   437     by (simp add: fact_setprod_Suc atLeast0_lessThan_Suc algebra_simps)

   438   with True show ?thesis

   439     by (simp add: binomial_fact')

   440 qed

   441

   442 lemma choose_row_sum: "(\<Sum>k=0..n. n choose k) = 2^n"

   443   using binomial [of 1 "1" n] by (simp add: numeral_2_eq_2)

   444

   445 lemma sum_choose_lower: "(\<Sum>k=0..n. (r+k) choose k) = Suc (r+n) choose n"

   446   by (induct n) auto

   447

   448 lemma sum_choose_upper: "(\<Sum>k=0..n. k choose m) = Suc n choose Suc m"

   449   by (induct n) auto

   450

   451 lemma choose_alternating_sum:

   452   "n > 0 \<Longrightarrow> (\<Sum>i\<le>n. (-1)^i * of_nat (n choose i)) = (0 :: 'a::comm_ring_1)"

   453   using binomial_ring[of "-1 :: 'a" 1 n]

   454   by (simp add: atLeast0AtMost mult_of_nat_commute zero_power)

   455

   456 lemma choose_even_sum:

   457   assumes "n > 0"

   458   shows "2 * (\<Sum>i\<le>n. if even i then of_nat (n choose i) else 0) = (2 ^ n :: 'a::comm_ring_1)"

   459 proof -

   460   have "2 ^ n = (\<Sum>i\<le>n. of_nat (n choose i)) + (\<Sum>i\<le>n. (-1) ^ i * of_nat (n choose i) :: 'a)"

   461     using choose_row_sum[of n]

   462     by (simp add: choose_alternating_sum assms atLeast0AtMost of_nat_setsum[symmetric])

   463   also have "\<dots> = (\<Sum>i\<le>n. of_nat (n choose i) + (-1) ^ i * of_nat (n choose i))"

   464     by (simp add: setsum.distrib)

   465   also have "\<dots> = 2 * (\<Sum>i\<le>n. if even i then of_nat (n choose i) else 0)"

   466     by (subst setsum_right_distrib, intro setsum.cong) simp_all

   467   finally show ?thesis ..

   468 qed

   469

   470 lemma choose_odd_sum:

   471   assumes "n > 0"

   472   shows "2 * (\<Sum>i\<le>n. if odd i then of_nat (n choose i) else 0) = (2 ^ n :: 'a::comm_ring_1)"

   473 proof -

   474   have "2 ^ n = (\<Sum>i\<le>n. of_nat (n choose i)) - (\<Sum>i\<le>n. (-1) ^ i * of_nat (n choose i) :: 'a)"

   475     using choose_row_sum[of n]

   476     by (simp add: choose_alternating_sum assms atLeast0AtMost of_nat_setsum[symmetric])

   477   also have "\<dots> = (\<Sum>i\<le>n. of_nat (n choose i) - (-1) ^ i * of_nat (n choose i))"

   478     by (simp add: setsum_subtractf)

   479   also have "\<dots> = 2 * (\<Sum>i\<le>n. if odd i then of_nat (n choose i) else 0)"

   480     by (subst setsum_right_distrib, intro setsum.cong) simp_all

   481   finally show ?thesis ..

   482 qed

   483

   484 lemma choose_row_sum': "(\<Sum>k\<le>n. (n choose k)) = 2 ^ n"

   485   using choose_row_sum[of n] by (simp add: atLeast0AtMost)

   486

   487 text\<open>NW diagonal sum property\<close>

   488 lemma sum_choose_diagonal:

   489   assumes "m \<le> n"

   490   shows "(\<Sum>k=0..m. (n - k) choose (m - k)) = Suc n choose m"

   491 proof -

   492   have "(\<Sum>k=0..m. (n-k) choose (m - k)) = (\<Sum>k=0..m. (n - m + k) choose k)"

   493     using setsum.atLeast_atMost_rev [of "\<lambda>k. (n - k) choose (m - k)" 0 m] assms

   494       by simp

   495   also have "\<dots> = Suc (n - m + m) choose m"

   496     by (rule sum_choose_lower)

   497   also have "\<dots> = Suc n choose m"

   498     using assms by simp

   499   finally show ?thesis .

   500 qed

   501

   502

   503 subsection \<open>Pochhammer's symbol: generalized rising factorial\<close>

   504

   505 text \<open>See \<^url>\<open>http://en.wikipedia.org/wiki/Pochhammer_symbol\<close>.\<close>

   506

   507 context comm_semiring_1

   508 begin

   509

   510 definition pochhammer :: "'a \<Rightarrow> nat \<Rightarrow> 'a"

   511   where pochhammer_setprod: "pochhammer a n = setprod (\<lambda>i. a + of_nat i) {0..<n}"

   512

   513 lemma pochhammer_setprod_rev: "pochhammer a n = setprod (\<lambda>i. a + of_nat (n - i)) {1..n}"

   514   using setprod.atLeast_lessThan_rev_at_least_Suc_atMost [of "\<lambda>i. a + of_nat i" 0 n]

   515   by (simp add: pochhammer_setprod)

   516

   517 lemma pochhammer_Suc_setprod: "pochhammer a (Suc n) = setprod (\<lambda>i. a + of_nat i) {0..n}"

   518   by (simp add: pochhammer_setprod atLeastLessThanSuc_atLeastAtMost)

   519

   520 lemma pochhammer_Suc_setprod_rev: "pochhammer a (Suc n) = setprod (\<lambda>i. a + of_nat (n - i)) {0..n}"

   521   by (simp add: pochhammer_setprod_rev setprod.atLeast_Suc_atMost_Suc_shift)

   522

   523 lemma pochhammer_0 [simp]: "pochhammer a 0 = 1"

   524   by (simp add: pochhammer_setprod)

   525

   526 lemma pochhammer_1 [simp]: "pochhammer a 1 = a"

   527   by (simp add: pochhammer_setprod lessThan_Suc)

   528

   529 lemma pochhammer_Suc0 [simp]: "pochhammer a (Suc 0) = a"

   530   by (simp add: pochhammer_setprod lessThan_Suc)

   531

   532 lemma pochhammer_Suc: "pochhammer a (Suc n) = pochhammer a n * (a + of_nat n)"

   533   by (simp add: pochhammer_setprod atLeast0_lessThan_Suc ac_simps)

   534

   535 end

   536

   537 lemma pochhammer_nonneg:

   538   fixes x :: "'a :: linordered_semidom"

   539   shows "x > 0 \<Longrightarrow> pochhammer x n \<ge> 0"

   540   by (induction n) (auto simp: pochhammer_Suc intro!: mult_nonneg_nonneg add_nonneg_nonneg)

   541

   542 lemma pochhammer_pos:

   543   fixes x :: "'a :: linordered_semidom"

   544   shows "x > 0 \<Longrightarrow> pochhammer x n > 0"

   545   by (induction n) (auto simp: pochhammer_Suc intro!: mult_pos_pos add_pos_nonneg)

   546

   547 lemma pochhammer_of_nat: "pochhammer (of_nat x) n = of_nat (pochhammer x n)"

   548   by (simp add: pochhammer_setprod)

   549

   550 lemma pochhammer_of_int: "pochhammer (of_int x) n = of_int (pochhammer x n)"

   551   by (simp add: pochhammer_setprod)

   552

   553 lemma pochhammer_rec: "pochhammer a (Suc n) = a * pochhammer (a + 1) n"

   554   by (simp add: pochhammer_setprod setprod.atLeast0_lessThan_Suc_shift ac_simps)

   555

   556 lemma pochhammer_rec': "pochhammer z (Suc n) = (z + of_nat n) * pochhammer z n"

   557   by (simp add: pochhammer_setprod setprod.atLeast0_lessThan_Suc ac_simps)

   558

   559 lemma pochhammer_fact: "fact n = pochhammer 1 n"

   560   by (simp add: pochhammer_setprod fact_setprod_Suc)

   561

   562 lemma pochhammer_of_nat_eq_0_lemma: "k > n \<Longrightarrow> pochhammer (- (of_nat n :: 'a:: idom)) k = 0"

   563   by (auto simp add: pochhammer_setprod)

   564

   565 lemma pochhammer_of_nat_eq_0_lemma':

   566   assumes kn: "k \<le> n"

   567   shows "pochhammer (- (of_nat n :: 'a::{idom,ring_char_0})) k \<noteq> 0"

   568 proof (cases k)

   569   case 0

   570   then show ?thesis by simp

   571 next

   572   case (Suc h)

   573   then show ?thesis

   574     apply (simp add: pochhammer_Suc_setprod)

   575     using Suc kn

   576     apply (auto simp add: algebra_simps)

   577     done

   578 qed

   579

   580 lemma pochhammer_of_nat_eq_0_iff:

   581   "pochhammer (- (of_nat n :: 'a::{idom,ring_char_0})) k = 0 \<longleftrightarrow> k > n"

   582   (is "?l = ?r")

   583   using pochhammer_of_nat_eq_0_lemma[of n k, where ?'a='a]

   584     pochhammer_of_nat_eq_0_lemma'[of k n, where ?'a = 'a]

   585   by (auto simp add: not_le[symmetric])

   586

   587 lemma pochhammer_eq_0_iff: "pochhammer a n = (0::'a::field_char_0) \<longleftrightarrow> (\<exists>k < n. a = - of_nat k)"

   588   by (auto simp add: pochhammer_setprod eq_neg_iff_add_eq_0)

   589

   590 lemma pochhammer_eq_0_mono:

   591   "pochhammer a n = (0::'a::field_char_0) \<Longrightarrow> m \<ge> n \<Longrightarrow> pochhammer a m = 0"

   592   unfolding pochhammer_eq_0_iff by auto

   593

   594 lemma pochhammer_neq_0_mono:

   595   "pochhammer a m \<noteq> (0::'a::field_char_0) \<Longrightarrow> m \<ge> n \<Longrightarrow> pochhammer a n \<noteq> 0"

   596   unfolding pochhammer_eq_0_iff by auto

   597

   598 lemma pochhammer_minus:

   599   "pochhammer (- b) k = ((- 1) ^ k :: 'a::comm_ring_1) * pochhammer (b - of_nat k + 1) k"

   600 proof (cases k)

   601   case 0

   602   then show ?thesis by simp

   603 next

   604   case (Suc h)

   605   have eq: "((- 1) ^ Suc h :: 'a) = (\<Prod>i = 0..h. - 1)"

   606     using setprod_constant [where A="{0.. h}" and y="- 1 :: 'a"]

   607     by auto

   608   with Suc show ?thesis

   609     using pochhammer_Suc_setprod_rev [of "b - of_nat k + 1"]

   610     by (auto simp add: pochhammer_Suc_setprod setprod.distrib [symmetric] eq of_nat_diff)

   611 qed

   612

   613 lemma pochhammer_minus':

   614   "pochhammer (b - of_nat k + 1) k = ((- 1) ^ k :: 'a::comm_ring_1) * pochhammer (- b) k"

   615   apply (simp only: pochhammer_minus [where b = b])

   616   apply (simp only: mult.assoc [symmetric])

   617   apply (simp only: power_add [symmetric])

   618   apply simp

   619   done

   620

   621 lemma pochhammer_same: "pochhammer (- of_nat n) n =

   622     ((- 1) ^ n :: 'a::{semiring_char_0,comm_ring_1,semiring_no_zero_divisors}) * fact n"

   623   unfolding pochhammer_minus

   624   by (simp add: of_nat_diff pochhammer_fact)

   625

   626 lemma pochhammer_product': "pochhammer z (n + m) = pochhammer z n * pochhammer (z + of_nat n) m"

   627 proof (induct n arbitrary: z)

   628   case 0

   629   then show ?case by simp

   630 next

   631   case (Suc n z)

   632   have "pochhammer z (Suc n) * pochhammer (z + of_nat (Suc n)) m =

   633       z * (pochhammer (z + 1) n * pochhammer (z + 1 + of_nat n) m)"

   634     by (simp add: pochhammer_rec ac_simps)

   635   also note Suc[symmetric]

   636   also have "z * pochhammer (z + 1) (n + m) = pochhammer z (Suc (n + m))"

   637     by (subst pochhammer_rec) simp

   638   finally show ?case

   639     by simp

   640 qed

   641

   642 lemma pochhammer_product:

   643   "m \<le> n \<Longrightarrow> pochhammer z n = pochhammer z m * pochhammer (z + of_nat m) (n - m)"

   644   using pochhammer_product'[of z m "n - m"] by simp

   645

   646 lemma pochhammer_times_pochhammer_half:

   647   fixes z :: "'a::field_char_0"

   648   shows "pochhammer z (Suc n) * pochhammer (z + 1/2) (Suc n) = (\<Prod>k=0..2*n+1. z + of_nat k / 2)"

   649 proof (induct n)

   650   case 0

   651   then show ?case

   652     by (simp add: atLeast0_atMost_Suc)

   653 next

   654   case (Suc n)

   655   define n' where "n' = Suc n"

   656   have "pochhammer z (Suc n') * pochhammer (z + 1 / 2) (Suc n') =

   657       (pochhammer z n' * pochhammer (z + 1 / 2) n') * ((z + of_nat n') * (z + 1/2 + of_nat n'))"

   658     (is "_ = _ * ?A")

   659     by (simp_all add: pochhammer_rec' mult_ac)

   660   also have "?A = (z + of_nat (Suc (2 * n + 1)) / 2) * (z + of_nat (Suc (Suc (2 * n + 1))) / 2)"

   661     (is "_ = ?B")

   662     by (simp add: field_simps n'_def)

   663   also note Suc[folded n'_def]

   664   also have "(\<Prod>k=0..2 * n + 1. z + of_nat k / 2) * ?B = (\<Prod>k=0..2 * Suc n + 1. z + of_nat k / 2)"

   665     by (simp add: atLeast0_atMost_Suc)

   666   finally show ?case

   667     by (simp add: n'_def)

   668 qed

   669

   670 lemma pochhammer_double:

   671   fixes z :: "'a::field_char_0"

   672   shows "pochhammer (2 * z) (2 * n) = of_nat (2^(2*n)) * pochhammer z n * pochhammer (z+1/2) n"

   673 proof (induct n)

   674   case 0

   675   then show ?case by simp

   676 next

   677   case (Suc n)

   678   have "pochhammer (2 * z) (2 * (Suc n)) = pochhammer (2 * z) (2 * n) *

   679       (2 * (z + of_nat n)) * (2 * (z + of_nat n) + 1)"

   680     by (simp add: pochhammer_rec' ac_simps)

   681   also note Suc

   682   also have "of_nat (2 ^ (2 * n)) * pochhammer z n * pochhammer (z + 1/2) n *

   683         (2 * (z + of_nat n)) * (2 * (z + of_nat n) + 1) =

   684       of_nat (2 ^ (2 * (Suc n))) * pochhammer z (Suc n) * pochhammer (z + 1/2) (Suc n)"

   685     by (simp add: field_simps pochhammer_rec')

   686   finally show ?case .

   687 qed

   688

   689 lemma fact_double:

   690   "fact (2 * n) = (2 ^ (2 * n) * pochhammer (1 / 2) n * fact n :: 'a::field_char_0)"

   691   using pochhammer_double[of "1/2::'a" n] by (simp add: pochhammer_fact)

   692

   693 lemma pochhammer_absorb_comp: "(r - of_nat k) * pochhammer (- r) k = r * pochhammer (-r + 1) k"

   694   (is "?lhs = ?rhs")

   695   for r :: "'a::comm_ring_1"

   696 proof -

   697   have "?lhs = - pochhammer (- r) (Suc k)"

   698     by (subst pochhammer_rec') (simp add: algebra_simps)

   699   also have "\<dots> = ?rhs"

   700     by (subst pochhammer_rec) simp

   701   finally show ?thesis .

   702 qed

   703

   704

   705 subsection \<open>Generalized binomial coefficients\<close>

   706

   707 definition gbinomial :: "'a::{semidom_divide,semiring_char_0} \<Rightarrow> nat \<Rightarrow> 'a"  (infixl "gchoose" 65)

   708   where gbinomial_setprod_rev: "a gchoose n = setprod (\<lambda>i. a - of_nat i) {0..<n} div fact n"

   709

   710 lemma gbinomial_0 [simp]:

   711   "a gchoose 0 = 1"

   712   "0 gchoose (Suc n) = 0"

   713   by (simp_all add: gbinomial_setprod_rev setprod.atLeast0_lessThan_Suc_shift)

   714

   715 lemma gbinomial_Suc: "a gchoose (Suc k) = setprod (\<lambda>i. a - of_nat i) {0..k} div fact (Suc k)"

   716   by (simp add: gbinomial_setprod_rev atLeastLessThanSuc_atLeastAtMost)

   717

   718 lemma gbinomial_mult_fact: "fact n * (a gchoose n) = (\<Prod>i = 0..<n. a - of_nat i)"

   719   for a :: "'a::field_char_0"

   720   by (simp_all add: gbinomial_setprod_rev field_simps)

   721

   722 lemma gbinomial_mult_fact': "(a gchoose n) * fact n = (\<Prod>i = 0..<n. a - of_nat i)"

   723   for a :: "'a::field_char_0"

   724   using gbinomial_mult_fact [of n a] by (simp add: ac_simps)

   725

   726 lemma gbinomial_pochhammer: "a gchoose n = (- 1) ^ n * pochhammer (- a) n / fact n"

   727   for a :: "'a::field_char_0"

   728   by (cases n)

   729     (simp_all add: pochhammer_minus,

   730      simp_all add: gbinomial_setprod_rev pochhammer_setprod_rev

   731        power_mult_distrib [symmetric] atLeastLessThanSuc_atLeastAtMost

   732        setprod.atLeast_Suc_atMost_Suc_shift of_nat_diff)

   733

   734 lemma gbinomial_pochhammer': "s gchoose n = pochhammer (s - of_nat n + 1) n / fact n"

   735   for s :: "'a::field_char_0"

   736 proof -

   737   have "s gchoose n = ((-1)^n * (-1)^n) * pochhammer (s - of_nat n + 1) n / fact n"

   738     by (simp add: gbinomial_pochhammer pochhammer_minus mult_ac)

   739   also have "(-1 :: 'a)^n * (-1)^n = 1"

   740     by (subst power_add [symmetric]) simp

   741   finally show ?thesis

   742     by simp

   743 qed

   744

   745 lemma gbinomial_binomial: "n gchoose k = n choose k"

   746 proof (cases "k \<le> n")

   747   case False

   748   then have "n < k"

   749     by (simp add: not_le)

   750   then have "0 \<in> (op - n)  {0..<k}"

   751     by auto

   752   then have "setprod (op - n) {0..<k} = 0"

   753     by (auto intro: setprod_zero)

   754   with \<open>n < k\<close> show ?thesis

   755     by (simp add: binomial_eq_0 gbinomial_setprod_rev setprod_zero)

   756 next

   757   case True

   758   then have "inj_on (op - n) {0..<k}"

   759     by (auto intro: inj_onI)

   760   then have "\<Prod>(op - n  {0..<k}) = setprod (op - n) {0..<k}"

   761     by (auto dest: setprod.reindex)

   762   also have "op - n  {0..<k} = {Suc (n - k)..n}"

   763     using True by (auto simp add: image_def Bex_def) presburger  (* FIXME slow *)

   764   finally have *: "setprod (\<lambda>q. n - q) {0..<k} = \<Prod>{Suc (n - k)..n}" ..

   765   from True have "n choose k = fact n div (fact k * fact (n - k))"

   766     by (rule binomial_fact')

   767   with * show ?thesis

   768     by (simp add: gbinomial_setprod_rev mult.commute [of "fact k"] div_mult2_eq fact_div_fact)

   769 qed

   770

   771 lemma of_nat_gbinomial: "of_nat (n gchoose k) = (of_nat n gchoose k :: 'a::field_char_0)"

   772 proof (cases "k \<le> n")

   773   case False

   774   then show ?thesis

   775     by (simp add: not_le gbinomial_binomial binomial_eq_0 gbinomial_setprod_rev)

   776 next

   777   case True

   778   define m where "m = n - k"

   779   with True have n: "n = m + k"

   780     by arith

   781   from n have "fact n = ((\<Prod>i = 0..<m + k. of_nat (m + k - i) ):: 'a)"

   782     by (simp add: fact_setprod_rev)

   783   also have "\<dots> = ((\<Prod>i\<in>{0..<k} \<union> {k..<m + k}. of_nat (m + k - i)) :: 'a)"

   784     by (simp add: ivl_disj_un)

   785   finally have "fact n = (fact m * (\<Prod>i = 0..<k. of_nat m + of_nat k - of_nat i) :: 'a)"

   786     using setprod_shift_bounds_nat_ivl [of "\<lambda>i. of_nat (m + k - i) :: 'a" 0 k m]

   787     by (simp add: fact_setprod_rev [of m] setprod.union_disjoint of_nat_diff)

   788   then have "fact n / fact (n - k) = ((\<Prod>i = 0..<k. of_nat n - of_nat i) :: 'a)"

   789     by (simp add: n)

   790   with True have "fact k * of_nat (n gchoose k) = (fact k * (of_nat n gchoose k) :: 'a)"

   791     by (simp only: gbinomial_mult_fact [of k "of_nat n"] gbinomial_binomial [of n k] fact_binomial)

   792   then show ?thesis

   793     by simp

   794 qed

   795

   796 lemma binomial_gbinomial: "of_nat (n choose k) = (of_nat n gchoose k :: 'a::field_char_0)"

   797   by (simp add: gbinomial_binomial [symmetric] of_nat_gbinomial)

   798

   799 setup

   800   \<open>Sign.add_const_constraint (@{const_name gbinomial}, SOME @{typ "'a::field_char_0 \<Rightarrow> nat \<Rightarrow> 'a"})\<close>

   801

   802 lemma gbinomial_1[simp]: "a gchoose 1 = a"

   803   by (simp add: gbinomial_setprod_rev lessThan_Suc)

   804

   805 lemma gbinomial_Suc0[simp]: "a gchoose (Suc 0) = a"

   806   by (simp add: gbinomial_setprod_rev lessThan_Suc)

   807

   808 lemma gbinomial_mult_1:

   809   fixes a :: "'a::field_char_0"

   810   shows "a * (a gchoose n) = of_nat n * (a gchoose n) + of_nat (Suc n) * (a gchoose (Suc n))"

   811   (is "?l = ?r")

   812 proof -

   813   have "?r = ((- 1) ^n * pochhammer (- a) n / (fact n)) * (of_nat n - (- a + of_nat n))"

   814     apply (simp only: gbinomial_pochhammer pochhammer_Suc right_diff_distrib power_Suc)

   815     apply (simp del: of_nat_Suc fact_Suc)

   816     apply (auto simp add: field_simps simp del: of_nat_Suc)

   817     done

   818   also have "\<dots> = ?l"

   819     by (simp add: field_simps gbinomial_pochhammer)

   820   finally show ?thesis ..

   821 qed

   822

   823 lemma gbinomial_mult_1':

   824   "(a gchoose n) * a = of_nat n * (a gchoose n) + of_nat (Suc n) * (a gchoose (Suc n))"

   825   for a :: "'a::field_char_0"

   826   by (simp add: mult.commute gbinomial_mult_1)

   827

   828 lemma gbinomial_Suc_Suc: "(a + 1) gchoose (Suc k) = a gchoose k + (a gchoose (Suc k))"

   829   for a :: "'a::field_char_0"

   830 proof (cases k)

   831   case 0

   832   then show ?thesis by simp

   833 next

   834   case (Suc h)

   835   have eq0: "(\<Prod>i\<in>{1..k}. (a + 1) - of_nat i) = (\<Prod>i\<in>{0..h}. a - of_nat i)"

   836     apply (rule setprod.reindex_cong [where l = Suc])

   837       using Suc

   838       apply (auto simp add: image_Suc_atMost)

   839     done

   840   have "fact (Suc k) * (a gchoose k + (a gchoose (Suc k))) =

   841       (a gchoose Suc h) * (fact (Suc (Suc h))) +

   842       (a gchoose Suc (Suc h)) * (fact (Suc (Suc h)))"

   843     by (simp add: Suc field_simps del: fact_Suc)

   844   also have "\<dots> =

   845     (a gchoose Suc h) * of_nat (Suc (Suc h) * fact (Suc h)) + (\<Prod>i=0..Suc h. a - of_nat i)"

   846     apply (simp del: fact_Suc add: gbinomial_mult_fact field_simps mult.left_commute [of _ "2"])

   847     apply (simp del: fact_Suc add: fact_Suc [of "Suc h"] field_simps gbinomial_mult_fact

   848       mult.left_commute [of _ "2"] atLeastLessThanSuc_atLeastAtMost)

   849     done

   850   also have "\<dots> =

   851     (fact (Suc h) * (a gchoose Suc h)) * of_nat (Suc (Suc h)) + (\<Prod>i=0..Suc h. a - of_nat i)"

   852     by (simp only: fact_Suc mult.commute mult.left_commute of_nat_fact of_nat_id of_nat_mult)

   853   also have "\<dots> =

   854     of_nat (Suc (Suc h)) * (\<Prod>i=0..h. a - of_nat i) + (\<Prod>i=0..Suc h. a - of_nat i)"

   855     unfolding gbinomial_mult_fact atLeastLessThanSuc_atLeastAtMost by auto

   856   also have "\<dots> =

   857     (\<Prod>i=0..Suc h. a - of_nat i) + (of_nat h * (\<Prod>i=0..h. a - of_nat i) + 2 * (\<Prod>i=0..h. a - of_nat i))"

   858     by (simp add: field_simps)

   859   also have "\<dots> =

   860     ((a gchoose Suc h) * (fact (Suc h)) * of_nat (Suc k)) + (\<Prod>i\<in>{0..Suc h}. a - of_nat i)"

   861     unfolding gbinomial_mult_fact'

   862     by (simp add: comm_semiring_class.distrib field_simps Suc atLeastLessThanSuc_atLeastAtMost)

   863   also have "\<dots> = (\<Prod>i\<in>{0..h}. a - of_nat i) * (a + 1)"

   864     unfolding gbinomial_mult_fact' atLeast0_atMost_Suc

   865     by (simp add: field_simps Suc atLeastLessThanSuc_atLeastAtMost)

   866   also have "\<dots> = (\<Prod>i\<in>{0..k}. (a + 1) - of_nat i)"

   867     using eq0

   868     by (simp add: Suc setprod.atLeast0_atMost_Suc_shift)

   869   also have "\<dots> = (fact (Suc k)) * ((a + 1) gchoose (Suc k))"

   870     by (simp only: gbinomial_mult_fact atLeastLessThanSuc_atLeastAtMost)

   871   finally show ?thesis

   872     using fact_nonzero [of "Suc k"] by auto

   873 qed

   874

   875 lemma gbinomial_reduce_nat: "0 < k \<Longrightarrow> a gchoose k = (a - 1) gchoose (k - 1) + ((a - 1) gchoose k)"

   876   for a :: "'a::field_char_0"

   877   by (metis Suc_pred' diff_add_cancel gbinomial_Suc_Suc)

   878

   879 lemma gchoose_row_sum_weighted:

   880   "(\<Sum>k = 0..m. (r gchoose k) * (r/2 - of_nat k)) = of_nat(Suc m) / 2 * (r gchoose (Suc m))"

   881   for r :: "'a::field_char_0"

   882   by (induct m) (simp_all add: field_simps distrib gbinomial_mult_1)

   883

   884 lemma binomial_symmetric:

   885   assumes kn: "k \<le> n"

   886   shows "n choose k = n choose (n - k)"

   887 proof -

   888   have kn': "n - k \<le> n"

   889     using kn by arith

   890   from binomial_fact_lemma[OF kn] binomial_fact_lemma[OF kn']

   891   have "fact k * fact (n - k) * (n choose k) = fact (n - k) * fact (n - (n - k)) * (n choose (n - k))"

   892     by simp

   893   then show ?thesis

   894     using kn by simp

   895 qed

   896

   897 lemma choose_rising_sum:

   898   "(\<Sum>j\<le>m. ((n + j) choose n)) = ((n + m + 1) choose (n + 1))"

   899   "(\<Sum>j\<le>m. ((n + j) choose n)) = ((n + m + 1) choose m)"

   900 proof -

   901   show "(\<Sum>j\<le>m. ((n + j) choose n)) = ((n + m + 1) choose (n + 1))"

   902     by (induct m) simp_all

   903   also have "\<dots> = (n + m + 1) choose m"

   904     by (subst binomial_symmetric) simp_all

   905   finally show "(\<Sum>j\<le>m. ((n + j) choose n)) = (n + m + 1) choose m" .

   906 qed

   907

   908 lemma choose_linear_sum: "(\<Sum>i\<le>n. i * (n choose i)) = n * 2 ^ (n - 1)"

   909 proof (cases n)

   910   case 0

   911   then show ?thesis by simp

   912 next

   913   case (Suc m)

   914   have "(\<Sum>i\<le>n. i * (n choose i)) = (\<Sum>i\<le>Suc m. i * (Suc m choose i))"

   915     by (simp add: Suc)

   916   also have "\<dots> = Suc m * 2 ^ m"

   917     by (simp only: setsum_atMost_Suc_shift Suc_times_binomial setsum_right_distrib[symmetric])

   918        (simp add: choose_row_sum')

   919   finally show ?thesis

   920     using Suc by simp

   921 qed

   922

   923 lemma choose_alternating_linear_sum:

   924   assumes "n \<noteq> 1"

   925   shows "(\<Sum>i\<le>n. (-1)^i * of_nat i * of_nat (n choose i) :: 'a::comm_ring_1) = 0"

   926 proof (cases n)

   927   case 0

   928   then show ?thesis by simp

   929 next

   930   case (Suc m)

   931   with assms have "m > 0"

   932     by simp

   933   have "(\<Sum>i\<le>n. (-1) ^ i * of_nat i * of_nat (n choose i) :: 'a) =

   934       (\<Sum>i\<le>Suc m. (-1) ^ i * of_nat i * of_nat (Suc m choose i))"

   935     by (simp add: Suc)

   936   also have "\<dots> = (\<Sum>i\<le>m. (-1) ^ (Suc i) * of_nat (Suc i * (Suc m choose Suc i)))"

   937     by (simp only: setsum_atMost_Suc_shift setsum_right_distrib[symmetric] mult_ac of_nat_mult) simp

   938   also have "\<dots> = - of_nat (Suc m) * (\<Sum>i\<le>m. (-1) ^ i * of_nat (m choose i))"

   939     by (subst setsum_right_distrib, rule setsum.cong[OF refl], subst Suc_times_binomial)

   940        (simp add: algebra_simps)

   941   also have "(\<Sum>i\<le>m. (-1 :: 'a) ^ i * of_nat ((m choose i))) = 0"

   942     using choose_alternating_sum[OF \<open>m > 0\<close>] by simp

   943   finally show ?thesis

   944     by simp

   945 qed

   946

   947 lemma vandermonde: "(\<Sum>k\<le>r. (m choose k) * (n choose (r - k))) = (m + n) choose r"

   948 proof (induct n arbitrary: r)

   949   case 0

   950   have "(\<Sum>k\<le>r. (m choose k) * (0 choose (r - k))) = (\<Sum>k\<le>r. if k = r then (m choose k) else 0)"

   951     by (intro setsum.cong) simp_all

   952   also have "\<dots> = m choose r"

   953     by (simp add: setsum.delta)

   954   finally show ?case

   955     by simp

   956 next

   957   case (Suc n r)

   958   show ?case

   959     by (cases r) (simp_all add: Suc [symmetric] algebra_simps setsum.distrib Suc_diff_le)

   960 qed

   961

   962 lemma choose_square_sum: "(\<Sum>k\<le>n. (n choose k)^2) = ((2*n) choose n)"

   963   using vandermonde[of n n n]

   964   by (simp add: power2_eq_square mult_2 binomial_symmetric [symmetric])

   965

   966 lemma pochhammer_binomial_sum:

   967   fixes a b :: "'a::comm_ring_1"

   968   shows "pochhammer (a + b) n = (\<Sum>k\<le>n. of_nat (n choose k) * pochhammer a k * pochhammer b (n - k))"

   969 proof (induction n arbitrary: a b)

   970   case 0

   971   then show ?case by simp

   972 next

   973   case (Suc n a b)

   974   have "(\<Sum>k\<le>Suc n. of_nat (Suc n choose k) * pochhammer a k * pochhammer b (Suc n - k)) =

   975       (\<Sum>i\<le>n. of_nat (n choose i) * pochhammer a (Suc i) * pochhammer b (n - i)) +

   976       ((\<Sum>i\<le>n. of_nat (n choose Suc i) * pochhammer a (Suc i) * pochhammer b (n - i)) +

   977       pochhammer b (Suc n))"

   978     by (subst setsum_atMost_Suc_shift) (simp add: ring_distribs setsum.distrib)

   979   also have "(\<Sum>i\<le>n. of_nat (n choose i) * pochhammer a (Suc i) * pochhammer b (n - i)) =

   980       a * pochhammer ((a + 1) + b) n"

   981     by (subst Suc) (simp add: setsum_right_distrib pochhammer_rec mult_ac)

   982   also have "(\<Sum>i\<le>n. of_nat (n choose Suc i) * pochhammer a (Suc i) * pochhammer b (n - i)) +

   983         pochhammer b (Suc n) =

   984       (\<Sum>i=0..Suc n. of_nat (n choose i) * pochhammer a i * pochhammer b (Suc n - i))"

   985     apply (subst setsum_head_Suc)

   986     apply simp

   987     apply (subst setsum_shift_bounds_cl_Suc_ivl)

   988     apply (simp add: atLeast0AtMost)

   989     done

   990   also have "\<dots> = (\<Sum>i\<le>n. of_nat (n choose i) * pochhammer a i * pochhammer b (Suc n - i))"

   991     using Suc by (intro setsum.mono_neutral_right) (auto simp: not_le binomial_eq_0)

   992   also have "\<dots> = (\<Sum>i\<le>n. of_nat (n choose i) * pochhammer a i * pochhammer b (Suc (n - i)))"

   993     by (intro setsum.cong) (simp_all add: Suc_diff_le)

   994   also have "\<dots> = b * pochhammer (a + (b + 1)) n"

   995     by (subst Suc) (simp add: setsum_right_distrib mult_ac pochhammer_rec)

   996   also have "a * pochhammer ((a + 1) + b) n + b * pochhammer (a + (b + 1)) n =

   997       pochhammer (a + b) (Suc n)"

   998     by (simp add: pochhammer_rec algebra_simps)

   999   finally show ?case ..

  1000 qed

  1001

  1002 text \<open>Contributed by Manuel Eberl, generalised by LCP.

  1003   Alternative definition of the binomial coefficient as @{term "\<Prod>i<k. (n - i) / (k - i)"}.\<close>

  1004 lemma gbinomial_altdef_of_nat: "x gchoose k = (\<Prod>i = 0..<k. (x - of_nat i) / of_nat (k - i) :: 'a)"

  1005   for k :: nat and x :: "'a::field_char_0"

  1006   by (simp add: setprod_dividef gbinomial_setprod_rev fact_setprod_rev)

  1007

  1008 lemma gbinomial_ge_n_over_k_pow_k:

  1009   fixes k :: nat

  1010     and x :: "'a::linordered_field"

  1011   assumes "of_nat k \<le> x"

  1012   shows "(x / of_nat k :: 'a) ^ k \<le> x gchoose k"

  1013 proof -

  1014   have x: "0 \<le> x"

  1015     using assms of_nat_0_le_iff order_trans by blast

  1016   have "(x / of_nat k :: 'a) ^ k = (\<Prod>i = 0..<k. x / of_nat k :: 'a)"

  1017     by (simp add: setprod_constant)

  1018   also have "\<dots> \<le> x gchoose k" (* FIXME *)

  1019     unfolding gbinomial_altdef_of_nat

  1020     apply (safe intro!: setprod_mono)

  1021     apply simp_all

  1022     prefer 2

  1023     subgoal premises for i

  1024     proof -

  1025       from assms have "x * of_nat i \<ge> of_nat (i * k)"

  1026         by (metis mult.commute mult_le_cancel_right of_nat_less_0_iff of_nat_mult)

  1027       then have "x * of_nat k - x * of_nat i \<le> x * of_nat k - of_nat (i * k)"

  1028         by arith

  1029       then have "x * of_nat (k - i) \<le> (x - of_nat i) * of_nat k"

  1030         using \<open>i < k\<close> by (simp add: algebra_simps zero_less_mult_iff of_nat_diff)

  1031       then have "x * of_nat (k - i) \<le> (x - of_nat i) * (of_nat k :: 'a)"

  1032         by (simp only: of_nat_mult[symmetric] of_nat_le_iff)

  1033       with assms show ?thesis

  1034         using \<open>i < k\<close> by (simp add: field_simps)

  1035     qed

  1036     apply (simp add: x zero_le_divide_iff)

  1037     done

  1038   finally show ?thesis .

  1039 qed

  1040

  1041 lemma gbinomial_negated_upper: "(a gchoose b) = (-1) ^ b * ((of_nat b - a - 1) gchoose b)"

  1042   by (simp add: gbinomial_pochhammer pochhammer_minus algebra_simps)

  1043

  1044 lemma gbinomial_minus: "((-a) gchoose b) = (-1) ^ b * ((a + of_nat b - 1) gchoose b)"

  1045   by (subst gbinomial_negated_upper) (simp add: add_ac)

  1046

  1047 lemma Suc_times_gbinomial: "of_nat (Suc b) * ((a + 1) gchoose (Suc b)) = (a + 1) * (a gchoose b)"

  1048 proof (cases b)

  1049   case 0

  1050   then show ?thesis by simp

  1051 next

  1052   case (Suc b)

  1053   then have "((a + 1) gchoose (Suc (Suc b))) = (\<Prod>i = 0..Suc b. a + (1 - of_nat i)) / fact (b + 2)"

  1054     by (simp add: field_simps gbinomial_setprod_rev atLeastLessThanSuc_atLeastAtMost)

  1055   also have "(\<Prod>i = 0..Suc b. a + (1 - of_nat i)) = (a + 1) * (\<Prod>i = 0..b. a - of_nat i)"

  1056     by (simp add: setprod.atLeast0_atMost_Suc_shift)

  1057   also have "\<dots> / fact (b + 2) = (a + 1) / of_nat (Suc (Suc b)) * (a gchoose Suc b)"

  1058     by (simp_all add: gbinomial_setprod_rev atLeastLessThanSuc_atLeastAtMost)

  1059   finally show ?thesis by (simp add: Suc field_simps del: of_nat_Suc)

  1060 qed

  1061

  1062 lemma gbinomial_factors: "((a + 1) gchoose (Suc b)) = (a + 1) / of_nat (Suc b) * (a gchoose b)"

  1063 proof (cases b)

  1064   case 0

  1065   then show ?thesis by simp

  1066 next

  1067   case (Suc b)

  1068   then have "((a + 1) gchoose (Suc (Suc b))) = (\<Prod>i = 0 .. Suc b. a + (1 - of_nat i)) / fact (b + 2)"

  1069     by (simp add: field_simps gbinomial_setprod_rev atLeastLessThanSuc_atLeastAtMost)

  1070   also have "(\<Prod>i = 0 .. Suc b. a + (1 - of_nat i)) = (a + 1) * (\<Prod>i = 0..b. a - of_nat i)"

  1071     by (simp add: setprod.atLeast0_atMost_Suc_shift)

  1072   also have "\<dots> / fact (b + 2) = (a + 1) / of_nat (Suc (Suc b)) * (a gchoose Suc b)"

  1073     by (simp_all add: gbinomial_setprod_rev atLeastLessThanSuc_atLeastAtMost atLeast0AtMost)

  1074   finally show ?thesis

  1075     by (simp add: Suc)

  1076 qed

  1077

  1078 lemma gbinomial_rec: "((r + 1) gchoose (Suc k)) = (r gchoose k) * ((r + 1) / of_nat (Suc k))"

  1079   using gbinomial_mult_1[of r k]

  1080   by (subst gbinomial_Suc_Suc) (simp add: field_simps del: of_nat_Suc, simp add: algebra_simps)

  1081

  1082 lemma gbinomial_of_nat_symmetric: "k \<le> n \<Longrightarrow> (of_nat n) gchoose k = (of_nat n) gchoose (n - k)"

  1083   using binomial_symmetric[of k n] by (simp add: binomial_gbinomial [symmetric])

  1084

  1085

  1086 text \<open>The absorption identity (equation 5.5 \cite[p.~157]{GKP}):

  1087 $  1088 {r \choose k} = \frac{r}{k}{r - 1 \choose k - 1},\quad \textnormal{integer } k \neq 0.   1089$\<close>

  1090 lemma gbinomial_absorption': "k > 0 \<Longrightarrow> r gchoose k = (r / of_nat k) * (r - 1 gchoose (k - 1))"

  1091   using gbinomial_rec[of "r - 1" "k - 1"]

  1092   by (simp_all add: gbinomial_rec field_simps del: of_nat_Suc)

  1093

  1094 text \<open>The absorption identity is written in the following form to avoid

  1095 division by $k$ (the lower index) and therefore remove the $k \neq 0$

  1096 restriction\cite[p.~157]{GKP}:

  1097 $  1098 k{r \choose k} = r{r - 1 \choose k - 1}, \quad \textnormal{integer } k.   1099$\<close>

  1100 lemma gbinomial_absorption: "of_nat (Suc k) * (r gchoose Suc k) = r * ((r - 1) gchoose k)"

  1101   using gbinomial_absorption'[of "Suc k" r] by (simp add: field_simps del: of_nat_Suc)

  1102

  1103 text \<open>The absorption identity for natural number binomial coefficients:\<close>

  1104 lemma binomial_absorption: "Suc k * (n choose Suc k) = n * ((n - 1) choose k)"

  1105   by (cases n) (simp_all add: binomial_eq_0 Suc_times_binomial del: binomial_Suc_Suc mult_Suc)

  1106

  1107 text \<open>The absorption companion identity for natural number coefficients,

  1108   following the proof by GKP \cite[p.~157]{GKP}:\<close>

  1109 lemma binomial_absorb_comp: "(n - k) * (n choose k) = n * ((n - 1) choose k)"

  1110   (is "?lhs = ?rhs")

  1111 proof (cases "n \<le> k")

  1112   case True

  1113   then show ?thesis by auto

  1114 next

  1115   case False

  1116   then have "?rhs = Suc ((n - 1) - k) * (n choose Suc ((n - 1) - k))"

  1117     using binomial_symmetric[of k "n - 1"] binomial_absorption[of "(n - 1) - k" n]

  1118     by simp

  1119   also have "Suc ((n - 1) - k) = n - k"

  1120     using False by simp

  1121   also have "n choose \<dots> = n choose k"

  1122     using False by (intro binomial_symmetric [symmetric]) simp_all

  1123   finally show ?thesis ..

  1124 qed

  1125

  1126 text \<open>The generalised absorption companion identity:\<close>

  1127 lemma gbinomial_absorb_comp: "(r - of_nat k) * (r gchoose k) = r * ((r - 1) gchoose k)"

  1128   using pochhammer_absorb_comp[of r k] by (simp add: gbinomial_pochhammer)

  1129

  1130 lemma gbinomial_addition_formula:

  1131   "r gchoose (Suc k) = ((r - 1) gchoose (Suc k)) + ((r - 1) gchoose k)"

  1132   using gbinomial_Suc_Suc[of "r - 1" k] by (simp add: algebra_simps)

  1133

  1134 lemma binomial_addition_formula:

  1135   "0 < n \<Longrightarrow> n choose (Suc k) = ((n - 1) choose (Suc k)) + ((n - 1) choose k)"

  1136   by (subst choose_reduce_nat) simp_all

  1137

  1138 text \<open>

  1139   Equation 5.9 of the reference material \cite[p.~159]{GKP} is a useful

  1140   summation formula, operating on both indices:

  1141   $  1142 \sum\limits_{k \leq n}{r + k \choose k} = {r + n + 1 \choose n},   1143 \quad \textnormal{integer } n.   1144$

  1145 \<close>

  1146 lemma gbinomial_parallel_sum: "(\<Sum>k\<le>n. (r + of_nat k) gchoose k) = (r + of_nat n + 1) gchoose n"

  1147 proof (induct n)

  1148   case 0

  1149   then show ?case by simp

  1150 next

  1151   case (Suc m)

  1152   then show ?case

  1153     using gbinomial_Suc_Suc[of "(r + of_nat m + 1)" m]

  1154     by (simp add: add_ac)

  1155 qed

  1156

  1157

  1158 subsubsection \<open>Summation on the upper index\<close>

  1159

  1160 text \<open>

  1161   Another summation formula is equation 5.10 of the reference material \cite[p.~160]{GKP},

  1162   aptly named \emph{summation on the upper index}:$\sum_{0 \leq k \leq n} {k \choose m} =   1163 {n + 1 \choose m + 1}, \quad \textnormal{integers } m, n \geq 0.$

  1164 \<close>

  1165 lemma gbinomial_sum_up_index:

  1166   "(\<Sum>k = 0..n. (of_nat k gchoose m) :: 'a::field_char_0) = (of_nat n + 1) gchoose (m + 1)"

  1167 proof (induct n)

  1168   case 0

  1169   show ?case

  1170     using gbinomial_Suc_Suc[of 0 m]

  1171     by (cases m) auto

  1172 next

  1173   case (Suc n)

  1174   then show ?case

  1175     using gbinomial_Suc_Suc[of "of_nat (Suc n) :: 'a" m]

  1176     by (simp add: add_ac)

  1177 qed

  1178

  1179 lemma gbinomial_index_swap:

  1180   "((-1) ^ m) * ((- (of_nat n) - 1) gchoose m) = ((-1) ^ n) * ((- (of_nat m) - 1) gchoose n)"

  1181   (is "?lhs = ?rhs")

  1182 proof -

  1183   have "?lhs = (of_nat (m + n) gchoose m)"

  1184     by (subst gbinomial_negated_upper) (simp add: power_mult_distrib [symmetric])

  1185   also have "\<dots> = (of_nat (m + n) gchoose n)"

  1186     by (subst gbinomial_of_nat_symmetric) simp_all

  1187   also have "\<dots> = ?rhs"

  1188     by (subst gbinomial_negated_upper) simp

  1189   finally show ?thesis .

  1190 qed

  1191

  1192 lemma gbinomial_sum_lower_neg: "(\<Sum>k\<le>m. (r gchoose k) * (- 1) ^ k) = (- 1) ^ m * (r - 1 gchoose m)"

  1193   (is "?lhs = ?rhs")

  1194 proof -

  1195   have "?lhs = (\<Sum>k\<le>m. -(r + 1) + of_nat k gchoose k)"

  1196     by (intro setsum.cong[OF refl]) (subst gbinomial_negated_upper, simp add: power_mult_distrib)

  1197   also have "\<dots>  = - r + of_nat m gchoose m"

  1198     by (subst gbinomial_parallel_sum) simp

  1199   also have "\<dots> = ?rhs"

  1200     by (subst gbinomial_negated_upper) (simp add: power_mult_distrib)

  1201   finally show ?thesis .

  1202 qed

  1203

  1204 lemma gbinomial_partial_row_sum:

  1205   "(\<Sum>k\<le>m. (r gchoose k) * ((r / 2) - of_nat k)) = ((of_nat m + 1)/2) * (r gchoose (m + 1))"

  1206 proof (induct m)

  1207   case 0

  1208   then show ?case by simp

  1209 next

  1210   case (Suc mm)

  1211   then have "(\<Sum>k\<le>Suc mm. (r gchoose k) * (r / 2 - of_nat k)) =

  1212       (r - of_nat (Suc mm)) * (r gchoose Suc mm) / 2"

  1213     by (simp add: field_simps)

  1214   also have "\<dots> = r * (r - 1 gchoose Suc mm) / 2"

  1215     by (subst gbinomial_absorb_comp) (rule refl)

  1216   also have "\<dots> = (of_nat (Suc mm) + 1) / 2 * (r gchoose (Suc mm + 1))"

  1217     by (subst gbinomial_absorption [symmetric]) simp

  1218   finally show ?case .

  1219 qed

  1220

  1221 lemma setsum_bounds_lt_plus1: "(\<Sum>k<mm. f (Suc k)) = (\<Sum>k=1..mm. f k)"

  1222   by (induct mm) simp_all

  1223

  1224 lemma gbinomial_partial_sum_poly:

  1225   "(\<Sum>k\<le>m. (of_nat m + r gchoose k) * x^k * y^(m-k)) =

  1226     (\<Sum>k\<le>m. (-r gchoose k) * (-x)^k * (x + y)^(m-k))"

  1227   (is "?lhs m = ?rhs m")

  1228 proof (induction m)

  1229   case 0

  1230   then show ?case by simp

  1231 next

  1232   case (Suc mm)

  1233   define G where "G i k = (of_nat i + r gchoose k) * x^k * y^(i - k)" for i k

  1234   define S where "S = ?lhs"

  1235   have SG_def: "S = (\<lambda>i. (\<Sum>k\<le>i. (G i k)))"

  1236     unfolding S_def G_def ..

  1237

  1238   have "S (Suc mm) = G (Suc mm) 0 + (\<Sum>k=Suc 0..Suc mm. G (Suc mm) k)"

  1239     using SG_def by (simp add: setsum_head_Suc atLeast0AtMost [symmetric])

  1240   also have "(\<Sum>k=Suc 0..Suc mm. G (Suc mm) k) = (\<Sum>k=0..mm. G (Suc mm) (Suc k))"

  1241     by (subst setsum_shift_bounds_cl_Suc_ivl) simp

  1242   also have "\<dots> = (\<Sum>k=0..mm. ((of_nat mm + r gchoose (Suc k)) +

  1243       (of_nat mm + r gchoose k)) * x^(Suc k) * y^(mm - k))"

  1244     unfolding G_def by (subst gbinomial_addition_formula) simp

  1245   also have "\<dots> = (\<Sum>k=0..mm. (of_nat mm + r gchoose (Suc k)) * x^(Suc k) * y^(mm - k)) +

  1246       (\<Sum>k=0..mm. (of_nat mm + r gchoose k) * x^(Suc k) * y^(mm - k))"

  1247     by (subst setsum.distrib [symmetric]) (simp add: algebra_simps)

  1248   also have "(\<Sum>k=0..mm. (of_nat mm + r gchoose (Suc k)) * x^(Suc k) * y^(mm - k)) =

  1249       (\<Sum>k<Suc mm. (of_nat mm + r gchoose (Suc k)) * x^(Suc k) * y^(mm - k))"

  1250     by (simp only: atLeast0AtMost lessThan_Suc_atMost)

  1251   also have "\<dots> = (\<Sum>k<mm. (of_nat mm + r gchoose Suc k) * x^(Suc k) * y^(mm-k)) +

  1252       (of_nat mm + r gchoose (Suc mm)) * x^(Suc mm)"

  1253     (is "_ = ?A + ?B")

  1254     by (subst setsum_lessThan_Suc) simp

  1255   also have "?A = (\<Sum>k=1..mm. (of_nat mm + r gchoose k) * x^k * y^(mm - k + 1))"

  1256   proof (subst setsum_bounds_lt_plus1 [symmetric], intro setsum.cong[OF refl], clarify)

  1257     fix k

  1258     assume "k < mm"

  1259     then have "mm - k = mm - Suc k + 1"

  1260       by linarith

  1261     then show "(of_nat mm + r gchoose Suc k) * x ^ Suc k * y ^ (mm - k) =

  1262         (of_nat mm + r gchoose Suc k) * x ^ Suc k * y ^ (mm - Suc k + 1)"

  1263       by (simp only:)

  1264   qed

  1265   also have "\<dots> + ?B = y * (\<Sum>k=1..mm. (G mm k)) + (of_nat mm + r gchoose (Suc mm)) * x^(Suc mm)"

  1266     unfolding G_def by (subst setsum_right_distrib) (simp add: algebra_simps)

  1267   also have "(\<Sum>k=0..mm. (of_nat mm + r gchoose k) * x^(Suc k) * y^(mm - k)) = x * (S mm)"

  1268     unfolding S_def by (subst setsum_right_distrib) (simp add: atLeast0AtMost algebra_simps)

  1269   also have "(G (Suc mm) 0) = y * (G mm 0)"

  1270     by (simp add: G_def)

  1271   finally have "S (Suc mm) =

  1272       y * (G mm 0 + (\<Sum>k=1..mm. (G mm k))) + (of_nat mm + r gchoose (Suc mm)) * x^(Suc mm) + x * (S mm)"

  1273     by (simp add: ring_distribs)

  1274   also have "G mm 0 + (\<Sum>k=1..mm. (G mm k)) = S mm"

  1275     by (simp add: setsum_head_Suc[symmetric] SG_def atLeast0AtMost)

  1276   finally have "S (Suc mm) = (x + y) * (S mm) + (of_nat mm + r gchoose (Suc mm)) * x^(Suc mm)"

  1277     by (simp add: algebra_simps)

  1278   also have "(of_nat mm + r gchoose (Suc mm)) = (-1) ^ (Suc mm) * (- r gchoose (Suc mm))"

  1279     by (subst gbinomial_negated_upper) simp

  1280   also have "(-1) ^ Suc mm * (- r gchoose Suc mm) * x ^ Suc mm =

  1281       (- r gchoose (Suc mm)) * (-x) ^ Suc mm"

  1282     by (simp add: power_minus[of x])

  1283   also have "(x + y) * S mm + \<dots> = (x + y) * ?rhs mm + (- r gchoose (Suc mm)) * (- x)^Suc mm"

  1284     unfolding S_def by (subst Suc.IH) simp

  1285   also have "(x + y) * ?rhs mm = (\<Sum>n\<le>mm. ((- r gchoose n) * (- x) ^ n * (x + y) ^ (Suc mm - n)))"

  1286     by (subst setsum_right_distrib, rule setsum.cong) (simp_all add: Suc_diff_le)

  1287   also have "\<dots> + (-r gchoose (Suc mm)) * (-x)^Suc mm =

  1288       (\<Sum>n\<le>Suc mm. (- r gchoose n) * (- x) ^ n * (x + y) ^ (Suc mm - n))"

  1289     by simp

  1290   finally show ?case

  1291     by (simp only: S_def)

  1292 qed

  1293

  1294 lemma gbinomial_partial_sum_poly_xpos:

  1295   "(\<Sum>k\<le>m. (of_nat m + r gchoose k) * x^k * y^(m-k)) =

  1296      (\<Sum>k\<le>m. (of_nat k + r - 1 gchoose k) * x^k * (x + y)^(m-k))"

  1297   apply (subst gbinomial_partial_sum_poly)

  1298   apply (subst gbinomial_negated_upper)

  1299   apply (intro setsum.cong, rule refl)

  1300   apply (simp add: power_mult_distrib [symmetric])

  1301   done

  1302

  1303 lemma binomial_r_part_sum: "(\<Sum>k\<le>m. (2 * m + 1 choose k)) = 2 ^ (2 * m)"

  1304 proof -

  1305   have "2 * 2^(2*m) = (\<Sum>k = 0..(2 * m + 1). (2 * m + 1 choose k))"

  1306     using choose_row_sum[where n="2 * m + 1"] by simp

  1307   also have "(\<Sum>k = 0..(2 * m + 1). (2 * m + 1 choose k)) =

  1308       (\<Sum>k = 0..m. (2 * m + 1 choose k)) +

  1309       (\<Sum>k = m+1..2*m+1. (2 * m + 1 choose k))"

  1310     using setsum_ub_add_nat[of 0 m "\<lambda>k. 2 * m + 1 choose k" "m+1"]

  1311     by (simp add: mult_2)

  1312   also have "(\<Sum>k = m+1..2*m+1. (2 * m + 1 choose k)) =

  1313       (\<Sum>k = 0..m. (2 * m + 1 choose (k + (m + 1))))"

  1314     by (subst setsum_shift_bounds_cl_nat_ivl [symmetric]) (simp add: mult_2)

  1315   also have "\<dots> = (\<Sum>k = 0..m. (2 * m + 1 choose (m - k)))"

  1316     by (intro setsum.cong[OF refl], subst binomial_symmetric) simp_all

  1317   also have "\<dots> = (\<Sum>k = 0..m. (2 * m + 1 choose k))"

  1318     using setsum.atLeast_atMost_rev [of "\<lambda>k. 2 * m + 1 choose (m - k)" 0 m]

  1319     by simp

  1320   also have "\<dots> + \<dots> = 2 * \<dots>"

  1321     by simp

  1322   finally show ?thesis

  1323     by (subst (asm) mult_cancel1) (simp add: atLeast0AtMost)

  1324 qed

  1325

  1326 lemma gbinomial_r_part_sum: "(\<Sum>k\<le>m. (2 * (of_nat m) + 1 gchoose k)) = 2 ^ (2 * m)"

  1327   (is "?lhs = ?rhs")

  1328 proof -

  1329   have "?lhs = of_nat (\<Sum>k\<le>m. (2 * m + 1) choose k)"

  1330     by (simp add: binomial_gbinomial add_ac)

  1331   also have "\<dots> = of_nat (2 ^ (2 * m))"

  1332     by (subst binomial_r_part_sum) (rule refl)

  1333   finally show ?thesis by simp

  1334 qed

  1335

  1336 lemma gbinomial_sum_nat_pow2:

  1337   "(\<Sum>k\<le>m. (of_nat (m + k) gchoose k :: 'a::field_char_0) / 2 ^ k) = 2 ^ m"

  1338   (is "?lhs = ?rhs")

  1339 proof -

  1340   have "2 ^ m * 2 ^ m = (2 ^ (2*m) :: 'a)"

  1341     by (induct m) simp_all

  1342   also have "\<dots> = (\<Sum>k\<le>m. (2 * (of_nat m) + 1 gchoose k))"

  1343     using gbinomial_r_part_sum ..

  1344   also have "\<dots> = (\<Sum>k\<le>m. (of_nat (m + k) gchoose k) * 2 ^ (m - k))"

  1345     using gbinomial_partial_sum_poly_xpos[where x="1" and y="1" and r="of_nat m + 1" and m="m"]

  1346     by (simp add: add_ac)

  1347   also have "\<dots> = 2 ^ m * (\<Sum>k\<le>m. (of_nat (m + k) gchoose k) / 2 ^ k)"

  1348     by (subst setsum_right_distrib) (simp add: algebra_simps power_diff)

  1349   finally show ?thesis

  1350     by (subst (asm) mult_left_cancel) simp_all

  1351 qed

  1352

  1353 lemma gbinomial_trinomial_revision:

  1354   assumes "k \<le> m"

  1355   shows "(r gchoose m) * (of_nat m gchoose k) = (r gchoose k) * (r - of_nat k gchoose (m - k))"

  1356 proof -

  1357   have "(r gchoose m) * (of_nat m gchoose k) = (r gchoose m) * fact m / (fact k * fact (m - k))"

  1358     using assms by (simp add: binomial_gbinomial [symmetric] binomial_fact)

  1359   also have "\<dots> = (r gchoose k) * (r - of_nat k gchoose (m - k))"

  1360     using assms by (simp add: gbinomial_pochhammer power_diff pochhammer_product)

  1361   finally show ?thesis .

  1362 qed

  1363

  1364 text \<open>Versions of the theorems above for the natural-number version of "choose"\<close>

  1365 lemma binomial_altdef_of_nat:

  1366   "k \<le> n \<Longrightarrow> of_nat (n choose k) = (\<Prod>i = 0..<k. of_nat (n - i) / of_nat (k - i) :: 'a)"

  1367   for n k :: nat and x :: "'a::field_char_0"

  1368   by (simp add: gbinomial_altdef_of_nat binomial_gbinomial of_nat_diff)

  1369

  1370 lemma binomial_ge_n_over_k_pow_k: "k \<le> n \<Longrightarrow> (of_nat n / of_nat k :: 'a) ^ k \<le> of_nat (n choose k)"

  1371   for k n :: nat and x :: "'a::linordered_field"

  1372   by (simp add: gbinomial_ge_n_over_k_pow_k binomial_gbinomial of_nat_diff)

  1373

  1374 lemma binomial_le_pow:

  1375   assumes "r \<le> n"

  1376   shows "n choose r \<le> n ^ r"

  1377 proof -

  1378   have "n choose r \<le> fact n div fact (n - r)"

  1379     using assms by (subst binomial_fact_lemma[symmetric]) auto

  1380   with fact_div_fact_le_pow [OF assms] show ?thesis

  1381     by auto

  1382 qed

  1383

  1384 lemma binomial_altdef_nat: "k \<le> n \<Longrightarrow> n choose k = fact n div (fact k * fact (n - k))"

  1385   for k n :: nat

  1386   by (subst binomial_fact_lemma [symmetric]) auto

  1387

  1388 lemma choose_dvd:

  1389   "k \<le> n \<Longrightarrow> fact k * fact (n - k) dvd (fact n :: 'a::{semiring_div,linordered_semidom})"

  1390   unfolding dvd_def

  1391   apply (rule exI [where x="of_nat (n choose k)"])

  1392   using binomial_fact_lemma [of k n, THEN arg_cong [where f = of_nat and 'b='a]]

  1393   apply auto

  1394   done

  1395

  1396 lemma fact_fact_dvd_fact:

  1397   "fact k * fact n dvd (fact (k + n) :: 'a::{semiring_div,linordered_semidom})"

  1398   by (metis add.commute add_diff_cancel_left' choose_dvd le_add2)

  1399

  1400 lemma choose_mult_lemma:

  1401   "((m + r + k) choose (m + k)) * ((m + k) choose k) = ((m + r + k) choose k) * ((m + r) choose m)"

  1402   (is "?lhs = _")

  1403 proof -

  1404   have "?lhs =

  1405       fact (m + r + k) div (fact (m + k) * fact (m + r - m)) * (fact (m + k) div (fact k * fact m))"

  1406     by (simp add: binomial_altdef_nat)

  1407   also have "\<dots> = fact (m + r + k) div (fact r * (fact k * fact m))"

  1408     apply (subst div_mult_div_if_dvd)

  1409     apply (auto simp: algebra_simps fact_fact_dvd_fact)

  1410     apply (metis add.assoc add.commute fact_fact_dvd_fact)

  1411     done

  1412   also have "\<dots> = (fact (m + r + k) * fact (m + r)) div (fact r * (fact k * fact m) * fact (m + r))"

  1413     apply (subst div_mult_div_if_dvd [symmetric])

  1414     apply (auto simp add: algebra_simps)

  1415     apply (metis fact_fact_dvd_fact dvd_trans nat_mult_dvd_cancel_disj)

  1416     done

  1417   also have "\<dots> =

  1418       (fact (m + r + k) div (fact k * fact (m + r)) * (fact (m + r) div (fact r * fact m)))"

  1419     apply (subst div_mult_div_if_dvd)

  1420     apply (auto simp: fact_fact_dvd_fact algebra_simps)

  1421     done

  1422   finally show ?thesis

  1423     by (simp add: binomial_altdef_nat mult.commute)

  1424 qed

  1425

  1426 text \<open>The "Subset of a Subset" identity.\<close>

  1427 lemma choose_mult:

  1428   "k \<le> m \<Longrightarrow> m \<le> n \<Longrightarrow> (n choose m) * (m choose k) = (n choose k) * ((n - k) choose (m - k))"

  1429   using choose_mult_lemma [of "m-k" "n-m" k] by simp

  1430

  1431

  1432 subsection \<open>More on Binomial Coefficients\<close>

  1433

  1434 lemma choose_one: "n choose 1 = n" for n :: nat

  1435   by simp

  1436

  1437 lemma card_UNION:

  1438   assumes "finite A"

  1439     and "\<forall>k \<in> A. finite k"

  1440   shows "card (\<Union>A) = nat (\<Sum>I | I \<subseteq> A \<and> I \<noteq> {}. (- 1) ^ (card I + 1) * int (card (\<Inter>I)))"

  1441   (is "?lhs = ?rhs")

  1442 proof -

  1443   have "?rhs = nat (\<Sum>I | I \<subseteq> A \<and> I \<noteq> {}. (- 1) ^ (card I + 1) * (\<Sum>_\<in>\<Inter>I. 1))"

  1444     by simp

  1445   also have "\<dots> = nat (\<Sum>I | I \<subseteq> A \<and> I \<noteq> {}. (\<Sum>_\<in>\<Inter>I. (- 1) ^ (card I + 1)))"

  1446     (is "_ = nat ?rhs")

  1447     by (subst setsum_right_distrib) simp

  1448   also have "?rhs = (\<Sum>(I, _)\<in>Sigma {I. I \<subseteq> A \<and> I \<noteq> {}} Inter. (- 1) ^ (card I + 1))"

  1449     using assms by (subst setsum.Sigma) auto

  1450   also have "\<dots> = (\<Sum>(x, I)\<in>(SIGMA x:UNIV. {I. I \<subseteq> A \<and> I \<noteq> {} \<and> x \<in> \<Inter>I}). (- 1) ^ (card I + 1))"

  1451     by (rule setsum.reindex_cong [where l = "\<lambda>(x, y). (y, x)"]) (auto intro: inj_onI simp add: split_beta)

  1452   also have "\<dots> = (\<Sum>(x, I)\<in>(SIGMA x:\<Union>A. {I. I \<subseteq> A \<and> I \<noteq> {} \<and> x \<in> \<Inter>I}). (- 1) ^ (card I + 1))"

  1453     using assms

  1454     by (auto intro!: setsum.mono_neutral_cong_right finite_SigmaI2 intro: finite_subset[where B="\<Union>A"])

  1455   also have "\<dots> = (\<Sum>x\<in>\<Union>A. (\<Sum>I|I \<subseteq> A \<and> I \<noteq> {} \<and> x \<in> \<Inter>I. (- 1) ^ (card I + 1)))"

  1456     using assms by (subst setsum.Sigma) auto

  1457   also have "\<dots> = (\<Sum>_\<in>\<Union>A. 1)" (is "setsum ?lhs _ = _")

  1458   proof (rule setsum.cong[OF refl])

  1459     fix x

  1460     assume x: "x \<in> \<Union>A"

  1461     define K where "K = {X \<in> A. x \<in> X}"

  1462     with \<open>finite A\<close> have K: "finite K"

  1463       by auto

  1464     let ?I = "\<lambda>i. {I. I \<subseteq> A \<and> card I = i \<and> x \<in> \<Inter>I}"

  1465     have "inj_on snd (SIGMA i:{1..card A}. ?I i)"

  1466       using assms by (auto intro!: inj_onI)

  1467     moreover have [symmetric]: "snd  (SIGMA i:{1..card A}. ?I i) = {I. I \<subseteq> A \<and> I \<noteq> {} \<and> x \<in> \<Inter>I}"

  1468       using assms

  1469       by (auto intro!: rev_image_eqI[where x="(card a, a)" for a]

  1470         simp add: card_gt_0_iff[folded Suc_le_eq]

  1471         dest: finite_subset intro: card_mono)

  1472     ultimately have "?lhs x = (\<Sum>(i, I)\<in>(SIGMA i:{1..card A}. ?I i). (- 1) ^ (i + 1))"

  1473       by (rule setsum.reindex_cong [where l = snd]) fastforce

  1474     also have "\<dots> = (\<Sum>i=1..card A. (\<Sum>I|I \<subseteq> A \<and> card I = i \<and> x \<in> \<Inter>I. (- 1) ^ (i + 1)))"

  1475       using assms by (subst setsum.Sigma) auto

  1476     also have "\<dots> = (\<Sum>i=1..card A. (- 1) ^ (i + 1) * (\<Sum>I|I \<subseteq> A \<and> card I = i \<and> x \<in> \<Inter>I. 1))"

  1477       by (subst setsum_right_distrib) simp

  1478     also have "\<dots> = (\<Sum>i=1..card K. (- 1) ^ (i + 1) * (\<Sum>I|I \<subseteq> K \<and> card I = i. 1))"

  1479       (is "_ = ?rhs")

  1480     proof (rule setsum.mono_neutral_cong_right[rule_format])

  1481       show "finite {1..card A}"

  1482         by simp

  1483       show "{1..card K} \<subseteq> {1..card A}"

  1484         using \<open>finite A\<close> by (auto simp add: K_def intro: card_mono)

  1485     next

  1486       fix i

  1487       assume "i \<in> {1..card A} - {1..card K}"

  1488       then have i: "i \<le> card A" "card K < i"

  1489         by auto

  1490       have "{I. I \<subseteq> A \<and> card I = i \<and> x \<in> \<Inter>I} = {I. I \<subseteq> K \<and> card I = i}"

  1491         by (auto simp add: K_def)

  1492       also have "\<dots> = {}"

  1493         using \<open>finite A\<close> i by (auto simp add: K_def dest: card_mono[rotated 1])

  1494       finally show "(- 1) ^ (i + 1) * (\<Sum>I | I \<subseteq> A \<and> card I = i \<and> x \<in> \<Inter>I. 1 :: int) = 0"

  1495         by (simp only:) simp

  1496     next

  1497       fix i

  1498       have "(\<Sum>I | I \<subseteq> A \<and> card I = i \<and> x \<in> \<Inter>I. 1) = (\<Sum>I | I \<subseteq> K \<and> card I = i. 1 :: int)"

  1499         (is "?lhs = ?rhs")

  1500         by (rule setsum.cong) (auto simp add: K_def)

  1501       then show "(- 1) ^ (i + 1) * ?lhs = (- 1) ^ (i + 1) * ?rhs"

  1502         by simp

  1503     qed

  1504     also have "{I. I \<subseteq> K \<and> card I = 0} = {{}}"

  1505       using assms by (auto simp add: card_eq_0_iff K_def dest: finite_subset)

  1506     then have "?rhs = (\<Sum>i = 0..card K. (- 1) ^ (i + 1) * (\<Sum>I | I \<subseteq> K \<and> card I = i. 1 :: int)) + 1"

  1507       by (subst (2) setsum_head_Suc) simp_all

  1508     also have "\<dots> = (\<Sum>i = 0..card K. (- 1) * ((- 1) ^ i * int (card K choose i))) + 1"

  1509       using K by (subst n_subsets[symmetric]) simp_all

  1510     also have "\<dots> = - (\<Sum>i = 0..card K. (- 1) ^ i * int (card K choose i)) + 1"

  1511       by (subst setsum_right_distrib[symmetric]) simp

  1512     also have "\<dots> =  - ((-1 + 1) ^ card K) + 1"

  1513       by (subst binomial_ring) (simp add: ac_simps)

  1514     also have "\<dots> = 1"

  1515       using x K by (auto simp add: K_def card_gt_0_iff)

  1516     finally show "?lhs x = 1" .

  1517   qed

  1518   also have "nat \<dots> = card (\<Union>A)"

  1519     by simp

  1520   finally show ?thesis ..

  1521 qed

  1522

  1523 text \<open>The number of nat lists of length \<open>m\<close> summing to \<open>N\<close> is @{term "(N + m - 1) choose N"}:\<close>

  1524 lemma card_length_sum_list_rec:

  1525   assumes "m \<ge> 1"

  1526   shows "card {l::nat list. length l = m \<and> sum_list l = N} =

  1527       card {l. length l = (m - 1) \<and> sum_list l = N} +

  1528       card {l. length l = m \<and> sum_list l + 1 = N}"

  1529     (is "card ?C = card ?A + card ?B")

  1530 proof -

  1531   let ?A' = "{l. length l = m \<and> sum_list l = N \<and> hd l = 0}"

  1532   let ?B' = "{l. length l = m \<and> sum_list l = N \<and> hd l \<noteq> 0}"

  1533   let ?f = "\<lambda>l. 0 # l"

  1534   let ?g = "\<lambda>l. (hd l + 1) # tl l"

  1535   have 1: "xs \<noteq> [] \<Longrightarrow> x = hd xs \<Longrightarrow> x # tl xs = xs" for x xs

  1536     by simp

  1537   have 2: "xs \<noteq> [] \<Longrightarrow> sum_list(tl xs) = sum_list xs - hd xs" for xs :: "nat list"

  1538     by (auto simp add: neq_Nil_conv)

  1539   have f: "bij_betw ?f ?A ?A'"

  1540     apply (rule bij_betw_byWitness[where f' = tl])

  1541     using assms

  1542     apply (auto simp: 2 length_0_conv[symmetric] 1 simp del: length_0_conv)

  1543     done

  1544   have 3: "xs \<noteq> [] \<Longrightarrow> hd xs + (sum_list xs - hd xs) = sum_list xs" for xs :: "nat list"

  1545     by (metis 1 sum_list_simps(2) 2)

  1546   have g: "bij_betw ?g ?B ?B'"

  1547     apply (rule bij_betw_byWitness[where f' = "\<lambda>l. (hd l - 1) # tl l"])

  1548     using assms

  1549     by (auto simp: 2 length_0_conv[symmetric] intro!: 3

  1550         simp del: length_greater_0_conv length_0_conv)

  1551   have fin: "finite {xs. size xs = M \<and> set xs \<subseteq> {0..<N}}" for M N :: nat

  1552     using finite_lists_length_eq[OF finite_atLeastLessThan] conj_commute by auto

  1553   have fin_A: "finite ?A" using fin[of _ "N+1"]

  1554     by (intro finite_subset[where ?A = "?A" and ?B = "{xs. size xs = m - 1 \<and> set xs \<subseteq> {0..<N+1}}"])

  1555       (auto simp: member_le_sum_list_nat less_Suc_eq_le)

  1556   have fin_B: "finite ?B"

  1557     by (intro finite_subset[where ?A = "?B" and ?B = "{xs. size xs = m \<and> set xs \<subseteq> {0..<N}}"])

  1558       (auto simp: member_le_sum_list_nat less_Suc_eq_le fin)

  1559   have uni: "?C = ?A' \<union> ?B'"

  1560     by auto

  1561   have disj: "?A' \<inter> ?B' = {}"

  1562     by auto

  1563   have "card ?C = card(?A' \<union> ?B')"

  1564     using uni by simp

  1565   also have "\<dots> = card ?A + card ?B"

  1566     using card_Un_disjoint[OF _ _ disj] bij_betw_finite[OF f] bij_betw_finite[OF g]

  1567       bij_betw_same_card[OF f] bij_betw_same_card[OF g] fin_A fin_B

  1568     by presburger

  1569   finally show ?thesis .

  1570 qed

  1571

  1572 lemma card_length_sum_list: "card {l::nat list. size l = m \<and> sum_list l = N} = (N + m - 1) choose N"

  1573   \<comment> "by Holden Lee, tidied by Tobias Nipkow"

  1574 proof (cases m)

  1575   case 0

  1576   then show ?thesis

  1577     by (cases N) (auto cong: conj_cong)

  1578 next

  1579   case (Suc m')

  1580   have m: "m \<ge> 1"

  1581     by (simp add: Suc)

  1582   then show ?thesis

  1583   proof (induct "N + m - 1" arbitrary: N m)

  1584     case 0  \<comment> "In the base case, the only solution is ."

  1585     have [simp]: "{l::nat list. length l = Suc 0 \<and> (\<forall>n\<in>set l. n = 0)} = {}"

  1586       by (auto simp: length_Suc_conv)

  1587     have "m = 1 \<and> N = 0"

  1588       using 0 by linarith

  1589     then show ?case

  1590       by simp

  1591   next

  1592     case (Suc k)

  1593     have c1: "card {l::nat list. size l = (m - 1) \<and> sum_list l =  N} = (N + (m - 1) - 1) choose N"

  1594     proof (cases "m = 1")

  1595       case True

  1596       with Suc.hyps have "N \<ge> 1"

  1597         by auto

  1598       with True show ?thesis

  1599         by (simp add: binomial_eq_0)

  1600     next

  1601       case False

  1602       then show ?thesis

  1603         using Suc by fastforce

  1604     qed

  1605     from Suc have c2: "card {l::nat list. size l = m \<and> sum_list l + 1 = N} =

  1606       (if N > 0 then ((N - 1) + m - 1) choose (N - 1) else 0)"

  1607     proof -

  1608       have *: "n > 0 \<Longrightarrow> Suc m = n \<longleftrightarrow> m = n - 1" for m n

  1609         by arith

  1610       from Suc have "N > 0 \<Longrightarrow>

  1611         card {l::nat list. size l = m \<and> sum_list l + 1 = N} =

  1612           ((N - 1) + m - 1) choose (N - 1)"

  1613         by (simp add: *)

  1614       then show ?thesis

  1615         by auto

  1616     qed

  1617     from Suc.prems have "(card {l::nat list. size l = (m - 1) \<and> sum_list l = N} +

  1618           card {l::nat list. size l = m \<and> sum_list l + 1 = N}) = (N + m - 1) choose N"

  1619       by (auto simp: c1 c2 choose_reduce_nat[of "N + m - 1" N] simp del: One_nat_def)

  1620     then show ?case

  1621       using card_length_sum_list_rec[OF Suc.prems] by auto

  1622   qed

  1623 qed

  1624

  1625 lemma Suc_times_binomial_add: "Suc a * (Suc (a + b) choose Suc a) = Suc b * (Suc (a + b) choose a)"

  1626   \<comment> \<open>by Lukas Bulwahn\<close>

  1627 proof -

  1628   have dvd: "Suc a * (fact a * fact b) dvd fact (Suc (a + b))" for a b

  1629     using fact_fact_dvd_fact[of "Suc a" "b", where 'a=nat]

  1630     by (simp only: fact_Suc add_Suc[symmetric] of_nat_id mult.assoc)

  1631   have "Suc a * (fact (Suc (a + b)) div (Suc a * fact a * fact b)) =

  1632       Suc a * fact (Suc (a + b)) div (Suc a * (fact a * fact b))"

  1633     by (subst div_mult_swap[symmetric]; simp only: mult.assoc dvd)

  1634   also have "\<dots> = Suc b * fact (Suc (a + b)) div (Suc b * (fact a * fact b))"

  1635     by (simp only: div_mult_mult1)

  1636   also have "\<dots> = Suc b * (fact (Suc (a + b)) div (Suc b * (fact a * fact b)))"

  1637     using dvd[of b a] by (subst div_mult_swap[symmetric]; simp only: ac_simps dvd)

  1638   finally show ?thesis

  1639     by (subst (1 2) binomial_altdef_nat)

  1640       (simp_all only: ac_simps diff_Suc_Suc Suc_diff_le diff_add_inverse fact_Suc of_nat_id)

  1641 qed

  1642

  1643

  1644 subsection \<open>Misc\<close>

  1645

  1646 lemma fact_code [code]:

  1647   "fact n = (of_nat (fold_atLeastAtMost_nat (op *) 2 n 1) :: 'a::semiring_char_0)"

  1648 proof -

  1649   have "fact n = (of_nat (\<Prod>{1..n}) :: 'a)"

  1650     by (simp add: fact_setprod)

  1651   also have "\<Prod>{1..n} = \<Prod>{2..n}"

  1652     by (intro setprod.mono_neutral_right) auto

  1653   also have "\<dots> = fold_atLeastAtMost_nat (op *) 2 n 1"

  1654     by (simp add: setprod_atLeastAtMost_code)

  1655   finally show ?thesis .

  1656 qed

  1657

  1658 lemma pochhammer_code [code]:

  1659   "pochhammer a n =

  1660     (if n = 0 then 1

  1661      else fold_atLeastAtMost_nat (\<lambda>n acc. (a + of_nat n) * acc) 0 (n - 1) 1)"

  1662   by (cases n)

  1663     (simp_all add: pochhammer_setprod setprod_atLeastAtMost_code [symmetric]

  1664       atLeastLessThanSuc_atLeastAtMost)

  1665

  1666 lemma gbinomial_code [code]:

  1667   "a gchoose n =

  1668     (if n = 0 then 1

  1669      else fold_atLeastAtMost_nat (\<lambda>n acc. (a - of_nat n) * acc) 0 (n - 1) 1 / fact n)"

  1670   by (cases n)

  1671     (simp_all add: gbinomial_setprod_rev setprod_atLeastAtMost_code [symmetric]

  1672       atLeastLessThanSuc_atLeastAtMost)

  1673

  1674 (* FIXME *)

  1675 (*TODO: This code equation breaks Scala code generation in HOL-Codegenerator_Test. We have to figure out why and how to prevent that. *)

  1676

  1677 (*

  1678 lemma binomial_code [code]:

  1679   "(n choose k) =

  1680       (if k > n then 0

  1681        else if 2 * k > n then (n choose (n - k))

  1682        else (fold_atLeastAtMost_nat (op * ) (n-k+1) n 1 div fact k))"

  1683 proof -

  1684   {

  1685     assume "k \<le> n"

  1686     then have "{1..n} = {1..n-k} \<union> {n-k+1..n}" by auto

  1687     then have "(fact n :: nat) = fact (n-k) * \<Prod>{n-k+1..n}"

  1688       by (simp add: setprod.union_disjoint fact_altdef_nat)

  1689   }

  1690   then show ?thesis by (auto simp: binomial_altdef_nat mult_ac setprod_atLeastAtMost_code)

  1691 qed

  1692 *)

  1693

  1694 end