src/Pure/sign.ML
author wenzelm
Mon May 03 14:25:56 2010 +0200 (2010-05-03)
changeset 36610 bafd82950e24
parent 36450 62eaaffe6e47
child 37145 01aa36932739
permissions -rw-r--r--
renamed ProofContext.init to ProofContext.init_global to emphasize that this is not the real thing;
     1 (*  Title:      Pure/sign.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Logical signature content: naming conventions, concrete syntax, type
     5 signature, polymorphic constants.
     6 *)
     7 
     8 signature SIGN =
     9 sig
    10   val rep_sg: theory ->
    11    {naming: Name_Space.naming,
    12     syn: Syntax.syntax,
    13     tsig: Type.tsig,
    14     consts: Consts.T}
    15   val map_naming: (Name_Space.naming -> Name_Space.naming) -> theory -> theory
    16   val naming_of: theory -> Name_Space.naming
    17   val full_name: theory -> binding -> string
    18   val full_name_path: theory -> string -> binding -> string
    19   val full_bname: theory -> bstring -> string
    20   val full_bname_path: theory -> string -> bstring -> string
    21   val syn_of: theory -> Syntax.syntax
    22   val tsig_of: theory -> Type.tsig
    23   val classes_of: theory -> Sorts.algebra
    24   val all_classes: theory -> class list
    25   val super_classes: theory -> class -> class list
    26   val minimize_sort: theory -> sort -> sort
    27   val complete_sort: theory -> sort -> sort
    28   val set_defsort: sort -> theory -> theory
    29   val defaultS: theory -> sort
    30   val subsort: theory -> sort * sort -> bool
    31   val of_sort: theory -> typ * sort -> bool
    32   val witness_sorts: theory -> (typ * sort) list -> sort list -> (typ * sort) list
    33   val is_logtype: theory -> string -> bool
    34   val typ_instance: theory -> typ * typ -> bool
    35   val typ_equiv: theory -> typ * typ -> bool
    36   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    37   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    38   val consts_of: theory -> Consts.T
    39   val the_const_constraint: theory -> string -> typ
    40   val const_type: theory -> string -> typ option
    41   val the_const_type: theory -> string -> typ
    42   val declared_tyname: theory -> string -> bool
    43   val declared_const: theory -> string -> bool
    44   val const_monomorphic: theory -> string -> bool
    45   val const_typargs: theory -> string * typ -> typ list
    46   val const_instance: theory -> string * typ list -> typ
    47   val mk_const: theory -> string * typ list -> term
    48   val class_space: theory -> Name_Space.T
    49   val type_space: theory -> Name_Space.T
    50   val const_space: theory -> Name_Space.T
    51   val class_alias: binding -> class -> theory -> theory
    52   val type_alias: binding -> string -> theory -> theory
    53   val const_alias: binding -> string -> theory -> theory
    54   val intern_class: theory -> xstring -> string
    55   val extern_class: theory -> string -> xstring
    56   val intern_type: theory -> xstring -> string
    57   val extern_type: theory -> string -> xstring
    58   val intern_const: theory -> xstring -> string
    59   val extern_const: theory -> string -> xstring
    60   val arity_number: theory -> string -> int
    61   val arity_sorts: theory -> string -> sort -> sort list
    62   val certify_class: theory -> class -> class
    63   val certify_sort: theory -> sort -> sort
    64   val certify_typ: theory -> typ -> typ
    65   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    66   val certify': bool -> Pretty.pp -> bool -> Consts.T -> theory -> term -> term * typ * int
    67   val certify_term: theory -> term -> term * typ * int
    68   val cert_term: theory -> term -> term
    69   val cert_prop: theory -> term -> term
    70   val no_frees: Pretty.pp -> term -> term
    71   val no_vars: Pretty.pp -> term -> term
    72   val add_types: (binding * int * mixfix) list -> theory -> theory
    73   val add_nonterminals: binding list -> theory -> theory
    74   val add_type_abbrev: binding * string list * typ -> theory -> theory
    75   val add_syntax: (string * string * mixfix) list -> theory -> theory
    76   val add_syntax_i: (string * typ * mixfix) list -> theory -> theory
    77   val add_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    78   val add_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    79   val del_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    80   val del_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    81   val type_notation: bool -> Syntax.mode -> (typ * mixfix) list -> theory -> theory
    82   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    83   val declare_const: (binding * typ) * mixfix -> theory -> term * theory
    84   val add_consts: (binding * string * mixfix) list -> theory -> theory
    85   val add_consts_i: (binding * typ * mixfix) list -> theory -> theory
    86   val add_abbrev: string -> binding * term -> theory -> (term * term) * theory
    87   val revert_abbrev: string -> string -> theory -> theory
    88   val add_const_constraint: string * typ option -> theory -> theory
    89   val primitive_class: binding * class list -> theory -> theory
    90   val primitive_classrel: class * class -> theory -> theory
    91   val primitive_arity: arity -> theory -> theory
    92   val add_trfuns:
    93     (string * (ast list -> ast)) list *
    94     (string * (term list -> term)) list *
    95     (string * (term list -> term)) list *
    96     (string * (ast list -> ast)) list -> theory -> theory
    97   val add_trfunsT:
    98     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
    99   val add_advanced_trfuns:
   100     (string * (Proof.context -> ast list -> ast)) list *
   101     (string * (Proof.context -> term list -> term)) list *
   102     (string * (Proof.context -> term list -> term)) list *
   103     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
   104   val add_advanced_trfunsT:
   105     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
   106   val add_tokentrfuns:
   107     (string * string * (Proof.context -> string -> Pretty.T)) list -> theory -> theory
   108   val add_mode_tokentrfuns: string -> (string * (Proof.context -> string -> Pretty.T)) list
   109     -> theory -> theory
   110   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   111   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   112   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
   113   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
   114   val new_group: theory -> theory
   115   val reset_group: theory -> theory
   116   val add_path: string -> theory -> theory
   117   val root_path: theory -> theory
   118   val parent_path: theory -> theory
   119   val mandatory_path: string -> theory -> theory
   120   val qualified_path: bool -> binding -> theory -> theory
   121   val local_path: theory -> theory
   122   val restore_naming: theory -> theory -> theory
   123   val hide_class: bool -> string -> theory -> theory
   124   val hide_type: bool -> string -> theory -> theory
   125   val hide_const: bool -> string -> theory -> theory
   126 end
   127 
   128 structure Sign: SIGN =
   129 struct
   130 
   131 (** datatype sign **)
   132 
   133 datatype sign = Sign of
   134  {naming: Name_Space.naming,    (*common naming conventions*)
   135   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   136   tsig: Type.tsig,              (*order-sorted signature of types*)
   137   consts: Consts.T};            (*polymorphic constants*)
   138 
   139 fun make_sign (naming, syn, tsig, consts) =
   140   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   141 
   142 structure Data = Theory_Data_PP
   143 (
   144   type T = sign;
   145   fun extend (Sign {syn, tsig, consts, ...}) =
   146     make_sign (Name_Space.default_naming, syn, tsig, consts);
   147 
   148   val empty =
   149     make_sign (Name_Space.default_naming, Syntax.basic_syntax, Type.empty_tsig, Consts.empty);
   150 
   151   fun merge pp (sign1, sign2) =
   152     let
   153       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   154       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   155 
   156       val naming = Name_Space.default_naming;
   157       val syn = Syntax.merge_syntaxes syn1 syn2;
   158       val tsig = Type.merge_tsig pp (tsig1, tsig2);
   159       val consts = Consts.merge (consts1, consts2);
   160     in make_sign (naming, syn, tsig, consts) end;
   161 );
   162 
   163 fun rep_sg thy = Data.get thy |> (fn Sign args => args);
   164 
   165 fun map_sign f = Data.map (fn Sign {naming, syn, tsig, consts} =>
   166   make_sign (f (naming, syn, tsig, consts)));
   167 
   168 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   169 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   170 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   171 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   172 
   173 
   174 (* naming *)
   175 
   176 val naming_of = #naming o rep_sg;
   177 
   178 val full_name = Name_Space.full_name o naming_of;
   179 fun full_name_path thy path = Name_Space.full_name (Name_Space.add_path path (naming_of thy));
   180 
   181 fun full_bname thy = Name_Space.full_name (naming_of thy) o Binding.name;
   182 fun full_bname_path thy path = full_name_path thy path o Binding.name;
   183 
   184 
   185 (* syntax *)
   186 
   187 val syn_of = #syn o rep_sg;
   188 
   189 
   190 (* type signature *)
   191 
   192 val tsig_of = #tsig o rep_sg;
   193 
   194 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   195 val all_classes = Sorts.all_classes o classes_of;
   196 val super_classes = Sorts.super_classes o classes_of;
   197 val minimize_sort = Sorts.minimize_sort o classes_of;
   198 val complete_sort = Sorts.complete_sort o classes_of;
   199 
   200 val set_defsort = map_tsig o Type.set_defsort;
   201 val defaultS = Type.defaultS o tsig_of;
   202 val subsort = Type.subsort o tsig_of;
   203 val of_sort = Type.of_sort o tsig_of;
   204 val witness_sorts = Type.witness_sorts o tsig_of;
   205 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   206 
   207 val typ_instance = Type.typ_instance o tsig_of;
   208 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   209 val typ_match = Type.typ_match o tsig_of;
   210 val typ_unify = Type.unify o tsig_of;
   211 
   212 
   213 (* polymorphic constants *)
   214 
   215 val consts_of = #consts o rep_sg;
   216 val the_const_constraint = Consts.the_constraint o consts_of;
   217 val the_const_type = Consts.the_type o consts_of;
   218 val const_type = try o the_const_type;
   219 val const_monomorphic = Consts.is_monomorphic o consts_of;
   220 val const_typargs = Consts.typargs o consts_of;
   221 val const_instance = Consts.instance o consts_of;
   222 
   223 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   224 
   225 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   226 val declared_const = can o the_const_constraint;
   227 
   228 
   229 
   230 (** intern / extern names **)
   231 
   232 val class_space = Type.class_space o tsig_of;
   233 val type_space = Type.type_space o tsig_of;
   234 val const_space = Consts.space_of o consts_of;
   235 
   236 fun class_alias b c thy = map_tsig (Type.class_alias (naming_of thy) b c) thy;
   237 fun type_alias b c thy = map_tsig (Type.type_alias (naming_of thy) b c) thy;
   238 fun const_alias b c thy = map_consts (Consts.alias (naming_of thy) b c) thy;
   239 
   240 val intern_class = Name_Space.intern o class_space;
   241 val extern_class = Name_Space.extern o class_space;
   242 val intern_type = Name_Space.intern o type_space;
   243 val extern_type = Name_Space.extern o type_space;
   244 val intern_const = Name_Space.intern o const_space;
   245 val extern_const = Name_Space.extern o const_space;
   246 
   247 
   248 
   249 (** certify entities **)    (*exception TYPE*)
   250 
   251 (* certify wrt. type signature *)
   252 
   253 val arity_number = Type.arity_number o tsig_of;
   254 fun arity_sorts thy = Type.arity_sorts (Syntax.pp_global thy) (tsig_of thy);
   255 
   256 val certify_class         = Type.cert_class o tsig_of;
   257 val certify_sort          = Type.cert_sort o tsig_of;
   258 val certify_typ           = Type.cert_typ o tsig_of;
   259 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   260 
   261 
   262 (* certify term/prop *)
   263 
   264 local
   265 
   266 fun type_check pp tm =
   267   let
   268     fun err_appl why bs t T u U =
   269       let
   270         val xs = map Free bs;           (*we do not rename here*)
   271         val t' = subst_bounds (xs, t);
   272         val u' = subst_bounds (xs, u);
   273         val msg = cat_lines
   274           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   275       in raise TYPE (msg, [T, U], [t', u']) end;
   276 
   277     fun typ_of (_, Const (_, T)) = T
   278       | typ_of (_, Free  (_, T)) = T
   279       | typ_of (_, Var (_, T)) = T
   280       | typ_of (bs, Bound i) = snd (nth bs i handle Subscript =>
   281           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   282       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   283       | typ_of (bs, t $ u) =
   284           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   285             (case T of
   286               Type ("fun", [T1, T2]) =>
   287                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   288             | _ => err_appl "Operator not of function type" bs t T u U)
   289           end;
   290   in typ_of ([], tm) end;
   291 
   292 fun err msg = raise TYPE (msg, [], []);
   293 
   294 fun check_vars (t $ u) = (check_vars t; check_vars u)
   295   | check_vars (Abs (_, _, t)) = check_vars t
   296   | check_vars (Free (x, _)) =
   297       if Long_Name.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   298   | check_vars (Var (xi as (_, i), _)) =
   299       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   300   | check_vars _ = ();
   301 
   302 in
   303 
   304 fun certify' prop pp do_expand consts thy tm =
   305   let
   306     val _ = check_vars tm;
   307     val tm' = Term.map_types (certify_typ thy) tm;
   308     val T = type_check pp tm';
   309     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   310     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   311   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   312 
   313 fun certify_term thy = certify' false (Syntax.pp_global thy) true (consts_of thy) thy;
   314 fun cert_term_abbrev thy = #1 o certify' false (Syntax.pp_global thy) false (consts_of thy) thy;
   315 val cert_term = #1 oo certify_term;
   316 fun cert_prop thy = #1 o certify' true (Syntax.pp_global thy) true (consts_of thy) thy;
   317 
   318 end;
   319 
   320 
   321 (* specifications *)
   322 
   323 fun no_variables kind add addT mk mkT pp tm =
   324   (case (add tm [], addT tm []) of
   325     ([], []) => tm
   326   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   327       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   328        Pretty.commas (map (Pretty.term pp o mk) frees @ map (Pretty.typ pp o mkT) tfrees)))));
   329 
   330 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   331 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   332 
   333 
   334 
   335 (** signature extension functions **)  (*exception ERROR/TYPE*)
   336 
   337 (* add type constructors *)
   338 
   339 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   340   let
   341     fun type_syntax (b, n, mx) =
   342       (Syntax.mark_type (Name_Space.full_name naming b), Syntax.make_type n, mx);
   343     val syn' = Syntax.update_type_gram true Syntax.mode_default (map type_syntax types) syn;
   344     val tsig' = fold (fn (a, n, _) => Type.add_type naming (a, n)) types tsig;
   345   in (naming, syn', tsig', consts) end);
   346 
   347 
   348 (* add nonterminals *)
   349 
   350 fun add_nonterminals ns = map_sign (fn (naming, syn, tsig, consts) =>
   351   (naming, syn, fold (Type.add_nonterminal naming) ns tsig, consts));
   352 
   353 
   354 (* add type abbreviations *)
   355 
   356 fun add_type_abbrev abbr = map_sign (fn (naming, syn, tsig, consts) =>
   357   (naming, syn, Type.add_abbrev naming abbr tsig, consts));
   358 
   359 
   360 (* modify syntax *)
   361 
   362 fun gen_syntax change_gram parse_typ mode args thy =
   363   let
   364     val ctxt = ProofContext.init_global thy;
   365     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   366       handle ERROR msg => cat_error msg ("in syntax declaration " ^ quote c);
   367   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   368 
   369 fun gen_add_syntax x = gen_syntax (Syntax.update_const_gram true) x;
   370 
   371 val add_modesyntax = gen_add_syntax Syntax.parse_typ;
   372 val add_modesyntax_i = gen_add_syntax (K I);
   373 val add_syntax = add_modesyntax Syntax.mode_default;
   374 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   375 val del_modesyntax = gen_syntax (Syntax.update_const_gram false) Syntax.parse_typ;
   376 val del_modesyntax_i = gen_syntax (Syntax.update_const_gram false) (K I);
   377 
   378 fun type_notation add mode args =
   379   let
   380     fun type_syntax (Type (c, args), mx) =
   381           SOME (Syntax.mark_type c, Syntax.make_type (length args), mx)
   382       | type_syntax _ = NONE;
   383   in map_syn (Syntax.update_type_gram add mode (map_filter type_syntax args)) end;
   384 
   385 fun notation add mode args thy =
   386   let
   387     fun const_syntax (Const (c, _), mx) =
   388           (case try (Consts.type_scheme (consts_of thy)) c of
   389             SOME T => SOME (Syntax.mark_const c, T, mx)
   390           | NONE => NONE)
   391       | const_syntax _ = NONE;
   392   in gen_syntax (Syntax.update_const_gram add) (K I) mode (map_filter const_syntax args) thy end;
   393 
   394 
   395 (* add constants *)
   396 
   397 local
   398 
   399 fun gen_add_consts parse_typ raw_args thy =
   400   let
   401     val ctxt = ProofContext.init_global thy;
   402     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o parse_typ ctxt;
   403     fun prep (b, raw_T, mx) =
   404       let
   405         val c = full_name thy b;
   406         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   407           cat_error msg ("in declaration of constant " ^ quote (Binding.str_of b));
   408         val T' = Logic.varifyT_global T;
   409       in ((b, T'), (Syntax.mark_const c, T', mx), Const (c, T)) end;
   410     val args = map prep raw_args;
   411   in
   412     thy
   413     |> map_consts (fold (Consts.declare (naming_of thy) o #1) args)
   414     |> add_syntax_i (map #2 args)
   415     |> pair (map #3 args)
   416   end;
   417 
   418 in
   419 
   420 fun add_consts args = snd o gen_add_consts Syntax.parse_typ args;
   421 fun add_consts_i args = snd o gen_add_consts (K I) args;
   422 
   423 fun declare_const ((b, T), mx) thy =
   424   let
   425     val pos = Binding.pos_of b;
   426     val ([const as Const (c, _)], thy') = gen_add_consts (K I) [(b, T, mx)] thy;
   427     val _ = Position.report (Markup.const_decl c) pos;
   428   in (const, thy') end;
   429 
   430 end;
   431 
   432 
   433 (* abbreviations *)
   434 
   435 fun add_abbrev mode (b, raw_t) thy =
   436   let
   437     val pp = Syntax.pp_global thy;
   438     val prep_tm = no_frees pp o Term.no_dummy_patterns o cert_term_abbrev thy;
   439     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   440       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote (Binding.str_of b));
   441     val (res, consts') = consts_of thy
   442       |> Consts.abbreviate pp (tsig_of thy) (naming_of thy) mode (b, t);
   443   in (res, thy |> map_consts (K consts')) end;
   444 
   445 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   446 
   447 
   448 (* add constraints *)
   449 
   450 fun add_const_constraint (c, opt_T) thy =
   451   let
   452     fun prepT raw_T =
   453       let val T = Logic.varifyT_global (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   454       in cert_term thy (Const (c, T)); T end
   455       handle TYPE (msg, _, _) => error msg;
   456   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   457 
   458 
   459 (* primitive classes and arities *)
   460 
   461 fun primitive_class (bclass, classes) thy =
   462   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   463     let
   464       val tsig' = Type.add_class (Syntax.pp_global thy) naming (bclass, classes) tsig;
   465     in (naming, syn, tsig', consts) end)
   466   |> add_consts_i [(Binding.map_name Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   467 
   468 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (Syntax.pp_global thy) arg);
   469 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (Syntax.pp_global thy) arg);
   470 
   471 
   472 (* add translation functions *)
   473 
   474 local
   475 
   476 fun mk trs = map Syntax.mk_trfun trs;
   477 
   478 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   479   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   480 
   481 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   482 
   483 in
   484 
   485 val add_trfuns = gen_add_trfuns Syntax.update_trfuns Syntax.non_typed_tr';
   486 val add_trfunsT = gen_add_trfunsT Syntax.update_trfuns;
   487 val add_advanced_trfuns = gen_add_trfuns Syntax.update_advanced_trfuns Syntax.non_typed_tr'';
   488 val add_advanced_trfunsT = gen_add_trfunsT Syntax.update_advanced_trfuns;
   489 
   490 end;
   491 
   492 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   493 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   494 
   495 
   496 (* translation rules *)
   497 
   498 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   499   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   500   in f (ProofContext.init_global thy) (is_logtype thy) syn rules syn end);
   501 
   502 val add_trrules = gen_trrules Syntax.update_trrules;
   503 val del_trrules = gen_trrules Syntax.remove_trrules;
   504 val add_trrules_i = map_syn o Syntax.update_trrules_i;
   505 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   506 
   507 
   508 (* naming *)
   509 
   510 val new_group = map_naming Name_Space.new_group;
   511 val reset_group = map_naming Name_Space.reset_group;
   512 
   513 val add_path = map_naming o Name_Space.add_path;
   514 val root_path = map_naming Name_Space.root_path;
   515 val parent_path = map_naming Name_Space.parent_path;
   516 val mandatory_path = map_naming o Name_Space.mandatory_path;
   517 val qualified_path = map_naming oo Name_Space.qualified_path;
   518 
   519 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   520 
   521 val restore_naming = map_naming o K o naming_of;
   522 
   523 
   524 (* hide names *)
   525 
   526 val hide_class = map_tsig oo Type.hide_class;
   527 val hide_type = map_tsig oo Type.hide_type;
   528 val hide_const = map_consts oo Consts.hide;
   529 
   530 end;