src/HOL/Algebra/UnivPoly.thy
author ballarin
Wed Dec 17 17:53:56 2008 +0100 (2008-12-17)
changeset 29240 bb81c3709fb6
parent 29237 e90d9d51106b
child 29246 3593802c9cf1
permissions -rw-r--r--
More porting to new locales.
     1 (*
     2   Title:     HOL/Algebra/UnivPoly.thy
     3   Author:    Clemens Ballarin, started 9 December 1996
     4   Copyright: Clemens Ballarin
     5 
     6 Contributions, in particular on long division, by Jesus Aransay.
     7 *)
     8 
     9 theory UnivPoly
    10 imports Module RingHom
    11 begin
    12 
    13 
    14 section {* Univariate Polynomials *}
    15 
    16 text {*
    17   Polynomials are formalised as modules with additional operations for
    18   extracting coefficients from polynomials and for obtaining monomials
    19   from coefficients and exponents (record @{text "up_ring"}).  The
    20   carrier set is a set of bounded functions from Nat to the
    21   coefficient domain.  Bounded means that these functions return zero
    22   above a certain bound (the degree).  There is a chapter on the
    23   formalisation of polynomials in the PhD thesis \cite{Ballarin:1999},
    24   which was implemented with axiomatic type classes.  This was later
    25   ported to Locales.
    26 *}
    27 
    28 
    29 subsection {* The Constructor for Univariate Polynomials *}
    30 
    31 text {*
    32   Functions with finite support.
    33 *}
    34 
    35 locale bound =
    36   fixes z :: 'a
    37     and n :: nat
    38     and f :: "nat => 'a"
    39   assumes bound: "!!m. n < m \<Longrightarrow> f m = z"
    40 
    41 declare bound.intro [intro!]
    42   and bound.bound [dest]
    43 
    44 lemma bound_below:
    45   assumes bound: "bound z m f" and nonzero: "f n \<noteq> z" shows "n \<le> m"
    46 proof (rule classical)
    47   assume "~ ?thesis"
    48   then have "m < n" by arith
    49   with bound have "f n = z" ..
    50   with nonzero show ?thesis by contradiction
    51 qed
    52 
    53 record ('a, 'p) up_ring = "('a, 'p) module" +
    54   monom :: "['a, nat] => 'p"
    55   coeff :: "['p, nat] => 'a"
    56 
    57 definition up :: "('a, 'm) ring_scheme => (nat => 'a) set"
    58   where up_def: "up R == {f. f \<in> UNIV -> carrier R & (EX n. bound \<zero>\<^bsub>R\<^esub> n f)}"
    59 
    60 definition UP :: "('a, 'm) ring_scheme => ('a, nat => 'a) up_ring"
    61   where UP_def: "UP R == (|
    62    carrier = up R,
    63    mult = (%p:up R. %q:up R. %n. \<Oplus>\<^bsub>R\<^esub>i \<in> {..n}. p i \<otimes>\<^bsub>R\<^esub> q (n-i)),
    64    one = (%i. if i=0 then \<one>\<^bsub>R\<^esub> else \<zero>\<^bsub>R\<^esub>),
    65    zero = (%i. \<zero>\<^bsub>R\<^esub>),
    66    add = (%p:up R. %q:up R. %i. p i \<oplus>\<^bsub>R\<^esub> q i),
    67    smult = (%a:carrier R. %p:up R. %i. a \<otimes>\<^bsub>R\<^esub> p i),
    68    monom = (%a:carrier R. %n i. if i=n then a else \<zero>\<^bsub>R\<^esub>),
    69    coeff = (%p:up R. %n. p n) |)"
    70 
    71 text {*
    72   Properties of the set of polynomials @{term up}.
    73 *}
    74 
    75 lemma mem_upI [intro]:
    76   "[| !!n. f n \<in> carrier R; EX n. bound (zero R) n f |] ==> f \<in> up R"
    77   by (simp add: up_def Pi_def)
    78 
    79 lemma mem_upD [dest]:
    80   "f \<in> up R ==> f n \<in> carrier R"
    81   by (simp add: up_def Pi_def)
    82 
    83 context ring
    84 begin
    85 
    86 lemma bound_upD [dest]: "f \<in> up R ==> EX n. bound \<zero> n f" by (simp add: up_def)
    87 
    88 lemma up_one_closed: "(%n. if n = 0 then \<one> else \<zero>) \<in> up R" using up_def by force
    89 
    90 lemma up_smult_closed: "[| a \<in> carrier R; p \<in> up R |] ==> (%i. a \<otimes> p i) \<in> up R" by force
    91 
    92 lemma up_add_closed:
    93   "[| p \<in> up R; q \<in> up R |] ==> (%i. p i \<oplus> q i) \<in> up R"
    94 proof
    95   fix n
    96   assume "p \<in> up R" and "q \<in> up R"
    97   then show "p n \<oplus> q n \<in> carrier R"
    98     by auto
    99 next
   100   assume UP: "p \<in> up R" "q \<in> up R"
   101   show "EX n. bound \<zero> n (%i. p i \<oplus> q i)"
   102   proof -
   103     from UP obtain n where boundn: "bound \<zero> n p" by fast
   104     from UP obtain m where boundm: "bound \<zero> m q" by fast
   105     have "bound \<zero> (max n m) (%i. p i \<oplus> q i)"
   106     proof
   107       fix i
   108       assume "max n m < i"
   109       with boundn and boundm and UP show "p i \<oplus> q i = \<zero>" by fastsimp
   110     qed
   111     then show ?thesis ..
   112   qed
   113 qed
   114 
   115 lemma up_a_inv_closed:
   116   "p \<in> up R ==> (%i. \<ominus> (p i)) \<in> up R"
   117 proof
   118   assume R: "p \<in> up R"
   119   then obtain n where "bound \<zero> n p" by auto
   120   then have "bound \<zero> n (%i. \<ominus> p i)" by auto
   121   then show "EX n. bound \<zero> n (%i. \<ominus> p i)" by auto
   122 qed auto
   123 
   124 lemma up_minus_closed:
   125   "[| p \<in> up R; q \<in> up R |] ==> (%i. p i \<ominus> q i) \<in> up R"
   126   using mem_upD [of p R] mem_upD [of q R] up_add_closed up_a_inv_closed a_minus_def [of _ R]
   127   by auto
   128 
   129 lemma up_mult_closed:
   130   "[| p \<in> up R; q \<in> up R |] ==>
   131   (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n-i)) \<in> up R"
   132 proof
   133   fix n
   134   assume "p \<in> up R" "q \<in> up R"
   135   then show "(\<Oplus>i \<in> {..n}. p i \<otimes> q (n-i)) \<in> carrier R"
   136     by (simp add: mem_upD  funcsetI)
   137 next
   138   assume UP: "p \<in> up R" "q \<in> up R"
   139   show "EX n. bound \<zero> n (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n-i))"
   140   proof -
   141     from UP obtain n where boundn: "bound \<zero> n p" by fast
   142     from UP obtain m where boundm: "bound \<zero> m q" by fast
   143     have "bound \<zero> (n + m) (%n. \<Oplus>i \<in> {..n}. p i \<otimes> q (n - i))"
   144     proof
   145       fix k assume bound: "n + m < k"
   146       {
   147         fix i
   148         have "p i \<otimes> q (k-i) = \<zero>"
   149         proof (cases "n < i")
   150           case True
   151           with boundn have "p i = \<zero>" by auto
   152           moreover from UP have "q (k-i) \<in> carrier R" by auto
   153           ultimately show ?thesis by simp
   154         next
   155           case False
   156           with bound have "m < k-i" by arith
   157           with boundm have "q (k-i) = \<zero>" by auto
   158           moreover from UP have "p i \<in> carrier R" by auto
   159           ultimately show ?thesis by simp
   160         qed
   161       }
   162       then show "(\<Oplus>i \<in> {..k}. p i \<otimes> q (k-i)) = \<zero>"
   163         by (simp add: Pi_def)
   164     qed
   165     then show ?thesis by fast
   166   qed
   167 qed
   168 
   169 end
   170 
   171 
   172 subsection {* Effect of Operations on Coefficients *}
   173 
   174 locale UP =
   175   fixes R (structure) and P (structure)
   176   defines P_def: "P == UP R"
   177 
   178 locale UP_ring = UP + R: ring R
   179 
   180 locale UP_cring = UP + R: cring R
   181 
   182 sublocale UP_cring < UP_ring
   183   by intro_locales [1] (rule P_def)
   184 
   185 locale UP_domain = UP + R: "domain" R
   186 
   187 sublocale UP_domain < UP_cring
   188   by intro_locales [1] (rule P_def)
   189 
   190 context UP
   191 begin
   192 
   193 text {*Temporarily declare @{thm [locale=UP] P_def} as simp rule.*}
   194 
   195 declare P_def [simp]
   196 
   197 lemma up_eqI:
   198   assumes prem: "!!n. coeff P p n = coeff P q n" and R: "p \<in> carrier P" "q \<in> carrier P"
   199   shows "p = q"
   200 proof
   201   fix x
   202   from prem and R show "p x = q x" by (simp add: UP_def)
   203 qed
   204 
   205 lemma coeff_closed [simp]:
   206   "p \<in> carrier P ==> coeff P p n \<in> carrier R" by (auto simp add: UP_def)
   207 
   208 end
   209 
   210 context UP_ring 
   211 begin
   212 
   213 (* Theorems generalised from commutative rings to rings by Jesus Aransay. *)
   214 
   215 lemma coeff_monom [simp]:
   216   "a \<in> carrier R ==> coeff P (monom P a m) n = (if m=n then a else \<zero>)"
   217 proof -
   218   assume R: "a \<in> carrier R"
   219   then have "(%n. if n = m then a else \<zero>) \<in> up R"
   220     using up_def by force
   221   with R show ?thesis by (simp add: UP_def)
   222 qed
   223 
   224 lemma coeff_zero [simp]: "coeff P \<zero>\<^bsub>P\<^esub> n = \<zero>" by (auto simp add: UP_def)
   225 
   226 lemma coeff_one [simp]: "coeff P \<one>\<^bsub>P\<^esub> n = (if n=0 then \<one> else \<zero>)"
   227   using up_one_closed by (simp add: UP_def)
   228 
   229 lemma coeff_smult [simp]:
   230   "[| a \<in> carrier R; p \<in> carrier P |] ==> coeff P (a \<odot>\<^bsub>P\<^esub> p) n = a \<otimes> coeff P p n"
   231   by (simp add: UP_def up_smult_closed)
   232 
   233 lemma coeff_add [simp]:
   234   "[| p \<in> carrier P; q \<in> carrier P |] ==> coeff P (p \<oplus>\<^bsub>P\<^esub> q) n = coeff P p n \<oplus> coeff P q n"
   235   by (simp add: UP_def up_add_closed)
   236 
   237 lemma coeff_mult [simp]:
   238   "[| p \<in> carrier P; q \<in> carrier P |] ==> coeff P (p \<otimes>\<^bsub>P\<^esub> q) n = (\<Oplus>i \<in> {..n}. coeff P p i \<otimes> coeff P q (n-i))"
   239   by (simp add: UP_def up_mult_closed)
   240 
   241 end
   242 
   243 
   244 subsection {* Polynomials Form a Ring. *}
   245 
   246 context UP_ring
   247 begin
   248 
   249 text {* Operations are closed over @{term P}. *}
   250 
   251 lemma UP_mult_closed [simp]:
   252   "[| p \<in> carrier P; q \<in> carrier P |] ==> p \<otimes>\<^bsub>P\<^esub> q \<in> carrier P" by (simp add: UP_def up_mult_closed)
   253 
   254 lemma UP_one_closed [simp]:
   255   "\<one>\<^bsub>P\<^esub> \<in> carrier P" by (simp add: UP_def up_one_closed)
   256 
   257 lemma UP_zero_closed [intro, simp]:
   258   "\<zero>\<^bsub>P\<^esub> \<in> carrier P" by (auto simp add: UP_def)
   259 
   260 lemma UP_a_closed [intro, simp]:
   261   "[| p \<in> carrier P; q \<in> carrier P |] ==> p \<oplus>\<^bsub>P\<^esub> q \<in> carrier P" by (simp add: UP_def up_add_closed)
   262 
   263 lemma monom_closed [simp]:
   264   "a \<in> carrier R ==> monom P a n \<in> carrier P" by (auto simp add: UP_def up_def Pi_def)
   265 
   266 lemma UP_smult_closed [simp]:
   267   "[| a \<in> carrier R; p \<in> carrier P |] ==> a \<odot>\<^bsub>P\<^esub> p \<in> carrier P" by (simp add: UP_def up_smult_closed)
   268 
   269 end
   270 
   271 declare (in UP) P_def [simp del]
   272 
   273 text {* Algebraic ring properties *}
   274 
   275 context UP_ring
   276 begin
   277 
   278 lemma UP_a_assoc:
   279   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   280   shows "(p \<oplus>\<^bsub>P\<^esub> q) \<oplus>\<^bsub>P\<^esub> r = p \<oplus>\<^bsub>P\<^esub> (q \<oplus>\<^bsub>P\<^esub> r)" by (rule up_eqI, simp add: a_assoc R, simp_all add: R)
   281 
   282 lemma UP_l_zero [simp]:
   283   assumes R: "p \<in> carrier P"
   284   shows "\<zero>\<^bsub>P\<^esub> \<oplus>\<^bsub>P\<^esub> p = p" by (rule up_eqI, simp_all add: R)
   285 
   286 lemma UP_l_neg_ex:
   287   assumes R: "p \<in> carrier P"
   288   shows "EX q : carrier P. q \<oplus>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>"
   289 proof -
   290   let ?q = "%i. \<ominus> (p i)"
   291   from R have closed: "?q \<in> carrier P"
   292     by (simp add: UP_def P_def up_a_inv_closed)
   293   from R have coeff: "!!n. coeff P ?q n = \<ominus> (coeff P p n)"
   294     by (simp add: UP_def P_def up_a_inv_closed)
   295   show ?thesis
   296   proof
   297     show "?q \<oplus>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>"
   298       by (auto intro!: up_eqI simp add: R closed coeff R.l_neg)
   299   qed (rule closed)
   300 qed
   301 
   302 lemma UP_a_comm:
   303   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   304   shows "p \<oplus>\<^bsub>P\<^esub> q = q \<oplus>\<^bsub>P\<^esub> p" by (rule up_eqI, simp add: a_comm R, simp_all add: R)
   305 
   306 lemma UP_m_assoc:
   307   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   308   shows "(p \<otimes>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r = p \<otimes>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)"
   309 proof (rule up_eqI)
   310   fix n
   311   {
   312     fix k and a b c :: "nat=>'a"
   313     assume R: "a \<in> UNIV -> carrier R" "b \<in> UNIV -> carrier R"
   314       "c \<in> UNIV -> carrier R"
   315     then have "k <= n ==>
   316       (\<Oplus>j \<in> {..k}. (\<Oplus>i \<in> {..j}. a i \<otimes> b (j-i)) \<otimes> c (n-j)) =
   317       (\<Oplus>j \<in> {..k}. a j \<otimes> (\<Oplus>i \<in> {..k-j}. b i \<otimes> c (n-j-i)))"
   318       (is "_ \<Longrightarrow> ?eq k")
   319     proof (induct k)
   320       case 0 then show ?case by (simp add: Pi_def m_assoc)
   321     next
   322       case (Suc k)
   323       then have "k <= n" by arith
   324       from this R have "?eq k" by (rule Suc)
   325       with R show ?case
   326         by (simp cong: finsum_cong
   327              add: Suc_diff_le Pi_def l_distr r_distr m_assoc)
   328            (simp cong: finsum_cong add: Pi_def a_ac finsum_ldistr m_assoc)
   329     qed
   330   }
   331   with R show "coeff P ((p \<otimes>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r) n = coeff P (p \<otimes>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)) n"
   332     by (simp add: Pi_def)
   333 qed (simp_all add: R)
   334 
   335 lemma UP_r_one [simp]:
   336   assumes R: "p \<in> carrier P" shows "p \<otimes>\<^bsub>P\<^esub> \<one>\<^bsub>P\<^esub> = p"
   337 proof (rule up_eqI)
   338   fix n
   339   show "coeff P (p \<otimes>\<^bsub>P\<^esub> \<one>\<^bsub>P\<^esub>) n = coeff P p n"
   340   proof (cases n)
   341     case 0 
   342     {
   343       with R show ?thesis by simp
   344     }
   345   next
   346     case Suc
   347     {
   348       (*JE: in the locale UP_cring the proof was solved only with "by (simp del: finsum_Suc add: finsum_Suc2 Pi_def)", but I did not get it to work here*)
   349       fix nn assume Succ: "n = Suc nn"
   350       have "coeff P (p \<otimes>\<^bsub>P\<^esub> \<one>\<^bsub>P\<^esub>) (Suc nn) = coeff P p (Suc nn)"
   351       proof -
   352 	have "coeff P (p \<otimes>\<^bsub>P\<^esub> \<one>\<^bsub>P\<^esub>) (Suc nn) = (\<Oplus>i\<in>{..Suc nn}. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>))" using R by simp
   353 	also have "\<dots> = coeff P p (Suc nn) \<otimes> (if Suc nn \<le> Suc nn then \<one> else \<zero>) \<oplus> (\<Oplus>i\<in>{..nn}. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>))"
   354 	  using finsum_Suc [of "(\<lambda>i::nat. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>))" "nn"] unfolding Pi_def using R by simp
   355 	also have "\<dots> = coeff P p (Suc nn) \<otimes> (if Suc nn \<le> Suc nn then \<one> else \<zero>)"
   356 	proof -
   357 	  have "(\<Oplus>i\<in>{..nn}. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>)) = (\<Oplus>i\<in>{..nn}. \<zero>)"
   358 	    using finsum_cong [of "{..nn}" "{..nn}" "(\<lambda>i::nat. coeff P p i \<otimes> (if Suc nn \<le> i then \<one> else \<zero>))" "(\<lambda>i::nat. \<zero>)"] using R 
   359 	    unfolding Pi_def by simp
   360 	  also have "\<dots> = \<zero>" by simp
   361 	  finally show ?thesis using r_zero R by simp
   362 	qed
   363 	also have "\<dots> = coeff P p (Suc nn)" using R by simp
   364 	finally show ?thesis by simp
   365       qed
   366       then show ?thesis using Succ by simp
   367     }
   368   qed
   369 qed (simp_all add: R)
   370   
   371 lemma UP_l_one [simp]:
   372   assumes R: "p \<in> carrier P"
   373   shows "\<one>\<^bsub>P\<^esub> \<otimes>\<^bsub>P\<^esub> p = p"
   374 proof (rule up_eqI)
   375   fix n
   376   show "coeff P (\<one>\<^bsub>P\<^esub> \<otimes>\<^bsub>P\<^esub> p) n = coeff P p n"
   377   proof (cases n)
   378     case 0 with R show ?thesis by simp
   379   next
   380     case Suc with R show ?thesis
   381       by (simp del: finsum_Suc add: finsum_Suc2 Pi_def)
   382   qed
   383 qed (simp_all add: R)
   384 
   385 lemma UP_l_distr:
   386   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   387   shows "(p \<oplus>\<^bsub>P\<^esub> q) \<otimes>\<^bsub>P\<^esub> r = (p \<otimes>\<^bsub>P\<^esub> r) \<oplus>\<^bsub>P\<^esub> (q \<otimes>\<^bsub>P\<^esub> r)"
   388   by (rule up_eqI) (simp add: l_distr R Pi_def, simp_all add: R)
   389 
   390 lemma UP_r_distr:
   391   assumes R: "p \<in> carrier P" "q \<in> carrier P" "r \<in> carrier P"
   392   shows "r \<otimes>\<^bsub>P\<^esub> (p \<oplus>\<^bsub>P\<^esub> q) = (r \<otimes>\<^bsub>P\<^esub> p) \<oplus>\<^bsub>P\<^esub> (r \<otimes>\<^bsub>P\<^esub> q)"
   393   by (rule up_eqI) (simp add: r_distr R Pi_def, simp_all add: R)
   394 
   395 theorem UP_ring: "ring P"
   396   by (auto intro!: ringI abelian_groupI monoidI UP_a_assoc)
   397     (auto intro: UP_a_comm UP_l_neg_ex UP_m_assoc UP_l_distr UP_r_distr)
   398 
   399 end
   400 
   401 
   402 subsection {* Polynomials Form a Commutative Ring. *}
   403 
   404 context UP_cring
   405 begin
   406 
   407 lemma UP_m_comm:
   408   assumes R1: "p \<in> carrier P" and R2: "q \<in> carrier P" shows "p \<otimes>\<^bsub>P\<^esub> q = q \<otimes>\<^bsub>P\<^esub> p"
   409 proof (rule up_eqI)
   410   fix n
   411   {
   412     fix k and a b :: "nat=>'a"
   413     assume R: "a \<in> UNIV -> carrier R" "b \<in> UNIV -> carrier R"
   414     then have "k <= n ==>
   415       (\<Oplus>i \<in> {..k}. a i \<otimes> b (n-i)) = (\<Oplus>i \<in> {..k}. a (k-i) \<otimes> b (i+n-k))"
   416       (is "_ \<Longrightarrow> ?eq k")
   417     proof (induct k)
   418       case 0 then show ?case by (simp add: Pi_def)
   419     next
   420       case (Suc k) then show ?case
   421         by (subst (2) finsum_Suc2) (simp add: Pi_def a_comm)+
   422     qed
   423   }
   424   note l = this
   425   from R1 R2 show "coeff P (p \<otimes>\<^bsub>P\<^esub> q) n =  coeff P (q \<otimes>\<^bsub>P\<^esub> p) n"
   426     unfolding coeff_mult [OF R1 R2, of n] 
   427     unfolding coeff_mult [OF R2 R1, of n] 
   428     using l [of "(\<lambda>i. coeff P p i)" "(\<lambda>i. coeff P q i)" "n"] by (simp add: Pi_def m_comm)
   429 qed (simp_all add: R1 R2)
   430 
   431 subsection{*Polynomials over a commutative ring for a commutative ring*}
   432 
   433 theorem UP_cring:
   434   "cring P" using UP_ring unfolding cring_def by (auto intro!: comm_monoidI UP_m_assoc UP_m_comm)
   435 
   436 end
   437 
   438 context UP_ring
   439 begin
   440 
   441 lemma UP_a_inv_closed [intro, simp]:
   442   "p \<in> carrier P ==> \<ominus>\<^bsub>P\<^esub> p \<in> carrier P"
   443   by (rule abelian_group.a_inv_closed [OF ring.is_abelian_group [OF UP_ring]])
   444 
   445 lemma coeff_a_inv [simp]:
   446   assumes R: "p \<in> carrier P"
   447   shows "coeff P (\<ominus>\<^bsub>P\<^esub> p) n = \<ominus> (coeff P p n)"
   448 proof -
   449   from R coeff_closed UP_a_inv_closed have
   450     "coeff P (\<ominus>\<^bsub>P\<^esub> p) n = \<ominus> coeff P p n \<oplus> (coeff P p n \<oplus> coeff P (\<ominus>\<^bsub>P\<^esub> p) n)"
   451     by algebra
   452   also from R have "... =  \<ominus> (coeff P p n)"
   453     by (simp del: coeff_add add: coeff_add [THEN sym]
   454       abelian_group.r_neg [OF ring.is_abelian_group [OF UP_ring]])
   455   finally show ?thesis .
   456 qed
   457 
   458 end
   459 
   460 sublocale UP_ring < P: ring P using UP_ring .
   461 sublocale UP_cring < P: cring P using UP_cring .
   462 
   463 
   464 subsection {* Polynomials Form an Algebra *}
   465 
   466 context UP_ring
   467 begin
   468 
   469 lemma UP_smult_l_distr:
   470   "[| a \<in> carrier R; b \<in> carrier R; p \<in> carrier P |] ==>
   471   (a \<oplus> b) \<odot>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> p \<oplus>\<^bsub>P\<^esub> b \<odot>\<^bsub>P\<^esub> p"
   472   by (rule up_eqI) (simp_all add: R.l_distr)
   473 
   474 lemma UP_smult_r_distr:
   475   "[| a \<in> carrier R; p \<in> carrier P; q \<in> carrier P |] ==>
   476   a \<odot>\<^bsub>P\<^esub> (p \<oplus>\<^bsub>P\<^esub> q) = a \<odot>\<^bsub>P\<^esub> p \<oplus>\<^bsub>P\<^esub> a \<odot>\<^bsub>P\<^esub> q"
   477   by (rule up_eqI) (simp_all add: R.r_distr)
   478 
   479 lemma UP_smult_assoc1:
   480       "[| a \<in> carrier R; b \<in> carrier R; p \<in> carrier P |] ==>
   481       (a \<otimes> b) \<odot>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> (b \<odot>\<^bsub>P\<^esub> p)"
   482   by (rule up_eqI) (simp_all add: R.m_assoc)
   483 
   484 lemma UP_smult_zero [simp]:
   485       "p \<in> carrier P ==> \<zero> \<odot>\<^bsub>P\<^esub> p = \<zero>\<^bsub>P\<^esub>"
   486   by (rule up_eqI) simp_all
   487 
   488 lemma UP_smult_one [simp]:
   489       "p \<in> carrier P ==> \<one> \<odot>\<^bsub>P\<^esub> p = p"
   490   by (rule up_eqI) simp_all
   491 
   492 lemma UP_smult_assoc2:
   493   "[| a \<in> carrier R; p \<in> carrier P; q \<in> carrier P |] ==>
   494   (a \<odot>\<^bsub>P\<^esub> p) \<otimes>\<^bsub>P\<^esub> q = a \<odot>\<^bsub>P\<^esub> (p \<otimes>\<^bsub>P\<^esub> q)"
   495   by (rule up_eqI) (simp_all add: R.finsum_rdistr R.m_assoc Pi_def)
   496 
   497 end
   498 
   499 text {*
   500   Interpretation of lemmas from @{term algebra}.
   501 *}
   502 
   503 lemma (in cring) cring:
   504   "cring R" ..
   505 
   506 lemma (in UP_cring) UP_algebra:
   507   "algebra R P" by (auto intro!: algebraI R.cring UP_cring UP_smult_l_distr UP_smult_r_distr
   508     UP_smult_assoc1 UP_smult_assoc2)
   509 
   510 sublocale UP_cring < algebra R P using UP_algebra .
   511 
   512 
   513 subsection {* Further Lemmas Involving Monomials *}
   514 
   515 context UP_ring
   516 begin
   517 
   518 lemma monom_zero [simp]:
   519   "monom P \<zero> n = \<zero>\<^bsub>P\<^esub>" by (simp add: UP_def P_def)
   520 
   521 lemma monom_mult_is_smult:
   522   assumes R: "a \<in> carrier R" "p \<in> carrier P"
   523   shows "monom P a 0 \<otimes>\<^bsub>P\<^esub> p = a \<odot>\<^bsub>P\<^esub> p"
   524 proof (rule up_eqI)
   525   fix n
   526   show "coeff P (monom P a 0 \<otimes>\<^bsub>P\<^esub> p) n = coeff P (a \<odot>\<^bsub>P\<^esub> p) n"
   527   proof (cases n)
   528     case 0 with R show ?thesis by simp
   529   next
   530     case Suc with R show ?thesis
   531       using R.finsum_Suc2 by (simp del: R.finsum_Suc add: R.r_null Pi_def)
   532   qed
   533 qed (simp_all add: R)
   534 
   535 lemma monom_one [simp]:
   536   "monom P \<one> 0 = \<one>\<^bsub>P\<^esub>"
   537   by (rule up_eqI) simp_all
   538 
   539 lemma monom_add [simp]:
   540   "[| a \<in> carrier R; b \<in> carrier R |] ==>
   541   monom P (a \<oplus> b) n = monom P a n \<oplus>\<^bsub>P\<^esub> monom P b n"
   542   by (rule up_eqI) simp_all
   543 
   544 lemma monom_one_Suc:
   545   "monom P \<one> (Suc n) = monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1"
   546 proof (rule up_eqI)
   547   fix k
   548   show "coeff P (monom P \<one> (Suc n)) k = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k"
   549   proof (cases "k = Suc n")
   550     case True show ?thesis
   551     proof -
   552       fix m
   553       from True have less_add_diff:
   554         "!!i. [| n < i; i <= n + m |] ==> n + m - i < m" by arith
   555       from True have "coeff P (monom P \<one> (Suc n)) k = \<one>" by simp
   556       also from True
   557       have "... = (\<Oplus>i \<in> {..<n} \<union> {n}. coeff P (monom P \<one> n) i \<otimes>
   558         coeff P (monom P \<one> 1) (k - i))"
   559         by (simp cong: R.finsum_cong add: Pi_def)
   560       also have "... = (\<Oplus>i \<in>  {..n}. coeff P (monom P \<one> n) i \<otimes>
   561         coeff P (monom P \<one> 1) (k - i))"
   562         by (simp only: ivl_disj_un_singleton)
   563       also from True
   564       have "... = (\<Oplus>i \<in> {..n} \<union> {n<..k}. coeff P (monom P \<one> n) i \<otimes>
   565         coeff P (monom P \<one> 1) (k - i))"
   566         by (simp cong: R.finsum_cong add: R.finsum_Un_disjoint ivl_disj_int_one
   567           order_less_imp_not_eq Pi_def)
   568       also from True have "... = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k"
   569         by (simp add: ivl_disj_un_one)
   570       finally show ?thesis .
   571     qed
   572   next
   573     case False
   574     note neq = False
   575     let ?s =
   576       "\<lambda>i. (if n = i then \<one> else \<zero>) \<otimes> (if Suc 0 = k - i then \<one> else \<zero>)"
   577     from neq have "coeff P (monom P \<one> (Suc n)) k = \<zero>" by simp
   578     also have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   579     proof -
   580       have f1: "(\<Oplus>i \<in> {..<n}. ?s i) = \<zero>"
   581         by (simp cong: R.finsum_cong add: Pi_def)
   582       from neq have f2: "(\<Oplus>i \<in> {n}. ?s i) = \<zero>"
   583         by (simp cong: R.finsum_cong add: Pi_def) arith
   584       have f3: "n < k ==> (\<Oplus>i \<in> {n<..k}. ?s i) = \<zero>"
   585         by (simp cong: R.finsum_cong add: order_less_imp_not_eq Pi_def)
   586       show ?thesis
   587       proof (cases "k < n")
   588         case True then show ?thesis by (simp cong: R.finsum_cong add: Pi_def)
   589       next
   590         case False then have n_le_k: "n <= k" by arith
   591         show ?thesis
   592         proof (cases "n = k")
   593           case True
   594           then have "\<zero> = (\<Oplus>i \<in> {..<n} \<union> {n}. ?s i)"
   595             by (simp cong: R.finsum_cong add: ivl_disj_int_singleton Pi_def)
   596           also from True have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   597             by (simp only: ivl_disj_un_singleton)
   598           finally show ?thesis .
   599         next
   600           case False with n_le_k have n_less_k: "n < k" by arith
   601           with neq have "\<zero> = (\<Oplus>i \<in> {..<n} \<union> {n}. ?s i)"
   602             by (simp add: R.finsum_Un_disjoint f1 f2
   603               ivl_disj_int_singleton Pi_def del: Un_insert_right)
   604           also have "... = (\<Oplus>i \<in> {..n}. ?s i)"
   605             by (simp only: ivl_disj_un_singleton)
   606           also from n_less_k neq have "... = (\<Oplus>i \<in> {..n} \<union> {n<..k}. ?s i)"
   607             by (simp add: R.finsum_Un_disjoint f3 ivl_disj_int_one Pi_def)
   608           also from n_less_k have "... = (\<Oplus>i \<in> {..k}. ?s i)"
   609             by (simp only: ivl_disj_un_one)
   610           finally show ?thesis .
   611         qed
   612       qed
   613     qed
   614     also have "... = coeff P (monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> 1) k" by simp
   615     finally show ?thesis .
   616   qed
   617 qed (simp_all)
   618 
   619 lemma monom_one_Suc2:
   620   "monom P \<one> (Suc n) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> n"
   621 proof (induct n)
   622   case 0 show ?case by simp
   623 next
   624   case Suc
   625   {
   626     fix k:: nat
   627     assume hypo: "monom P \<one> (Suc k) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> k"
   628     then show "monom P \<one> (Suc (Suc k)) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> (Suc k)"
   629     proof -
   630       have lhs: "monom P \<one> (Suc (Suc k)) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> k \<otimes>\<^bsub>P\<^esub> monom P \<one> 1"
   631 	unfolding monom_one_Suc [of "Suc k"] unfolding hypo ..
   632       note cl = monom_closed [OF R.one_closed, of 1]
   633       note clk = monom_closed [OF R.one_closed, of k]
   634       have rhs: "monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> (Suc k) = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> k \<otimes>\<^bsub>P\<^esub> monom P \<one> 1"
   635 	unfolding monom_one_Suc [of k] unfolding sym [OF m_assoc  [OF cl clk cl]] ..
   636       from lhs rhs show ?thesis by simp
   637     qed
   638   }
   639 qed
   640 
   641 text{*The following corollary follows from lemmas @{thm [locale=UP_ring] "monom_one_Suc"} 
   642   and @{thm [locale=UP_ring] "monom_one_Suc2"}, and is trivial in @{term UP_cring}*}
   643 
   644 corollary monom_one_comm: shows "monom P \<one> k \<otimes>\<^bsub>P\<^esub> monom P \<one> 1 = monom P \<one> 1 \<otimes>\<^bsub>P\<^esub> monom P \<one> k"
   645   unfolding monom_one_Suc [symmetric] monom_one_Suc2 [symmetric] ..
   646 
   647 lemma monom_mult_smult:
   648   "[| a \<in> carrier R; b \<in> carrier R |] ==> monom P (a \<otimes> b) n = a \<odot>\<^bsub>P\<^esub> monom P b n"
   649   by (rule up_eqI) simp_all
   650 
   651 lemma monom_one_mult:
   652   "monom P \<one> (n + m) = monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> m"
   653 proof (induct n)
   654   case 0 show ?case by simp
   655 next
   656   case Suc then show ?case
   657     unfolding add_Suc unfolding monom_one_Suc unfolding Suc.hyps
   658     using m_assoc monom_one_comm [of m] by simp
   659 qed
   660 
   661 lemma monom_one_mult_comm: "monom P \<one> n \<otimes>\<^bsub>P\<^esub> monom P \<one> m = monom P \<one> m \<otimes>\<^bsub>P\<^esub> monom P \<one> n"
   662   unfolding monom_one_mult [symmetric] by (rule up_eqI) simp_all
   663 
   664 lemma monom_mult [simp]:
   665   assumes a_in_R: "a \<in> carrier R" and b_in_R: "b \<in> carrier R"
   666   shows "monom P (a \<otimes> b) (n + m) = monom P a n \<otimes>\<^bsub>P\<^esub> monom P b m"
   667 proof (rule up_eqI)
   668   fix k 
   669   show "coeff P (monom P (a \<otimes> b) (n + m)) k = coeff P (monom P a n \<otimes>\<^bsub>P\<^esub> monom P b m) k"
   670   proof (cases "n + m = k")
   671     case True 
   672     {
   673       show ?thesis
   674 	unfolding True [symmetric]
   675 	  coeff_mult [OF monom_closed [OF a_in_R, of n] monom_closed [OF b_in_R, of m], of "n + m"] 
   676 	  coeff_monom [OF a_in_R, of n] coeff_monom [OF b_in_R, of m]
   677 	using R.finsum_cong [of "{.. n + m}" "{.. n + m}" "(\<lambda>i. (if n = i then a else \<zero>) \<otimes> (if m = n + m - i then b else \<zero>))" 
   678 	  "(\<lambda>i. if n = i then a \<otimes> b else \<zero>)"]
   679 	  a_in_R b_in_R
   680 	unfolding simp_implies_def
   681 	using R.finsum_singleton [of n "{.. n + m}" "(\<lambda>i. a \<otimes> b)"]
   682 	unfolding Pi_def by auto
   683     }
   684   next
   685     case False
   686     {
   687       show ?thesis
   688 	unfolding coeff_monom [OF R.m_closed [OF a_in_R b_in_R], of "n + m" k] apply (simp add: False)
   689 	unfolding coeff_mult [OF monom_closed [OF a_in_R, of n] monom_closed [OF b_in_R, of m], of k]
   690 	unfolding coeff_monom [OF a_in_R, of n] unfolding coeff_monom [OF b_in_R, of m] using False
   691 	using R.finsum_cong [of "{..k}" "{..k}" "(\<lambda>i. (if n = i then a else \<zero>) \<otimes> (if m = k - i then b else \<zero>))" "(\<lambda>i. \<zero>)"]
   692 	unfolding Pi_def simp_implies_def using a_in_R b_in_R by force
   693     }
   694   qed
   695 qed (simp_all add: a_in_R b_in_R)
   696 
   697 lemma monom_a_inv [simp]:
   698   "a \<in> carrier R ==> monom P (\<ominus> a) n = \<ominus>\<^bsub>P\<^esub> monom P a n"
   699   by (rule up_eqI) simp_all
   700 
   701 lemma monom_inj:
   702   "inj_on (%a. monom P a n) (carrier R)"
   703 proof (rule inj_onI)
   704   fix x y
   705   assume R: "x \<in> carrier R" "y \<in> carrier R" and eq: "monom P x n = monom P y n"
   706   then have "coeff P (monom P x n) n = coeff P (monom P y n) n" by simp
   707   with R show "x = y" by simp
   708 qed
   709 
   710 end
   711 
   712 
   713 subsection {* The Degree Function *}
   714 
   715 definition deg :: "[('a, 'm) ring_scheme, nat => 'a] => nat"
   716   where "deg R p == LEAST n. bound \<zero>\<^bsub>R\<^esub> n (coeff (UP R) p)"
   717 
   718 context UP_ring
   719 begin
   720 
   721 lemma deg_aboveI:
   722   "[| (!!m. n < m ==> coeff P p m = \<zero>); p \<in> carrier P |] ==> deg R p <= n"
   723   by (unfold deg_def P_def) (fast intro: Least_le)
   724 
   725 (*
   726 lemma coeff_bound_ex: "EX n. bound n (coeff p)"
   727 proof -
   728   have "(%n. coeff p n) : UP" by (simp add: coeff_def Rep_UP)
   729   then obtain n where "bound n (coeff p)" by (unfold UP_def) fast
   730   then show ?thesis ..
   731 qed
   732 
   733 lemma bound_coeff_obtain:
   734   assumes prem: "(!!n. bound n (coeff p) ==> P)" shows "P"
   735 proof -
   736   have "(%n. coeff p n) : UP" by (simp add: coeff_def Rep_UP)
   737   then obtain n where "bound n (coeff p)" by (unfold UP_def) fast
   738   with prem show P .
   739 qed
   740 *)
   741 
   742 lemma deg_aboveD:
   743   assumes "deg R p < m" and "p \<in> carrier P"
   744   shows "coeff P p m = \<zero>"
   745 proof -
   746   from `p \<in> carrier P` obtain n where "bound \<zero> n (coeff P p)"
   747     by (auto simp add: UP_def P_def)
   748   then have "bound \<zero> (deg R p) (coeff P p)"
   749     by (auto simp: deg_def P_def dest: LeastI)
   750   from this and `deg R p < m` show ?thesis ..
   751 qed
   752 
   753 lemma deg_belowI:
   754   assumes non_zero: "n ~= 0 ==> coeff P p n ~= \<zero>"
   755     and R: "p \<in> carrier P"
   756   shows "n <= deg R p"
   757 -- {* Logically, this is a slightly stronger version of
   758    @{thm [source] deg_aboveD} *}
   759 proof (cases "n=0")
   760   case True then show ?thesis by simp
   761 next
   762   case False then have "coeff P p n ~= \<zero>" by (rule non_zero)
   763   then have "~ deg R p < n" by (fast dest: deg_aboveD intro: R)
   764   then show ?thesis by arith
   765 qed
   766 
   767 lemma lcoeff_nonzero_deg:
   768   assumes deg: "deg R p ~= 0" and R: "p \<in> carrier P"
   769   shows "coeff P p (deg R p) ~= \<zero>"
   770 proof -
   771   from R obtain m where "deg R p <= m" and m_coeff: "coeff P p m ~= \<zero>"
   772   proof -
   773     have minus: "!!(n::nat) m. n ~= 0 ==> (n - Suc 0 < m) = (n <= m)"
   774       by arith
   775     from deg have "deg R p - 1 < (LEAST n. bound \<zero> n (coeff P p))"
   776       by (unfold deg_def P_def) simp
   777     then have "~ bound \<zero> (deg R p - 1) (coeff P p)" by (rule not_less_Least)
   778     then have "EX m. deg R p - 1 < m & coeff P p m ~= \<zero>"
   779       by (unfold bound_def) fast
   780     then have "EX m. deg R p <= m & coeff P p m ~= \<zero>" by (simp add: deg minus)
   781     then show ?thesis by (auto intro: that)
   782   qed
   783   with deg_belowI R have "deg R p = m" by fastsimp
   784   with m_coeff show ?thesis by simp
   785 qed
   786 
   787 lemma lcoeff_nonzero_nonzero:
   788   assumes deg: "deg R p = 0" and nonzero: "p ~= \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P"
   789   shows "coeff P p 0 ~= \<zero>"
   790 proof -
   791   have "EX m. coeff P p m ~= \<zero>"
   792   proof (rule classical)
   793     assume "~ ?thesis"
   794     with R have "p = \<zero>\<^bsub>P\<^esub>" by (auto intro: up_eqI)
   795     with nonzero show ?thesis by contradiction
   796   qed
   797   then obtain m where coeff: "coeff P p m ~= \<zero>" ..
   798   from this and R have "m <= deg R p" by (rule deg_belowI)
   799   then have "m = 0" by (simp add: deg)
   800   with coeff show ?thesis by simp
   801 qed
   802 
   803 lemma lcoeff_nonzero:
   804   assumes neq: "p ~= \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P"
   805   shows "coeff P p (deg R p) ~= \<zero>"
   806 proof (cases "deg R p = 0")
   807   case True with neq R show ?thesis by (simp add: lcoeff_nonzero_nonzero)
   808 next
   809   case False with neq R show ?thesis by (simp add: lcoeff_nonzero_deg)
   810 qed
   811 
   812 lemma deg_eqI:
   813   "[| !!m. n < m ==> coeff P p m = \<zero>;
   814       !!n. n ~= 0 ==> coeff P p n ~= \<zero>; p \<in> carrier P |] ==> deg R p = n"
   815 by (fast intro: le_anti_sym deg_aboveI deg_belowI)
   816 
   817 text {* Degree and polynomial operations *}
   818 
   819 lemma deg_add [simp]:
   820   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   821   shows "deg R (p \<oplus>\<^bsub>P\<^esub> q) <= max (deg R p) (deg R q)"
   822 proof (cases "deg R p <= deg R q")
   823   case True show ?thesis
   824     by (rule deg_aboveI) (simp_all add: True R deg_aboveD)
   825 next
   826   case False show ?thesis
   827     by (rule deg_aboveI) (simp_all add: False R deg_aboveD)
   828 qed
   829 
   830 lemma deg_monom_le:
   831   "a \<in> carrier R ==> deg R (monom P a n) <= n"
   832   by (intro deg_aboveI) simp_all
   833 
   834 lemma deg_monom [simp]:
   835   "[| a ~= \<zero>; a \<in> carrier R |] ==> deg R (monom P a n) = n"
   836   by (fastsimp intro: le_anti_sym deg_aboveI deg_belowI)
   837 
   838 lemma deg_const [simp]:
   839   assumes R: "a \<in> carrier R" shows "deg R (monom P a 0) = 0"
   840 proof (rule le_anti_sym)
   841   show "deg R (monom P a 0) <= 0" by (rule deg_aboveI) (simp_all add: R)
   842 next
   843   show "0 <= deg R (monom P a 0)" by (rule deg_belowI) (simp_all add: R)
   844 qed
   845 
   846 lemma deg_zero [simp]:
   847   "deg R \<zero>\<^bsub>P\<^esub> = 0"
   848 proof (rule le_anti_sym)
   849   show "deg R \<zero>\<^bsub>P\<^esub> <= 0" by (rule deg_aboveI) simp_all
   850 next
   851   show "0 <= deg R \<zero>\<^bsub>P\<^esub>" by (rule deg_belowI) simp_all
   852 qed
   853 
   854 lemma deg_one [simp]:
   855   "deg R \<one>\<^bsub>P\<^esub> = 0"
   856 proof (rule le_anti_sym)
   857   show "deg R \<one>\<^bsub>P\<^esub> <= 0" by (rule deg_aboveI) simp_all
   858 next
   859   show "0 <= deg R \<one>\<^bsub>P\<^esub>" by (rule deg_belowI) simp_all
   860 qed
   861 
   862 lemma deg_uminus [simp]:
   863   assumes R: "p \<in> carrier P" shows "deg R (\<ominus>\<^bsub>P\<^esub> p) = deg R p"
   864 proof (rule le_anti_sym)
   865   show "deg R (\<ominus>\<^bsub>P\<^esub> p) <= deg R p" by (simp add: deg_aboveI deg_aboveD R)
   866 next
   867   show "deg R p <= deg R (\<ominus>\<^bsub>P\<^esub> p)"
   868     by (simp add: deg_belowI lcoeff_nonzero_deg
   869       inj_on_iff [OF R.a_inv_inj, of _ "\<zero>", simplified] R)
   870 qed
   871 
   872 text{*The following lemma is later \emph{overwritten} by the most
   873   specific one for domains, @{text deg_smult}.*}
   874 
   875 lemma deg_smult_ring [simp]:
   876   "[| a \<in> carrier R; p \<in> carrier P |] ==>
   877   deg R (a \<odot>\<^bsub>P\<^esub> p) <= (if a = \<zero> then 0 else deg R p)"
   878   by (cases "a = \<zero>") (simp add: deg_aboveI deg_aboveD)+
   879 
   880 end
   881 
   882 context UP_domain
   883 begin
   884 
   885 lemma deg_smult [simp]:
   886   assumes R: "a \<in> carrier R" "p \<in> carrier P"
   887   shows "deg R (a \<odot>\<^bsub>P\<^esub> p) = (if a = \<zero> then 0 else deg R p)"
   888 proof (rule le_anti_sym)
   889   show "deg R (a \<odot>\<^bsub>P\<^esub> p) <= (if a = \<zero> then 0 else deg R p)"
   890     using R by (rule deg_smult_ring)
   891 next
   892   show "(if a = \<zero> then 0 else deg R p) <= deg R (a \<odot>\<^bsub>P\<^esub> p)"
   893   proof (cases "a = \<zero>")
   894   qed (simp, simp add: deg_belowI lcoeff_nonzero_deg integral_iff R)
   895 qed
   896 
   897 end
   898 
   899 context UP_ring
   900 begin
   901 
   902 lemma deg_mult_ring:
   903   assumes R: "p \<in> carrier P" "q \<in> carrier P"
   904   shows "deg R (p \<otimes>\<^bsub>P\<^esub> q) <= deg R p + deg R q"
   905 proof (rule deg_aboveI)
   906   fix m
   907   assume boundm: "deg R p + deg R q < m"
   908   {
   909     fix k i
   910     assume boundk: "deg R p + deg R q < k"
   911     then have "coeff P p i \<otimes> coeff P q (k - i) = \<zero>"
   912     proof (cases "deg R p < i")
   913       case True then show ?thesis by (simp add: deg_aboveD R)
   914     next
   915       case False with boundk have "deg R q < k - i" by arith
   916       then show ?thesis by (simp add: deg_aboveD R)
   917     qed
   918   }
   919   with boundm R show "coeff P (p \<otimes>\<^bsub>P\<^esub> q) m = \<zero>" by simp
   920 qed (simp add: R)
   921 
   922 end
   923 
   924 context UP_domain
   925 begin
   926 
   927 lemma deg_mult [simp]:
   928   "[| p ~= \<zero>\<^bsub>P\<^esub>; q ~= \<zero>\<^bsub>P\<^esub>; p \<in> carrier P; q \<in> carrier P |] ==>
   929   deg R (p \<otimes>\<^bsub>P\<^esub> q) = deg R p + deg R q"
   930 proof (rule le_anti_sym)
   931   assume "p \<in> carrier P" " q \<in> carrier P"
   932   then show "deg R (p \<otimes>\<^bsub>P\<^esub> q) <= deg R p + deg R q" by (rule deg_mult_ring)
   933 next
   934   let ?s = "(%i. coeff P p i \<otimes> coeff P q (deg R p + deg R q - i))"
   935   assume R: "p \<in> carrier P" "q \<in> carrier P" and nz: "p ~= \<zero>\<^bsub>P\<^esub>" "q ~= \<zero>\<^bsub>P\<^esub>"
   936   have less_add_diff: "!!(k::nat) n m. k < n ==> m < n + m - k" by arith
   937   show "deg R p + deg R q <= deg R (p \<otimes>\<^bsub>P\<^esub> q)"
   938   proof (rule deg_belowI, simp add: R)
   939     have "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i)
   940       = (\<Oplus>i \<in> {..< deg R p} \<union> {deg R p .. deg R p + deg R q}. ?s i)"
   941       by (simp only: ivl_disj_un_one)
   942     also have "... = (\<Oplus>i \<in> {deg R p .. deg R p + deg R q}. ?s i)"
   943       by (simp cong: R.finsum_cong add: R.finsum_Un_disjoint ivl_disj_int_one
   944         deg_aboveD less_add_diff R Pi_def)
   945     also have "...= (\<Oplus>i \<in> {deg R p} \<union> {deg R p <.. deg R p + deg R q}. ?s i)"
   946       by (simp only: ivl_disj_un_singleton)
   947     also have "... = coeff P p (deg R p) \<otimes> coeff P q (deg R q)"
   948       by (simp cong: R.finsum_cong
   949 	add: ivl_disj_int_singleton deg_aboveD R Pi_def)
   950     finally have "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i)
   951       = coeff P p (deg R p) \<otimes> coeff P q (deg R q)" .
   952     with nz show "(\<Oplus>i \<in> {.. deg R p + deg R q}. ?s i) ~= \<zero>"
   953       by (simp add: integral_iff lcoeff_nonzero R)
   954   qed (simp add: R)
   955 qed
   956 
   957 end
   958 
   959 text{*The following lemmas also can be lifted to @{term UP_ring}.*}
   960 
   961 context UP_ring
   962 begin
   963 
   964 lemma coeff_finsum:
   965   assumes fin: "finite A"
   966   shows "p \<in> A -> carrier P ==>
   967     coeff P (finsum P p A) k = (\<Oplus>i \<in> A. coeff P (p i) k)"
   968   using fin by induct (auto simp: Pi_def)
   969 
   970 lemma up_repr:
   971   assumes R: "p \<in> carrier P"
   972   shows "(\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. monom P (coeff P p i) i) = p"
   973 proof (rule up_eqI)
   974   let ?s = "(%i. monom P (coeff P p i) i)"
   975   fix k
   976   from R have RR: "!!i. (if i = k then coeff P p i else \<zero>) \<in> carrier R"
   977     by simp
   978   show "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k = coeff P p k"
   979   proof (cases "k <= deg R p")
   980     case True
   981     hence "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k =
   982           coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..k} \<union> {k<..deg R p}. ?s i) k"
   983       by (simp only: ivl_disj_un_one)
   984     also from True
   985     have "... = coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..k}. ?s i) k"
   986       by (simp cong: R.finsum_cong add: R.finsum_Un_disjoint
   987         ivl_disj_int_one order_less_imp_not_eq2 coeff_finsum R RR Pi_def)
   988     also
   989     have "... = coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..<k} \<union> {k}. ?s i) k"
   990       by (simp only: ivl_disj_un_singleton)
   991     also have "... = coeff P p k"
   992       by (simp cong: R.finsum_cong
   993 	add: ivl_disj_int_singleton coeff_finsum deg_aboveD R RR Pi_def)
   994     finally show ?thesis .
   995   next
   996     case False
   997     hence "coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..deg R p}. ?s i) k =
   998           coeff P (\<Oplus>\<^bsub>P\<^esub> i \<in> {..<deg R p} \<union> {deg R p}. ?s i) k"
   999       by (simp only: ivl_disj_un_singleton)
  1000     also from False have "... = coeff P p k"
  1001       by (simp cong: R.finsum_cong
  1002 	add: ivl_disj_int_singleton coeff_finsum deg_aboveD R Pi_def)
  1003     finally show ?thesis .
  1004   qed
  1005 qed (simp_all add: R Pi_def)
  1006 
  1007 lemma up_repr_le:
  1008   "[| deg R p <= n; p \<in> carrier P |] ==>
  1009   (\<Oplus>\<^bsub>P\<^esub> i \<in> {..n}. monom P (coeff P p i) i) = p"
  1010 proof -
  1011   let ?s = "(%i. monom P (coeff P p i) i)"
  1012   assume R: "p \<in> carrier P" and "deg R p <= n"
  1013   then have "finsum P ?s {..n} = finsum P ?s ({..deg R p} \<union> {deg R p<..n})"
  1014     by (simp only: ivl_disj_un_one)
  1015   also have "... = finsum P ?s {..deg R p}"
  1016     by (simp cong: P.finsum_cong add: P.finsum_Un_disjoint ivl_disj_int_one
  1017       deg_aboveD R Pi_def)
  1018   also have "... = p" using R by (rule up_repr)
  1019   finally show ?thesis .
  1020 qed
  1021 
  1022 end
  1023 
  1024 
  1025 subsection {* Polynomials over Integral Domains *}
  1026 
  1027 lemma domainI:
  1028   assumes cring: "cring R"
  1029     and one_not_zero: "one R ~= zero R"
  1030     and integral: "!!a b. [| mult R a b = zero R; a \<in> carrier R;
  1031       b \<in> carrier R |] ==> a = zero R | b = zero R"
  1032   shows "domain R"
  1033   by (auto intro!: domain.intro domain_axioms.intro cring.axioms assms
  1034     del: disjCI)
  1035 
  1036 context UP_domain
  1037 begin
  1038 
  1039 lemma UP_one_not_zero:
  1040   "\<one>\<^bsub>P\<^esub> ~= \<zero>\<^bsub>P\<^esub>"
  1041 proof
  1042   assume "\<one>\<^bsub>P\<^esub> = \<zero>\<^bsub>P\<^esub>"
  1043   hence "coeff P \<one>\<^bsub>P\<^esub> 0 = (coeff P \<zero>\<^bsub>P\<^esub> 0)" by simp
  1044   hence "\<one> = \<zero>" by simp
  1045   with R.one_not_zero show "False" by contradiction
  1046 qed
  1047 
  1048 lemma UP_integral:
  1049   "[| p \<otimes>\<^bsub>P\<^esub> q = \<zero>\<^bsub>P\<^esub>; p \<in> carrier P; q \<in> carrier P |] ==> p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>"
  1050 proof -
  1051   fix p q
  1052   assume pq: "p \<otimes>\<^bsub>P\<^esub> q = \<zero>\<^bsub>P\<^esub>" and R: "p \<in> carrier P" "q \<in> carrier P"
  1053   show "p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>"
  1054   proof (rule classical)
  1055     assume c: "~ (p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>)"
  1056     with R have "deg R p + deg R q = deg R (p \<otimes>\<^bsub>P\<^esub> q)" by simp
  1057     also from pq have "... = 0" by simp
  1058     finally have "deg R p + deg R q = 0" .
  1059     then have f1: "deg R p = 0 & deg R q = 0" by simp
  1060     from f1 R have "p = (\<Oplus>\<^bsub>P\<^esub> i \<in> {..0}. monom P (coeff P p i) i)"
  1061       by (simp only: up_repr_le)
  1062     also from R have "... = monom P (coeff P p 0) 0" by simp
  1063     finally have p: "p = monom P (coeff P p 0) 0" .
  1064     from f1 R have "q = (\<Oplus>\<^bsub>P\<^esub> i \<in> {..0}. monom P (coeff P q i) i)"
  1065       by (simp only: up_repr_le)
  1066     also from R have "... = monom P (coeff P q 0) 0" by simp
  1067     finally have q: "q = monom P (coeff P q 0) 0" .
  1068     from R have "coeff P p 0 \<otimes> coeff P q 0 = coeff P (p \<otimes>\<^bsub>P\<^esub> q) 0" by simp
  1069     also from pq have "... = \<zero>" by simp
  1070     finally have "coeff P p 0 \<otimes> coeff P q 0 = \<zero>" .
  1071     with R have "coeff P p 0 = \<zero> | coeff P q 0 = \<zero>"
  1072       by (simp add: R.integral_iff)
  1073     with p q show "p = \<zero>\<^bsub>P\<^esub> | q = \<zero>\<^bsub>P\<^esub>" by fastsimp
  1074   qed
  1075 qed
  1076 
  1077 theorem UP_domain:
  1078   "domain P"
  1079   by (auto intro!: domainI UP_cring UP_one_not_zero UP_integral del: disjCI)
  1080 
  1081 end
  1082 
  1083 text {*
  1084   Interpretation of theorems from @{term domain}.
  1085 *}
  1086 
  1087 sublocale UP_domain < "domain" P
  1088   by intro_locales (rule domain.axioms UP_domain)+
  1089 
  1090 
  1091 subsection {* The Evaluation Homomorphism and Universal Property*}
  1092 
  1093 (* alternative congruence rule (possibly more efficient)
  1094 lemma (in abelian_monoid) finsum_cong2:
  1095   "[| !!i. i \<in> A ==> f i \<in> carrier G = True; A = B;
  1096   !!i. i \<in> B ==> f i = g i |] ==> finsum G f A = finsum G g B"
  1097   sorry*)
  1098 
  1099 lemma (in abelian_monoid) boundD_carrier:
  1100   "[| bound \<zero> n f; n < m |] ==> f m \<in> carrier G"
  1101   by auto
  1102 
  1103 context ring
  1104 begin
  1105 
  1106 theorem diagonal_sum:
  1107   "[| f \<in> {..n + m::nat} -> carrier R; g \<in> {..n + m} -> carrier R |] ==>
  1108   (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1109   (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1110 proof -
  1111   assume Rf: "f \<in> {..n + m} -> carrier R" and Rg: "g \<in> {..n + m} -> carrier R"
  1112   {
  1113     fix j
  1114     have "j <= n + m ==>
  1115       (\<Oplus>k \<in> {..j}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1116       (\<Oplus>k \<in> {..j}. \<Oplus>i \<in> {..j - k}. f k \<otimes> g i)"
  1117     proof (induct j)
  1118       case 0 from Rf Rg show ?case by (simp add: Pi_def)
  1119     next
  1120       case (Suc j)
  1121       have R6: "!!i k. [| k <= j; i <= Suc j - k |] ==> g i \<in> carrier R"
  1122         using Suc by (auto intro!: funcset_mem [OF Rg])
  1123       have R8: "!!i k. [| k <= Suc j; i <= k |] ==> g (k - i) \<in> carrier R"
  1124         using Suc by (auto intro!: funcset_mem [OF Rg])
  1125       have R9: "!!i k. [| k <= Suc j |] ==> f k \<in> carrier R"
  1126         using Suc by (auto intro!: funcset_mem [OF Rf])
  1127       have R10: "!!i k. [| k <= Suc j; i <= Suc j - k |] ==> g i \<in> carrier R"
  1128         using Suc by (auto intro!: funcset_mem [OF Rg])
  1129       have R11: "g 0 \<in> carrier R"
  1130         using Suc by (auto intro!: funcset_mem [OF Rg])
  1131       from Suc show ?case
  1132         by (simp cong: finsum_cong add: Suc_diff_le a_ac
  1133           Pi_def R6 R8 R9 R10 R11)
  1134     qed
  1135   }
  1136   then show ?thesis by fast
  1137 qed
  1138 
  1139 theorem cauchy_product:
  1140   assumes bf: "bound \<zero> n f" and bg: "bound \<zero> m g"
  1141     and Rf: "f \<in> {..n} -> carrier R" and Rg: "g \<in> {..m} -> carrier R"
  1142   shows "(\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1143     (\<Oplus>i \<in> {..n}. f i) \<otimes> (\<Oplus>i \<in> {..m}. g i)"      (* State reverse direction? *)
  1144 proof -
  1145   have f: "!!x. f x \<in> carrier R"
  1146   proof -
  1147     fix x
  1148     show "f x \<in> carrier R"
  1149       using Rf bf boundD_carrier by (cases "x <= n") (auto simp: Pi_def)
  1150   qed
  1151   have g: "!!x. g x \<in> carrier R"
  1152   proof -
  1153     fix x
  1154     show "g x \<in> carrier R"
  1155       using Rg bg boundD_carrier by (cases "x <= m") (auto simp: Pi_def)
  1156   qed
  1157   from f g have "(\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..k}. f i \<otimes> g (k - i)) =
  1158       (\<Oplus>k \<in> {..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1159     by (simp add: diagonal_sum Pi_def)
  1160   also have "... = (\<Oplus>k \<in> {..n} \<union> {n<..n + m}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1161     by (simp only: ivl_disj_un_one)
  1162   also from f g have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..n + m - k}. f k \<otimes> g i)"
  1163     by (simp cong: finsum_cong
  1164       add: bound.bound [OF bf] finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1165   also from f g
  1166   have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..m} \<union> {m<..n + m - k}. f k \<otimes> g i)"
  1167     by (simp cong: finsum_cong add: ivl_disj_un_one le_add_diff Pi_def)
  1168   also from f g have "... = (\<Oplus>k \<in> {..n}. \<Oplus>i \<in> {..m}. f k \<otimes> g i)"
  1169     by (simp cong: finsum_cong
  1170       add: bound.bound [OF bg] finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1171   also from f g have "... = (\<Oplus>i \<in> {..n}. f i) \<otimes> (\<Oplus>i \<in> {..m}. g i)"
  1172     by (simp add: finsum_ldistr diagonal_sum Pi_def,
  1173       simp cong: finsum_cong add: finsum_rdistr Pi_def)
  1174   finally show ?thesis .
  1175 qed
  1176 
  1177 end
  1178 
  1179 lemma (in UP_ring) const_ring_hom:
  1180   "(%a. monom P a 0) \<in> ring_hom R P"
  1181   by (auto intro!: ring_hom_memI intro: up_eqI simp: monom_mult_is_smult)
  1182 
  1183 definition
  1184   eval :: "[('a, 'm) ring_scheme, ('b, 'n) ring_scheme,
  1185            'a => 'b, 'b, nat => 'a] => 'b"
  1186   where "eval R S phi s == \<lambda>p \<in> carrier (UP R).
  1187     \<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R p}. phi (coeff (UP R) p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i"
  1188 
  1189 context UP
  1190 begin
  1191 
  1192 lemma eval_on_carrier:
  1193   fixes S (structure)
  1194   shows "p \<in> carrier P ==>
  1195   eval R S phi s p = (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. phi (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1196   by (unfold eval_def, fold P_def) simp
  1197 
  1198 lemma eval_extensional:
  1199   "eval R S phi p \<in> extensional (carrier P)"
  1200   by (unfold eval_def, fold P_def) simp
  1201 
  1202 end
  1203 
  1204 text {* The universal property of the polynomial ring *}
  1205 
  1206 locale UP_pre_univ_prop = ring_hom_cring + UP_cring
  1207 
  1208 (* FIXME print_locale ring_hom_cring fails *)
  1209 
  1210 locale UP_univ_prop = UP_pre_univ_prop +
  1211   fixes s and Eval
  1212   assumes indet_img_carrier [simp, intro]: "s \<in> carrier S"
  1213   defines Eval_def: "Eval == eval R S h s"
  1214 
  1215 text{*JE: I have moved the following lemma from Ring.thy and lifted then to the locale @{term ring_hom_ring} from @{term ring_hom_cring}.*}
  1216 text{*JE: I was considering using it in @{text eval_ring_hom}, but that property does not hold for non commutative rings, so 
  1217   maybe it is not that necessary.*}
  1218 
  1219 lemma (in ring_hom_ring) hom_finsum [simp]:
  1220   "[| finite A; f \<in> A -> carrier R |] ==>
  1221   h (finsum R f A) = finsum S (h o f) A"
  1222 proof (induct set: finite)
  1223   case empty then show ?case by simp
  1224 next
  1225   case insert then show ?case by (simp add: Pi_def)
  1226 qed
  1227 
  1228 context UP_pre_univ_prop
  1229 begin
  1230 
  1231 theorem eval_ring_hom:
  1232   assumes S: "s \<in> carrier S"
  1233   shows "eval R S h s \<in> ring_hom P S"
  1234 proof (rule ring_hom_memI)
  1235   fix p
  1236   assume R: "p \<in> carrier P"
  1237   then show "eval R S h s p \<in> carrier S"
  1238     by (simp only: eval_on_carrier) (simp add: S Pi_def)
  1239 next
  1240   fix p q
  1241   assume R: "p \<in> carrier P" "q \<in> carrier P"
  1242   then show "eval R S h s (p \<oplus>\<^bsub>P\<^esub> q) = eval R S h s p \<oplus>\<^bsub>S\<^esub> eval R S h s q"
  1243   proof (simp only: eval_on_carrier P.a_closed)
  1244     from S R have
  1245       "(\<Oplus>\<^bsub>S \<^esub>i\<in>{..deg R (p \<oplus>\<^bsub>P\<^esub> q)}. h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1246       (\<Oplus>\<^bsub>S \<^esub>i\<in>{..deg R (p \<oplus>\<^bsub>P\<^esub> q)} \<union> {deg R (p \<oplus>\<^bsub>P\<^esub> q)<..max (deg R p) (deg R q)}.
  1247         h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1248       by (simp cong: S.finsum_cong
  1249         add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def del: coeff_add)
  1250     also from R have "... =
  1251         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..max (deg R p) (deg R q)}.
  1252           h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1253       by (simp add: ivl_disj_un_one)
  1254     also from R S have "... =
  1255       (\<Oplus>\<^bsub>S\<^esub>i\<in>{..max (deg R p) (deg R q)}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1256       (\<Oplus>\<^bsub>S\<^esub>i\<in>{..max (deg R p) (deg R q)}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1257       by (simp cong: S.finsum_cong
  1258         add: S.l_distr deg_aboveD ivl_disj_int_one Pi_def)
  1259     also have "... =
  1260         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p} \<union> {deg R p<..max (deg R p) (deg R q)}.
  1261           h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1262         (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q} \<union> {deg R q<..max (deg R p) (deg R q)}.
  1263           h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1264       by (simp only: ivl_disj_un_one le_maxI1 le_maxI2)
  1265     also from R S have "... =
  1266       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1267       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1268       by (simp cong: S.finsum_cong
  1269         add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1270     finally show
  1271       "(\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R (p \<oplus>\<^bsub>P\<^esub> q)}. h (coeff P (p \<oplus>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1272       (\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<oplus>\<^bsub>S\<^esub>
  1273       (\<Oplus>\<^bsub>S\<^esub>i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)" .
  1274   qed
  1275 next
  1276   show "eval R S h s \<one>\<^bsub>P\<^esub> = \<one>\<^bsub>S\<^esub>"
  1277     by (simp only: eval_on_carrier UP_one_closed) simp
  1278 next
  1279   fix p q
  1280   assume R: "p \<in> carrier P" "q \<in> carrier P"
  1281   then show "eval R S h s (p \<otimes>\<^bsub>P\<^esub> q) = eval R S h s p \<otimes>\<^bsub>S\<^esub> eval R S h s q"
  1282   proof (simp only: eval_on_carrier UP_mult_closed)
  1283     from R S have
  1284       "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1285       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)} \<union> {deg R (p \<otimes>\<^bsub>P\<^esub> q)<..deg R p + deg R q}.
  1286         h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1287       by (simp cong: S.finsum_cong
  1288         add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def
  1289         del: coeff_mult)
  1290     also from R have "... =
  1291       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p + deg R q}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1292       by (simp only: ivl_disj_un_one deg_mult_ring)
  1293     also from R S have "... =
  1294       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p + deg R q}.
  1295          \<Oplus>\<^bsub>S\<^esub> k \<in> {..i}.
  1296            h (coeff P p k) \<otimes>\<^bsub>S\<^esub> h (coeff P q (i - k)) \<otimes>\<^bsub>S\<^esub>
  1297            (s (^)\<^bsub>S\<^esub> k \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> (i - k)))"
  1298       by (simp cong: S.finsum_cong add: S.nat_pow_mult Pi_def
  1299         S.m_ac S.finsum_rdistr)
  1300     also from R S have "... =
  1301       (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<otimes>\<^bsub>S\<^esub>
  1302       (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1303       by (simp add: S.cauchy_product [THEN sym] bound.intro deg_aboveD S.m_ac
  1304         Pi_def)
  1305     finally show
  1306       "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (p \<otimes>\<^bsub>P\<^esub> q)}. h (coeff P (p \<otimes>\<^bsub>P\<^esub> q) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1307       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R p}. h (coeff P p i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) \<otimes>\<^bsub>S\<^esub>
  1308       (\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R q}. h (coeff P q i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)" .
  1309   qed
  1310 qed
  1311 
  1312 text {*
  1313   The following lemma could be proved in @{text UP_cring} with the additional
  1314   assumption that @{text h} is closed. *}
  1315 
  1316 lemma (in UP_pre_univ_prop) eval_const:
  1317   "[| s \<in> carrier S; r \<in> carrier R |] ==> eval R S h s (monom P r 0) = h r"
  1318   by (simp only: eval_on_carrier monom_closed) simp
  1319 
  1320 text {* Further properties of the evaluation homomorphism. *}
  1321 
  1322 text {* The following proof is complicated by the fact that in arbitrary
  1323   rings one might have @{term "one R = zero R"}. *}
  1324 
  1325 (* TODO: simplify by cases "one R = zero R" *)
  1326 
  1327 lemma (in UP_pre_univ_prop) eval_monom1:
  1328   assumes S: "s \<in> carrier S"
  1329   shows "eval R S h s (monom P \<one> 1) = s"
  1330 proof (simp only: eval_on_carrier monom_closed R.one_closed)
  1331    from S have
  1332     "(\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R (monom P \<one> 1)}. h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) =
  1333     (\<Oplus>\<^bsub>S\<^esub> i\<in>{..deg R (monom P \<one> 1)} \<union> {deg R (monom P \<one> 1)<..1}.
  1334       h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1335     by (simp cong: S.finsum_cong del: coeff_monom
  1336       add: deg_aboveD S.finsum_Un_disjoint ivl_disj_int_one Pi_def)
  1337   also have "... =
  1338     (\<Oplus>\<^bsub>S\<^esub> i \<in> {..1}. h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i)"
  1339     by (simp only: ivl_disj_un_one deg_monom_le R.one_closed)
  1340   also have "... = s"
  1341   proof (cases "s = \<zero>\<^bsub>S\<^esub>")
  1342     case True then show ?thesis by (simp add: Pi_def)
  1343   next
  1344     case False then show ?thesis by (simp add: S Pi_def)
  1345   qed
  1346   finally show "(\<Oplus>\<^bsub>S\<^esub> i \<in> {..deg R (monom P \<one> 1)}.
  1347     h (coeff P (monom P \<one> 1) i) \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> i) = s" .
  1348 qed
  1349 
  1350 end
  1351 
  1352 text {* Interpretation of ring homomorphism lemmas. *}
  1353 
  1354 sublocale UP_univ_prop < ring_hom_cring P S Eval
  1355   apply (unfold Eval_def)
  1356   apply intro_locales
  1357   apply (rule ring_hom_cring.axioms)
  1358   apply (rule ring_hom_cring.intro)
  1359   apply unfold_locales
  1360   apply (rule eval_ring_hom)
  1361   apply rule
  1362   done
  1363 
  1364 lemma (in UP_cring) monom_pow:
  1365   assumes R: "a \<in> carrier R"
  1366   shows "(monom P a n) (^)\<^bsub>P\<^esub> m = monom P (a (^) m) (n * m)"
  1367 proof (induct m)
  1368   case 0 from R show ?case by simp
  1369 next
  1370   case Suc with R show ?case
  1371     by (simp del: monom_mult add: monom_mult [THEN sym] add_commute)
  1372 qed
  1373 
  1374 lemma (in ring_hom_cring) hom_pow [simp]:
  1375   "x \<in> carrier R ==> h (x (^) n) = h x (^)\<^bsub>S\<^esub> (n::nat)"
  1376   by (induct n) simp_all
  1377 
  1378 lemma (in UP_univ_prop) Eval_monom:
  1379   "r \<in> carrier R ==> Eval (monom P r n) = h r \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> n"
  1380 proof -
  1381   assume R: "r \<in> carrier R"
  1382   from R have "Eval (monom P r n) = Eval (monom P r 0 \<otimes>\<^bsub>P\<^esub> (monom P \<one> 1) (^)\<^bsub>P\<^esub> n)"
  1383     by (simp del: monom_mult add: monom_mult [THEN sym] monom_pow)
  1384   also
  1385   from R eval_monom1 [where s = s, folded Eval_def]
  1386   have "... = h r \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> n"
  1387     by (simp add: eval_const [where s = s, folded Eval_def])
  1388   finally show ?thesis .
  1389 qed
  1390 
  1391 lemma (in UP_pre_univ_prop) eval_monom:
  1392   assumes R: "r \<in> carrier R" and S: "s \<in> carrier S"
  1393   shows "eval R S h s (monom P r n) = h r \<otimes>\<^bsub>S\<^esub> s (^)\<^bsub>S\<^esub> n"
  1394 proof -
  1395   interpret UP_univ_prop R S h P s "eval R S h s"
  1396     using UP_pre_univ_prop_axioms P_def R S
  1397     by (auto intro: UP_univ_prop.intro UP_univ_prop_axioms.intro)
  1398   from R
  1399   show ?thesis by (rule Eval_monom)
  1400 qed
  1401 
  1402 lemma (in UP_univ_prop) Eval_smult:
  1403   "[| r \<in> carrier R; p \<in> carrier P |] ==> Eval (r \<odot>\<^bsub>P\<^esub> p) = h r \<otimes>\<^bsub>S\<^esub> Eval p"
  1404 proof -
  1405   assume R: "r \<in> carrier R" and P: "p \<in> carrier P"
  1406   then show ?thesis
  1407     by (simp add: monom_mult_is_smult [THEN sym]
  1408       eval_const [where s = s, folded Eval_def])
  1409 qed
  1410 
  1411 lemma ring_hom_cringI:
  1412   assumes "cring R"
  1413     and "cring S"
  1414     and "h \<in> ring_hom R S"
  1415   shows "ring_hom_cring R S h"
  1416   by (fast intro: ring_hom_cring.intro ring_hom_cring_axioms.intro
  1417     cring.axioms assms)
  1418 
  1419 context UP_pre_univ_prop
  1420 begin
  1421 
  1422 lemma UP_hom_unique:
  1423   assumes "ring_hom_cring P S Phi"
  1424   assumes Phi: "Phi (monom P \<one> (Suc 0)) = s"
  1425       "!!r. r \<in> carrier R ==> Phi (monom P r 0) = h r"
  1426   assumes "ring_hom_cring P S Psi"
  1427   assumes Psi: "Psi (monom P \<one> (Suc 0)) = s"
  1428       "!!r. r \<in> carrier R ==> Psi (monom P r 0) = h r"
  1429     and P: "p \<in> carrier P" and S: "s \<in> carrier S"
  1430   shows "Phi p = Psi p"
  1431 proof -
  1432   interpret ring_hom_cring P S Phi by fact
  1433   interpret ring_hom_cring P S Psi by fact
  1434   have "Phi p =
  1435       Phi (\<Oplus>\<^bsub>P \<^esub>i \<in> {..deg R p}. monom P (coeff P p i) 0 \<otimes>\<^bsub>P\<^esub> monom P \<one> 1 (^)\<^bsub>P\<^esub> i)"
  1436     by (simp add: up_repr P monom_mult [THEN sym] monom_pow del: monom_mult)
  1437   also
  1438   have "... =
  1439       Psi (\<Oplus>\<^bsub>P \<^esub>i\<in>{..deg R p}. monom P (coeff P p i) 0 \<otimes>\<^bsub>P\<^esub> monom P \<one> 1 (^)\<^bsub>P\<^esub> i)"
  1440     by (simp add: Phi Psi P Pi_def comp_def)
  1441   also have "... = Psi p"
  1442     by (simp add: up_repr P monom_mult [THEN sym] monom_pow del: monom_mult)
  1443   finally show ?thesis .
  1444 qed
  1445 
  1446 lemma ring_homD:
  1447   assumes Phi: "Phi \<in> ring_hom P S"
  1448   shows "ring_hom_cring P S Phi"
  1449 proof (rule ring_hom_cring.intro)
  1450   show "ring_hom_cring_axioms P S Phi"
  1451   by (rule ring_hom_cring_axioms.intro) (rule Phi)
  1452 qed unfold_locales
  1453 
  1454 theorem UP_universal_property:
  1455   assumes S: "s \<in> carrier S"
  1456   shows "EX! Phi. Phi \<in> ring_hom P S \<inter> extensional (carrier P) &
  1457     Phi (monom P \<one> 1) = s &
  1458     (ALL r : carrier R. Phi (monom P r 0) = h r)"
  1459   using S eval_monom1
  1460   apply (auto intro: eval_ring_hom eval_const eval_extensional)
  1461   apply (rule extensionalityI)
  1462   apply (auto intro: UP_hom_unique ring_homD)
  1463   done
  1464 
  1465 end
  1466 
  1467 text{*JE: The following lemma was added by me; it might be even lifted to a simpler locale*}
  1468 
  1469 context monoid
  1470 begin
  1471 
  1472 lemma nat_pow_eone[simp]: assumes x_in_G: "x \<in> carrier G" shows "x (^) (1::nat) = x"
  1473   using nat_pow_Suc [of x 0] unfolding nat_pow_0 [of x] unfolding l_one [OF x_in_G] by simp
  1474 
  1475 end
  1476 
  1477 context UP_ring
  1478 begin
  1479 
  1480 abbreviation lcoeff :: "(nat =>'a) => 'a" where "lcoeff p == coeff P p (deg R p)"
  1481 
  1482 lemma lcoeff_nonzero2: assumes p_in_R: "p \<in> carrier P" and p_not_zero: "p \<noteq> \<zero>\<^bsub>P\<^esub>" shows "lcoeff p \<noteq> \<zero>" 
  1483   using lcoeff_nonzero [OF p_not_zero p_in_R] .
  1484 
  1485 subsection{*The long division algorithm: some previous facts.*}
  1486 
  1487 lemma coeff_minus [simp]:
  1488   assumes p: "p \<in> carrier P" and q: "q \<in> carrier P" shows "coeff P (p \<ominus>\<^bsub>P\<^esub> q) n = coeff P p n \<ominus> coeff P q n" 
  1489   unfolding a_minus_def [OF p q] unfolding coeff_add [OF p a_inv_closed [OF q]] unfolding coeff_a_inv [OF q]
  1490   using coeff_closed [OF p, of n] using coeff_closed [OF q, of n] by algebra
  1491 
  1492 lemma lcoeff_closed [simp]: assumes p: "p \<in> carrier P" shows "lcoeff p \<in> carrier R"
  1493   using coeff_closed [OF p, of "deg R p"] by simp
  1494 
  1495 lemma deg_smult_decr: assumes a_in_R: "a \<in> carrier R" and f_in_P: "f \<in> carrier P" shows "deg R (a \<odot>\<^bsub>P\<^esub> f) \<le> deg R f"
  1496   using deg_smult_ring [OF a_in_R f_in_P] by (cases "a = \<zero>", auto)
  1497 
  1498 lemma coeff_monom_mult: assumes R: "c \<in> carrier R" and P: "p \<in> carrier P" 
  1499   shows "coeff P (monom P c n \<otimes>\<^bsub>P\<^esub> p) (m + n) = c \<otimes> (coeff P p m)"
  1500 proof -
  1501   have "coeff P (monom P c n \<otimes>\<^bsub>P\<^esub> p) (m + n) = (\<Oplus>i\<in>{..m + n}. (if n = i then c else \<zero>) \<otimes> coeff P p (m + n - i))"
  1502     unfolding coeff_mult [OF monom_closed [OF R, of n] P, of "m + n"] unfolding coeff_monom [OF R, of n] by simp
  1503   also have "(\<Oplus>i\<in>{..m + n}. (if n = i then c else \<zero>) \<otimes> coeff P p (m + n - i)) = 
  1504     (\<Oplus>i\<in>{..m + n}. (if n = i then c \<otimes> coeff P p (m + n - i) else \<zero>))"
  1505     using  R.finsum_cong [of "{..m + n}" "{..m + n}" "(\<lambda>i::nat. (if n = i then c else \<zero>) \<otimes> coeff P p (m + n - i))" 
  1506       "(\<lambda>i::nat. (if n = i then c \<otimes> coeff P p (m + n - i) else \<zero>))"]
  1507     using coeff_closed [OF P] unfolding Pi_def simp_implies_def using R by auto
  1508   also have "\<dots> = c \<otimes> coeff P p m" using R.finsum_singleton [of n "{..m + n}" "(\<lambda>i. c \<otimes> coeff P p (m + n - i))"]
  1509     unfolding Pi_def using coeff_closed [OF P] using P R by auto
  1510   finally show ?thesis by simp
  1511 qed
  1512 
  1513 lemma deg_lcoeff_cancel: 
  1514   assumes p_in_P: "p \<in> carrier P" and q_in_P: "q \<in> carrier P" and r_in_P: "r \<in> carrier P" 
  1515   and deg_r_nonzero: "deg R r \<noteq> 0"
  1516   and deg_R_p: "deg R p \<le> deg R r" and deg_R_q: "deg R q \<le> deg R r" 
  1517   and coeff_R_p_eq_q: "coeff P p (deg R r) = \<ominus>\<^bsub>R\<^esub> (coeff P q (deg R r))"
  1518   shows "deg R (p \<oplus>\<^bsub>P\<^esub> q) < deg R r"
  1519 proof -
  1520   have deg_le: "deg R (p \<oplus>\<^bsub>P\<^esub> q) \<le> deg R r"
  1521   proof (rule deg_aboveI)
  1522     fix m
  1523     assume deg_r_le: "deg R r < m"
  1524     show "coeff P (p \<oplus>\<^bsub>P\<^esub> q) m = \<zero>"
  1525     proof -
  1526       have slp: "deg R p < m" and "deg R q < m" using deg_R_p deg_R_q using deg_r_le by auto
  1527       then have max_sl: "max (deg R p) (deg R q) < m" by simp
  1528       then have "deg R (p \<oplus>\<^bsub>P\<^esub> q) < m" using deg_add [OF p_in_P q_in_P] by arith
  1529       with deg_R_p deg_R_q show ?thesis using coeff_add [OF p_in_P q_in_P, of m]
  1530 	using deg_aboveD [of "p \<oplus>\<^bsub>P\<^esub> q" m] using p_in_P q_in_P by simp 
  1531     qed
  1532   qed (simp add: p_in_P q_in_P)
  1533   moreover have deg_ne: "deg R (p \<oplus>\<^bsub>P\<^esub> q) \<noteq> deg R r"
  1534   proof (rule ccontr)
  1535     assume nz: "\<not> deg R (p \<oplus>\<^bsub>P\<^esub> q) \<noteq> deg R r" then have deg_eq: "deg R (p \<oplus>\<^bsub>P\<^esub> q) = deg R r" by simp
  1536     from deg_r_nonzero have r_nonzero: "r \<noteq> \<zero>\<^bsub>P\<^esub>" by (cases "r = \<zero>\<^bsub>P\<^esub>", simp_all)
  1537     have "coeff P (p \<oplus>\<^bsub>P\<^esub> q) (deg R r) = \<zero>\<^bsub>R\<^esub>" using coeff_add [OF p_in_P q_in_P, of "deg R r"] using coeff_R_p_eq_q
  1538       using coeff_closed [OF p_in_P, of "deg R r"] coeff_closed [OF q_in_P, of "deg R r"] by algebra
  1539     with lcoeff_nonzero [OF r_nonzero r_in_P]  and deg_eq show False using lcoeff_nonzero [of "p \<oplus>\<^bsub>P\<^esub> q"] using p_in_P q_in_P
  1540       using deg_r_nonzero by (cases "p \<oplus>\<^bsub>P\<^esub> q \<noteq> \<zero>\<^bsub>P\<^esub>", auto)
  1541   qed
  1542   ultimately show ?thesis by simp
  1543 qed
  1544 
  1545 lemma monom_deg_mult: 
  1546   assumes f_in_P: "f \<in> carrier P" and g_in_P: "g \<in> carrier P" and deg_le: "deg R g \<le> deg R f"
  1547   and a_in_R: "a \<in> carrier R"
  1548   shows "deg R (g \<otimes>\<^bsub>P\<^esub> monom P a (deg R f - deg R g)) \<le> deg R f"
  1549   using deg_mult_ring [OF g_in_P monom_closed [OF a_in_R, of "deg R f - deg R g"]]
  1550   apply (cases "a = \<zero>") using g_in_P apply simp 
  1551   using deg_monom [OF _ a_in_R, of "deg R f - deg R g"] using deg_le by simp
  1552 
  1553 lemma deg_zero_impl_monom:
  1554   assumes f_in_P: "f \<in> carrier P" and deg_f: "deg R f = 0" 
  1555   shows "f = monom P (coeff P f 0) 0"
  1556   apply (rule up_eqI) using coeff_monom [OF coeff_closed [OF f_in_P], of 0 0]
  1557   using f_in_P deg_f using deg_aboveD [of f _] by auto
  1558 
  1559 end
  1560 
  1561 
  1562 subsection {* The long division proof for commutative rings *}
  1563 
  1564 context UP_cring
  1565 begin
  1566 
  1567 lemma exI3: assumes exist: "Pred x y z" 
  1568   shows "\<exists> x y z. Pred x y z"
  1569   using exist by blast
  1570 
  1571 text {* Jacobson's Theorem 2.14 *}
  1572 
  1573 lemma long_div_theorem: 
  1574   assumes g_in_P [simp]: "g \<in> carrier P" and f_in_P [simp]: "f \<in> carrier P"
  1575   and g_not_zero: "g \<noteq> \<zero>\<^bsub>P\<^esub>"
  1576   shows "\<exists> q r (k::nat). (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> (lcoeff g)(^)\<^bsub>R\<^esub>k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (r = \<zero>\<^bsub>P\<^esub> | deg R r < deg R g)"
  1577 proof -
  1578   let ?pred = "(\<lambda> q r (k::nat).
  1579     (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> (lcoeff g)(^)\<^bsub>R\<^esub>k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (r = \<zero>\<^bsub>P\<^esub> | deg R r < deg R g))"
  1580     and ?lg = "lcoeff g"
  1581   show ?thesis
  1582     (*JE: we distinguish some particular cases where the solution is almost direct.*)
  1583   proof (cases "deg R f < deg R g")
  1584     case True     
  1585       (*JE: if the degree of f is smaller than the one of g the solution is straightforward.*)
  1586       (* CB: avoid exI3 *)
  1587       have "?pred \<zero>\<^bsub>P\<^esub> f 0" using True by force
  1588       then show ?thesis by fast
  1589   next
  1590     case False then have deg_g_le_deg_f: "deg R g \<le> deg R f" by simp
  1591     {
  1592       (*JE: we now apply the induction hypothesis with some additional facts required*)
  1593       from f_in_P deg_g_le_deg_f show ?thesis
  1594       proof (induct n \<equiv> "deg R f" arbitrary: "f" rule: nat_less_induct)
  1595 	fix n f
  1596 	assume hypo: "\<forall>m<n. \<forall>x. x \<in> carrier P \<longrightarrow>
  1597           deg R g \<le> deg R x \<longrightarrow> 
  1598 	  m = deg R x \<longrightarrow>
  1599 	  (\<exists>q r (k::nat). q \<in> carrier P \<and> r \<in> carrier P \<and> lcoeff g (^) k \<odot>\<^bsub>P\<^esub> x = g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r & (r = \<zero>\<^bsub>P\<^esub> | deg R r < deg R g))"
  1600 	  and prem: "n = deg R f" and f_in_P [simp]: "f \<in> carrier P"
  1601 	  and deg_g_le_deg_f: "deg R g \<le> deg R f"
  1602 	let ?k = "1::nat" and ?r = "(g \<otimes>\<^bsub>P\<^esub> (monom P (lcoeff f) (deg R f - deg R g))) \<oplus>\<^bsub>P\<^esub> \<ominus>\<^bsub>P\<^esub> (lcoeff g \<odot>\<^bsub>P\<^esub> f)"
  1603 	  and ?q = "monom P (lcoeff f) (deg R f - deg R g)"
  1604 	show "\<exists> q r (k::nat). q \<in> carrier P \<and> r \<in> carrier P \<and> lcoeff g (^) k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r & (r = \<zero>\<^bsub>P\<^esub> | deg R r < deg R g)"
  1605 	proof -
  1606 	  (*JE: we first extablish the existence of a triple satisfying the previous equation. 
  1607 	    Then we will have to prove the second part of the predicate.*)
  1608 	  have exist: "lcoeff g (^) ?k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> \<ominus>\<^bsub>P\<^esub> ?r"
  1609 	    using minus_add
  1610 	    using sym [OF a_assoc [of "g \<otimes>\<^bsub>P\<^esub> ?q" "\<ominus>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q)" "lcoeff g \<odot>\<^bsub>P\<^esub> f"]]
  1611 	    using r_neg by auto
  1612 	  show ?thesis
  1613 	  proof (cases "deg R (\<ominus>\<^bsub>P\<^esub> ?r) < deg R g")
  1614 	    (*JE: if the degree of the remainder satisfies the statement property we are done*)
  1615 	    case True
  1616 	    {
  1617 	      show ?thesis
  1618 	      proof (rule exI3 [of _ ?q "\<ominus>\<^bsub>P\<^esub> ?r" ?k], intro conjI)
  1619 		show "lcoeff g (^) ?k \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> \<ominus>\<^bsub>P\<^esub> ?r" using exist by simp
  1620 		show "\<ominus>\<^bsub>P\<^esub> ?r = \<zero>\<^bsub>P\<^esub> \<or> deg R (\<ominus>\<^bsub>P\<^esub> ?r) < deg R g" using True by simp
  1621 	      qed (simp_all)
  1622 	    }
  1623 	  next
  1624 	    case False note n_deg_r_l_deg_g = False
  1625 	    {
  1626 	      (*JE: otherwise, we verify the conditions of the induction hypothesis.*)
  1627 	      show ?thesis
  1628 	      proof (cases "deg R f = 0")
  1629 		(*JE: the solutions are different if the degree of f is zero or not*)
  1630 		case True
  1631 		{
  1632 		  have deg_g: "deg R g = 0" using True using deg_g_le_deg_f by simp
  1633 		  have "lcoeff g (^) (1::nat) \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> f \<oplus>\<^bsub>P\<^esub> \<zero>\<^bsub>P\<^esub>"
  1634 		    unfolding deg_g apply simp
  1635 		    unfolding sym [OF monom_mult_is_smult [OF coeff_closed [OF g_in_P, of 0] f_in_P]]
  1636 		    using deg_zero_impl_monom [OF g_in_P deg_g] by simp
  1637 		  then show ?thesis using f_in_P by blast
  1638 		}
  1639 	      next
  1640 		case False note deg_f_nzero = False
  1641 		{
  1642 		  (*JE: now it only remains the case where the induction hypothesis can be used.*)
  1643 		  (*JE: we first prove that the degree of the remainder is smaller than the one of f*)
  1644 		  have deg_remainder_l_f: "deg R (\<ominus>\<^bsub>P\<^esub> ?r) < n"
  1645 		  proof -
  1646 		    have "deg R (\<ominus>\<^bsub>P\<^esub> ?r) = deg R ?r" using deg_uminus [of ?r] by simp
  1647 		    also have "\<dots> < deg R f"
  1648 		    proof (rule deg_lcoeff_cancel)
  1649 		      show "deg R (\<ominus>\<^bsub>P\<^esub> (lcoeff g \<odot>\<^bsub>P\<^esub> f)) \<le> deg R f"
  1650 			using deg_smult_ring [of "lcoeff g" f] using prem
  1651 			using lcoeff_nonzero2 [OF g_in_P g_not_zero] by simp
  1652 		      show "deg R (g \<otimes>\<^bsub>P\<^esub> ?q) \<le> deg R f"
  1653 			using monom_deg_mult [OF _ g_in_P, of f "lcoeff f"] and deg_g_le_deg_f
  1654 			by simp
  1655 		      show "coeff P (g \<otimes>\<^bsub>P\<^esub> ?q) (deg R f) = \<ominus> coeff P (\<ominus>\<^bsub>P\<^esub> (lcoeff g \<odot>\<^bsub>P\<^esub> f)) (deg R f)"
  1656 			unfolding coeff_mult [OF g_in_P monom_closed [OF lcoeff_closed [OF f_in_P], of "deg R f - deg R g"], of "deg R f"]
  1657 			unfolding coeff_monom [OF lcoeff_closed [OF f_in_P], of "(deg R f - deg R g)"]
  1658 			using R.finsum_cong' [of "{..deg R f}" "{..deg R f}" 
  1659 			  "(\<lambda>i. coeff P g i \<otimes> (if deg R f - deg R g = deg R f - i then lcoeff f else \<zero>))" 
  1660 			  "(\<lambda>i. if deg R g = i then coeff P g i \<otimes> lcoeff f else \<zero>)"]
  1661 			using R.finsum_singleton [of "deg R g" "{.. deg R f}" "(\<lambda>i. coeff P g i \<otimes> lcoeff f)"]
  1662 			unfolding Pi_def using deg_g_le_deg_f by force
  1663 		    qed (simp_all add: deg_f_nzero)
  1664 		    finally show "deg R (\<ominus>\<^bsub>P\<^esub> ?r) < n" unfolding prem .
  1665 		  qed
  1666 		  moreover have "\<ominus>\<^bsub>P\<^esub> ?r \<in> carrier P" by simp
  1667 		  moreover obtain m where deg_rem_eq_m: "deg R (\<ominus>\<^bsub>P\<^esub> ?r) = m" by auto
  1668 		  moreover have "deg R g \<le> deg R (\<ominus>\<^bsub>P\<^esub> ?r)" using n_deg_r_l_deg_g by simp
  1669 		    (*JE: now, by applying the induction hypothesis, we obtain new quotient, remainder and exponent.*)
  1670 		  ultimately obtain q' r' k'
  1671 		    where rem_desc: "lcoeff g (^) (k'::nat) \<odot>\<^bsub>P\<^esub> (\<ominus>\<^bsub>P\<^esub> ?r) = g \<otimes>\<^bsub>P\<^esub> q' \<oplus>\<^bsub>P\<^esub> r'"and rem_deg: "(r' = \<zero>\<^bsub>P\<^esub> \<or> deg R r' < deg R g)"
  1672 		    and q'_in_carrier: "q' \<in> carrier P" and r'_in_carrier: "r' \<in> carrier P"
  1673 		    using hypo by blast
  1674 		      (*JE: we now prove that the new quotient, remainder and exponent can be used to get 
  1675 		      the quotient, remainder and exponent of the long division theorem*)
  1676 		  show ?thesis
  1677 		  proof (rule exI3 [of _ "((lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> q')" r' "Suc k'"], intro conjI)
  1678 		    show "(lcoeff g (^) (Suc k')) \<odot>\<^bsub>P\<^esub> f = g \<otimes>\<^bsub>P\<^esub> ((lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> q') \<oplus>\<^bsub>P\<^esub> r'"
  1679 		    proof -
  1680 		      have "(lcoeff g (^) (Suc k')) \<odot>\<^bsub>P\<^esub> f = (lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> \<ominus>\<^bsub>P\<^esub> ?r)" 
  1681 			using smult_assoc1 exist by simp
  1682 		      also have "\<dots> = (lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q) \<oplus>\<^bsub>P\<^esub> ((lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> ( \<ominus>\<^bsub>P\<^esub> ?r))"
  1683 			using UP_smult_r_distr by simp
  1684 		      also have "\<dots> = (lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q) \<oplus>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> q' \<oplus>\<^bsub>P\<^esub> r')"
  1685 			using rem_desc by simp
  1686 		      also have "\<dots> = (lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q) \<oplus>\<^bsub>P\<^esub> g \<otimes>\<^bsub>P\<^esub> q' \<oplus>\<^bsub>P\<^esub> r'"
  1687 			using sym [OF a_assoc [of "lcoeff g (^) k' \<odot>\<^bsub>P\<^esub> (g \<otimes>\<^bsub>P\<^esub> ?q)" "g \<otimes>\<^bsub>P\<^esub> q'" "r'"]]
  1688 			using q'_in_carrier r'_in_carrier by simp
  1689 		      also have "\<dots> = (lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> (?q \<otimes>\<^bsub>P\<^esub> g) \<oplus>\<^bsub>P\<^esub> q' \<otimes>\<^bsub>P\<^esub> g \<oplus>\<^bsub>P\<^esub> r'"
  1690 			using q'_in_carrier by (auto simp add: m_comm)
  1691 		      also have "\<dots> = (((lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> ?q) \<otimes>\<^bsub>P\<^esub> g) \<oplus>\<^bsub>P\<^esub> q' \<otimes>\<^bsub>P\<^esub> g \<oplus>\<^bsub>P\<^esub> r'" 
  1692 			using smult_assoc2 q'_in_carrier by auto
  1693 		      also have "\<dots> = ((lcoeff g (^) k') \<odot>\<^bsub>P\<^esub> ?q \<oplus>\<^bsub>P\<^esub> q') \<otimes>\<^bsub>P\<^esub> g \<oplus>\<^bsub>P\<^esub> r'"
  1694 			using sym [OF l_distr] and q'_in_carrier by auto
  1695 		      finally show ?thesis using m_comm q'_in_carrier by auto
  1696 		    qed
  1697 		  qed (simp_all add: rem_deg q'_in_carrier r'_in_carrier)
  1698 		}
  1699 	      qed
  1700 	    }
  1701 	  qed
  1702 	qed
  1703       qed
  1704     }
  1705   qed
  1706 qed
  1707 
  1708 end
  1709 
  1710 
  1711 text {*The remainder theorem as corollary of the long division theorem.*}
  1712 
  1713 context UP_cring
  1714 begin
  1715 
  1716 lemma deg_minus_monom:
  1717   assumes a: "a \<in> carrier R"
  1718   and R_not_trivial: "(carrier R \<noteq> {\<zero>})"
  1719   shows "deg R (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) = 1"
  1720   (is "deg R ?g = 1")
  1721 proof -
  1722   have "deg R ?g \<le> 1"
  1723   proof (rule deg_aboveI)
  1724     fix m
  1725     assume "(1::nat) < m" 
  1726     then show "coeff P ?g m = \<zero>" 
  1727       using coeff_minus using a by auto algebra
  1728   qed (simp add: a)
  1729   moreover have "deg R ?g \<ge> 1"
  1730   proof (rule deg_belowI)
  1731     show "coeff P ?g 1 \<noteq> \<zero>"
  1732       using a using R.carrier_one_not_zero R_not_trivial by simp algebra
  1733   qed (simp add: a)
  1734   ultimately show ?thesis by simp
  1735 qed
  1736 
  1737 lemma lcoeff_monom:
  1738   assumes a: "a \<in> carrier R" and R_not_trivial: "(carrier R \<noteq> {\<zero>})"
  1739   shows "lcoeff (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) = \<one>"
  1740   using deg_minus_monom [OF a R_not_trivial]
  1741   using coeff_minus a by auto algebra
  1742 
  1743 lemma deg_nzero_nzero:
  1744   assumes deg_p_nzero: "deg R p \<noteq> 0"
  1745   shows "p \<noteq> \<zero>\<^bsub>P\<^esub>"
  1746   using deg_zero deg_p_nzero by auto
  1747 
  1748 lemma deg_monom_minus:
  1749   assumes a: "a \<in> carrier R"
  1750   and R_not_trivial: "carrier R \<noteq> {\<zero>}"
  1751   shows "deg R (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) = 1"
  1752   (is "deg R ?g = 1")
  1753 proof -
  1754   have "deg R ?g \<le> 1"
  1755   proof (rule deg_aboveI)
  1756     fix m::nat assume "1 < m" then show "coeff P ?g m = \<zero>" 
  1757       using coeff_minus [OF monom_closed [OF R.one_closed, of 1] monom_closed [OF a, of 0], of m] 
  1758       using coeff_monom [OF R.one_closed, of 1 m] using coeff_monom [OF a, of 0 m] by auto algebra
  1759   qed (simp add: a)
  1760   moreover have "1 \<le> deg R ?g"
  1761   proof (rule deg_belowI)
  1762     show "coeff P ?g 1 \<noteq> \<zero>" 
  1763       using coeff_minus [OF monom_closed [OF R.one_closed, of 1] monom_closed [OF a, of 0], of 1]
  1764       using coeff_monom [OF R.one_closed, of 1 1] using coeff_monom [OF a, of 0 1] 
  1765       using R_not_trivial using R.carrier_one_not_zero
  1766       by auto algebra
  1767   qed (simp add: a)
  1768   ultimately show ?thesis by simp
  1769 qed
  1770 
  1771 lemma eval_monom_expr:
  1772   assumes a: "a \<in> carrier R"
  1773   shows "eval R R id a (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) = \<zero>"
  1774   (is "eval R R id a ?g = _")
  1775 proof -
  1776   interpret UP_pre_univ_prop R R id P proof qed simp
  1777   have eval_ring_hom: "eval R R id a \<in> ring_hom P R" using eval_ring_hom [OF a] by simp
  1778   interpret ring_hom_cring P R "eval R R id a" proof qed (simp add: eval_ring_hom)
  1779   have mon1_closed: "monom P \<one>\<^bsub>R\<^esub> 1 \<in> carrier P" 
  1780     and mon0_closed: "monom P a 0 \<in> carrier P" 
  1781     and min_mon0_closed: "\<ominus>\<^bsub>P\<^esub> monom P a 0 \<in> carrier P"
  1782     using a R.a_inv_closed by auto
  1783   have "eval R R id a ?g = eval R R id a (monom P \<one> 1) \<ominus> eval R R id a (monom P a 0)"
  1784     unfolding P.minus_eq [OF mon1_closed mon0_closed]
  1785     unfolding R_S_h.hom_add [OF mon1_closed min_mon0_closed]
  1786     unfolding R_S_h.hom_a_inv [OF mon0_closed] 
  1787     using R.minus_eq [symmetric] mon1_closed mon0_closed by auto
  1788   also have "\<dots> = a \<ominus> a"
  1789     using eval_monom [OF R.one_closed a, of 1] using eval_monom [OF a a, of 0] using a by simp
  1790   also have "\<dots> = \<zero>"
  1791     using a by algebra
  1792   finally show ?thesis by simp
  1793 qed
  1794 
  1795 lemma remainder_theorem_exist:
  1796   assumes f: "f \<in> carrier P" and a: "a \<in> carrier R"
  1797   and R_not_trivial: "carrier R \<noteq> {\<zero>}"
  1798   shows "\<exists> q r. (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> f = (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (deg R r = 0)"
  1799   (is "\<exists> q r. (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (deg R r = 0)")
  1800 proof -
  1801   let ?g = "monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0"
  1802   from deg_minus_monom [OF a R_not_trivial]
  1803   have deg_g_nzero: "deg R ?g \<noteq> 0" by simp
  1804   have "\<exists>q r (k::nat). q \<in> carrier P \<and> r \<in> carrier P \<and>
  1805     lcoeff ?g (^) k \<odot>\<^bsub>P\<^esub> f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r \<and> (r = \<zero>\<^bsub>P\<^esub> \<or> deg R r < deg R ?g)"
  1806     using long_div_theorem [OF _ f deg_nzero_nzero [OF deg_g_nzero]] a
  1807     by auto
  1808   then show ?thesis
  1809     unfolding lcoeff_monom [OF a R_not_trivial]
  1810     unfolding deg_monom_minus [OF a R_not_trivial]
  1811     using smult_one [OF f] using deg_zero by force
  1812 qed
  1813 
  1814 lemma remainder_theorem_expression:
  1815   assumes f [simp]: "f \<in> carrier P" and a [simp]: "a \<in> carrier R"
  1816   and q [simp]: "q \<in> carrier P" and r [simp]: "r \<in> carrier P"
  1817   and R_not_trivial: "carrier R \<noteq> {\<zero>}"
  1818   and f_expr: "f = (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r"
  1819   (is "f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r" is "f = ?gq \<oplus>\<^bsub>P\<^esub> r")
  1820     and deg_r_0: "deg R r = 0"
  1821     shows "r = monom P (eval R R id a f) 0"
  1822 proof -
  1823   interpret UP_pre_univ_prop R R id P proof qed simp
  1824   have eval_ring_hom: "eval R R id a \<in> ring_hom P R"
  1825     using eval_ring_hom [OF a] by simp
  1826   have "eval R R id a f = eval R R id a ?gq \<oplus>\<^bsub>R\<^esub> eval R R id a r"
  1827     unfolding f_expr using ring_hom_add [OF eval_ring_hom] by auto
  1828   also have "\<dots> = ((eval R R id a ?g) \<otimes> (eval R R id a q)) \<oplus>\<^bsub>R\<^esub> eval R R id a r"
  1829     using ring_hom_mult [OF eval_ring_hom] by auto
  1830   also have "\<dots> = \<zero> \<oplus> eval R R id a r"
  1831     unfolding eval_monom_expr [OF a] using eval_ring_hom 
  1832     unfolding ring_hom_def using q unfolding Pi_def by simp
  1833   also have "\<dots> = eval R R id a r"
  1834     using eval_ring_hom unfolding ring_hom_def using r unfolding Pi_def by simp
  1835   finally have eval_eq: "eval R R id a f = eval R R id a r" by simp
  1836   from deg_zero_impl_monom [OF r deg_r_0]
  1837   have "r = monom P (coeff P r 0) 0" by simp
  1838   with eval_const [OF a, of "coeff P r 0"] eval_eq 
  1839   show ?thesis by auto
  1840 qed
  1841 
  1842 corollary remainder_theorem:
  1843   assumes f [simp]: "f \<in> carrier P" and a [simp]: "a \<in> carrier R"
  1844   and R_not_trivial: "carrier R \<noteq> {\<zero>}"
  1845   shows "\<exists> q r. (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> 
  1846      f = (monom P \<one>\<^bsub>R\<^esub> 1 \<ominus>\<^bsub>P\<^esub> monom P a 0) \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> monom P (eval R R id a f) 0"
  1847   (is "\<exists> q r. (q \<in> carrier P) \<and> (r \<in> carrier P) \<and> f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> monom P (eval R R id a f) 0")
  1848 proof -
  1849   from remainder_theorem_exist [OF f a R_not_trivial]
  1850   obtain q r
  1851     where q_r: "q \<in> carrier P \<and> r \<in> carrier P \<and> f = ?g \<otimes>\<^bsub>P\<^esub> q \<oplus>\<^bsub>P\<^esub> r"
  1852     and deg_r: "deg R r = 0" by force
  1853   with remainder_theorem_expression [OF f a _ _ R_not_trivial, of q r]
  1854   show ?thesis by auto
  1855 qed
  1856 
  1857 end
  1858 
  1859 
  1860 subsection {* Sample Application of Evaluation Homomorphism *}
  1861 
  1862 lemma UP_pre_univ_propI:
  1863   assumes "cring R"
  1864     and "cring S"
  1865     and "h \<in> ring_hom R S"
  1866   shows "UP_pre_univ_prop R S h"
  1867   using assms
  1868   by (auto intro!: UP_pre_univ_prop.intro ring_hom_cring.intro
  1869     ring_hom_cring_axioms.intro UP_cring.intro)
  1870 
  1871 definition  INTEG :: "int ring"
  1872   where INTEG_def: "INTEG == (| carrier = UNIV, mult = op *, one = 1, zero = 0, add = op + |)"
  1873 
  1874 lemma INTEG_cring:
  1875   "cring INTEG"
  1876   by (unfold INTEG_def) (auto intro!: cringI abelian_groupI comm_monoidI
  1877     zadd_zminus_inverse2 zadd_zmult_distrib)
  1878 
  1879 lemma INTEG_id_eval:
  1880   "UP_pre_univ_prop INTEG INTEG id"
  1881   by (fast intro: UP_pre_univ_propI INTEG_cring id_ring_hom)
  1882 
  1883 text {*
  1884   Interpretation now enables to import all theorems and lemmas
  1885   valid in the context of homomorphisms between @{term INTEG} and @{term
  1886   "UP INTEG"} globally.
  1887 *}
  1888 
  1889 interpretation INTEG!: UP_pre_univ_prop INTEG INTEG id
  1890   using INTEG_id_eval by simp_all
  1891 
  1892 lemma INTEG_closed [intro, simp]:
  1893   "z \<in> carrier INTEG"
  1894   by (unfold INTEG_def) simp
  1895 
  1896 lemma INTEG_mult [simp]:
  1897   "mult INTEG z w = z * w"
  1898   by (unfold INTEG_def) simp
  1899 
  1900 lemma INTEG_pow [simp]:
  1901   "pow INTEG z n = z ^ n"
  1902   by (induct n) (simp_all add: INTEG_def nat_pow_def)
  1903 
  1904 lemma "eval INTEG INTEG id 10 (monom (UP INTEG) 5 2) = 500"
  1905   by (simp add: INTEG.eval_monom)
  1906 
  1907 end