src/HOL/Tools/prop_logic.ML
author wenzelm
Wed Feb 15 21:34:55 2006 +0100 (2006-02-15)
changeset 19046 bc5c6c9b114e
parent 17809 195045659c06
child 20442 04621ea9440e
permissions -rw-r--r--
removed distinct, renamed gen_distinct to distinct;
     1 (*  Title:      HOL/Tools/prop_logic.ML
     2     ID:         $Id$
     3     Author:     Tjark Weber
     4     Copyright   2004-2005
     5 
     6 Formulas of propositional logic.
     7 *)
     8 
     9 signature PROP_LOGIC =
    10 sig
    11 	datatype prop_formula =
    12 		  True
    13 		| False
    14 		| BoolVar of int  (* NOTE: only use indices >= 1 *)
    15 		| Not of prop_formula
    16 		| Or of prop_formula * prop_formula
    17 		| And of prop_formula * prop_formula
    18 
    19 	val SNot     : prop_formula -> prop_formula
    20 	val SOr      : prop_formula * prop_formula -> prop_formula
    21 	val SAnd     : prop_formula * prop_formula -> prop_formula
    22 	val simplify : prop_formula -> prop_formula  (* eliminates True/False and double-negation *)
    23 
    24 	val indices : prop_formula -> int list  (* set of all variable indices *)
    25 	val maxidx  : prop_formula -> int       (* maximal variable index *)
    26 
    27 	val exists      : prop_formula list -> prop_formula  (* finite disjunction *)
    28 	val all         : prop_formula list -> prop_formula  (* finite conjunction *)
    29 	val dot_product : prop_formula list * prop_formula list -> prop_formula
    30 
    31 	val nnf    : prop_formula -> prop_formula  (* negation normal form *)
    32 	val cnf    : prop_formula -> prop_formula  (* conjunctive normal form *)
    33 	val auxcnf : prop_formula -> prop_formula  (* cnf with auxiliary variables *)
    34 	val defcnf : prop_formula -> prop_formula  (* definitional cnf *)
    35 
    36 	val eval : (int -> bool) -> prop_formula -> bool  (* semantics *)
    37 
    38 	val prop_formula_of_term : Term.term -> int Termtab.table -> prop_formula * int Termtab.table
    39 		(* propositional representation of HOL terms *)
    40 end;
    41 
    42 structure PropLogic : PROP_LOGIC =
    43 struct
    44 
    45 (* ------------------------------------------------------------------------- *)
    46 (* prop_formula: formulas of propositional logic, built from Boolean         *)
    47 (*               variables (referred to by index) and True/False using       *)
    48 (*               not/or/and                                                  *)
    49 (* ------------------------------------------------------------------------- *)
    50 
    51 	datatype prop_formula =
    52 		  True
    53 		| False
    54 		| BoolVar of int  (* NOTE: only use indices >= 1 *)
    55 		| Not of prop_formula
    56 		| Or of prop_formula * prop_formula
    57 		| And of prop_formula * prop_formula;
    58 
    59 (* ------------------------------------------------------------------------- *)
    60 (* The following constructor functions make sure that True and False do not  *)
    61 (* occur within any of the other connectives (i.e. Not, Or, And), and        *)
    62 (* perform double-negation elimination.                                      *)
    63 (* ------------------------------------------------------------------------- *)
    64 
    65 	(* prop_formula -> prop_formula *)
    66 
    67 	fun SNot True     = False
    68 	  | SNot False    = True
    69 	  | SNot (Not fm) = fm
    70 	  | SNot fm       = Not fm;
    71 
    72 	(* prop_formula * prop_formula -> prop_formula *)
    73 
    74 	fun SOr (True, _)   = True
    75 	  | SOr (_, True)   = True
    76 	  | SOr (False, fm) = fm
    77 	  | SOr (fm, False) = fm
    78 	  | SOr (fm1, fm2)  = Or (fm1, fm2);
    79 
    80 	(* prop_formula * prop_formula -> prop_formula *)
    81 
    82 	fun SAnd (True, fm) = fm
    83 	  | SAnd (fm, True) = fm
    84 	  | SAnd (False, _) = False
    85 	  | SAnd (_, False) = False
    86 	  | SAnd (fm1, fm2) = And (fm1, fm2);
    87 
    88 (* ------------------------------------------------------------------------- *)
    89 (* simplify: eliminates True/False below other connectives, and double-      *)
    90 (*      negation                                                             *)
    91 (* ------------------------------------------------------------------------- *)
    92 
    93 	(* prop_formula -> prop_formula *)
    94 
    95 	fun simplify (Not fm)         = SNot (simplify fm)
    96 	  | simplify (Or (fm1, fm2))  = SOr (simplify fm1, simplify fm2)
    97 	  | simplify (And (fm1, fm2)) = SAnd (simplify fm1, simplify fm2)
    98 	  | simplify fm               = fm;
    99 
   100 (* ------------------------------------------------------------------------- *)
   101 (* indices: collects all indices of Boolean variables that occur in a        *)
   102 (*      propositional formula 'fm'; no duplicates                            *)
   103 (* ------------------------------------------------------------------------- *)
   104 
   105 	(* prop_formula -> int list *)
   106 
   107 	fun indices True             = []
   108 	  | indices False            = []
   109 	  | indices (BoolVar i)      = [i]
   110 	  | indices (Not fm)         = indices fm
   111 	  | indices (Or (fm1, fm2))  = (indices fm1) union_int (indices fm2)
   112 	  | indices (And (fm1, fm2)) = (indices fm1) union_int (indices fm2);
   113 
   114 (* ------------------------------------------------------------------------- *)
   115 (* maxidx: computes the maximal variable index occuring in a formula of      *)
   116 (*      propositional logic 'fm'; 0 if 'fm' contains no variable             *)
   117 (* ------------------------------------------------------------------------- *)
   118 
   119 	(* prop_formula -> int *)
   120 
   121 	fun maxidx True             = 0
   122 	  | maxidx False            = 0
   123 	  | maxidx (BoolVar i)      = i
   124 	  | maxidx (Not fm)         = maxidx fm
   125 	  | maxidx (Or (fm1, fm2))  = Int.max (maxidx fm1, maxidx fm2)
   126 	  | maxidx (And (fm1, fm2)) = Int.max (maxidx fm1, maxidx fm2);
   127 
   128 (* ------------------------------------------------------------------------- *)
   129 (* exists: computes the disjunction over a list 'xs' of propositional        *)
   130 (*      formulas                                                             *)
   131 (* ------------------------------------------------------------------------- *)
   132 
   133 	(* prop_formula list -> prop_formula *)
   134 
   135 	fun exists xs = Library.foldl SOr (False, xs);
   136 
   137 (* ------------------------------------------------------------------------- *)
   138 (* all: computes the conjunction over a list 'xs' of propositional formulas  *)
   139 (* ------------------------------------------------------------------------- *)
   140 
   141 	(* prop_formula list -> prop_formula *)
   142 
   143 	fun all xs = Library.foldl SAnd (True, xs);
   144 
   145 (* ------------------------------------------------------------------------- *)
   146 (* dot_product: ([x1,...,xn], [y1,...,yn]) -> x1*y1+...+xn*yn                *)
   147 (* ------------------------------------------------------------------------- *)
   148 
   149 	(* prop_formula list * prop_formula list -> prop_formula *)
   150 
   151 	fun dot_product (xs,ys) = exists (map SAnd (xs~~ys));
   152 
   153 (* ------------------------------------------------------------------------- *)
   154 (* nnf: computes the negation normal form of a formula 'fm' of propositional *)
   155 (*      logic (i.e. only variables may be negated, but not subformulas).     *)
   156 (*      Simplification (c.f. 'simplify') is performed as well.               *)
   157 (* ------------------------------------------------------------------------- *)
   158 
   159 	(* prop_formula -> prop_formula *)
   160 
   161 	fun
   162 	(* constants *)
   163 	    nnf True                   = True
   164 	  | nnf False                  = False
   165 	(* variables *)
   166 	  | nnf (BoolVar i)            = (BoolVar i)
   167 	(* 'or' and 'and' as outermost connectives are left untouched *)
   168 	  | nnf (Or  (fm1, fm2))       = SOr  (nnf fm1, nnf fm2)
   169 	  | nnf (And (fm1, fm2))       = SAnd (nnf fm1, nnf fm2)
   170 	(* 'not' + constant *)
   171 	  | nnf (Not True)             = False
   172 	  | nnf (Not False)            = True
   173 	(* 'not' + variable *)
   174 	  | nnf (Not (BoolVar i))      = Not (BoolVar i)
   175 	(* pushing 'not' inside of 'or'/'and' using de Morgan's laws *)
   176 	  | nnf (Not (Or  (fm1, fm2))) = SAnd (nnf (SNot fm1), nnf (SNot fm2))
   177 	  | nnf (Not (And (fm1, fm2))) = SOr  (nnf (SNot fm1), nnf (SNot fm2))
   178 	(* double-negation elimination *)
   179 	  | nnf (Not (Not fm))         = nnf fm;
   180 
   181 (* ------------------------------------------------------------------------- *)
   182 (* cnf: computes the conjunctive normal form (i.e. a conjunction of          *)
   183 (*      disjunctions) of a formula 'fm' of propositional logic.  The result  *)
   184 (*      formula may be exponentially longer than 'fm'.                       *)
   185 (* ------------------------------------------------------------------------- *)
   186 
   187 	(* prop_formula -> prop_formula *)
   188 
   189 	fun cnf fm =
   190 	let
   191 		fun
   192 		(* constants *)
   193 		    cnf_from_nnf True             = True
   194 		  | cnf_from_nnf False            = False
   195 		(* literals *)
   196 		  | cnf_from_nnf (BoolVar i)      = BoolVar i
   197 		  | cnf_from_nnf (Not fm1)        = Not fm1  (* 'fm1' must be a variable since the formula is in NNF *)
   198 		(* pushing 'or' inside of 'and' using distributive laws *)
   199 		  | cnf_from_nnf (Or (fm1, fm2))  =
   200 			let
   201 				fun cnf_or (And (fm11, fm12), fm2) =
   202 					And (cnf_or (fm11, fm2), cnf_or (fm12, fm2))
   203 				  | cnf_or (fm1, And (fm21, fm22)) =
   204 					And (cnf_or (fm1, fm21), cnf_or (fm1, fm22))
   205 				(* neither subformula contains 'and' *)
   206 				  | cnf_or (fm1, fm2) =
   207 					Or (fm1, fm2)
   208 			in
   209 				cnf_or (cnf_from_nnf fm1, cnf_from_nnf fm2)
   210 			end
   211 		(* 'and' as outermost connective is left untouched *)
   212 		  | cnf_from_nnf (And (fm1, fm2)) = And (cnf_from_nnf fm1, cnf_from_nnf fm2)
   213 	in
   214 		(cnf_from_nnf o nnf) fm
   215 	end;
   216 
   217 (* ------------------------------------------------------------------------- *)
   218 (* auxcnf: computes the definitional conjunctive normal form of a formula    *)
   219 (*      'fm' of propositional logic, introducing auxiliary variables if      *)
   220 (*      necessary to avoid an exponential blowup of the formula.  The result *)
   221 (*      formula is satisfiable if and only if 'fm' is satisfiable.           *)
   222 (*      Auxiliary variables are introduced as switches for OR-nodes, based   *)
   223 (*      on the observation that e.g. "fm1 OR (fm21 AND fm22)" is             *)
   224 (*      equisatisfiable with "(fm1 OR ~aux) AND (fm21 OR aux) AND (fm22 OR   *)
   225 (*      aux)".                                                               *)
   226 (* ------------------------------------------------------------------------- *)
   227 
   228 (* ------------------------------------------------------------------------- *)
   229 (* Note: 'auxcnf' tends to use fewer variables and fewer clauses than        *)
   230 (*      'defcnf' below, but sometimes generates much larger SAT problems     *)
   231 (*      overall (hence it must sometimes generate longer clauses than        *)
   232 (*      'defcnf' does).  It is currently not quite clear to me if one of the *)
   233 (*      algorithms is clearly superior to the other, but I suggest using     *)
   234 (*      'defcnf' instead.                                                    *)
   235 (* ------------------------------------------------------------------------- *)
   236 
   237 	(* prop_formula -> prop_formula *)
   238 
   239 	fun auxcnf fm =
   240 	let
   241 		(* convert formula to NNF first *)
   242 		val fm' = nnf fm
   243 		(* 'new' specifies the next index that is available to introduce an auxiliary variable *)
   244 		(* int ref *)
   245 		val new = ref (maxidx fm' + 1)
   246 		(* unit -> int *)
   247 		fun new_idx () = let val idx = !new in new := idx+1; idx end
   248 		(* prop_formula -> prop_formula *)
   249 		fun
   250 		(* constants *)
   251 		    auxcnf_from_nnf True  = True
   252 		  | auxcnf_from_nnf False = False
   253 		(* literals *)
   254 		  | auxcnf_from_nnf (BoolVar i) = BoolVar i
   255 		  | auxcnf_from_nnf (Not fm1)   = Not fm1  (* 'fm1' must be a variable since the formula is in NNF *)
   256 		(* pushing 'or' inside of 'and' using auxiliary variables *)
   257 		  | auxcnf_from_nnf (Or (fm1, fm2)) =
   258 			let
   259 				val fm1' = auxcnf_from_nnf fm1
   260 				val fm2' = auxcnf_from_nnf fm2
   261 				(* prop_formula * prop_formula -> prop_formula *)
   262 				fun auxcnf_or (And (fm11, fm12), fm2) =
   263 					(case fm2 of
   264 					(* do not introduce an auxiliary variable for literals *)
   265 					  BoolVar _ =>
   266 							And (auxcnf_or (fm11, fm2), auxcnf_or (fm12, fm2))
   267 					| Not _ =>
   268 							And (auxcnf_or (fm11, fm2), auxcnf_or (fm12, fm2))
   269 					| _ =>
   270 						let
   271 							val aux = BoolVar (new_idx ())
   272 						in
   273 							And (And (auxcnf_or (fm11, aux), auxcnf_or (fm12, aux)), auxcnf_or (fm2, Not aux))
   274 						end)
   275 				  | auxcnf_or (fm1, And (fm21, fm22)) =
   276 					(case fm1 of
   277 					(* do not introduce an auxiliary variable for literals *)
   278 					  BoolVar _ =>
   279 							And (auxcnf_or (fm1, fm21), auxcnf_or (fm1, fm22))
   280 					| Not _ =>
   281 							And (auxcnf_or (fm1, fm21), auxcnf_or (fm1, fm22))
   282 					| _ =>
   283 						let
   284 							val aux = BoolVar (new_idx ())
   285 						in
   286 							And (auxcnf_or (fm1, Not aux), And (auxcnf_or (fm21, aux), auxcnf_or (fm22, aux)))
   287 						end)
   288 				(* neither subformula contains 'and' *)
   289 				  | auxcnf_or (fm1, fm2) =
   290 					Or (fm1, fm2)
   291 			in
   292 				auxcnf_or (fm1', fm2')
   293 			end
   294 		(* 'and' as outermost connective is left untouched *)
   295 		  | auxcnf_from_nnf (And (fm1, fm2)) =
   296 				And (auxcnf_from_nnf fm1, auxcnf_from_nnf fm2)
   297 	in
   298 		auxcnf_from_nnf fm'
   299 	end;
   300 
   301 (* ------------------------------------------------------------------------- *)
   302 (* defcnf: computes the definitional conjunctive normal form of a formula    *)
   303 (*      'fm' of propositional logic, introducing auxiliary variables to      *)
   304 (*      avoid an exponential blowup of the formula.  The result formula is   *)
   305 (*      satisfiable if and only if 'fm' is satisfiable.  Auxiliary variables *)
   306 (*      are introduced as abbreviations for AND-, OR-, and NOT-nodes, based  *)
   307 (*      on the following equisatisfiabilities (+/- indicates polarity):      *)
   308 (*      LITERAL+       == LITERAL                                            *)
   309 (*      LITERAL-       == NOT LITERAL                                        *)
   310 (*      (NOT fm1)+     == aux AND (NOT aux OR fm1-)                          *)
   311 (*      (fm1 OR fm2)+  == aux AND (NOT aux OR fm1+ OR fm2+)                  *)
   312 (*      (fm1 AND fm2)+ == aux AND (NOT aux OR fm1+) AND (NOT aux OR fm2+)    *)
   313 (*      (NOT fm1)-     == aux AND (NOT aux OR fm1+)                          *)
   314 (*      (fm1 OR fm2)-  == aux AND (NOT aux OR fm1-) AND (NOT aux OR fm2-)    *)
   315 (*      (fm1 AND fm2)- == aux AND (NOT aux OR fm1- OR fm2-)                  *)
   316 (*      Example:                                                             *)
   317 (*      NOT (a AND b) == aux1 AND (NOT aux1 OR aux2)                         *)
   318 (*                            AND (NOT aux2 OR NOT a OR NOT b)               *)
   319 (* ------------------------------------------------------------------------- *)
   320 
   321 	(* prop_formula -> prop_formula *)
   322 
   323 	fun defcnf fm =
   324 	let
   325 		(* simplify formula first *)
   326 		val fm' = simplify fm
   327 		(* 'new' specifies the next index that is available to introduce an auxiliary variable *)
   328 		(* int ref *)
   329 		val new = ref (maxidx fm' + 1)
   330 		(* unit -> int *)
   331 		fun new_idx () = let val idx = !new in new := idx+1; idx end
   332 		(* optimization for n-ary disjunction/conjunction *)
   333 		(* prop_formula -> prop_formula list *)
   334 		fun disjuncts (Or (fm1, fm2)) = (disjuncts fm1) @ (disjuncts fm2)
   335 		  | disjuncts fm1             = [fm1]
   336 		(* prop_formula -> prop_formula list *)
   337 		fun conjuncts (And (fm1, fm2)) = (conjuncts fm1) @ (conjuncts fm2)
   338 		  | conjuncts fm1              = [fm1]
   339 		(* polarity -> formula -> (defining clauses, literal) *)
   340 		(* bool -> prop_formula -> prop_formula * prop_formula *)
   341 		fun
   342 		(* constants *)
   343 		    defcnf' true  True  = (True, True)
   344 		  | defcnf' false True  = (*(True, False)*) error "formula is not simplified, True occurs with negative polarity"
   345 		  | defcnf' true  False = (True, False)
   346 		  | defcnf' false False = (*(True, True)*) error "formula is not simplified, False occurs with negative polarity"
   347 		(* literals *)
   348 		  | defcnf' true  (BoolVar i)       = (True, BoolVar i)
   349 		  | defcnf' false (BoolVar i)       = (True, Not (BoolVar i))
   350 		  | defcnf' true  (Not (BoolVar i)) = (True, Not (BoolVar i))
   351 		  | defcnf' false (Not (BoolVar i)) = (True, BoolVar i)
   352 		(* 'not' *)
   353 		  | defcnf' polarity (Not fm1) =
   354 			let
   355 				val (def1, aux1) = defcnf' (not polarity) fm1
   356 				val aux          = BoolVar (new_idx ())
   357 				val def          = Or (Not aux, aux1)
   358 			in
   359 				(SAnd (def1, def), aux)
   360 			end
   361 		(* 'or' *)
   362 		  | defcnf' polarity (Or (fm1, fm2)) =
   363 			let
   364 				val fms          = disjuncts (Or (fm1, fm2))
   365 				val (defs, auxs) = split_list (map (defcnf' polarity) fms)
   366 				val aux          = BoolVar (new_idx ())
   367 				val def          = if polarity then Or (Not aux, exists auxs) else all (map (fn a => Or (Not aux, a)) auxs)
   368 			in
   369 				(SAnd (all defs, def), aux)
   370 			end
   371 		(* 'and' *)
   372 		  | defcnf' polarity (And (fm1, fm2)) =
   373 			let
   374 				val fms          = conjuncts (And (fm1, fm2))
   375 				val (defs, auxs) = split_list (map (defcnf' polarity) fms)
   376 				val aux          = BoolVar (new_idx ())
   377 				val def          = if not polarity then Or (Not aux, exists auxs) else all (map (fn a => Or (Not aux, a)) auxs)
   378 			in
   379 				(SAnd (all defs, def), aux)
   380 			end
   381 		(* optimization: do not introduce auxiliary variables for parts of the formula that are in CNF already *)
   382 		(* prop_formula -> prop_formula * prop_formula *)
   383 		fun defcnf_or (Or (fm1, fm2)) =
   384 			let
   385 				val (def1, aux1) = defcnf_or fm1
   386 				val (def2, aux2) = defcnf_or fm2
   387 			in
   388 				(SAnd (def1, def2), Or (aux1, aux2))
   389 			end
   390 		  | defcnf_or fm =
   391 			defcnf' true fm
   392 		(* prop_formula -> prop_formula * prop_formula *)
   393 		fun defcnf_and (And (fm1, fm2)) =
   394 			let
   395 				val (def1, aux1) = defcnf_and fm1
   396 				val (def2, aux2) = defcnf_and fm2
   397 			in
   398 				(SAnd (def1, def2), And (aux1, aux2))
   399 			end
   400 		  | defcnf_and (Or (fm1, fm2)) =
   401 			let
   402 				val (def1, aux1) = defcnf_or fm1
   403 				val (def2, aux2) = defcnf_or fm2
   404 			in
   405 				(SAnd (def1, def2), Or (aux1, aux2))
   406 			end
   407 		  | defcnf_and fm =
   408 			defcnf' true fm
   409 	in
   410 		SAnd (defcnf_and fm')
   411 	end;
   412 
   413 (* ------------------------------------------------------------------------- *)
   414 (* eval: given an assignment 'a' of Boolean values to variable indices, the  *)
   415 (*      truth value of a propositional formula 'fm' is computed              *)
   416 (* ------------------------------------------------------------------------- *)
   417 
   418 	(* (int -> bool) -> prop_formula -> bool *)
   419 
   420 	fun eval a True            = true
   421 	  | eval a False           = false
   422 	  | eval a (BoolVar i)     = (a i)
   423 	  | eval a (Not fm)        = not (eval a fm)
   424 	  | eval a (Or (fm1,fm2))  = (eval a fm1) orelse (eval a fm2)
   425 	  | eval a (And (fm1,fm2)) = (eval a fm1) andalso (eval a fm2);
   426 
   427 (* ------------------------------------------------------------------------- *)
   428 (* prop_formula_of_term: returns the propositional structure of a HOL term,  *)
   429 (*      with subterms replaced by Boolean variables.  Also returns a table   *)
   430 (*      of terms and corresponding variables that extends the table that was *)
   431 (*      given as an argument.  Usually, you'll just want to use              *)
   432 (*      'Termtab.empty' as value for 'table'.                                *)
   433 (* ------------------------------------------------------------------------- *)
   434 
   435 (* Note: The implementation is somewhat optimized; the next index to be used *)
   436 (*       is computed only when it is actually needed.  However, when         *)
   437 (*       'prop_formula_of_term' is invoked many times, it might be more      *)
   438 (*       efficient to pass and return this value as an additional parameter, *)
   439 (*       so that it does not have to be recomputed (by folding over the      *)
   440 (*       table) for each invocation.                                         *)
   441 
   442 	(* Term.term -> int Termtab.table -> prop_formula * int Termtab.table *)
   443 	fun prop_formula_of_term t table =
   444 	let
   445 		val next_idx_is_valid = ref false
   446 		val next_idx          = ref 0
   447 		fun get_next_idx () =
   448 			if !next_idx_is_valid then
   449 				inc next_idx
   450 			else (
   451 				next_idx          := Termtab.fold (curry Int.max o snd) table 0;
   452 				next_idx_is_valid := true;
   453 				inc next_idx
   454 			)
   455 		fun aux (Const ("True", _))         table =
   456 			(True, table)
   457 		  | aux (Const ("False", _))        table =
   458 			(False, table)
   459 		  | aux (Const ("Not", _) $ x)      table =
   460 			apfst Not (aux x table)
   461 		  | aux (Const ("op |", _) $ x $ y) table =
   462 			let
   463 				val (fm1, table1) = aux x table
   464 				val (fm2, table2) = aux y table1
   465 			in
   466 				(Or (fm1, fm2), table2)
   467 			end
   468 		  | aux (Const ("op &", _) $ x $ y) table =
   469 			let
   470 				val (fm1, table1) = aux x table
   471 				val (fm2, table2) = aux y table1
   472 			in
   473 				(And (fm1, fm2), table2)
   474 			end
   475 		  | aux x                           table =
   476 			(case Termtab.lookup table x of
   477 			  SOME i =>
   478 				(BoolVar i, table)
   479 			| NONE   =>
   480 				let
   481 					val i = get_next_idx ()
   482 				in
   483 					(BoolVar i, Termtab.update (x, i) table)
   484 				end)
   485 	in
   486 		aux t table
   487 	end;
   488 
   489 end;