src/HOL/Topological_Spaces.thy
author wenzelm
Sun Sep 18 20:33:48 2016 +0200 (2016-09-18)
changeset 63915 bab633745c7f
parent 63713 009e176e1010
child 63952 354808e9f44b
permissions -rw-r--r--
tuned proofs;
     1 (*  Title:      HOL/Topological_Spaces.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 section \<open>Topological Spaces\<close>
     7 
     8 theory Topological_Spaces
     9   imports Main
    10 begin
    11 
    12 named_theorems continuous_intros "structural introduction rules for continuity"
    13 
    14 subsection \<open>Topological space\<close>
    15 
    16 class "open" =
    17   fixes "open" :: "'a set \<Rightarrow> bool"
    18 
    19 class topological_space = "open" +
    20   assumes open_UNIV [simp, intro]: "open UNIV"
    21   assumes open_Int [intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<inter> T)"
    22   assumes open_Union [intro]: "\<forall>S\<in>K. open S \<Longrightarrow> open (\<Union>K)"
    23 begin
    24 
    25 definition closed :: "'a set \<Rightarrow> bool"
    26   where "closed S \<longleftrightarrow> open (- S)"
    27 
    28 lemma open_empty [continuous_intros, intro, simp]: "open {}"
    29   using open_Union [of "{}"] by simp
    30 
    31 lemma open_Un [continuous_intros, intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<union> T)"
    32   using open_Union [of "{S, T}"] by simp
    33 
    34 lemma open_UN [continuous_intros, intro]: "\<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Union>x\<in>A. B x)"
    35   using open_Union [of "B ` A"] by simp
    36 
    37 lemma open_Inter [continuous_intros, intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. open T \<Longrightarrow> open (\<Inter>S)"
    38   by (induct set: finite) auto
    39 
    40 lemma open_INT [continuous_intros, intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Inter>x\<in>A. B x)"
    41   using open_Inter [of "B ` A"] by simp
    42 
    43 lemma openI:
    44   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S"
    45   shows "open S"
    46 proof -
    47   have "open (\<Union>{T. open T \<and> T \<subseteq> S})" by auto
    48   moreover have "\<Union>{T. open T \<and> T \<subseteq> S} = S" by (auto dest!: assms)
    49   ultimately show "open S" by simp
    50 qed
    51 
    52 lemma closed_empty [continuous_intros, intro, simp]: "closed {}"
    53   unfolding closed_def by simp
    54 
    55 lemma closed_Un [continuous_intros, intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<union> T)"
    56   unfolding closed_def by auto
    57 
    58 lemma closed_UNIV [continuous_intros, intro, simp]: "closed UNIV"
    59   unfolding closed_def by simp
    60 
    61 lemma closed_Int [continuous_intros, intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<inter> T)"
    62   unfolding closed_def by auto
    63 
    64 lemma closed_INT [continuous_intros, intro]: "\<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Inter>x\<in>A. B x)"
    65   unfolding closed_def by auto
    66 
    67 lemma closed_Inter [continuous_intros, intro]: "\<forall>S\<in>K. closed S \<Longrightarrow> closed (\<Inter>K)"
    68   unfolding closed_def uminus_Inf by auto
    69 
    70 lemma closed_Union [continuous_intros, intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. closed T \<Longrightarrow> closed (\<Union>S)"
    71   by (induct set: finite) auto
    72 
    73 lemma closed_UN [continuous_intros, intro]:
    74   "finite A \<Longrightarrow> \<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Union>x\<in>A. B x)"
    75   using closed_Union [of "B ` A"] by simp
    76 
    77 lemma open_closed: "open S \<longleftrightarrow> closed (- S)"
    78   by (simp add: closed_def)
    79 
    80 lemma closed_open: "closed S \<longleftrightarrow> open (- S)"
    81   by (rule closed_def)
    82 
    83 lemma open_Diff [continuous_intros, intro]: "open S \<Longrightarrow> closed T \<Longrightarrow> open (S - T)"
    84   by (simp add: closed_open Diff_eq open_Int)
    85 
    86 lemma closed_Diff [continuous_intros, intro]: "closed S \<Longrightarrow> open T \<Longrightarrow> closed (S - T)"
    87   by (simp add: open_closed Diff_eq closed_Int)
    88 
    89 lemma open_Compl [continuous_intros, intro]: "closed S \<Longrightarrow> open (- S)"
    90   by (simp add: closed_open)
    91 
    92 lemma closed_Compl [continuous_intros, intro]: "open S \<Longrightarrow> closed (- S)"
    93   by (simp add: open_closed)
    94 
    95 lemma open_Collect_neg: "closed {x. P x} \<Longrightarrow> open {x. \<not> P x}"
    96   unfolding Collect_neg_eq by (rule open_Compl)
    97 
    98 lemma open_Collect_conj:
    99   assumes "open {x. P x}" "open {x. Q x}"
   100   shows "open {x. P x \<and> Q x}"
   101   using open_Int[OF assms] by (simp add: Int_def)
   102 
   103 lemma open_Collect_disj:
   104   assumes "open {x. P x}" "open {x. Q x}"
   105   shows "open {x. P x \<or> Q x}"
   106   using open_Un[OF assms] by (simp add: Un_def)
   107 
   108 lemma open_Collect_ex: "(\<And>i. open {x. P i x}) \<Longrightarrow> open {x. \<exists>i. P i x}"
   109   using open_UN[of UNIV "\<lambda>i. {x. P i x}"] unfolding Collect_ex_eq by simp
   110 
   111 lemma open_Collect_imp: "closed {x. P x} \<Longrightarrow> open {x. Q x} \<Longrightarrow> open {x. P x \<longrightarrow> Q x}"
   112   unfolding imp_conv_disj by (intro open_Collect_disj open_Collect_neg)
   113 
   114 lemma open_Collect_const: "open {x. P}"
   115   by (cases P) auto
   116 
   117 lemma closed_Collect_neg: "open {x. P x} \<Longrightarrow> closed {x. \<not> P x}"
   118   unfolding Collect_neg_eq by (rule closed_Compl)
   119 
   120 lemma closed_Collect_conj:
   121   assumes "closed {x. P x}" "closed {x. Q x}"
   122   shows "closed {x. P x \<and> Q x}"
   123   using closed_Int[OF assms] by (simp add: Int_def)
   124 
   125 lemma closed_Collect_disj:
   126   assumes "closed {x. P x}" "closed {x. Q x}"
   127   shows "closed {x. P x \<or> Q x}"
   128   using closed_Un[OF assms] by (simp add: Un_def)
   129 
   130 lemma closed_Collect_all: "(\<And>i. closed {x. P i x}) \<Longrightarrow> closed {x. \<forall>i. P i x}"
   131   using closed_INT[of UNIV "\<lambda>i. {x. P i x}"] by (simp add: Collect_all_eq)
   132 
   133 lemma closed_Collect_imp: "open {x. P x} \<Longrightarrow> closed {x. Q x} \<Longrightarrow> closed {x. P x \<longrightarrow> Q x}"
   134   unfolding imp_conv_disj by (intro closed_Collect_disj closed_Collect_neg)
   135 
   136 lemma closed_Collect_const: "closed {x. P}"
   137   by (cases P) auto
   138 
   139 end
   140 
   141 
   142 subsection \<open>Hausdorff and other separation properties\<close>
   143 
   144 class t0_space = topological_space +
   145   assumes t0_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> \<not> (x \<in> U \<longleftrightarrow> y \<in> U)"
   146 
   147 class t1_space = topological_space +
   148   assumes t1_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> x \<in> U \<and> y \<notin> U"
   149 
   150 instance t1_space \<subseteq> t0_space
   151   by standard (fast dest: t1_space)
   152 
   153 lemma separation_t1: "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> x \<in> U \<and> y \<notin> U)"
   154   for x y :: "'a::t1_space"
   155   using t1_space[of x y] by blast
   156 
   157 lemma closed_singleton [iff]: "closed {a}"
   158   for a :: "'a::t1_space"
   159 proof -
   160   let ?T = "\<Union>{S. open S \<and> a \<notin> S}"
   161   have "open ?T"
   162     by (simp add: open_Union)
   163   also have "?T = - {a}"
   164     by (auto simp add: set_eq_iff separation_t1)
   165   finally show "closed {a}"
   166     by (simp only: closed_def)
   167 qed
   168 
   169 lemma closed_insert [continuous_intros, simp]:
   170   fixes a :: "'a::t1_space"
   171   assumes "closed S"
   172   shows "closed (insert a S)"
   173 proof -
   174   from closed_singleton assms have "closed ({a} \<union> S)"
   175     by (rule closed_Un)
   176   then show "closed (insert a S)"
   177     by simp
   178 qed
   179 
   180 lemma finite_imp_closed: "finite S \<Longrightarrow> closed S"
   181   for S :: "'a::t1_space set"
   182   by (induct pred: finite) simp_all
   183 
   184 
   185 text \<open>T2 spaces are also known as Hausdorff spaces.\<close>
   186 
   187 class t2_space = topological_space +
   188   assumes hausdorff: "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   189 
   190 instance t2_space \<subseteq> t1_space
   191   by standard (fast dest: hausdorff)
   192 
   193 lemma separation_t2: "x \<noteq> y \<longleftrightarrow> (\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {})"
   194   for x y :: "'a::t2_space"
   195   using hausdorff [of x y] by blast
   196 
   197 lemma separation_t0: "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> \<not> (x \<in> U \<longleftrightarrow> y \<in> U))"
   198   for x y :: "'a::t0_space"
   199   using t0_space [of x y] by blast
   200 
   201 
   202 text \<open>A perfect space is a topological space with no isolated points.\<close>
   203 
   204 class perfect_space = topological_space +
   205   assumes not_open_singleton: "\<not> open {x}"
   206 
   207 lemma UNIV_not_singleton: "UNIV \<noteq> {x}"
   208   for x :: "'a::perfect_space"
   209   by (metis open_UNIV not_open_singleton)
   210 
   211 
   212 subsection \<open>Generators for toplogies\<close>
   213 
   214 inductive generate_topology :: "'a set set \<Rightarrow> 'a set \<Rightarrow> bool" for S :: "'a set set"
   215   where
   216     UNIV: "generate_topology S UNIV"
   217   | Int: "generate_topology S (a \<inter> b)" if "generate_topology S a" and "generate_topology S b"
   218   | UN: "generate_topology S (\<Union>K)" if "(\<And>k. k \<in> K \<Longrightarrow> generate_topology S k)"
   219   | Basis: "generate_topology S s" if "s \<in> S"
   220 
   221 hide_fact (open) UNIV Int UN Basis
   222 
   223 lemma generate_topology_Union:
   224   "(\<And>k. k \<in> I \<Longrightarrow> generate_topology S (K k)) \<Longrightarrow> generate_topology S (\<Union>k\<in>I. K k)"
   225   using generate_topology.UN [of "K ` I"] by auto
   226 
   227 lemma topological_space_generate_topology: "class.topological_space (generate_topology S)"
   228   by standard (auto intro: generate_topology.intros)
   229 
   230 
   231 subsection \<open>Order topologies\<close>
   232 
   233 class order_topology = order + "open" +
   234   assumes open_generated_order: "open = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   235 begin
   236 
   237 subclass topological_space
   238   unfolding open_generated_order
   239   by (rule topological_space_generate_topology)
   240 
   241 lemma open_greaterThan [continuous_intros, simp]: "open {a <..}"
   242   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   243 
   244 lemma open_lessThan [continuous_intros, simp]: "open {..< a}"
   245   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   246 
   247 lemma open_greaterThanLessThan [continuous_intros, simp]: "open {a <..< b}"
   248    unfolding greaterThanLessThan_eq by (simp add: open_Int)
   249 
   250 end
   251 
   252 class linorder_topology = linorder + order_topology
   253 
   254 lemma closed_atMost [continuous_intros, simp]: "closed {..a}"
   255   for a :: "'a::linorder_topology"
   256   by (simp add: closed_open)
   257 
   258 lemma closed_atLeast [continuous_intros, simp]: "closed {a..}"
   259   for a :: "'a::linorder_topology"
   260   by (simp add: closed_open)
   261 
   262 lemma closed_atLeastAtMost [continuous_intros, simp]: "closed {a..b}"
   263   for a b :: "'a::linorder_topology"
   264 proof -
   265   have "{a .. b} = {a ..} \<inter> {.. b}"
   266     by auto
   267   then show ?thesis
   268     by (simp add: closed_Int)
   269 qed
   270 
   271 lemma (in linorder) less_separate:
   272   assumes "x < y"
   273   shows "\<exists>a b. x \<in> {..< a} \<and> y \<in> {b <..} \<and> {..< a} \<inter> {b <..} = {}"
   274 proof (cases "\<exists>z. x < z \<and> z < y")
   275   case True
   276   then obtain z where "x < z \<and> z < y" ..
   277   then have "x \<in> {..< z} \<and> y \<in> {z <..} \<and> {z <..} \<inter> {..< z} = {}"
   278     by auto
   279   then show ?thesis by blast
   280 next
   281   case False
   282   with \<open>x < y\<close> have "x \<in> {..< y}" "y \<in> {x <..}" "{x <..} \<inter> {..< y} = {}"
   283     by auto
   284   then show ?thesis by blast
   285 qed
   286 
   287 instance linorder_topology \<subseteq> t2_space
   288 proof
   289   fix x y :: 'a
   290   show "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   291     using less_separate [of x y] less_separate [of y x]
   292     by (elim neqE; metis open_lessThan open_greaterThan Int_commute)
   293 qed
   294 
   295 lemma (in linorder_topology) open_right:
   296   assumes "open S" "x \<in> S"
   297     and gt_ex: "x < y"
   298   shows "\<exists>b>x. {x ..< b} \<subseteq> S"
   299   using assms unfolding open_generated_order
   300 proof induct
   301   case UNIV
   302   then show ?case by blast
   303 next
   304   case (Int A B)
   305   then obtain a b where "a > x" "{x ..< a} \<subseteq> A"  "b > x" "{x ..< b} \<subseteq> B"
   306     by auto
   307   then show ?case
   308     by (auto intro!: exI[of _ "min a b"])
   309 next
   310   case UN
   311   then show ?case by blast
   312 next
   313   case Basis
   314   then show ?case
   315     by (fastforce intro: exI[of _ y] gt_ex)
   316 qed
   317 
   318 lemma (in linorder_topology) open_left:
   319   assumes "open S" "x \<in> S"
   320     and lt_ex: "y < x"
   321   shows "\<exists>b<x. {b <.. x} \<subseteq> S"
   322   using assms unfolding open_generated_order
   323 proof induction
   324   case UNIV
   325   then show ?case by blast
   326 next
   327   case (Int A B)
   328   then obtain a b where "a < x" "{a <.. x} \<subseteq> A"  "b < x" "{b <.. x} \<subseteq> B"
   329     by auto
   330   then show ?case
   331     by (auto intro!: exI[of _ "max a b"])
   332 next
   333   case UN
   334   then show ?case by blast
   335 next
   336   case Basis
   337   then show ?case
   338     by (fastforce intro: exI[of _ y] lt_ex)
   339 qed
   340 
   341 
   342 subsection \<open>Setup some topologies\<close>
   343 
   344 subsubsection \<open>Boolean is an order topology\<close>
   345 
   346 class discrete_topology = topological_space +
   347   assumes open_discrete: "\<And>A. open A"
   348 
   349 instance discrete_topology < t2_space
   350 proof
   351   fix x y :: 'a
   352   assume "x \<noteq> y"
   353   then show "\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   354     by (intro exI[of _ "{_}"]) (auto intro!: open_discrete)
   355 qed
   356 
   357 instantiation bool :: linorder_topology
   358 begin
   359 
   360 definition open_bool :: "bool set \<Rightarrow> bool"
   361   where "open_bool = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   362 
   363 instance
   364   by standard (rule open_bool_def)
   365 
   366 end
   367 
   368 instance bool :: discrete_topology
   369 proof
   370   fix A :: "bool set"
   371   have *: "{False <..} = {True}" "{..< True} = {False}"
   372     by auto
   373   have "A = UNIV \<or> A = {} \<or> A = {False <..} \<or> A = {..< True}"
   374     using subset_UNIV[of A] unfolding UNIV_bool * by blast
   375   then show "open A"
   376     by auto
   377 qed
   378 
   379 instantiation nat :: linorder_topology
   380 begin
   381 
   382 definition open_nat :: "nat set \<Rightarrow> bool"
   383   where "open_nat = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   384 
   385 instance
   386   by standard (rule open_nat_def)
   387 
   388 end
   389 
   390 instance nat :: discrete_topology
   391 proof
   392   fix A :: "nat set"
   393   have "open {n}" for n :: nat
   394   proof (cases n)
   395     case 0
   396     moreover have "{0} = {..<1::nat}"
   397       by auto
   398     ultimately show ?thesis
   399        by auto
   400   next
   401     case (Suc n')
   402     then have "{n} = {..<Suc n} \<inter> {n' <..}"
   403       by auto
   404     with Suc show ?thesis
   405       by (auto intro: open_lessThan open_greaterThan)
   406   qed
   407   then have "open (\<Union>a\<in>A. {a})"
   408     by (intro open_UN) auto
   409   then show "open A"
   410     by simp
   411 qed
   412 
   413 instantiation int :: linorder_topology
   414 begin
   415 
   416 definition open_int :: "int set \<Rightarrow> bool"
   417   where "open_int = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   418 
   419 instance
   420   by standard (rule open_int_def)
   421 
   422 end
   423 
   424 instance int :: discrete_topology
   425 proof
   426   fix A :: "int set"
   427   have "{..<i + 1} \<inter> {i-1 <..} = {i}" for i :: int
   428     by auto
   429   then have "open {i}" for i :: int
   430     using open_Int[OF open_lessThan[of "i + 1"] open_greaterThan[of "i - 1"]] by auto
   431   then have "open (\<Union>a\<in>A. {a})"
   432     by (intro open_UN) auto
   433   then show "open A"
   434     by simp
   435 qed
   436 
   437 
   438 subsubsection \<open>Topological filters\<close>
   439 
   440 definition (in topological_space) nhds :: "'a \<Rightarrow> 'a filter"
   441   where "nhds a = (INF S:{S. open S \<and> a \<in> S}. principal S)"
   442 
   443 definition (in topological_space) at_within :: "'a \<Rightarrow> 'a set \<Rightarrow> 'a filter"
   444     ("at (_)/ within (_)" [1000, 60] 60)
   445   where "at a within s = inf (nhds a) (principal (s - {a}))"
   446 
   447 abbreviation (in topological_space) at :: "'a \<Rightarrow> 'a filter"  ("at")
   448   where "at x \<equiv> at x within (CONST UNIV)"
   449 
   450 abbreviation (in order_topology) at_right :: "'a \<Rightarrow> 'a filter"
   451   where "at_right x \<equiv> at x within {x <..}"
   452 
   453 abbreviation (in order_topology) at_left :: "'a \<Rightarrow> 'a filter"
   454   where "at_left x \<equiv> at x within {..< x}"
   455 
   456 lemma (in topological_space) nhds_generated_topology:
   457   "open = generate_topology T \<Longrightarrow> nhds x = (INF S:{S\<in>T. x \<in> S}. principal S)"
   458   unfolding nhds_def
   459 proof (safe intro!: antisym INF_greatest)
   460   fix S
   461   assume "generate_topology T S" "x \<in> S"
   462   then show "(INF S:{S \<in> T. x \<in> S}. principal S) \<le> principal S"
   463     by induct
   464       (auto intro: INF_lower order_trans simp: inf_principal[symmetric] simp del: inf_principal)
   465 qed (auto intro!: INF_lower intro: generate_topology.intros)
   466 
   467 lemma (in topological_space) eventually_nhds:
   468   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   469   unfolding nhds_def by (subst eventually_INF_base) (auto simp: eventually_principal)
   470 
   471 lemma (in topological_space) eventually_nhds_in_open:
   472   "open s \<Longrightarrow> x \<in> s \<Longrightarrow> eventually (\<lambda>y. y \<in> s) (nhds x)"
   473   by (subst eventually_nhds) blast
   474 
   475 lemma eventually_nhds_x_imp_x: "eventually P (nhds x) \<Longrightarrow> P x"
   476   by (subst (asm) eventually_nhds) blast
   477 
   478 lemma nhds_neq_bot [simp]: "nhds a \<noteq> bot"
   479   by (simp add: trivial_limit_def eventually_nhds)
   480 
   481 lemma (in t1_space) t1_space_nhds: "x \<noteq> y \<Longrightarrow> (\<forall>\<^sub>F x in nhds x. x \<noteq> y)"
   482   by (drule t1_space) (auto simp: eventually_nhds)
   483 
   484 lemma (in topological_space) nhds_discrete_open: "open {x} \<Longrightarrow> nhds x = principal {x}"
   485   by (auto simp: nhds_def intro!: antisym INF_greatest INF_lower2[of "{x}"])
   486 
   487 lemma (in discrete_topology) nhds_discrete: "nhds x = principal {x}"
   488   by (simp add: nhds_discrete_open open_discrete)
   489 
   490 lemma (in discrete_topology) at_discrete: "at x within S = bot"
   491   unfolding at_within_def nhds_discrete by simp
   492 
   493 lemma at_within_eq: "at x within s = (INF S:{S. open S \<and> x \<in> S}. principal (S \<inter> s - {x}))"
   494   unfolding nhds_def at_within_def
   495   by (subst INF_inf_const2[symmetric]) (auto simp: Diff_Int_distrib)
   496 
   497 lemma eventually_at_filter:
   498   "eventually P (at a within s) \<longleftrightarrow> eventually (\<lambda>x. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x) (nhds a)"
   499   by (simp add: at_within_def eventually_inf_principal imp_conjL[symmetric] conj_commute)
   500 
   501 lemma at_le: "s \<subseteq> t \<Longrightarrow> at x within s \<le> at x within t"
   502   unfolding at_within_def by (intro inf_mono) auto
   503 
   504 lemma eventually_at_topological:
   505   "eventually P (at a within s) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x))"
   506   by (simp add: eventually_nhds eventually_at_filter)
   507 
   508 lemma at_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> at a within S = at a"
   509   unfolding filter_eq_iff eventually_at_topological by (metis open_Int Int_iff UNIV_I)
   510 
   511 lemma at_within_open_NO_MATCH: "a \<in> s \<Longrightarrow> open s \<Longrightarrow> NO_MATCH UNIV s \<Longrightarrow> at a within s = at a"
   512   by (simp only: at_within_open)
   513 
   514 lemma at_within_nhd:
   515   assumes "x \<in> S" "open S" "T \<inter> S - {x} = U \<inter> S - {x}"
   516   shows "at x within T = at x within U"
   517   unfolding filter_eq_iff eventually_at_filter
   518 proof (intro allI eventually_subst)
   519   have "eventually (\<lambda>x. x \<in> S) (nhds x)"
   520     using \<open>x \<in> S\<close> \<open>open S\<close> by (auto simp: eventually_nhds)
   521   then show "\<forall>\<^sub>F n in nhds x. (n \<noteq> x \<longrightarrow> n \<in> T \<longrightarrow> P n) = (n \<noteq> x \<longrightarrow> n \<in> U \<longrightarrow> P n)" for P
   522     by eventually_elim (insert \<open>T \<inter> S - {x} = U \<inter> S - {x}\<close>, blast)
   523 qed
   524 
   525 lemma at_within_empty [simp]: "at a within {} = bot"
   526   unfolding at_within_def by simp
   527 
   528 lemma at_within_union: "at x within (S \<union> T) = sup (at x within S) (at x within T)"
   529   unfolding filter_eq_iff eventually_sup eventually_at_filter
   530   by (auto elim!: eventually_rev_mp)
   531 
   532 lemma at_eq_bot_iff: "at a = bot \<longleftrightarrow> open {a}"
   533   unfolding trivial_limit_def eventually_at_topological
   534   apply safe
   535    apply (case_tac "S = {a}")
   536     apply simp
   537    apply fast
   538   apply fast
   539   done
   540 
   541 lemma at_neq_bot [simp]: "at a \<noteq> bot"
   542   for a :: "'a::perfect_space"
   543   by (simp add: at_eq_bot_iff not_open_singleton)
   544 
   545 lemma (in order_topology) nhds_order:
   546   "nhds x = inf (INF a:{x <..}. principal {..< a}) (INF a:{..< x}. principal {a <..})"
   547 proof -
   548   have 1: "{S \<in> range lessThan \<union> range greaterThan. x \<in> S} =
   549       (\<lambda>a. {..< a}) ` {x <..} \<union> (\<lambda>a. {a <..}) ` {..< x}"
   550     by auto
   551   show ?thesis
   552     by (simp only: nhds_generated_topology[OF open_generated_order] INF_union 1 INF_image comp_def)
   553 qed
   554 
   555 lemma filterlim_at_within_If:
   556   assumes "filterlim f G (at x within (A \<inter> {x. P x}))"
   557     and "filterlim g G (at x within (A \<inter> {x. \<not>P x}))"
   558   shows "filterlim (\<lambda>x. if P x then f x else g x) G (at x within A)"
   559 proof (rule filterlim_If)
   560   note assms(1)
   561   also have "at x within (A \<inter> {x. P x}) = inf (nhds x) (principal (A \<inter> Collect P - {x}))"
   562     by (simp add: at_within_def)
   563   also have "A \<inter> Collect P - {x} = (A - {x}) \<inter> Collect P"
   564     by blast
   565   also have "inf (nhds x) (principal \<dots>) = inf (at x within A) (principal (Collect P))"
   566     by (simp add: at_within_def inf_assoc)
   567   finally show "filterlim f G (inf (at x within A) (principal (Collect P)))" .
   568 next
   569   note assms(2)
   570   also have "at x within (A \<inter> {x. \<not> P x}) = inf (nhds x) (principal (A \<inter> {x. \<not> P x} - {x}))"
   571     by (simp add: at_within_def)
   572   also have "A \<inter> {x. \<not> P x} - {x} = (A - {x}) \<inter> {x. \<not> P x}"
   573     by blast
   574   also have "inf (nhds x) (principal \<dots>) = inf (at x within A) (principal {x. \<not> P x})"
   575     by (simp add: at_within_def inf_assoc)
   576   finally show "filterlim g G (inf (at x within A) (principal {x. \<not> P x}))" .
   577 qed
   578 
   579 lemma filterlim_at_If:
   580   assumes "filterlim f G (at x within {x. P x})"
   581     and "filterlim g G (at x within {x. \<not>P x})"
   582   shows "filterlim (\<lambda>x. if P x then f x else g x) G (at x)"
   583   using assms by (intro filterlim_at_within_If) simp_all
   584 
   585 lemma (in linorder_topology) at_within_order:
   586   assumes "UNIV \<noteq> {x}"
   587   shows "at x within s =
   588     inf (INF a:{x <..}. principal ({..< a} \<inter> s - {x}))
   589         (INF a:{..< x}. principal ({a <..} \<inter> s - {x}))"
   590 proof (cases "{x <..} = {}" "{..< x} = {}" rule: case_split [case_product case_split])
   591   case True_True
   592   have "UNIV = {..< x} \<union> {x} \<union> {x <..}"
   593     by auto
   594   with assms True_True show ?thesis
   595     by auto
   596 qed (auto simp del: inf_principal simp: at_within_def nhds_order Int_Diff
   597       inf_principal[symmetric] INF_inf_const2 inf_sup_aci[where 'a="'a filter"])
   598 
   599 lemma (in linorder_topology) at_left_eq:
   600   "y < x \<Longrightarrow> at_left x = (INF a:{..< x}. principal {a <..< x})"
   601   by (subst at_within_order)
   602      (auto simp: greaterThan_Int_greaterThan greaterThanLessThan_eq[symmetric] min.absorb2 INF_constant
   603            intro!: INF_lower2 inf_absorb2)
   604 
   605 lemma (in linorder_topology) eventually_at_left:
   606   "y < x \<Longrightarrow> eventually P (at_left x) \<longleftrightarrow> (\<exists>b<x. \<forall>y>b. y < x \<longrightarrow> P y)"
   607   unfolding at_left_eq
   608   by (subst eventually_INF_base) (auto simp: eventually_principal Ball_def)
   609 
   610 lemma (in linorder_topology) at_right_eq:
   611   "x < y \<Longrightarrow> at_right x = (INF a:{x <..}. principal {x <..< a})"
   612   by (subst at_within_order)
   613      (auto simp: lessThan_Int_lessThan greaterThanLessThan_eq[symmetric] max.absorb2 INF_constant Int_commute
   614            intro!: INF_lower2 inf_absorb1)
   615 
   616 lemma (in linorder_topology) eventually_at_right:
   617   "x < y \<Longrightarrow> eventually P (at_right x) \<longleftrightarrow> (\<exists>b>x. \<forall>y>x. y < b \<longrightarrow> P y)"
   618   unfolding at_right_eq
   619   by (subst eventually_INF_base) (auto simp: eventually_principal Ball_def)
   620 
   621 lemma eventually_at_right_less: "\<forall>\<^sub>F y in at_right (x::'a::{linorder_topology, no_top}). x < y"
   622   using gt_ex[of x] eventually_at_right[of x] by auto
   623 
   624 lemma trivial_limit_at_right_top: "at_right (top::_::{order_top,linorder_topology}) = bot"
   625   by (auto simp: filter_eq_iff eventually_at_topological)
   626 
   627 lemma trivial_limit_at_left_bot: "at_left (bot::_::{order_bot,linorder_topology}) = bot"
   628   by (auto simp: filter_eq_iff eventually_at_topological)
   629 
   630 lemma trivial_limit_at_left_real [simp]: "\<not> trivial_limit (at_left x)"
   631   for x :: "'a::{no_bot,dense_order,linorder_topology}"
   632   using lt_ex [of x]
   633   by safe (auto simp add: trivial_limit_def eventually_at_left dest: dense)
   634 
   635 lemma trivial_limit_at_right_real [simp]: "\<not> trivial_limit (at_right x)"
   636   for x :: "'a::{no_top,dense_order,linorder_topology}"
   637   using gt_ex[of x]
   638   by safe (auto simp add: trivial_limit_def eventually_at_right dest: dense)
   639 
   640 lemma at_eq_sup_left_right: "at x = sup (at_left x) (at_right x)"
   641   for x :: "'a::linorder_topology"
   642   by (auto simp: eventually_at_filter filter_eq_iff eventually_sup
   643       elim: eventually_elim2 eventually_mono)
   644 
   645 lemma eventually_at_split:
   646   "eventually P (at x) \<longleftrightarrow> eventually P (at_left x) \<and> eventually P (at_right x)"
   647   for x :: "'a::linorder_topology"
   648   by (subst at_eq_sup_left_right) (simp add: eventually_sup)
   649 
   650 lemma eventually_at_leftI:
   651   assumes "\<And>x. x \<in> {a<..<b} \<Longrightarrow> P x" "a < b"
   652   shows   "eventually P (at_left b)"
   653   using assms unfolding eventually_at_topological by (intro exI[of _ "{a<..}"]) auto
   654 
   655 lemma eventually_at_rightI:
   656   assumes "\<And>x. x \<in> {a<..<b} \<Longrightarrow> P x" "a < b"
   657   shows   "eventually P (at_right a)"
   658   using assms unfolding eventually_at_topological by (intro exI[of _ "{..<b}"]) auto
   659 
   660 
   661 subsubsection \<open>Tendsto\<close>
   662 
   663 abbreviation (in topological_space)
   664   tendsto :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b filter \<Rightarrow> bool"  (infixr "\<longlongrightarrow>" 55)
   665   where "(f \<longlongrightarrow> l) F \<equiv> filterlim f (nhds l) F"
   666 
   667 definition (in t2_space) Lim :: "'f filter \<Rightarrow> ('f \<Rightarrow> 'a) \<Rightarrow> 'a"
   668   where "Lim A f = (THE l. (f \<longlongrightarrow> l) A)"
   669 
   670 lemma tendsto_eq_rhs: "(f \<longlongrightarrow> x) F \<Longrightarrow> x = y \<Longrightarrow> (f \<longlongrightarrow> y) F"
   671   by simp
   672 
   673 named_theorems tendsto_intros "introduction rules for tendsto"
   674 setup \<open>
   675   Global_Theory.add_thms_dynamic (@{binding tendsto_eq_intros},
   676     fn context =>
   677       Named_Theorems.get (Context.proof_of context) @{named_theorems tendsto_intros}
   678       |> map_filter (try (fn thm => @{thm tendsto_eq_rhs} OF [thm])))
   679 \<close>
   680 
   681 lemma (in topological_space) tendsto_def:
   682    "(f \<longlongrightarrow> l) F \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) F)"
   683    unfolding nhds_def filterlim_INF filterlim_principal by auto
   684 
   685 lemma tendsto_cong: "(f \<longlongrightarrow> c) F \<longleftrightarrow> (g \<longlongrightarrow> c) F" if "eventually (\<lambda>x. f x = g x) F"
   686   by (rule filterlim_cong [OF refl refl that])
   687 
   688 lemma tendsto_mono: "F \<le> F' \<Longrightarrow> (f \<longlongrightarrow> l) F' \<Longrightarrow> (f \<longlongrightarrow> l) F"
   689   unfolding tendsto_def le_filter_def by fast
   690 
   691 lemma tendsto_within_subset: "(f \<longlongrightarrow> l) (at x within S) \<Longrightarrow> T \<subseteq> S \<Longrightarrow> (f \<longlongrightarrow> l) (at x within T)"
   692   by (blast intro: tendsto_mono at_le)
   693 
   694 lemma filterlim_at:
   695   "(LIM x F. f x :> at b within s) \<longleftrightarrow> eventually (\<lambda>x. f x \<in> s \<and> f x \<noteq> b) F \<and> (f \<longlongrightarrow> b) F"
   696   by (simp add: at_within_def filterlim_inf filterlim_principal conj_commute)
   697 
   698 lemma filterlim_at_withinI:
   699   assumes "filterlim f (nhds c) F"
   700   assumes "eventually (\<lambda>x. f x \<in> A - {c}) F"
   701   shows   "filterlim f (at c within A) F"
   702   using assms by (simp add: filterlim_at) 
   703 
   704 lemma filterlim_atI:
   705   assumes "filterlim f (nhds c) F"
   706   assumes "eventually (\<lambda>x. f x \<noteq> c) F"
   707   shows   "filterlim f (at c) F"
   708   using assms by (intro filterlim_at_withinI) simp_all
   709 
   710 lemma (in topological_space) topological_tendstoI:
   711   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F) \<Longrightarrow> (f \<longlongrightarrow> l) F"
   712   by (auto simp: tendsto_def)
   713 
   714 lemma (in topological_space) topological_tendstoD:
   715   "(f \<longlongrightarrow> l) F \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F"
   716   by (auto simp: tendsto_def)
   717 
   718 lemma (in order_topology) order_tendsto_iff:
   719   "(f \<longlongrightarrow> x) F \<longleftrightarrow> (\<forall>l<x. eventually (\<lambda>x. l < f x) F) \<and> (\<forall>u>x. eventually (\<lambda>x. f x < u) F)"
   720   by (auto simp: nhds_order filterlim_inf filterlim_INF filterlim_principal)
   721 
   722 lemma (in order_topology) order_tendstoI:
   723   "(\<And>a. a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F) \<Longrightarrow> (\<And>a. y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F) \<Longrightarrow>
   724     (f \<longlongrightarrow> y) F"
   725   by (auto simp: order_tendsto_iff)
   726 
   727 lemma (in order_topology) order_tendstoD:
   728   assumes "(f \<longlongrightarrow> y) F"
   729   shows "a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F"
   730     and "y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F"
   731   using assms by (auto simp: order_tendsto_iff)
   732 
   733 lemma tendsto_bot [simp]: "(f \<longlongrightarrow> a) bot"
   734   by (simp add: tendsto_def)
   735 
   736 lemma (in linorder_topology) tendsto_max:
   737   assumes X: "(X \<longlongrightarrow> x) net"
   738     and Y: "(Y \<longlongrightarrow> y) net"
   739   shows "((\<lambda>x. max (X x) (Y x)) \<longlongrightarrow> max x y) net"
   740 proof (rule order_tendstoI)
   741   fix a
   742   assume "a < max x y"
   743   then show "eventually (\<lambda>x. a < max (X x) (Y x)) net"
   744     using order_tendstoD(1)[OF X, of a] order_tendstoD(1)[OF Y, of a]
   745     by (auto simp: less_max_iff_disj elim: eventually_mono)
   746 next
   747   fix a
   748   assume "max x y < a"
   749   then show "eventually (\<lambda>x. max (X x) (Y x) < a) net"
   750     using order_tendstoD(2)[OF X, of a] order_tendstoD(2)[OF Y, of a]
   751     by (auto simp: eventually_conj_iff)
   752 qed
   753 
   754 lemma (in linorder_topology) tendsto_min:
   755   assumes X: "(X \<longlongrightarrow> x) net"
   756     and Y: "(Y \<longlongrightarrow> y) net"
   757   shows "((\<lambda>x. min (X x) (Y x)) \<longlongrightarrow> min x y) net"
   758 proof (rule order_tendstoI)
   759   fix a
   760   assume "a < min x y"
   761   then show "eventually (\<lambda>x. a < min (X x) (Y x)) net"
   762     using order_tendstoD(1)[OF X, of a] order_tendstoD(1)[OF Y, of a]
   763     by (auto simp: eventually_conj_iff)
   764 next
   765   fix a
   766   assume "min x y < a"
   767   then show "eventually (\<lambda>x. min (X x) (Y x) < a) net"
   768     using order_tendstoD(2)[OF X, of a] order_tendstoD(2)[OF Y, of a]
   769     by (auto simp: min_less_iff_disj elim: eventually_mono)
   770 qed
   771 
   772 lemma tendsto_ident_at [tendsto_intros, simp, intro]: "((\<lambda>x. x) \<longlongrightarrow> a) (at a within s)"
   773   by (auto simp: tendsto_def eventually_at_topological)
   774 
   775 lemma (in topological_space) tendsto_const [tendsto_intros, simp, intro]: "((\<lambda>x. k) \<longlongrightarrow> k) F"
   776   by (simp add: tendsto_def)
   777 
   778 lemma (in t2_space) tendsto_unique:
   779   assumes "F \<noteq> bot"
   780     and "(f \<longlongrightarrow> a) F"
   781     and "(f \<longlongrightarrow> b) F"
   782   shows "a = b"
   783 proof (rule ccontr)
   784   assume "a \<noteq> b"
   785   obtain U V where "open U" "open V" "a \<in> U" "b \<in> V" "U \<inter> V = {}"
   786     using hausdorff [OF \<open>a \<noteq> b\<close>] by fast
   787   have "eventually (\<lambda>x. f x \<in> U) F"
   788     using \<open>(f \<longlongrightarrow> a) F\<close> \<open>open U\<close> \<open>a \<in> U\<close> by (rule topological_tendstoD)
   789   moreover
   790   have "eventually (\<lambda>x. f x \<in> V) F"
   791     using \<open>(f \<longlongrightarrow> b) F\<close> \<open>open V\<close> \<open>b \<in> V\<close> by (rule topological_tendstoD)
   792   ultimately
   793   have "eventually (\<lambda>x. False) F"
   794   proof eventually_elim
   795     case (elim x)
   796     then have "f x \<in> U \<inter> V" by simp
   797     with \<open>U \<inter> V = {}\<close> show ?case by simp
   798   qed
   799   with \<open>\<not> trivial_limit F\<close> show "False"
   800     by (simp add: trivial_limit_def)
   801 qed
   802 
   803 lemma (in t2_space) tendsto_const_iff:
   804   fixes a b :: 'a
   805   assumes "\<not> trivial_limit F"
   806   shows "((\<lambda>x. a) \<longlongrightarrow> b) F \<longleftrightarrow> a = b"
   807   by (auto intro!: tendsto_unique [OF assms tendsto_const])
   808 
   809 lemma increasing_tendsto:
   810   fixes f :: "_ \<Rightarrow> 'a::order_topology"
   811   assumes bdd: "eventually (\<lambda>n. f n \<le> l) F"
   812     and en: "\<And>x. x < l \<Longrightarrow> eventually (\<lambda>n. x < f n) F"
   813   shows "(f \<longlongrightarrow> l) F"
   814   using assms by (intro order_tendstoI) (auto elim!: eventually_mono)
   815 
   816 lemma decreasing_tendsto:
   817   fixes f :: "_ \<Rightarrow> 'a::order_topology"
   818   assumes bdd: "eventually (\<lambda>n. l \<le> f n) F"
   819     and en: "\<And>x. l < x \<Longrightarrow> eventually (\<lambda>n. f n < x) F"
   820   shows "(f \<longlongrightarrow> l) F"
   821   using assms by (intro order_tendstoI) (auto elim!: eventually_mono)
   822 
   823 lemma tendsto_sandwich:
   824   fixes f g h :: "'a \<Rightarrow> 'b::order_topology"
   825   assumes ev: "eventually (\<lambda>n. f n \<le> g n) net" "eventually (\<lambda>n. g n \<le> h n) net"
   826   assumes lim: "(f \<longlongrightarrow> c) net" "(h \<longlongrightarrow> c) net"
   827   shows "(g \<longlongrightarrow> c) net"
   828 proof (rule order_tendstoI)
   829   fix a
   830   show "a < c \<Longrightarrow> eventually (\<lambda>x. a < g x) net"
   831     using order_tendstoD[OF lim(1), of a] ev by (auto elim: eventually_elim2)
   832 next
   833   fix a
   834   show "c < a \<Longrightarrow> eventually (\<lambda>x. g x < a) net"
   835     using order_tendstoD[OF lim(2), of a] ev by (auto elim: eventually_elim2)
   836 qed
   837 
   838 lemma limit_frequently_eq:
   839   fixes c d :: "'a::t1_space"
   840   assumes "F \<noteq> bot"
   841     and "frequently (\<lambda>x. f x = c) F"
   842     and "(f \<longlongrightarrow> d) F"
   843   shows "d = c"
   844 proof (rule ccontr)
   845   assume "d \<noteq> c"
   846   from t1_space[OF this] obtain U where "open U" "d \<in> U" "c \<notin> U"
   847     by blast
   848   with assms have "eventually (\<lambda>x. f x \<in> U) F"
   849     unfolding tendsto_def by blast
   850   then have "eventually (\<lambda>x. f x \<noteq> c) F"
   851     by eventually_elim (insert \<open>c \<notin> U\<close>, blast)
   852   with assms(2) show False
   853     unfolding frequently_def by contradiction
   854 qed
   855 
   856 lemma tendsto_imp_eventually_ne:
   857   fixes c :: "'a::t1_space"
   858   assumes "F \<noteq> bot" "(f \<longlongrightarrow> c) F" "c \<noteq> c'"
   859   shows "eventually (\<lambda>z. f z \<noteq> c') F"
   860 proof (rule ccontr)
   861   assume "\<not> eventually (\<lambda>z. f z \<noteq> c') F"
   862   then have "frequently (\<lambda>z. f z = c') F"
   863     by (simp add: frequently_def)
   864   from limit_frequently_eq[OF assms(1) this assms(2)] and assms(3) show False
   865     by contradiction
   866 qed
   867 
   868 lemma tendsto_le:
   869   fixes f g :: "'a \<Rightarrow> 'b::linorder_topology"
   870   assumes F: "\<not> trivial_limit F"
   871     and x: "(f \<longlongrightarrow> x) F"
   872     and y: "(g \<longlongrightarrow> y) F"
   873     and ev: "eventually (\<lambda>x. g x \<le> f x) F"
   874   shows "y \<le> x"
   875 proof (rule ccontr)
   876   assume "\<not> y \<le> x"
   877   with less_separate[of x y] obtain a b where xy: "x < a" "b < y" "{..<a} \<inter> {b<..} = {}"
   878     by (auto simp: not_le)
   879   then have "eventually (\<lambda>x. f x < a) F" "eventually (\<lambda>x. b < g x) F"
   880     using x y by (auto intro: order_tendstoD)
   881   with ev have "eventually (\<lambda>x. False) F"
   882     by eventually_elim (insert xy, fastforce)
   883   with F show False
   884     by (simp add: eventually_False)
   885 qed
   886 
   887 lemma tendsto_le_const:
   888   fixes f :: "'a \<Rightarrow> 'b::linorder_topology"
   889   assumes F: "\<not> trivial_limit F"
   890     and x: "(f \<longlongrightarrow> x) F"
   891     and ev: "eventually (\<lambda>i. a \<le> f i) F"
   892   shows "a \<le> x"
   893   using F x tendsto_const ev by (rule tendsto_le)
   894 
   895 lemma tendsto_ge_const:
   896   fixes f :: "'a \<Rightarrow> 'b::linorder_topology"
   897   assumes F: "\<not> trivial_limit F"
   898     and x: "(f \<longlongrightarrow> x) F"
   899     and ev: "eventually (\<lambda>i. a \<ge> f i) F"
   900   shows "a \<ge> x"
   901   by (rule tendsto_le [OF F tendsto_const x ev])
   902 
   903 
   904 subsubsection \<open>Rules about @{const Lim}\<close>
   905 
   906 lemma tendsto_Lim: "\<not> trivial_limit net \<Longrightarrow> (f \<longlongrightarrow> l) net \<Longrightarrow> Lim net f = l"
   907   unfolding Lim_def using tendsto_unique [of net f] by auto
   908 
   909 lemma Lim_ident_at: "\<not> trivial_limit (at x within s) \<Longrightarrow> Lim (at x within s) (\<lambda>x. x) = x"
   910   by (rule tendsto_Lim[OF _ tendsto_ident_at]) auto
   911 
   912 lemma filterlim_at_bot_at_right:
   913   fixes f :: "'a::linorder_topology \<Rightarrow> 'b::linorder"
   914   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
   915     and bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
   916     and Q: "eventually Q (at_right a)"
   917     and bound: "\<And>b. Q b \<Longrightarrow> a < b"
   918     and P: "eventually P at_bot"
   919   shows "filterlim f at_bot (at_right a)"
   920 proof -
   921   from P obtain x where x: "\<And>y. y \<le> x \<Longrightarrow> P y"
   922     unfolding eventually_at_bot_linorder by auto
   923   show ?thesis
   924   proof (intro filterlim_at_bot_le[THEN iffD2] allI impI)
   925     fix z
   926     assume "z \<le> x"
   927     with x have "P z" by auto
   928     have "eventually (\<lambda>x. x \<le> g z) (at_right a)"
   929       using bound[OF bij(2)[OF \<open>P z\<close>]]
   930       unfolding eventually_at_right[OF bound[OF bij(2)[OF \<open>P z\<close>]]]
   931       by (auto intro!: exI[of _ "g z"])
   932     with Q show "eventually (\<lambda>x. f x \<le> z) (at_right a)"
   933       by eventually_elim (metis bij \<open>P z\<close> mono)
   934   qed
   935 qed
   936 
   937 lemma filterlim_at_top_at_left:
   938   fixes f :: "'a::linorder_topology \<Rightarrow> 'b::linorder"
   939   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
   940     and bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
   941     and Q: "eventually Q (at_left a)"
   942     and bound: "\<And>b. Q b \<Longrightarrow> b < a"
   943     and P: "eventually P at_top"
   944   shows "filterlim f at_top (at_left a)"
   945 proof -
   946   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
   947     unfolding eventually_at_top_linorder by auto
   948   show ?thesis
   949   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
   950     fix z
   951     assume "x \<le> z"
   952     with x have "P z" by auto
   953     have "eventually (\<lambda>x. g z \<le> x) (at_left a)"
   954       using bound[OF bij(2)[OF \<open>P z\<close>]]
   955       unfolding eventually_at_left[OF bound[OF bij(2)[OF \<open>P z\<close>]]]
   956       by (auto intro!: exI[of _ "g z"])
   957     with Q show "eventually (\<lambda>x. z \<le> f x) (at_left a)"
   958       by eventually_elim (metis bij \<open>P z\<close> mono)
   959   qed
   960 qed
   961 
   962 lemma filterlim_split_at:
   963   "filterlim f F (at_left x) \<Longrightarrow> filterlim f F (at_right x) \<Longrightarrow>
   964     filterlim f F (at x)"
   965   for x :: "'a::linorder_topology"
   966   by (subst at_eq_sup_left_right) (rule filterlim_sup)
   967 
   968 lemma filterlim_at_split:
   969   "filterlim f F (at x) \<longleftrightarrow> filterlim f F (at_left x) \<and> filterlim f F (at_right x)"
   970   for x :: "'a::linorder_topology"
   971   by (subst at_eq_sup_left_right) (simp add: filterlim_def filtermap_sup)
   972 
   973 lemma eventually_nhds_top:
   974   fixes P :: "'a :: {order_top,linorder_topology} \<Rightarrow> bool"
   975     and b :: 'a
   976   assumes "b < top"
   977   shows "eventually P (nhds top) \<longleftrightarrow> (\<exists>b<top. (\<forall>z. b < z \<longrightarrow> P z))"
   978   unfolding eventually_nhds
   979 proof safe
   980   fix S :: "'a set"
   981   assume "open S" "top \<in> S"
   982   note open_left[OF this \<open>b < top\<close>]
   983   moreover assume "\<forall>s\<in>S. P s"
   984   ultimately show "\<exists>b<top. \<forall>z>b. P z"
   985     by (auto simp: subset_eq Ball_def)
   986 next
   987   fix b
   988   assume "b < top" "\<forall>z>b. P z"
   989   then show "\<exists>S. open S \<and> top \<in> S \<and> (\<forall>xa\<in>S. P xa)"
   990     by (intro exI[of _ "{b <..}"]) auto
   991 qed
   992 
   993 lemma tendsto_at_within_iff_tendsto_nhds:
   994   "(g \<longlongrightarrow> g l) (at l within S) \<longleftrightarrow> (g \<longlongrightarrow> g l) (inf (nhds l) (principal S))"
   995   unfolding tendsto_def eventually_at_filter eventually_inf_principal
   996   by (intro ext all_cong imp_cong) (auto elim!: eventually_mono)
   997 
   998 
   999 subsection \<open>Limits on sequences\<close>
  1000 
  1001 abbreviation (in topological_space)
  1002   LIMSEQ :: "[nat \<Rightarrow> 'a, 'a] \<Rightarrow> bool"  ("((_)/ \<longlonglongrightarrow> (_))" [60, 60] 60)
  1003   where "X \<longlonglongrightarrow> L \<equiv> (X \<longlongrightarrow> L) sequentially"
  1004 
  1005 abbreviation (in t2_space) lim :: "(nat \<Rightarrow> 'a) \<Rightarrow> 'a"
  1006   where "lim X \<equiv> Lim sequentially X"
  1007 
  1008 definition (in topological_space) convergent :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool"
  1009   where "convergent X = (\<exists>L. X \<longlonglongrightarrow> L)"
  1010 
  1011 lemma lim_def: "lim X = (THE L. X \<longlonglongrightarrow> L)"
  1012   unfolding Lim_def ..
  1013 
  1014 
  1015 subsubsection \<open>Monotone sequences and subsequences\<close>
  1016 
  1017 text \<open>
  1018   Definition of monotonicity.
  1019   The use of disjunction here complicates proofs considerably.
  1020   One alternative is to add a Boolean argument to indicate the direction.
  1021   Another is to develop the notions of increasing and decreasing first.
  1022 \<close>
  1023 definition monoseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool"
  1024   where "monoseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X m \<le> X n) \<or> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
  1025 
  1026 abbreviation incseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool"
  1027   where "incseq X \<equiv> mono X"
  1028 
  1029 lemma incseq_def: "incseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<ge> X m)"
  1030   unfolding mono_def ..
  1031 
  1032 abbreviation decseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool"
  1033   where "decseq X \<equiv> antimono X"
  1034 
  1035 lemma decseq_def: "decseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
  1036   unfolding antimono_def ..
  1037 
  1038 text \<open>Definition of subsequence.\<close>
  1039 definition subseq :: "(nat \<Rightarrow> nat) \<Rightarrow> bool"
  1040   where "subseq f \<longleftrightarrow> (\<forall>m. \<forall>n>m. f m < f n)"
  1041 
  1042 lemma incseq_SucI: "(\<And>n. X n \<le> X (Suc n)) \<Longrightarrow> incseq X"
  1043   using lift_Suc_mono_le[of X] by (auto simp: incseq_def)
  1044 
  1045 lemma incseqD: "incseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f i \<le> f j"
  1046   by (auto simp: incseq_def)
  1047 
  1048 lemma incseq_SucD: "incseq A \<Longrightarrow> A i \<le> A (Suc i)"
  1049   using incseqD[of A i "Suc i"] by auto
  1050 
  1051 lemma incseq_Suc_iff: "incseq f \<longleftrightarrow> (\<forall>n. f n \<le> f (Suc n))"
  1052   by (auto intro: incseq_SucI dest: incseq_SucD)
  1053 
  1054 lemma incseq_const[simp, intro]: "incseq (\<lambda>x. k)"
  1055   unfolding incseq_def by auto
  1056 
  1057 lemma decseq_SucI: "(\<And>n. X (Suc n) \<le> X n) \<Longrightarrow> decseq X"
  1058   using order.lift_Suc_mono_le[OF dual_order, of X] by (auto simp: decseq_def)
  1059 
  1060 lemma decseqD: "decseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f j \<le> f i"
  1061   by (auto simp: decseq_def)
  1062 
  1063 lemma decseq_SucD: "decseq A \<Longrightarrow> A (Suc i) \<le> A i"
  1064   using decseqD[of A i "Suc i"] by auto
  1065 
  1066 lemma decseq_Suc_iff: "decseq f \<longleftrightarrow> (\<forall>n. f (Suc n) \<le> f n)"
  1067   by (auto intro: decseq_SucI dest: decseq_SucD)
  1068 
  1069 lemma decseq_const[simp, intro]: "decseq (\<lambda>x. k)"
  1070   unfolding decseq_def by auto
  1071 
  1072 lemma monoseq_iff: "monoseq X \<longleftrightarrow> incseq X \<or> decseq X"
  1073   unfolding monoseq_def incseq_def decseq_def ..
  1074 
  1075 lemma monoseq_Suc: "monoseq X \<longleftrightarrow> (\<forall>n. X n \<le> X (Suc n)) \<or> (\<forall>n. X (Suc n) \<le> X n)"
  1076   unfolding monoseq_iff incseq_Suc_iff decseq_Suc_iff ..
  1077 
  1078 lemma monoI1: "\<forall>m. \<forall>n \<ge> m. X m \<le> X n \<Longrightarrow> monoseq X"
  1079   by (simp add: monoseq_def)
  1080 
  1081 lemma monoI2: "\<forall>m. \<forall>n \<ge> m. X n \<le> X m \<Longrightarrow> monoseq X"
  1082   by (simp add: monoseq_def)
  1083 
  1084 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) \<Longrightarrow> monoseq X"
  1085   by (simp add: monoseq_Suc)
  1086 
  1087 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n \<Longrightarrow> monoseq X"
  1088   by (simp add: monoseq_Suc)
  1089 
  1090 lemma monoseq_minus:
  1091   fixes a :: "nat \<Rightarrow> 'a::ordered_ab_group_add"
  1092   assumes "monoseq a"
  1093   shows "monoseq (\<lambda> n. - a n)"
  1094 proof (cases "\<forall>m. \<forall>n \<ge> m. a m \<le> a n")
  1095   case True
  1096   then have "\<forall>m. \<forall>n \<ge> m. - a n \<le> - a m" by auto
  1097   then show ?thesis by (rule monoI2)
  1098 next
  1099   case False
  1100   then have "\<forall>m. \<forall>n \<ge> m. - a m \<le> - a n"
  1101     using \<open>monoseq a\<close>[unfolded monoseq_def] by auto
  1102   then show ?thesis by (rule monoI1)
  1103 qed
  1104 
  1105 
  1106 text \<open>Subsequence (alternative definition, (e.g. Hoskins)\<close>
  1107 
  1108 lemma subseq_Suc_iff: "subseq f \<longleftrightarrow> (\<forall>n. f n < f (Suc n))"
  1109   apply (simp add: subseq_def)
  1110   apply (auto dest!: less_imp_Suc_add)
  1111   apply (induct_tac k)
  1112    apply (auto intro: less_trans)
  1113   done
  1114 
  1115 lemma subseq_add: "subseq (\<lambda>n. n + k)"
  1116   by (auto simp: subseq_Suc_iff)
  1117 
  1118 text \<open>For any sequence, there is a monotonic subsequence.\<close>
  1119 lemma seq_monosub:
  1120   fixes s :: "nat \<Rightarrow> 'a::linorder"
  1121   shows "\<exists>f. subseq f \<and> monoseq (\<lambda>n. (s (f n)))"
  1122 proof (cases "\<forall>n. \<exists>p>n. \<forall>m\<ge>p. s m \<le> s p")
  1123   case True
  1124   then have "\<exists>f. \<forall>n. (\<forall>m\<ge>f n. s m \<le> s (f n)) \<and> f n < f (Suc n)"
  1125     by (intro dependent_nat_choice) (auto simp: conj_commute)
  1126   then obtain f where f: "subseq f" and mono: "\<And>n m. f n \<le> m \<Longrightarrow> s m \<le> s (f n)"
  1127     by (auto simp: subseq_Suc_iff)
  1128   then have "incseq f"
  1129     unfolding subseq_Suc_iff incseq_Suc_iff by (auto intro: less_imp_le)
  1130   then have "monoseq (\<lambda>n. s (f n))"
  1131     by (auto simp add: incseq_def intro!: mono monoI2)
  1132   with f show ?thesis
  1133     by auto
  1134 next
  1135   case False
  1136   then obtain N where N: "p > N \<Longrightarrow> \<exists>m>p. s p < s m" for p
  1137     by (force simp: not_le le_less)
  1138   have "\<exists>f. \<forall>n. N < f n \<and> f n < f (Suc n) \<and> s (f n) \<le> s (f (Suc n))"
  1139   proof (intro dependent_nat_choice)
  1140     fix x
  1141     assume "N < x" with N[of x]
  1142     show "\<exists>y>N. x < y \<and> s x \<le> s y"
  1143       by (auto intro: less_trans)
  1144   qed auto
  1145   then show ?thesis
  1146     by (auto simp: monoseq_iff incseq_Suc_iff subseq_Suc_iff)
  1147 qed
  1148 
  1149 lemma seq_suble:
  1150   assumes sf: "subseq f"
  1151   shows "n \<le> f n"
  1152 proof (induct n)
  1153   case 0
  1154   show ?case by simp
  1155 next
  1156   case (Suc n)
  1157   with sf [unfolded subseq_Suc_iff, rule_format, of n] have "n < f (Suc n)"
  1158      by arith
  1159   then show ?case by arith
  1160 qed
  1161 
  1162 lemma eventually_subseq:
  1163   "subseq r \<Longrightarrow> eventually P sequentially \<Longrightarrow> eventually (\<lambda>n. P (r n)) sequentially"
  1164   unfolding eventually_sequentially by (metis seq_suble le_trans)
  1165 
  1166 lemma not_eventually_sequentiallyD:
  1167   assumes "\<not> eventually P sequentially"
  1168   shows "\<exists>r. subseq r \<and> (\<forall>n. \<not> P (r n))"
  1169 proof -
  1170   from assms have "\<forall>n. \<exists>m\<ge>n. \<not> P m"
  1171     unfolding eventually_sequentially by (simp add: not_less)
  1172   then obtain r where "\<And>n. r n \<ge> n" "\<And>n. \<not> P (r n)"
  1173     by (auto simp: choice_iff)
  1174   then show ?thesis
  1175     by (auto intro!: exI[of _ "\<lambda>n. r (((Suc \<circ> r) ^^ Suc n) 0)"]
  1176              simp: less_eq_Suc_le subseq_Suc_iff)
  1177 qed
  1178 
  1179 lemma filterlim_subseq: "subseq f \<Longrightarrow> filterlim f sequentially sequentially"
  1180   unfolding filterlim_iff by (metis eventually_subseq)
  1181 
  1182 lemma subseq_o: "subseq r \<Longrightarrow> subseq s \<Longrightarrow> subseq (r \<circ> s)"
  1183   unfolding subseq_def by simp
  1184 
  1185 lemma subseq_mono: "subseq r \<Longrightarrow> m < n \<Longrightarrow> r m < r n"
  1186   by (auto simp: subseq_def)
  1187 
  1188 lemma subseq_imp_inj_on: "subseq g \<Longrightarrow> inj_on g A"
  1189 proof (rule inj_onI)
  1190   assume g: "subseq g"
  1191   fix x y
  1192   assume "g x = g y"
  1193   with subseq_mono[OF g, of x y] subseq_mono[OF g, of y x] show "x = y"
  1194     by (cases x y rule: linorder_cases) simp_all
  1195 qed
  1196 
  1197 lemma subseq_strict_mono: "subseq g \<Longrightarrow> strict_mono g"
  1198   by (intro strict_monoI subseq_mono[of g])
  1199 
  1200 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
  1201   by (simp add: incseq_def monoseq_def)
  1202 
  1203 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
  1204   by (simp add: decseq_def monoseq_def)
  1205 
  1206 lemma decseq_eq_incseq: "decseq X = incseq (\<lambda>n. - X n)"
  1207   for X :: "nat \<Rightarrow> 'a::ordered_ab_group_add"
  1208   by (simp add: decseq_def incseq_def)
  1209 
  1210 lemma INT_decseq_offset:
  1211   assumes "decseq F"
  1212   shows "(\<Inter>i. F i) = (\<Inter>i\<in>{n..}. F i)"
  1213 proof safe
  1214   fix x i
  1215   assume x: "x \<in> (\<Inter>i\<in>{n..}. F i)"
  1216   show "x \<in> F i"
  1217   proof cases
  1218     from x have "x \<in> F n" by auto
  1219     also assume "i \<le> n" with \<open>decseq F\<close> have "F n \<subseteq> F i"
  1220       unfolding decseq_def by simp
  1221     finally show ?thesis .
  1222   qed (insert x, simp)
  1223 qed auto
  1224 
  1225 lemma LIMSEQ_const_iff: "(\<lambda>n. k) \<longlonglongrightarrow> l \<longleftrightarrow> k = l"
  1226   for k l :: "'a::t2_space"
  1227   using trivial_limit_sequentially by (rule tendsto_const_iff)
  1228 
  1229 lemma LIMSEQ_SUP: "incseq X \<Longrightarrow> X \<longlonglongrightarrow> (SUP i. X i :: 'a::{complete_linorder,linorder_topology})"
  1230   by (intro increasing_tendsto)
  1231     (auto simp: SUP_upper less_SUP_iff incseq_def eventually_sequentially intro: less_le_trans)
  1232 
  1233 lemma LIMSEQ_INF: "decseq X \<Longrightarrow> X \<longlonglongrightarrow> (INF i. X i :: 'a::{complete_linorder,linorder_topology})"
  1234   by (intro decreasing_tendsto)
  1235     (auto simp: INF_lower INF_less_iff decseq_def eventually_sequentially intro: le_less_trans)
  1236 
  1237 lemma LIMSEQ_ignore_initial_segment: "f \<longlonglongrightarrow> a \<Longrightarrow> (\<lambda>n. f (n + k)) \<longlonglongrightarrow> a"
  1238   unfolding tendsto_def by (subst eventually_sequentially_seg[where k=k])
  1239 
  1240 lemma LIMSEQ_offset: "(\<lambda>n. f (n + k)) \<longlonglongrightarrow> a \<Longrightarrow> f \<longlonglongrightarrow> a"
  1241   unfolding tendsto_def
  1242   by (subst (asm) eventually_sequentially_seg[where k=k])
  1243 
  1244 lemma LIMSEQ_Suc: "f \<longlonglongrightarrow> l \<Longrightarrow> (\<lambda>n. f (Suc n)) \<longlonglongrightarrow> l"
  1245   by (drule LIMSEQ_ignore_initial_segment [where k="Suc 0"]) simp
  1246 
  1247 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) \<longlonglongrightarrow> l \<Longrightarrow> f \<longlonglongrightarrow> l"
  1248   by (rule LIMSEQ_offset [where k="Suc 0"]) simp
  1249 
  1250 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) \<longlonglongrightarrow> l = f \<longlonglongrightarrow> l"
  1251   by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
  1252 
  1253 lemma LIMSEQ_unique: "X \<longlonglongrightarrow> a \<Longrightarrow> X \<longlonglongrightarrow> b \<Longrightarrow> a = b"
  1254   for a b :: "'a::t2_space"
  1255   using trivial_limit_sequentially by (rule tendsto_unique)
  1256 
  1257 lemma LIMSEQ_le_const: "X \<longlonglongrightarrow> x \<Longrightarrow> \<exists>N. \<forall>n\<ge>N. a \<le> X n \<Longrightarrow> a \<le> x"
  1258   for a x :: "'a::linorder_topology"
  1259   using tendsto_le_const[of sequentially X x a] by (simp add: eventually_sequentially)
  1260 
  1261 lemma LIMSEQ_le: "X \<longlonglongrightarrow> x \<Longrightarrow> Y \<longlonglongrightarrow> y \<Longrightarrow> \<exists>N. \<forall>n\<ge>N. X n \<le> Y n \<Longrightarrow> x \<le> y"
  1262   for x y :: "'a::linorder_topology"
  1263   using tendsto_le[of sequentially Y y X x] by (simp add: eventually_sequentially)
  1264 
  1265 lemma LIMSEQ_le_const2: "X \<longlonglongrightarrow> x \<Longrightarrow> \<exists>N. \<forall>n\<ge>N. X n \<le> a \<Longrightarrow> x \<le> a"
  1266   for a x :: "'a::linorder_topology"
  1267   by (rule LIMSEQ_le[of X x "\<lambda>n. a"]) auto
  1268 
  1269 lemma convergentD: "convergent X \<Longrightarrow> \<exists>L. X \<longlonglongrightarrow> L"
  1270   by (simp add: convergent_def)
  1271 
  1272 lemma convergentI: "X \<longlonglongrightarrow> L \<Longrightarrow> convergent X"
  1273   by (auto simp add: convergent_def)
  1274 
  1275 lemma convergent_LIMSEQ_iff: "convergent X \<longleftrightarrow> X \<longlonglongrightarrow> lim X"
  1276   by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
  1277 
  1278 lemma convergent_const: "convergent (\<lambda>n. c)"
  1279   by (rule convergentI) (rule tendsto_const)
  1280 
  1281 lemma monoseq_le:
  1282   "monoseq a \<Longrightarrow> a \<longlonglongrightarrow> x \<Longrightarrow>
  1283     (\<forall>n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n) \<or>
  1284     (\<forall>n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m)"
  1285   for x :: "'a::linorder_topology"
  1286   by (metis LIMSEQ_le_const LIMSEQ_le_const2 decseq_def incseq_def monoseq_iff)
  1287 
  1288 lemma LIMSEQ_subseq_LIMSEQ: "X \<longlonglongrightarrow> L \<Longrightarrow> subseq f \<Longrightarrow> (X \<circ> f) \<longlonglongrightarrow> L"
  1289   unfolding comp_def by (rule filterlim_compose [of X, OF _ filterlim_subseq])
  1290 
  1291 lemma convergent_subseq_convergent: "convergent X \<Longrightarrow> subseq f \<Longrightarrow> convergent (X \<circ> f)"
  1292   by (auto simp: convergent_def intro: LIMSEQ_subseq_LIMSEQ)
  1293 
  1294 lemma limI: "X \<longlonglongrightarrow> L \<Longrightarrow> lim X = L"
  1295   by (rule tendsto_Lim) (rule trivial_limit_sequentially)
  1296 
  1297 lemma lim_le: "convergent f \<Longrightarrow> (\<And>n. f n \<le> x) \<Longrightarrow> lim f \<le> x"
  1298   for x :: "'a::linorder_topology"
  1299   using LIMSEQ_le_const2[of f "lim f" x] by (simp add: convergent_LIMSEQ_iff)
  1300 
  1301 lemma lim_const [simp]: "lim (\<lambda>m. a) = a"
  1302   by (simp add: limI)
  1303 
  1304 
  1305 subsubsection \<open>Increasing and Decreasing Series\<close>
  1306 
  1307 lemma incseq_le: "incseq X \<Longrightarrow> X \<longlonglongrightarrow> L \<Longrightarrow> X n \<le> L"
  1308   for L :: "'a::linorder_topology"
  1309   by (metis incseq_def LIMSEQ_le_const)
  1310 
  1311 lemma decseq_le: "decseq X \<Longrightarrow> X \<longlonglongrightarrow> L \<Longrightarrow> L \<le> X n"
  1312   for L :: "'a::linorder_topology"
  1313   by (metis decseq_def LIMSEQ_le_const2)
  1314 
  1315 
  1316 subsection \<open>First countable topologies\<close>
  1317 
  1318 class first_countable_topology = topological_space +
  1319   assumes first_countable_basis:
  1320     "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
  1321 
  1322 lemma (in first_countable_topology) countable_basis_at_decseq:
  1323   obtains A :: "nat \<Rightarrow> 'a set" where
  1324     "\<And>i. open (A i)" "\<And>i. x \<in> (A i)"
  1325     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1326 proof atomize_elim
  1327   from first_countable_basis[of x] obtain A :: "nat \<Rightarrow> 'a set"
  1328     where nhds: "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1329       and incl: "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>i. A i \<subseteq> S"
  1330     by auto
  1331   define F where "F n = (\<Inter>i\<le>n. A i)" for n
  1332   show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and>
  1333     (\<forall>S. open S \<longrightarrow> x \<in> S \<longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially)"
  1334   proof (safe intro!: exI[of _ F])
  1335     fix i
  1336     show "open (F i)"
  1337       using nhds(1) by (auto simp: F_def)
  1338     show "x \<in> F i"
  1339       using nhds(2) by (auto simp: F_def)
  1340   next
  1341     fix S
  1342     assume "open S" "x \<in> S"
  1343     from incl[OF this] obtain i where "F i \<subseteq> S"
  1344       unfolding F_def by auto
  1345     moreover have "\<And>j. i \<le> j \<Longrightarrow> F j \<subseteq> F i"
  1346       by (simp add: Inf_superset_mono F_def image_mono)
  1347     ultimately show "eventually (\<lambda>i. F i \<subseteq> S) sequentially"
  1348       by (auto simp: eventually_sequentially)
  1349   qed
  1350 qed
  1351 
  1352 lemma (in first_countable_topology) nhds_countable:
  1353   obtains X :: "nat \<Rightarrow> 'a set"
  1354   where "decseq X" "\<And>n. open (X n)" "\<And>n. x \<in> X n" "nhds x = (INF n. principal (X n))"
  1355 proof -
  1356   from first_countable_basis obtain A :: "nat \<Rightarrow> 'a set"
  1357     where *: "\<And>n. x \<in> A n" "\<And>n. open (A n)" "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>i. A i \<subseteq> S"
  1358     by metis
  1359   show thesis
  1360   proof
  1361     show "decseq (\<lambda>n. \<Inter>i\<le>n. A i)"
  1362       by (simp add: antimono_iff_le_Suc atMost_Suc)
  1363     show "x \<in> (\<Inter>i\<le>n. A i)" "\<And>n. open (\<Inter>i\<le>n. A i)" for n
  1364       using * by auto
  1365     show "nhds x = (INF n. principal (\<Inter>i\<le>n. A i))"
  1366       using *
  1367       unfolding nhds_def
  1368       apply -
  1369       apply (rule INF_eq)
  1370        apply simp_all
  1371        apply fastforce
  1372       apply (intro exI [of _ "\<Inter>i\<le>n. A i" for n] conjI open_INT)
  1373          apply auto
  1374       done
  1375   qed
  1376 qed
  1377 
  1378 lemma (in first_countable_topology) countable_basis:
  1379   obtains A :: "nat \<Rightarrow> 'a set" where
  1380     "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1381     "\<And>F. (\<forall>n. F n \<in> A n) \<Longrightarrow> F \<longlonglongrightarrow> x"
  1382 proof atomize_elim
  1383   obtain A :: "nat \<Rightarrow> 'a set" where *:
  1384     "\<And>i. open (A i)"
  1385     "\<And>i. x \<in> A i"
  1386     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1387     by (rule countable_basis_at_decseq) blast
  1388   have "eventually (\<lambda>n. F n \<in> S) sequentially"
  1389     if "\<forall>n. F n \<in> A n" "open S" "x \<in> S" for F S
  1390     using *(3)[of S] that by (auto elim: eventually_mono simp: subset_eq)
  1391   with * show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and> (\<forall>F. (\<forall>n. F n \<in> A n) \<longrightarrow> F \<longlonglongrightarrow> x)"
  1392     by (intro exI[of _ A]) (auto simp: tendsto_def)
  1393 qed
  1394 
  1395 lemma (in first_countable_topology) sequentially_imp_eventually_nhds_within:
  1396   assumes "\<forall>f. (\<forall>n. f n \<in> s) \<and> f \<longlonglongrightarrow> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  1397   shows "eventually P (inf (nhds a) (principal s))"
  1398 proof (rule ccontr)
  1399   obtain A :: "nat \<Rightarrow> 'a set" where *:
  1400     "\<And>i. open (A i)"
  1401     "\<And>i. a \<in> A i"
  1402     "\<And>F. \<forall>n. F n \<in> A n \<Longrightarrow> F \<longlonglongrightarrow> a"
  1403     by (rule countable_basis) blast
  1404   assume "\<not> ?thesis"
  1405   with * have "\<exists>F. \<forall>n. F n \<in> s \<and> F n \<in> A n \<and> \<not> P (F n)"
  1406     unfolding eventually_inf_principal eventually_nhds
  1407     by (intro choice) fastforce
  1408   then obtain F where F: "\<forall>n. F n \<in> s" and "\<forall>n. F n \<in> A n" and F': "\<forall>n. \<not> P (F n)"
  1409     by blast
  1410   with * have "F \<longlonglongrightarrow> a"
  1411     by auto
  1412   then have "eventually (\<lambda>n. P (F n)) sequentially"
  1413     using assms F by simp
  1414   then show False
  1415     by (simp add: F')
  1416 qed
  1417 
  1418 lemma (in first_countable_topology) eventually_nhds_within_iff_sequentially:
  1419   "eventually P (inf (nhds a) (principal s)) \<longleftrightarrow>
  1420     (\<forall>f. (\<forall>n. f n \<in> s) \<and> f \<longlonglongrightarrow> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1421 proof (safe intro!: sequentially_imp_eventually_nhds_within)
  1422   assume "eventually P (inf (nhds a) (principal s))"
  1423   then obtain S where "open S" "a \<in> S" "\<forall>x\<in>S. x \<in> s \<longrightarrow> P x"
  1424     by (auto simp: eventually_inf_principal eventually_nhds)
  1425   moreover
  1426   fix f
  1427   assume "\<forall>n. f n \<in> s" "f \<longlonglongrightarrow> a"
  1428   ultimately show "eventually (\<lambda>n. P (f n)) sequentially"
  1429     by (auto dest!: topological_tendstoD elim: eventually_mono)
  1430 qed
  1431 
  1432 lemma (in first_countable_topology) eventually_nhds_iff_sequentially:
  1433   "eventually P (nhds a) \<longleftrightarrow> (\<forall>f. f \<longlonglongrightarrow> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1434   using eventually_nhds_within_iff_sequentially[of P a UNIV] by simp
  1435 
  1436 lemma tendsto_at_iff_sequentially:
  1437   "(f \<longlongrightarrow> a) (at x within s) \<longleftrightarrow> (\<forall>X. (\<forall>i. X i \<in> s - {x}) \<longrightarrow> X \<longlonglongrightarrow> x \<longrightarrow> ((f \<circ> X) \<longlonglongrightarrow> a))"
  1438   for f :: "'a::first_countable_topology \<Rightarrow> _"
  1439   unfolding filterlim_def[of _ "nhds a"] le_filter_def eventually_filtermap
  1440     at_within_def eventually_nhds_within_iff_sequentially comp_def
  1441   by metis
  1442 
  1443 
  1444 subsection \<open>Function limit at a point\<close>
  1445 
  1446 abbreviation LIM :: "('a::topological_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
  1447     ("((_)/ \<midarrow>(_)/\<rightarrow> (_))" [60, 0, 60] 60)
  1448   where "f \<midarrow>a\<rightarrow> L \<equiv> (f \<longlongrightarrow> L) (at a)"
  1449 
  1450 lemma tendsto_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> (f \<longlongrightarrow> l) (at a within S) \<longleftrightarrow> (f \<midarrow>a\<rightarrow> l)"
  1451   by (simp add: tendsto_def at_within_open[where S = S])
  1452 
  1453 lemma tendsto_within_open_NO_MATCH:
  1454   "a \<in> S \<Longrightarrow> NO_MATCH UNIV S \<Longrightarrow> open S \<Longrightarrow> (f \<longlongrightarrow> l)(at a within S) \<longleftrightarrow> (f \<longlongrightarrow> l)(at a)"
  1455   for f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
  1456   using tendsto_within_open by blast
  1457 
  1458 lemma LIM_const_not_eq[tendsto_intros]: "k \<noteq> L \<Longrightarrow> \<not> (\<lambda>x. k) \<midarrow>a\<rightarrow> L"
  1459   for a :: "'a::perfect_space" and k L :: "'b::t2_space"
  1460   by (simp add: tendsto_const_iff)
  1461 
  1462 lemmas LIM_not_zero = LIM_const_not_eq [where L = 0]
  1463 
  1464 lemma LIM_const_eq: "(\<lambda>x. k) \<midarrow>a\<rightarrow> L \<Longrightarrow> k = L"
  1465   for a :: "'a::perfect_space" and k L :: "'b::t2_space"
  1466   by (simp add: tendsto_const_iff)
  1467 
  1468 lemma LIM_unique: "f \<midarrow>a\<rightarrow> L \<Longrightarrow> f \<midarrow>a\<rightarrow> M \<Longrightarrow> L = M"
  1469   for a :: "'a::perfect_space" and L M :: "'b::t2_space"
  1470   using at_neq_bot by (rule tendsto_unique)
  1471 
  1472 
  1473 text \<open>Limits are equal for functions equal except at limit point.\<close>
  1474 lemma LIM_equal: "\<forall>x. x \<noteq> a \<longrightarrow> f x = g x \<Longrightarrow> (f \<midarrow>a\<rightarrow> l) \<longleftrightarrow> (g \<midarrow>a\<rightarrow> l)"
  1475   by (simp add: tendsto_def eventually_at_topological)
  1476 
  1477 lemma LIM_cong: "a = b \<Longrightarrow> (\<And>x. x \<noteq> b \<Longrightarrow> f x = g x) \<Longrightarrow> l = m \<Longrightarrow> (f \<midarrow>a\<rightarrow> l) \<longleftrightarrow> (g \<midarrow>b\<rightarrow> m)"
  1478   by (simp add: LIM_equal)
  1479 
  1480 lemma LIM_cong_limit: "f \<midarrow>x\<rightarrow> L \<Longrightarrow> K = L \<Longrightarrow> f \<midarrow>x\<rightarrow> K"
  1481   by simp
  1482 
  1483 lemma tendsto_at_iff_tendsto_nhds: "g \<midarrow>l\<rightarrow> g l \<longleftrightarrow> (g \<longlongrightarrow> g l) (nhds l)"
  1484   unfolding tendsto_def eventually_at_filter
  1485   by (intro ext all_cong imp_cong) (auto elim!: eventually_mono)
  1486 
  1487 lemma tendsto_compose: "g \<midarrow>l\<rightarrow> g l \<Longrightarrow> (f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) \<longlongrightarrow> g l) F"
  1488   unfolding tendsto_at_iff_tendsto_nhds by (rule filterlim_compose[of g])
  1489 
  1490 lemma LIM_o: "g \<midarrow>l\<rightarrow> g l \<Longrightarrow> f \<midarrow>a\<rightarrow> l \<Longrightarrow> (g \<circ> f) \<midarrow>a\<rightarrow> g l"
  1491   unfolding o_def by (rule tendsto_compose)
  1492 
  1493 lemma tendsto_compose_eventually:
  1494   "g \<midarrow>l\<rightarrow> m \<Longrightarrow> (f \<longlongrightarrow> l) F \<Longrightarrow> eventually (\<lambda>x. f x \<noteq> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) \<longlongrightarrow> m) F"
  1495   by (rule filterlim_compose[of g _ "at l"]) (auto simp add: filterlim_at)
  1496 
  1497 lemma LIM_compose_eventually:
  1498   assumes "f \<midarrow>a\<rightarrow> b"
  1499     and "g \<midarrow>b\<rightarrow> c"
  1500     and "eventually (\<lambda>x. f x \<noteq> b) (at a)"
  1501   shows "(\<lambda>x. g (f x)) \<midarrow>a\<rightarrow> c"
  1502   using assms(2,1,3) by (rule tendsto_compose_eventually)
  1503 
  1504 lemma tendsto_compose_filtermap: "((g \<circ> f) \<longlongrightarrow> T) F \<longleftrightarrow> (g \<longlongrightarrow> T) (filtermap f F)"
  1505   by (simp add: filterlim_def filtermap_filtermap comp_def)
  1506 
  1507 
  1508 subsubsection \<open>Relation of \<open>LIM\<close> and \<open>LIMSEQ\<close>\<close>
  1509 
  1510 lemma (in first_countable_topology) sequentially_imp_eventually_within:
  1511   "(\<forall>f. (\<forall>n. f n \<in> s \<and> f n \<noteq> a) \<and> f \<longlonglongrightarrow> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow>
  1512     eventually P (at a within s)"
  1513   unfolding at_within_def
  1514   by (intro sequentially_imp_eventually_nhds_within) auto
  1515 
  1516 lemma (in first_countable_topology) sequentially_imp_eventually_at:
  1517   "(\<forall>f. (\<forall>n. f n \<noteq> a) \<and> f \<longlonglongrightarrow> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow> eventually P (at a)"
  1518   using sequentially_imp_eventually_within [where s=UNIV] by simp
  1519 
  1520 lemma LIMSEQ_SEQ_conv1:
  1521   fixes f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
  1522   assumes f: "f \<midarrow>a\<rightarrow> l"
  1523   shows "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S \<longlonglongrightarrow> a \<longrightarrow> (\<lambda>n. f (S n)) \<longlonglongrightarrow> l"
  1524   using tendsto_compose_eventually [OF f, where F=sequentially] by simp
  1525 
  1526 lemma LIMSEQ_SEQ_conv2:
  1527   fixes f :: "'a::first_countable_topology \<Rightarrow> 'b::topological_space"
  1528   assumes "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S \<longlonglongrightarrow> a \<longrightarrow> (\<lambda>n. f (S n)) \<longlonglongrightarrow> l"
  1529   shows "f \<midarrow>a\<rightarrow> l"
  1530   using assms unfolding tendsto_def [where l=l] by (simp add: sequentially_imp_eventually_at)
  1531 
  1532 lemma LIMSEQ_SEQ_conv: "(\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S \<longlonglongrightarrow> a \<longrightarrow> (\<lambda>n. X (S n)) \<longlonglongrightarrow> L) \<longleftrightarrow> X \<midarrow>a\<rightarrow> L"
  1533   for a :: "'a::first_countable_topology" and L :: "'b::topological_space"
  1534   using LIMSEQ_SEQ_conv2 LIMSEQ_SEQ_conv1 ..
  1535 
  1536 lemma sequentially_imp_eventually_at_left:
  1537   fixes a :: "'a::{linorder_topology,first_countable_topology}"
  1538   assumes b[simp]: "b < a"
  1539     and *: "\<And>f. (\<And>n. b < f n) \<Longrightarrow> (\<And>n. f n < a) \<Longrightarrow> incseq f \<Longrightarrow> f \<longlonglongrightarrow> a \<Longrightarrow>
  1540       eventually (\<lambda>n. P (f n)) sequentially"
  1541   shows "eventually P (at_left a)"
  1542 proof (safe intro!: sequentially_imp_eventually_within)
  1543   fix X
  1544   assume X: "\<forall>n. X n \<in> {..< a} \<and> X n \<noteq> a" "X \<longlonglongrightarrow> a"
  1545   show "eventually (\<lambda>n. P (X n)) sequentially"
  1546   proof (rule ccontr)
  1547     assume neg: "\<not> ?thesis"
  1548     have "\<exists>s. \<forall>n. (\<not> P (X (s n)) \<and> b < X (s n)) \<and> (X (s n) \<le> X (s (Suc n)) \<and> Suc (s n) \<le> s (Suc n))"
  1549       (is "\<exists>s. ?P s")
  1550     proof (rule dependent_nat_choice)
  1551       have "\<not> eventually (\<lambda>n. b < X n \<longrightarrow> P (X n)) sequentially"
  1552         by (intro not_eventually_impI neg order_tendstoD(1) [OF X(2) b])
  1553       then show "\<exists>x. \<not> P (X x) \<and> b < X x"
  1554         by (auto dest!: not_eventuallyD)
  1555     next
  1556       fix x n
  1557       have "\<not> eventually (\<lambda>n. Suc x \<le> n \<longrightarrow> b < X n \<longrightarrow> X x < X n \<longrightarrow> P (X n)) sequentially"
  1558         using X
  1559         by (intro not_eventually_impI order_tendstoD(1)[OF X(2)] eventually_ge_at_top neg) auto
  1560       then show "\<exists>n. (\<not> P (X n) \<and> b < X n) \<and> (X x \<le> X n \<and> Suc x \<le> n)"
  1561         by (auto dest!: not_eventuallyD)
  1562     qed
  1563     then obtain s where "?P s" ..
  1564     with X have "b < X (s n)"
  1565       and "X (s n) < a"
  1566       and "incseq (\<lambda>n. X (s n))"
  1567       and "(\<lambda>n. X (s n)) \<longlonglongrightarrow> a"
  1568       and "\<not> P (X (s n))"
  1569       for n
  1570       by (auto simp: subseq_Suc_iff Suc_le_eq incseq_Suc_iff
  1571           intro!: LIMSEQ_subseq_LIMSEQ[OF \<open>X \<longlonglongrightarrow> a\<close>, unfolded comp_def])
  1572     from *[OF this(1,2,3,4)] this(5) show False
  1573       by auto
  1574   qed
  1575 qed
  1576 
  1577 lemma tendsto_at_left_sequentially:
  1578   fixes a b :: "'b::{linorder_topology,first_countable_topology}"
  1579   assumes "b < a"
  1580   assumes *: "\<And>S. (\<And>n. S n < a) \<Longrightarrow> (\<And>n. b < S n) \<Longrightarrow> incseq S \<Longrightarrow> S \<longlonglongrightarrow> a \<Longrightarrow>
  1581     (\<lambda>n. X (S n)) \<longlonglongrightarrow> L"
  1582   shows "(X \<longlongrightarrow> L) (at_left a)"
  1583   using assms by (simp add: tendsto_def [where l=L] sequentially_imp_eventually_at_left)
  1584 
  1585 lemma sequentially_imp_eventually_at_right:
  1586   fixes a b :: "'a::{linorder_topology,first_countable_topology}"
  1587   assumes b[simp]: "a < b"
  1588   assumes *: "\<And>f. (\<And>n. a < f n) \<Longrightarrow> (\<And>n. f n < b) \<Longrightarrow> decseq f \<Longrightarrow> f \<longlonglongrightarrow> a \<Longrightarrow>
  1589     eventually (\<lambda>n. P (f n)) sequentially"
  1590   shows "eventually P (at_right a)"
  1591 proof (safe intro!: sequentially_imp_eventually_within)
  1592   fix X
  1593   assume X: "\<forall>n. X n \<in> {a <..} \<and> X n \<noteq> a" "X \<longlonglongrightarrow> a"
  1594   show "eventually (\<lambda>n. P (X n)) sequentially"
  1595   proof (rule ccontr)
  1596     assume neg: "\<not> ?thesis"
  1597     have "\<exists>s. \<forall>n. (\<not> P (X (s n)) \<and> X (s n) < b) \<and> (X (s (Suc n)) \<le> X (s n) \<and> Suc (s n) \<le> s (Suc n))"
  1598       (is "\<exists>s. ?P s")
  1599     proof (rule dependent_nat_choice)
  1600       have "\<not> eventually (\<lambda>n. X n < b \<longrightarrow> P (X n)) sequentially"
  1601         by (intro not_eventually_impI neg order_tendstoD(2) [OF X(2) b])
  1602       then show "\<exists>x. \<not> P (X x) \<and> X x < b"
  1603         by (auto dest!: not_eventuallyD)
  1604     next
  1605       fix x n
  1606       have "\<not> eventually (\<lambda>n. Suc x \<le> n \<longrightarrow> X n < b \<longrightarrow> X n < X x \<longrightarrow> P (X n)) sequentially"
  1607         using X
  1608         by (intro not_eventually_impI order_tendstoD(2)[OF X(2)] eventually_ge_at_top neg) auto
  1609       then show "\<exists>n. (\<not> P (X n) \<and> X n < b) \<and> (X n \<le> X x \<and> Suc x \<le> n)"
  1610         by (auto dest!: not_eventuallyD)
  1611     qed
  1612     then obtain s where "?P s" ..
  1613     with X have "a < X (s n)"
  1614       and "X (s n) < b"
  1615       and "decseq (\<lambda>n. X (s n))"
  1616       and "(\<lambda>n. X (s n)) \<longlonglongrightarrow> a"
  1617       and "\<not> P (X (s n))"
  1618       for n
  1619       by (auto simp: subseq_Suc_iff Suc_le_eq decseq_Suc_iff
  1620           intro!: LIMSEQ_subseq_LIMSEQ[OF \<open>X \<longlonglongrightarrow> a\<close>, unfolded comp_def])
  1621     from *[OF this(1,2,3,4)] this(5) show False
  1622       by auto
  1623   qed
  1624 qed
  1625 
  1626 lemma tendsto_at_right_sequentially:
  1627   fixes a :: "_ :: {linorder_topology, first_countable_topology}"
  1628   assumes "a < b"
  1629     and *: "\<And>S. (\<And>n. a < S n) \<Longrightarrow> (\<And>n. S n < b) \<Longrightarrow> decseq S \<Longrightarrow> S \<longlonglongrightarrow> a \<Longrightarrow>
  1630       (\<lambda>n. X (S n)) \<longlonglongrightarrow> L"
  1631   shows "(X \<longlongrightarrow> L) (at_right a)"
  1632   using assms by (simp add: tendsto_def [where l=L] sequentially_imp_eventually_at_right)
  1633 
  1634 
  1635 subsection \<open>Continuity\<close>
  1636 
  1637 subsubsection \<open>Continuity on a set\<close>
  1638 
  1639 definition continuous_on :: "'a set \<Rightarrow> ('a::topological_space \<Rightarrow> 'b::topological_space) \<Rightarrow> bool"
  1640   where "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. (f \<longlongrightarrow> f x) (at x within s))"
  1641 
  1642 lemma continuous_on_cong [cong]:
  1643   "s = t \<Longrightarrow> (\<And>x. x \<in> t \<Longrightarrow> f x = g x) \<Longrightarrow> continuous_on s f \<longleftrightarrow> continuous_on t g"
  1644   unfolding continuous_on_def
  1645   by (intro ball_cong filterlim_cong) (auto simp: eventually_at_filter)
  1646 
  1647 lemma continuous_on_topological:
  1648   "continuous_on s f \<longleftrightarrow>
  1649     (\<forall>x\<in>s. \<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  1650   unfolding continuous_on_def tendsto_def eventually_at_topological by metis
  1651 
  1652 lemma continuous_on_open_invariant:
  1653   "continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s))"
  1654 proof safe
  1655   fix B :: "'b set"
  1656   assume "continuous_on s f" "open B"
  1657   then have "\<forall>x\<in>f -` B \<inter> s. (\<exists>A. open A \<and> x \<in> A \<and> s \<inter> A \<subseteq> f -` B)"
  1658     by (auto simp: continuous_on_topological subset_eq Ball_def imp_conjL)
  1659   then obtain A where "\<forall>x\<in>f -` B \<inter> s. open (A x) \<and> x \<in> A x \<and> s \<inter> A x \<subseteq> f -` B"
  1660     unfolding bchoice_iff ..
  1661   then show "\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s"
  1662     by (intro exI[of _ "\<Union>x\<in>f -` B \<inter> s. A x"]) auto
  1663 next
  1664   assume B: "\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s)"
  1665   show "continuous_on s f"
  1666     unfolding continuous_on_topological
  1667   proof safe
  1668     fix x B
  1669     assume "x \<in> s" "open B" "f x \<in> B"
  1670     with B obtain A where A: "open A" "A \<inter> s = f -` B \<inter> s"
  1671       by auto
  1672     with \<open>x \<in> s\<close> \<open>f x \<in> B\<close> show "\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)"
  1673       by (intro exI[of _ A]) auto
  1674   qed
  1675 qed
  1676 
  1677 lemma continuous_on_open_vimage:
  1678   "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> open (f -` B \<inter> s))"
  1679   unfolding continuous_on_open_invariant
  1680   by (metis open_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  1681 
  1682 corollary continuous_imp_open_vimage:
  1683   assumes "continuous_on s f" "open s" "open B" "f -` B \<subseteq> s"
  1684   shows "open (f -` B)"
  1685   by (metis assms continuous_on_open_vimage le_iff_inf)
  1686 
  1687 corollary open_vimage[continuous_intros]:
  1688   assumes "open s"
  1689     and "continuous_on UNIV f"
  1690   shows "open (f -` s)"
  1691   using assms by (simp add: continuous_on_open_vimage [OF open_UNIV])
  1692 
  1693 lemma continuous_on_closed_invariant:
  1694   "continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> (\<exists>A. closed A \<and> A \<inter> s = f -` B \<inter> s))"
  1695 proof -
  1696   have *: "(\<And>A. P A \<longleftrightarrow> Q (- A)) \<Longrightarrow> (\<forall>A. P A) \<longleftrightarrow> (\<forall>A. Q A)"
  1697     for P Q :: "'b set \<Rightarrow> bool"
  1698     by (metis double_compl)
  1699   show ?thesis
  1700     unfolding continuous_on_open_invariant
  1701     by (intro *) (auto simp: open_closed[symmetric])
  1702 qed
  1703 
  1704 lemma continuous_on_closed_vimage:
  1705   "closed s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> closed (f -` B \<inter> s))"
  1706   unfolding continuous_on_closed_invariant
  1707   by (metis closed_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  1708 
  1709 corollary closed_vimage_Int[continuous_intros]:
  1710   assumes "closed s"
  1711     and "continuous_on t f"
  1712     and t: "closed t"
  1713   shows "closed (f -` s \<inter> t)"
  1714   using assms by (simp add: continuous_on_closed_vimage [OF t])
  1715 
  1716 corollary closed_vimage[continuous_intros]:
  1717   assumes "closed s"
  1718     and "continuous_on UNIV f"
  1719   shows "closed (f -` s)"
  1720   using closed_vimage_Int [OF assms] by simp
  1721 
  1722 lemma continuous_on_empty [simp]: "continuous_on {} f"
  1723   by (simp add: continuous_on_def)
  1724 
  1725 lemma continuous_on_sing [simp]: "continuous_on {x} f"
  1726   by (simp add: continuous_on_def at_within_def)
  1727 
  1728 lemma continuous_on_open_Union:
  1729   "(\<And>s. s \<in> S \<Longrightarrow> open s) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on s f) \<Longrightarrow> continuous_on (\<Union>S) f"
  1730   unfolding continuous_on_def
  1731   by safe (metis open_Union at_within_open UnionI)
  1732 
  1733 lemma continuous_on_open_UN:
  1734   "(\<And>s. s \<in> S \<Longrightarrow> open (A s)) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on (A s) f) \<Longrightarrow>
  1735     continuous_on (\<Union>s\<in>S. A s) f"
  1736   by (rule continuous_on_open_Union) auto
  1737 
  1738 lemma continuous_on_open_Un:
  1739   "open s \<Longrightarrow> open t \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on t f \<Longrightarrow> continuous_on (s \<union> t) f"
  1740   using continuous_on_open_Union [of "{s,t}"] by auto
  1741 
  1742 lemma continuous_on_closed_Un:
  1743   "closed s \<Longrightarrow> closed t \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on t f \<Longrightarrow> continuous_on (s \<union> t) f"
  1744   by (auto simp add: continuous_on_closed_vimage closed_Un Int_Un_distrib)
  1745 
  1746 lemma continuous_on_If:
  1747   assumes closed: "closed s" "closed t"
  1748     and cont: "continuous_on s f" "continuous_on t g"
  1749     and P: "\<And>x. x \<in> s \<Longrightarrow> \<not> P x \<Longrightarrow> f x = g x" "\<And>x. x \<in> t \<Longrightarrow> P x \<Longrightarrow> f x = g x"
  1750   shows "continuous_on (s \<union> t) (\<lambda>x. if P x then f x else g x)"
  1751     (is "continuous_on _ ?h")
  1752 proof-
  1753   from P have "\<forall>x\<in>s. f x = ?h x" "\<forall>x\<in>t. g x = ?h x"
  1754     by auto
  1755   with cont have "continuous_on s ?h" "continuous_on t ?h"
  1756     by simp_all
  1757   with closed show ?thesis
  1758     by (rule continuous_on_closed_Un)
  1759 qed
  1760 
  1761 lemma continuous_on_id[continuous_intros]: "continuous_on s (\<lambda>x. x)"
  1762   unfolding continuous_on_def by fast
  1763 
  1764 lemma continuous_on_id'[continuous_intros]: "continuous_on s id"
  1765   unfolding continuous_on_def id_def by fast
  1766 
  1767 lemma continuous_on_const[continuous_intros]: "continuous_on s (\<lambda>x. c)"
  1768   unfolding continuous_on_def by auto
  1769 
  1770 lemma continuous_on_subset: "continuous_on s f \<Longrightarrow> t \<subseteq> s \<Longrightarrow> continuous_on t f"
  1771   unfolding continuous_on_def by (metis subset_eq tendsto_within_subset)
  1772 
  1773 lemma continuous_on_compose[continuous_intros]:
  1774   "continuous_on s f \<Longrightarrow> continuous_on (f ` s) g \<Longrightarrow> continuous_on s (g \<circ> f)"
  1775   unfolding continuous_on_topological by simp metis
  1776 
  1777 lemma continuous_on_compose2:
  1778   "continuous_on t g \<Longrightarrow> continuous_on s f \<Longrightarrow> f ` s \<subseteq> t \<Longrightarrow> continuous_on s (\<lambda>x. g (f x))"
  1779   using continuous_on_compose[of s f g] continuous_on_subset by (force simp add: comp_def)
  1780 
  1781 lemma continuous_on_generate_topology:
  1782   assumes *: "open = generate_topology X"
  1783     and **: "\<And>B. B \<in> X \<Longrightarrow> \<exists>C. open C \<and> C \<inter> A = f -` B \<inter> A"
  1784   shows "continuous_on A f"
  1785   unfolding continuous_on_open_invariant
  1786 proof safe
  1787   fix B :: "'a set"
  1788   assume "open B"
  1789   then show "\<exists>C. open C \<and> C \<inter> A = f -` B \<inter> A"
  1790     unfolding *
  1791   proof induct
  1792     case (UN K)
  1793     then obtain C where "\<And>k. k \<in> K \<Longrightarrow> open (C k)" "\<And>k. k \<in> K \<Longrightarrow> C k \<inter> A = f -` k \<inter> A"
  1794       by metis
  1795     then show ?case
  1796       by (intro exI[of _ "\<Union>k\<in>K. C k"]) blast
  1797   qed (auto intro: **)
  1798 qed
  1799 
  1800 lemma continuous_onI_mono:
  1801   fixes f :: "'a::linorder_topology \<Rightarrow> 'b::{dense_order,linorder_topology}"
  1802   assumes "open (f`A)"
  1803     and mono: "\<And>x y. x \<in> A \<Longrightarrow> y \<in> A \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1804   shows "continuous_on A f"
  1805 proof (rule continuous_on_generate_topology[OF open_generated_order], safe)
  1806   have monoD: "\<And>x y. x \<in> A \<Longrightarrow> y \<in> A \<Longrightarrow> f x < f y \<Longrightarrow> x < y"
  1807     by (auto simp: not_le[symmetric] mono)
  1808   have "\<exists>x. x \<in> A \<and> f x < b \<and> a < x" if a: "a \<in> A" and fa: "f a < b" for a b
  1809   proof -
  1810     obtain y where "f a < y" "{f a ..< y} \<subseteq> f`A"
  1811       using open_right[OF \<open>open (f`A)\<close>, of "f a" b] a fa
  1812       by auto
  1813     obtain z where z: "f a < z" "z < min b y"
  1814       using dense[of "f a" "min b y"] \<open>f a < y\<close> \<open>f a < b\<close> by auto
  1815     then obtain c where "z = f c" "c \<in> A"
  1816       using \<open>{f a ..< y} \<subseteq> f`A\<close>[THEN subsetD, of z] by (auto simp: less_imp_le)
  1817     with a z show ?thesis
  1818       by (auto intro!: exI[of _ c] simp: monoD)
  1819   qed
  1820   then show "\<exists>C. open C \<and> C \<inter> A = f -` {..<b} \<inter> A" for b
  1821     by (intro exI[of _ "(\<Union>x\<in>{x\<in>A. f x < b}. {..< x})"])
  1822        (auto intro: le_less_trans[OF mono] less_imp_le)
  1823 
  1824   have "\<exists>x. x \<in> A \<and> b < f x \<and> x < a" if a: "a \<in> A" and fa: "b < f a" for a b
  1825   proof -
  1826     note a fa
  1827     moreover
  1828     obtain y where "y < f a" "{y <.. f a} \<subseteq> f`A"
  1829       using open_left[OF \<open>open (f`A)\<close>, of "f a" b]  a fa
  1830       by auto
  1831     then obtain z where z: "max b y < z" "z < f a"
  1832       using dense[of "max b y" "f a"] \<open>y < f a\<close> \<open>b < f a\<close> by auto
  1833     then obtain c where "z = f c" "c \<in> A"
  1834       using \<open>{y <.. f a} \<subseteq> f`A\<close>[THEN subsetD, of z] by (auto simp: less_imp_le)
  1835     with a z show ?thesis
  1836       by (auto intro!: exI[of _ c] simp: monoD)
  1837   qed
  1838   then show "\<exists>C. open C \<and> C \<inter> A = f -` {b <..} \<inter> A" for b
  1839     by (intro exI[of _ "(\<Union>x\<in>{x\<in>A. b < f x}. {x <..})"])
  1840        (auto intro: less_le_trans[OF _ mono] less_imp_le)
  1841 qed
  1842 
  1843 
  1844 subsubsection \<open>Continuity at a point\<close>
  1845 
  1846 definition continuous :: "'a::t2_space filter \<Rightarrow> ('a \<Rightarrow> 'b::topological_space) \<Rightarrow> bool"
  1847   where "continuous F f \<longleftrightarrow> (f \<longlongrightarrow> f (Lim F (\<lambda>x. x))) F"
  1848 
  1849 lemma continuous_bot[continuous_intros, simp]: "continuous bot f"
  1850   unfolding continuous_def by auto
  1851 
  1852 lemma continuous_trivial_limit: "trivial_limit net \<Longrightarrow> continuous net f"
  1853   by simp
  1854 
  1855 lemma continuous_within: "continuous (at x within s) f \<longleftrightarrow> (f \<longlongrightarrow> f x) (at x within s)"
  1856   by (cases "trivial_limit (at x within s)") (auto simp add: Lim_ident_at continuous_def)
  1857 
  1858 lemma continuous_within_topological:
  1859   "continuous (at x within s) f \<longleftrightarrow>
  1860     (\<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  1861   unfolding continuous_within tendsto_def eventually_at_topological by metis
  1862 
  1863 lemma continuous_within_compose[continuous_intros]:
  1864   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  1865     continuous (at x within s) (g \<circ> f)"
  1866   by (simp add: continuous_within_topological) metis
  1867 
  1868 lemma continuous_within_compose2:
  1869   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  1870     continuous (at x within s) (\<lambda>x. g (f x))"
  1871   using continuous_within_compose[of x s f g] by (simp add: comp_def)
  1872 
  1873 lemma continuous_at: "continuous (at x) f \<longleftrightarrow> f \<midarrow>x\<rightarrow> f x"
  1874   using continuous_within[of x UNIV f] by simp
  1875 
  1876 lemma continuous_ident[continuous_intros, simp]: "continuous (at x within S) (\<lambda>x. x)"
  1877   unfolding continuous_within by (rule tendsto_ident_at)
  1878 
  1879 lemma continuous_const[continuous_intros, simp]: "continuous F (\<lambda>x. c)"
  1880   unfolding continuous_def by (rule tendsto_const)
  1881 
  1882 lemma continuous_on_eq_continuous_within:
  1883   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. continuous (at x within s) f)"
  1884   unfolding continuous_on_def continuous_within ..
  1885 
  1886 abbreviation isCont :: "('a::t2_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> bool"
  1887   where "isCont f a \<equiv> continuous (at a) f"
  1888 
  1889 lemma isCont_def: "isCont f a \<longleftrightarrow> f \<midarrow>a\<rightarrow> f a"
  1890   by (rule continuous_at)
  1891 
  1892 lemma isCont_cong:
  1893   assumes "eventually (\<lambda>x. f x = g x) (nhds x)"
  1894   shows "isCont f x \<longleftrightarrow> isCont g x"
  1895 proof -
  1896   from assms have [simp]: "f x = g x"
  1897     by (rule eventually_nhds_x_imp_x)
  1898   from assms have "eventually (\<lambda>x. f x = g x) (at x)"
  1899     by (auto simp: eventually_at_filter elim!: eventually_mono)
  1900   with assms have "isCont f x \<longleftrightarrow> isCont g x" unfolding isCont_def
  1901     by (intro filterlim_cong) (auto elim!: eventually_mono)
  1902   with assms show ?thesis by simp
  1903 qed
  1904 
  1905 lemma continuous_at_imp_continuous_at_within: "isCont f x \<Longrightarrow> continuous (at x within s) f"
  1906   by (auto intro: tendsto_mono at_le simp: continuous_at continuous_within)
  1907 
  1908 lemma continuous_on_eq_continuous_at: "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. isCont f x)"
  1909   by (simp add: continuous_on_def continuous_at at_within_open[of _ s])
  1910 
  1911 lemma continuous_within_open: "a \<in> A \<Longrightarrow> open A \<Longrightarrow> continuous (at a within A) f \<longleftrightarrow> isCont f a"
  1912   by (simp add: at_within_open_NO_MATCH)
  1913 
  1914 lemma continuous_at_imp_continuous_on: "\<forall>x\<in>s. isCont f x \<Longrightarrow> continuous_on s f"
  1915   by (auto intro: continuous_at_imp_continuous_at_within simp: continuous_on_eq_continuous_within)
  1916 
  1917 lemma isCont_o2: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (\<lambda>x. g (f x)) a"
  1918   unfolding isCont_def by (rule tendsto_compose)
  1919 
  1920 lemma isCont_o[continuous_intros]: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (g \<circ> f) a"
  1921   unfolding o_def by (rule isCont_o2)
  1922 
  1923 lemma isCont_tendsto_compose: "isCont g l \<Longrightarrow> (f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) \<longlongrightarrow> g l) F"
  1924   unfolding isCont_def by (rule tendsto_compose)
  1925 
  1926 lemma continuous_on_tendsto_compose:
  1927   assumes f_cont: "continuous_on s f"
  1928     and g: "(g \<longlongrightarrow> l) F"
  1929     and l: "l \<in> s"
  1930     and ev: "\<forall>\<^sub>Fx in F. g x \<in> s"
  1931   shows "((\<lambda>x. f (g x)) \<longlongrightarrow> f l) F"
  1932 proof -
  1933   from f_cont l have f: "(f \<longlongrightarrow> f l) (at l within s)"
  1934     by (simp add: continuous_on_def)
  1935   have i: "((\<lambda>x. if g x = l then f l else f (g x)) \<longlongrightarrow> f l) F"
  1936     by (rule filterlim_If)
  1937        (auto intro!: filterlim_compose[OF f] eventually_conj tendsto_mono[OF _ g]
  1938              simp: filterlim_at eventually_inf_principal eventually_mono[OF ev])
  1939   show ?thesis
  1940     by (rule filterlim_cong[THEN iffD1[OF _ i]]) auto
  1941 qed
  1942 
  1943 lemma continuous_within_compose3:
  1944   "isCont g (f x) \<Longrightarrow> continuous (at x within s) f \<Longrightarrow> continuous (at x within s) (\<lambda>x. g (f x))"
  1945   using continuous_at_imp_continuous_at_within continuous_within_compose2 by blast
  1946 
  1947 lemma filtermap_nhds_open_map:
  1948   assumes cont: "isCont f a"
  1949     and open_map: "\<And>S. open S \<Longrightarrow> open (f`S)"
  1950   shows "filtermap f (nhds a) = nhds (f a)"
  1951   unfolding filter_eq_iff
  1952 proof safe
  1953   fix P
  1954   assume "eventually P (filtermap f (nhds a))"
  1955   then obtain S where "open S" "a \<in> S" "\<forall>x\<in>S. P (f x)"
  1956     by (auto simp: eventually_filtermap eventually_nhds)
  1957   then show "eventually P (nhds (f a))"
  1958     unfolding eventually_nhds by (intro exI[of _ "f`S"]) (auto intro!: open_map)
  1959 qed (metis filterlim_iff tendsto_at_iff_tendsto_nhds isCont_def eventually_filtermap cont)
  1960 
  1961 lemma continuous_at_split:
  1962   "continuous (at x) f \<longleftrightarrow> continuous (at_left x) f \<and> continuous (at_right x) f"
  1963   for x :: "'a::linorder_topology"
  1964   by (simp add: continuous_within filterlim_at_split)
  1965 
  1966 text \<open>
  1967   The following open/closed Collect lemmas are ported from
  1968   Sébastien Gouëzel's \<open>Ergodic_Theory\<close>.
  1969 \<close>
  1970 lemma open_Collect_neq:
  1971   fixes f g :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  1972   assumes f: "continuous_on UNIV f" and g: "continuous_on UNIV g"
  1973   shows "open {x. f x \<noteq> g x}"
  1974 proof (rule openI)
  1975   fix t
  1976   assume "t \<in> {x. f x \<noteq> g x}"
  1977   then obtain U V where *: "open U" "open V" "f t \<in> U" "g t \<in> V" "U \<inter> V = {}"
  1978     by (auto simp add: separation_t2)
  1979   with open_vimage[OF \<open>open U\<close> f] open_vimage[OF \<open>open V\<close> g]
  1980   show "\<exists>T. open T \<and> t \<in> T \<and> T \<subseteq> {x. f x \<noteq> g x}"
  1981     by (intro exI[of _ "f -` U \<inter> g -` V"]) auto
  1982 qed
  1983 
  1984 lemma closed_Collect_eq:
  1985   fixes f g :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  1986   assumes f: "continuous_on UNIV f" and g: "continuous_on UNIV g"
  1987   shows "closed {x. f x = g x}"
  1988   using open_Collect_neq[OF f g] by (simp add: closed_def Collect_neg_eq)
  1989 
  1990 lemma open_Collect_less:
  1991   fixes f g :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  1992   assumes f: "continuous_on UNIV f" and g: "continuous_on UNIV g"
  1993   shows "open {x. f x < g x}"
  1994 proof (rule openI)
  1995   fix t
  1996   assume t: "t \<in> {x. f x < g x}"
  1997   show "\<exists>T. open T \<and> t \<in> T \<and> T \<subseteq> {x. f x < g x}"
  1998   proof (cases "\<exists>z. f t < z \<and> z < g t")
  1999     case True
  2000     then obtain z where "f t < z \<and> z < g t" by blast
  2001     then show ?thesis
  2002       using open_vimage[OF _ f, of "{..< z}"] open_vimage[OF _ g, of "{z <..}"]
  2003       by (intro exI[of _ "f -` {..<z} \<inter> g -` {z<..}"]) auto
  2004   next
  2005     case False
  2006     then have *: "{g t ..} = {f t <..}" "{..< g t} = {.. f t}"
  2007       using t by (auto intro: leI)
  2008     show ?thesis
  2009       using open_vimage[OF _ f, of "{..< g t}"] open_vimage[OF _ g, of "{f t <..}"] t
  2010       apply (intro exI[of _ "f -` {..< g t} \<inter> g -` {f t<..}"])
  2011       apply (simp add: open_Int)
  2012       apply (auto simp add: *)
  2013       done
  2014   qed
  2015 qed
  2016 
  2017 lemma closed_Collect_le:
  2018   fixes f g :: "'a :: topological_space \<Rightarrow> 'b::linorder_topology"
  2019   assumes f: "continuous_on UNIV f"
  2020     and g: "continuous_on UNIV g"
  2021   shows "closed {x. f x \<le> g x}"
  2022   using open_Collect_less [OF g f]
  2023   by (simp add: closed_def Collect_neg_eq[symmetric] not_le)
  2024 
  2025 
  2026 subsubsection \<open>Open-cover compactness\<close>
  2027 
  2028 context topological_space
  2029 begin
  2030 
  2031 definition compact :: "'a set \<Rightarrow> bool"
  2032   where compact_eq_heine_borel:  (* This name is used for backwards compatibility *)
  2033     "compact S \<longleftrightarrow> (\<forall>C. (\<forall>c\<in>C. open c) \<and> S \<subseteq> \<Union>C \<longrightarrow> (\<exists>D\<subseteq>C. finite D \<and> S \<subseteq> \<Union>D))"
  2034 
  2035 lemma compactI:
  2036   assumes "\<And>C. \<forall>t\<in>C. open t \<Longrightarrow> s \<subseteq> \<Union>C \<Longrightarrow> \<exists>C'. C' \<subseteq> C \<and> finite C' \<and> s \<subseteq> \<Union>C'"
  2037   shows "compact s"
  2038   unfolding compact_eq_heine_borel using assms by metis
  2039 
  2040 lemma compact_empty[simp]: "compact {}"
  2041   by (auto intro!: compactI)
  2042 
  2043 lemma compactE:
  2044   assumes "compact s"
  2045     and "\<forall>t\<in>C. open t"
  2046     and "s \<subseteq> \<Union>C"
  2047   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> \<Union>C'"
  2048   using assms unfolding compact_eq_heine_borel by metis
  2049 
  2050 lemma compactE_image:
  2051   assumes "compact s"
  2052     and "\<forall>t\<in>C. open (f t)"
  2053     and "s \<subseteq> (\<Union>c\<in>C. f c)"
  2054   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> (\<Union>c\<in>C'. f c)"
  2055   using assms unfolding ball_simps [symmetric]
  2056   by (metis (lifting) finite_subset_image compact_eq_heine_borel[of s])
  2057 
  2058 lemma compact_Int_closed [intro]:
  2059   assumes "compact s"
  2060     and "closed t"
  2061   shows "compact (s \<inter> t)"
  2062 proof (rule compactI)
  2063   fix C
  2064   assume C: "\<forall>c\<in>C. open c"
  2065   assume cover: "s \<inter> t \<subseteq> \<Union>C"
  2066   from C \<open>closed t\<close> have "\<forall>c\<in>C \<union> {- t}. open c"
  2067     by auto
  2068   moreover from cover have "s \<subseteq> \<Union>(C \<union> {- t})"
  2069     by auto
  2070   ultimately have "\<exists>D\<subseteq>C \<union> {- t}. finite D \<and> s \<subseteq> \<Union>D"
  2071     using \<open>compact s\<close> unfolding compact_eq_heine_borel by auto
  2072   then obtain D where "D \<subseteq> C \<union> {- t} \<and> finite D \<and> s \<subseteq> \<Union>D" ..
  2073   then show "\<exists>D\<subseteq>C. finite D \<and> s \<inter> t \<subseteq> \<Union>D"
  2074     by (intro exI[of _ "D - {-t}"]) auto
  2075 qed
  2076 
  2077 lemma inj_setminus: "inj_on uminus (A::'a set set)"
  2078   by (auto simp: inj_on_def)
  2079 
  2080 
  2081 subsection \<open>Finite intersection property\<close>
  2082 
  2083 lemma compact_fip:
  2084   "compact U \<longleftrightarrow>
  2085     (\<forall>A. (\<forall>a\<in>A. closed a) \<longrightarrow> (\<forall>B \<subseteq> A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}) \<longrightarrow> U \<inter> \<Inter>A \<noteq> {})"
  2086   (is "_ \<longleftrightarrow> ?R")
  2087 proof (safe intro!: compact_eq_heine_borel[THEN iffD2])
  2088   fix A
  2089   assume "compact U"
  2090   assume A: "\<forall>a\<in>A. closed a" "U \<inter> \<Inter>A = {}"
  2091   assume fin: "\<forall>B \<subseteq> A. finite B \<longrightarrow> U \<inter> \<Inter>B \<noteq> {}"
  2092   from A have "(\<forall>a\<in>uminus`A. open a) \<and> U \<subseteq> \<Union>(uminus`A)"
  2093     by auto
  2094   with \<open>compact U\<close> obtain B where "B \<subseteq> A" "finite (uminus`B)" "U \<subseteq> \<Union>(uminus`B)"
  2095     unfolding compact_eq_heine_borel by (metis subset_image_iff)
  2096   with fin[THEN spec, of B] show False
  2097     by (auto dest: finite_imageD intro: inj_setminus)
  2098 next
  2099   fix A
  2100   assume ?R
  2101   assume "\<forall>a\<in>A. open a" "U \<subseteq> \<Union>A"
  2102   then have "U \<inter> \<Inter>(uminus`A) = {}" "\<forall>a\<in>uminus`A. closed a"
  2103     by auto
  2104   with \<open>?R\<close> obtain B where "B \<subseteq> A" "finite (uminus`B)" "U \<inter> \<Inter>(uminus`B) = {}"
  2105     by (metis subset_image_iff)
  2106   then show "\<exists>T\<subseteq>A. finite T \<and> U \<subseteq> \<Union>T"
  2107     by (auto intro!: exI[of _ B] inj_setminus dest: finite_imageD)
  2108 qed
  2109 
  2110 lemma compact_imp_fip:
  2111   assumes "compact S"
  2112     and "\<And>T. T \<in> F \<Longrightarrow> closed T"
  2113     and "\<And>F'. finite F' \<Longrightarrow> F' \<subseteq> F \<Longrightarrow> S \<inter> (\<Inter>F') \<noteq> {}"
  2114   shows "S \<inter> (\<Inter>F) \<noteq> {}"
  2115   using assms unfolding compact_fip by auto
  2116 
  2117 lemma compact_imp_fip_image:
  2118   assumes "compact s"
  2119     and P: "\<And>i. i \<in> I \<Longrightarrow> closed (f i)"
  2120     and Q: "\<And>I'. finite I' \<Longrightarrow> I' \<subseteq> I \<Longrightarrow> (s \<inter> (\<Inter>i\<in>I'. f i) \<noteq> {})"
  2121   shows "s \<inter> (\<Inter>i\<in>I. f i) \<noteq> {}"
  2122 proof -
  2123   note \<open>compact s\<close>
  2124   moreover from P have "\<forall>i \<in> f ` I. closed i"
  2125     by blast
  2126   moreover have "\<forall>A. finite A \<and> A \<subseteq> f ` I \<longrightarrow> (s \<inter> (\<Inter>A) \<noteq> {})"
  2127     apply rule
  2128     apply rule
  2129     apply (erule conjE)
  2130   proof -
  2131     fix A :: "'a set set"
  2132     assume "finite A" and "A \<subseteq> f ` I"
  2133     then obtain B where "B \<subseteq> I" and "finite B" and "A = f ` B"
  2134       using finite_subset_image [of A f I] by blast
  2135     with Q [of B] show "s \<inter> \<Inter>A \<noteq> {}"
  2136       by simp
  2137   qed
  2138   ultimately have "s \<inter> (\<Inter>(f ` I)) \<noteq> {}"
  2139     by (metis compact_imp_fip)
  2140   then show ?thesis by simp
  2141 qed
  2142 
  2143 end
  2144 
  2145 lemma (in t2_space) compact_imp_closed:
  2146   assumes "compact s"
  2147   shows "closed s"
  2148   unfolding closed_def
  2149 proof (rule openI)
  2150   fix y
  2151   assume "y \<in> - s"
  2152   let ?C = "\<Union>x\<in>s. {u. open u \<and> x \<in> u \<and> eventually (\<lambda>y. y \<notin> u) (nhds y)}"
  2153   note \<open>compact s\<close>
  2154   moreover have "\<forall>u\<in>?C. open u" by simp
  2155   moreover have "s \<subseteq> \<Union>?C"
  2156   proof
  2157     fix x
  2158     assume "x \<in> s"
  2159     with \<open>y \<in> - s\<close> have "x \<noteq> y" by clarsimp
  2160     then have "\<exists>u v. open u \<and> open v \<and> x \<in> u \<and> y \<in> v \<and> u \<inter> v = {}"
  2161       by (rule hausdorff)
  2162     with \<open>x \<in> s\<close> show "x \<in> \<Union>?C"
  2163       unfolding eventually_nhds by auto
  2164   qed
  2165   ultimately obtain D where "D \<subseteq> ?C" and "finite D" and "s \<subseteq> \<Union>D"
  2166     by (rule compactE)
  2167   from \<open>D \<subseteq> ?C\<close> have "\<forall>x\<in>D. eventually (\<lambda>y. y \<notin> x) (nhds y)"
  2168     by auto
  2169   with \<open>finite D\<close> have "eventually (\<lambda>y. y \<notin> \<Union>D) (nhds y)"
  2170     by (simp add: eventually_ball_finite)
  2171   with \<open>s \<subseteq> \<Union>D\<close> have "eventually (\<lambda>y. y \<notin> s) (nhds y)"
  2172     by (auto elim!: eventually_mono)
  2173   then show "\<exists>t. open t \<and> y \<in> t \<and> t \<subseteq> - s"
  2174     by (simp add: eventually_nhds subset_eq)
  2175 qed
  2176 
  2177 lemma compact_continuous_image:
  2178   assumes f: "continuous_on s f"
  2179     and s: "compact s"
  2180   shows "compact (f ` s)"
  2181 proof (rule compactI)
  2182   fix C
  2183   assume "\<forall>c\<in>C. open c" and cover: "f`s \<subseteq> \<Union>C"
  2184   with f have "\<forall>c\<in>C. \<exists>A. open A \<and> A \<inter> s = f -` c \<inter> s"
  2185     unfolding continuous_on_open_invariant by blast
  2186   then obtain A where A: "\<forall>c\<in>C. open (A c) \<and> A c \<inter> s = f -` c \<inter> s"
  2187     unfolding bchoice_iff ..
  2188   with cover have "\<forall>c\<in>C. open (A c)" "s \<subseteq> (\<Union>c\<in>C. A c)"
  2189     by (fastforce simp add: subset_eq set_eq_iff)+
  2190   from compactE_image[OF s this] obtain D where "D \<subseteq> C" "finite D" "s \<subseteq> (\<Union>c\<in>D. A c)" .
  2191   with A show "\<exists>D \<subseteq> C. finite D \<and> f`s \<subseteq> \<Union>D"
  2192     by (intro exI[of _ D]) (fastforce simp add: subset_eq set_eq_iff)+
  2193 qed
  2194 
  2195 lemma continuous_on_inv:
  2196   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  2197   assumes "continuous_on s f"
  2198     and "compact s"
  2199     and "\<forall>x\<in>s. g (f x) = x"
  2200   shows "continuous_on (f ` s) g"
  2201   unfolding continuous_on_topological
  2202 proof (clarsimp simp add: assms(3))
  2203   fix x :: 'a and B :: "'a set"
  2204   assume "x \<in> s" and "open B" and "x \<in> B"
  2205   have 1: "\<forall>x\<in>s. f x \<in> f ` (s - B) \<longleftrightarrow> x \<in> s - B"
  2206     using assms(3) by (auto, metis)
  2207   have "continuous_on (s - B) f"
  2208     using \<open>continuous_on s f\<close> Diff_subset
  2209     by (rule continuous_on_subset)
  2210   moreover have "compact (s - B)"
  2211     using \<open>open B\<close> and \<open>compact s\<close>
  2212     unfolding Diff_eq by (intro compact_Int_closed closed_Compl)
  2213   ultimately have "compact (f ` (s - B))"
  2214     by (rule compact_continuous_image)
  2215   then have "closed (f ` (s - B))"
  2216     by (rule compact_imp_closed)
  2217   then have "open (- f ` (s - B))"
  2218     by (rule open_Compl)
  2219   moreover have "f x \<in> - f ` (s - B)"
  2220     using \<open>x \<in> s\<close> and \<open>x \<in> B\<close> by (simp add: 1)
  2221   moreover have "\<forall>y\<in>s. f y \<in> - f ` (s - B) \<longrightarrow> y \<in> B"
  2222     by (simp add: 1)
  2223   ultimately show "\<exists>A. open A \<and> f x \<in> A \<and> (\<forall>y\<in>s. f y \<in> A \<longrightarrow> y \<in> B)"
  2224     by fast
  2225 qed
  2226 
  2227 lemma continuous_on_inv_into:
  2228   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  2229   assumes s: "continuous_on s f" "compact s"
  2230     and f: "inj_on f s"
  2231   shows "continuous_on (f ` s) (the_inv_into s f)"
  2232   by (rule continuous_on_inv[OF s]) (auto simp: the_inv_into_f_f[OF f])
  2233 
  2234 lemma (in linorder_topology) compact_attains_sup:
  2235   assumes "compact S" "S \<noteq> {}"
  2236   shows "\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s"
  2237 proof (rule classical)
  2238   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s)"
  2239   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. s < t s"
  2240     by (metis not_le)
  2241   then have "\<forall>s\<in>S. open {..< t s}" "S \<subseteq> (\<Union>s\<in>S. {..< t s})"
  2242     by auto
  2243   with \<open>compact S\<close> obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {..< t s})"
  2244     by (erule compactE_image)
  2245   with \<open>S \<noteq> {}\<close> have Max: "Max (t`C) \<in> t`C" and "\<forall>s\<in>t`C. s \<le> Max (t`C)"
  2246     by (auto intro!: Max_in)
  2247   with C have "S \<subseteq> {..< Max (t`C)}"
  2248     by (auto intro: less_le_trans simp: subset_eq)
  2249   with t Max \<open>C \<subseteq> S\<close> show ?thesis
  2250     by fastforce
  2251 qed
  2252 
  2253 lemma (in linorder_topology) compact_attains_inf:
  2254   assumes "compact S" "S \<noteq> {}"
  2255   shows "\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t"
  2256 proof (rule classical)
  2257   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t)"
  2258   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. t s < s"
  2259     by (metis not_le)
  2260   then have "\<forall>s\<in>S. open {t s <..}" "S \<subseteq> (\<Union>s\<in>S. {t s <..})"
  2261     by auto
  2262   with \<open>compact S\<close> obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {t s <..})"
  2263     by (erule compactE_image)
  2264   with \<open>S \<noteq> {}\<close> have Min: "Min (t`C) \<in> t`C" and "\<forall>s\<in>t`C. Min (t`C) \<le> s"
  2265     by (auto intro!: Min_in)
  2266   with C have "S \<subseteq> {Min (t`C) <..}"
  2267     by (auto intro: le_less_trans simp: subset_eq)
  2268   with t Min \<open>C \<subseteq> S\<close> show ?thesis
  2269     by fastforce
  2270 qed
  2271 
  2272 lemma continuous_attains_sup:
  2273   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2274   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s.  f y \<le> f x)"
  2275   using compact_attains_sup[of "f ` s"] compact_continuous_image[of s f] by auto
  2276 
  2277 lemma continuous_attains_inf:
  2278   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2279   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s. f x \<le> f y)"
  2280   using compact_attains_inf[of "f ` s"] compact_continuous_image[of s f] by auto
  2281 
  2282 
  2283 subsection \<open>Connectedness\<close>
  2284 
  2285 context topological_space
  2286 begin
  2287 
  2288 definition "connected S \<longleftrightarrow>
  2289   \<not> (\<exists>A B. open A \<and> open B \<and> S \<subseteq> A \<union> B \<and> A \<inter> B \<inter> S = {} \<and> A \<inter> S \<noteq> {} \<and> B \<inter> S \<noteq> {})"
  2290 
  2291 lemma connectedI:
  2292   "(\<And>A B. open A \<Longrightarrow> open B \<Longrightarrow> A \<inter> U \<noteq> {} \<Longrightarrow> B \<inter> U \<noteq> {} \<Longrightarrow> A \<inter> B \<inter> U = {} \<Longrightarrow> U \<subseteq> A \<union> B \<Longrightarrow> False)
  2293   \<Longrightarrow> connected U"
  2294   by (auto simp: connected_def)
  2295 
  2296 lemma connected_empty [simp]: "connected {}"
  2297   by (auto intro!: connectedI)
  2298 
  2299 lemma connected_sing [simp]: "connected {x}"
  2300   by (auto intro!: connectedI)
  2301 
  2302 lemma connectedD:
  2303   "connected A \<Longrightarrow> open U \<Longrightarrow> open V \<Longrightarrow> U \<inter> V \<inter> A = {} \<Longrightarrow> A \<subseteq> U \<union> V \<Longrightarrow> U \<inter> A = {} \<or> V \<inter> A = {}"
  2304   by (auto simp: connected_def)
  2305 
  2306 end
  2307 
  2308 lemma connected_closed:
  2309   "connected s \<longleftrightarrow>
  2310     \<not> (\<exists>A B. closed A \<and> closed B \<and> s \<subseteq> A \<union> B \<and> A \<inter> B \<inter> s = {} \<and> A \<inter> s \<noteq> {} \<and> B \<inter> s \<noteq> {})"
  2311   apply (simp add: connected_def del: ex_simps, safe)
  2312    apply (drule_tac x="-A" in spec)
  2313    apply (drule_tac x="-B" in spec)
  2314    apply (fastforce simp add: closed_def [symmetric])
  2315   apply (drule_tac x="-A" in spec)
  2316   apply (drule_tac x="-B" in spec)
  2317   apply (fastforce simp add: open_closed [symmetric])
  2318   done
  2319 
  2320 lemma connected_closedD:
  2321   "\<lbrakk>connected s; A \<inter> B \<inter> s = {}; s \<subseteq> A \<union> B; closed A; closed B\<rbrakk> \<Longrightarrow> A \<inter> s = {} \<or> B \<inter> s = {}"
  2322   by (simp add: connected_closed)
  2323 
  2324 lemma connected_Union:
  2325   assumes cs: "\<And>s. s \<in> S \<Longrightarrow> connected s"
  2326     and ne: "\<Inter>S \<noteq> {}"
  2327   shows "connected(\<Union>S)"
  2328 proof (rule connectedI)
  2329   fix A B
  2330   assume A: "open A" and B: "open B" and Alap: "A \<inter> \<Union>S \<noteq> {}" and Blap: "B \<inter> \<Union>S \<noteq> {}"
  2331     and disj: "A \<inter> B \<inter> \<Union>S = {}" and cover: "\<Union>S \<subseteq> A \<union> B"
  2332   have disjs:"\<And>s. s \<in> S \<Longrightarrow> A \<inter> B \<inter> s = {}"
  2333     using disj by auto
  2334   obtain sa where sa: "sa \<in> S" "A \<inter> sa \<noteq> {}"
  2335     using Alap by auto
  2336   obtain sb where sb: "sb \<in> S" "B \<inter> sb \<noteq> {}"
  2337     using Blap by auto
  2338   obtain x where x: "\<And>s. s \<in> S \<Longrightarrow> x \<in> s"
  2339     using ne by auto
  2340   then have "x \<in> \<Union>S"
  2341     using \<open>sa \<in> S\<close> by blast
  2342   then have "x \<in> A \<or> x \<in> B"
  2343     using cover by auto
  2344   then show False
  2345     using cs [unfolded connected_def]
  2346     by (metis A B IntI Sup_upper sa sb disjs x cover empty_iff subset_trans)
  2347 qed
  2348 
  2349 lemma connected_Un: "connected s \<Longrightarrow> connected t \<Longrightarrow> s \<inter> t \<noteq> {} \<Longrightarrow> connected (s \<union> t)"
  2350   using connected_Union [of "{s,t}"] by auto
  2351 
  2352 lemma connected_diff_open_from_closed:
  2353   assumes st: "s \<subseteq> t"
  2354     and tu: "t \<subseteq> u"
  2355     and s: "open s"
  2356     and t: "closed t"
  2357     and u: "connected u"
  2358     and ts: "connected (t - s)"
  2359   shows "connected(u - s)"
  2360 proof (rule connectedI)
  2361   fix A B
  2362   assume AB: "open A" "open B" "A \<inter> (u - s) \<noteq> {}" "B \<inter> (u - s) \<noteq> {}"
  2363     and disj: "A \<inter> B \<inter> (u - s) = {}"
  2364     and cover: "u - s \<subseteq> A \<union> B"
  2365   then consider "A \<inter> (t - s) = {}" | "B \<inter> (t - s) = {}"
  2366     using st ts tu connectedD [of "t-s" "A" "B"] by auto
  2367   then show False
  2368   proof cases
  2369     case 1
  2370     then have "(A - t) \<inter> (B \<union> s) \<inter> u = {}"
  2371       using disj st by auto
  2372     moreover have "u \<subseteq> (A - t) \<union> (B \<union> s)"
  2373       using 1 cover by auto
  2374     ultimately show False
  2375       using connectedD [of u "A - t" "B \<union> s"] AB s t 1 u by auto
  2376   next
  2377     case 2
  2378     then have "(A \<union> s) \<inter> (B - t) \<inter> u = {}"
  2379       using disj st by auto
  2380     moreover have "u \<subseteq> (A \<union> s) \<union> (B - t)"
  2381       using 2 cover by auto
  2382     ultimately show False
  2383       using connectedD [of u "A \<union> s" "B - t"] AB s t 2 u by auto
  2384   qed
  2385 qed
  2386 
  2387 lemma connected_iff_const:
  2388   fixes S :: "'a::topological_space set"
  2389   shows "connected S \<longleftrightarrow> (\<forall>P::'a \<Rightarrow> bool. continuous_on S P \<longrightarrow> (\<exists>c. \<forall>s\<in>S. P s = c))"
  2390 proof safe
  2391   fix P :: "'a \<Rightarrow> bool"
  2392   assume "connected S" "continuous_on S P"
  2393   then have "\<And>b. \<exists>A. open A \<and> A \<inter> S = P -` {b} \<inter> S"
  2394     unfolding continuous_on_open_invariant by (simp add: open_discrete)
  2395   from this[of True] this[of False]
  2396   obtain t f where "open t" "open f" and *: "f \<inter> S = P -` {False} \<inter> S" "t \<inter> S = P -` {True} \<inter> S"
  2397     by meson
  2398   then have "t \<inter> S = {} \<or> f \<inter> S = {}"
  2399     by (intro connectedD[OF \<open>connected S\<close>])  auto
  2400   then show "\<exists>c. \<forall>s\<in>S. P s = c"
  2401   proof (rule disjE)
  2402     assume "t \<inter> S = {}"
  2403     then show ?thesis
  2404       unfolding * by (intro exI[of _ False]) auto
  2405   next
  2406     assume "f \<inter> S = {}"
  2407     then show ?thesis
  2408       unfolding * by (intro exI[of _ True]) auto
  2409   qed
  2410 next
  2411   assume P: "\<forall>P::'a \<Rightarrow> bool. continuous_on S P \<longrightarrow> (\<exists>c. \<forall>s\<in>S. P s = c)"
  2412   show "connected S"
  2413   proof (rule connectedI)
  2414     fix A B
  2415     assume *: "open A" "open B" "A \<inter> S \<noteq> {}" "B \<inter> S \<noteq> {}" "A \<inter> B \<inter> S = {}" "S \<subseteq> A \<union> B"
  2416     have "continuous_on S (\<lambda>x. x \<in> A)"
  2417       unfolding continuous_on_open_invariant
  2418     proof safe
  2419       fix C :: "bool set"
  2420       have "C = UNIV \<or> C = {True} \<or> C = {False} \<or> C = {}"
  2421         using subset_UNIV[of C] unfolding UNIV_bool by auto
  2422       with * show "\<exists>T. open T \<and> T \<inter> S = (\<lambda>x. x \<in> A) -` C \<inter> S"
  2423         by (intro exI[of _ "(if True \<in> C then A else {}) \<union> (if False \<in> C then B else {})"]) auto
  2424     qed
  2425     from P[rule_format, OF this] obtain c where "\<And>s. s \<in> S \<Longrightarrow> (s \<in> A) = c"
  2426       by blast
  2427     with * show False
  2428       by (cases c) auto
  2429   qed
  2430 qed
  2431 
  2432 lemma connectedD_const: "connected S \<Longrightarrow> continuous_on S P \<Longrightarrow> \<exists>c. \<forall>s\<in>S. P s = c"
  2433   for P :: "'a::topological_space \<Rightarrow> bool"
  2434   by (auto simp: connected_iff_const)
  2435 
  2436 lemma connectedI_const:
  2437   "(\<And>P::'a::topological_space \<Rightarrow> bool. continuous_on S P \<Longrightarrow> \<exists>c. \<forall>s\<in>S. P s = c) \<Longrightarrow> connected S"
  2438   by (auto simp: connected_iff_const)
  2439 
  2440 lemma connected_local_const:
  2441   assumes "connected A" "a \<in> A" "b \<in> A"
  2442     and *: "\<forall>a\<in>A. eventually (\<lambda>b. f a = f b) (at a within A)"
  2443   shows "f a = f b"
  2444 proof -
  2445   obtain S where S: "\<And>a. a \<in> A \<Longrightarrow> a \<in> S a" "\<And>a. a \<in> A \<Longrightarrow> open (S a)"
  2446     "\<And>a x. a \<in> A \<Longrightarrow> x \<in> S a \<Longrightarrow> x \<in> A \<Longrightarrow> f a = f x"
  2447     using * unfolding eventually_at_topological by metis
  2448   let ?P = "\<Union>b\<in>{b\<in>A. f a = f b}. S b" and ?N = "\<Union>b\<in>{b\<in>A. f a \<noteq> f b}. S b"
  2449   have "?P \<inter> A = {} \<or> ?N \<inter> A = {}"
  2450     using \<open>connected A\<close> S \<open>a\<in>A\<close>
  2451     by (intro connectedD) (auto, metis)
  2452   then show "f a = f b"
  2453   proof
  2454     assume "?N \<inter> A = {}"
  2455     then have "\<forall>x\<in>A. f a = f x"
  2456       using S(1) by auto
  2457     with \<open>b\<in>A\<close> show ?thesis by auto
  2458   next
  2459     assume "?P \<inter> A = {}" then show ?thesis
  2460       using \<open>a \<in> A\<close> S(1)[of a] by auto
  2461   qed
  2462 qed
  2463 
  2464 lemma (in linorder_topology) connectedD_interval:
  2465   assumes "connected U"
  2466     and xy: "x \<in> U" "y \<in> U"
  2467     and "x \<le> z" "z \<le> y"
  2468   shows "z \<in> U"
  2469 proof -
  2470   have eq: "{..<z} \<union> {z<..} = - {z}"
  2471     by auto
  2472   have "\<not> connected U" if "z \<notin> U" "x < z" "z < y"
  2473     using xy that
  2474     apply (simp only: connected_def simp_thms)
  2475     apply (rule_tac exI[of _ "{..< z}"])
  2476     apply (rule_tac exI[of _ "{z <..}"])
  2477     apply (auto simp add: eq)
  2478     done
  2479   with assms show "z \<in> U"
  2480     by (metis less_le)
  2481 qed
  2482 
  2483 lemma connected_continuous_image:
  2484   assumes *: "continuous_on s f"
  2485     and "connected s"
  2486   shows "connected (f ` s)"
  2487 proof (rule connectedI_const)
  2488   fix P :: "'b \<Rightarrow> bool"
  2489   assume "continuous_on (f ` s) P"
  2490   then have "continuous_on s (P \<circ> f)"
  2491     by (rule continuous_on_compose[OF *])
  2492   from connectedD_const[OF \<open>connected s\<close> this] show "\<exists>c. \<forall>s\<in>f ` s. P s = c"
  2493     by auto
  2494 qed
  2495 
  2496 
  2497 section \<open>Linear Continuum Topologies\<close>
  2498 
  2499 class linear_continuum_topology = linorder_topology + linear_continuum
  2500 begin
  2501 
  2502 lemma Inf_notin_open:
  2503   assumes A: "open A"
  2504     and bnd: "\<forall>a\<in>A. x < a"
  2505   shows "Inf A \<notin> A"
  2506 proof
  2507   assume "Inf A \<in> A"
  2508   then obtain b where "b < Inf A" "{b <.. Inf A} \<subseteq> A"
  2509     using open_left[of A "Inf A" x] assms by auto
  2510   with dense[of b "Inf A"] obtain c where "c < Inf A" "c \<in> A"
  2511     by (auto simp: subset_eq)
  2512   then show False
  2513     using cInf_lower[OF \<open>c \<in> A\<close>] bnd
  2514     by (metis not_le less_imp_le bdd_belowI)
  2515 qed
  2516 
  2517 lemma Sup_notin_open:
  2518   assumes A: "open A"
  2519     and bnd: "\<forall>a\<in>A. a < x"
  2520   shows "Sup A \<notin> A"
  2521 proof
  2522   assume "Sup A \<in> A"
  2523   with assms obtain b where "Sup A < b" "{Sup A ..< b} \<subseteq> A"
  2524     using open_right[of A "Sup A" x] by auto
  2525   with dense[of "Sup A" b] obtain c where "Sup A < c" "c \<in> A"
  2526     by (auto simp: subset_eq)
  2527   then show False
  2528     using cSup_upper[OF \<open>c \<in> A\<close>] bnd
  2529     by (metis less_imp_le not_le bdd_aboveI)
  2530 qed
  2531 
  2532 end
  2533 
  2534 instance linear_continuum_topology \<subseteq> perfect_space
  2535 proof
  2536   fix x :: 'a
  2537   obtain y where "x < y \<or> y < x"
  2538     using ex_gt_or_lt [of x] ..
  2539   with Inf_notin_open[of "{x}" y] Sup_notin_open[of "{x}" y] show "\<not> open {x}"
  2540     by auto
  2541 qed
  2542 
  2543 lemma connectedI_interval:
  2544   fixes U :: "'a :: linear_continuum_topology set"
  2545   assumes *: "\<And>x y z. x \<in> U \<Longrightarrow> y \<in> U \<Longrightarrow> x \<le> z \<Longrightarrow> z \<le> y \<Longrightarrow> z \<in> U"
  2546   shows "connected U"
  2547 proof (rule connectedI)
  2548   {
  2549     fix A B
  2550     assume "open A" "open B" "A \<inter> B \<inter> U = {}" "U \<subseteq> A \<union> B"
  2551     fix x y
  2552     assume "x < y" "x \<in> A" "y \<in> B" "x \<in> U" "y \<in> U"
  2553 
  2554     let ?z = "Inf (B \<inter> {x <..})"
  2555 
  2556     have "x \<le> ?z" "?z \<le> y"
  2557       using \<open>y \<in> B\<close> \<open>x < y\<close> by (auto intro: cInf_lower cInf_greatest)
  2558     with \<open>x \<in> U\<close> \<open>y \<in> U\<close> have "?z \<in> U"
  2559       by (rule *)
  2560     moreover have "?z \<notin> B \<inter> {x <..}"
  2561       using \<open>open B\<close> by (intro Inf_notin_open) auto
  2562     ultimately have "?z \<in> A"
  2563       using \<open>x \<le> ?z\<close> \<open>A \<inter> B \<inter> U = {}\<close> \<open>x \<in> A\<close> \<open>U \<subseteq> A \<union> B\<close> by auto
  2564     have "\<exists>b\<in>B. b \<in> A \<and> b \<in> U" if "?z < y"
  2565     proof -
  2566       obtain a where "?z < a" "{?z ..< a} \<subseteq> A"
  2567         using open_right[OF \<open>open A\<close> \<open>?z \<in> A\<close> \<open>?z < y\<close>] by auto
  2568       moreover obtain b where "b \<in> B" "x < b" "b < min a y"
  2569         using cInf_less_iff[of "B \<inter> {x <..}" "min a y"] \<open>?z < a\<close> \<open>?z < y\<close> \<open>x < y\<close> \<open>y \<in> B\<close>
  2570         by auto
  2571       moreover have "?z \<le> b"
  2572         using \<open>b \<in> B\<close> \<open>x < b\<close>
  2573         by (intro cInf_lower) auto
  2574       moreover have "b \<in> U"
  2575         using \<open>x \<le> ?z\<close> \<open>?z \<le> b\<close> \<open>b < min a y\<close>
  2576         by (intro *[OF \<open>x \<in> U\<close> \<open>y \<in> U\<close>]) (auto simp: less_imp_le)
  2577       ultimately show ?thesis
  2578         by (intro bexI[of _ b]) auto
  2579     qed
  2580     then have False
  2581       using \<open>?z \<le> y\<close> \<open>?z \<in> A\<close> \<open>y \<in> B\<close> \<open>y \<in> U\<close> \<open>A \<inter> B \<inter> U = {}\<close>
  2582       unfolding le_less by blast
  2583   }
  2584   note not_disjoint = this
  2585 
  2586   fix A B assume AB: "open A" "open B" "U \<subseteq> A \<union> B" "A \<inter> B \<inter> U = {}"
  2587   moreover assume "A \<inter> U \<noteq> {}" then obtain x where x: "x \<in> U" "x \<in> A" by auto
  2588   moreover assume "B \<inter> U \<noteq> {}" then obtain y where y: "y \<in> U" "y \<in> B" by auto
  2589   moreover note not_disjoint[of B A y x] not_disjoint[of A B x y]
  2590   ultimately show False
  2591     by (cases x y rule: linorder_cases) auto
  2592 qed
  2593 
  2594 lemma connected_iff_interval: "connected U \<longleftrightarrow> (\<forall>x\<in>U. \<forall>y\<in>U. \<forall>z. x \<le> z \<longrightarrow> z \<le> y \<longrightarrow> z \<in> U)"
  2595   for U :: "'a::linear_continuum_topology set"
  2596   by (auto intro: connectedI_interval dest: connectedD_interval)
  2597 
  2598 lemma connected_UNIV[simp]: "connected (UNIV::'a::linear_continuum_topology set)"
  2599   by (simp add: connected_iff_interval)
  2600 
  2601 lemma connected_Ioi[simp]: "connected {a<..}"
  2602   for a :: "'a::linear_continuum_topology"
  2603   by (auto simp: connected_iff_interval)
  2604 
  2605 lemma connected_Ici[simp]: "connected {a..}"
  2606   for a :: "'a::linear_continuum_topology"
  2607   by (auto simp: connected_iff_interval)
  2608 
  2609 lemma connected_Iio[simp]: "connected {..<a}"
  2610   for a :: "'a::linear_continuum_topology"
  2611   by (auto simp: connected_iff_interval)
  2612 
  2613 lemma connected_Iic[simp]: "connected {..a}"
  2614   for a :: "'a::linear_continuum_topology"
  2615   by (auto simp: connected_iff_interval)
  2616 
  2617 lemma connected_Ioo[simp]: "connected {a<..<b}"
  2618   for a b :: "'a::linear_continuum_topology"
  2619   unfolding connected_iff_interval by auto
  2620 
  2621 lemma connected_Ioc[simp]: "connected {a<..b}"
  2622   for a b :: "'a::linear_continuum_topology"
  2623   by (auto simp: connected_iff_interval)
  2624 
  2625 lemma connected_Ico[simp]: "connected {a..<b}"
  2626   for a b :: "'a::linear_continuum_topology"
  2627   by (auto simp: connected_iff_interval)
  2628 
  2629 lemma connected_Icc[simp]: "connected {a..b}"
  2630   for a b :: "'a::linear_continuum_topology"
  2631   by (auto simp: connected_iff_interval)
  2632 
  2633 lemma connected_contains_Ioo:
  2634   fixes A :: "'a :: linorder_topology set"
  2635   assumes "connected A" "a \<in> A" "b \<in> A" shows "{a <..< b} \<subseteq> A"
  2636   using connectedD_interval[OF assms] by (simp add: subset_eq Ball_def less_imp_le)
  2637 
  2638 lemma connected_contains_Icc:
  2639   fixes A :: "'a::linorder_topology set"
  2640   assumes "connected A" "a \<in> A" "b \<in> A"
  2641   shows "{a..b} \<subseteq> A"
  2642 proof
  2643   fix x assume "x \<in> {a..b}"
  2644   then have "x = a \<or> x = b \<or> x \<in> {a<..<b}"
  2645     by auto
  2646   then show "x \<in> A"
  2647     using assms connected_contains_Ioo[of A a b] by auto
  2648 qed
  2649 
  2650 
  2651 subsection \<open>Intermediate Value Theorem\<close>
  2652 
  2653 lemma IVT':
  2654   fixes f :: "'a::linear_continuum_topology \<Rightarrow> 'b::linorder_topology"
  2655   assumes y: "f a \<le> y" "y \<le> f b" "a \<le> b"
  2656     and *: "continuous_on {a .. b} f"
  2657   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2658 proof -
  2659   have "connected {a..b}"
  2660     unfolding connected_iff_interval by auto
  2661   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f a" "f b" y] y
  2662   show ?thesis
  2663     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2664 qed
  2665 
  2666 lemma IVT2':
  2667   fixes f :: "'a :: linear_continuum_topology \<Rightarrow> 'b :: linorder_topology"
  2668   assumes y: "f b \<le> y" "y \<le> f a" "a \<le> b"
  2669     and *: "continuous_on {a .. b} f"
  2670   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2671 proof -
  2672   have "connected {a..b}"
  2673     unfolding connected_iff_interval by auto
  2674   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f b" "f a" y] y
  2675   show ?thesis
  2676     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2677 qed
  2678 
  2679 lemma IVT:
  2680   fixes f :: "'a::linear_continuum_topology \<Rightarrow> 'b::linorder_topology"
  2681   shows "f a \<le> y \<Longrightarrow> y \<le> f b \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow>
  2682     \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2683   by (rule IVT') (auto intro: continuous_at_imp_continuous_on)
  2684 
  2685 lemma IVT2:
  2686   fixes f :: "'a::linear_continuum_topology \<Rightarrow> 'b::linorder_topology"
  2687   shows "f b \<le> y \<Longrightarrow> y \<le> f a \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow>
  2688     \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2689   by (rule IVT2') (auto intro: continuous_at_imp_continuous_on)
  2690 
  2691 lemma continuous_inj_imp_mono:
  2692   fixes f :: "'a::linear_continuum_topology \<Rightarrow> 'b::linorder_topology"
  2693   assumes x: "a < x" "x < b"
  2694     and cont: "continuous_on {a..b} f"
  2695     and inj: "inj_on f {a..b}"
  2696   shows "(f a < f x \<and> f x < f b) \<or> (f b < f x \<and> f x < f a)"
  2697 proof -
  2698   note I = inj_on_eq_iff[OF inj]
  2699   {
  2700     assume "f x < f a" "f x < f b"
  2701     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f x < f s"
  2702       using IVT'[of f x "min (f a) (f b)" b] IVT2'[of f x "min (f a) (f b)" a] x
  2703       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2704     with x I have False by auto
  2705   }
  2706   moreover
  2707   {
  2708     assume "f a < f x" "f b < f x"
  2709     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f s < f x"
  2710       using IVT'[of f a "max (f a) (f b)" x] IVT2'[of f b "max (f a) (f b)" x] x
  2711       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2712     with x I have False by auto
  2713   }
  2714   ultimately show ?thesis
  2715     using I[of a x] I[of x b] x less_trans[OF x]
  2716     by (auto simp add: le_less less_imp_neq neq_iff)
  2717 qed
  2718 
  2719 lemma continuous_at_Sup_mono:
  2720   fixes f :: "'a::{linorder_topology,conditionally_complete_linorder} \<Rightarrow>
  2721     'b::{linorder_topology,conditionally_complete_linorder}"
  2722   assumes "mono f"
  2723     and cont: "continuous (at_left (Sup S)) f"
  2724     and S: "S \<noteq> {}" "bdd_above S"
  2725   shows "f (Sup S) = (SUP s:S. f s)"
  2726 proof (rule antisym)
  2727   have f: "(f \<longlongrightarrow> f (Sup S)) (at_left (Sup S))"
  2728     using cont unfolding continuous_within .
  2729   show "f (Sup S) \<le> (SUP s:S. f s)"
  2730   proof cases
  2731     assume "Sup S \<in> S"
  2732     then show ?thesis
  2733       by (rule cSUP_upper) (auto intro: bdd_above_image_mono S \<open>mono f\<close>)
  2734   next
  2735     assume "Sup S \<notin> S"
  2736     from \<open>S \<noteq> {}\<close> obtain s where "s \<in> S"
  2737       by auto
  2738     with \<open>Sup S \<notin> S\<close> S have "s < Sup S"
  2739       unfolding less_le by (blast intro: cSup_upper)
  2740     show ?thesis
  2741     proof (rule ccontr)
  2742       assume "\<not> ?thesis"
  2743       with order_tendstoD(1)[OF f, of "SUP s:S. f s"] obtain b where "b < Sup S"
  2744         and *: "\<And>y. b < y \<Longrightarrow> y < Sup S \<Longrightarrow> (SUP s:S. f s) < f y"
  2745         by (auto simp: not_le eventually_at_left[OF \<open>s < Sup S\<close>])
  2746       with \<open>S \<noteq> {}\<close> obtain c where "c \<in> S" "b < c"
  2747         using less_cSupD[of S b] by auto
  2748       with \<open>Sup S \<notin> S\<close> S have "c < Sup S"
  2749         unfolding less_le by (blast intro: cSup_upper)
  2750       from *[OF \<open>b < c\<close> \<open>c < Sup S\<close>] cSUP_upper[OF \<open>c \<in> S\<close> bdd_above_image_mono[of f]]
  2751       show False
  2752         by (auto simp: assms)
  2753     qed
  2754   qed
  2755 qed (intro cSUP_least \<open>mono f\<close>[THEN monoD] cSup_upper S)
  2756 
  2757 lemma continuous_at_Sup_antimono:
  2758   fixes f :: "'a::{linorder_topology,conditionally_complete_linorder} \<Rightarrow>
  2759     'b::{linorder_topology,conditionally_complete_linorder}"
  2760   assumes "antimono f"
  2761     and cont: "continuous (at_left (Sup S)) f"
  2762     and S: "S \<noteq> {}" "bdd_above S"
  2763   shows "f (Sup S) = (INF s:S. f s)"
  2764 proof (rule antisym)
  2765   have f: "(f \<longlongrightarrow> f (Sup S)) (at_left (Sup S))"
  2766     using cont unfolding continuous_within .
  2767   show "(INF s:S. f s) \<le> f (Sup S)"
  2768   proof cases
  2769     assume "Sup S \<in> S"
  2770     then show ?thesis
  2771       by (intro cINF_lower) (auto intro: bdd_below_image_antimono S \<open>antimono f\<close>)
  2772   next
  2773     assume "Sup S \<notin> S"
  2774     from \<open>S \<noteq> {}\<close> obtain s where "s \<in> S"
  2775       by auto
  2776     with \<open>Sup S \<notin> S\<close> S have "s < Sup S"
  2777       unfolding less_le by (blast intro: cSup_upper)
  2778     show ?thesis
  2779     proof (rule ccontr)
  2780       assume "\<not> ?thesis"
  2781       with order_tendstoD(2)[OF f, of "INF s:S. f s"] obtain b where "b < Sup S"
  2782         and *: "\<And>y. b < y \<Longrightarrow> y < Sup S \<Longrightarrow> f y < (INF s:S. f s)"
  2783         by (auto simp: not_le eventually_at_left[OF \<open>s < Sup S\<close>])
  2784       with \<open>S \<noteq> {}\<close> obtain c where "c \<in> S" "b < c"
  2785         using less_cSupD[of S b] by auto
  2786       with \<open>Sup S \<notin> S\<close> S have "c < Sup S"
  2787         unfolding less_le by (blast intro: cSup_upper)
  2788       from *[OF \<open>b < c\<close> \<open>c < Sup S\<close>] cINF_lower[OF bdd_below_image_antimono, of f S c] \<open>c \<in> S\<close>
  2789       show False
  2790         by (auto simp: assms)
  2791     qed
  2792   qed
  2793 qed (intro cINF_greatest \<open>antimono f\<close>[THEN antimonoD] cSup_upper S)
  2794 
  2795 lemma continuous_at_Inf_mono:
  2796   fixes f :: "'a::{linorder_topology,conditionally_complete_linorder} \<Rightarrow>
  2797     'b::{linorder_topology,conditionally_complete_linorder}"
  2798   assumes "mono f"
  2799     and cont: "continuous (at_right (Inf S)) f"
  2800     and S: "S \<noteq> {}" "bdd_below S"
  2801   shows "f (Inf S) = (INF s:S. f s)"
  2802 proof (rule antisym)
  2803   have f: "(f \<longlongrightarrow> f (Inf S)) (at_right (Inf S))"
  2804     using cont unfolding continuous_within .
  2805   show "(INF s:S. f s) \<le> f (Inf S)"
  2806   proof cases
  2807     assume "Inf S \<in> S"
  2808     then show ?thesis
  2809       by (rule cINF_lower[rotated]) (auto intro: bdd_below_image_mono S \<open>mono f\<close>)
  2810   next
  2811     assume "Inf S \<notin> S"
  2812     from \<open>S \<noteq> {}\<close> obtain s where "s \<in> S"
  2813       by auto
  2814     with \<open>Inf S \<notin> S\<close> S have "Inf S < s"
  2815       unfolding less_le by (blast intro: cInf_lower)
  2816     show ?thesis
  2817     proof (rule ccontr)
  2818       assume "\<not> ?thesis"
  2819       with order_tendstoD(2)[OF f, of "INF s:S. f s"] obtain b where "Inf S < b"
  2820         and *: "\<And>y. Inf S < y \<Longrightarrow> y < b \<Longrightarrow> f y < (INF s:S. f s)"
  2821         by (auto simp: not_le eventually_at_right[OF \<open>Inf S < s\<close>])
  2822       with \<open>S \<noteq> {}\<close> obtain c where "c \<in> S" "c < b"
  2823         using cInf_lessD[of S b] by auto
  2824       with \<open>Inf S \<notin> S\<close> S have "Inf S < c"
  2825         unfolding less_le by (blast intro: cInf_lower)
  2826       from *[OF \<open>Inf S < c\<close> \<open>c < b\<close>] cINF_lower[OF bdd_below_image_mono[of f] \<open>c \<in> S\<close>]
  2827       show False
  2828         by (auto simp: assms)
  2829     qed
  2830   qed
  2831 qed (intro cINF_greatest \<open>mono f\<close>[THEN monoD] cInf_lower \<open>bdd_below S\<close> \<open>S \<noteq> {}\<close>)
  2832 
  2833 lemma continuous_at_Inf_antimono:
  2834   fixes f :: "'a::{linorder_topology,conditionally_complete_linorder} \<Rightarrow>
  2835     'b::{linorder_topology,conditionally_complete_linorder}"
  2836   assumes "antimono f"
  2837     and cont: "continuous (at_right (Inf S)) f"
  2838     and S: "S \<noteq> {}" "bdd_below S"
  2839   shows "f (Inf S) = (SUP s:S. f s)"
  2840 proof (rule antisym)
  2841   have f: "(f \<longlongrightarrow> f (Inf S)) (at_right (Inf S))"
  2842     using cont unfolding continuous_within .
  2843   show "f (Inf S) \<le> (SUP s:S. f s)"
  2844   proof cases
  2845     assume "Inf S \<in> S"
  2846     then show ?thesis
  2847       by (rule cSUP_upper) (auto intro: bdd_above_image_antimono S \<open>antimono f\<close>)
  2848   next
  2849     assume "Inf S \<notin> S"
  2850     from \<open>S \<noteq> {}\<close> obtain s where "s \<in> S"
  2851       by auto
  2852     with \<open>Inf S \<notin> S\<close> S have "Inf S < s"
  2853       unfolding less_le by (blast intro: cInf_lower)
  2854     show ?thesis
  2855     proof (rule ccontr)
  2856       assume "\<not> ?thesis"
  2857       with order_tendstoD(1)[OF f, of "SUP s:S. f s"] obtain b where "Inf S < b"
  2858         and *: "\<And>y. Inf S < y \<Longrightarrow> y < b \<Longrightarrow> (SUP s:S. f s) < f y"
  2859         by (auto simp: not_le eventually_at_right[OF \<open>Inf S < s\<close>])
  2860       with \<open>S \<noteq> {}\<close> obtain c where "c \<in> S" "c < b"
  2861         using cInf_lessD[of S b] by auto
  2862       with \<open>Inf S \<notin> S\<close> S have "Inf S < c"
  2863         unfolding less_le by (blast intro: cInf_lower)
  2864       from *[OF \<open>Inf S < c\<close> \<open>c < b\<close>] cSUP_upper[OF \<open>c \<in> S\<close> bdd_above_image_antimono[of f]]
  2865       show False
  2866         by (auto simp: assms)
  2867     qed
  2868   qed
  2869 qed (intro cSUP_least \<open>antimono f\<close>[THEN antimonoD] cInf_lower S)
  2870 
  2871 
  2872 subsection \<open>Uniform spaces\<close>
  2873 
  2874 class uniformity =
  2875   fixes uniformity :: "('a \<times> 'a) filter"
  2876 begin
  2877 
  2878 abbreviation uniformity_on :: "'a set \<Rightarrow> ('a \<times> 'a) filter"
  2879   where "uniformity_on s \<equiv> inf uniformity (principal (s\<times>s))"
  2880 
  2881 end
  2882 
  2883 lemma uniformity_Abort:
  2884   "uniformity =
  2885     Filter.abstract_filter (\<lambda>u. Code.abort (STR ''uniformity is not executable'') (\<lambda>u. uniformity))"
  2886   by simp
  2887 
  2888 class open_uniformity = "open" + uniformity +
  2889   assumes open_uniformity:
  2890     "\<And>U. open U \<longleftrightarrow> (\<forall>x\<in>U. eventually (\<lambda>(x', y). x' = x \<longrightarrow> y \<in> U) uniformity)"
  2891 
  2892 class uniform_space = open_uniformity +
  2893   assumes uniformity_refl: "eventually E uniformity \<Longrightarrow> E (x, x)"
  2894     and uniformity_sym: "eventually E uniformity \<Longrightarrow> eventually (\<lambda>(x, y). E (y, x)) uniformity"
  2895     and uniformity_trans:
  2896       "eventually E uniformity \<Longrightarrow>
  2897         \<exists>D. eventually D uniformity \<and> (\<forall>x y z. D (x, y) \<longrightarrow> D (y, z) \<longrightarrow> E (x, z))"
  2898 begin
  2899 
  2900 subclass topological_space
  2901   by standard (force elim: eventually_mono eventually_elim2 simp: split_beta' open_uniformity)+
  2902 
  2903 lemma uniformity_bot: "uniformity \<noteq> bot"
  2904   using uniformity_refl by auto
  2905 
  2906 lemma uniformity_trans':
  2907   "eventually E uniformity \<Longrightarrow>
  2908     eventually (\<lambda>((x, y), (y', z)). y = y' \<longrightarrow> E (x, z)) (uniformity \<times>\<^sub>F uniformity)"
  2909   by (drule uniformity_trans) (auto simp add: eventually_prod_same)
  2910 
  2911 lemma uniformity_transE:
  2912   assumes "eventually E uniformity"
  2913   obtains D where "eventually D uniformity" "\<And>x y z. D (x, y) \<Longrightarrow> D (y, z) \<Longrightarrow> E (x, z)"
  2914   using uniformity_trans [OF assms] by auto
  2915 
  2916 lemma eventually_nhds_uniformity:
  2917   "eventually P (nhds x) \<longleftrightarrow> eventually (\<lambda>(x', y). x' = x \<longrightarrow> P y) uniformity"
  2918   (is "_ \<longleftrightarrow> ?N P x")
  2919   unfolding eventually_nhds
  2920 proof safe
  2921   assume *: "?N P x"
  2922   have "?N (?N P) x" if "?N P x" for x
  2923   proof -
  2924     from that obtain D where ev: "eventually D uniformity"
  2925       and D: "D (a, b) \<Longrightarrow> D (b, c) \<Longrightarrow> case (a, c) of (x', y) \<Rightarrow> x' = x \<longrightarrow> P y" for a b c
  2926       by (rule uniformity_transE) simp
  2927     from ev show ?thesis
  2928       by eventually_elim (insert ev D, force elim: eventually_mono split: prod.split)
  2929   qed
  2930   then have "open {x. ?N P x}"
  2931     by (simp add: open_uniformity)
  2932   then show "\<exists>S. open S \<and> x \<in> S \<and> (\<forall>x\<in>S. P x)"
  2933     by (intro exI[of _ "{x. ?N P x}"]) (auto dest: uniformity_refl simp: *)
  2934 qed (force simp add: open_uniformity elim: eventually_mono)
  2935 
  2936 
  2937 subsubsection \<open>Totally bounded sets\<close>
  2938 
  2939 definition totally_bounded :: "'a set \<Rightarrow> bool"
  2940   where "totally_bounded S \<longleftrightarrow>
  2941     (\<forall>E. eventually E uniformity \<longrightarrow> (\<exists>X. finite X \<and> (\<forall>s\<in>S. \<exists>x\<in>X. E (x, s))))"
  2942 
  2943 lemma totally_bounded_empty[iff]: "totally_bounded {}"
  2944   by (auto simp add: totally_bounded_def)
  2945 
  2946 lemma totally_bounded_subset: "totally_bounded S \<Longrightarrow> T \<subseteq> S \<Longrightarrow> totally_bounded T"
  2947   by (fastforce simp add: totally_bounded_def)
  2948 
  2949 lemma totally_bounded_Union[intro]:
  2950   assumes M: "finite M" "\<And>S. S \<in> M \<Longrightarrow> totally_bounded S"
  2951   shows "totally_bounded (\<Union>M)"
  2952   unfolding totally_bounded_def
  2953 proof safe
  2954   fix E
  2955   assume "eventually E uniformity"
  2956   with M obtain X where "\<forall>S\<in>M. finite (X S) \<and> (\<forall>s\<in>S. \<exists>x\<in>X S. E (x, s))"
  2957     by (metis totally_bounded_def)
  2958   with \<open>finite M\<close> show "\<exists>X. finite X \<and> (\<forall>s\<in>\<Union>M. \<exists>x\<in>X. E (x, s))"
  2959     by (intro exI[of _ "\<Union>S\<in>M. X S"]) force
  2960 qed
  2961 
  2962 
  2963 subsubsection \<open>Cauchy filter\<close>
  2964 
  2965 definition cauchy_filter :: "'a filter \<Rightarrow> bool"
  2966   where "cauchy_filter F \<longleftrightarrow> F \<times>\<^sub>F F \<le> uniformity"
  2967 
  2968 definition Cauchy :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool"
  2969   where Cauchy_uniform: "Cauchy X = cauchy_filter (filtermap X sequentially)"
  2970 
  2971 lemma Cauchy_uniform_iff:
  2972   "Cauchy X \<longleftrightarrow> (\<forall>P. eventually P uniformity \<longrightarrow> (\<exists>N. \<forall>n\<ge>N. \<forall>m\<ge>N. P (X n, X m)))"
  2973   unfolding Cauchy_uniform cauchy_filter_def le_filter_def eventually_prod_same
  2974     eventually_filtermap eventually_sequentially
  2975 proof safe
  2976   let ?U = "\<lambda>P. eventually P uniformity"
  2977   {
  2978     fix P
  2979     assume "?U P" "\<forall>P. ?U P \<longrightarrow> (\<exists>Q. (\<exists>N. \<forall>n\<ge>N. Q (X n)) \<and> (\<forall>x y. Q x \<longrightarrow> Q y \<longrightarrow> P (x, y)))"
  2980     then obtain Q N where "\<And>n. n \<ge> N \<Longrightarrow> Q (X n)" "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> P (x, y)"
  2981       by metis
  2982     then show "\<exists>N. \<forall>n\<ge>N. \<forall>m\<ge>N. P (X n, X m)"
  2983       by blast
  2984   next
  2985     fix P
  2986     assume "?U P" and P: "\<forall>P. ?U P \<longrightarrow> (\<exists>N. \<forall>n\<ge>N. \<forall>m\<ge>N. P (X n, X m))"
  2987     then obtain Q where "?U Q" and Q: "\<And>x y z. Q (x, y) \<Longrightarrow> Q (y, z) \<Longrightarrow> P (x, z)"
  2988       by (auto elim: uniformity_transE)
  2989     then have "?U (\<lambda>x. Q x \<and> (\<lambda>(x, y). Q (y, x)) x)"
  2990       unfolding eventually_conj_iff by (simp add: uniformity_sym)
  2991     from P[rule_format, OF this]
  2992     obtain N where N: "\<And>n m. n \<ge> N \<Longrightarrow> m \<ge> N \<Longrightarrow> Q (X n, X m) \<and> Q (X m, X n)"
  2993       by auto
  2994     show "\<exists>Q. (\<exists>N. \<forall>n\<ge>N. Q (X n)) \<and> (\<forall>x y. Q x \<longrightarrow> Q y \<longrightarrow> P (x, y))"
  2995     proof (safe intro!: exI[of _ "\<lambda>x. \<forall>n\<ge>N. Q (x, X n) \<and> Q (X n, x)"] exI[of _ N] N)
  2996       fix x y
  2997       assume "\<forall>n\<ge>N. Q (x, X n) \<and> Q (X n, x)" "\<forall>n\<ge>N. Q (y, X n) \<and> Q (X n, y)"
  2998       then have "Q (x, X N)" "Q (X N, y)" by auto
  2999       then show "P (x, y)"
  3000         by (rule Q)
  3001     qed
  3002   }
  3003 qed
  3004 
  3005 lemma nhds_imp_cauchy_filter:
  3006   assumes *: "F \<le> nhds x"
  3007   shows "cauchy_filter F"
  3008 proof -
  3009   have "F \<times>\<^sub>F F \<le> nhds x \<times>\<^sub>F nhds x"
  3010     by (intro prod_filter_mono *)
  3011   also have "\<dots> \<le> uniformity"
  3012     unfolding le_filter_def eventually_nhds_uniformity eventually_prod_same
  3013   proof safe
  3014     fix P
  3015     assume "eventually P uniformity"
  3016     then obtain Ql where ev: "eventually Ql uniformity"
  3017       and "Ql (x, y) \<Longrightarrow> Ql (y, z) \<Longrightarrow> P (x, z)" for x y z
  3018       by (rule uniformity_transE) simp
  3019     with ev[THEN uniformity_sym]
  3020     show "\<exists>Q. eventually (\<lambda>(x', y). x' = x \<longrightarrow> Q y) uniformity \<and>
  3021         (\<forall>x y. Q x \<longrightarrow> Q y \<longrightarrow> P (x, y))"
  3022       by (rule_tac exI[of _ "\<lambda>y. Ql (y, x) \<and> Ql (x, y)"]) (fastforce elim: eventually_elim2)
  3023   qed
  3024   finally show ?thesis
  3025     by (simp add: cauchy_filter_def)
  3026 qed
  3027 
  3028 lemma LIMSEQ_imp_Cauchy: "X \<longlonglongrightarrow> x \<Longrightarrow> Cauchy X"
  3029   unfolding Cauchy_uniform filterlim_def by (intro nhds_imp_cauchy_filter)
  3030 
  3031 lemma Cauchy_subseq_Cauchy:
  3032   assumes "Cauchy X" "subseq f"
  3033   shows "Cauchy (X \<circ> f)"
  3034   unfolding Cauchy_uniform comp_def filtermap_filtermap[symmetric] cauchy_filter_def
  3035   by (rule order_trans[OF _ \<open>Cauchy X\<close>[unfolded Cauchy_uniform cauchy_filter_def]])
  3036      (intro prod_filter_mono filtermap_mono filterlim_subseq[OF \<open>subseq f\<close>, unfolded filterlim_def])
  3037 
  3038 lemma convergent_Cauchy: "convergent X \<Longrightarrow> Cauchy X"
  3039   unfolding convergent_def by (erule exE, erule LIMSEQ_imp_Cauchy)
  3040 
  3041 definition complete :: "'a set \<Rightarrow> bool"
  3042   where complete_uniform: "complete S \<longleftrightarrow>
  3043     (\<forall>F \<le> principal S. F \<noteq> bot \<longrightarrow> cauchy_filter F \<longrightarrow> (\<exists>x\<in>S. F \<le> nhds x))"
  3044 
  3045 end
  3046 
  3047 
  3048 subsubsection \<open>Uniformly continuous functions\<close>
  3049 
  3050 definition uniformly_continuous_on :: "'a set \<Rightarrow> ('a::uniform_space \<Rightarrow> 'b::uniform_space) \<Rightarrow> bool"
  3051   where uniformly_continuous_on_uniformity: "uniformly_continuous_on s f \<longleftrightarrow>
  3052     (LIM (x, y) (uniformity_on s). (f x, f y) :> uniformity)"
  3053 
  3054 lemma uniformly_continuous_onD:
  3055   "uniformly_continuous_on s f \<Longrightarrow> eventually E uniformity \<Longrightarrow>
  3056     eventually (\<lambda>(x, y). x \<in> s \<longrightarrow> y \<in> s \<longrightarrow> E (f x, f y)) uniformity"
  3057   by (simp add: uniformly_continuous_on_uniformity filterlim_iff
  3058       eventually_inf_principal split_beta' mem_Times_iff imp_conjL)
  3059 
  3060 lemma uniformly_continuous_on_const[continuous_intros]: "uniformly_continuous_on s (\<lambda>x. c)"
  3061   by (auto simp: uniformly_continuous_on_uniformity filterlim_iff uniformity_refl)
  3062 
  3063 lemma uniformly_continuous_on_id[continuous_intros]: "uniformly_continuous_on s (\<lambda>x. x)"
  3064   by (auto simp: uniformly_continuous_on_uniformity filterlim_def)
  3065 
  3066 lemma uniformly_continuous_on_compose[continuous_intros]:
  3067   "uniformly_continuous_on s g \<Longrightarrow> uniformly_continuous_on (g`s) f \<Longrightarrow>
  3068     uniformly_continuous_on s (\<lambda>x. f (g x))"
  3069   using filterlim_compose[of "\<lambda>(x, y). (f x, f y)" uniformity
  3070       "uniformity_on (g`s)"  "\<lambda>(x, y). (g x, g y)" "uniformity_on s"]
  3071   by (simp add: split_beta' uniformly_continuous_on_uniformity
  3072       filterlim_inf filterlim_principal eventually_inf_principal mem_Times_iff)
  3073 
  3074 lemma uniformly_continuous_imp_continuous:
  3075   assumes f: "uniformly_continuous_on s f"
  3076   shows "continuous_on s f"
  3077   by (auto simp: filterlim_iff eventually_at_filter eventually_nhds_uniformity continuous_on_def
  3078            elim: eventually_mono dest!: uniformly_continuous_onD[OF f])
  3079 
  3080 
  3081 section \<open>Product Topology\<close>
  3082 
  3083 subsection \<open>Product is a topological space\<close>
  3084 
  3085 instantiation prod :: (topological_space, topological_space) topological_space
  3086 begin
  3087 
  3088 definition open_prod_def[code del]:
  3089   "open (S :: ('a \<times> 'b) set) \<longleftrightarrow>
  3090     (\<forall>x\<in>S. \<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S)"
  3091 
  3092 lemma open_prod_elim:
  3093   assumes "open S" and "x \<in> S"
  3094   obtains A B where "open A" and "open B" and "x \<in> A \<times> B" and "A \<times> B \<subseteq> S"
  3095   using assms unfolding open_prod_def by fast
  3096 
  3097 lemma open_prod_intro:
  3098   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S"
  3099   shows "open S"
  3100   using assms unfolding open_prod_def by fast
  3101 
  3102 instance
  3103 proof
  3104   show "open (UNIV :: ('a \<times> 'b) set)"
  3105     unfolding open_prod_def by auto
  3106 next
  3107   fix S T :: "('a \<times> 'b) set"
  3108   assume "open S" "open T"
  3109   show "open (S \<inter> T)"
  3110   proof (rule open_prod_intro)
  3111     fix x
  3112     assume x: "x \<in> S \<inter> T"
  3113     from x have "x \<in> S" by simp
  3114     obtain Sa Sb where A: "open Sa" "open Sb" "x \<in> Sa \<times> Sb" "Sa \<times> Sb \<subseteq> S"
  3115       using \<open>open S\<close> and \<open>x \<in> S\<close> by (rule open_prod_elim)
  3116     from x have "x \<in> T" by simp
  3117     obtain Ta Tb where B: "open Ta" "open Tb" "x \<in> Ta \<times> Tb" "Ta \<times> Tb \<subseteq> T"
  3118       using \<open>open T\<close> and \<open>x \<in> T\<close> by (rule open_prod_elim)
  3119     let ?A = "Sa \<inter> Ta" and ?B = "Sb \<inter> Tb"
  3120     have "open ?A \<and> open ?B \<and> x \<in> ?A \<times> ?B \<and> ?A \<times> ?B \<subseteq> S \<inter> T"
  3121       using A B by (auto simp add: open_Int)
  3122     then show "\<exists>A B. open A \<and> open B \<and> x \<in> A \<times> B \<and> A \<times> B \<subseteq> S \<inter> T"
  3123       by fast
  3124   qed
  3125 next
  3126   fix K :: "('a \<times> 'b) set set"
  3127   assume "\<forall>S\<in>K. open S"
  3128   then show "open (\<Union>K)"
  3129     unfolding open_prod_def by fast
  3130 qed
  3131 
  3132 end
  3133 
  3134 declare [[code abort: "open :: ('a::topological_space \<times> 'b::topological_space) set \<Rightarrow> bool"]]
  3135 
  3136 lemma open_Times: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<times> T)"
  3137   unfolding open_prod_def by auto
  3138 
  3139 lemma fst_vimage_eq_Times: "fst -` S = S \<times> UNIV"
  3140   by auto
  3141 
  3142 lemma snd_vimage_eq_Times: "snd -` S = UNIV \<times> S"
  3143   by auto
  3144 
  3145 lemma open_vimage_fst: "open S \<Longrightarrow> open (fst -` S)"
  3146   by (simp add: fst_vimage_eq_Times open_Times)
  3147 
  3148 lemma open_vimage_snd: "open S \<Longrightarrow> open (snd -` S)"
  3149   by (simp add: snd_vimage_eq_Times open_Times)
  3150 
  3151 lemma closed_vimage_fst: "closed S \<Longrightarrow> closed (fst -` S)"
  3152   unfolding closed_open vimage_Compl [symmetric]
  3153   by (rule open_vimage_fst)
  3154 
  3155 lemma closed_vimage_snd: "closed S \<Longrightarrow> closed (snd -` S)"
  3156   unfolding closed_open vimage_Compl [symmetric]
  3157   by (rule open_vimage_snd)
  3158 
  3159 lemma closed_Times: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<times> T)"
  3160 proof -
  3161   have "S \<times> T = (fst -` S) \<inter> (snd -` T)"
  3162     by auto
  3163   then show "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<times> T)"
  3164     by (simp add: closed_vimage_fst closed_vimage_snd closed_Int)
  3165 qed
  3166 
  3167 lemma subset_fst_imageI: "A \<times> B \<subseteq> S \<Longrightarrow> y \<in> B \<Longrightarrow> A \<subseteq> fst ` S"
  3168   unfolding image_def subset_eq by force
  3169 
  3170 lemma subset_snd_imageI: "A \<times> B \<subseteq> S \<Longrightarrow> x \<in> A \<Longrightarrow> B \<subseteq> snd ` S"
  3171   unfolding image_def subset_eq by force
  3172 
  3173 lemma open_image_fst:
  3174   assumes "open S"
  3175   shows "open (fst ` S)"
  3176 proof (rule openI)
  3177   fix x
  3178   assume "x \<in> fst ` S"
  3179   then obtain y where "(x, y) \<in> S"
  3180     by auto
  3181   then obtain A B where "open A" "open B" "x \<in> A" "y \<in> B" "A \<times> B \<subseteq> S"
  3182     using \<open>open S\<close> unfolding open_prod_def by auto
  3183   from \<open>A \<times> B \<subseteq> S\<close> \<open>y \<in> B\<close> have "A \<subseteq> fst ` S"
  3184     by (rule subset_fst_imageI)
  3185   with \<open>open A\<close> \<open>x \<in> A\<close> have "open A \<and> x \<in> A \<and> A \<subseteq> fst ` S"
  3186     by simp
  3187   then show "\<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> fst ` S" ..
  3188 qed
  3189 
  3190 lemma open_image_snd:
  3191   assumes "open S"
  3192   shows "open (snd ` S)"
  3193 proof (rule openI)
  3194   fix y
  3195   assume "y \<in> snd ` S"
  3196   then obtain x where "(x, y) \<in> S"
  3197     by auto
  3198   then obtain A B where "open A" "open B" "x \<in> A" "y \<in> B" "A \<times> B \<subseteq> S"
  3199     using \<open>open S\<close> unfolding open_prod_def by auto
  3200   from \<open>A \<times> B \<subseteq> S\<close> \<open>x \<in> A\<close> have "B \<subseteq> snd ` S"
  3201     by (rule subset_snd_imageI)
  3202   with \<open>open B\<close> \<open>y \<in> B\<close> have "open B \<and> y \<in> B \<and> B \<subseteq> snd ` S"
  3203     by simp
  3204   then show "\<exists>T. open T \<and> y \<in> T \<and> T \<subseteq> snd ` S" ..
  3205 qed
  3206 
  3207 lemma nhds_prod: "nhds (a, b) = nhds a \<times>\<^sub>F nhds b"
  3208   unfolding nhds_def
  3209 proof (subst prod_filter_INF, auto intro!: antisym INF_greatest simp: principal_prod_principal)
  3210   fix S T
  3211   assume "open S" "a \<in> S" "open T" "b \<in> T"
  3212   then show "(INF x : {S. open S \<and> (a, b) \<in> S}. principal x) \<le> principal (S \<times> T)"
  3213     by (intro INF_lower) (auto intro!: open_Times)
  3214 next
  3215   fix S'
  3216   assume "open S'" "(a, b) \<in> S'"
  3217   then obtain S T where "open S" "a \<in> S" "open T" "b \<in> T" "S \<times> T \<subseteq> S'"
  3218     by (auto elim: open_prod_elim)
  3219   then show "(INF x : {S. open S \<and> a \<in> S}. INF y : {S. open S \<and> b \<in> S}.
  3220       principal (x \<times> y)) \<le> principal S'"
  3221     by (auto intro!: INF_lower2)
  3222 qed
  3223 
  3224 
  3225 subsubsection \<open>Continuity of operations\<close>
  3226 
  3227 lemma tendsto_fst [tendsto_intros]:
  3228   assumes "(f \<longlongrightarrow> a) F"
  3229   shows "((\<lambda>x. fst (f x)) \<longlongrightarrow> fst a) F"
  3230 proof (rule topological_tendstoI)
  3231   fix S
  3232   assume "open S" and "fst a \<in> S"
  3233   then have "open (fst -` S)" and "a \<in> fst -` S"
  3234     by (simp_all add: open_vimage_fst)
  3235   with assms have "eventually (\<lambda>x. f x \<in> fst -` S) F"
  3236     by (rule topological_tendstoD)
  3237   then show "eventually (\<lambda>x. fst (f x) \<in> S) F"
  3238     by simp
  3239 qed
  3240 
  3241 lemma tendsto_snd [tendsto_intros]:
  3242   assumes "(f \<longlongrightarrow> a) F"
  3243   shows "((\<lambda>x. snd (f x)) \<longlongrightarrow> snd a) F"
  3244 proof (rule topological_tendstoI)
  3245   fix S
  3246   assume "open S" and "snd a \<in> S"
  3247   then have "open (snd -` S)" and "a \<in> snd -` S"
  3248     by (simp_all add: open_vimage_snd)
  3249   with assms have "eventually (\<lambda>x. f x \<in> snd -` S) F"
  3250     by (rule topological_tendstoD)
  3251   then show "eventually (\<lambda>x. snd (f x) \<in> S) F"
  3252     by simp
  3253 qed
  3254 
  3255 lemma tendsto_Pair [tendsto_intros]:
  3256   assumes "(f \<longlongrightarrow> a) F" and "(g \<longlongrightarrow> b) F"
  3257   shows "((\<lambda>x. (f x, g x)) \<longlongrightarrow> (a, b)) F"
  3258 proof (rule topological_tendstoI)
  3259   fix S
  3260   assume "open S" and "(a, b) \<in> S"
  3261   then obtain A B where "open A" "open B" "a \<in> A" "b \<in> B" "A \<times> B \<subseteq> S"
  3262     unfolding open_prod_def by fast
  3263   have "eventually (\<lambda>x. f x \<in> A) F"
  3264     using \<open>(f \<longlongrightarrow> a) F\<close> \<open>open A\<close> \<open>a \<in> A\<close>
  3265     by (rule topological_tendstoD)
  3266   moreover
  3267   have "eventually (\<lambda>x. g x \<in> B) F"
  3268     using \<open>(g \<longlongrightarrow> b) F\<close> \<open>open B\<close> \<open>b \<in> B\<close>
  3269     by (rule topological_tendstoD)
  3270   ultimately
  3271   show "eventually (\<lambda>x. (f x, g x) \<in> S) F"
  3272     by (rule eventually_elim2)
  3273        (simp add: subsetD [OF \<open>A \<times> B \<subseteq> S\<close>])
  3274 qed
  3275 
  3276 lemma continuous_fst[continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. fst (f x))"
  3277   unfolding continuous_def by (rule tendsto_fst)
  3278 
  3279 lemma continuous_snd[continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. snd (f x))"
  3280   unfolding continuous_def by (rule tendsto_snd)
  3281 
  3282 lemma continuous_Pair[continuous_intros]:
  3283   "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. (f x, g x))"
  3284   unfolding continuous_def by (rule tendsto_Pair)
  3285 
  3286 lemma continuous_on_fst[continuous_intros]:
  3287   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. fst (f x))"
  3288   unfolding continuous_on_def by (auto intro: tendsto_fst)
  3289 
  3290 lemma continuous_on_snd[continuous_intros]:
  3291   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. snd (f x))"
  3292   unfolding continuous_on_def by (auto intro: tendsto_snd)
  3293 
  3294 lemma continuous_on_Pair[continuous_intros]:
  3295   "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. (f x, g x))"
  3296   unfolding continuous_on_def by (auto intro: tendsto_Pair)
  3297 
  3298 lemma continuous_on_swap[continuous_intros]: "continuous_on A prod.swap"
  3299   by (simp add: prod.swap_def continuous_on_fst continuous_on_snd
  3300       continuous_on_Pair continuous_on_id)
  3301 
  3302 lemma continuous_on_swap_args:
  3303   assumes "continuous_on (A\<times>B) (\<lambda>(x,y). d x y)"
  3304     shows "continuous_on (B\<times>A) (\<lambda>(x,y). d y x)"
  3305 proof -
  3306   have "(\<lambda>(x,y). d y x) = (\<lambda>(x,y). d x y) \<circ> prod.swap"
  3307     by force
  3308   then show ?thesis
  3309     apply (rule ssubst)
  3310     apply (rule continuous_on_compose)
  3311      apply (force intro: continuous_on_subset [OF continuous_on_swap])
  3312     apply (force intro: continuous_on_subset [OF assms])
  3313     done
  3314 qed
  3315 
  3316 lemma isCont_fst [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. fst (f x)) a"
  3317   by (fact continuous_fst)
  3318 
  3319 lemma isCont_snd [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. snd (f x)) a"
  3320   by (fact continuous_snd)
  3321 
  3322 lemma isCont_Pair [simp]: "\<lbrakk>isCont f a; isCont g a\<rbrakk> \<Longrightarrow> isCont (\<lambda>x. (f x, g x)) a"
  3323   by (fact continuous_Pair)
  3324 
  3325 
  3326 subsubsection \<open>Separation axioms\<close>
  3327 
  3328 instance prod :: (t0_space, t0_space) t0_space
  3329 proof
  3330   fix x y :: "'a \<times> 'b"
  3331   assume "x \<noteq> y"
  3332   then have "fst x \<noteq> fst y \<or> snd x \<noteq> snd y"
  3333     by (simp add: prod_eq_iff)
  3334   then show "\<exists>U. open U \<and> (x \<in> U) \<noteq> (y \<in> U)"
  3335     by (fast dest: t0_space elim: open_vimage_fst open_vimage_snd)
  3336 qed
  3337 
  3338 instance prod :: (t1_space, t1_space) t1_space
  3339 proof
  3340   fix x y :: "'a \<times> 'b"
  3341   assume "x \<noteq> y"
  3342   then have "fst x \<noteq> fst y \<or> snd x \<noteq> snd y"
  3343     by (simp add: prod_eq_iff)
  3344   then show "\<exists>U. open U \<and> x \<in> U \<and> y \<notin> U"
  3345     by (fast dest: t1_space elim: open_vimage_fst open_vimage_snd)
  3346 qed
  3347 
  3348 instance prod :: (t2_space, t2_space) t2_space
  3349 proof
  3350   fix x y :: "'a \<times> 'b"
  3351   assume "x \<noteq> y"
  3352   then have "fst x \<noteq> fst y \<or> snd x \<noteq> snd y"
  3353     by (simp add: prod_eq_iff)
  3354   then show "\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
  3355     by (fast dest: hausdorff elim: open_vimage_fst open_vimage_snd)
  3356 qed
  3357 
  3358 lemma isCont_swap[continuous_intros]: "isCont prod.swap a"
  3359   using continuous_on_eq_continuous_within continuous_on_swap by blast
  3360 
  3361 end