src/HOL/Fun.thy
author haftmann
Thu Aug 13 10:05:58 2015 +0200 (2015-08-13)
changeset 60929 bb3610d34e2e
parent 60758 d8d85a8172b5
child 61204 3e491e34a62e
permissions -rw-r--r--
more lemmas
     1 (*  Title:      HOL/Fun.thy
     2     Author:     Tobias Nipkow, Cambridge University Computer Laboratory
     3     Author:     Andrei Popescu, TU Muenchen
     4     Copyright   1994, 2012
     5 *)
     6 
     7 section \<open>Notions about functions\<close>
     8 
     9 theory Fun
    10 imports Set
    11 keywords "functor" :: thy_goal
    12 begin
    13 
    14 lemma apply_inverse:
    15   "f x = u \<Longrightarrow> (\<And>x. P x \<Longrightarrow> g (f x) = x) \<Longrightarrow> P x \<Longrightarrow> x = g u"
    16   by auto
    17 
    18 text\<open>Uniqueness, so NOT the axiom of choice.\<close>
    19 lemma uniq_choice: "\<forall>x. \<exists>!y. Q x y \<Longrightarrow> \<exists>f. \<forall>x. Q x (f x)"
    20   by (force intro: theI')
    21 
    22 lemma b_uniq_choice: "\<forall>x\<in>S. \<exists>!y. Q x y \<Longrightarrow> \<exists>f. \<forall>x\<in>S. Q x (f x)"
    23   by (force intro: theI')
    24 
    25 subsection \<open>The Identity Function @{text id}\<close>
    26 
    27 definition id :: "'a \<Rightarrow> 'a" where
    28   "id = (\<lambda>x. x)"
    29 
    30 lemma id_apply [simp]: "id x = x"
    31   by (simp add: id_def)
    32 
    33 lemma image_id [simp]: "image id = id"
    34   by (simp add: id_def fun_eq_iff)
    35 
    36 lemma vimage_id [simp]: "vimage id = id"
    37   by (simp add: id_def fun_eq_iff)
    38 
    39 code_printing
    40   constant id \<rightharpoonup> (Haskell) "id"
    41 
    42 
    43 subsection \<open>The Composition Operator @{text "f \<circ> g"}\<close>
    44 
    45 definition comp :: "('b \<Rightarrow> 'c) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "o" 55) where
    46   "f o g = (\<lambda>x. f (g x))"
    47 
    48 notation (xsymbols)
    49   comp  (infixl "\<circ>" 55)
    50 
    51 notation (HTML output)
    52   comp  (infixl "\<circ>" 55)
    53 
    54 lemma comp_apply [simp]: "(f o g) x = f (g x)"
    55   by (simp add: comp_def)
    56 
    57 lemma comp_assoc: "(f o g) o h = f o (g o h)"
    58   by (simp add: fun_eq_iff)
    59 
    60 lemma id_comp [simp]: "id o g = g"
    61   by (simp add: fun_eq_iff)
    62 
    63 lemma comp_id [simp]: "f o id = f"
    64   by (simp add: fun_eq_iff)
    65 
    66 lemma comp_eq_dest:
    67   "a o b = c o d \<Longrightarrow> a (b v) = c (d v)"
    68   by (simp add: fun_eq_iff)
    69 
    70 lemma comp_eq_elim:
    71   "a o b = c o d \<Longrightarrow> ((\<And>v. a (b v) = c (d v)) \<Longrightarrow> R) \<Longrightarrow> R"
    72   by (simp add: fun_eq_iff) 
    73 
    74 lemma comp_eq_dest_lhs: "a o b = c \<Longrightarrow> a (b v) = c v"
    75   by clarsimp
    76 
    77 lemma comp_eq_id_dest: "a o b = id o c \<Longrightarrow> a (b v) = c v"
    78   by clarsimp
    79 
    80 lemma image_comp:
    81   "f ` (g ` r) = (f o g) ` r"
    82   by auto
    83 
    84 lemma vimage_comp:
    85   "f -` (g -` x) = (g \<circ> f) -` x"
    86   by auto
    87 
    88 lemma image_eq_imp_comp: "f ` A = g ` B \<Longrightarrow> (h o f) ` A = (h o g) ` B"
    89   by (auto simp: comp_def elim!: equalityE)
    90 
    91 lemma image_bind: "f ` (Set.bind A g) = Set.bind A (op ` f \<circ> g)"
    92 by(auto simp add: Set.bind_def)
    93 
    94 lemma bind_image: "Set.bind (f ` A) g = Set.bind A (g \<circ> f)"
    95 by(auto simp add: Set.bind_def)
    96 
    97 lemma (in group_add) minus_comp_minus [simp]:
    98   "uminus \<circ> uminus = id"
    99   by (simp add: fun_eq_iff)
   100 
   101 lemma (in boolean_algebra) minus_comp_minus [simp]:
   102   "uminus \<circ> uminus = id"
   103   by (simp add: fun_eq_iff)
   104 
   105 code_printing
   106   constant comp \<rightharpoonup> (SML) infixl 5 "o" and (Haskell) infixr 9 "."
   107 
   108 
   109 subsection \<open>The Forward Composition Operator @{text fcomp}\<close>
   110 
   111 definition fcomp :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'c) \<Rightarrow> 'a \<Rightarrow> 'c" (infixl "\<circ>>" 60) where
   112   "f \<circ>> g = (\<lambda>x. g (f x))"
   113 
   114 lemma fcomp_apply [simp]:  "(f \<circ>> g) x = g (f x)"
   115   by (simp add: fcomp_def)
   116 
   117 lemma fcomp_assoc: "(f \<circ>> g) \<circ>> h = f \<circ>> (g \<circ>> h)"
   118   by (simp add: fcomp_def)
   119 
   120 lemma id_fcomp [simp]: "id \<circ>> g = g"
   121   by (simp add: fcomp_def)
   122 
   123 lemma fcomp_id [simp]: "f \<circ>> id = f"
   124   by (simp add: fcomp_def)
   125 
   126 code_printing
   127   constant fcomp \<rightharpoonup> (Eval) infixl 1 "#>"
   128 
   129 no_notation fcomp (infixl "\<circ>>" 60)
   130 
   131 
   132 subsection \<open>Mapping functions\<close>
   133 
   134 definition map_fun :: "('c \<Rightarrow> 'a) \<Rightarrow> ('b \<Rightarrow> 'd) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'c \<Rightarrow> 'd" where
   135   "map_fun f g h = g \<circ> h \<circ> f"
   136 
   137 lemma map_fun_apply [simp]:
   138   "map_fun f g h x = g (h (f x))"
   139   by (simp add: map_fun_def)
   140 
   141 
   142 subsection \<open>Injectivity and Bijectivity\<close>
   143 
   144 definition inj_on :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> bool" where -- "injective"
   145   "inj_on f A \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. f x = f y \<longrightarrow> x = y)"
   146 
   147 definition bij_betw :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> bool" where -- "bijective"
   148   "bij_betw f A B \<longleftrightarrow> inj_on f A \<and> f ` A = B"
   149 
   150 text\<open>A common special case: functions injective, surjective or bijective over
   151 the entire domain type.\<close>
   152 
   153 abbreviation
   154   "inj f \<equiv> inj_on f UNIV"
   155 
   156 abbreviation surj :: "('a \<Rightarrow> 'b) \<Rightarrow> bool" where -- "surjective"
   157   "surj f \<equiv> (range f = UNIV)"
   158 
   159 abbreviation
   160   "bij f \<equiv> bij_betw f UNIV UNIV"
   161 
   162 text\<open>The negated case:\<close>
   163 translations
   164 "\<not> CONST surj f" <= "CONST range f \<noteq> CONST UNIV"
   165 
   166 lemma injI:
   167   assumes "\<And>x y. f x = f y \<Longrightarrow> x = y"
   168   shows "inj f"
   169   using assms unfolding inj_on_def by auto
   170 
   171 theorem range_ex1_eq: "inj f \<Longrightarrow> b : range f = (EX! x. b = f x)"
   172   by (unfold inj_on_def, blast)
   173 
   174 lemma injD: "[| inj(f); f(x) = f(y) |] ==> x=y"
   175 by (simp add: inj_on_def)
   176 
   177 lemma inj_on_eq_iff: "inj_on f A ==> x:A ==> y:A ==> (f(x) = f(y)) = (x=y)"
   178 by (force simp add: inj_on_def)
   179 
   180 lemma inj_on_cong:
   181   "(\<And> a. a : A \<Longrightarrow> f a = g a) \<Longrightarrow> inj_on f A = inj_on g A"
   182 unfolding inj_on_def by auto
   183 
   184 lemma inj_on_strict_subset:
   185   "inj_on f B \<Longrightarrow> A \<subset> B \<Longrightarrow> f ` A \<subset> f ` B"
   186   unfolding inj_on_def by blast
   187 
   188 lemma inj_comp:
   189   "inj f \<Longrightarrow> inj g \<Longrightarrow> inj (f \<circ> g)"
   190   by (simp add: inj_on_def)
   191 
   192 lemma inj_fun: "inj f \<Longrightarrow> inj (\<lambda>x y. f x)"
   193   by (simp add: inj_on_def fun_eq_iff)
   194 
   195 lemma inj_eq: "inj f ==> (f(x) = f(y)) = (x=y)"
   196 by (simp add: inj_on_eq_iff)
   197 
   198 lemma inj_on_id[simp]: "inj_on id A"
   199   by (simp add: inj_on_def)
   200 
   201 lemma inj_on_id2[simp]: "inj_on (%x. x) A"
   202 by (simp add: inj_on_def)
   203 
   204 lemma inj_on_Int: "inj_on f A \<or> inj_on f B \<Longrightarrow> inj_on f (A \<inter> B)"
   205 unfolding inj_on_def by blast
   206 
   207 lemma surj_id: "surj id"
   208 by simp
   209 
   210 lemma bij_id[simp]: "bij id"
   211 by (simp add: bij_betw_def)
   212 
   213 lemma inj_onI:
   214     "(!! x y. [|  x:A;  y:A;  f(x) = f(y) |] ==> x=y) ==> inj_on f A"
   215 by (simp add: inj_on_def)
   216 
   217 lemma inj_on_inverseI: "(!!x. x:A ==> g(f(x)) = x) ==> inj_on f A"
   218 by (auto dest:  arg_cong [of concl: g] simp add: inj_on_def)
   219 
   220 lemma inj_onD: "[| inj_on f A;  f(x)=f(y);  x:A;  y:A |] ==> x=y"
   221 by (unfold inj_on_def, blast)
   222 
   223 lemma inj_on_iff: "[| inj_on f A;  x:A;  y:A |] ==> (f(x)=f(y)) = (x=y)"
   224   by (fact inj_on_eq_iff)
   225 
   226 lemma comp_inj_on:
   227      "[| inj_on f A;  inj_on g (f`A) |] ==> inj_on (g o f) A"
   228 by (simp add: comp_def inj_on_def)
   229 
   230 lemma inj_on_imageI: "inj_on (g o f) A \<Longrightarrow> inj_on g (f ` A)"
   231   by (simp add: inj_on_def) blast
   232 
   233 lemma inj_on_image_iff: "\<lbrakk> ALL x:A. ALL y:A. (g(f x) = g(f y)) = (g x = g y);
   234   inj_on f A \<rbrakk> \<Longrightarrow> inj_on g (f ` A) = inj_on g A"
   235 apply(unfold inj_on_def)
   236 apply blast
   237 done
   238 
   239 lemma inj_on_contraD: "[| inj_on f A;  ~x=y;  x:A;  y:A |] ==> ~ f(x)=f(y)"
   240 by (unfold inj_on_def, blast)
   241 
   242 lemma inj_singleton: "inj (%s. {s})"
   243 by (simp add: inj_on_def)
   244 
   245 lemma inj_on_empty[iff]: "inj_on f {}"
   246 by(simp add: inj_on_def)
   247 
   248 lemma subset_inj_on: "[| inj_on f B; A <= B |] ==> inj_on f A"
   249 by (unfold inj_on_def, blast)
   250 
   251 lemma inj_on_Un:
   252  "inj_on f (A Un B) =
   253   (inj_on f A & inj_on f B & f`(A-B) Int f`(B-A) = {})"
   254 apply(unfold inj_on_def)
   255 apply (blast intro:sym)
   256 done
   257 
   258 lemma inj_on_insert[iff]:
   259   "inj_on f (insert a A) = (inj_on f A & f a ~: f`(A-{a}))"
   260 apply(unfold inj_on_def)
   261 apply (blast intro:sym)
   262 done
   263 
   264 lemma inj_on_diff: "inj_on f A ==> inj_on f (A-B)"
   265 apply(unfold inj_on_def)
   266 apply (blast)
   267 done
   268 
   269 lemma comp_inj_on_iff:
   270   "inj_on f A \<Longrightarrow> inj_on f' (f ` A) \<longleftrightarrow> inj_on (f' o f) A"
   271 by(auto simp add: comp_inj_on inj_on_def)
   272 
   273 lemma inj_on_imageI2:
   274   "inj_on (f' o f) A \<Longrightarrow> inj_on f A"
   275 by(auto simp add: comp_inj_on inj_on_def)
   276 
   277 lemma inj_img_insertE:
   278   assumes "inj_on f A"
   279   assumes "x \<notin> B" and "insert x B = f ` A"
   280   obtains x' A' where "x' \<notin> A'" and "A = insert x' A'"
   281     and "x = f x'" and "B = f ` A'"
   282 proof -
   283   from assms have "x \<in> f ` A" by auto
   284   then obtain x' where *: "x' \<in> A" "x = f x'" by auto
   285   then have "A = insert x' (A - {x'})" by auto
   286   with assms * have "B = f ` (A - {x'})"
   287     by (auto dest: inj_on_contraD)
   288   have "x' \<notin> A - {x'}" by simp
   289   from \<open>x' \<notin> A - {x'}\<close> \<open>A = insert x' (A - {x'})\<close> \<open>x = f x'\<close> \<open>B = image f (A - {x'})\<close>
   290   show ?thesis ..
   291 qed
   292 
   293 lemma linorder_injI:
   294   assumes hyp: "\<And>x y. x < (y::'a::linorder) \<Longrightarrow> f x \<noteq> f y"
   295   shows "inj f"
   296   -- \<open>Courtesy of Stephan Merz\<close>
   297 proof (rule inj_onI)
   298   fix x y
   299   assume f_eq: "f x = f y"
   300   show "x = y" by (rule linorder_cases) (auto dest: hyp simp: f_eq)
   301 qed
   302 
   303 lemma surj_def: "surj f \<longleftrightarrow> (\<forall>y. \<exists>x. y = f x)"
   304   by auto
   305 
   306 lemma surjI: assumes *: "\<And> x. g (f x) = x" shows "surj g"
   307   using *[symmetric] by auto
   308 
   309 lemma surjD: "surj f \<Longrightarrow> \<exists>x. y = f x"
   310   by (simp add: surj_def)
   311 
   312 lemma surjE: "surj f \<Longrightarrow> (\<And>x. y = f x \<Longrightarrow> C) \<Longrightarrow> C"
   313   by (simp add: surj_def, blast)
   314 
   315 lemma comp_surj: "[| surj f;  surj g |] ==> surj (g o f)"
   316 apply (simp add: comp_def surj_def, clarify)
   317 apply (drule_tac x = y in spec, clarify)
   318 apply (drule_tac x = x in spec, blast)
   319 done
   320 
   321 lemma bij_betw_imageI:
   322   "\<lbrakk> inj_on f A; f ` A = B \<rbrakk> \<Longrightarrow> bij_betw f A B"
   323 unfolding bij_betw_def by clarify
   324 
   325 lemma bij_betw_imp_surj_on: "bij_betw f A B \<Longrightarrow> f ` A = B"
   326   unfolding bij_betw_def by clarify
   327 
   328 lemma bij_betw_imp_surj: "bij_betw f A UNIV \<Longrightarrow> surj f"
   329   unfolding bij_betw_def by auto
   330 
   331 lemma bij_betw_empty1:
   332   assumes "bij_betw f {} A"
   333   shows "A = {}"
   334 using assms unfolding bij_betw_def by blast
   335 
   336 lemma bij_betw_empty2:
   337   assumes "bij_betw f A {}"
   338   shows "A = {}"
   339 using assms unfolding bij_betw_def by blast
   340 
   341 lemma inj_on_imp_bij_betw:
   342   "inj_on f A \<Longrightarrow> bij_betw f A (f ` A)"
   343 unfolding bij_betw_def by simp
   344 
   345 lemma bij_def: "bij f \<longleftrightarrow> inj f \<and> surj f"
   346   unfolding bij_betw_def ..
   347 
   348 lemma bijI: "[| inj f; surj f |] ==> bij f"
   349 by (simp add: bij_def)
   350 
   351 lemma bij_is_inj: "bij f ==> inj f"
   352 by (simp add: bij_def)
   353 
   354 lemma bij_is_surj: "bij f ==> surj f"
   355 by (simp add: bij_def)
   356 
   357 lemma bij_betw_imp_inj_on: "bij_betw f A B \<Longrightarrow> inj_on f A"
   358 by (simp add: bij_betw_def)
   359 
   360 lemma bij_betw_trans:
   361   "bij_betw f A B \<Longrightarrow> bij_betw g B C \<Longrightarrow> bij_betw (g o f) A C"
   362 by(auto simp add:bij_betw_def comp_inj_on)
   363 
   364 lemma bij_comp: "bij f \<Longrightarrow> bij g \<Longrightarrow> bij (g o f)"
   365   by (rule bij_betw_trans)
   366 
   367 lemma bij_betw_comp_iff:
   368   "bij_betw f A A' \<Longrightarrow> bij_betw f' A' A'' \<longleftrightarrow> bij_betw (f' o f) A A''"
   369 by(auto simp add: bij_betw_def inj_on_def)
   370 
   371 lemma bij_betw_comp_iff2:
   372   assumes BIJ: "bij_betw f' A' A''" and IM: "f ` A \<le> A'"
   373   shows "bij_betw f A A' \<longleftrightarrow> bij_betw (f' o f) A A''"
   374 using assms
   375 proof(auto simp add: bij_betw_comp_iff)
   376   assume *: "bij_betw (f' \<circ> f) A A''"
   377   thus "bij_betw f A A'"
   378   using IM
   379   proof(auto simp add: bij_betw_def)
   380     assume "inj_on (f' \<circ> f) A"
   381     thus "inj_on f A" using inj_on_imageI2 by blast
   382   next
   383     fix a' assume **: "a' \<in> A'"
   384     hence "f' a' \<in> A''" using BIJ unfolding bij_betw_def by auto
   385     then obtain a where 1: "a \<in> A \<and> f'(f a) = f' a'" using *
   386     unfolding bij_betw_def by force
   387     hence "f a \<in> A'" using IM by auto
   388     hence "f a = a'" using BIJ ** 1 unfolding bij_betw_def inj_on_def by auto
   389     thus "a' \<in> f ` A" using 1 by auto
   390   qed
   391 qed
   392 
   393 lemma bij_betw_inv: assumes "bij_betw f A B" shows "EX g. bij_betw g B A"
   394 proof -
   395   have i: "inj_on f A" and s: "f ` A = B"
   396     using assms by(auto simp:bij_betw_def)
   397   let ?P = "%b a. a:A \<and> f a = b" let ?g = "%b. The (?P b)"
   398   { fix a b assume P: "?P b a"
   399     hence ex1: "\<exists>a. ?P b a" using s by blast
   400     hence uex1: "\<exists>!a. ?P b a" by(blast dest:inj_onD[OF i])
   401     hence " ?g b = a" using the1_equality[OF uex1, OF P] P by simp
   402   } note g = this
   403   have "inj_on ?g B"
   404   proof(rule inj_onI)
   405     fix x y assume "x:B" "y:B" "?g x = ?g y"
   406     from s \<open>x:B\<close> obtain a1 where a1: "?P x a1" by blast
   407     from s \<open>y:B\<close> obtain a2 where a2: "?P y a2" by blast
   408     from g[OF a1] a1 g[OF a2] a2 \<open>?g x = ?g y\<close> show "x=y" by simp
   409   qed
   410   moreover have "?g ` B = A"
   411   proof(auto simp: image_def)
   412     fix b assume "b:B"
   413     with s obtain a where P: "?P b a" by blast
   414     thus "?g b \<in> A" using g[OF P] by auto
   415   next
   416     fix a assume "a:A"
   417     then obtain b where P: "?P b a" using s by blast
   418     then have "b:B" using s by blast
   419     with g[OF P] show "\<exists>b\<in>B. a = ?g b" by blast
   420   qed
   421   ultimately show ?thesis by(auto simp:bij_betw_def)
   422 qed
   423 
   424 lemma bij_betw_cong:
   425   "(\<And> a. a \<in> A \<Longrightarrow> f a = g a) \<Longrightarrow> bij_betw f A A' = bij_betw g A A'"
   426 unfolding bij_betw_def inj_on_def by force
   427 
   428 lemma bij_betw_id[intro, simp]:
   429   "bij_betw id A A"
   430 unfolding bij_betw_def id_def by auto
   431 
   432 lemma bij_betw_id_iff:
   433   "bij_betw id A B \<longleftrightarrow> A = B"
   434 by(auto simp add: bij_betw_def)
   435 
   436 lemma bij_betw_combine:
   437   assumes "bij_betw f A B" "bij_betw f C D" "B \<inter> D = {}"
   438   shows "bij_betw f (A \<union> C) (B \<union> D)"
   439   using assms unfolding bij_betw_def inj_on_Un image_Un by auto
   440 
   441 lemma bij_betw_subset:
   442   assumes BIJ: "bij_betw f A A'" and
   443           SUB: "B \<le> A" and IM: "f ` B = B'"
   444   shows "bij_betw f B B'"
   445 using assms
   446 by(unfold bij_betw_def inj_on_def, auto simp add: inj_on_def)
   447 
   448 lemma bij_pointE:
   449   assumes "bij f"
   450   obtains x where "y = f x" and "\<And>x'. y = f x' \<Longrightarrow> x' = x"
   451 proof -
   452   from assms have "inj f" by (rule bij_is_inj)
   453   moreover from assms have "surj f" by (rule bij_is_surj)
   454   then have "y \<in> range f" by simp
   455   ultimately have "\<exists>!x. y = f x" by (simp add: range_ex1_eq)
   456   with that show thesis by blast
   457 qed
   458 
   459 lemma surj_image_vimage_eq: "surj f ==> f ` (f -` A) = A"
   460 by simp
   461 
   462 lemma surj_vimage_empty:
   463   assumes "surj f" shows "f -` A = {} \<longleftrightarrow> A = {}"
   464   using surj_image_vimage_eq[OF \<open>surj f\<close>, of A]
   465   by (intro iffI) fastforce+
   466 
   467 lemma inj_vimage_image_eq: "inj f ==> f -` (f ` A) = A"
   468 by (simp add: inj_on_def, blast)
   469 
   470 lemma vimage_subsetD: "surj f ==> f -` B <= A ==> B <= f ` A"
   471 by (blast intro: sym)
   472 
   473 lemma vimage_subsetI: "inj f ==> B <= f ` A ==> f -` B <= A"
   474 by (unfold inj_on_def, blast)
   475 
   476 lemma vimage_subset_eq: "bij f ==> (f -` B <= A) = (B <= f ` A)"
   477 apply (unfold bij_def)
   478 apply (blast del: subsetI intro: vimage_subsetI vimage_subsetD)
   479 done
   480 
   481 lemma inj_on_image_eq_iff: "\<lbrakk> inj_on f C; A \<subseteq> C; B \<subseteq> C \<rbrakk> \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   482 by(fastforce simp add: inj_on_def)
   483 
   484 lemma inj_on_Un_image_eq_iff: "inj_on f (A \<union> B) \<Longrightarrow> f ` A = f ` B \<longleftrightarrow> A = B"
   485 by(erule inj_on_image_eq_iff) simp_all
   486 
   487 lemma inj_on_image_Int:
   488    "[| inj_on f C;  A<=C;  B<=C |] ==> f`(A Int B) = f`A Int f`B"
   489   by (simp add: inj_on_def, blast)
   490 
   491 lemma inj_on_image_set_diff:
   492    "[| inj_on f C;  A-B \<subseteq> C;  B \<subseteq> C |] ==> f`(A-B) = f`A - f`B"
   493   by (simp add: inj_on_def, blast)
   494 
   495 lemma image_Int: "inj f ==> f`(A Int B) = f`A Int f`B"
   496   by (simp add: inj_on_def, blast)
   497 
   498 lemma image_set_diff: "inj f ==> f`(A-B) = f`A - f`B"
   499 by (simp add: inj_on_def, blast)
   500 
   501 lemma inj_on_image_mem_iff: "\<lbrakk>inj_on f B; a \<in> B; A \<subseteq> B\<rbrakk> \<Longrightarrow> f a \<in> f`A \<longleftrightarrow> a \<in> A"
   502   by (auto simp: inj_on_def)
   503 
   504 lemma inj_image_mem_iff: "inj f \<Longrightarrow> f a \<in> f`A \<longleftrightarrow> a \<in> A"
   505   by (blast dest: injD)
   506 
   507 lemma inj_image_subset_iff: "inj f ==> (f`A <= f`B) = (A<=B)"
   508   by (blast dest: injD)
   509 
   510 lemma inj_image_eq_iff: "inj f ==> (f`A = f`B) = (A = B)"
   511   by (blast dest: injD)
   512 
   513 lemma surj_Compl_image_subset: "surj f ==> -(f`A) <= f`(-A)"
   514 by auto
   515 
   516 lemma inj_image_Compl_subset: "inj f ==> f`(-A) <= -(f`A)"
   517 by (auto simp add: inj_on_def)
   518 
   519 lemma bij_image_Compl_eq: "bij f ==> f`(-A) = -(f`A)"
   520 apply (simp add: bij_def)
   521 apply (rule equalityI)
   522 apply (simp_all (no_asm_simp) add: inj_image_Compl_subset surj_Compl_image_subset)
   523 done
   524 
   525 lemma inj_vimage_singleton: "inj f \<Longrightarrow> f -` {a} \<subseteq> {THE x. f x = a}"
   526   -- \<open>The inverse image of a singleton under an injective function
   527          is included in a singleton.\<close>
   528   apply (auto simp add: inj_on_def)
   529   apply (blast intro: the_equality [symmetric])
   530   done
   531 
   532 lemma inj_on_vimage_singleton:
   533   "inj_on f A \<Longrightarrow> f -` {a} \<inter> A \<subseteq> {THE x. x \<in> A \<and> f x = a}"
   534   by (auto simp add: inj_on_def intro: the_equality [symmetric])
   535 
   536 lemma (in ordered_ab_group_add) inj_uminus[simp, intro]: "inj_on uminus A"
   537   by (auto intro!: inj_onI)
   538 
   539 lemma (in linorder) strict_mono_imp_inj_on: "strict_mono f \<Longrightarrow> inj_on f A"
   540   by (auto intro!: inj_onI dest: strict_mono_eq)
   541 
   542 lemma bij_betw_byWitness:
   543 assumes LEFT: "\<forall>a \<in> A. f'(f a) = a" and
   544         RIGHT: "\<forall>a' \<in> A'. f(f' a') = a'" and
   545         IM1: "f ` A \<le> A'" and IM2: "f' ` A' \<le> A"
   546 shows "bij_betw f A A'"
   547 using assms
   548 proof(unfold bij_betw_def inj_on_def, safe)
   549   fix a b assume *: "a \<in> A" "b \<in> A" and **: "f a = f b"
   550   have "a = f'(f a) \<and> b = f'(f b)" using * LEFT by simp
   551   with ** show "a = b" by simp
   552 next
   553   fix a' assume *: "a' \<in> A'"
   554   hence "f' a' \<in> A" using IM2 by blast
   555   moreover
   556   have "a' = f(f' a')" using * RIGHT by simp
   557   ultimately show "a' \<in> f ` A" by blast
   558 qed
   559 
   560 corollary notIn_Un_bij_betw:
   561 assumes NIN: "b \<notin> A" and NIN': "f b \<notin> A'" and
   562        BIJ: "bij_betw f A A'"
   563 shows "bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   564 proof-
   565   have "bij_betw f {b} {f b}"
   566   unfolding bij_betw_def inj_on_def by simp
   567   with assms show ?thesis
   568   using bij_betw_combine[of f A A' "{b}" "{f b}"] by blast
   569 qed
   570 
   571 lemma notIn_Un_bij_betw3:
   572 assumes NIN: "b \<notin> A" and NIN': "f b \<notin> A'"
   573 shows "bij_betw f A A' = bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   574 proof
   575   assume "bij_betw f A A'"
   576   thus "bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   577   using assms notIn_Un_bij_betw[of b A f A'] by blast
   578 next
   579   assume *: "bij_betw f (A \<union> {b}) (A' \<union> {f b})"
   580   have "f ` A = A'"
   581   proof(auto)
   582     fix a assume **: "a \<in> A"
   583     hence "f a \<in> A' \<union> {f b}" using * unfolding bij_betw_def by blast
   584     moreover
   585     {assume "f a = f b"
   586      hence "a = b" using * ** unfolding bij_betw_def inj_on_def by blast
   587      with NIN ** have False by blast
   588     }
   589     ultimately show "f a \<in> A'" by blast
   590   next
   591     fix a' assume **: "a' \<in> A'"
   592     hence "a' \<in> f`(A \<union> {b})"
   593     using * by (auto simp add: bij_betw_def)
   594     then obtain a where 1: "a \<in> A \<union> {b} \<and> f a = a'" by blast
   595     moreover
   596     {assume "a = b" with 1 ** NIN' have False by blast
   597     }
   598     ultimately have "a \<in> A" by blast
   599     with 1 show "a' \<in> f ` A" by blast
   600   qed
   601   thus "bij_betw f A A'" using * bij_betw_subset[of f "A \<union> {b}" _ A] by blast
   602 qed
   603 
   604 
   605 subsection\<open>Function Updating\<close>
   606 
   607 definition fun_upd :: "('a => 'b) => 'a => 'b => ('a => 'b)" where
   608   "fun_upd f a b == % x. if x=a then b else f x"
   609 
   610 nonterminal updbinds and updbind
   611 
   612 syntax
   613   "_updbind" :: "['a, 'a] => updbind"             ("(2_ :=/ _)")
   614   ""         :: "updbind => updbinds"             ("_")
   615   "_updbinds":: "[updbind, updbinds] => updbinds" ("_,/ _")
   616   "_Update"  :: "['a, updbinds] => 'a"            ("_/'((_)')" [1000, 0] 900)
   617 
   618 translations
   619   "_Update f (_updbinds b bs)" == "_Update (_Update f b) bs"
   620   "f(x:=y)" == "CONST fun_upd f x y"
   621 
   622 (* Hint: to define the sum of two functions (or maps), use case_sum.
   623          A nice infix syntax could be defined by
   624 notation
   625   case_sum  (infixr "'(+')"80)
   626 *)
   627 
   628 lemma fun_upd_idem_iff: "(f(x:=y) = f) = (f x = y)"
   629 apply (simp add: fun_upd_def, safe)
   630 apply (erule subst)
   631 apply (rule_tac [2] ext, auto)
   632 done
   633 
   634 lemma fun_upd_idem: "f x = y ==> f(x:=y) = f"
   635   by (simp only: fun_upd_idem_iff)
   636 
   637 lemma fun_upd_triv [iff]: "f(x := f x) = f"
   638   by (simp only: fun_upd_idem)
   639 
   640 lemma fun_upd_apply [simp]: "(f(x:=y))z = (if z=x then y else f z)"
   641 by (simp add: fun_upd_def)
   642 
   643 (* fun_upd_apply supersedes these two,   but they are useful
   644    if fun_upd_apply is intentionally removed from the simpset *)
   645 lemma fun_upd_same: "(f(x:=y)) x = y"
   646 by simp
   647 
   648 lemma fun_upd_other: "z~=x ==> (f(x:=y)) z = f z"
   649 by simp
   650 
   651 lemma fun_upd_upd [simp]: "f(x:=y,x:=z) = f(x:=z)"
   652 by (simp add: fun_eq_iff)
   653 
   654 lemma fun_upd_twist: "a ~= c ==> (m(a:=b))(c:=d) = (m(c:=d))(a:=b)"
   655 by (rule ext, auto)
   656 
   657 lemma inj_on_fun_updI:
   658   "inj_on f A \<Longrightarrow> y \<notin> f ` A \<Longrightarrow> inj_on (f(x := y)) A"
   659   by (fastforce simp: inj_on_def)
   660 
   661 lemma fun_upd_image:
   662      "f(x:=y) ` A = (if x \<in> A then insert y (f ` (A-{x})) else f ` A)"
   663 by auto
   664 
   665 lemma fun_upd_comp: "f \<circ> (g(x := y)) = (f \<circ> g)(x := f y)"
   666   by auto
   667 
   668 
   669 subsection \<open>@{text override_on}\<close>
   670 
   671 definition override_on :: "('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a set \<Rightarrow> 'a \<Rightarrow> 'b" where
   672   "override_on f g A = (\<lambda>a. if a \<in> A then g a else f a)"
   673 
   674 lemma override_on_emptyset[simp]: "override_on f g {} = f"
   675 by(simp add:override_on_def)
   676 
   677 lemma override_on_apply_notin[simp]: "a ~: A ==> (override_on f g A) a = f a"
   678 by(simp add:override_on_def)
   679 
   680 lemma override_on_apply_in[simp]: "a : A ==> (override_on f g A) a = g a"
   681 by(simp add:override_on_def)
   682 
   683 
   684 subsection \<open>@{text swap}\<close>
   685 
   686 definition swap :: "'a \<Rightarrow> 'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('a \<Rightarrow> 'b)"
   687 where
   688   "swap a b f = f (a := f b, b:= f a)"
   689 
   690 lemma swap_apply [simp]:
   691   "swap a b f a = f b"
   692   "swap a b f b = f a"
   693   "c \<noteq> a \<Longrightarrow> c \<noteq> b \<Longrightarrow> swap a b f c = f c"
   694   by (simp_all add: swap_def)
   695 
   696 lemma swap_self [simp]:
   697   "swap a a f = f"
   698   by (simp add: swap_def)
   699 
   700 lemma swap_commute:
   701   "swap a b f = swap b a f"
   702   by (simp add: fun_upd_def swap_def fun_eq_iff)
   703 
   704 lemma swap_nilpotent [simp]:
   705   "swap a b (swap a b f) = f"
   706   by (rule ext, simp add: fun_upd_def swap_def)
   707 
   708 lemma swap_comp_involutory [simp]:
   709   "swap a b \<circ> swap a b = id"
   710   by (rule ext) simp
   711 
   712 lemma swap_triple:
   713   assumes "a \<noteq> c" and "b \<noteq> c"
   714   shows "swap a b (swap b c (swap a b f)) = swap a c f"
   715   using assms by (simp add: fun_eq_iff swap_def)
   716 
   717 lemma comp_swap: "f \<circ> swap a b g = swap a b (f \<circ> g)"
   718   by (rule ext, simp add: fun_upd_def swap_def)
   719 
   720 lemma swap_image_eq [simp]:
   721   assumes "a \<in> A" "b \<in> A" shows "swap a b f ` A = f ` A"
   722 proof -
   723   have subset: "\<And>f. swap a b f ` A \<subseteq> f ` A"
   724     using assms by (auto simp: image_iff swap_def)
   725   then have "swap a b (swap a b f) ` A \<subseteq> (swap a b f) ` A" .
   726   with subset[of f] show ?thesis by auto
   727 qed
   728 
   729 lemma inj_on_imp_inj_on_swap:
   730   "\<lbrakk>inj_on f A; a \<in> A; b \<in> A\<rbrakk> \<Longrightarrow> inj_on (swap a b f) A"
   731   by (simp add: inj_on_def swap_def, blast)
   732 
   733 lemma inj_on_swap_iff [simp]:
   734   assumes A: "a \<in> A" "b \<in> A" shows "inj_on (swap a b f) A \<longleftrightarrow> inj_on f A"
   735 proof
   736   assume "inj_on (swap a b f) A"
   737   with A have "inj_on (swap a b (swap a b f)) A"
   738     by (iprover intro: inj_on_imp_inj_on_swap)
   739   thus "inj_on f A" by simp
   740 next
   741   assume "inj_on f A"
   742   with A show "inj_on (swap a b f) A" by (iprover intro: inj_on_imp_inj_on_swap)
   743 qed
   744 
   745 lemma surj_imp_surj_swap: "surj f \<Longrightarrow> surj (swap a b f)"
   746   by simp
   747 
   748 lemma surj_swap_iff [simp]: "surj (swap a b f) \<longleftrightarrow> surj f"
   749   by simp
   750 
   751 lemma bij_betw_swap_iff [simp]:
   752   "\<lbrakk> x \<in> A; y \<in> A \<rbrakk> \<Longrightarrow> bij_betw (swap x y f) A B \<longleftrightarrow> bij_betw f A B"
   753   by (auto simp: bij_betw_def)
   754 
   755 lemma bij_swap_iff [simp]: "bij (swap a b f) \<longleftrightarrow> bij f"
   756   by simp
   757 
   758 hide_const (open) swap
   759 
   760 
   761 subsection \<open>Inversion of injective functions\<close>
   762 
   763 definition the_inv_into :: "'a set => ('a => 'b) => ('b => 'a)" where
   764   "the_inv_into A f == %x. THE y. y : A & f y = x"
   765 
   766 lemma the_inv_into_f_f:
   767   "[| inj_on f A;  x : A |] ==> the_inv_into A f (f x) = x"
   768 apply (simp add: the_inv_into_def inj_on_def)
   769 apply blast
   770 done
   771 
   772 lemma f_the_inv_into_f:
   773   "inj_on f A ==> y : f`A  ==> f (the_inv_into A f y) = y"
   774 apply (simp add: the_inv_into_def)
   775 apply (rule the1I2)
   776  apply(blast dest: inj_onD)
   777 apply blast
   778 done
   779 
   780 lemma the_inv_into_into:
   781   "[| inj_on f A; x : f ` A; A <= B |] ==> the_inv_into A f x : B"
   782 apply (simp add: the_inv_into_def)
   783 apply (rule the1I2)
   784  apply(blast dest: inj_onD)
   785 apply blast
   786 done
   787 
   788 lemma the_inv_into_onto[simp]:
   789   "inj_on f A ==> the_inv_into A f ` (f ` A) = A"
   790 by (fast intro:the_inv_into_into the_inv_into_f_f[symmetric])
   791 
   792 lemma the_inv_into_f_eq:
   793   "[| inj_on f A; f x = y; x : A |] ==> the_inv_into A f y = x"
   794   apply (erule subst)
   795   apply (erule the_inv_into_f_f, assumption)
   796   done
   797 
   798 lemma the_inv_into_comp:
   799   "[| inj_on f (g ` A); inj_on g A; x : f ` g ` A |] ==>
   800   the_inv_into A (f o g) x = (the_inv_into A g o the_inv_into (g ` A) f) x"
   801 apply (rule the_inv_into_f_eq)
   802   apply (fast intro: comp_inj_on)
   803  apply (simp add: f_the_inv_into_f the_inv_into_into)
   804 apply (simp add: the_inv_into_into)
   805 done
   806 
   807 lemma inj_on_the_inv_into:
   808   "inj_on f A \<Longrightarrow> inj_on (the_inv_into A f) (f ` A)"
   809 by (auto intro: inj_onI simp: the_inv_into_f_f)
   810 
   811 lemma bij_betw_the_inv_into:
   812   "bij_betw f A B \<Longrightarrow> bij_betw (the_inv_into A f) B A"
   813 by (auto simp add: bij_betw_def inj_on_the_inv_into the_inv_into_into)
   814 
   815 abbreviation the_inv :: "('a \<Rightarrow> 'b) \<Rightarrow> ('b \<Rightarrow> 'a)" where
   816   "the_inv f \<equiv> the_inv_into UNIV f"
   817 
   818 lemma the_inv_f_f:
   819   assumes "inj f"
   820   shows "the_inv f (f x) = x" using assms UNIV_I
   821   by (rule the_inv_into_f_f)
   822 
   823 
   824 subsection \<open>Cantor's Paradox\<close>
   825 
   826 lemma Cantors_paradox:
   827   "\<not>(\<exists>f. f ` A = Pow A)"
   828 proof clarify
   829   fix f assume "f ` A = Pow A" hence *: "Pow A \<le> f ` A" by blast
   830   let ?X = "{a \<in> A. a \<notin> f a}"
   831   have "?X \<in> Pow A" unfolding Pow_def by auto
   832   with * obtain x where "x \<in> A \<and> f x = ?X" by blast
   833   thus False by best
   834 qed
   835 
   836 subsection \<open>Setup\<close> 
   837 
   838 subsubsection \<open>Proof tools\<close>
   839 
   840 text \<open>simplifies terms of the form
   841   f(...,x:=y,...,x:=z,...) to f(...,x:=z,...)\<close>
   842 
   843 simproc_setup fun_upd2 ("f(v := w, x := y)") = \<open>fn _ =>
   844 let
   845   fun gen_fun_upd NONE T _ _ = NONE
   846     | gen_fun_upd (SOME f) T x y = SOME (Const (@{const_name fun_upd}, T) $ f $ x $ y)
   847   fun dest_fun_T1 (Type (_, T :: Ts)) = T
   848   fun find_double (t as Const (@{const_name fun_upd},T) $ f $ x $ y) =
   849     let
   850       fun find (Const (@{const_name fun_upd},T) $ g $ v $ w) =
   851             if v aconv x then SOME g else gen_fun_upd (find g) T v w
   852         | find t = NONE
   853     in (dest_fun_T1 T, gen_fun_upd (find f) T x y) end
   854 
   855   val ss = simpset_of @{context}
   856 
   857   fun proc ctxt ct =
   858     let
   859       val t = Thm.term_of ct
   860     in
   861       case find_double t of
   862         (T, NONE) => NONE
   863       | (T, SOME rhs) =>
   864           SOME (Goal.prove ctxt [] [] (Logic.mk_equals (t, rhs))
   865             (fn _ =>
   866               resolve_tac ctxt [eq_reflection] 1 THEN
   867               resolve_tac ctxt @{thms ext} 1 THEN
   868               simp_tac (put_simpset ss ctxt) 1))
   869     end
   870 in proc end
   871 \<close>
   872 
   873 
   874 subsubsection \<open>Functorial structure of types\<close>
   875 
   876 ML_file "Tools/functor.ML"
   877 
   878 functor map_fun: map_fun
   879   by (simp_all add: fun_eq_iff)
   880 
   881 functor vimage
   882   by (simp_all add: fun_eq_iff vimage_comp)
   883 
   884 text \<open>Legacy theorem names\<close>
   885 
   886 lemmas o_def = comp_def
   887 lemmas o_apply = comp_apply
   888 lemmas o_assoc = comp_assoc [symmetric]
   889 lemmas id_o = id_comp
   890 lemmas o_id = comp_id
   891 lemmas o_eq_dest = comp_eq_dest
   892 lemmas o_eq_elim = comp_eq_elim
   893 lemmas o_eq_dest_lhs = comp_eq_dest_lhs
   894 lemmas o_eq_id_dest = comp_eq_id_dest
   895 
   896 end
   897