src/HOL/Complex.thy
author wenzelm
Sun Sep 18 20:33:48 2016 +0200 (2016-09-18)
changeset 63915 bab633745c7f
parent 63569 7e0b0db5e9ac
child 64267 b9a1486e79be
permissions -rw-r--r--
tuned proofs;
     1 (*  Title:       HOL/Complex.thy
     2     Author:      Jacques D. Fleuriot, 2001 University of Edinburgh
     3     Author:      Lawrence C Paulson, 2003/4
     4 *)
     5 
     6 section \<open>Complex Numbers: Rectangular and Polar Representations\<close>
     7 
     8 theory Complex
     9 imports Transcendental
    10 begin
    11 
    12 text \<open>
    13   We use the \<^theory_text>\<open>codatatype\<close> command to define the type of complex numbers. This
    14   allows us to use \<^theory_text>\<open>primcorec\<close> to define complex functions by defining their
    15   real and imaginary result separately.
    16 \<close>
    17 
    18 codatatype complex = Complex (Re: real) (Im: real)
    19 
    20 lemma complex_surj: "Complex (Re z) (Im z) = z"
    21   by (rule complex.collapse)
    22 
    23 lemma complex_eqI [intro?]: "Re x = Re y \<Longrightarrow> Im x = Im y \<Longrightarrow> x = y"
    24   by (rule complex.expand) simp
    25 
    26 lemma complex_eq_iff: "x = y \<longleftrightarrow> Re x = Re y \<and> Im x = Im y"
    27   by (auto intro: complex.expand)
    28 
    29 
    30 subsection \<open>Addition and Subtraction\<close>
    31 
    32 instantiation complex :: ab_group_add
    33 begin
    34 
    35 primcorec zero_complex
    36   where
    37     "Re 0 = 0"
    38   | "Im 0 = 0"
    39 
    40 primcorec plus_complex
    41   where
    42     "Re (x + y) = Re x + Re y"
    43   | "Im (x + y) = Im x + Im y"
    44 
    45 primcorec uminus_complex
    46   where
    47     "Re (- x) = - Re x"
    48   | "Im (- x) = - Im x"
    49 
    50 primcorec minus_complex
    51   where
    52     "Re (x - y) = Re x - Re y"
    53   | "Im (x - y) = Im x - Im y"
    54 
    55 instance
    56   by standard (simp_all add: complex_eq_iff)
    57 
    58 end
    59 
    60 
    61 subsection \<open>Multiplication and Division\<close>
    62 
    63 instantiation complex :: field
    64 begin
    65 
    66 primcorec one_complex
    67   where
    68     "Re 1 = 1"
    69   | "Im 1 = 0"
    70 
    71 primcorec times_complex
    72   where
    73     "Re (x * y) = Re x * Re y - Im x * Im y"
    74   | "Im (x * y) = Re x * Im y + Im x * Re y"
    75 
    76 primcorec inverse_complex
    77   where
    78     "Re (inverse x) = Re x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)"
    79   | "Im (inverse x) = - Im x / ((Re x)\<^sup>2 + (Im x)\<^sup>2)"
    80 
    81 definition "x div y = x * inverse y" for x y :: complex
    82 
    83 instance
    84   by standard
    85      (simp_all add: complex_eq_iff divide_complex_def
    86       distrib_left distrib_right right_diff_distrib left_diff_distrib
    87       power2_eq_square add_divide_distrib [symmetric])
    88 
    89 end
    90 
    91 lemma Re_divide: "Re (x / y) = (Re x * Re y + Im x * Im y) / ((Re y)\<^sup>2 + (Im y)\<^sup>2)"
    92   by (simp add: divide_complex_def add_divide_distrib)
    93 
    94 lemma Im_divide: "Im (x / y) = (Im x * Re y - Re x * Im y) / ((Re y)\<^sup>2 + (Im y)\<^sup>2)"
    95   unfolding divide_complex_def times_complex.sel inverse_complex.sel
    96   by (simp add: divide_simps)
    97 
    98 lemma Re_power2: "Re (x ^ 2) = (Re x)^2 - (Im x)^2"
    99   by (simp add: power2_eq_square)
   100 
   101 lemma Im_power2: "Im (x ^ 2) = 2 * Re x * Im x"
   102   by (simp add: power2_eq_square)
   103 
   104 lemma Re_power_real [simp]: "Im x = 0 \<Longrightarrow> Re (x ^ n) = Re x ^ n "
   105   by (induct n) simp_all
   106 
   107 lemma Im_power_real [simp]: "Im x = 0 \<Longrightarrow> Im (x ^ n) = 0"
   108   by (induct n) simp_all
   109 
   110 
   111 subsection \<open>Scalar Multiplication\<close>
   112 
   113 instantiation complex :: real_field
   114 begin
   115 
   116 primcorec scaleR_complex
   117   where
   118     "Re (scaleR r x) = r * Re x"
   119   | "Im (scaleR r x) = r * Im x"
   120 
   121 instance
   122 proof
   123   fix a b :: real and x y :: complex
   124   show "scaleR a (x + y) = scaleR a x + scaleR a y"
   125     by (simp add: complex_eq_iff distrib_left)
   126   show "scaleR (a + b) x = scaleR a x + scaleR b x"
   127     by (simp add: complex_eq_iff distrib_right)
   128   show "scaleR a (scaleR b x) = scaleR (a * b) x"
   129     by (simp add: complex_eq_iff mult.assoc)
   130   show "scaleR 1 x = x"
   131     by (simp add: complex_eq_iff)
   132   show "scaleR a x * y = scaleR a (x * y)"
   133     by (simp add: complex_eq_iff algebra_simps)
   134   show "x * scaleR a y = scaleR a (x * y)"
   135     by (simp add: complex_eq_iff algebra_simps)
   136 qed
   137 
   138 end
   139 
   140 
   141 subsection \<open>Numerals, Arithmetic, and Embedding from Reals\<close>
   142 
   143 abbreviation complex_of_real :: "real \<Rightarrow> complex"
   144   where "complex_of_real \<equiv> of_real"
   145 
   146 declare [[coercion "of_real :: real \<Rightarrow> complex"]]
   147 declare [[coercion "of_rat :: rat \<Rightarrow> complex"]]
   148 declare [[coercion "of_int :: int \<Rightarrow> complex"]]
   149 declare [[coercion "of_nat :: nat \<Rightarrow> complex"]]
   150 
   151 lemma complex_Re_of_nat [simp]: "Re (of_nat n) = of_nat n"
   152   by (induct n) simp_all
   153 
   154 lemma complex_Im_of_nat [simp]: "Im (of_nat n) = 0"
   155   by (induct n) simp_all
   156 
   157 lemma complex_Re_of_int [simp]: "Re (of_int z) = of_int z"
   158   by (cases z rule: int_diff_cases) simp
   159 
   160 lemma complex_Im_of_int [simp]: "Im (of_int z) = 0"
   161   by (cases z rule: int_diff_cases) simp
   162 
   163 lemma complex_Re_numeral [simp]: "Re (numeral v) = numeral v"
   164   using complex_Re_of_int [of "numeral v"] by simp
   165 
   166 lemma complex_Im_numeral [simp]: "Im (numeral v) = 0"
   167   using complex_Im_of_int [of "numeral v"] by simp
   168 
   169 lemma Re_complex_of_real [simp]: "Re (complex_of_real z) = z"
   170   by (simp add: of_real_def)
   171 
   172 lemma Im_complex_of_real [simp]: "Im (complex_of_real z) = 0"
   173   by (simp add: of_real_def)
   174 
   175 lemma Re_divide_numeral [simp]: "Re (z / numeral w) = Re z / numeral w"
   176   by (simp add: Re_divide sqr_conv_mult)
   177 
   178 lemma Im_divide_numeral [simp]: "Im (z / numeral w) = Im z / numeral w"
   179   by (simp add: Im_divide sqr_conv_mult)
   180 
   181 lemma Re_divide_of_nat [simp]: "Re (z / of_nat n) = Re z / of_nat n"
   182   by (cases n) (simp_all add: Re_divide divide_simps power2_eq_square del: of_nat_Suc)
   183 
   184 lemma Im_divide_of_nat [simp]: "Im (z / of_nat n) = Im z / of_nat n"
   185   by (cases n) (simp_all add: Im_divide divide_simps power2_eq_square del: of_nat_Suc)
   186 
   187 lemma of_real_Re [simp]: "z \<in> \<real> \<Longrightarrow> of_real (Re z) = z"
   188   by (auto simp: Reals_def)
   189 
   190 lemma complex_Re_fact [simp]: "Re (fact n) = fact n"
   191 proof -
   192   have "(fact n :: complex) = of_real (fact n)"
   193     by simp
   194   also have "Re \<dots> = fact n"
   195     by (subst Re_complex_of_real) simp_all
   196   finally show ?thesis .
   197 qed
   198 
   199 lemma complex_Im_fact [simp]: "Im (fact n) = 0"
   200   by (subst of_nat_fact [symmetric]) (simp only: complex_Im_of_nat)
   201 
   202 
   203 subsection \<open>The Complex Number $i$\<close>
   204 
   205 primcorec "ii" :: complex  ("\<i>")
   206   where
   207     "Re \<i> = 0"
   208   | "Im \<i> = 1"
   209 
   210 lemma Complex_eq[simp]: "Complex a b = a + \<i> * b"
   211   by (simp add: complex_eq_iff)
   212 
   213 lemma complex_eq: "a = Re a + \<i> * Im a"
   214   by (simp add: complex_eq_iff)
   215 
   216 lemma fun_complex_eq: "f = (\<lambda>x. Re (f x) + \<i> * Im (f x))"
   217   by (simp add: fun_eq_iff complex_eq)
   218 
   219 lemma i_squared [simp]: "\<i> * \<i> = -1"
   220   by (simp add: complex_eq_iff)
   221 
   222 lemma power2_i [simp]: "\<i>\<^sup>2 = -1"
   223   by (simp add: power2_eq_square)
   224 
   225 lemma inverse_i [simp]: "inverse \<i> = - \<i>"
   226   by (rule inverse_unique) simp
   227 
   228 lemma divide_i [simp]: "x / \<i> = - \<i> * x"
   229   by (simp add: divide_complex_def)
   230 
   231 lemma complex_i_mult_minus [simp]: "\<i> * (\<i> * x) = - x"
   232   by (simp add: mult.assoc [symmetric])
   233 
   234 lemma complex_i_not_zero [simp]: "\<i> \<noteq> 0"
   235   by (simp add: complex_eq_iff)
   236 
   237 lemma complex_i_not_one [simp]: "\<i> \<noteq> 1"
   238   by (simp add: complex_eq_iff)
   239 
   240 lemma complex_i_not_numeral [simp]: "\<i> \<noteq> numeral w"
   241   by (simp add: complex_eq_iff)
   242 
   243 lemma complex_i_not_neg_numeral [simp]: "\<i> \<noteq> - numeral w"
   244   by (simp add: complex_eq_iff)
   245 
   246 lemma complex_split_polar: "\<exists>r a. z = complex_of_real r * (cos a + \<i> * sin a)"
   247   by (simp add: complex_eq_iff polar_Ex)
   248 
   249 lemma i_even_power [simp]: "\<i> ^ (n * 2) = (-1) ^ n"
   250   by (metis mult.commute power2_i power_mult)
   251 
   252 lemma Re_ii_times [simp]: "Re (\<i> * z) = - Im z"
   253   by simp
   254 
   255 lemma Im_ii_times [simp]: "Im (\<i> * z) = Re z"
   256   by simp
   257 
   258 lemma ii_times_eq_iff: "\<i> * w = z \<longleftrightarrow> w = - (\<i> * z)"
   259   by auto
   260 
   261 lemma divide_numeral_i [simp]: "z / (numeral n * \<i>) = - (\<i> * z) / numeral n"
   262   by (metis divide_divide_eq_left divide_i mult.commute mult_minus_right)
   263 
   264 
   265 subsection \<open>Vector Norm\<close>
   266 
   267 instantiation complex :: real_normed_field
   268 begin
   269 
   270 definition "norm z = sqrt ((Re z)\<^sup>2 + (Im z)\<^sup>2)"
   271 
   272 abbreviation cmod :: "complex \<Rightarrow> real"
   273   where "cmod \<equiv> norm"
   274 
   275 definition complex_sgn_def: "sgn x = x /\<^sub>R cmod x"
   276 
   277 definition dist_complex_def: "dist x y = cmod (x - y)"
   278 
   279 definition uniformity_complex_def [code del]:
   280   "(uniformity :: (complex \<times> complex) filter) = (INF e:{0 <..}. principal {(x, y). dist x y < e})"
   281 
   282 definition open_complex_def [code del]:
   283   "open (U :: complex set) \<longleftrightarrow> (\<forall>x\<in>U. eventually (\<lambda>(x', y). x' = x \<longrightarrow> y \<in> U) uniformity)"
   284 
   285 instance
   286 proof
   287   fix r :: real and x y :: complex and S :: "complex set"
   288   show "(norm x = 0) = (x = 0)"
   289     by (simp add: norm_complex_def complex_eq_iff)
   290   show "norm (x + y) \<le> norm x + norm y"
   291     by (simp add: norm_complex_def complex_eq_iff real_sqrt_sum_squares_triangle_ineq)
   292   show "norm (scaleR r x) = \<bar>r\<bar> * norm x"
   293     by (simp add: norm_complex_def complex_eq_iff power_mult_distrib distrib_left [symmetric]
   294         real_sqrt_mult)
   295   show "norm (x * y) = norm x * norm y"
   296     by (simp add: norm_complex_def complex_eq_iff real_sqrt_mult [symmetric]
   297         power2_eq_square algebra_simps)
   298 qed (rule complex_sgn_def dist_complex_def open_complex_def uniformity_complex_def)+
   299 
   300 end
   301 
   302 declare uniformity_Abort[where 'a = complex, code]
   303 
   304 lemma norm_ii [simp]: "norm \<i> = 1"
   305   by (simp add: norm_complex_def)
   306 
   307 lemma cmod_unit_one: "cmod (cos a + \<i> * sin a) = 1"
   308   by (simp add: norm_complex_def)
   309 
   310 lemma cmod_complex_polar: "cmod (r * (cos a + \<i> * sin a)) = \<bar>r\<bar>"
   311   by (simp add: norm_mult cmod_unit_one)
   312 
   313 lemma complex_Re_le_cmod: "Re x \<le> cmod x"
   314   unfolding norm_complex_def by (rule real_sqrt_sum_squares_ge1)
   315 
   316 lemma complex_mod_minus_le_complex_mod: "- cmod x \<le> cmod x"
   317   by (rule order_trans [OF _ norm_ge_zero]) simp
   318 
   319 lemma complex_mod_triangle_ineq2: "cmod (b + a) - cmod b \<le> cmod a"
   320   by (rule ord_le_eq_trans [OF norm_triangle_ineq2]) simp
   321 
   322 lemma abs_Re_le_cmod: "\<bar>Re x\<bar> \<le> cmod x"
   323   by (simp add: norm_complex_def)
   324 
   325 lemma abs_Im_le_cmod: "\<bar>Im x\<bar> \<le> cmod x"
   326   by (simp add: norm_complex_def)
   327 
   328 lemma cmod_le: "cmod z \<le> \<bar>Re z\<bar> + \<bar>Im z\<bar>"
   329   apply (subst complex_eq)
   330   apply (rule order_trans)
   331    apply (rule norm_triangle_ineq)
   332   apply (simp add: norm_mult)
   333   done
   334 
   335 lemma cmod_eq_Re: "Im z = 0 \<Longrightarrow> cmod z = \<bar>Re z\<bar>"
   336   by (simp add: norm_complex_def)
   337 
   338 lemma cmod_eq_Im: "Re z = 0 \<Longrightarrow> cmod z = \<bar>Im z\<bar>"
   339   by (simp add: norm_complex_def)
   340 
   341 lemma cmod_power2: "(cmod z)\<^sup>2 = (Re z)\<^sup>2 + (Im z)\<^sup>2"
   342   by (simp add: norm_complex_def)
   343 
   344 lemma cmod_plus_Re_le_0_iff: "cmod z + Re z \<le> 0 \<longleftrightarrow> Re z = - cmod z"
   345   using abs_Re_le_cmod[of z] by auto
   346 
   347 lemma cmod_Re_le_iff: "Im x = Im y \<Longrightarrow> cmod x \<le> cmod y \<longleftrightarrow> \<bar>Re x\<bar> \<le> \<bar>Re y\<bar>"
   348   by (metis add.commute add_le_cancel_left norm_complex_def real_sqrt_abs real_sqrt_le_iff)
   349 
   350 lemma cmod_Im_le_iff: "Re x = Re y \<Longrightarrow> cmod x \<le> cmod y \<longleftrightarrow> \<bar>Im x\<bar> \<le> \<bar>Im y\<bar>"
   351   by (metis add_le_cancel_left norm_complex_def real_sqrt_abs real_sqrt_le_iff)
   352 
   353 lemma Im_eq_0: "\<bar>Re z\<bar> = cmod z \<Longrightarrow> Im z = 0"
   354   by (subst (asm) power_eq_iff_eq_base[symmetric, where n=2]) (auto simp add: norm_complex_def)
   355 
   356 lemma abs_sqrt_wlog: "(\<And>x. x \<ge> 0 \<Longrightarrow> P x (x\<^sup>2)) \<Longrightarrow> P \<bar>x\<bar> (x\<^sup>2)"
   357   for x::"'a::linordered_idom"
   358   by (metis abs_ge_zero power2_abs)
   359 
   360 lemma complex_abs_le_norm: "\<bar>Re z\<bar> + \<bar>Im z\<bar> \<le> sqrt 2 * norm z"
   361   unfolding norm_complex_def
   362   apply (rule abs_sqrt_wlog [where x="Re z"])
   363   apply (rule abs_sqrt_wlog [where x="Im z"])
   364   apply (rule power2_le_imp_le)
   365    apply (simp_all add: power2_sum add.commute sum_squares_bound real_sqrt_mult [symmetric])
   366   done
   367 
   368 lemma complex_unit_circle: "z \<noteq> 0 \<Longrightarrow> (Re z / cmod z)\<^sup>2 + (Im z / cmod z)\<^sup>2 = 1"
   369   by (simp add: norm_complex_def divide_simps complex_eq_iff)
   370 
   371 
   372 text \<open>Properties of complex signum.\<close>
   373 
   374 lemma sgn_eq: "sgn z = z / complex_of_real (cmod z)"
   375   by (simp add: sgn_div_norm divide_inverse scaleR_conv_of_real mult.commute)
   376 
   377 lemma Re_sgn [simp]: "Re(sgn z) = Re(z)/cmod z"
   378   by (simp add: complex_sgn_def divide_inverse)
   379 
   380 lemma Im_sgn [simp]: "Im(sgn z) = Im(z)/cmod z"
   381   by (simp add: complex_sgn_def divide_inverse)
   382 
   383 
   384 subsection \<open>Completeness of the Complexes\<close>
   385 
   386 lemma bounded_linear_Re: "bounded_linear Re"
   387   by (rule bounded_linear_intro [where K=1]) (simp_all add: norm_complex_def)
   388 
   389 lemma bounded_linear_Im: "bounded_linear Im"
   390   by (rule bounded_linear_intro [where K=1]) (simp_all add: norm_complex_def)
   391 
   392 lemmas Cauchy_Re = bounded_linear.Cauchy [OF bounded_linear_Re]
   393 lemmas Cauchy_Im = bounded_linear.Cauchy [OF bounded_linear_Im]
   394 lemmas tendsto_Re [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_Re]
   395 lemmas tendsto_Im [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_Im]
   396 lemmas isCont_Re [simp] = bounded_linear.isCont [OF bounded_linear_Re]
   397 lemmas isCont_Im [simp] = bounded_linear.isCont [OF bounded_linear_Im]
   398 lemmas continuous_Re [simp] = bounded_linear.continuous [OF bounded_linear_Re]
   399 lemmas continuous_Im [simp] = bounded_linear.continuous [OF bounded_linear_Im]
   400 lemmas continuous_on_Re [continuous_intros] = bounded_linear.continuous_on[OF bounded_linear_Re]
   401 lemmas continuous_on_Im [continuous_intros] = bounded_linear.continuous_on[OF bounded_linear_Im]
   402 lemmas has_derivative_Re [derivative_intros] = bounded_linear.has_derivative[OF bounded_linear_Re]
   403 lemmas has_derivative_Im [derivative_intros] = bounded_linear.has_derivative[OF bounded_linear_Im]
   404 lemmas sums_Re = bounded_linear.sums [OF bounded_linear_Re]
   405 lemmas sums_Im = bounded_linear.sums [OF bounded_linear_Im]
   406 
   407 lemma tendsto_Complex [tendsto_intros]:
   408   "(f \<longlongrightarrow> a) F \<Longrightarrow> (g \<longlongrightarrow> b) F \<Longrightarrow> ((\<lambda>x. Complex (f x) (g x)) \<longlongrightarrow> Complex a b) F"
   409   by (auto intro!: tendsto_intros)
   410 
   411 lemma tendsto_complex_iff:
   412   "(f \<longlongrightarrow> x) F \<longleftrightarrow> (((\<lambda>x. Re (f x)) \<longlongrightarrow> Re x) F \<and> ((\<lambda>x. Im (f x)) \<longlongrightarrow> Im x) F)"
   413 proof safe
   414   assume "((\<lambda>x. Re (f x)) \<longlongrightarrow> Re x) F" "((\<lambda>x. Im (f x)) \<longlongrightarrow> Im x) F"
   415   from tendsto_Complex[OF this] show "(f \<longlongrightarrow> x) F"
   416     unfolding complex.collapse .
   417 qed (auto intro: tendsto_intros)
   418 
   419 lemma continuous_complex_iff:
   420   "continuous F f \<longleftrightarrow> continuous F (\<lambda>x. Re (f x)) \<and> continuous F (\<lambda>x. Im (f x))"
   421   by (simp only: continuous_def tendsto_complex_iff)
   422 
   423 lemma has_vector_derivative_complex_iff: "(f has_vector_derivative x) F \<longleftrightarrow>
   424     ((\<lambda>x. Re (f x)) has_field_derivative (Re x)) F \<and>
   425     ((\<lambda>x. Im (f x)) has_field_derivative (Im x)) F"
   426   by (simp add: has_vector_derivative_def has_field_derivative_def has_derivative_def
   427       tendsto_complex_iff field_simps bounded_linear_scaleR_left bounded_linear_mult_right)
   428 
   429 lemma has_field_derivative_Re[derivative_intros]:
   430   "(f has_vector_derivative D) F \<Longrightarrow> ((\<lambda>x. Re (f x)) has_field_derivative (Re D)) F"
   431   unfolding has_vector_derivative_complex_iff by safe
   432 
   433 lemma has_field_derivative_Im[derivative_intros]:
   434   "(f has_vector_derivative D) F \<Longrightarrow> ((\<lambda>x. Im (f x)) has_field_derivative (Im D)) F"
   435   unfolding has_vector_derivative_complex_iff by safe
   436 
   437 instance complex :: banach
   438 proof
   439   fix X :: "nat \<Rightarrow> complex"
   440   assume X: "Cauchy X"
   441   then have "(\<lambda>n. Complex (Re (X n)) (Im (X n))) \<longlonglongrightarrow>
   442     Complex (lim (\<lambda>n. Re (X n))) (lim (\<lambda>n. Im (X n)))"
   443     by (intro tendsto_Complex convergent_LIMSEQ_iff[THEN iffD1]
   444         Cauchy_convergent_iff[THEN iffD1] Cauchy_Re Cauchy_Im)
   445   then show "convergent X"
   446     unfolding complex.collapse by (rule convergentI)
   447 qed
   448 
   449 declare DERIV_power[where 'a=complex, unfolded of_nat_def[symmetric], derivative_intros]
   450 
   451 
   452 subsection \<open>Complex Conjugation\<close>
   453 
   454 primcorec cnj :: "complex \<Rightarrow> complex"
   455   where
   456     "Re (cnj z) = Re z"
   457   | "Im (cnj z) = - Im z"
   458 
   459 lemma complex_cnj_cancel_iff [simp]: "cnj x = cnj y \<longleftrightarrow> x = y"
   460   by (simp add: complex_eq_iff)
   461 
   462 lemma complex_cnj_cnj [simp]: "cnj (cnj z) = z"
   463   by (simp add: complex_eq_iff)
   464 
   465 lemma complex_cnj_zero [simp]: "cnj 0 = 0"
   466   by (simp add: complex_eq_iff)
   467 
   468 lemma complex_cnj_zero_iff [iff]: "cnj z = 0 \<longleftrightarrow> z = 0"
   469   by (simp add: complex_eq_iff)
   470 
   471 lemma complex_cnj_add [simp]: "cnj (x + y) = cnj x + cnj y"
   472   by (simp add: complex_eq_iff)
   473 
   474 lemma cnj_setsum [simp]: "cnj (setsum f s) = (\<Sum>x\<in>s. cnj (f x))"
   475   by (induct s rule: infinite_finite_induct) auto
   476 
   477 lemma complex_cnj_diff [simp]: "cnj (x - y) = cnj x - cnj y"
   478   by (simp add: complex_eq_iff)
   479 
   480 lemma complex_cnj_minus [simp]: "cnj (- x) = - cnj x"
   481   by (simp add: complex_eq_iff)
   482 
   483 lemma complex_cnj_one [simp]: "cnj 1 = 1"
   484   by (simp add: complex_eq_iff)
   485 
   486 lemma complex_cnj_mult [simp]: "cnj (x * y) = cnj x * cnj y"
   487   by (simp add: complex_eq_iff)
   488 
   489 lemma cnj_setprod [simp]: "cnj (setprod f s) = (\<Prod>x\<in>s. cnj (f x))"
   490   by (induct s rule: infinite_finite_induct) auto
   491 
   492 lemma complex_cnj_inverse [simp]: "cnj (inverse x) = inverse (cnj x)"
   493   by (simp add: complex_eq_iff)
   494 
   495 lemma complex_cnj_divide [simp]: "cnj (x / y) = cnj x / cnj y"
   496   by (simp add: divide_complex_def)
   497 
   498 lemma complex_cnj_power [simp]: "cnj (x ^ n) = cnj x ^ n"
   499   by (induct n) simp_all
   500 
   501 lemma complex_cnj_of_nat [simp]: "cnj (of_nat n) = of_nat n"
   502   by (simp add: complex_eq_iff)
   503 
   504 lemma complex_cnj_of_int [simp]: "cnj (of_int z) = of_int z"
   505   by (simp add: complex_eq_iff)
   506 
   507 lemma complex_cnj_numeral [simp]: "cnj (numeral w) = numeral w"
   508   by (simp add: complex_eq_iff)
   509 
   510 lemma complex_cnj_neg_numeral [simp]: "cnj (- numeral w) = - numeral w"
   511   by (simp add: complex_eq_iff)
   512 
   513 lemma complex_cnj_scaleR [simp]: "cnj (scaleR r x) = scaleR r (cnj x)"
   514   by (simp add: complex_eq_iff)
   515 
   516 lemma complex_mod_cnj [simp]: "cmod (cnj z) = cmod z"
   517   by (simp add: norm_complex_def)
   518 
   519 lemma complex_cnj_complex_of_real [simp]: "cnj (of_real x) = of_real x"
   520   by (simp add: complex_eq_iff)
   521 
   522 lemma complex_cnj_i [simp]: "cnj \<i> = - \<i>"
   523   by (simp add: complex_eq_iff)
   524 
   525 lemma complex_add_cnj: "z + cnj z = complex_of_real (2 * Re z)"
   526   by (simp add: complex_eq_iff)
   527 
   528 lemma complex_diff_cnj: "z - cnj z = complex_of_real (2 * Im z) * \<i>"
   529   by (simp add: complex_eq_iff)
   530 
   531 lemma complex_mult_cnj: "z * cnj z = complex_of_real ((Re z)\<^sup>2 + (Im z)\<^sup>2)"
   532   by (simp add: complex_eq_iff power2_eq_square)
   533 
   534 lemma complex_mod_mult_cnj: "cmod (z * cnj z) = (cmod z)\<^sup>2"
   535   by (simp add: norm_mult power2_eq_square)
   536 
   537 lemma complex_mod_sqrt_Re_mult_cnj: "cmod z = sqrt (Re (z * cnj z))"
   538   by (simp add: norm_complex_def power2_eq_square)
   539 
   540 lemma complex_In_mult_cnj_zero [simp]: "Im (z * cnj z) = 0"
   541   by simp
   542 
   543 lemma complex_cnj_fact [simp]: "cnj (fact n) = fact n"
   544   by (subst of_nat_fact [symmetric], subst complex_cnj_of_nat) simp
   545 
   546 lemma complex_cnj_pochhammer [simp]: "cnj (pochhammer z n) = pochhammer (cnj z) n"
   547   by (induct n arbitrary: z) (simp_all add: pochhammer_rec)
   548 
   549 lemma bounded_linear_cnj: "bounded_linear cnj"
   550   using complex_cnj_add complex_cnj_scaleR by (rule bounded_linear_intro [where K=1]) simp
   551 
   552 lemmas tendsto_cnj [tendsto_intros] = bounded_linear.tendsto [OF bounded_linear_cnj]
   553   and isCont_cnj [simp] = bounded_linear.isCont [OF bounded_linear_cnj]
   554   and continuous_cnj [simp, continuous_intros] = bounded_linear.continuous [OF bounded_linear_cnj]
   555   and continuous_on_cnj [simp, continuous_intros] = bounded_linear.continuous_on [OF bounded_linear_cnj]
   556   and has_derivative_cnj [simp, derivative_intros] = bounded_linear.has_derivative [OF bounded_linear_cnj]
   557 
   558 lemma lim_cnj: "((\<lambda>x. cnj(f x)) \<longlongrightarrow> cnj l) F \<longleftrightarrow> (f \<longlongrightarrow> l) F"
   559   by (simp add: tendsto_iff dist_complex_def complex_cnj_diff [symmetric] del: complex_cnj_diff)
   560 
   561 lemma sums_cnj: "((\<lambda>x. cnj(f x)) sums cnj l) \<longleftrightarrow> (f sums l)"
   562   by (simp add: sums_def lim_cnj cnj_setsum [symmetric] del: cnj_setsum)
   563 
   564 
   565 subsection \<open>Basic Lemmas\<close>
   566 
   567 lemma complex_eq_0: "z=0 \<longleftrightarrow> (Re z)\<^sup>2 + (Im z)\<^sup>2 = 0"
   568   by (metis zero_complex.sel complex_eqI sum_power2_eq_zero_iff)
   569 
   570 lemma complex_neq_0: "z\<noteq>0 \<longleftrightarrow> (Re z)\<^sup>2 + (Im z)\<^sup>2 > 0"
   571   by (metis complex_eq_0 less_numeral_extra(3) sum_power2_gt_zero_iff)
   572 
   573 lemma complex_norm_square: "of_real ((norm z)\<^sup>2) = z * cnj z"
   574   by (cases z)
   575     (auto simp: complex_eq_iff norm_complex_def power2_eq_square[symmetric] of_real_power[symmetric]
   576       simp del: of_real_power)
   577 
   578 lemma complex_div_cnj: "a / b = (a * cnj b) / (norm b)\<^sup>2"
   579   using complex_norm_square by auto
   580 
   581 lemma Re_complex_div_eq_0: "Re (a / b) = 0 \<longleftrightarrow> Re (a * cnj b) = 0"
   582   by (auto simp add: Re_divide)
   583 
   584 lemma Im_complex_div_eq_0: "Im (a / b) = 0 \<longleftrightarrow> Im (a * cnj b) = 0"
   585   by (auto simp add: Im_divide)
   586 
   587 lemma complex_div_gt_0: "(Re (a / b) > 0 \<longleftrightarrow> Re (a * cnj b) > 0) \<and> (Im (a / b) > 0 \<longleftrightarrow> Im (a * cnj b) > 0)"
   588 proof (cases "b = 0")
   589   case True
   590   then show ?thesis by auto
   591 next
   592   case False
   593   then have "0 < (Re b)\<^sup>2 + (Im b)\<^sup>2"
   594     by (simp add: complex_eq_iff sum_power2_gt_zero_iff)
   595   then show ?thesis
   596     by (simp add: Re_divide Im_divide zero_less_divide_iff)
   597 qed
   598 
   599 lemma Re_complex_div_gt_0: "Re (a / b) > 0 \<longleftrightarrow> Re (a * cnj b) > 0"
   600   and Im_complex_div_gt_0: "Im (a / b) > 0 \<longleftrightarrow> Im (a * cnj b) > 0"
   601   using complex_div_gt_0 by auto
   602 
   603 lemma Re_complex_div_ge_0: "Re (a / b) \<ge> 0 \<longleftrightarrow> Re (a * cnj b) \<ge> 0"
   604   by (metis le_less Re_complex_div_eq_0 Re_complex_div_gt_0)
   605 
   606 lemma Im_complex_div_ge_0: "Im (a / b) \<ge> 0 \<longleftrightarrow> Im (a * cnj b) \<ge> 0"
   607   by (metis Im_complex_div_eq_0 Im_complex_div_gt_0 le_less)
   608 
   609 lemma Re_complex_div_lt_0: "Re (a / b) < 0 \<longleftrightarrow> Re (a * cnj b) < 0"
   610   by (metis less_asym neq_iff Re_complex_div_eq_0 Re_complex_div_gt_0)
   611 
   612 lemma Im_complex_div_lt_0: "Im (a / b) < 0 \<longleftrightarrow> Im (a * cnj b) < 0"
   613   by (metis Im_complex_div_eq_0 Im_complex_div_gt_0 less_asym neq_iff)
   614 
   615 lemma Re_complex_div_le_0: "Re (a / b) \<le> 0 \<longleftrightarrow> Re (a * cnj b) \<le> 0"
   616   by (metis not_le Re_complex_div_gt_0)
   617 
   618 lemma Im_complex_div_le_0: "Im (a / b) \<le> 0 \<longleftrightarrow> Im (a * cnj b) \<le> 0"
   619   by (metis Im_complex_div_gt_0 not_le)
   620 
   621 lemma Re_divide_of_real [simp]: "Re (z / of_real r) = Re z / r"
   622   by (simp add: Re_divide power2_eq_square)
   623 
   624 lemma Im_divide_of_real [simp]: "Im (z / of_real r) = Im z / r"
   625   by (simp add: Im_divide power2_eq_square)
   626 
   627 lemma Re_divide_Reals: "r \<in> Reals \<Longrightarrow> Re (z / r) = Re z / Re r"
   628   by (metis Re_divide_of_real of_real_Re)
   629 
   630 lemma Im_divide_Reals: "r \<in> Reals \<Longrightarrow> Im (z / r) = Im z / Re r"
   631   by (metis Im_divide_of_real of_real_Re)
   632 
   633 lemma Re_setsum[simp]: "Re (setsum f s) = (\<Sum>x\<in>s. Re (f x))"
   634   by (induct s rule: infinite_finite_induct) auto
   635 
   636 lemma Im_setsum[simp]: "Im (setsum f s) = (\<Sum>x\<in>s. Im(f x))"
   637   by (induct s rule: infinite_finite_induct) auto
   638 
   639 lemma sums_complex_iff: "f sums x \<longleftrightarrow> ((\<lambda>x. Re (f x)) sums Re x) \<and> ((\<lambda>x. Im (f x)) sums Im x)"
   640   unfolding sums_def tendsto_complex_iff Im_setsum Re_setsum ..
   641 
   642 lemma summable_complex_iff: "summable f \<longleftrightarrow> summable (\<lambda>x. Re (f x)) \<and>  summable (\<lambda>x. Im (f x))"
   643   unfolding summable_def sums_complex_iff[abs_def] by (metis complex.sel)
   644 
   645 lemma summable_complex_of_real [simp]: "summable (\<lambda>n. complex_of_real (f n)) \<longleftrightarrow> summable f"
   646   unfolding summable_complex_iff by simp
   647 
   648 lemma summable_Re: "summable f \<Longrightarrow> summable (\<lambda>x. Re (f x))"
   649   unfolding summable_complex_iff by blast
   650 
   651 lemma summable_Im: "summable f \<Longrightarrow> summable (\<lambda>x. Im (f x))"
   652   unfolding summable_complex_iff by blast
   653 
   654 lemma complex_is_Nat_iff: "z \<in> \<nat> \<longleftrightarrow> Im z = 0 \<and> (\<exists>i. Re z = of_nat i)"
   655   by (auto simp: Nats_def complex_eq_iff)
   656 
   657 lemma complex_is_Int_iff: "z \<in> \<int> \<longleftrightarrow> Im z = 0 \<and> (\<exists>i. Re z = of_int i)"
   658   by (auto simp: Ints_def complex_eq_iff)
   659 
   660 lemma complex_is_Real_iff: "z \<in> \<real> \<longleftrightarrow> Im z = 0"
   661   by (auto simp: Reals_def complex_eq_iff)
   662 
   663 lemma Reals_cnj_iff: "z \<in> \<real> \<longleftrightarrow> cnj z = z"
   664   by (auto simp: complex_is_Real_iff complex_eq_iff)
   665 
   666 lemma in_Reals_norm: "z \<in> \<real> \<Longrightarrow> norm z = \<bar>Re z\<bar>"
   667   by (simp add: complex_is_Real_iff norm_complex_def)
   668 
   669 lemma series_comparison_complex:
   670   fixes f:: "nat \<Rightarrow> 'a::banach"
   671   assumes sg: "summable g"
   672     and "\<And>n. g n \<in> \<real>" "\<And>n. Re (g n) \<ge> 0"
   673     and fg: "\<And>n. n \<ge> N \<Longrightarrow> norm(f n) \<le> norm(g n)"
   674   shows "summable f"
   675 proof -
   676   have g: "\<And>n. cmod (g n) = Re (g n)"
   677     using assms by (metis abs_of_nonneg in_Reals_norm)
   678   show ?thesis
   679     apply (rule summable_comparison_test' [where g = "\<lambda>n. norm (g n)" and N=N])
   680     using sg
   681      apply (auto simp: summable_def)
   682      apply (rule_tac x = "Re s" in exI)
   683      apply (auto simp: g sums_Re)
   684     apply (metis fg g)
   685     done
   686 qed
   687 
   688 
   689 subsection \<open>Polar Form for Complex Numbers\<close>
   690 
   691 lemma complex_unimodular_polar:
   692   assumes "norm z = 1"
   693   obtains t where "0 \<le> t" "t < 2 * pi" "z = Complex (cos t) (sin t)"
   694   by (metis cmod_power2 one_power2 complex_surj sincos_total_2pi [of "Re z" "Im z"] assms)
   695 
   696 
   697 subsubsection \<open>$\cos \theta + i \sin \theta$\<close>
   698 
   699 primcorec cis :: "real \<Rightarrow> complex"
   700   where
   701     "Re (cis a) = cos a"
   702   | "Im (cis a) = sin a"
   703 
   704 lemma cis_zero [simp]: "cis 0 = 1"
   705   by (simp add: complex_eq_iff)
   706 
   707 lemma norm_cis [simp]: "norm (cis a) = 1"
   708   by (simp add: norm_complex_def)
   709 
   710 lemma sgn_cis [simp]: "sgn (cis a) = cis a"
   711   by (simp add: sgn_div_norm)
   712 
   713 lemma cis_neq_zero [simp]: "cis a \<noteq> 0"
   714   by (metis norm_cis norm_zero zero_neq_one)
   715 
   716 lemma cis_mult: "cis a * cis b = cis (a + b)"
   717   by (simp add: complex_eq_iff cos_add sin_add)
   718 
   719 lemma DeMoivre: "(cis a) ^ n = cis (real n * a)"
   720   by (induct n) (simp_all add: algebra_simps cis_mult)
   721 
   722 lemma cis_inverse [simp]: "inverse (cis a) = cis (- a)"
   723   by (simp add: complex_eq_iff)
   724 
   725 lemma cis_divide: "cis a / cis b = cis (a - b)"
   726   by (simp add: divide_complex_def cis_mult)
   727 
   728 lemma cos_n_Re_cis_pow_n: "cos (real n * a) = Re (cis a ^ n)"
   729   by (auto simp add: DeMoivre)
   730 
   731 lemma sin_n_Im_cis_pow_n: "sin (real n * a) = Im (cis a ^ n)"
   732   by (auto simp add: DeMoivre)
   733 
   734 lemma cis_pi: "cis pi = -1"
   735   by (simp add: complex_eq_iff)
   736 
   737 
   738 subsubsection \<open>$r(\cos \theta + i \sin \theta)$\<close>
   739 
   740 definition rcis :: "real \<Rightarrow> real \<Rightarrow> complex"
   741   where "rcis r a = complex_of_real r * cis a"
   742 
   743 lemma Re_rcis [simp]: "Re(rcis r a) = r * cos a"
   744   by (simp add: rcis_def)
   745 
   746 lemma Im_rcis [simp]: "Im(rcis r a) = r * sin a"
   747   by (simp add: rcis_def)
   748 
   749 lemma rcis_Ex: "\<exists>r a. z = rcis r a"
   750   by (simp add: complex_eq_iff polar_Ex)
   751 
   752 lemma complex_mod_rcis [simp]: "cmod (rcis r a) = \<bar>r\<bar>"
   753   by (simp add: rcis_def norm_mult)
   754 
   755 lemma cis_rcis_eq: "cis a = rcis 1 a"
   756   by (simp add: rcis_def)
   757 
   758 lemma rcis_mult: "rcis r1 a * rcis r2 b = rcis (r1 * r2) (a + b)"
   759   by (simp add: rcis_def cis_mult)
   760 
   761 lemma rcis_zero_mod [simp]: "rcis 0 a = 0"
   762   by (simp add: rcis_def)
   763 
   764 lemma rcis_zero_arg [simp]: "rcis r 0 = complex_of_real r"
   765   by (simp add: rcis_def)
   766 
   767 lemma rcis_eq_zero_iff [simp]: "rcis r a = 0 \<longleftrightarrow> r = 0"
   768   by (simp add: rcis_def)
   769 
   770 lemma DeMoivre2: "(rcis r a) ^ n = rcis (r ^ n) (real n * a)"
   771   by (simp add: rcis_def power_mult_distrib DeMoivre)
   772 
   773 lemma rcis_inverse: "inverse(rcis r a) = rcis (1 / r) (- a)"
   774   by (simp add: divide_inverse rcis_def)
   775 
   776 lemma rcis_divide: "rcis r1 a / rcis r2 b = rcis (r1 / r2) (a - b)"
   777   by (simp add: rcis_def cis_divide [symmetric])
   778 
   779 
   780 subsubsection \<open>Complex exponential\<close>
   781 
   782 lemma cis_conv_exp: "cis b = exp (\<i> * b)"
   783 proof -
   784   have "(\<i> * complex_of_real b) ^ n /\<^sub>R fact n =
   785       of_real (cos_coeff n * b^n) + \<i> * of_real (sin_coeff n * b^n)"
   786     for n :: nat
   787   proof -
   788     have "\<i> ^ n = fact n *\<^sub>R (cos_coeff n + \<i> * sin_coeff n)"
   789       by (induct n)
   790         (simp_all add: sin_coeff_Suc cos_coeff_Suc complex_eq_iff Re_divide Im_divide field_simps
   791           power2_eq_square add_nonneg_eq_0_iff)
   792     then show ?thesis
   793       by (simp add: field_simps)
   794   qed
   795   then show ?thesis
   796     using sin_converges [of b] cos_converges [of b]
   797     by (auto simp add: cis.ctr exp_def simp del: of_real_mult
   798         intro!: sums_unique sums_add sums_mult sums_of_real)
   799 qed
   800 
   801 lemma exp_eq_polar: "exp z = exp (Re z) * cis (Im z)"
   802   unfolding cis_conv_exp exp_of_real [symmetric] mult_exp_exp
   803   by (cases z) simp
   804 
   805 lemma Re_exp: "Re (exp z) = exp (Re z) * cos (Im z)"
   806   unfolding exp_eq_polar by simp
   807 
   808 lemma Im_exp: "Im (exp z) = exp (Re z) * sin (Im z)"
   809   unfolding exp_eq_polar by simp
   810 
   811 lemma norm_cos_sin [simp]: "norm (Complex (cos t) (sin t)) = 1"
   812   by (simp add: norm_complex_def)
   813 
   814 lemma norm_exp_eq_Re [simp]: "norm (exp z) = exp (Re z)"
   815   by (simp add: cis.code cmod_complex_polar exp_eq_polar)
   816 
   817 lemma complex_exp_exists: "\<exists>a r. z = complex_of_real r * exp a"
   818   apply (insert rcis_Ex [of z])
   819   apply (auto simp add: exp_eq_polar rcis_def mult.assoc [symmetric])
   820   apply (rule_tac x = "\<i> * complex_of_real a" in exI)
   821   apply auto
   822   done
   823 
   824 lemma exp_pi_i [simp]: "exp (of_real pi * \<i>) = -1"
   825   by (metis cis_conv_exp cis_pi mult.commute)
   826 
   827 lemma exp_pi_i' [simp]: "exp (\<i> * of_real pi) = -1"
   828   using cis_conv_exp cis_pi by auto
   829 
   830 lemma exp_two_pi_i [simp]: "exp (2 * of_real pi * \<i>) = 1"
   831   by (simp add: exp_eq_polar complex_eq_iff)
   832 
   833 lemma exp_two_pi_i' [simp]: "exp (\<i> * (of_real pi * 2)) = 1"
   834   by (metis exp_two_pi_i mult.commute)
   835 
   836 
   837 subsubsection \<open>Complex argument\<close>
   838 
   839 definition arg :: "complex \<Rightarrow> real"
   840   where "arg z = (if z = 0 then 0 else (SOME a. sgn z = cis a \<and> - pi < a \<and> a \<le> pi))"
   841 
   842 lemma arg_zero: "arg 0 = 0"
   843   by (simp add: arg_def)
   844 
   845 lemma arg_unique:
   846   assumes "sgn z = cis x" and "-pi < x" and "x \<le> pi"
   847   shows "arg z = x"
   848 proof -
   849   from assms have "z \<noteq> 0" by auto
   850   have "(SOME a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi) = x"
   851   proof
   852     fix a
   853     define d where "d = a - x"
   854     assume a: "sgn z = cis a \<and> - pi < a \<and> a \<le> pi"
   855     from a assms have "- (2*pi) < d \<and> d < 2*pi"
   856       unfolding d_def by simp
   857     moreover
   858     from a assms have "cos a = cos x" and "sin a = sin x"
   859       by (simp_all add: complex_eq_iff)
   860     then have cos: "cos d = 1"
   861       by (simp add: d_def cos_diff)
   862     moreover from cos have "sin d = 0"
   863       by (rule cos_one_sin_zero)
   864     ultimately have "d = 0"
   865       by (auto simp: sin_zero_iff elim!: evenE dest!: less_2_cases)
   866     then show "a = x"
   867       by (simp add: d_def)
   868   qed (simp add: assms del: Re_sgn Im_sgn)
   869   with \<open>z \<noteq> 0\<close> show "arg z = x"
   870     by (simp add: arg_def)
   871 qed
   872 
   873 lemma arg_correct:
   874   assumes "z \<noteq> 0"
   875   shows "sgn z = cis (arg z) \<and> -pi < arg z \<and> arg z \<le> pi"
   876 proof (simp add: arg_def assms, rule someI_ex)
   877   obtain r a where z: "z = rcis r a"
   878     using rcis_Ex by fast
   879   with assms have "r \<noteq> 0" by auto
   880   define b where "b = (if 0 < r then a else a + pi)"
   881   have b: "sgn z = cis b"
   882     using \<open>r \<noteq> 0\<close> by (simp add: z b_def rcis_def of_real_def sgn_scaleR sgn_if complex_eq_iff)
   883   have cis_2pi_nat: "cis (2 * pi * real_of_nat n) = 1" for n
   884     by (induct n) (simp_all add: distrib_left cis_mult [symmetric] complex_eq_iff)
   885   have cis_2pi_int: "cis (2 * pi * real_of_int x) = 1" for x
   886     by (cases x rule: int_diff_cases)
   887       (simp add: right_diff_distrib cis_divide [symmetric] cis_2pi_nat)
   888   define c where "c = b - 2 * pi * of_int \<lceil>(b - pi) / (2 * pi)\<rceil>"
   889   have "sgn z = cis c"
   890     by (simp add: b c_def cis_divide [symmetric] cis_2pi_int)
   891   moreover have "- pi < c \<and> c \<le> pi"
   892     using ceiling_correct [of "(b - pi) / (2*pi)"]
   893     by (simp add: c_def less_divide_eq divide_le_eq algebra_simps del: le_of_int_ceiling)
   894   ultimately show "\<exists>a. sgn z = cis a \<and> -pi < a \<and> a \<le> pi"
   895     by fast
   896 qed
   897 
   898 lemma arg_bounded: "- pi < arg z \<and> arg z \<le> pi"
   899   by (cases "z = 0") (simp_all add: arg_zero arg_correct)
   900 
   901 lemma cis_arg: "z \<noteq> 0 \<Longrightarrow> cis (arg z) = sgn z"
   902   by (simp add: arg_correct)
   903 
   904 lemma rcis_cmod_arg: "rcis (cmod z) (arg z) = z"
   905   by (cases "z = 0") (simp_all add: rcis_def cis_arg sgn_div_norm of_real_def)
   906 
   907 lemma cos_arg_i_mult_zero [simp]: "y \<noteq> 0 \<Longrightarrow> Re y = 0 \<Longrightarrow> cos (arg y) = 0"
   908   using cis_arg [of y] by (simp add: complex_eq_iff)
   909 
   910 
   911 subsection \<open>Square root of complex numbers\<close>
   912 
   913 primcorec csqrt :: "complex \<Rightarrow> complex"
   914   where
   915     "Re (csqrt z) = sqrt ((cmod z + Re z) / 2)"
   916   | "Im (csqrt z) = (if Im z = 0 then 1 else sgn (Im z)) * sqrt ((cmod z - Re z) / 2)"
   917 
   918 lemma csqrt_of_real_nonneg [simp]: "Im x = 0 \<Longrightarrow> Re x \<ge> 0 \<Longrightarrow> csqrt x = sqrt (Re x)"
   919   by (simp add: complex_eq_iff norm_complex_def)
   920 
   921 lemma csqrt_of_real_nonpos [simp]: "Im x = 0 \<Longrightarrow> Re x \<le> 0 \<Longrightarrow> csqrt x = \<i> * sqrt \<bar>Re x\<bar>"
   922   by (simp add: complex_eq_iff norm_complex_def)
   923 
   924 lemma of_real_sqrt: "x \<ge> 0 \<Longrightarrow> of_real (sqrt x) = csqrt (of_real x)"
   925   by (simp add: complex_eq_iff norm_complex_def)
   926 
   927 lemma csqrt_0 [simp]: "csqrt 0 = 0"
   928   by simp
   929 
   930 lemma csqrt_1 [simp]: "csqrt 1 = 1"
   931   by simp
   932 
   933 lemma csqrt_ii [simp]: "csqrt \<i> = (1 + \<i>) / sqrt 2"
   934   by (simp add: complex_eq_iff Re_divide Im_divide real_sqrt_divide real_div_sqrt)
   935 
   936 lemma power2_csqrt[simp,algebra]: "(csqrt z)\<^sup>2 = z"
   937 proof (cases "Im z = 0")
   938   case True
   939   then show ?thesis
   940     using real_sqrt_pow2[of "Re z"] real_sqrt_pow2[of "- Re z"]
   941     by (cases "0::real" "Re z" rule: linorder_cases)
   942       (simp_all add: complex_eq_iff Re_power2 Im_power2 power2_eq_square cmod_eq_Re)
   943 next
   944   case False
   945   moreover have "cmod z * cmod z - Re z * Re z = Im z * Im z"
   946     by (simp add: norm_complex_def power2_eq_square)
   947   moreover have "\<bar>Re z\<bar> \<le> cmod z"
   948     by (simp add: norm_complex_def)
   949   ultimately show ?thesis
   950     by (simp add: Re_power2 Im_power2 complex_eq_iff real_sgn_eq
   951         field_simps real_sqrt_mult[symmetric] real_sqrt_divide)
   952 qed
   953 
   954 lemma csqrt_eq_0 [simp]: "csqrt z = 0 \<longleftrightarrow> z = 0"
   955   by auto (metis power2_csqrt power_eq_0_iff)
   956 
   957 lemma csqrt_eq_1 [simp]: "csqrt z = 1 \<longleftrightarrow> z = 1"
   958   by auto (metis power2_csqrt power2_eq_1_iff)
   959 
   960 lemma csqrt_principal: "0 < Re (csqrt z) \<or> Re (csqrt z) = 0 \<and> 0 \<le> Im (csqrt z)"
   961   by (auto simp add: not_less cmod_plus_Re_le_0_iff Im_eq_0)
   962 
   963 lemma Re_csqrt: "0 \<le> Re (csqrt z)"
   964   by (metis csqrt_principal le_less)
   965 
   966 lemma csqrt_square:
   967   assumes "0 < Re b \<or> (Re b = 0 \<and> 0 \<le> Im b)"
   968   shows "csqrt (b^2) = b"
   969 proof -
   970   have "csqrt (b^2) = b \<or> csqrt (b^2) = - b"
   971     by (simp add: power2_eq_iff[symmetric])
   972   moreover have "csqrt (b^2) \<noteq> -b \<or> b = 0"
   973     using csqrt_principal[of "b ^ 2"] assms
   974     by (intro disjCI notI) (auto simp: complex_eq_iff)
   975   ultimately show ?thesis
   976     by auto
   977 qed
   978 
   979 lemma csqrt_unique: "w\<^sup>2 = z \<Longrightarrow> 0 < Re w \<or> Re w = 0 \<and> 0 \<le> Im w \<Longrightarrow> csqrt z = w"
   980   by (auto simp: csqrt_square)
   981 
   982 lemma csqrt_minus [simp]:
   983   assumes "Im x < 0 \<or> (Im x = 0 \<and> 0 \<le> Re x)"
   984   shows "csqrt (- x) = \<i> * csqrt x"
   985 proof -
   986   have "csqrt ((\<i> * csqrt x)^2) = \<i> * csqrt x"
   987   proof (rule csqrt_square)
   988     have "Im (csqrt x) \<le> 0"
   989       using assms by (auto simp add: cmod_eq_Re mult_le_0_iff field_simps complex_Re_le_cmod)
   990     then show "0 < Re (\<i> * csqrt x) \<or> Re (\<i> * csqrt x) = 0 \<and> 0 \<le> Im (\<i> * csqrt x)"
   991       by (auto simp add: Re_csqrt simp del: csqrt.simps)
   992   qed
   993   also have "(\<i> * csqrt x)^2 = - x"
   994     by (simp add: power_mult_distrib)
   995   finally show ?thesis .
   996 qed
   997 
   998 
   999 text \<open>Legacy theorem names\<close>
  1000 
  1001 lemmas expand_complex_eq = complex_eq_iff
  1002 lemmas complex_Re_Im_cancel_iff = complex_eq_iff
  1003 lemmas complex_equality = complex_eqI
  1004 lemmas cmod_def = norm_complex_def
  1005 lemmas complex_norm_def = norm_complex_def
  1006 lemmas complex_divide_def = divide_complex_def
  1007 
  1008 lemma legacy_Complex_simps:
  1009   shows Complex_eq_0: "Complex a b = 0 \<longleftrightarrow> a = 0 \<and> b = 0"
  1010     and complex_add: "Complex a b + Complex c d = Complex (a + c) (b + d)"
  1011     and complex_minus: "- (Complex a b) = Complex (- a) (- b)"
  1012     and complex_diff: "Complex a b - Complex c d = Complex (a - c) (b - d)"
  1013     and Complex_eq_1: "Complex a b = 1 \<longleftrightarrow> a = 1 \<and> b = 0"
  1014     and Complex_eq_neg_1: "Complex a b = - 1 \<longleftrightarrow> a = - 1 \<and> b = 0"
  1015     and complex_mult: "Complex a b * Complex c d = Complex (a * c - b * d) (a * d + b * c)"
  1016     and complex_inverse: "inverse (Complex a b) = Complex (a / (a\<^sup>2 + b\<^sup>2)) (- b / (a\<^sup>2 + b\<^sup>2))"
  1017     and Complex_eq_numeral: "Complex a b = numeral w \<longleftrightarrow> a = numeral w \<and> b = 0"
  1018     and Complex_eq_neg_numeral: "Complex a b = - numeral w \<longleftrightarrow> a = - numeral w \<and> b = 0"
  1019     and complex_scaleR: "scaleR r (Complex a b) = Complex (r * a) (r * b)"
  1020     and Complex_eq_i: "Complex x y = \<i> \<longleftrightarrow> x = 0 \<and> y = 1"
  1021     and i_mult_Complex: "\<i> * Complex a b = Complex (- b) a"
  1022     and Complex_mult_i: "Complex a b * \<i> = Complex (- b) a"
  1023     and i_complex_of_real: "\<i> * complex_of_real r = Complex 0 r"
  1024     and complex_of_real_i: "complex_of_real r * \<i> = Complex 0 r"
  1025     and Complex_add_complex_of_real: "Complex x y + complex_of_real r = Complex (x+r) y"
  1026     and complex_of_real_add_Complex: "complex_of_real r + Complex x y = Complex (r+x) y"
  1027     and Complex_mult_complex_of_real: "Complex x y * complex_of_real r = Complex (x*r) (y*r)"
  1028     and complex_of_real_mult_Complex: "complex_of_real r * Complex x y = Complex (r*x) (r*y)"
  1029     and complex_eq_cancel_iff2: "(Complex x y = complex_of_real xa) = (x = xa \<and> y = 0)"
  1030     and complex_cn: "cnj (Complex a b) = Complex a (- b)"
  1031     and Complex_setsum': "setsum (\<lambda>x. Complex (f x) 0) s = Complex (setsum f s) 0"
  1032     and Complex_setsum: "Complex (setsum f s) 0 = setsum (\<lambda>x. Complex (f x) 0) s"
  1033     and complex_of_real_def: "complex_of_real r = Complex r 0"
  1034     and complex_norm: "cmod (Complex x y) = sqrt (x\<^sup>2 + y\<^sup>2)"
  1035   by (simp_all add: norm_complex_def field_simps complex_eq_iff Re_divide Im_divide del: Complex_eq)
  1036 
  1037 lemma Complex_in_Reals: "Complex x 0 \<in> \<real>"
  1038   by (metis Reals_of_real complex_of_real_def)
  1039 
  1040 end