src/HOL/Filter.thy
 author wenzelm Sun Sep 18 20:33:48 2016 +0200 (2016-09-18) changeset 63915 bab633745c7f parent 63556 36e9732988ce child 63967 2aa42596edc3 permissions -rw-r--r--
tuned proofs;
```     1 (*  Title:      HOL/Filter.thy
```
```     2     Author:     Brian Huffman
```
```     3     Author:     Johannes Hölzl
```
```     4 *)
```
```     5
```
```     6 section \<open>Filters on predicates\<close>
```
```     7
```
```     8 theory Filter
```
```     9 imports Set_Interval Lifting_Set
```
```    10 begin
```
```    11
```
```    12 subsection \<open>Filters\<close>
```
```    13
```
```    14 text \<open>
```
```    15   This definition also allows non-proper filters.
```
```    16 \<close>
```
```    17
```
```    18 locale is_filter =
```
```    19   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
```
```    20   assumes True: "F (\<lambda>x. True)"
```
```    21   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
```
```    22   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
```
```    23
```
```    24 typedef 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
```
```    25 proof
```
```    26   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
```
```    27 qed
```
```    28
```
```    29 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
```
```    30   using Rep_filter [of F] by simp
```
```    31
```
```    32 lemma Abs_filter_inverse':
```
```    33   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
```
```    34   using assms by (simp add: Abs_filter_inverse)
```
```    35
```
```    36
```
```    37 subsubsection \<open>Eventually\<close>
```
```    38
```
```    39 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
```
```    40   where "eventually P F \<longleftrightarrow> Rep_filter F P"
```
```    41
```
```    42 syntax
```
```    43   "_eventually" :: "pttrn => 'a filter => bool => bool"  ("(3\<forall>\<^sub>F _ in _./ _)" [0, 0, 10] 10)
```
```    44 translations
```
```    45   "\<forall>\<^sub>Fx in F. P" == "CONST eventually (\<lambda>x. P) F"
```
```    46
```
```    47 lemma eventually_Abs_filter:
```
```    48   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
```
```    49   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
```
```    50
```
```    51 lemma filter_eq_iff:
```
```    52   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
```
```    53   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
```
```    54
```
```    55 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
```
```    56   unfolding eventually_def
```
```    57   by (rule is_filter.True [OF is_filter_Rep_filter])
```
```    58
```
```    59 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
```
```    60 proof -
```
```    61   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
```
```    62   thus "eventually P F" by simp
```
```    63 qed
```
```    64
```
```    65 lemma eventuallyI: "(\<And>x. P x) \<Longrightarrow> eventually P F"
```
```    66   by (auto intro: always_eventually)
```
```    67
```
```    68 lemma eventually_mono:
```
```    69   "\<lbrakk>eventually P F; \<And>x. P x \<Longrightarrow> Q x\<rbrakk> \<Longrightarrow> eventually Q F"
```
```    70   unfolding eventually_def
```
```    71   by (blast intro: is_filter.mono [OF is_filter_Rep_filter])
```
```    72
```
```    73 lemma eventually_conj:
```
```    74   assumes P: "eventually (\<lambda>x. P x) F"
```
```    75   assumes Q: "eventually (\<lambda>x. Q x) F"
```
```    76   shows "eventually (\<lambda>x. P x \<and> Q x) F"
```
```    77   using assms unfolding eventually_def
```
```    78   by (rule is_filter.conj [OF is_filter_Rep_filter])
```
```    79
```
```    80 lemma eventually_mp:
```
```    81   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
```
```    82   assumes "eventually (\<lambda>x. P x) F"
```
```    83   shows "eventually (\<lambda>x. Q x) F"
```
```    84 proof -
```
```    85   have "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
```
```    86     using assms by (rule eventually_conj)
```
```    87   then show ?thesis
```
```    88     by (blast intro: eventually_mono)
```
```    89 qed
```
```    90
```
```    91 lemma eventually_rev_mp:
```
```    92   assumes "eventually (\<lambda>x. P x) F"
```
```    93   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
```
```    94   shows "eventually (\<lambda>x. Q x) F"
```
```    95 using assms(2) assms(1) by (rule eventually_mp)
```
```    96
```
```    97 lemma eventually_conj_iff:
```
```    98   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
```
```    99   by (auto intro: eventually_conj elim: eventually_rev_mp)
```
```   100
```
```   101 lemma eventually_elim2:
```
```   102   assumes "eventually (\<lambda>i. P i) F"
```
```   103   assumes "eventually (\<lambda>i. Q i) F"
```
```   104   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
```
```   105   shows "eventually (\<lambda>i. R i) F"
```
```   106   using assms by (auto elim!: eventually_rev_mp)
```
```   107
```
```   108 lemma eventually_ball_finite_distrib:
```
```   109   "finite A \<Longrightarrow> (eventually (\<lambda>x. \<forall>y\<in>A. P x y) net) \<longleftrightarrow> (\<forall>y\<in>A. eventually (\<lambda>x. P x y) net)"
```
```   110   by (induction A rule: finite_induct) (auto simp: eventually_conj_iff)
```
```   111
```
```   112 lemma eventually_ball_finite:
```
```   113   "finite A \<Longrightarrow> \<forall>y\<in>A. eventually (\<lambda>x. P x y) net \<Longrightarrow> eventually (\<lambda>x. \<forall>y\<in>A. P x y) net"
```
```   114   by (auto simp: eventually_ball_finite_distrib)
```
```   115
```
```   116 lemma eventually_all_finite:
```
```   117   fixes P :: "'a \<Rightarrow> 'b::finite \<Rightarrow> bool"
```
```   118   assumes "\<And>y. eventually (\<lambda>x. P x y) net"
```
```   119   shows "eventually (\<lambda>x. \<forall>y. P x y) net"
```
```   120 using eventually_ball_finite [of UNIV P] assms by simp
```
```   121
```
```   122 lemma eventually_ex: "(\<forall>\<^sub>Fx in F. \<exists>y. P x y) \<longleftrightarrow> (\<exists>Y. \<forall>\<^sub>Fx in F. P x (Y x))"
```
```   123 proof
```
```   124   assume "\<forall>\<^sub>Fx in F. \<exists>y. P x y"
```
```   125   then have "\<forall>\<^sub>Fx in F. P x (SOME y. P x y)"
```
```   126     by (auto intro: someI_ex eventually_mono)
```
```   127   then show "\<exists>Y. \<forall>\<^sub>Fx in F. P x (Y x)"
```
```   128     by auto
```
```   129 qed (auto intro: eventually_mono)
```
```   130
```
```   131 lemma not_eventually_impI: "eventually P F \<Longrightarrow> \<not> eventually Q F \<Longrightarrow> \<not> eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
```
```   132   by (auto intro: eventually_mp)
```
```   133
```
```   134 lemma not_eventuallyD: "\<not> eventually P F \<Longrightarrow> \<exists>x. \<not> P x"
```
```   135   by (metis always_eventually)
```
```   136
```
```   137 lemma eventually_subst:
```
```   138   assumes "eventually (\<lambda>n. P n = Q n) F"
```
```   139   shows "eventually P F = eventually Q F" (is "?L = ?R")
```
```   140 proof -
```
```   141   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
```
```   142       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
```
```   143     by (auto elim: eventually_mono)
```
```   144   then show ?thesis by (auto elim: eventually_elim2)
```
```   145 qed
```
```   146
```
```   147 subsection \<open> Frequently as dual to eventually \<close>
```
```   148
```
```   149 definition frequently :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
```
```   150   where "frequently P F \<longleftrightarrow> \<not> eventually (\<lambda>x. \<not> P x) F"
```
```   151
```
```   152 syntax
```
```   153   "_frequently" :: "pttrn \<Rightarrow> 'a filter \<Rightarrow> bool \<Rightarrow> bool"  ("(3\<exists>\<^sub>F _ in _./ _)" [0, 0, 10] 10)
```
```   154 translations
```
```   155   "\<exists>\<^sub>Fx in F. P" == "CONST frequently (\<lambda>x. P) F"
```
```   156
```
```   157 lemma not_frequently_False [simp]: "\<not> (\<exists>\<^sub>Fx in F. False)"
```
```   158   by (simp add: frequently_def)
```
```   159
```
```   160 lemma frequently_ex: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> \<exists>x. P x"
```
```   161   by (auto simp: frequently_def dest: not_eventuallyD)
```
```   162
```
```   163 lemma frequentlyE: assumes "frequently P F" obtains x where "P x"
```
```   164   using frequently_ex[OF assms] by auto
```
```   165
```
```   166 lemma frequently_mp:
```
```   167   assumes ev: "\<forall>\<^sub>Fx in F. P x \<longrightarrow> Q x" and P: "\<exists>\<^sub>Fx in F. P x" shows "\<exists>\<^sub>Fx in F. Q x"
```
```   168 proof -
```
```   169   from ev have "eventually (\<lambda>x. \<not> Q x \<longrightarrow> \<not> P x) F"
```
```   170     by (rule eventually_rev_mp) (auto intro!: always_eventually)
```
```   171   from eventually_mp[OF this] P show ?thesis
```
```   172     by (auto simp: frequently_def)
```
```   173 qed
```
```   174
```
```   175 lemma frequently_rev_mp:
```
```   176   assumes "\<exists>\<^sub>Fx in F. P x"
```
```   177   assumes "\<forall>\<^sub>Fx in F. P x \<longrightarrow> Q x"
```
```   178   shows "\<exists>\<^sub>Fx in F. Q x"
```
```   179 using assms(2) assms(1) by (rule frequently_mp)
```
```   180
```
```   181 lemma frequently_mono: "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> frequently P F \<Longrightarrow> frequently Q F"
```
```   182   using frequently_mp[of P Q] by (simp add: always_eventually)
```
```   183
```
```   184 lemma frequently_elim1: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> (\<And>i. P i \<Longrightarrow> Q i) \<Longrightarrow> \<exists>\<^sub>Fx in F. Q x"
```
```   185   by (metis frequently_mono)
```
```   186
```
```   187 lemma frequently_disj_iff: "(\<exists>\<^sub>Fx in F. P x \<or> Q x) \<longleftrightarrow> (\<exists>\<^sub>Fx in F. P x) \<or> (\<exists>\<^sub>Fx in F. Q x)"
```
```   188   by (simp add: frequently_def eventually_conj_iff)
```
```   189
```
```   190 lemma frequently_disj: "\<exists>\<^sub>Fx in F. P x \<Longrightarrow> \<exists>\<^sub>Fx in F. Q x \<Longrightarrow> \<exists>\<^sub>Fx in F. P x \<or> Q x"
```
```   191   by (simp add: frequently_disj_iff)
```
```   192
```
```   193 lemma frequently_bex_finite_distrib:
```
```   194   assumes "finite A" shows "(\<exists>\<^sub>Fx in F. \<exists>y\<in>A. P x y) \<longleftrightarrow> (\<exists>y\<in>A. \<exists>\<^sub>Fx in F. P x y)"
```
```   195   using assms by induction (auto simp: frequently_disj_iff)
```
```   196
```
```   197 lemma frequently_bex_finite: "finite A \<Longrightarrow> \<exists>\<^sub>Fx in F. \<exists>y\<in>A. P x y \<Longrightarrow> \<exists>y\<in>A. \<exists>\<^sub>Fx in F. P x y"
```
```   198   by (simp add: frequently_bex_finite_distrib)
```
```   199
```
```   200 lemma frequently_all: "(\<exists>\<^sub>Fx in F. \<forall>y. P x y) \<longleftrightarrow> (\<forall>Y. \<exists>\<^sub>Fx in F. P x (Y x))"
```
```   201   using eventually_ex[of "\<lambda>x y. \<not> P x y" F] by (simp add: frequently_def)
```
```   202
```
```   203 lemma
```
```   204   shows not_eventually: "\<not> eventually P F \<longleftrightarrow> (\<exists>\<^sub>Fx in F. \<not> P x)"
```
```   205     and not_frequently: "\<not> frequently P F \<longleftrightarrow> (\<forall>\<^sub>Fx in F. \<not> P x)"
```
```   206   by (auto simp: frequently_def)
```
```   207
```
```   208 lemma frequently_imp_iff:
```
```   209   "(\<exists>\<^sub>Fx in F. P x \<longrightarrow> Q x) \<longleftrightarrow> (eventually P F \<longrightarrow> frequently Q F)"
```
```   210   unfolding imp_conv_disj frequently_disj_iff not_eventually[symmetric] ..
```
```   211
```
```   212 lemma eventually_frequently_const_simps:
```
```   213   "(\<exists>\<^sub>Fx in F. P x \<and> C) \<longleftrightarrow> (\<exists>\<^sub>Fx in F. P x) \<and> C"
```
```   214   "(\<exists>\<^sub>Fx in F. C \<and> P x) \<longleftrightarrow> C \<and> (\<exists>\<^sub>Fx in F. P x)"
```
```   215   "(\<forall>\<^sub>Fx in F. P x \<or> C) \<longleftrightarrow> (\<forall>\<^sub>Fx in F. P x) \<or> C"
```
```   216   "(\<forall>\<^sub>Fx in F. C \<or> P x) \<longleftrightarrow> C \<or> (\<forall>\<^sub>Fx in F. P x)"
```
```   217   "(\<forall>\<^sub>Fx in F. P x \<longrightarrow> C) \<longleftrightarrow> ((\<exists>\<^sub>Fx in F. P x) \<longrightarrow> C)"
```
```   218   "(\<forall>\<^sub>Fx in F. C \<longrightarrow> P x) \<longleftrightarrow> (C \<longrightarrow> (\<forall>\<^sub>Fx in F. P x))"
```
```   219   by (cases C; simp add: not_frequently)+
```
```   220
```
```   221 lemmas eventually_frequently_simps =
```
```   222   eventually_frequently_const_simps
```
```   223   not_eventually
```
```   224   eventually_conj_iff
```
```   225   eventually_ball_finite_distrib
```
```   226   eventually_ex
```
```   227   not_frequently
```
```   228   frequently_disj_iff
```
```   229   frequently_bex_finite_distrib
```
```   230   frequently_all
```
```   231   frequently_imp_iff
```
```   232
```
```   233 ML \<open>
```
```   234   fun eventually_elim_tac facts =
```
```   235     CONTEXT_SUBGOAL (fn (goal, i) => fn (ctxt, st) =>
```
```   236       let
```
```   237         val mp_thms = facts RL @{thms eventually_rev_mp}
```
```   238         val raw_elim_thm =
```
```   239           (@{thm allI} RS @{thm always_eventually})
```
```   240           |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
```
```   241           |> fold (fn _ => fn thm => @{thm impI} RS thm) facts
```
```   242         val cases_prop =
```
```   243           Thm.prop_of
```
```   244             (Rule_Cases.internalize_params (raw_elim_thm RS Goal.init (Thm.cterm_of ctxt goal)))
```
```   245         val cases = Rule_Cases.make_common ctxt cases_prop [(("elim", []), [])]
```
```   246       in CONTEXT_CASES cases (resolve_tac ctxt [raw_elim_thm] i) (ctxt, st) end)
```
```   247 \<close>
```
```   248
```
```   249 method_setup eventually_elim = \<open>
```
```   250   Scan.succeed (fn _ => CONTEXT_METHOD (fn facts => eventually_elim_tac facts 1))
```
```   251 \<close> "elimination of eventually quantifiers"
```
```   252
```
```   253 subsubsection \<open>Finer-than relation\<close>
```
```   254
```
```   255 text \<open>@{term "F \<le> F'"} means that filter @{term F} is finer than
```
```   256 filter @{term F'}.\<close>
```
```   257
```
```   258 instantiation filter :: (type) complete_lattice
```
```   259 begin
```
```   260
```
```   261 definition le_filter_def:
```
```   262   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
```
```   263
```
```   264 definition
```
```   265   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
```
```   266
```
```   267 definition
```
```   268   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
```
```   269
```
```   270 definition
```
```   271   "bot = Abs_filter (\<lambda>P. True)"
```
```   272
```
```   273 definition
```
```   274   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
```
```   275
```
```   276 definition
```
```   277   "inf F F' = Abs_filter
```
```   278       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
```
```   279
```
```   280 definition
```
```   281   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
```
```   282
```
```   283 definition
```
```   284   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
```
```   285
```
```   286 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
```
```   287   unfolding top_filter_def
```
```   288   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
```
```   289
```
```   290 lemma eventually_bot [simp]: "eventually P bot"
```
```   291   unfolding bot_filter_def
```
```   292   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
```
```   293
```
```   294 lemma eventually_sup:
```
```   295   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
```
```   296   unfolding sup_filter_def
```
```   297   by (rule eventually_Abs_filter, rule is_filter.intro)
```
```   298      (auto elim!: eventually_rev_mp)
```
```   299
```
```   300 lemma eventually_inf:
```
```   301   "eventually P (inf F F') \<longleftrightarrow>
```
```   302    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
```
```   303   unfolding inf_filter_def
```
```   304   apply (rule eventually_Abs_filter, rule is_filter.intro)
```
```   305   apply (fast intro: eventually_True)
```
```   306   apply clarify
```
```   307   apply (intro exI conjI)
```
```   308   apply (erule (1) eventually_conj)
```
```   309   apply (erule (1) eventually_conj)
```
```   310   apply simp
```
```   311   apply auto
```
```   312   done
```
```   313
```
```   314 lemma eventually_Sup:
```
```   315   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
```
```   316   unfolding Sup_filter_def
```
```   317   apply (rule eventually_Abs_filter, rule is_filter.intro)
```
```   318   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
```
```   319   done
```
```   320
```
```   321 instance proof
```
```   322   fix F F' F'' :: "'a filter" and S :: "'a filter set"
```
```   323   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
```
```   324     by (rule less_filter_def) }
```
```   325   { show "F \<le> F"
```
```   326     unfolding le_filter_def by simp }
```
```   327   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
```
```   328     unfolding le_filter_def by simp }
```
```   329   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
```
```   330     unfolding le_filter_def filter_eq_iff by fast }
```
```   331   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
```
```   332     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
```
```   333   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
```
```   334     unfolding le_filter_def eventually_inf
```
```   335     by (auto intro: eventually_mono [OF eventually_conj]) }
```
```   336   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
```
```   337     unfolding le_filter_def eventually_sup by simp_all }
```
```   338   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
```
```   339     unfolding le_filter_def eventually_sup by simp }
```
```   340   { assume "F'' \<in> S" thus "Inf S \<le> F''"
```
```   341     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
```
```   342   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
```
```   343     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
```
```   344   { assume "F \<in> S" thus "F \<le> Sup S"
```
```   345     unfolding le_filter_def eventually_Sup by simp }
```
```   346   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
```
```   347     unfolding le_filter_def eventually_Sup by simp }
```
```   348   { show "Inf {} = (top::'a filter)"
```
```   349     by (auto simp: top_filter_def Inf_filter_def Sup_filter_def)
```
```   350       (metis (full_types) top_filter_def always_eventually eventually_top) }
```
```   351   { show "Sup {} = (bot::'a filter)"
```
```   352     by (auto simp: bot_filter_def Sup_filter_def) }
```
```   353 qed
```
```   354
```
```   355 end
```
```   356
```
```   357 lemma filter_leD:
```
```   358   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
```
```   359   unfolding le_filter_def by simp
```
```   360
```
```   361 lemma filter_leI:
```
```   362   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
```
```   363   unfolding le_filter_def by simp
```
```   364
```
```   365 lemma eventually_False:
```
```   366   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
```
```   367   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
```
```   368
```
```   369 lemma eventually_frequently: "F \<noteq> bot \<Longrightarrow> eventually P F \<Longrightarrow> frequently P F"
```
```   370   using eventually_conj[of P F "\<lambda>x. \<not> P x"]
```
```   371   by (auto simp add: frequently_def eventually_False)
```
```   372
```
```   373 lemma eventually_const_iff: "eventually (\<lambda>x. P) F \<longleftrightarrow> P \<or> F = bot"
```
```   374   by (cases P) (auto simp: eventually_False)
```
```   375
```
```   376 lemma eventually_const[simp]: "F \<noteq> bot \<Longrightarrow> eventually (\<lambda>x. P) F \<longleftrightarrow> P"
```
```   377   by (simp add: eventually_const_iff)
```
```   378
```
```   379 lemma frequently_const_iff: "frequently (\<lambda>x. P) F \<longleftrightarrow> P \<and> F \<noteq> bot"
```
```   380   by (simp add: frequently_def eventually_const_iff)
```
```   381
```
```   382 lemma frequently_const[simp]: "F \<noteq> bot \<Longrightarrow> frequently (\<lambda>x. P) F \<longleftrightarrow> P"
```
```   383   by (simp add: frequently_const_iff)
```
```   384
```
```   385 lemma eventually_happens: "eventually P net \<Longrightarrow> net = bot \<or> (\<exists>x. P x)"
```
```   386   by (metis frequentlyE eventually_frequently)
```
```   387
```
```   388 lemma eventually_happens':
```
```   389   assumes "F \<noteq> bot" "eventually P F"
```
```   390   shows   "\<exists>x. P x"
```
```   391   using assms eventually_frequently frequentlyE by blast
```
```   392
```
```   393 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
```
```   394   where "trivial_limit F \<equiv> F = bot"
```
```   395
```
```   396 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
```
```   397   by (rule eventually_False [symmetric])
```
```   398
```
```   399 lemma False_imp_not_eventually: "(\<forall>x. \<not> P x ) \<Longrightarrow> \<not> trivial_limit net \<Longrightarrow> \<not> eventually (\<lambda>x. P x) net"
```
```   400   by (simp add: eventually_False)
```
```   401
```
```   402 lemma eventually_Inf: "eventually P (Inf B) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X))"
```
```   403 proof -
```
```   404   let ?F = "\<lambda>P. \<exists>X\<subseteq>B. finite X \<and> eventually P (Inf X)"
```
```   405
```
```   406   { fix P have "eventually P (Abs_filter ?F) \<longleftrightarrow> ?F P"
```
```   407     proof (rule eventually_Abs_filter is_filter.intro)+
```
```   408       show "?F (\<lambda>x. True)"
```
```   409         by (rule exI[of _ "{}"]) (simp add: le_fun_def)
```
```   410     next
```
```   411       fix P Q
```
```   412       assume "?F P" then guess X ..
```
```   413       moreover
```
```   414       assume "?F Q" then guess Y ..
```
```   415       ultimately show "?F (\<lambda>x. P x \<and> Q x)"
```
```   416         by (intro exI[of _ "X \<union> Y"])
```
```   417            (auto simp: Inf_union_distrib eventually_inf)
```
```   418     next
```
```   419       fix P Q
```
```   420       assume "?F P" then guess X ..
```
```   421       moreover assume "\<forall>x. P x \<longrightarrow> Q x"
```
```   422       ultimately show "?F Q"
```
```   423         by (intro exI[of _ X]) (auto elim: eventually_mono)
```
```   424     qed }
```
```   425   note eventually_F = this
```
```   426
```
```   427   have "Inf B = Abs_filter ?F"
```
```   428   proof (intro antisym Inf_greatest)
```
```   429     show "Inf B \<le> Abs_filter ?F"
```
```   430       by (auto simp: le_filter_def eventually_F dest: Inf_superset_mono)
```
```   431   next
```
```   432     fix F assume "F \<in> B" then show "Abs_filter ?F \<le> F"
```
```   433       by (auto simp add: le_filter_def eventually_F intro!: exI[of _ "{F}"])
```
```   434   qed
```
```   435   then show ?thesis
```
```   436     by (simp add: eventually_F)
```
```   437 qed
```
```   438
```
```   439 lemma eventually_INF: "eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>X\<subseteq>B. finite X \<and> eventually P (INF b:X. F b))"
```
```   440   unfolding eventually_Inf [of P "F`B"]
```
```   441   by (metis finite_imageI image_mono finite_subset_image)
```
```   442
```
```   443 lemma Inf_filter_not_bot:
```
```   444   fixes B :: "'a filter set"
```
```   445   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> Inf X \<noteq> bot) \<Longrightarrow> Inf B \<noteq> bot"
```
```   446   unfolding trivial_limit_def eventually_Inf[of _ B]
```
```   447     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
```
```   448
```
```   449 lemma INF_filter_not_bot:
```
```   450   fixes F :: "'i \<Rightarrow> 'a filter"
```
```   451   shows "(\<And>X. X \<subseteq> B \<Longrightarrow> finite X \<Longrightarrow> (INF b:X. F b) \<noteq> bot) \<Longrightarrow> (INF b:B. F b) \<noteq> bot"
```
```   452   unfolding trivial_limit_def eventually_INF [of _ _ B]
```
```   453     bot_bool_def [symmetric] bot_fun_def [symmetric] bot_unique by simp
```
```   454
```
```   455 lemma eventually_Inf_base:
```
```   456   assumes "B \<noteq> {}" and base: "\<And>F G. F \<in> B \<Longrightarrow> G \<in> B \<Longrightarrow> \<exists>x\<in>B. x \<le> inf F G"
```
```   457   shows "eventually P (Inf B) \<longleftrightarrow> (\<exists>b\<in>B. eventually P b)"
```
```   458 proof (subst eventually_Inf, safe)
```
```   459   fix X assume "finite X" "X \<subseteq> B"
```
```   460   then have "\<exists>b\<in>B. \<forall>x\<in>X. b \<le> x"
```
```   461   proof induct
```
```   462     case empty then show ?case
```
```   463       using \<open>B \<noteq> {}\<close> by auto
```
```   464   next
```
```   465     case (insert x X)
```
```   466     then obtain b where "b \<in> B" "\<And>x. x \<in> X \<Longrightarrow> b \<le> x"
```
```   467       by auto
```
```   468     with \<open>insert x X \<subseteq> B\<close> base[of b x] show ?case
```
```   469       by (auto intro: order_trans)
```
```   470   qed
```
```   471   then obtain b where "b \<in> B" "b \<le> Inf X"
```
```   472     by (auto simp: le_Inf_iff)
```
```   473   then show "eventually P (Inf X) \<Longrightarrow> Bex B (eventually P)"
```
```   474     by (intro bexI[of _ b]) (auto simp: le_filter_def)
```
```   475 qed (auto intro!: exI[of _ "{x}" for x])
```
```   476
```
```   477 lemma eventually_INF_base:
```
```   478   "B \<noteq> {} \<Longrightarrow> (\<And>a b. a \<in> B \<Longrightarrow> b \<in> B \<Longrightarrow> \<exists>x\<in>B. F x \<le> inf (F a) (F b)) \<Longrightarrow>
```
```   479     eventually P (INF b:B. F b) \<longleftrightarrow> (\<exists>b\<in>B. eventually P (F b))"
```
```   480   by (subst eventually_Inf_base) auto
```
```   481
```
```   482 lemma eventually_INF1: "i \<in> I \<Longrightarrow> eventually P (F i) \<Longrightarrow> eventually P (INF i:I. F i)"
```
```   483   using filter_leD[OF INF_lower] .
```
```   484
```
```   485 lemma eventually_INF_mono:
```
```   486   assumes *: "\<forall>\<^sub>F x in \<Sqinter>i\<in>I. F i. P x"
```
```   487   assumes T1: "\<And>Q R P. (\<And>x. Q x \<and> R x \<longrightarrow> P x) \<Longrightarrow> (\<And>x. T Q x \<Longrightarrow> T R x \<Longrightarrow> T P x)"
```
```   488   assumes T2: "\<And>P. (\<And>x. P x) \<Longrightarrow> (\<And>x. T P x)"
```
```   489   assumes **: "\<And>i P. i \<in> I \<Longrightarrow> \<forall>\<^sub>F x in F i. P x \<Longrightarrow> \<forall>\<^sub>F x in F' i. T P x"
```
```   490   shows "\<forall>\<^sub>F x in \<Sqinter>i\<in>I. F' i. T P x"
```
```   491 proof -
```
```   492   from * obtain X where X: "finite X" "X \<subseteq> I" "\<forall>\<^sub>F x in \<Sqinter>i\<in>X. F i. P x"
```
```   493     unfolding eventually_INF[of _ _ I] by auto
```
```   494   then have "eventually (T P) (INFIMUM X F')"
```
```   495     apply (induction X arbitrary: P)
```
```   496     apply (auto simp: eventually_inf T2)
```
```   497     subgoal for x S P Q R
```
```   498       apply (intro exI[of _ "T Q"])
```
```   499       apply (auto intro!: **) []
```
```   500       apply (intro exI[of _ "T R"])
```
```   501       apply (auto intro: T1) []
```
```   502       done
```
```   503     done
```
```   504   with X show "\<forall>\<^sub>F x in \<Sqinter>i\<in>I. F' i. T P x"
```
```   505     by (subst eventually_INF) auto
```
```   506 qed
```
```   507
```
```   508
```
```   509 subsubsection \<open>Map function for filters\<close>
```
```   510
```
```   511 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
```
```   512   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
```
```   513
```
```   514 lemma eventually_filtermap:
```
```   515   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
```
```   516   unfolding filtermap_def
```
```   517   apply (rule eventually_Abs_filter)
```
```   518   apply (rule is_filter.intro)
```
```   519   apply (auto elim!: eventually_rev_mp)
```
```   520   done
```
```   521
```
```   522 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
```
```   523   by (simp add: filter_eq_iff eventually_filtermap)
```
```   524
```
```   525 lemma filtermap_filtermap:
```
```   526   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
```
```   527   by (simp add: filter_eq_iff eventually_filtermap)
```
```   528
```
```   529 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
```
```   530   unfolding le_filter_def eventually_filtermap by simp
```
```   531
```
```   532 lemma filtermap_bot [simp]: "filtermap f bot = bot"
```
```   533   by (simp add: filter_eq_iff eventually_filtermap)
```
```   534
```
```   535 lemma filtermap_sup: "filtermap f (sup F1 F2) = sup (filtermap f F1) (filtermap f F2)"
```
```   536   by (auto simp: filter_eq_iff eventually_filtermap eventually_sup)
```
```   537
```
```   538 lemma filtermap_inf: "filtermap f (inf F1 F2) \<le> inf (filtermap f F1) (filtermap f F2)"
```
```   539   by (auto simp: le_filter_def eventually_filtermap eventually_inf)
```
```   540
```
```   541 lemma filtermap_INF: "filtermap f (INF b:B. F b) \<le> (INF b:B. filtermap f (F b))"
```
```   542 proof -
```
```   543   { fix X :: "'c set" assume "finite X"
```
```   544     then have "filtermap f (INFIMUM X F) \<le> (INF b:X. filtermap f (F b))"
```
```   545     proof induct
```
```   546       case (insert x X)
```
```   547       have "filtermap f (INF a:insert x X. F a) \<le> inf (filtermap f (F x)) (filtermap f (INF a:X. F a))"
```
```   548         by (rule order_trans[OF _ filtermap_inf]) simp
```
```   549       also have "\<dots> \<le> inf (filtermap f (F x)) (INF a:X. filtermap f (F a))"
```
```   550         by (intro inf_mono insert order_refl)
```
```   551       finally show ?case
```
```   552         by simp
```
```   553     qed simp }
```
```   554   then show ?thesis
```
```   555     unfolding le_filter_def eventually_filtermap
```
```   556     by (subst (1 2) eventually_INF) auto
```
```   557 qed
```
```   558
```
```   559 subsubsection \<open>Standard filters\<close>
```
```   560
```
```   561 definition principal :: "'a set \<Rightarrow> 'a filter" where
```
```   562   "principal S = Abs_filter (\<lambda>P. \<forall>x\<in>S. P x)"
```
```   563
```
```   564 lemma eventually_principal: "eventually P (principal S) \<longleftrightarrow> (\<forall>x\<in>S. P x)"
```
```   565   unfolding principal_def
```
```   566   by (rule eventually_Abs_filter, rule is_filter.intro) auto
```
```   567
```
```   568 lemma eventually_inf_principal: "eventually P (inf F (principal s)) \<longleftrightarrow> eventually (\<lambda>x. x \<in> s \<longrightarrow> P x) F"
```
```   569   unfolding eventually_inf eventually_principal by (auto elim: eventually_mono)
```
```   570
```
```   571 lemma principal_UNIV[simp]: "principal UNIV = top"
```
```   572   by (auto simp: filter_eq_iff eventually_principal)
```
```   573
```
```   574 lemma principal_empty[simp]: "principal {} = bot"
```
```   575   by (auto simp: filter_eq_iff eventually_principal)
```
```   576
```
```   577 lemma principal_eq_bot_iff: "principal X = bot \<longleftrightarrow> X = {}"
```
```   578   by (auto simp add: filter_eq_iff eventually_principal)
```
```   579
```
```   580 lemma principal_le_iff[iff]: "principal A \<le> principal B \<longleftrightarrow> A \<subseteq> B"
```
```   581   by (auto simp: le_filter_def eventually_principal)
```
```   582
```
```   583 lemma le_principal: "F \<le> principal A \<longleftrightarrow> eventually (\<lambda>x. x \<in> A) F"
```
```   584   unfolding le_filter_def eventually_principal
```
```   585   apply safe
```
```   586   apply (erule_tac x="\<lambda>x. x \<in> A" in allE)
```
```   587   apply (auto elim: eventually_mono)
```
```   588   done
```
```   589
```
```   590 lemma principal_inject[iff]: "principal A = principal B \<longleftrightarrow> A = B"
```
```   591   unfolding eq_iff by simp
```
```   592
```
```   593 lemma sup_principal[simp]: "sup (principal A) (principal B) = principal (A \<union> B)"
```
```   594   unfolding filter_eq_iff eventually_sup eventually_principal by auto
```
```   595
```
```   596 lemma inf_principal[simp]: "inf (principal A) (principal B) = principal (A \<inter> B)"
```
```   597   unfolding filter_eq_iff eventually_inf eventually_principal
```
```   598   by (auto intro: exI[of _ "\<lambda>x. x \<in> A"] exI[of _ "\<lambda>x. x \<in> B"])
```
```   599
```
```   600 lemma SUP_principal[simp]: "(SUP i : I. principal (A i)) = principal (\<Union>i\<in>I. A i)"
```
```   601   unfolding filter_eq_iff eventually_Sup by (auto simp: eventually_principal)
```
```   602
```
```   603 lemma INF_principal_finite: "finite X \<Longrightarrow> (INF x:X. principal (f x)) = principal (\<Inter>x\<in>X. f x)"
```
```   604   by (induct X rule: finite_induct) auto
```
```   605
```
```   606 lemma filtermap_principal[simp]: "filtermap f (principal A) = principal (f ` A)"
```
```   607   unfolding filter_eq_iff eventually_filtermap eventually_principal by simp
```
```   608
```
```   609 subsubsection \<open>Order filters\<close>
```
```   610
```
```   611 definition at_top :: "('a::order) filter"
```
```   612   where "at_top = (INF k. principal {k ..})"
```
```   613
```
```   614 lemma at_top_sub: "at_top = (INF k:{c::'a::linorder..}. principal {k ..})"
```
```   615   by (auto intro!: INF_eq max.cobounded1 max.cobounded2 simp: at_top_def)
```
```   616
```
```   617 lemma eventually_at_top_linorder: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::linorder. \<forall>n\<ge>N. P n)"
```
```   618   unfolding at_top_def
```
```   619   by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
```
```   620
```
```   621 lemma eventually_at_top_linorderI:
```
```   622   fixes c::"'a::linorder"
```
```   623   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
```
```   624   shows "eventually P at_top"
```
```   625   using assms by (auto simp: eventually_at_top_linorder)
```
```   626
```
```   627 lemma eventually_ge_at_top:
```
```   628   "eventually (\<lambda>x. (c::_::linorder) \<le> x) at_top"
```
```   629   unfolding eventually_at_top_linorder by auto
```
```   630
```
```   631 lemma eventually_at_top_dense: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::{no_top, linorder}. \<forall>n>N. P n)"
```
```   632 proof -
```
```   633   have "eventually P (INF k. principal {k <..}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n>N. P n)"
```
```   634     by (subst eventually_INF_base) (auto simp: eventually_principal intro: max.cobounded1 max.cobounded2)
```
```   635   also have "(INF k. principal {k::'a <..}) = at_top"
```
```   636     unfolding at_top_def
```
```   637     by (intro INF_eq) (auto intro: less_imp_le simp: Ici_subset_Ioi_iff gt_ex)
```
```   638   finally show ?thesis .
```
```   639 qed
```
```   640
```
```   641 lemma eventually_at_top_not_equal: "eventually (\<lambda>x::'a::{no_top, linorder}. x \<noteq> c) at_top"
```
```   642   unfolding eventually_at_top_dense by auto
```
```   643
```
```   644 lemma eventually_gt_at_top: "eventually (\<lambda>x. (c::_::{no_top, linorder}) < x) at_top"
```
```   645   unfolding eventually_at_top_dense by auto
```
```   646
```
```   647 lemma eventually_all_ge_at_top:
```
```   648   assumes "eventually P (at_top :: ('a :: linorder) filter)"
```
```   649   shows   "eventually (\<lambda>x. \<forall>y\<ge>x. P y) at_top"
```
```   650 proof -
```
```   651   from assms obtain x where "\<And>y. y \<ge> x \<Longrightarrow> P y" by (auto simp: eventually_at_top_linorder)
```
```   652   hence "\<forall>z\<ge>y. P z" if "y \<ge> x" for y using that by simp
```
```   653   thus ?thesis by (auto simp: eventually_at_top_linorder)
```
```   654 qed
```
```   655
```
```   656 definition at_bot :: "('a::order) filter"
```
```   657   where "at_bot = (INF k. principal {.. k})"
```
```   658
```
```   659 lemma at_bot_sub: "at_bot = (INF k:{.. c::'a::linorder}. principal {.. k})"
```
```   660   by (auto intro!: INF_eq min.cobounded1 min.cobounded2 simp: at_bot_def)
```
```   661
```
```   662 lemma eventually_at_bot_linorder:
```
```   663   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n\<le>N. P n)"
```
```   664   unfolding at_bot_def
```
```   665   by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
```
```   666
```
```   667 lemma eventually_le_at_bot:
```
```   668   "eventually (\<lambda>x. x \<le> (c::_::linorder)) at_bot"
```
```   669   unfolding eventually_at_bot_linorder by auto
```
```   670
```
```   671 lemma eventually_at_bot_dense: "eventually P at_bot \<longleftrightarrow> (\<exists>N::'a::{no_bot, linorder}. \<forall>n<N. P n)"
```
```   672 proof -
```
```   673   have "eventually P (INF k. principal {..< k}) \<longleftrightarrow> (\<exists>N::'a. \<forall>n<N. P n)"
```
```   674     by (subst eventually_INF_base) (auto simp: eventually_principal intro: min.cobounded1 min.cobounded2)
```
```   675   also have "(INF k. principal {..< k::'a}) = at_bot"
```
```   676     unfolding at_bot_def
```
```   677     by (intro INF_eq) (auto intro: less_imp_le simp: Iic_subset_Iio_iff lt_ex)
```
```   678   finally show ?thesis .
```
```   679 qed
```
```   680
```
```   681 lemma eventually_at_bot_not_equal: "eventually (\<lambda>x::'a::{no_bot, linorder}. x \<noteq> c) at_bot"
```
```   682   unfolding eventually_at_bot_dense by auto
```
```   683
```
```   684 lemma eventually_gt_at_bot:
```
```   685   "eventually (\<lambda>x. x < (c::_::unbounded_dense_linorder)) at_bot"
```
```   686   unfolding eventually_at_bot_dense by auto
```
```   687
```
```   688 lemma trivial_limit_at_bot_linorder: "\<not> trivial_limit (at_bot ::('a::linorder) filter)"
```
```   689   unfolding trivial_limit_def
```
```   690   by (metis eventually_at_bot_linorder order_refl)
```
```   691
```
```   692 lemma trivial_limit_at_top_linorder: "\<not> trivial_limit (at_top ::('a::linorder) filter)"
```
```   693   unfolding trivial_limit_def
```
```   694   by (metis eventually_at_top_linorder order_refl)
```
```   695
```
```   696 subsection \<open>Sequentially\<close>
```
```   697
```
```   698 abbreviation sequentially :: "nat filter"
```
```   699   where "sequentially \<equiv> at_top"
```
```   700
```
```   701 lemma eventually_sequentially:
```
```   702   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
```
```   703   by (rule eventually_at_top_linorder)
```
```   704
```
```   705 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
```
```   706   unfolding filter_eq_iff eventually_sequentially by auto
```
```   707
```
```   708 lemmas trivial_limit_sequentially = sequentially_bot
```
```   709
```
```   710 lemma eventually_False_sequentially [simp]:
```
```   711   "\<not> eventually (\<lambda>n. False) sequentially"
```
```   712   by (simp add: eventually_False)
```
```   713
```
```   714 lemma le_sequentially:
```
```   715   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
```
```   716   by (simp add: at_top_def le_INF_iff le_principal)
```
```   717
```
```   718 lemma eventually_sequentiallyI [intro?]:
```
```   719   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
```
```   720   shows "eventually P sequentially"
```
```   721 using assms by (auto simp: eventually_sequentially)
```
```   722
```
```   723 lemma eventually_sequentially_Suc: "eventually (\<lambda>i. P (Suc i)) sequentially \<longleftrightarrow> eventually P sequentially"
```
```   724   unfolding eventually_sequentially by (metis Suc_le_D Suc_le_mono le_Suc_eq)
```
```   725
```
```   726 lemma eventually_sequentially_seg: "eventually (\<lambda>n. P (n + k)) sequentially \<longleftrightarrow> eventually P sequentially"
```
```   727   using eventually_sequentially_Suc[of "\<lambda>n. P (n + k)" for k] by (induction k) auto
```
```   728
```
```   729
```
```   730 subsection \<open>The cofinite filter\<close>
```
```   731
```
```   732 definition "cofinite = Abs_filter (\<lambda>P. finite {x. \<not> P x})"
```
```   733
```
```   734 abbreviation Inf_many :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "\<exists>\<^sub>\<infinity>" 10)
```
```   735   where "Inf_many P \<equiv> frequently P cofinite"
```
```   736
```
```   737 abbreviation Alm_all :: "('a \<Rightarrow> bool) \<Rightarrow> bool"  (binder "\<forall>\<^sub>\<infinity>" 10)
```
```   738   where "Alm_all P \<equiv> eventually P cofinite"
```
```   739
```
```   740 notation (ASCII)
```
```   741   Inf_many  (binder "INFM " 10) and
```
```   742   Alm_all  (binder "MOST " 10)
```
```   743
```
```   744 lemma eventually_cofinite: "eventually P cofinite \<longleftrightarrow> finite {x. \<not> P x}"
```
```   745   unfolding cofinite_def
```
```   746 proof (rule eventually_Abs_filter, rule is_filter.intro)
```
```   747   fix P Q :: "'a \<Rightarrow> bool" assume "finite {x. \<not> P x}" "finite {x. \<not> Q x}"
```
```   748   from finite_UnI[OF this] show "finite {x. \<not> (P x \<and> Q x)}"
```
```   749     by (rule rev_finite_subset) auto
```
```   750 next
```
```   751   fix P Q :: "'a \<Rightarrow> bool" assume P: "finite {x. \<not> P x}" and *: "\<forall>x. P x \<longrightarrow> Q x"
```
```   752   from * show "finite {x. \<not> Q x}"
```
```   753     by (intro finite_subset[OF _ P]) auto
```
```   754 qed simp
```
```   755
```
```   756 lemma frequently_cofinite: "frequently P cofinite \<longleftrightarrow> \<not> finite {x. P x}"
```
```   757   by (simp add: frequently_def eventually_cofinite)
```
```   758
```
```   759 lemma cofinite_bot[simp]: "cofinite = (bot::'a filter) \<longleftrightarrow> finite (UNIV :: 'a set)"
```
```   760   unfolding trivial_limit_def eventually_cofinite by simp
```
```   761
```
```   762 lemma cofinite_eq_sequentially: "cofinite = sequentially"
```
```   763   unfolding filter_eq_iff eventually_sequentially eventually_cofinite
```
```   764 proof safe
```
```   765   fix P :: "nat \<Rightarrow> bool" assume [simp]: "finite {x. \<not> P x}"
```
```   766   show "\<exists>N. \<forall>n\<ge>N. P n"
```
```   767   proof cases
```
```   768     assume "{x. \<not> P x} \<noteq> {}" then show ?thesis
```
```   769       by (intro exI[of _ "Suc (Max {x. \<not> P x})"]) (auto simp: Suc_le_eq)
```
```   770   qed auto
```
```   771 next
```
```   772   fix P :: "nat \<Rightarrow> bool" and N :: nat assume "\<forall>n\<ge>N. P n"
```
```   773   then have "{x. \<not> P x} \<subseteq> {..< N}"
```
```   774     by (auto simp: not_le)
```
```   775   then show "finite {x. \<not> P x}"
```
```   776     by (blast intro: finite_subset)
```
```   777 qed
```
```   778
```
```   779 subsubsection \<open>Product of filters\<close>
```
```   780
```
```   781 lemma filtermap_sequentually_ne_bot: "filtermap f sequentially \<noteq> bot"
```
```   782   by (auto simp add: filter_eq_iff eventually_filtermap eventually_sequentially)
```
```   783
```
```   784 definition prod_filter :: "'a filter \<Rightarrow> 'b filter \<Rightarrow> ('a \<times> 'b) filter" (infixr "\<times>\<^sub>F" 80) where
```
```   785   "prod_filter F G =
```
```   786     (INF (P, Q):{(P, Q). eventually P F \<and> eventually Q G}. principal {(x, y). P x \<and> Q y})"
```
```   787
```
```   788 lemma eventually_prod_filter: "eventually P (F \<times>\<^sub>F G) \<longleftrightarrow>
```
```   789   (\<exists>Pf Pg. eventually Pf F \<and> eventually Pg G \<and> (\<forall>x y. Pf x \<longrightarrow> Pg y \<longrightarrow> P (x, y)))"
```
```   790   unfolding prod_filter_def
```
```   791 proof (subst eventually_INF_base, goal_cases)
```
```   792   case 2
```
```   793   moreover have "eventually Pf F \<Longrightarrow> eventually Qf F \<Longrightarrow> eventually Pg G \<Longrightarrow> eventually Qg G \<Longrightarrow>
```
```   794     \<exists>P Q. eventually P F \<and> eventually Q G \<and>
```
```   795       Collect P \<times> Collect Q \<subseteq> Collect Pf \<times> Collect Pg \<inter> Collect Qf \<times> Collect Qg" for Pf Pg Qf Qg
```
```   796     by (intro conjI exI[of _ "inf Pf Qf"] exI[of _ "inf Pg Qg"])
```
```   797        (auto simp: inf_fun_def eventually_conj)
```
```   798   ultimately show ?case
```
```   799     by auto
```
```   800 qed (auto simp: eventually_principal intro: eventually_True)
```
```   801
```
```   802 lemma eventually_prod1:
```
```   803   assumes "B \<noteq> bot"
```
```   804   shows "(\<forall>\<^sub>F (x, y) in A \<times>\<^sub>F B. P x) \<longleftrightarrow> (\<forall>\<^sub>F x in A. P x)"
```
```   805   unfolding eventually_prod_filter
```
```   806 proof safe
```
```   807   fix R Q
```
```   808   assume *: "\<forall>\<^sub>F x in A. R x" "\<forall>\<^sub>F x in B. Q x" "\<forall>x y. R x \<longrightarrow> Q y \<longrightarrow> P x"
```
```   809   with \<open>B \<noteq> bot\<close> obtain y where "Q y" by (auto dest: eventually_happens)
```
```   810   with * show "eventually P A"
```
```   811     by (force elim: eventually_mono)
```
```   812 next
```
```   813   assume "eventually P A"
```
```   814   then show "\<exists>Pf Pg. eventually Pf A \<and> eventually Pg B \<and> (\<forall>x y. Pf x \<longrightarrow> Pg y \<longrightarrow> P x)"
```
```   815     by (intro exI[of _ P] exI[of _ "\<lambda>x. True"]) auto
```
```   816 qed
```
```   817
```
```   818 lemma eventually_prod2:
```
```   819   assumes "A \<noteq> bot"
```
```   820   shows "(\<forall>\<^sub>F (x, y) in A \<times>\<^sub>F B. P y) \<longleftrightarrow> (\<forall>\<^sub>F y in B. P y)"
```
```   821   unfolding eventually_prod_filter
```
```   822 proof safe
```
```   823   fix R Q
```
```   824   assume *: "\<forall>\<^sub>F x in A. R x" "\<forall>\<^sub>F x in B. Q x" "\<forall>x y. R x \<longrightarrow> Q y \<longrightarrow> P y"
```
```   825   with \<open>A \<noteq> bot\<close> obtain x where "R x" by (auto dest: eventually_happens)
```
```   826   with * show "eventually P B"
```
```   827     by (force elim: eventually_mono)
```
```   828 next
```
```   829   assume "eventually P B"
```
```   830   then show "\<exists>Pf Pg. eventually Pf A \<and> eventually Pg B \<and> (\<forall>x y. Pf x \<longrightarrow> Pg y \<longrightarrow> P y)"
```
```   831     by (intro exI[of _ P] exI[of _ "\<lambda>x. True"]) auto
```
```   832 qed
```
```   833
```
```   834 lemma INF_filter_bot_base:
```
```   835   fixes F :: "'a \<Rightarrow> 'b filter"
```
```   836   assumes *: "\<And>i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> \<exists>k\<in>I. F k \<le> F i \<sqinter> F j"
```
```   837   shows "(INF i:I. F i) = bot \<longleftrightarrow> (\<exists>i\<in>I. F i = bot)"
```
```   838 proof (cases "\<exists>i\<in>I. F i = bot")
```
```   839   case True
```
```   840   then have "(INF i:I. F i) \<le> bot"
```
```   841     by (auto intro: INF_lower2)
```
```   842   with True show ?thesis
```
```   843     by (auto simp: bot_unique)
```
```   844 next
```
```   845   case False
```
```   846   moreover have "(INF i:I. F i) \<noteq> bot"
```
```   847   proof (cases "I = {}")
```
```   848     case True
```
```   849     then show ?thesis
```
```   850       by (auto simp add: filter_eq_iff)
```
```   851   next
```
```   852     case False': False
```
```   853     show ?thesis
```
```   854     proof (rule INF_filter_not_bot)
```
```   855       fix J
```
```   856       assume "finite J" "J \<subseteq> I"
```
```   857       then have "\<exists>k\<in>I. F k \<le> (\<Sqinter>i\<in>J. F i)"
```
```   858       proof (induct J)
```
```   859         case empty
```
```   860         then show ?case
```
```   861           using \<open>I \<noteq> {}\<close> by auto
```
```   862       next
```
```   863         case (insert i J)
```
```   864         then obtain k where "k \<in> I" "F k \<le> (\<Sqinter>i\<in>J. F i)" by auto
```
```   865         with insert *[of i k] show ?case
```
```   866           by auto
```
```   867       qed
```
```   868       with False show "(\<Sqinter>i\<in>J. F i) \<noteq> \<bottom>"
```
```   869         by (auto simp: bot_unique)
```
```   870     qed
```
```   871   qed
```
```   872   ultimately show ?thesis
```
```   873     by auto
```
```   874 qed
```
```   875
```
```   876 lemma Collect_empty_eq_bot: "Collect P = {} \<longleftrightarrow> P = \<bottom>"
```
```   877   by auto
```
```   878
```
```   879 lemma prod_filter_eq_bot: "A \<times>\<^sub>F B = bot \<longleftrightarrow> A = bot \<or> B = bot"
```
```   880   unfolding prod_filter_def
```
```   881 proof (subst INF_filter_bot_base; clarsimp simp: principal_eq_bot_iff Collect_empty_eq_bot bot_fun_def simp del: Collect_empty_eq)
```
```   882   fix A1 A2 B1 B2 assume "\<forall>\<^sub>F x in A. A1 x" "\<forall>\<^sub>F x in A. A2 x" "\<forall>\<^sub>F x in B. B1 x" "\<forall>\<^sub>F x in B. B2 x"
```
```   883   then show "\<exists>x. eventually x A \<and> (\<exists>y. eventually y B \<and> Collect x \<times> Collect y \<subseteq> Collect A1 \<times> Collect B1 \<and> Collect x \<times> Collect y \<subseteq> Collect A2 \<times> Collect B2)"
```
```   884     by (intro exI[of _ "\<lambda>x. A1 x \<and> A2 x"] exI[of _ "\<lambda>x. B1 x \<and> B2 x"] conjI)
```
```   885        (auto simp: eventually_conj_iff)
```
```   886 next
```
```   887   show "(\<exists>x. eventually x A \<and> (\<exists>y. eventually y B \<and> (x = (\<lambda>x. False) \<or> y = (\<lambda>x. False)))) = (A = \<bottom> \<or> B = \<bottom>)"
```
```   888     by (auto simp: trivial_limit_def intro: eventually_True)
```
```   889 qed
```
```   890
```
```   891 lemma prod_filter_mono: "F \<le> F' \<Longrightarrow> G \<le> G' \<Longrightarrow> F \<times>\<^sub>F G \<le> F' \<times>\<^sub>F G'"
```
```   892   by (auto simp: le_filter_def eventually_prod_filter)
```
```   893
```
```   894 lemma prod_filter_mono_iff:
```
```   895   assumes nAB: "A \<noteq> bot" "B \<noteq> bot"
```
```   896   shows "A \<times>\<^sub>F B \<le> C \<times>\<^sub>F D \<longleftrightarrow> A \<le> C \<and> B \<le> D"
```
```   897 proof safe
```
```   898   assume *: "A \<times>\<^sub>F B \<le> C \<times>\<^sub>F D"
```
```   899   with assms have "A \<times>\<^sub>F B \<noteq> bot"
```
```   900     by (auto simp: bot_unique prod_filter_eq_bot)
```
```   901   with * have "C \<times>\<^sub>F D \<noteq> bot"
```
```   902     by (auto simp: bot_unique)
```
```   903   then have nCD: "C \<noteq> bot" "D \<noteq> bot"
```
```   904     by (auto simp: prod_filter_eq_bot)
```
```   905
```
```   906   show "A \<le> C"
```
```   907   proof (rule filter_leI)
```
```   908     fix P assume "eventually P C" with *[THEN filter_leD, of "\<lambda>(x, y). P x"] show "eventually P A"
```
```   909       using nAB nCD by (simp add: eventually_prod1 eventually_prod2)
```
```   910   qed
```
```   911
```
```   912   show "B \<le> D"
```
```   913   proof (rule filter_leI)
```
```   914     fix P assume "eventually P D" with *[THEN filter_leD, of "\<lambda>(x, y). P y"] show "eventually P B"
```
```   915       using nAB nCD by (simp add: eventually_prod1 eventually_prod2)
```
```   916   qed
```
```   917 qed (intro prod_filter_mono)
```
```   918
```
```   919 lemma eventually_prod_same: "eventually P (F \<times>\<^sub>F F) \<longleftrightarrow>
```
```   920     (\<exists>Q. eventually Q F \<and> (\<forall>x y. Q x \<longrightarrow> Q y \<longrightarrow> P (x, y)))"
```
```   921   unfolding eventually_prod_filter
```
```   922   apply safe
```
```   923   apply (rule_tac x="inf Pf Pg" in exI)
```
```   924   apply (auto simp: inf_fun_def intro!: eventually_conj)
```
```   925   done
```
```   926
```
```   927 lemma eventually_prod_sequentially:
```
```   928   "eventually P (sequentially \<times>\<^sub>F sequentially) \<longleftrightarrow> (\<exists>N. \<forall>m \<ge> N. \<forall>n \<ge> N. P (n, m))"
```
```   929   unfolding eventually_prod_same eventually_sequentially by auto
```
```   930
```
```   931 lemma principal_prod_principal: "principal A \<times>\<^sub>F principal B = principal (A \<times> B)"
```
```   932   apply (simp add: filter_eq_iff eventually_prod_filter eventually_principal)
```
```   933   apply safe
```
```   934   apply blast
```
```   935   apply (intro conjI exI[of _ "\<lambda>x. x \<in> A"] exI[of _ "\<lambda>x. x \<in> B"])
```
```   936   apply auto
```
```   937   done
```
```   938
```
```   939 lemma prod_filter_INF:
```
```   940   assumes "I \<noteq> {}" "J \<noteq> {}"
```
```   941   shows "(INF i:I. A i) \<times>\<^sub>F (INF j:J. B j) = (INF i:I. INF j:J. A i \<times>\<^sub>F B j)"
```
```   942 proof (safe intro!: antisym INF_greatest)
```
```   943   from \<open>I \<noteq> {}\<close> obtain i where "i \<in> I" by auto
```
```   944   from \<open>J \<noteq> {}\<close> obtain j where "j \<in> J" by auto
```
```   945
```
```   946   show "(\<Sqinter>i\<in>I. \<Sqinter>j\<in>J. A i \<times>\<^sub>F B j) \<le> (\<Sqinter>i\<in>I. A i) \<times>\<^sub>F (\<Sqinter>j\<in>J. B j)"
```
```   947     unfolding prod_filter_def
```
```   948   proof (safe intro!: INF_greatest)
```
```   949     fix P Q assume P: "\<forall>\<^sub>F x in \<Sqinter>i\<in>I. A i. P x" and Q: "\<forall>\<^sub>F x in \<Sqinter>j\<in>J. B j. Q x"
```
```   950     let ?X = "(\<Sqinter>i\<in>I. \<Sqinter>j\<in>J. \<Sqinter>(P, Q)\<in>{(P, Q). (\<forall>\<^sub>F x in A i. P x) \<and> (\<forall>\<^sub>F x in B j. Q x)}. principal {(x, y). P x \<and> Q y})"
```
```   951     have "?X \<le> principal {x. P (fst x)} \<sqinter> principal {x. Q (snd x)}"
```
```   952     proof (intro inf_greatest)
```
```   953       have "?X \<le> (\<Sqinter>i\<in>I. \<Sqinter>P\<in>{P. eventually P (A i)}. principal {x. P (fst x)})"
```
```   954         by (auto intro!: INF_greatest INF_lower2[of j] INF_lower2 \<open>j\<in>J\<close> INF_lower2[of "(_, \<lambda>x. True)"])
```
```   955       also have "\<dots> \<le> principal {x. P (fst x)}"
```
```   956         unfolding le_principal
```
```   957       proof (rule eventually_INF_mono[OF P])
```
```   958         fix i P assume "i \<in> I" "eventually P (A i)"
```
```   959         then show "\<forall>\<^sub>F x in \<Sqinter>P\<in>{P. eventually P (A i)}. principal {x. P (fst x)}. x \<in> {x. P (fst x)}"
```
```   960           unfolding le_principal[symmetric] by (auto intro!: INF_lower)
```
```   961       qed auto
```
```   962       finally show "?X \<le> principal {x. P (fst x)}" .
```
```   963
```
```   964       have "?X \<le> (\<Sqinter>i\<in>J. \<Sqinter>P\<in>{P. eventually P (B i)}. principal {x. P (snd x)})"
```
```   965         by (auto intro!: INF_greatest INF_lower2[of i] INF_lower2 \<open>i\<in>I\<close> INF_lower2[of "(\<lambda>x. True, _)"])
```
```   966       also have "\<dots> \<le> principal {x. Q (snd x)}"
```
```   967         unfolding le_principal
```
```   968       proof (rule eventually_INF_mono[OF Q])
```
```   969         fix j Q assume "j \<in> J" "eventually Q (B j)"
```
```   970         then show "\<forall>\<^sub>F x in \<Sqinter>P\<in>{P. eventually P (B j)}. principal {x. P (snd x)}. x \<in> {x. Q (snd x)}"
```
```   971           unfolding le_principal[symmetric] by (auto intro!: INF_lower)
```
```   972       qed auto
```
```   973       finally show "?X \<le> principal {x. Q (snd x)}" .
```
```   974     qed
```
```   975     also have "\<dots> = principal {(x, y). P x \<and> Q y}"
```
```   976       by auto
```
```   977     finally show "?X \<le> principal {(x, y). P x \<and> Q y}" .
```
```   978   qed
```
```   979 qed (intro prod_filter_mono INF_lower)
```
```   980
```
```   981 lemma filtermap_Pair: "filtermap (\<lambda>x. (f x, g x)) F \<le> filtermap f F \<times>\<^sub>F filtermap g F"
```
```   982   by (simp add: le_filter_def eventually_filtermap eventually_prod_filter)
```
```   983      (auto elim: eventually_elim2)
```
```   984
```
```   985 lemma eventually_prodI: "eventually P F \<Longrightarrow> eventually Q G \<Longrightarrow> eventually (\<lambda>x. P (fst x) \<and> Q (snd x)) (F \<times>\<^sub>F G)"
```
```   986   unfolding prod_filter_def
```
```   987   by (intro eventually_INF1[of "(P, Q)"]) (auto simp: eventually_principal)
```
```   988
```
```   989 lemma prod_filter_INF1: "I \<noteq> {} \<Longrightarrow> (INF i:I. A i) \<times>\<^sub>F B = (INF i:I. A i \<times>\<^sub>F B)"
```
```   990   using prod_filter_INF[of I "{B}" A "\<lambda>x. x"] by simp
```
```   991
```
```   992 lemma prod_filter_INF2: "J \<noteq> {} \<Longrightarrow> A \<times>\<^sub>F (INF i:J. B i) = (INF i:J. A \<times>\<^sub>F B i)"
```
```   993   using prod_filter_INF[of "{A}" J "\<lambda>x. x" B] by simp
```
```   994
```
```   995 subsection \<open>Limits\<close>
```
```   996
```
```   997 definition filterlim :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter \<Rightarrow> bool" where
```
```   998   "filterlim f F2 F1 \<longleftrightarrow> filtermap f F1 \<le> F2"
```
```   999
```
```  1000 syntax
```
```  1001   "_LIM" :: "pttrns \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> bool" ("(3LIM (_)/ (_)./ (_) :> (_))" [1000, 10, 0, 10] 10)
```
```  1002
```
```  1003 translations
```
```  1004   "LIM x F1. f :> F2" == "CONST filterlim (\<lambda>x. f) F2 F1"
```
```  1005
```
```  1006 lemma filterlim_top [simp]: "filterlim f top F"
```
```  1007   by (simp add: filterlim_def)
```
```  1008
```
```  1009 lemma filterlim_iff:
```
```  1010   "(LIM x F1. f x :> F2) \<longleftrightarrow> (\<forall>P. eventually P F2 \<longrightarrow> eventually (\<lambda>x. P (f x)) F1)"
```
```  1011   unfolding filterlim_def le_filter_def eventually_filtermap ..
```
```  1012
```
```  1013 lemma filterlim_compose:
```
```  1014   "filterlim g F3 F2 \<Longrightarrow> filterlim f F2 F1 \<Longrightarrow> filterlim (\<lambda>x. g (f x)) F3 F1"
```
```  1015   unfolding filterlim_def filtermap_filtermap[symmetric] by (metis filtermap_mono order_trans)
```
```  1016
```
```  1017 lemma filterlim_mono:
```
```  1018   "filterlim f F2 F1 \<Longrightarrow> F2 \<le> F2' \<Longrightarrow> F1' \<le> F1 \<Longrightarrow> filterlim f F2' F1'"
```
```  1019   unfolding filterlim_def by (metis filtermap_mono order_trans)
```
```  1020
```
```  1021 lemma filterlim_ident: "LIM x F. x :> F"
```
```  1022   by (simp add: filterlim_def filtermap_ident)
```
```  1023
```
```  1024 lemma filterlim_cong:
```
```  1025   "F1 = F1' \<Longrightarrow> F2 = F2' \<Longrightarrow> eventually (\<lambda>x. f x = g x) F2 \<Longrightarrow> filterlim f F1 F2 = filterlim g F1' F2'"
```
```  1026   by (auto simp: filterlim_def le_filter_def eventually_filtermap elim: eventually_elim2)
```
```  1027
```
```  1028 lemma filterlim_mono_eventually:
```
```  1029   assumes "filterlim f F G" and ord: "F \<le> F'" "G' \<le> G"
```
```  1030   assumes eq: "eventually (\<lambda>x. f x = f' x) G'"
```
```  1031   shows "filterlim f' F' G'"
```
```  1032   apply (rule filterlim_cong[OF refl refl eq, THEN iffD1])
```
```  1033   apply (rule filterlim_mono[OF _ ord])
```
```  1034   apply fact
```
```  1035   done
```
```  1036
```
```  1037 lemma filtermap_mono_strong: "inj f \<Longrightarrow> filtermap f F \<le> filtermap f G \<longleftrightarrow> F \<le> G"
```
```  1038   apply (auto intro!: filtermap_mono) []
```
```  1039   apply (auto simp: le_filter_def eventually_filtermap)
```
```  1040   apply (erule_tac x="\<lambda>x. P (inv f x)" in allE)
```
```  1041   apply auto
```
```  1042   done
```
```  1043
```
```  1044 lemma filtermap_eq_strong: "inj f \<Longrightarrow> filtermap f F = filtermap f G \<longleftrightarrow> F = G"
```
```  1045   by (simp add: filtermap_mono_strong eq_iff)
```
```  1046
```
```  1047 lemma filtermap_fun_inverse:
```
```  1048   assumes g: "filterlim g F G"
```
```  1049   assumes f: "filterlim f G F"
```
```  1050   assumes ev: "eventually (\<lambda>x. f (g x) = x) G"
```
```  1051   shows "filtermap f F = G"
```
```  1052 proof (rule antisym)
```
```  1053   show "filtermap f F \<le> G"
```
```  1054     using f unfolding filterlim_def .
```
```  1055   have "G = filtermap f (filtermap g G)"
```
```  1056     using ev by (auto elim: eventually_elim2 simp: filter_eq_iff eventually_filtermap)
```
```  1057   also have "\<dots> \<le> filtermap f F"
```
```  1058     using g by (intro filtermap_mono) (simp add: filterlim_def)
```
```  1059   finally show "G \<le> filtermap f F" .
```
```  1060 qed
```
```  1061
```
```  1062 lemma filterlim_principal:
```
```  1063   "(LIM x F. f x :> principal S) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> S) F)"
```
```  1064   unfolding filterlim_def eventually_filtermap le_principal ..
```
```  1065
```
```  1066 lemma filterlim_inf:
```
```  1067   "(LIM x F1. f x :> inf F2 F3) \<longleftrightarrow> ((LIM x F1. f x :> F2) \<and> (LIM x F1. f x :> F3))"
```
```  1068   unfolding filterlim_def by simp
```
```  1069
```
```  1070 lemma filterlim_INF:
```
```  1071   "(LIM x F. f x :> (INF b:B. G b)) \<longleftrightarrow> (\<forall>b\<in>B. LIM x F. f x :> G b)"
```
```  1072   unfolding filterlim_def le_INF_iff ..
```
```  1073
```
```  1074 lemma filterlim_INF_INF:
```
```  1075   "(\<And>m. m \<in> J \<Longrightarrow> \<exists>i\<in>I. filtermap f (F i) \<le> G m) \<Longrightarrow> LIM x (INF i:I. F i). f x :> (INF j:J. G j)"
```
```  1076   unfolding filterlim_def by (rule order_trans[OF filtermap_INF INF_mono])
```
```  1077
```
```  1078 lemma filterlim_base:
```
```  1079   "(\<And>m x. m \<in> J \<Longrightarrow> i m \<in> I) \<Longrightarrow> (\<And>m x. m \<in> J \<Longrightarrow> x \<in> F (i m) \<Longrightarrow> f x \<in> G m) \<Longrightarrow>
```
```  1080     LIM x (INF i:I. principal (F i)). f x :> (INF j:J. principal (G j))"
```
```  1081   by (force intro!: filterlim_INF_INF simp: image_subset_iff)
```
```  1082
```
```  1083 lemma filterlim_base_iff:
```
```  1084   assumes "I \<noteq> {}" and chain: "\<And>i j. i \<in> I \<Longrightarrow> j \<in> I \<Longrightarrow> F i \<subseteq> F j \<or> F j \<subseteq> F i"
```
```  1085   shows "(LIM x (INF i:I. principal (F i)). f x :> INF j:J. principal (G j)) \<longleftrightarrow>
```
```  1086     (\<forall>j\<in>J. \<exists>i\<in>I. \<forall>x\<in>F i. f x \<in> G j)"
```
```  1087   unfolding filterlim_INF filterlim_principal
```
```  1088 proof (subst eventually_INF_base)
```
```  1089   fix i j assume "i \<in> I" "j \<in> I"
```
```  1090   with chain[OF this] show "\<exists>x\<in>I. principal (F x) \<le> inf (principal (F i)) (principal (F j))"
```
```  1091     by auto
```
```  1092 qed (auto simp: eventually_principal \<open>I \<noteq> {}\<close>)
```
```  1093
```
```  1094 lemma filterlim_filtermap: "filterlim f F1 (filtermap g F2) = filterlim (\<lambda>x. f (g x)) F1 F2"
```
```  1095   unfolding filterlim_def filtermap_filtermap ..
```
```  1096
```
```  1097 lemma filterlim_sup:
```
```  1098   "filterlim f F F1 \<Longrightarrow> filterlim f F F2 \<Longrightarrow> filterlim f F (sup F1 F2)"
```
```  1099   unfolding filterlim_def filtermap_sup by auto
```
```  1100
```
```  1101 lemma filterlim_sequentially_Suc:
```
```  1102   "(LIM x sequentially. f (Suc x) :> F) \<longleftrightarrow> (LIM x sequentially. f x :> F)"
```
```  1103   unfolding filterlim_iff by (subst eventually_sequentially_Suc) simp
```
```  1104
```
```  1105 lemma filterlim_Suc: "filterlim Suc sequentially sequentially"
```
```  1106   by (simp add: filterlim_iff eventually_sequentially) (metis le_Suc_eq)
```
```  1107
```
```  1108 lemma filterlim_If:
```
```  1109   "LIM x inf F (principal {x. P x}). f x :> G \<Longrightarrow>
```
```  1110     LIM x inf F (principal {x. \<not> P x}). g x :> G \<Longrightarrow>
```
```  1111     LIM x F. if P x then f x else g x :> G"
```
```  1112   unfolding filterlim_iff eventually_inf_principal by (auto simp: eventually_conj_iff)
```
```  1113
```
```  1114 lemma filterlim_Pair:
```
```  1115   "LIM x F. f x :> G \<Longrightarrow> LIM x F. g x :> H \<Longrightarrow> LIM x F. (f x, g x) :> G \<times>\<^sub>F H"
```
```  1116   unfolding filterlim_def
```
```  1117   by (rule order_trans[OF filtermap_Pair prod_filter_mono])
```
```  1118
```
```  1119 subsection \<open>Limits to @{const at_top} and @{const at_bot}\<close>
```
```  1120
```
```  1121 lemma filterlim_at_top:
```
```  1122   fixes f :: "'a \<Rightarrow> ('b::linorder)"
```
```  1123   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z \<le> f x) F)"
```
```  1124   by (auto simp: filterlim_iff eventually_at_top_linorder elim!: eventually_mono)
```
```  1125
```
```  1126 lemma filterlim_at_top_mono:
```
```  1127   "LIM x F. f x :> at_top \<Longrightarrow> eventually (\<lambda>x. f x \<le> (g x::'a::linorder)) F \<Longrightarrow>
```
```  1128     LIM x F. g x :> at_top"
```
```  1129   by (auto simp: filterlim_at_top elim: eventually_elim2 intro: order_trans)
```
```  1130
```
```  1131 lemma filterlim_at_top_dense:
```
```  1132   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)"
```
```  1133   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z < f x) F)"
```
```  1134   by (metis eventually_mono[of _ F] eventually_gt_at_top order_less_imp_le
```
```  1135             filterlim_at_top[of f F] filterlim_iff[of f at_top F])
```
```  1136
```
```  1137 lemma filterlim_at_top_ge:
```
```  1138   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
```
```  1139   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F)"
```
```  1140   unfolding at_top_sub[of c] filterlim_INF by (auto simp add: filterlim_principal)
```
```  1141
```
```  1142 lemma filterlim_at_top_at_top:
```
```  1143   fixes f :: "'a::linorder \<Rightarrow> 'b::linorder"
```
```  1144   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
```
```  1145   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
```
```  1146   assumes Q: "eventually Q at_top"
```
```  1147   assumes P: "eventually P at_top"
```
```  1148   shows "filterlim f at_top at_top"
```
```  1149 proof -
```
```  1150   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
```
```  1151     unfolding eventually_at_top_linorder by auto
```
```  1152   show ?thesis
```
```  1153   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
```
```  1154     fix z assume "x \<le> z"
```
```  1155     with x have "P z" by auto
```
```  1156     have "eventually (\<lambda>x. g z \<le> x) at_top"
```
```  1157       by (rule eventually_ge_at_top)
```
```  1158     with Q show "eventually (\<lambda>x. z \<le> f x) at_top"
```
```  1159       by eventually_elim (metis mono bij \<open>P z\<close>)
```
```  1160   qed
```
```  1161 qed
```
```  1162
```
```  1163 lemma filterlim_at_top_gt:
```
```  1164   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
```
```  1165   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z>c. eventually (\<lambda>x. Z \<le> f x) F)"
```
```  1166   by (metis filterlim_at_top order_less_le_trans gt_ex filterlim_at_top_ge)
```
```  1167
```
```  1168 lemma filterlim_at_bot:
```
```  1169   fixes f :: "'a \<Rightarrow> ('b::linorder)"
```
```  1170   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F)"
```
```  1171   by (auto simp: filterlim_iff eventually_at_bot_linorder elim!: eventually_mono)
```
```  1172
```
```  1173 lemma filterlim_at_bot_dense:
```
```  1174   fixes f :: "'a \<Rightarrow> ('b::{dense_linorder, no_bot})"
```
```  1175   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x < Z) F)"
```
```  1176 proof (auto simp add: filterlim_at_bot[of f F])
```
```  1177   fix Z :: 'b
```
```  1178   from lt_ex [of Z] obtain Z' where 1: "Z' < Z" ..
```
```  1179   assume "\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F"
```
```  1180   hence "eventually (\<lambda>x. f x \<le> Z') F" by auto
```
```  1181   thus "eventually (\<lambda>x. f x < Z) F"
```
```  1182     apply (rule eventually_mono)
```
```  1183     using 1 by auto
```
```  1184   next
```
```  1185     fix Z :: 'b
```
```  1186     show "\<forall>Z. eventually (\<lambda>x. f x < Z) F \<Longrightarrow> eventually (\<lambda>x. f x \<le> Z) F"
```
```  1187       by (drule spec [of _ Z], erule eventually_mono, auto simp add: less_imp_le)
```
```  1188 qed
```
```  1189
```
```  1190 lemma filterlim_at_bot_le:
```
```  1191   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
```
```  1192   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F)"
```
```  1193   unfolding filterlim_at_bot
```
```  1194 proof safe
```
```  1195   fix Z assume *: "\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F"
```
```  1196   with *[THEN spec, of "min Z c"] show "eventually (\<lambda>x. Z \<ge> f x) F"
```
```  1197     by (auto elim!: eventually_mono)
```
```  1198 qed simp
```
```  1199
```
```  1200 lemma filterlim_at_bot_lt:
```
```  1201   fixes f :: "'a \<Rightarrow> ('b::unbounded_dense_linorder)" and c :: "'b"
```
```  1202   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z<c. eventually (\<lambda>x. Z \<ge> f x) F)"
```
```  1203   by (metis filterlim_at_bot filterlim_at_bot_le lt_ex order_le_less_trans)
```
```  1204
```
```  1205
```
```  1206 subsection \<open>Setup @{typ "'a filter"} for lifting and transfer\<close>
```
```  1207
```
```  1208 context includes lifting_syntax
```
```  1209 begin
```
```  1210
```
```  1211 definition rel_filter :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> 'b filter \<Rightarrow> bool"
```
```  1212 where "rel_filter R F G = ((R ===> op =) ===> op =) (Rep_filter F) (Rep_filter G)"
```
```  1213
```
```  1214 lemma rel_filter_eventually:
```
```  1215   "rel_filter R F G \<longleftrightarrow>
```
```  1216   ((R ===> op =) ===> op =) (\<lambda>P. eventually P F) (\<lambda>P. eventually P G)"
```
```  1217 by(simp add: rel_filter_def eventually_def)
```
```  1218
```
```  1219 lemma filtermap_id [simp, id_simps]: "filtermap id = id"
```
```  1220 by(simp add: fun_eq_iff id_def filtermap_ident)
```
```  1221
```
```  1222 lemma filtermap_id' [simp]: "filtermap (\<lambda>x. x) = (\<lambda>F. F)"
```
```  1223 using filtermap_id unfolding id_def .
```
```  1224
```
```  1225 lemma Quotient_filter [quot_map]:
```
```  1226   assumes Q: "Quotient R Abs Rep T"
```
```  1227   shows "Quotient (rel_filter R) (filtermap Abs) (filtermap Rep) (rel_filter T)"
```
```  1228 unfolding Quotient_alt_def
```
```  1229 proof(intro conjI strip)
```
```  1230   from Q have *: "\<And>x y. T x y \<Longrightarrow> Abs x = y"
```
```  1231     unfolding Quotient_alt_def by blast
```
```  1232
```
```  1233   fix F G
```
```  1234   assume "rel_filter T F G"
```
```  1235   thus "filtermap Abs F = G" unfolding filter_eq_iff
```
```  1236     by(auto simp add: eventually_filtermap rel_filter_eventually * rel_funI del: iffI elim!: rel_funD)
```
```  1237 next
```
```  1238   from Q have *: "\<And>x. T (Rep x) x" unfolding Quotient_alt_def by blast
```
```  1239
```
```  1240   fix F
```
```  1241   show "rel_filter T (filtermap Rep F) F"
```
```  1242     by(auto elim: rel_funD intro: * intro!: ext arg_cong[where f="\<lambda>P. eventually P F"] rel_funI
```
```  1243             del: iffI simp add: eventually_filtermap rel_filter_eventually)
```
```  1244 qed(auto simp add: map_fun_def o_def eventually_filtermap filter_eq_iff fun_eq_iff rel_filter_eventually
```
```  1245          fun_quotient[OF fun_quotient[OF Q identity_quotient] identity_quotient, unfolded Quotient_alt_def])
```
```  1246
```
```  1247 lemma eventually_parametric [transfer_rule]:
```
```  1248   "((A ===> op =) ===> rel_filter A ===> op =) eventually eventually"
```
```  1249 by(simp add: rel_fun_def rel_filter_eventually)
```
```  1250
```
```  1251 lemma frequently_parametric [transfer_rule]:
```
```  1252   "((A ===> op =) ===> rel_filter A ===> op =) frequently frequently"
```
```  1253   unfolding frequently_def[abs_def] by transfer_prover
```
```  1254
```
```  1255 lemma rel_filter_eq [relator_eq]: "rel_filter op = = op ="
```
```  1256 by(auto simp add: rel_filter_eventually rel_fun_eq fun_eq_iff filter_eq_iff)
```
```  1257
```
```  1258 lemma rel_filter_mono [relator_mono]:
```
```  1259   "A \<le> B \<Longrightarrow> rel_filter A \<le> rel_filter B"
```
```  1260 unfolding rel_filter_eventually[abs_def]
```
```  1261 by(rule le_funI)+(intro fun_mono fun_mono[THEN le_funD, THEN le_funD] order.refl)
```
```  1262
```
```  1263 lemma rel_filter_conversep [simp]: "rel_filter A\<inverse>\<inverse> = (rel_filter A)\<inverse>\<inverse>"
```
```  1264 apply (simp add: rel_filter_eventually fun_eq_iff rel_fun_def)
```
```  1265 apply (safe; metis)
```
```  1266 done
```
```  1267
```
```  1268 lemma is_filter_parametric_aux:
```
```  1269   assumes "is_filter F"
```
```  1270   assumes [transfer_rule]: "bi_total A" "bi_unique A"
```
```  1271   and [transfer_rule]: "((A ===> op =) ===> op =) F G"
```
```  1272   shows "is_filter G"
```
```  1273 proof -
```
```  1274   interpret is_filter F by fact
```
```  1275   show ?thesis
```
```  1276   proof
```
```  1277     have "F (\<lambda>_. True) = G (\<lambda>x. True)" by transfer_prover
```
```  1278     thus "G (\<lambda>x. True)" by(simp add: True)
```
```  1279   next
```
```  1280     fix P' Q'
```
```  1281     assume "G P'" "G Q'"
```
```  1282     moreover
```
```  1283     from bi_total_fun[OF \<open>bi_unique A\<close> bi_total_eq, unfolded bi_total_def]
```
```  1284     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
```
```  1285     have "F P = G P'" "F Q = G Q'" by transfer_prover+
```
```  1286     ultimately have "F (\<lambda>x. P x \<and> Q x)" by(simp add: conj)
```
```  1287     moreover have "F (\<lambda>x. P x \<and> Q x) = G (\<lambda>x. P' x \<and> Q' x)" by transfer_prover
```
```  1288     ultimately show "G (\<lambda>x. P' x \<and> Q' x)" by simp
```
```  1289   next
```
```  1290     fix P' Q'
```
```  1291     assume "\<forall>x. P' x \<longrightarrow> Q' x" "G P'"
```
```  1292     moreover
```
```  1293     from bi_total_fun[OF \<open>bi_unique A\<close> bi_total_eq, unfolded bi_total_def]
```
```  1294     obtain P Q where [transfer_rule]: "(A ===> op =) P P'" "(A ===> op =) Q Q'" by blast
```
```  1295     have "F P = G P'" by transfer_prover
```
```  1296     moreover have "(\<forall>x. P x \<longrightarrow> Q x) \<longleftrightarrow> (\<forall>x. P' x \<longrightarrow> Q' x)" by transfer_prover
```
```  1297     ultimately have "F Q" by(simp add: mono)
```
```  1298     moreover have "F Q = G Q'" by transfer_prover
```
```  1299     ultimately show "G Q'" by simp
```
```  1300   qed
```
```  1301 qed
```
```  1302
```
```  1303 lemma is_filter_parametric [transfer_rule]:
```
```  1304   "\<lbrakk> bi_total A; bi_unique A \<rbrakk>
```
```  1305   \<Longrightarrow> (((A ===> op =) ===> op =) ===> op =) is_filter is_filter"
```
```  1306 apply(rule rel_funI)
```
```  1307 apply(rule iffI)
```
```  1308  apply(erule (3) is_filter_parametric_aux)
```
```  1309 apply(erule is_filter_parametric_aux[where A="conversep A"])
```
```  1310 apply (simp_all add: rel_fun_def)
```
```  1311 apply metis
```
```  1312 done
```
```  1313
```
```  1314 lemma left_total_rel_filter [transfer_rule]:
```
```  1315   assumes [transfer_rule]: "bi_total A" "bi_unique A"
```
```  1316   shows "left_total (rel_filter A)"
```
```  1317 proof(rule left_totalI)
```
```  1318   fix F :: "'a filter"
```
```  1319   from bi_total_fun[OF bi_unique_fun[OF \<open>bi_total A\<close> bi_unique_eq] bi_total_eq]
```
```  1320   obtain G where [transfer_rule]: "((A ===> op =) ===> op =) (\<lambda>P. eventually P F) G"
```
```  1321     unfolding  bi_total_def by blast
```
```  1322   moreover have "is_filter (\<lambda>P. eventually P F) \<longleftrightarrow> is_filter G" by transfer_prover
```
```  1323   hence "is_filter G" by(simp add: eventually_def is_filter_Rep_filter)
```
```  1324   ultimately have "rel_filter A F (Abs_filter G)"
```
```  1325     by(simp add: rel_filter_eventually eventually_Abs_filter)
```
```  1326   thus "\<exists>G. rel_filter A F G" ..
```
```  1327 qed
```
```  1328
```
```  1329 lemma right_total_rel_filter [transfer_rule]:
```
```  1330   "\<lbrakk> bi_total A; bi_unique A \<rbrakk> \<Longrightarrow> right_total (rel_filter A)"
```
```  1331 using left_total_rel_filter[of "A\<inverse>\<inverse>"] by simp
```
```  1332
```
```  1333 lemma bi_total_rel_filter [transfer_rule]:
```
```  1334   assumes "bi_total A" "bi_unique A"
```
```  1335   shows "bi_total (rel_filter A)"
```
```  1336 unfolding bi_total_alt_def using assms
```
```  1337 by(simp add: left_total_rel_filter right_total_rel_filter)
```
```  1338
```
```  1339 lemma left_unique_rel_filter [transfer_rule]:
```
```  1340   assumes "left_unique A"
```
```  1341   shows "left_unique (rel_filter A)"
```
```  1342 proof(rule left_uniqueI)
```
```  1343   fix F F' G
```
```  1344   assume [transfer_rule]: "rel_filter A F G" "rel_filter A F' G"
```
```  1345   show "F = F'"
```
```  1346     unfolding filter_eq_iff
```
```  1347   proof
```
```  1348     fix P :: "'a \<Rightarrow> bool"
```
```  1349     obtain P' where [transfer_rule]: "(A ===> op =) P P'"
```
```  1350       using left_total_fun[OF assms left_total_eq] unfolding left_total_def by blast
```
```  1351     have "eventually P F = eventually P' G"
```
```  1352       and "eventually P F' = eventually P' G" by transfer_prover+
```
```  1353     thus "eventually P F = eventually P F'" by simp
```
```  1354   qed
```
```  1355 qed
```
```  1356
```
```  1357 lemma right_unique_rel_filter [transfer_rule]:
```
```  1358   "right_unique A \<Longrightarrow> right_unique (rel_filter A)"
```
```  1359 using left_unique_rel_filter[of "A\<inverse>\<inverse>"] by simp
```
```  1360
```
```  1361 lemma bi_unique_rel_filter [transfer_rule]:
```
```  1362   "bi_unique A \<Longrightarrow> bi_unique (rel_filter A)"
```
```  1363 by(simp add: bi_unique_alt_def left_unique_rel_filter right_unique_rel_filter)
```
```  1364
```
```  1365 lemma top_filter_parametric [transfer_rule]:
```
```  1366   "bi_total A \<Longrightarrow> (rel_filter A) top top"
```
```  1367 by(simp add: rel_filter_eventually All_transfer)
```
```  1368
```
```  1369 lemma bot_filter_parametric [transfer_rule]: "(rel_filter A) bot bot"
```
```  1370 by(simp add: rel_filter_eventually rel_fun_def)
```
```  1371
```
```  1372 lemma sup_filter_parametric [transfer_rule]:
```
```  1373   "(rel_filter A ===> rel_filter A ===> rel_filter A) sup sup"
```
```  1374 by(fastforce simp add: rel_filter_eventually[abs_def] eventually_sup dest: rel_funD)
```
```  1375
```
```  1376 lemma Sup_filter_parametric [transfer_rule]:
```
```  1377   "(rel_set (rel_filter A) ===> rel_filter A) Sup Sup"
```
```  1378 proof(rule rel_funI)
```
```  1379   fix S T
```
```  1380   assume [transfer_rule]: "rel_set (rel_filter A) S T"
```
```  1381   show "rel_filter A (Sup S) (Sup T)"
```
```  1382     by(simp add: rel_filter_eventually eventually_Sup) transfer_prover
```
```  1383 qed
```
```  1384
```
```  1385 lemma principal_parametric [transfer_rule]:
```
```  1386   "(rel_set A ===> rel_filter A) principal principal"
```
```  1387 proof(rule rel_funI)
```
```  1388   fix S S'
```
```  1389   assume [transfer_rule]: "rel_set A S S'"
```
```  1390   show "rel_filter A (principal S) (principal S')"
```
```  1391     by(simp add: rel_filter_eventually eventually_principal) transfer_prover
```
```  1392 qed
```
```  1393
```
```  1394 context
```
```  1395   fixes A :: "'a \<Rightarrow> 'b \<Rightarrow> bool"
```
```  1396   assumes [transfer_rule]: "bi_unique A"
```
```  1397 begin
```
```  1398
```
```  1399 lemma le_filter_parametric [transfer_rule]:
```
```  1400   "(rel_filter A ===> rel_filter A ===> op =) op \<le> op \<le>"
```
```  1401 unfolding le_filter_def[abs_def] by transfer_prover
```
```  1402
```
```  1403 lemma less_filter_parametric [transfer_rule]:
```
```  1404   "(rel_filter A ===> rel_filter A ===> op =) op < op <"
```
```  1405 unfolding less_filter_def[abs_def] by transfer_prover
```
```  1406
```
```  1407 context
```
```  1408   assumes [transfer_rule]: "bi_total A"
```
```  1409 begin
```
```  1410
```
```  1411 lemma Inf_filter_parametric [transfer_rule]:
```
```  1412   "(rel_set (rel_filter A) ===> rel_filter A) Inf Inf"
```
```  1413 unfolding Inf_filter_def[abs_def] by transfer_prover
```
```  1414
```
```  1415 lemma inf_filter_parametric [transfer_rule]:
```
```  1416   "(rel_filter A ===> rel_filter A ===> rel_filter A) inf inf"
```
```  1417 proof(intro rel_funI)+
```
```  1418   fix F F' G G'
```
```  1419   assume [transfer_rule]: "rel_filter A F F'" "rel_filter A G G'"
```
```  1420   have "rel_filter A (Inf {F, G}) (Inf {F', G'})" by transfer_prover
```
```  1421   thus "rel_filter A (inf F G) (inf F' G')" by simp
```
```  1422 qed
```
```  1423
```
```  1424 end
```
```  1425
```
```  1426 end
```
```  1427
```
```  1428 end
```
```  1429
```
```  1430 text \<open>Code generation for filters\<close>
```
```  1431
```
```  1432 definition abstract_filter :: "(unit \<Rightarrow> 'a filter) \<Rightarrow> 'a filter"
```
```  1433   where [simp]: "abstract_filter f = f ()"
```
```  1434
```
```  1435 code_datatype principal abstract_filter
```
```  1436
```
```  1437 hide_const (open) abstract_filter
```
```  1438
```
```  1439 declare [[code drop: filterlim prod_filter filtermap eventually
```
```  1440   "inf :: _ filter \<Rightarrow> _" "sup :: _ filter \<Rightarrow> _" "less_eq :: _ filter \<Rightarrow> _"
```
```  1441   Abs_filter]]
```
```  1442
```
```  1443 declare filterlim_principal [code]
```
```  1444 declare principal_prod_principal [code]
```
```  1445 declare filtermap_principal [code]
```
```  1446 declare eventually_principal [code]
```
```  1447 declare inf_principal [code]
```
```  1448 declare sup_principal [code]
```
```  1449 declare principal_le_iff [code]
```
```  1450
```
```  1451 lemma Rep_filter_iff_eventually [simp, code]:
```
```  1452   "Rep_filter F P \<longleftrightarrow> eventually P F"
```
```  1453   by (simp add: eventually_def)
```
```  1454
```
```  1455 lemma bot_eq_principal_empty [code]:
```
```  1456   "bot = principal {}"
```
```  1457   by simp
```
```  1458
```
```  1459 lemma top_eq_principal_UNIV [code]:
```
```  1460   "top = principal UNIV"
```
```  1461   by simp
```
```  1462
```
```  1463 instantiation filter :: (equal) equal
```
```  1464 begin
```
```  1465
```
```  1466 definition equal_filter :: "'a filter \<Rightarrow> 'a filter \<Rightarrow> bool"
```
```  1467   where "equal_filter F F' \<longleftrightarrow> F = F'"
```
```  1468
```
```  1469 lemma equal_filter [code]:
```
```  1470   "HOL.equal (principal A) (principal B) \<longleftrightarrow> A = B"
```
```  1471   by (simp add: equal_filter_def)
```
```  1472
```
```  1473 instance
```
```  1474   by standard (simp add: equal_filter_def)
```
```  1475
```
```  1476 end
```
```  1477
```
```  1478 end
```