src/HOL/Orderings.thy
author wenzelm
Sun Sep 18 20:33:48 2016 +0200 (2016-09-18)
changeset 63915 bab633745c7f
parent 63819 58f74e90b96d
child 64287 d85d88722745
permissions -rw-r--r--
tuned proofs;
     1 (*  Title:      HOL/Orderings.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 section \<open>Abstract orderings\<close>
     6 
     7 theory Orderings
     8 imports HOL
     9 keywords "print_orders" :: diag
    10 begin
    11 
    12 ML_file "~~/src/Provers/order.ML"
    13 ML_file "~~/src/Provers/quasi.ML"  (* FIXME unused? *)
    14 
    15 subsection \<open>Abstract ordering\<close>
    16 
    17 locale ordering =
    18   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infix "\<^bold>\<le>" 50)
    19    and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool" (infix "\<^bold><" 50)
    20   assumes strict_iff_order: "a \<^bold>< b \<longleftrightarrow> a \<^bold>\<le> b \<and> a \<noteq> b"
    21   assumes refl: "a \<^bold>\<le> a" \<comment> \<open>not \<open>iff\<close>: makes problems due to multiple (dual) interpretations\<close>
    22     and antisym: "a \<^bold>\<le> b \<Longrightarrow> b \<^bold>\<le> a \<Longrightarrow> a = b"
    23     and trans: "a \<^bold>\<le> b \<Longrightarrow> b \<^bold>\<le> c \<Longrightarrow> a \<^bold>\<le> c"
    24 begin
    25 
    26 lemma strict_implies_order:
    27   "a \<^bold>< b \<Longrightarrow> a \<^bold>\<le> b"
    28   by (simp add: strict_iff_order)
    29 
    30 lemma strict_implies_not_eq:
    31   "a \<^bold>< b \<Longrightarrow> a \<noteq> b"
    32   by (simp add: strict_iff_order)
    33 
    34 lemma not_eq_order_implies_strict:
    35   "a \<noteq> b \<Longrightarrow> a \<^bold>\<le> b \<Longrightarrow> a \<^bold>< b"
    36   by (simp add: strict_iff_order)
    37 
    38 lemma order_iff_strict:
    39   "a \<^bold>\<le> b \<longleftrightarrow> a \<^bold>< b \<or> a = b"
    40   by (auto simp add: strict_iff_order refl)
    41 
    42 lemma irrefl: \<comment> \<open>not \<open>iff\<close>: makes problems due to multiple (dual) interpretations\<close>
    43   "\<not> a \<^bold>< a"
    44   by (simp add: strict_iff_order)
    45 
    46 lemma asym:
    47   "a \<^bold>< b \<Longrightarrow> b \<^bold>< a \<Longrightarrow> False"
    48   by (auto simp add: strict_iff_order intro: antisym)
    49 
    50 lemma strict_trans1:
    51   "a \<^bold>\<le> b \<Longrightarrow> b \<^bold>< c \<Longrightarrow> a \<^bold>< c"
    52   by (auto simp add: strict_iff_order intro: trans antisym)
    53 
    54 lemma strict_trans2:
    55   "a \<^bold>< b \<Longrightarrow> b \<^bold>\<le> c \<Longrightarrow> a \<^bold>< c"
    56   by (auto simp add: strict_iff_order intro: trans antisym)
    57 
    58 lemma strict_trans:
    59   "a \<^bold>< b \<Longrightarrow> b \<^bold>< c \<Longrightarrow> a \<^bold>< c"
    60   by (auto intro: strict_trans1 strict_implies_order)
    61 
    62 end
    63 
    64 text \<open>Alternative introduction rule with bias towards strict order\<close>
    65 
    66 lemma ordering_strictI:
    67   fixes less_eq (infix "\<^bold>\<le>" 50)
    68     and less (infix "\<^bold><" 50)
    69   assumes less_eq_less: "\<And>a b. a \<^bold>\<le> b \<longleftrightarrow> a \<^bold>< b \<or> a = b"
    70     assumes asym: "\<And>a b. a \<^bold>< b \<Longrightarrow> \<not> b \<^bold>< a"
    71   assumes irrefl: "\<And>a. \<not> a \<^bold>< a"
    72   assumes trans: "\<And>a b c. a \<^bold>< b \<Longrightarrow> b \<^bold>< c \<Longrightarrow> a \<^bold>< c"
    73   shows "ordering less_eq less"
    74 proof
    75   fix a b
    76   show "a \<^bold>< b \<longleftrightarrow> a \<^bold>\<le> b \<and> a \<noteq> b"
    77     by (auto simp add: less_eq_less asym irrefl)
    78 next
    79   fix a
    80   show "a \<^bold>\<le> a"
    81     by (auto simp add: less_eq_less)
    82 next
    83   fix a b c
    84   assume "a \<^bold>\<le> b" and "b \<^bold>\<le> c" then show "a \<^bold>\<le> c"
    85     by (auto simp add: less_eq_less intro: trans)
    86 next
    87   fix a b
    88   assume "a \<^bold>\<le> b" and "b \<^bold>\<le> a" then show "a = b"
    89     by (auto simp add: less_eq_less asym)
    90 qed
    91 
    92 lemma ordering_dualI:
    93   fixes less_eq (infix "\<^bold>\<le>" 50)
    94     and less (infix "\<^bold><" 50)
    95   assumes "ordering (\<lambda>a b. b \<^bold>\<le> a) (\<lambda>a b. b \<^bold>< a)"
    96   shows "ordering less_eq less"
    97 proof -
    98   from assms interpret ordering "\<lambda>a b. b \<^bold>\<le> a" "\<lambda>a b. b \<^bold>< a" .
    99   show ?thesis
   100     by standard (auto simp: strict_iff_order refl intro: antisym trans)
   101 qed
   102 
   103 locale ordering_top = ordering +
   104   fixes top :: "'a"  ("\<^bold>\<top>")
   105   assumes extremum [simp]: "a \<^bold>\<le> \<^bold>\<top>"
   106 begin
   107 
   108 lemma extremum_uniqueI:
   109   "\<^bold>\<top> \<^bold>\<le> a \<Longrightarrow> a = \<^bold>\<top>"
   110   by (rule antisym) auto
   111 
   112 lemma extremum_unique:
   113   "\<^bold>\<top> \<^bold>\<le> a \<longleftrightarrow> a = \<^bold>\<top>"
   114   by (auto intro: antisym)
   115 
   116 lemma extremum_strict [simp]:
   117   "\<not> (\<^bold>\<top> \<^bold>< a)"
   118   using extremum [of a] by (auto simp add: order_iff_strict intro: asym irrefl)
   119 
   120 lemma not_eq_extremum:
   121   "a \<noteq> \<^bold>\<top> \<longleftrightarrow> a \<^bold>< \<^bold>\<top>"
   122   by (auto simp add: order_iff_strict intro: not_eq_order_implies_strict extremum)
   123 
   124 end
   125 
   126 
   127 subsection \<open>Syntactic orders\<close>
   128 
   129 class ord =
   130   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   131     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
   132 begin
   133 
   134 notation
   135   less_eq  ("op \<le>") and
   136   less_eq  ("(_/ \<le> _)"  [51, 51] 50) and
   137   less  ("op <") and
   138   less  ("(_/ < _)"  [51, 51] 50)
   139 
   140 abbreviation (input)
   141   greater_eq  (infix "\<ge>" 50)
   142   where "x \<ge> y \<equiv> y \<le> x"
   143 
   144 abbreviation (input)
   145   greater  (infix ">" 50)
   146   where "x > y \<equiv> y < x"
   147 
   148 notation (ASCII)
   149   less_eq  ("op <=") and
   150   less_eq  ("(_/ <= _)" [51, 51] 50)
   151 
   152 notation (input)
   153   greater_eq  (infix ">=" 50)
   154 
   155 end
   156 
   157 
   158 subsection \<open>Quasi orders\<close>
   159 
   160 class preorder = ord +
   161   assumes less_le_not_le: "x < y \<longleftrightarrow> x \<le> y \<and> \<not> (y \<le> x)"
   162   and order_refl [iff]: "x \<le> x"
   163   and order_trans: "x \<le> y \<Longrightarrow> y \<le> z \<Longrightarrow> x \<le> z"
   164 begin
   165 
   166 text \<open>Reflexivity.\<close>
   167 
   168 lemma eq_refl: "x = y \<Longrightarrow> x \<le> y"
   169     \<comment> \<open>This form is useful with the classical reasoner.\<close>
   170 by (erule ssubst) (rule order_refl)
   171 
   172 lemma less_irrefl [iff]: "\<not> x < x"
   173 by (simp add: less_le_not_le)
   174 
   175 lemma less_imp_le: "x < y \<Longrightarrow> x \<le> y"
   176 by (simp add: less_le_not_le)
   177 
   178 
   179 text \<open>Asymmetry.\<close>
   180 
   181 lemma less_not_sym: "x < y \<Longrightarrow> \<not> (y < x)"
   182 by (simp add: less_le_not_le)
   183 
   184 lemma less_asym: "x < y \<Longrightarrow> (\<not> P \<Longrightarrow> y < x) \<Longrightarrow> P"
   185 by (drule less_not_sym, erule contrapos_np) simp
   186 
   187 
   188 text \<open>Transitivity.\<close>
   189 
   190 lemma less_trans: "x < y \<Longrightarrow> y < z \<Longrightarrow> x < z"
   191 by (auto simp add: less_le_not_le intro: order_trans)
   192 
   193 lemma le_less_trans: "x \<le> y \<Longrightarrow> y < z \<Longrightarrow> x < z"
   194 by (auto simp add: less_le_not_le intro: order_trans)
   195 
   196 lemma less_le_trans: "x < y \<Longrightarrow> y \<le> z \<Longrightarrow> x < z"
   197 by (auto simp add: less_le_not_le intro: order_trans)
   198 
   199 
   200 text \<open>Useful for simplification, but too risky to include by default.\<close>
   201 
   202 lemma less_imp_not_less: "x < y \<Longrightarrow> (\<not> y < x) \<longleftrightarrow> True"
   203 by (blast elim: less_asym)
   204 
   205 lemma less_imp_triv: "x < y \<Longrightarrow> (y < x \<longrightarrow> P) \<longleftrightarrow> True"
   206 by (blast elim: less_asym)
   207 
   208 
   209 text \<open>Transitivity rules for calculational reasoning\<close>
   210 
   211 lemma less_asym': "a < b \<Longrightarrow> b < a \<Longrightarrow> P"
   212 by (rule less_asym)
   213 
   214 
   215 text \<open>Dual order\<close>
   216 
   217 lemma dual_preorder:
   218   "class.preorder (op \<ge>) (op >)"
   219   by standard (auto simp add: less_le_not_le intro: order_trans)
   220 
   221 end
   222 
   223 
   224 subsection \<open>Partial orders\<close>
   225 
   226 class order = preorder +
   227   assumes antisym: "x \<le> y \<Longrightarrow> y \<le> x \<Longrightarrow> x = y"
   228 begin
   229 
   230 lemma less_le: "x < y \<longleftrightarrow> x \<le> y \<and> x \<noteq> y"
   231   by (auto simp add: less_le_not_le intro: antisym)
   232 
   233 sublocale order: ordering less_eq less + dual_order: ordering greater_eq greater
   234 proof -
   235   interpret ordering less_eq less
   236     by standard (auto intro: antisym order_trans simp add: less_le)
   237   show "ordering less_eq less"
   238     by (fact ordering_axioms)
   239   then show "ordering greater_eq greater"
   240     by (rule ordering_dualI)
   241 qed
   242 
   243 text \<open>Reflexivity.\<close>
   244 
   245 lemma le_less: "x \<le> y \<longleftrightarrow> x < y \<or> x = y"
   246     \<comment> \<open>NOT suitable for iff, since it can cause PROOF FAILED.\<close>
   247 by (fact order.order_iff_strict)
   248 
   249 lemma le_imp_less_or_eq: "x \<le> y \<Longrightarrow> x < y \<or> x = y"
   250 by (simp add: less_le)
   251 
   252 
   253 text \<open>Useful for simplification, but too risky to include by default.\<close>
   254 
   255 lemma less_imp_not_eq: "x < y \<Longrightarrow> (x = y) \<longleftrightarrow> False"
   256 by auto
   257 
   258 lemma less_imp_not_eq2: "x < y \<Longrightarrow> (y = x) \<longleftrightarrow> False"
   259 by auto
   260 
   261 
   262 text \<open>Transitivity rules for calculational reasoning\<close>
   263 
   264 lemma neq_le_trans: "a \<noteq> b \<Longrightarrow> a \<le> b \<Longrightarrow> a < b"
   265 by (fact order.not_eq_order_implies_strict)
   266 
   267 lemma le_neq_trans: "a \<le> b \<Longrightarrow> a \<noteq> b \<Longrightarrow> a < b"
   268 by (rule order.not_eq_order_implies_strict)
   269 
   270 
   271 text \<open>Asymmetry.\<close>
   272 
   273 lemma eq_iff: "x = y \<longleftrightarrow> x \<le> y \<and> y \<le> x"
   274 by (blast intro: antisym)
   275 
   276 lemma antisym_conv: "y \<le> x \<Longrightarrow> x \<le> y \<longleftrightarrow> x = y"
   277 by (blast intro: antisym)
   278 
   279 lemma less_imp_neq: "x < y \<Longrightarrow> x \<noteq> y"
   280 by (fact order.strict_implies_not_eq)
   281 
   282 
   283 text \<open>Least value operator\<close>
   284 
   285 definition (in ord)
   286   Least :: "('a \<Rightarrow> bool) \<Rightarrow> 'a" (binder "LEAST " 10) where
   287   "Least P = (THE x. P x \<and> (\<forall>y. P y \<longrightarrow> x \<le> y))"
   288 
   289 lemma Least_equality:
   290   assumes "P x"
   291     and "\<And>y. P y \<Longrightarrow> x \<le> y"
   292   shows "Least P = x"
   293 unfolding Least_def by (rule the_equality)
   294   (blast intro: assms antisym)+
   295 
   296 lemma LeastI2_order:
   297   assumes "P x"
   298     and "\<And>y. P y \<Longrightarrow> x \<le> y"
   299     and "\<And>x. P x \<Longrightarrow> \<forall>y. P y \<longrightarrow> x \<le> y \<Longrightarrow> Q x"
   300   shows "Q (Least P)"
   301 unfolding Least_def by (rule theI2)
   302   (blast intro: assms antisym)+
   303 
   304 end
   305 
   306 lemma ordering_orderI:
   307   fixes less_eq (infix "\<^bold>\<le>" 50)
   308     and less (infix "\<^bold><" 50)
   309   assumes "ordering less_eq less"
   310   shows "class.order less_eq less"
   311 proof -
   312   from assms interpret ordering less_eq less .
   313   show ?thesis
   314     by standard (auto intro: antisym trans simp add: refl strict_iff_order)
   315 qed
   316 
   317 lemma order_strictI:
   318   fixes less (infix "\<sqsubset>" 50)
   319     and less_eq (infix "\<sqsubseteq>" 50)
   320   assumes "\<And>a b. a \<sqsubseteq> b \<longleftrightarrow> a \<sqsubset> b \<or> a = b"
   321     assumes "\<And>a b. a \<sqsubset> b \<Longrightarrow> \<not> b \<sqsubset> a"
   322   assumes "\<And>a. \<not> a \<sqsubset> a"
   323   assumes "\<And>a b c. a \<sqsubset> b \<Longrightarrow> b \<sqsubset> c \<Longrightarrow> a \<sqsubset> c"
   324   shows "class.order less_eq less"
   325   by (rule ordering_orderI) (rule ordering_strictI, (fact assms)+)
   326 
   327 context order
   328 begin
   329 
   330 text \<open>Dual order\<close>
   331 
   332 lemma dual_order:
   333   "class.order (op \<ge>) (op >)"
   334   using dual_order.ordering_axioms by (rule ordering_orderI)
   335 
   336 end
   337 
   338 
   339 subsection \<open>Linear (total) orders\<close>
   340 
   341 class linorder = order +
   342   assumes linear: "x \<le> y \<or> y \<le> x"
   343 begin
   344 
   345 lemma less_linear: "x < y \<or> x = y \<or> y < x"
   346 unfolding less_le using less_le linear by blast
   347 
   348 lemma le_less_linear: "x \<le> y \<or> y < x"
   349 by (simp add: le_less less_linear)
   350 
   351 lemma le_cases [case_names le ge]:
   352   "(x \<le> y \<Longrightarrow> P) \<Longrightarrow> (y \<le> x \<Longrightarrow> P) \<Longrightarrow> P"
   353 using linear by blast
   354 
   355 lemma (in linorder) le_cases3:
   356   "\<lbrakk>\<lbrakk>x \<le> y; y \<le> z\<rbrakk> \<Longrightarrow> P; \<lbrakk>y \<le> x; x \<le> z\<rbrakk> \<Longrightarrow> P; \<lbrakk>x \<le> z; z \<le> y\<rbrakk> \<Longrightarrow> P;
   357     \<lbrakk>z \<le> y; y \<le> x\<rbrakk> \<Longrightarrow> P; \<lbrakk>y \<le> z; z \<le> x\<rbrakk> \<Longrightarrow> P; \<lbrakk>z \<le> x; x \<le> y\<rbrakk> \<Longrightarrow> P\<rbrakk> \<Longrightarrow> P"
   358 by (blast intro: le_cases)
   359 
   360 lemma linorder_cases [case_names less equal greater]:
   361   "(x < y \<Longrightarrow> P) \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> (y < x \<Longrightarrow> P) \<Longrightarrow> P"
   362 using less_linear by blast
   363 
   364 lemma linorder_wlog[case_names le sym]:
   365   "(\<And>a b. a \<le> b \<Longrightarrow> P a b) \<Longrightarrow> (\<And>a b. P b a \<Longrightarrow> P a b) \<Longrightarrow> P a b"
   366   by (cases rule: le_cases[of a b]) blast+
   367 
   368 lemma not_less: "\<not> x < y \<longleftrightarrow> y \<le> x"
   369 apply (simp add: less_le)
   370 using linear apply (blast intro: antisym)
   371 done
   372 
   373 lemma not_less_iff_gr_or_eq:
   374  "\<not>(x < y) \<longleftrightarrow> (x > y | x = y)"
   375 apply(simp add:not_less le_less)
   376 apply blast
   377 done
   378 
   379 lemma not_le: "\<not> x \<le> y \<longleftrightarrow> y < x"
   380 apply (simp add: less_le)
   381 using linear apply (blast intro: antisym)
   382 done
   383 
   384 lemma neq_iff: "x \<noteq> y \<longleftrightarrow> x < y \<or> y < x"
   385 by (cut_tac x = x and y = y in less_linear, auto)
   386 
   387 lemma neqE: "x \<noteq> y \<Longrightarrow> (x < y \<Longrightarrow> R) \<Longrightarrow> (y < x \<Longrightarrow> R) \<Longrightarrow> R"
   388 by (simp add: neq_iff) blast
   389 
   390 lemma antisym_conv1: "\<not> x < y \<Longrightarrow> x \<le> y \<longleftrightarrow> x = y"
   391 by (blast intro: antisym dest: not_less [THEN iffD1])
   392 
   393 lemma antisym_conv2: "x \<le> y \<Longrightarrow> \<not> x < y \<longleftrightarrow> x = y"
   394 by (blast intro: antisym dest: not_less [THEN iffD1])
   395 
   396 lemma antisym_conv3: "\<not> y < x \<Longrightarrow> \<not> x < y \<longleftrightarrow> x = y"
   397 by (blast intro: antisym dest: not_less [THEN iffD1])
   398 
   399 lemma leI: "\<not> x < y \<Longrightarrow> y \<le> x"
   400 unfolding not_less .
   401 
   402 lemma leD: "y \<le> x \<Longrightarrow> \<not> x < y"
   403 unfolding not_less .
   404 
   405 lemma not_le_imp_less: "\<not> y \<le> x \<Longrightarrow> x < y"
   406 unfolding not_le .
   407 
   408 text \<open>Dual order\<close>
   409 
   410 lemma dual_linorder:
   411   "class.linorder (op \<ge>) (op >)"
   412 by (rule class.linorder.intro, rule dual_order) (unfold_locales, rule linear)
   413 
   414 end
   415 
   416 
   417 text \<open>Alternative introduction rule with bias towards strict order\<close>
   418 
   419 lemma linorder_strictI:
   420   fixes less_eq (infix "\<^bold>\<le>" 50)
   421     and less (infix "\<^bold><" 50)
   422   assumes "class.order less_eq less"
   423   assumes trichotomy: "\<And>a b. a \<^bold>< b \<or> a = b \<or> b \<^bold>< a"
   424   shows "class.linorder less_eq less"
   425 proof -
   426   interpret order less_eq less
   427     by (fact \<open>class.order less_eq less\<close>)
   428   show ?thesis
   429   proof
   430     fix a b
   431     show "a \<^bold>\<le> b \<or> b \<^bold>\<le> a"
   432       using trichotomy by (auto simp add: le_less)
   433   qed
   434 qed
   435 
   436 
   437 subsection \<open>Reasoning tools setup\<close>
   438 
   439 ML \<open>
   440 signature ORDERS =
   441 sig
   442   val print_structures: Proof.context -> unit
   443   val order_tac: Proof.context -> thm list -> int -> tactic
   444   val add_struct: string * term list -> string -> attribute
   445   val del_struct: string * term list -> attribute
   446 end;
   447 
   448 structure Orders: ORDERS =
   449 struct
   450 
   451 (* context data *)
   452 
   453 fun struct_eq ((s1: string, ts1), (s2, ts2)) =
   454   s1 = s2 andalso eq_list (op aconv) (ts1, ts2);
   455 
   456 structure Data = Generic_Data
   457 (
   458   type T = ((string * term list) * Order_Tac.less_arith) list;
   459     (* Order structures:
   460        identifier of the structure, list of operations and record of theorems
   461        needed to set up the transitivity reasoner,
   462        identifier and operations identify the structure uniquely. *)
   463   val empty = [];
   464   val extend = I;
   465   fun merge data = AList.join struct_eq (K fst) data;
   466 );
   467 
   468 fun print_structures ctxt =
   469   let
   470     val structs = Data.get (Context.Proof ctxt);
   471     fun pretty_term t = Pretty.block
   472       [Pretty.quote (Syntax.pretty_term ctxt t), Pretty.brk 1,
   473         Pretty.str "::", Pretty.brk 1,
   474         Pretty.quote (Syntax.pretty_typ ctxt (type_of t))];
   475     fun pretty_struct ((s, ts), _) = Pretty.block
   476       [Pretty.str s, Pretty.str ":", Pretty.brk 1,
   477        Pretty.enclose "(" ")" (Pretty.breaks (map pretty_term ts))];
   478   in
   479     Pretty.writeln (Pretty.big_list "order structures:" (map pretty_struct structs))
   480   end;
   481 
   482 val _ =
   483   Outer_Syntax.command @{command_keyword print_orders}
   484     "print order structures available to transitivity reasoner"
   485     (Scan.succeed (Toplevel.keep (print_structures o Toplevel.context_of)));
   486 
   487 
   488 (* tactics *)
   489 
   490 fun struct_tac ((s, ops), thms) ctxt facts =
   491   let
   492     val [eq, le, less] = ops;
   493     fun decomp thy (@{const Trueprop} $ t) =
   494           let
   495             fun excluded t =
   496               (* exclude numeric types: linear arithmetic subsumes transitivity *)
   497               let val T = type_of t
   498               in
   499                 T = HOLogic.natT orelse T = HOLogic.intT orelse T = HOLogic.realT
   500               end;
   501             fun rel (bin_op $ t1 $ t2) =
   502                   if excluded t1 then NONE
   503                   else if Pattern.matches thy (eq, bin_op) then SOME (t1, "=", t2)
   504                   else if Pattern.matches thy (le, bin_op) then SOME (t1, "<=", t2)
   505                   else if Pattern.matches thy (less, bin_op) then SOME (t1, "<", t2)
   506                   else NONE
   507               | rel _ = NONE;
   508             fun dec (Const (@{const_name Not}, _) $ t) =
   509                   (case rel t of NONE =>
   510                     NONE
   511                   | SOME (t1, rel, t2) => SOME (t1, "~" ^ rel, t2))
   512               | dec x = rel x;
   513           in dec t end
   514       | decomp _ _ = NONE;
   515   in
   516     (case s of
   517       "order" => Order_Tac.partial_tac decomp thms ctxt facts
   518     | "linorder" => Order_Tac.linear_tac decomp thms ctxt facts
   519     | _ => error ("Unknown order kind " ^ quote s ^ " encountered in transitivity reasoner"))
   520   end
   521 
   522 fun order_tac ctxt facts =
   523   FIRST' (map (fn s => CHANGED o struct_tac s ctxt facts) (Data.get (Context.Proof ctxt)));
   524 
   525 
   526 (* attributes *)
   527 
   528 fun add_struct s tag =
   529   Thm.declaration_attribute
   530     (fn thm => Data.map (AList.map_default struct_eq (s, Order_Tac.empty TrueI) (Order_Tac.update tag thm)));
   531 fun del_struct s =
   532   Thm.declaration_attribute
   533     (fn _ => Data.map (AList.delete struct_eq s));
   534 
   535 end;
   536 \<close>
   537 
   538 attribute_setup order = \<open>
   539   Scan.lift ((Args.add -- Args.name >> (fn (_, s) => SOME s) || Args.del >> K NONE) --|
   540     Args.colon (* FIXME || Scan.succeed true *) ) -- Scan.lift Args.name --
   541     Scan.repeat Args.term
   542     >> (fn ((SOME tag, n), ts) => Orders.add_struct (n, ts) tag
   543          | ((NONE, n), ts) => Orders.del_struct (n, ts))
   544 \<close> "theorems controlling transitivity reasoner"
   545 
   546 method_setup order = \<open>
   547   Scan.succeed (fn ctxt => SIMPLE_METHOD' (Orders.order_tac ctxt []))
   548 \<close> "transitivity reasoner"
   549 
   550 
   551 text \<open>Declarations to set up transitivity reasoner of partial and linear orders.\<close>
   552 
   553 context order
   554 begin
   555 
   556 (* The type constraint on @{term op =} below is necessary since the operation
   557    is not a parameter of the locale. *)
   558 
   559 declare less_irrefl [THEN notE, order add less_reflE: order "op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool" "op <=" "op <"]
   560 
   561 declare order_refl  [order add le_refl: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   562 
   563 declare less_imp_le [order add less_imp_le: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   564 
   565 declare antisym [order add eqI: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   566 
   567 declare eq_refl [order add eqD1: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   568 
   569 declare sym [THEN eq_refl, order add eqD2: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   570 
   571 declare less_trans [order add less_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   572 
   573 declare less_le_trans [order add less_le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   574 
   575 declare le_less_trans [order add le_less_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   576 
   577 declare order_trans [order add le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   578 
   579 declare le_neq_trans [order add le_neq_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   580 
   581 declare neq_le_trans [order add neq_le_trans: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   582 
   583 declare less_imp_neq [order add less_imp_neq: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   584 
   585 declare eq_neq_eq_imp_neq [order add eq_neq_eq_imp_neq: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   586 
   587 declare not_sym [order add not_sym: order "op = :: 'a => 'a => bool" "op <=" "op <"]
   588 
   589 end
   590 
   591 context linorder
   592 begin
   593 
   594 declare [[order del: order "op = :: 'a => 'a => bool" "op <=" "op <"]]
   595 
   596 declare less_irrefl [THEN notE, order add less_reflE: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   597 
   598 declare order_refl [order add le_refl: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   599 
   600 declare less_imp_le [order add less_imp_le: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   601 
   602 declare not_less [THEN iffD2, order add not_lessI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   603 
   604 declare not_le [THEN iffD2, order add not_leI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   605 
   606 declare not_less [THEN iffD1, order add not_lessD: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   607 
   608 declare not_le [THEN iffD1, order add not_leD: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   609 
   610 declare antisym [order add eqI: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   611 
   612 declare eq_refl [order add eqD1: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   613 
   614 declare sym [THEN eq_refl, order add eqD2: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   615 
   616 declare less_trans [order add less_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   617 
   618 declare less_le_trans [order add less_le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   619 
   620 declare le_less_trans [order add le_less_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   621 
   622 declare order_trans [order add le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   623 
   624 declare le_neq_trans [order add le_neq_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   625 
   626 declare neq_le_trans [order add neq_le_trans: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   627 
   628 declare less_imp_neq [order add less_imp_neq: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   629 
   630 declare eq_neq_eq_imp_neq [order add eq_neq_eq_imp_neq: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   631 
   632 declare not_sym [order add not_sym: linorder "op = :: 'a => 'a => bool" "op <=" "op <"]
   633 
   634 end
   635 
   636 setup \<open>
   637   map_theory_simpset (fn ctxt0 => ctxt0 addSolver
   638     mk_solver "Transitivity" (fn ctxt => Orders.order_tac ctxt (Simplifier.prems_of ctxt)))
   639   (*Adding the transitivity reasoners also as safe solvers showed a slight
   640     speed up, but the reasoning strength appears to be not higher (at least
   641     no breaking of additional proofs in the entire HOL distribution, as
   642     of 5 March 2004, was observed).*)
   643 \<close>
   644 
   645 ML \<open>
   646 local
   647   fun prp t thm = Thm.prop_of thm = t;  (* FIXME proper aconv!? *)
   648 in
   649 
   650 fun antisym_le_simproc ctxt ct =
   651   (case Thm.term_of ct of
   652     (le as Const (_, T)) $ r $ s =>
   653      (let
   654         val prems = Simplifier.prems_of ctxt;
   655         val less = Const (@{const_name less}, T);
   656         val t = HOLogic.mk_Trueprop(le $ s $ r);
   657       in
   658         (case find_first (prp t) prems of
   659           NONE =>
   660             let val t = HOLogic.mk_Trueprop(HOLogic.Not $ (less $ r $ s)) in
   661               (case find_first (prp t) prems of
   662                 NONE => NONE
   663               | SOME thm => SOME(mk_meta_eq(thm RS @{thm linorder_class.antisym_conv1})))
   664              end
   665          | SOME thm => SOME (mk_meta_eq (thm RS @{thm order_class.antisym_conv})))
   666       end handle THM _ => NONE)
   667   | _ => NONE);
   668 
   669 fun antisym_less_simproc ctxt ct =
   670   (case Thm.term_of ct of
   671     NotC $ ((less as Const(_,T)) $ r $ s) =>
   672      (let
   673        val prems = Simplifier.prems_of ctxt;
   674        val le = Const (@{const_name less_eq}, T);
   675        val t = HOLogic.mk_Trueprop(le $ r $ s);
   676       in
   677         (case find_first (prp t) prems of
   678           NONE =>
   679             let val t = HOLogic.mk_Trueprop (NotC $ (less $ s $ r)) in
   680               (case find_first (prp t) prems of
   681                 NONE => NONE
   682               | SOME thm => SOME (mk_meta_eq(thm RS @{thm linorder_class.antisym_conv3})))
   683             end
   684         | SOME thm => SOME (mk_meta_eq (thm RS @{thm linorder_class.antisym_conv2})))
   685       end handle THM _ => NONE)
   686   | _ => NONE);
   687 
   688 end;
   689 \<close>
   690 
   691 simproc_setup antisym_le ("(x::'a::order) \<le> y") = "K antisym_le_simproc"
   692 simproc_setup antisym_less ("\<not> (x::'a::linorder) < y") = "K antisym_less_simproc"
   693 
   694 
   695 subsection \<open>Bounded quantifiers\<close>
   696 
   697 syntax (ASCII)
   698   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3ALL _<_./ _)"  [0, 0, 10] 10)
   699   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3EX _<_./ _)"  [0, 0, 10] 10)
   700   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _<=_./ _)" [0, 0, 10] 10)
   701   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _<=_./ _)" [0, 0, 10] 10)
   702 
   703   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3ALL _>_./ _)"  [0, 0, 10] 10)
   704   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3EX _>_./ _)"  [0, 0, 10] 10)
   705   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3ALL _>=_./ _)" [0, 0, 10] 10)
   706   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3EX _>=_./ _)" [0, 0, 10] 10)
   707 
   708 syntax
   709   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_<_./ _)"  [0, 0, 10] 10)
   710   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_<_./ _)"  [0, 0, 10] 10)
   711   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<le>_./ _)" [0, 0, 10] 10)
   712   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<le>_./ _)" [0, 0, 10] 10)
   713 
   714   "_All_greater" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_>_./ _)"  [0, 0, 10] 10)
   715   "_Ex_greater" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_>_./ _)"  [0, 0, 10] 10)
   716   "_All_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<forall>_\<ge>_./ _)" [0, 0, 10] 10)
   717   "_Ex_greater_eq" :: "[idt, 'a, bool] => bool"    ("(3\<exists>_\<ge>_./ _)" [0, 0, 10] 10)
   718 
   719 syntax (input)
   720   "_All_less" :: "[idt, 'a, bool] => bool"    ("(3! _<_./ _)"  [0, 0, 10] 10)
   721   "_Ex_less" :: "[idt, 'a, bool] => bool"    ("(3? _<_./ _)"  [0, 0, 10] 10)
   722   "_All_less_eq" :: "[idt, 'a, bool] => bool"    ("(3! _<=_./ _)" [0, 0, 10] 10)
   723   "_Ex_less_eq" :: "[idt, 'a, bool] => bool"    ("(3? _<=_./ _)" [0, 0, 10] 10)
   724 
   725 translations
   726   "ALL x<y. P"   =>  "ALL x. x < y \<longrightarrow> P"
   727   "EX x<y. P"    =>  "EX x. x < y \<and> P"
   728   "ALL x<=y. P"  =>  "ALL x. x <= y \<longrightarrow> P"
   729   "EX x<=y. P"   =>  "EX x. x <= y \<and> P"
   730   "ALL x>y. P"   =>  "ALL x. x > y \<longrightarrow> P"
   731   "EX x>y. P"    =>  "EX x. x > y \<and> P"
   732   "ALL x>=y. P"  =>  "ALL x. x >= y \<longrightarrow> P"
   733   "EX x>=y. P"   =>  "EX x. x >= y \<and> P"
   734 
   735 print_translation \<open>
   736 let
   737   val All_binder = Mixfix.binder_name @{const_syntax All};
   738   val Ex_binder = Mixfix.binder_name @{const_syntax Ex};
   739   val impl = @{const_syntax HOL.implies};
   740   val conj = @{const_syntax HOL.conj};
   741   val less = @{const_syntax less};
   742   val less_eq = @{const_syntax less_eq};
   743 
   744   val trans =
   745    [((All_binder, impl, less),
   746     (@{syntax_const "_All_less"}, @{syntax_const "_All_greater"})),
   747     ((All_binder, impl, less_eq),
   748     (@{syntax_const "_All_less_eq"}, @{syntax_const "_All_greater_eq"})),
   749     ((Ex_binder, conj, less),
   750     (@{syntax_const "_Ex_less"}, @{syntax_const "_Ex_greater"})),
   751     ((Ex_binder, conj, less_eq),
   752     (@{syntax_const "_Ex_less_eq"}, @{syntax_const "_Ex_greater_eq"}))];
   753 
   754   fun matches_bound v t =
   755     (case t of
   756       Const (@{syntax_const "_bound"}, _) $ Free (v', _) => v = v'
   757     | _ => false);
   758   fun contains_var v = Term.exists_subterm (fn Free (x, _) => x = v | _ => false);
   759   fun mk x c n P = Syntax.const c $ Syntax_Trans.mark_bound_body x $ n $ P;
   760 
   761   fun tr' q = (q, fn _ =>
   762     (fn [Const (@{syntax_const "_bound"}, _) $ Free (v, T),
   763         Const (c, _) $ (Const (d, _) $ t $ u) $ P] =>
   764         (case AList.lookup (op =) trans (q, c, d) of
   765           NONE => raise Match
   766         | SOME (l, g) =>
   767             if matches_bound v t andalso not (contains_var v u) then mk (v, T) l u P
   768             else if matches_bound v u andalso not (contains_var v t) then mk (v, T) g t P
   769             else raise Match)
   770       | _ => raise Match));
   771 in [tr' All_binder, tr' Ex_binder] end
   772 \<close>
   773 
   774 
   775 subsection \<open>Transitivity reasoning\<close>
   776 
   777 context ord
   778 begin
   779 
   780 lemma ord_le_eq_trans: "a \<le> b \<Longrightarrow> b = c \<Longrightarrow> a \<le> c"
   781   by (rule subst)
   782 
   783 lemma ord_eq_le_trans: "a = b \<Longrightarrow> b \<le> c \<Longrightarrow> a \<le> c"
   784   by (rule ssubst)
   785 
   786 lemma ord_less_eq_trans: "a < b \<Longrightarrow> b = c \<Longrightarrow> a < c"
   787   by (rule subst)
   788 
   789 lemma ord_eq_less_trans: "a = b \<Longrightarrow> b < c \<Longrightarrow> a < c"
   790   by (rule ssubst)
   791 
   792 end
   793 
   794 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
   795   (!!x y. x < y ==> f x < f y) ==> f a < c"
   796 proof -
   797   assume r: "!!x y. x < y ==> f x < f y"
   798   assume "a < b" hence "f a < f b" by (rule r)
   799   also assume "f b < c"
   800   finally (less_trans) show ?thesis .
   801 qed
   802 
   803 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
   804   (!!x y. x < y ==> f x < f y) ==> a < f c"
   805 proof -
   806   assume r: "!!x y. x < y ==> f x < f y"
   807   assume "a < f b"
   808   also assume "b < c" hence "f b < f c" by (rule r)
   809   finally (less_trans) show ?thesis .
   810 qed
   811 
   812 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
   813   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
   814 proof -
   815   assume r: "!!x y. x <= y ==> f x <= f y"
   816   assume "a <= b" hence "f a <= f b" by (rule r)
   817   also assume "f b < c"
   818   finally (le_less_trans) show ?thesis .
   819 qed
   820 
   821 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
   822   (!!x y. x < y ==> f x < f y) ==> a < f c"
   823 proof -
   824   assume r: "!!x y. x < y ==> f x < f y"
   825   assume "a <= f b"
   826   also assume "b < c" hence "f b < f c" by (rule r)
   827   finally (le_less_trans) show ?thesis .
   828 qed
   829 
   830 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
   831   (!!x y. x < y ==> f x < f y) ==> f a < c"
   832 proof -
   833   assume r: "!!x y. x < y ==> f x < f y"
   834   assume "a < b" hence "f a < f b" by (rule r)
   835   also assume "f b <= c"
   836   finally (less_le_trans) show ?thesis .
   837 qed
   838 
   839 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
   840   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
   841 proof -
   842   assume r: "!!x y. x <= y ==> f x <= f y"
   843   assume "a < f b"
   844   also assume "b <= c" hence "f b <= f c" by (rule r)
   845   finally (less_le_trans) show ?thesis .
   846 qed
   847 
   848 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
   849   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   850 proof -
   851   assume r: "!!x y. x <= y ==> f x <= f y"
   852   assume "a <= f b"
   853   also assume "b <= c" hence "f b <= f c" by (rule r)
   854   finally (order_trans) show ?thesis .
   855 qed
   856 
   857 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
   858   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   859 proof -
   860   assume r: "!!x y. x <= y ==> f x <= f y"
   861   assume "a <= b" hence "f a <= f b" by (rule r)
   862   also assume "f b <= c"
   863   finally (order_trans) show ?thesis .
   864 qed
   865 
   866 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
   867   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
   868 proof -
   869   assume r: "!!x y. x <= y ==> f x <= f y"
   870   assume "a <= b" hence "f a <= f b" by (rule r)
   871   also assume "f b = c"
   872   finally (ord_le_eq_trans) show ?thesis .
   873 qed
   874 
   875 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
   876   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
   877 proof -
   878   assume r: "!!x y. x <= y ==> f x <= f y"
   879   assume "a = f b"
   880   also assume "b <= c" hence "f b <= f c" by (rule r)
   881   finally (ord_eq_le_trans) show ?thesis .
   882 qed
   883 
   884 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
   885   (!!x y. x < y ==> f x < f y) ==> f a < c"
   886 proof -
   887   assume r: "!!x y. x < y ==> f x < f y"
   888   assume "a < b" hence "f a < f b" by (rule r)
   889   also assume "f b = c"
   890   finally (ord_less_eq_trans) show ?thesis .
   891 qed
   892 
   893 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
   894   (!!x y. x < y ==> f x < f y) ==> a < f c"
   895 proof -
   896   assume r: "!!x y. x < y ==> f x < f y"
   897   assume "a = f b"
   898   also assume "b < c" hence "f b < f c" by (rule r)
   899   finally (ord_eq_less_trans) show ?thesis .
   900 qed
   901 
   902 text \<open>
   903   Note that this list of rules is in reverse order of priorities.
   904 \<close>
   905 
   906 lemmas [trans] =
   907   order_less_subst2
   908   order_less_subst1
   909   order_le_less_subst2
   910   order_le_less_subst1
   911   order_less_le_subst2
   912   order_less_le_subst1
   913   order_subst2
   914   order_subst1
   915   ord_le_eq_subst
   916   ord_eq_le_subst
   917   ord_less_eq_subst
   918   ord_eq_less_subst
   919   forw_subst
   920   back_subst
   921   rev_mp
   922   mp
   923 
   924 lemmas (in order) [trans] =
   925   neq_le_trans
   926   le_neq_trans
   927 
   928 lemmas (in preorder) [trans] =
   929   less_trans
   930   less_asym'
   931   le_less_trans
   932   less_le_trans
   933   order_trans
   934 
   935 lemmas (in order) [trans] =
   936   antisym
   937 
   938 lemmas (in ord) [trans] =
   939   ord_le_eq_trans
   940   ord_eq_le_trans
   941   ord_less_eq_trans
   942   ord_eq_less_trans
   943 
   944 lemmas [trans] =
   945   trans
   946 
   947 lemmas order_trans_rules =
   948   order_less_subst2
   949   order_less_subst1
   950   order_le_less_subst2
   951   order_le_less_subst1
   952   order_less_le_subst2
   953   order_less_le_subst1
   954   order_subst2
   955   order_subst1
   956   ord_le_eq_subst
   957   ord_eq_le_subst
   958   ord_less_eq_subst
   959   ord_eq_less_subst
   960   forw_subst
   961   back_subst
   962   rev_mp
   963   mp
   964   neq_le_trans
   965   le_neq_trans
   966   less_trans
   967   less_asym'
   968   le_less_trans
   969   less_le_trans
   970   order_trans
   971   antisym
   972   ord_le_eq_trans
   973   ord_eq_le_trans
   974   ord_less_eq_trans
   975   ord_eq_less_trans
   976   trans
   977 
   978 text \<open>These support proving chains of decreasing inequalities
   979     a >= b >= c ... in Isar proofs.\<close>
   980 
   981 lemma xt1 [no_atp]:
   982   "a = b ==> b > c ==> a > c"
   983   "a > b ==> b = c ==> a > c"
   984   "a = b ==> b >= c ==> a >= c"
   985   "a >= b ==> b = c ==> a >= c"
   986   "(x::'a::order) >= y ==> y >= x ==> x = y"
   987   "(x::'a::order) >= y ==> y >= z ==> x >= z"
   988   "(x::'a::order) > y ==> y >= z ==> x > z"
   989   "(x::'a::order) >= y ==> y > z ==> x > z"
   990   "(a::'a::order) > b ==> b > a ==> P"
   991   "(x::'a::order) > y ==> y > z ==> x > z"
   992   "(a::'a::order) >= b ==> a ~= b ==> a > b"
   993   "(a::'a::order) ~= b ==> a >= b ==> a > b"
   994   "a = f b ==> b > c ==> (!!x y. x > y ==> f x > f y) ==> a > f c"
   995   "a > b ==> f b = c ==> (!!x y. x > y ==> f x > f y) ==> f a > c"
   996   "a = f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
   997   "a >= b ==> f b = c ==> (!! x y. x >= y ==> f x >= f y) ==> f a >= c"
   998   by auto
   999 
  1000 lemma xt2 [no_atp]:
  1001   "(a::'a::order) >= f b ==> b >= c ==> (!!x y. x >= y ==> f x >= f y) ==> a >= f c"
  1002 by (subgoal_tac "f b >= f c", force, force)
  1003 
  1004 lemma xt3 [no_atp]: "(a::'a::order) >= b ==> (f b::'b::order) >= c ==>
  1005     (!!x y. x >= y ==> f x >= f y) ==> f a >= c"
  1006 by (subgoal_tac "f a >= f b", force, force)
  1007 
  1008 lemma xt4 [no_atp]: "(a::'a::order) > f b ==> (b::'b::order) >= c ==>
  1009   (!!x y. x >= y ==> f x >= f y) ==> a > f c"
  1010 by (subgoal_tac "f b >= f c", force, force)
  1011 
  1012 lemma xt5 [no_atp]: "(a::'a::order) > b ==> (f b::'b::order) >= c==>
  1013     (!!x y. x > y ==> f x > f y) ==> f a > c"
  1014 by (subgoal_tac "f a > f b", force, force)
  1015 
  1016 lemma xt6 [no_atp]: "(a::'a::order) >= f b ==> b > c ==>
  1017     (!!x y. x > y ==> f x > f y) ==> a > f c"
  1018 by (subgoal_tac "f b > f c", force, force)
  1019 
  1020 lemma xt7 [no_atp]: "(a::'a::order) >= b ==> (f b::'b::order) > c ==>
  1021     (!!x y. x >= y ==> f x >= f y) ==> f a > c"
  1022 by (subgoal_tac "f a >= f b", force, force)
  1023 
  1024 lemma xt8 [no_atp]: "(a::'a::order) > f b ==> (b::'b::order) > c ==>
  1025     (!!x y. x > y ==> f x > f y) ==> a > f c"
  1026 by (subgoal_tac "f b > f c", force, force)
  1027 
  1028 lemma xt9 [no_atp]: "(a::'a::order) > b ==> (f b::'b::order) > c ==>
  1029     (!!x y. x > y ==> f x > f y) ==> f a > c"
  1030 by (subgoal_tac "f a > f b", force, force)
  1031 
  1032 lemmas xtrans = xt1 xt2 xt3 xt4 xt5 xt6 xt7 xt8 xt9
  1033 
  1034 (*
  1035   Since "a >= b" abbreviates "b <= a", the abbreviation "..." stands
  1036   for the wrong thing in an Isar proof.
  1037 
  1038   The extra transitivity rules can be used as follows:
  1039 
  1040 lemma "(a::'a::order) > z"
  1041 proof -
  1042   have "a >= b" (is "_ >= ?rhs")
  1043     sorry
  1044   also have "?rhs >= c" (is "_ >= ?rhs")
  1045     sorry
  1046   also (xtrans) have "?rhs = d" (is "_ = ?rhs")
  1047     sorry
  1048   also (xtrans) have "?rhs >= e" (is "_ >= ?rhs")
  1049     sorry
  1050   also (xtrans) have "?rhs > f" (is "_ > ?rhs")
  1051     sorry
  1052   also (xtrans) have "?rhs > z"
  1053     sorry
  1054   finally (xtrans) show ?thesis .
  1055 qed
  1056 
  1057   Alternatively, one can use "declare xtrans [trans]" and then
  1058   leave out the "(xtrans)" above.
  1059 *)
  1060 
  1061 
  1062 subsection \<open>Monotonicity\<close>
  1063 
  1064 context order
  1065 begin
  1066 
  1067 definition mono :: "('a \<Rightarrow> 'b::order) \<Rightarrow> bool" where
  1068   "mono f \<longleftrightarrow> (\<forall>x y. x \<le> y \<longrightarrow> f x \<le> f y)"
  1069 
  1070 lemma monoI [intro?]:
  1071   fixes f :: "'a \<Rightarrow> 'b::order"
  1072   shows "(\<And>x y. x \<le> y \<Longrightarrow> f x \<le> f y) \<Longrightarrow> mono f"
  1073   unfolding mono_def by iprover
  1074 
  1075 lemma monoD [dest?]:
  1076   fixes f :: "'a \<Rightarrow> 'b::order"
  1077   shows "mono f \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1078   unfolding mono_def by iprover
  1079 
  1080 lemma monoE:
  1081   fixes f :: "'a \<Rightarrow> 'b::order"
  1082   assumes "mono f"
  1083   assumes "x \<le> y"
  1084   obtains "f x \<le> f y"
  1085 proof
  1086   from assms show "f x \<le> f y" by (simp add: mono_def)
  1087 qed
  1088 
  1089 definition antimono :: "('a \<Rightarrow> 'b::order) \<Rightarrow> bool" where
  1090   "antimono f \<longleftrightarrow> (\<forall>x y. x \<le> y \<longrightarrow> f x \<ge> f y)"
  1091 
  1092 lemma antimonoI [intro?]:
  1093   fixes f :: "'a \<Rightarrow> 'b::order"
  1094   shows "(\<And>x y. x \<le> y \<Longrightarrow> f x \<ge> f y) \<Longrightarrow> antimono f"
  1095   unfolding antimono_def by iprover
  1096 
  1097 lemma antimonoD [dest?]:
  1098   fixes f :: "'a \<Rightarrow> 'b::order"
  1099   shows "antimono f \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<ge> f y"
  1100   unfolding antimono_def by iprover
  1101 
  1102 lemma antimonoE:
  1103   fixes f :: "'a \<Rightarrow> 'b::order"
  1104   assumes "antimono f"
  1105   assumes "x \<le> y"
  1106   obtains "f x \<ge> f y"
  1107 proof
  1108   from assms show "f x \<ge> f y" by (simp add: antimono_def)
  1109 qed
  1110 
  1111 definition strict_mono :: "('a \<Rightarrow> 'b::order) \<Rightarrow> bool" where
  1112   "strict_mono f \<longleftrightarrow> (\<forall>x y. x < y \<longrightarrow> f x < f y)"
  1113 
  1114 lemma strict_monoI [intro?]:
  1115   assumes "\<And>x y. x < y \<Longrightarrow> f x < f y"
  1116   shows "strict_mono f"
  1117   using assms unfolding strict_mono_def by auto
  1118 
  1119 lemma strict_monoD [dest?]:
  1120   "strict_mono f \<Longrightarrow> x < y \<Longrightarrow> f x < f y"
  1121   unfolding strict_mono_def by auto
  1122 
  1123 lemma strict_mono_mono [dest?]:
  1124   assumes "strict_mono f"
  1125   shows "mono f"
  1126 proof (rule monoI)
  1127   fix x y
  1128   assume "x \<le> y"
  1129   show "f x \<le> f y"
  1130   proof (cases "x = y")
  1131     case True then show ?thesis by simp
  1132   next
  1133     case False with \<open>x \<le> y\<close> have "x < y" by simp
  1134     with assms strict_monoD have "f x < f y" by auto
  1135     then show ?thesis by simp
  1136   qed
  1137 qed
  1138 
  1139 end
  1140 
  1141 context linorder
  1142 begin
  1143 
  1144 lemma mono_invE:
  1145   fixes f :: "'a \<Rightarrow> 'b::order"
  1146   assumes "mono f"
  1147   assumes "f x < f y"
  1148   obtains "x \<le> y"
  1149 proof
  1150   show "x \<le> y"
  1151   proof (rule ccontr)
  1152     assume "\<not> x \<le> y"
  1153     then have "y \<le> x" by simp
  1154     with \<open>mono f\<close> obtain "f y \<le> f x" by (rule monoE)
  1155     with \<open>f x < f y\<close> show False by simp
  1156   qed
  1157 qed
  1158 
  1159 lemma strict_mono_eq:
  1160   assumes "strict_mono f"
  1161   shows "f x = f y \<longleftrightarrow> x = y"
  1162 proof
  1163   assume "f x = f y"
  1164   show "x = y" proof (cases x y rule: linorder_cases)
  1165     case less with assms strict_monoD have "f x < f y" by auto
  1166     with \<open>f x = f y\<close> show ?thesis by simp
  1167   next
  1168     case equal then show ?thesis .
  1169   next
  1170     case greater with assms strict_monoD have "f y < f x" by auto
  1171     with \<open>f x = f y\<close> show ?thesis by simp
  1172   qed
  1173 qed simp
  1174 
  1175 lemma strict_mono_less_eq:
  1176   assumes "strict_mono f"
  1177   shows "f x \<le> f y \<longleftrightarrow> x \<le> y"
  1178 proof
  1179   assume "x \<le> y"
  1180   with assms strict_mono_mono monoD show "f x \<le> f y" by auto
  1181 next
  1182   assume "f x \<le> f y"
  1183   show "x \<le> y" proof (rule ccontr)
  1184     assume "\<not> x \<le> y" then have "y < x" by simp
  1185     with assms strict_monoD have "f y < f x" by auto
  1186     with \<open>f x \<le> f y\<close> show False by simp
  1187   qed
  1188 qed
  1189 
  1190 lemma strict_mono_less:
  1191   assumes "strict_mono f"
  1192   shows "f x < f y \<longleftrightarrow> x < y"
  1193   using assms
  1194     by (auto simp add: less_le Orderings.less_le strict_mono_eq strict_mono_less_eq)
  1195 
  1196 end
  1197 
  1198 
  1199 subsection \<open>min and max -- fundamental\<close>
  1200 
  1201 definition (in ord) min :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
  1202   "min a b = (if a \<le> b then a else b)"
  1203 
  1204 definition (in ord) max :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" where
  1205   "max a b = (if a \<le> b then b else a)"
  1206 
  1207 lemma min_absorb1: "x \<le> y \<Longrightarrow> min x y = x"
  1208   by (simp add: min_def)
  1209 
  1210 lemma max_absorb2: "x \<le> y \<Longrightarrow> max x y = y"
  1211   by (simp add: max_def)
  1212 
  1213 lemma min_absorb2: "(y::'a::order) \<le> x \<Longrightarrow> min x y = y"
  1214   by (simp add:min_def)
  1215 
  1216 lemma max_absorb1: "(y::'a::order) \<le> x \<Longrightarrow> max x y = x"
  1217   by (simp add: max_def)
  1218 
  1219 lemma max_min_same [simp]:
  1220   fixes x y :: "'a :: linorder"
  1221   shows "max x (min x y) = x" "max (min x y) x = x" "max (min x y) y = y" "max y (min x y) = y"
  1222 by(auto simp add: max_def min_def)
  1223 
  1224 subsection \<open>(Unique) top and bottom elements\<close>
  1225 
  1226 class bot =
  1227   fixes bot :: 'a ("\<bottom>")
  1228 
  1229 class order_bot = order + bot +
  1230   assumes bot_least: "\<bottom> \<le> a"
  1231 begin
  1232 
  1233 sublocale bot: ordering_top greater_eq greater bot
  1234   by standard (fact bot_least)
  1235 
  1236 lemma le_bot:
  1237   "a \<le> \<bottom> \<Longrightarrow> a = \<bottom>"
  1238   by (fact bot.extremum_uniqueI)
  1239 
  1240 lemma bot_unique:
  1241   "a \<le> \<bottom> \<longleftrightarrow> a = \<bottom>"
  1242   by (fact bot.extremum_unique)
  1243 
  1244 lemma not_less_bot:
  1245   "\<not> a < \<bottom>"
  1246   by (fact bot.extremum_strict)
  1247 
  1248 lemma bot_less:
  1249   "a \<noteq> \<bottom> \<longleftrightarrow> \<bottom> < a"
  1250   by (fact bot.not_eq_extremum)
  1251 
  1252 end
  1253 
  1254 class top =
  1255   fixes top :: 'a ("\<top>")
  1256 
  1257 class order_top = order + top +
  1258   assumes top_greatest: "a \<le> \<top>"
  1259 begin
  1260 
  1261 sublocale top: ordering_top less_eq less top
  1262   by standard (fact top_greatest)
  1263 
  1264 lemma top_le:
  1265   "\<top> \<le> a \<Longrightarrow> a = \<top>"
  1266   by (fact top.extremum_uniqueI)
  1267 
  1268 lemma top_unique:
  1269   "\<top> \<le> a \<longleftrightarrow> a = \<top>"
  1270   by (fact top.extremum_unique)
  1271 
  1272 lemma not_top_less:
  1273   "\<not> \<top> < a"
  1274   by (fact top.extremum_strict)
  1275 
  1276 lemma less_top:
  1277   "a \<noteq> \<top> \<longleftrightarrow> a < \<top>"
  1278   by (fact top.not_eq_extremum)
  1279 
  1280 end
  1281 
  1282 
  1283 subsection \<open>Dense orders\<close>
  1284 
  1285 class dense_order = order +
  1286   assumes dense: "x < y \<Longrightarrow> (\<exists>z. x < z \<and> z < y)"
  1287 
  1288 class dense_linorder = linorder + dense_order
  1289 begin
  1290 
  1291 lemma dense_le:
  1292   fixes y z :: 'a
  1293   assumes "\<And>x. x < y \<Longrightarrow> x \<le> z"
  1294   shows "y \<le> z"
  1295 proof (rule ccontr)
  1296   assume "\<not> ?thesis"
  1297   hence "z < y" by simp
  1298   from dense[OF this]
  1299   obtain x where "x < y" and "z < x" by safe
  1300   moreover have "x \<le> z" using assms[OF \<open>x < y\<close>] .
  1301   ultimately show False by auto
  1302 qed
  1303 
  1304 lemma dense_le_bounded:
  1305   fixes x y z :: 'a
  1306   assumes "x < y"
  1307   assumes *: "\<And>w. \<lbrakk> x < w ; w < y \<rbrakk> \<Longrightarrow> w \<le> z"
  1308   shows "y \<le> z"
  1309 proof (rule dense_le)
  1310   fix w assume "w < y"
  1311   from dense[OF \<open>x < y\<close>] obtain u where "x < u" "u < y" by safe
  1312   from linear[of u w]
  1313   show "w \<le> z"
  1314   proof (rule disjE)
  1315     assume "u \<le> w"
  1316     from less_le_trans[OF \<open>x < u\<close> \<open>u \<le> w\<close>] \<open>w < y\<close>
  1317     show "w \<le> z" by (rule *)
  1318   next
  1319     assume "w \<le> u"
  1320     from \<open>w \<le> u\<close> *[OF \<open>x < u\<close> \<open>u < y\<close>]
  1321     show "w \<le> z" by (rule order_trans)
  1322   qed
  1323 qed
  1324 
  1325 lemma dense_ge:
  1326   fixes y z :: 'a
  1327   assumes "\<And>x. z < x \<Longrightarrow> y \<le> x"
  1328   shows "y \<le> z"
  1329 proof (rule ccontr)
  1330   assume "\<not> ?thesis"
  1331   hence "z < y" by simp
  1332   from dense[OF this]
  1333   obtain x where "x < y" and "z < x" by safe
  1334   moreover have "y \<le> x" using assms[OF \<open>z < x\<close>] .
  1335   ultimately show False by auto
  1336 qed
  1337 
  1338 lemma dense_ge_bounded:
  1339   fixes x y z :: 'a
  1340   assumes "z < x"
  1341   assumes *: "\<And>w. \<lbrakk> z < w ; w < x \<rbrakk> \<Longrightarrow> y \<le> w"
  1342   shows "y \<le> z"
  1343 proof (rule dense_ge)
  1344   fix w assume "z < w"
  1345   from dense[OF \<open>z < x\<close>] obtain u where "z < u" "u < x" by safe
  1346   from linear[of u w]
  1347   show "y \<le> w"
  1348   proof (rule disjE)
  1349     assume "w \<le> u"
  1350     from \<open>z < w\<close> le_less_trans[OF \<open>w \<le> u\<close> \<open>u < x\<close>]
  1351     show "y \<le> w" by (rule *)
  1352   next
  1353     assume "u \<le> w"
  1354     from *[OF \<open>z < u\<close> \<open>u < x\<close>] \<open>u \<le> w\<close>
  1355     show "y \<le> w" by (rule order_trans)
  1356   qed
  1357 qed
  1358 
  1359 end
  1360 
  1361 class no_top = order +
  1362   assumes gt_ex: "\<exists>y. x < y"
  1363 
  1364 class no_bot = order +
  1365   assumes lt_ex: "\<exists>y. y < x"
  1366 
  1367 class unbounded_dense_linorder = dense_linorder + no_top + no_bot
  1368 
  1369 
  1370 subsection \<open>Wellorders\<close>
  1371 
  1372 class wellorder = linorder +
  1373   assumes less_induct [case_names less]: "(\<And>x. (\<And>y. y < x \<Longrightarrow> P y) \<Longrightarrow> P x) \<Longrightarrow> P a"
  1374 begin
  1375 
  1376 lemma wellorder_Least_lemma:
  1377   fixes k :: 'a
  1378   assumes "P k"
  1379   shows LeastI: "P (LEAST x. P x)" and Least_le: "(LEAST x. P x) \<le> k"
  1380 proof -
  1381   have "P (LEAST x. P x) \<and> (LEAST x. P x) \<le> k"
  1382   using assms proof (induct k rule: less_induct)
  1383     case (less x) then have "P x" by simp
  1384     show ?case proof (rule classical)
  1385       assume assm: "\<not> (P (LEAST a. P a) \<and> (LEAST a. P a) \<le> x)"
  1386       have "\<And>y. P y \<Longrightarrow> x \<le> y"
  1387       proof (rule classical)
  1388         fix y
  1389         assume "P y" and "\<not> x \<le> y"
  1390         with less have "P (LEAST a. P a)" and "(LEAST a. P a) \<le> y"
  1391           by (auto simp add: not_le)
  1392         with assm have "x < (LEAST a. P a)" and "(LEAST a. P a) \<le> y"
  1393           by auto
  1394         then show "x \<le> y" by auto
  1395       qed
  1396       with \<open>P x\<close> have Least: "(LEAST a. P a) = x"
  1397         by (rule Least_equality)
  1398       with \<open>P x\<close> show ?thesis by simp
  1399     qed
  1400   qed
  1401   then show "P (LEAST x. P x)" and "(LEAST x. P x) \<le> k" by auto
  1402 qed
  1403 
  1404 \<comment> "The following 3 lemmas are due to Brian Huffman"
  1405 lemma LeastI_ex: "\<exists>x. P x \<Longrightarrow> P (Least P)"
  1406   by (erule exE) (erule LeastI)
  1407 
  1408 lemma LeastI2:
  1409   "P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (Least P)"
  1410   by (blast intro: LeastI)
  1411 
  1412 lemma LeastI2_ex:
  1413   "\<exists>a. P a \<Longrightarrow> (\<And>x. P x \<Longrightarrow> Q x) \<Longrightarrow> Q (Least P)"
  1414   by (blast intro: LeastI_ex)
  1415 
  1416 lemma LeastI2_wellorder:
  1417   assumes "P a"
  1418   and "\<And>a. \<lbrakk> P a; \<forall>b. P b \<longrightarrow> a \<le> b \<rbrakk> \<Longrightarrow> Q a"
  1419   shows "Q (Least P)"
  1420 proof (rule LeastI2_order)
  1421   show "P (Least P)" using \<open>P a\<close> by (rule LeastI)
  1422 next
  1423   fix y assume "P y" thus "Least P \<le> y" by (rule Least_le)
  1424 next
  1425   fix x assume "P x" "\<forall>y. P y \<longrightarrow> x \<le> y" thus "Q x" by (rule assms(2))
  1426 qed
  1427 
  1428 lemma LeastI2_wellorder_ex:
  1429   assumes "\<exists>x. P x"
  1430   and "\<And>a. \<lbrakk> P a; \<forall>b. P b \<longrightarrow> a \<le> b \<rbrakk> \<Longrightarrow> Q a"
  1431   shows "Q (Least P)"
  1432 using assms by clarify (blast intro!: LeastI2_wellorder)
  1433 
  1434 lemma not_less_Least: "k < (LEAST x. P x) \<Longrightarrow> \<not> P k"
  1435 apply (simp add: not_le [symmetric])
  1436 apply (erule contrapos_nn)
  1437 apply (erule Least_le)
  1438 done
  1439 
  1440 end
  1441 
  1442 
  1443 subsection \<open>Order on @{typ bool}\<close>
  1444 
  1445 instantiation bool :: "{order_bot, order_top, linorder}"
  1446 begin
  1447 
  1448 definition
  1449   le_bool_def [simp]: "P \<le> Q \<longleftrightarrow> P \<longrightarrow> Q"
  1450 
  1451 definition
  1452   [simp]: "(P::bool) < Q \<longleftrightarrow> \<not> P \<and> Q"
  1453 
  1454 definition
  1455   [simp]: "\<bottom> \<longleftrightarrow> False"
  1456 
  1457 definition
  1458   [simp]: "\<top> \<longleftrightarrow> True"
  1459 
  1460 instance proof
  1461 qed auto
  1462 
  1463 end
  1464 
  1465 lemma le_boolI: "(P \<Longrightarrow> Q) \<Longrightarrow> P \<le> Q"
  1466   by simp
  1467 
  1468 lemma le_boolI': "P \<longrightarrow> Q \<Longrightarrow> P \<le> Q"
  1469   by simp
  1470 
  1471 lemma le_boolE: "P \<le> Q \<Longrightarrow> P \<Longrightarrow> (Q \<Longrightarrow> R) \<Longrightarrow> R"
  1472   by simp
  1473 
  1474 lemma le_boolD: "P \<le> Q \<Longrightarrow> P \<longrightarrow> Q"
  1475   by simp
  1476 
  1477 lemma bot_boolE: "\<bottom> \<Longrightarrow> P"
  1478   by simp
  1479 
  1480 lemma top_boolI: \<top>
  1481   by simp
  1482 
  1483 lemma [code]:
  1484   "False \<le> b \<longleftrightarrow> True"
  1485   "True \<le> b \<longleftrightarrow> b"
  1486   "False < b \<longleftrightarrow> b"
  1487   "True < b \<longleftrightarrow> False"
  1488   by simp_all
  1489 
  1490 
  1491 subsection \<open>Order on @{typ "_ \<Rightarrow> _"}\<close>
  1492 
  1493 instantiation "fun" :: (type, ord) ord
  1494 begin
  1495 
  1496 definition
  1497   le_fun_def: "f \<le> g \<longleftrightarrow> (\<forall>x. f x \<le> g x)"
  1498 
  1499 definition
  1500   "(f::'a \<Rightarrow> 'b) < g \<longleftrightarrow> f \<le> g \<and> \<not> (g \<le> f)"
  1501 
  1502 instance ..
  1503 
  1504 end
  1505 
  1506 instance "fun" :: (type, preorder) preorder proof
  1507 qed (auto simp add: le_fun_def less_fun_def
  1508   intro: order_trans antisym)
  1509 
  1510 instance "fun" :: (type, order) order proof
  1511 qed (auto simp add: le_fun_def intro: antisym)
  1512 
  1513 instantiation "fun" :: (type, bot) bot
  1514 begin
  1515 
  1516 definition
  1517   "\<bottom> = (\<lambda>x. \<bottom>)"
  1518 
  1519 instance ..
  1520 
  1521 end
  1522 
  1523 instantiation "fun" :: (type, order_bot) order_bot
  1524 begin
  1525 
  1526 lemma bot_apply [simp, code]:
  1527   "\<bottom> x = \<bottom>"
  1528   by (simp add: bot_fun_def)
  1529 
  1530 instance proof
  1531 qed (simp add: le_fun_def)
  1532 
  1533 end
  1534 
  1535 instantiation "fun" :: (type, top) top
  1536 begin
  1537 
  1538 definition
  1539   [no_atp]: "\<top> = (\<lambda>x. \<top>)"
  1540 
  1541 instance ..
  1542 
  1543 end
  1544 
  1545 instantiation "fun" :: (type, order_top) order_top
  1546 begin
  1547 
  1548 lemma top_apply [simp, code]:
  1549   "\<top> x = \<top>"
  1550   by (simp add: top_fun_def)
  1551 
  1552 instance proof
  1553 qed (simp add: le_fun_def)
  1554 
  1555 end
  1556 
  1557 lemma le_funI: "(\<And>x. f x \<le> g x) \<Longrightarrow> f \<le> g"
  1558   unfolding le_fun_def by simp
  1559 
  1560 lemma le_funE: "f \<le> g \<Longrightarrow> (f x \<le> g x \<Longrightarrow> P) \<Longrightarrow> P"
  1561   unfolding le_fun_def by simp
  1562 
  1563 lemma le_funD: "f \<le> g \<Longrightarrow> f x \<le> g x"
  1564   by (rule le_funE)
  1565 
  1566 lemma mono_compose: "mono Q \<Longrightarrow> mono (\<lambda>i x. Q i (f x))"
  1567   unfolding mono_def le_fun_def by auto
  1568 
  1569 
  1570 subsection \<open>Order on unary and binary predicates\<close>
  1571 
  1572 lemma predicate1I:
  1573   assumes PQ: "\<And>x. P x \<Longrightarrow> Q x"
  1574   shows "P \<le> Q"
  1575   apply (rule le_funI)
  1576   apply (rule le_boolI)
  1577   apply (rule PQ)
  1578   apply assumption
  1579   done
  1580 
  1581 lemma predicate1D:
  1582   "P \<le> Q \<Longrightarrow> P x \<Longrightarrow> Q x"
  1583   apply (erule le_funE)
  1584   apply (erule le_boolE)
  1585   apply assumption+
  1586   done
  1587 
  1588 lemma rev_predicate1D:
  1589   "P x \<Longrightarrow> P \<le> Q \<Longrightarrow> Q x"
  1590   by (rule predicate1D)
  1591 
  1592 lemma predicate2I:
  1593   assumes PQ: "\<And>x y. P x y \<Longrightarrow> Q x y"
  1594   shows "P \<le> Q"
  1595   apply (rule le_funI)+
  1596   apply (rule le_boolI)
  1597   apply (rule PQ)
  1598   apply assumption
  1599   done
  1600 
  1601 lemma predicate2D:
  1602   "P \<le> Q \<Longrightarrow> P x y \<Longrightarrow> Q x y"
  1603   apply (erule le_funE)+
  1604   apply (erule le_boolE)
  1605   apply assumption+
  1606   done
  1607 
  1608 lemma rev_predicate2D:
  1609   "P x y \<Longrightarrow> P \<le> Q \<Longrightarrow> Q x y"
  1610   by (rule predicate2D)
  1611 
  1612 lemma bot1E [no_atp]: "\<bottom> x \<Longrightarrow> P"
  1613   by (simp add: bot_fun_def)
  1614 
  1615 lemma bot2E: "\<bottom> x y \<Longrightarrow> P"
  1616   by (simp add: bot_fun_def)
  1617 
  1618 lemma top1I: "\<top> x"
  1619   by (simp add: top_fun_def)
  1620 
  1621 lemma top2I: "\<top> x y"
  1622   by (simp add: top_fun_def)
  1623 
  1624 
  1625 subsection \<open>Name duplicates\<close>
  1626 
  1627 lemmas order_eq_refl = preorder_class.eq_refl
  1628 lemmas order_less_irrefl = preorder_class.less_irrefl
  1629 lemmas order_less_imp_le = preorder_class.less_imp_le
  1630 lemmas order_less_not_sym = preorder_class.less_not_sym
  1631 lemmas order_less_asym = preorder_class.less_asym
  1632 lemmas order_less_trans = preorder_class.less_trans
  1633 lemmas order_le_less_trans = preorder_class.le_less_trans
  1634 lemmas order_less_le_trans = preorder_class.less_le_trans
  1635 lemmas order_less_imp_not_less = preorder_class.less_imp_not_less
  1636 lemmas order_less_imp_triv = preorder_class.less_imp_triv
  1637 lemmas order_less_asym' = preorder_class.less_asym'
  1638 
  1639 lemmas order_less_le = order_class.less_le
  1640 lemmas order_le_less = order_class.le_less
  1641 lemmas order_le_imp_less_or_eq = order_class.le_imp_less_or_eq
  1642 lemmas order_less_imp_not_eq = order_class.less_imp_not_eq
  1643 lemmas order_less_imp_not_eq2 = order_class.less_imp_not_eq2
  1644 lemmas order_neq_le_trans = order_class.neq_le_trans
  1645 lemmas order_le_neq_trans = order_class.le_neq_trans
  1646 lemmas order_antisym = order_class.antisym
  1647 lemmas order_eq_iff = order_class.eq_iff
  1648 lemmas order_antisym_conv = order_class.antisym_conv
  1649 
  1650 lemmas linorder_linear = linorder_class.linear
  1651 lemmas linorder_less_linear = linorder_class.less_linear
  1652 lemmas linorder_le_less_linear = linorder_class.le_less_linear
  1653 lemmas linorder_le_cases = linorder_class.le_cases
  1654 lemmas linorder_not_less = linorder_class.not_less
  1655 lemmas linorder_not_le = linorder_class.not_le
  1656 lemmas linorder_neq_iff = linorder_class.neq_iff
  1657 lemmas linorder_neqE = linorder_class.neqE
  1658 lemmas linorder_antisym_conv1 = linorder_class.antisym_conv1
  1659 lemmas linorder_antisym_conv2 = linorder_class.antisym_conv2
  1660 lemmas linorder_antisym_conv3 = linorder_class.antisym_conv3
  1661 
  1662 end