src/HOL/Library/Poly_Deriv.thy
author bulwahn
Tue Apr 05 09:38:28 2011 +0200 (2011-04-05)
changeset 42231 bc1891226d00
parent 41959 b460124855b8
child 44317 b7e9fa025f15
permissions -rw-r--r--
removing bounded_forall code equation for characters when loading Code_Char
     1 (*  Title:      HOL/Library/Poly_Deriv.thy
     2     Author:     Amine Chaieb
     3     Author:     Brian Huffman
     4 *)
     5 
     6 header{* Polynomials and Differentiation *}
     7 
     8 theory Poly_Deriv
     9 imports Deriv Polynomial
    10 begin
    11 
    12 subsection {* Derivatives of univariate polynomials *}
    13 
    14 definition
    15   pderiv :: "'a::real_normed_field poly \<Rightarrow> 'a poly" where
    16   "pderiv = poly_rec 0 (\<lambda>a p p'. p + pCons 0 p')"
    17 
    18 lemma pderiv_0 [simp]: "pderiv 0 = 0"
    19   unfolding pderiv_def by (simp add: poly_rec_0)
    20 
    21 lemma pderiv_pCons: "pderiv (pCons a p) = p + pCons 0 (pderiv p)"
    22   unfolding pderiv_def by (simp add: poly_rec_pCons)
    23 
    24 lemma coeff_pderiv: "coeff (pderiv p) n = of_nat (Suc n) * coeff p (Suc n)"
    25   apply (induct p arbitrary: n, simp)
    26   apply (simp add: pderiv_pCons coeff_pCons algebra_simps split: nat.split)
    27   done
    28 
    29 lemma pderiv_eq_0_iff: "pderiv p = 0 \<longleftrightarrow> degree p = 0"
    30   apply (rule iffI)
    31   apply (cases p, simp)
    32   apply (simp add: expand_poly_eq coeff_pderiv del: of_nat_Suc)
    33   apply (simp add: expand_poly_eq coeff_pderiv coeff_eq_0)
    34   done
    35 
    36 lemma degree_pderiv: "degree (pderiv p) = degree p - 1"
    37   apply (rule order_antisym [OF degree_le])
    38   apply (simp add: coeff_pderiv coeff_eq_0)
    39   apply (cases "degree p", simp)
    40   apply (rule le_degree)
    41   apply (simp add: coeff_pderiv del: of_nat_Suc)
    42   apply (rule subst, assumption)
    43   apply (rule leading_coeff_neq_0, clarsimp)
    44   done
    45 
    46 lemma pderiv_singleton [simp]: "pderiv [:a:] = 0"
    47 by (simp add: pderiv_pCons)
    48 
    49 lemma pderiv_add: "pderiv (p + q) = pderiv p + pderiv q"
    50 by (rule poly_ext, simp add: coeff_pderiv algebra_simps)
    51 
    52 lemma pderiv_minus: "pderiv (- p) = - pderiv p"
    53 by (rule poly_ext, simp add: coeff_pderiv)
    54 
    55 lemma pderiv_diff: "pderiv (p - q) = pderiv p - pderiv q"
    56 by (rule poly_ext, simp add: coeff_pderiv algebra_simps)
    57 
    58 lemma pderiv_smult: "pderiv (smult a p) = smult a (pderiv p)"
    59 by (rule poly_ext, simp add: coeff_pderiv algebra_simps)
    60 
    61 lemma pderiv_mult: "pderiv (p * q) = p * pderiv q + q * pderiv p"
    62 apply (induct p)
    63 apply simp
    64 apply (simp add: pderiv_add pderiv_smult pderiv_pCons algebra_simps)
    65 done
    66 
    67 lemma pderiv_power_Suc:
    68   "pderiv (p ^ Suc n) = smult (of_nat (Suc n)) (p ^ n) * pderiv p"
    69 apply (induct n)
    70 apply simp
    71 apply (subst power_Suc)
    72 apply (subst pderiv_mult)
    73 apply (erule ssubst)
    74 apply (simp add: smult_add_left algebra_simps)
    75 done
    76 
    77 lemma DERIV_cmult2: "DERIV f x :> D ==> DERIV (%x. (f x) * c :: real) x :> D * c"
    78 by (simp add: DERIV_cmult mult_commute [of _ c])
    79 
    80 lemma DERIV_pow2: "DERIV (%x. x ^ Suc n) x :> real (Suc n) * (x ^ n)"
    81 by (rule lemma_DERIV_subst, rule DERIV_pow, simp)
    82 declare DERIV_pow2 [simp] DERIV_pow [simp]
    83 
    84 lemma DERIV_add_const: "DERIV f x :> D ==>  DERIV (%x. a + f x :: 'a::real_normed_field) x :> D"
    85 by (rule lemma_DERIV_subst, rule DERIV_add, auto)
    86 
    87 lemma poly_DERIV[simp]: "DERIV (%x. poly p x) x :> poly (pderiv p) x"
    88   by (induct p, auto intro!: DERIV_intros simp add: pderiv_pCons)
    89 
    90 text{* Consequences of the derivative theorem above*}
    91 
    92 lemma poly_differentiable[simp]: "(%x. poly p x) differentiable (x::real)"
    93 apply (simp add: differentiable_def)
    94 apply (blast intro: poly_DERIV)
    95 done
    96 
    97 lemma poly_isCont[simp]: "isCont (%x. poly p x) (x::real)"
    98 by (rule poly_DERIV [THEN DERIV_isCont])
    99 
   100 lemma poly_IVT_pos: "[| a < b; poly p (a::real) < 0; 0 < poly p b |]
   101       ==> \<exists>x. a < x & x < b & (poly p x = 0)"
   102 apply (cut_tac f = "%x. poly p x" and a = a and b = b and y = 0 in IVT_objl)
   103 apply (auto simp add: order_le_less)
   104 done
   105 
   106 lemma poly_IVT_neg: "[| (a::real) < b; 0 < poly p a; poly p b < 0 |]
   107       ==> \<exists>x. a < x & x < b & (poly p x = 0)"
   108 by (insert poly_IVT_pos [where p = "- p" ]) simp
   109 
   110 lemma poly_MVT: "(a::real) < b ==>
   111      \<exists>x. a < x & x < b & (poly p b - poly p a = (b - a) * poly (pderiv p) x)"
   112 apply (drule_tac f = "poly p" in MVT, auto)
   113 apply (rule_tac x = z in exI)
   114 apply (auto simp add: real_mult_left_cancel poly_DERIV [THEN DERIV_unique])
   115 done
   116 
   117 text{*Lemmas for Derivatives*}
   118 
   119 lemma order_unique_lemma:
   120   fixes p :: "'a::idom poly"
   121   assumes "[:-a, 1:] ^ n dvd p \<and> \<not> [:-a, 1:] ^ Suc n dvd p"
   122   shows "n = order a p"
   123 unfolding Polynomial.order_def
   124 apply (rule Least_equality [symmetric])
   125 apply (rule assms [THEN conjunct2])
   126 apply (erule contrapos_np)
   127 apply (rule power_le_dvd)
   128 apply (rule assms [THEN conjunct1])
   129 apply simp
   130 done
   131 
   132 lemma lemma_order_pderiv1:
   133   "pderiv ([:- a, 1:] ^ Suc n * q) = [:- a, 1:] ^ Suc n * pderiv q +
   134     smult (of_nat (Suc n)) (q * [:- a, 1:] ^ n)"
   135 apply (simp only: pderiv_mult pderiv_power_Suc)
   136 apply (simp del: power_Suc of_nat_Suc add: pderiv_pCons)
   137 done
   138 
   139 lemma dvd_add_cancel1:
   140   fixes a b c :: "'a::comm_ring_1"
   141   shows "a dvd b + c \<Longrightarrow> a dvd b \<Longrightarrow> a dvd c"
   142   by (drule (1) Rings.dvd_diff, simp)
   143 
   144 lemma lemma_order_pderiv [rule_format]:
   145      "\<forall>p q a. 0 < n &
   146        pderiv p \<noteq> 0 &
   147        p = [:- a, 1:] ^ n * q & ~ [:- a, 1:] dvd q
   148        --> n = Suc (order a (pderiv p))"
   149  apply (cases "n", safe, rename_tac n p q a)
   150  apply (rule order_unique_lemma)
   151  apply (rule conjI)
   152   apply (subst lemma_order_pderiv1)
   153   apply (rule dvd_add)
   154    apply (rule dvd_mult2)
   155    apply (rule le_imp_power_dvd, simp)
   156   apply (rule dvd_smult)
   157   apply (rule dvd_mult)
   158   apply (rule dvd_refl)
   159  apply (subst lemma_order_pderiv1)
   160  apply (erule contrapos_nn) back
   161  apply (subgoal_tac "[:- a, 1:] ^ Suc n dvd q * [:- a, 1:] ^ n")
   162   apply (simp del: mult_pCons_left)
   163  apply (drule dvd_add_cancel1)
   164   apply (simp del: mult_pCons_left)
   165  apply (drule dvd_smult_cancel, simp del: of_nat_Suc)
   166  apply assumption
   167 done
   168 
   169 lemma order_decomp:
   170      "p \<noteq> 0
   171       ==> \<exists>q. p = [:-a, 1:] ^ (order a p) * q &
   172                 ~([:-a, 1:] dvd q)"
   173 apply (drule order [where a=a])
   174 apply (erule conjE)
   175 apply (erule dvdE)
   176 apply (rule exI)
   177 apply (rule conjI, assumption)
   178 apply (erule contrapos_nn)
   179 apply (erule ssubst) back
   180 apply (subst power_Suc2)
   181 apply (erule mult_dvd_mono [OF dvd_refl])
   182 done
   183 
   184 lemma order_pderiv: "[| pderiv p \<noteq> 0; order a p \<noteq> 0 |]
   185       ==> (order a p = Suc (order a (pderiv p)))"
   186 apply (case_tac "p = 0", simp)
   187 apply (drule_tac a = a and p = p in order_decomp)
   188 using neq0_conv
   189 apply (blast intro: lemma_order_pderiv)
   190 done
   191 
   192 lemma order_mult: "p * q \<noteq> 0 \<Longrightarrow> order a (p * q) = order a p + order a q"
   193 proof -
   194   def i \<equiv> "order a p"
   195   def j \<equiv> "order a q"
   196   def t \<equiv> "[:-a, 1:]"
   197   have t_dvd_iff: "\<And>u. t dvd u \<longleftrightarrow> poly u a = 0"
   198     unfolding t_def by (simp add: dvd_iff_poly_eq_0)
   199   assume "p * q \<noteq> 0"
   200   then show "order a (p * q) = i + j"
   201     apply clarsimp
   202     apply (drule order [where a=a and p=p, folded i_def t_def])
   203     apply (drule order [where a=a and p=q, folded j_def t_def])
   204     apply clarify
   205     apply (rule order_unique_lemma [symmetric], fold t_def)
   206     apply (erule dvdE)+
   207     apply (simp add: power_add t_dvd_iff)
   208     done
   209 qed
   210 
   211 text{*Now justify the standard squarefree decomposition, i.e. f / gcd(f,f'). *}
   212 
   213 lemma order_divides: "[:-a, 1:] ^ n dvd p \<longleftrightarrow> p = 0 \<or> n \<le> order a p"
   214 apply (cases "p = 0", auto)
   215 apply (drule order_2 [where a=a and p=p])
   216 apply (erule contrapos_np)
   217 apply (erule power_le_dvd)
   218 apply simp
   219 apply (erule power_le_dvd [OF order_1])
   220 done
   221 
   222 lemma poly_squarefree_decomp_order:
   223   assumes "pderiv p \<noteq> 0"
   224   and p: "p = q * d"
   225   and p': "pderiv p = e * d"
   226   and d: "d = r * p + s * pderiv p"
   227   shows "order a q = (if order a p = 0 then 0 else 1)"
   228 proof (rule classical)
   229   assume 1: "order a q \<noteq> (if order a p = 0 then 0 else 1)"
   230   from `pderiv p \<noteq> 0` have "p \<noteq> 0" by auto
   231   with p have "order a p = order a q + order a d"
   232     by (simp add: order_mult)
   233   with 1 have "order a p \<noteq> 0" by (auto split: if_splits)
   234   have "order a (pderiv p) = order a e + order a d"
   235     using `pderiv p \<noteq> 0` `pderiv p = e * d` by (simp add: order_mult)
   236   have "order a p = Suc (order a (pderiv p))"
   237     using `pderiv p \<noteq> 0` `order a p \<noteq> 0` by (rule order_pderiv)
   238   have "d \<noteq> 0" using `p \<noteq> 0` `p = q * d` by simp
   239   have "([:-a, 1:] ^ (order a (pderiv p))) dvd d"
   240     apply (simp add: d)
   241     apply (rule dvd_add)
   242     apply (rule dvd_mult)
   243     apply (simp add: order_divides `p \<noteq> 0`
   244            `order a p = Suc (order a (pderiv p))`)
   245     apply (rule dvd_mult)
   246     apply (simp add: order_divides)
   247     done
   248   then have "order a (pderiv p) \<le> order a d"
   249     using `d \<noteq> 0` by (simp add: order_divides)
   250   show ?thesis
   251     using `order a p = order a q + order a d`
   252     using `order a (pderiv p) = order a e + order a d`
   253     using `order a p = Suc (order a (pderiv p))`
   254     using `order a (pderiv p) \<le> order a d`
   255     by auto
   256 qed
   257 
   258 lemma poly_squarefree_decomp_order2: "[| pderiv p \<noteq> 0;
   259          p = q * d;
   260          pderiv p = e * d;
   261          d = r * p + s * pderiv p
   262       |] ==> \<forall>a. order a q = (if order a p = 0 then 0 else 1)"
   263 apply (blast intro: poly_squarefree_decomp_order)
   264 done
   265 
   266 lemma order_pderiv2: "[| pderiv p \<noteq> 0; order a p \<noteq> 0 |]
   267       ==> (order a (pderiv p) = n) = (order a p = Suc n)"
   268 apply (auto dest: order_pderiv)
   269 done
   270 
   271 definition
   272   rsquarefree :: "'a::idom poly => bool" where
   273   "rsquarefree p = (p \<noteq> 0 & (\<forall>a. (order a p = 0) | (order a p = 1)))"
   274 
   275 lemma pderiv_iszero: "pderiv p = 0 \<Longrightarrow> \<exists>h. p = [:h:]"
   276 apply (simp add: pderiv_eq_0_iff)
   277 apply (case_tac p, auto split: if_splits)
   278 done
   279 
   280 lemma rsquarefree_roots:
   281   "rsquarefree p = (\<forall>a. ~(poly p a = 0 & poly (pderiv p) a = 0))"
   282 apply (simp add: rsquarefree_def)
   283 apply (case_tac "p = 0", simp, simp)
   284 apply (case_tac "pderiv p = 0")
   285 apply simp
   286 apply (drule pderiv_iszero, clarify)
   287 apply simp
   288 apply (rule allI)
   289 apply (cut_tac p = "[:h:]" and a = a in order_root)
   290 apply simp
   291 apply (auto simp add: order_root order_pderiv2)
   292 apply (erule_tac x="a" in allE, simp)
   293 done
   294 
   295 lemma poly_squarefree_decomp:
   296   assumes "pderiv p \<noteq> 0"
   297     and "p = q * d"
   298     and "pderiv p = e * d"
   299     and "d = r * p + s * pderiv p"
   300   shows "rsquarefree q & (\<forall>a. (poly q a = 0) = (poly p a = 0))"
   301 proof -
   302   from `pderiv p \<noteq> 0` have "p \<noteq> 0" by auto
   303   with `p = q * d` have "q \<noteq> 0" by simp
   304   have "\<forall>a. order a q = (if order a p = 0 then 0 else 1)"
   305     using assms by (rule poly_squarefree_decomp_order2)
   306   with `p \<noteq> 0` `q \<noteq> 0` show ?thesis
   307     by (simp add: rsquarefree_def order_root)
   308 qed
   309 
   310 end