src/HOL/Rat.thy
author wenzelm
Sun Sep 18 20:33:48 2016 +0200 (2016-09-18)
changeset 63915 bab633745c7f
parent 63911 d00d4f399f05
child 64240 eabf80376aab
permissions -rw-r--r--
tuned proofs;
     1 (*  Title:      HOL/Rat.thy
     2     Author:     Markus Wenzel, TU Muenchen
     3 *)
     4 
     5 section \<open>Rational numbers\<close>
     6 
     7 theory Rat
     8   imports GCD Archimedean_Field
     9 begin
    10 
    11 subsection \<open>Rational numbers as quotient\<close>
    12 
    13 subsubsection \<open>Construction of the type of rational numbers\<close>
    14 
    15 definition ratrel :: "(int \<times> int) \<Rightarrow> (int \<times> int) \<Rightarrow> bool"
    16   where "ratrel = (\<lambda>x y. snd x \<noteq> 0 \<and> snd y \<noteq> 0 \<and> fst x * snd y = fst y * snd x)"
    17 
    18 lemma ratrel_iff [simp]: "ratrel x y \<longleftrightarrow> snd x \<noteq> 0 \<and> snd y \<noteq> 0 \<and> fst x * snd y = fst y * snd x"
    19   by (simp add: ratrel_def)
    20 
    21 lemma exists_ratrel_refl: "\<exists>x. ratrel x x"
    22   by (auto intro!: one_neq_zero)
    23 
    24 lemma symp_ratrel: "symp ratrel"
    25   by (simp add: ratrel_def symp_def)
    26 
    27 lemma transp_ratrel: "transp ratrel"
    28 proof (rule transpI, unfold split_paired_all)
    29   fix a b a' b' a'' b'' :: int
    30   assume *: "ratrel (a, b) (a', b')"
    31   assume **: "ratrel (a', b') (a'', b'')"
    32   have "b' * (a * b'') = b'' * (a * b')" by simp
    33   also from * have "a * b' = a' * b" by auto
    34   also have "b'' * (a' * b) = b * (a' * b'')" by simp
    35   also from ** have "a' * b'' = a'' * b'" by auto
    36   also have "b * (a'' * b') = b' * (a'' * b)" by simp
    37   finally have "b' * (a * b'') = b' * (a'' * b)" .
    38   moreover from ** have "b' \<noteq> 0" by auto
    39   ultimately have "a * b'' = a'' * b" by simp
    40   with * ** show "ratrel (a, b) (a'', b'')" by auto
    41 qed
    42 
    43 lemma part_equivp_ratrel: "part_equivp ratrel"
    44   by (rule part_equivpI [OF exists_ratrel_refl symp_ratrel transp_ratrel])
    45 
    46 quotient_type rat = "int \<times> int" / partial: "ratrel"
    47   morphisms Rep_Rat Abs_Rat
    48   by (rule part_equivp_ratrel)
    49 
    50 lemma Domainp_cr_rat [transfer_domain_rule]: "Domainp pcr_rat = (\<lambda>x. snd x \<noteq> 0)"
    51   by (simp add: rat.domain_eq)
    52 
    53 
    54 subsubsection \<open>Representation and basic operations\<close>
    55 
    56 lift_definition Fract :: "int \<Rightarrow> int \<Rightarrow> rat"
    57   is "\<lambda>a b. if b = 0 then (0, 1) else (a, b)"
    58   by simp
    59 
    60 lemma eq_rat:
    61   "\<And>a b c d. b \<noteq> 0 \<Longrightarrow> d \<noteq> 0 \<Longrightarrow> Fract a b = Fract c d \<longleftrightarrow> a * d = c * b"
    62   "\<And>a. Fract a 0 = Fract 0 1"
    63   "\<And>a c. Fract 0 a = Fract 0 c"
    64   by (transfer, simp)+
    65 
    66 lemma Rat_cases [case_names Fract, cases type: rat]:
    67   assumes that: "\<And>a b. q = Fract a b \<Longrightarrow> b > 0 \<Longrightarrow> coprime a b \<Longrightarrow> C"
    68   shows C
    69 proof -
    70   obtain a b :: int where q: "q = Fract a b" and b: "b \<noteq> 0"
    71     by transfer simp
    72   let ?a = "a div gcd a b"
    73   let ?b = "b div gcd a b"
    74   from b have "?b * gcd a b = b"
    75     by simp
    76   with b have "?b \<noteq> 0"
    77     by fastforce
    78   with q b have q2: "q = Fract ?a ?b"
    79     by (simp add: eq_rat dvd_div_mult mult.commute [of a])
    80   from b have coprime: "coprime ?a ?b"
    81     by (auto intro: div_gcd_coprime)
    82   show C
    83   proof (cases "b > 0")
    84     case True
    85     then have "?b > 0"
    86       by (simp add: nonneg1_imp_zdiv_pos_iff)
    87     from q2 this coprime show C by (rule that)
    88   next
    89     case False
    90     have "q = Fract (- ?a) (- ?b)"
    91       unfolding q2 by transfer simp
    92     moreover from False b have "- ?b > 0"
    93       by (simp add: pos_imp_zdiv_neg_iff)
    94     moreover from coprime have "coprime (- ?a) (- ?b)"
    95       by simp
    96     ultimately show C
    97       by (rule that)
    98   qed
    99 qed
   100 
   101 lemma Rat_induct [case_names Fract, induct type: rat]:
   102   assumes "\<And>a b. b > 0 \<Longrightarrow> coprime a b \<Longrightarrow> P (Fract a b)"
   103   shows "P q"
   104   using assms by (cases q) simp
   105 
   106 instantiation rat :: field
   107 begin
   108 
   109 lift_definition zero_rat :: "rat" is "(0, 1)"
   110   by simp
   111 
   112 lift_definition one_rat :: "rat" is "(1, 1)"
   113   by simp
   114 
   115 lemma Zero_rat_def: "0 = Fract 0 1"
   116   by transfer simp
   117 
   118 lemma One_rat_def: "1 = Fract 1 1"
   119   by transfer simp
   120 
   121 lift_definition plus_rat :: "rat \<Rightarrow> rat \<Rightarrow> rat"
   122   is "\<lambda>x y. (fst x * snd y + fst y * snd x, snd x * snd y)"
   123   by (auto simp: distrib_right) (simp add: ac_simps)
   124 
   125 lemma add_rat [simp]:
   126   assumes "b \<noteq> 0" and "d \<noteq> 0"
   127   shows "Fract a b + Fract c d = Fract (a * d + c * b) (b * d)"
   128   using assms by transfer simp
   129 
   130 lift_definition uminus_rat :: "rat \<Rightarrow> rat" is "\<lambda>x. (- fst x, snd x)"
   131   by simp
   132 
   133 lemma minus_rat [simp]: "- Fract a b = Fract (- a) b"
   134   by transfer simp
   135 
   136 lemma minus_rat_cancel [simp]: "Fract (- a) (- b) = Fract a b"
   137   by (cases "b = 0") (simp_all add: eq_rat)
   138 
   139 definition diff_rat_def: "q - r = q + - r" for q r :: rat
   140 
   141 lemma diff_rat [simp]:
   142   "b \<noteq> 0 \<Longrightarrow> d \<noteq> 0 \<Longrightarrow> Fract a b - Fract c d = Fract (a * d - c * b) (b * d)"
   143   by (simp add: diff_rat_def)
   144 
   145 lift_definition times_rat :: "rat \<Rightarrow> rat \<Rightarrow> rat"
   146   is "\<lambda>x y. (fst x * fst y, snd x * snd y)"
   147   by (simp add: ac_simps)
   148 
   149 lemma mult_rat [simp]: "Fract a b * Fract c d = Fract (a * c) (b * d)"
   150   by transfer simp
   151 
   152 lemma mult_rat_cancel: "c \<noteq> 0 \<Longrightarrow> Fract (c * a) (c * b) = Fract a b"
   153   by transfer simp
   154 
   155 lift_definition inverse_rat :: "rat \<Rightarrow> rat"
   156   is "\<lambda>x. if fst x = 0 then (0, 1) else (snd x, fst x)"
   157   by (auto simp add: mult.commute)
   158 
   159 lemma inverse_rat [simp]: "inverse (Fract a b) = Fract b a"
   160   by transfer simp
   161 
   162 definition divide_rat_def: "q div r = q * inverse r" for q r :: rat
   163 
   164 lemma divide_rat [simp]: "Fract a b div Fract c d = Fract (a * d) (b * c)"
   165   by (simp add: divide_rat_def)
   166 
   167 instance
   168 proof
   169   fix q r s :: rat
   170   show "(q * r) * s = q * (r * s)"
   171     by transfer simp
   172   show "q * r = r * q"
   173     by transfer simp
   174   show "1 * q = q"
   175     by transfer simp
   176   show "(q + r) + s = q + (r + s)"
   177     by transfer (simp add: algebra_simps)
   178   show "q + r = r + q"
   179     by transfer simp
   180   show "0 + q = q"
   181     by transfer simp
   182   show "- q + q = 0"
   183     by transfer simp
   184   show "q - r = q + - r"
   185     by (fact diff_rat_def)
   186   show "(q + r) * s = q * s + r * s"
   187     by transfer (simp add: algebra_simps)
   188   show "(0::rat) \<noteq> 1"
   189     by transfer simp
   190   show "inverse q * q = 1" if "q \<noteq> 0"
   191     using that by transfer simp
   192   show "q div r = q * inverse r"
   193     by (fact divide_rat_def)
   194   show "inverse 0 = (0::rat)"
   195     by transfer simp
   196 qed
   197 
   198 end
   199 
   200 (* We cannot state these two rules earlier because of pending sort hypotheses *)
   201 lemma div_add_self1_no_field [simp]:
   202   assumes "NO_MATCH (x :: 'b :: field) b" "(b :: 'a :: semiring_div) \<noteq> 0"
   203   shows "(b + a) div b = a div b + 1"
   204   using assms(2) by (fact div_add_self1)
   205 
   206 lemma div_add_self2_no_field [simp]:
   207   assumes "NO_MATCH (x :: 'b :: field) b" "(b :: 'a :: semiring_div) \<noteq> 0"
   208   shows "(a + b) div b = a div b + 1"
   209   using assms(2) by (fact div_add_self2)
   210 
   211 lemma of_nat_rat: "of_nat k = Fract (of_nat k) 1"
   212   by (induct k) (simp_all add: Zero_rat_def One_rat_def)
   213 
   214 lemma of_int_rat: "of_int k = Fract k 1"
   215   by (cases k rule: int_diff_cases) (simp add: of_nat_rat)
   216 
   217 lemma Fract_of_nat_eq: "Fract (of_nat k) 1 = of_nat k"
   218   by (rule of_nat_rat [symmetric])
   219 
   220 lemma Fract_of_int_eq: "Fract k 1 = of_int k"
   221   by (rule of_int_rat [symmetric])
   222 
   223 lemma rat_number_collapse:
   224   "Fract 0 k = 0"
   225   "Fract 1 1 = 1"
   226   "Fract (numeral w) 1 = numeral w"
   227   "Fract (- numeral w) 1 = - numeral w"
   228   "Fract (- 1) 1 = - 1"
   229   "Fract k 0 = 0"
   230   using Fract_of_int_eq [of "numeral w"]
   231     and Fract_of_int_eq [of "- numeral w"]
   232   by (simp_all add: Zero_rat_def One_rat_def eq_rat)
   233 
   234 lemma rat_number_expand:
   235   "0 = Fract 0 1"
   236   "1 = Fract 1 1"
   237   "numeral k = Fract (numeral k) 1"
   238   "- 1 = Fract (- 1) 1"
   239   "- numeral k = Fract (- numeral k) 1"
   240   by (simp_all add: rat_number_collapse)
   241 
   242 lemma Rat_cases_nonzero [case_names Fract 0]:
   243   assumes Fract: "\<And>a b. q = Fract a b \<Longrightarrow> b > 0 \<Longrightarrow> a \<noteq> 0 \<Longrightarrow> coprime a b \<Longrightarrow> C"
   244     and 0: "q = 0 \<Longrightarrow> C"
   245   shows C
   246 proof (cases "q = 0")
   247   case True
   248   then show C using 0 by auto
   249 next
   250   case False
   251   then obtain a b where *: "q = Fract a b" "b > 0" "coprime a b"
   252     by (cases q) auto
   253   with False have "0 \<noteq> Fract a b"
   254     by simp
   255   with \<open>b > 0\<close> have "a \<noteq> 0"
   256     by (simp add: Zero_rat_def eq_rat)
   257   with Fract * show C by blast
   258 qed
   259 
   260 
   261 subsubsection \<open>Function \<open>normalize\<close>\<close>
   262 
   263 lemma Fract_coprime: "Fract (a div gcd a b) (b div gcd a b) = Fract a b"
   264 proof (cases "b = 0")
   265   case True
   266   then show ?thesis
   267     by (simp add: eq_rat)
   268 next
   269   case False
   270   moreover have "b div gcd a b * gcd a b = b"
   271     by (rule dvd_div_mult_self) simp
   272   ultimately have "b div gcd a b * gcd a b \<noteq> 0"
   273     by simp
   274   then have "b div gcd a b \<noteq> 0"
   275     by fastforce
   276   with False show ?thesis
   277     by (simp add: eq_rat dvd_div_mult mult.commute [of a])
   278 qed
   279 
   280 definition normalize :: "int \<times> int \<Rightarrow> int \<times> int"
   281   where "normalize p =
   282    (if snd p > 0 then (let a = gcd (fst p) (snd p) in (fst p div a, snd p div a))
   283     else if snd p = 0 then (0, 1)
   284     else (let a = - gcd (fst p) (snd p) in (fst p div a, snd p div a)))"
   285 
   286 lemma normalize_crossproduct:
   287   assumes "q \<noteq> 0" "s \<noteq> 0"
   288   assumes "normalize (p, q) = normalize (r, s)"
   289   shows "p * s = r * q"
   290 proof -
   291   have *: "p * s = q * r"
   292     if "p * gcd r s = sgn (q * s) * r * gcd p q" and "q * gcd r s = sgn (q * s) * s * gcd p q"
   293   proof -
   294     from that have "(p * gcd r s) * (sgn (q * s) * s * gcd p q) =
   295         (q * gcd r s) * (sgn (q * s) * r * gcd p q)"
   296       by simp
   297     with assms show ?thesis
   298       by (auto simp add: ac_simps sgn_times sgn_0_0)
   299   qed
   300   from assms show ?thesis
   301     by (auto simp: normalize_def Let_def dvd_div_div_eq_mult mult.commute sgn_times
   302         split: if_splits intro: *)
   303 qed
   304 
   305 lemma normalize_eq: "normalize (a, b) = (p, q) \<Longrightarrow> Fract p q = Fract a b"
   306   by (auto simp: normalize_def Let_def Fract_coprime dvd_div_neg rat_number_collapse
   307       split: if_split_asm)
   308 
   309 lemma normalize_denom_pos: "normalize r = (p, q) \<Longrightarrow> q > 0"
   310   by (auto simp: normalize_def Let_def dvd_div_neg pos_imp_zdiv_neg_iff nonneg1_imp_zdiv_pos_iff
   311       split: if_split_asm)
   312 
   313 lemma normalize_coprime: "normalize r = (p, q) \<Longrightarrow> coprime p q"
   314   by (auto simp: normalize_def Let_def dvd_div_neg div_gcd_coprime split: if_split_asm)
   315 
   316 lemma normalize_stable [simp]: "q > 0 \<Longrightarrow> coprime p q \<Longrightarrow> normalize (p, q) = (p, q)"
   317   by (simp add: normalize_def)
   318 
   319 lemma normalize_denom_zero [simp]: "normalize (p, 0) = (0, 1)"
   320   by (simp add: normalize_def)
   321 
   322 lemma normalize_negative [simp]: "q < 0 \<Longrightarrow> normalize (p, q) = normalize (- p, - q)"
   323   by (simp add: normalize_def Let_def dvd_div_neg dvd_neg_div)
   324 
   325 text\<open>
   326   Decompose a fraction into normalized, i.e. coprime numerator and denominator:
   327 \<close>
   328 
   329 definition quotient_of :: "rat \<Rightarrow> int \<times> int"
   330   where "quotient_of x =
   331     (THE pair. x = Fract (fst pair) (snd pair) \<and> snd pair > 0 \<and> coprime (fst pair) (snd pair))"
   332 
   333 lemma quotient_of_unique: "\<exists>!p. r = Fract (fst p) (snd p) \<and> snd p > 0 \<and> coprime (fst p) (snd p)"
   334 proof (cases r)
   335   case (Fract a b)
   336   then have "r = Fract (fst (a, b)) (snd (a, b)) \<and>
   337       snd (a, b) > 0 \<and> coprime (fst (a, b)) (snd (a, b))"
   338     by auto
   339   then show ?thesis
   340   proof (rule ex1I)
   341     fix p
   342     assume r: "r = Fract (fst p) (snd p) \<and> snd p > 0 \<and> coprime (fst p) (snd p)"
   343     obtain c d where p: "p = (c, d)" by (cases p)
   344     with r have Fract': "r = Fract c d" "d > 0" "coprime c d"
   345       by simp_all
   346     have "(c, d) = (a, b)"
   347     proof (cases "a = 0")
   348       case True
   349       with Fract Fract' show ?thesis
   350         by (simp add: eq_rat)
   351     next
   352       case False
   353       with Fract Fract' have *: "c * b = a * d" and "c \<noteq> 0"
   354         by (auto simp add: eq_rat)
   355       then have "c * b > 0 \<longleftrightarrow> a * d > 0"
   356         by auto
   357       with \<open>b > 0\<close> \<open>d > 0\<close> have "a > 0 \<longleftrightarrow> c > 0"
   358         by (simp add: zero_less_mult_iff)
   359       with \<open>a \<noteq> 0\<close> \<open>c \<noteq> 0\<close> have sgn: "sgn a = sgn c"
   360         by (auto simp add: not_less)
   361       from \<open>coprime a b\<close> \<open>coprime c d\<close> have "\<bar>a\<bar> * \<bar>d\<bar> = \<bar>c\<bar> * \<bar>b\<bar> \<longleftrightarrow> \<bar>a\<bar> = \<bar>c\<bar> \<and> \<bar>d\<bar> = \<bar>b\<bar>"
   362         by (simp add: coprime_crossproduct_int)
   363       with \<open>b > 0\<close> \<open>d > 0\<close> have "\<bar>a\<bar> * d = \<bar>c\<bar> * b \<longleftrightarrow> \<bar>a\<bar> = \<bar>c\<bar> \<and> d = b"
   364         by simp
   365       then have "a * sgn a * d = c * sgn c * b \<longleftrightarrow> a * sgn a = c * sgn c \<and> d = b"
   366         by (simp add: abs_sgn)
   367       with sgn * show ?thesis
   368         by (auto simp add: sgn_0_0)
   369     qed
   370     with p show "p = (a, b)"
   371       by simp
   372   qed
   373 qed
   374 
   375 lemma quotient_of_Fract [code]: "quotient_of (Fract a b) = normalize (a, b)"
   376 proof -
   377   have "Fract a b = Fract (fst (normalize (a, b))) (snd (normalize (a, b)))" (is ?Fract)
   378     by (rule sym) (auto intro: normalize_eq)
   379   moreover have "0 < snd (normalize (a, b))" (is ?denom_pos)
   380     by (cases "normalize (a, b)") (rule normalize_denom_pos, simp)
   381   moreover have "coprime (fst (normalize (a, b))) (snd (normalize (a, b)))" (is ?coprime)
   382     by (rule normalize_coprime) simp
   383   ultimately have "?Fract \<and> ?denom_pos \<and> ?coprime" by blast
   384   then have "(THE p. Fract a b = Fract (fst p) (snd p) \<and> 0 < snd p \<and>
   385     coprime (fst p) (snd p)) = normalize (a, b)"
   386     by (rule the1_equality [OF quotient_of_unique])
   387   then show ?thesis by (simp add: quotient_of_def)
   388 qed
   389 
   390 lemma quotient_of_number [simp]:
   391   "quotient_of 0 = (0, 1)"
   392   "quotient_of 1 = (1, 1)"
   393   "quotient_of (numeral k) = (numeral k, 1)"
   394   "quotient_of (- 1) = (- 1, 1)"
   395   "quotient_of (- numeral k) = (- numeral k, 1)"
   396   by (simp_all add: rat_number_expand quotient_of_Fract)
   397 
   398 lemma quotient_of_eq: "quotient_of (Fract a b) = (p, q) \<Longrightarrow> Fract p q = Fract a b"
   399   by (simp add: quotient_of_Fract normalize_eq)
   400 
   401 lemma quotient_of_denom_pos: "quotient_of r = (p, q) \<Longrightarrow> q > 0"
   402   by (cases r) (simp add: quotient_of_Fract normalize_denom_pos)
   403 
   404 lemma quotient_of_coprime: "quotient_of r = (p, q) \<Longrightarrow> coprime p q"
   405   by (cases r) (simp add: quotient_of_Fract normalize_coprime)
   406 
   407 lemma quotient_of_inject:
   408   assumes "quotient_of a = quotient_of b"
   409   shows "a = b"
   410 proof -
   411   obtain p q r s where a: "a = Fract p q" and b: "b = Fract r s" and "q > 0" and "s > 0"
   412     by (cases a, cases b)
   413   with assms show ?thesis
   414     by (simp add: eq_rat quotient_of_Fract normalize_crossproduct)
   415 qed
   416 
   417 lemma quotient_of_inject_eq: "quotient_of a = quotient_of b \<longleftrightarrow> a = b"
   418   by (auto simp add: quotient_of_inject)
   419 
   420 
   421 subsubsection \<open>Various\<close>
   422 
   423 lemma Fract_of_int_quotient: "Fract k l = of_int k / of_int l"
   424   by (simp add: Fract_of_int_eq [symmetric])
   425 
   426 lemma Fract_add_one: "n \<noteq> 0 \<Longrightarrow> Fract (m + n) n = Fract m n + 1"
   427   by (simp add: rat_number_expand)
   428 
   429 lemma quotient_of_div:
   430   assumes r: "quotient_of r = (n,d)"
   431   shows "r = of_int n / of_int d"
   432 proof -
   433   from theI'[OF quotient_of_unique[of r], unfolded r[unfolded quotient_of_def]]
   434   have "r = Fract n d" by simp
   435   then show ?thesis using Fract_of_int_quotient
   436     by simp
   437 qed
   438 
   439 
   440 subsubsection \<open>The ordered field of rational numbers\<close>
   441 
   442 lift_definition positive :: "rat \<Rightarrow> bool"
   443   is "\<lambda>x. 0 < fst x * snd x"
   444 proof clarsimp
   445   fix a b c d :: int
   446   assume "b \<noteq> 0" and "d \<noteq> 0" and "a * d = c * b"
   447   then have "a * d * b * d = c * b * b * d"
   448     by simp
   449   then have "a * b * d\<^sup>2 = c * d * b\<^sup>2"
   450     unfolding power2_eq_square by (simp add: ac_simps)
   451   then have "0 < a * b * d\<^sup>2 \<longleftrightarrow> 0 < c * d * b\<^sup>2"
   452     by simp
   453   then show "0 < a * b \<longleftrightarrow> 0 < c * d"
   454     using \<open>b \<noteq> 0\<close> and \<open>d \<noteq> 0\<close>
   455     by (simp add: zero_less_mult_iff)
   456 qed
   457 
   458 lemma positive_zero: "\<not> positive 0"
   459   by transfer simp
   460 
   461 lemma positive_add: "positive x \<Longrightarrow> positive y \<Longrightarrow> positive (x + y)"
   462   apply transfer
   463   apply (simp add: zero_less_mult_iff)
   464   apply (elim disjE)
   465      apply (simp_all add: add_pos_pos add_neg_neg mult_pos_neg mult_neg_pos mult_neg_neg)
   466   done
   467 
   468 lemma positive_mult: "positive x \<Longrightarrow> positive y \<Longrightarrow> positive (x * y)"
   469   apply transfer
   470   apply (drule (1) mult_pos_pos)
   471   apply (simp add: ac_simps)
   472   done
   473 
   474 lemma positive_minus: "\<not> positive x \<Longrightarrow> x \<noteq> 0 \<Longrightarrow> positive (- x)"
   475   by transfer (auto simp: neq_iff zero_less_mult_iff mult_less_0_iff)
   476 
   477 instantiation rat :: linordered_field
   478 begin
   479 
   480 definition "x < y \<longleftrightarrow> positive (y - x)"
   481 
   482 definition "x \<le> y \<longleftrightarrow> x < y \<or> x = y" for x y :: rat
   483 
   484 definition "\<bar>a\<bar> = (if a < 0 then - a else a)" for a :: rat
   485 
   486 definition "sgn a = (if a = 0 then 0 else if 0 < a then 1 else - 1)" for a :: rat
   487 
   488 instance
   489 proof
   490   fix a b c :: rat
   491   show "\<bar>a\<bar> = (if a < 0 then - a else a)"
   492     by (rule abs_rat_def)
   493   show "a < b \<longleftrightarrow> a \<le> b \<and> \<not> b \<le> a"
   494     unfolding less_eq_rat_def less_rat_def
   495     apply auto
   496      apply (drule (1) positive_add)
   497      apply (simp_all add: positive_zero)
   498     done
   499   show "a \<le> a"
   500     unfolding less_eq_rat_def by simp
   501   show "a \<le> b \<Longrightarrow> b \<le> c \<Longrightarrow> a \<le> c"
   502     unfolding less_eq_rat_def less_rat_def
   503     apply auto
   504     apply (drule (1) positive_add)
   505     apply (simp add: algebra_simps)
   506     done
   507   show "a \<le> b \<Longrightarrow> b \<le> a \<Longrightarrow> a = b"
   508     unfolding less_eq_rat_def less_rat_def
   509     apply auto
   510     apply (drule (1) positive_add)
   511     apply (simp add: positive_zero)
   512     done
   513   show "a \<le> b \<Longrightarrow> c + a \<le> c + b"
   514     unfolding less_eq_rat_def less_rat_def by auto
   515   show "sgn a = (if a = 0 then 0 else if 0 < a then 1 else - 1)"
   516     by (rule sgn_rat_def)
   517   show "a \<le> b \<or> b \<le> a"
   518     unfolding less_eq_rat_def less_rat_def
   519     by (auto dest!: positive_minus)
   520   show "a < b \<Longrightarrow> 0 < c \<Longrightarrow> c * a < c * b"
   521     unfolding less_rat_def
   522     apply (drule (1) positive_mult)
   523     apply (simp add: algebra_simps)
   524     done
   525 qed
   526 
   527 end
   528 
   529 instantiation rat :: distrib_lattice
   530 begin
   531 
   532 definition "(inf :: rat \<Rightarrow> rat \<Rightarrow> rat) = min"
   533 
   534 definition "(sup :: rat \<Rightarrow> rat \<Rightarrow> rat) = max"
   535 
   536 instance
   537   by standard (auto simp add: inf_rat_def sup_rat_def max_min_distrib2)
   538 
   539 end
   540 
   541 lemma positive_rat: "positive (Fract a b) \<longleftrightarrow> 0 < a * b"
   542   by transfer simp
   543 
   544 lemma less_rat [simp]:
   545   "b \<noteq> 0 \<Longrightarrow> d \<noteq> 0 \<Longrightarrow> Fract a b < Fract c d \<longleftrightarrow> (a * d) * (b * d) < (c * b) * (b * d)"
   546   by (simp add: less_rat_def positive_rat algebra_simps)
   547 
   548 lemma le_rat [simp]:
   549   "b \<noteq> 0 \<Longrightarrow> d \<noteq> 0 \<Longrightarrow> Fract a b \<le> Fract c d \<longleftrightarrow> (a * d) * (b * d) \<le> (c * b) * (b * d)"
   550   by (simp add: le_less eq_rat)
   551 
   552 lemma abs_rat [simp, code]: "\<bar>Fract a b\<bar> = Fract \<bar>a\<bar> \<bar>b\<bar>"
   553   by (auto simp add: abs_rat_def zabs_def Zero_rat_def not_less le_less eq_rat zero_less_mult_iff)
   554 
   555 lemma sgn_rat [simp, code]: "sgn (Fract a b) = of_int (sgn a * sgn b)"
   556   unfolding Fract_of_int_eq
   557   by (auto simp: zsgn_def sgn_rat_def Zero_rat_def eq_rat)
   558     (auto simp: rat_number_collapse not_less le_less zero_less_mult_iff)
   559 
   560 lemma Rat_induct_pos [case_names Fract, induct type: rat]:
   561   assumes step: "\<And>a b. 0 < b \<Longrightarrow> P (Fract a b)"
   562   shows "P q"
   563 proof (cases q)
   564   case (Fract a b)
   565   have step': "P (Fract a b)" if b: "b < 0" for a b :: int
   566   proof -
   567     from b have "0 < - b"
   568       by simp
   569     then have "P (Fract (- a) (- b))"
   570       by (rule step)
   571     then show "P (Fract a b)"
   572       by (simp add: order_less_imp_not_eq [OF b])
   573   qed
   574   from Fract show "P q"
   575     by (auto simp add: linorder_neq_iff step step')
   576 qed
   577 
   578 lemma zero_less_Fract_iff: "0 < b \<Longrightarrow> 0 < Fract a b \<longleftrightarrow> 0 < a"
   579   by (simp add: Zero_rat_def zero_less_mult_iff)
   580 
   581 lemma Fract_less_zero_iff: "0 < b \<Longrightarrow> Fract a b < 0 \<longleftrightarrow> a < 0"
   582   by (simp add: Zero_rat_def mult_less_0_iff)
   583 
   584 lemma zero_le_Fract_iff: "0 < b \<Longrightarrow> 0 \<le> Fract a b \<longleftrightarrow> 0 \<le> a"
   585   by (simp add: Zero_rat_def zero_le_mult_iff)
   586 
   587 lemma Fract_le_zero_iff: "0 < b \<Longrightarrow> Fract a b \<le> 0 \<longleftrightarrow> a \<le> 0"
   588   by (simp add: Zero_rat_def mult_le_0_iff)
   589 
   590 lemma one_less_Fract_iff: "0 < b \<Longrightarrow> 1 < Fract a b \<longleftrightarrow> b < a"
   591   by (simp add: One_rat_def mult_less_cancel_right_disj)
   592 
   593 lemma Fract_less_one_iff: "0 < b \<Longrightarrow> Fract a b < 1 \<longleftrightarrow> a < b"
   594   by (simp add: One_rat_def mult_less_cancel_right_disj)
   595 
   596 lemma one_le_Fract_iff: "0 < b \<Longrightarrow> 1 \<le> Fract a b \<longleftrightarrow> b \<le> a"
   597   by (simp add: One_rat_def mult_le_cancel_right)
   598 
   599 lemma Fract_le_one_iff: "0 < b \<Longrightarrow> Fract a b \<le> 1 \<longleftrightarrow> a \<le> b"
   600   by (simp add: One_rat_def mult_le_cancel_right)
   601 
   602 
   603 subsubsection \<open>Rationals are an Archimedean field\<close>
   604 
   605 lemma rat_floor_lemma: "of_int (a div b) \<le> Fract a b \<and> Fract a b < of_int (a div b + 1)"
   606 proof -
   607   have "Fract a b = of_int (a div b) + Fract (a mod b) b"
   608     by (cases "b = 0") (simp, simp add: of_int_rat)
   609   moreover have "0 \<le> Fract (a mod b) b \<and> Fract (a mod b) b < 1"
   610     unfolding Fract_of_int_quotient
   611     by (rule linorder_cases [of b 0]) (simp_all add: divide_nonpos_neg)
   612   ultimately show ?thesis by simp
   613 qed
   614 
   615 instance rat :: archimedean_field
   616 proof
   617   show "\<exists>z. r \<le> of_int z" for r :: rat
   618   proof (induct r)
   619     case (Fract a b)
   620     have "Fract a b \<le> of_int (a div b + 1)"
   621       using rat_floor_lemma [of a b] by simp
   622     then show "\<exists>z. Fract a b \<le> of_int z" ..
   623   qed
   624 qed
   625 
   626 instantiation rat :: floor_ceiling
   627 begin
   628 
   629 definition [code del]: "\<lfloor>x\<rfloor> = (THE z. of_int z \<le> x \<and> x < of_int (z + 1))" for x :: rat
   630 
   631 instance
   632 proof
   633   show "of_int \<lfloor>x\<rfloor> \<le> x \<and> x < of_int (\<lfloor>x\<rfloor> + 1)" for x :: rat
   634     unfolding floor_rat_def using floor_exists1 by (rule theI')
   635 qed
   636 
   637 end
   638 
   639 lemma floor_Fract: "\<lfloor>Fract a b\<rfloor> = a div b"
   640   by (simp add: Fract_of_int_quotient floor_divide_of_int_eq)
   641 
   642 
   643 subsection \<open>Linear arithmetic setup\<close>
   644 
   645 declaration \<open>
   646   K (Lin_Arith.add_inj_thms [@{thm of_nat_le_iff} RS iffD2, @{thm of_nat_eq_iff} RS iffD2]
   647     (* not needed because x < (y::nat) can be rewritten as Suc x <= y: of_nat_less_iff RS iffD2 *)
   648   #> Lin_Arith.add_inj_thms [@{thm of_int_le_iff} RS iffD2, @{thm of_int_eq_iff} RS iffD2]
   649     (* not needed because x < (y::int) can be rewritten as x + 1 <= y: of_int_less_iff RS iffD2 *)
   650   #> Lin_Arith.add_simps [@{thm neg_less_iff_less},
   651       @{thm True_implies_equals},
   652       @{thm distrib_left [where a = "numeral v" for v]},
   653       @{thm distrib_left [where a = "- numeral v" for v]},
   654       @{thm divide_1}, @{thm divide_zero_left},
   655       @{thm times_divide_eq_right}, @{thm times_divide_eq_left},
   656       @{thm minus_divide_left} RS sym, @{thm minus_divide_right} RS sym,
   657       @{thm add_divide_distrib}, @{thm diff_divide_distrib},
   658       @{thm of_int_minus}, @{thm of_int_diff},
   659       @{thm of_int_of_nat_eq}]
   660   #> Lin_Arith.add_simprocs [Numeral_Simprocs.field_divide_cancel_numeral_factor]
   661   #> Lin_Arith.add_inj_const (@{const_name of_nat}, @{typ "nat \<Rightarrow> rat"})
   662   #> Lin_Arith.add_inj_const (@{const_name of_int}, @{typ "int \<Rightarrow> rat"}))
   663 \<close>
   664 
   665 
   666 subsection \<open>Embedding from Rationals to other Fields\<close>
   667 
   668 context field_char_0
   669 begin
   670 
   671 lift_definition of_rat :: "rat \<Rightarrow> 'a"
   672   is "\<lambda>x. of_int (fst x) / of_int (snd x)"
   673   by (auto simp: nonzero_divide_eq_eq nonzero_eq_divide_eq) (simp only: of_int_mult [symmetric])
   674 
   675 end
   676 
   677 lemma of_rat_rat: "b \<noteq> 0 \<Longrightarrow> of_rat (Fract a b) = of_int a / of_int b"
   678   by transfer simp
   679 
   680 lemma of_rat_0 [simp]: "of_rat 0 = 0"
   681   by transfer simp
   682 
   683 lemma of_rat_1 [simp]: "of_rat 1 = 1"
   684   by transfer simp
   685 
   686 lemma of_rat_add: "of_rat (a + b) = of_rat a + of_rat b"
   687   by transfer (simp add: add_frac_eq)
   688 
   689 lemma of_rat_minus: "of_rat (- a) = - of_rat a"
   690   by transfer simp
   691 
   692 lemma of_rat_neg_one [simp]: "of_rat (- 1) = - 1"
   693   by (simp add: of_rat_minus)
   694 
   695 lemma of_rat_diff: "of_rat (a - b) = of_rat a - of_rat b"
   696   using of_rat_add [of a "- b"] by (simp add: of_rat_minus)
   697 
   698 lemma of_rat_mult: "of_rat (a * b) = of_rat a * of_rat b"
   699   by transfer (simp add: divide_inverse nonzero_inverse_mult_distrib ac_simps)
   700 
   701 lemma of_rat_setsum: "of_rat (\<Sum>a\<in>A. f a) = (\<Sum>a\<in>A. of_rat (f a))"
   702   by (induct rule: infinite_finite_induct) (auto simp: of_rat_add)
   703 
   704 lemma of_rat_setprod: "of_rat (\<Prod>a\<in>A. f a) = (\<Prod>a\<in>A. of_rat (f a))"
   705   by (induct rule: infinite_finite_induct) (auto simp: of_rat_mult)
   706 
   707 lemma nonzero_of_rat_inverse: "a \<noteq> 0 \<Longrightarrow> of_rat (inverse a) = inverse (of_rat a)"
   708   by (rule inverse_unique [symmetric]) (simp add: of_rat_mult [symmetric])
   709 
   710 lemma of_rat_inverse: "(of_rat (inverse a) :: 'a::{field_char_0,field}) = inverse (of_rat a)"
   711   by (cases "a = 0") (simp_all add: nonzero_of_rat_inverse)
   712 
   713 lemma nonzero_of_rat_divide: "b \<noteq> 0 \<Longrightarrow> of_rat (a / b) = of_rat a / of_rat b"
   714   by (simp add: divide_inverse of_rat_mult nonzero_of_rat_inverse)
   715 
   716 lemma of_rat_divide: "(of_rat (a / b) :: 'a::{field_char_0,field}) = of_rat a / of_rat b"
   717   by (cases "b = 0") (simp_all add: nonzero_of_rat_divide)
   718 
   719 lemma of_rat_power: "(of_rat (a ^ n) :: 'a::field_char_0) = of_rat a ^ n"
   720   by (induct n) (simp_all add: of_rat_mult)
   721 
   722 lemma of_rat_eq_iff [simp]: "of_rat a = of_rat b \<longleftrightarrow> a = b"
   723   apply transfer
   724   apply (simp add: nonzero_divide_eq_eq nonzero_eq_divide_eq)
   725   apply (simp only: of_int_mult [symmetric] of_int_eq_iff)
   726   done
   727 
   728 lemma of_rat_eq_0_iff [simp]: "of_rat a = 0 \<longleftrightarrow> a = 0"
   729   using of_rat_eq_iff [of _ 0] by simp
   730 
   731 lemma zero_eq_of_rat_iff [simp]: "0 = of_rat a \<longleftrightarrow> 0 = a"
   732   by simp
   733 
   734 lemma of_rat_eq_1_iff [simp]: "of_rat a = 1 \<longleftrightarrow> a = 1"
   735   using of_rat_eq_iff [of _ 1] by simp
   736 
   737 lemma one_eq_of_rat_iff [simp]: "1 = of_rat a \<longleftrightarrow> 1 = a"
   738   by simp
   739 
   740 lemma of_rat_less: "(of_rat r :: 'a::linordered_field) < of_rat s \<longleftrightarrow> r < s"
   741 proof (induct r, induct s)
   742   fix a b c d :: int
   743   assume not_zero: "b > 0" "d > 0"
   744   then have "b * d > 0" by simp
   745   have of_int_divide_less_eq:
   746     "(of_int a :: 'a) / of_int b < of_int c / of_int d \<longleftrightarrow>
   747       (of_int a :: 'a) * of_int d < of_int c * of_int b"
   748     using not_zero by (simp add: pos_less_divide_eq pos_divide_less_eq)
   749   show "(of_rat (Fract a b) :: 'a::linordered_field) < of_rat (Fract c d) \<longleftrightarrow>
   750       Fract a b < Fract c d"
   751     using not_zero \<open>b * d > 0\<close>
   752     by (simp add: of_rat_rat of_int_divide_less_eq of_int_mult [symmetric] del: of_int_mult)
   753 qed
   754 
   755 lemma of_rat_less_eq: "(of_rat r :: 'a::linordered_field) \<le> of_rat s \<longleftrightarrow> r \<le> s"
   756   unfolding le_less by (auto simp add: of_rat_less)
   757 
   758 lemma of_rat_le_0_iff [simp]: "(of_rat r :: 'a::linordered_field) \<le> 0 \<longleftrightarrow> r \<le> 0"
   759   using of_rat_less_eq [of r 0, where 'a = 'a] by simp
   760 
   761 lemma zero_le_of_rat_iff [simp]: "0 \<le> (of_rat r :: 'a::linordered_field) \<longleftrightarrow> 0 \<le> r"
   762   using of_rat_less_eq [of 0 r, where 'a = 'a] by simp
   763 
   764 lemma of_rat_le_1_iff [simp]: "(of_rat r :: 'a::linordered_field) \<le> 1 \<longleftrightarrow> r \<le> 1"
   765   using of_rat_less_eq [of r 1] by simp
   766 
   767 lemma one_le_of_rat_iff [simp]: "1 \<le> (of_rat r :: 'a::linordered_field) \<longleftrightarrow> 1 \<le> r"
   768   using of_rat_less_eq [of 1 r] by simp
   769 
   770 lemma of_rat_less_0_iff [simp]: "(of_rat r :: 'a::linordered_field) < 0 \<longleftrightarrow> r < 0"
   771   using of_rat_less [of r 0, where 'a = 'a] by simp
   772 
   773 lemma zero_less_of_rat_iff [simp]: "0 < (of_rat r :: 'a::linordered_field) \<longleftrightarrow> 0 < r"
   774   using of_rat_less [of 0 r, where 'a = 'a] by simp
   775 
   776 lemma of_rat_less_1_iff [simp]: "(of_rat r :: 'a::linordered_field) < 1 \<longleftrightarrow> r < 1"
   777   using of_rat_less [of r 1] by simp
   778 
   779 lemma one_less_of_rat_iff [simp]: "1 < (of_rat r :: 'a::linordered_field) \<longleftrightarrow> 1 < r"
   780   using of_rat_less [of 1 r] by simp
   781 
   782 lemma of_rat_eq_id [simp]: "of_rat = id"
   783 proof
   784   show "of_rat a = id a" for a
   785     by (induct a) (simp add: of_rat_rat Fract_of_int_eq [symmetric])
   786 qed
   787 
   788 text \<open>Collapse nested embeddings.\<close>
   789 lemma of_rat_of_nat_eq [simp]: "of_rat (of_nat n) = of_nat n"
   790   by (induct n) (simp_all add: of_rat_add)
   791 
   792 lemma of_rat_of_int_eq [simp]: "of_rat (of_int z) = of_int z"
   793   by (cases z rule: int_diff_cases) (simp add: of_rat_diff)
   794 
   795 lemma of_rat_numeral_eq [simp]: "of_rat (numeral w) = numeral w"
   796   using of_rat_of_int_eq [of "numeral w"] by simp
   797 
   798 lemma of_rat_neg_numeral_eq [simp]: "of_rat (- numeral w) = - numeral w"
   799   using of_rat_of_int_eq [of "- numeral w"] by simp
   800 
   801 lemmas zero_rat = Zero_rat_def
   802 lemmas one_rat = One_rat_def
   803 
   804 abbreviation rat_of_nat :: "nat \<Rightarrow> rat"
   805   where "rat_of_nat \<equiv> of_nat"
   806 
   807 abbreviation rat_of_int :: "int \<Rightarrow> rat"
   808   where "rat_of_int \<equiv> of_int"
   809 
   810 
   811 subsection \<open>The Set of Rational Numbers\<close>
   812 
   813 context field_char_0
   814 begin
   815 
   816 definition Rats :: "'a set" ("\<rat>")
   817   where "\<rat> = range of_rat"
   818 
   819 end
   820 
   821 lemma Rats_of_rat [simp]: "of_rat r \<in> \<rat>"
   822   by (simp add: Rats_def)
   823 
   824 lemma Rats_of_int [simp]: "of_int z \<in> \<rat>"
   825   by (subst of_rat_of_int_eq [symmetric]) (rule Rats_of_rat)
   826 
   827 lemma Rats_of_nat [simp]: "of_nat n \<in> \<rat>"
   828   by (subst of_rat_of_nat_eq [symmetric]) (rule Rats_of_rat)
   829 
   830 lemma Rats_number_of [simp]: "numeral w \<in> \<rat>"
   831   by (subst of_rat_numeral_eq [symmetric]) (rule Rats_of_rat)
   832 
   833 lemma Rats_0 [simp]: "0 \<in> \<rat>"
   834   unfolding Rats_def by (rule range_eqI) (rule of_rat_0 [symmetric])
   835 
   836 lemma Rats_1 [simp]: "1 \<in> \<rat>"
   837   unfolding Rats_def by (rule range_eqI) (rule of_rat_1 [symmetric])
   838 
   839 lemma Rats_add [simp]: "a \<in> \<rat> \<Longrightarrow> b \<in> \<rat> \<Longrightarrow> a + b \<in> \<rat>"
   840   apply (auto simp add: Rats_def)
   841   apply (rule range_eqI)
   842   apply (rule of_rat_add [symmetric])
   843   done
   844 
   845 lemma Rats_minus [simp]: "a \<in> \<rat> \<Longrightarrow> - a \<in> \<rat>"
   846   apply (auto simp add: Rats_def)
   847   apply (rule range_eqI)
   848   apply (rule of_rat_minus [symmetric])
   849   done
   850 
   851 lemma Rats_diff [simp]: "a \<in> \<rat> \<Longrightarrow> b \<in> \<rat> \<Longrightarrow> a - b \<in> \<rat>"
   852   apply (auto simp add: Rats_def)
   853   apply (rule range_eqI)
   854   apply (rule of_rat_diff [symmetric])
   855   done
   856 
   857 lemma Rats_mult [simp]: "a \<in> \<rat> \<Longrightarrow> b \<in> \<rat> \<Longrightarrow> a * b \<in> \<rat>"
   858   apply (auto simp add: Rats_def)
   859   apply (rule range_eqI)
   860   apply (rule of_rat_mult [symmetric])
   861   done
   862 
   863 lemma nonzero_Rats_inverse: "a \<in> \<rat> \<Longrightarrow> a \<noteq> 0 \<Longrightarrow> inverse a \<in> \<rat>"
   864   for a :: "'a::field_char_0"
   865   apply (auto simp add: Rats_def)
   866   apply (rule range_eqI)
   867   apply (erule nonzero_of_rat_inverse [symmetric])
   868   done
   869 
   870 lemma Rats_inverse [simp]: "a \<in> \<rat> \<Longrightarrow> inverse a \<in> \<rat>"
   871   for a :: "'a::{field_char_0,field}"
   872   apply (auto simp add: Rats_def)
   873   apply (rule range_eqI)
   874   apply (rule of_rat_inverse [symmetric])
   875   done
   876 
   877 lemma nonzero_Rats_divide: "a \<in> \<rat> \<Longrightarrow> b \<in> \<rat> \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> a / b \<in> \<rat>"
   878   for a b :: "'a::field_char_0"
   879   apply (auto simp add: Rats_def)
   880   apply (rule range_eqI)
   881   apply (erule nonzero_of_rat_divide [symmetric])
   882   done
   883 
   884 lemma Rats_divide [simp]: "a \<in> \<rat> \<Longrightarrow> b \<in> \<rat> \<Longrightarrow> a / b \<in> \<rat>"
   885   for a b :: "'a::{field_char_0, field}"
   886   apply (auto simp add: Rats_def)
   887   apply (rule range_eqI)
   888   apply (rule of_rat_divide [symmetric])
   889   done
   890 
   891 lemma Rats_power [simp]: "a \<in> \<rat> \<Longrightarrow> a ^ n \<in> \<rat>"
   892   for a :: "'a::field_char_0"
   893   apply (auto simp add: Rats_def)
   894   apply (rule range_eqI)
   895   apply (rule of_rat_power [symmetric])
   896   done
   897 
   898 lemma Rats_cases [cases set: Rats]:
   899   assumes "q \<in> \<rat>"
   900   obtains (of_rat) r where "q = of_rat r"
   901 proof -
   902   from \<open>q \<in> \<rat>\<close> have "q \<in> range of_rat"
   903     by (simp only: Rats_def)
   904   then obtain r where "q = of_rat r" ..
   905   then show thesis ..
   906 qed
   907 
   908 lemma Rats_induct [case_names of_rat, induct set: Rats]: "q \<in> \<rat> \<Longrightarrow> (\<And>r. P (of_rat r)) \<Longrightarrow> P q"
   909   by (rule Rats_cases) auto
   910 
   911 lemma Rats_infinite: "\<not> finite \<rat>"
   912   by (auto dest!: finite_imageD simp: inj_on_def infinite_UNIV_char_0 Rats_def)
   913 
   914 
   915 subsection \<open>Implementation of rational numbers as pairs of integers\<close>
   916 
   917 text \<open>Formal constructor\<close>
   918 
   919 definition Frct :: "int \<times> int \<Rightarrow> rat"
   920   where [simp]: "Frct p = Fract (fst p) (snd p)"
   921 
   922 lemma [code abstype]: "Frct (quotient_of q) = q"
   923   by (cases q) (auto intro: quotient_of_eq)
   924 
   925 
   926 text \<open>Numerals\<close>
   927 
   928 declare quotient_of_Fract [code abstract]
   929 
   930 definition of_int :: "int \<Rightarrow> rat"
   931   where [code_abbrev]: "of_int = Int.of_int"
   932 
   933 hide_const (open) of_int
   934 
   935 lemma quotient_of_int [code abstract]: "quotient_of (Rat.of_int a) = (a, 1)"
   936   by (simp add: of_int_def of_int_rat quotient_of_Fract)
   937 
   938 lemma [code_unfold]: "numeral k = Rat.of_int (numeral k)"
   939   by (simp add: Rat.of_int_def)
   940 
   941 lemma [code_unfold]: "- numeral k = Rat.of_int (- numeral k)"
   942   by (simp add: Rat.of_int_def)
   943 
   944 lemma Frct_code_post [code_post]:
   945   "Frct (0, a) = 0"
   946   "Frct (a, 0) = 0"
   947   "Frct (1, 1) = 1"
   948   "Frct (numeral k, 1) = numeral k"
   949   "Frct (1, numeral k) = 1 / numeral k"
   950   "Frct (numeral k, numeral l) = numeral k / numeral l"
   951   "Frct (- a, b) = - Frct (a, b)"
   952   "Frct (a, - b) = - Frct (a, b)"
   953   "- (- Frct q) = Frct q"
   954   by (simp_all add: Fract_of_int_quotient)
   955 
   956 
   957 text \<open>Operations\<close>
   958 
   959 lemma rat_zero_code [code abstract]: "quotient_of 0 = (0, 1)"
   960   by (simp add: Zero_rat_def quotient_of_Fract normalize_def)
   961 
   962 lemma rat_one_code [code abstract]: "quotient_of 1 = (1, 1)"
   963   by (simp add: One_rat_def quotient_of_Fract normalize_def)
   964 
   965 lemma rat_plus_code [code abstract]:
   966   "quotient_of (p + q) = (let (a, c) = quotient_of p; (b, d) = quotient_of q
   967      in normalize (a * d + b * c, c * d))"
   968   by (cases p, cases q) (simp add: quotient_of_Fract)
   969 
   970 lemma rat_uminus_code [code abstract]:
   971   "quotient_of (- p) = (let (a, b) = quotient_of p in (- a, b))"
   972   by (cases p) (simp add: quotient_of_Fract)
   973 
   974 lemma rat_minus_code [code abstract]:
   975   "quotient_of (p - q) =
   976     (let (a, c) = quotient_of p; (b, d) = quotient_of q
   977      in normalize (a * d - b * c, c * d))"
   978   by (cases p, cases q) (simp add: quotient_of_Fract)
   979 
   980 lemma rat_times_code [code abstract]:
   981   "quotient_of (p * q) =
   982     (let (a, c) = quotient_of p; (b, d) = quotient_of q
   983      in normalize (a * b, c * d))"
   984   by (cases p, cases q) (simp add: quotient_of_Fract)
   985 
   986 lemma rat_inverse_code [code abstract]:
   987   "quotient_of (inverse p) =
   988     (let (a, b) = quotient_of p
   989      in if a = 0 then (0, 1) else (sgn a * b, \<bar>a\<bar>))"
   990 proof (cases p)
   991   case (Fract a b)
   992   then show ?thesis
   993     by (cases "0::int" a rule: linorder_cases) (simp_all add: quotient_of_Fract gcd.commute)
   994 qed
   995 
   996 lemma rat_divide_code [code abstract]:
   997   "quotient_of (p / q) =
   998     (let (a, c) = quotient_of p; (b, d) = quotient_of q
   999      in normalize (a * d, c * b))"
  1000   by (cases p, cases q) (simp add: quotient_of_Fract)
  1001 
  1002 lemma rat_abs_code [code abstract]: "quotient_of \<bar>p\<bar> = (let (a, b) = quotient_of p in (\<bar>a\<bar>, b))"
  1003   by (cases p) (simp add: quotient_of_Fract)
  1004 
  1005 lemma rat_sgn_code [code abstract]: "quotient_of (sgn p) = (sgn (fst (quotient_of p)), 1)"
  1006 proof (cases p)
  1007   case (Fract a b)
  1008   then show ?thesis
  1009     by (cases "0::int" a rule: linorder_cases) (simp_all add: quotient_of_Fract)
  1010 qed
  1011 
  1012 lemma rat_floor_code [code]: "\<lfloor>p\<rfloor> = (let (a, b) = quotient_of p in a div b)"
  1013   by (cases p) (simp add: quotient_of_Fract floor_Fract)
  1014 
  1015 instantiation rat :: equal
  1016 begin
  1017 
  1018 definition [code]: "HOL.equal a b \<longleftrightarrow> quotient_of a = quotient_of b"
  1019 
  1020 instance
  1021   by standard (simp add: equal_rat_def quotient_of_inject_eq)
  1022 
  1023 lemma rat_eq_refl [code nbe]: "HOL.equal (r::rat) r \<longleftrightarrow> True"
  1024   by (rule equal_refl)
  1025 
  1026 end
  1027 
  1028 lemma rat_less_eq_code [code]:
  1029   "p \<le> q \<longleftrightarrow> (let (a, c) = quotient_of p; (b, d) = quotient_of q in a * d \<le> c * b)"
  1030   by (cases p, cases q) (simp add: quotient_of_Fract mult.commute)
  1031 
  1032 lemma rat_less_code [code]:
  1033   "p < q \<longleftrightarrow> (let (a, c) = quotient_of p; (b, d) = quotient_of q in a * d < c * b)"
  1034   by (cases p, cases q) (simp add: quotient_of_Fract mult.commute)
  1035 
  1036 lemma [code]: "of_rat p = (let (a, b) = quotient_of p in of_int a / of_int b)"
  1037   by (cases p) (simp add: quotient_of_Fract of_rat_rat)
  1038 
  1039 
  1040 text \<open>Quickcheck\<close>
  1041 
  1042 definition (in term_syntax)
  1043   valterm_fract :: "int \<times> (unit \<Rightarrow> Code_Evaluation.term) \<Rightarrow>
  1044     int \<times> (unit \<Rightarrow> Code_Evaluation.term) \<Rightarrow>
  1045     rat \<times> (unit \<Rightarrow> Code_Evaluation.term)"
  1046   where [code_unfold]: "valterm_fract k l = Code_Evaluation.valtermify Fract {\<cdot>} k {\<cdot>} l"
  1047 
  1048 notation fcomp (infixl "\<circ>>" 60)
  1049 notation scomp (infixl "\<circ>\<rightarrow>" 60)
  1050 
  1051 instantiation rat :: random
  1052 begin
  1053 
  1054 definition
  1055   "Quickcheck_Random.random i =
  1056     Quickcheck_Random.random i \<circ>\<rightarrow> (\<lambda>num. Random.range i \<circ>\<rightarrow> (\<lambda>denom. Pair
  1057       (let j = int_of_integer (integer_of_natural (denom + 1))
  1058        in valterm_fract num (j, \<lambda>u. Code_Evaluation.term_of j))))"
  1059 
  1060 instance ..
  1061 
  1062 end
  1063 
  1064 no_notation fcomp (infixl "\<circ>>" 60)
  1065 no_notation scomp (infixl "\<circ>\<rightarrow>" 60)
  1066 
  1067 instantiation rat :: exhaustive
  1068 begin
  1069 
  1070 definition
  1071   "exhaustive_rat f d =
  1072     Quickcheck_Exhaustive.exhaustive
  1073       (\<lambda>l. Quickcheck_Exhaustive.exhaustive
  1074         (\<lambda>k. f (Fract k (int_of_integer (integer_of_natural l) + 1))) d) d"
  1075 
  1076 instance ..
  1077 
  1078 end
  1079 
  1080 instantiation rat :: full_exhaustive
  1081 begin
  1082 
  1083 definition
  1084   "full_exhaustive_rat f d =
  1085     Quickcheck_Exhaustive.full_exhaustive
  1086       (\<lambda>(l, _). Quickcheck_Exhaustive.full_exhaustive
  1087         (\<lambda>k. f
  1088           (let j = int_of_integer (integer_of_natural l) + 1
  1089            in valterm_fract k (j, \<lambda>_. Code_Evaluation.term_of j))) d) d"
  1090 
  1091 instance ..
  1092 
  1093 end
  1094 
  1095 instance rat :: partial_term_of ..
  1096 
  1097 lemma [code]:
  1098   "partial_term_of (ty :: rat itself) (Quickcheck_Narrowing.Narrowing_variable p tt) \<equiv>
  1099     Code_Evaluation.Free (STR ''_'') (Typerep.Typerep (STR ''Rat.rat'') [])"
  1100   "partial_term_of (ty :: rat itself) (Quickcheck_Narrowing.Narrowing_constructor 0 [l, k]) \<equiv>
  1101     Code_Evaluation.App
  1102       (Code_Evaluation.Const (STR ''Rat.Frct'')
  1103         (Typerep.Typerep (STR ''fun'')
  1104           [Typerep.Typerep (STR ''Product_Type.prod'')
  1105            [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''Int.int'') []],
  1106            Typerep.Typerep (STR ''Rat.rat'') []]))
  1107       (Code_Evaluation.App
  1108         (Code_Evaluation.App
  1109           (Code_Evaluation.Const (STR ''Product_Type.Pair'')
  1110             (Typerep.Typerep (STR ''fun'')
  1111               [Typerep.Typerep (STR ''Int.int'') [],
  1112                Typerep.Typerep (STR ''fun'')
  1113                 [Typerep.Typerep (STR ''Int.int'') [],
  1114                  Typerep.Typerep (STR ''Product_Type.prod'')
  1115                  [Typerep.Typerep (STR ''Int.int'') [], Typerep.Typerep (STR ''Int.int'') []]]]))
  1116           (partial_term_of (TYPE(int)) l)) (partial_term_of (TYPE(int)) k))"
  1117   by (rule partial_term_of_anything)+
  1118 
  1119 instantiation rat :: narrowing
  1120 begin
  1121 
  1122 definition
  1123   "narrowing =
  1124     Quickcheck_Narrowing.apply
  1125       (Quickcheck_Narrowing.apply
  1126         (Quickcheck_Narrowing.cons (\<lambda>nom denom. Fract nom denom)) narrowing) narrowing"
  1127 
  1128 instance ..
  1129 
  1130 end
  1131 
  1132 
  1133 subsection \<open>Setup for Nitpick\<close>
  1134 
  1135 declaration \<open>
  1136   Nitpick_HOL.register_frac_type @{type_name rat}
  1137     [(@{const_name Abs_Rat}, @{const_name Nitpick.Abs_Frac}),
  1138      (@{const_name zero_rat_inst.zero_rat}, @{const_name Nitpick.zero_frac}),
  1139      (@{const_name one_rat_inst.one_rat}, @{const_name Nitpick.one_frac}),
  1140      (@{const_name plus_rat_inst.plus_rat}, @{const_name Nitpick.plus_frac}),
  1141      (@{const_name times_rat_inst.times_rat}, @{const_name Nitpick.times_frac}),
  1142      (@{const_name uminus_rat_inst.uminus_rat}, @{const_name Nitpick.uminus_frac}),
  1143      (@{const_name inverse_rat_inst.inverse_rat}, @{const_name Nitpick.inverse_frac}),
  1144      (@{const_name ord_rat_inst.less_rat}, @{const_name Nitpick.less_frac}),
  1145      (@{const_name ord_rat_inst.less_eq_rat}, @{const_name Nitpick.less_eq_frac}),
  1146      (@{const_name field_char_0_class.of_rat}, @{const_name Nitpick.of_frac})]
  1147 \<close>
  1148 
  1149 lemmas [nitpick_unfold] =
  1150   inverse_rat_inst.inverse_rat
  1151   one_rat_inst.one_rat ord_rat_inst.less_rat
  1152   ord_rat_inst.less_eq_rat plus_rat_inst.plus_rat times_rat_inst.times_rat
  1153   uminus_rat_inst.uminus_rat zero_rat_inst.zero_rat
  1154 
  1155 
  1156 subsection \<open>Float syntax\<close>
  1157 
  1158 syntax "_Float" :: "float_const \<Rightarrow> 'a"    ("_")
  1159 
  1160 parse_translation \<open>
  1161   let
  1162     fun mk_frac str =
  1163       let
  1164         val {mant = i, exp = n} = Lexicon.read_float str;
  1165         val exp = Syntax.const @{const_syntax Power.power};
  1166         val ten = Numeral.mk_number_syntax 10;
  1167         val exp10 = if n = 1 then ten else exp $ ten $ Numeral.mk_number_syntax n;
  1168       in Syntax.const @{const_syntax Fields.inverse_divide} $ Numeral.mk_number_syntax i $ exp10 end;
  1169 
  1170     fun float_tr [(c as Const (@{syntax_const "_constrain"}, _)) $ t $ u] = c $ float_tr [t] $ u
  1171       | float_tr [t as Const (str, _)] = mk_frac str
  1172       | float_tr ts = raise TERM ("float_tr", ts);
  1173   in [(@{syntax_const "_Float"}, K float_tr)] end
  1174 \<close>
  1175 
  1176 text\<open>Test:\<close>
  1177 lemma "123.456 = -111.111 + 200 + 30 + 4 + 5/10 + 6/100 + (7/1000::rat)"
  1178   by simp
  1179 
  1180 
  1181 subsection \<open>Hiding implementation details\<close>
  1182 
  1183 hide_const (open) normalize positive
  1184 
  1185 lifting_update rat.lifting
  1186 lifting_forget rat.lifting
  1187 
  1188 end